Subversion Repositories Kolibri OS

Rev

Rev 9909 | Rev 9915 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. (*
  2.     Copyright 2021-2023 Anton Krotov
  3.  
  4.     This file is part of CEdit.
  5.  
  6.     CEdit is free software: you can redistribute it and/or modify
  7.     it under the terms of the GNU General Public License as published by
  8.     the Free Software Foundation, either version 3 of the License, or
  9.     (at your option) any later version.
  10.  
  11.     CEdit is distributed in the hope that it will be useful,
  12.     but WITHOUT ANY WARRANTY; without even the implied warranty of
  13.     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14.     GNU General Public License for more details.
  15.  
  16.     You should have received a copy of the GNU General Public License
  17.     along with CEdit. If not, see <http://www.gnu.org/licenses/>.
  18. *)
  19.  
  20. MODULE CEdit;
  21.  
  22. IMPORT
  23.     OpenDlg, K := KolibriOS, Args,
  24.     U := Utils, Lines, Menu, List,
  25.     G := Graph, T := Text, E := Encodings,
  26.     CB := Clipboard, Languages,
  27.     ChangeLog, Scroll, CheckBox, Icons,
  28.     RW, Ini, EB := EditBox, Tabs, Toolbar, SB := StatusBar;
  29.  
  30. CONST
  31.     HEADER = "CEdit (13-apr-2023)";
  32.  
  33.     ShellFilter = "";
  34.     EditFilter = "sh|inc|txt|asm|ob07|c|cpp|h|pas|pp|lua|ini|json";
  35.  
  36.     fontWidth = K.fontWidth;
  37.     fontHeight = K.fontHeight;
  38.  
  39.     btnClose = 1;
  40.  
  41.     btnNew = 20;
  42.     btnOpen = 21;
  43.     btnSave = 22;
  44.     btnSearch = 23;
  45.     btnUndo = 24;
  46.     btnRedo = 25;
  47.     btnUpper = 26;
  48.     btnLower = 27;
  49.     btnBuild = 28;
  50.     btnRun = 29;
  51.  
  52.     btnYes = 40;
  53.     btnNo = 41;
  54.     btnFindNext = 42;
  55.     btnReplace = 43;
  56.     btnReplaceAll = 44;
  57.     btnGoto = 45;
  58.     btnCloseSearch = 46;
  59.     btnHideSearch = 47;
  60.  
  61.     mainMenuBtn = 60;
  62.  
  63.     btnHeight = 25;
  64.     btnWidth = 75;
  65.  
  66.     toolbarTop = Menu.MainMenuHeight + 3;
  67.  
  68.     TOP = toolbarTop + Toolbar.BtnSize + 9 + Tabs.tabHeight;
  69.  
  70.     minWinWidth = 635; minWinHeight = 550;
  71.  
  72.     SEARCH_PADDING = 10;
  73.     LEFT_PADDING = 1;
  74.     RIGHT_PADDING = 1;
  75.  
  76.     EditBox_Width = 180;
  77.     EDITBOX_MAXCHARS = 500;
  78.  
  79.     menuCut = 1;
  80.     menuCopy = 2;
  81.     menuPaste = 3;
  82.     menuDelete = 4;
  83.     menuSelectAll = 5;
  84.  
  85.     menuUndo = 6;
  86.     menuRedo = 7;
  87.  
  88.     menuCurLine = 100;
  89.     menuIndent = 110;
  90.     menuCase = 120;
  91.  
  92.     menuNew = 10;
  93.     menuOpen = 11;
  94.     menuSave = 12;
  95.     menuSaveAs = 13;
  96.     menuSaveAll = 14;
  97.     menuFolder = 15;
  98.     menuClose = 16;
  99.     menuExit = 17;
  100.  
  101.     menuFontSmall = 20;
  102.     menuFontMedium = menuFontSmall + 1;
  103.     menuFontLarge = menuFontMedium + 1;
  104.     menuColors = 1000;
  105.     menuMaxColors = menuColors + Ini.MAX_SECTIONS - 1;
  106.  
  107.     menuText = 30;
  108.     menuC = 31;
  109.     menuFasm = 32;
  110.     menuIni = 33;
  111.     menuJSON = 34;
  112.     menuLua = 35;
  113.     menuOberon = 36;
  114.     menuPascal = 37;
  115.  
  116.     menuBuild = 50;
  117.     menuBuildScript = 51;
  118.     menuRun = 52;
  119.     menuRunScript = 53;
  120.     menuDebug = 54;
  121.     menuDebugScript = 55;
  122.     menuFASM = 56;
  123.  
  124.     menuUTF8BOM = 60;
  125.     menuUTF8 = 61;
  126.     menuCP866 = 62;
  127.     menuCP1251 = 63;
  128.     menuEOL = 140;
  129.     menuConv1251_866 = 64;
  130.     menuConv866_1251 = 65;
  131.  
  132.     menuPipet = 70;
  133.     menuMagnify = 71;
  134.     menuBoard = 72;
  135.     menuSysFunc = 73;
  136.  
  137.     menuFind = 80;
  138.     menuFindNext = 81;
  139.     menuFindPrev = 82;
  140.     menuGoto = 83;
  141.     menuBookmark = 130;
  142.  
  143.     menuLineNumbers  = 90;
  144.     menuAutoIndents  = 91;
  145.     menuAutoBrackets = 92;
  146.     menuTrimSpace    = 93;
  147.  
  148.     menuMoveUp = 101;
  149.     menuMoveDown = 102;
  150.     menuDuplicate = 103;
  151.     menuRemove = 104;
  152.  
  153.     menuIncInd = 111;
  154.     menuDecInd = 112;
  155.  
  156.     menuUpper = 121;
  157.     menuLower = 122;
  158.  
  159.     menuToggleBookmark = 131;
  160.     menuNextBookmark = 132;
  161.     menuPrevBookmark = 133;
  162.  
  163.     menuLF = 141;
  164.     menuCRLF = 142;
  165.     menuCR = 143;
  166.  
  167.     maxTexts = 32;
  168.  
  169.         SHIFT = Menu.SHIFT;
  170.         CTRL  = Menu.CTRL;
  171.  
  172.         ClippingArea = 50;
  173.  
  174.  
  175. VAR
  176.         header: RW.tFileName;
  177.     canvas: G.tCanvas;
  178.     font: G.tFont;
  179.  
  180.     tabs: Tabs.tTabs;
  181.     text: T.tText;
  182.     texts: ARRAY maxTexts OF T.tText;
  183.     textsCount, curText: INTEGER;
  184.  
  185.     winWidth, winHeight: INTEGER;
  186.     SkinHeight, scrollWidth: INTEGER;
  187.     AppPath, runScript, buildScript, debugScript, CurFolder: RW.tFileName;
  188.     OD: OpenDlg.Dialog;
  189.     confirm, notFound, menuFindClicked, search, searchOpened: BOOLEAN;
  190.  
  191.     switch, closing, newtab: BOOLEAN;
  192.     leftButton: BOOLEAN;
  193.     LEFT, RIGHT, BOTTOM: INTEGER;
  194.  
  195.     FindEdit, ReplaceEdit, GotoEdit: EB.tEditBox;
  196.     hScroll, vScroll: Scroll.tScroll;
  197.     CS, WH, BKW: CheckBox.tCheckBox;
  198.  
  199.     new_searchText, searchText, replaceText, gotoText: T.tString;
  200.     cs, whole: BOOLEAN;
  201.  
  202.     replaced: INTEGER;
  203.  
  204.     context, menuFile, menuEdit, menuSearch, menuEncoding,
  205.     menuView, menuLanguage, menuProgram, menuTools, menuOptions,
  206.     subCurLine, subIndent, subCase, subBookmark, subEOL: Menu.tMenu;
  207.  
  208.     mainMenu: Menu.tMain;
  209.  
  210.     menuActive: BOOLEAN;
  211.  
  212.     toolbar: Toolbar.tToolbar;
  213.  
  214.     CursorTime, CurrentTime: INTEGER;
  215.     timerEnabled: BOOLEAN;
  216.  
  217.     IPC: ARRAY 64 OF INTEGER; mainTID: INTEGER;
  218.  
  219.  
  220. PROCEDURE EditBox_Focus (edit: EB.tEditBox): BOOLEAN;
  221.         RETURN 1 IN edit.flags
  222. END EditBox_Focus;
  223.  
  224.  
  225. PROCEDURE resetTimer;
  226. BEGIN
  227.         IF EditBox_Focus(FindEdit) OR EditBox_Focus(ReplaceEdit) OR EditBox_Focus(GotoEdit) THEN
  228.                 T.hideCursor;
  229.                 timerEnabled := FALSE
  230.         ELSE
  231.                 T.showCursor;
  232.                 timerEnabled := TRUE
  233.         END;
  234.         CursorTime := CurrentTime
  235. END resetTimer;
  236.  
  237.  
  238. PROCEDURE EditBox_SetFocus (VAR edit: EB.tEditBox; value: BOOLEAN);
  239. BEGIN
  240.     IF value THEN
  241.         INCL(edit.flags, 1)
  242.     ELSE
  243.         EXCL(edit.flags, 1)
  244.     END;
  245.     IF search & searchOpened THEN
  246.         EB.draw(edit)
  247.     END
  248. END EditBox_SetFocus;
  249.  
  250.  
  251. PROCEDURE SetFocus (VAR edit: EB.tEditBox; value: BOOLEAN);
  252. BEGIN
  253.     EditBox_SetFocus(FindEdit, FALSE);
  254.     EditBox_SetFocus(ReplaceEdit, FALSE);
  255.     EditBox_SetFocus(GotoEdit, FALSE);
  256.     EditBox_SetFocus(edit, value);
  257.         resetTimer
  258. END SetFocus;
  259.  
  260.  
  261. PROCEDURE Rect (left, top, right, bottom, color: INTEGER);
  262. BEGIN
  263.     K.DrawLine(left, top, right, top, color);
  264.     K.DrawLine(left, bottom, right, bottom, color);
  265.     K.DrawLine(left, top, left, bottom, color);
  266.     K.DrawLine(right, top, right, bottom, color);
  267. END Rect;
  268.  
  269.  
  270. PROCEDURE Message (s: ARRAY OF WCHAR);
  271. CONST
  272.     minWidth = 30;
  273.     height = 40;
  274. VAR
  275.     top, left, right, bottom, x, y, width: INTEGER;
  276. BEGIN
  277.         timerEnabled := FALSE;
  278.         CursorTime := CurrentTime;
  279.     width := minWidth + LENGTH(s)*fontWidth;
  280.     left := (canvas.width - width) DIV 2 + LEFT;
  281.     top := (canvas.height - height) DIV 2 + TOP;
  282.     bottom := top + height - 1;
  283.     right := left + width - 1;
  284.     x := minWidth DIV 2 + left;
  285.     y := (height - fontHeight) DIV 2 + top;
  286.     K.DrawRect(left, top, width, height, K.colors.work);
  287.     Rect(left, top, right, bottom, K.colors.line);
  288.     K.DrawText(x, y, K.colors.work_text, s);
  289. END Message;
  290.  
  291.  
  292. PROCEDURE NotFound;
  293. BEGIN
  294.     IF notFound THEN
  295.         Message("not found");
  296.         IF menuFindClicked THEN
  297.                 menuFindClicked := FALSE
  298.         ELSE
  299.                 notFound := FALSE
  300.         END;
  301.         SetFocus(FindEdit, TRUE)
  302.     END
  303. END NotFound;
  304.  
  305.  
  306. PROCEDURE Replaced;
  307. VAR
  308.     s, s1: ARRAY 32 OF WCHAR;
  309. BEGIN
  310.     IF replaced # 0 THEN
  311.         s := "replaced: ";
  312.         U.int2str(replaced, s1);
  313.         U.append(s, s1);
  314.         Message(s);
  315.         replaced := 0;
  316.         SetFocus(FindEdit, TRUE)
  317.     END
  318. END Replaced;
  319.  
  320.  
  321. PROCEDURE getIdx (text: T.tText): INTEGER;
  322. VAR
  323.     i: INTEGER;
  324. BEGIN
  325.     i := 0;
  326.     WHILE texts[i] # text DO
  327.         INC(i)
  328.     END
  329.     RETURN i
  330. END getIdx;
  331.  
  332.  
  333. PROCEDURE SetCaption (fileName: RW.tFileName);
  334. VAR
  335.         newHeader: RW.tFileName;
  336. BEGIN
  337.     newHeader := HEADER;
  338.     IF text.fileName # "" THEN
  339.         U.append8(newHeader, " - ");
  340.         U.append8(newHeader, text.fileName)
  341.     END;
  342.     IF newHeader # header THEN
  343.         header := newHeader;
  344.                 K.SetCaption(header)
  345.     END
  346. END SetCaption;
  347.  
  348.  
  349. PROCEDURE Status (text: T.tText; height: INTEGER);
  350. VAR
  351.         line, col, chars, lines: INTEGER;
  352. BEGIN
  353.         T.getPos(text, col, line);
  354.         T.getSelCnt(text, chars, lines);
  355.         SB.setWidth(canvas.width + scrollWidth);
  356.         SB.setPos(line, col);
  357.         SB.setSel(chars, lines);
  358.         SB.setEnc(E.eolNames[T.getEol(text)], E.names[T.getEnc(text)]);
  359.         SB.draw(LEFT, height - BOTTOM + scrollWidth - 1);
  360.         Tabs.modify(tabs, getIdx(text), text.modified)
  361. END Status;
  362.  
  363.  
  364. PROCEDURE DrawScroll (VAR scroll: Scroll.tScroll; left, top, value, maxVal: INTEGER);
  365. BEGIN
  366.         scroll.maxVal := maxVal;
  367.     scroll.left := left;
  368.     scroll.top := top;
  369.     Scroll.setValue(scroll, value);
  370.     Scroll.draw(scroll)
  371. END DrawScroll;
  372.  
  373.  
  374. PROCEDURE drawText;
  375. BEGIN
  376.         G.SetColor(canvas, K.colors.line);
  377.         G.VLine(canvas, 0, 0, canvas.height - 1);
  378.         G.DrawCanvas(canvas, LEFT, TOP)
  379. END drawText;
  380.  
  381.  
  382. PROCEDURE repaint;
  383. VAR
  384.     width, height, scrollX, scrollY: INTEGER;
  385. BEGIN
  386.     IF (text # NIL) & ~K.RolledUp() THEN
  387.         IF confirm THEN
  388.             K.DeleteButton(btnYes);
  389.             K.DeleteButton(btnNo);
  390.             confirm := FALSE;
  391.             resetTimer;
  392.             closing := FALSE
  393.         END;
  394.         IF ~search OR (searchText = "") THEN
  395.             T.wordSel(text)
  396.         END;
  397.         K.ClientSize(width, height);
  398.         IF switch THEN
  399.             Status(text, height);
  400.             Tabs.draw(tabs);
  401.             IF search & T.search(text, searchText, cs, whole) THEN END;
  402.             switch := FALSE
  403.         END;
  404.         T.draw(text);
  405.         Status(text, height);
  406.  
  407.         T.getScroll(text, scrollX, scrollY);
  408.         DrawScroll(vScroll, LEFT + canvas.width, TOP - 1, scrollY, text.count - 1);
  409.         DrawScroll(hScroll, LEFT, TOP + canvas.height, scrollX, text.maxLength);
  410.         IF search & searchOpened THEN
  411.                 CheckBox.draw(BKW);
  412.                 CheckBox.draw(CS);
  413.                 CheckBox.draw(WH);
  414.         END;
  415.         IF ~search OR (searchText = "") THEN
  416.             T.wordSel(text)
  417.         END;
  418.         drawText;
  419.         NotFound;
  420.         Replaced;
  421.         Toolbar.enable(toolbar, btnSave,  text.modified);
  422.         Toolbar.enable(toolbar, btnUndo,  ~ChangeLog.isFirstGuard(text.edition));
  423.         Toolbar.enable(toolbar, btnRedo,  ~ChangeLog.isLastGuard(text.edition));
  424.         Toolbar.enable(toolbar, btnUpper, T.selected(text));
  425.         Toolbar.enable(toolbar, btnLower, T.selected(text));
  426.         Toolbar.enable(toolbar, btnBuild, (buildScript # "") OR text.fasm);
  427.         Toolbar.enable(toolbar, btnRun,   (runScript # "") OR text.fasm);
  428.         Toolbar.drawIcons(toolbar)
  429.     END
  430. END repaint;
  431.  
  432.  
  433. PROCEDURE resize;
  434. VAR
  435.     cliWidth, cliHeight: INTEGER;
  436. BEGIN
  437.     K.WinSize(winWidth, winHeight);
  438.     IF winWidth < minWinWidth THEN
  439.         winWidth := minWinWidth
  440.     END;
  441.     IF winHeight < minWinHeight THEN
  442.         winHeight := minWinHeight
  443.     END;
  444.     K.SetWinSize(winWidth, winHeight);
  445.     K.WinSize(winWidth, winHeight);
  446.     K.ClientSize(cliWidth, cliHeight);
  447.     IF font # G.fonts[2] THEN
  448.         SB.SetFont(font)
  449.     ELSE
  450.         SB.SetFont(G.fonts[1])
  451.     END;
  452.     BOTTOM := SB.height() + scrollWidth - 1;
  453.     G.destroy(canvas);
  454.     canvas := G.CreateCanvas(cliWidth - (LEFT + RIGHT + 2 + RIGHT_PADDING), cliHeight - (TOP + BOTTOM + 1 - ClippingArea));
  455.     DEC(canvas.height, ClippingArea);
  456.     Tabs.setArea(tabs, LEFT, TOP - Tabs.tabHeight, cliWidth - (LEFT + RIGHT + 2 + RIGHT_PADDING), Tabs.tabHeight);
  457.     G.SetFont(canvas, font);
  458.     T.setCanvas(canvas);
  459.     T.resize(canvas.width, canvas.height);
  460.     Scroll.resize(vScroll, vScroll.width, canvas.height + 2);
  461.     Scroll.resize(hScroll, canvas.width + 1, hScroll.height);
  462. END resize;
  463.  
  464.  
  465. PROCEDURE SearchPanel (left, top: INTEGER);
  466. VAR
  467.     y, right, bottom: INTEGER;
  468. BEGIN
  469.     DEC(top, Tabs.tabHeight);
  470.     right := left + EditBox_Width + SEARCH_PADDING*2;
  471.     bottom := top + 395 + btnHeight + SEARCH_PADDING;
  472.     Rect(left, top, right, bottom, K.colors.line);
  473.  
  474.     K.CreateButton(btnCloseSearch, right - 20, top, 20, 20, Tabs.btnCloseColor, "");
  475.     K.DrawLine(right - 14, top + 5, right - 5, top + 14, 0FFFFFFH);
  476.     K.DrawLine(right - 15, top + 5, right - 5, top + 15, 0FFFFFFH);
  477.     K.DrawLine(right - 15, top + 6, right - 6, top + 15, 0FFFFFFH);
  478.     K.DrawLine(right - 15, top + 14, right - 6, top + 5, 0FFFFFFH);
  479.     K.DrawLine(right - 15, top + 15, right - 5, top + 5, 0FFFFFFH);
  480.     K.DrawLine(right - 14, top + 15, right - 5, top + 6, 0FFFFFFH);
  481.  
  482.     K.CreateButton(btnHideSearch, right - 40, top, 20, 20, K.colors.button, "");
  483.     K.DrawLine(right - 34, top + 14, right - 26, top + 14, K.colors.button_text);
  484.     K.DrawLine(right - 34, top + 15, right - 26, top + 15, K.colors.button_text);
  485.  
  486.     INC(top, 15);
  487.     INC(left, SEARCH_PADDING);
  488.     K.DrawText866(left, top, K.colors.work_text, "find");
  489.     K.DrawText866(left, top + 55, K.colors.work_text, "replace with");
  490.     K.DrawText866(left, top + 330, K.colors.work_text, "go to line");
  491.     BKW.top := top + 110;
  492.     BKW.left := left;
  493.     CS.top := top + 140;
  494.     CS.left := left;
  495.     WH.top := top + 170;
  496.     WH.left := left;
  497.     FindEdit.top := top + 20;
  498.     ReplaceEdit.top := top + 75;
  499.     GotoEdit.top := top + 350;
  500.     FindEdit.left := left;
  501.     ReplaceEdit.left := left;
  502.     GotoEdit.left := left;
  503.     EB.draw(FindEdit);
  504.     EB.draw(ReplaceEdit);
  505.     EB.draw(GotoEdit);
  506.     y := top + 200;
  507.     K.CreateButton(btnFindNext, left, y, btnWidth, btnHeight, K.colors.button, "next"); INC(y, btnHeight + 10);
  508.     K.CreateButton(btnReplace, left, y, btnWidth, btnHeight, K.colors.button, "replace"); INC(y, btnHeight + 10);
  509.     K.CreateButton(btnReplaceAll, left, y, btnWidth + 5*fontWidth - 2, btnHeight, K.colors.button, "replace all");
  510.     K.CreateButton(btnGoto, left, top + 380, btnWidth, btnHeight, K.colors.button, "go");
  511. END SearchPanel;
  512.  
  513.  
  514. PROCEDURE draw_window;
  515. VAR
  516.     width, height: INTEGER;
  517. BEGIN
  518.     K.BeginDraw;
  519.     K.CreateWindow(30 + K.GetTickCount() MOD 128, 30 + K.GetTickCount() MOD 128, winWidth, winHeight, K.colors.work, 73H, 0, 0, "");
  520.     IF (text # NIL) & ~K.RolledUp() THEN
  521.         IF confirm THEN
  522.                 resetTimer
  523.         END;
  524.         confirm := FALSE;
  525.         K.ClientSize(width, height);
  526.  
  527.         K.DrawRect(0, 0, width, TOP - 1, K.colors.work);
  528.         K.DrawRect(0, 0, LEFT, height, K.colors.work);
  529.         K.DrawRect(width - RIGHT_PADDING, 0, RIGHT_PADDING, height, K.colors.work);
  530.         K.DrawRect(LEFT + canvas.width + 1, TOP + canvas.height + 1, scrollWidth - 1, scrollWidth - 1, K.colors.work);
  531.         Menu.DrawMain(mainMenu);
  532.  
  533.         Toolbar.draw(toolbar);
  534.                 SetCaption(text.fileName);
  535.         Status(text, height);
  536.         IF search & searchOpened THEN
  537.             SearchPanel(LEFT_PADDING, TOP)
  538.         END;
  539.         Tabs.draw(tabs);
  540.         repaint
  541.     END;
  542.     K.EndDraw
  543. END draw_window;
  544.  
  545.  
  546. PROCEDURE mouse (VAR x, y: INTEGER);
  547. VAR
  548.     msState: SET;
  549. BEGIN
  550.         K.mouse(msState, x, y);
  551.         DEC(x, LEFT);
  552.         DEC(y, TOP)
  553. END mouse;
  554.  
  555.  
  556. PROCEDURE stopTimer;
  557. BEGIN
  558.         T.hideCursor;
  559.     timerEnabled := FALSE;
  560.     CursorTime := CurrentTime;
  561.     repaint
  562. END stopTimer;
  563.  
  564.  
  565. PROCEDURE OpenFile (VAR FileName: RW.tFileName; filter: ARRAY OF CHAR);
  566. BEGIN
  567.     stopTimer;
  568.     OpenDlg.SetFilter(OD, filter);
  569.     OpenDlg.Show(OD, 500, 400);
  570.     WHILE OD.status = 2 DO
  571.         K.Pause(30)
  572.     END;
  573.     IF OD.status = 1 THEN
  574.         COPY(OD.FilePath, FileName)
  575.     ELSE
  576.         FileName := ""
  577.     END;
  578.     resetTimer
  579. END OpenFile;
  580.  
  581.  
  582. PROCEDURE error (s: RW.tFileName);
  583. VAR
  584.     temp: RW.tFileName;
  585. BEGIN
  586.         temp := "'CEdit: ";
  587.         U.append8(temp, s);
  588.         U.append8(temp, "' -E");
  589.     K.Run("/sys/@notify", temp)
  590. END error;
  591.  
  592.  
  593. PROCEDURE saveError (name: RW.tFileName);
  594. VAR
  595.     s: RW.tFileName;
  596. BEGIN
  597.     s := "error saving file ";
  598.     U.append8(s, name);
  599.     error(s)
  600. END saveError;
  601.  
  602.  
  603. PROCEDURE saveAs (text: T.tText);
  604. VAR
  605.     fileName, name: RW.tFileName;
  606.     ext: ARRAY 8 OF CHAR;
  607. BEGIN
  608.     OD._type := OpenDlg.tsave;
  609.     U.getFileName(text.fileName, OD.FileName, U.SLASH);
  610.     IF OD.FileName = "" THEN
  611.         OD.FileName := "NewFile.";
  612.         Languages.getExt(text.lang, ext);
  613.         U.append8(OD.FileName, ext)
  614.     END;
  615.     OpenFile(fileName, EditFilter);
  616.     IF fileName # "" THEN
  617.         IF T.save(text, fileName) THEN
  618.             T.setName(text, fileName);
  619.             U.getFileName(fileName, name, U.SLASH);
  620.             Tabs.rename(tabs, curText, name)
  621.         ELSE
  622.             saveError(fileName)
  623.         END
  624.     END
  625. END saveAs;
  626.  
  627.  
  628. PROCEDURE Switch (txt: T.tText);
  629. BEGIN
  630.     Tabs.switch(tabs, curText);
  631.     text := txt;
  632.     T.switch(txt);
  633.     switch := TRUE
  634. END Switch;
  635.  
  636.  
  637. PROCEDURE save (text: T.tText);
  638. BEGIN
  639.     IF text.modified THEN
  640.         IF text.fileName # "" THEN
  641.             IF ~T.save(text, text.fileName) THEN
  642.                 saveError(text.fileName)
  643.             END
  644.         ELSE
  645.             curText := getIdx(text);
  646.             Switch(text);
  647.             saveAs(text)
  648.         END;
  649.                 Tabs.modify(tabs, getIdx(text), text.modified)
  650.     END
  651. END save;
  652.  
  653.  
  654. PROCEDURE saveAll;
  655. VAR
  656.     i: INTEGER;
  657.     txt: T.tText;
  658. BEGIN
  659.     i := textsCount - 1;
  660.     WHILE i >= 0 DO
  661.         txt := texts[i];
  662.         IF txt.modified THEN
  663.                 T.switch(txt);
  664.             save(txt)
  665.         END;
  666.         DEC(i)
  667.     END;
  668.     T.switch(text)
  669. END saveAll;
  670.  
  671.  
  672. PROCEDURE insert (pos: INTEGER; txt: T.tText);
  673. VAR
  674.     i: INTEGER;
  675.     name: RW.tFileName;
  676. BEGIN
  677.     FOR i := textsCount - 1 TO pos BY -1 DO
  678.         texts[i + 1] := texts[i]
  679.     END;
  680.     texts[pos] := txt;
  681.     INC(textsCount);
  682.     curText := pos;
  683.     IF txt.fileName = "" THEN
  684.         name := "new"
  685.     ELSE
  686.         U.getFileName(txt.fileName, name, U.SLASH)
  687.     END;
  688.     Tabs.add(tabs, name);
  689.     Switch(txt)
  690. END insert;
  691.  
  692.  
  693. PROCEDURE Confirm;
  694. CONST
  695.     width  = btnWidth*2 + 30;
  696.     height = btnHeight*2 + 20;
  697. VAR
  698.     left, top, right, bottom: INTEGER;
  699. BEGIN
  700.         stopTimer;
  701.     draw_window;
  702.     confirm := TRUE;
  703.     left := (canvas.width - width) DIV 2 + LEFT;
  704.     top := (canvas.height - height) DIV 2 + TOP;
  705.     right := left + width - 1;
  706.     bottom := top + height - 1;
  707.     K.DrawRect(left, top, width, height, K.colors.work);
  708.     Rect(left, top, right, bottom, K.colors.line);
  709.     K.DrawText866(left + (width - 10*fontWidth) DIV 2, top + 10, K.colors.work_text, "save file?");
  710.     K.CreateButton(btnYes, left + 10, top + 35, btnWidth, btnHeight, K.colors.button, "yes");
  711.     K.CreateButton(btnNo, left + 20 + btnWidth, top + 35, btnWidth, btnHeight, K.colors.button, "no");
  712. END Confirm;
  713.  
  714.  
  715. PROCEDURE closeFile (conf: BOOLEAN; n: INTEGER);
  716. VAR
  717.     i: INTEGER;
  718. BEGIN
  719.     IF texts[n].modified & conf THEN
  720.         Confirm
  721.     ELSE
  722.         Tabs.delete(tabs, n);
  723.         T.destroy(texts[n]);
  724.         FOR i := n + 1 TO textsCount - 1 DO
  725.             texts[i - 1] := texts[i]
  726.         END;
  727.         DEC(textsCount);
  728.         IF (curText = textsCount) OR (n < curText) THEN
  729.             DEC(curText)
  730.         END;
  731.         IF curText >= 0 THEN
  732.             Switch(texts[curText])
  733.         ELSE
  734.             K.Exit
  735.         END;
  736.         draw_window
  737.     END
  738. END closeFile;
  739.  
  740.  
  741. PROCEDURE getFileNum (fileName: RW.tFileName): INTEGER;
  742. VAR
  743.     i: INTEGER;
  744.  
  745.     PROCEDURE nameEq (name1, name2: RW.tFileName): BOOLEAN;
  746.     VAR
  747.         n1, n2: RW.tFileName;
  748.     BEGIN
  749.         n1 := name1;
  750.         n2 := name2;
  751.         U.lowcase8(n1);
  752.         U.lowcase8(n2)
  753.         RETURN n1 = n2
  754.     END nameEq;
  755.  
  756. BEGIN
  757.     i := 0;
  758.     WHILE (i < textsCount) & ~nameEq(texts[i].fileName, fileName) DO
  759.         INC(i)
  760.     END;
  761.     IF i = textsCount THEN
  762.         i := -1
  763.     END
  764.     RETURN i
  765. END getFileNum;
  766.  
  767.  
  768. PROCEDURE SwitchTab (n: INTEGER);
  769. BEGIN
  770.         curText := n;
  771.         Tabs.switch(tabs, n);
  772.         Switch(texts[n]);
  773.         resetTimer;
  774.         IF ~newtab THEN
  775.                 draw_window
  776.         END
  777. END SwitchTab;
  778.  
  779.  
  780. PROCEDURE NewFile;
  781. VAR
  782.         nov: T.tText;
  783. BEGIN
  784.         IF textsCount < maxTexts THEN
  785.                 nov := T.New();
  786.                 T.SetPos(nov, 0, 0);
  787.                 insert(textsCount, nov);
  788.                 newtab := TRUE;
  789.                 SwitchTab(curText)
  790.         ELSE
  791.                 error("too many files")
  792.         END
  793. END NewFile;
  794.  
  795.  
  796. PROCEDURE open (_fileName: RW.tFileName): BOOLEAN;
  797. VAR
  798.         fileName: RW.tFileName;
  799.     nov: T.tText;
  800.     err, n: INTEGER;
  801.     res, empty: BOOLEAN;
  802. BEGIN
  803.         res := TRUE;
  804.     IF textsCount < maxTexts THEN
  805.         fileName := _fileName;
  806.         IF fileName = "" THEN
  807.                 OD._type := OpenDlg.topen;
  808.                 OpenFile(fileName, EditFilter)
  809.         END;
  810.         IF fileName # "" THEN
  811.             n := getFileNum(fileName);
  812.             IF n = -1 THEN
  813.                 nov := T.open(fileName, 0, 0, err);
  814.                 IF nov = NIL THEN
  815.                     error("error opening file");
  816.                     SwitchTab(curText);
  817.                     res := FALSE
  818.                 ELSE
  819.                         T.switch(text);
  820.                         empty := (textsCount = 1) & (text.fileName = "") & T.empty(text) &
  821.                                 ChangeLog.isFirstGuard(text.edition) & ChangeLog.isLastGuard(text.edition);
  822.                         T.switch(nov);
  823.                         T.SetPos(nov, 0, 0);
  824.                     insert(textsCount, nov);
  825.                     IF empty THEN
  826.                         closeFile(FALSE, 0)
  827.                     END;
  828.                     Scroll.setValue(hScroll, 0);
  829.                     Scroll.setValue(vScroll, 0)
  830.                 END
  831.             ELSE
  832.                 SwitchTab(n)
  833.             END
  834.         END
  835.     ELSE
  836.         error("too many files");
  837.         res := FALSE
  838.     END
  839.     RETURN res
  840. END open;
  841.  
  842.  
  843. PROCEDURE OpenDial;
  844. VAR
  845.         res: BOOLEAN;
  846. BEGIN
  847.         res := open("")
  848. END OpenDial;
  849.  
  850.  
  851. PROCEDURE createSearchForm;
  852. BEGIN
  853.         EB.create(LEFT_PADDING, TOP + 20, EditBox_Width, EDITBOX_MAXCHARS, FindEdit);
  854.         EB.create(LEFT_PADDING, TOP + 20 + 55, EditBox_Width, EDITBOX_MAXCHARS, ReplaceEdit);
  855.     EB.create(LEFT_PADDING, TOP + 20 + 330, EditBox_Width, EDITBOX_MAXCHARS, GotoEdit);
  856.     INCL(GotoEdit.flags, 15);
  857.     CheckBox.create("backward", BKW);
  858.     CheckBox.create("match case", CS);
  859.     CheckBox.create("whole word", WH);
  860. END createSearchForm;
  861.  
  862.  
  863. PROCEDURE EditBox_Get (edit: EB.tEditBox; VAR s: ARRAY OF WCHAR);
  864. VAR
  865.     str: ARRAY EDITBOX_MAXCHARS + 1 OF CHAR;
  866.     i: INTEGER;
  867. BEGIN
  868.     EB.get(edit, str);
  869.     i := 0;
  870.     WHILE str[i] # 0X DO
  871.         s[i] := WCHR(E.cp866[ORD(str[i])]);
  872.         INC(i)
  873.     END;
  874.     s[i] := 0X
  875. END EditBox_Get;
  876.  
  877.  
  878. PROCEDURE Search;
  879. BEGIN
  880.     search := ~search;
  881.     LEFT := LEFT_PADDING;
  882.     IF search THEN
  883.         searchOpened := TRUE;
  884.         INC(LEFT, EditBox_Width + SEARCH_PADDING*2 + 4);
  885.         IF T.search(text, searchText, cs, whole) THEN END
  886.     ELSE
  887.         IF T.search(text, "", FALSE, FALSE) THEN END
  888.     END;
  889.     SetFocus(FindEdit, search);
  890.     resize;
  891.     draw_window
  892. END Search;
  893.  
  894.  
  895. PROCEDURE click (x, y: INTEGER): INTEGER;
  896. VAR
  897.     scrollX, scrollY: INTEGER;
  898.     shift, ctrl: BOOLEAN;
  899. BEGIN
  900.     K.getKBState(shift, ctrl);
  901.     T.getScroll(text, scrollX, scrollY);
  902.     T.scroll(text, hScroll.value - scrollX, vScroll.value - scrollY);
  903.     IF U.between(0, x, canvas.width - 1) & U.between(0, y, canvas.height - 1) THEN
  904.         leftButton := TRUE;
  905.         SetFocus(FindEdit, FALSE);
  906.         IF ~shift THEN
  907.             T.resetSelect(text)
  908.         END;
  909.         T.mouse(text, x, y)
  910.     END;
  911.     repaint
  912.     RETURN K.GetTickCount()
  913. END click;
  914.  
  915.  
  916. PROCEDURE Close;
  917. VAR
  918.     cont: BOOLEAN;
  919. BEGIN
  920.     closing := TRUE;
  921.     cont := TRUE;
  922.     WHILE (textsCount > 0) & cont DO
  923.         IF text.modified THEN
  924.             Confirm;
  925.             cont := FALSE
  926.         ELSE
  927.             closeFile(FALSE, curText);
  928.             repaint
  929.         END
  930.     END
  931. END Close;
  932.  
  933.  
  934. PROCEDURE CloseMenu;
  935. BEGIN
  936.     Menu.close(subEOL);
  937.     Menu.close(subCurLine);
  938.     Menu.close(subIndent);
  939.     Menu.close(subCase);
  940.     Menu.close(subBookmark);
  941.     Menu.close(menuFile);
  942.     Menu.close(menuEdit);
  943.     Menu.close(menuSearch);
  944.     Menu.close(menuEncoding);
  945.     Menu.close(menuView);
  946.     Menu.close(menuLanguage);
  947.     Menu.close(menuProgram);
  948.     Menu.close(menuTools);
  949.     Menu.close(menuOptions);
  950.     Menu.close(context)
  951. END CloseMenu;
  952.  
  953.  
  954. PROCEDURE goto;
  955. VAR
  956.     gotoVal: INTEGER;
  957. BEGIN
  958.     EditBox_Get(GotoEdit, gotoText);
  959.     IF U.str2int(gotoText, gotoVal) & T.goto(text, gotoVal) THEN
  960.         SetFocus(GotoEdit, FALSE)
  961.     END
  962. END goto;
  963.  
  964.  
  965. PROCEDURE Script (script: ARRAY OF CHAR);
  966. BEGIN
  967.     IF script # "" THEN
  968.         U.getPath(script, CurFolder);
  969.         K.SetCurFolder(CurFolder);
  970.         K.Run("/sys/@open", script)
  971.     END
  972. END Script;
  973.  
  974.  
  975. PROCEDURE ShowSearchPanel (goto: BOOLEAN);
  976. VAR
  977.         i: INTEGER;
  978. BEGIN
  979.         IF T.selected(text) & ~goto THEN
  980.                 T.getSelectedText(text, new_searchText);
  981.                 IF new_searchText # "" THEN
  982.                         i := 0;
  983.                         WHILE (new_searchText[i] # 0X) & (new_searchText[i] # Lines.TAB) DO
  984.                                 INC(i)
  985.                         END;
  986.                         IF new_searchText[i] = 0X THEN
  987.                                 searchText := new_searchText;
  988.                                 EB.set(FindEdit, searchText);
  989.                                 notFound := ~T.search(text, searchText, cs, whole);
  990.                         END
  991.                 END
  992.         END;
  993.     IF ~search THEN
  994.         Search
  995.     ELSIF ~searchOpened THEN
  996.         search := FALSE;
  997.         Search
  998.     END;
  999.     IF goto THEN
  1000.         SetFocus(GotoEdit, TRUE)
  1001.     ELSE
  1002.         SetFocus(FindEdit, TRUE)
  1003.     END
  1004. END ShowSearchPanel;
  1005.  
  1006.  
  1007. PROCEDURE CanvasToScreen (VAR x, y: INTEGER);
  1008. VAR
  1009.     cliX, cliY,
  1010.     winX, winY: INTEGER;
  1011. BEGIN
  1012.     K.WinPos(winX, winY);
  1013.     K.ClientPos(cliX, cliY);
  1014.     x := x + winX + cliX + LEFT;
  1015.     y := y + winY + cliY + TOP;
  1016. END CanvasToScreen;
  1017.  
  1018.  
  1019. PROCEDURE ShowMenu (menu: Menu.tMenu);
  1020. VAR
  1021.     winX, winY, cliX, cliY, x, y, i: INTEGER;
  1022.     selected, enabled: BOOLEAN;
  1023. BEGIN
  1024.     IF menu = context THEN
  1025.         mouse(x, y);
  1026.         IF ~(U.between(0, x, canvas.width - 1) & U.between(0, y, canvas.height - 1)) THEN
  1027.             menu := NIL
  1028.         END
  1029.     ELSE
  1030.         K.WinPos(winX, winY);
  1031.         K.ClientPos(cliX, cliY);
  1032.         x := winX + cliX;
  1033.         y := Menu.MainMenuHeight + winY + cliY
  1034.     END;
  1035.     selected := T.selected(text);
  1036.  
  1037.     IF menu = menuFile THEN
  1038.         Menu.setEnabled(menu, menuSave, text.modified);
  1039.         Menu.setEnabled(menu, menuFolder, text.fileName # "");
  1040.         i := 0;
  1041.         WHILE (i < textsCount) & ~texts[i].modified DO
  1042.             INC(i)
  1043.         END;
  1044.         Menu.setEnabled(menu, menuSaveAll, i < textsCount)
  1045.     ELSIF (menu = menuEdit) OR (menu = context) THEN
  1046.         Menu.setEnabled(menu, menuUndo, ~ChangeLog.isFirstGuard(text.edition));
  1047.         Menu.setEnabled(menu, menuRedo, ~ChangeLog.isLastGuard(text.edition));
  1048.         Menu.setEnabled(menu, menuCut, selected);
  1049.         Menu.setEnabled(menu, menuCopy, selected);
  1050.         Menu.setEnabled(menu, menuDelete, selected);
  1051.         Menu.setEnabled(menu, menuPaste, CB.available());
  1052.         IF menu = context THEN
  1053.             IF y + menu.height >= canvas.height THEN
  1054.                 DEC(y, menu.height)
  1055.             END;
  1056.             IF x + menu.width >= canvas.width THEN
  1057.                 DEC(x, menu.width)
  1058.             END;
  1059.             CanvasToScreen(x, y);
  1060.             menu.x := x;
  1061.             x := 0
  1062.         END
  1063.     ELSIF menu = menuEncoding THEN
  1064.         Menu.option(menu, menuUTF8BOM, T.getEnc(text) = E.UTF8BOM);
  1065.         Menu.option(menu, menuUTF8,    T.getEnc(text) = E.UTF8);
  1066.         Menu.option(menu, menuCP866,   T.getEnc(text) = E.CP866);
  1067.         Menu.option(menu, menuCP1251,  T.getEnc(text) = E.CP1251)
  1068.     ELSIF menu = menuView THEN
  1069.         Menu.option(menu, menuFontSmall,  font = G.fonts[0]);
  1070.         Menu.option(menu, menuFontMedium, font = G.fonts[1]);
  1071.         Menu.option(menu, menuFontLarge,  font = G.fonts[2]);
  1072.         FOR i := 0 TO Ini.sections.count - 1 DO
  1073.             Menu.option(menu, menuColors + i, Ini.curSectionNum = i)
  1074.         END
  1075.     ELSIF menu = menuLanguage THEN
  1076.         Menu.option(menu, menuText,   text.lang = Languages.langText);
  1077.         Menu.option(menu, menuC,      text.lang = Languages.langC);
  1078.         Menu.option(menu, menuFasm,   text.lang = Languages.langFasm);
  1079.         Menu.option(menu, menuIni,    text.lang = Languages.langIni);
  1080.         Menu.option(menu, menuJSON,   text.lang = Languages.langJSON);
  1081.         Menu.option(menu, menuLua,    text.lang = Languages.langLua);
  1082.         Menu.option(menu, menuOberon, text.lang = Languages.langOberon);
  1083.         Menu.option(menu, menuPascal, text.lang = Languages.langPascal);
  1084.     ELSIF menu = menuProgram THEN
  1085.         Menu.setEnabled(menu, menuBuild, (buildScript # "") OR text.fasm);
  1086.         Menu.setEnabled(menu, menuDebug, (debugScript # "") OR text.fasm);
  1087.         Menu.setEnabled(menu, menuRun,   (runScript # "") OR text.fasm);
  1088.         Menu.setEnabled(menu, menuBuildScript, ~text.fasm);
  1089.         Menu.setEnabled(menu, menuDebugScript, ~text.fasm);
  1090.         Menu.setEnabled(menu, menuRunScript,   ~text.fasm);
  1091.         Menu.check(menu, menuFASM, text.fasm)
  1092.     ELSIF menu = menuOptions THEN
  1093.         Menu.check(menu, menuLineNumbers,  T.lineNumbers);
  1094.         Menu.check(menu, menuAutoIndents,  T.autoIndents);
  1095.         Menu.check(menu, menuAutoBrackets, T.autoBrackets);
  1096.         Menu.check(menu, menuTrimSpace,    T.trimSpace)
  1097.     END;
  1098.  
  1099.     enabled := search & (searchText # "");
  1100.     Menu.setEnabled(menuSearch, menuFindNext, enabled);
  1101.     Menu.setEnabled(menuSearch, menuFindPrev, enabled);
  1102.  
  1103.     Menu.setEnabled(subIndent, menuIncInd, selected);
  1104.     Menu.setEnabled(subIndent, menuDecInd, selected);
  1105.  
  1106.     Menu.setEnabled(subCase, menuUpper, selected);
  1107.     Menu.setEnabled(subCase, menuLower, selected);
  1108.  
  1109.         Menu.option(subEOL, menuCRLF, T.getEol(text) = E.EOL_CRLF);
  1110.         Menu.option(subEOL, menuLF,   T.getEol(text) = E.EOL_LF);
  1111.         Menu.option(subEOL, menuCR,   T.getEol(text) = E.EOL_CR);
  1112.  
  1113.     IF menu # NIL THEN
  1114.         timerEnabled := FALSE;
  1115.         IF Menu.opened(menu) THEN
  1116.             Menu.close(menu)
  1117.         END;
  1118.         Menu.open(menu, menu.x + x, y);
  1119.         menuActive := TRUE
  1120.     END
  1121. END ShowMenu;
  1122.  
  1123.  
  1124. PROCEDURE setScript (VAR script: RW.tFileName);
  1125. VAR
  1126.         temp: RW.tFileName;
  1127. BEGIN
  1128.         OpenFile(temp, ShellFilter);
  1129.         IF temp # "" THEN
  1130.                 script := temp
  1131.         END
  1132. END setScript;
  1133.  
  1134.  
  1135. PROCEDURE FasmCompile (run, debug: BOOLEAN);
  1136. VAR
  1137.         curFileName, ext, outfile, path, param: RW.tFileName;
  1138. BEGIN
  1139.         curFileName := texts[curText].fileName;
  1140.         U.getFileName(curFileName, param, U.SLASH);
  1141.         U.getFileName(curFileName, ext, ".");
  1142.         U.getPath(curFileName, path);
  1143.         outfile := param;
  1144.         IF (ext # "") & ((LENGTH(ext) + 1) < LENGTH(outfile)) THEN
  1145.                 outfile[LENGTH(outfile) - LENGTH(ext) - 1] := 0X
  1146.         ELSE
  1147.                 U.append8(outfile, ".kex")
  1148.         END;
  1149.         U.append8(param, ",");
  1150.         U.append8(param, outfile);
  1151.         U.append8(param, ",");
  1152.         U.append8(param, path);
  1153.         U.append8(param, U.SLASH);
  1154.         IF run THEN
  1155.                 U.append8(param, ",run")
  1156.         ELSIF debug THEN
  1157.                 U.append8(param, ",dbg")
  1158.         END;
  1159.         K.Run("/sys/develop/fasm", param)
  1160. END FasmCompile;
  1161.  
  1162.  
  1163. PROCEDURE ProgramBuild;
  1164. BEGIN
  1165.         IF ~text.fasm THEN
  1166.         Script(buildScript)
  1167.     ELSE
  1168.         FasmCompile(FALSE, FALSE)
  1169.     END
  1170. END ProgramBuild;
  1171.  
  1172.  
  1173. PROCEDURE ProgramRun;
  1174. BEGIN
  1175.         IF ~text.fasm THEN
  1176.         Script(runScript)
  1177.     ELSE
  1178.         FasmCompile(TRUE, FALSE)
  1179.     END
  1180. END ProgramRun;
  1181.  
  1182.  
  1183. PROCEDURE ProgramDebug;
  1184. BEGIN
  1185.         IF ~text.fasm THEN
  1186.         Script(debugScript)
  1187.     ELSE
  1188.         FasmCompile(FALSE, TRUE)
  1189.     END
  1190. END ProgramDebug;
  1191.  
  1192.  
  1193. PROCEDURE ClickMenu;
  1194. VAR
  1195.         item: List.tItem;
  1196. BEGIN
  1197.         IF Menu.MenuItem < 0 THEN
  1198.                 item := List.getItem(mainMenu, (-Menu.MenuItem - mainMenuBtn) MOD mainMenu.count);
  1199.                 IF item # NIL THEN
  1200.                         ShowMenu(item(Menu.tMainItem).menu)
  1201.                 END;
  1202.                 Menu.SetItem(0)
  1203.         END;
  1204.     CASE Menu.MenuItem OF
  1205.     |0:
  1206.     |menuCut:       T.key(text, ORD("X"), FALSE, TRUE)
  1207.     |menuCopy:      T.key(text, ORD("C"), FALSE, TRUE)
  1208.     |menuPaste:     T.key(text, ORD("V"), FALSE, TRUE)
  1209.     |menuDelete:    T.key(text,       46, FALSE, FALSE)
  1210.     |menuSelectAll: T.key(text, ORD("A"), FALSE, TRUE)
  1211.  
  1212.     |menuNew:
  1213.         NewFile
  1214.     |menuOpen:
  1215.         OpenDial
  1216.     |menuSave:
  1217.         save(text);
  1218.         repaint
  1219.     |menuSaveAs:
  1220.         saveAs(text);
  1221.         repaint
  1222.     |menuSaveAll:
  1223.         saveAll;
  1224.         repaint
  1225.     |menuClose:
  1226.         closeFile(TRUE, curText)
  1227.     |menuFolder:
  1228.         K.Run("/sys/File Managers/Eolite", text.fileName)
  1229.     |menuExit:
  1230.         Close
  1231.     |menuUndo:
  1232.         T.undo(text);
  1233.         repaint
  1234.     |menuRedo:
  1235.         T.redo(text);
  1236.         repaint
  1237.     |menuFind:
  1238.         ShowSearchPanel(FALSE)
  1239.     |menuFindNext:
  1240.         notFound := ~T.findNext(text, BKW.value);
  1241.         menuFindClicked := TRUE
  1242.     |menuFindPrev:
  1243.         notFound := ~T.findNext(text, ~BKW.value);
  1244.         menuFindClicked := TRUE
  1245.     |menuGoto:
  1246.         ShowSearchPanel(TRUE)
  1247.     |menuToggleBookmark:
  1248.         T.toggleLabel(text)
  1249.     |menuNextBookmark:
  1250.         T.gotoLabel(text, TRUE)
  1251.     |menuPrevBookmark:
  1252.         T.gotoLabel(text, FALSE)
  1253.     |menuFontSmall..menuFontLarge:
  1254.         font := G.fonts[Menu.MenuItem - menuFontSmall];
  1255.         Ini.setInt("settings", "font", Menu.MenuItem - menuFontSmall);
  1256.         resize
  1257.     |menuText:
  1258.         T.setLang(text, Languages.langText)
  1259.     |menuC:
  1260.         T.setLang(text, Languages.langC)
  1261.     |menuFasm:
  1262.         T.setLang(text, Languages.langFasm)
  1263.     |menuIni:
  1264.         T.setLang(text, Languages.langIni)
  1265.     |menuJSON:
  1266.         T.setLang(text, Languages.langJSON)
  1267.     |menuLua:
  1268.         T.setLang(text, Languages.langLua)
  1269.     |menuOberon:
  1270.         T.setLang(text, Languages.langOberon)
  1271.     |menuPascal:
  1272.         T.setLang(text, Languages.langPascal)
  1273.     |menuBuild:
  1274.         ProgramBuild
  1275.     |menuBuildScript:
  1276.         setScript(buildScript)
  1277.     |menuRun:
  1278.         ProgramRun
  1279.     |menuRunScript:
  1280.         setScript(runScript)
  1281.     |menuDebug:
  1282.         ProgramDebug
  1283.     |menuDebugScript:
  1284.         setScript(debugScript)
  1285.     |menuFASM:
  1286.         text.fasm := ~text.fasm
  1287.     |menuUTF8BOM:
  1288.         T.setEnc(text, E.UTF8BOM)
  1289.     |menuUTF8:
  1290.         T.setEnc(text, E.UTF8)
  1291.     |menuCP866:
  1292.         T.setEnc(text, E.CP866)
  1293.     |menuCP1251:
  1294.         T.setEnc(text, E.CP1251)
  1295.     |menuLF:
  1296.         T.setEol(text, E.EOL_LF)
  1297.     |menuCRLF:
  1298.         T.setEol(text, E.EOL_CRLF)
  1299.     |menuCR:
  1300.         T.setEol(text, E.EOL_CR)
  1301.     |menuConv1251_866:
  1302.         T.convert(text, (*E.cp866,*) E.CP1251)
  1303.     |menuConv866_1251:
  1304.         T.convert(text, (*E.cp1251,*) E.CP866)
  1305.     |menuPipet:
  1306.         K.Run("/sys/develop/pipet", "")
  1307.     |menuMagnify:
  1308.         K.Run("/sys/magnify", "")
  1309.     |menuBoard:
  1310.         K.Run("/sys/develop/board", "")
  1311.     |menuSysFunc:
  1312.         K.Run("/sys/docpack", "f")
  1313.     |menuLineNumbers:
  1314.         T.toggleNumbers;
  1315.         Ini.setInt("settings", "line_numbers", ORD(T.lineNumbers))
  1316.     |menuAutoIndents:
  1317.         T.toggleIndents;
  1318.         Ini.setInt("settings", "auto_indents", ORD(T.autoIndents))
  1319.     |menuAutoBrackets:
  1320.         T.toggleBrackets;
  1321.         Ini.setInt("settings", "auto_brackets", ORD(T.autoBrackets))
  1322.     |menuTrimSpace:
  1323.         T.toggleTrimSpace;
  1324.         Ini.setInt("settings", "trim_space", ORD(T.trimSpace))
  1325.     |menuColors..menuMaxColors:
  1326.         Ini.selectSection(Menu.MenuItem - menuColors);
  1327.         Ini.setInt("settings", "theme", Menu.MenuItem - menuColors)
  1328.     |menuMoveUp:
  1329.         T.MoveLines(text, FALSE)
  1330.     |menuMoveDown:
  1331.                 T.MoveLines(text, TRUE)
  1332.     |menuDuplicate:
  1333.         T.dupLine(text)
  1334.     |menuRemove:
  1335.         T.delLine(text)
  1336.     |menuIncInd:
  1337.         T.Indent(text, TRUE)
  1338.         |menuDecInd:
  1339.                 T.Indent(text, FALSE)
  1340.         |menuUpper:
  1341.                 T.chCase(text, TRUE)
  1342.         |menuLower:
  1343.                 T.chCase(text, FALSE)
  1344.     END;
  1345.     Menu.SetItem(0)
  1346. END ClickMenu;
  1347.  
  1348.  
  1349. PROCEDURE CreateContextMenu (): Menu.tMenu;
  1350. VAR
  1351.     menu: List.tList;
  1352. BEGIN
  1353.     menu := List.create(NIL);
  1354.     Menu.AddMenuItem(menu, menuUndo,      "undo         ctrl-Z");
  1355.     Menu.AddMenuItem(menu, menuRedo,      "redo         ctrl-Y");
  1356.     Menu.delimiter(menu);
  1357.     Menu.AddMenuItem(menu, menuCut,       "cut          ctrl-X");
  1358.     Menu.AddMenuItem(menu, menuCopy,      "copy         ctrl-C");
  1359.     Menu.AddMenuItem(menu, menuPaste,     "paste        ctrl-V");
  1360.     Menu.AddMenuItem(menu, menuDelete,    "delete");
  1361.     Menu.delimiter(menu);
  1362.     Menu.AddMenuItem(menu, menuSelectAll, "select all   ctrl-A");
  1363.     RETURN Menu.create(menu, mainTID)
  1364. END CreateContextMenu;
  1365.  
  1366.  
  1367. PROCEDURE CreateMenuFile (): Menu.tMenu;
  1368. VAR
  1369.     menu: List.tList;
  1370. BEGIN
  1371.     menu := List.create(NIL);
  1372.     Menu.AddMenuItem(menu, menuNew,     "new         ctrl-N");
  1373.     Menu.AddMenuItem(menu, menuOpen,    "open        ctrl-O");
  1374.     Menu.AddMenuItem(menu, menuSave,    "save        ctrl-S");
  1375.     Menu.AddMenuItem(menu, menuSaveAs,  "save as");
  1376.     Menu.AddMenuItem(menu, menuSaveAll, "save all");
  1377.     Menu.AddMenuItem(menu, menuFolder,  "folder");
  1378.     Menu.delimiter(menu);
  1379.     Menu.AddMenuItem(menu, menuClose,   "close       ctrl-W");
  1380.     Menu.delimiter(menu);
  1381.     Menu.AddMenuItem(menu, menuExit,    "exit");
  1382.     RETURN Menu.create(menu, mainTID)
  1383. END CreateMenuFile;
  1384.  
  1385.  
  1386. PROCEDURE CreateMenuEdit (): Menu.tMenu;
  1387. VAR
  1388.     menu: List.tList;
  1389. BEGIN
  1390.     menu := List.create(NIL);
  1391.     Menu.AddMenuItem(menu, menuUndo,      "undo            ctrl-Z");
  1392.     Menu.AddMenuItem(menu, menuRedo,      "redo            ctrl-Y");
  1393.     Menu.delimiter(menu);
  1394.     Menu.AddMenuItem(menu, menuCut,       "cut             ctrl-X");
  1395.     Menu.AddMenuItem(menu, menuCopy,      "copy            ctrl-C");
  1396.     Menu.AddMenuItem(menu, menuPaste,     "paste           ctrl-V");
  1397.     Menu.AddMenuItem(menu, menuDelete,    "delete");
  1398.     Menu.delimiter(menu);
  1399.     Menu.AddMenuItem(menu, menuSelectAll, "select all      ctrl-A");
  1400.     Menu.delimiter(menu);
  1401.     Menu.AddMenuItem(menu, menuCurLine,   "current line");
  1402.     Menu.child(menu, subCurLine);
  1403.     Menu.AddMenuItem(menu, menuIndent,    "indent");
  1404.     Menu.child(menu, subIndent);
  1405.     Menu.AddMenuItem(menu, menuCase,      "case");
  1406.     Menu.child(menu, subCase);
  1407.     RETURN Menu.create(menu, mainTID)
  1408. END CreateMenuEdit;
  1409.  
  1410.  
  1411. PROCEDURE CreateMenuSearch (): Menu.tMenu;
  1412. VAR
  1413.     menu: List.tList;
  1414. BEGIN
  1415.     menu := List.create(NIL);
  1416.     Menu.AddMenuItem(menu, menuFind,     "search           ctrl-F");
  1417.     Menu.AddMenuItem(menu, menuFindNext, "find next        F3");
  1418.     Menu.AddMenuItem(menu, menuFindPrev, "find previous    shift-F3");
  1419.     Menu.AddMenuItem(menu, menuGoto,     "go to line       ctrl-G");
  1420.     Menu.delimiter(menu);
  1421.     Menu.AddMenuItem(menu, menuBookmark, "bookmark");
  1422.     Menu.child(menu, subBookmark);
  1423.     RETURN Menu.create(menu, mainTID)
  1424. END CreateMenuSearch;
  1425.  
  1426.  
  1427. PROCEDURE CreateMenuEncoding (): Menu.tMenu;
  1428. VAR
  1429.     menu: List.tList;
  1430. BEGIN
  1431.     menu := List.create(NIL);
  1432.     Menu.AddMenuItem(menu, menuUTF8BOM, E.names[E.UTF8BOM]);
  1433.     Menu.AddMenuItem(menu, menuUTF8,    E.names[E.UTF8]);
  1434.     Menu.AddMenuItem(menu, menuCP866,   E.names[E.CP866]);
  1435.     Menu.AddMenuItem(menu, menuCP1251,  E.names[E.CP1251]);
  1436.     Menu.delimiter(menu);
  1437.     Menu.AddMenuItem(menu, menuConv1251_866, "convert 1251 >> 866");
  1438.     Menu.AddMenuItem(menu, menuConv866_1251, "convert 866 >> 1251");
  1439.     Menu.delimiter(menu);
  1440.     Menu.AddMenuItem(menu, menuEOL,     "EOL");
  1441.     Menu.child(menu, subEOL);
  1442.     RETURN Menu.create(menu, mainTID)
  1443. END CreateMenuEncoding;
  1444.  
  1445.  
  1446. PROCEDURE CreateMenuEOL (): Menu.tMenu;
  1447. VAR
  1448.     menu: List.tList;
  1449. BEGIN
  1450.     menu := List.create(NIL);
  1451.     Menu.AddMenuItem(menu, menuCRLF, E.eolNames[E.EOL_CRLF]);
  1452.     Menu.AddMenuItem(menu, menuLF,   E.eolNames[E.EOL_LF]);
  1453.     Menu.AddMenuItem(menu, menuCR,   E.eolNames[E.EOL_CR]);
  1454.     RETURN Menu.create(menu, mainTID)
  1455. END CreateMenuEOL;
  1456.  
  1457.  
  1458. PROCEDURE CreateMenuView (): Menu.tMenu;
  1459. VAR
  1460.     menu: List.tList;
  1461.     colors: Ini.tSection;
  1462.     idx: INTEGER;
  1463. BEGIN
  1464.     menu := List.create(NIL);
  1465.     Menu.AddMenuItem(menu, menuFontSmall,  "small");
  1466.     Menu.AddMenuItem(menu, menuFontMedium, "medium");
  1467.     Menu.AddMenuItem(menu, menuFontLarge,  "large");
  1468.     Menu.delimiter(menu);
  1469.  
  1470.     colors := Ini.sections.first(Ini.tSection);
  1471.     idx := menuColors;
  1472.     WHILE colors # NIL DO
  1473.         Menu.AddMenuItem(menu, idx, colors.name);
  1474.         INC(idx);
  1475.         colors := colors.next(Ini.tSection)
  1476.     END;
  1477.  
  1478.     RETURN Menu.create(menu, mainTID)
  1479. END CreateMenuView;
  1480.  
  1481.  
  1482. PROCEDURE CreateMenuLanguage (): Menu.tMenu;
  1483. VAR
  1484.     menu: List.tList;
  1485. BEGIN
  1486.     menu := List.create(NIL);
  1487.     Menu.AddMenuItem(menu, menuC,      "C");
  1488.     Menu.AddMenuItem(menu, menuFasm,   "Fasm");
  1489.     Menu.AddMenuItem(menu, menuIni,    "Ini");
  1490.     Menu.AddMenuItem(menu, menuJSON,   "JSON");
  1491.     Menu.AddMenuItem(menu, menuLua,    "Lua");
  1492.     Menu.AddMenuItem(menu, menuOberon, "Oberon");
  1493.     Menu.AddMenuItem(menu, menuPascal, "Pascal");
  1494.     Menu.delimiter(menu);
  1495.     Menu.AddMenuItem(menu, menuText,   "Text");
  1496.     RETURN Menu.create(menu, mainTID)
  1497. END CreateMenuLanguage;
  1498.  
  1499.  
  1500. PROCEDURE CreateMenuProgram (): Menu.tMenu;
  1501. VAR
  1502.     menu: List.tList;
  1503. BEGIN
  1504.     menu := List.create(NIL);
  1505.     Menu.AddMenuItem(menu, menuBuild,       "build    ctrl-F9");
  1506.     Menu.AddMenuItem(menu, menuBuildScript, "script");
  1507.     Menu.delimiter(menu);
  1508.     Menu.AddMenuItem(menu, menuRun,         "run           F9");
  1509.     Menu.AddMenuItem(menu, menuRunScript,   "script");
  1510.     Menu.delimiter(menu);
  1511.     Menu.AddMenuItem(menu, menuDebug,       "debug    ctrl-F8");
  1512.     Menu.AddMenuItem(menu, menuDebugScript, "script");
  1513.     Menu.delimiter(menu);
  1514.     Menu.AddMenuItem(menu, menuFASM, "Fasm");
  1515.     RETURN Menu.create(menu, mainTID)
  1516. END CreateMenuProgram;
  1517.  
  1518.  
  1519. PROCEDURE CreateMenuTools (): Menu.tMenu;
  1520. VAR
  1521.     menu: List.tList;
  1522. BEGIN
  1523.     menu := List.create(NIL);
  1524.     Menu.AddMenuItem(menu, menuPipet,   "pipet");
  1525.     Menu.AddMenuItem(menu, menuMagnify, "magnify");
  1526.     Menu.AddMenuItem(menu, menuBoard,   "board");
  1527.     Menu.AddMenuItem(menu, menuSysFunc, "system functions");
  1528.     RETURN Menu.create(menu, mainTID)
  1529. END CreateMenuTools;
  1530.  
  1531.  
  1532. PROCEDURE CreateMenuOptions (): Menu.tMenu;
  1533. VAR
  1534.     menu: List.tList;
  1535. BEGIN
  1536.     menu := List.create(NIL);
  1537.     Menu.AddMenuItem(menu, menuLineNumbers,  "line numbers");
  1538.     Menu.AddMenuItem(menu, menuAutoIndents,  "automatic indents");
  1539.     Menu.AddMenuItem(menu, menuAutoBrackets, "automatic brackets");
  1540.     Menu.AddMenuItem(menu, menuTrimSpace,    "trim trailing space");
  1541.     RETURN Menu.create(menu, mainTID)
  1542. END CreateMenuOptions;
  1543.  
  1544.  
  1545. PROCEDURE CreateMenuCurLine(): Menu.tMenu;
  1546. VAR
  1547.     menu: List.tList;
  1548. BEGIN
  1549.     menu := List.create(NIL);
  1550.     Menu.AddMenuItem(menu, menuMoveUp,    "move up     ctrl-Up");
  1551.     Menu.AddMenuItem(menu, menuMoveDown,  "move down   ctrl-Down");
  1552.     Menu.AddMenuItem(menu, menuDuplicate, "duplicate   ctrl-D");
  1553.     Menu.AddMenuItem(menu, menuRemove,    "remove      ctrl-Del");
  1554.     RETURN Menu.create(menu, mainTID)
  1555. END CreateMenuCurLine;
  1556.  
  1557.  
  1558. PROCEDURE CreateMenuIndent(): Menu.tMenu;
  1559. VAR
  1560.     menu: List.tList;
  1561. BEGIN
  1562.     menu := List.create(NIL);
  1563.     Menu.AddMenuItem(menu, menuIncInd, "increase    Tab");
  1564.     Menu.AddMenuItem(menu, menuDecInd, "decrease    shift-Bksp");
  1565.     RETURN Menu.create(menu, mainTID)
  1566. END CreateMenuIndent;
  1567.  
  1568.  
  1569. PROCEDURE CreateMenuCase(): Menu.tMenu;
  1570. VAR
  1571.     menu: List.tList;
  1572. BEGIN
  1573.     menu := List.create(NIL);
  1574.     Menu.AddMenuItem(menu, menuUpper, "UPPER    ctrl-U");
  1575.     Menu.AddMenuItem(menu, menuLower, "lower    ctrl-L");
  1576.     RETURN Menu.create(menu, mainTID)
  1577. END CreateMenuCase;
  1578.  
  1579.  
  1580. PROCEDURE CreateMenuBookmark(): Menu.tMenu;
  1581. VAR
  1582.     menu: List.tList;
  1583. BEGIN
  1584.     menu := List.create(NIL);
  1585.     Menu.AddMenuItem(menu, menuToggleBookmark, "toggle      ctrl-F2");
  1586.     Menu.AddMenuItem(menu, menuNextBookmark,   "next        F2");
  1587.     Menu.AddMenuItem(menu, menuPrevBookmark,   "previous    shift-F2");
  1588.     RETURN Menu.create(menu, mainTID)
  1589. END CreateMenuBookmark;
  1590.  
  1591.  
  1592. PROCEDURE Shortcuts;
  1593. BEGIN
  1594.     Menu.AddShortcut(17 + CTRL,  menuClose);
  1595.     Menu.AddShortcut(21 + CTRL,  menuRedo);
  1596.     Menu.AddShortcut(30 + CTRL,  menuSelectAll);
  1597.     Menu.AddShortcut(32 + CTRL,  menuDuplicate);
  1598.     Menu.AddShortcut(33 + CTRL,  menuFind);
  1599.     Menu.AddShortcut(35 + CTRL,  menuFind);
  1600.     Menu.AddShortcut(34 + CTRL,  menuGoto);
  1601.     Menu.AddShortcut(44 + CTRL,  menuUndo);
  1602.     Menu.AddShortcut(45 + CTRL,  menuCut);
  1603.     Menu.AddShortcut(46 + CTRL,  menuCopy);
  1604.     Menu.AddShortcut(47 + CTRL,  menuPaste);
  1605.     Menu.AddShortcut(24 + CTRL,  menuOpen);
  1606.     Menu.AddShortcut(31 + CTRL,  menuSave);
  1607.     Menu.AddShortcut(49 + CTRL,  menuNew);
  1608.     Menu.AddShortcut(67 + CTRL,  menuBuild);
  1609.     Menu.AddShortcut(66 + CTRL,  menuDebug);
  1610.     Menu.AddShortcut(83 + CTRL,  menuRemove);
  1611.     Menu.AddShortcut(22 + CTRL,  menuUpper);
  1612.     Menu.AddShortcut(38 + CTRL,  menuLower);
  1613.     Menu.AddShortcut(60 + CTRL,  menuToggleBookmark);
  1614.     Menu.AddShortcut(72 + CTRL,  menuMoveUp);
  1615.     Menu.AddShortcut(80 + CTRL,  menuMoveDown);
  1616.     Menu.AddShortcut(83,         menuDelete);
  1617.     Menu.AddShortcut(67,         menuRun);
  1618.     Menu.AddShortcut(15,         menuIncInd);
  1619.     Menu.AddShortcut(14 + SHIFT, menuDecInd);
  1620.     Menu.AddShortcut(60 + SHIFT, menuPrevBookmark);
  1621.     Menu.AddShortcut(60,         menuNextBookmark);
  1622.     Menu.AddShortcut(61 + SHIFT, menuFindPrev);
  1623.     Menu.AddShortcut(61,         menuFindNext);
  1624. END Shortcuts;
  1625.  
  1626.  
  1627. PROCEDURE HideSearch;
  1628. BEGIN
  1629.     SetFocus(FindEdit, FALSE);
  1630.     searchOpened := FALSE;
  1631.     LEFT := LEFT_PADDING;
  1632.     resize;
  1633.     draw_window
  1634. END HideSearch;
  1635.  
  1636.  
  1637. PROCEDURE KeyDown (key: INTEGER);
  1638. VAR
  1639.     keyCode, ah: INTEGER;
  1640.     shift, ctrl, rep: BOOLEAN;
  1641. BEGIN
  1642.         K.getKBState(shift, ctrl);
  1643.         rep := FALSE;
  1644.     keyCode := key DIV 65536;
  1645.  
  1646.     (* Numpad *)
  1647.     ah := (key DIV 256) MOD 256;
  1648.     CASE keyCode OF
  1649.     |83: IF ah = 46 THEN keyCode := 52 END (* . / Del  *)
  1650.     |82: IF ah = 48 THEN keyCode := 11 END (* 0 / Ins  *)
  1651.     |79: IF ah = 49 THEN keyCode :=  2 END (* 1 / End  *)
  1652.     |80: IF ah = 50 THEN keyCode :=  3 END (* 2 / Down *)
  1653.     |81: IF ah = 51 THEN keyCode :=  4 END (* 3 / PgDn *)
  1654.     |75: IF ah = 52 THEN keyCode :=  5 END (* 4 / <-   *)
  1655.     |76: IF ah = 55 THEN keyCode := -1 END (* 5 / --- *)
  1656.     |77: IF ah = 54 THEN keyCode :=  7 END (* 6 / ->   *)
  1657.     |71: IF ah = 55 THEN keyCode :=  8 END (* 7 / Home *)
  1658.     |72: IF ah = 56 THEN keyCode :=  9 END (* 8 / Up   *)
  1659.     |73: IF ah = 57 THEN keyCode := 10 END (* 9 / PgUp *)
  1660.     ELSE
  1661.         (* nothing to do *)
  1662.     END;
  1663.  
  1664.     IF confirm THEN
  1665.         IF keyCode = 28 THEN (* Enter *)
  1666.             save(text);
  1667.             IF ~text.modified THEN
  1668.                 closeFile(FALSE, curText)
  1669.             END
  1670.         END;
  1671.         key := -1
  1672.     ELSE
  1673.         IF keyCode = -1 THEN
  1674.                 key := -1
  1675.         ELSIF keyCode = 61 THEN (* F3 *)
  1676.             key := -1;
  1677.             IF search & (searchText # "") THEN
  1678.                 IF shift THEN
  1679.                     notFound := ~T.findNext(text, ~BKW.value)
  1680.                 ELSE
  1681.                     notFound := ~T.findNext(text, BKW.value)
  1682.                 END
  1683.             END
  1684.         ELSIF keyCode = 60 THEN (* F2 *)
  1685.             key := -1;
  1686.             IF ctrl THEN
  1687.                 T.toggleLabel(text)
  1688.             ELSE
  1689.                 T.gotoLabel(text, ~shift)
  1690.             END
  1691.         ELSIF keyCode = 66 THEN (* F8 *)
  1692.             key := -1;
  1693.             IF ctrl THEN
  1694.                 ProgramDebug
  1695.             END
  1696.         ELSIF keyCode = 67 THEN (* F9 *)
  1697.             key := -1;
  1698.             IF ctrl THEN
  1699.                 ProgramBuild
  1700.             ELSE
  1701.                 ProgramRun
  1702.             END
  1703.         ELSIF keyCode = 68 THEN (* F10 *)
  1704.                 IF shift THEN
  1705.                         ShowMenu(context)
  1706.                 ELSE
  1707.                         ShowMenu(menuFile)
  1708.                 END;
  1709.             key := -1
  1710.         ELSIF keyCode = 1 THEN (* Esc *)
  1711.             IF search THEN
  1712.                 IF shift THEN
  1713.                         HideSearch
  1714.                 ELSE
  1715.                         Search
  1716.                 END
  1717.             END;
  1718.             key := -1
  1719.         ELSIF (keyCode = 55) & (key DIV 256 MOD 256 = 52) THEN (* PrtScn *)
  1720.             key := -1
  1721.         ELSIF (keyCode = 14) & shift THEN (* shift+Backspace *)
  1722.             key := -1;
  1723.             T.input(text, -8)
  1724.         ELSIF (keyCode = 15) & ctrl THEN (* ctrl+Tab *)
  1725.             key := -1;
  1726.             SwitchTab((curText + 1) MOD textsCount)
  1727.         ELSIF ((keyCode = 33) OR (keyCode = 35)) & ctrl THEN (* ctrl+F, ctrl+H*)
  1728.             key := -1;
  1729.             ShowSearchPanel(FALSE)
  1730.         ELSIF (keyCode = 34) & ctrl THEN (* ctrl+G *)
  1731.             key := -1;
  1732.             ShowSearchPanel(TRUE)
  1733.         ELSIF (keyCode = 18) & ctrl THEN (* ctrl+E *)
  1734.             key := -1;
  1735.             T.selectWord(text)
  1736.         ELSE
  1737.             IF EditBox_Focus(FindEdit) THEN
  1738.                 IF keyCode = 15 THEN (* Tab *)
  1739.                         SetFocus(ReplaceEdit, TRUE)
  1740.                 ELSE
  1741.                         EB.key(FindEdit, key);
  1742.                         EditBox_Get(FindEdit, new_searchText);
  1743.                         IF new_searchText # searchText THEN
  1744.                             searchText := new_searchText;
  1745.                             notFound := ~T.search(text, searchText, cs, whole)
  1746.                         END
  1747.                 END
  1748.             ELSIF EditBox_Focus(ReplaceEdit) THEN
  1749.                 IF keyCode = 15 THEN (* Tab *)
  1750.                         SetFocus(GotoEdit, TRUE)
  1751.                 ELSE
  1752.                         EB.key(ReplaceEdit, key);
  1753.                         EditBox_Get(ReplaceEdit, replaceText)
  1754.                 END
  1755.             ELSIF EditBox_Focus(GotoEdit) THEN
  1756.                 IF keyCode = 15 THEN (* Tab *)
  1757.                         SetFocus(FindEdit, TRUE)
  1758.                 ELSE
  1759.                         IF (key DIV 256) MOD 256 = 13 THEN
  1760.                             goto
  1761.                         ELSE
  1762.                             EB.key(GotoEdit, key)
  1763.                         END
  1764.                 END
  1765.             ELSE
  1766.                 CASE keyCode OF
  1767.                 |73: key := 33
  1768.                 |81: key := 34
  1769.                 |71: key := 36
  1770.                 |79: key := 35
  1771.                 |72: key := 38
  1772.                 |80: key := 40
  1773.                 |75: key := 37
  1774.                 |77: key := 39
  1775.                 |82, 91, 219, 92, 220: key := -1 (* insert, windows *)
  1776.                 |93: ShowMenu(context); key := -1
  1777.                 |83: key := 46
  1778.                 |59, 62..66, 87, 88: key := -1 (* F1, F4..F8, F11, F12 *)
  1779.                 ELSE
  1780.                     IF ctrl THEN
  1781.                         CASE keyCode OF
  1782.                         |17: closeFile(TRUE, curText);
  1783.                              key := -2
  1784.                         |21: T.redo(text);
  1785.                              key := -1
  1786.                         |22: key := ORD("U")
  1787.                         |24: key := -1;
  1788.                              OpenDial
  1789.                         |30: key := ORD("A")
  1790.                         |31: key := -1;
  1791.                              save(text)
  1792.                         |32: key := ORD("D")
  1793.                         |38: key := ORD("L")
  1794.                         |44: T.undo(text);
  1795.                              key := -1
  1796.                         |45: key := ORD("X")
  1797.                         |46: key := ORD("C")
  1798.                         |47: key := ORD("V")
  1799.                         |49,
  1800.                          20: key := -1;
  1801.                              NewFile
  1802.                         ELSE
  1803.                             key := -1
  1804.                         END
  1805.                     ELSE
  1806.                         T.input(text, E.cp866[key DIV 256 MOD 256]);
  1807.                         IF key DIV 256 MOD 256 = 13 THEN
  1808.                                 rep := TRUE
  1809.                         END;
  1810.                         key := -1
  1811.                     END
  1812.                 END;
  1813.                 IF key >= 0 THEN
  1814.                     T.key(text, key, shift, ctrl);
  1815.                     IF ((key = 38) OR (key = 40) OR (key = ORD("D"))) & ctrl THEN
  1816.                         rep := TRUE
  1817.                     END
  1818.                 END
  1819.             END
  1820.         END
  1821.     END;
  1822.     IF key # -2 THEN
  1823.         repaint;
  1824.         IF rep THEN
  1825.                 repaint
  1826.         END
  1827.     END
  1828. END KeyDown;
  1829.  
  1830.  
  1831. PROCEDURE BtnClick;
  1832. VAR
  1833.     btn: INTEGER;
  1834.     middle, exit: BOOLEAN;
  1835.     menu: Menu.tMenu;
  1836. BEGIN
  1837.         exit := FALSE;
  1838.     btn := K.ButtonCode(middle);
  1839.     IF U.between(Tabs.btnID, btn, Tabs.btnID + maxTexts - 1) THEN
  1840.         DEC(btn, Tabs.btnID);
  1841.         IF middle THEN
  1842.             IF texts[btn].modified THEN
  1843.                 SwitchTab(btn)
  1844.             END;
  1845.             closeFile(TRUE, btn)
  1846.         ELSE
  1847.             SwitchTab(btn)
  1848.         END;
  1849.         btn := 0
  1850.     ELSIF U.between(Tabs.btnClose, btn, Tabs.btnClose + maxTexts - 1) THEN
  1851.         DEC(btn, Tabs.btnClose);
  1852.         IF texts[btn].modified THEN
  1853.             SwitchTab(btn)
  1854.         END;
  1855.         closeFile(TRUE, btn);
  1856.         middle := TRUE;
  1857.         btn := 0
  1858.     ELSE
  1859.         IF middle THEN
  1860.             btn := 0
  1861.         END
  1862.     END;
  1863.     IF btn # 0 THEN
  1864.         menu := Menu.ClickMain(mainMenu, btn);
  1865.         IF menu # NIL THEN
  1866.                 ShowMenu(menu);
  1867.                 btn := 0
  1868.         END
  1869.     END;
  1870.  
  1871.     CASE btn OF
  1872.     |0:
  1873.     |Tabs.btnLeft, Tabs.btnRight:
  1874.         Tabs.scroll(tabs, btn);
  1875.         switch := TRUE
  1876.     |btnNo:
  1877.         exit := closing;
  1878.         closeFile(FALSE, curText);
  1879.         repaint
  1880.     |btnYes:
  1881.         exit := closing;
  1882.         save(text);
  1883.         IF ~text.modified THEN
  1884.             closeFile(FALSE, curText)
  1885.         END;
  1886.         repaint
  1887.     |btnClose:
  1888.         exit := TRUE
  1889.     |btnNew:
  1890.         NewFile
  1891.     |btnOpen:
  1892.         OpenDial
  1893.     |btnSave:
  1894.         save(text)
  1895.     |btnSearch:
  1896.         ShowSearchPanel(FALSE)
  1897.     |btnCloseSearch:
  1898.         Search
  1899.     |btnHideSearch:
  1900.         HideSearch
  1901.     |btnUndo:
  1902.         T.undo(text)
  1903.     |btnRedo:
  1904.         T.redo(text)
  1905.     |btnUpper:
  1906.         T.chCase(text, TRUE)
  1907.     |btnLower:
  1908.         T.chCase(text, FALSE)
  1909.     |btnBuild:
  1910.         ProgramBuild
  1911.     |btnRun:
  1912.         ProgramRun
  1913.     |btnFindNext:
  1914.         IF searchText # "" THEN
  1915.             notFound := ~T.findNext(text, BKW.value);
  1916.             SetFocus(FindEdit, FALSE)
  1917.         END
  1918.     |btnReplace:
  1919.         T.replace(text, replaceText, LENGTH(searchText));
  1920.         SetFocus(FindEdit, FALSE)
  1921.     |btnReplaceAll:
  1922.         notFound := ~T.search(text, searchText, cs, whole);
  1923.         IF ~notFound THEN
  1924.             replaced := T.replaceAll(text, replaceText, LENGTH(searchText));
  1925.         END;
  1926.         SetFocus(FindEdit, FALSE)
  1927.     |btnGoto:
  1928.         goto
  1929.     END;
  1930.  
  1931.     IF ~middle THEN
  1932.                 IF exit THEN
  1933.                         Close
  1934.                 ELSE
  1935.                         repaint
  1936.                 END
  1937.         END
  1938. END BtnClick;
  1939.  
  1940.  
  1941. PROCEDURE MouseEvent (VAR resized: BOOLEAN; VAR firstClickX, firstClickY, time: INTEGER);
  1942. CONST
  1943.     DELAY = 10;
  1944. VAR
  1945.     msState: SET;
  1946.     scroll, x, y, scrollX, scrollY: INTEGER;
  1947.     pos1, pos2: T.tPoint;
  1948.  
  1949.  
  1950.     PROCEDURE EditBox (VAR eb: EB.tEditBox);
  1951.     VAR
  1952.         focus: BOOLEAN;
  1953.     BEGIN
  1954.         focus := EditBox_Focus(eb);
  1955.         EB.mouse(eb);
  1956.         IF focus # EditBox_Focus(eb) THEN
  1957.             SetFocus(eb, TRUE);
  1958.             repaint
  1959.         END
  1960.     END EditBox;
  1961.  
  1962.  
  1963. BEGIN
  1964.         CloseMenu;
  1965.     IF ~resized THEN
  1966.         msState := K.MouseState();
  1967.         IF ~(0 IN msState) OR (16 IN msState) THEN
  1968.                 leftButton := FALSE
  1969.         END;
  1970.         scroll := K.Scroll();
  1971.         IF scroll # 0 THEN
  1972.             T.scroll(text, 0, scroll*3);
  1973.             repaint
  1974.         END;
  1975.         IF leftButton THEN
  1976.             IF K.GetTickCount() - time >= DELAY THEN
  1977.                 T.getPos(text, pos1.Y, pos1.X);
  1978.                 mouse(x, y);
  1979.                 T.mouse(text, x, y);
  1980.                 T.getPos(text, pos2.Y, pos2.X);
  1981.                 IF (pos1.X # pos2.X) OR (pos1.Y # pos2.Y) THEN
  1982.                         repaint
  1983.                 END
  1984.             END
  1985.         END;
  1986.  
  1987.                 Scroll.mouse(hScroll);
  1988.                 Scroll.mouse(vScroll);
  1989.                 msState := K.MouseState();
  1990.         T.getScroll(text, scrollX, scrollY);
  1991.         IF (hScroll.value # scrollX) OR (vScroll.value # scrollY) THEN
  1992.                         T.scroll(text, hScroll.value - scrollX, vScroll.value - scrollY);
  1993.                 repaint
  1994.         END;
  1995.  
  1996.         IF (8 IN msState) & ~(24 IN msState) THEN
  1997.             mouse(firstClickX, firstClickY);
  1998.             time := click(firstClickX, firstClickY)
  1999.         END;
  2000.         IF 9 IN msState THEN
  2001.             ShowMenu(context)
  2002.         END;
  2003.         IF 24 IN msState THEN
  2004.             mouse(x, y);
  2005.             IF U.between(-4, x - firstClickX, 4) & U.between(-4, y - firstClickY, 4) THEN
  2006.                 IF U.between(0, x, canvas.width - 1) & U.between(0, y, canvas.height - 1) THEN
  2007.                     leftButton := FALSE;
  2008.                     T.selectWord(text);
  2009.                     repaint
  2010.                 ELSIF Tabs.DblClicked(tabs, x + LEFT, y + TOP) THEN
  2011.                         leftButton := FALSE;
  2012.                         NewFile;
  2013.                         repaint
  2014.                 END
  2015.             ELSE
  2016.                 firstClickX := x;
  2017.                 firstClickY := y;
  2018.                 time := click(firstClickX, firstClickY)
  2019.             END
  2020.         END;
  2021.         IF msState = {} THEN
  2022.                 mouse(x, y);
  2023.                 Menu.MouseMove(mainMenu, x + LEFT, y + TOP)
  2024.         END
  2025.     END;
  2026.     IF search & searchOpened THEN
  2027.             CheckBox.mouse(BKW);
  2028.         CheckBox.mouse(CS);
  2029.         CheckBox.mouse(WH);
  2030.         EditBox(FindEdit);
  2031.         EditBox(ReplaceEdit);
  2032.         EditBox(GotoEdit);
  2033.         IF (CS.value # cs) OR (WH.value # whole) THEN
  2034.             cs := CS.value;
  2035.             whole := WH.value;
  2036.             notFound := ~T.search(text, searchText, cs, whole);
  2037.             repaint
  2038.         END
  2039.     END;
  2040.     resized := FALSE
  2041. END MouseEvent;
  2042.  
  2043.  
  2044. PROCEDURE Redraw (VAR resized: BOOLEAN; VAR width, height, cliWidth, cliHeight: INTEGER);
  2045. VAR
  2046.         onClose: BOOLEAN;
  2047. BEGIN
  2048.         onClose := (Menu.MenuItem = menuClose) OR (Menu.MenuItem = menuExit);
  2049.         IF ~onClose THEN
  2050.                 ClickMenu
  2051.         END;
  2052.         K.GetSystemColors;
  2053.         IF ~K.RolledUp() THEN
  2054.                 K.ClientSize(width, height);
  2055.                 IF (width # cliWidth) OR (height # cliHeight) THEN
  2056.                         cliWidth := width;
  2057.                         cliHeight := height;
  2058.                         resize;
  2059.                         resized := TRUE
  2060.                 END
  2061.         ELSE
  2062.                 SetCaption(text.fileName)
  2063.         END;
  2064.         draw_window;
  2065.         IF SkinHeight # K.SkinHeight() THEN
  2066.                 SkinHeight := K.SkinHeight();
  2067.                 Redraw(resized, width, height, cliWidth, cliHeight)
  2068.         END;
  2069.         IF onClose THEN
  2070.                 ClickMenu
  2071.         END
  2072. END Redraw;
  2073.  
  2074.  
  2075. PROCEDURE ScrollChange;
  2076. BEGIN
  2077.         T.scroll(text, hScroll.btn, vScroll.btn);
  2078.         IF menuActive THEN
  2079.                 draw_window;
  2080.                 menuActive := FALSE
  2081.         ELSE
  2082.                 repaint
  2083.         END
  2084. END ScrollChange;
  2085.  
  2086.  
  2087. PROCEDURE receiveIPC;
  2088. VAR
  2089.         x, y, cliX, cliY, winX, winY: INTEGER;
  2090. BEGIN
  2091.         K.ClientPos(cliX, cliY);
  2092.         K.WinPos(winX, winY);
  2093.         x := IPC[2] DIV 65536 - cliX - winX;
  2094.         y := IPC[2] MOD 65536 - cliY - winY;
  2095.         Menu.MouseMove(mainMenu, x, y);
  2096.         IPC[1] := 0;
  2097.         IPC[0] := 0
  2098. END receiveIPC;
  2099.  
  2100.  
  2101. PROCEDURE main;
  2102. VAR
  2103.     fileName, filePath: RW.tFileName;
  2104.     width, height, cliWidth, cliHeight: INTEGER;
  2105.     resized: BOOLEAN;
  2106.     firstClickX, firstClickY, time, blink, i: INTEGER;
  2107.     key, scr: INTEGER;
  2108.     text_ptr, text_size, errno: INTEGER;
  2109. BEGIN
  2110.         mainTID := K.ThreadID();
  2111.         header := "";
  2112.     K.GetSystemColors;
  2113.     switch := FALSE;
  2114.     closing := FALSE;
  2115.     textsCount := 0;
  2116.     curText := 0;
  2117.     Args.GetArg(0, AppPath);
  2118.     Ini.load(AppPath);
  2119.     Ini.getSettings;
  2120.     runScript := Ini.runScript;
  2121.     buildScript := Ini.buildScript;
  2122.     debugScript := Ini.debugScript;
  2123.     leftButton := FALSE;
  2124.     resized := FALSE;
  2125.     newtab := FALSE;
  2126.     K.ScreenSize(winWidth, winHeight);
  2127.     scrollWidth := winHeight DIV 35;
  2128.     winWidth := (winWidth*80) DIV 100 - (128 + 30);
  2129.     winHeight := winHeight - (128 + 30);
  2130.     winWidth := MAX(winWidth, minWinWidth);
  2131.     winHeight := MAX(winHeight, minWinHeight);
  2132.     cliWidth := winWidth;
  2133.     cliHeight := winHeight;
  2134.  
  2135.     LEFT := LEFT_PADDING;
  2136.     RIGHT := scrollWidth - 2;
  2137.     BOTTOM := SB.height() + scrollWidth - 1;
  2138.     SkinHeight := K.SkinHeight();
  2139.     canvas := G.CreateCanvas(winWidth - (LEFT + RIGHT + 11 + RIGHT_PADDING), winHeight - (TOP + BOTTOM + 5 - ClippingArea) - SkinHeight);
  2140.     DEC(canvas.height, ClippingArea);
  2141.     tabs := Tabs.create();
  2142.     Tabs.setArea(tabs, LEFT, TOP - Tabs.tabHeight, canvas.width, Tabs.tabHeight);
  2143.     font := G.fonts[Ini.font];
  2144.     G.SetFont(canvas, font);
  2145.     T.init(resetTimer, Ini.lineNumbers, Ini.autoIndents, Ini.autoBrackets, Ini.trimSpace);
  2146.     Ini.selectSection(Ini.theme);
  2147.     T.setCanvas(canvas);
  2148.  
  2149.     mainMenu := Menu.CreateMain(mainMenuBtn);
  2150.  
  2151.     Menu.init(resetTimer);
  2152.     context := CreateContextMenu();
  2153.     menuFile := CreateMenuFile();
  2154.     subCurLine := CreateMenuCurLine();
  2155.     subIndent := CreateMenuIndent();
  2156.     subCase := CreateMenuCase();
  2157.     menuEdit := CreateMenuEdit();
  2158.     subCurLine.parent := menuEdit;
  2159.     subIndent.parent := menuEdit;
  2160.     subCase.parent := menuEdit;
  2161.     subBookmark := CreateMenuBookmark();
  2162.     menuSearch := CreateMenuSearch();
  2163.     subBookmark.parent := menuSearch;
  2164.     subEOL := CreateMenuEOL();
  2165.     menuEncoding := CreateMenuEncoding();
  2166.     subEOL.parent := menuEncoding;
  2167.     menuView := CreateMenuView();
  2168.     menuLanguage := CreateMenuLanguage();
  2169.     menuProgram := CreateMenuProgram();
  2170.     menuTools := CreateMenuTools();
  2171.     menuOptions := CreateMenuOptions();
  2172.  
  2173.  
  2174.     Menu.AddMainItem(mainMenu, "file", menuFile);
  2175.     Menu.AddMainItem(mainMenu, "edit", menuEdit);
  2176.     Menu.AddMainItem(mainMenu, "search", menuSearch);
  2177.     Menu.AddMainItem(mainMenu, "encoding", menuEncoding);
  2178.     Menu.AddMainItem(mainMenu, "view", menuView);
  2179.     Menu.AddMainItem(mainMenu, "language", menuLanguage);
  2180.     Menu.AddMainItem(mainMenu, "program", menuProgram);
  2181.     Menu.AddMainItem(mainMenu, "tools", menuTools);
  2182.     Menu.AddMainItem(mainMenu, "options", menuOptions);
  2183.     Shortcuts;
  2184.  
  2185.     Toolbar.create(toolbar, LEFT_PADDING + 5, toolbarTop);
  2186.     Toolbar.add(toolbar, btnNew,    Icons.icoNew, "");
  2187.     Toolbar.add(toolbar, btnOpen,   Icons.icoOpen, "");
  2188.     Toolbar.add(toolbar, btnSave,   Icons.icoSave, "");
  2189.     Toolbar.delimiter(toolbar);
  2190.     Toolbar.add(toolbar, btnSearch, Icons.icoSearch, "");
  2191.     Toolbar.delimiter(toolbar);
  2192.     Toolbar.add(toolbar, btnUndo,   Icons.icoUndo, "");
  2193.     Toolbar.add(toolbar, btnRedo,   Icons.icoRedo, "");
  2194.     Toolbar.delimiter(toolbar);
  2195.     Toolbar.add(toolbar, btnUpper,  -1, "AB");
  2196.     Toolbar.add(toolbar, btnLower,  -1, "ab");
  2197.     Toolbar.delimiter(toolbar);
  2198.     Toolbar.add(toolbar, btnBuild,  Icons.icoBuild, "");
  2199.     Toolbar.add(toolbar, btnRun,    Icons.icoRun, "");
  2200.  
  2201.     filePath := "/sys";
  2202.     IF Args.argc = 1 THEN
  2203.         text := T.New();
  2204.         insert(0, text);
  2205.         T.SetPos(text, 0, 0)
  2206.     END;
  2207.         FOR i := 1 TO Args.argc - 1 DO
  2208.                 Args.GetArg(i, fileName);
  2209.                 IF fileName[0] # "*" THEN
  2210.                         IF open(fileName) THEN
  2211.                                 U.getPath(fileName, filePath)
  2212.                         END
  2213.                 ELSE
  2214.                         K.docpack(fileName, text_ptr, text_size);
  2215.                         IF text_ptr # 0 THEN
  2216.                                 text := T.open("", text_ptr, text_size, errno);
  2217.                                 IF text # NIL THEN
  2218.                                         insert(0, text);
  2219.                                         T.SetPos(text, 0, 0)
  2220.                                 END
  2221.                         END
  2222.                 END
  2223.         END;
  2224.         IF textsCount = 0 THEN
  2225.                 K.Exit
  2226.         END;
  2227.         SwitchTab(textsCount - 1);
  2228.  
  2229.     Scroll.create(FALSE, canvas.width + 1, scrollWidth, scrollWidth, scrollWidth*3 DIV 2, ScrollChange, hScroll);
  2230.     Scroll.create(TRUE, scrollWidth, canvas.height + 2, scrollWidth, scrollWidth*3 DIV 2, ScrollChange, vScroll);
  2231.     T.resize(canvas.width, canvas.height);
  2232.     confirm := FALSE;
  2233.     notFound := FALSE;
  2234.     menuFindClicked := FALSE;
  2235.     menuActive := FALSE;
  2236.     search := FALSE;
  2237.     searchOpened := FALSE;
  2238.     createSearchForm;
  2239.     new_searchText := "";
  2240.     searchText := "";
  2241.     cs := FALSE;
  2242.     whole := FALSE;
  2243.     replaced := 0;
  2244.  
  2245.         OD := OpenDlg.Create(draw_window, OpenDlg.topen, filePath, "");
  2246.  
  2247.         IPC[1] := 0;
  2248.         IPC[0] := 0;
  2249.         K.SetIPC(IPC);
  2250.     K.SetEventsMask({0, 1, 2, 5, 6, 31});
  2251.     draw_window;
  2252.     blink := Ini.blink;
  2253.         IF blink <= 0 THEN
  2254.                 blink := 0
  2255.         ELSIF blink < 30 THEN
  2256.                 blink := 30
  2257.         END;
  2258.     timerEnabled := TRUE;
  2259.     CursorTime := K.GetTickCount();
  2260.     WHILE TRUE DO
  2261.  
  2262.         CurrentTime := K.GetTickCount();
  2263.         IF (CurrentTime - CursorTime > blink) & (blink > 0) & timerEnabled & ~K.RolledUp() THEN
  2264.                 CursorTime := CurrentTime;
  2265.                 T.cursor(text);
  2266.                 drawText
  2267.         END;
  2268.  
  2269.         CASE K.EventTimeout(10) OF
  2270.         |0:
  2271.         |1:     Redraw(resized, width, height, cliWidth, cliHeight)
  2272.         |2:
  2273.                 key := K.GetKey();
  2274.                 IF ~K.RolledUp() THEN
  2275.                         KeyDown(key)
  2276.                 END
  2277.         |3: BtnClick
  2278.         |6:
  2279.                 IF ~K.RolledUp() THEN
  2280.                         MouseEvent(resized, firstClickX, firstClickY, time)
  2281.                 ELSE
  2282.                         scr := K.Scroll()
  2283.                 END
  2284.         |7: receiveIPC
  2285.         END;
  2286.         IF newtab THEN
  2287.                 Redraw(resized, width, height, cliWidth, cliHeight);
  2288.                 newtab := FALSE
  2289.         END
  2290.     END
  2291. END main;
  2292.  
  2293.  
  2294. BEGIN
  2295.     main
  2296. END CEdit.