Subversion Repositories Kolibri OS

Rev

Rev 1910 | Rev 2177 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. format MS COFF
  2. public EXPORTS
  3. section '.flat' code readable align 16
  4.  
  5. include '../../../../macros.inc'
  6. include '../../../../proc32.inc'
  7.  
  8. ;-----------------------------------------------------------------------------
  9. mem.alloc   dd ? ;функция для выделения памяти
  10. mem.free    dd ? ;функция для освобождения памяти
  11. mem.realloc dd ? ;функция для перераспределения памяти
  12. dll.load    dd ?
  13.  
  14. BUF_STRUCT_SIZE equ 21
  15. buf2d_data equ dword[edi] ;данные буфера изображения
  16. buf2d_w equ dword[edi+8] ;ширина буфера
  17. buf2d_h equ dword[edi+12] ;высота буфера
  18. buf2d_l equ word[edi+4]
  19. buf2d_t equ word[edi+6] ;отступ сверху
  20. buf2d_size_lt equ dword[edi+4] ;отступ слева и справа для буфера
  21. buf2d_color equ dword[edi+16] ;цвет фона буфера
  22. buf2d_bits equ byte[edi+20] ;количество бит в 1-й точке изображения
  23.  
  24. struct buf_2d_header
  25.         img_data dd ?
  26.         left dw ? ;+4 left
  27.         top dw ? ;+6 top
  28.         size_x dd ? ;+8 w
  29.         size_y dd ? ;+12 h
  30.         color dd ? ;+16 color
  31.         bit_pp db ? ;+21 bit in pixel
  32. ends
  33.  
  34. macro swap v1, v2 {
  35.   push v1
  36.   push v2
  37.   pop v1
  38.   pop v2
  39. }
  40.  
  41. ;флаги, для функции обрезания буфера
  42. BUF2D_OPT_CROP_TOP equ 1 ;обрезка сверху
  43. BUF2D_OPT_CROP_LEFT equ 2 ;обрезка слева
  44. BUF2D_OPT_CROP_BOTTOM equ 4 ;обрезка снизу
  45. BUF2D_OPT_CROP_RIGHT equ 8 ;обрезка справа
  46. BUF2D_BIT_OPT_CROP_TOP equ 0
  47. BUF2D_BIT_OPT_CROP_LEFT equ 1
  48. BUF2D_BIT_OPT_CROP_BOTTOM equ 2
  49. BUF2D_BIT_OPT_CROP_RIGHT equ 3
  50.  
  51. ;input:
  52. ; eax = указатель на функцию выделения памяти
  53. ; ebx = ... освобождения памяти
  54. ; ecx = ... перераспределения памяти
  55. ; edx = ... загрузки библиотеки (пока не используется)
  56. align 16
  57. lib_init:
  58.         mov dword[mem.alloc], eax
  59.         mov dword[mem.free], ebx
  60.         mov dword[mem.realloc], ecx
  61.         mov dword[dll.load], edx
  62.         ret
  63.  
  64. ;input:
  65. ; ebx = coord x
  66. ; ecx = coord y
  67. ; edx = pixel color
  68. ; edi = pointer to buffer struct
  69. align 4
  70. draw_pixel:
  71.         ;cmp buf2d_bits,24
  72.         ;jne @f
  73.         bt ebx,31
  74.         jc @f
  75.         bt ecx,31
  76.         jc @f
  77.         cmp ebx,buf2d_w
  78.         jge @f
  79.         cmp ecx,buf2d_h
  80.         jge @f
  81.         push esi
  82.                 mov esi,buf2d_w ;size x
  83.                 imul esi,ecx ;size_x*y
  84.                 add esi,ebx      ;size_x*y+x
  85.                 lea esi,[esi+esi*2] ;(size_x*y+x)*3
  86.                 add esi,buf2d_data  ;ptr+(size_x*y+x)*3
  87.  
  88.                 mov word[esi],dx ;copy pixel color
  89.                 ror edx,16
  90.                 mov byte[esi+2],dl
  91.                 ror edx,16
  92.         pop esi
  93.         @@:
  94.         ret
  95.  
  96. ;input:
  97. ; ebx = coord x
  98. ; ecx = coord y
  99. ; edi = pointer to buffer struct
  100. ;output:
  101. ; eax = цвет точки
  102. ; в случае ошибки eax = 0xffffffff
  103. align 4
  104. get_pixel_24:
  105.         mov eax,0xffffffff
  106.  
  107.         bt ebx,31
  108.         jc @f
  109.         bt ecx,31
  110.         jc @f
  111.         cmp ebx,buf2d_w
  112.         jge @f
  113.         cmp ecx,buf2d_h
  114.         jge @f
  115.         push esi
  116.                 mov esi,buf2d_w ;size x
  117.                 imul esi,ecx ;size_x*y
  118.                 add esi,ebx      ;size_x*y+x
  119.                 lea esi,[esi+esi*2] ;(size_x*y+x)*3
  120.                 add esi,buf2d_data  ;ptr+(size_x*y+x)*3
  121.  
  122.                 xor eax,eax
  123.                 mov ax,word[esi] ;copy pixel color
  124.                 ror eax,16
  125.                 mov al,byte[esi+2]
  126.                 ror eax,16
  127.         pop esi
  128.         @@:
  129.         ret
  130.  
  131.  
  132. ;создание буфера
  133. align 4
  134. proc buf_create, buf_struc:dword
  135.         pushad
  136.         mov edi,dword[buf_struc]
  137.         mov ecx,buf2d_w
  138.         mov ebx,buf2d_h
  139.         imul ecx,ebx
  140.         cmp buf2d_bits,24
  141.         jne @f
  142.                 lea ecx,[ecx+ecx*2] ; 24 bit = 3
  143.                 ;;;inc ecx ;запасной байт в конце буфера, что-бы не глючили некоторые функции на изображениях кратных 4К
  144.         @@:
  145.         cmp buf2d_bits,32
  146.         jne @f
  147.                 shl ecx,2 ; 32 bit = 4
  148.         @@:
  149.         invoke mem.alloc,ecx
  150.         mov buf2d_data,eax
  151.  
  152.         stdcall buf_clear,edi,buf2d_color ;очистка буфера фоновым цветом
  153.         popad
  154.         ret
  155. endp
  156.  
  157. ;создание буфера на основе изображения rgb
  158. align 4
  159. proc buf_create_f_img, buf_struc:dword, rgb_data:dword
  160.         pushad
  161.         mov edi,dword[buf_struc]
  162.         mov ecx,buf2d_w
  163.         mov ebx,buf2d_h
  164.         imul ecx,ebx
  165.         cmp buf2d_bits,24
  166.         jne @f
  167.                 lea ecx,[ecx+ecx*2] ; 24 bit = 3
  168.                 ;;;inc ecx ;запасной байт в конце буфера, что-бы не глючили некоторые функции на изображениях кратных 4К
  169.         @@:
  170.         cmp buf2d_bits,32
  171.         jne @f
  172.                 shl ecx,2 ; 32 bit = 4
  173.         @@:
  174.         invoke mem.alloc,ecx
  175.         mov buf2d_data,eax
  176.  
  177.         cmp buf2d_bits,24
  178.         jne @f
  179.                 cld
  180.                 mov esi,[rgb_data]
  181.                 mov edi,eax ;eax=buf2d_data
  182.                 rep movsb ;копируем биты изображения в буфер
  183.                 jmp .end_create
  184.         @@:
  185.                 stdcall buf_clear,edi,buf2d_color ;очистка буфера фоновым цветом
  186.         .end_create:
  187.         popad
  188.         ret
  189. endp
  190.  
  191. align 4
  192. proc buf_clear, buf_struc:dword, color:dword ;очистка буфера заданым цветом
  193.         pushad
  194.         mov edi,dword[buf_struc]
  195.  
  196.         mov ecx,buf2d_w
  197.         mov ebx,buf2d_h
  198.         imul ecx,ebx
  199.  
  200.         cld
  201.  
  202.         cmp buf2d_bits,8
  203.         jne .end_clear_8
  204.                 mov edi,buf2d_data
  205.                 mov al,byte[color]
  206.                 rep stosb
  207.                 jmp .end_clear_32
  208.         .end_clear_8:
  209.  
  210.         cmp buf2d_bits,24
  211.         jne .end_clear_24
  212.                 mov edi,buf2d_data
  213.                 mov eax,dword[color]
  214.                 mov ebx,eax
  215.                 shr ebx,16
  216.                 @@:
  217.                         stosw
  218.                         mov byte[edi],bl
  219.                         inc edi
  220.                         loop @b
  221.                 jmp .end_clear_32
  222.         .end_clear_24:
  223.  
  224.         cmp buf2d_bits,32
  225.         jne .end_clear_32
  226.                 mov edi,buf2d_data
  227.                 mov eax,dword[color]
  228.                 rep stosd
  229.                 ;jmp .end_clear_32
  230.         .end_clear_32:
  231.         popad
  232.         ret
  233. endp
  234.  
  235. ;функция для обрезания буферов 8 и 24 битных, по заданому цвету.
  236. ;параметр opt задается комбинацией констант:
  237. ; BUF2D_OPT_CROP_TOP - обрезка сверху
  238. ; BUF2D_OPT_CROP_LEFT - обрезка слева
  239. ; BUF2D_OPT_CROP_BOTTOM - обрезка снизу
  240. ; BUF2D_OPT_CROP_RIGHT - обрезка справа
  241. align 4
  242. proc buf_crop_color, buf_struc:dword, color:dword, opt:dword
  243. locals
  244.         crop_r dd ?
  245. endl
  246.         pushad
  247.         mov edi,dword[buf_struc]
  248.         cmp buf2d_bits,24
  249.         jne .24end_f
  250.  
  251.         bt dword[opt],BUF2D_BIT_OPT_CROP_BOTTOM
  252.         jae .24no_crop_bottom
  253.                 mov eax,dword[color]
  254.                 mov edx,eax ;ax = colors - r,g
  255.                 shr edx,16 ;dl = color - b
  256.                 mov ecx,buf2d_h
  257.                 cmp ecx,1
  258.                 jle .24no_crop_bottom ;проверяем на случай если высота буфера 1 пиксель
  259.                 mov ebx,buf2d_w
  260.                 imul ecx,ebx
  261.                 lea esi,[ecx+ecx*2] ;esi=3*ecx
  262.                 add esi,buf2d_data
  263.                 cld
  264.                 @@:
  265.                         sub esi,3
  266.                         cmp word[esi],ax
  267.                         jne @f
  268.                         cmp byte[esi+2],dl
  269.                         jne @f
  270.                         loop @b
  271.                 @@:
  272.                 lea ebx,[ebx+ebx*2]
  273.                 xor edx,edx
  274.                 mov eax,buf2d_h
  275.                 imul eax,ebx
  276.                 add eax,buf2d_data ;eax - указатель на конец буфера изображения
  277.                 @@:
  278.                         add esi,ebx
  279.                         cmp esi,eax
  280.                         jge @f
  281.                         inc edx ;вычисляем число полных строк для обрезания
  282.                         loop @b
  283.                 @@:
  284.                 cmp edx,0
  285.                 je .24no_crop_bottom
  286.                         cmp edx,buf2d_h
  287.                         jge .24no_crop_bottom ;что-бы не получить пустой буфер
  288.                         sub buf2d_h,edx ;уменьшаем высоту буфера
  289.                         mov ecx,buf2d_h
  290.                         imul ecx,ebx ;ecx = новый размер изображения
  291.                         invoke mem.realloc,buf2d_data,ecx
  292.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  293.         .24no_crop_bottom:
  294.  
  295.         bt dword[opt],BUF2D_BIT_OPT_CROP_TOP
  296.         jae .24no_crop_top
  297.                 mov eax,dword[color]
  298.                 mov edx,eax ;ax = colors - r,g
  299.                 shr edx,16 ;dl = color - b
  300.                 mov esi,buf2d_data
  301.                 mov ecx,buf2d_h
  302.                 cmp ecx,1
  303.                 jle .24no_crop_top ;проверяем на случай если высота буфера 1 пиксель
  304.                 dec ecx ;при обрезании должна остаться минимум 1-на строка пикселей
  305.                 mov ebx,buf2d_w
  306.                 imul ecx,ebx
  307.                 cld
  308.                 @@:
  309.                         cmp word[esi],ax
  310.                         jne @f
  311.                         cmp byte[esi+2],dl
  312.                         jne @f
  313.                         add esi,3
  314.                         loop @b
  315.                 @@:
  316.                 lea ebx,[ebx+ebx*2]
  317.                 xor edx,edx
  318.                 @@:
  319.                         sub esi,ebx
  320.                         cmp esi,buf2d_data
  321.                         jl @f
  322.                         inc edx ;вычисляем число полных строк для обрезания
  323.                         loop @b
  324.                 @@:
  325.                 cmp edx,0
  326.                 je .24no_crop_top
  327.                         xor eax,eax
  328.                         sub eax,edx
  329.                         mov ebx,buf2d_h
  330.                         sub ebx,edx
  331.                         stdcall buf_offset_h, edi, eax, edx, ebx ;сдвигаем изображение в буфере вверх (eax<0)
  332.                         sub buf2d_h,edx ;уменьшаем высоту буфера
  333.                         mov ecx,buf2d_h
  334.                         add buf2d_t,dx ;сдвигаем отступ вниз, на число обрезанных строк
  335.                         mov ebx,buf2d_w
  336.                         imul ecx,ebx
  337.                         lea ecx,[ecx+ecx*2]
  338.                         invoke mem.realloc,buf2d_data,ecx
  339.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  340.         .24no_crop_top:
  341.  
  342.         bt dword[opt],BUF2D_BIT_OPT_CROP_RIGHT
  343.         jae .24no_crop_right
  344.                 mov eax,dword[color]
  345.                 mov edx,eax ;ax = colors - r,g
  346.                 shr edx,16 ;dl = color - b
  347.                 mov ebx,buf2d_w
  348.                 cmp ebx,1
  349.                 jle .24no_crop_right ;на случай если ширина буфера 1 пиксель
  350.                 lea ebx,[ebx+ebx*2]
  351.                 mov esi,ebx
  352.                 imul esi,buf2d_h
  353.                 add esi,buf2d_data ;esi - указатель на конец буфера изображения
  354.                 mov dword[crop_r],0
  355.                 cld
  356.                 .24found_beg_right:
  357.                 sub esi,3 ;двигаемся на 1-ну колонку влево
  358.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  359.                 @@:
  360.                         cmp word[esi],ax
  361.                         jne .24found_right
  362.                         cmp byte[esi+2],dl
  363.                         jne .24found_right
  364.                         sub esi,ebx ;прыгаем на верхнюю строку
  365.                         loop @b
  366.                 inc dword[crop_r]
  367.  
  368.                 mov ecx,buf2d_w
  369.                 dec ecx ;1 колонка на запас
  370.                 cmp dword[crop_r],ecx
  371.                 jge .24found_right
  372.  
  373.                 sub esi,3 ;двигаемся на 1-ну колонку влево
  374.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  375.                 @@:
  376.                         add esi,ebx ;прыгаем на нижнюю строку
  377.                         cmp word[esi],ax
  378.                         jne .24found_right
  379.                         cmp byte[esi+2],dl
  380.                         jne .24found_right
  381.                         loop @b
  382.                 inc dword[crop_r]
  383.  
  384.                 mov ecx,buf2d_w
  385.                 dec ecx ;1 колонка на запас
  386.                 cmp dword[crop_r],ecx
  387.                 jl .24found_beg_right
  388.  
  389.                 .24found_right:
  390.                 cmp dword[crop_r],0
  391.                 je .24no_crop_right
  392.                         mov ecx,buf2d_w
  393.                         sub ecx,dword[crop_r]
  394.                         stdcall img_rgb_crop_r, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  395.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  396.                         mov ebx,buf2d_h
  397.                         imul ecx,ebx
  398.                         lea ecx,[ecx+ecx*2]
  399.                         invoke mem.realloc,buf2d_data,ecx
  400.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  401.         .24no_crop_right:
  402.  
  403.         bt dword[opt],BUF2D_BIT_OPT_CROP_LEFT
  404.         jae .24no_crop_left
  405.                 mov eax,dword[color]
  406.                 mov edx,eax ;ax = colors - r,g
  407.                 shr edx,16 ;dl = color - b
  408.                 mov ebx,buf2d_w
  409.                 cmp ebx,1
  410.                 jle .24no_crop_left ;на случай если ширина буфера 1 пиксель
  411.                 lea ebx,[ebx+ebx*2]
  412.                 mov esi,buf2d_data ;esi - указатель на начоло буфера изображения
  413.                 mov dword[crop_r],0
  414.                 cld
  415.                 .24found_beg_left:
  416.  
  417.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  418.                 @@:
  419.                         cmp word[esi],ax
  420.                         jne .24found_left
  421.                         cmp byte[esi+2],dl
  422.                         jne .24found_left
  423.                         add esi,ebx ;прыгаем на нижнюю строку
  424.                         loop @b
  425.                 inc dword[crop_r]
  426.                 add esi,3 ;двигаемся на 1-ну колонку вправо
  427.  
  428.                 mov ecx,buf2d_w
  429.                 dec ecx ;1 колонка на запас
  430.                 cmp dword[crop_r],ecx
  431.                 jge .24found_left
  432.  
  433.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  434.                 @@:
  435.                         sub esi,ebx ;прыгаем на верхнюю строку
  436.                         cmp word[esi],ax
  437.                         jne .24found_left
  438.                         cmp byte[esi+2],dl
  439.                         jne .24found_left
  440.                         loop @b
  441.                 inc dword[crop_r]
  442.                 add esi,3 ;двигаемся на 1-ну колонку вправо
  443.  
  444.                 mov ecx,buf2d_w
  445.                 dec ecx ;1 колонка на запас
  446.                 cmp dword[crop_r],ecx
  447.                 jl .24found_beg_left
  448.  
  449.                 .24found_left:
  450.                 cmp dword[crop_r],0
  451.                 je .24no_crop_left
  452.                         mov ecx,buf2d_w
  453.                         sub ecx,dword[crop_r]
  454.                         stdcall img_rgb_crop_l, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  455.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  456.                         mov ebx,buf2d_h
  457.                         imul ecx,ebx
  458.                         lea ecx,[ecx+ecx*2]
  459.                         invoke mem.realloc,buf2d_data,ecx
  460.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  461.                         mov eax,dword[crop_r]
  462.                         add buf2d_l,ax
  463.         .24no_crop_left:
  464.  
  465.         .24end_f:
  466.  
  467.  
  468.         cmp buf2d_bits,8
  469.         jne .8end_f
  470.  
  471.         bt dword[opt],BUF2D_BIT_OPT_CROP_BOTTOM
  472.         jae .8no_crop_bottom
  473.                 mov eax,dword[color]
  474.                 mov esi,buf2d_data
  475.                 mov ecx,buf2d_h
  476.                 cmp ecx,1
  477.                 jle .8no_crop_bottom ;проверяем на случай если высота буфера 1 пиксель
  478.                 mov ebx,buf2d_w
  479.                 imul ecx,ebx
  480.                 mov esi,ecx
  481.                 add esi,buf2d_data
  482.                 cld
  483.                 @@:
  484.                         dec esi
  485.                         cmp byte[esi],al
  486.                         jne @f
  487.                         loop @b
  488.                 @@:
  489.                 xor edx,edx
  490.                 mov eax,buf2d_h
  491.                 imul eax,ebx
  492.                 add eax,buf2d_data ;eax - указатель на конец буфера изображения
  493.                 @@:
  494.                         add esi,ebx
  495.                         cmp esi,eax
  496.                         jge @f
  497.                         inc edx
  498.                         loop @b
  499.                 @@:
  500.                 cmp edx,0
  501.                 je .8no_crop_bottom
  502.                         cmp edx,buf2d_h
  503.                         jge .8no_crop_bottom ;что-бы не получить пустой буфер
  504.                         sub buf2d_h,edx ;уменьшаем высоту буфера
  505.                         mov ecx,buf2d_h
  506.                         imul ecx,ebx ;ecx = новый размер изображения
  507.                         invoke mem.realloc,buf2d_data,ecx
  508.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  509.         .8no_crop_bottom:
  510.  
  511.         bt dword[opt],BUF2D_BIT_OPT_CROP_TOP
  512.         jae .8no_crop_top
  513.                 mov eax,dword[color]
  514.                 mov esi,buf2d_data
  515.                 mov ecx,buf2d_h
  516.                 cmp ecx,1
  517.                 jle .8no_crop_top ;проверяем на случай если высота буфера 1 пиксель
  518.                 dec ecx ;при обрезании должна остаться минимум 1-на строка пикселей
  519.                 mov ebx,buf2d_w
  520.                 imul ecx,ebx
  521.                 cld
  522.                 @@:
  523.                         cmp byte[esi],al
  524.                         jne @f
  525.                         inc esi
  526.                         loop @b
  527.                 @@:
  528.                 xor edx,edx
  529.                 @@:
  530.                         sub esi,ebx
  531.                         cmp esi,buf2d_data
  532.                         jl @f
  533.                         inc edx
  534.                         loop @b
  535.                 @@:
  536.                 cmp edx,0
  537.                 je .8no_crop_top
  538.                         xor eax,eax
  539.                         sub eax,edx
  540.                         mov ebx,buf2d_h
  541.                         sub ebx,edx
  542.                         stdcall buf_offset_h, edi, eax, edx, ebx
  543.                         mov ecx,buf2d_h
  544.                         sub ecx,edx
  545.                         mov buf2d_h,ecx ;уменьшаем высоту буфера
  546.                         add buf2d_t,dx ;сдвигаем отступ вниз, на число обрезанных строк
  547.                         mov ebx,buf2d_w
  548.                         imul ecx,ebx
  549.                         invoke mem.realloc,buf2d_data,ecx
  550.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  551.         .8no_crop_top:
  552.  
  553.         bt dword[opt],BUF2D_BIT_OPT_CROP_RIGHT
  554.         jae .8no_crop_right
  555.                 mov eax,dword[color]
  556.                 mov ebx,buf2d_w
  557.                 cmp ebx,1
  558.                 jle .8no_crop_right ;на случай если ширина буфера 1 пиксель
  559.                 mov esi,ebx
  560.                 imul esi,buf2d_h
  561.                 add esi,buf2d_data ;esi - указатель на конец буфера изображения
  562.                 xor edx,edx
  563.                 cld
  564.  
  565.                 .8found_beg:
  566.                 dec esi ;двигаемся на 1-ну колонку влево
  567.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  568.                 @@:
  569.                         cmp byte[esi],al
  570.                         jne .8found
  571.                         sub esi,ebx ;прыгаем на верхнюю строку
  572.                         loop @b
  573.                 inc edx
  574.                 mov ecx,buf2d_w
  575.                 dec ecx ;1 колонка на запас
  576.                 cmp edx,ecx
  577.                 jge .8found
  578.  
  579.                 dec esi ;двигаемся на 1-ну колонку влево
  580.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  581.                 @@:
  582.                         add esi,ebx ;прыгаем на нижнюю строку
  583.                         cmp byte[esi],al
  584.                         jne .8found
  585.                         loop @b
  586.                 inc edx
  587.  
  588.                 mov ecx,buf2d_w
  589.                 dec ecx ;1 колонка на запас
  590.                 cmp edx,ecx
  591.                 jl .8found_beg
  592.  
  593.                 .8found:
  594.                 cmp edx,0
  595.                 je .8no_crop_right
  596.                         mov ecx,buf2d_w
  597.                         sub ecx,edx
  598.                         stdcall img_gray_crop_r, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  599.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  600.                         mov ebx,buf2d_h
  601.                         imul ecx,ebx
  602.                         invoke mem.realloc,buf2d_data,ecx
  603.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  604.         .8no_crop_right:
  605.  
  606.         bt dword[opt],BUF2D_BIT_OPT_CROP_LEFT
  607.         jae .8no_crop_left
  608.                 mov eax,dword[color]
  609.                 mov ebx,buf2d_w
  610.                 cmp ebx,1
  611.                 jle .8no_crop_left ;на случай если ширина буфера 1 пиксель
  612.                 mov esi,buf2d_data ;esi - указатель на начоло буфера изображения
  613.                 mov edx,0
  614.                 cld
  615.                 .8found_beg_left:
  616.  
  617.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  618.                 @@:
  619.                         cmp word[esi],ax
  620.                         jne .8found_left
  621.                         add esi,ebx ;прыгаем на нижнюю строку
  622.                         loop @b
  623.                 inc edx
  624.                 inc esi ;двигаемся на 1-ну колонку вправо
  625.  
  626.                 mov ecx,buf2d_w
  627.                 dec ecx ;1 колонка на запас
  628.                 cmp edx,ecx
  629.                 jge .8found_left
  630.  
  631.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  632.                 @@:
  633.                         sub esi,ebx ;прыгаем на верхнюю строку
  634.                         cmp word[esi],ax
  635.                         jne .8found_left
  636.                         loop @b
  637.                 inc edx
  638.                 inc esi ;двигаемся на 1-ну колонку вправо
  639.  
  640.                 mov ecx,buf2d_w
  641.                 dec ecx ;1 колонка на запас
  642.                 cmp edx,ecx
  643.                 jl .8found_beg_left
  644.  
  645.                 .8found_left:
  646.                 cmp edx,0
  647.                 je .8no_crop_left
  648.                         mov ecx,buf2d_w
  649.                         sub ecx,edx
  650.                         stdcall img_gray_crop_l, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  651.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  652.                         mov ebx,buf2d_h
  653.                         imul ecx,ebx
  654.                         invoke mem.realloc,buf2d_data,ecx
  655.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  656.                         mov eax,edx
  657.                         add buf2d_l,ax
  658.         .8no_crop_left:
  659.  
  660.         .8end_f:
  661.  
  662.         popad
  663.         ret
  664. endp
  665.  
  666. ;обрезаем цветное изображение с правой стороны
  667. ;input:
  668. ;data_rgb - pointer to rgb data
  669. ;size_w_old - width img in pixels
  670. ;size_w_new - new width img in pixels
  671. ;size_h - height img in pixels
  672. align 4
  673. proc img_rgb_crop_r, data_rgb:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  674.         pushad
  675.         mov eax, dword[size_w_old]
  676.         lea eax, dword[eax+eax*2] ;eax = width(old) * 3(rgb)
  677.         mov ebx, dword[size_w_new]
  678.         lea ebx, dword[ebx+ebx*2] ;ebx = width(new) * 3(rgb)
  679.         mov edx, dword[size_h]
  680.         mov edi, dword[data_rgb] ;edi - получает данные
  681.         mov esi, edi
  682.         add edi, ebx
  683.         add esi, eax
  684.         cld
  685.         @@:
  686.                 dec edx ;уменьшаем счетчик оставшихся строк на 1
  687.                 cmp edx,0
  688.                 jle @f
  689.                 mov ecx, ebx
  690.                 rep movsb ;перенос (копирование) строки пикселей
  691.                 add esi,eax ;переход на новую строчку изображения
  692.                 sub esi,ebx
  693.                 jmp @b
  694.         @@:
  695.         popad
  696.         ret
  697. endp
  698.  
  699. ;обрезаем серое изображение с правой стороны
  700. ;input:
  701. ;data_gray - pointer to gray data
  702. ;size_w_old - width img in pixels
  703. ;size_w_new - new width img in pixels
  704. ;size_h - height img in pixels
  705. align 4
  706. proc img_gray_crop_r, data_gray:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  707.         pushad
  708.         mov eax, dword[size_w_old]
  709.         mov ebx, dword[size_w_new]
  710.         mov edx, dword[size_h]
  711.         mov edi, dword[data_gray] ;edi - получает данные
  712.         mov esi, edi
  713.         add edi, ebx
  714.         add esi, eax
  715.         cld
  716.         @@:
  717.                 dec edx ;уменьшаем счетчик оставшихся строк на 1
  718.                 cmp edx,0
  719.                 jle @f
  720.                 mov ecx, ebx
  721.                 rep movsb ;перенос (копирование) строки пикселей
  722.                 add esi,eax ;переход на новую строчку изображения
  723.                 sub esi,ebx
  724.                 jmp @b
  725.         @@:
  726.         popad
  727.         ret
  728. endp
  729.  
  730. ;обрезаем цветное изображение с левой стороны
  731. ;input:
  732. ;data_rgb - pointer to rgb data
  733. ;size_w_old - width img in pixels
  734. ;size_w_new - new width img in pixels
  735. ;size_h - height img in pixels
  736. align 4
  737. proc img_rgb_crop_l, data_rgb:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  738.         pushad
  739.         mov edi,dword[data_rgb]
  740.         mov esi,edi
  741.         mov eax,dword[size_w_old]
  742.         mov ebx,dword[size_w_new]
  743.         cmp eax,ebx
  744.         jle .end_f ;старый размер изображения не может быть меньше нового (при условии обрезания картинки)
  745.                 lea eax,[eax+eax*2]
  746.                 lea ebx,[ebx+ebx*2]
  747.                 sub eax,ebx
  748.                 mov edx,dword[size_h] ;высота изображения
  749.                 cld
  750.                 @@:
  751.                         add esi,eax
  752.                         mov ecx,ebx
  753.                         rep movsb
  754.                         dec edx
  755.                         cmp edx,0
  756.                         jg @b
  757.         .end_f:
  758.         popad
  759.         ret
  760. endp
  761.  
  762. ;обрезаем серое изображение с левой стороны
  763. ;input:
  764. ;data_gray - pointer to gray data
  765. ;size_w_old - width img in pixels
  766. ;size_w_new - new width img in pixels
  767. ;size_h - height img in pixels
  768. align 4
  769. proc img_gray_crop_l, data_gray:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  770.         pushad
  771.         mov edi,dword[data_gray]
  772.         mov esi,edi
  773.         mov eax,dword[size_w_old]
  774.         mov ebx,dword[size_w_new]
  775.         cmp eax,ebx
  776.         jle .end_f ;старый размер изображения не может быть меньше нового (при условии обрезания картинки)
  777.                 sub eax,ebx
  778.                 mov edx,dword[size_h] ;высота изображения
  779.                 cld
  780.                 @@:
  781.                         add esi,eax
  782.                         mov ecx,ebx
  783.                         rep movsb
  784.                         dec edx
  785.                         cmp edx,0
  786.                         jg @b
  787.         .end_f:
  788.         popad
  789.         ret
  790. endp
  791.  
  792. ;hoffs - колличество пикселей на котрые поднимается/опускается изображение
  793. ;img_t - высота, с которой начинается двигающаяся часть изображения
  794. align 4
  795. proc buf_offset_h, buf_struc:dword, hoffs:dword, img_t:dword, img_h:dword ;сдвигает изображение по высоте
  796.         pushad
  797.         mov edi,dword[buf_struc]
  798.         cmp buf2d_bits,24
  799.         jne .end_move_24
  800.  
  801.         mov eax,[hoffs]
  802.         cmp eax,0
  803.         je .end_move_24
  804.                 mov ebx,buf2d_w
  805.                 mov edx,dword[img_t]
  806.                         mov ecx,dword[img_h] ;ecx - высота сдвигаемых данных
  807.                         cmp ecx,buf2d_h
  808.                         jge .end_f ;ошибочное условие, высота изображения меньше чем высота сдвигаемого изображения
  809.                         imul ecx,ebx ;ecx - колличество пикселей в сдвигаемых данных
  810.                         lea ecx,[ecx+ecx*2]
  811.                 imul ebx,edx
  812.                 lea ebx,[ebx+ebx*2]
  813.                 mov esi,buf2d_data
  814.                 add esi,ebx
  815.  
  816.                 add edx,eax ;edx = img_t+hoffs (hoffs<0)
  817.                 mov ebx,buf2d_w
  818.                 imul ebx,edx
  819.                 lea ebx,[ebx+ebx*2]
  820.                 mov edi,buf2d_data ;позиция, куда будет двигаться изображение
  821.                 add edi,ebx
  822.  
  823.                 cmp eax,0
  824.                 jg .move_down_24
  825.                         ;двигаем изображение вверх
  826.                         cld
  827.                         rep movsb
  828.                         jmp .end_f
  829.                 .move_down_24:
  830.                         ;двигаем изображение вниз
  831.                         add esi,ecx
  832.                         dec esi
  833.                         add edi,ecx
  834.                         dec edi
  835.                         std
  836.                         rep movsb
  837.                         jmp .end_f
  838.         .end_move_24:
  839.  
  840. ;stdcall print_err,sz_buf2d_offset_h,txt_err_n24b
  841.  
  842.         cmp buf2d_bits,8
  843.         jne .end_move_8
  844.  
  845.         mov eax,[hoffs]
  846.         cmp eax,0
  847.         je .end_move_8
  848.                 ;двигаем изображение вверх
  849.                 mov ebx,buf2d_w
  850.                 mov edx,dword[img_t]
  851.                         mov ecx,dword[img_h] ;ecx - высота сдвигаемых данных
  852.                         cmp ecx,buf2d_h
  853.                         jge .end_f ;ошибочное условие, высота изображения меньше чем высота сдвигаемого изображения
  854.                         imul ecx,ebx ;ecx - колличество пикселей в сдвигаемых данных
  855.                 imul ebx,edx
  856.                 mov esi,buf2d_data
  857.                 add esi,ebx
  858.  
  859.                 add edx,eax ;edx = img_t+hoffs (hoffs<0)
  860.                 mov ebx,buf2d_w
  861.                 imul ebx,edx
  862.                 mov edi,buf2d_data ;позиция, куда будет двигаться изображение
  863.                 add edi,ebx
  864.  
  865.                 cmp eax,0
  866.                 jg .move_down_8
  867.                         cld
  868.                         rep movsb
  869.                         jmp .end_f
  870.                 .move_down_8:
  871.                         ;двигаем изображение вниз
  872.                         add esi,ecx
  873.                         dec esi
  874.                         add edi,ecx
  875.                         dec edi
  876.                         std
  877.                         rep movsb
  878.                         jmp .end_f
  879.         .end_move_8:
  880.  
  881.         .end_f:
  882.         popad
  883.         ret
  884. endp
  885.  
  886.  
  887. align 4
  888. proc buf_draw_buf, buf_struc:dword
  889.         pushad
  890.         mov edi,dword[buf_struc]
  891.         cmp buf2d_bits,24
  892.         jne .error
  893.                 mov eax,7
  894.                 mov ebx,buf2d_data
  895.  
  896.                 mov ecx,buf2d_w
  897.                 ror ecx,16
  898.                 mov edx,buf2d_h
  899.                 mov cx,dx
  900.  
  901.                 mov edx,buf2d_size_lt
  902.                 ror edx,16
  903.                 int 0x40
  904.                 jmp .end_draw_24
  905.         .error:
  906.                 stdcall print_err,sz_buf2d_draw,txt_err_n24b
  907.         .end_draw_24:
  908.         popad
  909.         ret
  910. endp
  911.  
  912. align 4
  913. proc buf_delete, buf_struc:dword
  914.         push eax edi
  915.         mov edi,dword[buf_struc]
  916.         invoke mem.free,buf2d_data
  917.         pop edi eax
  918.         ret
  919. endp
  920.  
  921. align 4
  922. proc buf_resize, buf_struc:dword, new_w:dword, new_h:dword
  923.         pushad
  924.         mov edi,dword[buf_struc]
  925.         cmp buf2d_bits,24
  926.         jne .24bit
  927.                 mov eax,dword[new_w]
  928.                 cmp eax,1
  929.                 jl @f
  930.                         mov buf2d_w,eax
  931.                 @@:
  932.                 mov ecx,buf2d_w
  933.                 mov eax,dword[new_h]
  934.                 cmp eax,1
  935.                 jl @f
  936.                         mov buf2d_h,eax
  937.                 @@:
  938.                 mov ebx,buf2d_h
  939.                 imul ecx,ebx
  940.                 lea ecx,[ecx+ecx*2] ; 24 bit = 3
  941.                 invoke mem.realloc,buf2d_data,ecx ;изменяем память занимаемую буфером
  942.                 mov buf2d_data,eax ;на случай если изменился указатель на данные
  943.         .24bit:
  944.         popad
  945.         ret
  946. endp
  947.  
  948. align 4
  949. proc buf_line_brs, buf_struc:dword, coord_x0:dword, coord_y0:dword, coord_x1:dword, coord_y1:dword, color:dword
  950. locals
  951.         loc_1 dd ?
  952.         loc_2 dd ?
  953.         napravl db ?
  954. endl
  955.         pushad
  956.                 mov edx,dword[color]
  957.  
  958.                 mov eax,dword[coord_x1]
  959.                 sub eax,dword[coord_x0]
  960.                 bt eax,31
  961.                 jae @f
  962.                         neg eax
  963.                         inc eax
  964.                 @@:
  965.                 mov ebx,dword[coord_y1]
  966.                 sub ebx,dword[coord_y0]
  967.                 bt ebx,31
  968.                 jae @f
  969.                         neg ebx
  970.                         inc ebx
  971.                 @@:
  972.  
  973.                 mov [napravl],byte 0 ;bool steep=false
  974.                 cmp eax,ebx
  975.                 jle @f
  976.                         mov [napravl],byte 1 ;bool steep=true
  977.                         swap dword[coord_x0],dword[coord_y0] ;swap(x0, y0);
  978.                         swap dword[coord_x1],dword[coord_y1] ;swap(x1, y1);
  979.                 @@:
  980.                 mov eax,dword[coord_y0] ;x0
  981.                 cmp eax,dword[coord_y1] ;if(x0>x1)
  982.                 jle @f
  983.                         swap dword[coord_y0],dword[coord_y1] ;swap(x0, x1);
  984.                         swap dword[coord_x0],dword[coord_x1] ;swap(y0, y1);
  985.                 @@:
  986.  
  987. ; int deltax esi
  988. ; int deltay edi
  989. ; int error  ebp-6
  990. ; int ystep  ebp-8
  991.  
  992.                 mov eax,dword[coord_y0]
  993.                 mov esi,dword[coord_y1]
  994.                 sub esi,eax ;deltax = y1-y0
  995.                 mov ebx,esi
  996.                 shr ebx,1
  997.                 mov [loc_1],ebx ;error = deltax/2
  998.  
  999.                 mov eax,dword[coord_x0]
  1000.                 mov edi,dword[coord_x1]
  1001.                 mov [loc_2],dword -1 ;ystep = -1
  1002.                 cmp eax,edi ;if (x0<x1) ystep = 1;
  1003.                 jge @f
  1004.                         mov [loc_2],dword 1 ;ystep = 1
  1005.                 @@:
  1006.                 sub edi,eax ;x1-x0
  1007.  
  1008.                 bts edi,31
  1009.                 jae @f
  1010.                         neg edi
  1011.                         inc edi
  1012.                 @@:
  1013.                 and edi,0x7fffffff ;deltay = abs(x1-x0)
  1014.  
  1015.                 mov eax,edi
  1016.                 mov edi,[buf_struc]
  1017.                 cmp buf2d_bits,24
  1018.                 jne .coord_end
  1019.  
  1020.                 cmp [napravl],0
  1021.                 jne .coord_yx
  1022.                         mov ebx,dword[coord_x0]
  1023.                         mov ecx,dword[coord_y0]
  1024.  
  1025.                         @@: ;for (x=x0 ; x<x1; x++) ;------------------------------------
  1026.                                 cmp ecx,dword[coord_y1]
  1027.                                 jg @f ;jge ???
  1028.                                 call draw_pixel
  1029.  
  1030.                                 sub dword[loc_1],eax ;error -= deltay
  1031.                                 cmp dword[loc_1],0 ;if(error<0)
  1032.                                 jge .if0
  1033.                                         add ebx,[loc_2] ;y += ystep
  1034.                                         add [loc_1],esi ;error += deltax
  1035.                                 .if0:
  1036.                                 inc ecx
  1037.                                 jmp @b
  1038.                         @@:
  1039.                         jmp .coord_end
  1040.                 .coord_yx:
  1041.                         mov ebx,dword[coord_y0]
  1042.                         mov ecx,dword[coord_x0]
  1043.  
  1044.                         @@: ;for (x=x0 ; x<x1; x++) ;------------------------------------
  1045.                                 cmp ebx,dword[coord_y1]
  1046.                                 jg @f ;jge ???
  1047.                                 call draw_pixel
  1048.  
  1049.                                 sub dword[loc_1],eax ;error -= deltay
  1050.                                 cmp dword[loc_1],0 ;if(error<0)
  1051.                                 jge .if1
  1052.                                         add ecx,[loc_2] ;y += ystep
  1053.                                         add [loc_1],esi ;error += deltax
  1054.                                 .if1:
  1055.                                 inc ebx
  1056.                                 jmp @b
  1057.                         @@:
  1058.         .coord_end:
  1059.         popad
  1060.         ret
  1061. endp
  1062.  
  1063. ;рисование горизонтальной линии, потому нет параметра coord_y1
  1064. align 4
  1065. proc buf_line_h, buf_struc:dword, coord_x0:dword, coord_y0:dword, coord_x1:dword, color:dword
  1066.         pushad
  1067.                 mov edi,[buf_struc]
  1068.                 cmp buf2d_bits,24
  1069.                 jne .end24
  1070.  
  1071.                 mov ebx,dword[coord_x0]
  1072.                 mov ecx,dword[coord_y0]
  1073.                 mov edx,dword[color]
  1074.                 mov esi,dword[coord_x1]
  1075.                 cmp ebx,esi
  1076.                 jle @f
  1077.                         xchg ebx,esi ;если x0 > x1 то меняем местами x0 и x1
  1078.  
  1079.                 @@: ;цикл по оси x от x0 до x1
  1080.                         cmp ebx,esi
  1081.                         jge @f
  1082.                         call draw_pixel
  1083.                         inc ebx
  1084.                         jmp @b
  1085.                 @@:
  1086.                 .end24:
  1087.         popad
  1088.         ret
  1089. endp
  1090.  
  1091. align 4
  1092. proc buf_rect_by_size, buf_struc:dword, coord_x:dword,coord_y:dword,w:dword,h:dword, color:dword
  1093. pushad
  1094.         mov edi,[buf_struc]
  1095.         cmp buf2d_bits,24
  1096.         jne .coord_end
  1097.  
  1098.                 mov eax,[coord_x]
  1099.                 mov ebx,[coord_y]
  1100.                 mov ecx,[w]
  1101.                 cmp ecx,1
  1102.                 jl .coord_end
  1103.                 add ecx,eax
  1104.                 dec ecx
  1105.                 mov edx,[h]
  1106.                 cmp edx,1
  1107.                 jl .coord_end
  1108.  
  1109.                 add edx,ebx
  1110.                 dec edx
  1111.                 mov esi,dword[color]
  1112.                 stdcall buf_line_h, edi, eax, ebx, ecx, esi ;линия -
  1113.                 stdcall buf_line_brs, edi, eax, ebx, eax, edx, esi ;линия |
  1114.                 stdcall buf_line_h, edi, eax, edx, ecx, esi ;линия -
  1115.                 stdcall buf_line_brs, edi, ecx, ebx, ecx, edx, esi ;линия |
  1116.         .coord_end:
  1117. popad
  1118.         ret
  1119. endp
  1120.  
  1121. align 4
  1122. proc buf_filled_rect_by_size, buf_struc:dword, coord_x:dword,coord_y:dword,w:dword,h:dword, color:dword
  1123. pushad
  1124.         mov edi,[buf_struc]
  1125.         cmp buf2d_bits,24
  1126.         jne .coord_end
  1127.                 mov eax,[coord_x]
  1128.                 mov ebx,[coord_y]
  1129.                 mov edx,[w]
  1130.                 add edx,eax
  1131.                 mov ecx,[h]
  1132.                 cmp ecx,1 ;сравнение с минимально возможной высотой
  1133.                 jl .coord_end ;если высота меньше 1-го пикселя
  1134.                 mov esi,dword[color]
  1135.                 cld
  1136.                 @@:
  1137.                         stdcall buf_line_h, edi, eax, ebx, edx, esi ;линия -
  1138.                         inc ebx
  1139.                         loop @b
  1140.         .coord_end:
  1141. popad
  1142.         ret
  1143. endp
  1144.  
  1145. align 4
  1146. proc buf_circle, buf_struc:dword, coord_x:dword, coord_y:dword, r:dword, color:dword
  1147. locals
  1148.         po_x dd ?
  1149.         po_y dd ?
  1150. endl
  1151.         pushad
  1152.         mov edi,dword[buf_struc]
  1153.         cmp buf2d_bits,24
  1154.         jne .error
  1155.                 mov edx,dword[color]
  1156.  
  1157.                 finit
  1158.                 fild dword[coord_x]
  1159.                 fild dword[coord_y]
  1160.                 fild dword[r]
  1161.                 fldz ;px=0
  1162.                 fld st1 ;py=r
  1163.  
  1164.                 fldpi
  1165.                 fmul st0,st3
  1166.                 fistp dword[po_x]
  1167.                 mov esi,dword[po_x] ;esi=pi*r
  1168.                 shl esi,1 ;esi=2*pi*r
  1169.  
  1170.                 ;st0 = py
  1171.                 ;st1 = px
  1172.                 ;st2 = r
  1173.                 ;st3 = y
  1174.                 ;st4 = x
  1175.  
  1176.                 @@:
  1177.                         ;Point(px + x, y - py)
  1178.                         fld st1 ;st0=px
  1179.                         fadd st0,st5 ;st0=px+x
  1180.                         fistp dword[po_x]
  1181.                         mov ebx,dword[po_x]
  1182.                         fld st3 ;st0=y
  1183.                         fsub st0,st1 ;st0=y-py
  1184.                         fistp dword[po_y]
  1185.                         mov ecx,dword[po_y]
  1186.                         call draw_pixel
  1187.                         ;px += py/r
  1188.                         fld st0 ;st0=py
  1189.                         fdiv st0,st3 ;st0=py/r
  1190.                         faddp st2,st0 ;st3+=st0
  1191.                         ;py -= px/r
  1192.                         fld st1 ;st0=px
  1193.                         fdiv st0,st3 ;st0=px/r
  1194.                         fsubp st1,st0 ;st2-=st0
  1195.  
  1196.                         dec esi
  1197.                         cmp esi,0
  1198.                         jge @b
  1199.                 jmp .exit_fun
  1200.         .error:
  1201.                 stdcall print_err,sz_buf2d_circle,txt_err_n24b
  1202.         .exit_fun:
  1203.  
  1204.         popad
  1205.         ret
  1206. endp
  1207.  
  1208. ;функция для заливки области выбранным цветом
  1209. align 4
  1210. proc buf_flood_fill, buf_struc:dword, coord_x:dword, coord_y:dword, mode:dword, color_f:dword, color_b:dword
  1211.         pushad
  1212.                 mov edi,[buf_struc]
  1213.                 cmp buf2d_bits,24
  1214.                 jne .end24
  1215.  
  1216.                         mov ebx,dword[coord_x]
  1217.                         mov ecx,dword[coord_y]
  1218.                         mov edx,dword[color_f]
  1219.                         mov esi,dword[color_b]
  1220.  
  1221.                         cmp dword[mode],1 ;в зависимости от 'mode' определяем каким алгоритмом будем пользоваться
  1222.                         je @f
  1223.                                 call buf_flood_fill_recurs_0 ;заливаем до пикселей цвета esi
  1224.                                 jmp .end24
  1225.                         @@:
  1226.                                 call buf_flood_fill_recurs_1 ;заливаем пиксели имеющие цвет esi
  1227.  
  1228.                 .end24:
  1229.         popad
  1230.         ret
  1231. endp
  1232.  
  1233. ;input:
  1234. ; ebx = coord_x
  1235. ; ecx = coord_y
  1236. ; edx = цвет заливки
  1237. ; esi = цвет границы, до которой будет ити заливка
  1238. ; edi = buf_struc
  1239. ;output:
  1240. ; eax = портится
  1241. align 4
  1242. buf_flood_fill_recurs_0:
  1243.         call get_pixel_24
  1244.         cmp eax,0xffffffff ;if error coords
  1245.         je .end_fun
  1246.         cmp eax,edx ;если цвет пикселя совпал с цветом заливки, значит заливка в этой области уже была сделана
  1247.         je .end_fun
  1248.  
  1249.                 call draw_pixel
  1250.  
  1251.                 dec ebx
  1252.                 call get_pixel_24
  1253.                 cmp eax,esi
  1254.                 je @f
  1255.                         call buf_flood_fill_recurs_0
  1256.                 @@:
  1257.                 inc ebx
  1258.  
  1259.  
  1260.                 inc ebx
  1261.                 call get_pixel_24
  1262.                 cmp eax,esi
  1263.                 je @f
  1264.                         call buf_flood_fill_recurs_0
  1265.                 @@:
  1266.                 dec ebx
  1267.  
  1268.                 dec ecx
  1269.                 call get_pixel_24
  1270.                 cmp eax,esi
  1271.                 je @f
  1272.                         call buf_flood_fill_recurs_0
  1273.                 @@:
  1274.                 inc ecx
  1275.  
  1276.                 inc ecx
  1277.                 call get_pixel_24
  1278.                 cmp eax,esi
  1279.                 je @f
  1280.                         call buf_flood_fill_recurs_0
  1281.                 @@:
  1282.                 dec ecx
  1283.  
  1284.         .end_fun:
  1285.         ret
  1286.  
  1287. ;input:
  1288. ; ebx = coord_x
  1289. ; ecx = coord_y
  1290. ; edx = цвет заливки
  1291. ; esi = цвет пикселей, по которым будет ити заливка
  1292. ; edi = buf_struc
  1293. ;output:
  1294. ; eax = портится
  1295. align 4
  1296. buf_flood_fill_recurs_1:
  1297.         call get_pixel_24
  1298.         cmp eax,0xffffffff ;if error coords
  1299.         je .end_fun
  1300.         cmp eax,edx ;если цвет пикселя совпал с цветом заливки, значит заливка в этой области уже была сделана
  1301.         je .end_fun
  1302.         cmp eax,esi ;если цвет пикселя не совпал с заливаемым цветом заливки, то прекращаем заливку
  1303.         jne .end_fun
  1304.  
  1305.                 call draw_pixel
  1306.  
  1307.                 dec ebx
  1308.                 call get_pixel_24
  1309.                 cmp eax,esi
  1310.                 jne @f
  1311.                         call buf_flood_fill_recurs_1
  1312.                 @@:
  1313.                 inc ebx
  1314.  
  1315.  
  1316.                 inc ebx
  1317.                 call get_pixel_24
  1318.                 cmp eax,esi
  1319.                 jne @f
  1320.                         call buf_flood_fill_recurs_1
  1321.                 @@:
  1322.                 dec ebx
  1323.  
  1324.                 dec ecx
  1325.                 call get_pixel_24
  1326.                 cmp eax,esi
  1327.                 jne @f
  1328.                         call buf_flood_fill_recurs_1
  1329.                 @@:
  1330.                 inc ecx
  1331.  
  1332.                 inc ecx
  1333.                 call get_pixel_24
  1334.                 cmp eax,esi
  1335.                 jne @f
  1336.                         call buf_flood_fill_recurs_1
  1337.                 @@:
  1338.                 dec ecx
  1339.  
  1340.         .end_fun:
  1341.         ret
  1342.  
  1343. ;функция для рисования точки
  1344. align 4
  1345. proc buf_set_pixel, buf_struc:dword, coord_x:dword, coord_y:dword, color:dword
  1346.         pushad
  1347.                 mov edi,[buf_struc]
  1348.                 cmp buf2d_bits,24
  1349.                 jne .end24
  1350.                         mov ebx,dword[coord_x]
  1351.                         mov ecx,dword[coord_y]
  1352.                         mov edx,dword[color]
  1353.                         call draw_pixel
  1354.                 .end24:
  1355.         popad
  1356.         ret
  1357. endp
  1358.  
  1359. align 4
  1360. proc buf_img_wdiv2, buf_struc:dword
  1361.         pushad
  1362.         mov edi,dword[buf_struc]
  1363.         cmp buf2d_bits,24
  1364.         jne .end_draw_24
  1365.                 mov eax,buf2d_w
  1366.                 mov ecx,buf2d_h
  1367.                 imul ecx,eax
  1368.                 stdcall img_rgb24_wdiv2, buf2d_data,ecx
  1369.         .end_draw_24:
  1370.         popad
  1371.         ret
  1372. endp
  1373.  
  1374. ;input:
  1375. ;data_rgb - pointer to rgb data
  1376. ;size - count img pixels (size img data / 3(rgb) )
  1377. align 4
  1378. proc img_rgb24_wdiv2 data_rgb:dword, size:dword
  1379.   ;push eax ebx ecx edx
  1380.   mov eax,dword[data_rgb]
  1381.   mov ecx,dword[size] ;ecx = size
  1382.   lea ecx,[ecx+ecx*2]
  1383.   cld
  1384.   @@: ;затемнение цвета пикселей
  1385.                 shr byte[eax],1
  1386.                 inc eax
  1387.                 loop @b
  1388.  
  1389.   mov eax,dword[data_rgb]
  1390.   mov ecx,dword[size] ;ecx = size
  1391.   shr ecx,1
  1392.   @@: ;сложение цветов пикселей
  1393.                 mov bx,word[eax+3] ;копируем цвет соседнего пикселя
  1394.                 add word[eax],bx
  1395.                 mov bl,byte[eax+5] ;копируем цвет соседнего пикселя
  1396.                 add byte[eax+2],bl
  1397.                 add eax,6 ;=2*3
  1398.                 loop @b
  1399.  
  1400.   mov eax,dword[data_rgb]
  1401.   add eax,3
  1402.   mov ebx,eax
  1403.   add ebx,3
  1404.   mov ecx,dword[size] ;ecx = size
  1405.   shr ecx,1
  1406.   dec ecx ;лишний пиксель
  1407.   @@: ;поджатие пикселей
  1408.                 mov edx,dword[ebx]
  1409.                 mov word[eax],dx
  1410.                 shr edx,16
  1411.                 mov byte[eax+2],dl
  1412.  
  1413.                 add eax,3
  1414.                 add ebx,6
  1415.                 loop @b
  1416.   ;pop edx ecx ebx eax
  1417.   ret
  1418. endp
  1419.  
  1420. align 4
  1421. proc buf_img_hdiv2, buf_struc:dword
  1422.         pushad
  1423.         mov edi,dword[buf_struc]
  1424.         cmp buf2d_bits,24
  1425.         jne .end_draw_24
  1426.                 mov eax,buf2d_w
  1427.                 mov ecx,buf2d_h
  1428.                 imul ecx,eax
  1429.                 stdcall img_rgb24_hdiv2, buf2d_data,ecx,eax
  1430.         .end_draw_24:
  1431.         popad
  1432.         ret
  1433. endp
  1434.  
  1435. ;input:
  1436. ;data_rgb - pointer to rgb data
  1437. ;size - count img pixels (size img data / 3(rgb) )
  1438. ;size_w - width img in pixels
  1439. align 4
  1440. proc img_rgb24_hdiv2, data_rgb:dword, size:dword, size_w:dword
  1441.   ;pushad
  1442.  
  1443.   mov eax,dword[data_rgb] ;eax =
  1444.   mov ecx,dword[size]     ;ecx = size
  1445.   lea ecx,[ecx+ecx*2]
  1446.   cld
  1447.   @@: ;затемнение цвета пикселей
  1448.     shr byte[eax],1
  1449.     inc eax
  1450.     loop @b
  1451.  
  1452.   mov eax,dword[data_rgb] ;eax =
  1453.   mov edi,dword[size_w]
  1454.   lea esi,[edi+edi*2] ;esi = width*3(rgb)
  1455.   mov ebx,esi
  1456.   add ebx,eax
  1457.   mov ecx,dword[size]  ;ecx = size
  1458.   shr ecx,1
  1459.   xor edi,edi
  1460.   @@: ;сложение цветов пикселей
  1461.     mov dx,word[ebx] ;копируем цвет нижнего пикселя
  1462.     add word[eax],dx
  1463.     mov dl,byte[ebx+2] ;копируем цвет нижнего пикселя
  1464.     add byte[eax+2],dl
  1465.  
  1466.     add eax,3
  1467.     add ebx,3
  1468.     inc edi
  1469.     cmp edi,dword[size_w]
  1470.     jl .old_line
  1471.       add eax,esi
  1472.       add ebx,esi
  1473.       xor edi,edi
  1474.     .old_line:
  1475.     loop @b
  1476.  
  1477.  
  1478.   mov eax,dword[data_rgb] ;eax =
  1479.   add eax,esi ;esi = width*3(rgb)
  1480.   mov ebx,esi
  1481.   add ebx,eax
  1482.   mov ecx,dword[size] ;ecx = size
  1483.   shr ecx,1
  1484.   sub ecx,dword[size_w] ;лишняя строка пикселей
  1485.   xor edi,edi
  1486.   @@: ;поджатие пикселей
  1487.     mov edx,dword[ebx] ;копируем цвет нижнего пикселя
  1488.     mov word[eax],dx
  1489.     shr edx,16
  1490.     mov byte[eax+2],dl
  1491.  
  1492.     add eax,3
  1493.     add ebx,3
  1494.     inc edi
  1495.     cmp edi,dword[size_w]
  1496.     jl .old_line_2
  1497.       add ebx,esi
  1498.       xor edi,edi
  1499.     .old_line_2:
  1500.     loop @b
  1501.  
  1502.   ;popad
  1503.   ret
  1504. endp
  1505.  
  1506. ;преобразование буфера из 24-битного в 8-битный
  1507. ; spectr - определяет какой спектр брать при преобразовании 0-синий, 1-зеленый, 2-красный
  1508. align 4
  1509. proc buf_conv_24_to_8, buf_struc:dword, spectr:dword
  1510.         pushad
  1511.         mov edi,dword[buf_struc]
  1512.         cmp buf2d_bits,24
  1513.         jne .error
  1514.                 mov eax,buf2d_w
  1515.                 mov ecx,buf2d_h
  1516.                 imul ecx,eax
  1517.                 mov esi,ecx
  1518.                 ;ebx - память из которой копируется
  1519.                 ;edx - память куда копируется
  1520.                 mov edx,buf2d_data
  1521.                 mov ebx,edx
  1522.                 cmp [spectr],3
  1523.                 jge @f
  1524.                         add ebx,[spectr]
  1525.                 @@:
  1526.                         mov al,byte[ebx]
  1527.                         mov byte[edx],al
  1528.                         add ebx,3
  1529.                         inc edx
  1530.                         loop @b
  1531.                 mov buf2d_bits,8
  1532.                 invoke mem.realloc,buf2d_data,esi ;уменьшаем память занимаемую буфером
  1533.                 jmp .end_conv
  1534.         .error:
  1535.                 stdcall print_err,sz_buf2d_conv_24_to_8,txt_err_n24b
  1536.         .end_conv:
  1537.         popad
  1538.         ret
  1539. endp
  1540.  
  1541. ;преобразование буфера из 24-битного в 32-битный
  1542. align 4
  1543. proc buf_conv_24_to_32, buf_struc:dword, buf_str8:dword
  1544.         pushad
  1545.         mov edi,dword[buf_struc]
  1546.         cmp buf2d_bits,24
  1547.         jne .error1
  1548.                 mov ecx,buf2d_w
  1549.                 mov ebx,buf2d_h
  1550.                 imul ebx,ecx
  1551.                 mov ecx,ebx ;ecx = size  8 b
  1552.                 shl ebx,2   ;ebx = size 32 b
  1553.                 invoke mem.realloc,buf2d_data,ebx ;увеличиваем память занимаемую буфером
  1554.                 mov buf2d_data,eax ;на случай если изменился указатель на данные
  1555.                 mov buf2d_bits,32
  1556.                 mov edx,ebx ;edx = size 32 b
  1557.                 sub ebx,ecx ;ebx = size 24 b
  1558.                 mov eax,ecx
  1559.                 ;eax - размер  8 битных данных
  1560.                 ;ebx - размер 24 битных данных
  1561.                 ;edx - размер 32 битных данных
  1562.                 add ebx,buf2d_data
  1563.                 add edx,buf2d_data
  1564.                 mov edi,dword[buf_str8]
  1565.                 cmp buf2d_bits,8
  1566.                 jne .error2
  1567.                 add eax,buf2d_data
  1568.                 mov edi,edx
  1569.                 ;eax - указатель на конец  8 битных данных
  1570.                 ;ebx - указатель на конец 24 битных данных
  1571.                 ;edi - указатель на конец 32 битных данных
  1572.                 @@:
  1573.                         sub edi,4 ;отнимаем в начале цикла,
  1574.                         sub ebx,3 ; потому, что указатели стоят
  1575.                         dec eax   ; за пределами буферов
  1576.                         mov edx,dword[ebx]
  1577.                         mov dword[edi],edx
  1578.                         mov dl,byte[eax]
  1579.                         mov byte[edi+3],dl
  1580.                         loop @b
  1581.  
  1582.                 jmp .end_conv
  1583.         .error1:
  1584.                 stdcall print_err,sz_buf2d_conv_24_to_32,txt_err_n24b
  1585.                 jmp .end_conv
  1586.         .error2:
  1587.                 stdcall print_err,sz_buf2d_conv_24_to_32,txt_err_n8b
  1588.         .end_conv:
  1589.         popad
  1590.         ret
  1591. endp
  1592.  
  1593. ;функция копирует изображение из буфера buf_source (24b|32b) в buf_destination (24b)
  1594. ; указываются координаты вставки буфера buf_source относительно buf_destination
  1595. ; прозрачность при копировании не учитывается
  1596. align 4
  1597. proc buf_bit_blt, buf_destination:dword, coord_x:dword, coord_y:dword, buf_source:dword
  1598.         locals
  1599.                 right_bytes dd ?
  1600.         endl
  1601.         pushad
  1602.  
  1603.         mov edi,[buf_source]
  1604.         cmp buf2d_bits,24
  1605.         je .sou24
  1606.         cmp buf2d_bits,32
  1607.         je .sou32
  1608.                 jmp .copy_end ;формат буфера не поодерживается
  1609.  
  1610.         .sou24: ;в источнике 24 битная картинка
  1611.         mov eax,buf2d_w
  1612.         mov edx,buf2d_h ;высота копируемой картинки
  1613.         mov esi,buf2d_data ;данные копируемой картинки
  1614.  
  1615.         mov edi,[buf_destination]
  1616.         cmp buf2d_bits,24
  1617.         jne .copy_end ;формат буфера не поодерживается
  1618.         mov ebx,[coord_x] ;в ebx временно ставим отступ изображения (для проверки)
  1619.         cmp ebx,buf2d_w   ;проверяем влазит ли изображение по ширине
  1620.         jge .copy_end     ;если изображение полностью вылазит за правую сторону
  1621.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1622.                 mov ecx,[coord_y]
  1623.                 cmp ecx,ebx
  1624.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1625.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1626.                 cmp ecx,ebx
  1627.                 jle @f
  1628.                         sub ecx,ebx
  1629.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1630.                 @@:
  1631.                 mov ebx,buf2d_w
  1632.                 mov ecx,ebx ;ecx используем для временных целей
  1633.                 imul ecx,[coord_y]
  1634.                 add ecx,[coord_x]
  1635.                 lea ecx,[ecx+ecx*2]
  1636.                 add ecx,buf2d_data
  1637.                 sub ebx,eax
  1638.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1639.  
  1640.         mov [right_bytes],0
  1641.         mov ecx,[coord_x]
  1642.         cmp ecx,ebx
  1643.         jl @f
  1644.                 sub ecx,ebx
  1645.                 sub eax,ecx ;укорачиваем копируемую строку
  1646.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1647.                 lea ecx,[ecx+ecx*2] ;ecx - число байт в 1-й строке картинки, которые вылазят за правую сторону
  1648.                 mov [right_bytes],ecx
  1649.         @@:
  1650.  
  1651.         lea eax,[eax+eax*2] ;колличество байт в 1-й строке копируемой картинки
  1652.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1653.  
  1654.         cld
  1655.         cmp [right_bytes],0
  1656.         jg .copy_1
  1657.         .copy_0: ;простое копирование
  1658.                 mov ecx,eax
  1659.                 rep movsb
  1660.                 add edi,ebx
  1661.                 dec edx
  1662.                 cmp edx,0
  1663.                 jg .copy_0
  1664.         jmp .copy_end
  1665.         .copy_1: ;не простое копирование (картинка вылазит за правую сторону)
  1666.                 mov ecx,eax
  1667.                 rep movsb
  1668.                 add edi,ebx
  1669.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  1670.                 dec edx
  1671.                 cmp edx,0
  1672.                 jg .copy_1
  1673.         jmp .copy_end
  1674.  
  1675.         .sou32: ;в источнике 32 битная картинка
  1676.         mov eax,buf2d_w
  1677.         mov edx,buf2d_h ;высота копируемой картинки
  1678.         mov esi,buf2d_data ;данные копируемой картинки
  1679.  
  1680.         mov edi,[buf_destination]
  1681.         cmp buf2d_bits,24
  1682.         jne .copy_end ;формат буфера не поодерживается
  1683.         mov ebx,[coord_x] ;в ebx временно ставим отступ изображения (для проверки)
  1684.         cmp ebx,buf2d_w   ;проверяем влазит ли изображение по ширине
  1685.         jge .copy_end     ;если изображение полностью вылазит за правую сторону
  1686.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1687.                 mov ecx,[coord_y]
  1688.                 cmp ecx,ebx
  1689.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1690.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1691.                 cmp ecx,ebx
  1692.                 jle @f
  1693.                         sub ecx,ebx
  1694.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1695.                 @@:
  1696.                 mov ebx,buf2d_w
  1697.                 mov ecx,ebx ;ecx используем для временных целей
  1698.                 imul ecx,[coord_y]
  1699.                 add ecx,[coord_x]
  1700.                 lea ecx,[ecx+ecx*2]
  1701.                 add ecx,buf2d_data
  1702.                 sub ebx,eax
  1703.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1704.  
  1705.         mov [right_bytes],0
  1706.         mov ecx,[coord_x]
  1707.         cmp ecx,ebx
  1708.         jl @f
  1709.                 sub ecx,ebx
  1710.                 sub eax,ecx ;укорачиваем копируемую строку
  1711.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1712.                 shl ecx,2 ;ecx - число байт в 1-й строке картинки, которые вылазят за правую сторону
  1713.                 mov [right_bytes],ecx
  1714.         @@:
  1715.  
  1716.         ;eax - колличество пикселей в 1-й строке копируемой картинки
  1717.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1718.  
  1719.         cld
  1720.         cmp [right_bytes],0
  1721.         jg .copy_3
  1722.         .copy_2: ;простое копирование
  1723.                 mov ecx,eax
  1724.                 @@:
  1725.                         movsw
  1726.                         movsb
  1727.                         inc esi
  1728.                         loop @b
  1729.                 add edi,ebx
  1730.                 dec edx
  1731.                 cmp edx,0
  1732.                 jg .copy_2
  1733.         jmp .copy_end
  1734.         .copy_3: ;не простое копирование (картинка вылазит за правую сторону)
  1735.                 mov ecx,eax
  1736.                 @@:
  1737.                         movsw
  1738.                         movsb
  1739.                         inc esi
  1740.                         loop @b
  1741.                 add edi,ebx
  1742.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  1743.                 dec edx
  1744.                 cmp edx,0
  1745.                 jg .copy_3
  1746.  
  1747.         .copy_end:
  1748.         popad
  1749.         ret
  1750. endp
  1751.  
  1752. ;input:
  1753. ; esi = pointer to color1 + transparent
  1754. ; edi = pointer to background color2
  1755. ;output:
  1756. ; [edi] = combine color
  1757. align 4
  1758. combine_colors:
  1759.         push ax bx cx dx
  1760.         mov bx,0x00ff ;---get transparent---
  1761.         mov cl,byte[esi+3] ;pro
  1762.         xor ch,ch
  1763.         sub bx,cx ;256-pro
  1764.         ;---blye---
  1765.         xor ah,ah
  1766.         mov al,byte[esi]
  1767.         imul ax,bx
  1768.         xor dh,dh
  1769.         mov dl,byte[edi]
  1770.         imul dx,cx
  1771.         add ax,dx
  1772.         mov byte[edi],ah
  1773.         ;---green---
  1774.         xor ah,ah
  1775.         mov al,byte[esi+1]
  1776.         imul ax,bx
  1777.         xor dh,dh
  1778.         mov dl,byte[edi+1]
  1779.         imul dx,cx
  1780.         add ax,dx
  1781.         mov byte[edi+1],ah
  1782.         ;---red---
  1783.         xor ah,ah
  1784.         mov al,byte[esi+2]
  1785.         imul ax,bx
  1786.         xor dh,dh
  1787.         mov dl,byte[edi+2]
  1788.         imul dx,cx
  1789.         add ax,dx
  1790.         mov byte[edi+2],ah
  1791.  
  1792.         pop dx cx bx ax
  1793.         ret
  1794.  
  1795. ;функция копирует изображение из буфера buf_source (32b) в buf_destination (24b)
  1796. ; указываются координаты вставки буфера buf_source относительно buf_destination
  1797. ; при копировании учитывается прозрачность
  1798. align 4
  1799. proc buf_bit_blt_transp, buf_destination:dword, coord_x:dword, coord_y:dword, buf_source:dword
  1800.         locals
  1801.                 right_bytes dd ?
  1802.         endl
  1803.         pushad
  1804.  
  1805.         mov edi,[buf_source]
  1806.         cmp buf2d_bits,32
  1807.         jne .copy_end ;формат буфера не поодерживается
  1808.         mov eax,buf2d_w
  1809.         mov edx,buf2d_h ;высота копируемой картинки
  1810.         mov esi,buf2d_data ;данные копируемой картинки
  1811.  
  1812.         mov edi,[buf_destination]
  1813.         cmp buf2d_bits,24
  1814.         jne .copy_end ;формат буфера не поодерживается
  1815.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1816.                 mov ecx,[coord_y]
  1817.                 cmp ecx,ebx
  1818.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1819.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1820.                 cmp ecx,ebx
  1821.                 jle @f
  1822.                         sub ecx,ebx
  1823.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1824.                 @@:
  1825.                 mov ebx,buf2d_w
  1826.                 mov ecx,ebx ;ecx используем для временных целей
  1827.                 imul ecx,[coord_y]
  1828.                 add ecx,[coord_x]
  1829.                 lea ecx,[ecx+ecx*2]
  1830.                 add ecx,buf2d_data
  1831.                 sub ebx,eax
  1832.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1833.  
  1834.         mov [right_bytes],0
  1835.         mov ecx,[coord_x]
  1836.         cmp ecx,ebx
  1837.         jl @f
  1838.                 sub ecx,ebx
  1839.                 sub eax,ecx ;укорачиваем копируемую строку
  1840.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1841.                 shl ecx,2 ;ecx - число байт в 1-й строке картинки, которые вылазят за правую сторону
  1842.                 mov [right_bytes],ecx
  1843.         @@:
  1844.  
  1845.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1846.  
  1847.         cld
  1848.         cmp [right_bytes],0
  1849.         jg .copy_1
  1850.         .copy_0: ;простое копирование
  1851.                 mov ecx,eax
  1852.                 @@:
  1853.                         call combine_colors
  1854.                         add edi,3
  1855.                         add esi,4
  1856.                         loop @b
  1857.                 add edi,ebx
  1858.                 dec edx
  1859.                 cmp edx,0
  1860.                 jg .copy_0
  1861.         jmp .copy_end
  1862.         .copy_1: ;не простое копирование (картинка вылазит за правую сторону)
  1863.                 mov ecx,eax
  1864.                 @@:
  1865.                         call combine_colors
  1866.                         add edi,3
  1867.                         add esi,4
  1868.                         loop @b
  1869.                 add edi,ebx
  1870.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  1871.                 dec edx
  1872.                 cmp edx,0
  1873.                 jg .copy_1
  1874.  
  1875.         .copy_end:
  1876.         popad
  1877.         ret
  1878. endp
  1879.  
  1880. ;input:
  1881. ; ebx - color1
  1882. ; esi = pointer to transparent
  1883. ; edi = pointer to background color2
  1884. ;output:
  1885. ; [edi] = combine color
  1886. align 4
  1887. combine_colors_2:
  1888.         push ax ebx cx dx si
  1889.         mov cl,byte[esi] ;pro
  1890.         xor ch,ch
  1891.         mov si,0x00ff ;---get transparent---
  1892.         sub si,cx ;256-pro
  1893.  
  1894.                 ;---blye---
  1895.                 mov al,bl
  1896.                 xor ah,ah
  1897.                 shr ebx,8
  1898.                 imul ax,si
  1899.                 xor dh,dh
  1900.                 mov dl,byte[edi]
  1901.                 imul dx,cx
  1902.                 add ax,dx
  1903.                 mov byte[edi],ah
  1904.                 ;---green---
  1905.                 mov al,bl
  1906.                 xor ah,ah
  1907.                 shr ebx,8
  1908.                 imul ax,si
  1909.                 xor dh,dh
  1910.                 mov dl,byte[edi+1]
  1911.                 imul dx,cx
  1912.                 add ax,dx
  1913.                 mov byte[edi+1],ah
  1914.                 ;---red---
  1915.                 mov al,bl
  1916.                 xor ah,ah
  1917.                 imul ax,si
  1918.                 xor dh,dh
  1919.                 mov dl,byte[edi+2]
  1920.                 imul dx,cx
  1921.                 add ax,dx
  1922.                 mov byte[edi+2],ah
  1923.  
  1924.         pop si dx cx ebx ax
  1925.         ret
  1926.  
  1927. ;функция копирует изображение из буфера buf_source (8b) в buf_destination (24b)
  1928. ; указываются координаты вставки буфера buf_source относительно buf_destination
  1929. align 4
  1930. proc buf_bit_blt_alpha, buf_destination:dword, coord_x:dword, coord_y:dword, buf_source:dword, color:dword
  1931.         locals
  1932.                 right_bytes dd ?
  1933.                 dest_w_bytes dd ? ;колличество байт в буфере приемнике по ширине - ширина вставляемой картинки
  1934.         endl
  1935.         pushad
  1936.  
  1937.         mov edi,[buf_source]
  1938.         cmp buf2d_bits,8
  1939.         jne .error1 ;формат буфера не поодерживается
  1940.         mov eax,buf2d_w
  1941.         mov edx,buf2d_h ;высота копируемой картинки
  1942.         mov esi,buf2d_data ;данные копируемой картинки
  1943.  
  1944.         mov edi,[buf_destination]
  1945.         cmp buf2d_bits,24
  1946.         jne .error2 ;формат буфера не поодерживается
  1947.         mov ebx,[coord_x] ;в ebx временно ставим отступ изображения (для проверки)
  1948.         cmp ebx,buf2d_w   ;проверяем влазит ли изображение по ширине
  1949.         jge .copy_end     ;если изображение полностью вылазит за правую сторону
  1950.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1951.                 mov ecx,[coord_y]
  1952.                 cmp ecx,ebx
  1953.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1954.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1955.                 cmp ecx,ebx
  1956.                 jle @f
  1957.                         sub ecx,ebx
  1958.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1959.                 @@:
  1960.                 mov ebx,buf2d_w
  1961.                 mov ecx,ebx ;ecx используем для временных целей
  1962.                 imul ecx,[coord_y]
  1963.                 add ecx,[coord_x]
  1964.                 lea ecx,[ecx+ecx*2]
  1965.                 add ecx,buf2d_data
  1966.                 sub ebx,eax
  1967.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1968.  
  1969.         mov [right_bytes],0
  1970.         mov ecx,[coord_x]
  1971.         cmp ecx,ebx
  1972.         jl @f
  1973.                 sub ecx,ebx
  1974.                 sub eax,ecx ;укорачиваем копируемую строку
  1975.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1976.                 ;ecx - число пикселей в 1-й строке картинки, которые вылазят за правую сторону
  1977.                 mov [right_bytes],ecx
  1978.         @@:
  1979.  
  1980.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1981.         mov [dest_w_bytes],ebx
  1982.         mov ebx,[color]
  1983.  
  1984.         cld
  1985.         cmp [right_bytes],0
  1986.         jg .copy_1
  1987.         .copy_0: ;простое копирование
  1988.                 mov ecx,eax
  1989.                 @@:
  1990.                         call combine_colors_2
  1991.                         add edi,3
  1992.                         inc esi
  1993.                         loop @b
  1994.                 add edi,[dest_w_bytes]
  1995.                 dec edx
  1996.                 cmp edx,0
  1997.                 jg .copy_0
  1998.         jmp .copy_end
  1999.         .copy_1: ;не простое копирование (картинка вылазит за правую сторону)
  2000.                 mov ecx,eax
  2001.                 @@:
  2002.                         call combine_colors_2
  2003.                         add edi,3
  2004.                         inc esi
  2005.                         loop @b
  2006.                 add edi,[dest_w_bytes]
  2007.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  2008.                 dec edx
  2009.                 cmp edx,0
  2010.                 jg .copy_1
  2011.  
  2012.         jmp .copy_end
  2013.         .error1:
  2014.                 stdcall print_err,sz_buf2d_bit_blt_alpha,txt_err_n8b
  2015.                 jmp .copy_end
  2016.         .error2:
  2017.                 stdcall print_err,sz_buf2d_bit_blt_alpha,txt_err_n24b
  2018.         .copy_end:
  2019.         popad
  2020.         ret
  2021. endp
  2022.  
  2023. ;преобразование 8-битного буфера размером 16*16 в размер 1*256 символов
  2024. align 4
  2025. proc buf_convert_text_matrix, buf_struc:dword
  2026.         locals
  2027.                 tmp_mem dd ?
  2028.                 c1 dw ?
  2029.                 c2 dd ?
  2030.                 c3 dw ?
  2031.         endl
  2032.         pushad
  2033.         mov edi,dword[buf_struc]
  2034.         cmp buf2d_bits,8
  2035.         jne .error
  2036.                 mov ecx,buf2d_h
  2037.                 mov ebx,ecx
  2038.                 shr ebx,4 ;предполагаем что в буфере 16 строк с символами, потому делим на 2^4
  2039.                 mov edx,buf2d_w
  2040.                 imul ecx,edx ;ecx = size  8 b
  2041.                 invoke mem.alloc,ecx ;выделяем временную память
  2042.                 mov [tmp_mem],eax ;eax - new memory
  2043.  
  2044.                 shr edx,4 ;предполагаем что в буфере 16 колонок с символами, потому делим на 2^4
  2045.                 mov eax,ebx
  2046.                 imul ebx,edx ;вычисляем кооличество пикселей на 1 символ
  2047.                 ;eax = bhe - высота буквы
  2048.                 ;ebx = bwi*bhe - колличество пикселей в 1-й букве
  2049.                 ;edx = bwi - ширина буквы
  2050.                 ;ecx,esi,edi - используются в цикле .c_0
  2051.                 shr buf2d_w,4
  2052.                 shl buf2d_h,4 ;преобразовываем размеры буфера
  2053.  
  2054.                 cld
  2055.                 mov esi,buf2d_data
  2056.                 mov edi,[tmp_mem]
  2057.                 mov word[c3],16
  2058.                 .c_3:
  2059.                         mov dword[c2],eax
  2060.                         .c_2:
  2061.                                 mov word[c1],16
  2062.                                 .c_1:
  2063.                                         mov ecx,edx ;.c_0:
  2064.                                         rep movsb
  2065.                                         add edi,ebx
  2066.                                         sub edi,edx ;edi+=(bwi*bhe-bwi)
  2067.                                         dec word[c1]
  2068.                                         cmp word[c1],0
  2069.                                         jg .c_1
  2070.                                 add edi,edx
  2071.                                 shl ebx,4
  2072.                                 sub edi,ebx ;edi-=(16*bwi*bhe-bwi)
  2073.                                 shr ebx,4
  2074.                                 dec dword[c2]
  2075.                                 cmp dword[c2],0
  2076.                                 jg .c_2
  2077.                         sub edi,ebx
  2078.                         shl ebx,4
  2079.                         add edi,ebx ;edi+=(15*bwi*bhe)
  2080.                         shr ebx,4
  2081.                         dec word[c3]
  2082.                         cmp word[c3],0
  2083.                         jg .c_3
  2084.  
  2085.                 mov edi,dword[buf_struc] ;копирование новой матрицы в основной буфер
  2086.                 mov edi,buf2d_data
  2087.                 mov esi,[tmp_mem]
  2088.                 mov ecx,ebx
  2089.                 shl ecx,8
  2090.                 rep movsb
  2091.                 invoke mem.free,[tmp_mem] ;чистим временную память
  2092.                 jmp .end_conv
  2093.         .error:
  2094.                 stdcall print_err,sz_buf2d_convert_text_matrix,txt_err_n8b
  2095.         .end_conv:
  2096.         popad
  2097.         ret
  2098. endp
  2099.  
  2100. align 4
  2101. buf_s_matr buf_2d_header ? ;локальная матрица символа
  2102.  
  2103. align 4
  2104. proc buf_draw_text, buf_struc:dword, buf_t_matr:dword, text:dword, coord_x:dword, coord_y:dword, color:dword
  2105.         locals
  2106.                 buf_t_matr_offs dd ?
  2107.         endl
  2108.         pushad
  2109.         mov edi,dword[buf_struc]
  2110.         cmp buf2d_bits,24
  2111.         jne .error2
  2112.         mov edi,dword[buf_t_matr]
  2113.         cmp buf2d_bits,8
  2114.         jne .error1
  2115.                 mov edx,buf2d_data
  2116.                 mov [buf_t_matr_offs],edx
  2117.                 mov ecx,BUF_STRUCT_SIZE ;копируем структуру текстовой матрицы
  2118.                 mov esi,edi
  2119.                 lea edi,[buf_s_matr]
  2120.                 cld
  2121.                 rep movsb
  2122.                 lea edi,[buf_s_matr]
  2123.                 shr buf2d_h,8 ;делим высоту символьного буфера на 256, для нахождения высоты 1-го символа
  2124.                 mov ebx,buf2d_h ;берем высоту символа
  2125.                 mov ecx,buf2d_w ;берем ширину символа
  2126.  
  2127.                 mov eax,[coord_x]
  2128.                 mov esi,[text]
  2129.                 cmp byte[esi],0
  2130.                 je .end_draw ;если пустая строка
  2131.                 @@:
  2132.                         xor edx,edx
  2133.                         mov dl,byte[esi] ;берем код символа
  2134.                         imul edx,ebx ;умножаем его на высоту символа
  2135.                         imul edx,ecx ;умножаем на ширину символа
  2136.                         add edx,[buf_t_matr_offs] ;прибавляем смещение 0-го символа, т. е. получается смещение выводимого символа
  2137.                         mov buf2d_data,edx ;в локальный буфер символа, ставим указатель на нужный символ из буфера buf_t_matr
  2138.                         stdcall buf_bit_blt_alpha, [buf_struc], eax,[coord_y], edi,[color]
  2139.                         add eax,ecx
  2140.                         .new_s:
  2141.                                 inc esi
  2142.                                 cmp byte[esi],13
  2143.                                 jne .no_13
  2144.                                         mov eax,[coord_x]
  2145.                                         add [coord_y],ebx
  2146.                                         jmp .new_s
  2147.                                 .no_13:
  2148.                         cmp byte[esi],0
  2149.                         jne @b
  2150.                 jmp .end_draw
  2151.         .error1:
  2152.                 stdcall print_err,sz_buf2d_draw_text,txt_err_n8b
  2153.                 jmp .end_draw
  2154.         .error2:
  2155.                 stdcall print_err,sz_buf2d_draw_text,txt_err_n24b
  2156.         .end_draw:
  2157.         popad
  2158.         ret
  2159. endp
  2160.  
  2161. align 4
  2162. proc print_err, fun:dword, mes:dword ;выводим сообщение об шибке на доску отладки
  2163.         pushad
  2164.         mov eax,63
  2165.         mov ebx,1
  2166.  
  2167.         mov esi,[fun]
  2168.         @@:
  2169.                 mov cl,byte[esi]
  2170.                 int 0x40
  2171.                 inc esi
  2172.                 cmp byte[esi],0
  2173.                 jne @b
  2174.         mov cl,':'
  2175.         int 0x40
  2176.         mov cl,' '
  2177.         int 0x40
  2178.         mov esi,[mes]
  2179.         @@:
  2180.                 mov cl,byte[esi]
  2181.                 int 0x40
  2182.                 inc esi
  2183.                 cmp byte[esi],0
  2184.                 jne @b
  2185.         popad
  2186.         ret
  2187. endp
  2188.  
  2189. ;input:
  2190. ; ebp+8  = p0
  2191. ; ebp+12 = p1
  2192. align 4
  2193. line_len4i:
  2194.         push ebp
  2195.         mov ebp,esp
  2196.                 finit
  2197.                 fild word [ebp+8]
  2198.                 fisub word [ebp+12]
  2199.                 fmul st0,st0 ;st0=x^2
  2200.                 fild word [ebp+10]
  2201.                 fisub word [ebp+14]
  2202.                 fmul st0,st0 ;st0=y^2
  2203.                 fadd st0,st1
  2204.                 fsqrt
  2205.                 fstp dword [ebp+12]
  2206.         pop ebp
  2207.         ret 4 ;8
  2208.  
  2209. align 4
  2210. proc buf_curve_bezier, buffer:dword, coord_p0:dword,coord_p1:dword,coord_p2:dword, color:dword
  2211.         locals
  2212.                 delt_t dd ?
  2213.                 opr_param dd ?
  2214.                 v_poi_0 dd ?
  2215.         endl
  2216.         pushad
  2217.  
  2218. ;float t, xt,yt;
  2219. ;for(t=.0;t<1.;t+=.005){
  2220. ;  xt=pow(1.-t,2)*x0+2*t*(1.-t)*x1+pow(t,2)*x2;
  2221. ;  yt=pow(1.-t,2)*y0+2*t*(1.-t)*y1+pow(t,2)*y2;
  2222. ;  dc.SetPixel(xt,yt,255L);
  2223. ;}
  2224.  
  2225.         mov edx,[color] ;set curve color
  2226.         mov edi,[buffer]
  2227.         xor ebx,ebx
  2228.         xor ecx,ecx
  2229.  
  2230.         finit
  2231.  
  2232.         ; calculate delta t
  2233.         stdcall line_len4i, dword[coord_p1],dword[coord_p0]
  2234.         fadd dword[esp]
  2235.         add esp,4 ;pop ...
  2236.  
  2237.         stdcall line_len4i, dword[coord_p2],dword[coord_p1]
  2238.         fadd dword[esp]
  2239.         add esp,4 ;pop ...
  2240.  
  2241.         fadd st0,st0 ; len*=2
  2242.         ftst
  2243.         fstsw ax
  2244.  
  2245.         fld1
  2246.         sahf
  2247.         jle @f ;избегаем деления на 0
  2248.                 fdiv st0,st1
  2249.         @@:
  2250.         fstp dword[delt_t]
  2251.  
  2252.         finit
  2253.  
  2254.         ;fild word[coord_p2+2] ;y2
  2255.         fild word[coord_p1+2] ;y1
  2256.         fild word[coord_p0+2] ;y0
  2257.         fild word[coord_p2] ;x2
  2258.         fild word[coord_p1] ;x1
  2259.         fild word[coord_p0] ;x0
  2260.         fld dword[delt_t]
  2261.         fldz ;t=.0
  2262.  
  2263.         @@:
  2264.                 fld1
  2265.                 fsub st0,st1 ;1.-t
  2266.                 fmul st0,st0 ;pow(1.-t,2)
  2267.                 fmul st0,st3 ;...*x0
  2268.                 fstp dword[opr_param]
  2269.  
  2270.                 fld1
  2271.                 fsub st0,st1 ;1.-t
  2272.                 fmul st0,st1 ;(1.-t)*t
  2273.                 fadd st0,st0
  2274.                 fmul st0,st4 ;...*x1
  2275.                 mov esi,dword[opr_param]
  2276.                 fstp dword[opr_param]
  2277.  
  2278.                 fldz
  2279.                 fadd st0,st1 ;0+t
  2280.                 fmul st0,st0 ;t*t
  2281.                 fmul st0,st5 ;...*x2
  2282.  
  2283.                 fadd dword[opr_param]
  2284.                 mov dword[opr_param],esi
  2285.                 fadd dword[opr_param]
  2286.                 fistp word[v_poi_0] ;x
  2287.  
  2288.                 fld1
  2289.                 fsub st0,st1 ;1.-t
  2290.                 fmul st0,st0 ;pow(1.-t,2)
  2291.                 fmul st0,st6 ;...*y0
  2292.                 fstp dword[opr_param]
  2293.  
  2294.                 fld1
  2295.                 fsub st0,st1 ;1.-t
  2296.                 fmul st0,st1 ;(1.-t)*t
  2297.                 fadd st0,st0
  2298.                 fmul st0,st7 ;...*y1
  2299.                 mov esi,dword[opr_param]
  2300.                 fstp dword[opr_param]
  2301.  
  2302.                 fldz
  2303.                 fadd st0,st1 ;0+t
  2304.                 fmul st0,st0 ;t*t
  2305.                 fimul word[coord_p2+2] ;...*y2
  2306.  
  2307.                 fadd dword[opr_param]
  2308.                 mov dword[opr_param],esi
  2309.                 fadd dword[opr_param]
  2310.                 fistp word[v_poi_0+2] ;y
  2311.  
  2312.                 mov eax,1
  2313.                 mov bx,word[v_poi_0+2]
  2314.                 mov cx,word[v_poi_0]
  2315.                 call draw_pixel
  2316.  
  2317.                 fadd st0,st1 ;t+dt
  2318.  
  2319.                 fld1
  2320.                 fcomp
  2321.                 fstsw ax
  2322.                 sahf
  2323.         jae @b
  2324.  
  2325.         popad
  2326.         ret
  2327. endp
  2328.  
  2329. txt_err_n8b db 'need buffer 8 bit',13,10,0
  2330. txt_err_n24b db 'need buffer 24 bit',13,10,0
  2331.  
  2332. align 16
  2333. EXPORTS:
  2334.         dd sz_lib_init, lib_init
  2335.         dd sz_buf2d_create, buf_create
  2336.         dd sz_buf2d_create_f_img, buf_create_f_img
  2337.         dd sz_buf2d_clear, buf_clear
  2338.         dd sz_buf2d_draw, buf_draw_buf
  2339.         dd sz_buf2d_delete, buf_delete
  2340.         dd sz_buf2d_resize, buf_resize
  2341.         dd sz_buf2d_line, buf_line_brs
  2342.         dd sz_buf2d_rect_by_size, buf_rect_by_size
  2343.         dd sz_buf2d_filled_rect_by_size, buf_filled_rect_by_size
  2344.         dd sz_buf2d_circle, buf_circle
  2345.         dd sz_buf2d_img_hdiv2, buf_img_hdiv2
  2346.         dd sz_buf2d_img_wdiv2, buf_img_wdiv2
  2347.         dd sz_buf2d_conv_24_to_8, buf_conv_24_to_8
  2348.         dd sz_buf2d_conv_24_to_32, buf_conv_24_to_32
  2349.         dd sz_buf2d_bit_blt, buf_bit_blt
  2350.         dd sz_buf2d_bit_blt_transp, buf_bit_blt_transp
  2351.         dd sz_buf2d_bit_blt_alpha, buf_bit_blt_alpha
  2352.         dd sz_buf2d_curve_bezier, buf_curve_bezier
  2353.         dd sz_buf2d_convert_text_matrix, buf_convert_text_matrix
  2354.         dd sz_buf2d_draw_text, buf_draw_text
  2355.         dd sz_buf2d_crop_color, buf_crop_color
  2356.         dd sz_buf2d_offset_h, buf_offset_h
  2357.         dd sz_buf2d_flood_fill, buf_flood_fill
  2358.         dd sz_buf2d_set_pixel, buf_set_pixel
  2359.         dd 0,0
  2360.         sz_lib_init db 'lib_init',0
  2361.         sz_buf2d_create db 'buf2d_create',0
  2362.         sz_buf2d_create_f_img db 'buf2d_create_f_img',0
  2363.         sz_buf2d_clear db 'buf2d_clear',0 ;очистка буфера указанным цветом
  2364.         sz_buf2d_draw db 'buf2d_draw',0
  2365.         sz_buf2d_delete db 'buf2d_delete',0
  2366.         sz_buf2d_resize db 'buf2d_resize',0
  2367.         sz_buf2d_line db 'buf2d_line',0 ;рисование линии
  2368.         sz_buf2d_rect_by_size db 'buf2d_rect_by_size',0 ;рисование рамки прямоугольника, 2-я координата задана по размеру
  2369.         sz_buf2d_filled_rect_by_size db 'buf2d_filled_rect_by_size',0 ;рисование залитого прямоугольника, 2-я координата задана по размеру
  2370.         sz_buf2d_circle db 'buf2d_circle',0 ;рисование окружности
  2371.         sz_buf2d_img_hdiv2 db 'buf2d_img_hdiv2',0 ;сжатие изображения по высоте в 2 раза (размер буфера не меняется)
  2372.         sz_buf2d_img_wdiv2 db 'buf2d_img_wdiv2',0 ;сжатие изображения по ширине в 2 раза (размер буфера не меняется)
  2373.         sz_buf2d_conv_24_to_8 db 'buf2d_conv_24_to_8',0
  2374.         sz_buf2d_conv_24_to_32 db 'buf2d_conv_24_to_32',0
  2375.         sz_buf2d_bit_blt db 'buf2d_bit_blt',0
  2376.         sz_buf2d_bit_blt_transp db 'buf2d_bit_blt_transp',0
  2377.         sz_buf2d_bit_blt_alpha db 'buf2d_bit_blt_alpha',0
  2378.         sz_buf2d_curve_bezier db 'buf2d_curve_bezier',0
  2379.         sz_buf2d_convert_text_matrix db 'buf2d_convert_text_matrix',0
  2380.         sz_buf2d_draw_text db 'buf2d_draw_text',0
  2381.         sz_buf2d_crop_color db 'buf2d_crop_color',0
  2382.         sz_buf2d_offset_h db 'buf2d_offset_h',0
  2383.         sz_buf2d_flood_fill db 'buf2d_flood_fill',0
  2384.         sz_buf2d_set_pixel db 'buf2d_set_pixel',0
  2385.  
  2386.