Subversion Repositories Kolibri OS

Rev

Rev 2664 | Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2012, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. preprocessor:
  7.         mov     edi,characters
  8.         xor     al,al
  9.       make_characters_table:
  10.         stosb
  11.         inc     al
  12.         jnz     make_characters_table
  13.         mov     esi,characters+'a'
  14.         mov     edi,characters+'A'
  15.         mov     ecx,26
  16.         rep     movsb
  17.         mov     edi,characters
  18.         mov     esi,symbol_characters+1
  19.         movzx   ecx,byte [esi-1]
  20.         xor     eax,eax
  21.       mark_symbol_characters:
  22.         lodsb
  23.         mov     byte [edi+eax],0
  24.         loop    mark_symbol_characters
  25.         mov     edi,locals_counter
  26.         mov     ax,1 + '0' shl 8
  27.         stos    word [edi]
  28.         mov     edi,[memory_start]
  29.         mov     [include_paths],edi
  30.         mov     esi,include_variable
  31.         call    get_environment_variable
  32.         xor     al,al
  33.         stos    byte [edi]
  34.         mov     [memory_start],edi
  35.         mov     eax,[additional_memory]
  36.         mov     [free_additional_memory],eax
  37.         mov     eax,[additional_memory_end]
  38.         mov     [labels_list],eax
  39.         xor     eax,eax
  40.         mov     [source_start],eax
  41.         mov     [display_buffer],eax
  42.         mov     [hash_tree],eax
  43.         mov     [error],eax
  44.         mov     [macro_status],al
  45.         mov     esi,[input_file]
  46.         mov     edx,esi
  47.         call    open
  48.         jc      main_file_not_found
  49.         mov     edi,[memory_start]
  50.         call    preprocess_file
  51.         mov     eax,[error_line]
  52.         mov     [current_line],eax
  53.         cmp     [macro_status],0
  54.         jne     incomplete_macro
  55.         mov     [source_start],edi
  56.         ret
  57.  
  58. preprocess_file:
  59.         push    [memory_end]
  60.         push    esi
  61.         mov     al,2
  62.         xor     edx,edx
  63.         call    lseek
  64.         push    eax
  65.         xor     al,al
  66.         xor     edx,edx
  67.         call    lseek
  68.         pop     ecx
  69.         mov     edx,[memory_end]
  70.         dec     edx
  71.         mov     byte [edx],1Ah
  72.         sub     edx,ecx
  73.         jc      out_of_memory
  74.         mov     esi,edx
  75.         cmp     edx,edi
  76.         jbe     out_of_memory
  77.         mov     [memory_end],edx
  78.         call    read
  79.         call    close
  80.         pop     edx
  81.         xor     ecx,ecx
  82.         mov     ebx,esi
  83.       preprocess_source:
  84.         inc     ecx
  85.         mov     [current_line],edi
  86.         mov     eax,edx
  87.         stos    dword [edi]
  88.         mov     eax,ecx
  89.         stos    dword [edi]
  90.         mov     eax,esi
  91.         sub     eax,ebx
  92.         stos    dword [edi]
  93.         xor     eax,eax
  94.         stos    dword [edi]
  95.         push    ebx edx
  96.         call    convert_line
  97.         call    preprocess_line
  98.         pop     edx ebx
  99.       next_line:
  100.         cmp     byte [esi-1],0
  101.         je      file_end
  102.         cmp     byte [esi-1],1Ah
  103.         jne     preprocess_source
  104.       file_end:
  105.         pop     [memory_end]
  106.         clc
  107.         ret
  108.  
  109. convert_line:
  110.         push    ecx
  111.         test    [macro_status],0Fh
  112.         jz      convert_line_data
  113.         mov     ax,3Bh
  114.         stos    word [edi]
  115.       convert_line_data:
  116.         cmp     edi,[memory_end]
  117.         jae     out_of_memory
  118.         lods    byte [esi]
  119.         cmp     al,20h
  120.         je      convert_line_data
  121.         cmp     al,9
  122.         je      convert_line_data
  123.         mov     ah,al
  124.         mov     ebx,characters
  125.         xlat    byte [ebx]
  126.         or      al,al
  127.         jz      convert_separator
  128.         cmp     ah,27h
  129.         je      convert_string
  130.         cmp     ah,22h
  131.         je      convert_string
  132.         mov     byte [edi],1Ah
  133.         scas    word [edi]
  134.         xchg    al,ah
  135.         stos    byte [edi]
  136.         mov     ebx,characters
  137.         xor     ecx,ecx
  138.       convert_symbol:
  139.         lods    byte [esi]
  140.         stos    byte [edi]
  141.         xlat    byte [ebx]
  142.         or      al,al
  143.         loopnzd convert_symbol
  144.         neg     ecx
  145.         cmp     ecx,255
  146.         ja      name_too_long
  147.         mov     ebx,edi
  148.         sub     ebx,ecx
  149.         mov     byte [ebx-2],cl
  150.       found_separator:
  151.         dec     edi
  152.         mov     ah,[esi-1]
  153.       convert_separator:
  154.         xchg    al,ah
  155.         cmp     al,20h
  156.         jb      control_character
  157.         je      convert_line_data
  158.       symbol_character:
  159.         cmp     al,3Bh
  160.         je      ignore_comment
  161.         cmp     al,5Ch
  162.         je      backslash_character
  163.         stos    byte [edi]
  164.         jmp     convert_line_data
  165.       control_character:
  166.         cmp     al,1Ah
  167.         je      line_end
  168.         cmp     al,0Dh
  169.         je      cr_character
  170.         cmp     al,0Ah
  171.         je      lf_character
  172.         cmp     al,9
  173.         je      convert_line_data
  174.         or      al,al
  175.         jnz     symbol_character
  176.         jmp     line_end
  177.       lf_character:
  178.         lods    byte [esi]
  179.         cmp     al,0Dh
  180.         je      line_end
  181.         dec     esi
  182.         jmp     line_end
  183.       cr_character:
  184.         lods    byte [esi]
  185.         cmp     al,0Ah
  186.         je      line_end
  187.         dec     esi
  188.         jmp     line_end
  189.       convert_string:
  190.         mov     al,22h
  191.         stos    byte [edi]
  192.         scas    dword [edi]
  193.         mov     ebx,edi
  194.       copy_string:
  195.         lods    byte [esi]
  196.         stos    byte [edi]
  197.         cmp     al,0Ah
  198.         je      missing_end_quote
  199.         cmp     al,0Dh
  200.         je      missing_end_quote
  201.         or      al,al
  202.         jz      missing_end_quote
  203.         cmp     al,1Ah
  204.         je      missing_end_quote
  205.         cmp     al,ah
  206.         jne     copy_string
  207.         lods    byte [esi]
  208.         cmp     al,ah
  209.         je      copy_string
  210.         dec     esi
  211.         dec     edi
  212.         mov     eax,edi
  213.         sub     eax,ebx
  214.         mov     [ebx-4],eax
  215.         jmp     convert_line_data
  216.       backslash_character:
  217.         mov     byte [edi],0
  218.         lods    byte [esi]
  219.         cmp     al,20h
  220.         je      concatenate_lines
  221.         cmp     al,9
  222.         je      concatenate_lines
  223.         cmp     al,1Ah
  224.         je      unexpected_end_of_file
  225.         or      al,al
  226.         jz      unexpected_end_of_file
  227.         cmp     al,0Ah
  228.         je      concatenate_lf
  229.         cmp     al,0Dh
  230.         je      concatenate_cr
  231.         cmp     al,3Bh
  232.         je      find_concatenated_line
  233.         mov     al,1Ah
  234.         stos    byte [edi]
  235.         mov     ecx,edi
  236.         mov     ax,5C01h
  237.         stos    word [edi]
  238.         dec     esi
  239.       group_backslashes:
  240.         lods    byte [esi]
  241.         cmp     al,5Ch
  242.         jne     backslashed_symbol
  243.         stos    byte [edi]
  244.         inc     byte [ecx]
  245.         jmp     group_backslashes
  246.       backslashed_symbol:
  247.         cmp     al,1Ah
  248.         je      unexpected_end_of_file
  249.         or      al,al
  250.         jz      unexpected_end_of_file
  251.         cmp     al,0Ah
  252.         je      extra_characters_on_line
  253.         cmp     al,0Dh
  254.         je      extra_characters_on_line
  255.         cmp     al,20h
  256.         je      extra_characters_on_line
  257.         cmp     al,9
  258.         je      extra_characters_on_line
  259.         cmp     al,22h
  260.         je      extra_characters_on_line
  261.         cmp     al,27h
  262.         je      extra_characters_on_line
  263.         cmp     al,3Bh
  264.         je      extra_characters_on_line
  265.         mov     ah,al
  266.         mov     ebx,characters
  267.         xlat    byte [ebx]
  268.         or      al,al
  269.         jz      backslashed_symbol_character
  270.         mov     al,ah
  271.       convert_backslashed_symbol:
  272.         stos    byte [edi]
  273.         xlat    byte [ebx]
  274.         or      al,al
  275.         jz      found_separator
  276.         inc     byte [ecx]
  277.         jz      name_too_long
  278.         lods    byte [esi]
  279.         jmp     convert_backslashed_symbol
  280.       backslashed_symbol_character:
  281.         mov     al,ah
  282.         stos    byte [edi]
  283.         inc     byte [ecx]
  284.         jmp     convert_line_data
  285.       concatenate_lines:
  286.         lods    byte [esi]
  287.         cmp     al,20h
  288.         je      concatenate_lines
  289.         cmp     al,9
  290.         je      concatenate_lines
  291.         cmp     al,1Ah
  292.         je      unexpected_end_of_file
  293.         or      al,al
  294.         jz      unexpected_end_of_file
  295.         cmp     al,0Ah
  296.         je      concatenate_lf
  297.         cmp     al,0Dh
  298.         je      concatenate_cr
  299.         cmp     al,3Bh
  300.         jne     extra_characters_on_line
  301.       find_concatenated_line:
  302.         lods    byte [esi]
  303.         cmp     al,0Ah
  304.         je      concatenate_lf
  305.         cmp     al,0Dh
  306.         je      concatenate_cr
  307.         or      al,al
  308.         jz      concatenate_ok
  309.         cmp     al,1Ah
  310.         jne     find_concatenated_line
  311.         jmp     unexpected_end_of_file
  312.       concatenate_lf:
  313.         lods    byte [esi]
  314.         cmp     al,0Dh
  315.         je      concatenate_ok
  316.         dec     esi
  317.         jmp     concatenate_ok
  318.       concatenate_cr:
  319.         lods    byte [esi]
  320.         cmp     al,0Ah
  321.         je      concatenate_ok
  322.         dec     esi
  323.       concatenate_ok:
  324.         inc     dword [esp]
  325.         jmp     convert_line_data
  326.       ignore_comment:
  327.         lods    byte [esi]
  328.         cmp     al,0Ah
  329.         je      lf_character
  330.         cmp     al,0Dh
  331.         je      cr_character
  332.         or      al,al
  333.         jz      line_end
  334.         cmp     al,1Ah
  335.         jne     ignore_comment
  336.       line_end:
  337.         xor     al,al
  338.         stos    byte [edi]
  339.         pop     ecx
  340.         ret
  341.  
  342. lower_case:
  343.         mov     edi,converted
  344.         mov     ebx,characters
  345.       convert_case:
  346.         lods    byte [esi]
  347.         xlat    byte [ebx]
  348.         stos    byte [edi]
  349.         loop    convert_case
  350.       case_ok:
  351.         ret
  352.  
  353. get_directive:
  354.         push    edi
  355.         mov     edx,esi
  356.         mov     ebp,ecx
  357.         call    lower_case
  358.         pop     edi
  359.       scan_directives:
  360.         mov     esi,converted
  361.         movzx   eax,byte [edi]
  362.         or      al,al
  363.         jz      no_directive
  364.         mov     ecx,ebp
  365.         inc     edi
  366.         mov     ebx,edi
  367.         add     ebx,eax
  368.         mov     ah,[esi]
  369.         cmp     ah,[edi]
  370.         jb      no_directive
  371.         ja      next_directive
  372.         cmp     cl,al
  373.         jne     next_directive
  374.         repe    cmps byte [esi],[edi]
  375.         jb      no_directive
  376.         je      directive_ok
  377.       next_directive:
  378.         mov     edi,ebx
  379.         add     edi,2
  380.         jmp     scan_directives
  381.       no_directive:
  382.         mov     esi,edx
  383.         mov     ecx,ebp
  384.         stc
  385.         ret
  386.       directive_ok:
  387.         lea     esi,[edx+ebp]
  388.         call    directive_handler
  389.       directive_handler:
  390.         pop     ecx
  391.         movzx   eax,word [ebx]
  392.         add     eax,ecx
  393.         clc
  394.         ret
  395.  
  396. preprocess_line:
  397.         mov     eax,esp
  398.         sub     eax,100h
  399.         jc      stack_overflow
  400.         cmp     eax,[stack_limit]
  401.         jb      stack_overflow
  402.         push    ecx esi
  403.       preprocess_current_line:
  404.         mov     esi,[current_line]
  405.         add     esi,16
  406.         cmp     word [esi],3Bh
  407.         jne     line_start_ok
  408.         add     esi,2
  409.       line_start_ok:
  410.         test    [macro_status],0F0h
  411.         jnz     macro_preprocessing
  412.         cmp     byte [esi],1Ah
  413.         jne     not_fix_constant
  414.         movzx   edx,byte [esi+1]
  415.         lea     edx,[esi+2+edx]
  416.         cmp     word [edx],031Ah
  417.         jne     not_fix_constant
  418.         mov     ebx,characters
  419.         movzx   eax,byte [edx+2]
  420.         xlat    byte [ebx]
  421.         ror     eax,8
  422.         mov     al,[edx+3]
  423.         xlat    byte [ebx]
  424.         ror     eax,8
  425.         mov     al,[edx+4]
  426.         xlat    byte [ebx]
  427.         ror     eax,16
  428.         cmp     eax,'fix'
  429.         je      define_fix_constant
  430.       not_fix_constant:
  431.         call    process_fix_constants
  432.         jmp     initial_preprocessing_ok
  433.       macro_preprocessing:
  434.         call    process_macro_operators
  435.       initial_preprocessing_ok:
  436.         mov     esi,[current_line]
  437.         add     esi,16
  438.         mov     al,[macro_status]
  439.         test    al,2
  440.         jnz     skip_macro_block
  441.         test    al,1
  442.         jnz     find_macro_block
  443.       preprocess_instruction:
  444.         mov     [current_offset],esi
  445.         lods    byte [esi]
  446.         movzx   ecx,byte [esi]
  447.         inc     esi
  448.         cmp     al,1Ah
  449.         jne     not_preprocessor_symbol
  450.         cmp     cl,3
  451.         jb      not_preprocessor_directive
  452.         push    edi
  453.         mov     edi,preprocessor_directives
  454.         call    get_directive
  455.         pop     edi
  456.         jc      not_preprocessor_directive
  457.         mov     byte [edx-2],3Bh
  458.         jmp     near eax
  459.       not_preprocessor_directive:
  460.         xor     ch,ch
  461.         call    get_preprocessor_symbol
  462.         jc      not_macro
  463.         mov     byte [ebx-2],3Bh
  464.         mov     [struc_name],0
  465.         jmp     use_macro
  466.       not_macro:
  467.         mov     [struc_name],esi
  468.         add     esi,ecx
  469.         lods    byte [esi]
  470.         cmp     al,':'
  471.         je      preprocess_label
  472.         cmp     al,1Ah
  473.         jne     not_preprocessor_symbol
  474.         lods    byte [esi]
  475.         cmp     al,3
  476.         jne     not_symbolic_constant
  477.         mov     ebx,characters
  478.         movzx   eax,byte [esi]
  479.         xlat    byte [ebx]
  480.         ror     eax,8
  481.         mov     al,[esi+1]
  482.         xlat    byte [ebx]
  483.         ror     eax,8
  484.         mov     al,[esi+2]
  485.         xlat    byte [ebx]
  486.         ror     eax,16
  487.         cmp     eax,'equ'
  488.         je      define_equ_constant
  489.         mov     al,3
  490.       not_symbolic_constant:
  491.         mov     ch,1
  492.         mov     cl,al
  493.         call    get_preprocessor_symbol
  494.         jc      not_preprocessor_symbol
  495.         push    edx esi
  496.         mov     esi,[struc_name]
  497.         mov     [struc_label],esi
  498.         sub     [struc_label],2
  499.         mov     cl,[esi-1]
  500.         mov     ch,10b
  501.         call    get_preprocessor_symbol
  502.         jc      struc_name_ok
  503.         mov     ecx,[edx+12]
  504.         add     ecx,3
  505.         lea     ebx,[edi+ecx]
  506.         mov     ecx,edi
  507.         sub     ecx,[struc_label]
  508.         lea     esi,[edi-1]
  509.         lea     edi,[ebx-1]
  510.         std
  511.         rep     movs byte [edi],[esi]
  512.         cld
  513.         mov     edi,[struc_label]
  514.         mov     esi,[edx+8]
  515.         mov     ecx,[edx+12]
  516.         add     [struc_name],ecx
  517.         add     [struc_name],3
  518.         call    move_data
  519.         mov     al,3Ah
  520.         stos    byte [edi]
  521.         mov     ax,3Bh
  522.         stos    word [edi]
  523.         mov     edi,ebx
  524.         pop     esi
  525.         add     esi,[edx+12]
  526.         add     esi,3
  527.         pop     edx
  528.         jmp     use_macro
  529.       struc_name_ok:
  530.         mov     edx,[struc_name]
  531.         movzx   eax,byte [edx-1]
  532.         add     edx,eax
  533.         push    edi
  534.         lea     esi,[edi-1]
  535.         mov     ecx,edi
  536.         sub     ecx,edx
  537.         std
  538.         rep     movs byte [edi],[esi]
  539.         cld
  540.         pop     edi
  541.         inc     edi
  542.         mov     al,3Ah
  543.         mov     [edx],al
  544.         inc     al
  545.         mov     [edx+1],al
  546.         pop     esi edx
  547.         inc     esi
  548.         jmp     use_macro
  549.       preprocess_label:
  550.         dec     esi
  551.         sub     esi,ecx
  552.         lea     ebp,[esi-2]
  553.         mov     ch,10b
  554.         call    get_preprocessor_symbol
  555.         jnc     symbolic_constant_in_label
  556.         lea     esi,[esi+ecx+1]
  557.         jmp     preprocess_instruction
  558.       symbolic_constant_in_label:
  559.         mov     ebx,[edx+8]
  560.         mov     ecx,[edx+12]
  561.         add     ecx,ebx
  562.       check_for_broken_label:
  563.         cmp     ebx,ecx
  564.         je      label_broken
  565.         cmp     byte [ebx],1Ah
  566.         jne     label_broken
  567.         movzx   eax,byte [ebx+1]
  568.         lea     ebx,[ebx+2+eax]
  569.         cmp     ebx,ecx
  570.         je      label_constant_ok
  571.         cmp     byte [ebx],':'
  572.         jne     label_broken
  573.         inc     ebx
  574.         jmp     check_for_broken_label
  575.       label_broken:
  576.         push    line_preprocessed
  577.         jmp     replace_symbolic_constant
  578.       label_constant_ok:
  579.         mov     ecx,edi
  580.         sub     ecx,esi
  581.         mov     edi,[edx+12]
  582.         add     edi,ebp
  583.         push    edi
  584.         lea     eax,[edi+ecx]
  585.         push    eax
  586.         cmp     esi,edi
  587.         je      replace_label
  588.         jb      move_rest_of_line_up
  589.         rep     movs byte [edi],[esi]
  590.         jmp     replace_label
  591.       move_rest_of_line_up:
  592.         lea     esi,[esi+ecx-1]
  593.         lea     edi,[edi+ecx-1]
  594.         std
  595.         rep     movs byte [edi],[esi]
  596.         cld
  597.       replace_label:
  598.         mov     ecx,[edx+12]
  599.         mov     edi,[esp+4]
  600.         sub     edi,ecx
  601.         mov     esi,[edx+8]
  602.         rep     movs byte [edi],[esi]
  603.         pop     edi esi
  604.         inc     esi
  605.         jmp     preprocess_instruction
  606.       not_preprocessor_symbol:
  607.         mov     esi,[current_offset]
  608.         call    process_equ_constants
  609.       line_preprocessed:
  610.         pop     esi ecx
  611.         ret
  612.  
  613. get_preprocessor_symbol:
  614.         push    ebp edi esi
  615.         mov     ebp,ecx
  616.         shl     ebp,22
  617.         movzx   ecx,cl
  618.         mov     ebx,hash_tree
  619.         mov     edi,10
  620.       follow_hashes_roots:
  621.         mov     edx,[ebx]
  622.         or      edx,edx
  623.         jz      preprocessor_symbol_not_found
  624.         xor     eax,eax
  625.         shl     ebp,1
  626.         adc     eax,0
  627.         lea     ebx,[edx+eax*4]
  628.         dec     edi
  629.         jnz     follow_hashes_roots
  630.         mov     edi,ebx
  631.         call    calculate_hash
  632.         mov     ebp,eax
  633.         and     ebp,3FFh
  634.         shl     ebp,10
  635.         xor     ebp,eax
  636.         mov     ebx,edi
  637.         mov     edi,22
  638.       follow_hashes_tree:
  639.         mov     edx,[ebx]
  640.         or      edx,edx
  641.         jz      preprocessor_symbol_not_found
  642.         xor     eax,eax
  643.         shl     ebp,1
  644.         adc     eax,0
  645.         lea     ebx,[edx+eax*4]
  646.         dec     edi
  647.         jnz     follow_hashes_tree
  648.         mov     al,cl
  649.         mov     edx,[ebx]
  650.         or      edx,edx
  651.         jz      preprocessor_symbol_not_found
  652.       compare_with_preprocessor_symbol:
  653.         mov     edi,[edx+4]
  654.         cmp     edi,1
  655.         jbe     next_equal_hash
  656.         repe    cmps byte [esi],[edi]
  657.         je      preprocessor_symbol_found
  658.         mov     cl,al
  659.         mov     esi,[esp]
  660.       next_equal_hash:
  661.         mov     edx,[edx]
  662.         or      edx,edx
  663.         jnz     compare_with_preprocessor_symbol
  664.       preprocessor_symbol_not_found:
  665.         pop     esi edi ebp
  666.         stc
  667.         ret
  668.       preprocessor_symbol_found:
  669.         pop     ebx edi ebp
  670.         clc
  671.         ret
  672.       calculate_hash:
  673.         xor     ebx,ebx
  674.         mov     eax,2166136261
  675.         mov     ebp,16777619
  676.       fnv1a_hash:
  677.         xor     al,[esi+ebx]
  678.         mul     ebp
  679.         inc     bl
  680.         cmp     bl,cl
  681.         jb      fnv1a_hash
  682.         ret
  683. add_preprocessor_symbol:
  684.         push    edi esi
  685.         cmp     ch,11b
  686.         je      preprocessor_symbol_name_ok
  687.         push    ecx
  688.         movzx   ecx,cl
  689.         mov     edi,preprocessor_directives
  690.         call    get_directive
  691.         jnc     reserved_word_used_as_symbol
  692.         pop     ecx
  693.       preprocessor_symbol_name_ok:
  694.         call    calculate_hash
  695.         mov     ebp,eax
  696.         and     ebp,3FFh
  697.         shr     eax,10
  698.         xor     ebp,eax
  699.         shl     ecx,22
  700.         or      ebp,ecx
  701.         mov     ebx,hash_tree
  702.         mov     ecx,32
  703.       find_leave_for_symbol:
  704.         mov     edx,[ebx]
  705.         or      edx,edx
  706.         jz      extend_hashes_tree
  707.         xor     eax,eax
  708.         rol     ebp,1
  709.         adc     eax,0
  710.         lea     ebx,[edx+eax*4]
  711.         dec     ecx
  712.         jnz     find_leave_for_symbol
  713.         mov     edx,[ebx]
  714.         or      edx,edx
  715.         jz      add_symbol_entry
  716.         shr     ebp,30
  717.         cmp     ebp,11b
  718.         je      reuse_symbol_entry
  719.         cmp     dword [edx+4],0
  720.         jne     add_symbol_entry
  721.       find_entry_to_reuse:
  722.         mov     edi,[edx]
  723.         or      edi,edi
  724.         jz      reuse_symbol_entry
  725.         cmp     dword [edi+4],0
  726.         jne     reuse_symbol_entry
  727.         mov     edx,edi
  728.         jmp     find_entry_to_reuse
  729.       add_symbol_entry:
  730.         mov     eax,edx
  731.         mov     edx,[labels_list]
  732.         sub     edx,16
  733.         cmp     edx,[free_additional_memory]
  734.         jb      out_of_memory
  735.         mov     [labels_list],edx
  736.         mov     [edx],eax
  737.         mov     [ebx],edx
  738.       reuse_symbol_entry:
  739.         pop     esi edi
  740.         mov     [edx+4],esi
  741.         ret
  742.       extend_hashes_tree:
  743.         mov     edx,[labels_list]
  744.         sub     edx,8
  745.         cmp     edx,[free_additional_memory]
  746.         jb      out_of_memory
  747.         mov     [labels_list],edx
  748.         xor     eax,eax
  749.         mov     [edx],eax
  750.         mov     [edx+4],eax
  751.         shl     ebp,1
  752.         adc     eax,0
  753.         mov     [ebx],edx
  754.         lea     ebx,[edx+eax*4]
  755.         dec     ecx
  756.         jnz     extend_hashes_tree
  757.         mov     edx,[labels_list]
  758.         sub     edx,16
  759.         cmp     edx,[free_additional_memory]
  760.         jb      out_of_memory
  761.         mov     [labels_list],edx
  762.         mov     dword [edx],0
  763.         mov     [ebx],edx
  764.         pop     esi edi
  765.         mov     [edx+4],esi
  766.         ret
  767.  
  768. define_fix_constant:
  769.         add     edx,5
  770.         add     esi,2
  771.         push    edx
  772.         mov     ch,11b
  773.         jmp     define_preprocessor_constant
  774. define_equ_constant:
  775.         add     esi,3
  776.         push    esi
  777.         call    process_equ_constants
  778.         mov     esi,[struc_name]
  779.         mov     ch,10b
  780.       define_preprocessor_constant:
  781.         mov     byte [esi-2],3Bh
  782.         mov     cl,[esi-1]
  783.         call    add_preprocessor_symbol
  784.         pop     ebx
  785.         mov     ecx,edi
  786.         dec     ecx
  787.         sub     ecx,ebx
  788.         mov     [edx+8],ebx
  789.         mov     [edx+12],ecx
  790.         jmp     line_preprocessed
  791. define_symbolic_constant:
  792.         lods    byte [esi]
  793.         cmp     al,1Ah
  794.         jne     invalid_name
  795.         lods    byte [esi]
  796.         mov     cl,al
  797.         mov     ch,10b
  798.         call    add_preprocessor_symbol
  799.         movzx   eax,byte [esi-1]
  800.         add     esi,eax
  801.         lea     ecx,[edi-1]
  802.         sub     ecx,esi
  803.         mov     [edx+8],esi
  804.         mov     [edx+12],ecx
  805.         jmp     line_preprocessed
  806.  
  807. define_struc:
  808.         mov     ch,1
  809.         jmp     make_macro
  810. define_macro:
  811.         xor     ch,ch
  812.       make_macro:
  813.         lods    byte [esi]
  814.         cmp     al,1Ah
  815.         jne     invalid_name
  816.         lods    byte [esi]
  817.         mov     cl,al
  818.         call    add_preprocessor_symbol
  819.         mov     eax,[current_line]
  820.         mov     [edx+12],eax
  821.         movzx   eax,byte [esi-1]
  822.         add     esi,eax
  823.         mov     [edx+8],esi
  824.         mov     al,[macro_status]
  825.         and     al,0F0h
  826.         or      al,1
  827.         mov     [macro_status],al
  828.         mov     eax,[current_line]
  829.         mov     [error_line],eax
  830.         xor     ebp,ebp
  831.         lods    byte [esi]
  832.         or      al,al
  833.         jz      line_preprocessed
  834.         cmp     al,'{'
  835.         je      found_macro_block
  836.         dec     esi
  837.       skip_macro_arguments:
  838.         lods    byte [esi]
  839.         cmp     al,1Ah
  840.         je      skip_macro_argument
  841.         cmp     al,'['
  842.         jne     invalid_macro_arguments
  843.         or      ebp,-1
  844.         jz      invalid_macro_arguments
  845.         lods    byte [esi]
  846.         cmp     al,1Ah
  847.         jne     invalid_macro_arguments
  848.       skip_macro_argument:
  849.         movzx   eax,byte [esi]
  850.         inc     esi
  851.         add     esi,eax
  852.         lods    byte [esi]
  853.         cmp     al,'='
  854.         je      macro_argument_with_default_value
  855.         cmp     al,'*'
  856.         jne     macro_argument_end
  857.         lods    byte [esi]
  858.       macro_argument_end:
  859.         cmp     al,','
  860.         je      skip_macro_arguments
  861.         cmp     al,']'
  862.         jne     end_macro_arguments
  863.         lods    byte [esi]
  864.         not     ebp
  865.       end_macro_arguments:
  866.         or      ebp,ebp
  867.         jnz     invalid_macro_arguments
  868.         or      al,al
  869.         jz      line_preprocessed
  870.         cmp     al,'{'
  871.         je      found_macro_block
  872.         jmp     invalid_macro_arguments
  873.       macro_argument_with_default_value:
  874.         or      [default_argument_value],-1
  875.         call    skip_macro_argument_value
  876.         inc     esi
  877.         jmp     macro_argument_end
  878.       skip_macro_argument_value:
  879.         cmp     byte [esi],'<'
  880.         jne     simple_argument
  881.         mov     ecx,1
  882.         inc     esi
  883.       enclosed_argument:
  884.         lods    byte [esi]
  885.         or      al,al
  886.         jz      invalid_macro_arguments
  887.         cmp     al,1Ah
  888.         je      enclosed_symbol
  889.         cmp     al,22h
  890.         je      enclosed_string
  891.         cmp     al,'>'
  892.         je      enclosed_argument_end
  893.         cmp     al,'<'
  894.         jne     enclosed_argument
  895.         inc     ecx
  896.         jmp     enclosed_argument
  897.       enclosed_symbol:
  898.         movzx   eax,byte [esi]
  899.         inc     esi
  900.         add     esi,eax
  901.         jmp     enclosed_argument
  902.       enclosed_string:
  903.         lods    dword [esi]
  904.         add     esi,eax
  905.         jmp     enclosed_argument
  906.       enclosed_argument_end:
  907.         loop    enclosed_argument
  908.         lods    byte [esi]
  909.         or      al,al
  910.         jz      argument_value_end
  911.         cmp     al,','
  912.         je      argument_value_end
  913.         cmp     [default_argument_value],0
  914.         je      invalid_macro_arguments
  915.         cmp     al,'{'
  916.         je      argument_value_end
  917.         or      ebp,ebp
  918.         jz      invalid_macro_arguments
  919.         cmp     al,']'
  920.         je      argument_value_end
  921.         jmp     invalid_macro_arguments
  922.       simple_argument:
  923.         lods    byte [esi]
  924.         or      al,al
  925.         jz      argument_value_end
  926.         cmp     al,','
  927.         je      argument_value_end
  928.         cmp     al,22h
  929.         je      argument_string
  930.         cmp     al,1Ah
  931.         je      argument_symbol
  932.         cmp     [default_argument_value],0
  933.         je      simple_argument
  934.         cmp     al,'{'
  935.         je      argument_value_end
  936.         or      ebp,ebp
  937.         jz      simple_argument
  938.         cmp     al,']'
  939.         je      argument_value_end
  940.       argument_symbol:
  941.         movzx   eax,byte [esi]
  942.         inc     esi
  943.         add     esi,eax
  944.         jmp     simple_argument
  945.       argument_string:
  946.         lods    dword [esi]
  947.         add     esi,eax
  948.         jmp     simple_argument
  949.       argument_value_end:
  950.         dec     esi
  951.         ret
  952.       find_macro_block:
  953.         add     esi,2
  954.         lods    byte [esi]
  955.         or      al,al
  956.         jz      line_preprocessed
  957.         cmp     al,'{'
  958.         jne     unexpected_characters
  959.       found_macro_block:
  960.         or      [macro_status],2
  961.       skip_macro_block:
  962.         lods    byte [esi]
  963.         cmp     al,1Ah
  964.         je      skip_macro_symbol
  965.         cmp     al,3Bh
  966.         je      skip_macro_symbol
  967.         cmp     al,22h
  968.         je      skip_macro_string
  969.         or      al,al
  970.         jz      line_preprocessed
  971.         cmp     al,'}'
  972.         jne     skip_macro_block
  973.         mov     al,[macro_status]
  974.         and     [macro_status],0F0h
  975.         test    al,8
  976.         jnz     use_instant_macro
  977.         cmp     byte [esi],0
  978.         je      line_preprocessed
  979.         mov     ecx,edi
  980.         sub     ecx,esi
  981.         mov     edx,esi
  982.         lea     esi,[esi+ecx-1]
  983.         lea     edi,[edi+1+16]
  984.         mov     ebx,edi
  985.         dec     edi
  986.         std
  987.         rep     movs byte [edi],[esi]
  988.         cld
  989.         mov     edi,edx
  990.         xor     al,al
  991.         stos    byte [edi]
  992.         mov     esi,[current_line]
  993.         mov     [current_line],edi
  994.         mov     ecx,4
  995.         rep     movs dword [edi],[esi]
  996.         mov     edi,ebx
  997.         jmp     initial_preprocessing_ok
  998.       skip_macro_symbol:
  999.         movzx   eax,byte [esi]
  1000.         inc     esi
  1001.         add     esi,eax
  1002.         jmp     skip_macro_block
  1003.       skip_macro_string:
  1004.         lods    dword [esi]
  1005.         add     esi,eax
  1006.         jmp     skip_macro_block
  1007. rept_directive:
  1008.         mov     [base_code],0
  1009.         jmp     define_instant_macro
  1010. irp_directive:
  1011.         mov     [base_code],1
  1012.         jmp     define_instant_macro
  1013. irps_directive:
  1014.         mov     [base_code],2
  1015.         jmp     define_instant_macro
  1016. match_directive:
  1017.         mov     [base_code],10h
  1018. define_instant_macro:
  1019.         mov     al,[macro_status]
  1020.         and     al,0F0h
  1021.         or      al,8+1
  1022.         mov     [macro_status],al
  1023.         mov     eax,[current_line]
  1024.         mov     [error_line],eax
  1025.         mov     [instant_macro_start],esi
  1026.         cmp     [base_code],10h
  1027.         je      prepare_match
  1028.       skip_parameters:
  1029.         lods    byte [esi]
  1030.         or      al,al
  1031.         jz      parameters_skipped
  1032.         cmp     al,'{'
  1033.         je      parameters_skipped
  1034.         cmp     al,22h
  1035.         je      skip_quoted_parameter
  1036.         cmp     al,1Ah
  1037.         jne     skip_parameters
  1038.         lods    byte [esi]
  1039.         movzx   eax,al
  1040.         add     esi,eax
  1041.         jmp     skip_parameters
  1042.       skip_quoted_parameter:
  1043.         lods    dword [esi]
  1044.         add     esi,eax
  1045.         jmp     skip_parameters
  1046.       parameters_skipped:
  1047.         dec     esi
  1048.         mov     [parameters_end],esi
  1049.         lods    byte [esi]
  1050.         cmp     al,'{'
  1051.         je      found_macro_block
  1052.         or      al,al
  1053.         jnz     invalid_macro_arguments
  1054.         jmp     line_preprocessed
  1055. prepare_match:
  1056.         call    skip_pattern
  1057.         mov     [value_type],80h+10b
  1058.         call    process_symbolic_constants
  1059.         jmp     parameters_skipped
  1060.       skip_pattern:
  1061.         lods    byte [esi]
  1062.         or      al,al
  1063.         jz      invalid_macro_arguments
  1064.         cmp     al,','
  1065.         je      pattern_skipped
  1066.         cmp     al,22h
  1067.         je      skip_quoted_string_in_pattern
  1068.         cmp     al,1Ah
  1069.         je      skip_symbol_in_pattern
  1070.         cmp     al,'='
  1071.         jne     skip_pattern
  1072.         mov     al,[esi]
  1073.         cmp     al,1Ah
  1074.         je      skip_pattern
  1075.         cmp     al,22h
  1076.         je      skip_pattern
  1077.         inc     esi
  1078.         jmp     skip_pattern
  1079.       skip_symbol_in_pattern:
  1080.         lods    byte [esi]
  1081.         movzx   eax,al
  1082.         add     esi,eax
  1083.         jmp     skip_pattern
  1084.       skip_quoted_string_in_pattern:
  1085.         lods    dword [esi]
  1086.         add     esi,eax
  1087.         jmp     skip_pattern
  1088.       pattern_skipped:
  1089.         ret
  1090.  
  1091. purge_macro:
  1092.         xor     ch,ch
  1093.         jmp     restore_preprocessor_symbol
  1094. purge_struc:
  1095.         mov     ch,1
  1096.         jmp     restore_preprocessor_symbol
  1097. restore_equ_constant:
  1098.         mov     ch,10b
  1099.       restore_preprocessor_symbol:
  1100.         push    ecx
  1101.         lods    byte [esi]
  1102.         cmp     al,1Ah
  1103.         jne     invalid_name
  1104.         lods    byte [esi]
  1105.         mov     cl,al
  1106.         call    get_preprocessor_symbol
  1107.         jc      no_symbol_to_restore
  1108.         mov     dword [edx+4],0
  1109.         jmp     symbol_restored
  1110.       no_symbol_to_restore:
  1111.         add     esi,ecx
  1112.       symbol_restored:
  1113.         pop     ecx
  1114.         lods    byte [esi]
  1115.         cmp     al,','
  1116.         je      restore_preprocessor_symbol
  1117.         or      al,al
  1118.         jnz     extra_characters_on_line
  1119.         jmp     line_preprocessed
  1120.  
  1121. process_fix_constants:
  1122.         mov     [value_type],11b
  1123.         jmp     process_symbolic_constants
  1124. process_equ_constants:
  1125.         mov     [value_type],10b
  1126.       process_symbolic_constants:
  1127.         mov     ebp,esi
  1128.         lods    byte [esi]
  1129.         cmp     al,1Ah
  1130.         je      check_symbol
  1131.         cmp     al,22h
  1132.         je      ignore_string
  1133.         cmp     al,'{'
  1134.         je      check_brace
  1135.         or      al,al
  1136.         jnz     process_symbolic_constants
  1137.         ret
  1138.       ignore_string:
  1139.         lods    dword [esi]
  1140.         add     esi,eax
  1141.         jmp     process_symbolic_constants
  1142.       check_brace:
  1143.         test    [value_type],80h
  1144.         jz      process_symbolic_constants
  1145.         ret
  1146.       no_replacing:
  1147.         movzx   ecx,byte [esi-1]
  1148.         add     esi,ecx
  1149.         jmp     process_symbolic_constants
  1150.       check_symbol:
  1151.         mov     cl,[esi]
  1152.         inc     esi
  1153.         mov     ch,[value_type]
  1154.         call    get_preprocessor_symbol
  1155.         jc      no_replacing
  1156.         mov     [current_section],edi
  1157.       replace_symbolic_constant:
  1158.         mov     ecx,[edx+12]
  1159.         mov     edx,[edx+8]
  1160.         xchg    esi,edx
  1161.         call    move_data
  1162.         mov     esi,edx
  1163.       process_after_replaced:
  1164.         lods    byte [esi]
  1165.         cmp     al,1Ah
  1166.         je      symbol_after_replaced
  1167.         stos    byte [edi]
  1168.         cmp     al,22h
  1169.         je      string_after_replaced
  1170.         cmp     al,'{'
  1171.         je      brace_after_replaced
  1172.         or      al,al
  1173.         jnz     process_after_replaced
  1174.         mov     ecx,edi
  1175.         sub     ecx,esi
  1176.         mov     edi,ebp
  1177.         call    move_data
  1178.         mov     esi,edi
  1179.         ret
  1180.       move_data:
  1181.         lea     eax,[edi+ecx]
  1182.         cmp     eax,[memory_end]
  1183.         jae     out_of_memory
  1184.         shr     ecx,1
  1185.         jnc     movsb_ok
  1186.         movs    byte [edi],[esi]
  1187.       movsb_ok:
  1188.         shr     ecx,1
  1189.         jnc     movsw_ok
  1190.         movs    word [edi],[esi]
  1191.       movsw_ok:
  1192.         rep     movs dword [edi],[esi]
  1193.         ret
  1194.       string_after_replaced:
  1195.         lods    dword [esi]
  1196.         stos    dword [edi]
  1197.         mov     ecx,eax
  1198.         call    move_data
  1199.         jmp     process_after_replaced
  1200.       brace_after_replaced:
  1201.         test    [value_type],80h
  1202.         jz      process_after_replaced
  1203.         mov     edx,edi
  1204.         mov     ecx,[current_section]
  1205.         sub     edx,ecx
  1206.         sub     ecx,esi
  1207.         rep     movs byte [edi],[esi]
  1208.         mov     ecx,edi
  1209.         sub     ecx,esi
  1210.         mov     edi,ebp
  1211.         call    move_data
  1212.         lea     esi,[ebp+edx]
  1213.         ret
  1214.       symbol_after_replaced:
  1215.         mov     cl,[esi]
  1216.         inc     esi
  1217.         mov     ch,[value_type]
  1218.         call    get_preprocessor_symbol
  1219.         jnc     replace_symbolic_constant
  1220.         movzx   ecx,byte [esi-1]
  1221.         mov     al,1Ah
  1222.         mov     ah,cl
  1223.         stos    word [edi]
  1224.         call    move_data
  1225.         jmp     process_after_replaced
  1226. process_macro_operators:
  1227.         xor     dl,dl
  1228.         mov     ebp,edi
  1229.       before_macro_operators:
  1230.         mov     edi,esi
  1231.         lods    byte [esi]
  1232.         cmp     al,'`'
  1233.         je      symbol_conversion
  1234.         cmp     al,'#'
  1235.         je      concatenation
  1236.         cmp     al,1Ah
  1237.         je      symbol_before_macro_operators
  1238.         cmp     al,3Bh
  1239.         je      no_more_macro_operators
  1240.         cmp     al,22h
  1241.         je      string_before_macro_operators
  1242.         xor     dl,dl
  1243.         or      al,al
  1244.         jnz     before_macro_operators
  1245.         mov     edi,esi
  1246.         ret
  1247.       no_more_macro_operators:
  1248.         mov     edi,ebp
  1249.         ret
  1250.       symbol_before_macro_operators:
  1251.         mov     dl,1Ah
  1252.         mov     ebx,esi
  1253.         lods    byte [esi]
  1254.         movzx   ecx,al
  1255.         jecxz   symbol_before_macro_operators_ok
  1256.         mov     edi,esi
  1257.         cmp     byte [esi],'\'
  1258.         je      escaped_symbol
  1259.       symbol_before_macro_operators_ok:
  1260.         add     esi,ecx
  1261.         jmp     before_macro_operators
  1262.       string_before_macro_operators:
  1263.         mov     dl,22h
  1264.         mov     ebx,esi
  1265.         lods    dword [esi]
  1266.         add     esi,eax
  1267.         jmp     before_macro_operators
  1268.       escaped_symbol:
  1269.         dec     byte [edi-1]
  1270.         dec     ecx
  1271.         inc     esi
  1272.         cmp     ecx,1
  1273.         rep     movs byte [edi],[esi]
  1274.         jne     after_macro_operators
  1275.         mov     al,[esi-1]
  1276.         mov     ecx,ebx
  1277.         mov     ebx,characters
  1278.         xlat    byte [ebx]
  1279.         mov     ebx,ecx
  1280.         or      al,al
  1281.         jnz     after_macro_operators
  1282.         sub     edi,3
  1283.         mov     al,[esi-1]
  1284.         stos    byte [edi]
  1285.         xor     dl,dl
  1286.         jmp     after_macro_operators
  1287.       reduce_symbol_conversion:
  1288.         inc     esi
  1289.       symbol_conversion:
  1290.         mov     edx,esi
  1291.         mov     al,[esi]
  1292.         cmp     al,1Ah
  1293.         jne     symbol_character_conversion
  1294.         lods    word [esi]
  1295.         movzx   ecx,ah
  1296.         lea     ebx,[edi+3]
  1297.         jecxz   convert_to_quoted_string
  1298.         cmp     byte [esi],'\'
  1299.         jne     convert_to_quoted_string
  1300.         inc     esi
  1301.         dec     ecx
  1302.         dec     ebx
  1303.         jmp     convert_to_quoted_string
  1304.       symbol_character_conversion:
  1305.         cmp     al,22h
  1306.         je      after_macro_operators
  1307.         cmp     al,'`'
  1308.         je      reduce_symbol_conversion
  1309.         lea     ebx,[edi+5]
  1310.         xor     ecx,ecx
  1311.         or      al,al
  1312.         jz      convert_to_quoted_string
  1313.         cmp     al,'#'
  1314.         je      convert_to_quoted_string
  1315.         inc     ecx
  1316.       convert_to_quoted_string:
  1317.         sub     ebx,edx
  1318.         ja      shift_line_data
  1319.         mov     al,22h
  1320.         mov     dl,al
  1321.         stos    byte [edi]
  1322.         mov     ebx,edi
  1323.         mov     eax,ecx
  1324.         stos    dword [edi]
  1325.         rep     movs byte [edi],[esi]
  1326.         cmp     edi,esi
  1327.         je      before_macro_operators
  1328.         jmp     after_macro_operators
  1329.       shift_line_data:
  1330.         push    ecx
  1331.         mov     edx,esi
  1332.         lea     esi,[ebp-1]
  1333.         add     ebp,ebx
  1334.         lea     edi,[ebp-1]
  1335.         lea     ecx,[esi+1]
  1336.         sub     ecx,edx
  1337.         std
  1338.         rep     movs byte [edi],[esi]
  1339.         cld
  1340.         pop     eax
  1341.         sub     edi,3
  1342.         mov     dl,22h
  1343.         mov     [edi-1],dl
  1344.         mov     ebx,edi
  1345.         mov     [edi],eax
  1346.         lea     esi,[edi+4+eax]
  1347.         jmp     before_macro_operators
  1348.       concatenation:
  1349.         cmp     dl,1Ah
  1350.         je      symbol_concatenation
  1351.         cmp     dl,22h
  1352.         je      string_concatenation
  1353.       no_concatenation:
  1354.         cmp     esi,edi
  1355.         je      before_macro_operators
  1356.         jmp     after_macro_operators
  1357.       symbol_concatenation:
  1358.         cmp     byte [esi],1Ah
  1359.         jne     no_concatenation
  1360.         inc     esi
  1361.         lods    byte [esi]
  1362.         movzx   ecx,al
  1363.         jecxz   do_symbol_concatenation
  1364.         cmp     byte [esi],'\'
  1365.         je      concatenate_escaped_symbol
  1366.       do_symbol_concatenation:
  1367.         add     [ebx],cl
  1368.         jc      name_too_long
  1369.         rep     movs byte [edi],[esi]
  1370.         jmp     after_macro_operators
  1371.       concatenate_escaped_symbol:
  1372.         inc     esi
  1373.         dec     ecx
  1374.         jz      do_symbol_concatenation
  1375.         movzx   eax,byte [esi]
  1376.         cmp     byte [characters+eax],0
  1377.         jne     do_symbol_concatenation
  1378.         sub     esi,3
  1379.         jmp     no_concatenation
  1380.       string_concatenation:
  1381.         cmp     byte [esi],22h
  1382.         je      do_string_concatenation
  1383.         cmp     byte [esi],'`'
  1384.         jne     no_concatenation
  1385.       concatenate_converted_symbol:
  1386.         inc     esi
  1387.         mov     al,[esi]
  1388.         cmp     al,'`'
  1389.         je      concatenate_converted_symbol
  1390.         cmp     al,22h
  1391.         je      do_string_concatenation
  1392.         cmp     al,1Ah
  1393.         jne     concatenate_converted_symbol_character
  1394.         inc     esi
  1395.         lods    byte [esi]
  1396.         movzx   ecx,al
  1397.         jecxz   finish_concatenating_converted_symbol
  1398.         cmp     byte [esi],'\'
  1399.         jne     finish_concatenating_converted_symbol
  1400.         inc     esi
  1401.         dec     ecx
  1402.       finish_concatenating_converted_symbol:
  1403.         add     [ebx],ecx
  1404.         rep     movs byte [edi],[esi]
  1405.         jmp     after_macro_operators
  1406.       concatenate_converted_symbol_character:
  1407.         or      al,al
  1408.         jz      after_macro_operators
  1409.         cmp     al,'#'
  1410.         je      after_macro_operators
  1411.         inc     dword [ebx]
  1412.         movs    byte [edi],[esi]
  1413.         jmp     after_macro_operators
  1414.       do_string_concatenation:
  1415.         inc     esi
  1416.         lods    dword [esi]
  1417.         mov     ecx,eax
  1418.         add     [ebx],eax
  1419.         rep     movs byte [edi],[esi]
  1420.       after_macro_operators:
  1421.         lods    byte [esi]
  1422.         cmp     al,'`'
  1423.         je      symbol_conversion
  1424.         cmp     al,'#'
  1425.         je      concatenation
  1426.         stos    byte [edi]
  1427.         cmp     al,1Ah
  1428.         je      symbol_after_macro_operators
  1429.         cmp     al,3Bh
  1430.         je      no_more_macro_operators
  1431.         cmp     al,22h
  1432.         je      string_after_macro_operators
  1433.         xor     dl,dl
  1434.         or      al,al
  1435.         jnz     after_macro_operators
  1436.         ret
  1437.       symbol_after_macro_operators:
  1438.         mov     dl,1Ah
  1439.         mov     ebx,edi
  1440.         lods    byte [esi]
  1441.         stos    byte [edi]
  1442.         movzx   ecx,al
  1443.         jecxz   symbol_after_macro_operatorss_ok
  1444.         cmp     byte [esi],'\'
  1445.         je      escaped_symbol
  1446.       symbol_after_macro_operatorss_ok:
  1447.         rep     movs byte [edi],[esi]
  1448.         jmp     after_macro_operators
  1449.       string_after_macro_operators:
  1450.         mov     dl,22h
  1451.         mov     ebx,edi
  1452.         lods    dword [esi]
  1453.         stos    dword [edi]
  1454.         mov     ecx,eax
  1455.         rep     movs byte [edi],[esi]
  1456.         jmp     after_macro_operators
  1457.  
  1458. use_macro:
  1459.         push    [free_additional_memory]
  1460.         push    [macro_symbols]
  1461.         mov     [macro_symbols],0
  1462.         push    [counter_limit]
  1463.         push    dword [edx+4]
  1464.         mov     dword [edx+4],1
  1465.         push    edx
  1466.         mov     ebx,esi
  1467.         mov     esi,[edx+8]
  1468.         mov     eax,[edx+12]
  1469.         mov     [macro_line],eax
  1470.         mov     [counter_limit],0
  1471.         xor     ebp,ebp
  1472.       process_macro_arguments:
  1473.         mov     al,[esi]
  1474.         or      al,al
  1475.         jz      arguments_end
  1476.         cmp     al,'{'
  1477.         je      arguments_end
  1478.         inc     esi
  1479.         cmp     al,'['
  1480.         jne     get_macro_arguments
  1481.         mov     ebp,esi
  1482.         inc     esi
  1483.         inc     [counter_limit]
  1484.       get_macro_arguments:
  1485.         call    get_macro_argument
  1486.         lods    byte [esi]
  1487.         cmp     al,','
  1488.         je      next_argument
  1489.         cmp     al,']'
  1490.         je      next_arguments_group
  1491.         dec     esi
  1492.         jmp     arguments_end
  1493.       next_argument:
  1494.         cmp     byte [ebx],','
  1495.         jne     process_macro_arguments
  1496.         inc     ebx
  1497.         jmp     process_macro_arguments
  1498.       next_arguments_group:
  1499.         cmp     byte [ebx],','
  1500.         jne     arguments_end
  1501.         inc     ebx
  1502.         inc     [counter_limit]
  1503.         mov     esi,ebp
  1504.         jmp     process_macro_arguments
  1505.       get_macro_argument:
  1506.         lods    byte [esi]
  1507.         movzx   ecx,al
  1508.         mov     eax,[counter_limit]
  1509.         call    add_macro_symbol
  1510.         add     esi,ecx
  1511.         xchg    esi,ebx
  1512.         mov     [edx+12],esi
  1513.         mov     [default_argument_value],0
  1514.         call    skip_macro_argument_value
  1515.         call    finish_macro_argument
  1516.         xchg    esi,ebx
  1517.         cmp     byte [esi],'='
  1518.         je      argument_with_default_value
  1519.         cmp     byte [esi],'*'
  1520.         jne     macro_argument_ok
  1521.         cmp     dword [edx+8],0
  1522.         je      invalid_macro_arguments
  1523.         inc     esi
  1524.       macro_argument_ok:
  1525.         ret
  1526.       finish_macro_argument:
  1527.         mov     eax,[edx+12]
  1528.         mov     ecx,esi
  1529.         sub     ecx,eax
  1530.         cmp     byte [eax],'<'
  1531.         jne     argument_value_length_ok
  1532.         inc     dword [edx+12]
  1533.         sub     ecx,2
  1534.         or      ecx,80000000h
  1535.       argument_value_length_ok:
  1536.         mov     [edx+8],ecx
  1537.         ret
  1538.       argument_with_default_value:
  1539.         inc     esi
  1540.         push    esi
  1541.         or      [default_argument_value],-1
  1542.         call    skip_macro_argument_value
  1543.         pop     eax
  1544.         cmp     dword [edx+8],0
  1545.         jne     macro_argument_ok
  1546.         mov     [edx+12],eax
  1547.         call    finish_macro_argument
  1548.         jmp     macro_argument_ok
  1549.       arguments_end:
  1550.         cmp     byte [ebx],0
  1551.         jne     invalid_macro_arguments
  1552.         mov     eax,[esp+4]
  1553.         dec     eax
  1554.         call    process_macro
  1555.         pop     edx
  1556.         pop     dword [edx+4]
  1557.         pop     [counter_limit]
  1558.         pop     [macro_symbols]
  1559.         pop     [free_additional_memory]
  1560.         jmp     line_preprocessed
  1561. use_instant_macro:
  1562.         push    edi [current_line] esi
  1563.         mov     eax,[error_line]
  1564.         mov     [current_line],eax
  1565.         mov     [macro_line],eax
  1566.         mov     esi,[instant_macro_start]
  1567.         cmp     [base_code],10h
  1568.         jae     do_match
  1569.         cmp     [base_code],0
  1570.         jne     do_irp
  1571.         call    precalculate_value
  1572.         cmp     eax,0
  1573.         jl      value_out_of_range
  1574.         push    [free_additional_memory]
  1575.         push    [macro_symbols]
  1576.         mov     [macro_symbols],0
  1577.         push    [counter_limit]
  1578.         mov     [struc_name],0
  1579.         mov     [counter_limit],eax
  1580.         lods    byte [esi]
  1581.         or      al,al
  1582.         jz      rept_counters_ok
  1583.         cmp     al,'{'
  1584.         je      rept_counters_ok
  1585.         cmp     al,1Ah
  1586.         jne     invalid_macro_arguments
  1587.       add_rept_counter:
  1588.         lods    byte [esi]
  1589.         movzx   ecx,al
  1590.         xor     eax,eax
  1591.         call    add_macro_symbol
  1592.         add     esi,ecx
  1593.         xor     eax,eax
  1594.         mov     dword [edx+12],eax
  1595.         inc     eax
  1596.         mov     dword [edx+8],eax
  1597.         lods    byte [esi]
  1598.         cmp     al,':'
  1599.         jne     rept_counter_added
  1600.         push    edx
  1601.         call    precalculate_value
  1602.         mov     edx,eax
  1603.         add     edx,[counter_limit]
  1604.         jo      value_out_of_range
  1605.         pop     edx
  1606.         mov     dword [edx+8],eax
  1607.         lods    byte [esi]
  1608.       rept_counter_added:
  1609.         cmp     al,','
  1610.         jne     rept_counters_ok
  1611.         lods    byte [esi]
  1612.         cmp     al,1Ah
  1613.         jne     invalid_macro_arguments
  1614.         jmp     add_rept_counter
  1615.       rept_counters_ok:
  1616.         dec     esi
  1617.         cmp     [counter_limit],0
  1618.         je      instant_macro_finish
  1619.       instant_macro_parameters_ok:
  1620.         xor     eax,eax
  1621.         call    process_macro
  1622.       instant_macro_finish:
  1623.         pop     [counter_limit]
  1624.         pop     [macro_symbols]
  1625.         pop     [free_additional_memory]
  1626.       instant_macro_done:
  1627.         pop     ebx esi edx
  1628.         cmp     byte [ebx],0
  1629.         je      line_preprocessed
  1630.         mov     [current_line],edi
  1631.         mov     ecx,4
  1632.         rep     movs dword [edi],[esi]
  1633.         test    [macro_status],0Fh
  1634.         jz      instant_macro_attached_line
  1635.         mov     ax,3Bh
  1636.         stos    word [edi]
  1637.       instant_macro_attached_line:
  1638.         mov     esi,ebx
  1639.         sub     edx,ebx
  1640.         mov     ecx,edx
  1641.         call    move_data
  1642.         jmp     initial_preprocessing_ok
  1643.       precalculate_value:
  1644.         push    edi
  1645.         call    convert_expression
  1646.         mov     al,')'
  1647.         stosb
  1648.         push    esi
  1649.         mov     esi,[esp+4]
  1650.         mov     [error_line],0
  1651.         mov     [value_size],0
  1652.         call    calculate_expression
  1653.         cmp     [error_line],0
  1654.         je      value_precalculated
  1655.         jmp     [error]
  1656.       value_precalculated:
  1657.         mov     eax,[edi]
  1658.         mov     ecx,[edi+4]
  1659.         cdq
  1660.         cmp     edx,ecx
  1661.         jne     value_out_of_range
  1662.         cmp     dl,[edi+13]
  1663.         jne     value_out_of_range
  1664.         pop     esi edi
  1665.         ret
  1666. do_irp:
  1667.         cmp     byte [esi],1Ah
  1668.         jne     invalid_macro_arguments
  1669.         movzx   eax,byte [esi+1]
  1670.         lea     esi,[esi+2+eax]
  1671.         lods    byte [esi]
  1672.         cmp     [base_code],1
  1673.         ja      irps_name_ok
  1674.         cmp     al,'='
  1675.         je      irp_with_default_value
  1676.         cmp     al,'*'
  1677.         jne     irp_name_ok
  1678.         lods    byte [esi]
  1679.       irp_name_ok:
  1680.         cmp     al,','
  1681.         jne     invalid_macro_arguments
  1682.         jmp     irp_parameters_start
  1683.       irp_with_default_value:
  1684.         xor     ebp,ebp
  1685.         or      [default_argument_value],-1
  1686.         call    skip_macro_argument_value
  1687.         inc     esi
  1688.       irps_name_ok:
  1689.         cmp     al,','
  1690.         jne     invalid_macro_arguments
  1691.         mov     al,[esi]
  1692.         or      al,al
  1693.         jz      instant_macro_done
  1694.         cmp     al,'{'
  1695.         je      instant_macro_done
  1696.       irp_parameters_start:
  1697.         xor     eax,eax
  1698.         push    [free_additional_memory]
  1699.         push    [macro_symbols]
  1700.         mov     [macro_symbols],eax
  1701.         push    [counter_limit]
  1702.         mov     [counter_limit],eax
  1703.         mov     [struc_name],eax
  1704.         mov     ebx,esi
  1705.         cmp     [base_code],1
  1706.         ja      get_irps_parameter
  1707.         mov     edx,[parameters_end]
  1708.         mov     al,[edx]
  1709.         push    eax
  1710.         mov     byte [edx],0
  1711.       get_irp_parameter:
  1712.         inc     [counter_limit]
  1713.         mov     esi,[instant_macro_start]
  1714.         inc     esi
  1715.         call    get_macro_argument
  1716.         cmp     byte [ebx],','
  1717.         jne     irp_parameters_end
  1718.         inc     ebx
  1719.         jmp     get_irp_parameter
  1720.       irp_parameters_end:
  1721.         mov     esi,ebx
  1722.         pop     eax
  1723.         mov     [esi],al
  1724.         jmp     instant_macro_parameters_ok
  1725.       get_irps_parameter:
  1726.         mov     esi,[instant_macro_start]
  1727.         inc     esi
  1728.         lods    byte [esi]
  1729.         movzx   ecx,al
  1730.         inc     [counter_limit]
  1731.         mov     eax,[counter_limit]
  1732.         call    add_macro_symbol
  1733.         mov     [edx+12],ebx
  1734.         cmp     byte [ebx],1Ah
  1735.         je      irps_symbol
  1736.         cmp     byte [ebx],22h
  1737.         je      irps_quoted_string
  1738.         mov     eax,1
  1739.         jmp     irps_parameter_ok
  1740.       irps_quoted_string:
  1741.         mov     eax,[ebx+1]
  1742.         add     eax,1+4
  1743.         jmp     irps_parameter_ok
  1744.       irps_symbol:
  1745.         movzx   eax,byte [ebx+1]
  1746.         add     eax,1+1
  1747.       irps_parameter_ok:
  1748.         mov     [edx+8],eax
  1749.         add     ebx,eax
  1750.         cmp     byte [ebx],0
  1751.         je      irps_parameters_end
  1752.         cmp     byte [ebx],'{'
  1753.         jne     get_irps_parameter
  1754.       irps_parameters_end:
  1755.         mov     esi,ebx
  1756.         jmp     instant_macro_parameters_ok
  1757. do_match:
  1758.         mov     ebx,esi
  1759.         call    skip_pattern
  1760.         call    exact_match
  1761.         mov     edx,edi
  1762.         mov     al,[ebx]
  1763.         cmp     al,1Ah
  1764.         je      free_match
  1765.         cmp     al,','
  1766.         jne     instant_macro_done
  1767.         cmp     esi,[parameters_end]
  1768.         je      matched_pattern
  1769.         jmp     instant_macro_done
  1770.       free_match:
  1771.         add     edx,12
  1772.         cmp     edx,[memory_end]
  1773.         ja      out_of_memory
  1774.         mov     [edx-12],ebx
  1775.         mov     [edx-8],esi
  1776.         call    skip_match_element
  1777.         jc      try_different_matching
  1778.         mov     [edx-4],esi
  1779.         movzx   eax,byte [ebx+1]
  1780.         lea     ebx,[ebx+2+eax]
  1781.         cmp     byte [ebx],1Ah
  1782.         je      free_match
  1783.       find_exact_match:
  1784.         call    exact_match
  1785.         cmp     esi,[parameters_end]
  1786.         je      end_matching
  1787.         cmp     byte [ebx],1Ah
  1788.         je      free_match
  1789.         mov     ebx,[edx-12]
  1790.         movzx   eax,byte [ebx+1]
  1791.         lea     ebx,[ebx+2+eax]
  1792.         mov     esi,[edx-4]
  1793.         jmp     match_more_elements
  1794.       try_different_matching:
  1795.         sub     edx,12
  1796.         cmp     edx,edi
  1797.         je      instant_macro_done
  1798.         mov     ebx,[edx-12]
  1799.         movzx   eax,byte [ebx+1]
  1800.         lea     ebx,[ebx+2+eax]
  1801.         cmp     byte [ebx],1Ah
  1802.         je      try_different_matching
  1803.         mov     esi,[edx-4]
  1804.       match_more_elements:
  1805.         call    skip_match_element
  1806.         jc      try_different_matching
  1807.         mov     [edx-4],esi
  1808.         jmp     find_exact_match
  1809.       skip_match_element:
  1810.         cmp     esi,[parameters_end]
  1811.         je      cannot_match
  1812.         mov     al,[esi]
  1813.         cmp     al,1Ah
  1814.         je      skip_match_symbol
  1815.         cmp     al,22h
  1816.         je      skip_match_quoted_string
  1817.         add     esi,1
  1818.         ret
  1819.       skip_match_quoted_string:
  1820.         mov     eax,[esi+1]
  1821.         add     esi,5
  1822.         jmp     skip_match_ok
  1823.       skip_match_symbol:
  1824.         movzx   eax,byte [esi+1]
  1825.         add     esi,2
  1826.       skip_match_ok:
  1827.         add     esi,eax
  1828.         ret
  1829.       cannot_match:
  1830.         stc
  1831.         ret
  1832.       exact_match:
  1833.         cmp     esi,[parameters_end]
  1834.         je      exact_match_complete
  1835.         mov     ah,[esi]
  1836.         mov     al,[ebx]
  1837.         cmp     al,','
  1838.         je      exact_match_complete
  1839.         cmp     al,1Ah
  1840.         je      exact_match_complete
  1841.         cmp     al,'='
  1842.         je      match_verbatim
  1843.         call    match_elements
  1844.         je      exact_match
  1845.       exact_match_complete:
  1846.         ret
  1847.       match_verbatim:
  1848.         inc     ebx
  1849.         call    match_elements
  1850.         je      exact_match
  1851.         dec     ebx
  1852.         ret
  1853.       match_elements:
  1854.         mov     al,[ebx]
  1855.         cmp     al,1Ah
  1856.         je      match_symbols
  1857.         cmp     al,22h
  1858.         je      match_quoted_strings
  1859.         cmp     al,ah
  1860.         je      symbol_characters_matched
  1861.         ret
  1862.       symbol_characters_matched:
  1863.         lea     ebx,[ebx+1]
  1864.         lea     esi,[esi+1]
  1865.         ret
  1866.       match_quoted_strings:
  1867.         mov     ecx,[ebx+1]
  1868.         add     ecx,5
  1869.         jmp     compare_elements
  1870.       match_symbols:
  1871.         movzx   ecx,byte [ebx+1]
  1872.         add     ecx,2
  1873.       compare_elements:
  1874.         mov     eax,esi
  1875.         mov     ebp,edi
  1876.         mov     edi,ebx
  1877.         repe    cmps byte [esi],[edi]
  1878.         jne     elements_mismatch
  1879.         mov     ebx,edi
  1880.         mov     edi,ebp
  1881.         ret
  1882.       elements_mismatch:
  1883.         mov     esi,eax
  1884.         mov     edi,ebp
  1885.         ret
  1886.       end_matching:
  1887.         cmp     byte [ebx],','
  1888.         jne     instant_macro_done
  1889.       matched_pattern:
  1890.         xor     eax,eax
  1891.         push    [free_additional_memory]
  1892.         push    [macro_symbols]
  1893.         mov     [macro_symbols],eax
  1894.         push    [counter_limit]
  1895.         mov     [counter_limit],eax
  1896.         mov     [struc_name],eax
  1897.         push    esi edi edx
  1898.       add_matched_symbol:
  1899.         cmp     edi,[esp]
  1900.         je      matched_symbols_ok
  1901.         mov     esi,[edi]
  1902.         inc     esi
  1903.         lods    byte [esi]
  1904.         movzx   ecx,al
  1905.         xor     eax,eax
  1906.         call    add_macro_symbol
  1907.         mov     eax,[edi+4]
  1908.         mov     dword [edx+12],eax
  1909.         mov     ecx,[edi+8]
  1910.         sub     ecx,eax
  1911.         mov     dword [edx+8],ecx
  1912.         add     edi,12
  1913.         jmp     add_matched_symbol
  1914.       matched_symbols_ok:
  1915.         pop     edx edi esi
  1916.         jmp     instant_macro_parameters_ok
  1917.  
  1918. process_macro:
  1919.         push    dword [macro_status]
  1920.         or      [macro_status],10h
  1921.         push    [counter]
  1922.         push    [macro_block]
  1923.         push    [macro_block_line]
  1924.         push    [macro_block_line_number]
  1925.         push    [struc_label]
  1926.         push    [struc_name]
  1927.         push    eax
  1928.         push    [current_line]
  1929.         lods    byte [esi]
  1930.         cmp     al,'{'
  1931.         je      macro_instructions_start
  1932.         or      al,al
  1933.         jnz     unexpected_characters
  1934.       find_macro_instructions:
  1935.         mov     [macro_line],esi
  1936.         add     esi,16+2
  1937.         lods    byte [esi]
  1938.         or      al,al
  1939.         jz      find_macro_instructions
  1940.         cmp     al,'{'
  1941.         je      macro_instructions_start
  1942.         cmp     al,3Bh
  1943.         jne     unexpected_characters
  1944.         call    skip_foreign_symbol
  1945.         jmp     find_macro_instructions
  1946.       macro_instructions_start:
  1947.         mov     ecx,80000000h
  1948.         mov     [macro_block],esi
  1949.         mov     eax,[macro_line]
  1950.         mov     [macro_block_line],eax
  1951.         mov     [macro_block_line_number],ecx
  1952.         xor     eax,eax
  1953.         mov     [counter],eax
  1954.         cmp     [counter_limit],eax
  1955.         je      process_macro_line
  1956.         inc     [counter]
  1957.       process_macro_line:
  1958.         lods    byte [esi]
  1959.         or      al,al
  1960.         jz      process_next_line
  1961.         cmp     al,'}'
  1962.         je      macro_block_processed
  1963.         dec     esi
  1964.         mov     [current_line],edi
  1965.         lea     eax,[edi+10h]
  1966.         cmp     eax,[memory_end]
  1967.         jae     out_of_memory
  1968.         mov     eax,[esp+4]
  1969.         or      eax,eax
  1970.         jz      instant_macro_line_header
  1971.         stos    dword [edi]
  1972.         mov     eax,ecx
  1973.         stos    dword [edi]
  1974.         mov     eax,[esp]
  1975.         stos    dword [edi]
  1976.         mov     eax,[macro_line]
  1977.         stos    dword [edi]
  1978.         jmp     macro_line_header_ok
  1979.       instant_macro_line_header:
  1980.         mov     eax,[macro_line]
  1981.         add     eax,16+1
  1982.         stos    dword [edi]
  1983.         mov     eax,ecx
  1984.         stos    dword [edi]
  1985.         mov     eax,[macro_line]
  1986.         stos    dword [edi]
  1987.         stos    dword [edi]
  1988.       macro_line_header_ok:
  1989.         or      [macro_status],20h
  1990.         push    ebx ecx
  1991.         test    [macro_status],0Fh
  1992.         jz      process_macro_line_element
  1993.         mov     ax,3Bh
  1994.         stos    word [edi]
  1995.       process_macro_line_element:
  1996.         lea     eax,[edi+100h]
  1997.         cmp     eax,[memory_end]
  1998.         jae     out_of_memory
  1999.         lods    byte [esi]
  2000.         cmp     al,'}'
  2001.         je      macro_line_processed
  2002.         or      al,al
  2003.         jz      macro_line_processed
  2004.         cmp     al,1Ah
  2005.         je      process_macro_symbol
  2006.         cmp     al,3Bh
  2007.         je      macro_foreign_line
  2008.         and     [macro_status],not 20h
  2009.         stos    byte [edi]
  2010.         cmp     al,22h
  2011.         jne     process_macro_line_element
  2012.       copy_macro_string:
  2013.         mov     ecx,[esi]
  2014.         add     ecx,4
  2015.         call    move_data
  2016.         jmp     process_macro_line_element
  2017.       process_macro_symbol:
  2018.         push    esi edi
  2019.         test    [macro_status],20h
  2020.         jz      not_macro_directive
  2021.         movzx   ecx,byte [esi]
  2022.         inc     esi
  2023.         mov     edi,macro_directives
  2024.         call    get_directive
  2025.         jnc     process_macro_directive
  2026.         dec     esi
  2027.         jmp     not_macro_directive
  2028.       process_macro_directive:
  2029.         mov     edx,eax
  2030.         pop     edi eax
  2031.         mov     byte [edi],0
  2032.         inc     edi
  2033.         pop     ecx ebx
  2034.         jmp     near edx
  2035.       not_macro_directive:
  2036.         and     [macro_status],not 20h
  2037.         movzx   ecx,byte [esi]
  2038.         inc     esi
  2039.         mov     eax,[counter]
  2040.         call    get_macro_symbol
  2041.         jnc     group_macro_symbol
  2042.         xor     eax,eax
  2043.         cmp     [counter],eax
  2044.         je      multiple_macro_symbol_values
  2045.         call    get_macro_symbol
  2046.         jc      not_macro_symbol
  2047.       replace_macro_symbol:
  2048.         pop     edi eax
  2049.         mov     ecx,[edx+8]
  2050.         mov     edx,[edx+12]
  2051.         or      edx,edx
  2052.         jz      replace_macro_counter
  2053.         and     ecx,not 80000000h
  2054.         xchg    esi,edx
  2055.         call    move_data
  2056.         mov     esi,edx
  2057.         jmp     process_macro_line_element
  2058.       group_macro_symbol:
  2059.         xor     eax,eax
  2060.         cmp     [counter],eax
  2061.         je      replace_macro_symbol
  2062.         push    esi edx
  2063.         sub     esi,ecx
  2064.         call    get_macro_symbol
  2065.         mov     ebx,edx
  2066.         pop     edx esi
  2067.         jc      replace_macro_symbol
  2068.         cmp     edx,ebx
  2069.         ja      replace_macro_symbol
  2070.         mov     edx,ebx
  2071.         jmp     replace_macro_symbol
  2072.       multiple_macro_symbol_values:
  2073.         inc     eax
  2074.         push    eax
  2075.         call    get_macro_symbol
  2076.         pop     eax
  2077.         jc      not_macro_symbol
  2078.         pop     edi
  2079.         push    ecx
  2080.         mov     ecx,[edx+8]
  2081.         mov     edx,[edx+12]
  2082.         xchg    esi,edx
  2083.         btr     ecx,31
  2084.         jc      enclose_macro_symbol_value
  2085.         rep     movs byte [edi],[esi]
  2086.         jmp     macro_symbol_value_ok
  2087.       enclose_macro_symbol_value:
  2088.         mov     byte [edi],'<'
  2089.         inc     edi
  2090.         rep     movs byte [edi],[esi]
  2091.         mov     byte [edi],'>'
  2092.         inc     edi
  2093.       macro_symbol_value_ok:
  2094.         cmp     eax,[counter_limit]
  2095.         je      multiple_macro_symbol_values_ok
  2096.         mov     byte [edi],','
  2097.         inc     edi
  2098.         mov     esi,edx
  2099.         pop     ecx
  2100.         push    edi
  2101.         sub     esi,ecx
  2102.         jmp     multiple_macro_symbol_values
  2103.       multiple_macro_symbol_values_ok:
  2104.         pop     ecx eax
  2105.         mov     esi,edx
  2106.         jmp     process_macro_line_element
  2107.       replace_macro_counter:
  2108.         mov     eax,[counter]
  2109.         and     eax,not 80000000h
  2110.         jz      group_macro_counter
  2111.         add     ecx,eax
  2112.         dec     ecx
  2113.         call    store_number_symbol
  2114.         jmp     process_macro_line_element
  2115.       group_macro_counter:
  2116.         mov     edx,ecx
  2117.         xor     ecx,ecx
  2118.       multiple_macro_counter_values:
  2119.         push    ecx edx
  2120.         add     ecx,edx
  2121.         call    store_number_symbol
  2122.         pop     edx ecx
  2123.         inc     ecx
  2124.         cmp     ecx,[counter_limit]
  2125.         je      process_macro_line_element
  2126.         mov     byte [edi],','
  2127.         inc     edi
  2128.         jmp     multiple_macro_counter_values
  2129.       store_number_symbol:
  2130.         cmp     ecx,0
  2131.         jge     numer_symbol_sign_ok
  2132.         neg     ecx
  2133.         mov     al,'-'
  2134.         stos    byte [edi]
  2135.       numer_symbol_sign_ok:
  2136.         mov     ax,1Ah
  2137.         stos    word [edi]
  2138.         push    edi
  2139.         mov     eax,ecx
  2140.         mov     ecx,1000000000
  2141.         xor     edx,edx
  2142.         xor     bl,bl
  2143.       store_number_digits:
  2144.         div     ecx
  2145.         push    edx
  2146.         or      bl,bl
  2147.         jnz     store_number_digit
  2148.         cmp     ecx,1
  2149.         je      store_number_digit
  2150.         or      al,al
  2151.         jz      number_digit_ok
  2152.         not     bl
  2153.       store_number_digit:
  2154.         add     al,30h
  2155.         stos    byte [edi]
  2156.       number_digit_ok:
  2157.         mov     eax,ecx
  2158.         xor     edx,edx
  2159.         mov     ecx,10
  2160.         div     ecx
  2161.         mov     ecx,eax
  2162.         pop     eax
  2163.         or      ecx,ecx
  2164.         jnz     store_number_digits
  2165.         pop     ebx
  2166.         mov     eax,edi
  2167.         sub     eax,ebx
  2168.         mov     [ebx-1],al
  2169.         ret
  2170.       not_macro_symbol:
  2171.         pop     edi esi
  2172.         mov     al,1Ah
  2173.         stos    byte [edi]
  2174.         mov     al,[esi]
  2175.         inc     esi
  2176.         stos    byte [edi]
  2177.         cmp     byte [esi],'.'
  2178.         jne     copy_raw_symbol
  2179.         mov     ebx,[esp+8+8]
  2180.         or      ebx,ebx
  2181.         jz      copy_raw_symbol
  2182.         cmp     al,1
  2183.         je      copy_struc_name
  2184.         xchg    esi,ebx
  2185.         movzx   ecx,byte [esi-1]
  2186.         add     [edi-1],cl
  2187.         jc      name_too_long
  2188.         rep     movs byte [edi],[esi]
  2189.         xchg    esi,ebx
  2190.       copy_raw_symbol:
  2191.         movzx   ecx,al
  2192.         rep     movs byte [edi],[esi]
  2193.         jmp     process_macro_line_element
  2194.       copy_struc_name:
  2195.         inc     esi
  2196.         xchg    esi,ebx
  2197.         movzx   ecx,byte [esi-1]
  2198.         mov     [edi-1],cl
  2199.         rep     movs byte [edi],[esi]
  2200.         xchg    esi,ebx
  2201.         mov     eax,[esp+8+12]
  2202.         cmp     byte [eax],3Bh
  2203.         je      process_macro_line_element
  2204.         cmp     byte [eax],1Ah
  2205.         jne     disable_replaced_struc_name
  2206.         mov     byte [eax],3Bh
  2207.         jmp     process_macro_line_element
  2208.       disable_replaced_struc_name:
  2209.         mov     ebx,[esp+8+8]
  2210.         push    esi edi
  2211.         lea     edi,[ebx-3]
  2212.         lea     esi,[edi-2]
  2213.         lea     ecx,[esi+1]
  2214.         sub     ecx,eax
  2215.         std
  2216.         rep     movs byte [edi],[esi]
  2217.         cld
  2218.         mov     word [eax],3Bh
  2219.         pop     edi esi
  2220.         jmp     process_macro_line_element
  2221.       skip_foreign_symbol:
  2222.         lods    byte [esi]
  2223.         movzx   eax,al
  2224.         add     esi,eax
  2225.       skip_foreign_line:
  2226.         lods    byte [esi]
  2227.         cmp     al,1Ah
  2228.         je      skip_foreign_symbol
  2229.         cmp     al,3Bh
  2230.         je      skip_foreign_symbol
  2231.         cmp     al,22h
  2232.         je      skip_foreign_string
  2233.         or      al,al
  2234.         jnz     skip_foreign_line
  2235.         ret
  2236.       skip_foreign_string:
  2237.         lods    dword [esi]
  2238.         add     esi,eax
  2239.         jmp     skip_foreign_line
  2240.       macro_foreign_line:
  2241.         call    skip_foreign_symbol
  2242.       macro_line_processed:
  2243.         mov     byte [edi],0
  2244.         inc     edi
  2245.         push    eax
  2246.         call    preprocess_line
  2247.         pop     eax
  2248.         pop     ecx ebx
  2249.         cmp     al,'}'
  2250.         je      macro_block_processed
  2251.       process_next_line:
  2252.         inc     ecx
  2253.         mov     [macro_line],esi
  2254.         add     esi,16+2
  2255.         jmp     process_macro_line
  2256.       macro_block_processed:
  2257.         call    close_macro_block
  2258.         jc      process_macro_line
  2259.         pop     [current_line]
  2260.         add     esp,12
  2261.         pop     [macro_block_line_number]
  2262.         pop     [macro_block_line]
  2263.         pop     [macro_block]
  2264.         pop     [counter]
  2265.         pop     eax
  2266.         and     al,0F0h
  2267.         and     [macro_status],0Fh
  2268.         or      [macro_status],al
  2269.         ret
  2270.  
  2271. local_symbols:
  2272.         lods    byte [esi]
  2273.         cmp     al,1Ah
  2274.         jne     invalid_argument
  2275.         mov     byte [edi-1],3Bh
  2276.         xor     al,al
  2277.         stos    byte [edi]
  2278.       make_local_symbol:
  2279.         push    ecx
  2280.         lods    byte [esi]
  2281.         movzx   ecx,al
  2282.         mov     eax,[counter]
  2283.         call    add_macro_symbol
  2284.         mov     [edx+12],edi
  2285.         movzx   eax,[locals_counter]
  2286.         add     eax,ecx
  2287.         inc     eax
  2288.         cmp     eax,100h
  2289.         jae     name_too_long
  2290.         lea     ebp,[edi+2+eax]
  2291.         cmp     ebp,[memory_end]
  2292.         jae     out_of_memory
  2293.         mov     ah,al
  2294.         mov     al,1Ah
  2295.         stos    word [edi]
  2296.         rep     movs byte [edi],[esi]
  2297.         mov     al,'?'
  2298.         stos    byte [edi]
  2299.         push    esi
  2300.         mov     esi,locals_counter+1
  2301.         movzx   ecx,[locals_counter]
  2302.         rep     movs byte [edi],[esi]
  2303.         pop     esi
  2304.         mov     eax,edi
  2305.         sub     eax,[edx+12]
  2306.         mov     [edx+8],eax
  2307.         xor     al,al
  2308.         stos    byte [edi]
  2309.         mov     eax,locals_counter
  2310.         movzx   ecx,byte [eax]
  2311.       counter_loop:
  2312.         inc     byte [eax+ecx]
  2313.         cmp     byte [eax+ecx],'9'+1
  2314.         jb      counter_ok
  2315.         jne     letter_digit
  2316.         mov     byte [eax+ecx],'A'
  2317.         jmp     counter_ok
  2318.       letter_digit:
  2319.         cmp     byte [eax+ecx],'Z'+1
  2320.         jb      counter_ok
  2321.         jne     small_letter_digit
  2322.         mov     byte [eax+ecx],'a'
  2323.         jmp     counter_ok
  2324.       small_letter_digit:
  2325.         cmp     byte [eax+ecx],'z'+1
  2326.         jb      counter_ok
  2327.         mov     byte [eax+ecx],'0'
  2328.         loop    counter_loop
  2329.         inc     byte [eax]
  2330.         movzx   ecx,byte [eax]
  2331.         mov     byte [eax+ecx],'0'
  2332.       counter_ok:
  2333.         pop     ecx
  2334.         lods    byte [esi]
  2335.         cmp     al,'}'
  2336.         je      macro_block_processed
  2337.         or      al,al
  2338.         jz      process_next_line
  2339.         cmp     al,','
  2340.         jne     extra_characters_on_line
  2341.         dec     edi
  2342.         lods    byte [esi]
  2343.         cmp     al,1Ah
  2344.         je      make_local_symbol
  2345.         jmp     invalid_argument
  2346. common_block:
  2347.         call    close_macro_block
  2348.         jc      process_macro_line
  2349.         mov     [counter],0
  2350.         jmp     new_macro_block
  2351. forward_block:
  2352.         cmp     [counter_limit],0
  2353.         je      common_block
  2354.         call    close_macro_block
  2355.         jc      process_macro_line
  2356.         mov     [counter],1
  2357.         jmp     new_macro_block
  2358. reverse_block:
  2359.         cmp     [counter_limit],0
  2360.         je      common_block
  2361.         call    close_macro_block
  2362.         jc      process_macro_line
  2363.         mov     eax,[counter_limit]
  2364.         or      eax,80000000h
  2365.         mov     [counter],eax
  2366.       new_macro_block:
  2367.         mov     [macro_block],esi
  2368.         mov     eax,[macro_line]
  2369.         mov     [macro_block_line],eax
  2370.         mov     [macro_block_line_number],ecx
  2371.         jmp     process_macro_line
  2372. close_macro_block:
  2373.         cmp     [counter],0
  2374.         je      block_closed
  2375.         jl      reverse_counter
  2376.         mov     eax,[counter]
  2377.         cmp     eax,[counter_limit]
  2378.         je      block_closed
  2379.         inc     [counter]
  2380.         jmp     continue_block
  2381.       reverse_counter:
  2382.         mov     eax,[counter]
  2383.         dec     eax
  2384.         cmp     eax,80000000h
  2385.         je      block_closed
  2386.         mov     [counter],eax
  2387.       continue_block:
  2388.         mov     esi,[macro_block]
  2389.         mov     eax,[macro_block_line]
  2390.         mov     [macro_line],eax
  2391.         mov     ecx,[macro_block_line_number]
  2392.         stc
  2393.         ret
  2394.       block_closed:
  2395.         clc
  2396.         ret
  2397. get_macro_symbol:
  2398.         push    ecx
  2399.         call    find_macro_symbol_leaf
  2400.         jc      macro_symbol_not_found
  2401.         mov     edx,[ebx]
  2402.         mov     ebx,esi
  2403.       try_macro_symbol:
  2404.         or      edx,edx
  2405.         jz      macro_symbol_not_found
  2406.         mov     ecx,[esp]
  2407.         mov     edi,[edx+4]
  2408.         repe    cmps byte [esi],[edi]
  2409.         je      macro_symbol_found
  2410.         mov     esi,ebx
  2411.         mov     edx,[edx]
  2412.         jmp     try_macro_symbol
  2413.       macro_symbol_found:
  2414.         pop     ecx
  2415.         clc
  2416.         ret
  2417.       macro_symbol_not_found:
  2418.         pop     ecx
  2419.         stc
  2420.         ret
  2421.       find_macro_symbol_leaf:
  2422.         shl     eax,8
  2423.         mov     al,cl
  2424.         mov     ebp,eax
  2425.         mov     ebx,macro_symbols
  2426.       follow_macro_symbols_tree:
  2427.         mov     edx,[ebx]
  2428.         or      edx,edx
  2429.         jz      no_such_macro_symbol
  2430.         xor     eax,eax
  2431.         shr     ebp,1
  2432.         adc     eax,0
  2433.         lea     ebx,[edx+eax*4]
  2434.         or      ebp,ebp
  2435.         jnz     follow_macro_symbols_tree
  2436.         add     ebx,8
  2437.         clc
  2438.         ret
  2439.       no_such_macro_symbol:
  2440.         stc
  2441.         ret
  2442. add_macro_symbol:
  2443.         push    ebx ebp
  2444.         call    find_macro_symbol_leaf
  2445.         jc      extend_macro_symbol_tree
  2446.         mov     eax,[ebx]
  2447.       make_macro_symbol:
  2448.         mov     edx,[free_additional_memory]
  2449.         add     edx,16
  2450.         cmp     edx,[labels_list]
  2451.         ja      out_of_memory
  2452.         xchg    edx,[free_additional_memory]
  2453.         mov     [ebx],edx
  2454.         mov     [edx],eax
  2455.         mov     [edx+4],esi
  2456.         pop     ebp ebx
  2457.         ret
  2458.       extend_macro_symbol_tree:
  2459.         mov     edx,[free_additional_memory]
  2460.         add     edx,16
  2461.         cmp     edx,[labels_list]
  2462.         ja      out_of_memory
  2463.         xchg    edx,[free_additional_memory]
  2464.         xor     eax,eax
  2465.         mov     [edx],eax
  2466.         mov     [edx+4],eax
  2467.         mov     [edx+8],eax
  2468.         mov     [edx+12],eax
  2469.         shr     ebp,1
  2470.         adc     eax,0
  2471.         mov     [ebx],edx
  2472.         lea     ebx,[edx+eax*4]
  2473.         or      ebp,ebp
  2474.         jnz     extend_macro_symbol_tree
  2475.         add     ebx,8
  2476.         xor     eax,eax
  2477.         jmp     make_macro_symbol
  2478.  
  2479. include_file:
  2480.         lods    byte [esi]
  2481.         cmp     al,22h
  2482.         jne     invalid_argument
  2483.         lods    dword [esi]
  2484.         cmp     byte [esi+eax],0
  2485.         jne     extra_characters_on_line
  2486.         push    esi
  2487.         push    edi
  2488.         mov     ebx,[current_line]
  2489.       find_current_file_path:
  2490.         mov     esi,[ebx]
  2491.         test    byte [ebx+7],80h
  2492.         jz      copy_current_file_path
  2493.         mov     ebx,[ebx+8]
  2494.         jmp     find_current_file_path
  2495.       copy_current_file_path:
  2496.         lods    byte [esi]
  2497.         stos    byte [edi]
  2498.         or      al,al
  2499.         jnz     copy_current_file_path
  2500.       cut_current_file_name:
  2501.         cmp     edi,[esp]
  2502.         je      current_file_path_ok
  2503.         cmp     byte [edi-1],'\'
  2504.         je      current_file_path_ok
  2505.         cmp     byte [edi-1],'/'
  2506.         je      current_file_path_ok
  2507.         dec     edi
  2508.         jmp     cut_current_file_name
  2509.       current_file_path_ok:
  2510.         mov     esi,[esp+4]
  2511.         call    expand_path
  2512.         pop     edx
  2513.         mov     esi,edx
  2514.         call    open
  2515.         jnc     include_path_ok
  2516.         mov     ebp,[include_paths]
  2517.       try_include_directories:
  2518.         mov     edi,esi
  2519.         mov     esi,ebp
  2520.         cmp     byte [esi],0
  2521.         je      try_in_current_directory
  2522.         push    ebp
  2523.         push    edi
  2524.         call    get_include_directory
  2525.         mov     [esp+4],esi
  2526.         mov     esi,[esp+8]
  2527.         call    expand_path
  2528.         pop     edx
  2529.         mov     esi,edx
  2530.         call    open
  2531.         pop     ebp
  2532.         jnc     include_path_ok
  2533.         jmp     try_include_directories
  2534.         mov     edi,esi
  2535.       try_in_current_directory:
  2536.         mov     esi,[esp]
  2537.         push    edi
  2538.         call    expand_path
  2539.         pop     edx
  2540.         mov     esi,edx
  2541.         call    open
  2542.         jc      file_not_found
  2543.       include_path_ok:
  2544.         mov     edi,[esp]
  2545.       copy_preprocessed_path:
  2546.         lods    byte [esi]
  2547.         stos    byte [edi]
  2548.         or      al,al
  2549.         jnz     copy_preprocessed_path
  2550.         pop     esi
  2551.         lea     ecx,[edi-1]
  2552.         sub     ecx,esi
  2553.         mov     [esi-4],ecx
  2554.         push    dword [macro_status]
  2555.         and     [macro_status],0Fh
  2556.         call    preprocess_file
  2557.         pop     eax
  2558.         and     al,0F0h
  2559.         and     [macro_status],0Fh
  2560.         or      [macro_status],al
  2561.         jmp     line_preprocessed
  2562.