Subversion Repositories Kolibri OS

Rev

Go to most recent revision | Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2005, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. convert_expression:
  7.         push    ebp
  8.         call    get_fp_value
  9.         jnc     fp_expression
  10.         mov     ebp,esp
  11.       expression_loop:
  12.         push    ebp edi
  13.         mov     edi,single_operand_operators
  14.         call    get_operator
  15.         pop     edi
  16.         push    eax
  17.         mov     al,[esi]
  18.         cmp     al,1Ah
  19.         je      expression_number
  20.         cmp     al,22h
  21.         je      expression_number
  22.         cmp     al,'('
  23.         je      expression_number
  24.         mov     al,11h
  25.         stos    byte [edi]
  26.         or      eax,-1
  27.         stos    dword [edi]
  28.         jmp     expression_number_ok
  29.       expression_number:
  30.         call    convert_number
  31.       expression_number_ok:
  32.         pop     eax
  33.         or      al,al
  34.         jz      expression_operator
  35.         stos    byte [edi]
  36.       expression_operator:
  37.         push    edi
  38.         mov     edi,operators
  39.         call    get_operator
  40.         pop     edi ebp
  41.         or      al,al
  42.         jz      expression_end
  43.       operators_loop:
  44.         cmp     esp,ebp
  45.         je      push_operator
  46.         mov     bl,al
  47.         and     bl,0F0h
  48.         mov     bh,byte [esp]
  49.         and     bh,0F0h
  50.         cmp     bl,bh
  51.         ja      push_operator
  52.         pop     ebx
  53.         mov     byte [edi],bl
  54.         inc     edi
  55.         jmp     operators_loop
  56.       push_operator:
  57.         push    eax
  58.         jmp     expression_loop
  59.       expression_end:
  60.         cmp     esp,ebp
  61.         je      expression_converted
  62.         pop     eax
  63.         stos    byte [edi]
  64.         jmp     expression_end
  65.       expression_converted:
  66.         pop     ebp
  67.         ret
  68.       fp_expression:
  69.         mov     al,'.'
  70.         stos    byte [edi]
  71.         mov     eax,[fp_value]
  72.         stos    dword [edi]
  73.         mov     eax,[fp_value+4]
  74.         stos    dword [edi]
  75.         mov     eax,[fp_value+8]
  76.         stos    dword [edi]
  77.         pop     ebp
  78.         ret
  79.  
  80. convert_number:
  81.         cmp     byte [esi],'('
  82.         je      expression_value
  83.         inc     edi
  84.         call    get_number
  85.         jc      symbol_value
  86.         or      ebp,ebp
  87.         jz      valid_number
  88.         mov     byte [edi-1],0Fh
  89.         ret
  90.       valid_number:
  91.         cmp     dword [edi+4],0
  92.         jne     qword_number
  93.         cmp     word [edi+2],0
  94.         jne     dword_number
  95.         cmp     byte [edi+1],0
  96.         jne     word_number
  97.       byte_number:
  98.         mov     byte [edi-1],1
  99.         inc     edi
  100.         ret
  101.       qword_number:
  102.         mov     byte [edi-1],8
  103.         add     edi,8
  104.         ret
  105.       dword_number:
  106.         mov     byte [edi-1],4
  107.         scas    dword [edi]
  108.         ret
  109.       word_number:
  110.         mov     byte [edi-1],2
  111.         scas    word [edi]
  112.         ret
  113.       expression_value:
  114.         mov     eax,esp
  115.         sub     eax,100h
  116.         jc      stack_overflow
  117.         cmp     eax,[stack_limit]
  118.         jb      stack_overflow
  119.         inc     esi
  120.         call    convert_expression
  121.         lods    byte [esi]
  122.         cmp     al,')'
  123.         jne     invalid_expression
  124.         ret
  125.       symbol_value:
  126.         lods    byte [esi]
  127.         cmp     al,1Ah
  128.         jne     invalid_value
  129.         lods    byte [esi]
  130.         movzx   ecx,al
  131.         push    ecx esi edi
  132.         mov     edi,address_registers
  133.         call    get_symbol
  134.         jnc     register_value
  135.         mov     edi,directive_operators
  136.         call    get_symbol
  137.         pop     edi esi ecx
  138.         jnc     broken_value
  139.         call    get_label_id
  140.       store_label_value:
  141.         mov     byte [edi-1],11h
  142.         stos    dword [edi]
  143.         ret
  144.       broken_value:
  145.         sub     esi,2
  146.         or      eax,-1
  147.         jmp     store_label_value
  148.       register_value:
  149.         pop     edi
  150.         add     esp,8
  151.         mov     byte [edi-1],10h
  152.         mov     al,ah
  153.         stos    byte [edi]
  154.         ret
  155.  
  156. get_number:
  157.         xor     ebp,ebp
  158.         lods    byte [esi]
  159.         cmp     al,22h
  160.         je      get_text_number
  161.         cmp     al,1Ah
  162.         jne     not_number
  163.         lods    byte [esi]
  164.         movzx   ecx,al
  165.         mov     [number_start],esi
  166.         mov     al,[esi]
  167.         cmp     al,'$'
  168.         je      number_begin
  169.         sub     al,30h
  170.         cmp     al,9
  171.         ja      invalid_number
  172.       number_begin:
  173.         mov     ebx,esi
  174.         add     esi,ecx
  175.         push    esi
  176.         dec     esi
  177.         mov     dword [edi],0
  178.         mov     dword [edi+4],0
  179.         cmp     byte [ebx],'$'
  180.         je      pascal_hex_number
  181.         cmp     word [ebx],'0x'
  182.         je      get_hex_number
  183.         mov     al,[esi]
  184.         dec     esi
  185.         cmp     al,'h'
  186.         je      get_hex_number
  187.         cmp     al,'b'
  188.         je      get_bin_number
  189.         cmp     al,'d'
  190.         je      get_dec_number
  191.         cmp     al,'o'
  192.         je      get_oct_number
  193.         cmp     al,'H'
  194.         je      get_hex_number
  195.         cmp     al,'B'
  196.         je      get_bin_number
  197.         cmp     al,'D'
  198.         je      get_dec_number
  199.         cmp     al,'O'
  200.         je      get_oct_number
  201.         inc     esi
  202.       get_dec_number:
  203.         mov     ebx,esi
  204.         mov     esi,[number_start]
  205.       get_dec_digit:
  206.         cmp     esi,ebx
  207.         ja      number_ok
  208.         xor     edx,edx
  209.         mov     eax,[edi]
  210.         shld    edx,eax,2
  211.         shl     eax,2
  212.         add     eax,[edi]
  213.         adc     edx,0
  214.         add     eax,eax
  215.         adc     edx,edx
  216.         mov     [edi],eax
  217.         mov     eax,[edi+4]
  218.         add     eax,eax
  219.         jc      dec_out_of_range
  220.         add     eax,eax
  221.         jc      dec_out_of_range
  222.         add     eax,[edi+4]
  223.         jc      dec_out_of_range
  224.         add     eax,eax
  225.         jc      dec_out_of_range
  226.         add     eax,edx
  227.         jc      dec_out_of_range
  228.         mov     [edi+4],eax
  229.         movzx   eax,byte [esi]
  230.         sub     al,30h
  231.         cmp     al,9
  232.         ja      bad_number
  233.         add     [edi],eax
  234.         adc     dword [edi+4],0
  235.         jc      dec_out_of_range
  236.         inc     esi
  237.         jmp     get_dec_digit
  238.       dec_out_of_range:
  239.         or      ebp,-1
  240.         inc     esi
  241.         jmp     get_dec_digit
  242.       bad_number:
  243.         pop     eax
  244.       invalid_number:
  245.         mov     esi,[number_start]
  246.         dec     esi
  247.       not_number:
  248.         dec     esi
  249.         stc
  250.         ret
  251.       get_bin_number:
  252.         xor     bl,bl
  253.       get_bin_digit:
  254.         cmp     esi,[number_start]
  255.         jb      number_ok
  256.         movzx   eax,byte [esi]
  257.         sub     al,30h
  258.         cmp     al,1
  259.         ja      bad_number
  260.         xor     edx,edx
  261.         mov     cl,bl
  262.         dec     esi
  263.         cmp     bl,64
  264.         je      bin_out_of_range
  265.         inc     bl
  266.         cmp     cl,32
  267.         jae     bin_digit_high
  268.         shl     eax,cl
  269.         or      dword [edi],eax
  270.         jmp     get_bin_digit
  271.       bin_digit_high:
  272.         sub     cl,32
  273.         shl     eax,cl
  274.         or      dword [edi+4],eax
  275.         jmp     get_bin_digit
  276.       bin_out_of_range:
  277.         or      al,al
  278.         jz      get_bin_digit
  279.         or      ebp,-1
  280.         jmp     get_bin_digit
  281.       pascal_hex_number:
  282.         cmp     cl,1
  283.         je      bad_number
  284.       get_hex_number:
  285.         xor     bl,bl
  286.       get_hex_digit:
  287.         cmp     esi,[number_start]
  288.         jb      number_ok
  289.         movzx   eax,byte [esi]
  290.         cmp     al,'x'
  291.         je      hex_number_ok
  292.         cmp     al,'$'
  293.         je      pascal_hex_ok
  294.         sub     al,30h
  295.         cmp     al,9
  296.         jbe     hex_digit_ok
  297.         sub     al,7
  298.         cmp     al,15
  299.         jbe     hex_letter_digit_ok
  300.         sub     al,20h
  301.         cmp     al,15
  302.         ja      bad_number
  303.       hex_letter_digit_ok:
  304.         cmp     al,10
  305.         jb      bad_number
  306.       hex_digit_ok:
  307.         xor     edx,edx
  308.         mov     cl,bl
  309.         dec     esi
  310.         cmp     bl,64
  311.         je      hex_out_of_range
  312.         add     bl,4
  313.         cmp     cl,32
  314.         jae     hex_digit_high
  315.         shl     eax,cl
  316.         or      dword [edi],eax
  317.         jmp     get_hex_digit
  318.       hex_digit_high:
  319.         sub     cl,32
  320.         shl     eax,cl
  321.         or      dword [edi+4],eax
  322.         jmp     get_hex_digit
  323.       hex_out_of_range:
  324.         or      al,al
  325.         jz      get_hex_digit
  326.         or      ebp,-1
  327.         jmp     get_hex_digit
  328.       get_oct_number:
  329.         xor     bl,bl
  330.       get_oct_digit:
  331.         cmp     esi,[number_start]
  332.         jb      number_ok
  333.         movzx   eax,byte [esi]
  334.         sub     al,30h
  335.         cmp     al,7
  336.         ja      bad_number
  337.       oct_digit_ok:
  338.         xor     edx,edx
  339.         mov     cl,bl
  340.         dec     esi
  341.         cmp     bl,64
  342.         jae     oct_out_of_range
  343.         add     bl,3
  344.         cmp     cl,30
  345.         je      oct_digit_wrap
  346.         ja      oct_digit_high
  347.         shl     eax,cl
  348.         or      dword [edi],eax
  349.         jmp     get_oct_digit
  350.       oct_digit_wrap:
  351.         shl     eax,cl
  352.         adc     dword [edi+4],0
  353.         or      dword [edi],eax
  354.         jmp     get_oct_digit
  355.       oct_digit_high:
  356.         sub     cl,32
  357.         shl     eax,cl
  358.         or      dword [edi+4],eax
  359.         jmp     get_oct_digit
  360.       oct_out_of_range:
  361.         or      al,al
  362.         jz      get_oct_digit
  363.         or      ebp,-1
  364.         jmp     get_oct_digit
  365.       hex_number_ok:
  366.         dec     esi
  367.       pascal_hex_ok:
  368.         cmp     esi,[number_start]
  369.         jne     bad_number
  370.       number_ok:
  371.         pop     esi
  372.       number_done:
  373.         clc
  374.         ret
  375.       get_text_number:
  376.         lods    dword [esi]
  377.         mov     edx,eax
  378.         xor     bl,bl
  379.         mov     dword [edi],0
  380.         mov     dword [edi+4],0
  381.       get_text_character:
  382.         sub     edx,1
  383.         jc      number_done
  384.         movzx   eax,byte [esi]
  385.         inc     esi
  386.         mov     cl,bl
  387.         cmp     bl,64
  388.         je      text_out_of_range
  389.         add     bl,8
  390.         cmp     cl,32
  391.         jae     text_character_high
  392.         shl     eax,cl
  393.         or      dword [edi],eax
  394.         jmp     get_text_character
  395.       text_character_high:
  396.         sub     cl,32
  397.         shl     eax,cl
  398.         or      dword [edi+4],eax
  399.         jmp     get_text_character
  400.       text_out_of_range:
  401.         or      ebp,-1
  402.         jmp     get_text_character
  403.  
  404. get_fp_value:
  405.         push    edi esi
  406.         lods    byte [esi]
  407.         cmp     al,1Ah
  408.         je      fp_value_start
  409.         cmp     al,'-'
  410.         je      fp_sign_ok
  411.         cmp     al,'+'
  412.         jne     not_fp_value
  413.       fp_sign_ok:
  414.         lods    byte [esi]
  415.         cmp     al,1Ah
  416.         jne     not_fp_value
  417.       fp_value_start:
  418.         lods    byte [esi]
  419.         movzx   ecx,al
  420.         cmp     cl,1
  421.         jbe     not_fp_value
  422.         lea     edx,[esi+1]
  423.         xor     ah,ah
  424.       check_fp_value:
  425.         lods    byte [esi]
  426.         cmp     al,'.'
  427.         je      fp_character_dot
  428.         cmp     al,'E'
  429.         je      fp_character_exp
  430.         cmp     al,'e'
  431.         je      fp_character_exp
  432.         cmp     al,'F'
  433.         je      fp_last_character
  434.         cmp     al,'f'
  435.         je      fp_last_character
  436.       digit_expected:
  437.         cmp     al,'0'
  438.         jb      not_fp_value
  439.         cmp     al,'9'
  440.         ja      not_fp_value
  441.         jmp     fp_character_ok
  442.       fp_character_dot:
  443.         cmp     esi,edx
  444.         je      not_fp_value
  445.         or      ah,ah
  446.         jnz     not_fp_value
  447.         or      ah,1
  448.         lods    byte [esi]
  449.         loop    digit_expected
  450.       not_fp_value:
  451.         pop     esi edi
  452.         stc
  453.         ret
  454.       fp_character_exp:
  455.         cmp     esi,edx
  456.         je      not_fp_value
  457.         cmp     ah,1
  458.         ja      not_fp_value
  459.         or      ah,2
  460.         cmp     ecx,1
  461.         jne     fp_character_ok
  462.         cmp     byte [esi],'+'
  463.         je      fp_exp_sign
  464.         cmp     byte [esi],'-'
  465.         jne     fp_character_ok
  466.       fp_last_character:
  467.         cmp     cl,1
  468.         jne     not_fp_value
  469.         or      ah,4
  470.         jmp     fp_character_ok
  471.       fp_exp_sign:
  472.         inc     esi
  473.         cmp     byte [esi],1Ah
  474.         jne     not_fp_value
  475.         inc     esi
  476.         lods    byte [esi]
  477.         movzx   ecx,al
  478.         inc     ecx
  479.       fp_character_ok:
  480.         dec     ecx
  481.         jnz     check_fp_value
  482.         or      ah,ah
  483.         jz      not_fp_value
  484.         pop     esi
  485.         lods    byte [esi]
  486.         mov     [fp_sign],0
  487.         cmp     al,1Ah
  488.         je      fp_get
  489.         inc     esi
  490.         cmp     al,'+'
  491.         je      fp_get
  492.         mov     [fp_sign],1
  493.       fp_get:
  494.         lods    byte [esi]
  495.         movzx   ecx,al
  496.         xor     edx,edx
  497.         mov     edi,fp_value
  498.         mov     [edi],edx
  499.         mov     [edi+4],edx
  500.         mov     [edi+12],edx
  501.         call    fp_optimize
  502.         mov     [fp_format],0
  503.         mov     al,[esi]
  504.       fp_before_dot:
  505.         lods    byte [esi]
  506.         cmp     al,'.'
  507.         je      fp_dot
  508.         cmp     al,'E'
  509.         je      fp_exponent
  510.         cmp     al,'e'
  511.         je      fp_exponent
  512.         cmp     al,'F'
  513.         je      fp_done
  514.         cmp     al,'f'
  515.         je      fp_done
  516.         sub     al,30h
  517.         mov     edi,fp_value+16
  518.         xor     edx,edx
  519.         mov     dword [edi+12],edx
  520.         mov     dword [edi],edx
  521.         mov     dword [edi+4],edx
  522.         mov     [edi+7],al
  523.         mov     dl,7
  524.         mov     dword [edi+8],edx
  525.         call    fp_optimize
  526.         mov     edi,fp_value
  527.         push    ecx
  528.         mov     ecx,10
  529.         call    fp_mul
  530.         pop     ecx
  531.         mov     ebx,fp_value+16
  532.         call    fp_add
  533.         loop    fp_before_dot
  534.       fp_dot:
  535.         mov     edi,fp_value+16
  536.         xor     edx,edx
  537.         mov     [edi],edx
  538.         mov     [edi+4],edx
  539.         mov     byte [edi+7],80h
  540.         mov     [edi+8],edx
  541.         mov     dword [edi+12],edx
  542.         dec     ecx
  543.         jz      fp_done
  544.       fp_after_dot:
  545.         lods    byte [esi]
  546.         cmp     al,'E'
  547.         je      fp_exponent
  548.         cmp     al,'e'
  549.         je      fp_exponent
  550.         cmp     al,'F'
  551.         je      fp_done
  552.         cmp     al,'f'
  553.         je      fp_done
  554.         inc     [fp_format]
  555.         cmp     [fp_format],80h
  556.         jne     fp_counter_ok
  557.         mov     [fp_format],7Fh
  558.       fp_counter_ok:
  559.         dec     esi
  560.         mov     edi,fp_value+16
  561.         push    ecx
  562.         mov     ecx,10
  563.         call    fp_div
  564.         push    dword [edi]
  565.         push    dword [edi+4]
  566.         push    dword [edi+8]
  567.         push    dword [edi+12]
  568.         lods    byte [esi]
  569.         sub     al,30h
  570.         movzx   ecx,al
  571.         call    fp_mul
  572.         mov     ebx,edi
  573.         mov     edi,fp_value
  574.         call    fp_add
  575.         mov     edi,fp_value+16
  576.         pop     dword [edi+12]
  577.         pop     dword [edi+8]
  578.         pop     dword [edi+4]
  579.         pop     dword [edi]
  580.         pop     ecx
  581.         loop    fp_after_dot
  582.         jmp     fp_done
  583.       fp_exponent:
  584.         or      [fp_format],80h
  585.         xor     edx,edx
  586.         xor     ebp,ebp
  587.         dec     ecx
  588.         jnz     get_exponent
  589.         cmp     byte [esi],'+'
  590.         je      fp_exponent_sign
  591.         cmp     byte [esi],'-'
  592.         jne     fp_done
  593.         not     ebp
  594.       fp_exponent_sign:
  595.         add     esi,2
  596.         lods    byte [esi]
  597.         movzx   ecx,al
  598.       get_exponent:
  599.         movzx   eax,byte [esi]
  600.         inc     esi
  601.         sub     al,30h
  602.         cmp     al,10
  603.         jae     exponent_ok
  604.         imul    edx,10
  605.         cmp     edx,8000h
  606.         jae     value_out_of_range
  607.         add     edx,eax
  608.         loop    get_exponent
  609.       exponent_ok:
  610.         mov     edi,fp_value
  611.         or      edx,edx
  612.         jz      fp_done
  613.         mov     ecx,edx
  614.         or      ebp,ebp
  615.         jnz     fp_negative_power
  616.       fp_power:
  617.         push    ecx
  618.         mov     ecx,10
  619.         call    fp_mul
  620.         pop     ecx
  621.         loop    fp_power
  622.         jmp     fp_done
  623.       fp_negative_power:
  624.         push    ecx
  625.         mov     ecx,10
  626.         call    fp_div
  627.         pop     ecx
  628.         loop    fp_negative_power
  629.       fp_done:
  630.         mov     edi,fp_value
  631.         mov     al,[fp_format]
  632.         mov     [edi+10],al
  633.         mov     al,[fp_sign]
  634.         mov     [edi+11],al
  635.         test    byte [edi+15],80h
  636.         jz      fp_ok
  637.         add     dword [edi],1
  638.         adc     dword [edi+4],0
  639.         jnc     fp_ok
  640.         mov     eax,[edi+4]
  641.         shrd    [edi],eax,1
  642.         shr     eax,1
  643.         or      eax,80000000h
  644.         mov     [edi+4],eax
  645.         inc     word [edi+8]
  646.       fp_ok:
  647.         pop     edi
  648.         clc
  649.         ret
  650.       fp_mul:
  651.         or      ecx,ecx
  652.         jz      fp_zero
  653.         mov     eax,[edi+12]
  654.         mul     ecx
  655.         mov     [edi+12],eax
  656.         mov     ebx,edx
  657.         mov     eax,[edi]
  658.         mul     ecx
  659.         add     eax,ebx
  660.         adc     edx,0
  661.         mov     [edi],eax
  662.         mov     ebx,edx
  663.         mov     eax,[edi+4]
  664.         mul     ecx
  665.         add     eax,ebx
  666.         adc     edx,0
  667.         mov     [edi+4],eax
  668.       .loop:
  669.         or      edx,edx
  670.         jz      .done
  671.         mov     eax,[edi]
  672.         shrd    [edi+12],eax,1
  673.         mov     eax,[edi+4]
  674.         shrd    [edi],eax,1
  675.         shrd    eax,edx,1
  676.         mov     [edi+4],eax
  677.         shr     edx,1
  678.         inc     dword [edi+8]
  679.         cmp     dword [edi+8],8000h
  680.         jge     value_out_of_range
  681.         jmp     .loop
  682.       .done:
  683.         ret
  684.       fp_div:
  685.         mov     eax,[edi+4]
  686.         xor     edx,edx
  687.         div     ecx
  688.         mov     [edi+4],eax
  689.         mov     eax,[edi]
  690.         div     ecx
  691.         mov     [edi],eax
  692.         mov     eax,[edi+12]
  693.         div     ecx
  694.         mov     [edi+12],eax
  695.         mov     ebx,eax
  696.         or      ebx,[edi]
  697.         or      ebx,[edi+4]
  698.         jz      fp_zero
  699.       .loop:
  700.         test    byte [edi+7],80h
  701.         jnz     .exp_ok
  702.         mov     eax,[edi]
  703.         shld    [edi+4],eax,1
  704.         mov     eax,[edi+12]
  705.         shld    [edi],eax,1
  706.         add     eax,eax
  707.         mov     [edi+12],eax
  708.         dec     dword [edi+8]
  709.         add     edx,edx
  710.         jmp     .loop
  711.       .exp_ok:
  712.         mov     eax,edx
  713.         xor     edx,edx
  714.         div     ecx
  715.         add     [edi+12],eax
  716.         adc     dword [edi],0
  717.         adc     dword [edi+4],0
  718.         jnc     .done
  719.         mov     eax,[edi+4]
  720.         mov     ebx,[edi]
  721.         shrd    [edi],eax,1
  722.         shrd    [edi+12],ebx,1
  723.         shr     eax,1
  724.         or      eax,80000000h
  725.         mov     [edi+4],eax
  726.         inc     dword [edi+8]
  727.       .done:
  728.         ret
  729.       fp_add:
  730.         cmp     dword [ebx+8],8000h
  731.         je      .done
  732.         cmp     dword [edi+8],8000h
  733.         je      .copy
  734.         mov     eax,[ebx+8]
  735.         cmp     eax,[edi+8]
  736.         jge     .exp_ok
  737.         mov     eax,[edi+8]
  738.       .exp_ok:
  739.         call    .change_exp
  740.         xchg    ebx,edi
  741.         call    .change_exp
  742.         xchg    ebx,edi
  743.         mov     edx,[ebx+12]
  744.         mov     eax,[ebx]
  745.         mov     ebx,[ebx+4]
  746.         add     [edi+12],edx
  747.         adc     [edi],eax
  748.         adc     [edi+4],ebx
  749.         jnc     .done
  750.         mov     eax,[edi]
  751.         shrd    [edi+12],eax,1
  752.         mov     eax,[edi+4]
  753.         shrd    [edi],eax,1
  754.         shr     eax,1
  755.         or      eax,80000000h
  756.         mov     [edi+4],eax
  757.         inc     dword [edi+8]
  758.       .done:
  759.         ret
  760.       .copy:
  761.         mov     eax,[ebx]
  762.         mov     [edi],eax
  763.         mov     eax,[ebx+4]
  764.         mov     [edi+4],eax
  765.         mov     eax,[ebx+8]
  766.         mov     [edi+8],eax
  767.         mov     eax,[ebx+12]
  768.         mov     [edi+12],eax
  769.         ret
  770.       .change_exp:
  771.         push    ecx
  772.         mov     ecx,eax
  773.         sub     ecx,[ebx+8]
  774.         mov     edx,[ebx+4]
  775.         jecxz   .exp_done
  776.       .exp_loop:
  777.         mov     ebp,[ebx]
  778.         shrd    [ebx+12],ebp,1
  779.         shrd    [ebx],edx,1
  780.         shr     edx,1
  781.         inc     dword [ebx+8]
  782.         loop    .exp_loop
  783.       .exp_done:
  784.         mov     [ebx+4],edx
  785.         pop     ecx
  786.         ret
  787.       fp_optimize:
  788.         mov     eax,[edi]
  789.         mov     ebp,[edi+4]
  790.         or      ebp,[edi]
  791.         or      ebp,[edi+12]
  792.         jz      fp_zero
  793.       .loop:
  794.         test    byte [edi+7],80h
  795.         jnz     .done
  796.         shld    [edi+4],eax,1
  797.         mov     ebp,[edi+12]
  798.         shld    eax,ebp,1
  799.         mov     [edi],eax
  800.         shl     dword [edi+12],1
  801.         dec     dword [edi+8]
  802.         jmp     .loop
  803.       .done:
  804.         ret
  805.       fp_zero:
  806.         mov     dword [edi+8],8000h
  807.         ret
  808.  
  809. calculate_expression:
  810.         mov     [current_offset],edi
  811.         mov     [value_undefined],0
  812.       calculation_loop:
  813.         lods    byte [esi]
  814.         or      al,al
  815.         jz      get_string_value
  816.         cmp     al,'.'
  817.         je      convert_fp
  818.         cmp     al,1
  819.         je      get_byte_number
  820.         cmp     al,2
  821.         je      get_word_number
  822.         cmp     al,4
  823.         je      get_dword_number
  824.         cmp     al,8
  825.         je      get_qword_number
  826.         cmp     al,0Fh
  827.         je      value_out_of_range
  828.         cmp     al,10h
  829.         je      get_register
  830.         cmp     al,11h
  831.         je      get_label
  832.         cmp     al,')'
  833.         je      expression_calculated
  834.         cmp     al,']'
  835.         je      expression_calculated
  836.         sub     edi,14h
  837.         mov     ebx,edi
  838.         sub     ebx,14h
  839.         cmp     al,0E0h
  840.         je      calculate_rva
  841.         cmp     al,0D0h
  842.         je      calculate_not
  843.         cmp     al,0D1h
  844.         je      calculate_neg
  845.         mov     dx,[ebx+8]
  846.         or      dx,[edi+8]
  847.         cmp     al,80h
  848.         je      calculate_add
  849.         cmp     al,81h
  850.         je      calculate_sub
  851.         mov     ah,[ebx+12]
  852.         or      ah,[edi+12]
  853.         jz      absolute_values_calculation
  854.         cmp     [error_line],0
  855.         jne     absolute_values_calculation
  856.         mov     eax,[current_line]
  857.         mov     [error_line],eax
  858.         mov     [error],invalid_use_of_symbol
  859.       absolute_values_calculation:
  860.         cmp     al,90h
  861.         je      calculate_mul
  862.         cmp     al,91h
  863.         je      calculate_div
  864.         or      dx,dx
  865.         jnz     invalid_expression
  866.         cmp     al,0A0h
  867.         je      calculate_mod
  868.         cmp     al,0B0h
  869.         je      calculate_and
  870.         cmp     al,0B1h
  871.         je      calculate_or
  872.         cmp     al,0B2h
  873.         je      calculate_xor
  874.         cmp     al,0C0h
  875.         je      calculate_shl
  876.         cmp     al,0C1h
  877.         je      calculate_shr
  878.         jmp     invalid_expression
  879.       expression_calculated:
  880.         sub     edi,14h
  881.         cmp     [value_undefined],0
  882.         je      expression_value_ok
  883.         xor     eax,eax
  884.         mov     [edi],eax
  885.         mov     [edi+4],eax
  886.       expression_value_ok:
  887.         ret
  888.       get_byte_number:
  889.         mov     word [edi+8],0
  890.         mov     byte [edi+12],0
  891.         xor     eax,eax
  892.         lods    byte [esi]
  893.         stos    dword [edi]
  894.         xor     al,al
  895.         stos    dword [edi]
  896.         add     edi,0Ch
  897.         jmp     calculation_loop
  898.       get_word_number:
  899.         mov     word [edi+8],0
  900.         mov     byte [edi+12],0
  901.         xor     eax,eax
  902.         lods    word [esi]
  903.         stos    dword [edi]
  904.         xor     ax,ax
  905.         stos    dword [edi]
  906.         add     edi,0Ch
  907.         jmp     calculation_loop
  908.       get_dword_number:
  909.         mov     word [edi+8],0
  910.         mov     byte [edi+12],0
  911.         movs    dword [edi],[esi]
  912.         xor     eax,eax
  913.         stos    dword [edi]
  914.         add     edi,0Ch
  915.         jmp     calculation_loop
  916.       get_qword_number:
  917.         mov     word [edi+8],0
  918.         mov     byte [edi+12],0
  919.         movs    dword [edi],[esi]
  920.         movs    dword [edi],[esi]
  921.         add     edi,0Ch
  922.         jmp     calculation_loop
  923.       get_register:
  924.         mov     byte [edi+9],0
  925.         mov     byte [edi+12],0
  926.         lods    byte [esi]
  927.         mov     [edi+8],al
  928.         mov     byte [edi+10],1
  929.         xor     eax,eax
  930.         stos    dword [edi]
  931.         stos    dword [edi]
  932.         add     edi,0Ch
  933.         jmp     calculation_loop
  934.       get_label:
  935.         xor     eax,eax
  936.         mov     [edi+8],eax
  937.         mov     [edi+12],al
  938.         mov     [edi+20],eax
  939.         lods    dword [esi]
  940.         cmp     eax,0Fh
  941.         jb      predefined_label
  942.         je      reserved_word_used_as_symbol
  943.         cmp     eax,-1
  944.         je      invalid_expression
  945.         mov     ebx,eax
  946.         mov     ax,[current_pass]
  947.         mov     [ebx+18],ax
  948.         or      byte [ebx+8],8
  949.         test    byte [ebx+8],1
  950.         jz      label_undefined
  951.         cmp     ax,[ebx+16]
  952.         je      label_defined
  953.         test    byte [ebx+8],4
  954.         jnz     label_undefined
  955.         test    byte [ebx+9],1
  956.         jz      label_defined
  957.         mov     eax,[ebx]
  958.         sub     eax,dword [adjustment]
  959.         stos    dword [edi]
  960.         mov     eax,[ebx+4]
  961.         sbb     eax,dword [adjustment+4]
  962.         stos    dword [edi]
  963.         mov     eax,dword [adjustment]
  964.         or      eax,dword [adjustment+4]
  965.         jz      got_label
  966.         or      [next_pass_needed],-1
  967.         jmp     got_label
  968.       label_defined:
  969.         mov     eax,[ebx]
  970.         stos    dword [edi]
  971.         mov     eax,[ebx+4]
  972.         stos    dword [edi]
  973.       got_label:
  974.         mov     al,[ebx+11]
  975.         mov     [edi-8+12],al
  976.         mov     eax,[ebx+12]
  977.         mov     [edi-8+8],eax
  978.         mov     eax,[ebx+20]
  979.         mov     [edi-8+16],eax
  980.         add     edi,0Ch
  981.         mov     al,[ebx+10]
  982.         or      al,al
  983.         jz      calculation_loop
  984.         cmp     [size_override],-1
  985.         je      calculation_loop
  986.         cmp     [size_override],0
  987.         je      check_size
  988.         cmp     [operand_size],0
  989.         jne     calculation_loop
  990.         mov     [operand_size],al
  991.         jmp     calculation_loop
  992.       check_size:
  993.         xchg    [operand_size],al
  994.         or      al,al
  995.         jz      calculation_loop
  996.         cmp     al,[operand_size]
  997.         jne     operand_sizes_do_not_match
  998.         jmp     calculation_loop
  999.       current_offset_label:
  1000.         mov     al,[labels_type]
  1001.         mov     [edi+12],al
  1002.         mov     eax,[org_symbol]
  1003.         mov     [edi+16],eax
  1004.         mov     eax,[current_offset]
  1005.         xor     edx,edx
  1006.         sub     eax,dword [org_origin]
  1007.         sbb     edx,dword [org_origin+4]
  1008.         stos    dword [edi]
  1009.         mov     eax,edx
  1010.         stos    dword [edi]
  1011.         mov     eax,[org_registers]
  1012.         stos    dword [edi]
  1013.         add     edi,8
  1014.         jmp     calculation_loop
  1015.       org_origin_label:
  1016.         mov     al,[labels_type]
  1017.         mov     [edi+12],al
  1018.         mov     eax,[org_symbol]
  1019.         mov     [edi+16],eax
  1020.         mov     eax,[org_start]
  1021.         xor     edx,edx
  1022.         sub     eax,dword [org_origin]
  1023.         sbb     edx,dword [org_origin+4]
  1024.         stos    dword [edi]
  1025.         mov     eax,edx
  1026.         stos    dword [edi]
  1027.         mov     eax,[org_registers]
  1028.         stos    dword [edi]
  1029.         add     edi,8
  1030.         jmp     calculation_loop
  1031.       counter_label:
  1032.         mov     eax,[counter]
  1033.       make_dword_label_value:
  1034.         stos    dword [edi]
  1035.         xor     eax,eax
  1036.         stos    dword [edi]
  1037.         add     edi,0Ch
  1038.         jmp     calculation_loop
  1039.       timestamp_label:
  1040.         call    make_timestamp
  1041.         jmp     make_dword_label_value
  1042.       predefined_label:
  1043.         or      eax,eax
  1044.         jz      current_offset_label
  1045.         cmp     eax,1
  1046.         je      counter_label
  1047.         cmp     eax,2
  1048.         je      timestamp_label
  1049.         cmp     eax,3
  1050.         je      org_origin_label
  1051.       label_undefined:
  1052.         cmp     [current_pass],1
  1053.         jbe     force_next_pass
  1054.         cmp     [error_line],0
  1055.         jne     undefined_value
  1056.         mov     eax,[current_line]
  1057.         mov     [error_line],eax
  1058.         mov     [error],undefined_symbol
  1059.         jmp     undefined_value
  1060.       force_next_pass:
  1061.         or      [next_pass_needed],-1
  1062.       undefined_value:
  1063.         mov     byte [edi+12],0
  1064.         or      [value_undefined],-1
  1065.         xor     eax,eax
  1066.         stos    dword [edi]
  1067.         stos    dword [edi]
  1068.         add     edi,0Ch
  1069.         jmp     calculation_loop
  1070.       calculate_add:
  1071.         mov     ecx,[ebx+16]
  1072.         cmp     byte [edi+12],0
  1073.         je      add_values
  1074.         mov     ecx,[edi+16]
  1075.         cmp     byte [ebx+12],0
  1076.         je      add_values
  1077.         cmp     [error_line],0
  1078.         jne     add_values
  1079.         mov     eax,[current_line]
  1080.         mov     [error_line],eax
  1081.         mov     [error],invalid_use_of_symbol
  1082.       add_values:
  1083.         mov     al,[edi+12]
  1084.         or      [ebx+12],al
  1085.         mov     [ebx+16],ecx
  1086.         mov     eax,[edi]
  1087.         add     [ebx],eax
  1088.         mov     eax,[edi+4]
  1089.         adc     [ebx+4],eax
  1090.         or      dx,dx
  1091.         jz      calculation_loop
  1092.         push    esi
  1093.         mov     esi,ebx
  1094.         lea     ebx,[edi+10]
  1095.         mov     cl,[edi+8]
  1096.         call    add_register
  1097.         lea     ebx,[edi+11]
  1098.         mov     cl,[edi+9]
  1099.         call    add_register
  1100.         pop     esi
  1101.         jmp     calculation_loop
  1102.       add_register:
  1103.         or      cl,cl
  1104.         jz      add_register_done
  1105.       add_register_start:
  1106.         cmp     [esi+8],cl
  1107.         jne     add_in_second_slot
  1108.         mov     al,[ebx]
  1109.         add     [esi+10],al
  1110.         jnz     add_register_done
  1111.         mov     byte [esi+8],0
  1112.         ret
  1113.       add_in_second_slot:
  1114.         cmp     [esi+9],cl
  1115.         jne     create_in_first_slot
  1116.         mov     al,[ebx]
  1117.         add     [esi+11],al
  1118.         jnz     add_register_done
  1119.         mov     byte [esi+9],0
  1120.         ret
  1121.       create_in_first_slot:
  1122.         cmp     byte [esi+8],0
  1123.         jne     create_in_second_slot
  1124.         mov     [esi+8],cl
  1125.         mov     al,[ebx]
  1126.         mov     [esi+10],al
  1127.         ret
  1128.       create_in_second_slot:
  1129.         cmp     byte [esi+9],0
  1130.         jne     invalid_expression
  1131.         mov     [esi+9],cl
  1132.         mov     al,[ebx]
  1133.         mov     [esi+11],al
  1134.       add_register_done:
  1135.         ret
  1136.       calculate_sub:
  1137.         xor     ah,ah
  1138.         mov     ah,[ebx+12]
  1139.         mov     al,[edi+12]
  1140.         or      al,al
  1141.         jz      sub_values
  1142.         cmp     al,ah
  1143.         jne     invalid_sub
  1144.         xor     ah,ah
  1145.         mov     ecx,[edi+16]
  1146.         cmp     ecx,[ebx+16]
  1147.         je      sub_values
  1148.         cmp     ecx,[org_symbol]
  1149.         jne     invalid_sub
  1150.         test    byte [ebx+12],1
  1151.         jnz     invalid_sub
  1152.         mov     ah,3
  1153.       sub_values:
  1154.         mov     [ebx+12],ah
  1155.         mov     eax,[edi]
  1156.         sub     [ebx],eax
  1157.         mov     eax,[edi+4]
  1158.         sbb     [ebx+4],eax
  1159.         or      dx,dx
  1160.         jz      calculation_loop
  1161.         push    esi
  1162.         mov     esi,ebx
  1163.         lea     ebx,[edi+10]
  1164.         mov     cl,[edi+8]
  1165.         call    sub_register
  1166.         lea     ebx,[edi+11]
  1167.         mov     cl,[edi+9]
  1168.         call    sub_register
  1169.         pop     esi
  1170.         jmp     calculation_loop
  1171.       invalid_sub:
  1172.         cmp     [error_line],0
  1173.         jne     sub_values
  1174.         mov     eax,[current_line]
  1175.         mov     [error_line],eax
  1176.         mov     [error],invalid_use_of_symbol
  1177.         jmp     sub_values
  1178.       sub_register:
  1179.         or      cl,cl
  1180.         jz      add_register_done
  1181.         neg     byte [ebx]
  1182.         jmp     add_register_start
  1183.       calculate_mul:
  1184.         or      dx,dx
  1185.         jz      mul_start
  1186.         cmp     word [ebx+8],0
  1187.         jne     mul_start
  1188.         mov     eax,[ebx]
  1189.         xchg    eax,[edi]
  1190.         mov     [ebx],eax
  1191.         mov     eax,[ebx+4]
  1192.         xchg    eax,[edi+4]
  1193.         mov     [ebx+4],eax
  1194.         mov     eax,[ebx+8]
  1195.         xchg    eax,[edi+8]
  1196.         mov     [ebx+8],eax
  1197.         mov     eax,[ebx+12]
  1198.         xchg    eax,[edi+12]
  1199.         mov     [ebx+12],eax
  1200.       mul_start:
  1201.         push    esi edx
  1202.         mov     esi,ebx
  1203.         xor     bl,bl
  1204.         bt      dword [esi+4],31
  1205.         jnc     mul_first_sign_ok
  1206.         not     dword [esi]
  1207.         not     dword [esi+4]
  1208.         add     dword [esi],1
  1209.         adc     dword [esi+4],0
  1210.         not     bl
  1211.       mul_first_sign_ok:
  1212.         bt      dword [edi+4],31
  1213.         jnc     mul_second_sign_ok
  1214.         not     dword [edi]
  1215.         not     dword [edi+4]
  1216.         add     dword [edi],1
  1217.         adc     dword [edi+4],0
  1218.         not     bl
  1219.       mul_second_sign_ok:
  1220.         cmp     dword [esi+4],0
  1221.         jz      mul_numbers
  1222.         cmp     dword [edi+4],0
  1223.         jnz     value_out_of_range
  1224.       mul_numbers:
  1225.         mov     eax,[esi+4]
  1226.         mul     dword [edi]
  1227.         or      edx,edx
  1228.         jnz     value_out_of_range
  1229.         mov     ecx,eax
  1230.         mov     eax,[esi]
  1231.         mul     dword [edi+4]
  1232.         or      edx,edx
  1233.         jnz     value_out_of_range
  1234.         add     ecx,eax
  1235.         jc      value_out_of_range
  1236.         mov     eax,[esi]
  1237.         mul     dword [edi]
  1238.         add     edx,ecx
  1239.         jc      value_out_of_range
  1240.         test    edx,1 shl 31
  1241.         jnz     value_out_of_range
  1242.         mov     [esi],eax
  1243.         mov     [esi+4],edx
  1244.         or      bl,bl
  1245.         jz      mul_ok
  1246.         not     dword [esi]
  1247.         not     dword [esi+4]
  1248.         add     dword [esi],1
  1249.         adc     dword [esi+4],0
  1250.       mul_ok:
  1251.         pop     edx
  1252.         or      dx,dx
  1253.         jz      mul_calculated
  1254.         cmp     word [edi+8],0
  1255.         jne     invalid_value
  1256.         cmp     byte [esi+8],0
  1257.         je      mul_first_register_ok
  1258.         mov     al,[edi]
  1259.         cbw
  1260.         cwde
  1261.         cdq
  1262.         cmp     edx,[edi+4]
  1263.         jne     value_out_of_range
  1264.         cmp     eax,[edi]
  1265.         jne     value_out_of_range
  1266.         imul    byte [esi+10]
  1267.         mov     dl,ah
  1268.         cbw
  1269.         cmp     ah,dl
  1270.         jne     value_out_of_range
  1271.         mov     [esi+10],al
  1272.       mul_first_register_ok:
  1273.         cmp     byte [esi+9],0
  1274.         je      mul_calculated
  1275.         mov     al,[edi]
  1276.         cbw
  1277.         cwde
  1278.         cdq
  1279.         cmp     edx,[edi+4]
  1280.         jne     value_out_of_range
  1281.         cmp     eax,[edi]
  1282.         jne     value_out_of_range
  1283.         imul    byte [esi+11]
  1284.         mov     dl,ah
  1285.         cbw
  1286.         cmp     ah,dl
  1287.         jne     value_out_of_range
  1288.         mov     [esi+11],al
  1289.       mul_calculated:
  1290.         pop     esi
  1291.         jmp     calculation_loop
  1292.       calculate_div:
  1293.         push    esi edx
  1294.         mov     esi,ebx
  1295.         call    div_64
  1296.         pop     edx
  1297.         or      dx,dx
  1298.         jz      div_calculated
  1299.         cmp     byte [esi+8],0
  1300.         je      div_first_register_ok
  1301.         mov     al,[edi]
  1302.         cbw
  1303.         cwde
  1304.         cdq
  1305.         cmp     edx,[edi+4]
  1306.         jne     value_out_of_range
  1307.         cmp     eax,[edi]
  1308.         jne     value_out_of_range
  1309.         or      al,al
  1310.         jz      value_out_of_range
  1311.         mov     al,[esi+10]
  1312.         cbw
  1313.         idiv    byte [edi]
  1314.         mov     [esi+10],al
  1315.       div_first_register_ok:
  1316.         cmp     byte [esi+9],0
  1317.         je      div_calculated
  1318.         mov     al,[edi]
  1319.         cbw
  1320.         cwde
  1321.         cdq
  1322.         cmp     edx,[edi+4]
  1323.         jne     value_out_of_range
  1324.         cmp     eax,[edi]
  1325.         jne     value_out_of_range
  1326.         or      al,al
  1327.         jz      value_out_of_range
  1328.         mov     al,[esi+11]
  1329.         cbw
  1330.         idiv    byte [edi]
  1331.         mov     [esi+11],al
  1332.       div_calculated:
  1333.         pop     esi
  1334.         jmp     calculation_loop
  1335.       calculate_mod:
  1336.         push    esi
  1337.         mov     esi,ebx
  1338.         call    div_64
  1339.         mov     [esi],eax
  1340.         mov     [esi+4],edx
  1341.         pop     esi
  1342.         jmp     calculation_loop
  1343.       calculate_and:
  1344.         mov     eax,[edi]
  1345.         and     [ebx],eax
  1346.         mov     eax,[edi+4]
  1347.         and     [ebx+4],eax
  1348.         jmp     calculation_loop
  1349.       calculate_or:
  1350.         mov     eax,[edi]
  1351.         or      [ebx],eax
  1352.         mov     eax,[edi+4]
  1353.         or      [ebx+4],eax
  1354.         jmp     calculation_loop
  1355.       calculate_xor:
  1356.         mov     eax,[edi]
  1357.         xor     [ebx],eax
  1358.         mov     eax,[edi+4]
  1359.         xor     [ebx+4],eax
  1360.         jmp     calculation_loop
  1361.       shr_negative:
  1362.         not     dword [edi]
  1363.         not     dword [edi+4]
  1364.         add     dword [edi],1
  1365.         adc     dword [edi+4],0
  1366.       calculate_shl:
  1367.         mov     eax,dword [edi+4]
  1368.         bt      eax,31
  1369.         jc      shl_negative
  1370.         or      eax,eax
  1371.         jnz     zero_value
  1372.         mov     ecx,[edi]
  1373.         cmp     ecx,64
  1374.         jae     zero_value
  1375.         cmp     ecx,32
  1376.         jae     shl_high
  1377.         mov     edx,[ebx+4]
  1378.         mov     eax,[ebx]
  1379.         shld    edx,eax,cl
  1380.         shl     eax,cl
  1381.         mov     [ebx],eax
  1382.         mov     [ebx+4],edx
  1383.         jmp     calculation_loop
  1384.       shl_high:
  1385.         sub     cl,32
  1386.         mov     eax,[ebx]
  1387.         shl     eax,cl
  1388.         mov     [ebx+4],eax
  1389.         mov     dword [ebx],0
  1390.         jmp     calculation_loop
  1391.       shl_negative:
  1392.         not     dword [edi]
  1393.         not     dword [edi+4]
  1394.         add     dword [edi],1
  1395.         adc     dword [edi+4],0
  1396.       calculate_shr:
  1397.         mov     eax,dword [edi+4]
  1398.         bt      eax,31
  1399.         jc      shr_negative
  1400.         or      eax,eax
  1401.         jnz     zero_value
  1402.         mov     ecx,[edi]
  1403.         cmp     ecx,64
  1404.         jae     zero_value
  1405.         cmp     ecx,32
  1406.         jae     shr_high
  1407.         mov     edx,[ebx+4]
  1408.         mov     eax,[ebx]
  1409.         shrd    eax,edx,cl
  1410.         shr     edx,cl
  1411.         mov     [ebx],eax
  1412.         mov     [ebx+4],edx
  1413.         jmp     calculation_loop
  1414.       shr_high:
  1415.         sub     cl,32
  1416.         mov     eax,[ebx+4]
  1417.         shr     eax,cl
  1418.         mov     [ebx],eax
  1419.         mov     dword [ebx+4],0
  1420.         jmp     calculation_loop
  1421.       zero_value:
  1422.         mov     dword [ebx],0
  1423.         mov     dword [ebx+4],0
  1424.         jmp     calculation_loop
  1425.       calculate_not:
  1426.         cmp     word [edi+8],0
  1427.         jne     invalid_expression
  1428.         cmp     byte [edi+12],0
  1429.         je      not_ok
  1430.         cmp     [error_line],0
  1431.         jne     not_ok
  1432.         mov     eax,[current_line]
  1433.         mov     [error_line],eax
  1434.         mov     [error],invalid_use_of_symbol
  1435.       not_ok:
  1436.         cmp     [value_size],1
  1437.         je      not_byte
  1438.         cmp     [value_size],2
  1439.         je      not_word
  1440.         cmp     [value_size],4
  1441.         je      not_dword
  1442.         cmp     [value_size],6
  1443.         je      not_pword
  1444.       not_qword:
  1445.         not     dword [edi]
  1446.         not     dword [edi+4]
  1447.         add     edi,14h
  1448.         jmp     calculation_loop
  1449.       not_byte:
  1450.         cmp     dword [edi+4],0
  1451.         jne     not_qword
  1452.         cmp     word [edi+2],0
  1453.         jne     not_qword
  1454.         cmp     byte [edi+1],0
  1455.         jne     not_qword
  1456.         not     byte [edi]
  1457.         add     edi,14h
  1458.         jmp     calculation_loop
  1459.       not_word:
  1460.         cmp     dword [edi+4],0
  1461.         jne     not_qword
  1462.         cmp     word [edi+2],0
  1463.         jne     not_qword
  1464.         not     word [edi]
  1465.         add     edi,14h
  1466.         jmp     calculation_loop
  1467.       not_dword:
  1468.         cmp     dword [edi+4],0
  1469.         jne     not_qword
  1470.         not     dword [edi]
  1471.         add     edi,14h
  1472.         jmp     calculation_loop
  1473.       not_pword:
  1474.         cmp     word [edi+6],0
  1475.         jne     not_qword
  1476.         not     dword [edi]
  1477.         not     word [edi+4]
  1478.         add     edi,14h
  1479.         jmp     calculation_loop
  1480.       calculate_neg:
  1481.         cmp     word [edi+8],0
  1482.         jne     invalid_expression
  1483.         cmp     byte [edi+12],0
  1484.         je      neg_ok
  1485.         cmp     [error_line],0
  1486.         jne     neg_ok
  1487.         mov     eax,[current_line]
  1488.         mov     [error_line],eax
  1489.         mov     [error],invalid_use_of_symbol
  1490.       neg_ok:
  1491.         mov     eax,[edi]
  1492.         mov     edx,[edi+4]
  1493.         mov     dword [edi],0
  1494.         mov     dword [edi+4],0
  1495.         sub     [edi],eax
  1496.         sbb     [edi+4],edx
  1497.         add     edi,14h
  1498.         jmp     calculation_loop
  1499.       calculate_rva:
  1500.         cmp     [output_format],3
  1501.         jne     invalid_expression
  1502.         cmp     word [edi+8],0
  1503.         jne     invalid_expression
  1504.         test    [format_flags],8
  1505.         jnz     pe64_rva
  1506.         cmp     byte [edi+12],2
  1507.         je      rva_ok
  1508.         cmp     [error_line],0
  1509.         jne     rva_ok
  1510.         mov     eax,[current_line]
  1511.         mov     [error_line],eax
  1512.         mov     [error],invalid_use_of_symbol
  1513.       rva_ok:
  1514.         mov     byte [edi+12],0
  1515.         mov     eax,[code_start]
  1516.         mov     eax,[eax+34h]
  1517.         cdq
  1518.         sub     [edi],eax
  1519.         sbb     [edi+4],edx
  1520.         add     edi,14h
  1521.         jmp     calculation_loop
  1522.       pe64_rva:
  1523.         cmp     byte [edi+12],4
  1524.         je      pe64_rva_ok
  1525.         cmp     [error_line],0
  1526.         jne     pe64_rva_ok
  1527.         mov     eax,[current_line]
  1528.         mov     [error_line],eax
  1529.         mov     [error],invalid_use_of_symbol
  1530.       pe64_rva_ok:
  1531.         mov     byte [edi+12],0
  1532.         mov     eax,[code_start]
  1533.         mov     edx,[eax+34h]
  1534.         mov     eax,[eax+30h]
  1535.         sub     [edi],eax
  1536.         sbb     [edi+4],edx
  1537.         add     edi,14h
  1538.         jmp     calculation_loop
  1539.       div_64:
  1540.         xor     ebx,ebx
  1541.         cmp     dword [edi],0
  1542.         jne     divider_ok
  1543.         cmp     dword [edi+4],0
  1544.         jne     divider_ok
  1545.         cmp     [next_pass_needed],0
  1546.         je      value_out_of_range
  1547.         jmp     div_done
  1548.       divider_ok:
  1549.         bt      dword [esi+4],31
  1550.         jnc     div_first_sign_ok
  1551.         not     dword [esi]
  1552.         not     dword [esi+4]
  1553.         add     dword [esi],1
  1554.         adc     dword [esi+4],0
  1555.         not     bx
  1556.       div_first_sign_ok:
  1557.         bt      dword [edi+4],31
  1558.         jnc     div_second_sign_ok
  1559.         not     dword [edi]
  1560.         not     dword [edi+4]
  1561.         add     dword [edi],1
  1562.         adc     dword [edi+4],0
  1563.         not     bl
  1564.       div_second_sign_ok:
  1565.         cmp     dword [edi+4],0
  1566.         jne     div_high
  1567.         mov     ecx,[edi]
  1568.         mov     eax,[esi+4]
  1569.         xor     edx,edx
  1570.         div     ecx
  1571.         mov     [esi+4],eax
  1572.         mov     eax,[esi]
  1573.         div     ecx
  1574.         mov     [esi],eax
  1575.         mov     eax,edx
  1576.         xor     edx,edx
  1577.         jmp     div_done
  1578.       div_high:
  1579.         mov     eax,[esi+4]
  1580.         xor     edx,edx
  1581.         div     dword [edi+4]
  1582.         mov     ebx,[esi]
  1583.         mov     [esi],eax
  1584.         mov     dword [esi+4],0
  1585.         mov     ecx,edx
  1586.         mul     dword [edi]
  1587.       div_high_loop:
  1588.         cmp     ecx,edx
  1589.         ja      div_high_done
  1590.         jb      div_high_large_correction
  1591.         cmp     ebx,eax
  1592.         jae     div_high_done
  1593.       div_high_correction:
  1594.         dec     dword [esi]
  1595.         sub     eax,[edi]
  1596.         sbb     edx,[edi+4]
  1597.         jnc     div_high_loop
  1598.       div_high_done:
  1599.         sub     ebx,eax
  1600.         sbb     ecx,edx
  1601.         mov     edx,ecx
  1602.         mov     eax,ebx
  1603.         ret
  1604.       div_high_large_correction:
  1605.         push    eax edx
  1606.         mov     eax,edx
  1607.         sub     eax,ecx
  1608.         xor     edx,edx
  1609.         div     dword [edi+4]
  1610.         shr     eax,1
  1611.         jz      div_high_small_correction
  1612.         sub     [esi],eax
  1613.         push    eax
  1614.         mul     dword [edi+4]
  1615.         sub     dword [esp+4],eax
  1616.         pop     eax
  1617.         mul     dword [edi]
  1618.         sub     dword [esp+4],eax
  1619.         sbb     dword [esp],edx
  1620.         pop     edx eax
  1621.         jmp     div_high_loop
  1622.       div_high_small_correction:
  1623.         pop     edx eax
  1624.         jmp     div_high_correction
  1625.       div_done:
  1626.         or      bh,bh
  1627.         jz      remainder_ok
  1628.         not     eax
  1629.         not     edx
  1630.         add     eax,1
  1631.         adc     edx,0
  1632.       remainder_ok:
  1633.         or      bl,bl
  1634.         jz      div_ok
  1635.         not     dword [esi]
  1636.         not     dword [esi+4]
  1637.         add     dword [esi],1
  1638.         adc     dword [esi+4],0
  1639.       div_ok:
  1640.         ret
  1641.       convert_fp:
  1642.         mov     word [edi+8],0
  1643.         mov     byte [edi+12],0
  1644.         mov     al,[value_size]
  1645.         cmp     al,4
  1646.         je      convert_fp_dword
  1647.         cmp     al,8
  1648.         je      convert_fp_qword
  1649.         jmp     invalid_value
  1650.       convert_fp_dword:
  1651.         xor     eax,eax
  1652.         cmp     word [esi+8],8000h
  1653.         je      fp_dword_store
  1654.         mov     bx,[esi+8]
  1655.         mov     eax,[esi+4]
  1656.         shl     eax,1
  1657.         shr     eax,9
  1658.         jnc     fp_dword_ok
  1659.         inc     eax
  1660.         bt      eax,23
  1661.         jnc     fp_dword_ok
  1662.         and     eax,1 shl 23 - 1
  1663.         inc     bx
  1664.         shr     eax,1
  1665.       fp_dword_ok:
  1666.         add     bx,7Fh
  1667.         cmp     bx,100h
  1668.         jae     value_out_of_range
  1669.         shl     ebx,23
  1670.         or      eax,ebx
  1671.       fp_dword_store:
  1672.         mov     bl,[esi+11]
  1673.         shl     ebx,31
  1674.         or      eax,ebx
  1675.         mov     [edi],eax
  1676.         xor     eax,eax
  1677.         mov     [edi+4],eax
  1678.         add     esi,13
  1679.         ret
  1680.       convert_fp_qword:
  1681.         xor     eax,eax
  1682.         xor     edx,edx
  1683.         cmp     word [esi+8],8000h
  1684.         je      fp_qword_store
  1685.         mov     bx,[esi+8]
  1686.         mov     eax,[esi]
  1687.         mov     edx,[esi+4]
  1688.         add     eax,eax
  1689.         adc     edx,edx
  1690.         mov     ecx,edx
  1691.         shr     edx,12
  1692.         shrd    eax,ecx,12
  1693.         jnc     fp_qword_ok
  1694.         add     eax,1
  1695.         adc     edx,0
  1696.         bt      edx,20
  1697.         jnc     fp_qword_ok
  1698.         and     edx,1 shl 20 - 1
  1699.         inc     bx
  1700.         shr     edx,1
  1701.         rcr     eax,1
  1702.       fp_qword_ok:
  1703.         add     bx,3FFh
  1704.         cmp     bx,800h
  1705.         jae     value_out_of_range
  1706.         shl     ebx,20
  1707.         or      edx,ebx
  1708.       fp_qword_store:
  1709.         mov     bl,[esi+11]
  1710.         shl     ebx,31
  1711.         or      edx,ebx
  1712.         mov     [edi],eax
  1713.         mov     [edi+4],edx
  1714.         add     esi,13
  1715.         ret
  1716.       get_string_value:
  1717.         lods    dword [esi]
  1718.         mov     ecx,eax
  1719.         cmp     ecx,8
  1720.         ja      value_out_of_range
  1721.         mov     edx,edi
  1722.         xor     eax,eax
  1723.         stos    dword [edi]
  1724.         stos    dword [edi]
  1725.         mov     edi,edx
  1726.         rep     movs byte [edi],[esi]
  1727.         mov     edi,edx
  1728.         inc     esi
  1729.         mov     word [edi+8],0
  1730.         mov     byte [edi+12],0
  1731.         ret
  1732.  
  1733. get_byte_value:
  1734.         mov     [value_size],1
  1735.         mov     [size_override],-1
  1736.         call    calculate_expression
  1737.         mov     eax,[edi+16]
  1738.         mov     [symbol_identifier],eax
  1739.         mov     [value_type],0
  1740.         cmp     word [edi+8],0
  1741.         jne     invalid_value
  1742.         cmp     byte [edi+12],0
  1743.         je      check_byte_value
  1744.         cmp     [error_line],0
  1745.         jne     check_byte_value
  1746.         mov     eax,[current_line]
  1747.         mov     [error_line],eax
  1748.         mov     [error],invalid_use_of_symbol
  1749.       check_byte_value:
  1750.         mov     eax,[edi]
  1751.         mov     edx,[edi+4]
  1752.         or      edx,edx
  1753.         jz      byte_positive
  1754.         cmp     edx,-1
  1755.         jne     range_exceeded
  1756.         cmp     eax,-80h
  1757.         jb      range_exceeded
  1758.         ret
  1759.       byte_positive:
  1760.         cmp     eax,100h
  1761.         jae     range_exceeded
  1762.       return_byte_value:
  1763.         ret
  1764.       range_exceeded:
  1765.         xor     eax,eax
  1766.         xor     edx,edx
  1767.         cmp     [error_line],0
  1768.         jne     return_byte_value
  1769.         mov     ecx,[current_line]
  1770.         mov     [error_line],ecx
  1771.         mov     [error],value_out_of_range
  1772.         ret
  1773. get_word_value:
  1774.         mov     [value_size],2
  1775.         mov     [size_override],-1
  1776.         call    calculate_expression
  1777.         mov     eax,[edi+16]
  1778.         mov     [symbol_identifier],eax
  1779.         cmp     word [edi+8],0
  1780.         jne     invalid_value
  1781.         mov     al,[edi+12]
  1782.         mov     [value_type],al
  1783.         cmp     al,2
  1784.         jb      check_word_value
  1785.         cmp     [error_line],0
  1786.         jne     check_word_value
  1787.         mov     eax,[current_line]
  1788.         mov     [error_line],eax
  1789.         mov     [error],invalid_use_of_symbol
  1790.       check_word_value:
  1791.         mov     eax,[edi]
  1792.         mov     edx,[edi+4]
  1793.         or      edx,edx
  1794.         jz      word_positive
  1795.         cmp     edx,-1
  1796.         jne     range_exceeded
  1797.         cmp     eax,-8000h
  1798.         jb      range_exceeded
  1799.         ret
  1800.       word_positive:
  1801.         cmp     eax,10000h
  1802.         jae     range_exceeded
  1803.         ret
  1804. get_dword_value:
  1805.         mov     [value_size],4
  1806.         mov     [size_override],-1
  1807.         call    calculate_expression
  1808.         mov     eax,[edi+16]
  1809.         mov     [symbol_identifier],eax
  1810.         cmp     word [edi+8],0
  1811.         jne     invalid_value
  1812.         mov     al,[edi+12]
  1813.         mov     [value_type],al
  1814.         cmp     al,4
  1815.         jb      check_dword_value
  1816.         cmp     [error_line],0
  1817.         jne     check_dword_value
  1818.         mov     eax,[current_line]
  1819.         mov     [error_line],eax
  1820.         mov     [error],invalid_use_of_symbol
  1821.       check_dword_value:
  1822.         mov     eax,[edi]
  1823.         mov     edx,[edi+4]
  1824.         or      edx,edx
  1825.         jz      dword_positive
  1826.         cmp     edx,-1
  1827.         jne     range_exceeded
  1828.         bt      eax,31
  1829.         jnc     range_exceeded
  1830.       dword_positive:
  1831.         ret
  1832. get_pword_value:
  1833.         mov     [value_size],6
  1834.         mov     [size_override],-1
  1835.         call    calculate_expression
  1836.         mov     eax,[edi+16]
  1837.         mov     [symbol_identifier],eax
  1838.         cmp     word [edi+8],0
  1839.         jne     invalid_value
  1840.         mov     al,[edi+12]
  1841.         mov     [value_type],al
  1842.         cmp     al,4
  1843.         jb      check_pword_value
  1844.         cmp     [error_line],0
  1845.         jne     check_pword_value
  1846.         mov     eax,[current_line]
  1847.         mov     [error_line],eax
  1848.         mov     [error],invalid_use_of_symbol
  1849.       check_pword_value:
  1850.         mov     eax,[edi]
  1851.         mov     edx,[edi+4]
  1852.         cmp     edx,10000h
  1853.         jge     range_exceeded
  1854.         cmp     edx,-8000h
  1855.         jl      range_exceeded
  1856.         ret
  1857. get_qword_value:
  1858.         mov     [value_size],8
  1859.         mov     [size_override],-1
  1860.         call    calculate_expression
  1861.         mov     eax,[edi+16]
  1862.         mov     [symbol_identifier],eax
  1863.         cmp     word [edi+8],0
  1864.         jne     invalid_value
  1865.         mov     al,[edi+12]
  1866.         mov     [value_type],al
  1867.       check_qword_value:
  1868.         mov     eax,[edi]
  1869.         mov     edx,[edi+4]
  1870.         ret
  1871. get_value:
  1872.         mov     [operand_size],0
  1873.         lods    byte [esi]
  1874.         call    get_size_operator
  1875.         cmp     al,'('
  1876.         jne     invalid_value
  1877.         mov     al,[operand_size]
  1878.         cmp     al,1
  1879.         je      value_byte
  1880.         cmp     al,2
  1881.         je      value_word
  1882.         cmp     al,4
  1883.         je      value_dword
  1884.         cmp     al,6
  1885.         je      value_pword
  1886.         cmp     al,8
  1887.         je      value_qword
  1888.         or      al,al
  1889.         jnz     invalid_value
  1890.       value_qword:
  1891.         call    get_qword_value
  1892.         ret
  1893.       value_pword:
  1894.         call    get_pword_value
  1895.         movzx   edx,dx
  1896.         ret
  1897.       value_dword:
  1898.         call    get_dword_value
  1899.         xor     edx,edx
  1900.         ret
  1901.       value_word:
  1902.         call    get_word_value
  1903.         xor     edx,edx
  1904.         movzx   eax,ax
  1905.         ret
  1906.       value_byte:
  1907.         call    get_byte_value
  1908.         xor     edx,edx
  1909.         movzx   eax,al
  1910.         ret
  1911. get_address_value:
  1912.         mov     [address_size],0
  1913.         mov     [value_size],8
  1914.       calculate_address:
  1915.         cmp     byte [esi],'.'
  1916.         je      invalid_address
  1917.         call    calculate_expression
  1918.         mov     eax,[edi+16]
  1919.         mov     [address_symbol],eax
  1920.         mov     al,[edi+12]
  1921.         test    al,1
  1922.         jnz     invalid_use_of_symbol
  1923.         mov     [value_type],al
  1924.         or      al,al
  1925.         jz      address_symbol_ok
  1926.         shl     al,5
  1927.         mov     ah,[address_size]
  1928.         or      [address_size],al
  1929.         shr     al,4
  1930.         or      ah,ah
  1931.         jz      address_symbol_ok
  1932.         cmp     al,ah
  1933.         jne     address_sizes_do_not_agree
  1934.       address_symbol_ok:
  1935.         xor     bx,bx
  1936.         xor     cl,cl
  1937.         mov     ch,[address_size]
  1938.         cmp     word [edi+8],0
  1939.         je      check_immediate_address
  1940.         mov     al,[edi+8]
  1941.         mov     dl,[edi+10]
  1942.         call    get_address_register
  1943.         mov     al,[edi+9]
  1944.         mov     dl,[edi+11]
  1945.         call    get_address_register
  1946.         mov     ax,bx
  1947.         shr     ah,4
  1948.         shr     al,4
  1949.         or      bh,bh
  1950.         jz      check_address_registers
  1951.         or      bl,bl
  1952.         jz      check_address_registers
  1953.         cmp     al,ah
  1954.         jne     invalid_address
  1955.       check_address_registers:
  1956.         or      al,ah
  1957.         cmp     al,4
  1958.         je      sib_allowed
  1959.         cmp     al,8
  1960.         je      sib_allowed
  1961.         or      cl,cl
  1962.         jz      check_word_value
  1963.         cmp     cl,1
  1964.         je      check_word_value
  1965.         jmp     invalid_address
  1966.       get_address_register:
  1967.         or      al,al
  1968.         jz      address_register_ok
  1969.         cmp     dl,1
  1970.         jne     scaled_register
  1971.         or      bh,bh
  1972.         jnz     scaled_register
  1973.         mov     bh,al
  1974.       address_register_ok:
  1975.         ret
  1976.       scaled_register:
  1977.         or      bl,bl
  1978.         jnz     invalid_address
  1979.         mov     bl,al
  1980.         mov     cl,dl
  1981.         jmp     address_register_ok
  1982.       sib_allowed:
  1983.         or      bh,bh
  1984.         jnz     check_index_scale
  1985.         cmp     cl,2
  1986.         je      special_index_scale
  1987.         cmp     cl,3
  1988.         je      special_index_scale
  1989.         cmp     cl,5
  1990.         je      special_index_scale
  1991.         cmp     cl,9
  1992.         je      special_index_scale
  1993.       check_index_scale:
  1994.         or      cl,cl
  1995.         jz      address_registers_ok
  1996.         cmp     cl,1
  1997.         je      address_registers_ok
  1998.         cmp     cl,2
  1999.         je      address_registers_ok
  2000.         cmp     cl,4
  2001.         je      address_registers_ok
  2002.         cmp     cl,8
  2003.         je      address_registers_ok
  2004.         jmp     invalid_address
  2005.       special_index_scale:
  2006.         mov     bh,bl
  2007.         dec     cl
  2008.       address_registers_ok:
  2009.         jmp     check_dword_value
  2010.       check_immediate_address:
  2011.         cmp     [code_type],64
  2012.         jne     check_dword_value
  2013.         jmp     check_qword_value
  2014. get_relative_offset:
  2015.         mov     [value_size],4
  2016.         mov     [size_override],-1
  2017.         call    calculate_expression
  2018.       calculate_relative_offset:
  2019.         push    esi
  2020.         add     edi,14h
  2021.         mov     esi,[display_buffer]
  2022.         sub     esi,7
  2023.         lea     eax,[esi-14h]
  2024.         cmp     eax,edi
  2025.         jb      out_of_memory
  2026.         mov     byte [esi],11h
  2027.         xor     eax,eax
  2028.         mov     dword [esi+1],eax
  2029.         mov     word [esi+5],')' shl 8 + 81h
  2030.         call    calculation_loop
  2031.         pop     esi
  2032.         cmp     word [edi+8],0
  2033.         jne     invalid_value
  2034.         mov     al,[edi+12]
  2035.         mov     [value_type],al
  2036.         mov     eax,[edi+16]
  2037.         mov     [symbol_identifier],eax
  2038.         mov     eax,[edi]
  2039.         mov     edx,[edi+4]
  2040.         or      edx,edx
  2041.         jz      offset_positive
  2042.         cmp     edx,-1
  2043.         jne     range_exceeded
  2044.         bt      eax,31
  2045.         jnc     range_exceeded
  2046.         ret
  2047.       offset_positive:
  2048.         bt      eax,31
  2049.         jc      range_exceeded
  2050.         ret
  2051.  
  2052. calculate_logical_expression:
  2053.         call    get_logical_value
  2054.       logical_loop:
  2055.         cmp     byte [esi],'|'
  2056.         je      logical_or
  2057.         cmp     byte [esi],'&'
  2058.         je      logical_and
  2059.         ret
  2060.       logical_or:
  2061.         inc     esi
  2062.         push    eax
  2063.         call    get_logical_value
  2064.         pop     ebx
  2065.         or      al,bl
  2066.         jmp     logical_loop
  2067.       logical_and:
  2068.         inc     esi
  2069.         push    eax
  2070.         call    get_logical_value
  2071.         pop     ebx
  2072.         and     al,bl
  2073.         jmp     logical_loop
  2074.  
  2075. get_logical_value:
  2076.         xor     al,al
  2077.       check_for_negation:
  2078.         cmp     byte [esi],'~'
  2079.         jne     negation_ok
  2080.         inc     esi
  2081.         xor     al,-1
  2082.         jmp     check_for_negation
  2083.       negation_ok:
  2084.         push    eax
  2085.         mov     al,[esi]
  2086.         cmp     al,'{'
  2087.         je      logical_expression
  2088.         cmp     al,88h
  2089.         je      check_for_defined
  2090.         cmp     al,89h
  2091.         je      check_for_used
  2092.         push    esi
  2093.         cmp     al,11h
  2094.         jne     check_for_values
  2095.         add     esi,2
  2096.       check_for_values:
  2097.         xor     bl,bl
  2098.         cmp     byte [esi],'('
  2099.         jne     find_eq_symbol
  2100.         call    skip_symbol
  2101.         lods    byte [esi]
  2102.         cmp     al,'='
  2103.         je      compare_values
  2104.         cmp     al,'>'
  2105.         je      compare_values
  2106.         cmp     al,'<'
  2107.         je      compare_values
  2108.         cmp     al,0F1h
  2109.         je      compare_values
  2110.         cmp     al,0F2h
  2111.         je      compare_values
  2112.         cmp     al,0F3h
  2113.         je      compare_values
  2114.         dec     esi
  2115.       find_eq_symbol:
  2116.         cmp     byte [esi],0F0h
  2117.         je      compare_symbols
  2118.         cmp     byte [esi],0F7h
  2119.         je      compare_symbol_types
  2120.         cmp     byte [esi],0F6h
  2121.         je      scan_symbols_list
  2122.         call    check_character
  2123.         jc      logical_number
  2124.         cmp     al,','
  2125.         jne     next_eq_symbol
  2126.         mov     bl,1
  2127.       next_eq_symbol:
  2128.         call    skip_symbol
  2129.         jmp     find_eq_symbol
  2130.       compare_symbols:
  2131.         inc     esi
  2132.         pop     ebx
  2133.         mov     edx,esi
  2134.         push    edi
  2135.         mov     edi,ebx
  2136.         mov     ecx,esi
  2137.         dec     ecx
  2138.         sub     ecx,edi
  2139.         repe    cmps byte [esi],[edi]
  2140.         pop     edi
  2141.         je      symbols_equal
  2142.         mov     esi,edx
  2143.       symbols_different:
  2144.         call    check_character
  2145.         jc      return_false
  2146.         call    skip_symbol
  2147.         jmp     symbols_different
  2148.       symbols_equal:
  2149.         call    check_character
  2150.         jc      return_true
  2151.         jmp     symbols_different
  2152.       compare_symbol_types:
  2153.         inc     esi
  2154.         pop     ebx
  2155.       type_comparision:
  2156.         call    check_character
  2157.         jc      types_compared
  2158.         mov     al,[esi]
  2159.         cmp     al,[ebx]
  2160.         jne     symbols_different
  2161.         cmp     al,'('
  2162.         jne     equal_type
  2163.         mov     al,[esi+1]
  2164.         mov     ah,[ebx+1]
  2165.         cmp     al,ah
  2166.         je      equal_type
  2167.         or      al,al
  2168.         jz      symbols_different
  2169.         or      ah,ah
  2170.         jz      symbols_different
  2171.         cmp     al,'.'
  2172.         je      symbols_different
  2173.         cmp     ah,'.'
  2174.         je      symbols_different
  2175.       equal_type:
  2176.         call    skip_symbol
  2177.         xchg    esi,ebx
  2178.         call    skip_symbol
  2179.         xchg    esi,ebx
  2180.         jmp     type_comparision
  2181.       types_compared:
  2182.         cmp     byte [ebx],0F7h
  2183.         jne     return_false
  2184.         jmp     return_true
  2185.       scan_symbols_list:
  2186.         or      bl,bl
  2187.         jnz     invalid_expression
  2188.         xor     bp,bp
  2189.         inc     esi
  2190.         lods    byte [esi]
  2191.         cmp     al,'<'
  2192.         jne     invalid_expression
  2193.         pop     ebx
  2194.         mov     ecx,esi
  2195.         sub     ecx,2
  2196.         sub     ecx,ebx
  2197.       compare_in_list:
  2198.         mov     edx,esi
  2199.         push    ecx edi
  2200.         mov     edi,ebx
  2201.         repe    cmps byte [esi],[edi]
  2202.         pop     edi ecx
  2203.         jne     not_equal_in_list
  2204.         cmp     byte [esi],','
  2205.         je      skip_rest_of_list
  2206.         cmp     byte [esi],'>'
  2207.         jne     not_equal_in_list
  2208.       skip_rest_of_list:
  2209.         mov     al,[esi]
  2210.         or      al,al
  2211.         jz      invalid_expression
  2212.         cmp     al,0Fh
  2213.         je      invalid_expression
  2214.         cmp     al,'>'
  2215.         je      list_return_true
  2216.         call    skip_symbol
  2217.         jmp     skip_rest_of_list
  2218.       list_return_true:
  2219.         inc     esi
  2220.         jmp     return_true
  2221.       not_equal_in_list:
  2222.         mov     esi,edx
  2223.       skip_list_item:
  2224.         mov     al,[esi]
  2225.         or      al,al
  2226.         jz      invalid_expression
  2227.         cmp     al,0Fh
  2228.         je      invalid_expression
  2229.         cmp     al,'<'
  2230.         je      invalid_expression
  2231.         cmp     al,'>'
  2232.         je      list_return_false
  2233.         cmp     al,','
  2234.         je      next_in_list
  2235.         call    skip_symbol
  2236.         jmp     skip_list_item
  2237.       next_in_list:
  2238.         inc     esi
  2239.         jmp     compare_in_list
  2240.       list_return_false:
  2241.         inc     esi
  2242.         jmp     return_false
  2243.       check_character:
  2244.         mov     al,[esi]
  2245.         or      al,al
  2246.         jz      stop
  2247.         cmp     al,0Fh
  2248.         je      stop
  2249.         cmp     al,'}'
  2250.         je      stop
  2251.         cmp     al,'|'
  2252.         je      stop
  2253.         cmp     al,'&'
  2254.         je      stop
  2255.         clc
  2256.         ret
  2257.       stop:
  2258.         stc
  2259.         ret
  2260.       compare_values:
  2261.         pop     esi
  2262.         call    get_value
  2263.         mov     bl,[value_type]
  2264.         push    eax edx ebx
  2265.         lods    byte [esi]
  2266.         mov     [compare_type],al
  2267.         call    get_value
  2268.         pop     ebx
  2269.         cmp     [next_pass_needed],0
  2270.         jne     values_ok
  2271.         cmp     bl,[value_type]
  2272.         jne     invalid_use_of_symbol
  2273.       values_ok:
  2274.         pop     ecx ebx
  2275.         cmp     [compare_type],'='
  2276.         je      check_equal
  2277.         cmp     [compare_type],'>'
  2278.         je      check_greater
  2279.         cmp     [compare_type],'<'
  2280.         je      check_less
  2281.         cmp     [compare_type],0F1h
  2282.         je      check_not_equal
  2283.         cmp     [compare_type],0F2h
  2284.         je      check_not_less
  2285.         cmp     [compare_type],0F3h
  2286.         je      check_not_greater
  2287.         jmp     invalid_expression
  2288.       check_equal:
  2289.         cmp     eax,ebx
  2290.         jne     return_false
  2291.         cmp     edx,ecx
  2292.         jne     return_false
  2293.         jmp     return_true
  2294.       check_greater:
  2295.         cmp     edx,ecx
  2296.         jl      return_true
  2297.         jg      return_false
  2298.         cmp     eax,ebx
  2299.         jb      return_true
  2300.         jae     return_false
  2301.       check_less:
  2302.         cmp     edx,ecx
  2303.         jl      return_false
  2304.         jg      return_true
  2305.         cmp     eax,ebx
  2306.         jbe     return_false
  2307.         ja      return_true
  2308.       check_not_less:
  2309.         cmp     edx,ecx
  2310.         jl      return_true
  2311.         jg      return_false
  2312.         cmp     eax,ebx
  2313.         jbe     return_true
  2314.         ja      return_false
  2315.       check_not_greater:
  2316.         cmp     edx,ecx
  2317.         jl      return_false
  2318.         jg      return_true
  2319.         cmp     eax,ebx
  2320.         jb      return_false
  2321.         jae     return_true
  2322.       check_not_equal:
  2323.         cmp     eax,ebx
  2324.         jne     return_true
  2325.         cmp     edx,ecx
  2326.         jne     return_true
  2327.         jmp     return_false
  2328.       logical_number:
  2329.         pop     esi
  2330.         call    get_value
  2331.         cmp     [value_type],0
  2332.         jne     invalid_expression
  2333.         or      eax,edx
  2334.         jnz     return_true
  2335.         jmp     return_false
  2336.       check_for_defined:
  2337.         or      bl,-1
  2338.         lods    word [esi]
  2339.         cmp     ah,'('
  2340.         jne     invalid_expression
  2341.       check_expression:
  2342.         lods    byte [esi]
  2343.         or      al,al
  2344.         jz      defined_string
  2345.         cmp     al,'.'
  2346.         je      defined_fp_value
  2347.         cmp     al,')'
  2348.         je      expression_checked
  2349.         cmp     al,0Fh
  2350.         je      check_expression
  2351.         cmp     al,10h
  2352.         je      defined_register
  2353.         cmp     al,11h
  2354.         je      check_if_symbol_defined
  2355.         cmp     al,80h
  2356.         jae     check_expression
  2357.         movzx   eax,al
  2358.         add     esi,eax
  2359.         jmp     check_expression
  2360.       defined_register:
  2361.         inc     esi
  2362.         jmp     check_expression
  2363.       defined_fp_value:
  2364.         add     esi,12
  2365.         jmp     expression_checked
  2366.       defined_string:
  2367.         lods    dword [esi]
  2368.         add     esi,eax
  2369.         inc     esi
  2370.         jmp     expression_checked
  2371.       check_if_symbol_defined:
  2372.         lods    dword [esi]
  2373.         cmp     eax,-1
  2374.         je      invalid_expression
  2375.         cmp     eax,0Fh
  2376.         jb      check_expression
  2377.         je      reserved_word_used_as_symbol
  2378.         test    byte [eax+8],4
  2379.         jnz     no_prediction
  2380.         test    byte [eax+8],1
  2381.         jz      symbol_predicted_undefined
  2382.         mov     cx,[current_pass]
  2383.         sub     cx,[eax+16]
  2384.         jz      check_expression
  2385.         cmp     cx,1
  2386.         ja      symbol_predicted_undefined
  2387.         or      byte [eax+8],40h+80h
  2388.         jmp     check_expression
  2389.       no_prediction:
  2390.         test    byte [eax+8],1
  2391.         jz      symbol_undefined
  2392.         mov     cx,[current_pass]
  2393.         sub     cx,[eax+16]
  2394.         jz      check_expression
  2395.         jmp     symbol_undefined
  2396.       symbol_predicted_undefined:
  2397.         or      byte [eax+8],40h
  2398.         and     byte [eax+8],not 80h
  2399.       symbol_undefined:
  2400.         xor     bl,bl
  2401.         jmp     check_expression
  2402.       expression_checked:
  2403.         mov     al,bl
  2404.         jmp     logical_value_ok
  2405.       check_for_used:
  2406.         lods    word [esi]
  2407.         cmp     ah,2
  2408.         jne     invalid_expression
  2409.         lods    dword [esi]
  2410.         cmp     eax,0Fh
  2411.         jb      invalid_use_of_symbol
  2412.         je      reserved_word_used_as_symbol
  2413.         inc     esi
  2414.         test    byte [eax+8],8
  2415.         jz      not_used
  2416.         mov     cx,[current_pass]
  2417.         sub     cx,[eax+18]
  2418.         jz      return_true
  2419.         cmp     cx,1
  2420.         ja      not_used
  2421.         or      byte [eax+8],10h+20h
  2422.         jmp     return_true
  2423.       not_used:
  2424.         or      byte [eax+8],10h
  2425.         and     byte [eax+8],not 20h
  2426.       return_false:
  2427.         xor     al,al
  2428.         jmp     logical_value_ok
  2429.       return_true:
  2430.         or      al,-1
  2431.         jmp     logical_value_ok
  2432.       logical_expression:
  2433.         inc     esi
  2434.         call    calculate_logical_expression
  2435.         push    eax
  2436.         lods    byte [esi]
  2437.         cmp     al,'}'
  2438.         jne     invalid_expression
  2439.         pop     eax
  2440.       logical_value_ok:
  2441.         pop     ebx
  2442.         xor     al,bl
  2443.         ret
  2444.