Subversion Repositories Kolibri OS

Rev

Rev 5677 | Rev 5693 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                                 ;;
  3. ;; Copyright (C) KolibriOS team 2010-2015. All rights reserved.    ;;
  4. ;; Distributed under terms of the GNU General Public License       ;;
  5. ;;                                                                 ;;
  6. ;;  VNC client for KolibriOS                                       ;;
  7. ;;                                                                 ;;
  8. ;;  Written by hidnplayr@kolibrios.org                             ;;
  9. ;;                                                                 ;;
  10. ;;          GNU GENERAL PUBLIC LICENSE                             ;;
  11. ;;             Version 2, June 1991                                ;;
  12. ;;                                                                 ;;
  13. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  14.  
  15. format binary as ""
  16.  
  17. __DEBUG__       = 1
  18. __DEBUG_LEVEL__ = 2
  19.  
  20. BITS_PER_PIXEL  = 8             ; 8, 16 24
  21.  
  22. use32
  23.  
  24.         org     0x0
  25.  
  26.         db      "MENUET01"      ; 8 byte id
  27.         dd      0x01            ; header version
  28.         dd      START           ; start of code
  29.         dd      I_END           ; size of image
  30.         dd      IM_END          ; memory for app
  31.         dd      IM_END          ; esp
  32.         dd      0x0, 0x0        ; I_Param , I_Path
  33.  
  34. include "../../macros.inc"
  35. include "../../debug-fdo.inc"
  36. include "../../proc32.inc"
  37. include "../../dll.inc"
  38. include "../../struct.inc"
  39. include "../../develop/libraries/box_lib/trunk/box_lib.mac"
  40. include "../../network.inc"
  41.  
  42. struct  pixel_format
  43.         bpp             db ?
  44.         depth           db ?
  45.         big_endian      db ?
  46.         true_color      db ?
  47.         red_max         dw ?
  48.         green_max       dw ?
  49.         blue_max        dw ?
  50.         red_shift       db ?
  51.         green_shift     db ?
  52.         blue_shift      db ?
  53.         padding         rb 3
  54. ends
  55.  
  56. struct  framebuffer
  57.         width           dw ?
  58.         height          dw ?
  59.         pixelformat     pixel_format
  60.         name_length     dd ?
  61.         name            rb 256
  62. ends
  63.  
  64. xpos                    = 4
  65. ypos                    = 21
  66.  
  67. TIMEOUT                 = 5             ; timeout in seconds
  68.  
  69. RECEIVE_BUFFER_SIZE     = 8*1024*1024   ; 8 Mib
  70.  
  71. STATUS_INITIAL          = 0
  72. STATUS_CONNECTING       = 1
  73. STATUS_REQ_LOGIN        = 2
  74. STATUS_LOGIN            = 3
  75. STATUS_CONNECTED        = 4
  76. STATUS_CLOSED           = 5
  77.  
  78. STATUS_DISCONNECTED     = 10
  79. STATUS_DNS_ERR          = 11
  80. STATUS_SOCK_ERR         = 12
  81. STATUS_CONNECT_ERR      = 13
  82. STATUS_PROTO_ERR        = 14
  83. STATUS_SECURITY_ERR     = 15
  84. STATUS_LIB_ERR          = 16
  85. STATUS_THREAD_ERR       = 17
  86. STATUS_LOGIN_FAILED     = 18
  87.  
  88. include "keymap.inc"
  89. include "gui.inc"
  90. include "network.inc"
  91. include "raw.inc"
  92. include "copyrect.inc"
  93. include "rre.inc"
  94. include "des.inc"
  95.  
  96. START:
  97.  
  98.         mcall   68, 11                  ; init heap
  99.  
  100. ; Load libraries
  101.         stdcall dll.Load, @IMPORT
  102.         test    eax, eax
  103.         jz      @f
  104.         mov     [status], STATUS_LIB_ERR
  105.   @@:
  106.  
  107. ; Present the user with the GUI and wait for network connection
  108.         call    draw_gui
  109.  
  110. ; Create main window
  111.         mcall   71, 1, name             ; reset window caption (add server name)
  112.  
  113.         mov     edx, dword[screen]
  114.         movzx   esi, dx
  115.         shr     edx, 16
  116.         add     edx, 2*xpos
  117.         add     esi, ypos+xpos
  118.         mcall   67, 10, 10              ; resize the window
  119.  
  120.         mcall   40, EVM_MOUSE + EVM_MOUSE_FILTER + EVM_KEY + EVM_REDRAW + EVM_BUTTON
  121.  
  122.         mcall   66, 1, 1                ; Switch keyboard to scancode mode
  123.  
  124.         call    generate_keymap
  125.  
  126. redraw:
  127.         mcall   12, 1
  128.  
  129.         mov     ebx, dword[screen]
  130.         movzx   ecx, bx
  131.         shr     ebx, 16
  132.         mov     edx, 0x74ffffff
  133.         mov     edi, name
  134.         mcall   0                       ; draw window
  135.  
  136.         mcall   12, 2
  137.  
  138. draw_framebuffer:
  139.         mcall   7, framebuffer_data, dword[screen], 0
  140.         mov     [update_framebuffer], 0
  141.  
  142. mainloop:
  143.         cmp     [status], STATUS_CONNECTED
  144.         jne     draw_gui
  145.         cmp     [update_framebuffer], 0
  146.         jne     draw_framebuffer
  147.  
  148.         mcall   23, 10                  ; Check for event with 0,1s timeout
  149.  
  150.         dec     eax
  151.         jz      redraw
  152.         dec     eax
  153.         jz      key
  154.         dec     eax
  155.         jz      button
  156.         sub     eax, 3
  157.         jz      mouse
  158.         jmp     mainloop
  159.  
  160. key:
  161.         mcall   66, 3
  162.         mov     ebx, eax
  163.  
  164.         mcall   2
  165.         cmp     ah, 224         ; ext
  166.         je      mainloop        ;; TODO
  167.  
  168.         xor     al, al
  169.         test    ah, 0x80        ; key up?
  170.         jnz     @f
  171.         inc     al
  172.   @@:
  173.         mov     byte[KeyEvent.down], al
  174.  
  175.         shr     eax, 7
  176.         and     eax, 0x000000fe
  177.  
  178.         test    ebx, 100000b    ; alt?
  179.         jz      @f
  180.         add     eax, 512
  181.         jmp     .key
  182.   @@:
  183.         test    ebx, 11b        ; shift?
  184.         jz      @f
  185.         add     eax, 256
  186.   @@:
  187.   .key:
  188.         mov     ax, [keymap+eax]
  189.         mov     word[KeyEvent.key+2], ax
  190.         DEBUGF  1, "Sending key: 0x%x\n", ax
  191.         mcall   send, [socketnum], KeyEvent, 8, 0
  192.         jmp     mainloop
  193.  
  194.  
  195. mouse:
  196. ;        DEBUGF  1, "Sending pointer event\n"
  197.  
  198.         mcall   37, 1           ; get mouse pos
  199.         bswap   eax
  200.         mov     [PointerEvent.x], ax
  201.         shr     eax, 16
  202.         mov     [PointerEvent.y], ax
  203.  
  204.         mcall   37, 2           ; get mouse buttons
  205.         test    al, 00000010b   ; test if right button was pressed  (bit 1 in kolibri)
  206.         jz      @f
  207.         add     al, 00000010b   ; in RFB protocol it is bit 2, so if we add bit 2 again, we"ll get bit 3 and bit 1 will remain the same
  208.       @@:
  209.         mov     [PointerEvent.mask], al
  210.  
  211.         mcall   send, [socketnum], PointerEvent, 6, 0
  212.         jmp     mainloop
  213.  
  214. button:
  215.         mcall   17              ; get id
  216.         mov     [status], STATUS_CLOSED
  217.         mcall   close, [socketnum]
  218.         mcall   -1
  219.  
  220.  
  221. ; DATA AREA
  222.  
  223. include_debug_strings
  224.  
  225. HandShake               db "RFB 003.003", 10
  226.  
  227. ClientInit              db 0            ; not shared
  228.  
  229. SetPixelFormat32        db 0            ; setPixelformat
  230.                         db 0, 0, 0      ; padding
  231. .bpp                    db 32           ; bits per pixel
  232. .depth                  db 32           ; depth
  233. .big_endian             db 0            ; big-endian flag
  234. .true_color             db 1            ; true-colour flag
  235. .red_max                db 0, 255       ; red-max
  236. .green_max              db 0, 255       ; green-max
  237. .blue_max               db 0, 255       ; blue-max
  238. .red_shif               db 0            ; red-shift
  239. .green_shift            db 8            ; green-shift
  240. .blue_shift             db 16           ; blue-shift
  241.                         db 0, 0, 0      ; padding
  242.  
  243. SetPixelFormat24        db 0            ; setPixelformat
  244.                         db 0, 0, 0      ; padding
  245. .bpp                    db 24           ; bits per pixel
  246. .depth                  db 24           ; depth
  247. .big_endian             db 0            ; big-endian flag
  248. .true_color             db 1            ; true-colour flag
  249. .red_max                db 0, 255       ; red-max
  250. .green_max              db 0, 255       ; green-max
  251. .blue_max               db 0, 255       ; blue-max
  252. .red_shift              db 16           ; red-shift
  253. .green_shift            db 8            ; green-shift
  254. .blue_shift             db 0            ; blue-shift
  255.                         db 0, 0, 0      ; padding
  256.  
  257. SetPixelFormat16        db 0            ; setPixelformat
  258.                         db 0, 0, 0      ; padding
  259. .bpp                    db 16           ; bits per pixel
  260. .depth                  db 16           ; depth
  261. .big_endian             db 0            ; big-endian flag
  262. .true_color             db 1            ; true-colour flag
  263. .red_max                db 0, 31        ; red-max
  264. .green_max              db 0, 63        ; green-max
  265. .blue_max               db 0, 31        ; blue-max
  266. .red_shift              db 11           ; red-shift
  267. .green_shift            db 5            ; green-shift
  268. .blue_shift             db 0            ; blue-shift
  269.                         db 0, 0, 0      ; padding
  270.  
  271. SetPixelFormat8         db 0            ; setPixelformat
  272.                         db 0, 0, 0      ; padding
  273. .bpp                    db 8            ; bits per pixel
  274. .depth                  db 8            ; depth
  275. .big_endian             db 0            ; big-endian flag
  276. .true_color             db 1            ; true-colour flag
  277. .red_max                db 0, 7         ; red-max
  278. .green_max              db 0, 7         ; green-max
  279. .blue_max               db 0, 3         ; blue-max
  280. .red_shift              db 0            ; red-shift
  281. .green_shift            db 3            ; green-shift
  282. .blue_shift             db 6            ; blue-shift
  283.                         db 0, 0, 0      ; padding
  284.  
  285. SetEncodings            db 2            ; setEncodings
  286.                         db 0            ; padding
  287.                         db 0, 2         ; number of encodings
  288.                         db 0, 0, 0, 0   ; raw encoding        (DWORD, Big endian order)
  289.                         db 0, 0, 0, 1   ; Copyrect encoding
  290. ;                        db 0, 0, 0, 2   ; RRE
  291. ;                        db 0, 0, 0, 5   ; HexTile
  292. ;                        db 0, 0, 0, 15  ; TRLE
  293. ;                        db 0, 0, 0, 16  ; ZRLE
  294.  
  295. FramebufferUpdateRequest        db 3
  296. .inc                            db 0    ; incremental
  297. .x                              dw 0
  298. .y                              dw 0
  299. .width                          dw 0
  300. .height                         dw 0
  301.  
  302. KeyEvent                db 4            ; keyevent
  303. .down                   db 0            ; down-flag
  304.                         dw 0            ; padding
  305. .key                    dd 0            ; key
  306.  
  307. PointerEvent            db 5            ; pointerevent
  308. .mask                   db 0            ; button-mask
  309. .x                      dw 0            ; x-position
  310. .y                      dw 0            ; y-position
  311.  
  312.  
  313. sockaddr1:
  314.                 dw AF_INET4
  315. .port           dw 0x0c17               ; 5900
  316. .ip             dd 0
  317.                 rb 10
  318.  
  319. beep            db 0x85, 0x25, 0x85, 0x40, 0
  320.  
  321. status                  dd STATUS_INITIAL
  322. update_gui              dd 0
  323. mouse_dd                dd 0
  324. update_framebuffer      dd 0
  325.  
  326. URLbox          edit_box 235, 70, 10, 0xffffff, 0x6f9480, 0, 0, 0, 65535, serveraddr, mouse_dd, ed_focus, 0, 0
  327. USERbox         edit_box 200, 90, 10, 0xffffff, 0x6f9480, 0, 0, 0, 127, username, mouse_dd, ed_focus, 0, 0
  328. PASSbox         edit_box 200, 90, 30, 0xffffff, 0x6f9480, 0, 0, 0, 127, password, mouse_dd, ed_pass, 0, 0
  329.  
  330. serverstr       db "server:"
  331. userstr         db "username:"
  332. passstr         db "password:"
  333. connectstr      db "Connect"
  334. loginstr        db "Log in"
  335. loginstr_e:
  336.  
  337. sz_err_disconnected     db "Server closed connection unexpectedly.", 0
  338. sz_err_dns              db "Could not resolve hostname.", 0
  339. sz_err_sock             db "Could not open socket.", 0
  340. sz_err_connect          db "Could not connect to the server.", 0
  341. sz_err_proto            db "A protocol error has occured.", 0
  342. sz_err_security         db "Server requested an unsupported security type.", 0
  343. sz_err_library          db "Could not load needed libraries.", 0
  344. sz_err_thread           db "Could not create thread.", 0
  345. sz_err_login_failed     db "Login failed.", 0
  346.  
  347. err_msg         dd sz_err_disconnected
  348.                 dd sz_err_dns
  349.                 dd sz_err_sock
  350.                 dd sz_err_connect
  351.                 dd sz_err_proto
  352.                 dd sz_err_security
  353.                 dd sz_err_library
  354.                 dd sz_err_thread
  355.                 dd sz_err_login_failed
  356.  
  357. ; import
  358. align 4
  359. @IMPORT:
  360.  
  361. library network,                "network.obj",\
  362.         box_lib,                "box_lib.obj",\
  363.         archiver,               "archiver.obj"
  364.  
  365. import  network,\
  366.         getaddrinfo,            "getaddrinfo",  \
  367.         freeaddrinfo,           "freeaddrinfo", \
  368.         inet_ntoa,              "inet_ntoa"
  369.  
  370. import  box_lib,\
  371.         edit_box_draw,          "edit_box",\
  372.         edit_box_key,           "edit_box_key",\
  373.         edit_box_mouse,         "edit_box_mouse",\
  374.         scrollbar_v_draw,       "scrollbar_v_draw",\
  375.         scrollbar_v_mouse,      "scrollbar_v_mouse",\
  376.         scrollbar_h_draw,       "scrollbar_h_draw",\
  377.         scrollbar_h_mouse,      "scrollbar_h_mouse"
  378.  
  379. import  archiver,\
  380.         deflate_unpack,         "deflate_unpack"
  381.  
  382. name                    db "VNC viewer "
  383. .dash                   db 0, " "
  384.  
  385. I_END:
  386.  
  387. servername              rb 64+1
  388.  
  389. socketnum               dd ?
  390. datapointer             dd ?
  391.  
  392. rectangles              dw ?
  393.  
  394. rectangle:
  395. .x                      dd ?
  396. .y                      dd ?
  397. .width                  dd ?
  398. .height                 dd ?
  399.  
  400. subrectangles           dd ?
  401.  
  402. subrectangle:
  403. .x                      dd ?
  404. .y                      dd ?
  405. .width                  dd ?
  406. .height                 dd ?
  407.  
  408. screen:                 ; Remote screen resolution
  409. .height                 dw ?
  410. .width                  dw ?
  411.  
  412. keymap                  rw 128
  413. keymap_shift            rw 128
  414. keymap_alt              rw 128
  415. username                rb 128
  416. password                rb 128
  417. keys                    rd 32*2         ; DES keys for VNC authentication
  418.  
  419. serveraddr              rb 65536
  420. receive_buffer          rb RECEIVE_BUFFER_SIZE
  421. framebuffer_data        rb 1280*1024*3  ; framebuffer
  422.  
  423.                         rb 0x1000
  424. thread_stack:
  425.                         rb 0x1000
  426. IM_END:
  427.  
  428.  
  429.