Subversion Repositories Kolibri OS

Rev

Rev 8532 | Rev 8852 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ; макрос для системной библиотеки box_lib.obj
  2. ; элемент TextEditor для Kolibri OS
  3. ; файл последний раз изменялся 12.01.2021 IgorA
  4. ; на код применена GPL2 лицензия
  5.  
  6. ;input:
  7. ; edi = pointer to tedit struct
  8. ; reg = index
  9. ;output:
  10. ; reg = pointer to 'tex' struct
  11. macro ConvertIndexToPointer reg {
  12.         imul reg,sizeof.symbol
  13.         add reg,ted_tex
  14. }
  15.  
  16. ;--- out_reg = ted_key_words_data[ind_reg].Text[0] ---
  17. macro ColToIndexOffset ind_reg,out_reg {
  18.         mov out_reg,ind_reg
  19.         imul out_reg,sizeof.TexColViv
  20.         add out_reg,ted_key_words_data
  21. }
  22.  
  23. TED_LINES_IN_NEW_FILE equ 30 ;число строк в новом файле
  24. MAX_COLOR_WORD_LEN equ 40
  25. ;------------------------------------------------------------------------------
  26. struct TexSelect
  27.         x0 dd ?
  28.         y0 dd ?
  29.         x1 dd ?
  30.         y1 dd ?
  31. ends
  32.  
  33. struct TexColViv
  34.         Text  rb MAX_COLOR_WORD_LEN ; слово для подсветки
  35.         f1    dd 0 ; справка по слову
  36.         flags db ? ; f1+4 флаги используемые при выделении
  37.         endc  db ? ; f1+5 символ конца выделения (используется при flags&4)
  38.         escc  db ? ; f1+6 экранирующий символ (используется при flags&4)
  39.         color db ? ; f1+7 номер цвета
  40. ends
  41.  
  42. struct symbol
  43.         c db ?    ;  +0 символ
  44.         col db ?  ;  +1 цвет
  45.         perv dd ? ;  +2
  46.         next dd ? ;  +6 указатели
  47.         tc dd ?   ; +10 врем. создания
  48.         td dd ?   ; +14 врем. удаления
  49. ends
  50. ;------------------------------------------------------------------------------
  51.  
  52. ted_symbol_space db 32 ;ascii код пробела, иногда бывает нужен в коде
  53. ted_symbol_tab db 26 ;ascii код стрелки вправо, используется для рисования табуляции в режиме показа невидимых символов
  54.  
  55. if lang eq ru
  56.  
  57. txtRow db 'Строка',0
  58. txtCol db 'Знак',0
  59. txtOtm db 'Отмены',0
  60. txtBuf db 'Буфер:',0
  61.  
  62. else
  63.  
  64. txtRow db 'Rows',0
  65. txtCol db 'Cols',0
  66. txtOtm db 'Undo',0
  67. txtBuf db 'Buffer:',0
  68.  
  69. end if
  70.  
  71. ;EvChar - таблица для фильтрования добавляемых символов, что-бы не попали лишние знаки
  72. align 16
  73. EvChar db 0,0,0,0,0,0,0,0,0,1,0,0,0,1,0,0
  74.     db 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  75.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  76.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  77.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  78.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  79.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  80.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,0
  81.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  82.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  83.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  84.     db 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  85.     db 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  86.     db 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  87.     db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
  88.     db 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  89.  
  90. KM_SHIFT equ 0x00010000
  91. KM_CTRL equ 0x00020000
  92. KM_ALT equ 0x00040000
  93. KM_NUMLOCK equ 0x00080000
  94.  
  95. ; KEY CODES
  96. KEY_F1 equ 0x0000003B
  97. KEY_F2 equ 0x0000003C
  98. KEY_F3 equ 0x0000003D
  99.  
  100.  
  101.  
  102. align 16
  103. proc ted_init uses eax ecx edi, edit:dword
  104.         mov edi,[edit]
  105.  
  106.         mov ecx,sizeof.symbol
  107.         imul ecx,ted_max_chars
  108.         invoke mem.alloc,ecx ;выделяем память
  109.         mov ted_tex,eax
  110.         mov ted_tex_1,eax
  111.         add ted_tex_1,sizeof.symbol
  112.         add eax,ecx
  113.         mov ted_tex_end,eax
  114.  
  115.         stdcall ted_clear, edi,1
  116.  
  117. ;-------------------------------------------------
  118.         mov ecx,1024 ;1024 - для массива ted_arr_key_pos
  119.         add ecx,ted_syntax_file_size
  120.         invoke mem.alloc,ecx
  121.         mov ted_arr_key_pos,eax
  122.         add eax,1024
  123.         mov ted_syntax_file,eax
  124.  
  125.         stdcall ted_init_scroll_bars,edi,3
  126.         ret
  127. endp
  128.  
  129. MIN_W_SCRL_ARE equ 3 ;минимальная отображаемая область для верт. скроллинга
  130. MIN_H_SCRL_ARE equ 3 ;минимальная отображаемая область для гориз. скроллинга
  131. ;input:
  132. ; opt = 1 - менять цвет скроллингов, 2 - изменились размеры окна,
  133. ;  4 - изменились размеры документа
  134. align 16
  135. proc ted_init_scroll_bars, edit:dword, opt:dword
  136.         pushad
  137.         mov edi,[edit]
  138.         mov esi,ted_scr_w
  139.         mov ebx,ted_scr_h
  140.         bt dword[opt],0
  141.         jae @f
  142.                 mov ecx,ted_color_wnd_work
  143.                 mov dword[esi+sb_offs_bckg_col],ecx
  144.                 mov dword[ebx+sb_offs_bckg_col],ecx
  145.                 mov ecx,ted_color_wnd_capt
  146.                 mov dword[esi+sb_offs_frnt_col],ecx
  147.                 mov dword[ebx+sb_offs_frnt_col],ecx
  148.                 mov ecx,ted_color_wnd_bord
  149.                 mov dword[esi+sb_offs_line_col],ecx
  150.                 mov dword[ebx+sb_offs_line_col],ecx
  151.         @@:
  152.         bt dword[opt],2 ; изменились размеры документа ?
  153.         jae .doc_resize
  154.                 call ted_get_num_lines
  155.                 cmp eax,TED_LINES_IN_NEW_FILE
  156.                 jge @f
  157.                         mov eax,TED_LINES_IN_NEW_FILE
  158.                 @@:
  159.                 mov dword[esi+sb_offs_max_area],eax
  160.         .doc_resize:
  161.         bt dword[opt],1 ; изменились размеры окна ?
  162.         jae .no_size
  163.                         mov edx,ted_wnd_l
  164.                         add edx,ted_rec_l
  165.                         mov word[ebx+sb_offs_start_x],dx ;выставляем левый отступ гориз. скроллинга
  166.                         mov eax,ted_wnd_h ;calculate lines in page
  167.                         mov edx,ted_wnd_t
  168.                         add edx,eax
  169.                         mov word[ebx+sb_offs_start_y],dx ;выставляем верхний отступ гориз. скроллинга
  170.                 sub eax,ted_rec_t
  171.                 xor edx,edx
  172.                 mov ecx,ted_rec_h
  173.                 div ecx
  174.                 cmp eax,MIN_W_SCRL_ARE
  175.                 jg @f
  176.                         mov eax,MIN_W_SCRL_ARE
  177.                 @@:
  178.                 mov dword[esi+sb_offs_cur_area],eax
  179.  
  180.                 mov eax,ted_wnd_w ;calculate cols in page
  181.                         mov edx,ted_wnd_l ;левый отступ окна
  182.                         add edx,eax ;добавляем ширину окна
  183.                         mov word[esi+sb_offs_start_x],dx ;выставляем левый отступ верт. скроллинга
  184.                         mov edx,ted_wnd_t
  185.                         mov word[esi+sb_offs_start_y],dx ;выставляем верхний отступ верт. скроллинга
  186.                         mov edx,ted_wnd_h
  187.                         mov word[esi+sb_offs_size_y],dx ;выставляем высоту верт. скроллинга
  188.                 sub eax,ted_rec_l
  189.                         mov word[ebx+sb_offs_size_x],ax ;выставляем ширину гориз. скроллинга
  190.                 xor edx,edx
  191.                 mov ecx,ted_rec_w
  192.                 div ecx
  193.                 cmp eax,MIN_H_SCRL_ARE
  194.                 jg @f
  195.                         mov eax,MIN_H_SCRL_ARE
  196.                 @@:
  197.                 dec eax
  198.                 mov dword[ebx+sb_offs_cur_area],eax ;устанавливаем число символов, которые влазят в экран для гориз. скроллинга
  199.         .no_size:
  200.         popad
  201.         ret
  202. endp
  203.  
  204. align 16
  205. proc ted_delete uses edi, edit:dword
  206.         mov edi,[edit]
  207.         invoke mem.free,ted_tex
  208.         invoke mem.free,ted_arr_key_pos ;ted_syntax_file
  209.         ret
  210. endp
  211.  
  212.  
  213. ;input:
  214. ; eax = key kodes
  215. align 16
  216. proc ted_key, edit:dword, table:dword, control:dword
  217.         pushad
  218.         mov edi,[edit]
  219.         mov esi,ted_el_focus
  220.         cmp dword[esi],edi
  221.         jne .end_key_fun ;элемент не в фокусе выходим из функции
  222.         mov esi,dword[control]
  223.  
  224.         cmp ah,KEY_F1 ;[F1]
  225.         jne @f
  226.                 stdcall ted_show_help_f1,edi
  227.                 jmp .end_key_fun
  228.         @@:
  229.         cmp ah,KEY_F3 ;[F3]
  230.         jne @f
  231.                 stdcall ted_but_find,edi,0
  232.                 jmp .end_key_fun
  233.         @@:
  234.  
  235.         test esi,KM_CTRL ;Ctrl+...
  236.         jz .key_Ctrl
  237.                 ; *** вызов внешних функций которые требуют окна открытия/сохранения/поиска/...
  238.                 cmp ted_fun_on_key_ctrl_all,0
  239.                 je .end0
  240.                 xor al,al
  241.                 cmp ah,24 ;Ctrl+O
  242.                 jne @f
  243.                         mov al,'O'
  244.                 @@:
  245.                 cmp ah,31 ;Ctrl+S
  246.                 jne @f
  247.                         mov al,'S'
  248.                 @@:
  249.                 cmp ah,33 ;Ctrl+F
  250.                 jne @f
  251.                         mov al,'F'
  252.                 @@:
  253.                 cmp ah,34 ;Ctrl+G
  254.                 jne @f
  255.                         mov al,'G'
  256.                 @@:
  257.                 cmp ah,35 ;Ctrl+H
  258.                 jne @f
  259.                         mov al,'H'
  260.                 @@:
  261.                 cmp ah,49 ;Ctrl+N
  262.                 jne @f
  263.                         mov al,'N'
  264.                 @@:
  265.                 or al,al
  266.                 jz .end0
  267.                         and eax,0xff
  268.                         test esi,KM_SHIFT
  269.                         jz @f
  270.                                 or eax,0x100
  271.                         @@:
  272.                         stdcall ted_fun_on_key_ctrl_all, eax
  273.                         jmp .end_key_fun
  274.                 .end0:
  275.  
  276.                 ; *** вызов внутренних функций
  277.                 cmp ah,30 ;Ctrl+A
  278.                 jne @f
  279.                         call ted_sel_all
  280.                 @@:
  281.                 cmp ah,44 ;Ctrl+Z
  282.                 jne @f
  283.                         stdcall ted_but_undo,edi
  284.                 @@:
  285.                 cmp ah,45 ;Ctrl+X
  286.                 jne @f
  287.                         stdcall ted_but_cut,edi
  288.                 @@:
  289.                 cmp ah,46 ;Ctrl+C
  290.                 jne @f
  291.                         stdcall ted_but_copy,edi
  292.                 @@:
  293.                 cmp ah,47 ;Ctrl+V
  294.                 jne @f
  295.                         stdcall ted_but_paste,edi
  296.                 @@:
  297.                 cmp ah,199 ;Ctrl+Home
  298.                 jne @f
  299.                         call ted_key_ctrl_home
  300.                 @@:
  301.                 cmp ah,207 ;Ctrl+End
  302.                 jne @f
  303.                         call ted_key_ctrl_end
  304.                 @@:
  305.                 jmp .end_key_fun
  306.         .key_Ctrl:
  307.  
  308.         test esi,KM_SHIFT ;Shift+...
  309.         jz .key_Shift
  310.                 cmp ah,72 ;Shift+Up
  311.                 jne @f
  312.                         call ted_sel_key_up
  313.                 @@:
  314.                 cmp ah,75 ;Shift+Left
  315.                 jne @f
  316.                         call ted_sel_key_left
  317.                 @@:
  318.                 cmp ah,77 ;Shift+Right
  319.                 jne @f
  320.                         call ted_sel_key_right
  321.                 @@:
  322.                 cmp ah,80 ;Shift+Down
  323.                 jne @f
  324.                         call ted_sel_key_down
  325.                 @@:
  326.                 ;mov ted_drag_k,1 ;начинаем выделение от клавиатуры
  327.                 jmp .key_MoveCur
  328.         .key_Shift:
  329. ;-------------------------------------------------
  330.         cmp ah,72 ;178 ;Up
  331.         jne @f
  332.                 call ted_draw_cursor_sumb
  333.                 call ted_cur_move_up
  334.                 cmp dl,8
  335.                 jne .no_red_0
  336.                         call ted_scroll_set_redraw
  337.                         stdcall ted_draw,edi
  338.                         jmp @f
  339.                 .no_red_0:
  340.                 call ted_sel_end
  341.         @@:
  342.         cmp ah,80 ;177 ;Down
  343.         jne @f
  344.                 call ted_draw_cursor_sumb
  345.                 call ted_cur_move_down
  346.                 cmp dl,8
  347.                 jne .no_red_1
  348.                         call ted_scroll_set_redraw
  349.                         stdcall ted_draw,edi
  350.                         jmp @f
  351.                 .no_red_1:
  352.                 call ted_sel_end
  353.         @@:
  354.         cmp ah,75 ;176 ;Left
  355.         jne @f
  356.                 call ted_draw_cursor_sumb
  357.                 call ted_cur_move_left
  358.                 cmp dl,8
  359.                 jne .no_red_2
  360.                         call ted_scroll_set_redraw
  361.                         stdcall ted_draw,edi
  362.                         jmp @f
  363.                 .no_red_2:
  364.                 call ted_sel_end
  365.         @@:
  366.         cmp ah,77 ;179 ;Right
  367.         jne @f
  368.                 call ted_draw_cursor_sumb
  369.                 call ted_cur_move_right
  370.                 cmp dl,8
  371.                 jne .no_red_3
  372.                         call ted_scroll_set_redraw
  373.                         stdcall ted_draw,edi
  374.                         jmp @f
  375.                 .no_red_3:
  376.                 call ted_sel_end
  377.         @@:
  378.         cmp ah,71 ;180 ;Home
  379.         jne @f
  380.                 call ted_draw_cursor_sumb
  381.                 call ted_cur_move_x_first_char
  382.                 cmp dl,8
  383.                 jne .no_red_4
  384.                         call ted_scroll_set_redraw
  385.                         stdcall ted_draw,edi
  386.                         jmp @f
  387.                 .no_red_4:
  388.                 call ted_sel_end
  389.         @@:
  390.         cmp ah,79 ;181 ;End
  391.         jne @f
  392.                 call ted_draw_cursor_sumb
  393.                 call ted_cur_move_x_last_char
  394.                 cmp dl,8
  395.                 jne .no_red_5
  396.                         call ted_scroll_set_redraw
  397.                         stdcall ted_draw,edi
  398.                         jmp @f
  399.                 .no_red_5:
  400.                 call ted_sel_end
  401.         @@:
  402.         cmp ah,73 ;184 ;PageUp
  403.         jne @f
  404.                 call ted_cur_move_page_up
  405.                 cmp dl,0
  406.                 je @f
  407.                 call ted_scroll_set_redraw
  408.                 stdcall ted_draw,edi
  409.                 mov ted_drag_k,0 ;заканчиваем выделение от клавиатуры
  410.         @@:
  411.         cmp ah,81 ;183 ;PageDown
  412.         jne @f
  413.                 call ted_cur_move_page_down
  414.                 cmp dl,0
  415.                 je @f
  416.                 call ted_scroll_set_redraw
  417.                 stdcall ted_draw,edi
  418.                 mov ted_drag_k,0 ;заканчиваем выделение от клавиатуры
  419.         @@:
  420. ;-------------------------------------------------
  421.         .key_MoveCur:
  422.  
  423.         ;ниже пропускаются служебные клавиши, которые могут давать мусорные символы в окно
  424.         cmp ah,42 ;[L Shift] когда нажат без других кнопок
  425.         je .end_key_fun
  426.         cmp ah,54 ;[R Shift] когда нажат без других кнопок
  427.         je .end_key_fun
  428.         cmp ah,58 ;[Caps Lock]
  429.         je .end_key_fun
  430.         cmp ah,69 ;[Pause Break]
  431.         je .end_key_fun
  432.         cmp ah,120 ;[Fn]
  433.         je .end_key_fun
  434.         cmp ah,0x80 ;if key up
  435.         ja .end_key_fun
  436.  
  437.         cmp dword[table],0
  438.         je @f
  439.                 stdcall KeyConvertToASCII, [table]
  440.         @@:
  441.  
  442.         ;mov ted_drag_k,0 ;заканчиваем выделение от клавиатуры
  443.  
  444.         lea edx,[EvChar] ;берем адрес таблицы с допустимыми символами
  445.         add dl,ah
  446.         jae @f
  447.                 add edx,0x100 ;если было переполнение при добавлении кода символа
  448.         @@:
  449.         cmp byte[edx],1
  450.         jne @f
  451.                 mov ted_key_new,ah
  452.                 call ted_set_undo
  453.                 mov edx,ted_opt_ed_change_time+ted_opt_ed_move_cursor
  454.                 stdcall ted_sel_text_del,edx
  455.                 cmp al,1
  456.                 jne .del
  457.                         mov edx,ted_opt_ed_move_cursor
  458.                 .del:
  459.                 cmp ted_cur_ins,1
  460.                 je .no_ins_mod
  461.                         stdcall ted_text_del,edi,ted_opt_ed_change_time
  462.                         mov edx,ted_opt_ed_move_cursor
  463.                 .no_ins_mod:
  464.                 mov ecx,edi
  465.                 add ecx,ted_offs_key_new
  466.                 stdcall ted_text_add,edi,ecx,1,edx ;добавляем символ введенный с клавиатуры
  467.                 cmp ted_key_new,13
  468.                 jne .dr_m_win
  469.                         ;если вставили символ новой строки
  470.                         mov ecx,ted_scr_w
  471.                         inc dword[ecx+sb_offs_max_area] ;увеличиваем размер вертикального скроллинга
  472.                         mov edx,ted_cur_y
  473.                         cmp edx,[ecx+sb_offs_cur_area]
  474.                         jl .no_change
  475.                                 dec ted_cur_y ;курсор оставляем на месте
  476.                                 inc dword[ecx+sb_offs_position] ;сдвигаем ползунок
  477.                         .no_change:
  478.                         stdcall ted_draw,edi
  479.                         jmp .dr_cur_l
  480.                 .dr_m_win:
  481.                         stdcall ted_draw_cur_line,edi
  482.                 .dr_cur_l:
  483.                 cmp ted_fun_draw_panel_buttons,0
  484.                 je @f
  485.                         call ted_fun_draw_panel_buttons
  486.         @@:
  487.  
  488.         cmp ah,8 ;[<-]
  489.         jne @f
  490.                 call ted_set_undo
  491.                 stdcall ted_sel_text_del,ted_opt_ed_change_time
  492.                 cmp al,1
  493.                 je .del_one_b
  494.                         stdcall ted_text_del,edi,ted_opt_ed_change_time+ted_opt_ed_move_cursor
  495.                 .del_one_b:
  496.                 stdcall ted_draw,edi
  497.                 cmp ted_fun_draw_panel_buttons,0
  498.                 je .end_key_fun
  499.                         call ted_fun_draw_panel_buttons
  500.                 jmp .end_key_fun
  501. align 4
  502.         @@:
  503.  
  504.         cmp ah,182 ;Delete
  505.         jne @f
  506.                 call ted_set_undo
  507.                 stdcall ted_sel_text_del,ted_opt_ed_change_time
  508.                 cmp al,1
  509.                 je .del_one_d
  510.                         stdcall ted_text_del,edi,ted_opt_ed_change_time
  511.                 .del_one_d:
  512.                 stdcall ted_draw,edi
  513.                 cmp ted_fun_draw_panel_buttons,0
  514.                 je .end_key_fun
  515.                         call ted_fun_draw_panel_buttons
  516.                 jmp .end_key_fun
  517.         @@:
  518.  
  519.         cmp ah,185 ;Ins
  520.         jne @f
  521.                 call ted_draw_cursor_sumb
  522.                 xor ted_cur_ins,1
  523.                 call ted_draw_main_cursor
  524.         @@:
  525.  
  526.         .end_key_fun:
  527.         popad
  528.         ret
  529. endp
  530.  
  531. ;output:
  532. ; al = 1 - can save
  533. align 16
  534. proc ted_can_save uses ecx edi, edit:dword
  535.         mov edi,[edit]
  536.  
  537.         mov ecx,ted_tim_ch
  538.         sub ecx,ted_tim_undo
  539.         mov al,1
  540.         cmp ted_tim_ls,ecx
  541.         jne @f
  542.                 dec al
  543.         @@:
  544.         ret
  545. endp
  546.  
  547. ;input:
  548. ; edi = pointer to tedit struct
  549. ;output:
  550. ; al = 1 - selected
  551. align 16
  552. proc ted_is_select uses ebx
  553.         xor al,al
  554.         cmp ted_drag_m,1
  555.         je @f
  556.                 inc al
  557.                 mov ebx,ted_sel_x0
  558.                 cmp ebx,ted_sel_x1
  559.                 jne @f
  560.                 mov ebx,ted_sel_y0
  561.                 cmp ebx,ted_sel_y1
  562.                 jne @f
  563.                 xor al,al
  564.         @@:
  565.         ret
  566. endp
  567.  
  568. ;input:
  569. ; edi = pointer to tedit struct
  570. align 16
  571. proc ted_sel_normalize uses ecx esi
  572.         push edi
  573.                 mov esi,edi
  574.                 add esi,ted_offs_sel
  575.                 add edi,ted_offs_seln
  576.                 mov ecx,sizeof.TexSelect/4
  577.                 rep movsd
  578.         pop edi
  579.  
  580.         jmp @f
  581.                 .swp_f:
  582.                 mov ecx,ted_seln_x0
  583.                 m2m ted_seln_x0,ted_seln_x1
  584.                 mov ted_seln_x1,ecx
  585.  
  586.                 mov ecx,ted_seln_y0
  587.                 cmp ecx,ted_seln_y1 ;(sel_y0>sel_y1)
  588.                 jle .end_f
  589.                 m2m ted_seln_y0,ted_seln_y1
  590.                 mov ted_seln_y1,ecx
  591.  
  592.                 jmp .end_f
  593. align 4
  594.         @@:
  595.  
  596.         mov ecx,ted_seln_y0
  597.         cmp ecx,ted_seln_y1 ;(sel_y0>sel_y1)
  598.         jg .swp_f
  599.  
  600.         cmp ecx,ted_seln_y1 ;(sel_y0==sel_y1)
  601.         jne .end_f
  602.                 mov ecx,ted_seln_x0
  603.                 cmp ecx,ted_seln_x1 ;(sel_x0>sel_x1)
  604.                 jg .swp_f
  605.  
  606.         .end_f:
  607.         ret
  608. endp
  609.  
  610. ;input:
  611. ; edi = pointer to tedit struct
  612. ;description:
  613. ; Функция вызываемая при начале выделения
  614. align 16
  615. proc ted_sel_start uses eax ecx
  616.         mov eax,ted_scr_h
  617.         mov ecx,ted_cur_x
  618.         add ecx,[eax+sb_offs_position]
  619.         mov ted_sel_x0,ecx
  620.         mov ted_sel_x1,ecx
  621.  
  622.         mov eax,ted_scr_w
  623.         mov ecx,ted_cur_y
  624.         add ecx,[eax+sb_offs_position]
  625.         mov ted_sel_y0,ecx
  626.         mov ted_sel_y1,ecx
  627.         ret
  628. endp
  629.  
  630. ;input:
  631. ; edi = pointer to tedit struct
  632. ;description:
  633. ; Функция вызываемая при снятии выделения
  634. align 16
  635. proc ted_sel_end uses eax
  636.         mov ted_drag_k,0 ;заканчиваем выделение от клавиатуры
  637.         call ted_is_select
  638.         or al,al
  639.         jz @f
  640.                 xor eax,eax
  641.                 mov ted_sel_x0,eax
  642.                 mov ted_sel_x1,eax
  643.                 mov ted_sel_y0,eax
  644.                 mov ted_sel_y1,eax
  645.                 stdcall ted_draw,edi
  646.                 jmp .end_f
  647.         @@:
  648.         call ted_draw_main_cursor
  649.         .end_f:
  650.         ret
  651. endp
  652.  
  653. ;input:
  654. ; edi = pointer to tedit struct
  655. ;description:
  656. ; Функция вызываемая при перемещении выделения
  657. align 16
  658. proc ted_sel_move
  659.         push eax ecx
  660.                 mov ecx,ted_cur_x
  661.                 mov eax,ted_scr_h
  662.                 add ecx,[eax+sb_offs_position]
  663.                 mov ted_sel_x1,ecx
  664.  
  665.                 mov eax,ted_scr_w
  666.                 mov ecx,ted_cur_y
  667.                 add ecx,[eax+sb_offs_position]
  668.                 mov ted_sel_y1,ecx
  669.         pop ecx eax
  670.         cmp ted_fun_draw_panel_buttons,0 ;redraw toolbar (need to button Copy)
  671.         je @f
  672.                 call ted_fun_draw_panel_buttons
  673.         @@:
  674.         ret
  675. endp
  676.  
  677. ;input:
  678. ; edi = pointer to tedit struct
  679. ;description:
  680. ; Функция вызываемая при выделении всего документа
  681. align 16
  682. proc ted_sel_all
  683.         push eax
  684.                 xor eax,eax
  685.                 mov ted_sel_x0,eax
  686.                 mov ted_sel_y0,eax
  687.  
  688.                 mov ted_sel_x1,eax ;???
  689.                 call ted_get_num_lines
  690.                 mov ted_sel_y1,eax
  691.         pop eax
  692.         stdcall ted_draw,edi
  693.         cmp ted_fun_draw_panel_buttons,0 ;redraw toolbar (need to button Copy)
  694.         je @f
  695.                 call ted_fun_draw_panel_buttons
  696.         @@:
  697.         ret
  698. endp
  699.  
  700. ;input:
  701. ; cl_al_mem = 1 - clear all memory
  702. align 16
  703. proc ted_clear uses ecx edi, edit:dword, cl_al_mem:dword
  704.         mov edi,[edit]
  705.  
  706.         mov ted_cur_x,0
  707.         mov ted_cur_y,0
  708.         mov ted_tim_ch,0
  709.         mov ted_tim_ls,0
  710.         mov ted_tim_co,0
  711.         mov ted_tim_undo,0
  712.         mov ted_help_id,-1
  713.         mov ecx,sizeof.symbol
  714.         shl ecx,1
  715.         add ecx,ted_tex
  716.         mov ted_ptr_free_symb,ecx
  717.  
  718.         mov ecx,ted_scr_w
  719.         mov dword[ecx+sb_offs_position],0
  720.         mov dword[ecx+sb_offs_max_area],100 ;число строк видимых в новом документе
  721.         mov dword[ecx+sb_offs_redraw],1
  722.         mov ecx,ted_scr_h
  723.         mov dword[ecx+sb_offs_position],0
  724.         mov dword[ecx+sb_offs_max_area],100 ;число символов видимых в новом документе
  725.  
  726.         mov ted_sel_x0,0
  727.         mov ted_sel_y0,0
  728.         mov ted_sel_x1,0
  729.         mov ted_sel_y1,0
  730.  
  731.         cmp dword[cl_al_mem],0
  732.         je .exit
  733.  
  734.         push edx
  735.         mov ecx,sizeof.symbol
  736.         imul ecx,ted_max_chars
  737.         mov edx,ted_tex
  738.         @@:
  739.                 mov byte [edx],0
  740.                 inc edx
  741.         loop @b
  742.         mov edx,ted_tex
  743.         mov dword [edx+symbol.next],1
  744.         pop edx
  745.  
  746.         .exit:
  747.         ret
  748. endp
  749.  
  750.  
  751. align 16
  752. proc ted_init_syntax_file, edit:dword
  753.         pushad
  754.         mov edi,[edit]
  755.  
  756.         mov ecx,0x100
  757.         mov edx,ted_arr_key_pos
  758.         @@:
  759.                 mov dword[edx],-1
  760.                 add edx,4
  761.         loop @b
  762.  
  763.         ;init: ted_colors_text_count, ted_key_words_count, ...
  764.         mov ted_colors_text_count,1
  765.         mov ted_key_words_count,0
  766.         mov ted_help_text_f1,0
  767.         mov ted_help_id,-1 ;идентификатор слова для справки
  768.  
  769.         mov eax,edi ;сохраняем значение edi
  770.         mov esi,ted_syntax_file
  771.         add edi,ted_offs_count_colors
  772.         mov ecx,9
  773.         rep movsd
  774.         mov edi,eax ;востанавливаем значение edi
  775.  
  776.         mov eax,ted_syntax_file
  777.         add eax,32
  778.         mov ted_text_colors,eax
  779.  
  780.         mov eax,ted_colors_text_count ;init: count_colors_text (offset to key words)
  781.         lea eax,[4*eax+32]
  782.         add eax,ted_syntax_file
  783.         mov ted_key_words_data,eax
  784.  
  785.         mov ecx,ted_key_words_count ;init: ted_arr_key_pos (first key positions)
  786.         xor eax,eax
  787.         @@:
  788.                 ColToIndexOffset eax,edx
  789.                 movzx ebx,byte[edx]
  790.                 mov esi,ted_arr_key_pos
  791.                 lea esi,[esi+4*ebx]
  792.                 cmp dword[esi],-1
  793.                 jne .no_ch_key
  794.                         mov [esi],eax
  795.                 .no_ch_key:
  796.                 inc eax
  797.         loop @b
  798.  
  799.         ;init: ted_help_text_f1
  800.         mov ecx,ted_key_words_count ;количество ключевых слов
  801.         imul ecx,sizeof.TexColViv   ;размер структуры с 1-м кл. сл.
  802.         add ecx,ted_key_words_data  ;начало файла с кл. сл.
  803.         mov ted_help_text_f1,ecx    ;метка в памяти, где начинется текст со справкой
  804.  
  805.         stdcall ted_init_scroll_bars,edi,1 ;меняем цвета скроллингов
  806.         .no_colors:
  807.         popad
  808.         ret
  809. endp
  810.  
  811. ;input:
  812. ; ebx = file size
  813. ; edi = pointer to tedit struct
  814. ;description:
  815. ; Функция вызывается при открытии файла
  816. align 16
  817. proc ted_on_open_file
  818.         push eax ;destination
  819.         push ecx ;for cycle
  820.         push edx ;source
  821.         push esi
  822.  
  823.         or ebx,ebx
  824.         jnz @f
  825.                 ;если файл пустой
  826.                 stdcall ted_clear,edi,1 ;чистим всю память
  827.                 jmp .end_opn
  828.         @@:
  829.         stdcall ted_clear,edi,0 ;чистим не всю память, потому что ниже будем ее заполнять новыми даными
  830.  
  831.         ;когда символ завершения строки только 10 (без 13)
  832.         mov edx,ted_tex
  833.         mov ecx,ebx
  834.         @@:
  835.                 cmp byte[edx],13
  836.                 je .no_10 ;если найден символ 13, то 10-е игнорируем
  837.                 inc edx
  838.                 loop @b
  839.         mov edx,ted_tex
  840.         mov ecx,ebx
  841.         .s_10:
  842.                 cmp byte[edx],10
  843.                 jne @f
  844.                         mov byte[edx],13 ;меняем 10-й символ конца строки
  845.                 @@:
  846.                 inc edx
  847.                 loop .s_10
  848.         .no_10:
  849.  
  850.         ;переводим открытый файл внутрь элемента t_edit
  851.         mov ecx,ebx
  852.         lea eax,[ebx+2]
  853.         ConvertIndexToPointer eax
  854.         mov edx,ted_tex
  855.         add edx,ebx
  856.         push ebx
  857.         @@:
  858.                 mov ebx,[edx]
  859.                 mov byte[eax],bl
  860.                 mov dword[eax+symbol.perv],ecx
  861.                 inc dword[eax+symbol.perv]
  862.                 mov dword[eax+symbol.next],ecx
  863.                 add dword[eax+symbol.next],3
  864.                 ;mov byte[eax+1],0 ;col=0
  865.                 mov dword[eax+symbol.tc],-1
  866.                 mov dword[eax+symbol.td],0
  867.  
  868.                 or ecx,ecx
  869.                 jz @f
  870.                 dec ecx
  871.                 dec edx
  872.                 sub eax,sizeof.symbol
  873.                 jmp @b
  874.         @@:
  875.         pop ebx
  876.         mov dword[eax+symbol.perv],0 ; first sumbol 'perv=0'
  877.  
  878.         mov edx,ted_tex ; настройки начального служебного символа
  879.         ; begining sumbol 'perv=0' 'next=2'
  880.         mov dword[edx+symbol.perv],0
  881.         mov dword[edx+symbol.next],2
  882.  
  883.         add edx,sizeof.symbol ; настройки конечного служебного символа
  884.         mov dword[edx+symbol.next],0 ; last sumbol 'next=0'
  885.         mov dword[edx+symbol.perv],ebx ; last sumbol 'perv=last'
  886.         inc dword[edx+symbol.perv]
  887.         mov dword[edx+symbol.tc],0 ; ставим время создания равное 0, что бы символ правильно обрабатывался при открытии файлов больших 28 байт
  888.  
  889.         mov edx,ebx
  890.         inc edx ;2 = rezerv sumbols
  891.         imul edx,sizeof.symbol
  892.         add edx,ted_tex
  893.         mov dword[edx+symbol.next],1 ; last sumbol 'next=1'
  894.  
  895.         @@: ;clear memory, need if before was open big file
  896.                 add edx,sizeof.symbol
  897.                 cmp edx,ted_tex_end
  898.                 jge .end_opn
  899.                         mov dword[edx+symbol.tc],0
  900.                         mov dword[edx+symbol.td],0
  901.                 jmp @b
  902.         .end_opn:
  903.  
  904.         call ted_get_num_lines
  905.         cmp eax,TED_LINES_IN_NEW_FILE
  906.         jge @f
  907.                 mov eax,TED_LINES_IN_NEW_FILE
  908.         @@:
  909.         mov esi,ted_scr_w
  910.         mov dword[esi+sb_offs_max_area],eax
  911.         pop esi edx ecx eax
  912.  
  913.         call ted_text_colored
  914.         stdcall ted_draw,edi
  915.         cmp ted_fun_draw_panel_buttons,0
  916.         je @f
  917.                 call ted_fun_draw_panel_buttons
  918.         @@:
  919.         ret
  920. endp
  921.  
  922. ;input:
  923. ; edx = pointer to symbol struct
  924. ; edi = pointer to tedit struct
  925. ;output:
  926. ; edx = pointer to 'perv' visible symbol struct
  927. align 16
  928. ted_iterat_perv:
  929.         cmp ted_tim_undo,0
  930.         je .else
  931.         push ebx
  932.         @@:
  933.                 mov edx,[edx+symbol.perv]
  934.                 or edx,edx
  935.                 jz @f
  936.                 imul edx,sizeof.symbol
  937.                 add edx,ted_tex
  938.                 call ted_symbol_not_vis
  939.                 cmp bl,1
  940.                 je @b
  941.                 cmp byte[edx],10 ;пропуск символа с кодом 10
  942.                 je @b
  943.         pop ebx
  944.         ret
  945.         @@:
  946.         mov edx,ted_tex ;начало файла
  947.         pop ebx
  948.         ret
  949.         .else:
  950.                 mov edx,[edx+symbol.perv]
  951.                 or edx,edx
  952.                 jz @f
  953.                 imul edx,sizeof.symbol
  954.                 add edx,ted_tex
  955.                 cmp dword[edx+symbol.td],0
  956.                 jne .else
  957.                 cmp byte[edx],10 ;пропуск символа с кодом 10
  958.                 je .else
  959.         ret
  960.         @@:
  961.         mov edx,ted_tex ;начало файла
  962.         ret
  963.  
  964.  
  965. ;input:
  966. ; edx = pointer to symbol struct
  967. ; edi = pointer to tedit struct
  968. ;output:
  969. ; edx = pointer to 'next' visible symbol struct
  970. align 16
  971. ted_iterat_next:
  972.         cmp ted_tim_undo,0
  973.         je .else
  974.         push ebx
  975.         @@:
  976.                 mov edx,[edx+symbol.next]
  977.                 cmp edx,1
  978.                 jle @f
  979.                 imul edx,sizeof.symbol
  980.                 add edx,ted_tex
  981.  
  982.                 call ted_symbol_not_vis
  983.                 cmp bl,1
  984.                 je @b
  985.                 cmp byte[edx],10 ;пропуск символа с кодом 10
  986.                 je @b
  987.         pop ebx
  988.         ret
  989.         @@:
  990.         mov edx,ted_tex_1 ;конец файла
  991.         pop ebx
  992.         ret
  993.         .else:
  994.                 mov edx,[edx+symbol.next]
  995.                 cmp edx,1
  996.                 jle @f
  997.                 imul edx,sizeof.symbol
  998.                 add edx,ted_tex
  999.  
  1000.                 cmp dword[edx+symbol.td],0
  1001.                 jne .else
  1002.                 cmp byte[edx],10 ;пропуск символа с кодом 10
  1003.                 je .else
  1004.         ret
  1005.         @@:
  1006.         mov edx,ted_tex_1 ;конец файла
  1007.         ret
  1008.  
  1009. ;input:
  1010. ; bl = symbol end of select
  1011. ; bh = экранирующий символ (= 0 если нет проверки на них)
  1012. ; edx = pointer to symbol struct
  1013. ; edi = pointer to tedit struct
  1014. ;description:
  1015. ; найти следующую позицию указанного символа
  1016. align 16
  1017. ted_iterat_next_pos_char:
  1018.         push ax
  1019.         mov al,1 ;предыдущий символ, служит для сравнения с символом bh
  1020.         @@:
  1021.                 cmp bl,byte[edx]
  1022.                 je .found
  1023.                 .no_found:
  1024.                 cmp edx,ted_tex_1
  1025.                 jle @f
  1026.                         mov al,byte[edx]
  1027.                         call ted_iterat_next
  1028.                         jmp @b
  1029.         .found:
  1030.                 cmp bh,al
  1031.                 je .no_found
  1032.         @@:
  1033.         call ted_iterat_next
  1034.         pop ax
  1035.         ret
  1036.  
  1037. ;input:
  1038. ; edx = pointer to symbol struct
  1039. ; edi = pointer to tedit struct
  1040. align 16
  1041. ted_iterat_perv_color_tag:
  1042.         @@:
  1043.                 cmp byte[edx+1],0
  1044.                 jne @f
  1045.                 call ted_iterat_perv
  1046.                 cmp edx,ted_tex_1
  1047.                 jle @f
  1048.                 jmp @b
  1049. align 4
  1050.         @@:
  1051.         ret
  1052.  
  1053. ;input:
  1054. ; edx = pointer to symbol struct
  1055. ; edi = pointer to tedit struct
  1056. align 16
  1057. ted_iterat_next_color_tag:
  1058.         @@:
  1059.                 call ted_iterat_next
  1060.                 cmp byte[edx+1],0
  1061.                 jne @f
  1062.                 cmp edx,ted_tex_1
  1063.                 jle @f
  1064.                 jmp @b
  1065. align 4
  1066.         @@:
  1067.         ret
  1068.  
  1069. ;input:
  1070. ; edx = pointer to symbol struct
  1071. ; edi = pointer to tedit struct
  1072. ;output:
  1073. ; bl = 1 if sumbol not visible
  1074. ; (tex[i].td+ted_tim_undo<=ted_tim_ch && tex[i].td) || (tex[i].tc>ted_tim_ch-ted_tim_undo)
  1075. align 16
  1076. ted_symbol_not_vis:
  1077.         push eax
  1078.  
  1079.         xor bl,bl
  1080.         cmp dword[edx+symbol.td],0
  1081.         je @f
  1082.         mov eax,[edx+symbol.td] ;eax=tex[i].td
  1083.         add eax,ted_tim_undo
  1084.         cmp eax,ted_tim_ch
  1085.         jg @f
  1086.                 mov bl,1
  1087.                 pop eax
  1088.                 ret
  1089.         @@:
  1090.  
  1091.         mov eax,ted_tim_ch
  1092.         sub eax,ted_tim_undo
  1093.         cmp [edx+symbol.tc],eax
  1094.         jle @f
  1095.                 or bl,1
  1096.         @@:
  1097.  
  1098.         pop eax
  1099.         ret
  1100.  
  1101. ;input:
  1102. ; text - pointer to text string
  1103. ; add_opt - options
  1104. align 16
  1105. proc ted_text_add, edit:dword, text:dword, t_len:dword, add_opt:dword
  1106.         locals
  1107.                 new_spc dd ? ;count new spaces
  1108.                 new_lin dd ? ;count new lines
  1109.         endl
  1110. ;использование регистров внутри функции:
  1111. ;eax - позиция для вставки текста
  1112. ;ebx - для временных нужд, длинна вставляемого текста
  1113. ;ecx - для временных нужд
  1114. ;edx - указатель на структуру символа
  1115.         pushad
  1116.         cmp dword[t_len],1 ;проверяем длинну добвляемого текста
  1117.         jl .no_add ;когда длинна <1 прыгаем на конец функции, во избежание глюков
  1118.  
  1119.         mov edi,[edit]
  1120.         mov esi,[text]
  1121.  
  1122.         call ted_get_pos_by_cursor
  1123.         call ted_get_text_perv_pos
  1124.         call ted_get_text_arr_index ;eax=po_t
  1125.  
  1126.         mov dword[new_spc],0
  1127.         cmp ted_gp_opt,2
  1128.         je @f
  1129.                 push eax ;c_sp=cur[cn].x+Scroller->XPos-StrLen(cur[cn].y+Scroller->YPos);
  1130.                         mov eax,ted_scr_h
  1131.                         mov eax,[eax+sb_offs_position]
  1132.                         add eax,ted_cur_x ;eax - номер символа
  1133.                         mov [new_spc],eax
  1134.  
  1135.                         mov eax,ted_scr_w
  1136.                         mov eax,[eax+sb_offs_position]
  1137.                         add eax,ted_cur_y ;eax - номер строки
  1138.                         call ted_strlen ;ebx = line len
  1139.                         sub [new_spc],ebx ;от позиции курсора отнимаем длинну строки, узнаем колличество добавляемых пробелов
  1140.                 pop eax
  1141.         @@:
  1142.  
  1143.         mov ebx,[t_len]
  1144.  
  1145.         mov dword[new_lin],0
  1146.         cmp ted_gp_opt,0
  1147.         jne @f
  1148.                 push eax
  1149.                         mov eax,ted_scr_w
  1150.                         mov eax,[eax+sb_offs_position]
  1151.                         add eax,ted_cur_y
  1152.                         inc eax
  1153.                         mov [new_lin],eax
  1154.  
  1155.                         call ted_get_num_lines
  1156.                         sub [new_lin],eax
  1157.                         ;увеличиваем линии в скроллинге на число добавленных дополнительных строк
  1158.                         mov ecx,ted_scr_w
  1159.                         add [ecx+sb_offs_max_area],eax ;увеличиваем размер вертикального скроллинга
  1160.                 pop eax
  1161.         @@:
  1162.  
  1163.         mov edx,ted_ptr_free_symb
  1164.         .beg_cycle: ;for(i=...;i<ted_max_chars;i++)
  1165.                 cmp dword[edx+symbol.tc],0 ;if(!tex[i].tc && !tex[i].td)
  1166.                 jne .u1f
  1167.                 cmp dword[edx+symbol.td],0
  1168.                 jne .u1f
  1169.                         test dword[add_opt],ted_opt_ed_change_time ;if(n_tim) ted_tim_ch++;
  1170.                         jz .no_tim
  1171.                                 inc ted_tim_ch
  1172.                         .no_tim:
  1173.                         test dword[add_opt],ted_opt_ed_move_cursor
  1174.                         jz .no_cur_mov
  1175.                         cmp dword[new_lin],0 ;если есть добавочные строки, то курсор еще не двигаем
  1176.                         jg .no_cur_mov
  1177.                         cmp dword[new_spc],0 ;если нет добавочных пробелов, то курсор тоже не двигаем
  1178.                         jg .no_cur_mov
  1179.                                 inc ted_cur_x ;move cursor
  1180.                                 ;call ted_go_to_pos
  1181.                                 cmp byte[esi],13
  1182.                                 jne .no_cur_mov
  1183.                                         mov ted_cur_x,0
  1184.                                         inc ted_cur_y
  1185.                                         ;увеличиваем линии в скроллинге на число добавленных в тексте строк
  1186.                                         mov ecx,ted_scr_w
  1187.                                         inc dword[ecx+sb_offs_max_area] ;увеличиваем размер вертикального скроллинга
  1188.                         .no_cur_mov:
  1189.  
  1190.                         ; *** вставка текущего символа из строки ***
  1191.                         mov ecx,ted_opt_ed_change_time
  1192.                         not ecx
  1193.                         and [add_opt],ecx ;n_tim=false;
  1194.  
  1195.                         mov cl,byte[esi] ;tex[i].c=ta[ns];
  1196.                         mov byte[edx],cl
  1197.                         m2m dword[edx+symbol.tc],ted_tim_ch ;tex[i].tc=ted_tim_ch;
  1198.                         mov [edx+symbol.perv],eax ;tex[i].perv=po_t;
  1199.  
  1200.                         mov ecx,eax
  1201.                         imul ecx,sizeof.symbol
  1202.                         add ecx,ted_tex ; *** ecx = tex[po_t] ***
  1203.                         add ecx,symbol.next ; *** ecx = tex[po_t].next ***
  1204.                         m2m dword[edx+symbol.next],dword[ecx] ;tex[i].next=tex[po_t].next;
  1205.  
  1206.                         call ted_get_text_arr_index ;*** eax = i ***
  1207.                         mov [ecx],eax ;tex[po_t].next=i; // ссылки перенаправляем
  1208.                         mov ecx,[edx+symbol.next] ; *** ecx = tex[i].next ***
  1209.                         imul ecx,sizeof.symbol
  1210.                         add ecx,ted_tex ; *** ecx = tex[tex[i].next] ***
  1211.                         mov [ecx+symbol.perv],eax ;tex[tex[i].next].perv=i;
  1212.  
  1213.                         ; *** вставка дополнительных строк и пробелов
  1214.                         ; если курсор во время вставки находился за текстом ***
  1215.                         cmp dword[new_lin],0 ;add lines or text
  1216.                         jle .spc_add
  1217.                                 dec dword[new_lin]
  1218.                                 mov byte [edx],13
  1219.                                 jmp .u1f
  1220.                         .spc_add:
  1221.                         cmp dword[new_spc],0 ;add spaces or text
  1222.                         jle .tex_add
  1223.                                 dec dword[new_spc]
  1224.                                 mov byte [edx],' '
  1225.                                 jmp .u1f
  1226.                         .tex_add:
  1227.                         inc esi ; переход к следующему вставляемому символу
  1228.                         dec ebx
  1229.                 .u1f:
  1230.                 add edx,sizeof.symbol
  1231.                 cmp edx,ted_tex_end
  1232.                 jge @f ;out of memory
  1233.                 or ebx,ebx
  1234.                 jnz .beg_cycle
  1235.                 mov ted_ptr_free_symb,edx ;меняем указатель на свободный символ, для более быстрого поиска памяти
  1236.                 jmp .add_all
  1237.         @@:
  1238.         cmp ted_increase_size,0
  1239.         je .add_all
  1240.                 call ted_memory_increase
  1241.                 or ebx,ebx
  1242.                 jnz .beg_cycle
  1243.         .add_all: ;все символы добавлены
  1244.  
  1245.         call ted_text_colored
  1246.         .no_add:
  1247.         popad
  1248.         ret
  1249. endp
  1250.  
  1251. ;input:
  1252. ;  edx = pointer to sumbol, when insert
  1253. ;  edi = pointer to tedit struct
  1254. ;output:
  1255. ;  edx = new pointer to sumbol, when insert
  1256. align 16
  1257. proc ted_memory_increase
  1258.         cmp ted_increase_size,0
  1259.         je @f
  1260.                 push eax ebx ecx
  1261.                 mov ecx,ted_increase_size
  1262.                 add ecx,ted_max_chars
  1263.                 mov ted_max_chars,ecx
  1264.                 imul ecx,sizeof.symbol
  1265.                 invoke mem.realloc, ted_tex,ecx
  1266.                 mov ebx,ted_tex
  1267.                 mov ted_tex,eax
  1268.                 mov ted_tex_1,eax
  1269.                 add ted_tex_1,sizeof.symbol
  1270.                         sub edx,ebx
  1271.                         add edx,eax
  1272.                         mov ted_ptr_free_symb,edx
  1273.                 add eax,ecx
  1274.                 mov ted_tex_end,eax
  1275.                 pop ecx ebx eax
  1276.         @@:
  1277.         ret
  1278. endp
  1279.  
  1280. ;input:
  1281. ;  ecx = position to free insert cell
  1282. ;  edx = pointer to sumbol, when insert
  1283. ;  esi = added symbol
  1284. ;  edi = pointer to tedit struct
  1285. ;output:
  1286. ;  ecx = position to inserted cell
  1287. align 16
  1288. ted_char_add:
  1289.         .loop_b:
  1290.                 cmp ecx,ted_tex_end
  1291.                 jge .end_f
  1292.                 cmp dword[ecx+symbol.tc],0
  1293.                 jne @f
  1294.                         cmp dword[ecx+symbol.td],0
  1295.                         je .loop_e
  1296.                 @@:
  1297.                 add ecx,sizeof.symbol
  1298.                 jmp .loop_b
  1299. align 4
  1300.         .loop_e:
  1301.  
  1302.         push eax ebx
  1303.         mov eax,ted_tim_ch
  1304.         mov [ecx+symbol.tc],eax
  1305.         mov ax,si
  1306.         mov byte[ecx],al
  1307.  
  1308.         call ted_get_text_arr_index ; *** eax=pos ***
  1309.         mov [ecx+symbol.perv],eax ;tex[i].perv=pos;
  1310.         m2m dword[ecx+symbol.next],dword[edx+symbol.next] ;tex[i].next=tex[pos].next;
  1311.  
  1312.         push edx
  1313.                 mov edx,ecx
  1314.                 call ted_get_text_arr_index ; *** eax=i ***
  1315.         pop edx
  1316.  
  1317.         mov [edx+symbol.next],eax ;tex[pos].next=i; // ссылки перенаправляем
  1318.         mov ebx,[ecx+symbol.next]
  1319.         ConvertIndexToPointer ebx
  1320.         mov [ebx+symbol.perv],eax ;tex[tex[i].next].perv=i; // ...
  1321.         pop ebx eax
  1322.  
  1323.         .end_f:
  1324.         call ted_text_colored
  1325.         ret
  1326.  
  1327. ;description:
  1328. ; функция для смены кодировок
  1329. ;input:
  1330. ; table - таблица для перекодировки
  1331. align 16
  1332. proc ted_but_convert_by_table uses eax edx edi esi, edit:dword, table:dword
  1333.         mov edi,[edit]
  1334.         mov esi,[table]
  1335.         mov edx,ted_tex
  1336.         .cycle:
  1337.                 ;переходим на следующий символ
  1338.                 mov edx,[edx+symbol.next]
  1339.                 cmp edx,1
  1340.                 jle .end_text
  1341.                 imul edx,sizeof.symbol
  1342.                 add edx,ted_tex
  1343.  
  1344.                 movzx eax,byte[edx]
  1345.                 add eax,esi
  1346.                 mov al,byte[eax]
  1347.                 cmp al,0
  1348.                 je @f
  1349.                         mov byte[edx],al ;меняем кодировку символа
  1350.                 @@:
  1351.                 jmp .cycle
  1352.         .end_text:
  1353.         ;cmp esi,0
  1354.         ;je @f
  1355.                 stdcall ted_draw,edi ;обновляем окно
  1356.         ;@@:
  1357.         ret
  1358. endp
  1359.  
  1360. ;input:
  1361. ; edi = pointer to tedit struct
  1362. ;output:
  1363. ; esi = count converted symbols
  1364. ;description:
  1365. ; Функция используется для смены регистра выбранных символов
  1366. align 16
  1367. proc ted_convert_sel_text, conv_fun:dword
  1368.         locals
  1369.                 conv_cou dd ?
  1370.         endl
  1371.         mov dword[conv_cou],0
  1372.         pushad
  1373.  
  1374.         call ted_is_select
  1375.         or al,al
  1376.         jz .end_f
  1377.                 call ted_set_undo
  1378.                 call ted_sel_normalize
  1379.  
  1380.                 mov esi,ted_seln_x0
  1381.                 mov ecx,ted_seln_y0
  1382.                 call ted_get_pos_by_coords
  1383.                 mov eax,edx
  1384.                 mov esi,ted_seln_x1
  1385.                 mov ecx,ted_seln_y1
  1386.                 call ted_get_pos_by_coords
  1387.                 ;call ted_get_text_perv_pos
  1388.                 mov ebx,edx
  1389.  
  1390.                 cmp eax,ebx
  1391.                 je .end_f
  1392.  
  1393.                 inc ted_tim_ch
  1394.                 mov edx,eax ;i=p0;
  1395.                 mov ecx,ted_ptr_free_symb
  1396.                 @@:
  1397.                 push eax
  1398.                 mov al,byte[edx]
  1399.                 call dword[conv_fun] ;преобразование символа
  1400.                 mov esi,eax
  1401.                 cmp byte[edx],al
  1402.                 pop eax
  1403.                 je .no_change
  1404.                         m2m dword[edx+symbol.td],ted_tim_ch
  1405.                         call ted_char_add ;b_pos=ted_char_add(tex[i].c^32,i,false,b_pos);
  1406.                         call ted_get_text_next_pos ;go to added symbol
  1407.                         inc dword[conv_cou]
  1408.                 .no_change:
  1409.  
  1410.                 call ted_iterat_next
  1411.                 cmp edx,ted_tex
  1412.                 je @f
  1413.                 cmp edx,ebx
  1414.                 jne @b
  1415.                 @@:
  1416.                 cmp dword[conv_cou],0
  1417.                 jne @f
  1418.                         dec ted_tim_ch
  1419.                 @@:
  1420.         .end_f:
  1421.         popad
  1422.         mov esi,[conv_cou]
  1423.         ret
  1424. endp
  1425.  
  1426. ;output:
  1427. ; bl = 0 - no delete
  1428. ; bl = 1 - delete
  1429. align 16
  1430. proc ted_text_del uses ecx edx edi, edit:dword, del_opt:dword
  1431.         mov edi,[edit]
  1432.         mov ebx,[del_opt]
  1433.  
  1434.         xor cl,cl
  1435.         test ebx,ted_opt_ed_move_cursor
  1436.         jz @f
  1437.                 call ted_cur_move_left
  1438.                 cmp dl,0
  1439.                 je .no_del
  1440.         @@:
  1441.         call ted_get_pos_by_cursor
  1442.         cmp ted_gp_opt,1
  1443.         je .no_del
  1444.                 test ebx,ted_opt_ed_change_time
  1445.                 jz @f
  1446.                         inc ted_tim_ch
  1447.                 @@:
  1448.                 m2m dword[edx+symbol.td], ted_tim_ch
  1449.                 mov cl,1
  1450.         .no_del:
  1451.         mov bl,cl
  1452.         ret
  1453. endp
  1454.  
  1455. ;input:
  1456. ; edi = pointer to tedit struct
  1457. ;output:
  1458. ; al = 1 if delete
  1459. ;description:
  1460. ; Функция удаляет выделенный текст
  1461. align 16
  1462. proc ted_sel_text_del uses ebx ecx edx esi, del_opt:dword
  1463.         call ted_is_select
  1464.         or al,al
  1465.         jz .end_f
  1466.                 call ted_sel_normalize
  1467.  
  1468.                 mov esi,ted_seln_x1
  1469.                 mov ecx,ted_seln_y1
  1470.                 call ted_get_pos_by_coords
  1471.                 mov ebx,edx
  1472.  
  1473.                 mov esi,ted_seln_x0
  1474.                 mov ecx,ted_seln_y0
  1475.                 call ted_get_pos_by_coords
  1476.  
  1477.                 test dword[del_opt],ted_opt_ed_change_time
  1478.                 jz @f
  1479.                         inc ted_tim_ch
  1480.                 @@:
  1481.                 cmp edx,ted_tex
  1482.                 je @f
  1483.                 cmp edx,ebx ;if(i==te)break;
  1484.                 je @f
  1485.                         m2m dword[edx+symbol.td],ted_tim_ch
  1486.                         mov esi,ted_opt_ed_change_time
  1487.                         not esi
  1488.                         and dword[del_opt],esi ;n_tim=false;
  1489.                         call ted_iterat_next
  1490.                         jmp @b
  1491. align 4
  1492.                 @@:
  1493.                 test dword[del_opt],ted_opt_ed_change_time
  1494.                 jz @f
  1495.                         dec ted_tim_ch
  1496.                         xor al,al
  1497.                 @@:
  1498.                 test dword[del_opt],ted_opt_ed_change_time
  1499.                 jnz @f
  1500.                         mov ecx,ted_seln_x0
  1501.                         mov edx,ted_seln_y0
  1502.                         call ted_go_to_pos
  1503.                         mov ted_sel_x0,0
  1504.                         mov ted_sel_y0,0
  1505.                         mov ted_sel_x1,0
  1506.                         mov ted_sel_y1,0
  1507.                 @@:
  1508.         .end_f:
  1509.         ret
  1510. endp
  1511.  
  1512.  
  1513. ;input:
  1514. ; eax = pointer to begin select
  1515. ; ebx = pointer to end select
  1516. ; edi = pointer to tedit struct
  1517. align 16
  1518. ted_revers:
  1519.         cmp eax,ebx
  1520.         jne @f
  1521.                 ret
  1522.         @@:
  1523.  
  1524.         push ecx edx
  1525.  
  1526.         mov edx,ted_tex_1
  1527.         cmp edx,ebx ;if(p1==1)p1=tex[1].perv;
  1528.         jne @f
  1529.                 call ted_get_text_perv_pos
  1530.                 mov ebx,edx
  1531.         @@:
  1532.  
  1533.         push esi
  1534.                 mov edx,[eax+symbol.perv] ; *** edx = tex[p0].perv ***
  1535.                 ConvertIndexToPointer edx
  1536.                 add edx,symbol.next
  1537.                 mov ecx,[edx] ;ecx = tex[tex[p0].perv].next
  1538.  
  1539.                 mov esi,[ebx+symbol.next] ; *** esi = tex[p1].next ***
  1540.                 ConvertIndexToPointer esi
  1541.                 add esi,symbol.perv
  1542.                 m2m dword[edx],dword[esi] ;tex[tex[p0].perv].next = tex[tex[p1].next].perv
  1543.  
  1544.                 mov [esi],ecx ;tex[tex[p1].next].perv = ecx
  1545.         pop esi
  1546.  
  1547.         mov ecx,[eax+symbol.perv] ;ecx = tex[p0].perv
  1548.         m2m dword[eax+symbol.perv],dword[ebx+symbol.next] ;tex[p0].perv = tex[p1].next
  1549.         mov [ebx+symbol.next],ecx ;tex[p1].next = ecx
  1550.  
  1551.         mov edx,eax ;i=p0;
  1552.         @@:
  1553.                 mov ecx,[edx+symbol.next] ;ecx = tex[i].next
  1554.                 m2m dword[edx+symbol.next],dword[edx+symbol.perv] ;tex[i].next = tex[i].perv
  1555.                 mov [edx+symbol.perv],ecx ;tex[i].perv = ecx
  1556.                 cmp edx,ebx ;if(i==p1)break;
  1557.                 je @f
  1558. ; ---
  1559. ;cmp edx,ted_tex
  1560. ;je @f
  1561. ; ---
  1562.                 mov edx,ecx ;i = ecx
  1563.                 ConvertIndexToPointer edx
  1564.                 jmp @b
  1565.         @@:
  1566.         pop edx ecx
  1567.         call ted_text_colored
  1568.         ret
  1569.  
  1570.  
  1571. ;input:
  1572. ; edi = pointer to tedit struct
  1573. ;output:
  1574. ; dl = 0 not move
  1575. ; dl = 2 if move up
  1576. ; dl = 8 if scroll move up
  1577. align 16
  1578. ted_cur_move_up:
  1579.   cmp ted_cur_y,0
  1580.   je @f
  1581.     dec ted_cur_y
  1582.     mov dl,2
  1583.     ret
  1584.   @@:
  1585.   push eax
  1586.   mov eax,ted_scr_w
  1587.   cmp dword[eax+sb_offs_position],0
  1588.   je @f
  1589.     dec dword[eax+sb_offs_position]
  1590.     mov dl,8
  1591.     jmp .ret_f
  1592.   @@:
  1593.   mov dl,0
  1594.   .ret_f:
  1595.   pop eax
  1596.   ret
  1597.  
  1598. ;input:
  1599. ; edi = pointer to tedit struct
  1600. ;output:
  1601. ; dl = 0 not move
  1602. ; dl = 2 if move down
  1603. ; dl = 8 if scroll move down
  1604. align 16
  1605. ted_cur_move_down:
  1606.   push eax ebx
  1607.   mov ebx,ted_scr_w
  1608.   xor dl,dl
  1609.   mov eax,[ebx+sb_offs_cur_area]
  1610.   dec eax
  1611.   cmp ted_cur_y,eax
  1612.   jge @f
  1613.     inc ted_cur_y
  1614.     mov dl,2
  1615.     jmp .ret_f
  1616.   @@:
  1617.   mov eax,ted_cur_y
  1618.   add eax,[ebx+sb_offs_position]
  1619.   inc eax
  1620.   cmp [ebx+sb_offs_max_area],eax
  1621.   jle @f
  1622.     inc dword[ebx+sb_offs_position]
  1623.     mov dl,8
  1624.   @@:
  1625.   .ret_f:
  1626.   pop ebx eax
  1627.   ret
  1628.  
  1629.  
  1630. ;input:
  1631. ; edi = pointer to tedit struct
  1632. ;output:
  1633. ; dl = 0 not move
  1634. ; dl = 1 if move up
  1635. align 16
  1636. ted_cur_move_page_up:
  1637.         push eax ebx
  1638.         mov ebx,ted_scr_w
  1639.         mov eax,[ebx+sb_offs_cur_area]
  1640.         xor dl,dl
  1641.         cmp eax,[ebx+sb_offs_position]
  1642.         jg @f
  1643.                 sub [ebx+sb_offs_position],eax
  1644.                 mov dl,1
  1645.         @@:
  1646.         cmp dword[ebx+sb_offs_position],0
  1647.         je @f
  1648.         cmp dl,1
  1649.         je @f
  1650.                 mov dword[ebx+sb_offs_position],0
  1651.                 mov dl,1
  1652.         @@:
  1653.         pop ebx eax
  1654.         ret
  1655.  
  1656. ;input:
  1657. ; edi = pointer to tedit struct
  1658. align 16
  1659. ted_cur_move_page_down:
  1660.         push eax ebx ecx
  1661.         mov ecx,ted_scr_w
  1662.  
  1663.         xor dl,dl
  1664.         mov eax,[ecx+sb_offs_max_area]
  1665.         sub eax,[ecx+sb_offs_cur_area]
  1666.         cmp [ecx+sb_offs_position],eax
  1667.         jge @f
  1668.                 mov ebx,[ecx+sb_offs_cur_area]
  1669.                 add [ecx+sb_offs_position],ebx
  1670.                 mov dl,1
  1671.                 mov dword[ecx+sb_offs_redraw],1
  1672.                 cmp [ecx+sb_offs_position],eax
  1673.                 jle @f
  1674.                         mov [ecx+sb_offs_position],eax
  1675.         @@:
  1676.         pop ecx ebx eax
  1677.         ret
  1678.  
  1679. ;input:
  1680. ; edi = pointer to tedit struct
  1681. ;output:
  1682. ; dl = 0 not move
  1683. ; dl = 1 if move left
  1684. ; dl = 3 if move left and up
  1685. ; dl = 8 if scroll move up
  1686. align 16
  1687. ted_cur_move_left:
  1688.         cmp ted_cur_x,0
  1689.         je @f
  1690.                 dec ted_cur_x
  1691.                 mov dl,1
  1692.                 ret
  1693.         @@:
  1694.         push eax
  1695.         mov eax,ted_scr_h
  1696.         cmp dword[eax+sb_offs_position],0
  1697.         je @f
  1698.                 dec dword[eax+sb_offs_position]
  1699.                 mov dl,8
  1700.                 jmp .ret_f
  1701.         @@:
  1702.         cmp ted_cur_y,0
  1703.         jne @f
  1704.                 mov eax,ted_scr_w
  1705.                 mov dl,0
  1706.                 cmp dword[eax+sb_offs_position],0
  1707.                 je .ret_f
  1708.                         dec dword[eax+sb_offs_position]
  1709.                         call ted_scroll_set_redraw
  1710.                         call ted_cur_move_x_last_char
  1711.                         mov dl,8
  1712.                         jmp .ret_f
  1713.         @@:
  1714.         cmp ted_cur_y,0
  1715.         je @f
  1716.                 dec ted_cur_y
  1717.                 call ted_cur_move_x_last_char
  1718.                 cmp dl,8
  1719.                 je .ret_f
  1720.                 mov dl,3
  1721.                 jmp .ret_f
  1722.         @@:
  1723.         mov dl,0
  1724.         .ret_f:
  1725.         pop eax
  1726.         ret
  1727.  
  1728. ;input:
  1729. ; edi = pointer to tedit struct
  1730. align 16
  1731. ted_cur_move_right:
  1732.         push eax ebx
  1733.         mov eax,ted_scr_h
  1734.         xor dl,dl
  1735.         mov ebx,[eax+sb_offs_cur_area]
  1736.         cmp ted_cur_x,ebx
  1737.         jge @f
  1738.                 inc ted_cur_x
  1739.                 mov dl,1
  1740.                 jmp .ret_f
  1741.         @@:
  1742.                 inc dword[eax+sb_offs_position]
  1743.                 mov dl,8
  1744.         .ret_f:
  1745.         pop ebx eax
  1746.         ret
  1747.  
  1748. ;input:
  1749. ; edi = pointer to tedit struct
  1750. align 16
  1751. ted_cur_move_x_last_char:
  1752. ;[hScr.position]
  1753. ;[hScr.cur_area]
  1754. ;dl-???
  1755.   push eax ebx ecx
  1756.   mov eax,ted_cur_y
  1757.   mov ecx,ted_scr_w
  1758.   add eax,[ecx+sb_offs_position]
  1759.   call ted_strlen
  1760.   xor dl,dl
  1761.  
  1762.   mov ecx,ted_scr_h
  1763.   cmp ebx,[ecx+sb_offs_position]
  1764.   jge @f
  1765.     mov dl,8
  1766.     mov [ecx+sb_offs_position],ebx
  1767.   @@:
  1768.   sub ebx,[ecx+sb_offs_position]
  1769.  
  1770.   cmp ebx,[ecx+sb_offs_cur_area]
  1771.   jle @f ; b---[---]---e
  1772.     add [ecx+sb_offs_position],ebx
  1773.     mov ebx,[ecx+sb_offs_cur_area]
  1774.     sub [ecx+sb_offs_position],ebx
  1775.     mov dl,8
  1776.   @@:
  1777.   mov ted_cur_x,ebx
  1778.   pop ecx ebx eax
  1779.   ret
  1780.  
  1781. ;input:
  1782. ; edi = pointer to tedit struct
  1783. ;output:
  1784. ; dl = 0 not move
  1785. ; dl = 1 move cursor
  1786. ; dl = 8 move cursor and scroll
  1787. align 16
  1788. ted_cur_move_x_first_char:
  1789.         xor dl,dl
  1790.         cmp ted_cur_x,0
  1791.         je @f
  1792.                 mov ted_cur_x,0
  1793.                 mov dl,1
  1794.         @@:
  1795.         push eax
  1796.         mov eax,ted_scr_h
  1797.         cmp dword[eax+sb_offs_position],0
  1798.         je @f
  1799.                 mov dword[eax+sb_offs_position],0
  1800.                 mov dl,8
  1801.         @@:
  1802.         pop eax
  1803.         ret
  1804.  
  1805. ;input:
  1806. ; edx = pointer to symbol struct
  1807. ; edi = pointer to tedit struct
  1808. ;output:
  1809. ; eax = array index
  1810. align 16
  1811. ted_get_text_arr_index:
  1812.         push ecx edx
  1813.                 mov eax,edx
  1814.                 sub eax,ted_tex
  1815.                 xor edx,edx
  1816.                 mov ecx,sizeof.symbol
  1817.                 div ecx
  1818.         pop edx ecx
  1819.         ret
  1820.  
  1821. ;input:
  1822. ; edx = pointer to symbol struct
  1823. ; edi = pointer to tedit struct
  1824. ;output:
  1825. ; edx = pointer to 'perv' struct
  1826. align 16
  1827. ted_get_text_perv_pos:
  1828.         mov edx,[edx+symbol.perv]
  1829.         imul edx,sizeof.symbol
  1830.         add edx,ted_tex
  1831.         ret
  1832.  
  1833. ;input:
  1834. ; edx = pointer to symbol struct
  1835. ;output:
  1836. ; edx = pointer to 'next' symbol struct
  1837. align 16
  1838. ted_get_text_next_pos:
  1839.         mov edx,[edx+symbol.next]
  1840.         imul edx,sizeof.symbol
  1841.         add edx,ted_tex
  1842.         ret
  1843.  
  1844. ;input:
  1845. ; edi = pointer to tedit struct
  1846. ;output:
  1847. ; edx = symbol under cursor
  1848. ; ted_gp_opt = 1,2
  1849. ; edx = tex[1].perv if error
  1850. ; ted_gp_opt = 0
  1851. align 16
  1852. ted_get_pos_by_cursor:
  1853.         push eax ecx esi
  1854.                 mov esi,ted_cur_x
  1855.                 mov eax,ted_scr_h
  1856.                 add esi,[eax+sb_offs_position]
  1857.                 mov ecx,ted_cur_y
  1858.                 mov eax,ted_scr_w
  1859.                 add ecx,[eax+sb_offs_position]
  1860.                 call ted_get_pos_by_coords
  1861.         pop esi ecx eax
  1862.         ret
  1863.  
  1864. ;input:
  1865. ; esi = XPos
  1866. ; ecx = YPos
  1867. ; edi = pointer to tedit struct
  1868. ;output:
  1869. ; edx = symbol under cursor
  1870. ; ted_gp_opt = 1 if found text line
  1871. ; ted_gp_opt = 2 if found text line and column
  1872. ; edx = tex[1] if error
  1873. ; ted_gp_opt = 0 if text no found
  1874. align 16
  1875. proc ted_get_pos_by_coords uses eax ebx
  1876.         xor eax,eax ;Row
  1877.         xor ebx,ebx ;Col
  1878.   mov ted_gp_opt,0
  1879.   mov edx,ted_tex
  1880.   @@:
  1881.     call ted_iterat_next
  1882.     cmp edx,ted_tex_1
  1883.     jle @f
  1884.     cmp ebx,esi
  1885.     jne .u1_0 ;Col <> ted_cur_x
  1886.       mov ted_gp_opt,1
  1887.       cmp eax,ecx
  1888.       jge @f ; Row >= ted_cur_y
  1889.     .u1_0:
  1890.     mov ted_gp_opt,0
  1891.     inc ebx
  1892.     cmp byte [edx],13
  1893.     jne @b
  1894.     cmp eax,ecx
  1895.     jge @f ; Row >= ted_cur_y
  1896.     inc eax
  1897.     xor ebx,ebx
  1898.     jmp @b
  1899.   @@:
  1900.   cmp eax,ecx
  1901.   jne @f ; Row = ted_cur_y
  1902.     inc ted_gp_opt
  1903.   @@:
  1904.   cmp ted_gp_opt,0
  1905.   jne @f
  1906.     mov edx,ted_tex_1
  1907.     ;call ted_get_text_perv_pos
  1908.   @@:
  1909.   ret
  1910. endp
  1911.  
  1912. ;input:
  1913. ; eax = Row
  1914. ; edi = pointer to tedit struct
  1915. ;output:
  1916. ; ebx = str len
  1917. align 16
  1918. ted_strlen:
  1919.   push edx ecx
  1920.   ;ecx = Row, from cycle
  1921.  
  1922.   xor ebx,ebx
  1923.   xor ecx,ecx
  1924.   mov edx,ted_tex
  1925.   @@:
  1926.     call ted_iterat_next
  1927.     cmp edx,ted_tex_1
  1928.     jle @f
  1929.     inc ebx
  1930.     cmp byte [edx],13
  1931.     jne @b
  1932.     dec ebx ;lenght minus 1 sumbol to paragraph
  1933.     cmp eax,ecx
  1934.     je @f
  1935.     xor ebx,ebx
  1936.     inc ecx
  1937.     jmp @b
  1938.   @@:
  1939.  
  1940.   cmp eax,ecx
  1941.   je @f
  1942.     xor ebx,ebx
  1943.   @@:
  1944.  
  1945.   pop ecx edx
  1946.   ret
  1947.  
  1948.  
  1949. ;input:
  1950. ; edx = symbol position
  1951. ; edi = pointer to tedit struct
  1952. ;output:
  1953. ; eax = number of line
  1954. ; ebx = symbol position in line
  1955. align 16
  1956. ted_get_text_coords:
  1957.         push edx
  1958.         xor eax,eax
  1959.         xor ebx,ebx
  1960.         @@:
  1961.                 call ted_iterat_perv
  1962.  
  1963.                 or eax,eax
  1964.                 jnz .no_col_mov
  1965.                         inc ebx
  1966.                 .no_col_mov:
  1967.  
  1968.                 cmp edx,ted_tex_1
  1969.                 jle @f
  1970.                 cmp byte [edx],13
  1971.                 jne @b
  1972.                 inc eax
  1973.                 jmp @b
  1974.         @@:
  1975.         dec ebx
  1976.         pop edx
  1977.         ret
  1978.  
  1979. ;input:
  1980. ; edi = pointer to tedit struct
  1981. ;output:
  1982. ; eax = num lines
  1983. align 16
  1984. ted_get_num_lines:
  1985.         push edx
  1986.         mov eax,1
  1987.         mov edx,ted_tex
  1988.         @@:
  1989.                 call ted_iterat_next
  1990.                 cmp edx,ted_tex_1
  1991.                 jle @f
  1992.                 cmp byte[edx],13
  1993.                 jne @b
  1994.                 inc eax
  1995.                 jmp @b
  1996.         @@:
  1997. ;...
  1998. ;dec eax
  1999.         pop edx
  2000.         ret
  2001.  
  2002.  
  2003. ;input:
  2004. ; edi = pointer to tedit struct
  2005. ;description:
  2006. ; отменяет отмененные действия, перед изменением документа
  2007. align 16
  2008. proc ted_set_undo
  2009.         mov ted_drag_k,0 ;заканчиваем выделение от клавиатуры
  2010.         cmp ted_tim_undo,1
  2011.         jl .no_work
  2012.  
  2013.         push eax ebx edx
  2014.         mov edx,ted_tex
  2015.         call ted_get_text_next_pos ;long i=tex[0].next;
  2016.         mov eax,ted_tim_undo
  2017.         sub ted_tim_ch,eax ;ted_tim_ch-=ted_tim_undo;
  2018.         mov eax,ted_tim_ch
  2019.         cmp ted_tim_ls,eax ;if(ted_tim_ls>ted_tim_ch)
  2020.         jle @f
  2021.                 mov ted_tim_ls,0
  2022.         @@:
  2023.                 cmp edx,ted_tex_1
  2024.                 jle @f
  2025.  
  2026.                 ;if(tex[i].tc>ted_tim_ch){ // если создание символа было отменено
  2027.                 cmp [edx+symbol.tc],eax
  2028.                 jle .no_u1
  2029.                         mov dword[edx+symbol.tc],0
  2030.                         mov dword[edx+symbol.td],0
  2031.  
  2032.                         mov ebx,[edx+symbol.perv]
  2033.                         imul ebx,sizeof.symbol
  2034.                         add ebx,ted_tex ;ebx=tex[i].perv
  2035.                         m2m dword [ebx+symbol.next],dword [edx+symbol.next] ;tex[tex[i].perv].next=tex[i].next;
  2036.  
  2037.                         mov ebx,[edx+symbol.next]
  2038.                         imul ebx,sizeof.symbol
  2039.                         add ebx,ted_tex ;ebx=tex[i].next
  2040.                         m2m dword [ebx+symbol.perv],dword [edx+symbol.perv] ;tex[tex[i].next].perv=tex[i].perv;
  2041.  
  2042.                         cmp ted_ptr_free_symb,edx
  2043.                         jle .no_cor_free
  2044.                                 mov ted_ptr_free_symb,edx ;меняем указатель на свободный символ, для более быстрого поиска памяти
  2045.                         .no_cor_free:
  2046.                         mov edx,ebx ;оптимизируем по скорости (edx после вызова ted_get_text_next_pos будет равен ebx)
  2047.                         jmp @b
  2048.                 .no_u1:
  2049.  
  2050.                 ;else if(tex[i].td>ted_tim_ch) tex[i].td=0; // если удаление символа было отменено
  2051.                 cmp [edx+symbol.td],eax
  2052.                 jle .no_u2
  2053.                         mov dword[edx+symbol.td],0
  2054.                 .no_u2:
  2055.  
  2056.                 call ted_get_text_next_pos
  2057.                 jmp @b
  2058.         @@:
  2059.         mov ted_tim_undo,0
  2060.         mov eax,ted_tim_co
  2061.         cmp ted_tim_ch,eax
  2062.         jge @f
  2063.                 mov ted_tim_co,0
  2064.         @@:
  2065.         pop edx ebx eax
  2066.         .no_work:
  2067.         ret
  2068. endp
  2069.  
  2070. ;description:
  2071. ; переход на указанную позицию
  2072. ;input:
  2073. ; row = номер строки
  2074. ; col = символ
  2075. align 16
  2076. proc ted_go_to_position uses ecx edx edi, edit:dword, row:dword, col:dword
  2077.         mov edi,[edit]
  2078.         ; подготовка строки
  2079.         mov edx,[row]
  2080.         call ted_get_num_lines
  2081.         cmp edx,eax
  2082.         jle @f
  2083.                 mov edx,eax ;ограничение по строке max
  2084.         @@:
  2085.         dec edx
  2086.         cmp edx,0
  2087.         jge @f
  2088.                 xor edx,edx ;ограничение по строке min
  2089.         @@:
  2090.         ; подготовка символа
  2091.         mov ecx,[col]
  2092.         dec ecx
  2093.         cmp ecx,0
  2094.         jge @f
  2095.                 xor ecx,ecx
  2096.         @@:
  2097.         call ted_go_to_pos
  2098.         stdcall ted_draw,edi
  2099.         ret
  2100. endp
  2101.  
  2102. ;input:
  2103. ; ecx = Col
  2104. ; edx = Row
  2105. ; edi = pointer to tedit struct
  2106. ;output:
  2107. ; ecx = cursor x
  2108. ; edx = cursor y
  2109. align 16
  2110. ted_go_to_pos:
  2111.         push eax ebx
  2112.         mov eax,ted_scr_h
  2113.         sub ecx,[eax+sb_offs_position]
  2114.         cmp ecx,0 ;ted_cur_x < 0
  2115.         jge @f
  2116.                 add [eax+sb_offs_position],ecx ;прокрутка скроллинга влево
  2117.                 xor ecx,ecx
  2118.         @@:
  2119.         mov ebx,5 ;5 - желаемый отступ слева
  2120.         cmp ecx,ebx
  2121.         jge .end0
  2122.                 sub ebx,ecx ;ebx - на сколько символов нужно сдвинуть курсор
  2123.                 cmp [eax+sb_offs_position],ebx
  2124.                 jge @f
  2125.                         add ecx,[eax+sb_offs_position]
  2126.                         mov dword[eax+sb_offs_position],0
  2127.                         jmp .end0
  2128.                 @@:
  2129.                         sub [eax+sb_offs_position],ebx
  2130.                         add ecx,ebx
  2131.         .end0:
  2132.         cmp ecx,[eax+sb_offs_cur_area] ;ted_cur_x > [.cur_area]
  2133.         jl .end1
  2134.                 mov ebx,ecx
  2135.                 sub ebx,[eax+sb_offs_cur_area]
  2136.                 inc ebx
  2137.                 add [eax+sb_offs_position],ebx ;прокрутка скроллинга вправо
  2138.                 sub ecx,ebx
  2139.         .end1:
  2140.         mov ted_cur_x,ecx
  2141.  
  2142.         mov eax,ted_scr_w
  2143.         sub edx,[eax+sb_offs_position]
  2144.         cmp edx,0 ;ted_cur_y < 0
  2145.         jge @f
  2146.                 add [eax+sb_offs_position],edx ;прокрутка скроллинга вверх
  2147.                 xor edx,edx
  2148.                 jmp .end2
  2149.         @@:
  2150.         cmp edx,[eax+sb_offs_cur_area] ;ted_cur_y > [.cur_area]
  2151.         jl .end2
  2152.                 mov ebx,edx
  2153.                 sub ebx,[eax+sb_offs_cur_area]
  2154.                 inc ebx
  2155.                 add [eax+sb_offs_position],ebx ;прокрутка скроллинга вниз
  2156.                 sub edx,ebx
  2157.         .end2:
  2158.         mov ted_cur_y,edx
  2159.         pop ebx eax
  2160.         ret
  2161.  
  2162. ;input:
  2163. ; edi = pointer to tedit struct
  2164. align 16
  2165. ted_text_colored:
  2166.         push eax edx
  2167.         mov eax,ted_tim_ch
  2168.         sub eax,ted_tim_undo
  2169.         mov ted_tim_co,eax
  2170.         mov edx,ted_tex
  2171.         @@:
  2172.                 call ted_iterat_next
  2173.                 cmp edx,ted_tex_1
  2174.                 jle @f
  2175.                 mov byte[edx+1],0
  2176.                 jmp @b
  2177.         @@:
  2178.  
  2179.         cmp ted_key_words_count,1
  2180.         jl .no_colors
  2181.         mov edx,ted_tex
  2182.         @@:
  2183.                 call ted_text_find_sel_color
  2184.                 cmp edx,ted_tex_1
  2185.                 jle .no_colors
  2186.                 jmp @b
  2187.         .no_colors:
  2188.         pop edx eax
  2189.         ret
  2190.  
  2191.  
  2192. ;input:
  2193. ; edx = pointer to start symbol
  2194. ; edi = pointer to tedit struct
  2195. ;output:
  2196. ; edx = pointer to next symbol
  2197. ;description:
  2198. ; Функция для поиска и выделения подсвеченых слов
  2199. align 16
  2200. proc ted_text_find_sel_color uses eax ebx ecx esi
  2201. locals
  2202.         begPos dd ? ;начальная позиция
  2203.         endPos dd ? ;конечная позиция
  2204.         find db ? ;0 - не найдено, 1 - найдено, 2 - найдено в конце файла
  2205.         f_color db ? ;индекс цвета найденого слова
  2206. endl
  2207. ;eax = word_n текущий номер (позиция) проверяемого слова в списке
  2208. ;ebx = для разных целей
  2209. ;ecx = l_pos последний номер (позиция) подходящего слова в списке
  2210. ;esi = для разных целей, номер проверяемого символа в слове
  2211.         mov dword[begPos],1
  2212.         mov dword[endPos],1
  2213.         mov byte[find],0
  2214.         mov byte[f_color],1
  2215.         .cycle0:
  2216.                 call ted_iterat_next
  2217.                 cmp edx,ted_tex_1
  2218.                 jle .cycle0end
  2219.  
  2220.                 movzx eax,byte[edx]
  2221.                 shl eax,2 ;eax*=4
  2222.                 add eax,ted_arr_key_pos
  2223.                 mov eax,[eax]
  2224.                 cmp eax,0
  2225.                 jl .cycle0 ;if( (word_n=ted_arr_key_pos[(unsigned char)tex[i].c])>-1 ){
  2226.  
  2227.                 mov ecx,eax
  2228.                 ;while(l_pos<ted_key_words_count && Col[l_pos].Text[0]==Col[word_n].Text[0])
  2229.                 .wh_1b:
  2230.                         cmp ecx,ted_key_words_count
  2231.                         jge .wh_1e
  2232.                         ColToIndexOffset ecx,esi
  2233.                         mov bl,byte[esi]
  2234.                         ColToIndexOffset eax,esi
  2235.                         cmp bl,byte[esi]
  2236.                         jne .wh_1e
  2237.                                 inc ecx
  2238.                         jmp .wh_1b
  2239.                 .wh_1e:
  2240.  
  2241.                 mov [begPos],edx ;bP=i;
  2242.                 mov esi,1
  2243. align 4
  2244.                 .wh_2b: ;while(1){
  2245.                 call ted_iterat_next
  2246.  
  2247.                 ;while(l_pos>word_n && Col[l_pos-1].Text[pos]!=tex[i].c)
  2248.                 @@:
  2249.                         cmp ecx,eax
  2250.                         jle @f
  2251.                         dec ecx
  2252.                         ColToIndexOffset ecx,ebx
  2253.                         inc ecx
  2254.                         ;cmp byte[ebx+esi],byte[edx]
  2255.                         mov bl,byte[ebx+esi]
  2256.                         cmp bl,byte[edx]
  2257.                         je @f
  2258.                                 dec ecx
  2259.                         jmp @b
  2260.                 @@:
  2261.  
  2262.                 ColToIndexOffset eax,ebx
  2263.                 cmp byte[ebx+esi],0
  2264.                 jne .if_0 ;if(Col[word_n].Text[pos]==0){
  2265.                 mov [endPos],edx ;eP=i;
  2266.                 ColToIndexOffset eax,ebx
  2267.                 mov bl,[ebx+MAX_COLOR_WORD_LEN+7]
  2268.                 mov [f_color],bl ;f_color=Col[word_n].color;
  2269.  
  2270.                 mov byte[find],1
  2271.                 ColToIndexOffset eax,ebx ;... ebx = Col[word_n]
  2272.                 mov bl,[ebx+MAX_COLOR_WORD_LEN+4]
  2273.                 cmp bl,0 ;if(Col[word_n].wwo)
  2274.                 je .if_2n
  2275.                         push edx
  2276.                         mov edx,[begPos]
  2277.                         call ted_iterat_perv
  2278.  
  2279.                         btr bx,0 ;1-1
  2280.                         jae @f ;if(Col[word_n].wwo&1)
  2281.                                 ;u1= !(isalnum(cont_s)||cont_s=='_')
  2282.                                 call isalnum
  2283.                                 jae @f
  2284.                                         mov byte[find],0
  2285.                                         jmp .if_4e
  2286.                         @@:
  2287.  
  2288.                         btr bx,3 ;4-1
  2289.                         jae .if_4e ;if(Col[word_n].wwo&8)
  2290.                                 ;u1= !isalpha(cont_s);
  2291.                                 call isalpha
  2292.                                 jae .if_4e
  2293.                                         mov byte[find],0
  2294.                         .if_4e:
  2295.  
  2296.                         mov edx,[endPos]
  2297.                         ;call ted_iterat_next
  2298.  
  2299.                         btr bx,1 ;2-1
  2300.                         jae @f ;if(Col[word_n].wwo&2)
  2301.                                 ;u1= !(isalnum(cont_s)||cont_s=='_')
  2302.                                 call isalnum
  2303.                                 jae @f
  2304.                                         mov byte[find],0
  2305.                                         jmp .if_6e
  2306.                         @@:
  2307.  
  2308.                         btr bx,4 ;5-1
  2309.                         jae .if_6e ;if(Col[word_n].wwo&16)
  2310.                                 ;u1= !isalpha(cont_s);
  2311.                                 call isalpha
  2312.                                 jae .if_6e
  2313.                                         mov byte[find],0
  2314.                         .if_6e:
  2315.  
  2316.                         btr bx,2 ;3-1
  2317.                         jae .if_7e ;if(Col[word_n].wwo&4)
  2318.                                 ColToIndexOffset eax,ebx
  2319.                                 mov bx,word[ebx+MAX_COLOR_WORD_LEN+5]
  2320.                                 call ted_iterat_next_pos_char
  2321.                                 cmp edx,ted_tex_1
  2322.                                 jg @f
  2323.                                         ;если дошли до конца файла и не нашли символ конца разметки
  2324.                                         call ted_iterat_perv
  2325.                                         mov byte[find],2
  2326.                                 @@:
  2327.                                         mov dword[endPos],edx
  2328.                         .if_7e:
  2329.  
  2330.                         pop edx
  2331.                 .if_2n:
  2332. ;if(i!=1){ // не конец документа
  2333. ;  cont_s=tex[eP].c;
  2334. ;  if(Col[word_n].wwo&2) u2= !(isalnum(cont_s)||cont_s=='_');  // не букв.-числ. символ
  2335. ;  if(u2 && Col[word_n].wwo&16) u2= !isalpha(cont_s); // не числ. символ
  2336. ;  if(Col[word_n].wwo&4) eP=ted_iterat_next_pos_char(eP,Col[word_n].endc);
  2337.  
  2338.                         cmp eax,ecx
  2339.                         je .wh_2e ;if(word_n==l_pos) break; // do double - если слово точно последнее
  2340.                 .if_0:
  2341.  
  2342.                 cmp edx,ted_tex_1
  2343.                 jle .wh_2e ;if(i==1) break;
  2344.  
  2345.                 ;while(l_pos>word_n && Col[word_n].Text[pos]!=tex[i].c)
  2346.                 .wh_4b:
  2347.                 cmp ecx,eax
  2348.                 jle .wh_4e
  2349.                         ColToIndexOffset eax,ebx
  2350.                         ;cmp byte[ebx+esi],byte[edx]
  2351.                         mov bl,byte[ebx+esi]
  2352.                         cmp bl,byte[edx]
  2353.                         je .wh_4e
  2354.                                 inc eax
  2355.                         jmp .wh_4b
  2356.                 .wh_4e:
  2357.  
  2358.                 cmp eax,ecx
  2359.                 je .wh_2e;if(word_n==l_pos) break;
  2360.                         inc esi ;pos++;
  2361.                         jmp .wh_2b
  2362.                 .wh_2e:
  2363.  
  2364.                 cmp byte[find],0 ;if(fnd)break;
  2365.                 jne .cycle0end
  2366.                         mov edx,[begPos];i=bP;
  2367.                 jmp .cycle0
  2368.         .cycle0end:
  2369.  
  2370.         cmp byte[find],0
  2371.         je .if_1e ;if(fnd){ // выделение найденого текста
  2372.                 ;if(!mode_sf1 || (mode_sf1 && strlen(Col[word_n].f1->c_str())>0)){
  2373.                 mov eax,[begPos]
  2374.                 mov bl,[f_color]
  2375.                 mov [eax+1],bl ;tex[bP].col=f_color;
  2376.                 mov eax,[endPos]
  2377.                 mov byte[eax+1],0xff ;tex[eP].col=255;
  2378.                 cmp byte[find],2
  2379.                 je .if_1e
  2380.                 ;return ItPoPerv(eP); // возвращаем позицию конца вхождения            
  2381.                 mov edx,[endPos]
  2382.                 call ted_get_text_perv_pos
  2383.                 jmp @f
  2384.         .if_1e:
  2385.                 mov edx,ted_tex
  2386.         @@:
  2387.  
  2388.         ret
  2389. endp
  2390.  
  2391. ;input:
  2392. ; edx = pointer to char (byte)
  2393. ;output:
  2394. ; cf=1 if symbol is...
  2395. align 16
  2396. tab_all_num db 0,0,0,0,0,0,0xff,11b,11111110b,0xff,0xff,10000111b,11111110b,0xff,0xff,111b,0,0,0,0,0,0,0,0;,0,0,0,0,0,0,0,0 - tab_alpha_0,0,0,0,0,0,0,0
  2397. tab_alpha db 0,0,0,0,0,0,0,0,11111110b,0xff,0xff,10000111b,11111110b,0xff,0xff,111b,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  2398.  
  2399. ;output:
  2400. ; cf=1 если в [edx] буква, цифра или '_'
  2401. align 16
  2402. isalnum:
  2403.         push eax ebx
  2404.         movzx eax,byte[edx] ;al=offset
  2405.         shr eax,3
  2406.         lea ebx,[tab_all_num]
  2407.         add ebx,eax
  2408.         movzx ax,byte[edx] ;al=bit
  2409.         and ax,111b
  2410.         bt word[ebx],ax
  2411.         pop ebx eax
  2412.         ret
  2413.  
  2414. ;output:
  2415. ; cf=1 если в [edx] буква или '_'
  2416. align 16
  2417. isalpha:
  2418.         push eax ebx
  2419.         movzx eax,byte[edx] ;al=offset
  2420.         shr eax,3
  2421.         lea ebx,[tab_alpha]
  2422.         add ebx,eax
  2423.         movzx ax,byte[edx] ;al=bit
  2424.         and ax,111b
  2425.         bt word[ebx],ax
  2426.         pop ebx eax
  2427.         ret
  2428.  
  2429. align 16
  2430. proc ted_show_help_f1 uses eax edx edi, edit:dword
  2431.         mov edi,[edit]
  2432.  
  2433.         call ted_get_pos_by_cursor
  2434.         push edx
  2435.                 call ted_iterat_next_color_tag
  2436.                 mov eax,edx
  2437.         pop edx
  2438.         call ted_iterat_perv_color_tag
  2439.  
  2440.         cmp eax,ted_tex
  2441.         jle @f
  2442.         cmp edx,ted_tex_1
  2443.         jle @f
  2444.                 stdcall ted_find_help_id,eax
  2445.         @@:
  2446.         ;call ted_draw_main_cursor
  2447.         call ted_draw_help_f1
  2448.         ret
  2449. endp
  2450.  
  2451. ;input:
  2452. ; edx = position begin 'symbol' struct
  2453. ; edi = pointer to tedit struct
  2454. ; end_pos = position end 'symbol' struct
  2455. align 16
  2456. proc ted_find_help_id uses ebx ecx, end_pos:dword
  2457. ; ecx = word_n
  2458. ; ebx = l_pos
  2459.   mov ted_help_id,-1
  2460.  
  2461.     movzx ebx,byte[edx]
  2462.     shl ebx,2 ;ebx*=4
  2463.     add ebx,ted_arr_key_pos
  2464.     mov ecx,[ebx]
  2465.     cmp ecx,0
  2466.     jl .if_0e ;if( (word_n=ted_arr_key_pos[(unsigned char)tf[0]])>-1 ){
  2467.       push esi eax
  2468.       mov ebx,ecx ;l_pos=word_n;
  2469.       ColToIndexOffset ecx,esi
  2470.       push cx
  2471.       mov cl,[esi]
  2472.       @@:
  2473.         cmp ebx,ted_key_words_count ;while(l_pos<ted_key_words_count)
  2474.         jge @f
  2475.         ;ColToIndexOffset ecx,esi
  2476.         ColToIndexOffset ebx,eax
  2477.         cmp cl,[eax] ;&& Col[l_pos].Text[0]==Col[word_n].Text[0])
  2478.         jne @f
  2479.           inc ebx ;l_pos++;
  2480.           jmp @b
  2481.       @@:
  2482.       pop cx
  2483.       call ted_iterat_next ;pos=1;
  2484.       mov esi,1
  2485.       @@:
  2486.         push dx
  2487.         push word[edx]
  2488.         pop dx
  2489.           .wh_0b:
  2490.             cmp ebx,ecx ;while(l_pos>word_n
  2491.             jle .wh_0e
  2492.             dec ebx
  2493.             ColToIndexOffset ebx,eax
  2494.             inc ebx
  2495.             cmp byte[eax+esi],dl ;&& Col[l_pos-1].Text[pos]!=tf[i])
  2496.             je .wh_0e
  2497.               dec ebx ;l_pos--;
  2498.             jmp .wh_0b
  2499.           .wh_0e:
  2500.  
  2501.           .wh_1b:
  2502.             cmp ebx,ecx ;while(l_pos>word_n
  2503.             jle .wh_1e
  2504.             ColToIndexOffset ecx,eax
  2505.             cmp byte[eax+esi],dl
  2506.             je .wh_1e
  2507.               inc ecx ;word_n++;
  2508.             jmp .wh_1b
  2509.           .wh_1e:
  2510.         pop dx
  2511.  
  2512.         cmp ecx,ebx ;if(word_n==l_pos) break;
  2513.         je @f
  2514.         call ted_iterat_next ;pos++;
  2515.         cmp edx,[end_pos] ;for(...;i<strlen;...)
  2516.         je @f ;jge
  2517.         inc esi
  2518.         jmp @b
  2519.       @@:
  2520.       pop eax esi
  2521.  
  2522.       mov ted_help_id,ecx
  2523.       ;return word_n;
  2524.  
  2525.     .if_0e:
  2526.   ret
  2527. endp
  2528.  
  2529. ;output:
  2530. ; eax = код ошибки
  2531. ; ebx = колличество прочитанных байт
  2532. align 16
  2533. proc ted_open_file uses ecx edx edi, edit:dword, file:dword, f_name:dword ;функция открытия файла
  2534.         mov edi,[edit]
  2535.  
  2536.         ; *** проверяем размер памяти и если не хватает то увеличиваем ***
  2537.         ;пробуем получить информацию о файле
  2538.         mov ebx,[file]
  2539.         mov dword[ebx], SSF_GET_INFO
  2540.         mov dword[ebx+4], 0
  2541.         mov dword[ebx+8], 0
  2542.         mov dword[ebx+12], 0
  2543.         m2m dword[ebx+16], ted_tex
  2544.         mov  byte[ebx+20], 0
  2545.         push dword[f_name]
  2546.         pop dword[ebx+21]
  2547.         mcall SF_FILE
  2548.         or eax,eax
  2549.         jz .end_0
  2550.                 mov edx,ted_max_chars
  2551.                 cmp eax,2 ;функция не поддерживается для данной файловой системы
  2552.                 je @f
  2553.                 jmp .ret_f
  2554. align 4
  2555.         .end_0:
  2556.         ;проверяем хватит ли памяти для загрузки файла
  2557.         mov ecx,ted_max_chars
  2558.         sub ecx,2 ;ecx = максимальное число байт, для которых была выделена память
  2559.         mov edx,ted_tex
  2560.         mov edx,[edx+32] ;+32 = +0x20: qword: размер файла в байтах
  2561.         cmp edx,ecx
  2562.         jl @f
  2563.                 ;увеличиваем память если не хватило
  2564.                 mov ecx,edx ;память необходимая для открытия файла
  2565.                 add ecx,2  ;память для служебных начального и конечного символов
  2566.                 add ecx,ted_increase_size ;память для редактирования файла
  2567.                 mov ted_max_chars,ecx
  2568.                 imul ecx,sizeof.symbol
  2569.                 invoke mem.realloc, ted_tex,ecx
  2570.                 mov ted_tex,eax
  2571.                 mov ted_tex_1,eax
  2572.                 add ted_tex_1,sizeof.symbol
  2573.                 add eax,ecx
  2574.                 mov ted_tex_end,eax
  2575.                 mov ecx,ted_tex_1
  2576.                 add ecx,sizeof.symbol
  2577.                 mov ted_ptr_free_symb,ecx
  2578.         @@:
  2579.  
  2580.         ; *** пробуем открыть файл ***
  2581.         mov ebx,[file]
  2582.         mov dword[ebx], SSF_READ_FILE
  2583.         mov dword[ebx+4], 0
  2584.         mov dword[ebx+8], 0
  2585.         m2m dword[ebx+12], edx ;число байт, которые могут быть считаны с файла (не больше чем ted_max_chars)
  2586.         m2m dword[ebx+16], ted_tex
  2587.         mov  byte[ebx+20], 0
  2588.         push dword[f_name]
  2589.         pop dword[ebx+21]
  2590.         mcall SF_FILE
  2591.  
  2592.         or eax,eax
  2593.         jz @f
  2594.         cmp eax,6
  2595.         jne .ret_f
  2596.         @@:
  2597.         cmp ebx,-1
  2598.         je .ret_f
  2599.                 ;if open file
  2600.                 call ted_on_open_file
  2601.         .ret_f:
  2602.         ret
  2603. endp
  2604.  
  2605. align 16
  2606. proc ted_but_select_word, edit:dword
  2607.         pushad
  2608.         mov edi,[edit]
  2609.  
  2610.         call ted_get_pos_by_cursor
  2611.         push edx
  2612.                 call ted_iterat_perv_color_tag
  2613.                 cmp edx,ted_tex_1
  2614.                 jle @f
  2615.                         call ted_get_text_coords
  2616.                         mov ted_sel_x0,ebx
  2617.                         mov ted_sel_y0,eax
  2618.                 @@:
  2619.         pop edx
  2620.         call ted_iterat_next_color_tag
  2621.         cmp edx,ted_tex_1
  2622.         jle @f
  2623.                 call ted_get_text_coords
  2624.                 mov ted_sel_x1,ebx
  2625.                 mov ted_sel_y1,eax
  2626.         @@:
  2627.  
  2628.         cmp ted_fun_draw_panel_buttons,0
  2629.         je @f
  2630.                 call ted_fun_draw_panel_buttons
  2631.         @@:
  2632.         stdcall ted_draw,edi
  2633.         popad
  2634.         ret
  2635. endp
  2636.  
  2637. ;output:
  2638. ; al = 1 if delete
  2639. align 16
  2640. proc ted_but_cut uses edi, edit:dword
  2641.         mov edi,[edit]
  2642.  
  2643.         stdcall ted_but_copy,edi
  2644.         call ted_set_undo
  2645.         stdcall ted_sel_text_del,ted_opt_ed_change_time
  2646.  
  2647.         cmp al,1
  2648.         jne @f
  2649.                 stdcall ted_draw,edi
  2650.                 cmp ted_fun_draw_panel_buttons,0
  2651.                 je @f
  2652.                         call ted_fun_draw_panel_buttons
  2653.         @@:
  2654.         ret
  2655. endp
  2656.  
  2657. align 16
  2658. proc ted_but_copy, edit:dword
  2659.         pushad
  2660.         mov edi,[edit]
  2661.  
  2662.         call ted_is_select
  2663.         or al,al
  2664.         jz .end_f ;if not selected text
  2665.         call ted_sel_normalize
  2666.  
  2667.         mov esi,ted_seln_x1
  2668.         mov ecx,ted_seln_y1
  2669.         call ted_get_pos_by_coords
  2670.         mov ebx,edx
  2671.         mov esi,ted_seln_x0
  2672.         mov ecx,ted_seln_y0
  2673.         call ted_get_pos_by_coords
  2674.         mov esi,ebx
  2675.  
  2676.         mov ecx,12 ;system buffer header size
  2677.         mov ebx,ted_buffer
  2678.         mov dword[ebx+4],0 ;text data
  2679.         mov dword[ebx+8],1 ;code 866
  2680.         add ebx,ecx
  2681.         @@:
  2682.                 cmp edx,ted_tex_1 ;end of file
  2683.                 jle @f
  2684.                 cmp edx,esi ;end of select
  2685.                 je @f
  2686.                 inc ecx
  2687.                 cmp ecx,ted_buffer_size ;owerflow bufer
  2688.                 je @f
  2689.  
  2690.                 mov al,byte[edx]
  2691.                 mov byte[ebx],al
  2692.                 inc ebx
  2693.                 cmp al,13
  2694.                 jne .no_13
  2695.                         mov byte[ebx],10 ;делаем конец строки в буфере 13,10 для совместимости с другими программами
  2696.                         inc ebx
  2697.                         inc ecx
  2698.                 .no_13:
  2699.                
  2700.                 call ted_iterat_next
  2701.                 jmp @b
  2702.         @@:
  2703.         mov byte[ebx],0
  2704.  
  2705.         cmp ecx,12
  2706.         je .end_f
  2707.                 mov ebx,ted_buffer
  2708.                 mov [ebx],ecx
  2709.                 mcall SF_CLIPBOARD,SSF_WRITE_CB,ecx,ted_buffer
  2710.                 call ted_draw_buffer
  2711.                 cmp ted_fun_draw_panel_buttons,0
  2712.                 je .end_f
  2713.                         call ted_fun_draw_panel_buttons
  2714.         .end_f:
  2715.         popad
  2716.         ret
  2717. endp
  2718.  
  2719.  
  2720. align 16
  2721. proc ted_but_paste, edit:dword
  2722.         pushad
  2723.         mov edi,[edit]
  2724.  
  2725.         mcall SF_CLIPBOARD,SSF_GET_SLOT_COUNT
  2726.         cmp eax,1
  2727.         jl .no_buf_r
  2728.  
  2729.         mov esi,eax
  2730.         .cycle: ;обратный цикл по слотам
  2731.         dec esi ;номер текущего, проверяемого слота
  2732.         mcall SF_CLIPBOARD,SSF_READ_CB,esi
  2733.         cmp eax,1
  2734.         je .no_buf_r
  2735.         cmp eax,-1
  2736.         je .no_buf_r
  2737.                 mov ecx,[eax]
  2738.                 cmp ecx,1 ;size
  2739.                 jl .no_buf_r
  2740.                 cmp dword[eax+4],0 ;text
  2741.                 je @f