Subversion Repositories Kolibri OS

Rev

Go to most recent revision | Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2005, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. preprocessor:
  7.         mov     edi,characters
  8.         mov     ecx,100h
  9.         xor     al,al
  10.       make_characters_table:
  11.         stosb
  12.         inc     al
  13.         loop    make_characters_table
  14.         mov     esi,characters+'a'
  15.         mov     edi,characters+'A'
  16.         mov     ecx,26
  17.         rep     movsb
  18.         mov     edi,characters
  19.         mov     esi,symbol_characters+1
  20.         movzx   ecx,byte [esi-1]
  21.         xor     eax,eax
  22.       mark_symbol_characters:
  23.         lodsb
  24.         mov     byte [edi+eax],0
  25.         loop    mark_symbol_characters
  26.         mov     edi,locals_counter
  27.         mov     al,7
  28.         stos    byte [edi]
  29.         movzx   ecx,al
  30.         mov     al,'0'
  31.         rep     stos byte [edi]
  32.         mov     edi,[memory_start]
  33.         mov     [include_paths],edi
  34.         mov     esi,include_variable
  35.         call    get_environment_variable
  36.         xor     al,al
  37.         stosb
  38.         mov     [memory_start],edi
  39.         mov     eax,[additional_memory]
  40.         mov     [free_additional_memory],eax
  41.         mov     eax,[additional_memory_end]
  42.         mov     [labels_list],eax
  43.         xor     eax,eax
  44.         mov     [display_buffer],eax
  45.         mov     [hash_tree],eax
  46.         mov     [macro_status],al
  47.         mov     esi,[input_file]
  48.         mov     edx,esi
  49.         call    open
  50.         jc      main_file_not_found
  51.         mov     edi,[memory_start]
  52.         call    preprocess_file
  53.         mov     eax,[error_line]
  54.         mov     [current_line],eax
  55.         cmp     [macro_status],0
  56.         jne     incomplete_macro
  57.         mov     [source_start],edi
  58.         ret
  59.  
  60. preprocess_file:
  61.         push    [memory_end]
  62.         push    esi
  63.         mov     al,2
  64.         xor     edx,edx
  65.         call    lseek
  66.         push    eax
  67.         xor     al,al
  68.         xor     edx,edx
  69.         call    lseek
  70.         pop     ecx
  71.         mov     edx,[memory_end]
  72.         dec     edx
  73.         mov     byte [edx],1Ah
  74.         sub     edx,ecx
  75.         jc      out_of_memory
  76.         mov     esi,edx
  77.         cmp     edx,edi
  78.         jbe     out_of_memory
  79.         mov     [memory_end],edx
  80.         call    read
  81.         call    close
  82.         pop     edx
  83.         xor     ecx,ecx
  84.         mov     ebx,esi
  85.       preprocess_source:
  86.         inc     ecx
  87.         mov     [current_line],edi
  88.         mov     eax,edx
  89.         stos    dword [edi]
  90.         mov     eax,ecx
  91.         stos    dword [edi]
  92.         mov     eax,esi
  93.         sub     eax,ebx
  94.         stos    dword [edi]
  95.         xor     eax,eax
  96.         stos    dword [edi]
  97.         push    ebx edx
  98.         call    convert_line
  99.         call    preprocess_line
  100.         pop     edx ebx
  101.       next_line:
  102.         cmp     byte [esi-1],1Ah
  103.         jne     preprocess_source
  104.       file_end:
  105.         pop     [memory_end]
  106.         clc
  107.         ret
  108.  
  109. convert_line:
  110.         push    ecx
  111.         test    [macro_status],0Fh
  112.         jz      convert_line_data
  113.         mov     ax,3Bh
  114.         stos    word [edi]
  115.       convert_line_data:
  116.         cmp     edi,[memory_end]
  117.         jae     out_of_memory
  118.         lods    byte [esi]
  119.         cmp     al,20h
  120.         je      convert_line_data
  121.         cmp     al,9
  122.         je      convert_line_data
  123.         mov     ah,al
  124.         mov     ebx,characters
  125.         xlat    byte [ebx]
  126.         or      al,al
  127.         jz      convert_separator
  128.         cmp     ah,27h
  129.         je      convert_string
  130.         cmp     ah,22h
  131.         je      convert_string
  132.         mov     byte [edi],1Ah
  133.         scas    word [edi]
  134.         xchg    al,ah
  135.         stos    byte [edi]
  136.         mov     ebx,characters
  137.         xor     ecx,ecx
  138.       convert_symbol:
  139.         lods    byte [esi]
  140.         stos    byte [edi]
  141.         xlat    byte [ebx]
  142.         or      al,al
  143.         loopnzd convert_symbol
  144.         neg     ecx
  145.         cmp     ecx,255
  146.         ja      name_too_long
  147.         mov     ebx,edi
  148.         sub     ebx,ecx
  149.         mov     byte [ebx-2],cl
  150.       found_separator:
  151.         dec     edi
  152.         mov     ah,[esi-1]
  153.       convert_separator:
  154.         xchg    al,ah
  155.         cmp     al,20h
  156.         jb      control_character
  157.         je      convert_line_data
  158.       symbol_character:
  159.         cmp     al,3Bh
  160.         je      ignore_comment
  161.         cmp     al,5Ch
  162.         je      backslash_character
  163.         stos    byte [edi]
  164.         jmp     convert_line_data
  165.       control_character:
  166.         cmp     al,1Ah
  167.         je      line_end
  168.         cmp     al,0Dh
  169.         je      cr_character
  170.         cmp     al,0Ah
  171.         je      lf_character
  172.         cmp     al,9
  173.         je      convert_line_data
  174.         or      al,al
  175.         jnz     symbol_character
  176.         jmp     line_end
  177.       lf_character:
  178.         lods    byte [esi]
  179.         cmp     al,0Dh
  180.         je      line_end
  181.         dec     esi
  182.         jmp     line_end
  183.       cr_character:
  184.         lods    byte [esi]
  185.         cmp     al,0Ah
  186.         je      line_end
  187.         dec     esi
  188.         jmp     line_end
  189.       convert_string:
  190.         mov     al,22h
  191.         stos    byte [edi]
  192.         scas    dword [edi]
  193.         mov     ebx,edi
  194.       copy_string:
  195.         lods    byte [esi]
  196.         stos    byte [edi]
  197.         cmp     al,0Ah
  198.         je      missing_end_quote
  199.         cmp     al,0Dh
  200.         je      missing_end_quote
  201.         or      al,al
  202.         jz      missing_end_quote
  203.         cmp     al,1Ah
  204.         je      missing_end_quote
  205.         cmp     al,ah
  206.         jne     copy_string
  207.         lods    byte [esi]
  208.         cmp     al,ah
  209.         je      copy_string
  210.         dec     esi
  211.         dec     edi
  212.         mov     eax,edi
  213.         sub     eax,ebx
  214.         mov     [ebx-4],eax
  215.         jmp     convert_line_data
  216.       backslash_character:
  217.         mov     byte [edi],0
  218.         lods    byte [esi]
  219.         cmp     al,20h
  220.         je      concatenate_lines
  221.         cmp     al,9
  222.         je      concatenate_lines
  223.         cmp     al,1Ah
  224.         je      unexpected_end_of_file
  225.         cmp     al,0Ah
  226.         je      concatenate_lf
  227.         cmp     al,0Dh
  228.         je      concatenate_cr
  229.         cmp     al,3Bh
  230.         je      find_concatenated_line
  231.         mov     al,1Ah
  232.         stos    byte [edi]
  233.         mov     ecx,edi
  234.         mov     ax,5C01h
  235.         stos    word [edi]
  236.         dec     esi
  237.       group_backslashes:
  238.         lods    byte [esi]
  239.         cmp     al,5Ch
  240.         jne     backslashed_symbol
  241.         stos    byte [edi]
  242.         inc     byte [ecx]
  243.         jmp     group_backslashes
  244.       backslashed_symbol:
  245.         cmp     al,1Ah
  246.         je      unexpected_end_of_file
  247.         cmp     al,0Ah
  248.         je      extra_characters_on_line
  249.         cmp     al,0Dh
  250.         je      extra_characters_on_line
  251.         cmp     al,20h
  252.         je      extra_characters_on_line
  253.         cmp     al,9
  254.         je      extra_characters_on_line
  255.         cmp     al,22h
  256.         je      extra_characters_on_line
  257.         cmp     al,27h
  258.         je      extra_characters_on_line
  259.         cmp     al,3Bh
  260.         je      extra_characters_on_line
  261.         mov     ah,al
  262.         mov     ebx,characters
  263.         xlat    byte [ebx]
  264.         or      al,al
  265.         jz      backslashed_symbol_character
  266.         mov     al,ah
  267.       convert_backslashed_symbol:
  268.         stos    byte [edi]
  269.         xlat    byte [ebx]
  270.         or      al,al
  271.         jz      found_separator
  272.         inc     byte [ecx]
  273.         jz      name_too_long
  274.         lods    byte [esi]
  275.         jmp     convert_backslashed_symbol
  276.       backslashed_symbol_character:
  277.         mov     al,ah
  278.         stos    byte [edi]
  279.         inc     byte [ecx]
  280.         jmp     convert_line_data
  281.       concatenate_lines:
  282.         lods    byte [esi]
  283.         cmp     al,20h
  284.         je      concatenate_lines
  285.         cmp     al,9
  286.         je      concatenate_lines
  287.         cmp     al,1Ah
  288.         je      unexpected_end_of_file
  289.         cmp     al,0Ah
  290.         je      concatenate_lf
  291.         cmp     al,0Dh
  292.         je      concatenate_cr
  293.         cmp     al,3Bh
  294.         jne     extra_characters_on_line
  295.       find_concatenated_line:
  296.         lods    byte [esi]
  297.         cmp     al,0Ah
  298.         je      concatenate_lf
  299.         cmp     al,0Dh
  300.         je      concatenate_cr
  301.         or      al,al
  302.         jz      concatenate_ok
  303.         cmp     al,1Ah
  304.         jne     find_concatenated_line
  305.         jmp     unexpected_end_of_file
  306.       concatenate_lf:
  307.         lods    byte [esi]
  308.         cmp     al,0Dh
  309.         je      concatenate_ok
  310.         dec     esi
  311.         jmp     concatenate_ok
  312.       concatenate_cr:
  313.         lods    byte [esi]
  314.         cmp     al,0Ah
  315.         je      concatenate_ok
  316.         dec     esi
  317.       concatenate_ok:
  318.         inc     dword [esp]
  319.         jmp     convert_line_data
  320.       ignore_comment:
  321.         lods    byte [esi]
  322.         cmp     al,0Ah
  323.         je      lf_character
  324.         cmp     al,0Dh
  325.         je      cr_character
  326.         or      al,al
  327.         jz      line_end
  328.         cmp     al,1Ah
  329.         jne     ignore_comment
  330.       line_end:
  331.         xor     al,al
  332.         stos    byte [edi]
  333.         pop     ecx
  334.         ret
  335.  
  336. preprocess_line:
  337.         mov     eax,esp
  338.         sub     eax,100h
  339.         jc      stack_overflow
  340.         cmp     eax,[stack_limit]
  341.         jb      stack_overflow
  342.         push    ecx esi
  343.       preprocess_current_line:
  344.         mov     esi,[current_line]
  345.         add     esi,16
  346.         cmp     word [esi],3Bh
  347.         jne     line_start_ok
  348.         add     esi,2
  349.       line_start_ok:
  350.         test    [macro_status],0F0h
  351.         jnz     macro_preprocessing
  352.         cmp     byte [esi],1Ah
  353.         jne     not_fix_constant
  354.         movzx   edx,byte [esi+1]
  355.         lea     edx,[esi+2+edx]
  356.         cmp     word [edx],031Ah
  357.         jne     not_fix_constant
  358.         mov     ebx,characters
  359.         movzx   eax,byte [edx+2]
  360.         xlat    byte [ebx]
  361.         ror     eax,8
  362.         mov     al,[edx+3]
  363.         xlat    byte [ebx]
  364.         ror     eax,8
  365.         mov     al,[edx+4]
  366.         xlat    byte [ebx]
  367.         ror     eax,16
  368.         cmp     eax,'fix'
  369.         je      define_fix_constant
  370.       not_fix_constant:
  371.         call    process_fix_constants
  372.         jmp     initial_preprocessing_ok
  373.       macro_preprocessing:
  374.         call    process_macro_operators
  375.       initial_preprocessing_ok:
  376.         mov     esi,[current_line]
  377.         add     esi,16
  378.         mov     al,[macro_status]
  379.         test    al,2
  380.         jnz     skip_macro_block
  381.         test    al,1
  382.         jnz     find_macro_block
  383.       preprocess_instruction:
  384.         mov     [current_offset],esi
  385.         lods    byte [esi]
  386.         movzx   ecx,byte [esi]
  387.         inc     esi
  388.         cmp     al,1Ah
  389.         jne     not_preprocessor_symbol
  390.         cmp     cl,3
  391.         jb      not_preprocessor_directive
  392.         push    edi
  393.         mov     edi,preprocessor_directives
  394.         call    get_symbol
  395.         pop     edi
  396.         jc      not_preprocessor_directive
  397.         mov     byte [edx-2],3Bh
  398.         movzx   ebx,ax
  399.         add     ebx,preprocessor
  400.         jmp     near ebx
  401.       not_preprocessor_directive:
  402.         xor     ch,ch
  403.         call    get_preprocessor_symbol
  404.         jc      not_macro
  405.         mov     byte [ebx-2],3Bh
  406.         mov     [struc_name],0
  407.         jmp     use_macro
  408.       not_macro:
  409.         mov     [struc_name],esi
  410.         add     esi,ecx
  411.         lods    byte [esi]
  412.         cmp     al,':'
  413.         je      preprocess_label
  414.         cmp     al,1Ah
  415.         jne     not_preprocessor_symbol
  416.         lods    byte [esi]
  417.         cmp     al,3
  418.         jne     not_symbolic_constant
  419.         mov     ebx,characters
  420.         movzx   eax,byte [esi]
  421.         xlat    byte [ebx]
  422.         ror     eax,8
  423.         mov     al,[esi+1]
  424.         xlat    byte [ebx]
  425.         ror     eax,8
  426.         mov     al,[esi+2]
  427.         xlat    byte [ebx]
  428.         ror     eax,16
  429.         cmp     eax,'equ'
  430.         je      define_equ_constant
  431.         mov     al,3
  432.       not_symbolic_constant:
  433.         mov     ch,1
  434.         mov     cl,al
  435.         call    get_preprocessor_symbol
  436.         jc      not_preprocessor_symbol
  437.         push    edx esi
  438.         mov     esi,[struc_name]
  439.         mov     [struc_label],esi
  440.         sub     [struc_label],2
  441.         mov     cl,[esi-1]
  442.         mov     ch,10b
  443.         call    get_preprocessor_symbol
  444.         jc      struc_name_ok
  445.         mov     ecx,[edx+12]
  446.         add     ecx,3
  447.         lea     ebx,[edi+ecx]
  448.         mov     ecx,edi
  449.         sub     ecx,[struc_label]
  450.         lea     esi,[edi-1]
  451.         lea     edi,[ebx-1]
  452.         std
  453.         rep     movs byte [edi],[esi]
  454.         cld
  455.         mov     edi,[struc_label]
  456.         mov     esi,[edx+8]
  457.         mov     ecx,[edx+12]
  458.         add     [struc_name],ecx
  459.         add     [struc_name],3
  460.         call    move_data
  461.         mov     al,3Ah
  462.         stos    byte [edi]
  463.         mov     ax,3Bh
  464.         stos    word [edi]
  465.         mov     edi,ebx
  466.         pop     esi
  467.         add     esi,[edx+12]
  468.         add     esi,3
  469.         pop     edx
  470.         jmp     use_macro
  471.       struc_name_ok:
  472.         mov     edx,[struc_name]
  473.         movzx   eax,byte [edx-1]
  474.         add     edx,eax
  475.         mov     al,3Ah
  476.         mov     [edx],al
  477.         inc     al
  478.         xchg    al,[edx+1]
  479.         dec     al
  480.         mov     [edx+2],al
  481.         pop     esi edx
  482.         jmp     use_macro
  483.       preprocess_label:
  484.         dec     esi
  485.         sub     esi,ecx
  486.         lea     ebp,[esi-2]
  487.         mov     ch,10b
  488.         call    get_preprocessor_symbol
  489.         jnc     symbolic_constant_in_label
  490.         lea     esi,[esi+ecx+1]
  491.         jmp     preprocess_instruction
  492.       symbolic_constant_in_label:
  493.         mov     ebx,[edx+8]
  494.         mov     ecx,[edx+12]
  495.         add     ecx,ebx
  496.       check_for_broken_label:
  497.         cmp     ebx,ecx
  498.         je      label_broken
  499.         cmp     byte [ebx],1Ah
  500.         jne     label_broken
  501.         movzx   eax,byte [ebx+1]
  502.         lea     ebx,[ebx+2+eax]
  503.         cmp     ebx,ecx
  504.         je      label_constant_ok
  505.         cmp     byte [ebx],':'
  506.         jne     label_broken
  507.         inc     ebx
  508.         jmp     check_for_broken_label
  509.       label_broken:
  510.         push    line_preprocessed
  511.         jmp     replace_symbolic_constant
  512.       label_constant_ok:
  513.         mov     ecx,edi
  514.         sub     ecx,esi
  515.         mov     edi,[edx+12]
  516.         add     edi,ebp
  517.         push    edi
  518.         lea     eax,[edi+ecx]
  519.         push    eax
  520.         cmp     esi,edi
  521.         je      replace_label
  522.         jb      move_rest_of_line_up
  523.         rep     movs byte [edi],[esi]
  524.         jmp     replace_label
  525.       move_rest_of_line_up:
  526.         lea     esi,[esi+ecx-1]
  527.         lea     edi,[edi+ecx-1]
  528.         std
  529.         rep     movs byte [edi],[esi]
  530.         cld
  531.       replace_label:
  532.         mov     ecx,[edx+12]
  533.         mov     edi,[esp+4]
  534.         sub     edi,ecx
  535.         mov     esi,[edx+8]
  536.         rep     movs byte [edi],[esi]
  537.         pop     edi esi
  538.         inc     esi
  539.         jmp     preprocess_instruction
  540.       not_preprocessor_symbol:
  541.         mov     esi,[current_offset]
  542.         call    process_equ_constants
  543.       line_preprocessed:
  544.         pop     esi ecx
  545.         ret
  546.  
  547. get_preprocessor_symbol:
  548.         push    ebp edi esi
  549.         mov     ebp,ecx
  550.         shl     ebp,22
  551.         movzx   ecx,cl
  552.         mov     ebx,hash_tree
  553.         mov     edi,10
  554.       follow_hashes_roots:
  555.         mov     edx,[ebx]
  556.         or      edx,edx
  557.         jz      preprocessor_symbol_not_found
  558.         xor     eax,eax
  559.         shl     ebp,1
  560.         adc     eax,0
  561.         lea     ebx,[edx+eax*4]
  562.         dec     edi
  563.         jnz     follow_hashes_roots
  564.         mov     edi,ebx
  565.         call    calculate_hash
  566.         mov     ebp,eax
  567.         and     ebp,3FFh
  568.         shl     ebp,10
  569.         xor     ebp,eax
  570.         mov     ebx,edi
  571.         mov     edi,22
  572.       follow_hashes_tree:
  573.         mov     edx,[ebx]
  574.         or      edx,edx
  575.         jz      preprocessor_symbol_not_found
  576.         xor     eax,eax
  577.         shl     ebp,1
  578.         adc     eax,0
  579.         lea     ebx,[edx+eax*4]
  580.         dec     edi
  581.         jnz     follow_hashes_tree
  582.         mov     al,cl
  583.         mov     edx,[ebx]
  584.         or      edx,edx
  585.         jz      preprocessor_symbol_not_found
  586.       compare_with_preprocessor_symbol:
  587.         mov     edi,[edx+4]
  588.         cmp     edi,1
  589.         jbe     next_equal_hash
  590.         repe    cmps byte [esi],[edi]
  591.         je      preprocessor_symbol_found
  592.         mov     cl,al
  593.         mov     esi,[esp]
  594.       next_equal_hash:
  595.         mov     edx,[edx]
  596.         or      edx,edx
  597.         jnz     compare_with_preprocessor_symbol
  598.       preprocessor_symbol_not_found:
  599.         pop     esi edi ebp
  600.         stc
  601.         ret
  602.       preprocessor_symbol_found:
  603.         pop     ebx edi ebp
  604.         clc
  605.         ret
  606.       calculate_hash:
  607.         xor     ebx,ebx
  608.         mov     eax,2166136261
  609.         mov     ebp,16777619
  610.       fnv1a_hash:
  611.         xor     al,[esi+ebx]
  612.         mul     ebp
  613.         inc     bl
  614.         cmp     bl,cl
  615.         jb      fnv1a_hash
  616.         ret
  617. add_preprocessor_symbol:
  618.         push    edi esi
  619.         call    calculate_hash
  620.         mov     ebp,eax
  621.         and     ebp,3FFh
  622.         shr     eax,10
  623.         xor     ebp,eax
  624.         shl     ecx,22
  625.         or      ebp,ecx
  626.         mov     ebx,hash_tree
  627.         mov     ecx,32
  628.       find_leave_for_symbol:
  629.         mov     edx,[ebx]
  630.         or      edx,edx
  631.         jz      extend_hashes_tree
  632.         xor     eax,eax
  633.         rol     ebp,1
  634.         adc     eax,0
  635.         lea     ebx,[edx+eax*4]
  636.         dec     ecx
  637.         jnz     find_leave_for_symbol
  638.         mov     edx,[ebx]
  639.         or      edx,edx
  640.         jz      add_symbol_entry
  641.         shr     ebp,30
  642.         cmp     ebp,11b
  643.         je      reuse_symbol_entry
  644.         cmp     dword [edx+4],0
  645.         jne     add_symbol_entry
  646.       find_entry_to_reuse:
  647.         mov     edi,[edx]
  648.         or      edi,edi
  649.         jz      reuse_symbol_entry
  650.         cmp     dword [edi+4],0
  651.         jne     reuse_symbol_entry
  652.         mov     edx,edi
  653.         jmp     find_entry_to_reuse
  654.       add_symbol_entry:
  655.         mov     eax,edx
  656.         mov     edx,[labels_list]
  657.         sub     edx,16
  658.         cmp     edx,[free_additional_memory]
  659.         jb      out_of_memory
  660.         mov     [labels_list],edx
  661.         mov     [edx],eax
  662.         mov     [ebx],edx
  663.       reuse_symbol_entry:
  664.         pop     esi edi
  665.         mov     [edx+4],esi
  666.         ret
  667.       extend_hashes_tree:
  668.         mov     edx,[labels_list]
  669.         sub     edx,8
  670.         cmp     edx,[free_additional_memory]
  671.         jb      out_of_memory
  672.         mov     [labels_list],edx
  673.         xor     eax,eax
  674.         mov     [edx],eax
  675.         mov     [edx+4],eax
  676.         shl     ebp,1
  677.         adc     eax,0
  678.         mov     [ebx],edx
  679.         lea     ebx,[edx+eax*4]
  680.         dec     ecx
  681.         jnz     extend_hashes_tree
  682.         mov     edx,[labels_list]
  683.         sub     edx,16
  684.         cmp     edx,[free_additional_memory]
  685.         jb      out_of_memory
  686.         mov     [labels_list],edx
  687.         mov     dword [edx],0
  688.         mov     [ebx],edx
  689.         pop     esi edi
  690.         mov     [edx+4],esi
  691.         ret
  692.  
  693. define_fix_constant:
  694.         add     edx,5
  695.         add     esi,2
  696.         push    edx esi
  697.         mov     esi,edx
  698.         call    process_fix_constants
  699.         xchg    esi,[esp]
  700.         mov     ch,11b
  701.         jmp     define_symbolic_constant
  702. define_equ_constant:
  703.         add     esi,3
  704.         push    esi
  705.         call    process_equ_constants
  706.         push    esi
  707.         mov     esi,[struc_name]
  708.         mov     ch,10b
  709.       define_symbolic_constant:
  710.         mov     byte [esi-2],3Bh
  711.         mov     cl,[esi-1]
  712.         call    add_preprocessor_symbol
  713.         pop     esi ebx
  714.         mov     ecx,edi
  715.         dec     ecx
  716.         sub     ecx,ebx
  717.         mov     [edx+8],ebx
  718.         mov     [edx+12],ecx
  719.         jmp     line_preprocessed
  720. define_struc:
  721.         mov     ch,1
  722.         jmp     make_macro
  723. define_macro:
  724.         xor     ch,ch
  725.       make_macro:
  726.         lods    byte [esi]
  727.         cmp     al,1Ah
  728.         jne     invalid_name
  729.         lods    byte [esi]
  730.         mov     cl,al
  731.         call    add_preprocessor_symbol
  732.         mov     eax,[current_line]
  733.         mov     [edx+12],eax
  734.         movzx   eax,byte [esi-1]
  735.         add     esi,eax
  736.         mov     [edx+8],esi
  737.         mov     al,[macro_status]
  738.         and     al,0F0h
  739.         or      al,1
  740.         mov     [macro_status],al
  741.         mov     eax,[current_line]
  742.         mov     [error_line],eax
  743.         xor     bl,bl
  744.         lods    byte [esi]
  745.         or      al,al
  746.         jz      line_preprocessed
  747.         cmp     al,'{'
  748.         je      found_macro_block
  749.         dec     esi
  750.       skip_macro_arguments:
  751.         lods    byte [esi]
  752.         cmp     al,1Ah
  753.         je      skip_macro_argument
  754.         cmp     al,'['
  755.         jne     invalid_macro_arguments
  756.         xor     bl,-1
  757.         jz      invalid_macro_arguments
  758.         lods    byte [esi]
  759.         cmp     al,1Ah
  760.         jne     invalid_macro_arguments
  761.       skip_macro_argument:
  762.         movzx   eax,byte [esi]
  763.         inc     esi
  764.         add     esi,eax
  765.         lods    byte [esi]
  766.         cmp     al,'*'
  767.         jne     macro_argument_end
  768.         lods    byte [esi]
  769.       macro_argument_end:
  770.         cmp     al,','
  771.         je      skip_macro_arguments
  772.         cmp     al,']'
  773.         jne     end_macro_arguments
  774.         lods    byte [esi]
  775.         not     bl
  776.       end_macro_arguments:
  777.         or      bl,bl
  778.         jnz     invalid_macro_arguments
  779.         or      al,al
  780.         jz      line_preprocessed
  781.         cmp     al,'{'
  782.         je      found_macro_block
  783.         jmp     invalid_macro_arguments
  784.       find_macro_block:
  785.         add     esi,2
  786.         lods    byte [esi]
  787.         or      al,al
  788.         jz      line_preprocessed
  789.         cmp     al,'{'
  790.         jne     unexpected_characters
  791.       found_macro_block:
  792.         or      [macro_status],2
  793.       skip_macro_block:
  794.         lods    byte [esi]
  795.         cmp     al,1Ah
  796.         je      skip_macro_symbol
  797.         cmp     al,3Bh
  798.         je      skip_macro_symbol
  799.         cmp     al,22h
  800.         je      skip_macro_string
  801.         or      al,al
  802.         jz      line_preprocessed
  803.         cmp     al,'}'
  804.         jne     skip_macro_block
  805.         mov     al,[macro_status]
  806.         and     [macro_status],0F0h
  807.         test    al,8
  808.         jnz     use_instant_macro
  809.         cmp     byte [esi],0
  810.         je      line_preprocessed
  811.         mov     ecx,edi
  812.         sub     ecx,esi
  813.         mov     edx,esi
  814.         lea     esi,[esi+ecx-1]
  815.         lea     edi,[edi+1+16]
  816.         mov     ebx,edi
  817.         dec     edi
  818.         std
  819.         rep     movs byte [edi],[esi]
  820.         cld
  821.         mov     edi,edx
  822.         xor     al,al
  823.         stos    byte [edi]
  824.         mov     esi,[current_line]
  825.         mov     [current_line],edi
  826.         mov     ecx,4
  827.         rep     movs dword [edi],[esi]
  828.         mov     edi,ebx
  829.         jmp     preprocess_current_line
  830.       skip_macro_symbol:
  831.         movzx   eax,byte [esi]
  832.         inc     esi
  833.         add     esi,eax
  834.         jmp     skip_macro_block
  835.       skip_macro_string:
  836.         lods    dword [esi]
  837.         add     esi,eax
  838.         jmp     skip_macro_block
  839. rept_directive:
  840.         mov     [base_code],0
  841.         jmp     define_instant_macro
  842. irp_directive:
  843.         mov     [base_code],1
  844.         jmp     define_instant_macro
  845. irps_directive:
  846.         mov     [base_code],2
  847.         jmp     define_instant_macro
  848. match_directive:
  849.         mov     [base_code],10h
  850. define_instant_macro:
  851.         mov     al,[macro_status]
  852.         and     al,0F0h
  853.         or      al,8+1
  854.         mov     [macro_status],al
  855.         mov     eax,[current_line]
  856.         mov     [error_line],eax
  857.         mov     [instant_macro_start],esi
  858.         cmp     [base_code],10h
  859.         je      prepare_match
  860.       skip_parameters:
  861.         lods    byte [esi]
  862.         or      al,al
  863.         jz      instant_macro_parameters_end
  864.         cmp     al,'{'
  865.         je      instant_macro_parameters_end
  866.         cmp     al,22h
  867.         je      skip_quoted_parameter
  868.         cmp     al,1Ah
  869.         jne     skip_parameters
  870.         lods    byte [esi]
  871.         movzx   eax,al
  872.         add     esi,eax
  873.         jmp     skip_parameters
  874.       skip_quoted_parameter:
  875.         lods    dword [esi]
  876.         add     esi,eax
  877.         jmp     skip_parameters
  878.       instant_macro_parameters_end:
  879.         dec     esi
  880.         mov     [parameters_end],esi
  881.         lods    byte [esi]
  882.         cmp     al,'{'
  883.         je      found_macro_block
  884.         or      al,al
  885.         jnz     invalid_macro_arguments
  886.         jmp     line_preprocessed
  887. prepare_match:
  888.         call    skip_pattern
  889.         mov     [value_type],80h+10b
  890.         call    process_symbolic_constants
  891.         jmp     instant_macro_parameters_end
  892.       skip_pattern:
  893.         lods    byte [esi]
  894.         or      al,al
  895.         jz      invalid_macro_arguments
  896.         cmp     al,','
  897.         je      pattern_skipped
  898.         cmp     al,22h
  899.         je      skip_quoted_string_in_pattern
  900.         cmp     al,1Ah
  901.         je      skip_symbol_in_pattern
  902.         cmp     al,'='
  903.         jne     skip_pattern
  904.         mov     al,[esi]
  905.         cmp     al,1Ah
  906.         je      skip_pattern
  907.         cmp     al,22h
  908.         je      skip_pattern
  909.         inc     esi
  910.         jmp     skip_pattern
  911.       skip_symbol_in_pattern:
  912.         lods    byte [esi]
  913.         movzx   eax,al
  914.         add     esi,eax
  915.         jmp     skip_pattern
  916.       skip_quoted_string_in_pattern:
  917.         lods    dword [esi]
  918.         add     esi,eax
  919.         jmp     skip_pattern
  920.       pattern_skipped:
  921.         ret
  922.  
  923. purge_macro:
  924.         xor     ch,ch
  925.         jmp     restore_preprocessor_symbol
  926. purge_struc:
  927.         mov     ch,1
  928.         jmp     restore_preprocessor_symbol
  929. restore_equ_constant:
  930.         mov     ch,10b
  931.       restore_preprocessor_symbol:
  932.         push    ecx
  933.         lods    byte [esi]
  934.         cmp     al,1Ah
  935.         jne     invalid_name
  936.         lods    byte [esi]
  937.         mov     cl,al
  938.         call    get_preprocessor_symbol
  939.         jc      no_symbol_to_restore
  940.         mov     dword [edx+4],0
  941.         jmp     symbol_restored
  942.       no_symbol_to_restore:
  943.         add     esi,ecx
  944.       symbol_restored:
  945.         pop     ecx
  946.         lods    byte [esi]
  947.         cmp     al,','
  948.         je      restore_preprocessor_symbol
  949.         or      al,al
  950.         jnz     extra_characters_on_line
  951.         jmp     line_preprocessed
  952.  
  953. process_fix_constants:
  954.         mov     [value_type],11b
  955.         jmp     process_symbolic_constants
  956. process_equ_constants:
  957.         mov     [value_type],10b
  958.       process_symbolic_constants:
  959.         mov     ebp,esi
  960.         lods    byte [esi]
  961.         cmp     al,1Ah
  962.         je      check_symbol
  963.         cmp     al,22h
  964.         je      ignore_string
  965.         cmp     al,'{'
  966.         je      check_brace
  967.         or      al,al
  968.         jnz     process_symbolic_constants
  969.         ret
  970.       ignore_string:
  971.         lods    dword [esi]
  972.         add     esi,eax
  973.         jmp     process_symbolic_constants
  974.       check_brace:
  975.         test    [value_type],80h
  976.         jz      process_symbolic_constants
  977.         ret
  978.       no_replacing:
  979.         movzx   ecx,byte [esi-1]
  980.         add     esi,ecx
  981.         jmp     process_symbolic_constants
  982.       check_symbol:
  983.         mov     cl,[esi]
  984.         inc     esi
  985.         mov     ch,[value_type]
  986.         call    get_preprocessor_symbol
  987.         jc      no_replacing
  988.         mov     [current_section],edi
  989.       replace_symbolic_constant:
  990.         mov     ecx,[edx+12]
  991.         mov     edx,[edx+8]
  992.         xchg    esi,edx
  993.         call    move_data
  994.         mov     esi,edx
  995.       process_after_replaced:
  996.         lods    byte [esi]
  997.         cmp     al,1Ah
  998.         je      symbol_after_replaced
  999.         stos    byte [edi]
  1000.         cmp     al,22h
  1001.         je      string_after_replaced
  1002.         cmp     al,'{'
  1003.         je      brace_after_replaced
  1004.         or      al,al
  1005.         jnz     process_after_replaced
  1006.         mov     ecx,edi
  1007.         sub     ecx,esi
  1008.         mov     edi,ebp
  1009.         call    move_data
  1010.         mov     esi,edi
  1011.         ret
  1012.       move_data:
  1013.         shr     ecx,1
  1014.         jnc     movsb_ok
  1015.         movs    byte [edi],[esi]
  1016.       movsb_ok:
  1017.         shr     ecx,1
  1018.         jnc     movsw_ok
  1019.         movs    word [edi],[esi]
  1020.       movsw_ok:
  1021.         rep     movs dword [edi],[esi]
  1022.         ret
  1023.       string_after_replaced:
  1024.         lods    dword [esi]
  1025.         stos    dword [edi]
  1026.         mov     ecx,eax
  1027.         call    move_data
  1028.         jmp     process_after_replaced
  1029.       brace_after_replaced:
  1030.         test    [value_type],80h
  1031.         jz      process_after_replaced
  1032.         mov     edx,edi
  1033.         mov     ecx,[current_section]
  1034.         sub     edx,ecx
  1035.         sub     ecx,esi
  1036.         rep     movs byte [edi],[esi]
  1037.         mov     ecx,edi
  1038.         sub     ecx,esi
  1039.         mov     edi,ebp
  1040.         call    move_data
  1041.         lea     esi,[ebp+edx]
  1042.         ret
  1043.       symbol_after_replaced:
  1044.         mov     cl,[esi]
  1045.         inc     esi
  1046.         mov     ch,[value_type]
  1047.         call    get_preprocessor_symbol
  1048.         jnc     replace_symbolic_constant
  1049.         movzx   ecx,byte [esi-1]
  1050.         mov     al,1Ah
  1051.         mov     ah,cl
  1052.         stos    word [edi]
  1053.         call    move_data
  1054.         jmp     process_after_replaced
  1055. process_macro_operators:
  1056.         xor     dl,dl
  1057.         mov     ebp,edi
  1058.       before_macro_operators:
  1059.         mov     edi,esi
  1060.         lods    byte [esi]
  1061.         cmp     al,'`'
  1062.         je      symbol_conversion
  1063.         cmp     al,'#'
  1064.         je      concatenation
  1065.         cmp     al,1Ah
  1066.         je      symbol_before_macro_operators
  1067.         cmp     al,3Bh
  1068.         je      no_more_macro_operators
  1069.         cmp     al,22h
  1070.         je      string_before_macro_operators
  1071.         xor     dl,dl
  1072.         or      al,al
  1073.         jnz     before_macro_operators
  1074.         mov     edi,esi
  1075.         ret
  1076.       no_more_macro_operators:
  1077.         mov     edi,ebp
  1078.         ret
  1079.       symbol_before_macro_operators:
  1080.         mov     dl,1Ah
  1081.         mov     ebx,esi
  1082.         lods    byte [esi]
  1083.         movzx   ecx,al
  1084.         jecxz   symbol_before_macro_operators_ok
  1085.         mov     edi,esi
  1086.         cmp     byte [esi],'\'
  1087.         je      escaped_symbol
  1088.       symbol_before_macro_operators_ok:
  1089.         add     esi,ecx
  1090.         jmp     before_macro_operators
  1091.       string_before_macro_operators:
  1092.         mov     dl,22h
  1093.         mov     ebx,esi
  1094.         lods    dword [esi]
  1095.         add     esi,eax
  1096.         jmp     before_macro_operators
  1097.       escaped_symbol:
  1098.         dec     byte [edi-1]
  1099.         dec     ecx
  1100.         inc     esi
  1101.         cmp     ecx,1
  1102.         rep     movs byte [edi],[esi]
  1103.         jne     after_macro_operators
  1104.         mov     al,[esi-1]
  1105.         mov     ecx,ebx
  1106.         mov     ebx,characters
  1107.         xlat    byte [ebx]
  1108.         mov     ebx,ecx
  1109.         or      al,al
  1110.         jnz     after_macro_operators
  1111.         sub     edi,3
  1112.         mov     al,[esi-1]
  1113.         stos    byte [edi]
  1114.         xor     dl,dl
  1115.         jmp     after_macro_operators
  1116.       symbol_conversion:
  1117.         cmp     byte [esi],1Ah
  1118.         jne     unexpected_characters
  1119.         lea     eax,[edi+3]
  1120.         sub     eax,esi
  1121.         ja      shift_line_data
  1122.         mov     al,22h
  1123.         mov     dl,al
  1124.         stos    byte [edi]
  1125.         lods    word [esi]
  1126.         movzx   eax,ah
  1127.         mov     ecx,eax
  1128.         mov     ebx,edi
  1129.         stos    dword [edi]
  1130.         rep     movs byte [edi],[esi]
  1131.         cmp     edi,esi
  1132.         je      before_macro_operators
  1133.         jmp     after_macro_operators
  1134.       shift_line_data:
  1135.         lea     edx,[esi+2]
  1136.         lea     esi,[ebp-1]
  1137.         add     ebp,eax
  1138.         lea     edi,[ebp-1]
  1139.         lea     ecx,[esi+1]
  1140.         sub     ecx,edx
  1141.         std
  1142.         rep     movs byte [edi],[esi]
  1143.         cld
  1144.         movzx   eax,byte [edx-1]
  1145.         sub     edi,3
  1146.         mov     dl,22h
  1147.         mov     [edi-1],dl
  1148.         mov     ebx,edi
  1149.         mov     [edi],eax
  1150.         lea     esi,[edi+4+eax]
  1151.         jmp     before_macro_operators
  1152.       concatenation:
  1153.         cmp     byte [esi],'#'
  1154.         je      reduce_concatenation_symbol
  1155.         cmp     dl,1Ah
  1156.         je      symbol_concatenation
  1157.         cmp     dl,22h
  1158.         je      string_concatenation
  1159.       no_concatenation:
  1160.         cmp     esi,edi
  1161.         je      before_macro_operators
  1162.         jmp     after_macro_operators
  1163.       reduce_concatenation_symbol:
  1164.         movs    byte [edi],[esi]
  1165.         cmp     byte [esi],'#'
  1166.         je      reduce_concatenation_symbol
  1167.         jmp     no_concatenation
  1168.       symbol_concatenation:
  1169.         cmp     byte [esi],1Ah
  1170.         jne     no_concatenation
  1171.         inc     esi
  1172.         lods    byte [esi]
  1173.         movzx   ecx,al
  1174.         jecxz   do_symbol_concatenation
  1175.         cmp     byte [esi],'\'
  1176.         jne     do_symbol_concatenation
  1177.         sub     esi,2
  1178.         jmp     no_concatenation
  1179.       do_symbol_concatenation:
  1180.         add     [ebx],al
  1181.         jc      name_too_long
  1182.         rep     movs byte [edi],[esi]
  1183.         jmp     after_macro_operators
  1184.       string_concatenation:
  1185.         cmp     byte [esi],22h
  1186.         je      do_string_concatenation
  1187.         cmp     byte [esi],'`'
  1188.         jne     no_concatenation
  1189.         inc     esi
  1190.         cmp     byte [esi],1Ah
  1191.         jne     unexpected_characters
  1192.         inc     esi
  1193.         lods    byte [esi]
  1194.         movzx   ecx,al
  1195.         add     [ebx],ecx
  1196.         rep     movs byte [edi],[esi]
  1197.         jmp     after_macro_operators
  1198.       do_string_concatenation:
  1199.         inc     esi
  1200.         lods    dword [esi]
  1201.         mov     ecx,eax
  1202.         add     [ebx],eax
  1203.         rep     movs byte [edi],[esi]
  1204.       after_macro_operators:
  1205.         lods    byte [esi]
  1206.         cmp     al,'`'
  1207.         je      symbol_conversion
  1208.         cmp     al,'#'
  1209.         je      concatenation
  1210.         stos    byte [edi]
  1211.         cmp     al,1Ah
  1212.         je      symbol_after_macro_operators
  1213.         cmp     al,3Bh
  1214.         je      no_more_macro_operators
  1215.         cmp     al,22h
  1216.         je      string_after_macro_operators
  1217.         xor     dl,dl
  1218.         or      al,al
  1219.         jnz     after_macro_operators
  1220.         ret
  1221.       symbol_after_macro_operators:
  1222.         mov     dl,1Ah
  1223.         mov     ebx,edi
  1224.         lods    byte [esi]
  1225.         stos    byte [edi]
  1226.         movzx   ecx,al
  1227.         jecxz   symbol_after_macro_operatorss_ok
  1228.         cmp     byte [esi],'\'
  1229.         je      escaped_symbol
  1230.       symbol_after_macro_operatorss_ok:
  1231.         rep     movs byte [edi],[esi]
  1232.         jmp     after_macro_operators
  1233.       string_after_macro_operators:
  1234.         mov     dl,22h
  1235.         mov     ebx,edi
  1236.         lods    dword [esi]
  1237.         stos    dword [edi]
  1238.         mov     ecx,eax
  1239.         rep     movs byte [edi],[esi]
  1240.         jmp     after_macro_operators
  1241.  
  1242. use_macro:
  1243.         push    [free_additional_memory]
  1244.         push    [macro_symbols]
  1245.         mov     [macro_symbols],0
  1246.         push    [counter_limit]
  1247.         push    dword [edx+4]
  1248.         mov     dword [edx+4],1
  1249.         push    edx
  1250.         mov     ebx,esi
  1251.         mov     esi,[edx+8]
  1252.         mov     eax,[edx+12]
  1253.         mov     [macro_line],eax
  1254.         mov     [counter_limit],0
  1255.       process_macro_arguments:
  1256.         mov     al,[esi]
  1257.         or      al,al
  1258.         jz      arguments_end
  1259.         cmp     al,'{'
  1260.         je      arguments_end
  1261.         inc     esi
  1262.         cmp     al,'['
  1263.         jne     get_macro_arguments
  1264.         mov     ebp,esi
  1265.         inc     esi
  1266.         inc     [counter_limit]
  1267.       get_macro_arguments:
  1268.         call    get_macro_argument
  1269.         lods    byte [esi]
  1270.         cmp     al,','
  1271.         je      next_argument
  1272.         cmp     al,']'
  1273.         je      next_arguments_group
  1274.         dec     esi
  1275.         jmp     arguments_end
  1276.       next_argument:
  1277.         cmp     byte [ebx],','
  1278.         jne     process_macro_arguments
  1279.         inc     ebx
  1280.         jmp     process_macro_arguments
  1281.       next_arguments_group:
  1282.         cmp     byte [ebx],','
  1283.         jne     arguments_end
  1284.         inc     ebx
  1285.         inc     [counter_limit]
  1286.         mov     esi,ebp
  1287.         jmp     process_macro_arguments
  1288.       get_macro_argument:
  1289.         lods    byte [esi]
  1290.         movzx   ecx,al
  1291.         mov     eax,[counter_limit]
  1292.         call    add_macro_symbol
  1293.         add     esi,ecx
  1294.         xchg    esi,ebx
  1295.         mov     [edx+12],esi
  1296.         cmp     byte [esi],'<'
  1297.         jne     simple_argument
  1298.         inc     esi
  1299.         mov     [edx+12],esi
  1300.         mov     ecx,1
  1301.       enclosed_argument:
  1302.         lods    byte [esi]
  1303.         or      al,al
  1304.         jz      invalid_macro_arguments
  1305.         cmp     al,1Ah
  1306.         je      enclosed_symbol
  1307.         cmp     al,22h
  1308.         je      enclosed_string
  1309.         cmp     al,'>'
  1310.         je      enclosed_argument_end
  1311.         cmp     al,'<'
  1312.         jne     enclosed_argument
  1313.         inc     ecx
  1314.         jmp     enclosed_argument
  1315.       enclosed_symbol:
  1316.         movzx   eax,byte [esi]
  1317.         inc     esi
  1318.         add     esi,eax
  1319.         jmp     enclosed_argument
  1320.       enclosed_string:
  1321.         lods    dword [esi]
  1322.         add     esi,eax
  1323.         jmp     enclosed_argument
  1324.       enclosed_argument_end:
  1325.         loop    enclosed_argument
  1326.         mov     al,[esi]
  1327.         or      al,al
  1328.         jz      enclosed_argument_ok
  1329.         cmp     al,','
  1330.         jne     invalid_macro_arguments
  1331.       enclosed_argument_ok:
  1332.         mov     eax,esi
  1333.         sub     eax,[edx+12]
  1334.         dec     eax
  1335.         or      eax,80000000h
  1336.         mov     [edx+8],eax
  1337.         jmp     argument_value_ok
  1338.       simple_argument:
  1339.         lods    byte [esi]
  1340.         or      al,al
  1341.         jz      argument_value_end
  1342.         cmp     al,','
  1343.         je      argument_value_end
  1344.         cmp     al,22h
  1345.         je      argument_string
  1346.         cmp     al,1Ah
  1347.         jne     simple_argument
  1348.         movzx   eax,byte [esi]
  1349.         inc     esi
  1350.         add     esi,eax
  1351.         jmp     simple_argument
  1352.       argument_string:
  1353.         lods    dword [esi]
  1354.         add     esi,eax
  1355.         jmp     simple_argument
  1356.       argument_value_end:
  1357.         dec     esi
  1358.         mov     eax,esi
  1359.         sub     eax,[edx+12]
  1360.         mov     [edx+8],eax
  1361.       argument_value_ok:
  1362.         xchg    esi,ebx
  1363.         cmp     byte [esi],'*'
  1364.         jne     macro_argument_ok
  1365.         cmp     dword [edx+8],0
  1366.         je      invalid_macro_arguments
  1367.         inc     esi
  1368.       macro_argument_ok:
  1369.         ret
  1370.       arguments_end:
  1371.         cmp     byte [ebx],0
  1372.         jne     invalid_macro_arguments
  1373.         mov     eax,[esp+4]
  1374.         dec     eax
  1375.         call    process_macro
  1376.         pop     edx
  1377.         pop     dword [edx+4]
  1378.         pop     [counter_limit]
  1379.         pop     [macro_symbols]
  1380.         pop     [free_additional_memory]
  1381.         jmp     line_preprocessed
  1382. use_instant_macro:
  1383.         push    edi [current_line] esi
  1384.         mov     eax,[error_line]
  1385.         mov     [current_line],eax
  1386.         mov     [macro_line],eax
  1387.         mov     esi,[instant_macro_start]
  1388.         cmp     [base_code],10h
  1389.         jae     do_match
  1390.         cmp     [base_code],0
  1391.         jne     do_irp
  1392.         call    get_number
  1393.         jc      invalid_value
  1394.         or      ebp,ebp
  1395.         jnz     invalid_value
  1396.         cmp     dword [edi+4],0
  1397.         jne     value_out_of_range
  1398.         mov     eax,[edi]
  1399.         or      eax,eax
  1400.         jz      instant_macro_done
  1401.         cmp     eax,80000000h
  1402.         jae     value_out_of_range
  1403.         push    [free_additional_memory]
  1404.         push    [macro_symbols]
  1405.         mov     [macro_symbols],0
  1406.         push    [counter_limit]
  1407.         mov     [struc_name],0
  1408.         mov     [counter_limit],eax
  1409.         lods    byte [esi]
  1410.         or      al,al
  1411.         jz      rept_counters_ok
  1412.         cmp     al,'{'
  1413.         je      rept_counters_ok
  1414.         cmp     al,1Ah
  1415.         jne     invalid_macro_arguments
  1416.       add_rept_counter:
  1417.         lods    byte [esi]
  1418.         movzx   ecx,al
  1419.         xor     eax,eax
  1420.         call    add_macro_symbol
  1421.         add     esi,ecx
  1422.         xor     eax,eax
  1423.         mov     dword [edx+12],eax
  1424.         inc     eax
  1425.         mov     dword [edx+8],eax
  1426.         lods    byte [esi]
  1427.         cmp     al,':'
  1428.         jne     rept_counter_added
  1429.         push    edx
  1430.         call    get_number
  1431.         jc      invalid_value
  1432.         or      ebp,ebp
  1433.         jnz     invalid_value
  1434.         cmp     dword [edi+4],0
  1435.         jne     value_out_of_range
  1436.         mov     eax,[edi]
  1437.         mov     edx,eax
  1438.         add     edx,[counter_limit]
  1439.         jc      value_out_of_range
  1440.         pop     edx
  1441.         mov     dword [edx+8],eax
  1442.         lods    byte [esi]
  1443.       rept_counter_added:
  1444.         cmp     al,','
  1445.         jne     rept_counters_ok
  1446.         lods    byte [esi]
  1447.         cmp     al,1Ah
  1448.         jne     invalid_macro_arguments
  1449.         jmp     add_rept_counter
  1450.       rept_counters_ok:
  1451.         dec     esi
  1452.       instant_macro_parameters_ok:
  1453.         xor     eax,eax
  1454.         call    process_macro
  1455.         pop     [counter_limit]
  1456.         pop     [macro_symbols]
  1457.         pop     [free_additional_memory]
  1458.       instant_macro_done:
  1459.         pop     ebx esi edx
  1460.         cmp     byte [ebx],0
  1461.         je      line_preprocessed
  1462.         mov     [current_line],edi
  1463.         mov     ecx,4
  1464.         rep     movs dword [edi],[esi]
  1465.         test    [macro_status],0Fh
  1466.         jz      instant_macro_attached_line
  1467.         mov     ax,3Bh
  1468.         stos    word [edi]
  1469.       instant_macro_attached_line:
  1470.         mov     esi,ebx
  1471.         sub     edx,ebx
  1472.         mov     ecx,edx
  1473.         call    move_data
  1474.         jmp     preprocess_current_line
  1475. do_irp:
  1476.         cmp     byte [esi],1Ah
  1477.         jne     invalid_macro_arguments
  1478.         movzx   eax,byte [esi+1]
  1479.         lea     esi,[esi+2+eax]
  1480.         lods    byte [esi]
  1481.         cmp     [base_code],1
  1482.         ja      irps_name_ok
  1483.         cmp     al,'*'
  1484.         jne     irp_name_ok
  1485.         lods    byte [esi]
  1486.       irp_name_ok:
  1487.         cmp     al,','
  1488.         jne     invalid_macro_arguments
  1489.         jmp     irp_parameters_start
  1490.       irps_name_ok:
  1491.         cmp     al,','
  1492.         jne     invalid_macro_arguments
  1493.         mov     al,[esi]
  1494.         or      al,al
  1495.         jz      instant_macro_done
  1496.         cmp     al,'{'
  1497.         je      instant_macro_done
  1498.       irp_parameters_start:
  1499.         xor     eax,eax
  1500.         push    [free_additional_memory]
  1501.         push    [macro_symbols]
  1502.         mov     [macro_symbols],eax
  1503.         push    [counter_limit]
  1504.         mov     [counter_limit],eax
  1505.         mov     [struc_name],eax
  1506.         mov     ebx,esi
  1507.         cmp     [base_code],1
  1508.         ja      get_irps_parameter
  1509.         mov     edx,[parameters_end]
  1510.         mov     al,[edx]
  1511.         push    eax
  1512.         mov     byte [edx],0
  1513.       get_irp_parameter:
  1514.         inc     [counter_limit]
  1515.         mov     esi,[instant_macro_start]
  1516.         inc     esi
  1517.         call    get_macro_argument
  1518.         cmp     byte [ebx],','
  1519.         jne     irp_parameters_end
  1520.         inc     ebx
  1521.         jmp     get_irp_parameter
  1522.       irp_parameters_end:
  1523.         mov     esi,ebx
  1524.         pop     eax
  1525.         mov     [esi],al
  1526.         jmp     instant_macro_parameters_ok
  1527.       get_irps_parameter:
  1528.         mov     esi,[instant_macro_start]
  1529.         inc     esi
  1530.         lods    byte [esi]
  1531.         movzx   ecx,al
  1532.         inc     [counter_limit]
  1533.         mov     eax,[counter_limit]
  1534.         call    add_macro_symbol
  1535.         mov     [edx+12],ebx
  1536.         cmp     byte [ebx],1Ah
  1537.         je      irps_symbol
  1538.         cmp     byte [ebx],22h
  1539.         je      irps_quoted_string
  1540.         mov     eax,1
  1541.         jmp     irps_parameter_ok
  1542.       irps_quoted_string:
  1543.         mov     eax,[ebx+1]
  1544.         add     eax,1+4
  1545.       irps_symbol:
  1546.         movzx   eax,byte [ebx+1]
  1547.         add     eax,1+1
  1548.       irps_parameter_ok:
  1549.         mov     [edx+8],eax
  1550.         add     ebx,eax
  1551.         cmp     byte [ebx],0
  1552.         je      irps_parameters_end
  1553.         cmp     byte [ebx],'{'
  1554.         jne     get_irps_parameter
  1555.       irps_parameters_end:
  1556.         mov     esi,ebx
  1557.         jmp     instant_macro_parameters_ok
  1558. do_match:
  1559.         mov     ebx,esi
  1560.         call    skip_pattern
  1561.         call    exact_match
  1562.         mov     edx,edi
  1563.         mov     al,[ebx]
  1564.         cmp     al,1Ah
  1565.         je      free_match
  1566.         cmp     al,','
  1567.         jne     instant_macro_done
  1568.         cmp     esi,[parameters_end]
  1569.         je      matched_pattern
  1570.         jmp     instant_macro_done
  1571.       free_match:
  1572.         add     edx,12
  1573.         cmp     edx,[memory_end]
  1574.         ja      out_of_memory
  1575.         mov     [edx-12],ebx
  1576.         mov     [edx-8],esi
  1577.         call    skip_match_element
  1578.         jc      try_different_matching
  1579.         mov     [edx-4],esi
  1580.         movzx   eax,byte [ebx+1]
  1581.         lea     ebx,[ebx+2+eax]
  1582.         cmp     byte [ebx],1Ah
  1583.         je      free_match
  1584.       find_exact_match:
  1585.         call    exact_match
  1586.         cmp     esi,[parameters_end]
  1587.         je      end_matching
  1588.         cmp     byte [ebx],1Ah
  1589.         je      free_match
  1590.         mov     ebx,[edx-12]
  1591.         movzx   eax,byte [ebx+1]
  1592.         lea     ebx,[ebx+2+eax]
  1593.         mov     esi,[edx-4]
  1594.         jmp     match_more_elements
  1595.       try_different_matching:
  1596.         sub     edx,12
  1597.         cmp     edx,edi
  1598.         je      instant_macro_done
  1599.         mov     ebx,[edx-12]
  1600.         movzx   eax,byte [ebx+1]
  1601.         lea     ebx,[ebx+2+eax]
  1602.         cmp     byte [ebx],1Ah
  1603.         je      try_different_matching
  1604.         mov     esi,[edx-4]
  1605.       match_more_elements:
  1606.         call    skip_match_element
  1607.         jc      try_different_matching
  1608.         mov     [edx-4],esi
  1609.         jmp     find_exact_match
  1610.       skip_match_element:
  1611.         cmp     esi,[parameters_end]
  1612.         je      cannot_match
  1613.         mov     al,[esi]
  1614.         cmp     al,1Ah
  1615.         je      skip_match_symbol
  1616.         cmp     al,22h
  1617.         je      skip_match_quoted_string
  1618.         add     esi,1
  1619.         ret
  1620.       skip_match_quoted_string:
  1621.         mov     eax,[esi+1]
  1622.         add     esi,5
  1623.         jmp     skip_match_ok
  1624.       skip_match_symbol:
  1625.         movzx   eax,byte [esi+1]
  1626.         add     esi,2
  1627.       skip_match_ok:
  1628.         add     esi,eax
  1629.         ret
  1630.       cannot_match:
  1631.         stc
  1632.         ret
  1633.       exact_match:
  1634.         cmp     esi,[parameters_end]
  1635.         je      exact_match_complete
  1636.         mov     ah,[esi]
  1637.         mov     al,[ebx]
  1638.         cmp     al,','
  1639.         je      exact_match_complete
  1640.         cmp     al,1Ah
  1641.         je      exact_match_complete
  1642.         cmp     al,'='
  1643.         je      match_verbatim
  1644.         call    match_elements
  1645.         je      exact_match
  1646.       exact_match_complete:
  1647.         ret
  1648.       match_verbatim:
  1649.         inc     ebx
  1650.         call    match_elements
  1651.         je      exact_match
  1652.         dec     ebx
  1653.         ret
  1654.       match_elements:
  1655.         mov     al,[ebx]
  1656.         cmp     al,1Ah
  1657.         je      match_symbols
  1658.         cmp     al,22h
  1659.         je      match_quoted_strings
  1660.         cmp     al,ah
  1661.         je      symbol_characters_matched
  1662.         ret
  1663.       symbol_characters_matched:
  1664.         lea     ebx,[ebx+1]
  1665.         lea     esi,[esi+1]
  1666.         ret
  1667.       match_quoted_strings:
  1668.         mov     ecx,[ebx+1]
  1669.         add     ecx,5
  1670.         jmp     compare_elements
  1671.       match_symbols:
  1672.         movzx   ecx,byte [ebx+1]
  1673.         add     ecx,2
  1674.       compare_elements:
  1675.         mov     eax,esi
  1676.         mov     ebp,edi
  1677.         mov     edi,ebx
  1678.         repe    cmps byte [esi],[edi]
  1679.         jne     elements_mismatch
  1680.         mov     ebx,edi
  1681.         mov     edi,ebp
  1682.         ret
  1683.       elements_mismatch:
  1684.         mov     esi,eax
  1685.         mov     edi,ebp
  1686.         ret
  1687.       end_matching:
  1688.         cmp     byte [ebx],','
  1689.         jne     instant_macro_done
  1690.       matched_pattern:
  1691.         xor     eax,eax
  1692.         push    [free_additional_memory]
  1693.         push    [macro_symbols]
  1694.         mov     [macro_symbols],eax
  1695.         push    [counter_limit]
  1696.         mov     [counter_limit],eax
  1697.         mov     [struc_name],eax
  1698.         push    esi edi edx
  1699.       add_matched_symbol:
  1700.         cmp     edi,[esp]
  1701.         je      matched_symbols_ok
  1702.         mov     esi,[edi]
  1703.         inc     esi
  1704.         lods    byte [esi]
  1705.         movzx   ecx,al
  1706.         xor     eax,eax
  1707.         call    add_macro_symbol
  1708.         mov     eax,[edi+4]
  1709.         mov     dword [edx+12],eax
  1710.         mov     ecx,[edi+8]
  1711.         sub     ecx,eax
  1712.         mov     dword [edx+8],ecx
  1713.         add     edi,12
  1714.         jmp     add_matched_symbol
  1715.       matched_symbols_ok:
  1716.         pop     edx edi esi
  1717.         jmp     instant_macro_parameters_ok
  1718.  
  1719. process_macro:
  1720.         push    dword [macro_status]
  1721.         or      [macro_status],10h
  1722.         push    [counter]
  1723.         push    [macro_block]
  1724.         push    [macro_block_line]
  1725.         push    [macro_block_line_number]
  1726.         push    [struc_label]
  1727.         push    [struc_name]
  1728.         push    eax
  1729.         push    [current_line]
  1730.         lods    byte [esi]
  1731.         cmp     al,'{'
  1732.         je      macro_instructions_start
  1733.         or      al,al
  1734.         jnz     unexpected_characters
  1735.       find_macro_instructions:
  1736.         mov     [macro_line],esi
  1737.         add     esi,16+2
  1738.         lods    byte [esi]
  1739.         or      al,al
  1740.         jz      find_macro_instructions
  1741.         cmp     al,'{'
  1742.         je      macro_instructions_start
  1743.         cmp     al,3Bh
  1744.         jne     unexpected_characters
  1745.         call    skip_foreign_symbol
  1746.         jmp     find_macro_instructions
  1747.       macro_instructions_start:
  1748.         mov     ecx,80000000h
  1749.         mov     [macro_block],esi
  1750.         mov     eax,[macro_line]
  1751.         mov     [macro_block_line],eax
  1752.         mov     [macro_block_line_number],ecx
  1753.         xor     eax,eax
  1754.         mov     [counter],eax
  1755.         cmp     [counter_limit],eax
  1756.         je      process_macro_line
  1757.         inc     [counter]
  1758.       process_macro_line:
  1759.         mov     [current_line],edi
  1760.         cmp     edi,[memory_end]
  1761.         jae     out_of_memory
  1762.         mov     eax,[esp+4]
  1763.         or      eax,eax
  1764.         jz      instant_macro_line_header
  1765.         stos    dword [edi]
  1766.         mov     eax,ecx
  1767.         stos    dword [edi]
  1768.         mov     eax,[esp]
  1769.         stos    dword [edi]
  1770.         mov     eax,[macro_line]
  1771.         stos    dword [edi]
  1772.         jmp     macro_line_header_ok
  1773.       instant_macro_line_header:
  1774.         mov     edx,[macro_line]
  1775.         mov     eax,[edx]
  1776.         stos    dword [edi]
  1777.         mov     eax,[edx+4]
  1778.         stos    dword [edi]
  1779.         mov     eax,[edx+8]
  1780.         stos    dword [edi]
  1781.         mov     eax,[edx+12]
  1782.         stos    dword [edi]
  1783.       macro_line_header_ok:
  1784.         or      [macro_status],20h
  1785.         push    ebx ecx
  1786.         test    [macro_status],0Fh
  1787.         jz      process_macro_line_element
  1788.         mov     ax,3Bh
  1789.         stos    word [edi]
  1790.       process_macro_line_element:
  1791.         lods    byte [esi]
  1792.         cmp     al,'}'
  1793.         je      macro_line_processed
  1794.         or      al,al
  1795.         jz      macro_line_processed
  1796.         cmp     al,1Ah
  1797.         je      process_macro_symbol
  1798.         cmp     al,3Bh
  1799.         je      macro_foreign_line
  1800.         and     [macro_status],not 20h
  1801.         stos    byte [edi]
  1802.         cmp     al,22h
  1803.         jne     process_macro_line_element
  1804.       copy_macro_string:
  1805.         mov     ecx,[esi]
  1806.         add     ecx,4
  1807.         rep     movs byte [edi],[esi]
  1808.         jmp     process_macro_line_element
  1809.       process_macro_symbol:
  1810.         push    esi edi
  1811.         test    [macro_status],20h
  1812.         jz      not_macro_directive
  1813.         movzx   ecx,byte [esi]
  1814.         inc     esi
  1815.         mov     edi,macro_directives
  1816.         call    get_symbol
  1817.         jnc     process_macro_directive
  1818.         dec     esi
  1819.         jmp     not_macro_directive
  1820.       process_macro_directive:
  1821.         movzx   edx,ax
  1822.         add     edx,preprocessor
  1823.         pop     edi eax
  1824.         mov     byte [edi],0
  1825.         inc     edi
  1826.         pop     ecx ebx
  1827.         jmp     near edx
  1828.       not_macro_directive:
  1829.         and     [macro_status],not 20h
  1830.         movzx   ecx,byte [esi]
  1831.         inc     esi
  1832.         mov     eax,[counter]
  1833.         call    get_macro_symbol
  1834.         jnc     group_macro_symbol
  1835.         xor     eax,eax
  1836.         cmp     [counter],eax
  1837.         je      multiple_macro_symbol_values
  1838.         call    get_macro_symbol
  1839.         jc      not_macro_symbol
  1840.       replace_macro_symbol:
  1841.         pop     edi eax
  1842.         mov     ecx,[edx+8]
  1843.         and     ecx,not 80000000h
  1844.         mov     edx,[edx+12]
  1845.         or      edx,edx
  1846.         jz      replace_macro_counter
  1847.         xchg    esi,edx
  1848.         rep     movs byte [edi],[esi]
  1849.         mov     esi,edx
  1850.         jmp     process_macro_line_element
  1851.       group_macro_symbol:
  1852.         xor     eax,eax
  1853.         cmp     [counter],eax
  1854.         je      replace_macro_symbol
  1855.         push    esi edx
  1856.         sub     esi,ecx
  1857.         call    get_macro_symbol
  1858.         mov     ebx,edx
  1859.         pop     edx esi
  1860.         jc      replace_macro_symbol
  1861.         cmp     edx,ebx
  1862.         ja      replace_macro_symbol
  1863.         mov     edx,ebx
  1864.         jmp     replace_macro_symbol
  1865.       multiple_macro_symbol_values:
  1866.         inc     eax
  1867.         push    eax
  1868.         call    get_macro_symbol
  1869.         pop     eax
  1870.         jc      not_macro_symbol
  1871.         pop     edi
  1872.         push    ecx
  1873.         mov     ecx,[edx+8]
  1874.         mov     edx,[edx+12]
  1875.         xchg    esi,edx
  1876.         btr     ecx,31
  1877.         jc      enclose_macro_symbol_value
  1878.         rep     movs byte [edi],[esi]
  1879.         jmp     macro_symbol_value_ok
  1880.       enclose_macro_symbol_value:
  1881.         mov     byte [edi],'<'
  1882.         inc     edi
  1883.         rep     movs byte [edi],[esi]
  1884.         mov     byte [edi],'>'
  1885.         inc     edi
  1886.       macro_symbol_value_ok:
  1887.         cmp     eax,[counter_limit]
  1888.         je      multiple_macro_symbol_values_ok
  1889.         mov     byte [edi],','
  1890.         inc     edi
  1891.         mov     esi,edx
  1892.         pop     ecx
  1893.         push    edi
  1894.         sub     esi,ecx
  1895.         jmp     multiple_macro_symbol_values
  1896.       multiple_macro_symbol_values_ok:
  1897.         pop     ecx eax
  1898.         mov     esi,edx
  1899.         jmp     process_macro_line_element
  1900.       replace_macro_counter:
  1901.         mov     eax,[counter]
  1902.         and     eax,not 80000000h
  1903.         jz      group_macro_counter
  1904.         add     ecx,eax
  1905.         dec     ecx
  1906.         call    store_number_symbol
  1907.         jmp     process_macro_line_element
  1908.       group_macro_counter:
  1909.         mov     edx,ecx
  1910.         xor     ecx,ecx
  1911.       multiple_macro_counter_values:
  1912.         push    ecx edx
  1913.         add     ecx,edx
  1914.         call    store_number_symbol
  1915.         pop     edx ecx
  1916.         inc     ecx
  1917.         cmp     ecx,[counter_limit]
  1918.         je      process_macro_line_element
  1919.         mov     byte [edi],','
  1920.         inc     edi
  1921.         jmp     multiple_macro_counter_values
  1922.       store_number_symbol:
  1923.         mov     ax,1Ah
  1924.         stos    word [edi]
  1925.         push    edi
  1926.         mov     eax,ecx
  1927.         mov     ecx,1000000000
  1928.         xor     edx,edx
  1929.         xor     bl,bl
  1930.       store_number_digits:
  1931.         div     ecx
  1932.         push    edx
  1933.         or      bl,bl
  1934.         jnz     store_number_digit
  1935.         cmp     ecx,1
  1936.         je      store_number_digit
  1937.         or      al,al
  1938.         jz      number_digit_ok
  1939.         not     bl
  1940.       store_number_digit:
  1941.         add     al,30h
  1942.         stos    byte [edi]
  1943.       number_digit_ok:
  1944.         mov     eax,ecx
  1945.         xor     edx,edx
  1946.         mov     ecx,10
  1947.         div     ecx
  1948.         mov     ecx,eax
  1949.         pop     eax
  1950.         or      ecx,ecx
  1951.         jnz     store_number_digits
  1952.         pop     ebx
  1953.         mov     eax,edi
  1954.         sub     eax,ebx
  1955.         mov     [ebx-1],al
  1956.         ret
  1957.       not_macro_symbol:
  1958.         pop     edi esi
  1959.         mov     al,1Ah
  1960.         stos    byte [edi]
  1961.         mov     al,[esi]
  1962.         inc     esi
  1963.         stos    byte [edi]
  1964.         cmp     byte [esi],'.'
  1965.         jne     copy_raw_symbol
  1966.         mov     ebx,[esp+8+8]
  1967.         or      ebx,ebx
  1968.         jz      copy_raw_symbol
  1969.         cmp     al,1
  1970.         je      copy_struc_name
  1971.         xchg    esi,ebx
  1972.         movzx   ecx,byte [esi-1]
  1973.         add     [edi-1],cl
  1974.         jc      name_too_long
  1975.         rep     movs byte [edi],[esi]
  1976.         xchg    esi,ebx
  1977.       copy_raw_symbol:
  1978.         movzx   ecx,al
  1979.         rep     movs byte [edi],[esi]
  1980.         jmp     process_macro_line_element
  1981.       copy_struc_name:
  1982.         inc     esi
  1983.         xchg    esi,ebx
  1984.         movzx   ecx,byte [esi-1]
  1985.         mov     [edi-1],cl
  1986.         rep     movs byte [edi],[esi]
  1987.         xchg    esi,ebx
  1988.         mov     eax,[esp+8+12]
  1989.         cmp     byte [eax],3Bh
  1990.         je      process_macro_line_element
  1991.         cmp     byte [eax],1Ah
  1992.         jne     disable_replaced_struc_name
  1993.         mov     byte [eax],3Bh
  1994.         jmp     process_macro_line_element
  1995.       disable_replaced_struc_name:
  1996.         mov     ebx,[esp+8+8]
  1997.         push    esi edi
  1998.         lea     edi,[ebx-3]
  1999.         lea     esi,[edi-2]
  2000.         lea     ecx,[esi+1]
  2001.         sub     ecx,eax
  2002.         std
  2003.         rep     movs byte [edi],[esi]
  2004.         cld
  2005.         mov     word [eax],3Bh
  2006.         pop     edi esi
  2007.         jmp     process_macro_line_element
  2008.       skip_foreign_symbol:
  2009.         lods    byte [esi]
  2010.         movzx   eax,al
  2011.         add     esi,eax
  2012.       skip_foreign_line:
  2013.         lods    byte [esi]
  2014.         cmp     al,1Ah
  2015.         je      skip_foreign_symbol
  2016.         cmp     al,3Bh
  2017.         je      skip_foreign_symbol
  2018.         cmp     al,22h
  2019.         je      skip_foreign_string
  2020.         or      al,al
  2021.         jnz     skip_foreign_line
  2022.         ret
  2023.       skip_foreign_string:
  2024.         lods    dword [esi]
  2025.         add     esi,eax
  2026.         jmp     skip_foreign_line
  2027.       macro_foreign_line:
  2028.         call    skip_foreign_symbol
  2029.       macro_line_processed:
  2030.         mov     byte [edi],0
  2031.         inc     edi
  2032.         push    eax
  2033.         call    preprocess_line
  2034.         pop     eax
  2035.         pop     ecx ebx
  2036.         cmp     al,'}'
  2037.         je      macro_block_processed
  2038.       process_next_line:
  2039.         inc     ecx
  2040.         mov     [macro_line],esi
  2041.         add     esi,16+2
  2042.         jmp     process_macro_line
  2043.       macro_block_processed:
  2044.         call    close_macro_block
  2045.         jc      process_macro_line
  2046.         pop     [current_line]
  2047.         add     esp,12
  2048.         pop     [macro_block_line_number]
  2049.         pop     [macro_block_line]
  2050.         pop     [macro_block]
  2051.         pop     [counter]
  2052.         pop     eax
  2053.         and     al,0F0h
  2054.         and     [macro_status],0Fh
  2055.         or      [macro_status],al
  2056.         ret
  2057.  
  2058. local_symbols:
  2059.         lods    byte [esi]
  2060.         cmp     al,1Ah
  2061.         jne     invalid_argument
  2062.         mov     byte [edi-1],3Bh
  2063.         xor     al,al
  2064.         stos    byte [edi]
  2065.       make_local_symbol:
  2066.         push    ecx
  2067.         lods    byte [esi]
  2068.         movzx   ecx,al
  2069.         mov     eax,[counter]
  2070.         call    add_macro_symbol
  2071.         mov     [edx+12],edi
  2072.         movzx   eax,[locals_counter]
  2073.         add     eax,ecx
  2074.         inc     eax
  2075.         cmp     eax,100h
  2076.         jae     name_too_long
  2077.         lea     ebp,[edi+2+eax]
  2078.         cmp     ebp,[memory_end]
  2079.         jae     out_of_memory
  2080.         mov     ah,al
  2081.         mov     al,1Ah
  2082.         stos    word [edi]
  2083.         rep     movs byte [edi],[esi]
  2084.         mov     al,'?'
  2085.         stos    byte [edi]
  2086.         push    esi
  2087.         mov     esi,locals_counter+1
  2088.         movzx   ecx,[locals_counter]
  2089.         rep     movs byte [edi],[esi]
  2090.         pop     esi
  2091.         mov     eax,edi
  2092.         sub     eax,[edx+12]
  2093.         mov     [edx+8],eax
  2094.         xor     al,al
  2095.         stos    byte [edi]
  2096.         mov     eax,locals_counter
  2097.         movzx   ecx,byte [eax]
  2098.       counter_loop:
  2099.         inc     byte [eax+ecx]
  2100.         cmp     byte [eax+ecx],':'
  2101.         jb      counter_ok
  2102.         jne     letter_digit
  2103.         mov     byte [eax+ecx],'A'
  2104.         jmp     counter_ok
  2105.       letter_digit:
  2106.         cmp     byte [eax+ecx],'F'
  2107.         jbe     counter_ok
  2108.         mov     byte [eax+ecx],'0'
  2109.         loop    counter_loop
  2110.       counter_ok:
  2111.         pop     ecx
  2112.         lods    byte [esi]
  2113.         cmp     al,'}'
  2114.         je      macro_block_processed
  2115.         or      al,al
  2116.         jz      process_next_line
  2117.         cmp     al,','
  2118.         jne     extra_characters_on_line
  2119.         dec     edi
  2120.         lods    byte [esi]
  2121.         cmp     al,1Ah
  2122.         je      make_local_symbol
  2123.         jmp     invalid_argument
  2124. common_block:
  2125.         call    close_macro_block
  2126.         jc      process_macro_line
  2127.         mov     [counter],0
  2128.         jmp     new_macro_block
  2129. forward_block:
  2130.         cmp     [counter_limit],0
  2131.         je      common_block
  2132.         call    close_macro_block
  2133.         jc      process_macro_line
  2134.         mov     [counter],1
  2135.         jmp     new_macro_block
  2136. reverse_block:
  2137.         cmp     [counter_limit],0
  2138.         je      common_block
  2139.         call    close_macro_block
  2140.         jc      process_macro_line
  2141.         mov     eax,[counter_limit]
  2142.         or      eax,80000000h
  2143.         mov     [counter],eax
  2144.       new_macro_block:
  2145.         mov     [macro_block],esi
  2146.         mov     eax,[macro_line]
  2147.         mov     [macro_block_line],eax
  2148.         mov     [macro_block_line_number],ecx
  2149.         jmp     process_macro_line
  2150. close_macro_block:
  2151.         cmp     [counter],0
  2152.         je      block_closed
  2153.         jl      reverse_counter
  2154.         mov     eax,[counter]
  2155.         cmp     eax,[counter_limit]
  2156.         je      block_closed
  2157.         inc     [counter]
  2158.         jmp     continue_block
  2159.       reverse_counter:
  2160.         mov     eax,[counter]
  2161.         dec     eax
  2162.         cmp     eax,80000000h
  2163.         je      block_closed
  2164.         mov     [counter],eax
  2165.       continue_block:
  2166.         mov     esi,[macro_block]
  2167.         mov     eax,[macro_block_line]
  2168.         mov     [macro_line],eax
  2169.         mov     ecx,[macro_block_line_number]
  2170.         stc
  2171.         ret
  2172.       block_closed:
  2173.         clc
  2174.         ret
  2175. get_macro_symbol:
  2176.         push    ecx
  2177.         call    find_macro_symbol_leaf
  2178.         jc      macro_symbol_not_found
  2179.         mov     edx,[ebx]
  2180.         mov     ebx,esi
  2181.       try_macro_symbol:
  2182.         or      edx,edx
  2183.         jz      macro_symbol_not_found
  2184.         mov     ecx,[esp]
  2185.         mov     edi,[edx+4]
  2186.         repe    cmps byte [esi],[edi]
  2187.         je      macro_symbol_found
  2188.         mov     esi,ebx
  2189.         mov     edx,[edx]
  2190.         jmp     try_macro_symbol
  2191.       macro_symbol_found:
  2192.         pop     ecx
  2193.         clc
  2194.         ret
  2195.       macro_symbol_not_found:
  2196.         pop     ecx
  2197.         stc
  2198.         ret
  2199.       find_macro_symbol_leaf:
  2200.         shl     eax,8
  2201.         mov     al,cl
  2202.         mov     ebp,eax
  2203.         mov     ebx,macro_symbols
  2204.       follow_macro_symbols_tree:
  2205.         mov     edx,[ebx]
  2206.         or      edx,edx
  2207.         jz      no_such_macro_symbol
  2208.         xor     eax,eax
  2209.         shr     ebp,1
  2210.         adc     eax,0
  2211.         lea     ebx,[edx+eax*4]
  2212.         or      ebp,ebp
  2213.         jnz     follow_macro_symbols_tree
  2214.         add     ebx,8
  2215.         clc
  2216.         ret
  2217.       no_such_macro_symbol:
  2218.         stc
  2219.         ret
  2220. add_macro_symbol:
  2221.         push    ebx ebp
  2222.         call    find_macro_symbol_leaf
  2223.         jc      extend_macro_symbol_tree
  2224.         mov     eax,[ebx]
  2225.       make_macro_symbol:
  2226.         mov     edx,[free_additional_memory]
  2227.         add     edx,16
  2228.         cmp     edx,[labels_list]
  2229.         ja      out_of_memory
  2230.         xchg    edx,[free_additional_memory]
  2231.         mov     [ebx],edx
  2232.         mov     [edx],eax
  2233.         mov     [edx+4],esi
  2234.         pop     ebp ebx
  2235.         ret
  2236.       extend_macro_symbol_tree:
  2237.         mov     edx,[free_additional_memory]
  2238.         add     edx,16
  2239.         cmp     edx,[labels_list]
  2240.         ja      out_of_memory
  2241.         xchg    edx,[free_additional_memory]
  2242.         xor     eax,eax
  2243.         mov     [edx],eax
  2244.         mov     [edx+4],eax
  2245.         mov     [edx+8],eax
  2246.         mov     [edx+12],eax
  2247.         shr     ebp,1
  2248.         adc     eax,0
  2249.         mov     [ebx],edx
  2250.         lea     ebx,[edx+eax*4]
  2251.         or      ebp,ebp
  2252.         jnz     extend_macro_symbol_tree
  2253.         add     ebx,8
  2254.         xor     eax,eax
  2255.         jmp     make_macro_symbol
  2256.  
  2257. include_file:
  2258.         lods    byte [esi]
  2259.         cmp     al,22h
  2260.         jne     invalid_argument
  2261.         lods    dword [esi]
  2262.         cmp     byte [esi+eax],0
  2263.         jne     extra_characters_on_line
  2264.         push    esi
  2265.         push    edi
  2266.         mov     ebx,[current_line]
  2267.       find_current_file_path:
  2268.         mov     esi,[ebx]
  2269.         test    byte [ebx+7],80h
  2270.         jz      copy_current_file_path
  2271.         mov     ebx,[ebx+8]
  2272.         jmp     find_current_file_path
  2273.       copy_current_file_path:
  2274.         lods    byte [esi]
  2275.         stos    byte [edi]
  2276.         or      al,al
  2277.         jnz     copy_current_file_path
  2278.       cut_current_file_name:
  2279.         cmp     edi,[esp]
  2280.         je      current_file_path_ok
  2281.         cmp     byte [edi-1],'\'
  2282.         je      current_file_path_ok
  2283.         cmp     byte [edi-1],'/'
  2284.         je      current_file_path_ok
  2285.         dec     edi
  2286.         jmp     cut_current_file_name
  2287.       current_file_path_ok:
  2288.         mov     esi,[esp+4]
  2289.         call    preprocess_path
  2290.         pop     edx
  2291.         mov     esi,edx
  2292.         call    open
  2293.         jnc     include_path_ok
  2294.         mov     ebp,[include_paths]
  2295.       try_include_directories:
  2296.         mov     edi,esi
  2297.         mov     esi,ebp
  2298.         cmp     byte [esi],0
  2299.         je      try_in_current_directory
  2300.         push    ebp
  2301.         push    edi
  2302.       copy_include_directory:
  2303.         lods    byte [esi]
  2304.         cmp     al,';'
  2305.         je      include_directory_ok
  2306.         stos    byte [edi]
  2307.         or      al,al
  2308.         jnz     copy_include_directory
  2309.         dec     esi
  2310.         dec     edi
  2311.       include_directory_ok:
  2312.         cmp     byte [edi-1],'/'
  2313.         je      path_separator_ok
  2314.         cmp     byte [edi-1],'\'
  2315.         je      path_separator_ok
  2316.         mov     al,'/'
  2317.         stos    byte [edi]
  2318.       path_separator_ok:
  2319.         mov     [esp+4],esi
  2320.         mov     esi,[esp+8]
  2321.         call    preprocess_path
  2322.         pop     edx
  2323.         mov     esi,edx
  2324.         call    open
  2325.         pop     ebp
  2326.         jnc     include_path_ok
  2327.         jmp     try_include_directories
  2328.         mov     edi,esi
  2329.       try_in_current_directory:
  2330.         mov     esi,[esp]
  2331.         push    edi
  2332.         call    preprocess_path
  2333.         pop     edx
  2334.         mov     esi,edx
  2335.         call    open
  2336.         jc      file_not_found
  2337.       include_path_ok:
  2338.         mov     edi,[esp]
  2339.       copy_preprocessed_path:
  2340.         lods    byte [esi]
  2341.         stos    byte [edi]
  2342.         or      al,al
  2343.         jnz     copy_preprocessed_path
  2344.         pop     esi
  2345.         lea     ecx,[edi-1]
  2346.         sub     ecx,esi
  2347.         mov     [esi-4],ecx
  2348.         push    dword [macro_status]
  2349.         and     [macro_status],0Fh
  2350.         call    preprocess_file
  2351.         pop     eax
  2352.         mov     [macro_status],al
  2353.         jmp     line_preprocessed
  2354.       preprocess_path:
  2355.         lods    byte [esi]
  2356.         cmp     al,'%'
  2357.         je      environment_variable
  2358.         stos    byte [edi]
  2359.         or      al,al
  2360.         jnz     preprocess_path
  2361.         cmp     edi,[memory_end]
  2362.         ja      out_of_memory
  2363.         ret
  2364.       environment_variable:
  2365.         mov     ebx,esi
  2366.       find_variable_end:
  2367.         lods    byte [esi]
  2368.         or      al,al
  2369.         jz      not_environment_variable
  2370.         cmp     al,'%'
  2371.         jne     find_variable_end
  2372.         mov     byte [esi-1],0
  2373.         push    esi
  2374.         mov     esi,ebx
  2375.         call    get_environment_variable
  2376.         pop     esi
  2377.         mov     byte [esi-1],'%'
  2378.         jmp     preprocess_path
  2379.       not_environment_variable:
  2380.         mov     al,'%'
  2381.         stos    byte [edi]
  2382.         mov     esi,ebx
  2383.         jmp     preprocess_path
  2384.  
  2385. include_variable db 'INCLUDE',0
  2386.  
  2387. symbol_characters db 27
  2388.  db 9,0Ah,0Dh,1Ah,20h,'+-/*=<>()[]{}:,|&~#`;\'
  2389.  
  2390. preprocessor_directives:
  2391.  db 7,'include'
  2392.  dw include_file-preprocessor
  2393.  db 3,'irp'
  2394.  dw irp_directive-preprocessor
  2395.  db 4,'irps'
  2396.  dw irps_directive-preprocessor
  2397.  db 5,'macro'
  2398.  dw define_macro-preprocessor
  2399.  db 5,'match'
  2400.  dw match_directive-preprocessor
  2401.  db 5,'purge'
  2402.  dw purge_macro-preprocessor
  2403.  db 4,'rept'
  2404.  dw rept_directive-preprocessor
  2405.  db 7,'restore'
  2406.  dw restore_equ_constant-preprocessor
  2407.  db 7,'restruc'
  2408.  dw purge_struc-preprocessor
  2409.  db 5,'struc'
  2410.  dw define_struc-preprocessor
  2411.  db 0
  2412.  
  2413. macro_directives:
  2414.  db 6,'common'
  2415.  dw common_block-preprocessor
  2416.  db 7,'forward'
  2417.  dw forward_block-preprocessor
  2418.  db 5,'local'
  2419.  dw local_symbols-preprocessor
  2420.  db 7,'reverse'
  2421.  dw reverse_block-preprocessor
  2422.  db 0
  2423.