Subversion Repositories Kolibri OS

Rev

Rev 109 | Go to most recent revision | Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2006, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. convert_expression:
  7.         push    ebp
  8.         call    get_fp_value
  9.         jnc     fp_expression
  10.         mov     [current_offset],esp
  11.       expression_loop:
  12.         push    edi
  13.         mov     edi,single_operand_operators
  14.         call    get_operator
  15.         pop     edi
  16.         or      al,al
  17.         jz      expression_element
  18.         push    eax
  19.         jmp     expression_loop
  20.       expression_element:
  21.         mov     al,[esi]
  22.         cmp     al,1Ah
  23.         je      expression_number
  24.         cmp     al,22h
  25.         je      expression_number
  26.         cmp     al,'('
  27.         je      expression_number
  28.         mov     al,'!'
  29.         stos    byte [edi]
  30.         jmp     expression_operator
  31.       expression_number:
  32.         call    convert_number
  33.       expression_operator:
  34.         push    edi
  35.         mov     edi,operators
  36.         call    get_operator
  37.         pop     edi
  38.         or      al,al
  39.         jz      expression_end
  40.       operators_loop:
  41.         cmp     esp,[current_offset]
  42.         je      push_operator
  43.         mov     bl,al
  44.         and     bl,0F0h
  45.         mov     bh,byte [esp]
  46.         and     bh,0F0h
  47.         cmp     bl,bh
  48.         ja      push_operator
  49.         pop     ebx
  50.         mov     byte [edi],bl
  51.         inc     edi
  52.         jmp     operators_loop
  53.       push_operator:
  54.         push    eax
  55.         jmp     expression_loop
  56.       expression_end:
  57.         cmp     esp,[current_offset]
  58.         je      expression_converted
  59.         pop     eax
  60.         stos    byte [edi]
  61.         jmp     expression_end
  62.       expression_converted:
  63.         pop     ebp
  64.         ret
  65.       fp_expression:
  66.         mov     al,'.'
  67.         stos    byte [edi]
  68.         mov     eax,[fp_value]
  69.         stos    dword [edi]
  70.         mov     eax,[fp_value+4]
  71.         stos    dword [edi]
  72.         mov     eax,[fp_value+8]
  73.         stos    dword [edi]
  74.         pop     ebp
  75.         ret
  76.  
  77. convert_number:
  78.         lea     eax,[edi-10h]
  79.         cmp     eax,[labels_list]
  80.         jae     out_of_memory
  81.         cmp     byte [esi],'('
  82.         je      expression_value
  83.         inc     edi
  84.         call    get_number
  85.         jc      symbol_value
  86.         or      ebp,ebp
  87.         jz      valid_number
  88.         mov     byte [edi-1],0Fh
  89.         ret
  90.       valid_number:
  91.         cmp     dword [edi+4],0
  92.         jne     qword_number
  93.         cmp     word [edi+2],0
  94.         jne     dword_number
  95.         cmp     byte [edi+1],0
  96.         jne     word_number
  97.       byte_number:
  98.         mov     byte [edi-1],1
  99.         inc     edi
  100.         ret
  101.       qword_number:
  102.         mov     byte [edi-1],8
  103.         add     edi,8
  104.         ret
  105.       dword_number:
  106.         mov     byte [edi-1],4
  107.         scas    dword [edi]
  108.         ret
  109.       word_number:
  110.         mov     byte [edi-1],2
  111.         scas    word [edi]
  112.         ret
  113.       expression_value:
  114.         mov     eax,esp
  115.         sub     eax,100h
  116.         jc      stack_overflow
  117.         cmp     eax,[stack_limit]
  118.         jb      stack_overflow
  119.         inc     esi
  120.         push    [current_offset]
  121.         call    convert_expression
  122.         pop     [current_offset]
  123.         lods    byte [esi]
  124.         cmp     al,')'
  125.         jne     invalid_expression
  126.         ret
  127.       symbol_value:
  128.         push    edi
  129.         mov     edi,address_registers
  130.         call    get_operator
  131.         or      al,al
  132.         jnz     register_value
  133.         mov     edi,directive_operators
  134.         call    get_operator
  135.         pop     edi
  136.         or      al,al
  137.         jnz     broken_value
  138.         lods    byte [esi]
  139.         cmp     al,1Ah
  140.         jne     invalid_value
  141.         lods    byte [esi]
  142.         movzx   ecx,al
  143.         call    get_label_id
  144.       store_label_value:
  145.         mov     byte [edi-1],11h
  146.         stos    dword [edi]
  147.         ret
  148.       broken_value:
  149.         mov     eax,0Fh
  150.         jmp     store_label_value
  151.       register_value:
  152.         pop     edi
  153.         mov     byte [edi-1],10h
  154.         stos    byte [edi]
  155.         ret
  156.  
  157. get_number:
  158.         xor     ebp,ebp
  159.         lods    byte [esi]
  160.         cmp     al,22h
  161.         je      get_text_number
  162.         cmp     al,1Ah
  163.         jne     not_number
  164.         lods    byte [esi]
  165.         movzx   ecx,al
  166.         mov     [number_start],esi
  167.         mov     al,[esi]
  168.         cmp     al,'$'
  169.         je      number_begin
  170.         sub     al,30h
  171.         cmp     al,9
  172.         ja      invalid_number
  173.       number_begin:
  174.         mov     ebx,esi
  175.         add     esi,ecx
  176.         push    esi
  177.         dec     esi
  178.         mov     dword [edi],0
  179.         mov     dword [edi+4],0
  180.         cmp     byte [ebx],'$'
  181.         je      pascal_hex_number
  182.         cmp     word [ebx],'0x'
  183.         je      get_hex_number
  184.         mov     al,[esi]
  185.         dec     esi
  186.         cmp     al,'h'
  187.         je      get_hex_number
  188.         cmp     al,'b'
  189.         je      get_bin_number
  190.         cmp     al,'d'
  191.         je      get_dec_number
  192.         cmp     al,'o'
  193.         je      get_oct_number
  194.         cmp     al,'H'
  195.         je      get_hex_number
  196.         cmp     al,'B'
  197.         je      get_bin_number
  198.         cmp     al,'D'
  199.         je      get_dec_number
  200.         cmp     al,'O'
  201.         je      get_oct_number
  202.         inc     esi
  203.       get_dec_number:
  204.         mov     ebx,esi
  205.         mov     esi,[number_start]
  206.       get_dec_digit:
  207.         cmp     esi,ebx
  208.         ja      number_ok
  209.         xor     edx,edx
  210.         mov     eax,[edi]
  211.         shld    edx,eax,2
  212.         shl     eax,2
  213.         add     eax,[edi]
  214.         adc     edx,0
  215.         add     eax,eax
  216.         adc     edx,edx
  217.         mov     [edi],eax
  218.         mov     eax,[edi+4]
  219.         add     eax,eax
  220.         jc      dec_out_of_range
  221.         add     eax,eax
  222.         jc      dec_out_of_range
  223.         add     eax,[edi+4]
  224.         jc      dec_out_of_range
  225.         add     eax,eax
  226.         jc      dec_out_of_range
  227.         add     eax,edx
  228.         jc      dec_out_of_range
  229.         mov     [edi+4],eax
  230.         movzx   eax,byte [esi]
  231.         sub     al,30h
  232.         cmp     al,9
  233.         ja      bad_number
  234.         add     [edi],eax
  235.         adc     dword [edi+4],0
  236.         jc      dec_out_of_range
  237.         inc     esi
  238.         jmp     get_dec_digit
  239.       dec_out_of_range:
  240.         or      ebp,-1
  241.         inc     esi
  242.         jmp     get_dec_digit
  243.       bad_number:
  244.         pop     eax
  245.       invalid_number:
  246.         mov     esi,[number_start]
  247.         dec     esi
  248.       not_number:
  249.         dec     esi
  250.         stc
  251.         ret
  252.       get_bin_number:
  253.         xor     bl,bl
  254.       get_bin_digit:
  255.         cmp     esi,[number_start]
  256.         jb      number_ok
  257.         movzx   eax,byte [esi]
  258.         sub     al,30h
  259.         cmp     al,1
  260.         ja      bad_number
  261.         xor     edx,edx
  262.         mov     cl,bl
  263.         dec     esi
  264.         cmp     bl,64
  265.         je      bin_out_of_range
  266.         inc     bl
  267.         cmp     cl,32
  268.         jae     bin_digit_high
  269.         shl     eax,cl
  270.         or      dword [edi],eax
  271.         jmp     get_bin_digit
  272.       bin_digit_high:
  273.         sub     cl,32
  274.         shl     eax,cl
  275.         or      dword [edi+4],eax
  276.         jmp     get_bin_digit
  277.       bin_out_of_range:
  278.         or      al,al
  279.         jz      get_bin_digit
  280.         or      ebp,-1
  281.         jmp     get_bin_digit
  282.       pascal_hex_number:
  283.         cmp     cl,1
  284.         je      bad_number
  285.       get_hex_number:
  286.         xor     bl,bl
  287.       get_hex_digit:
  288.         cmp     esi,[number_start]
  289.         jb      number_ok
  290.         movzx   eax,byte [esi]
  291.         cmp     al,'x'
  292.         je      hex_number_ok
  293.         cmp     al,'$'
  294.         je      pascal_hex_ok
  295.         sub     al,30h
  296.         cmp     al,9
  297.         jbe     hex_digit_ok
  298.         sub     al,7
  299.         cmp     al,15
  300.         jbe     hex_letter_digit_ok
  301.         sub     al,20h
  302.         cmp     al,15
  303.         ja      bad_number
  304.       hex_letter_digit_ok:
  305.         cmp     al,10
  306.         jb      bad_number
  307.       hex_digit_ok:
  308.         xor     edx,edx
  309.         mov     cl,bl
  310.         dec     esi
  311.         cmp     bl,64
  312.         je      hex_out_of_range
  313.         add     bl,4
  314.         cmp     cl,32
  315.         jae     hex_digit_high
  316.         shl     eax,cl
  317.         or      dword [edi],eax
  318.         jmp     get_hex_digit
  319.       hex_digit_high:
  320.         sub     cl,32
  321.         shl     eax,cl
  322.         or      dword [edi+4],eax
  323.         jmp     get_hex_digit
  324.       hex_out_of_range:
  325.         or      al,al
  326.         jz      get_hex_digit
  327.         or      ebp,-1
  328.         jmp     get_hex_digit
  329.       get_oct_number:
  330.         xor     bl,bl
  331.       get_oct_digit:
  332.         cmp     esi,[number_start]
  333.         jb      number_ok
  334.         movzx   eax,byte [esi]
  335.         sub     al,30h
  336.         cmp     al,7
  337.         ja      bad_number
  338.       oct_digit_ok:
  339.         xor     edx,edx
  340.         mov     cl,bl
  341.         dec     esi
  342.         cmp     bl,64
  343.         jae     oct_out_of_range
  344.         add     bl,3
  345.         cmp     cl,30
  346.         je      oct_digit_wrap
  347.         ja      oct_digit_high
  348.         shl     eax,cl
  349.         or      dword [edi],eax
  350.         jmp     get_oct_digit
  351.       oct_digit_wrap:
  352.         shl     eax,cl
  353.         adc     dword [edi+4],0
  354.         or      dword [edi],eax
  355.         jmp     get_oct_digit
  356.       oct_digit_high:
  357.         sub     cl,32
  358.         shl     eax,cl
  359.         or      dword [edi+4],eax
  360.         jmp     get_oct_digit
  361.       oct_out_of_range:
  362.         or      al,al
  363.         jz      get_oct_digit
  364.         or      ebp,-1
  365.         jmp     get_oct_digit
  366.       hex_number_ok:
  367.         dec     esi
  368.       pascal_hex_ok:
  369.         cmp     esi,[number_start]
  370.         jne     bad_number
  371.       number_ok:
  372.         pop     esi
  373.       number_done:
  374.         clc
  375.         ret
  376.       get_text_number:
  377.         lods    dword [esi]
  378.         mov     edx,eax
  379.         xor     bl,bl
  380.         mov     dword [edi],0
  381.         mov     dword [edi+4],0
  382.       get_text_character:
  383.         sub     edx,1
  384.         jc      number_done
  385.         movzx   eax,byte [esi]
  386.         inc     esi
  387.         mov     cl,bl
  388.         cmp     bl,64
  389.         je      text_out_of_range
  390.         add     bl,8
  391.         cmp     cl,32
  392.         jae     text_character_high
  393.         shl     eax,cl
  394.         or      dword [edi],eax
  395.         jmp     get_text_character
  396.       text_character_high:
  397.         sub     cl,32
  398.         shl     eax,cl
  399.         or      dword [edi+4],eax
  400.         jmp     get_text_character
  401.       text_out_of_range:
  402.         or      ebp,-1
  403.         jmp     get_text_character
  404.  
  405. get_fp_value:
  406.         push    edi esi
  407.         lods    byte [esi]
  408.         cmp     al,1Ah
  409.         je      fp_value_start
  410.         cmp     al,'-'
  411.         je      fp_sign_ok
  412.         cmp     al,'+'
  413.         jne     not_fp_value
  414.       fp_sign_ok:
  415.         lods    byte [esi]
  416.         cmp     al,1Ah
  417.         jne     not_fp_value
  418.       fp_value_start:
  419.         lods    byte [esi]
  420.         movzx   ecx,al
  421.         cmp     cl,1
  422.         jbe     not_fp_value
  423.         lea     edx,[esi+1]
  424.         xor     ah,ah
  425.       check_fp_value:
  426.         lods    byte [esi]
  427.         cmp     al,'.'
  428.         je      fp_character_dot
  429.         cmp     al,'E'
  430.         je      fp_character_exp
  431.         cmp     al,'e'
  432.         je      fp_character_exp
  433.         cmp     al,'F'
  434.         je      fp_last_character
  435.         cmp     al,'f'
  436.         je      fp_last_character
  437.       digit_expected:
  438.         cmp     al,'0'
  439.         jb      not_fp_value
  440.         cmp     al,'9'
  441.         ja      not_fp_value
  442.         jmp     fp_character_ok
  443.       fp_character_dot:
  444.         cmp     esi,edx
  445.         je      not_fp_value
  446.         or      ah,ah
  447.         jnz     not_fp_value
  448.         or      ah,1
  449.         lods    byte [esi]
  450.         loop    digit_expected
  451.       not_fp_value:
  452.         pop     esi edi
  453.         stc
  454.         ret
  455.       fp_last_character:
  456.         cmp     cl,1
  457.         jne     not_fp_value
  458.         or      ah,4
  459.         jmp     fp_character_ok
  460.       fp_character_exp:
  461.         cmp     esi,edx
  462.         je      not_fp_value
  463.         cmp     ah,1
  464.         ja      not_fp_value
  465.         or      ah,2
  466.         cmp     ecx,1
  467.         jne     fp_character_ok
  468.         cmp     byte [esi],'+'
  469.         je      fp_exp_sign
  470.         cmp     byte [esi],'-'
  471.         jne     fp_character_ok
  472.       fp_exp_sign:
  473.         inc     esi
  474.         cmp     byte [esi],1Ah
  475.         jne     not_fp_value
  476.         inc     esi
  477.         lods    byte [esi]
  478.         movzx   ecx,al
  479.         inc     ecx
  480.       fp_character_ok:
  481.         dec     ecx
  482.         jnz     check_fp_value
  483.         or      ah,ah
  484.         jz      not_fp_value
  485.         pop     esi
  486.         lods    byte [esi]
  487.         mov     [fp_sign],0
  488.         cmp     al,1Ah
  489.         je      fp_get
  490.         inc     esi
  491.         cmp     al,'+'
  492.         je      fp_get
  493.         mov     [fp_sign],1
  494.       fp_get:
  495.         lods    byte [esi]
  496.         movzx   ecx,al
  497.         xor     edx,edx
  498.         mov     edi,fp_value
  499.         mov     [edi],edx
  500.         mov     [edi+4],edx
  501.         mov     [edi+12],edx
  502.         call    fp_optimize
  503.         mov     [fp_format],0
  504.         mov     al,[esi]
  505.       fp_before_dot:
  506.         lods    byte [esi]
  507.         cmp     al,'.'
  508.         je      fp_dot
  509.         cmp     al,'E'
  510.         je      fp_exponent
  511.         cmp     al,'e'
  512.         je      fp_exponent
  513.         cmp     al,'F'
  514.         je      fp_done
  515.         cmp     al,'f'
  516.         je      fp_done
  517.         sub     al,30h
  518.         mov     edi,fp_value+16
  519.         xor     edx,edx
  520.         mov     dword [edi+12],edx
  521.         mov     dword [edi],edx
  522.         mov     dword [edi+4],edx
  523.         mov     [edi+7],al
  524.         mov     dl,7
  525.         mov     dword [edi+8],edx
  526.         call    fp_optimize
  527.         mov     edi,fp_value
  528.         push    ecx
  529.         mov     ecx,10
  530.         call    fp_mul
  531.         pop     ecx
  532.         mov     ebx,fp_value+16
  533.         call    fp_add
  534.         loop    fp_before_dot
  535.       fp_dot:
  536.         mov     edi,fp_value+16
  537.         xor     edx,edx
  538.         mov     [edi],edx
  539.         mov     [edi+4],edx
  540.         mov     byte [edi+7],80h
  541.         mov     [edi+8],edx
  542.         mov     dword [edi+12],edx
  543.         dec     ecx
  544.         jz      fp_done
  545.       fp_after_dot:
  546.         lods    byte [esi]
  547.         cmp     al,'E'
  548.         je      fp_exponent
  549.         cmp     al,'e'
  550.         je      fp_exponent
  551.         cmp     al,'F'
  552.         je      fp_done
  553.         cmp     al,'f'
  554.         je      fp_done
  555.         inc     [fp_format]
  556.         cmp     [fp_format],80h
  557.         jne     fp_counter_ok
  558.         mov     [fp_format],7Fh
  559.       fp_counter_ok:
  560.         dec     esi
  561.         mov     edi,fp_value+16
  562.         push    ecx
  563.         mov     ecx,10
  564.         call    fp_div
  565.         push    dword [edi]
  566.         push    dword [edi+4]
  567.         push    dword [edi+8]
  568.         push    dword [edi+12]
  569.         lods    byte [esi]
  570.         sub     al,30h
  571.         movzx   ecx,al
  572.         call    fp_mul
  573.         mov     ebx,edi
  574.         mov     edi,fp_value
  575.         call    fp_add
  576.         mov     edi,fp_value+16
  577.         pop     dword [edi+12]
  578.         pop     dword [edi+8]
  579.         pop     dword [edi+4]
  580.         pop     dword [edi]
  581.         pop     ecx
  582.         loop    fp_after_dot
  583.         jmp     fp_done
  584.       fp_exponent:
  585.         or      [fp_format],80h
  586.         xor     edx,edx
  587.         xor     ebp,ebp
  588.         dec     ecx
  589.         jnz     get_exponent
  590.         cmp     byte [esi],'+'
  591.         je      fp_exponent_sign
  592.         cmp     byte [esi],'-'
  593.         jne     fp_done
  594.         not     ebp
  595.       fp_exponent_sign:
  596.         add     esi,2
  597.         lods    byte [esi]
  598.         movzx   ecx,al
  599.       get_exponent:
  600.         movzx   eax,byte [esi]
  601.         inc     esi
  602.         sub     al,30h
  603.         cmp     al,10
  604.         jae     exponent_ok
  605.         imul    edx,10
  606.         cmp     edx,8000h
  607.         jae     value_out_of_range
  608.         add     edx,eax
  609.         loop    get_exponent
  610.       exponent_ok:
  611.         mov     edi,fp_value
  612.         or      edx,edx
  613.         jz      fp_done
  614.         mov     ecx,edx
  615.         or      ebp,ebp
  616.         jnz     fp_negative_power
  617.       fp_power:
  618.         push    ecx
  619.         mov     ecx,10
  620.         call    fp_mul
  621.         pop     ecx
  622.         loop    fp_power
  623.         jmp     fp_done
  624.       fp_negative_power:
  625.         push    ecx
  626.         mov     ecx,10
  627.         call    fp_div
  628.         pop     ecx
  629.         loop    fp_negative_power
  630.       fp_done:
  631.         mov     edi,fp_value
  632.         mov     al,[fp_format]
  633.         mov     [edi+10],al
  634.         mov     al,[fp_sign]
  635.         mov     [edi+11],al
  636.         test    byte [edi+15],80h
  637.         jz      fp_ok
  638.         add     dword [edi],1
  639.         adc     dword [edi+4],0
  640.         jnc     fp_ok
  641.         mov     eax,[edi+4]
  642.         shrd    [edi],eax,1
  643.         shr     eax,1
  644.         or      eax,80000000h
  645.         mov     [edi+4],eax
  646.         inc     word [edi+8]
  647.       fp_ok:
  648.         pop     edi
  649.         clc
  650.         ret
  651.       fp_mul:
  652.         or      ecx,ecx
  653.         jz      fp_zero
  654.         mov     eax,[edi+12]
  655.         mul     ecx
  656.         mov     [edi+12],eax
  657.         mov     ebx,edx
  658.         mov     eax,[edi]
  659.         mul     ecx
  660.         add     eax,ebx
  661.         adc     edx,0
  662.         mov     [edi],eax
  663.         mov     ebx,edx
  664.         mov     eax,[edi+4]
  665.         mul     ecx
  666.         add     eax,ebx
  667.         adc     edx,0
  668.         mov     [edi+4],eax
  669.       .loop:
  670.         or      edx,edx
  671.         jz      .done
  672.         mov     eax,[edi]
  673.         shrd    [edi+12],eax,1
  674.         mov     eax,[edi+4]
  675.         shrd    [edi],eax,1
  676.         shrd    eax,edx,1
  677.         mov     [edi+4],eax
  678.         shr     edx,1
  679.         inc     dword [edi+8]
  680.         cmp     dword [edi+8],8000h
  681.         jge     value_out_of_range
  682.         jmp     .loop
  683.       .done:
  684.         ret
  685.       fp_div:
  686.         mov     eax,[edi+4]
  687.         xor     edx,edx
  688.         div     ecx
  689.         mov     [edi+4],eax
  690.         mov     eax,[edi]
  691.         div     ecx
  692.         mov     [edi],eax
  693.         mov     eax,[edi+12]
  694.         div     ecx
  695.         mov     [edi+12],eax
  696.         mov     ebx,eax
  697.         or      ebx,[edi]
  698.         or      ebx,[edi+4]
  699.         jz      fp_zero
  700.       .loop:
  701.         test    byte [edi+7],80h
  702.         jnz     .exp_ok
  703.         mov     eax,[edi]
  704.         shld    [edi+4],eax,1
  705.         mov     eax,[edi+12]
  706.         shld    [edi],eax,1
  707.         add     eax,eax
  708.         mov     [edi+12],eax
  709.         dec     dword [edi+8]
  710.         add     edx,edx
  711.         jmp     .loop
  712.       .exp_ok:
  713.         mov     eax,edx
  714.         xor     edx,edx
  715.         div     ecx
  716.         add     [edi+12],eax
  717.         adc     dword [edi],0
  718.         adc     dword [edi+4],0
  719.         jnc     .done
  720.         mov     eax,[edi+4]
  721.         mov     ebx,[edi]
  722.         shrd    [edi],eax,1
  723.         shrd    [edi+12],ebx,1
  724.         shr     eax,1
  725.         or      eax,80000000h
  726.         mov     [edi+4],eax
  727.         inc     dword [edi+8]
  728.       .done:
  729.         ret
  730.       fp_add:
  731.         cmp     dword [ebx+8],8000h
  732.         je      .done
  733.         cmp     dword [edi+8],8000h
  734.         je      .copy
  735.         mov     eax,[ebx+8]
  736.         cmp     eax,[edi+8]
  737.         jge     .exp_ok
  738.         mov     eax,[edi+8]
  739.       .exp_ok:
  740.         call    .change_exp
  741.         xchg    ebx,edi
  742.         call    .change_exp
  743.         xchg    ebx,edi
  744.         mov     edx,[ebx+12]
  745.         mov     eax,[ebx]
  746.         mov     ebx,[ebx+4]
  747.         add     [edi+12],edx
  748.         adc     [edi],eax
  749.         adc     [edi+4],ebx
  750.         jnc     .done
  751.         mov     eax,[edi]
  752.         shrd    [edi+12],eax,1
  753.         mov     eax,[edi+4]
  754.         shrd    [edi],eax,1
  755.         shr     eax,1
  756.         or      eax,80000000h
  757.         mov     [edi+4],eax
  758.         inc     dword [edi+8]
  759.       .done:
  760.         ret
  761.       .copy:
  762.         mov     eax,[ebx]
  763.         mov     [edi],eax
  764.         mov     eax,[ebx+4]
  765.         mov     [edi+4],eax
  766.         mov     eax,[ebx+8]
  767.         mov     [edi+8],eax
  768.         mov     eax,[ebx+12]
  769.         mov     [edi+12],eax
  770.         ret
  771.       .change_exp:
  772.         push    ecx
  773.         mov     ecx,eax
  774.         sub     ecx,[ebx+8]
  775.         mov     edx,[ebx+4]
  776.         jecxz   .exp_done
  777.       .exp_loop:
  778.         mov     ebp,[ebx]
  779.         shrd    [ebx+12],ebp,1
  780.         shrd    [ebx],edx,1
  781.         shr     edx,1
  782.         inc     dword [ebx+8]
  783.         loop    .exp_loop
  784.       .exp_done:
  785.         mov     [ebx+4],edx
  786.         pop     ecx
  787.         ret
  788.       fp_optimize:
  789.         mov     eax,[edi]
  790.         mov     ebp,[edi+4]
  791.         or      ebp,[edi]
  792.         or      ebp,[edi+12]
  793.         jz      fp_zero
  794.       .loop:
  795.         test    byte [edi+7],80h
  796.         jnz     .done
  797.         shld    [edi+4],eax,1
  798.         mov     ebp,[edi+12]
  799.         shld    eax,ebp,1
  800.         mov     [edi],eax
  801.         shl     dword [edi+12],1
  802.         dec     dword [edi+8]
  803.         jmp     .loop
  804.       .done:
  805.         ret
  806.       fp_zero:
  807.         mov     dword [edi+8],8000h
  808.         ret
  809.  
  810. calculate_expression:
  811.         mov     [current_offset],edi
  812.         mov     [value_undefined],0
  813.         cmp     byte [esi],0
  814.         je      get_string_value
  815.         cmp     byte [esi],'.'
  816.         je      convert_fp
  817.       calculation_loop:
  818.         lods    byte [esi]
  819.         cmp     al,1
  820.         je      get_byte_number
  821.         cmp     al,2
  822.         je      get_word_number
  823.         cmp     al,4
  824.         je      get_dword_number
  825.         cmp     al,8
  826.         je      get_qword_number
  827.         cmp     al,0Fh
  828.         je      value_out_of_range
  829.         cmp     al,10h
  830.         je      get_register
  831.         cmp     al,11h
  832.         je      get_label
  833.         cmp     al,')'
  834.         je      expression_calculated
  835.         cmp     al,']'
  836.         je      expression_calculated
  837.         cmp     al,'!'
  838.         je      invalid_expression
  839.         sub     edi,14h
  840.         mov     ebx,edi
  841.         sub     ebx,14h
  842.         cmp     al,0E0h
  843.         je      calculate_rva
  844.         cmp     al,0D0h
  845.         je      calculate_not
  846.         cmp     al,083h
  847.         je      calculate_neg
  848.         mov     dx,[ebx+8]
  849.         or      dx,[edi+8]
  850.         cmp     al,80h
  851.         je      calculate_add
  852.         cmp     al,81h
  853.         je      calculate_sub
  854.         mov     ah,[ebx+12]
  855.         or      ah,[edi+12]
  856.         jz      absolute_values_calculation
  857.         cmp     [error_line],0
  858.         jne     absolute_values_calculation
  859.         mov     eax,[current_line]
  860.         mov     [error_line],eax
  861.         mov     [error],invalid_use_of_symbol
  862.       absolute_values_calculation:
  863.         cmp     al,90h
  864.         je      calculate_mul
  865.         cmp     al,91h
  866.         je      calculate_div
  867.         or      dx,dx
  868.         jnz     invalid_expression
  869.         cmp     al,0A0h
  870.         je      calculate_mod
  871.         cmp     al,0B0h
  872.         je      calculate_and
  873.         cmp     al,0B1h
  874.         je      calculate_or
  875.         cmp     al,0B2h
  876.         je      calculate_xor
  877.         cmp     al,0C0h
  878.         je      calculate_shl
  879.         cmp     al,0C1h
  880.         je      calculate_shr
  881.         jmp     invalid_expression
  882.       expression_calculated:
  883.         sub     edi,14h
  884.         cmp     [value_undefined],0
  885.         je      expression_value_ok
  886.         xor     eax,eax
  887.         mov     [edi],eax
  888.         mov     [edi+4],eax
  889.         mov     [edi+12],al
  890.       expression_value_ok:
  891.         ret
  892.       get_byte_number:
  893.         mov     word [edi+8],0
  894.         mov     byte [edi+12],0
  895.         xor     eax,eax
  896.         lods    byte [esi]
  897.         stos    dword [edi]
  898.         xor     al,al
  899.         stos    dword [edi]
  900.         add     edi,0Ch
  901.         jmp     calculation_loop
  902.       get_word_number:
  903.         mov     word [edi+8],0
  904.         mov     byte [edi+12],0
  905.         xor     eax,eax
  906.         lods    word [esi]
  907.         stos    dword [edi]
  908.         xor     ax,ax
  909.         stos    dword [edi]
  910.         add     edi,0Ch
  911.         jmp     calculation_loop
  912.       get_dword_number:
  913.         mov     word [edi+8],0
  914.         mov     byte [edi+12],0
  915.         movs    dword [edi],[esi]
  916.         xor     eax,eax
  917.         stos    dword [edi]
  918.         add     edi,0Ch
  919.         jmp     calculation_loop
  920.       get_qword_number:
  921.         mov     word [edi+8],0
  922.         mov     byte [edi+12],0
  923.         movs    dword [edi],[esi]
  924.         movs    dword [edi],[esi]
  925.         add     edi,0Ch
  926.         jmp     calculation_loop
  927.       get_register:
  928.         mov     byte [edi+9],0
  929.         mov     byte [edi+12],0
  930.         lods    byte [esi]
  931.         mov     [edi+8],al
  932.         mov     byte [edi+10],1
  933.         xor     eax,eax
  934.         stos    dword [edi]
  935.         stos    dword [edi]
  936.         add     edi,0Ch
  937.         jmp     calculation_loop
  938.       get_label:
  939.         xor     eax,eax
  940.         mov     [edi+8],eax
  941.         mov     [edi+12],al
  942.         mov     [edi+20],eax
  943.         lods    dword [esi]
  944.         cmp     eax,0Fh
  945.         jb      predefined_label
  946.         je      reserved_word_used_as_symbol
  947.         mov     ebx,eax
  948.         mov     ax,[current_pass]
  949.         mov     [ebx+18],ax
  950.         or      byte [ebx+8],8
  951.         test    byte [ebx+8],1
  952.         jz      label_undefined
  953.         cmp     ax,[ebx+16]
  954.         je      label_defined
  955.         test    byte [ebx+8],4
  956.         jnz     label_undefined
  957.         test    byte [ebx+9],1
  958.         jz      label_defined
  959.         mov     eax,[ebx]
  960.         sub     eax,dword [adjustment]
  961.         stos    dword [edi]
  962.         mov     eax,[ebx+4]
  963.         sbb     eax,dword [adjustment+4]
  964.         stos    dword [edi]
  965.         mov     eax,dword [adjustment]
  966.         or      eax,dword [adjustment+4]
  967.         jz      got_label
  968.         or      [next_pass_needed],-1
  969.         jmp     got_label
  970.       label_defined:
  971.         mov     eax,[ebx]
  972.         stos    dword [edi]
  973.         mov     eax,[ebx+4]
  974.         stos    dword [edi]
  975.       got_label:
  976.         mov     al,[ebx+11]
  977.         mov     [edi-8+12],al
  978.         mov     eax,[ebx+12]
  979.         mov     [edi-8+8],eax
  980.         mov     eax,[ebx+20]
  981.         mov     [edi-8+16],eax
  982.         add     edi,0Ch
  983.         mov     al,[ebx+10]
  984.         or      al,al
  985.         jz      calculation_loop
  986.         cmp     [size_override],-1
  987.         je      calculation_loop
  988.         cmp     [size_override],0
  989.         je      check_size
  990.         cmp     [operand_size],0
  991.         jne     calculation_loop
  992.         mov     [operand_size],al
  993.         jmp     calculation_loop
  994.       check_size:
  995.         xchg    [operand_size],al
  996.         or      al,al
  997.         jz      calculation_loop
  998.         cmp     al,[operand_size]
  999.         jne     operand_sizes_do_not_match
  1000.         jmp     calculation_loop
  1001.       current_offset_label:
  1002.         mov     al,[labels_type]
  1003.         mov     [edi+12],al
  1004.         mov     eax,[org_symbol]
  1005.         mov     [edi+16],eax
  1006.         mov     eax,[current_offset]
  1007.         xor     edx,edx
  1008.         sub     eax,dword [org_origin]
  1009.         sbb     edx,dword [org_origin+4]
  1010.         stos    dword [edi]
  1011.         mov     eax,edx
  1012.         stos    dword [edi]
  1013.         mov     eax,[org_registers]
  1014.         stos    dword [edi]
  1015.         add     edi,8
  1016.         jmp     calculation_loop
  1017.       org_origin_label:
  1018.         mov     al,[labels_type]
  1019.         mov     [edi+12],al
  1020.         mov     eax,[org_symbol]
  1021.         mov     [edi+16],eax
  1022.         mov     eax,[org_start]
  1023.         xor     edx,edx
  1024.         sub     eax,dword [org_origin]
  1025.         sbb     edx,dword [org_origin+4]
  1026.         stos    dword [edi]
  1027.         mov     eax,edx
  1028.         stos    dword [edi]
  1029.         mov     eax,[org_registers]
  1030.         stos    dword [edi]
  1031.         add     edi,8
  1032.         jmp     calculation_loop
  1033.       counter_label:
  1034.         mov     eax,[counter]
  1035.       make_dword_label_value:
  1036.         stos    dword [edi]
  1037.         xor     eax,eax
  1038.         stos    dword [edi]
  1039.         add     edi,0Ch
  1040.         jmp     calculation_loop
  1041.       timestamp_label:
  1042.         call    make_timestamp
  1043.         jmp     make_dword_label_value
  1044.       predefined_label:
  1045.         or      eax,eax
  1046.         jz      current_offset_label
  1047.         cmp     eax,1
  1048.         je      counter_label
  1049.         cmp     eax,2
  1050.         je      timestamp_label
  1051.         cmp     eax,3
  1052.         je      org_origin_label
  1053.       label_undefined:
  1054.         cmp     [current_pass],1
  1055.         ja      undefined_value
  1056.       force_next_pass:
  1057.         or      [next_pass_needed],-1
  1058.       undefined_value:
  1059.         mov     byte [edi+12],0
  1060.         or      [value_undefined],-1
  1061.         xor     eax,eax
  1062.         stos    dword [edi]
  1063.         stos    dword [edi]
  1064.         add     edi,0Ch
  1065.         cmp     [error_line],0
  1066.         jne     calculation_loop
  1067.         mov     eax,[current_line]
  1068.         mov     [error_line],eax
  1069.         mov     [error],undefined_symbol
  1070.         jmp     calculation_loop
  1071.       calculate_add:
  1072.         mov     ecx,[ebx+16]
  1073.         cmp     byte [edi+12],0
  1074.         je      add_values
  1075.         mov     ecx,[edi+16]
  1076.         cmp     byte [ebx+12],0
  1077.         je      add_values
  1078.         cmp     [error_line],0
  1079.         jne     add_values
  1080.         mov     eax,[current_line]
  1081.         mov     [error_line],eax
  1082.         mov     [error],invalid_use_of_symbol
  1083.       add_values:
  1084.         mov     al,[edi+12]
  1085.         or      [ebx+12],al
  1086.         mov     [ebx+16],ecx
  1087.         mov     eax,[edi]
  1088.         add     [ebx],eax
  1089.         mov     eax,[edi+4]
  1090.         adc     [ebx+4],eax
  1091.         or      dx,dx
  1092.         jz      calculation_loop
  1093.         push    esi
  1094.         mov     esi,ebx
  1095.         lea     ebx,[edi+10]
  1096.         mov     cl,[edi+8]
  1097.         call    add_register
  1098.         lea     ebx,[edi+11]
  1099.         mov     cl,[edi+9]
  1100.         call    add_register
  1101.         pop     esi
  1102.         jmp     calculation_loop
  1103.       add_register:
  1104.         or      cl,cl
  1105.         jz      add_register_done
  1106.       add_register_start:
  1107.         cmp     [esi+8],cl
  1108.         jne     add_in_second_slot
  1109.         mov     al,[ebx]
  1110.         add     [esi+10],al
  1111.         jnz     add_register_done
  1112.         mov     byte [esi+8],0
  1113.         ret
  1114.       add_in_second_slot:
  1115.         cmp     [esi+9],cl
  1116.         jne     create_in_first_slot
  1117.         mov     al,[ebx]
  1118.         add     [esi+11],al
  1119.         jnz     add_register_done
  1120.         mov     byte [esi+9],0
  1121.         ret
  1122.       create_in_first_slot:
  1123.         cmp     byte [esi+8],0
  1124.         jne     create_in_second_slot
  1125.         mov     [esi+8],cl
  1126.         mov     al,[ebx]
  1127.         mov     [esi+10],al
  1128.         ret
  1129.       create_in_second_slot:
  1130.         cmp     byte [esi+9],0
  1131.         jne     invalid_expression
  1132.         mov     [esi+9],cl
  1133.         mov     al,[ebx]
  1134.         mov     [esi+11],al
  1135.       add_register_done:
  1136.         ret
  1137.       calculate_sub:
  1138.         xor     ah,ah
  1139.         mov     ah,[ebx+12]
  1140.         mov     al,[edi+12]
  1141.         or      al,al
  1142.         jz      sub_values
  1143.         cmp     al,ah
  1144.         jne     invalid_sub
  1145.         xor     ah,ah
  1146.         mov     ecx,[edi+16]
  1147.         cmp     ecx,[ebx+16]
  1148.         je      sub_values
  1149.         cmp     ecx,[org_symbol]
  1150.         jne     invalid_sub
  1151.         test    byte [ebx+12],1
  1152.         jnz     invalid_sub
  1153.         mov     ah,3
  1154.       sub_values:
  1155.         mov     [ebx+12],ah
  1156.         mov     eax,[edi]
  1157.         sub     [ebx],eax
  1158.         mov     eax,[edi+4]
  1159.         sbb     [ebx+4],eax
  1160.         or      dx,dx
  1161.         jz      calculation_loop
  1162.         push    esi
  1163.         mov     esi,ebx
  1164.         lea     ebx,[edi+10]
  1165.         mov     cl,[edi+8]
  1166.         call    sub_register
  1167.         lea     ebx,[edi+11]
  1168.         mov     cl,[edi+9]
  1169.         call    sub_register
  1170.         pop     esi
  1171.         jmp     calculation_loop
  1172.       invalid_sub:
  1173.         cmp     [error_line],0
  1174.         jne     sub_values
  1175.         mov     eax,[current_line]
  1176.         mov     [error_line],eax
  1177.         mov     [error],invalid_use_of_symbol
  1178.         jmp     sub_values
  1179.       sub_register:
  1180.         or      cl,cl
  1181.         jz      add_register_done
  1182.         neg     byte [ebx]
  1183.         jmp     add_register_start
  1184.       calculate_mul:
  1185.         or      dx,dx
  1186.         jz      mul_start
  1187.         cmp     word [ebx+8],0
  1188.         jne     mul_start
  1189.         mov     eax,[ebx]
  1190.         xchg    eax,[edi]
  1191.         mov     [ebx],eax
  1192.         mov     eax,[ebx+4]
  1193.         xchg    eax,[edi+4]
  1194.         mov     [ebx+4],eax
  1195.         mov     eax,[ebx+8]
  1196.         xchg    eax,[edi+8]
  1197.         mov     [ebx+8],eax
  1198.         mov     eax,[ebx+12]
  1199.         xchg    eax,[edi+12]
  1200.         mov     [ebx+12],eax
  1201.       mul_start:
  1202.         push    esi edx
  1203.         mov     esi,ebx
  1204.         xor     bl,bl
  1205.         bt      dword [esi+4],31
  1206.         jnc     mul_first_sign_ok
  1207.         not     dword [esi]
  1208.         not     dword [esi+4]
  1209.         add     dword [esi],1
  1210.         adc     dword [esi+4],0
  1211.         not     bl
  1212.       mul_first_sign_ok:
  1213.         bt      dword [edi+4],31
  1214.         jnc     mul_second_sign_ok
  1215.         not     dword [edi]
  1216.         not     dword [edi+4]
  1217.         add     dword [edi],1
  1218.         adc     dword [edi+4],0
  1219.         not     bl
  1220.       mul_second_sign_ok:
  1221.         cmp     dword [esi+4],0
  1222.         jz      mul_numbers
  1223.         cmp     dword [edi+4],0
  1224.         jnz     value_out_of_range
  1225.       mul_numbers:
  1226.         mov     eax,[esi+4]
  1227.         mul     dword [edi]
  1228.         or      edx,edx
  1229.         jnz     value_out_of_range
  1230.         mov     ecx,eax
  1231.         mov     eax,[esi]
  1232.         mul     dword [edi+4]
  1233.         or      edx,edx
  1234.         jnz     value_out_of_range
  1235.         add     ecx,eax
  1236.         jc      value_out_of_range
  1237.         mov     eax,[esi]
  1238.         mul     dword [edi]
  1239.         add     edx,ecx
  1240.         jc      value_out_of_range
  1241.         test    edx,1 shl 31
  1242.         jnz     value_out_of_range
  1243.         mov     [esi],eax
  1244.         mov     [esi+4],edx
  1245.         or      bl,bl
  1246.         jz      mul_ok
  1247.         not     dword [esi]
  1248.         not     dword [esi+4]
  1249.         add     dword [esi],1
  1250.         adc     dword [esi+4],0
  1251.       mul_ok:
  1252.         pop     edx
  1253.         or      dx,dx
  1254.         jz      mul_calculated
  1255.         cmp     word [edi+8],0
  1256.         jne     invalid_value
  1257.         cmp     byte [esi+8],0
  1258.         je      mul_first_register_ok
  1259.         mov     al,[edi]
  1260.         cbw
  1261.         cwde
  1262.         cdq
  1263.         cmp     edx,[edi+4]
  1264.         jne     value_out_of_range
  1265.         cmp     eax,[edi]
  1266.         jne     value_out_of_range
  1267.         imul    byte [esi+10]
  1268.         mov     dl,ah
  1269.         cbw
  1270.         cmp     ah,dl
  1271.         jne     value_out_of_range
  1272.         mov     [esi+10],al
  1273.       mul_first_register_ok:
  1274.         cmp     byte [esi+9],0
  1275.         je      mul_calculated
  1276.         mov     al,[edi]
  1277.         cbw
  1278.         cwde
  1279.         cdq
  1280.         cmp     edx,[edi+4]
  1281.         jne     value_out_of_range
  1282.         cmp     eax,[edi]
  1283.         jne     value_out_of_range
  1284.         imul    byte [esi+11]
  1285.         mov     dl,ah
  1286.         cbw
  1287.         cmp     ah,dl
  1288.         jne     value_out_of_range
  1289.         mov     [esi+11],al
  1290.       mul_calculated:
  1291.         pop     esi
  1292.         jmp     calculation_loop
  1293.       calculate_div:
  1294.         push    esi edx
  1295.         mov     esi,ebx
  1296.         call    div_64
  1297.         pop     edx
  1298.         or      dx,dx
  1299.         jz      div_calculated
  1300.         cmp     byte [esi+8],0
  1301.         je      div_first_register_ok
  1302.         mov     al,[edi]
  1303.         cbw
  1304.         cwde
  1305.         cdq
  1306.         cmp     edx,[edi+4]
  1307.         jne     value_out_of_range
  1308.         cmp     eax,[edi]
  1309.         jne     value_out_of_range
  1310.         or      al,al
  1311.         jz      value_out_of_range
  1312.         mov     al,[esi+10]
  1313.         cbw
  1314.         idiv    byte [edi]
  1315.         or      ah,ah
  1316.         jnz     invalid_use_of_symbol
  1317.         mov     [esi+10],al
  1318.       div_first_register_ok:
  1319.         cmp     byte [esi+9],0
  1320.         je      div_calculated
  1321.         mov     al,[edi]
  1322.         cbw
  1323.         cwde
  1324.         cdq
  1325.         cmp     edx,[edi+4]
  1326.         jne     value_out_of_range
  1327.         cmp     eax,[edi]
  1328.         jne     value_out_of_range
  1329.         or      al,al
  1330.         jz      value_out_of_range
  1331.         mov     al,[esi+11]
  1332.         cbw
  1333.         idiv    byte [edi]
  1334.         or      ah,ah
  1335.         jnz     invalid_use_of_symbol
  1336.         mov     [esi+11],al
  1337.       div_calculated:
  1338.         pop     esi
  1339.         jmp     calculation_loop
  1340.       calculate_mod:
  1341.         push    esi
  1342.         mov     esi,ebx
  1343.         call    div_64
  1344.         mov     [esi],eax
  1345.         mov     [esi+4],edx
  1346.         pop     esi
  1347.         jmp     calculation_loop
  1348.       calculate_and:
  1349.         mov     eax,[edi]
  1350.         and     [ebx],eax
  1351.         mov     eax,[edi+4]
  1352.         and     [ebx+4],eax
  1353.         jmp     calculation_loop
  1354.       calculate_or:
  1355.         mov     eax,[edi]
  1356.         or      [ebx],eax
  1357.         mov     eax,[edi+4]
  1358.         or      [ebx+4],eax
  1359.         jmp     calculation_loop
  1360.       calculate_xor:
  1361.         mov     eax,[edi]
  1362.         xor     [ebx],eax
  1363.         mov     eax,[edi+4]
  1364.         xor     [ebx+4],eax
  1365.         jmp     calculation_loop
  1366.       shr_negative:
  1367.         not     dword [edi]
  1368.         not     dword [edi+4]
  1369.         add     dword [edi],1
  1370.         adc     dword [edi+4],0
  1371.       calculate_shl:
  1372.         mov     eax,dword [edi+4]
  1373.         bt      eax,31
  1374.         jc      shl_negative
  1375.         or      eax,eax
  1376.         jnz     zero_value
  1377.         mov     ecx,[edi]
  1378.         cmp     ecx,64
  1379.         jae     zero_value
  1380.         cmp     ecx,32
  1381.         jae     shl_high
  1382.         mov     edx,[ebx+4]
  1383.         mov     eax,[ebx]
  1384.         shld    edx,eax,cl
  1385.         shl     eax,cl
  1386.         mov     [ebx],eax
  1387.         mov     [ebx+4],edx
  1388.         jmp     calculation_loop
  1389.       shl_high:
  1390.         sub     cl,32
  1391.         mov     eax,[ebx]
  1392.         shl     eax,cl
  1393.         mov     [ebx+4],eax
  1394.         mov     dword [ebx],0
  1395.         jmp     calculation_loop
  1396.       shl_negative:
  1397.         not     dword [edi]
  1398.         not     dword [edi+4]
  1399.         add     dword [edi],1
  1400.         adc     dword [edi+4],0
  1401.       calculate_shr:
  1402.         mov     eax,dword [edi+4]
  1403.         bt      eax,31
  1404.         jc      shr_negative
  1405.         or      eax,eax
  1406.         jnz     zero_value
  1407.         mov     ecx,[edi]
  1408.         cmp     ecx,64
  1409.         jae     zero_value
  1410.         cmp     ecx,32
  1411.         jae     shr_high
  1412.         mov     edx,[ebx+4]
  1413.         mov     eax,[ebx]
  1414.         shrd    eax,edx,cl
  1415.         shr     edx,cl
  1416.         mov     [ebx],eax
  1417.         mov     [ebx+4],edx
  1418.         jmp     calculation_loop
  1419.       shr_high:
  1420.         sub     cl,32
  1421.         mov     eax,[ebx+4]
  1422.         shr     eax,cl
  1423.         mov     [ebx],eax
  1424.         mov     dword [ebx+4],0
  1425.         jmp     calculation_loop
  1426.       zero_value:
  1427.         mov     dword [ebx],0
  1428.         mov     dword [ebx+4],0
  1429.         jmp     calculation_loop
  1430.       calculate_not:
  1431.         cmp     word [edi+8],0
  1432.         jne     invalid_expression
  1433.         cmp     byte [edi+12],0
  1434.         je      not_ok
  1435.         cmp     [error_line],0
  1436.         jne     not_ok
  1437.         mov     eax,[current_line]
  1438.         mov     [error_line],eax
  1439.         mov     [error],invalid_use_of_symbol
  1440.       not_ok:
  1441.         cmp     [value_size],1
  1442.         je      not_byte
  1443.         cmp     [value_size],2
  1444.         je      not_word
  1445.         cmp     [value_size],4
  1446.         je      not_dword
  1447.         cmp     [value_size],6
  1448.         je      not_pword
  1449.       not_qword:
  1450.         not     dword [edi]
  1451.         not     dword [edi+4]
  1452.         add     edi,14h
  1453.         jmp     calculation_loop
  1454.       not_byte:
  1455.         cmp     dword [edi+4],0
  1456.         jne     not_qword
  1457.         cmp     word [edi+2],0
  1458.         jne     not_qword
  1459.         cmp     byte [edi+1],0
  1460.         jne     not_qword
  1461.         not     byte [edi]
  1462.         add     edi,14h
  1463.         jmp     calculation_loop
  1464.       not_word:
  1465.         cmp     dword [edi+4],0
  1466.         jne     not_qword
  1467.         cmp     word [edi+2],0
  1468.         jne     not_qword
  1469.         not     word [edi]
  1470.         add     edi,14h
  1471.         jmp     calculation_loop
  1472.       not_dword:
  1473.         cmp     dword [edi+4],0
  1474.         jne     not_qword
  1475.         not     dword [edi]
  1476.         add     edi,14h
  1477.         jmp     calculation_loop
  1478.       not_pword:
  1479.         cmp     word [edi+6],0
  1480.         jne     not_qword
  1481.         not     dword [edi]
  1482.         not     word [edi+4]
  1483.         add     edi,14h
  1484.         jmp     calculation_loop
  1485.       calculate_neg:
  1486.         cmp     word [edi+8],0
  1487.         jne     invalid_expression
  1488.         cmp     byte [edi+12],0
  1489.         je      neg_ok
  1490.         cmp     [error_line],0
  1491.         jne     neg_ok
  1492.         mov     eax,[current_line]
  1493.         mov     [error_line],eax
  1494.         mov     [error],invalid_use_of_symbol
  1495.       neg_ok:
  1496.         mov     eax,[edi]
  1497.         mov     edx,[edi+4]
  1498.         mov     dword [edi],0
  1499.         mov     dword [edi+4],0
  1500.         sub     [edi],eax
  1501.         sbb     [edi+4],edx
  1502.         add     edi,14h
  1503.         jmp     calculation_loop
  1504.       calculate_rva:
  1505.         cmp     word [edi+8],0
  1506.         jne     invalid_expression
  1507.         cmp     [output_format],5
  1508.         je      calculate_gotoff
  1509.         cmp     [output_format],3
  1510.         jne     invalid_expression
  1511.         test    [format_flags],8
  1512.         jnz     pe64_rva
  1513.         mov     al,2
  1514.         bt      [resolver_flags],0
  1515.         jc      rva_type_ok
  1516.         xor     al,al
  1517.       rva_type_ok:
  1518.         cmp     byte [edi+12],al
  1519.         je      rva_ok
  1520.         cmp     [error_line],0
  1521.         jne     rva_ok
  1522.         mov     eax,[current_line]
  1523.         mov     [error_line],eax
  1524.         mov     [error],invalid_use_of_symbol
  1525.       rva_ok:
  1526.         mov     byte [edi+12],0
  1527.         mov     eax,[code_start]
  1528.         mov     eax,[eax+34h]
  1529.         cdq
  1530.         sub     [edi],eax
  1531.         sbb     [edi+4],edx
  1532.         add     edi,14h
  1533.         jmp     calculation_loop
  1534.       pe64_rva:
  1535.         mov     al,4
  1536.         bt      [resolver_flags],0
  1537.         jc      pe64_rva_type_ok
  1538.         xor     al,al
  1539.       pe64_rva_type_ok:
  1540.         cmp     byte [edi+12],al
  1541.         je      pe64_rva_ok
  1542.         cmp     [error_line],0
  1543.         jne     pe64_rva_ok
  1544.         mov     eax,[current_line]
  1545.         mov     [error_line],eax
  1546.         mov     [error],invalid_use_of_symbol
  1547.       pe64_rva_ok:
  1548.         mov     byte [edi+12],0
  1549.         mov     eax,[code_start]
  1550.         mov     edx,[eax+34h]
  1551.         mov     eax,[eax+30h]
  1552.         sub     [edi],eax
  1553.         sbb     [edi+4],edx
  1554.         add     edi,14h
  1555.         jmp     calculation_loop
  1556.       calculate_gotoff:
  1557.         test    [format_flags],8+1
  1558.         jnz     invalid_expression
  1559.         cmp     byte [edi+12],2
  1560.         je      gotoff_ok
  1561.         cmp     [error_line],0
  1562.         jne     pe64_rva_ok
  1563.         mov     eax,[current_line]
  1564.         mov     [error_line],eax
  1565.         mov     [error],invalid_use_of_symbol
  1566.       gotoff_ok:
  1567.         mov     byte [edi+12],5
  1568.         add     edi,14h
  1569.         jmp     calculation_loop
  1570.       div_64:
  1571.         xor     ebx,ebx
  1572.         cmp     dword [edi],0
  1573.         jne     divider_ok
  1574.         cmp     dword [edi+4],0
  1575.         jne     divider_ok
  1576.         cmp     [next_pass_needed],0
  1577.         je      value_out_of_range
  1578.         jmp     div_done
  1579.       divider_ok:
  1580.         bt      dword [esi+4],31
  1581.         jnc     div_first_sign_ok
  1582.         not     dword [esi]
  1583.         not     dword [esi+4]
  1584.         add     dword [esi],1
  1585.         adc     dword [esi+4],0
  1586.         not     bx
  1587.       div_first_sign_ok:
  1588.         bt      dword [edi+4],31
  1589.         jnc     div_second_sign_ok
  1590.         not     dword [edi]
  1591.         not     dword [edi+4]
  1592.         add     dword [edi],1
  1593.         adc     dword [edi+4],0
  1594.         not     bl
  1595.       div_second_sign_ok:
  1596.         cmp     dword [edi+4],0
  1597.         jne     div_high
  1598.         mov     ecx,[edi]
  1599.         mov     eax,[esi+4]
  1600.         xor     edx,edx
  1601.         div     ecx
  1602.         mov     [esi+4],eax
  1603.         mov     eax,[esi]
  1604.         div     ecx
  1605.         mov     [esi],eax
  1606.         mov     eax,edx
  1607.         xor     edx,edx
  1608.         jmp     div_done
  1609.       div_high:
  1610.         mov     eax,[esi+4]
  1611.         xor     edx,edx
  1612.         div     dword [edi+4]
  1613.         mov     ebx,[esi]
  1614.         mov     [esi],eax
  1615.         mov     dword [esi+4],0
  1616.         mov     ecx,edx
  1617.         mul     dword [edi]
  1618.       div_high_loop:
  1619.         cmp     ecx,edx
  1620.         ja      div_high_done
  1621.         jb      div_high_large_correction
  1622.         cmp     ebx,eax
  1623.         jae     div_high_done
  1624.       div_high_correction:
  1625.         dec     dword [esi]
  1626.         sub     eax,[edi]
  1627.         sbb     edx,[edi+4]
  1628.         jnc     div_high_loop
  1629.       div_high_done:
  1630.         sub     ebx,eax
  1631.         sbb     ecx,edx
  1632.         mov     edx,ecx
  1633.         mov     eax,ebx
  1634.         ret
  1635.       div_high_large_correction:
  1636.         push    eax edx
  1637.         mov     eax,edx
  1638.         sub     eax,ecx
  1639.         xor     edx,edx
  1640.         div     dword [edi+4]
  1641.         shr     eax,1
  1642.         jz      div_high_small_correction
  1643.         sub     [esi],eax
  1644.         push    eax
  1645.         mul     dword [edi+4]
  1646.         sub     dword [esp+4],eax
  1647.         pop     eax
  1648.         mul     dword [edi]
  1649.         sub     dword [esp+4],eax
  1650.         sbb     dword [esp],edx
  1651.         pop     edx eax
  1652.         jmp     div_high_loop
  1653.       div_high_small_correction:
  1654.         pop     edx eax
  1655.         jmp     div_high_correction
  1656.       div_done:
  1657.         or      bh,bh
  1658.         jz      remainder_ok
  1659.         not     eax
  1660.         not     edx
  1661.         add     eax,1
  1662.         adc     edx,0
  1663.       remainder_ok:
  1664.         or      bl,bl
  1665.         jz      div_ok
  1666.         not     dword [esi]
  1667.         not     dword [esi+4]
  1668.         add     dword [esi],1
  1669.         adc     dword [esi+4],0
  1670.       div_ok:
  1671.         ret
  1672.       convert_fp:
  1673.         inc     esi
  1674.         mov     word [edi+8],0
  1675.         mov     byte [edi+12],0
  1676.         mov     al,[value_size]
  1677.         cmp     al,4
  1678.         je      convert_fp_dword
  1679.         cmp     al,8
  1680.         je      convert_fp_qword
  1681.         jmp     invalid_value
  1682.       convert_fp_dword:
  1683.         xor     eax,eax
  1684.         cmp     word [esi+8],8000h
  1685.         je      fp_dword_store
  1686.         mov     bx,[esi+8]
  1687.         mov     eax,[esi+4]
  1688.         shl     eax,1
  1689.         shr     eax,9
  1690.         jnc     fp_dword_ok
  1691.         inc     eax
  1692.         bt      eax,23
  1693.         jnc     fp_dword_ok
  1694.         and     eax,1 shl 23 - 1
  1695.         inc     bx
  1696.         shr     eax,1
  1697.       fp_dword_ok:
  1698.         add     bx,7Fh
  1699.         cmp     bx,100h
  1700.         jae     value_out_of_range
  1701.         shl     ebx,23
  1702.         or      eax,ebx
  1703.       fp_dword_store:
  1704.         mov     bl,[esi+11]
  1705.         shl     ebx,31
  1706.         or      eax,ebx
  1707.         mov     [edi],eax
  1708.         xor     eax,eax
  1709.         mov     [edi+4],eax
  1710.         add     esi,13
  1711.         ret
  1712.       convert_fp_qword:
  1713.         xor     eax,eax
  1714.         xor     edx,edx
  1715.         cmp     word [esi+8],8000h
  1716.         je      fp_qword_store
  1717.         mov     bx,[esi+8]
  1718.         mov     eax,[esi]
  1719.         mov     edx,[esi+4]
  1720.         add     eax,eax
  1721.         adc     edx,edx
  1722.         mov     ecx,edx
  1723.         shr     edx,12
  1724.         shrd    eax,ecx,12
  1725.         jnc     fp_qword_ok
  1726.         add     eax,1
  1727.         adc     edx,0
  1728.         bt      edx,20
  1729.         jnc     fp_qword_ok
  1730.         and     edx,1 shl 20 - 1
  1731.         inc     bx
  1732.         shr     edx,1
  1733.         rcr     eax,1
  1734.       fp_qword_ok:
  1735.         add     bx,3FFh
  1736.         cmp     bx,800h
  1737.         jae     value_out_of_range
  1738.         shl     ebx,20
  1739.         or      edx,ebx
  1740.       fp_qword_store:
  1741.         mov     bl,[esi+11]
  1742.         shl     ebx,31
  1743.         or      edx,ebx
  1744.         mov     [edi],eax
  1745.         mov     [edi+4],edx
  1746.         add     esi,13
  1747.         ret
  1748.       get_string_value:
  1749.         inc     esi
  1750.         lods    dword [esi]
  1751.         mov     ecx,eax
  1752.         cmp     ecx,8
  1753.         ja      value_out_of_range
  1754.         mov     edx,edi
  1755.         xor     eax,eax
  1756.         stos    dword [edi]
  1757.         stos    dword [edi]
  1758.         mov     edi,edx
  1759.         rep     movs byte [edi],[esi]
  1760.         mov     edi,edx
  1761.         inc     esi
  1762.         mov     word [edi+8],0
  1763.         mov     byte [edi+12],0
  1764.         ret
  1765.  
  1766. get_byte_value:
  1767.         mov     [value_size],1
  1768.         mov     [size_override],-1
  1769.         call    calculate_expression
  1770.         mov     eax,[edi+16]
  1771.         mov     [symbol_identifier],eax
  1772.         mov     [value_type],0
  1773.         cmp     word [edi+8],0
  1774.         jne     invalid_value
  1775.         cmp     byte [edi+12],0
  1776.         je      check_byte_value
  1777.         cmp     [error_line],0
  1778.         jne     check_byte_value
  1779.         mov     eax,[current_line]
  1780.         mov     [error_line],eax
  1781.         mov     [error],invalid_use_of_symbol
  1782.       check_byte_value:
  1783.         mov     eax,[edi]
  1784.         mov     edx,[edi+4]
  1785.         or      edx,edx
  1786.         jz      byte_positive
  1787.         cmp     edx,-1
  1788.         jne     range_exceeded
  1789.         cmp     eax,-80h
  1790.         jb      range_exceeded
  1791.         ret
  1792.       byte_positive:
  1793.         cmp     eax,100h
  1794.         jae     range_exceeded
  1795.       return_byte_value:
  1796.         ret
  1797.       range_exceeded:
  1798.         xor     eax,eax
  1799.         xor     edx,edx
  1800.         cmp     [error_line],0
  1801.         jne     return_byte_value
  1802.         mov     ecx,[current_line]
  1803.         mov     [error_line],ecx
  1804.         mov     [error],value_out_of_range
  1805.         ret
  1806. get_word_value:
  1807.         mov     [value_size],2
  1808.         mov     [size_override],-1
  1809.         call    calculate_expression
  1810.         mov     eax,[edi+16]
  1811.         mov     [symbol_identifier],eax
  1812.         cmp     word [edi+8],0
  1813.         jne     invalid_value
  1814.         mov     al,[edi+12]
  1815.         mov     [value_type],al
  1816.         cmp     al,2
  1817.         jb      check_word_value
  1818.         cmp     [error_line],0
  1819.         jne     check_word_value
  1820.         mov     eax,[current_line]
  1821.         mov     [error_line],eax
  1822.         mov     [error],invalid_use_of_symbol
  1823.       check_word_value:
  1824.         mov     eax,[edi]
  1825.         mov     edx,[edi+4]
  1826.         or      edx,edx
  1827.         jz      word_positive
  1828.         cmp     edx,-1
  1829.         jne     range_exceeded
  1830.         cmp     eax,-8000h
  1831.         jb      range_exceeded
  1832.         ret
  1833.       word_positive:
  1834.         cmp     eax,10000h
  1835.         jae     range_exceeded
  1836.         ret
  1837. get_dword_value:
  1838.         mov     [value_size],4
  1839.         mov     [size_override],-1
  1840.         call    calculate_expression
  1841.         mov     eax,[edi+16]
  1842.         mov     [symbol_identifier],eax
  1843.         cmp     word [edi+8],0
  1844.         jne     invalid_value
  1845.         mov     al,[edi+12]
  1846.         mov     [value_type],al
  1847.         cmp     al,4
  1848.         jne     check_dword_value
  1849.         mov     [value_type],2
  1850.         mov     eax,[edi]
  1851.         cdq
  1852.         cmp     edx,[edi+4]
  1853.         jne     range_exceeded
  1854.         ret
  1855.       check_dword_value:
  1856.         mov     eax,[edi]
  1857.         mov     edx,[edi+4]
  1858.         or      edx,edx
  1859.         jz      dword_positive
  1860.         cmp     edx,-1
  1861.         jne     range_exceeded
  1862.         bt      eax,31
  1863.         jnc     range_exceeded
  1864.       dword_positive:
  1865.         ret
  1866. get_pword_value:
  1867.         mov     [value_size],6
  1868.         mov     [size_override],-1
  1869.         call    calculate_expression
  1870.         mov     eax,[edi+16]
  1871.         mov     [symbol_identifier],eax
  1872.         cmp     word [edi+8],0
  1873.         jne     invalid_value
  1874.         mov     al,[edi+12]
  1875.         mov     [value_type],al
  1876.         cmp     al,4
  1877.         jne     check_pword_value
  1878.         cmp     [error_line],0
  1879.         jne     check_pword_value
  1880.         mov     eax,[current_line]
  1881.         mov     [error_line],eax
  1882.         mov     [error],invalid_use_of_symbol
  1883.       check_pword_value:
  1884.         mov     eax,[edi]
  1885.         mov     edx,[edi+4]
  1886.         cmp     edx,10000h
  1887.         jge     range_exceeded
  1888.         cmp     edx,-8000h
  1889.         jl      range_exceeded
  1890.         ret
  1891. get_qword_value:
  1892.         mov     [value_size],8
  1893.         mov     [size_override],-1
  1894.         call    calculate_expression
  1895.         mov     eax,[edi+16]
  1896.         mov     [symbol_identifier],eax
  1897.         cmp     word [edi+8],0
  1898.         jne     invalid_value
  1899.         mov     al,[edi+12]
  1900.         mov     [value_type],al
  1901.       check_qword_value:
  1902.         mov     eax,[edi]
  1903.         mov     edx,[edi+4]
  1904.         ret
  1905. get_value:
  1906.         mov     [operand_size],0
  1907.         lods    byte [esi]
  1908.         call    get_size_operator
  1909.         cmp     al,'('
  1910.         jne     invalid_value
  1911.         mov     al,[operand_size]
  1912.         cmp     al,1
  1913.         je      value_byte
  1914.         cmp     al,2
  1915.         je      value_word
  1916.         cmp     al,4
  1917.         je      value_dword
  1918.         cmp     al,6
  1919.         je      value_pword
  1920.         cmp     al,8
  1921.         je      value_qword
  1922.         or      al,al
  1923.         jnz     invalid_value
  1924.       value_qword:
  1925.         call    get_qword_value
  1926.         ret
  1927.       value_pword:
  1928.         call    get_pword_value
  1929.         movzx   edx,dx
  1930.         ret
  1931.       value_dword:
  1932.         call    get_dword_value
  1933.         xor     edx,edx
  1934.         ret
  1935.       value_word:
  1936.         call    get_word_value
  1937.         xor     edx,edx
  1938.         movzx   eax,ax
  1939.         ret
  1940.       value_byte:
  1941.         call    get_byte_value
  1942.         xor     edx,edx
  1943.         movzx   eax,al
  1944.         ret
  1945. get_address_value:
  1946.         mov     [address_size],0
  1947.         mov     [value_size],8
  1948.       calculate_address:
  1949.         cmp     byte [esi],'.'
  1950.         je      invalid_address
  1951.         call    calculate_expression
  1952.         mov     eax,[edi+16]
  1953.         mov     [address_symbol],eax
  1954.         mov     al,[edi+12]
  1955.         mov     [value_type],al
  1956.         cmp     al,5
  1957.         je      gotoff_address
  1958.         test    al,1
  1959.         jnz     invalid_use_of_symbol
  1960.         or      al,al
  1961.         jz      address_size_ok
  1962.         shl     al,5
  1963.         jmp     address_symbol_ok
  1964.       gotoff_address:
  1965.         mov     al,40h
  1966.       address_symbol_ok:
  1967.         mov     ah,[address_size]
  1968.         or      [address_size],al
  1969.         shr     al,4
  1970.         or      ah,ah
  1971.         jz      address_size_ok
  1972.         cmp     al,ah
  1973.         je      address_size_ok
  1974.         cmp     ax,0408h
  1975.         jne     address_sizes_do_not_agree
  1976.         mov     [value_type],2
  1977.         mov     eax,[edi]
  1978.         cdq
  1979.         cmp     edx,[edi+4]
  1980.         je      address_size_ok
  1981.         cmp     [error_line],0
  1982.         jne     address_size_ok
  1983.         mov     ecx,[current_line]
  1984.         mov     [error_line],ecx
  1985.         mov     [error],value_out_of_range
  1986.       address_size_ok:
  1987.         xor     bx,bx
  1988.         xor     cl,cl
  1989.         mov     ch,[address_size]
  1990.         cmp     word [edi+8],0
  1991.         je      check_immediate_address
  1992.         mov     al,[edi+8]
  1993.         mov     dl,[edi+10]
  1994.         call    get_address_register
  1995.         mov     al,[edi+9]
  1996.         mov     dl,[edi+11]
  1997.         call    get_address_register
  1998.         mov     ax,bx
  1999.         shr     ah,4
  2000.         shr     al,4
  2001.         or      bh,bh
  2002.         jz      check_address_registers
  2003.         or      bl,bl
  2004.         jz      check_address_registers
  2005.         cmp     al,ah
  2006.         jne     invalid_address
  2007.       check_address_registers:
  2008.         or      al,ah
  2009.         mov     ah,[address_size]
  2010.         and     ah,0Fh
  2011.         jz      address_registers_sizes_ok
  2012.         cmp     al,ah
  2013.         jne     invalid_address
  2014.       address_registers_sizes_ok:
  2015.         cmp     al,4
  2016.         je      sib_allowed
  2017.         cmp     al,8
  2018.         je      sib_allowed
  2019.         or      cl,cl
  2020.         jz      check_word_value
  2021.         cmp     cl,1
  2022.         je      check_word_value
  2023.         jmp     invalid_address
  2024.       get_address_register:
  2025.         or      al,al
  2026.         jz      address_register_ok
  2027.         cmp     dl,1
  2028.         jne     scaled_register
  2029.         or      bh,bh
  2030.         jnz     scaled_register
  2031.         mov     bh,al
  2032.       address_register_ok:
  2033.         ret
  2034.       scaled_register:
  2035.         or      bl,bl
  2036.         jnz     invalid_address
  2037.         mov     bl,al
  2038.         mov     cl,dl
  2039.         jmp     address_register_ok
  2040.       sib_allowed:
  2041.         or      bh,bh
  2042.         jnz     check_index_scale
  2043.         cmp     cl,2
  2044.         je      special_index_scale
  2045.         cmp     cl,3
  2046.         je      special_index_scale
  2047.         cmp     cl,5
  2048.         je      special_index_scale
  2049.         cmp     cl,9
  2050.         je      special_index_scale
  2051.       check_index_scale:
  2052.         or      cl,cl
  2053.         jz      address_registers_ok
  2054.         cmp     cl,1
  2055.         je      address_registers_ok
  2056.         cmp     cl,2
  2057.         je      address_registers_ok
  2058.         cmp     cl,4
  2059.         je      address_registers_ok
  2060.         cmp     cl,8
  2061.         je      address_registers_ok
  2062.         jmp     invalid_address
  2063.       special_index_scale:
  2064.         mov     bh,bl
  2065.         dec     cl
  2066.       address_registers_ok:
  2067.         jmp     check_dword_value
  2068.       check_immediate_address:
  2069.         cmp     [code_type],64
  2070.         jne     check_dword_value
  2071.         cmp     [address_size],4
  2072.         je      check_dword_value
  2073.         jmp     check_qword_value
  2074. get_relative_offset:
  2075.         mov     [value_size],4
  2076.         mov     [size_override],-1
  2077.         call    calculate_expression
  2078.       calculate_relative_offset:
  2079.         push    esi
  2080.         add     edi,14h
  2081.         mov     esi,[display_buffer]
  2082.         sub     esi,7
  2083.         lea     eax,[esi-14h]
  2084.         cmp     eax,edi
  2085.         jb      out_of_memory
  2086.         mov     byte [esi],11h
  2087.         xor     eax,eax
  2088.         mov     dword [esi+1],eax
  2089.         mov     word [esi+5],')' shl 8 + 81h
  2090.         call    calculation_loop
  2091.         pop     esi
  2092.         cmp     word [edi+8],0
  2093.         jne     invalid_value
  2094.         mov     al,[edi+12]
  2095.         mov     [value_type],al
  2096.         mov     eax,[edi+16]
  2097.         mov     [symbol_identifier],eax
  2098.         mov     eax,[edi]
  2099.         mov     edx,[edi+4]
  2100.         or      edx,edx
  2101.         jz      offset_positive
  2102.         cmp     edx,-1
  2103.         jne     range_exceeded
  2104.         bt      eax,31
  2105.         jnc     range_exceeded
  2106.         ret
  2107.       offset_positive:
  2108.         bt      eax,31
  2109.         jc      range_exceeded
  2110.         ret
  2111.  
  2112. preevaluate_logical_expression:
  2113.         push    edi
  2114.         call    preevaluate_logical_value
  2115.       preevaluation_loop:
  2116.         cmp     al,0FFh
  2117.         je      invalid_logical_expression
  2118.         mov     dl,[esi]
  2119.         inc     esi
  2120.         cmp     dl,'|'
  2121.         je      preevaluate_or
  2122.         cmp     dl,'&'
  2123.         je      preevaluate_and
  2124.         cmp     dl,'}'
  2125.         je      preevaluation_done
  2126.         or      dl,dl
  2127.         jnz     invalid_logical_expression
  2128.       preevaluation_done:
  2129.         pop     edx
  2130.         dec     esi
  2131.         ret
  2132.       preevaluate_or:
  2133.         cmp     al,'1'
  2134.         je      quick_true
  2135.         cmp     al,'0'
  2136.         je      leave_only_following
  2137.         push    edi
  2138.         mov     al,dl
  2139.         stos    byte [edi]
  2140.         call    preevaluate_logical_value
  2141.         pop     ebx
  2142.         cmp     al,'0'
  2143.         je      leave_only_preceding
  2144.         cmp     al,'1'
  2145.         jne     preevaluation_loop
  2146.         stos    byte [edi]
  2147.         xor     al,al
  2148.         jmp     preevaluation_loop
  2149.       preevaluate_and:
  2150.         cmp     al,'0'
  2151.         je      quick_false
  2152.         cmp     al,'1'
  2153.         je      leave_only_following
  2154.         push    edi
  2155.         mov     al,dl
  2156.         stos    byte [edi]
  2157.         call    preevaluate_logical_value
  2158.         pop     ebx
  2159.         cmp     al,'1'
  2160.         je      leave_only_preceding
  2161.         cmp     al,'0'
  2162.         jne     preevaluation_loop
  2163.         stos    byte [edi]
  2164.         xor     al,al
  2165.         jmp     preevaluation_loop
  2166.       leave_only_following:
  2167.         mov     edi,[esp]
  2168.         call    preevaluate_logical_value
  2169.         jmp     preevaluation_loop
  2170.       leave_only_preceding:
  2171.         mov     edi,ebx
  2172.         xor     al,al
  2173.         jmp     preevaluation_loop
  2174.       quick_true:
  2175.         call    skip_logical_value
  2176.         jc      invalid_logical_expression
  2177.         mov     edi,[esp]
  2178.         mov     al,'1'
  2179.         jmp     preevaluation_loop
  2180.       quick_false:
  2181.         call    skip_logical_value
  2182.         jc      invalid_logical_expression
  2183.         mov     edi,[esp]
  2184.         mov     al,'0'
  2185.         jmp     preevaluation_loop
  2186.       invalid_logical_expression:
  2187.         pop     edi
  2188.         mov     esi,edi
  2189.         mov     al,0FFh
  2190.         stos    byte [edi]
  2191.         ret
  2192. skip_logical_value:
  2193.         cmp     byte [esi],'~'
  2194.         jne     negation_skipped
  2195.         inc     esi
  2196.         jmp     skip_logical_value
  2197.       negation_skipped:
  2198.         cmp     byte [esi],'{'
  2199.         jne     skip_simple_logical_value
  2200.         inc     esi
  2201.       skip_logical_expression:
  2202.         call    skip_logical_value
  2203.         lods    byte [esi]
  2204.         or      al,al
  2205.         jz      wrongly_structured_logical_expression
  2206.         cmp     al,0Fh
  2207.         je      wrongly_structured_logical_expression
  2208.         cmp     al,'|'
  2209.         je      skip_logical_expression
  2210.         cmp     al,'&'
  2211.         je      skip_logical_expression
  2212.         cmp     al,'}'
  2213.         je      logical_value_skipped
  2214.       wrongly_structured_logical_expression:
  2215.         stc
  2216.         ret
  2217.       skip_simple_logical_value:
  2218.         mov     al,[esi]
  2219.         or      al,al
  2220.         jz      logical_value_skipped
  2221.         cmp     al,0Fh
  2222.         je      logical_value_skipped
  2223.         cmp     al,'}'
  2224.         je      logical_value_skipped
  2225.         cmp     al,'|'
  2226.         je      logical_value_skipped
  2227.         cmp     al,'&'
  2228.         je      logical_value_skipped
  2229.         call    skip_symbol
  2230.         jmp     skip_simple_logical_value
  2231.       logical_value_skipped:
  2232.         clc
  2233.         ret
  2234.  
  2235. preevaluate_logical_value:
  2236.         mov     ebp,edi
  2237.       preevaluate_negation:
  2238.         cmp     byte [esi],'~'
  2239.         jne     preevaluate_negation_ok
  2240.         movs    byte [edi],[esi]
  2241.         jmp     preevaluate_negation
  2242.       preevaluate_negation_ok:
  2243.         mov     ebx,esi
  2244.         xor     edx,edx
  2245.         cmp     byte [esi],'{'
  2246.         jne     find_logical_value_boundaries
  2247.         movs    byte [edi],[esi]
  2248.         push    ebp
  2249.         call    preevaluate_logical_expression
  2250.         pop     ebp
  2251.         cmp     al,0FFh
  2252.         je      invalid_logical_value
  2253.         cmp     byte [esi],'}'
  2254.         jne     invalid_logical_value
  2255.         or      al,al
  2256.         jnz     preevaluated_expression_value
  2257.         movs    byte [edi],[esi]
  2258.         ret
  2259.       preevaluated_expression_value:
  2260.         inc     esi
  2261.         lea     edx,[edi-1]
  2262.         sub     edx,ebp
  2263.         test    edx,1
  2264.         jz      expression_negation_ok
  2265.         xor     al,1
  2266.       expression_negation_ok:
  2267.         mov     edi,ebp
  2268.         ret
  2269.       invalid_logical_value:
  2270.         mov     edi,ebp
  2271.         mov     al,0FFh
  2272.         ret
  2273.       find_logical_value_boundaries:
  2274.         mov     al,[esi]
  2275.         or      al,al
  2276.         jz      logical_value_boundaries_found
  2277.         cmp     al,'}'
  2278.         je      logical_value_boundaries_found
  2279.         cmp     al,'|'
  2280.         je      logical_value_boundaries_found
  2281.         cmp     al,'&'
  2282.         je      logical_value_boundaries_found
  2283.         or      edx,edx
  2284.         jnz     next_symbol_in_logical_value
  2285.         cmp     al,0F0h
  2286.         je      preevaluable_logical_operator
  2287.         cmp     al,0F7h
  2288.         je      preevaluable_logical_operator
  2289.         cmp     al,0F6h
  2290.         jne     next_symbol_in_logical_value
  2291.       preevaluable_logical_operator:
  2292.         mov     edx,esi
  2293.       next_symbol_in_logical_value:
  2294.         call    skip_symbol
  2295.         jmp     find_logical_value_boundaries
  2296.       logical_value_boundaries_found:
  2297.         or      edx,edx
  2298.         jz      non_preevaluable_logical_value
  2299.         mov     al,[edx]
  2300.         cmp     al,0F0h
  2301.         je      compare_symbols
  2302.         cmp     al,0F7h
  2303.         je      compare_symbol_types
  2304.         cmp     al,0F6h
  2305.         je      scan_symbols_list
  2306.       non_preevaluable_logical_value:
  2307.         mov     ecx,esi
  2308.         mov     esi,ebx
  2309.         sub     ecx,esi
  2310.         jz      invalid_logical_value
  2311.         cmp     esi,edi
  2312.         je      leave_logical_value_intact
  2313.         rep     movs byte [edi],[esi]
  2314.         xor     al,al
  2315.         ret
  2316.       leave_logical_value_intact:
  2317.         add     edi,ecx
  2318.         add     esi,ecx
  2319.         xor     al,al
  2320.         ret
  2321.       compare_symbols:
  2322.         lea     ecx,[esi-1]
  2323.         sub     ecx,edx
  2324.         mov     eax,edx
  2325.         sub     eax,ebx
  2326.         cmp     ecx,eax
  2327.         jne     preevaluated_false
  2328.         push    esi edi
  2329.         mov     esi,ebx
  2330.         lea     edi,[edx+1]
  2331.         repe    cmps byte [esi],[edi]
  2332.         pop     edi esi
  2333.         je      preevaluated_true
  2334.       preevaluated_false:
  2335.         mov     eax,edi
  2336.         sub     eax,ebp
  2337.         test    eax,1
  2338.         jnz     store_true
  2339.       store_false:
  2340.         mov     edi,ebp
  2341.         mov     al,'0'
  2342.         ret
  2343.       preevaluated_true:
  2344.         mov     eax,edi
  2345.         sub     eax,ebp
  2346.         test    eax,1
  2347.         jnz     store_false
  2348.       store_true:
  2349.         mov     edi,ebp
  2350.         mov     al,'1'
  2351.         ret
  2352.       compare_symbol_types:
  2353.         push    esi
  2354.         lea     esi,[edx+1]
  2355.       type_comparison:
  2356.         cmp     esi,[esp]
  2357.         je      types_compared
  2358.         mov     al,[esi]
  2359.         cmp     al,[ebx]
  2360.         jne     different_type
  2361.         cmp     al,'('
  2362.         jne     equal_type
  2363.         mov     al,[esi+1]
  2364.         mov     ah,[ebx+1]
  2365.         cmp     al,ah
  2366.         je      equal_type
  2367.         or      al,al
  2368.         jz      different_type
  2369.         or      ah,ah
  2370.         jz      different_type
  2371.         cmp     al,'.'
  2372.         je      different_type
  2373.         cmp     ah,'.'
  2374.         je      different_type
  2375.       equal_type:
  2376.         call    skip_symbol
  2377.         xchg    esi,ebx
  2378.         call    skip_symbol
  2379.         xchg    esi,ebx
  2380.         jmp     type_comparison
  2381.       types_compared:
  2382.         pop     esi
  2383.         cmp     byte [ebx],0F7h
  2384.         jne     preevaluated_false
  2385.         jmp     preevaluated_true
  2386.       different_type:
  2387.         pop     esi
  2388.         jmp     preevaluated_false
  2389.       scan_symbols_list:
  2390.         push    edi esi
  2391.         lea     esi,[edx+1]
  2392.         sub     edx,ebx
  2393.         lods    byte [esi]
  2394.         cmp     al,'<'
  2395.         jne     invalid_symbols_list
  2396.       get_next_from_list:
  2397.         mov     edi,esi
  2398.       get_from_list:
  2399.         cmp     byte [esi],','
  2400.         je      compare_in_list
  2401.         cmp     byte [esi],'>'
  2402.         je      compare_in_list
  2403.         cmp     esi,[esp]
  2404.         jae     invalid_symbols_list
  2405.         call    skip_symbol
  2406.         jmp     get_from_list
  2407.       compare_in_list:
  2408.         mov     ecx,esi
  2409.         sub     ecx,edi
  2410.         cmp     ecx,edx
  2411.         jne     not_equal_length_in_list
  2412.         mov     esi,ebx
  2413.         repe    cmps byte [esi],[edi]
  2414.         mov     esi,edi
  2415.         jne     not_equal_in_list
  2416.       skip_rest_of_list:
  2417.         cmp     byte [esi],'>'
  2418.         je      check_list_end
  2419.         cmp     esi,[esp]
  2420.         jae     invalid_symbols_list
  2421.         call    skip_symbol
  2422.         jmp     skip_rest_of_list
  2423.       check_list_end:
  2424.         inc     esi
  2425.         cmp     esi,[esp]
  2426.         jne     invalid_symbols_list
  2427.         pop     esi edi
  2428.         jmp     preevaluated_true
  2429.       not_equal_in_list:
  2430.         add     esi,ecx
  2431.       not_equal_length_in_list:
  2432.         lods    byte [esi]
  2433.         cmp     al,','
  2434.         je      get_next_from_list
  2435.         cmp     esi,[esp]
  2436.         jne     invalid_symbols_list
  2437.         pop     esi edi
  2438.         jmp     preevaluated_false
  2439.       invalid_symbols_list:
  2440.         pop     esi edi
  2441.         jmp     invalid_logical_value
  2442.  
  2443. calculate_logical_expression:
  2444.         call    get_logical_value
  2445.       logical_loop:
  2446.         cmp     byte [esi],'|'
  2447.         je      logical_or
  2448.         cmp     byte [esi],'&'
  2449.         je      logical_and
  2450.         ret
  2451.       logical_or:
  2452.         inc     esi
  2453.         or      al,al
  2454.         jnz     logical_value_already_determined
  2455.         push    eax
  2456.         call    get_logical_value
  2457.         pop     ebx
  2458.         or      al,bl
  2459.         jmp     logical_loop
  2460.       logical_and:
  2461.         inc     esi
  2462.         or      al,al
  2463.         jz      logical_value_already_determined
  2464.         push    eax
  2465.         call    get_logical_value
  2466.         pop     ebx
  2467.         and     al,bl
  2468.         jmp     logical_loop
  2469.       logical_value_already_determined:
  2470.         push    eax
  2471.         call    skip_logical_value
  2472.         jc      invalid_expression
  2473.         pop     eax
  2474.         jmp     logical_loop
  2475. get_logical_value:
  2476.         xor     al,al
  2477.       check_for_negation:
  2478.         cmp     byte [esi],'~'
  2479.         jne     negation_ok
  2480.         inc     esi
  2481.         xor     al,-1
  2482.         jmp     check_for_negation
  2483.       negation_ok:
  2484.         push    eax
  2485.         mov     al,[esi]
  2486.         cmp     al,'{'
  2487.         je      logical_expression
  2488.         cmp     al,0FFh
  2489.         je      invalid_expression
  2490.         cmp     al,88h
  2491.         je      check_for_defined
  2492.         cmp     al,89h
  2493.         je      check_for_used
  2494.         cmp     al,'0'
  2495.         je      given_false
  2496.         cmp     al,'1'
  2497.         je      given_true
  2498.         call    get_value
  2499.         mov     bl,[value_type]
  2500.         push    eax edx ebx
  2501.         mov     al,[esi]
  2502.         or      al,al
  2503.         jz      logical_number
  2504.         cmp     al,0Fh
  2505.         je      logical_number
  2506.         cmp     al,'}'
  2507.         je      logical_number
  2508.         cmp     al,'&'
  2509.         je      logical_number
  2510.         cmp     al,'|'
  2511.         je      logical_number
  2512.         inc     esi
  2513.         mov     [compare_type],al
  2514.         call    get_value
  2515.         pop     ebx
  2516.         cmp     [next_pass_needed],0
  2517.         jne     values_ok
  2518.         cmp     bl,[value_type]
  2519.         jne     invalid_use_of_symbol
  2520.       values_ok:
  2521.         pop     ecx ebx
  2522.         cmp     [compare_type],'='
  2523.         je      check_equal
  2524.         cmp     [compare_type],'>'
  2525.         je      check_greater
  2526.         cmp     [compare_type],'<'
  2527.         je      check_less
  2528.         cmp     [compare_type],0F1h
  2529.         je      check_not_equal
  2530.         cmp     [compare_type],0F2h
  2531.         je      check_not_less
  2532.         cmp     [compare_type],0F3h
  2533.         je      check_not_greater
  2534.         jmp     invalid_expression
  2535.       check_equal:
  2536.         cmp     eax,ebx
  2537.         jne     return_false
  2538.         cmp     edx,ecx
  2539.         jne     return_false
  2540.         jmp     return_true
  2541.       check_greater:
  2542.         cmp     edx,ecx
  2543.         jl      return_true
  2544.         jg      return_false
  2545.         cmp     eax,ebx
  2546.         jb      return_true
  2547.         jae     return_false
  2548.       check_less:
  2549.         cmp     edx,ecx
  2550.         jl      return_false
  2551.         jg      return_true
  2552.         cmp     eax,ebx
  2553.         jbe     return_false
  2554.         ja      return_true
  2555.       check_not_less:
  2556.         cmp     edx,ecx
  2557.         jl      return_true
  2558.         jg      return_false
  2559.         cmp     eax,ebx
  2560.         jbe     return_true
  2561.         ja      return_false
  2562.       check_not_greater:
  2563.         cmp     edx,ecx
  2564.         jl      return_false
  2565.         jg      return_true
  2566.         cmp     eax,ebx
  2567.         jb      return_false
  2568.         jae     return_true
  2569.       check_not_equal:
  2570.         cmp     eax,ebx
  2571.         jne     return_true
  2572.         cmp     edx,ecx
  2573.         jne     return_true
  2574.         jmp     return_false
  2575.       logical_number:
  2576.         pop     ebx edx eax
  2577.         or      bl,bl
  2578.         jnz     invalid_expression
  2579.         or      eax,edx
  2580.         jnz     return_true
  2581.         jmp     return_false
  2582.       check_for_defined:
  2583.         or      bl,-1
  2584.         lods    word [esi]
  2585.         cmp     ah,'('
  2586.         jne     invalid_expression
  2587.       check_expression:
  2588.         lods    byte [esi]
  2589.         or      al,al
  2590.         jz      defined_string
  2591.         cmp     al,'.'
  2592.         je      defined_fp_value
  2593.         cmp     al,')'
  2594.         je      expression_checked
  2595.         cmp     al,0Fh
  2596.         je      check_expression
  2597.         cmp     al,10h
  2598.         je      defined_register
  2599.         cmp     al,11h
  2600.         je      check_if_symbol_defined
  2601.         cmp     al,80h
  2602.         jae     check_expression
  2603.         movzx   eax,al
  2604.         add     esi,eax
  2605.         jmp     check_expression
  2606.       defined_register:
  2607.         inc     esi
  2608.         jmp     check_expression
  2609.       defined_fp_value:
  2610.         add     esi,12
  2611.         jmp     expression_checked
  2612.       defined_string:
  2613.         lods    dword [esi]
  2614.         add     esi,eax
  2615.         inc     esi
  2616.         jmp     expression_checked
  2617.       check_if_symbol_defined:
  2618.         lods    dword [esi]
  2619.         cmp     eax,-1
  2620.         je      invalid_expression
  2621.         cmp     eax,0Fh
  2622.         jb      check_expression
  2623.         je      reserved_word_used_as_symbol
  2624.         test    byte [eax+8],4
  2625.         jnz     no_prediction
  2626.         test    byte [eax+8],1
  2627.         jz      symbol_predicted_undefined
  2628.         mov     cx,[current_pass]
  2629.         sub     cx,[eax+16]
  2630.         jz      check_expression
  2631.         cmp     cx,1
  2632.         ja      symbol_predicted_undefined
  2633.         or      byte [eax+8],40h+80h
  2634.         jmp     check_expression
  2635.       no_prediction:
  2636.         test    byte [eax+8],1
  2637.         jz      symbol_undefined
  2638.         mov     cx,[current_pass]
  2639.         sub     cx,[eax+16]
  2640.         jz      check_expression
  2641.         jmp     symbol_undefined
  2642.       symbol_predicted_undefined:
  2643.         or      byte [eax+8],40h
  2644.         and     byte [eax+8],not 80h
  2645.       symbol_undefined:
  2646.         xor     bl,bl
  2647.         jmp     check_expression
  2648.       expression_checked:
  2649.         mov     al,bl
  2650.         jmp     logical_value_ok
  2651.       check_for_used:
  2652.         lods    word [esi]
  2653.         cmp     ah,2
  2654.         jne     invalid_expression
  2655.         lods    dword [esi]
  2656.         cmp     eax,0Fh
  2657.         jb      invalid_use_of_symbol
  2658.         je      reserved_word_used_as_symbol
  2659.         inc     esi
  2660.         test    byte [eax+8],8
  2661.         jz      not_used
  2662.         mov     cx,[current_pass]
  2663.         sub     cx,[eax+18]
  2664.         jz      return_true
  2665.         cmp     cx,1
  2666.         ja      not_used
  2667.         or      byte [eax+8],10h+20h
  2668.         jmp     return_true
  2669.       not_used:
  2670.         or      byte [eax+8],10h
  2671.         and     byte [eax+8],not 20h
  2672.         jmp     return_false
  2673.       given_false:
  2674.         inc     esi
  2675.       return_false:
  2676.         xor     al,al
  2677.         jmp     logical_value_ok
  2678.       given_true:
  2679.         inc     esi
  2680.       return_true:
  2681.         or      al,-1
  2682.         jmp     logical_value_ok
  2683.       logical_expression:
  2684.         inc     esi
  2685.         call    calculate_logical_expression
  2686.         push    eax
  2687.         lods    byte [esi]
  2688.         cmp     al,'}'
  2689.         jne     invalid_expression
  2690.         pop     eax
  2691.       logical_value_ok:
  2692.         pop     ebx
  2693.         xor     al,bl
  2694.         ret
  2695.