Subversion Repositories Kolibri OS

Rev

Rev 2700 | Rev 4716 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;---------------------------------------------------------------------
  2. ;
  3. ;   DOCPAK FOR KOLIBRI v1.2
  4. ;   Written in pure assembly by Ivushkin Andrey aka Willow
  5. ;
  6. ;---------------------------------------------------------------------
  7.  
  8. FILE_COUNT=0
  9. DEF_FILE equ 'g'
  10.  
  11. macro embed_file fn
  12. {
  13.  forward
  14.    local label,label2,label3
  15.    dd label2-label
  16.    dd label-label3
  17.    label3:
  18.    db fn
  19.    label:
  20.      file '%DOCDIR%' # fn
  21.    label2:
  22.    FILE_COUNT=FILE_COUNT+1
  23. }
  24.  
  25.    use32
  26.    org    0x0
  27.    db     'MENUET01'              ; 8 byte id
  28.    dd     0x01                    ; header version
  29.    dd     start                   ; start of code
  30.    dd     I_END                   ; size of image
  31.    dd     I_END+0x400             ; memory for app
  32.    dd     I_END+0x400             ; esp
  33.    dd     my_param , 0x0          ; I_Param , I_Icon
  34. include '../../../macros.inc'
  35. include 'lang.inc'
  36.  
  37. start:
  38.   cmp   [my_param],0
  39.   je    red
  40.   cmp   [my_param],'a'
  41.   jb    .par_a
  42.   cmp   [my_param],'z'
  43.   jbe   .ok2
  44.  .par_a:
  45.   mov   [my_param],DEF_FILE
  46.  .ok2:
  47.   movzx ecx,[my_param]
  48.   mov   [my_param],'*'
  49.  .open:
  50.   sub   ecx,'a'-1
  51.   mov   edx,embedded
  52.   xor   esi,esi
  53.  .list:
  54.   lea   edx,[edx+esi+8]
  55.   mov   esi,[edx-8]
  56.   add   edx,[edx-4]
  57.   test  esi,esi
  58.   jz    .close
  59.   loop  .list
  60.         push    edx
  61. ; convert number in esi to decimal representation
  62.         mov     ecx, 10
  63.         push    -'0'
  64.         mov     eax, esi
  65. @@:
  66.         xor     edx, edx
  67.         div     ecx
  68.         push    edx
  69.         test    eax, eax
  70.         jnz     @b
  71.         mov     edi, fsize
  72. @@:
  73.         pop     eax
  74.         add     al, '0'
  75.         stosb
  76.         jnz     @b
  77.   mcall 70,fileinfo
  78.   mov   ecx,eax
  79.   mcall 5,20
  80.   pop   edx
  81.   mcall 60,2
  82.   cmp   [my_param],'*'
  83.   jne   still
  84.  .close:
  85.   mcall -1
  86.  
  87. red:
  88.   mov   [my_param],'a'
  89.  
  90.   mcall 48, 3, sc, sizeof.system_colors
  91.  
  92.   mcall 12,1
  93.  
  94.   mov  edx,[sc.work]
  95.   or   edx,0x34000000
  96.   mcall 0, <220,120>, <30,FILECOUNT*16+35>, , ,title
  97.  
  98.   mov   ecx,FILECOUNT
  99.   mov   ebx,5 shl 16+100
  100.   mov   esi,[sc.work_button]
  101.   mov   edi,5 shl 16+14
  102.   mov   edx,10
  103.   mov   eax,8
  104.  .btnlp:
  105.   push  ecx
  106.   mcall ,,edi
  107.   add   edi,16 shl 16
  108.   inc   edx
  109.   pop   ecx
  110.   loop  .btnlp
  111.   mov   ecx,FILECOUNT
  112.   mov   edx,embedded
  113.   xor   edi,edi
  114.   mov   ebx,25 shl 16+8
  115.   mov   eax,4
  116.  .list:
  117.   lea   edx,[edx+edi+8]
  118.   mov   edi,[edx-8]
  119.   pusha
  120.   sub   ebx,15 shl 16
  121.   mcall ,,0xff0000,my_param,1
  122.   inc   [my_param]
  123.   popa
  124.   push  ecx
  125.   mcall ,,[sc.work_button_text],,[edx-4]
  126.   pop   ecx
  127.   add   edx,esi
  128.   add   ebx,16
  129.   loop  .list
  130.   mcall 12,2
  131.  
  132. still:
  133.   mcall 10
  134.   cmp   eax,1
  135.   je    red
  136.   cmp   eax,2
  137.   jne   .nokey
  138.   mcall 2
  139.   cmp   ah,27 ;Esc
  140.   je    start.close
  141.   cmp   ah,'a'
  142.   jb    still
  143.   cmp   ah,'a'+FILECOUNT
  144.   jae   still
  145.   jmp   .cxax
  146.  .nokey:
  147.   mcall 17
  148.   cmp   ah,1
  149.   je    start.close
  150.   sub   ah,10-'a'
  151.  .cxax:
  152.   movzx  ecx,ah
  153.   jmp   start.open
  154.  
  155. fileinfo:
  156.         dd      7
  157.         dd      0
  158.         dd      param
  159.         dd      0 ,0
  160.         db      '/sys/TINYPAD',0
  161.  
  162. param  db '*'
  163. fsize:
  164.        times 10 db '0'
  165.        db 0
  166.  
  167. embedded:
  168.  
  169. ; Please use only filenames w/o path!
  170.  
  171. ; -- Start of embedding area ------
  172.   embed_file 'README.TXT'        ;a
  173. if lang eq ru
  174.   embed_file 'GNU.TXT'           ;b
  175. else
  176.   embed_file 'COPYING.TXT'       ;b
  177. end if
  178.   embed_file 'HOT_KEYS.TXT'      ;c
  179.   embed_file 'FASM.TXT'          ;d
  180.   embed_file 'MTDBG.TXT'         ;e
  181. if lang eq ru
  182.   embed_file 'SYSFUNCR.TXT'      ;f
  183. else
  184.   embed_file 'SYSFUNCS.TXT'      ;f
  185. end if
  186.   embed_file 'STACK.TXT'         ;g
  187.   embed_file 'KFAR_KEYS.TXT'     ;h
  188.   embed_file 'INI.TXT'           ;i
  189.   embed_file 'OPENDIAL.TXT'      ;j
  190. ; -- End of embedding area  -------
  191.  
  192.   dd 0
  193. FILECOUNT = FILE_COUNT
  194.  
  195.   if ~ FILECOUNT>0
  196.     error 'No embedded files'
  197.   end if
  198.  
  199. my_param db 0
  200.   rb 256
  201. I_END:
  202.  
  203. title db 'Doc Pack',0
  204.  
  205. sc     system_colors
  206.