Subversion Repositories Kolibri OS

Rev

Rev 2080 | Rev 2125 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. use32
  2.         org 0x0
  3.         db 'MENUET01' ;идентиф. исполняемого файла всегда 8 байт
  4.         dd 0x1
  5.         dd start
  6.         dd i_end ;размер приложения
  7.         dd mem
  8.         dd stacktop
  9.         dd 0
  10.         dd sys_path
  11.  
  12. include '../../macros.inc'
  13. include '../../proc32.inc'
  14. include '../../develop/libraries/box_lib/load_lib.mac'
  15. include '../../develop/libraries/box_lib/trunk/box_lib.mac'
  16. include 'mem.inc'
  17. include 'dll.inc'
  18. include 'lang.inc'
  19.  
  20. debug equ 0
  21.  
  22. @use_library_mem mem.Alloc,mem.Free,mem.ReAlloc,dll.Load
  23.  
  24. struct FileInfoBlock
  25.         Function dd ?
  26.         Position dd ?
  27.         Flags    dd ?
  28.         Count    dd ?
  29.         Buffer   dd ?
  30.                 db ?
  31.         FileName dd ?
  32. ends
  33.  
  34. run_file_70 FileInfoBlock
  35. image_data dd 0 ;указатель на временную память. для нужен преобразования изображения
  36. open_file_lif dd 0 ;указатель на память для открытия файлов 3ds
  37.  
  38. ;
  39. fn_toolbar db 'toolbar.png',0
  40. IMAGE_TOOLBAR_ICON_SIZE equ 16*16*3
  41. IMAGE_TOOLBAR_SIZE equ IMAGE_TOOLBAR_ICON_SIZE*7
  42. image_data_toolbar dd 0
  43. ;
  44. TREE_ICON_SYS16_BMP_SIZE equ IMAGE_TOOLBAR_ICON_SIZE*11+54 ;размер bmp файла с системными иконками
  45. icon_tl_sys dd 0 ;указатеель на память для хранения системных иконок
  46. icon_toolbar dd 0 ;указатеель на память для хранения иконок объектов
  47. TOOLBAR_ICON_BMP_SIZE equ IMAGE_TOOLBAR_ICON_SIZE*7+54 ;размер bmp файла с иконками объектов
  48. ;
  49. IMAGE_FILE1_SIZE equ 128*144*3+54 ;размер файла с изображением
  50.  
  51. macro load_image_file path,buf,size { ;макрос для загрузки изображений
  52.         ;path - может быть переменной или строковым параметром
  53.         if path eqtype '' ;проверяем задан ли строкой параметр path
  54.                 jmp @f
  55.                         local .path_str
  56.                         .path_str db path ;формируем локальную переменную
  57.                         db 0
  58.                 @@:
  59.                 ;32 - стандартный адрес по которому должен быть буфер с системным путем
  60.                 copy_path .path_str,[32],file_name,0x0
  61.         else
  62.                 copy_path path,[32],file_name,0x0 ;формируем полный путь к файлу изображения, подразумеваем что он в одной папке с программой
  63.         end if
  64.  
  65.         stdcall mem.Alloc, dword size ;выделяем память для изображения
  66.         mov [buf],eax
  67.  
  68.         mov eax,70 ;70-я функция работа с файлами
  69.         mov [run_file_70.Function], 0
  70.         mov [run_file_70.Position], 0
  71.         mov [run_file_70.Flags], 0
  72.         mov [run_file_70.Count], dword size
  73.         m2m [run_file_70.Buffer], [buf]
  74.         mov byte[run_file_70+20], 0
  75.         mov [run_file_70.FileName], file_name
  76.         mov ebx,run_file_70
  77.         int 0x40 ;загружаем файл изображения
  78.         cmp ebx,0xffffffff
  79.         je @f
  80.                 ;определяем вид изображения и переводим его во временный буфер image_data
  81.                 stdcall dword[img_decode], dword[buf],ebx,0
  82.                 mov dword[image_data],eax
  83.                 ;преобразуем изображение к формату rgb
  84.                 stdcall dword[img_to_rgb2], dword[image_data],dword[buf]
  85.                 ;удаляем временный буфер image_data
  86.                 stdcall dword[img_destroy], dword[image_data]
  87.         @@:
  88. }
  89.  
  90. ;--------------------------------------
  91. include 'data.inc'
  92.  
  93. level_stack dd 0
  94. offs_last_timer dd 0 ;последний сдвиг показаный в функции таймера
  95.  
  96. ID_ICON_CHUNK_MAIN equ 0 ;иконка главного блока
  97. ID_ICON_CHUNK_NOT_FOUND equ 1 ;иконка не известного блока
  98. ID_ICON_DATA equ 2 ;иконка для данных блока, не определенной структуры
  99.  
  100. FILE_ERROR_CHUNK_SIZE equ -3 ;ошибка в размере блока
  101.  
  102. align 4
  103. file_3ds:
  104. .offs: dd 0 ;+0 указатель на начало блока
  105. .size: dd 0 ;+4 размер блока (для 1-го параметра = размер файла 3ds)
  106. rb 8*MAX_FILE_LEVEL
  107.  
  108. size_one_list equ 40
  109. list_offs_text equ 12 ;сдвиг начала текста в листе
  110. buffer rb size_one_list ;буфер для добавления структур в список tree1
  111.  
  112. txt_3ds_symb db 0,0
  113. ;--------------------------------------
  114.  
  115.  
  116. align 4
  117. start:
  118.         load_libraries l_libs_start,l_libs_end
  119.         ;проверка на сколько удачно загузилась наша либа
  120.         mov     ebp,lib_7
  121.         cmp     dword [ebp+ll_struc_size-4],0
  122.         jz      @f
  123.                 mcall -1 ;exit not correct
  124.         @@:
  125.         mcall 48,3,sc,sizeof.system_colors
  126.         mcall 40,0x27
  127.         stdcall [OpenDialog_Init],OpenDialog_data ;подготовка диалога
  128.  
  129.         stdcall dword[tl_data_init], tree1
  130.         ;системные иконки 16*16 для tree_list
  131.         load_image_file 'tl_sys_16.png', icon_tl_sys,TREE_ICON_SYS16_BMP_SIZE
  132.         ;если изображение не открылось, то в icon_tl_sys будут
  133.         ;не инициализированные данные, но ошибки не будет, т. к. буфер нужного размера
  134.         mov eax,dword[icon_tl_sys]
  135.         mov dword[tree1.data_img_sys],eax
  136.  
  137.         load_image_file 'objects.png', icon_toolbar,TOOLBAR_ICON_BMP_SIZE
  138.         mov eax,dword[icon_toolbar]
  139.         mov dword[tree1.data_img],eax
  140.  
  141.         stdcall [buf2d_create], buf_0 ;создание буфера
  142.  
  143.         load_image_file 'font8x9.bmp', image_data_toolbar,IMAGE_FILE1_SIZE
  144.         stdcall [buf2d_create_f_img], buf_1,[image_data_toolbar] ;создаем буфер
  145.         stdcall mem.Free,[image_data_toolbar] ;освобождаем память
  146.         stdcall [buf2d_conv_24_to_8], buf_1,1 ;делаем буфер прозрачности 8 бит
  147.         stdcall [buf2d_convert_text_matrix], buf_1
  148.  
  149.         load_image_file fn_toolbar, image_data_toolbar,IMAGE_TOOLBAR_SIZE
  150.  
  151.         stdcall mem.Alloc,MAX_FILE_SIZE
  152.         mov dword[open_file_lif],eax
  153.  
  154.         mcall 26,9
  155.         mov [last_time],eax
  156.  
  157. align 4
  158. red_win:
  159.         call draw_window
  160.  
  161. align 4
  162. still:
  163.         mcall 26,9
  164.         mov ebx,[last_time]
  165.         add ebx,10 ;задержка
  166.         cmp ebx,eax
  167.         jge @f
  168.                 mov ebx,eax
  169.         @@:
  170.         sub ebx,eax
  171.         ;cmp ebx,10 ;задержка
  172.         ;ja timer_funct
  173.         ;test ebx,ebx
  174.         ;jz timer_funct
  175.         mcall 23
  176.         cmp eax,0
  177.         je timer_funct
  178.  
  179.         cmp al,1
  180.         jz red_win
  181.         cmp al,2
  182.         jz key
  183.         cmp al,3
  184.         jz button
  185.         cmp al,6
  186.         jne @f
  187.                 call mouse
  188.         @@:
  189.         jmp still
  190.  
  191. align 4
  192. mouse:
  193.         stdcall [tl_mouse], dword tree1
  194.         ret
  195.  
  196. align 4
  197. timer_funct:
  198.         pushad
  199. if debug
  200.         mov eax,4
  201.         mov ebx,(5 shl 16)+8
  202.         mov ecx,0xff+0x80000000
  203.         mov edx,txt_0002
  204.         int 0x40
  205. end if
  206.         mcall 26,9
  207.         mov [last_time],eax
  208.  
  209.         ;
  210.         stdcall [tl_node_get_data],tree1
  211.         pop ebx
  212.         cmp ebx,0
  213.         je @f
  214.                 mov eax,dword[ebx] ;получаем значение сдвига выбранного блока относительно начала файла
  215.                 mov ecx,dword[ebx+4]
  216.                 stdcall hex_in_str, txt_3ds_offs.dig, eax,8
  217.  
  218.                 add eax,dword[open_file_lif] ;получаем значение сдвига в памяти
  219.                 cmp dword[offs_last_timer],eax
  220.                 je @f
  221.                         mov dword[offs_last_timer],eax
  222.                         call buf_draw_beg
  223.                         stdcall [buf2d_draw_text], buf_0, buf_1,txt_3ds_offs,5,35,0xb000
  224.                         mov edx,dword[ebx+8]
  225.                         cmp edx,0 ;смотрим есть ли описание блока
  226.                         je .no_info
  227.                                 stdcall [buf2d_draw_text], buf_0, buf_1,edx,5,45,0xb000
  228.                         .no_info:
  229.                         add ecx,eax ;получаем размер блока
  230.                         stdcall buf_draw_hex_table,eax,ecx ;добавление 16-ричных данных
  231.                         stdcall [buf2d_draw], buf_0 ;обновляем буфер на экране
  232.         @@:
  233.         popad
  234.         jmp still
  235.  
  236. align 4
  237. buf_draw_beg:
  238.         stdcall [buf2d_clear], buf_0, [buf_0.color] ;чистим буфер
  239.         stdcall [buf2d_draw_text], buf_0, buf_1,txt_open_3ds,5,5,0xff
  240.         stdcall [buf2d_draw_text], buf_0, buf_1,openfile_path,5,15,0xff
  241.         cmp dword[level_stack],FILE_ERROR_CHUNK_SIZE ;возможна ошибка файла
  242.         jne @f
  243.                 stdcall [buf2d_draw_text], buf_0, buf_1,txt_3ds_err_sizes,5,25,0xff0000
  244.         @@:
  245.         ret
  246.  
  247. align 4
  248. proc buf_draw_hex_table, offs:dword, size_line:dword
  249.         pushad
  250.         locals
  251.                 coord_y dd 55 ;координата y для начала вывода таблицы
  252.         endl
  253.                 mov esi,dword[offs]
  254.                 mov edi,dword[open_file_lif]
  255.                 add edi,dword[file_3ds.size] ;edi - указатель на конец файла в памяти
  256.                 mov dword[txt_3ds_offs.dig],0
  257.                 cld
  258.                 .cycle_rows:
  259.                         mov ebx,5 ;отступ слева для цифр
  260.                         mov edx,5+10*24 ;отступ слева для текста
  261.                         mov ecx,10
  262.                         @@:
  263.                                 stdcall hex_in_str, txt_3ds_offs.dig, dword[esi],2
  264.                                 stdcall [buf2d_draw_text], buf_0, buf_1,txt_3ds_offs.dig,ebx,[coord_y],0
  265.  
  266.                                 mov al,byte[esi]
  267.                                 mov byte[txt_3ds_symb],al
  268.                                 stdcall [buf2d_draw_text], buf_0, buf_1,txt_3ds_symb,edx,[coord_y],0x808080
  269.                                 inc esi
  270.                                 cmp esi,dword[size_line]
  271.                                 jne .end_block
  272.                                         stdcall draw_block_end_line, dword[coord_y]
  273.                                 .end_block:
  274.                                 cmp esi,edi
  275.                                 jge @f ;jg ???
  276.                                 add ebx,24
  277.                                 add edx,9 ;ширина 1-го символа +1pix
  278.                                 loop @b
  279.                         add dword[coord_y],10 ;высота 1-го символа (или интервал между строками)
  280.                         mov ebx,dword[buf_0.h]
  281.                         cmp dword[coord_y],ebx
  282.                         jl .cycle_rows
  283.                 @@:
  284.         popad
  285.         ret
  286. endp
  287.  
  288. align 4
  289. proc draw_block_end_line, coord_y:dword
  290.         push eax ebx ecx
  291.                 add ebx,20 ;20 = width 2.5 symbols
  292.                 mov eax,[coord_y]
  293.                 sub eax,2
  294.                 mov ecx,eax
  295.                 add ecx,10
  296.                 stdcall [buf2d_line], buf_0, 0,ecx,ebx,ecx ,0xff
  297.                 stdcall [buf2d_line], buf_0, ebx,ecx,ebx,eax ,0xff
  298.                 stdcall [buf2d_line], buf_0, ebx,eax,5+10*24-4,eax ,0xff
  299.         pop ecx ebx eax
  300.         ret
  301. endp
  302.  
  303. align 4
  304. draw_window:
  305. pushad
  306.         mcall 12,1
  307.         xor eax,eax
  308.         mov ebx,(20 shl 16)+560
  309.         mov ecx,(20 shl 16)+315
  310.         mov edx,[sc.work]
  311.         or  edx,(3 shl 24)+0x10000000+0x20000000
  312.         mov edi,capt
  313.         int 0x40
  314.  
  315.         mov eax,8
  316.         mov ebx,(5 shl 16)+20
  317.         mov ecx,(5 shl 16)+20
  318.         mov edx,3
  319.         mov esi,[sc.work_button]
  320.         int 0x40
  321.  
  322.         mov ebx,(30 shl 16)+20
  323.         mov ecx,(5 shl 16)+20
  324.         mov edx,4
  325.         int 0x40
  326.  
  327.         ;mov ebx,(55 shl 16)+20
  328.         ;mov ecx,(5 shl 16)+20
  329.         ;mov edx,5
  330.         ;int 0x40
  331.  
  332.  
  333.         mov eax,7
  334.         mov ebx,[image_data_toolbar]
  335.         mov ecx,(16 shl 16)+16
  336.         mov edx,(7 shl 16)+7 ;new
  337.         int 0x40
  338.  
  339.         add ebx,IMAGE_TOOLBAR_ICON_SIZE
  340.         mov edx,(32 shl 16)+7 ;open
  341.         int 0x40
  342.  
  343.         ;add ebx,IMAGE_TOOLBAR_ICON_SIZE
  344.         ;mov edx,(57 shl 16)+7 ;save
  345.         ;int 0x40
  346.  
  347.         mov dword[w_scr_t1.all_redraw],1
  348.         stdcall [tl_draw],dword tree1
  349.  
  350.         stdcall [buf2d_draw], buf_0
  351.  
  352.         mcall 12,2
  353. popad
  354.         ret
  355.  
  356. align 4
  357. key:
  358.         mcall 2
  359.         stdcall [tl_key], dword tree1
  360.         jmp still
  361.  
  362.  
  363. align 4
  364. button:
  365.         mcall 17
  366.         cmp ah,3
  367.         jne @f
  368.                 call but_new_file
  369.         @@:
  370.         cmp ah,4
  371.         jne @f
  372.                 call but_open_file
  373.         @@:
  374.         cmp ah,5
  375.         jne @f
  376.                 call but_save_file
  377.         @@:
  378.  
  379.         cmp ah,1
  380.         jne still
  381. .exit:
  382.         mov dword[tree1.data_img],0
  383.         mov dword[tree1.data_img_sys],0
  384.         stdcall dword[tl_data_clear], tree1
  385.         stdcall [buf2d_delete],buf_0
  386.         stdcall [buf2d_delete],buf_1 ;удаляем буфер
  387.         stdcall mem.Free,[image_data_toolbar]
  388.         stdcall mem.Free,[open_file_lif]
  389.         mcall -1
  390.  
  391.  
  392. align 4
  393. but_new_file:
  394.         stdcall [tl_info_clear], tree1 ;очистка списка объектов
  395.         stdcall [buf2d_clear], buf_0, [buf_0.color] ;чистим буфер
  396.         ;;;call draw_window
  397.         stdcall [tl_draw], tree1
  398.         stdcall [buf2d_draw], buf_0 ;обновляем буфер на экране
  399.         ret
  400.  
  401. align 4
  402. but_open_file:
  403.         pushad
  404.         copy_path open_dialog_name,communication_area_default_path,file_name,0
  405.         mov [OpenDialog_data.type],0
  406.         stdcall [OpenDialog_Start],OpenDialog_data
  407.         cmp [OpenDialog_data.status],2
  408.         je .end_open_file
  409.         ;код при удачном открытии диалога
  410.  
  411.         mov eax,70 ;70-я функция работа с файлами
  412.         mov [run_file_70.Function], 0
  413.         mov [run_file_70.Position], 0
  414.         mov [run_file_70.Flags], 0
  415.         mov dword[run_file_70.Count], MAX_FILE_SIZE
  416.         m2m [run_file_70.Buffer], dword[open_file_lif]
  417.         mov byte[run_file_70+20], 0
  418.         mov dword[run_file_70.FileName], openfile_path
  419.         mov ebx,run_file_70
  420.         int 0x40 ;загружаем файл изображения
  421.         cmp ebx,0xffffffff
  422.         je .end_open_file
  423.  
  424.         ;add ebx,[open_file_lif]
  425.         ;mov byte[ebx],0 ;на случай если ранее был открыт файл большего размера чистим конец буфера с файлом
  426.         ;mcall 71,1,openfile_path
  427.  
  428.         stdcall [tl_info_clear], tree1 ;очистка списка объектов
  429.  
  430.         mov esi,dword[open_file_lif]
  431.         cmp word[esi],CHUNK_MAIN
  432.         je @f
  433.                 call buf_draw_beg
  434.                 stdcall [buf2d_draw_text], buf_0, buf_1,txt_no_3ds,5,25,0xff0000 ;рисуем строку с текстом
  435.                 jmp .end_open
  436.         @@:
  437.         cmp dword[esi+2],MAX_FILE_SIZE
  438.         jle @f
  439.                 call buf_draw_beg
  440.                 stdcall [buf2d_draw_text], buf_0, buf_1,txt_3ds_big_file,5,25,0xff0000 ;рисуем строку с текстом
  441.                 jmp .end_open
  442.         @@:
  443.         ;--- обработка открытого *.3ds файла
  444.         mov eax,file_3ds
  445.         mov dword[level_stack],0 ;обнуляем уровень стека
  446.         mov dword[offs_last_timer],0
  447.         ;--- добавление главного блока в список
  448.         stdcall add_3ds_object, ID_ICON_CHUNK_MAIN,0,dword[esi+2],0
  449.         call block_children ;вход в дочерний блок
  450.  
  451.         mov edi,dword[file_3ds.offs]
  452.         add edi,dword[file_3ds.size]
  453.         .cycle_main:
  454.                 cmp dword[level_stack],0
  455.                 jle .end_cycle
  456.                
  457.                 cmp esi,edi ;если конец файла
  458.                 jge .end_cycle
  459.  
  460.                 mov edx,dword[esi+2] ;размер блока
  461.                 call block_analiz
  462.                 cmp dword[bl_found],0
  463.                 jne @f
  464.                         ;объект не известного вида
  465.                         stdcall add_3ds_object, ID_ICON_CHUNK_NOT_FOUND,dword[level_stack],edx,0
  466.                         call block_next
  467.                         jmp .cycle_main
  468.                 @@:
  469.                         ;объект известного вида
  470.                         mov ecx,dword[bl_found]
  471.                         mov bx,word[ecx+2] ;номер иконки для объекта
  472.                         stdcall add_3ds_object, ebx,dword[level_stack],edx,dword[ecx+5]
  473.                         cmp byte[ecx+4],1
  474.                         je .bl_data
  475.                                 ;блок содержит дочерние блоки
  476.                                 call block_children ;вход в дочерний блок
  477.                                 jmp .cycle_main
  478.                         .bl_data:
  479.                                 ;блок содержит данные
  480.                                 call block_analiz_data
  481.                                 jmp .cycle_main
  482.         .end_cycle:
  483.                 stdcall [tl_cur_beg], tree1
  484.                 stdcall [tl_draw], tree1
  485.         .end_open:
  486.  
  487.         stdcall [buf2d_draw], buf_0 ;обновляем буфер на экране
  488.         .end_open_file:
  489.         popad
  490.         ret
  491.  
  492. ;анализ данных блока
  493. ;input:
  494. ; esi - memory pointer
  495. ;output:
  496. ; eax - new stack pointer
  497. ; esi - new memory pointer
  498. align 4
  499. block_analiz_data:
  500.         push ebx ecx edx edi
  501.                 mov dx,word[esi]
  502.                 mov ecx,dword[esi+2]
  503.                 sub ecx,6 ;размер данных в блоке
  504.                 add esi,6
  505.                 mov ebx,dword[level_stack]
  506.                 inc ebx
  507.                 ; *** анализ блоков с разными данными и выделением подблоков
  508.                 cmp dx,CHUNK_OBJBLOCK ;объект
  509.                 jne @f
  510.                         .cycle_0:
  511.                                 push ax
  512.                                         cld
  513.                                         xor al,al
  514.                                         mov edi,esi
  515.                                         repne scasb
  516.                                 pop ax
  517.                                 sub edi,esi ;edi - strlen
  518.                                 stdcall add_3ds_object, ID_ICON_DATA,ebx,edi,0 ;название объекта
  519.                                 add esi,edi
  520.                                 sub ecx,edi
  521.                         jmp .next_bl
  522.                 @@:
  523.                 ; *** анализ блока с данными по умолчанию (без выделения подблоков)
  524.                         stdcall add_3ds_object, ID_ICON_DATA,ebx,ecx,0
  525.                         sub esi,6 ;восстановление esi
  526.                         call block_next
  527.                         jmp .end_f
  528.                 .next_bl:
  529.                 ; *** настройки для анализа оставшихся подблоков
  530.                         mov dword[eax],esi ;указатель на начало блока
  531.                         mov ebx,dword[esi+2]
  532.                         mov dword[eax+4],ebx ;размер блока
  533.                         inc dword[level_stack]
  534.                         add eax,8
  535.                 .end_f:
  536.         pop edi edx ecx ebx
  537.         ret
  538.  
  539. ;вход в 1-й дочерний блок
  540. ;output:
  541. ; edx - destroy
  542. align 4
  543. block_children:
  544.         push ecx
  545.                 ;проверка правильности размеров дочернего блока
  546.                 mov ebx,esi ;смещение начала родительского блока
  547.                 add ebx,6 ;переход на начало дочернего блока
  548.                 add ebx,dword[ebx+2] ;добавляем размер дочернего блока
  549.                 mov ecx,esi ;смещение начала родительского блока
  550.                 add ecx,dword[esi+2] ;добавляем размер родительского блока
  551.                 cmp ebx,ecx ;учитывать заголовки не нужно, т. к. сравниваются только данные блоков
  552.                 jle @f
  553.                         ;диагностировали ошибку файла, дочерний блок выходит за пределы родительского
  554.                         mov dword[level_stack],FILE_ERROR_CHUNK_SIZE
  555.                         jmp .end_f
  556.                 @@:
  557.                 mov dword[eax],esi ;указатель на начало блока
  558.                 mov ebx,dword[esi+2]
  559.                 mov dword[eax+4],ebx ;размер блока
  560.                 add esi,6 ;переходим к данным блока
  561.                 inc dword[level_stack]
  562.                 add eax,8
  563.         .end_f:
  564.         pop ecx
  565.         ret
  566.  
  567. ;переход к следущему блоку текущего уровня
  568. align 4
  569. block_next:
  570. push ebx
  571.         add esi,dword[esi+2] ;пропускаем данные блока
  572.  
  573.         ;проверка размеров родительского блока, для возможного выхода на верхний уровень если конец блока
  574.         @@:
  575.         mov ebx,dword[eax-8]
  576.         add ebx,dword[eax-4]
  577.         cmp esi,ebx
  578.         jl @f
  579.                 dec dword[level_stack]
  580.                 sub eax,8
  581.                 cmp dword[level_stack],0
  582.                 jg @b
  583.         @@:
  584. pop ebx
  585.         ret
  586.  
  587. ;функция поиска структуры описывающей блок
  588. ;input:
  589. ;esi - memory pointer
  590. ;output:
  591. ;dword[bl_found] - pointer to chunk struct (= 0 if not found)
  592. align 4
  593. bl_found dd 0
  594. block_analiz:
  595. pushad
  596.         mov dword[bl_found],0
  597.         mov ecx,type_bloks
  598.         @@:
  599.                 mov bx,word[ecx]
  600.                 cmp word[esi],bx
  601.                 je .found
  602.                 add ecx,sizeof.block_3ds
  603.                 cmp ecx,type_bloks.end
  604.                 jl @b
  605.         jmp .no_found
  606.         .found:
  607.                 mov dword[bl_found],ecx
  608.         .no_found:
  609. popad
  610.         ret
  611.  
  612. ;input:
  613. ; esi - указатель на анализируемые данные
  614. align 4
  615. proc add_3ds_object, icon:dword,level:dword,size_bl:dword,info_bl:dword
  616.         pushad
  617.                 mov bx,word[icon]
  618.                 shl ebx,16
  619.                 mov bx,word[level]
  620.  
  621.                 mov eax,esi
  622.                 sub eax,dword[open_file_lif]
  623.                 mov dword[buffer],eax ;смещение блока
  624.                 mov ecx,dword[size_bl]
  625.                 mov dword[buffer+4],ecx ;размер блока (используется в функции buf_draw_hex_table для рисования линии)
  626.                 mov ecx,dword[info_bl]
  627.                 mov dword[buffer+8],ecx
  628.                 stdcall hex_in_str, buffer+list_offs_text,dword[esi+1],2
  629.                 stdcall hex_in_str, buffer+list_offs_text+2,dword[esi],2 ;код 3ds блока
  630.                 cmp ecx,0
  631.                 jne @f
  632.                         mov byte[buffer+list_offs_text+4],0 ;0 - символ конеца строки
  633.                         jmp .no_capt
  634.                 @@:
  635.                         mov byte[buffer+list_offs_text+4],' '
  636.                         mov esi,ecx
  637.                         mov edi,buffer+list_offs_text+5
  638.                         mov ecx,size_one_list-(list_offs_text+5)
  639.                         cld
  640.                         rep movsb
  641.                         mov byte[buffer+size_one_list-1],0 ;0 - символ конеца строки
  642.                 .no_capt:
  643.                 stdcall [tl_node_add], buffer, ebx, tree1
  644.                 stdcall [tl_cur_next], tree1
  645.                 if debug
  646.                         stdcall print_err,sz_add_3ds_object,buffer+list_offs_text
  647.                 end if
  648.         popad
  649.         ret
  650. endp
  651.  
  652. if debug
  653. sz_add_3ds_object db 13,10,'3ds_object',0
  654.  
  655. align 4
  656. proc print_err, fun:dword, mes:dword ;выводим сообщение об шибке на доску отладки
  657.         pushad
  658.         mov eax,63
  659.         mov ebx,1
  660.  
  661.         mov esi,[fun]
  662.         @@:
  663.                 mov cl,byte[esi]
  664.                 int 0x40
  665.                 inc esi
  666.                 cmp byte[esi],0
  667.                 jne @b
  668.         mov cl,':'
  669.         int 0x40
  670.         mov cl,' '
  671.         int 0x40
  672.         mov esi,[mes]
  673.         @@:
  674.                 mov cl,byte[esi]
  675.                 int 0x40
  676.                 inc esi
  677.                 cmp byte[esi],0
  678.                 jne @b
  679.         popad
  680.         ret
  681. endp
  682. end if
  683.  
  684. align 4
  685. proc hex_in_str, buf:dword,val:dword,zif:dword
  686.         pushad
  687.                 mov edi,dword[buf]
  688.                 mov ecx,dword[zif]
  689.                 add edi,ecx
  690.                 dec edi
  691.                 mov ebx,dword[val]
  692.  
  693.                 .cycle:
  694.                         mov al,bl
  695.                         and al,0xf
  696.                         cmp al,10
  697.                         jl @f
  698.                                 add al,'a'-'0'-10
  699.                         @@:
  700.                         add al,'0'
  701.                         mov byte[edi],al
  702.                         dec edi
  703.                         shr ebx,4
  704.                 loop .cycle
  705.  
  706.         popad
  707.         ret
  708. endp
  709.  
  710. align 4
  711. but_save_file:
  712. if debug
  713.         stdcall buf_draw_hex_table,dword[open_file_lif],3 ;добавление 16-ричных данных
  714. end if
  715.         ret
  716.  
  717.  
  718.  
  719. ;input:
  720. ; buf - указатель на строку, число должно быть в 10 или 16 ричном виде
  721. ;output:
  722. ; eax - число
  723. align 4
  724. proc conv_str_to_int, buf:dword
  725.         xor eax,eax
  726.         push ebx ecx esi
  727.         xor ebx,ebx
  728.         mov esi,[buf]
  729.         ;определение отрицательных чисел
  730.         xor ecx,ecx
  731.         inc ecx
  732.         cmp byte[esi],'-'
  733.         jne @f
  734.                 dec ecx
  735.                 inc esi
  736.         @@:
  737.  
  738.         cmp word[esi],'0x'
  739.         je .load_digit_16
  740.  
  741.         .load_digit_10: ;считывание 10-тичных цифр
  742.                 mov bl,byte[esi]
  743.                 cmp bl,'0'
  744.                 jl @f
  745.                 cmp bl,'9'
  746.                 jg @f
  747.                         sub bl,'0'
  748.                         imul eax,10
  749.                         add eax,ebx
  750.                         inc esi
  751.                         jmp .load_digit_10
  752.         jmp @f
  753.  
  754.         .load_digit_16: ;считывание 16-ричных цифр
  755.                 add esi,2
  756.         .cycle_16:
  757.                 mov bl,byte[esi]
  758.                 cmp bl,'0'
  759.                 jl @f
  760.                 cmp bl,'f'
  761.                 jg @f
  762.                 cmp bl,'9'
  763.                 jle .us1
  764.                         cmp bl,'A'
  765.                         jl @f ;отсеиваем символы >'9' и <'A'
  766.                 .us1: ;составное условие
  767.                 cmp bl,'F'
  768.                 jle .us2
  769.                         cmp bl,'a'
  770.                         jl @f ;отсеиваем символы >'F' и <'a'
  771.                         sub bl,32 ;переводим символы в верхний регистр, для упрощения их последущей обработки
  772.                 .us2: ;составное условие
  773.                         sub bl,'0'
  774.                         cmp bl,9
  775.                         jle .cor1
  776.                                 sub bl,7 ;convert 'A' to '10'
  777.                         .cor1:
  778.                         shl eax,4
  779.                         add eax,ebx
  780.                         inc esi
  781.                         jmp .cycle_16
  782.         @@:
  783.         cmp ecx,0 ;если число отрицательное
  784.         jne @f
  785.                 sub ecx,eax
  786.                 mov eax,ecx
  787.         @@:
  788.         pop esi ecx ebx
  789.         ret
  790. endp
  791.  
  792. ;данные для диалога открытия файлов
  793. align 4
  794. OpenDialog_data:
  795. .type                   dd 0 ;0 - открыть, 1 - сохранить, 2 - выбрать дтректорию
  796. .procinfo               dd procinfo     ;+4
  797. .com_area_name          dd communication_area_name      ;+8
  798. .com_area               dd 0    ;+12
  799. .opendir_path           dd plugin_path  ;+16
  800. .dir_default_path       dd default_dir ;+20
  801. .start_path             dd file_name ;+24 путь к диалогу открытия файлов
  802. .draw_window            dd draw_window  ;+28
  803. .status                 dd 0    ;+32
  804. .openfile_path          dd openfile_path        ;+36 путь к открываемому файлу
  805. .filename_area          dd filename_area        ;+40
  806. .filter_area            dd Filter
  807. .x:
  808. .x_size                 dw 420 ;+48 ; Window X size
  809. .x_start                dw 10 ;+50 ; Window X position
  810. .y:
  811. .y_size                 dw 320 ;+52 ; Window y size
  812. .y_start                dw 10 ;+54 ; Window Y position
  813.  
  814. default_dir db '/rd/1',0
  815.  
  816. communication_area_name:
  817.         db 'FFFFFFFF_open_dialog',0
  818. open_dialog_name:
  819.         db 'opendial',0
  820. communication_area_default_path:
  821.         db '/rd/1/File managers/',0
  822.  
  823. Filter:
  824. dd Filter.end - Filter.1
  825. .1:
  826. db '3DS',0
  827. db 'TXT',0
  828. .end:
  829. db 0
  830.  
  831.  
  832.  
  833. head_f_i:
  834. head_f_l db 'Системная ошибка',0
  835.  
  836. system_dir_0 db '/sys/lib/'
  837. lib_name_0 db 'proc_lib.obj',0
  838. err_message_found_lib_0 db 'Не найдена библиотека ',39,'proc_lib.obj',39,0
  839. err_message_import_0 db 'Ошибка при импорте библиотеки ',39,'proc_lib.obj',39,0
  840.  
  841. system_dir_1 db '/sys/lib/'
  842. lib_name_1 db 'libimg.obj',0
  843. err_message_found_lib_1 db 'Не найдена библиотека ',39,'libimg.obj',39,0
  844. err_message_import_1 db 'Ошибка при импорте библиотеки ',39,'libimg.obj',39,0
  845.  
  846. system_dir_2 db '/sys/lib/'
  847. lib_name_2 db 'box_lib.obj',0
  848. err_msg_found_lib_2 db 'Не найдена библиотека ',39,'box_lib.obj',39,0
  849. err_msg_import_2 db 'Ошибка при импорте библиотеки ',39,'box_lib',39,0
  850.  
  851. system_dir_7 db '/sys/lib/'
  852. lib_name_7 db 'buf2d.obj',0
  853. err_msg_found_lib_7 db 'Не найдена библиотека ',39,'buf2d.obj',39,0
  854. err_msg_import_7 db 'Ошибка при импорте библиотеки ',39,'buf2d',39,0
  855.  
  856. l_libs_start:
  857.         lib0 l_libs lib_name_0, sys_path, file_name, system_dir_0,\
  858.                 err_message_found_lib_0, head_f_l, proclib_import,err_message_import_0, head_f_i
  859.         lib1 l_libs lib_name_1, sys_path, file_name, system_dir_1,\
  860.                 err_message_found_lib_1, head_f_l, import_libimg, err_message_import_1, head_f_i
  861.         lib_2 l_libs lib_name_2, sys_path, library_path, system_dir_2,\
  862.                 err_msg_found_lib_2,head_f_l,import_box_lib,err_msg_import_2,head_f_i
  863.         lib_7 l_libs lib_name_7, sys_path, library_path, system_dir_7,\
  864.                 err_msg_found_lib_7,head_f_l,import_buf2d,err_msg_import_7,head_f_i
  865. l_libs_end:
  866.  
  867. align 4
  868. import_libimg:
  869.         dd alib_init1
  870.         img_is_img  dd aimg_is_img
  871.         img_info    dd aimg_info
  872.         img_from_file dd aimg_from_file
  873.         img_to_file dd aimg_to_file
  874.         img_from_rgb dd aimg_from_rgb
  875.         img_to_rgb  dd aimg_to_rgb
  876.         img_to_rgb2 dd aimg_to_rgb2
  877.         img_decode  dd aimg_decode
  878.         img_encode  dd aimg_encode
  879.         img_create  dd aimg_create
  880.         img_destroy dd aimg_destroy
  881.         img_destroy_layer dd aimg_destroy_layer
  882.         img_count   dd aimg_count
  883.         img_lock_bits dd aimg_lock_bits
  884.         img_unlock_bits dd aimg_unlock_bits
  885.         img_flip    dd aimg_flip
  886.         img_flip_layer dd aimg_flip_layer
  887.         img_rotate  dd aimg_rotate
  888.         img_rotate_layer dd aimg_rotate_layer
  889.         img_draw    dd aimg_draw
  890.  
  891.         dd 0,0
  892.         alib_init1   db 'lib_init',0
  893.         aimg_is_img  db 'img_is_img',0 ;определяет по данным, может ли библиотека сделать из них изображение
  894.         aimg_info    db 'img_info',0
  895.         aimg_from_file db 'img_from_file',0
  896.         aimg_to_file db 'img_to_file',0
  897.         aimg_from_rgb db 'img_from_rgb',0
  898.         aimg_to_rgb  db 'img_to_rgb',0 ;преобразование изображения в данные RGB
  899.         aimg_to_rgb2 db 'img_to_rgb2',0
  900.         aimg_decode  db 'img_decode',0 ;автоматически определяет формат графических данных
  901.         aimg_encode  db 'img_encode',0
  902.         aimg_create  db 'img_create',0
  903.         aimg_destroy db 'img_destroy',0
  904.         aimg_destroy_layer db 'img_destroy_layer',0
  905.         aimg_count   db 'img_count',0
  906.         aimg_lock_bits db 'img_lock_bits',0
  907.         aimg_unlock_bits db 'img_unlock_bits',0
  908.         aimg_flip    db 'img_flip',0
  909.         aimg_flip_layer db 'img_flip_layer',0
  910.         aimg_rotate  db 'img_rotate',0
  911.         aimg_rotate_layer db 'img_rotate_layer',0
  912.         aimg_draw    db 'img_draw',0
  913.  
  914. align 4
  915. proclib_import: ;описание экспортируемых функций
  916.         OpenDialog_Init dd aOpenDialog_Init
  917.         OpenDialog_Start dd aOpenDialog_Start
  918. dd 0,0
  919.         aOpenDialog_Init db 'OpenDialog_init',0
  920.         aOpenDialog_Start db 'OpenDialog_start',0
  921.  
  922. ;       file.find_first db 'file_find_first',0
  923. ;       file.find_next  db 'file_find_next',0
  924. ;       file.find_close db 'file_find_close',0
  925. ;       file.size      db 'file_size',0
  926. ;       file.open      db 'file_open',0
  927. ;       file.read      db 'file_read',0
  928. ;       file.write     db 'file_write',0
  929. ;       file.seek      db 'file_seek',0
  930. ;       file.tell      db 'file_tell',0
  931. ;       file.eof?      db 'file_iseof',0
  932. ;       file.truncate  db 'file_truncate',0
  933. ;       file.close     db 'file_close',0
  934.  
  935. align 4
  936. import_buf2d:
  937.         dd sz_init0
  938.         buf2d_create dd sz_buf2d_create
  939.         buf2d_create_f_img dd sz_buf2d_create_f_img
  940.         buf2d_clear dd sz_buf2d_clear
  941.         buf2d_draw dd sz_buf2d_draw
  942.         buf2d_delete dd sz_buf2d_delete
  943.         buf2d_line dd sz_buf2d_line
  944.         buf2d_rect_by_size dd sz_buf2d_rect_by_size
  945.         buf2d_filled_rect_by_size dd sz_buf2d_filled_rect_by_size
  946.         buf2d_circle dd sz_buf2d_circle
  947.         buf2d_img_hdiv2 dd sz_buf2d_img_hdiv2
  948.         buf2d_img_wdiv2 dd sz_buf2d_img_wdiv2
  949.         buf2d_conv_24_to_8 dd sz_buf2d_conv_24_to_8
  950.         buf2d_conv_24_to_32 dd sz_buf2d_conv_24_to_32
  951.         buf2d_bit_blt dd sz_buf2d_bit_blt
  952.         buf2d_bit_blt_transp dd sz_buf2d_bit_blt_transp
  953.         buf2d_bit_blt_alpha dd sz_buf2d_bit_blt_alpha
  954.         buf2d_curve_bezier dd sz_buf2d_curve_bezier
  955.         buf2d_convert_text_matrix dd sz_buf2d_convert_text_matrix
  956.         buf2d_draw_text dd sz_buf2d_draw_text
  957.         buf2d_crop_color dd sz_buf2d_crop_color
  958.         buf2d_offset_h dd sz_buf2d_offset_h
  959.         buf2d_flood_fill dd sz_buf2d_flood_fill
  960.         buf2d_set_pixel dd sz_buf2d_set_pixel
  961.         dd 0,0
  962.         sz_init0 db 'lib_init',0
  963.         sz_buf2d_create db 'buf2d_create',0
  964.         sz_buf2d_create_f_img db 'buf2d_create_f_img',0
  965.         sz_buf2d_clear db 'buf2d_clear',0
  966.         sz_buf2d_draw db 'buf2d_draw',0
  967.         sz_buf2d_delete db 'buf2d_delete',0
  968.         sz_buf2d_line db 'buf2d_line',0
  969.         sz_buf2d_rect_by_size db 'buf2d_rect_by_size',0
  970.         sz_buf2d_filled_rect_by_size db 'buf2d_filled_rect_by_size',0
  971.         sz_buf2d_circle db 'buf2d_circle',0
  972.         sz_buf2d_img_hdiv2 db 'buf2d_img_hdiv2',0
  973.         sz_buf2d_img_wdiv2 db 'buf2d_img_wdiv2',0
  974.         sz_buf2d_conv_24_to_8 db 'buf2d_conv_24_to_8',0
  975.         sz_buf2d_conv_24_to_32 db 'buf2d_conv_24_to_32',0
  976.         sz_buf2d_bit_blt db 'buf2d_bit_blt',0
  977.         sz_buf2d_bit_blt_transp db 'buf2d_bit_blt_transp',0
  978.         sz_buf2d_bit_blt_alpha db 'buf2d_bit_blt_alpha',0
  979.         sz_buf2d_curve_bezier db 'buf2d_curve_bezier',0
  980.         sz_buf2d_convert_text_matrix db 'buf2d_convert_text_matrix',0
  981.         sz_buf2d_draw_text db 'buf2d_draw_text',0
  982.         sz_buf2d_crop_color db 'buf2d_crop_color',0
  983.         sz_buf2d_offset_h db 'buf2d_offset_h',0
  984.         sz_buf2d_flood_fill db 'buf2d_flood_fill',0
  985.         sz_buf2d_set_pixel db 'buf2d_set_pixel',0
  986.  
  987. align 4
  988. import_box_lib:
  989.         dd sz_init1
  990.         init_checkbox dd sz_init_checkbox
  991.         check_box_draw dd sz_check_box_draw
  992.         edit_box_draw dd sz_edit_box_draw
  993.         edit_box_key dd sz_edit_box_key
  994.         edit_box_mouse dd sz_edit_box_mouse
  995.         edit_box_set_text dd sz_edit_box_set_text
  996.         scrollbar_ver_draw dd sz_scrollbar_ver_draw
  997.         scrollbar_hor_draw dd sz_scrollbar_hor_draw
  998.  
  999.         tl_data_init dd sz_tl_data_init
  1000.         tl_data_clear dd sz_tl_data_clear
  1001.         tl_info_clear dd sz_tl_info_clear
  1002.         tl_key dd sz_tl_key
  1003.         tl_mouse dd sz_tl_mouse
  1004.         tl_draw dd sz_tl_draw
  1005.         tl_info_undo dd sz_tl_info_undo
  1006.         tl_info_redo dd sz_tl_info_redo
  1007.         tl_node_add dd sz_tl_node_add
  1008.         tl_node_set_data dd sz_tl_node_set_data
  1009.         tl_node_get_data dd sz_tl_node_get_data
  1010.         tl_node_delete dd sz_tl_node_delete
  1011.         tl_node_move_up dd sz_tl_node_move_up
  1012.         tl_node_move_down dd sz_tl_node_move_down
  1013.         tl_cur_beg dd sz_tl_cur_beg
  1014.         tl_cur_next dd sz_tl_cur_next
  1015.         tl_cur_perv dd sz_tl_cur_perv
  1016.         tl_node_close_open dd sz_tl_node_close_open
  1017.         tl_node_lev_inc dd sz_tl_node_lev_inc
  1018.         tl_node_lev_dec dd sz_tl_node_lev_dec
  1019.         tl_node_poi_get_info dd sz_tl_node_poi_get_info
  1020.         tl_node_poi_get_next_info dd sz_tl_node_poi_get_next_info
  1021.         tl_node_poi_get_data dd sz_tl_node_poi_get_data
  1022.  
  1023.         dd 0,0
  1024.         sz_init1 db 'lib_init',0
  1025.         sz_init_checkbox db 'init_checkbox2',0
  1026.         sz_check_box_draw db 'check_box_draw2',0
  1027.         sz_edit_box_draw db 'edit_box',0
  1028.         sz_edit_box_key db 'edit_box_key',0
  1029.         sz_edit_box_mouse db 'edit_box_mouse',0
  1030.         sz_edit_box_set_text db 'edit_box_set_text',0
  1031.         sz_scrollbar_ver_draw db 'scrollbar_v_draw',0
  1032.         sz_scrollbar_hor_draw db 'scrollbar_h_draw',0
  1033.  
  1034.         sz_tl_data_init db 'tl_data_init',0
  1035.         sz_tl_data_clear db 'tl_data_clear',0
  1036.         sz_tl_info_clear db 'tl_info_clear',0
  1037.         sz_tl_key db 'tl_key',0
  1038.         sz_tl_mouse db 'tl_mouse',0
  1039.         sz_tl_draw db 'tl_draw',0
  1040.         sz_tl_info_undo db 'tl_info_undo',0
  1041.         sz_tl_info_redo db 'tl_info_redo',0
  1042.         sz_tl_node_add db 'tl_node_add',0
  1043.         sz_tl_node_set_data db 'tl_node_set_data',0
  1044.         sz_tl_node_get_data db 'tl_node_get_data',0
  1045.         sz_tl_node_delete db 'tl_node_delete',0
  1046.         sz_tl_node_move_up db 'tl_node_move_up',0
  1047.         sz_tl_node_move_down db 'tl_node_move_down',0
  1048.         sz_tl_cur_beg db 'tl_cur_beg',0
  1049.         sz_tl_cur_next db 'tl_cur_next',0
  1050.         sz_tl_cur_perv db 'tl_cur_perv',0
  1051.         sz_tl_node_close_open db 'tl_node_close_open',0
  1052.         sz_tl_node_lev_inc db 'tl_node_lev_inc',0
  1053.         sz_tl_node_lev_dec db 'tl_node_lev_dec',0
  1054.         sz_tl_node_poi_get_info db 'tl_node_poi_get_info',0
  1055.         sz_tl_node_poi_get_next_info db 'tl_node_poi_get_next_info',0
  1056.         sz_tl_node_poi_get_data db 'tl_node_poi_get_data',0
  1057.  
  1058.  
  1059.  
  1060. mouse_dd dd 0x0
  1061. sc system_colors
  1062. last_time dd 0
  1063.  
  1064. align 16
  1065. procinfo process_information
  1066.  
  1067. align 4
  1068. buf_0: dd 0 ;указатель на буфер изображения
  1069.         dw 205 ;+4 left
  1070.         dw 35 ;+6 top
  1071. .w: dd 340 ;+8 w
  1072. .h: dd 250 ;+12 h
  1073. .color: dd 0xffffd0 ;+16 color
  1074.         db 24 ;+20 bit in pixel
  1075.  
  1076. align 4
  1077. buf_1:
  1078.         dd 0 ;указатель на буфер изображения
  1079.         dw 25 ;+4 left
  1080.         dw 25 ;+6 top
  1081.         dd 128 ;+8 w
  1082.         dd 144 ;+12 h
  1083.         dd 0 ;+16 color
  1084.         db 24 ;+20 bit in pixel
  1085.  
  1086. el_focus dd tree1
  1087. tree1 tree_list size_one_list,200+2, tl_key_no_edit+tl_draw_par_line,\
  1088.         16,16, 0xffffff,0xb0d0ff,0xd000ff, 5,35,195-16,250, 16,list_offs_text,0, el_focus,\
  1089.         w_scr_t1,0
  1090.  
  1091. align 4
  1092. w_scr_t1:
  1093. .size_x     dw 16 ;+0
  1094. rb 2+2+2
  1095. .btn_high   dd 15 ;+8
  1096. .type       dd 1  ;+12
  1097. .max_area   dd 100  ;+16
  1098. rb 4+4
  1099. .bckg_col   dd 0xeeeeee ;+28
  1100. .frnt_col   dd 0xbbddff ;+32
  1101. .line_col   dd 0  ;+36
  1102. rb 4+2+2
  1103. .run_x:
  1104. rb 2+2+2+2+4+4+4+4+4+4
  1105. .all_redraw dd 0 ;+80
  1106. .ar_offset  dd 1 ;+84
  1107.  
  1108.  
  1109.  
  1110. ;этот код не мой, он преобразует число в строку
  1111. ;input:
  1112. ; eax = value
  1113. ; edi = string buffer
  1114. ;output:
  1115. align 4
  1116. tl_convert_to_str:
  1117.         pushad
  1118.                 mov dword[edi+1],0;0x20202020
  1119.                 call .str
  1120.         popad
  1121.         ret
  1122.  
  1123. align 4
  1124. .str:
  1125.         mov ecx,0x0a ;задается система счисления изменяются регистры ebx,eax,ecx,edx входные параметры eax - число
  1126.     ;преревод числа в ASCII строку взодные данные ecx=система счисленя edi адрес куда записывать, будем строку, причем конец переменной
  1127.         cmp eax,ecx  ;сравнить если в eax меньше чем в ecx то перейти на @@-1 т.е. на pop eax
  1128.         jb @f
  1129.                 xor edx,edx  ;очистить edx
  1130.                 div ecx      ;разделить - остаток в edx
  1131.                 push edx     ;положить в стек
  1132.                 ;dec edi             ;смещение необходимое для записи с конца строки
  1133.                 call .str ;перейти на саму себя т.е. вызвать саму себя и так до того момента пока в eax не станет меньше чем в ecx
  1134.                 pop eax
  1135.         @@: ;cmp al,10 ;проверить не меньше ли значение в al чем 10 (для системы счисленя 10 данная команда - лишная))
  1136.         or al,0x30  ;данная команда короче  чем две выше
  1137.         stosb       ;записать элемент из регистра al в ячеку памяти es:edi
  1138.         ret           ;вернуться чень интересный ход т.к. пока в стеке храниться кол-во вызовов то столько раз мы и будем вызываться
  1139.  
  1140. i_end:
  1141.         rb 1024
  1142. stacktop:
  1143.         sys_path rb 1024
  1144.         file_name:
  1145.                 rb 1024 ;4096
  1146.         library_path rb 1024
  1147.         plugin_path rb 4096
  1148.         openfile_path rb 4096
  1149.         filename_area rb 256
  1150. mem:
  1151.