Subversion Repositories Kolibri OS

Rev

Rev 4307 | Rev 4381 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 4311 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_BIOS32
  287. ; MEMORY MODEL
  288.         call    mem_test
  289.         call    init_mem
  290.         call    init_page_map
  291.  
  292. ; ENABLE PAGING
  293.  
  294.         mov     eax, sys_pgdir-OS_BASE
  295.         mov     cr3, eax
  296.  
  297.         mov     eax, cr0
  298.         or      eax, CR0_PG+CR0_WP
  299.         mov     cr0, eax
  300.  
  301.         lgdt    [gdts]
  302.         jmp     pword os_code:high_code
  303.  
  304. align 4
  305. bios32_entry    dd ?
  306. tmp_page_tabs   dd ?
  307.  
  308. use16
  309. org $-0x10000
  310. include "boot/shutdown.inc" ; shutdown or restart
  311. org $+0x10000
  312. use32
  313.  
  314. __DEBUG__ fix 1
  315. __DEBUG_LEVEL__ fix 1
  316. include 'init.inc'
  317.  
  318. org OS_BASE+$
  319.  
  320. include 'fdo.inc'
  321.  
  322. align 4
  323. high_code:
  324.         mov     ax, os_stack
  325.         mov     bx, app_data
  326.         mov     cx, app_tls
  327.         mov     ss, ax
  328.         add     esp, OS_BASE
  329.  
  330.         mov     ds, bx
  331.         mov     es, bx
  332.         mov     fs, cx
  333.         mov     gs, bx
  334.  
  335.         bt      [cpu_caps], CAPS_PGE
  336.         jnc     @F
  337.  
  338.         or      dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  339.  
  340.         mov     ebx, cr4
  341.         or      ebx, CR4_PGE
  342.         mov     cr4, ebx
  343. @@:
  344.         xor     eax, eax
  345.         mov     dword [sys_pgdir], eax
  346.         mov     dword [sys_pgdir+4], eax
  347.  
  348.         mov     eax, cr3
  349.         mov     cr3, eax          ; flush TLB
  350.  
  351.         mov     ecx, pg_data.mutex
  352.         call    mutex_init
  353.  
  354.         mov     ecx, disk_list_mutex
  355.         call    mutex_init
  356.  
  357.         mov     ecx, keyboard_list_mutex
  358.         call    mutex_init
  359.  
  360.         mov     ecx, unpack_mutex
  361.         call    mutex_init
  362.  
  363.         mov     ecx, application_table_mutex
  364.         call    mutex_init
  365.  
  366.         mov     ecx, ide_mutex
  367.         call    mutex_init
  368.         mov     ecx, ide_channel1_mutex
  369.         call    mutex_init
  370.         mov     ecx, ide_channel2_mutex
  371.         call    mutex_init
  372. ;-----------------------------------------------------------------------------
  373. ; SAVE REAL MODE VARIABLES
  374. ;-----------------------------------------------------------------------------
  375. save_variables_IDE_controller:
  376.         xor     eax, eax
  377.         mov     ax, [BOOT_VARS + BOOT_IDE_INTERR_16]
  378.         mov     [IDE_Interrupt], ax
  379. ;--------------------------------------
  380.         mov     ax, [BOOT_VARS + BOOT_IDE_PI_16]
  381.         mov     [IDEContrProgrammingInterface], ax
  382. ;--------------------------------------
  383.         mov     ax, [BOOT_VARS + BOOT_IDE_BASE_ADDR]
  384.         mov     [IDEContrRegsBaseAddr], ax
  385. ;--------------------------------------
  386.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR0_16]
  387.         cmp     ax, 0
  388.         je      @f
  389.         cmp     ax, 1
  390.         jne     .no_PATA_BAR0
  391. @@:
  392.         mov     ax, 0x1F0
  393.         jmp     @f
  394. .no_PATA_BAR0:
  395.         and     ax, 0xFFFC
  396. @@:
  397.         mov     [StandardATABases], ax
  398.         mov     [hd_address_table], eax
  399.         mov     [hd_address_table+8], eax
  400.         mov     [IDE_BAR0_val], ax
  401. ;--------------------------------------
  402.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR1_16]
  403.         cmp     ax, 0
  404.         je      @f
  405.         cmp     ax, 1
  406.         jne     .no_PATA_BAR1
  407. @@:
  408.         mov     ax, 0x3F4
  409.         jmp     @f
  410. .no_PATA_BAR1:
  411.         and     ax, 0xFFFC
  412. @@:
  413.         mov     [IDE_BAR1_val], ax
  414. ;--------------------------------------
  415.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR2_16]
  416.         cmp     ax, 0
  417.         je      @f
  418.         cmp     ax, 1
  419.         jne     .no_PATA_BAR2
  420. @@:
  421.         mov     ax, 0x170
  422.         jmp     @f
  423. .no_PATA_BAR2:
  424.         and     ax, 0xFFFC
  425. @@:
  426.         mov     [StandardATABases+2], ax
  427.         mov     [hd_address_table+16], eax
  428.         mov     [hd_address_table+24], eax
  429.         mov     [IDE_BAR2_val], ax
  430. ;--------------------------------------
  431.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR3_16]
  432.         cmp     ax, 0
  433.         je      @f
  434.         cmp     ax, 1
  435.         jne     .no_PATA_BAR3
  436. @@:
  437.         mov     ax, 0x374
  438.         jmp     @f
  439. .no_PATA_BAR3:
  440.         and     ax, 0xFFFC
  441. @@:
  442.         mov     [IDE_BAR3_val], ax
  443.  
  444. ; --------------- APM ---------------------
  445.  
  446. ; init selectors
  447.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  448.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  449.                                                                                 ; protected-mode 32-bit code segment
  450.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  451.                                                                                 ; protected-mode 16-bit code segment
  452.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  453.                                                                                 ; protected-mode 16-bit data segment
  454.  
  455.         shl     eax, 4
  456.         mov     [dword apm_code_32 + 2], ax
  457.         shr     eax, 16
  458.         mov     [dword apm_code_32 + 4], al
  459.  
  460.         shl     ecx, 4
  461.         mov     [dword apm_code_16 + 2], cx
  462.         shr     ecx, 16
  463.         mov     [dword apm_code_16 + 4], cl
  464.  
  465.         shl     edx, 4
  466.         mov     [dword apm_data_16 + 2], dx
  467.         shr     edx, 16
  468.         mov     [dword apm_data_16 + 4], dl
  469.  
  470.         mov     dword[apm_entry], ebx
  471.         mov     word [apm_entry + 4], apm_code_32 - gdts
  472.  
  473.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  474.         mov     [apm_vf], eax
  475. ; -----------------------------------------
  476.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  477.         mov     [allow_dma_access], al
  478.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  479.         mov     [_display.bpp], eax
  480.         mov     [_display.vrefresh], 60
  481.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  482.         mov     [debug_direct_print], al
  483.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  484.         mov     [launcher_start], al
  485.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  486.         mov     [_display.width], eax
  487.         mov     [display_width_standard], eax
  488.         dec     eax
  489.         mov     [Screen_Max_X], eax
  490.         mov     [screen_workarea.right], eax
  491.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  492.         mov     [_display.height], eax
  493.         mov     [display_height_standard], eax
  494.         dec     eax
  495.         mov     [Screen_Max_Y], eax
  496.         mov     [screen_workarea.bottom], eax
  497.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  498.         mov     dword [SCR_MODE], eax
  499. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  500. ;        mov     [BANK_SWITCH], eax
  501.         mov     eax, 640 *4                         ; Bytes PerScanLine
  502.         cmp     [SCR_MODE], word 0x13               ; 320x200
  503.         je      @f
  504.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  505.         je      @f
  506.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  507. @@:
  508.         mov     [_display.pitch], eax
  509.         mov     eax, [_display.width]
  510.         mul     [_display.height]
  511.         mov     [_WinMapSize], eax
  512.  
  513.         call    calculate_fast_getting_offset_for_WinMapAddress
  514. ; for Qemu or non standart video cards
  515. ; Unfortunately [BytesPerScanLine] does not always
  516. ;                             equal to [_display.width] * [ScreenBPP] / 8
  517.         call    calculate_fast_getting_offset_for_LFB
  518.  
  519.         mov     esi, BOOT_VARS+0x9080
  520.         movzx   ecx, byte [esi-1]
  521.         mov     [NumBiosDisks], ecx
  522.         mov     edi, BiosDisksData
  523.         rep movsd
  524.  
  525. ; GRAPHICS ADDRESSES
  526.  
  527.         mov     eax, [BOOT_VARS+BOOT_LFB]
  528.         mov     [LFBAddress], eax
  529.  
  530.         cmp     [SCR_MODE], word 0100000000000000b
  531.         jge     setvesa20
  532.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  533.         je      v20ga32
  534.         jmp     v20ga24
  535.  
  536. setvesa20:
  537.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  538.         mov     [GETPIXEL], dword Vesa20_getpixel24
  539.         cmp     byte [_display.bpp], 24
  540.         jz      v20ga24
  541. v20ga32:
  542.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  543.         mov     [GETPIXEL], dword Vesa20_getpixel32
  544.         jmp     no_mode_0x12
  545. v20ga24:
  546.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  547.         jne     no_mode_0x12
  548.         mov     [PUTPIXEL], dword VGA_putpixel
  549.         mov     [GETPIXEL], dword Vesa20_getpixel32
  550. no_mode_0x12:
  551.  
  552.         mov     [MOUSE_PICTURE], dword mousepointer
  553.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  554.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  555.  
  556. ; -------- Fast System Call init ----------
  557. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  558.         bt      [cpu_caps], CAPS_SEP
  559.         jnc     .SEnP  ; SysEnter not Present
  560.         xor     edx, edx
  561.         mov     ecx, MSR_SYSENTER_CS
  562.         mov     eax, os_code
  563.         wrmsr
  564.         mov     ecx, MSR_SYSENTER_ESP
  565. ;           mov eax, sysenter_stack ; Check it
  566.         xor     eax, eax
  567.         wrmsr
  568.         mov     ecx, MSR_SYSENTER_EIP
  569.         mov     eax, sysenter_entry
  570.         wrmsr
  571. .SEnP:
  572. ; AMD SYSCALL/SYSRET
  573.         cmp     byte[cpu_vendor], 'A'
  574.         jne     .noSYSCALL
  575.         mov     eax, 0x80000001
  576.         cpuid
  577.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  578.         jz      .noSYSCALL
  579.         mov     ecx, MSR_AMD_EFER
  580.         rdmsr
  581.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  582.         wrmsr
  583.  
  584.         ; !!!! It`s dirty hack, fix it !!!
  585.         ; Bits of EDX :
  586.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  587.         ;  and the contents of this field, plus 8, are copied into the SS register.
  588.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  589.         ;  and the contents of this field, plus 8, are copied into the SS register.
  590.  
  591.         ; mov   edx, (os_code + 16) * 65536 + os_code
  592.         mov     edx, 0x1B0008
  593.  
  594.         mov     eax, syscall_entry
  595.         mov     ecx, MSR_AMD_STAR
  596.         wrmsr
  597. .noSYSCALL:
  598. ; -----------------------------------------
  599.         stdcall alloc_page
  600.         stdcall map_page, tss-0xF80, eax, PG_SW
  601.         stdcall alloc_page
  602.         stdcall map_page, tss+0x80, eax, PG_SW
  603.         stdcall alloc_page
  604.         stdcall map_page, tss+0x1080, eax, PG_SW
  605.  
  606. ; LOAD IDT
  607.  
  608.         call    build_interrupt_table ;lidt is executed
  609.           ;lidt [idtreg]
  610.  
  611.         call    init_kernel_heap
  612.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  613.         mov     [os_stack_seg], eax
  614.  
  615.         lea     esp, [eax+RING0_STACK_SIZE]
  616.  
  617.         mov     [tss._ss0], os_stack
  618.         mov     [tss._esp0], esp
  619.         mov     [tss._esp], esp
  620.         mov     [tss._cs], os_code
  621.         mov     [tss._ss], os_stack
  622.         mov     [tss._ds], app_data
  623.         mov     [tss._es], app_data
  624.         mov     [tss._fs], app_data
  625.         mov     [tss._gs], app_data
  626.         mov     [tss._io], 128
  627. ;Add IO access table - bit array of permitted ports
  628.         mov     edi, tss._io_map_0
  629.         xor     eax, eax
  630.         not     eax
  631.         mov     ecx, 8192/4
  632.         rep stosd                    ; access to 4096*8=65536 ports
  633.  
  634.         mov     ax, tss0
  635.         ltr     ax
  636.  
  637.         mov     [LFBSize], 0xC00000
  638.         call    init_LFB
  639.         call    init_fpu
  640.         call    init_malloc
  641.  
  642.         stdcall alloc_kernel_space, 0x51000
  643.         mov     [default_io_map], eax
  644.  
  645.         add     eax, 0x2000
  646.         mov     [ipc_tmp], eax
  647.         mov     ebx, 0x1000
  648.  
  649.         add     eax, 0x40000
  650.         mov     [proc_mem_map], eax
  651.  
  652.         add     eax, 0x8000
  653.         mov     [proc_mem_pdir], eax
  654.  
  655.         add     eax, ebx
  656.         mov     [proc_mem_tab], eax
  657.  
  658.         add     eax, ebx
  659.         mov     [tmp_task_pdir], eax
  660.  
  661.         add     eax, ebx
  662.         mov     [tmp_task_ptab], eax
  663.  
  664.         add     eax, ebx
  665.         mov     [ipc_pdir], eax
  666.  
  667.         add     eax, ebx
  668.         mov     [ipc_ptab], eax
  669.  
  670.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  671.                 (unpack.lc+unpack.lp)))*4
  672.  
  673.         mov     [unpack.p], eax
  674.  
  675.         call    init_events
  676.         mov     eax, srv.fd-SRV.fd
  677.         mov     [srv.fd], eax
  678.         mov     [srv.bk], eax
  679.  
  680. ;Set base of graphic segment to linear address of LFB
  681.         mov     eax, [LFBAddress]         ; set for gs
  682.         mov     [graph_data_l+2], ax
  683.         shr     eax, 16
  684.         mov     [graph_data_l+4], al
  685.         mov     [graph_data_l+7], ah
  686.  
  687.         stdcall kernel_alloc, [_WinMapSize]
  688.         mov     [_WinMapAddress], eax
  689.  
  690.         xor     eax, eax
  691.         inc     eax
  692.  
  693. ; set background
  694.  
  695.         mov     [BgrDrawMode], eax
  696.         mov     [BgrDataWidth], eax
  697.         mov     [BgrDataHeight], eax
  698.         mov     [mem_BACKGROUND], 4
  699.         mov     [img_background], static_background_data
  700.  
  701. ; set clipboard
  702.  
  703.         xor     eax, eax
  704.         mov     [clipboard_slots], eax
  705.         mov     [clipboard_write_lock], eax
  706.         stdcall kernel_alloc, 4096
  707.         test    eax, eax
  708.         jnz     @f
  709.  
  710.         dec     eax
  711. @@:
  712.         mov     [clipboard_main_list], eax
  713.  
  714. ; SET UP OS TASK
  715.  
  716.         mov     esi, boot_setostask
  717.         call    boot_log
  718.  
  719.         mov     edx, SLOT_BASE+256
  720.         mov     ebx, [os_stack_seg]
  721.         add     ebx, 0x2000
  722.         call    setup_os_slot
  723.         mov     dword [edx], 'IDLE'
  724.         sub     [edx+APPDATA.saved_esp], 4
  725.         mov     eax, [edx+APPDATA.saved_esp]
  726.         mov     dword [eax], idle_thread
  727.         mov     ecx, IDLE_PRIORITY
  728.         call    scheduler_add_thread
  729.  
  730.         mov     edx, SLOT_BASE+256*2
  731.         mov     ebx, [os_stack_seg]
  732.         call    setup_os_slot
  733.         mov     dword [edx], 'OS'
  734.         xor     ecx, ecx
  735.         call    scheduler_add_thread
  736.  
  737.         mov     dword [CURRENT_TASK], 2
  738.         mov     dword [TASK_COUNT], 2
  739.         mov     dword [current_slot], SLOT_BASE + 256*2
  740.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  741.  
  742.  
  743. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  744.         mov     esi, boot_initirq
  745.         call    boot_log
  746.         call    init_irqs
  747.  
  748.         mov     esi, boot_picinit
  749.         call    boot_log
  750.         call    PIC_init
  751.  
  752.         mov     esi, boot_v86machine
  753.         call    boot_log
  754. ; Initialize system V86 machine
  755.         call    init_sys_v86
  756.  
  757.         mov     esi, boot_inittimer
  758.         call    boot_log
  759. ; Initialize system timer (IRQ0)
  760.         call    PIT_init
  761.  
  762. ; Register ramdisk file system
  763.         mov     esi, boot_initramdisk
  764.         call    boot_log
  765.         call    ramdisk_init
  766.  
  767.         mov     esi, boot_initapic
  768.         call    boot_log
  769. ; Try to Initialize APIC
  770.         call    APIC_init
  771.  
  772.         mov     esi, boot_enableirq
  773.         call    boot_log
  774. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  775. ; they are used: when partitions are scanned, hd_read relies on timer
  776.         call    unmask_timer
  777.         stdcall enable_irq, 2               ; @#$%! PIC
  778.         stdcall enable_irq, 13              ; co-processor
  779.  
  780.         cmp     [IDEContrProgrammingInterface], 0
  781.         je      @f
  782.  
  783.         mov     esi, boot_disabling_ide
  784.         call    boot_log
  785. ;--------------------------------------
  786. ; Disable IDE interrupts, because the search
  787. ; for IDE partitions is in the PIO mode.
  788. ;--------------------------------------
  789. .disable_IDE_interrupt:
  790. ; Disable interrupts in IDE controller for PIO
  791.         mov     al, 2
  792.         mov     dx, [IDE_BAR1_val] ;0x3F4
  793.         add     dx, 2 ;0x3F6
  794.         out     dx, al
  795.         mov     dx, [IDE_BAR3_val] ;0x374
  796.         add     dx, 2 ;0x376
  797.         out     dx, al
  798. @@:
  799. ;-----------------------------------------------------------------------------
  800. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  801. ;        mov     esi, boot_detectdisks
  802. ;        call    boot_log
  803. ;include 'detect/disks.inc'
  804.         mov     esi, boot_detectfloppy
  805.         call    boot_log
  806. include 'detect/dev_fd.inc'
  807.         mov     esi, boot_detecthdcd
  808.         call    boot_log
  809. include 'detect/dev_hdcd.inc'
  810.         mov     esi, boot_getcache
  811.         call    boot_log
  812. include 'detect/getcache.inc'
  813.         mov     esi, boot_detectpart
  814.         call    boot_log
  815. include 'detect/sear_par.inc'
  816. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  817.  
  818.         mov     esi, boot_init_sys
  819.         call    boot_log
  820.         call    Parser_params
  821.  
  822. if ~ defined extended_primary_loader
  823. ; ramdisk image should be loaded by extended primary loader if it exists
  824. ; READ RAMDISK IMAGE FROM HD
  825.  
  826. ;!!!!!!!!!!!!!!!!!!!!!!!
  827. include 'boot/rdload.inc'
  828. ;!!!!!!!!!!!!!!!!!!!!!!!
  829. end if
  830. ;    mov    [dma_hdd],1
  831.  
  832. if 0
  833.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  834.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  835.         je      no_lib_load
  836.  
  837.         mov     esi, boot_loadlibs
  838.         call    boot_log
  839. ; LOADING LIBRARES
  840.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  841.         call    load_file_parse_table       ; prepare file parse table
  842.         call    set_kernel_conf             ; configure devices and gui
  843. no_lib_load:
  844. end if
  845.  
  846. ; Display APIC status
  847.         mov     esi, boot_APIC_found
  848.         cmp     [irq_mode], IRQ_APIC
  849.         je      @f
  850.         mov     esi, boot_APIC_nfound
  851. @@:
  852.         call    boot_log
  853.  
  854. ; PRINT AMOUNT OF MEMORY
  855.         mov     esi, boot_memdetect
  856.         call    boot_log
  857.  
  858.         movzx   ecx, word [boot_y]
  859.         if lang eq ru
  860.         or      ecx, (10+30*6) shl 16
  861.         else if lang eq sp
  862.         or      ecx, (10+33*6) shl 16
  863.         else
  864.         or      ecx, (10+29*6) shl 16
  865.         end if
  866.         sub     ecx, 10
  867.         mov     edx, 0xFFFFFF
  868.         mov     ebx, [MEM_AMOUNT]
  869.         shr     ebx, 20
  870.         xor     edi, edi
  871.         mov     eax, 0x00040000
  872.         inc     edi
  873.         call    display_number_force
  874.  
  875. ; BUILD SCHEDULER
  876.  
  877. ;        call    build_scheduler; sys32.inc
  878.  
  879. ;        mov     esi, boot_devices
  880. ;        call    boot_log
  881.  
  882.         mov     [pci_access_enabled], 1
  883.         call    pci_enum
  884. ;-----------------------------------------------------------------------------
  885.         mov     dx, [IDEContrRegsBaseAddr]
  886. ; test whether it is our interrupt?
  887.         add     dx, 2
  888.         in      al, dx
  889.         test    al, 100b
  890.         jz      @f
  891. ; clear Bus Master IDE Status register
  892. ; clear Interrupt bit
  893.         out     dx, al
  894. @@:
  895.         add     dx, 8
  896. ; test whether it is our interrupt?
  897.         in      al, dx
  898.         test    al, 100b
  899.         jz      @f
  900. ; clear Bus Master IDE Status register
  901. ; clear Interrupt bit
  902.         out     dx, al
  903. @@:
  904. ; read status register and remove the interrupt request
  905.         mov     dx, [IDE_BAR0_val] ;0x1F0
  906.         add     dx, 0x7 ;0x1F7
  907.         in      al, dx
  908.         mov     dx, [IDE_BAR2_val] ;0x170
  909.         add     dx, 0x7 ;0x177
  910.         in      al, dx
  911. ;-----------------------------------------------------------------------------
  912. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  913.  
  914.         stdcall load_driver, szVidintel
  915.  
  916.         call    usb_init
  917.  
  918. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  919.  
  920.         mov     esi, boot_windefs
  921.         call    boot_log
  922.         call    set_window_defaults
  923.  
  924. ; SET BACKGROUND DEFAULTS
  925.  
  926.         mov     esi, boot_bgr
  927.         call    boot_log
  928.         call    init_background
  929.         call    calculatebackground
  930.  
  931. ; RESERVE SYSTEM IRQ'S JA PORT'S
  932.  
  933.         mov     esi, boot_resirqports
  934.         call    boot_log
  935.         call    reserve_irqs_ports
  936.  
  937.         call    init_display
  938.         mov     eax, [def_cursor]
  939.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  940.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  941.  
  942. ; PRINT CPU FREQUENCY
  943.  
  944.         mov     esi, boot_cpufreq
  945.         call    boot_log
  946.  
  947.         cli                         ;FIXME check IF
  948.         rdtsc
  949.         mov     ecx, eax
  950.         mov     esi, 250            ; wait 1/4 a second
  951.         call    delay_ms
  952.         rdtsc
  953.  
  954.         sub     eax, ecx
  955.         xor     edx, edx
  956.         shld    edx, eax, 2
  957.         shl     eax, 2
  958.         mov     dword [cpu_freq], eax
  959.         mov     dword [cpu_freq+4], edx
  960.         mov     ebx, 1000000
  961.         div     ebx
  962.         mov     ebx, eax
  963.  
  964.         movzx   ecx, word [boot_y]
  965.         if lang eq ru
  966.         add     ecx, (10+19*6) shl 16 - 10
  967.         else if lang eq sp
  968.         add     ecx, (10+25*6) shl 16 - 10
  969.         else
  970.         add     ecx, (10+17*6) shl 16 - 10
  971.         end if
  972.  
  973.         mov     edx, 0xFFFFFF
  974.         xor     edi, edi
  975.         mov     eax, 0x00040000
  976.         inc     edi
  977.         call    display_number_force
  978.  
  979. ; SET VARIABLES
  980.  
  981.         call    set_variables
  982.  
  983. ; STACK AND FDC
  984.  
  985.         call    stack_init
  986.         call    fdc_init
  987.  
  988. ; PALETTE FOR 320x200 and 640x480 16 col
  989.  
  990.         cmp     [SCR_MODE], word 0x12
  991.         jne     no_pal_vga
  992.         mov     esi, boot_pal_vga
  993.         call    boot_log
  994.         call    paletteVGA
  995.       no_pal_vga:
  996.  
  997.         cmp     [SCR_MODE], word 0x13
  998.         jne     no_pal_ega
  999.         mov     esi, boot_pal_ega
  1000.         call    boot_log
  1001.         call    palette320x200
  1002.       no_pal_ega:
  1003.  
  1004. ; LOAD DEFAULT SKIN
  1005.  
  1006.         call    load_default_skin
  1007.  
  1008. ;protect io permission map
  1009.  
  1010.         mov     esi, [default_io_map]
  1011.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1012.         add     esi, 0x1000
  1013.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1014.  
  1015.         stdcall map_page, tss._io_map_0, \
  1016.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  1017.         stdcall map_page, tss._io_map_1, \
  1018.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  1019.  
  1020. ; LOAD FIRST APPLICATION
  1021.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1022.         jnz     first_app_found
  1023.  
  1024.         cli
  1025.         mov     ebp, firstapp
  1026.         call    fs_execute_from_sysdir
  1027.         test    eax, eax
  1028.         jns     first_app_found
  1029.  
  1030.         mov     esi, boot_failed
  1031.         call    boot_log
  1032.  
  1033.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1034.         hlt
  1035.  
  1036. first_app_found:
  1037.  
  1038.         cli
  1039.  
  1040. ; SET KEYBOARD PARAMETERS
  1041.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1042.         call    kb_write
  1043.         test    ah, ah
  1044.         jnz     .no_keyboard
  1045.  
  1046.         ; wait until 8042 is ready
  1047.         xor     ecx, ecx
  1048.       @@:
  1049.         in      al, 64h
  1050.         and     al, 00000010b
  1051.         loopnz  @b
  1052.  
  1053. iglobal
  1054. align 4
  1055. ps2_keyboard_functions:
  1056.         dd      .end - $
  1057.         dd      0       ; no close
  1058.         dd      ps2_set_lights
  1059. .end:
  1060. endg
  1061.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1062.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1063.        ; call  kb_write
  1064.        ; call  kb_read
  1065.        ; mov   al, 111b
  1066.        ; call  kb_write
  1067.        ; call  kb_read
  1068.  
  1069.         mov     al, 0xF3     ; set repeat rate & delay
  1070.         call    kb_write
  1071. ;        call  kb_read
  1072.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1073.         call    kb_write
  1074. ;        call  kb_read
  1075.      ;// mike.dld [
  1076.         call    set_lights
  1077.      ;// mike.dld ]
  1078.         stdcall attach_int_handler, 1, irq1, 0
  1079.         DEBUGF  1, "K : IRQ1 error code %x\n", eax
  1080. .no_keyboard:
  1081.  
  1082. ; SET MOUSE
  1083.  
  1084.         stdcall load_driver, szPS2MDriver
  1085. ;        stdcall load_driver, szCOM_MDriver
  1086.  
  1087.         mov     esi, boot_setmouse
  1088.         call    boot_log
  1089.         call    setmouse
  1090.  
  1091. ; Setup serial output console (if enabled)
  1092.  
  1093. if defined debug_com_base
  1094.  
  1095.         ; enable Divisor latch
  1096.  
  1097.         mov     dx, debug_com_base+3
  1098.         mov     al, 1 shl 7
  1099.         out     dx, al
  1100.  
  1101.         ; Set speed to 115200 baud (max speed)
  1102.  
  1103.         mov     dx, debug_com_base
  1104.         mov     al, 0x01
  1105.         out     dx, al
  1106.  
  1107.         mov     dx, debug_com_base+1
  1108.         mov     al, 0x00
  1109.         out     dx, al
  1110.  
  1111.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  1112.  
  1113.         mov     dx, debug_com_base+3
  1114.         mov     al, 3
  1115.         out     dx, al
  1116.  
  1117.         ; disable interrupts
  1118.  
  1119.         mov     dx, debug_com_base+1
  1120.         mov     al, 0
  1121.         out     dx, al
  1122.  
  1123.         ; clear +  enable fifo (64 bits)
  1124.  
  1125.         mov     dx, debug_com_base+2
  1126.         mov     al, 0x7 + 1 shl 5
  1127.         out     dx, al
  1128.  
  1129.  
  1130. end if
  1131.         mov     eax, [version_inf.rev]
  1132.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  1133.  
  1134.         mov     eax, [cpu_count]
  1135.         test    eax, eax
  1136.         jnz     @F
  1137.         mov     al, 1                             ; at least one CPU
  1138. @@:
  1139.         DEBUGF  1, "K : %d CPU detected\n", eax
  1140.  
  1141.         DEBUGF  1, "K : BAR0 %x \n", [IDE_BAR0_val]:4
  1142.         DEBUGF  1, "K : BAR1 %x \n", [IDE_BAR1_val]:4
  1143.         DEBUGF  1, "K : BAR2 %x \n", [IDE_BAR2_val]:4
  1144.         DEBUGF  1, "K : BAR3 %x \n", [IDE_BAR3_val]:4
  1145.         DEBUGF  1, "K : BAR4 %x \n", [IDEContrRegsBaseAddr]:4
  1146.         DEBUGF  1, "K : IDEContrProgrammingInterface %x \n", [IDEContrProgrammingInterface]:4
  1147.         DEBUGF  1, "K : IDE_Interrupt %x \n", [IDE_Interrupt]:4
  1148.  
  1149. ; START MULTITASKING
  1150.  
  1151. ; A 'All set - press ESC to start' messages if need
  1152. if preboot_blogesc
  1153.         mov     esi, boot_tasking
  1154.         call    boot_log
  1155. .bll1:
  1156.         in      al, 0x60        ; wait for ESC key press
  1157.         cmp     al, 129
  1158.         jne     .bll1
  1159. end if
  1160.  
  1161.         push    eax edx
  1162.         mov     dx, [IDEContrRegsBaseAddr]
  1163.         xor     eax, eax
  1164.         add     dx, 2
  1165.         in      al, dx
  1166.         DEBUGF  1, "K : Primary Bus Master IDE Status Register %x\n", eax
  1167.  
  1168.         add     dx, 8
  1169.         in      al, dx
  1170.         DEBUGF  1, "K : Secondary Bus Master IDE Status Register %x\n", eax
  1171.         pop     edx eax
  1172.  
  1173.         cmp     [IDEContrRegsBaseAddr], 0
  1174.         setnz   [dma_hdd]
  1175.  
  1176.         cmp     [IDEContrProgrammingInterface], 0
  1177.         je      set_interrupts_for_IDE_controllers.continue
  1178. ;-----------------------------------------------------------------------------
  1179. ; set interrupts for IDE Controller
  1180. ;-----------------------------------------------------------------------------
  1181.         mov     esi, boot_set_int_IDE
  1182.         call    boot_log
  1183. set_interrupts_for_IDE_controllers:
  1184.         mov     ax, [IDEContrProgrammingInterface]
  1185.         cmp     ax, 0x0180
  1186.         je      .pata_ide
  1187.  
  1188.         cmp     ax, 0x018a
  1189.         jne     .sata_ide
  1190. ;--------------------------------------
  1191. .pata_ide:
  1192.         cmp     [IDEContrRegsBaseAddr], 0
  1193.         je      .end_set_interrupts
  1194.  
  1195.         stdcall attach_int_handler, 14, IDE_irq_14_handler, 0
  1196.         DEBUGF  1, "K : Set IDE IRQ14 return code %x\n", eax
  1197.         stdcall attach_int_handler, 15, IDE_irq_15_handler, 0
  1198.         DEBUGF  1, "K : Set IDE IRQ15 return code %x\n", eax
  1199.         jmp     .enable_IDE_interrupt
  1200. ;--------------------------------------
  1201. .sata_ide:
  1202.         cmp     ax, 0x0185
  1203.         je      .sata_ide_1
  1204.  
  1205.         cmp     ax, 0x018f
  1206.         jne     .end_set_interrupts
  1207. ;--------------------------------------
  1208. .sata_ide_1:
  1209.         cmp     [IDEContrRegsBaseAddr], 0
  1210.         je      .end_set_interrupts
  1211.  
  1212.         mov     ax, [IDE_Interrupt]
  1213.         movzx   eax, al
  1214.         stdcall attach_int_handler, eax, IDE_common_irq_handler, 0
  1215.         DEBUGF  1, "K : Set IDE IRQ%d return code %x\n", [IDE_Interrupt]:1, eax
  1216. ;--------------------------------------
  1217. .enable_IDE_interrupt:
  1218.         mov     esi, boot_enabling_ide
  1219.         call    boot_log
  1220. ; Enable interrupts in IDE controller for DMA
  1221.         mov     al, 0
  1222.         mov     ah, [DRIVE_DATA+1]
  1223.         test    ah, 10100000b
  1224.         jz      @f
  1225.  
  1226.         DEBUGF  1, "K : IDE CH1 PIO, because ATAPI drive present\n"
  1227.         jmp     .ch2_check
  1228. @@:
  1229.         mov     dx, [IDE_BAR1_val] ;0x3F4
  1230.         add     dx, 2 ;0x3F6
  1231.         out     dx, al
  1232.         DEBUGF  1, "K : IDE CH1 DMA enabled\n"
  1233. .ch2_check:
  1234.         test    ah, 1010b
  1235.         jz      @f
  1236.  
  1237.         DEBUGF  1, "K : IDE CH2 PIO, because ATAPI drive present\n"
  1238.         jmp     .end_set_interrupts
  1239. @@:
  1240.         mov     dx, [IDE_BAR3_val] ;0x374
  1241.         add     dx, 2 ;0x376
  1242.         out     dx, al
  1243.         DEBUGF  1, "K : IDE CH2 DMA enabled\n"
  1244. ;--------------------------------------
  1245. .end_set_interrupts:
  1246. ;-----------------------------------------------------------------------------
  1247.         cmp     [dma_hdd], 0
  1248.         je      .print_pio
  1249. .print_dma:
  1250.         DEBUGF  1, "K : IDE DMA mode\n"
  1251.         jmp     .continue
  1252.  
  1253. .print_pio:
  1254.         DEBUGF  1, "K : IDE PIO mode\n"
  1255. .continue:
  1256.  
  1257.         mov     [timer_ticks_enable], 1         ; for cd driver
  1258.  
  1259.         sti
  1260. ;        call    change_task
  1261.  
  1262.         jmp     osloop
  1263.  
  1264.  
  1265.         ; Fly :)
  1266.  
  1267. include 'unpacker.inc'
  1268.  
  1269. align 4
  1270. boot_log:
  1271.         pushad
  1272.  
  1273.         mov     ebx, 10*65536
  1274.         mov     bx, word [boot_y]
  1275.         add     [boot_y], dword 10
  1276.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1277.         xor     edi, edi
  1278.         mov     edx, esi
  1279.         inc     edi
  1280.         call    dtext
  1281.  
  1282.         mov     [novesachecksum], 1000
  1283.         call    checkVga_N13
  1284.  
  1285.         popad
  1286.  
  1287.         ret
  1288.  
  1289. ; in: edx -> APPDATA for OS/IDLE slot
  1290. ; in: ebx = stack base
  1291. proc setup_os_slot
  1292.         xor     eax, eax
  1293.         mov     ecx, 256/4
  1294.         mov     edi, edx
  1295.         rep stosd
  1296.  
  1297.         mov     eax, tss+0x80
  1298.         call    get_pg_addr
  1299.         inc     eax
  1300.         mov     [edx+APPDATA.io_map], eax
  1301.         mov     eax, tss+0x1080
  1302.         call    get_pg_addr
  1303.         inc     eax
  1304.         mov     [edx+APPDATA.io_map+4], eax
  1305.  
  1306.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1307.         lea     edi, [ebx+0x2000-512]
  1308.         mov     dword [edx+APPDATA.fpu_state], edi
  1309.         mov     dword [edx+APPDATA.saved_esp0], edi
  1310.         mov     dword [edx+APPDATA.saved_esp], edi
  1311.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1312.  
  1313.         mov     esi, fpu_data
  1314.         mov     ecx, 512/4
  1315.         cld
  1316.         rep movsd
  1317.  
  1318.         lea     eax, [edx+APP_OBJ_OFFSET]
  1319.         mov     dword [edx+APPDATA.fd_obj], eax
  1320.         mov     dword [edx+APPDATA.bk_obj], eax
  1321.  
  1322.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1323.  
  1324.         mov     [edx + APPDATA.dir_table], sys_pgdir - OS_BASE
  1325.  
  1326.         mov     eax, edx
  1327.         shr     eax, 3
  1328.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1329.         mov     [eax+TASKDATA.wnd_number], dh
  1330.         mov     byte [eax+TASKDATA.pid], dh
  1331.  
  1332.         ret
  1333. endp
  1334.  
  1335. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1336. ;                                                                    ;
  1337. ;                    MAIN OS LOOP START                              ;
  1338. ;                                                                    ;
  1339. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1340. align 32
  1341. osloop:
  1342.         mov     edx, osloop_has_work?
  1343.         xor     ecx, ecx
  1344.         call    Wait_events
  1345.         xor     eax, eax
  1346.         xchg    eax, [osloop_nonperiodic_work]
  1347.         test    eax, eax
  1348.         jz      .no_periodic
  1349. ;        call    [draw_pointer]
  1350.         call    __sys_draw_pointer
  1351.         call    window_check_events
  1352.         call    mouse_check_events
  1353.         call    checkmisc
  1354.         call    checkVga_N13
  1355. .no_periodic:
  1356.         call    stack_handler
  1357.         call    check_fdd_motor_status
  1358.         call    check_ATAPI_device_event
  1359.         call    check_lights_state
  1360.         call    check_timers
  1361.         jmp     osloop
  1362. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1363. ;                                                                    ;
  1364. ;                      MAIN OS LOOP END                              ;
  1365. ;                                                                    ;
  1366. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1367. proc osloop_has_work?
  1368.         cmp     [osloop_nonperiodic_work], 0
  1369.         jnz     .yes
  1370.         call    stack_handler_has_work?
  1371.         jnz     .yes
  1372.         call    check_fdd_motor_status_has_work?
  1373.         jnz     .yes
  1374.         call    check_ATAPI_device_event_has_work?
  1375.         jnz     .yes
  1376.         call    check_lights_state_has_work?
  1377.         jnz     .yes
  1378.         call    check_timers_has_work?
  1379.         jnz     .yes
  1380. .no:
  1381.         xor     eax, eax
  1382.         ret
  1383. .yes:
  1384.         xor     eax, eax
  1385.         inc     eax
  1386.         ret
  1387. endp
  1388.  
  1389. proc wakeup_osloop
  1390.         mov     [osloop_nonperiodic_work], 1
  1391.         ret
  1392. endp
  1393.  
  1394. uglobal
  1395. align 4
  1396. osloop_nonperiodic_work dd      ?
  1397. endg
  1398.  
  1399. align 4
  1400. idle_thread:
  1401.         sti
  1402. idle_loop:
  1403.         hlt
  1404.         jmp     idle_loop
  1405.  
  1406.  
  1407.  
  1408. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1409. ;                                                                      ;
  1410. ;                   INCLUDED SYSTEM FILES                              ;
  1411. ;                                                                      ;
  1412. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1413.  
  1414.  
  1415. include "kernel32.inc"
  1416.  
  1417.  
  1418. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1419. ;                                                                      ;
  1420. ;                       KERNEL FUNCTIONS                               ;
  1421. ;                                                                      ;
  1422. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1423.  
  1424. reserve_irqs_ports:
  1425.  
  1426.  
  1427. ; RESERVE PORTS
  1428.         mov     eax, RESERVED_PORTS
  1429.         mov     ecx, 1
  1430.  
  1431.         mov     [eax], dword 4
  1432.  
  1433.         mov     [eax+16], ecx
  1434.         mov     [eax+16+4], dword 0
  1435.         mov     [eax+16+8], dword 0x2D
  1436.  
  1437.         mov     [eax+32], ecx
  1438.         mov     [eax+32+4], dword 0x30
  1439.         mov     [eax+32+8], dword 0x4D
  1440.  
  1441.         mov     [eax+48], ecx
  1442.         mov     [eax+48+4], dword 0x50
  1443.         mov     [eax+48+8], dword 0xDF
  1444.  
  1445.         mov     [eax+64], ecx
  1446.         mov     [eax+64+4], dword 0xE5
  1447.         mov     [eax+64+8], dword 0xFF
  1448.  
  1449.         ret
  1450.  
  1451.  
  1452. iglobal
  1453.   process_number dd 0x2
  1454. endg
  1455.  
  1456. set_variables:
  1457.  
  1458.         mov     ecx, 0x16                    ; flush port 0x60
  1459. .fl60:
  1460.         in      al, 0x60
  1461.         loop    .fl60
  1462.         push    eax
  1463.  
  1464.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1465.         shr     ax, 1
  1466.         shl     eax, 16
  1467.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1468.         shr     ax, 1
  1469.         mov     [MOUSE_X], eax
  1470.         call    wakeup_osloop
  1471.  
  1472.         xor     eax, eax
  1473.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1474.  
  1475.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1476.         mov     byte [BTN_COUNT], al              ; button buffer
  1477. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1478.  
  1479.         pop     eax
  1480.         ret
  1481.  
  1482. align 4
  1483. ;input  eax=43,bl-byte of output, ecx - number of port
  1484. sys_outport:
  1485.  
  1486.         mov     edi, ecx   ; separate flag for read / write
  1487.         and     ecx, 65535
  1488.  
  1489.         mov     eax, [RESERVED_PORTS]
  1490.         test    eax, eax
  1491.         jnz     .sopl8
  1492.         inc     eax
  1493.         mov     [esp+32], eax
  1494.         ret
  1495.  
  1496.   .sopl8:
  1497.         mov     edx, [TASK_BASE]
  1498.         mov     edx, [edx+0x4]
  1499.     ;and   ecx,65535
  1500.     ;cld - set on interrupt 0x40
  1501.   .sopl1:
  1502.  
  1503.         mov     esi, eax
  1504.         shl     esi, 4
  1505.         add     esi, RESERVED_PORTS
  1506.         cmp     edx, [esi+0]
  1507.         jne     .sopl2
  1508.         cmp     ecx, [esi+4]
  1509.         jb      .sopl2
  1510.         cmp     ecx, [esi+8]
  1511.         jg      .sopl2
  1512. .sopl3:
  1513.  
  1514.         test    edi, 0x80000000; read ?
  1515.         jnz     .sopl4
  1516.  
  1517.         mov     eax, ebx
  1518.         mov     dx, cx   ; write
  1519.         out     dx, al
  1520.         and     [esp+32], dword 0
  1521.         ret
  1522.  
  1523.         .sopl2:
  1524.  
  1525.         dec     eax
  1526.         jnz     .sopl1
  1527.         inc     eax
  1528.         mov     [esp+32], eax
  1529.         ret
  1530.  
  1531.  
  1532.   .sopl4:
  1533.  
  1534.         mov     dx, cx   ; read
  1535.         in      al, dx
  1536.         and     eax, 0xff
  1537.         and     [esp+32], dword 0
  1538.         mov     [esp+20], eax
  1539.         ret
  1540.  
  1541. display_number:
  1542. ;It is not optimization
  1543.         mov     eax, ebx
  1544.         mov     ebx, ecx
  1545.         mov     ecx, edx
  1546.         mov     edx, esi
  1547.         mov     esi, edi
  1548. ; eax = print type, al=0 -> ebx is number
  1549. ;                   al=1 -> ebx is pointer
  1550. ;                   ah=0 -> display decimal
  1551. ;                   ah=1 -> display hexadecimal
  1552. ;                   ah=2 -> display binary
  1553. ;                   eax bits 16-21 = number of digits to display (0-32)
  1554. ;                   eax bits 22-31 = reserved
  1555. ;
  1556. ; ebx = number or pointer
  1557. ; ecx = x shl 16 + y
  1558. ; edx = color
  1559.         xor     edi, edi
  1560. display_number_force:
  1561.         push    eax
  1562.         and     eax, 0x3fffffff
  1563.         cmp     eax, 0xffff     ; length > 0 ?
  1564.         pop     eax
  1565.         jge     cont_displ
  1566.         ret
  1567.    cont_displ:
  1568.         push    eax
  1569.         and     eax, 0x3fffffff
  1570.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1571.         pop     eax
  1572.         jb      cont_displ2
  1573.         ret
  1574.    cont_displ2:
  1575.  
  1576.         pushad
  1577.  
  1578.         cmp     al, 1            ; ecx is a pointer ?
  1579.         jne     displnl1
  1580.         mov     ebp, ebx
  1581.         add     ebp, 4
  1582.         mov     ebp, [ebp+std_application_base_address]
  1583.         mov     ebx, [ebx+std_application_base_address]
  1584.  displnl1:
  1585.         sub     esp, 64
  1586.  
  1587.         test    ah, ah            ; DECIMAL
  1588.         jnz     no_display_desnum
  1589.         shr     eax, 16
  1590.         and     eax, 0xC03f
  1591. ;     and   eax,0x3f
  1592.         push    eax
  1593.         and     eax, 0x3f
  1594.         mov     edi, esp
  1595.         add     edi, 4+64-1
  1596.         mov     ecx, eax
  1597.         mov     eax, ebx
  1598.         mov     ebx, 10
  1599.  d_desnum:
  1600.         xor     edx, edx
  1601.         call    division_64_bits
  1602.         div     ebx
  1603.         add     dl, 48
  1604.         mov     [edi], dl
  1605.         dec     edi
  1606.         loop    d_desnum
  1607.         pop     eax
  1608.         call    normalize_number
  1609.         call    draw_num_text
  1610.         add     esp, 64
  1611.         popad
  1612.         ret
  1613.    no_display_desnum:
  1614.  
  1615.         cmp     ah, 0x01         ; HEXADECIMAL
  1616.         jne     no_display_hexnum
  1617.         shr     eax, 16
  1618.         and     eax, 0xC03f
  1619. ;     and   eax,0x3f
  1620.         push    eax
  1621.         and     eax, 0x3f
  1622.         mov     edi, esp
  1623.         add     edi, 4+64-1
  1624.         mov     ecx, eax
  1625.         mov     eax, ebx
  1626.         mov     ebx, 16
  1627.    d_hexnum:
  1628.         xor     edx, edx
  1629.         call    division_64_bits
  1630.         div     ebx
  1631.    hexletters = __fdo_hexdigits
  1632.         add     edx, hexletters
  1633.         mov     dl, [edx]
  1634.         mov     [edi], dl
  1635.         dec     edi
  1636.         loop    d_hexnum
  1637.         pop     eax
  1638.         call    normalize_number
  1639.         call    draw_num_text
  1640.         add     esp, 64
  1641.         popad
  1642.         ret
  1643.    no_display_hexnum:
  1644.  
  1645.         cmp     ah, 0x02         ; BINARY
  1646.         jne     no_display_binnum
  1647.         shr     eax, 16
  1648.         and     eax, 0xC03f
  1649. ;     and   eax,0x3f
  1650.         push    eax
  1651.         and     eax, 0x3f
  1652.         mov     edi, esp
  1653.         add     edi, 4+64-1
  1654.         mov     ecx, eax
  1655.         mov     eax, ebx
  1656.         mov     ebx, 2
  1657.    d_binnum:
  1658.         xor     edx, edx
  1659.         call    division_64_bits
  1660.         div     ebx
  1661.         add     dl, 48
  1662.         mov     [edi], dl
  1663.         dec     edi
  1664.         loop    d_binnum
  1665.         pop     eax
  1666.         call    normalize_number
  1667.         call    draw_num_text
  1668.         add     esp, 64
  1669.         popad
  1670.         ret
  1671.    no_display_binnum:
  1672.  
  1673.         add     esp, 64
  1674.         popad
  1675.         ret
  1676.  
  1677. normalize_number:
  1678.         test    ah, 0x80
  1679.         jz      .continue
  1680.         mov     ecx, 48
  1681.         and     eax, 0x3f
  1682. @@:
  1683.         inc     edi
  1684.         cmp     [edi], cl
  1685.         jne     .continue
  1686.         dec     eax
  1687.         cmp     eax, 1
  1688.         ja      @r
  1689.         mov     al, 1
  1690. .continue:
  1691.         and     eax, 0x3f
  1692.         ret
  1693.  
  1694. division_64_bits:
  1695.         test    [esp+1+4], byte 0x40
  1696.         jz      .continue
  1697.         push    eax
  1698.         mov     eax, ebp
  1699.         div     ebx
  1700.         mov     ebp, eax
  1701.         pop     eax
  1702. .continue:
  1703.         ret
  1704.  
  1705. draw_num_text:
  1706.         mov     esi, eax
  1707.         mov     edx, 64+4
  1708.         sub     edx, eax
  1709.         add     edx, esp
  1710.         mov     ebx, [esp+64+32-8+4]
  1711. ; add window start x & y
  1712.         mov     ecx, [TASK_BASE]
  1713.  
  1714.         mov     edi, [CURRENT_TASK]
  1715.         shl     edi, 8
  1716.  
  1717.         mov     eax, [ecx-twdw+WDATA.box.left]
  1718.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1719.         shl     eax, 16
  1720.         add     eax, [ecx-twdw+WDATA.box.top]
  1721.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1722.         add     ebx, eax
  1723.         mov     ecx, [esp+64+32-12+4]
  1724.         and     ecx, not 0x80000000     ; force counted string
  1725.         mov     eax, [esp+64+8]         ; background color (if given)
  1726.         mov     edi, [esp+64+4]
  1727.         jmp     dtext
  1728.  
  1729. align 4
  1730.  
  1731. sys_setup:
  1732.  
  1733. ; 1=roland mpu midi base , base io address
  1734. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1735. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1736. ; 5=system language, 1eng 2fi 3ger 4rus
  1737. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1738. ; 8=fat32 partition in hd
  1739. ; 9
  1740. ; 10 = sound dma channel
  1741. ; 11 = enable lba read
  1742. ; 12 = enable pci access
  1743.  
  1744.  
  1745.         and     [esp+32], dword 0
  1746.         dec     ebx                             ; MIDI
  1747.         jnz     nsyse1
  1748.         cmp     ecx, 0x100
  1749.  
  1750.         jb      nsyse1
  1751.         mov     esi, 65535
  1752.         cmp     esi, ecx
  1753.  
  1754.         jb      nsyse1
  1755.         mov     [midi_base], cx ;bx
  1756.         mov     word [mididp], cx;bx
  1757.         inc     cx              ;bx
  1758.         mov     word [midisp], cx;bx
  1759.         ret
  1760.  
  1761. iglobal
  1762. midi_base dw 0
  1763. endg
  1764.  
  1765.    nsyse1:
  1766.         dec     ebx                              ; KEYBOARD
  1767.         jnz     nsyse2
  1768.         mov     edi, [TASK_BASE]
  1769.         mov     eax, [edi+TASKDATA.mem_start]
  1770.         add     eax, edx
  1771.  
  1772.         dec     ecx
  1773.         jnz     kbnobase
  1774.         mov     ebx, keymap
  1775.         mov     ecx, 128
  1776.         call    memmove
  1777.         ret
  1778.    kbnobase:
  1779.         dec     ecx
  1780.         jnz     kbnoshift
  1781.  
  1782.         mov     ebx, keymap_shift
  1783.         mov     ecx, 128
  1784.         call    memmove
  1785.         ret
  1786.    kbnoshift:
  1787.         dec     ecx
  1788.         jnz     kbnoalt
  1789.         mov     ebx, keymap_alt
  1790.         mov     ecx, 128
  1791.         call    memmove
  1792.         ret
  1793.    kbnoalt:
  1794.         sub     ecx, 6
  1795.         jnz     kbnocountry
  1796.         mov     word [keyboard], dx
  1797.         ret
  1798.    kbnocountry:
  1799.         mov     [esp+32], dword 1
  1800.         ret
  1801.    nsyse2:
  1802.         dec     ebx                         ; CD
  1803.         jnz     nsyse4
  1804.  
  1805.         test    ecx, ecx
  1806.         jz      nosesl
  1807.  
  1808.         cmp     ecx, 4
  1809.         ja      nosesl
  1810.         mov     [cd_base], cl
  1811.  
  1812.         dec     ecx
  1813.         jnz     noprma
  1814.         mov     eax, [hd_address_table]
  1815.         mov     [cdbase], eax   ;0x1f0
  1816.         mov     [cdid], 0xa0
  1817.    noprma:
  1818.  
  1819.         dec     ecx
  1820.         jnz     noprsl
  1821.         mov     eax, [hd_address_table]
  1822.         mov     [cdbase], eax   ;0x1f0
  1823.         mov     [cdid], 0xb0
  1824.    noprsl:
  1825.         dec     ecx
  1826.         jnz     nosema
  1827.         mov     eax, [hd_address_table+16]
  1828.         mov     [cdbase], eax   ;0x170
  1829.         mov     [cdid], 0xa0
  1830.    nosema:
  1831.         dec     ecx
  1832.         jnz     nosesl
  1833.         mov     eax, [hd_address_table+16]
  1834.         mov     [cdbase], eax   ;0x170
  1835.         mov     [cdid], 0xb0
  1836.    nosesl:
  1837.         ret
  1838.  
  1839. iglobal
  1840. cd_base db 0
  1841.  
  1842. endg
  1843.    nsyse4:
  1844.  
  1845.         sub     ebx, 2           ; SYSTEM LANGUAGE
  1846.         jnz     nsyse5
  1847.         mov     [syslang], ecx
  1848.         ret
  1849.    nsyse5:
  1850.  
  1851.         sub     ebx, 2          ; HD BASE - obsolete
  1852.         jnz     nsyse7
  1853.  
  1854.    nosethd:
  1855.         ret
  1856.  
  1857. nsyse7:
  1858.  
  1859. ;     cmp  eax,8                      ; HD PARTITION - obsolete
  1860.         dec     ebx
  1861.         jnz     nsyse8
  1862.         ret
  1863.  
  1864. nsyse8:
  1865. ;     cmp  eax,11                     ; ENABLE LBA READ
  1866.         and     ecx, 1
  1867.         sub     ebx, 3
  1868.         jnz     no_set_lba_read
  1869.         mov     [lba_read_enabled], ecx
  1870.         ret
  1871.  
  1872. no_set_lba_read:
  1873. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1874.         dec     ebx
  1875.         jnz     sys_setup_err
  1876.         mov     [pci_access_enabled], ecx
  1877.         ret
  1878.  
  1879. sys_setup_err:
  1880.         or      [esp+32], dword -1
  1881.         ret
  1882.  
  1883. align 4
  1884.  
  1885. sys_getsetup:
  1886.  
  1887. ; 1=roland mpu midi base , base io address
  1888. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1889. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1890. ; 5=system language, 1eng 2fi 3ger 4rus
  1891. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1892. ; 8=fat32 partition in hd
  1893. ; 9=get hs timer tic
  1894.  
  1895. ;     cmp  eax,1
  1896.         dec     ebx
  1897.         jnz     ngsyse1
  1898.         movzx   eax, [midi_base]
  1899.         mov     [esp+32], eax
  1900.         ret
  1901. ngsyse1:
  1902. ;     cmp  eax,2
  1903.         dec     ebx
  1904.         jnz     ngsyse2
  1905.  
  1906.         mov     edi, [TASK_BASE]
  1907.         mov     ebx, [edi+TASKDATA.mem_start]
  1908.         add     ebx, edx
  1909.  
  1910. ;     cmp  ebx,1
  1911.         dec     ecx
  1912.         jnz     kbnobaseret
  1913.         mov     eax, keymap
  1914.         mov     ecx, 128
  1915.         call    memmove
  1916.         ret
  1917. kbnobaseret:
  1918. ;     cmp  ebx,2
  1919.         dec     ecx
  1920.         jnz     kbnoshiftret
  1921.  
  1922.         mov     eax, keymap_shift
  1923.         mov     ecx, 128
  1924.         call    memmove
  1925.         ret
  1926. kbnoshiftret:
  1927. ;     cmp  ebx,3
  1928.         dec     ecx
  1929.         jne     kbnoaltret
  1930.  
  1931.         mov     eax, keymap_alt
  1932.         mov     ecx, 128
  1933.         call    memmove
  1934.         ret
  1935. kbnoaltret:
  1936. ;     cmp  ebx,9
  1937.         sub     ecx, 6
  1938.         jnz     ngsyse2
  1939.         movzx   eax, word [keyboard]
  1940.         mov     [esp+32], eax
  1941.         ret
  1942.  
  1943.  
  1944. ngsyse2:
  1945. ;         cmp  eax,3
  1946.         dec     ebx
  1947.         jnz     ngsyse3
  1948.         movzx   eax, [cd_base]
  1949.         mov     [esp+32], eax
  1950.         ret
  1951. ngsyse3:
  1952. ;         cmp  eax,5
  1953.         sub     ebx, 2
  1954.         jnz     ngsyse5
  1955.         mov     eax, [syslang]
  1956.         mov     [esp+32], eax
  1957.         ret
  1958. ngsyse5:
  1959. ;     cmp  eax,7
  1960.         sub     ebx, 2
  1961.         jnz     ngsyse7
  1962.         xor     eax, eax
  1963.         mov     [esp+32], eax
  1964.         ret
  1965. ngsyse7:
  1966. ;     cmp  eax,8
  1967.         dec     ebx
  1968.         jnz     ngsyse8
  1969.         mov     eax, [fat32part]
  1970.         mov     [esp+32], eax
  1971.         ret
  1972. ngsyse8:
  1973. ;     cmp  eax,9
  1974.         dec     ebx
  1975.         jnz     ngsyse9
  1976.         mov     eax, [timer_ticks];[0xfdf0]
  1977.         mov     [esp+32], eax
  1978.         ret
  1979. ngsyse9:
  1980. ;     cmp  eax,11
  1981.         sub     ebx, 2
  1982.         jnz     ngsyse11
  1983.         mov     eax, [lba_read_enabled]
  1984.         mov     [esp+32], eax
  1985.         ret
  1986. ngsyse11:
  1987. ;     cmp  eax,12
  1988.         dec     ebx
  1989.         jnz     ngsyse12
  1990.         mov     eax, [pci_access_enabled]
  1991.         mov     [esp+32], eax
  1992.         ret
  1993. ngsyse12:
  1994.         mov     [esp+32], dword 1
  1995.         ret
  1996.  
  1997.  
  1998. get_timer_ticks:
  1999.         mov     eax, [timer_ticks]
  2000.         ret
  2001.  
  2002. iglobal
  2003. align 4
  2004. mousefn dd msscreen, mswin, msbutton, msset
  2005.         dd app_load_cursor
  2006.         dd app_set_cursor
  2007.         dd app_delete_cursor
  2008.         dd msz
  2009. endg
  2010.  
  2011. readmousepos:
  2012.  
  2013. ; eax=0 screen relative
  2014. ; eax=1 window relative
  2015. ; eax=2 buttons pressed
  2016. ; eax=3 set mouse pos   ; reserved
  2017. ; eax=4 load cursor
  2018. ; eax=5 set cursor
  2019. ; eax=6 delete cursor   ; reserved
  2020. ; eax=7 get mouse_z
  2021.  
  2022.         cmp     ebx, 7
  2023.         ja      msset
  2024.         jmp     [mousefn+ebx*4]
  2025. msscreen:
  2026.         mov     eax, [MOUSE_X]
  2027.         shl     eax, 16
  2028.         mov     ax, [MOUSE_Y]
  2029.         mov     [esp+36-4], eax
  2030.         ret
  2031. mswin:
  2032.         mov     eax, [MOUSE_X]
  2033.         shl     eax, 16
  2034.         mov     ax, [MOUSE_Y]
  2035.         mov     esi, [TASK_BASE]
  2036.         mov     bx, word [esi-twdw+WDATA.box.left]
  2037.         shl     ebx, 16
  2038.         mov     bx, word [esi-twdw+WDATA.box.top]
  2039.         sub     eax, ebx
  2040.  
  2041.         mov     edi, [CURRENT_TASK]
  2042.         shl     edi, 8
  2043.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  2044.         rol     eax, 16
  2045.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  2046.         rol     eax, 16
  2047.         mov     [esp+36-4], eax
  2048.         ret
  2049. msbutton:
  2050.         movzx   eax, byte [BTN_DOWN]
  2051.         mov     [esp+36-4], eax
  2052.         ret
  2053. msz:
  2054.         mov     edi, [TASK_COUNT]
  2055.         movzx   edi, word [WIN_POS + edi*2]
  2056.         cmp     edi, [CURRENT_TASK]
  2057.         jne     @f
  2058.         mov     ax, [MOUSE_SCROLL_H]
  2059.         shl     eax, 16
  2060.         mov     ax, [MOUSE_SCROLL_V]
  2061.         mov     [esp+36-4], eax
  2062.         and     [MOUSE_SCROLL_H], word 0
  2063.         and     [MOUSE_SCROLL_V], word 0
  2064.         ret
  2065.        @@:
  2066.         and     [esp+36-4], dword 0
  2067. ;           ret
  2068. msset:
  2069.         ret
  2070.  
  2071. app_load_cursor:
  2072.         cmp     ecx, OS_BASE
  2073.         jae     msset
  2074.         stdcall load_cursor, ecx, edx
  2075.         mov     [esp+36-4], eax
  2076.         ret
  2077.  
  2078. app_set_cursor:
  2079.         stdcall set_cursor, ecx
  2080.         mov     [esp+36-4], eax
  2081.         ret
  2082.  
  2083. app_delete_cursor:
  2084.         stdcall delete_cursor, ecx
  2085.         mov     [esp+36-4], eax
  2086.         ret
  2087.  
  2088. is_input:
  2089.  
  2090.         push    edx
  2091.         mov     dx, word [midisp]
  2092.         in      al, dx
  2093.         and     al, 0x80
  2094.         pop     edx
  2095.         ret
  2096.  
  2097. is_output:
  2098.  
  2099.         push    edx
  2100.         mov     dx, word [midisp]
  2101.         in      al, dx
  2102.         and     al, 0x40
  2103.         pop     edx
  2104.         ret
  2105.  
  2106.  
  2107. get_mpu_in:
  2108.  
  2109.         push    edx
  2110.         mov     dx, word [mididp]
  2111.         in      al, dx
  2112.         pop     edx
  2113.         ret
  2114.  
  2115.  
  2116. put_mpu_out:
  2117.  
  2118.         push    edx
  2119.         mov     dx, word [mididp]
  2120.         out     dx, al
  2121.         pop     edx
  2122.         ret
  2123.  
  2124.  
  2125.  
  2126. align 4
  2127.  
  2128. sys_midi:
  2129.         cmp     [mididp], 0
  2130.         jnz     sm0
  2131.         mov     [esp+36], dword 1
  2132.         ret
  2133. sm0:
  2134.         and     [esp+36], dword 0
  2135.         dec     ebx
  2136.         jnz     smn1
  2137.  ;    call setuart
  2138. su1:
  2139.         call    is_output
  2140.         test    al, al
  2141.         jnz     su1
  2142.         mov     dx, word [midisp]
  2143.         mov     al, 0xff
  2144.         out     dx, al
  2145. su2:
  2146.         mov     dx, word [midisp]
  2147.         mov     al, 0xff
  2148.         out     dx, al
  2149.         call    is_input
  2150.         test    al, al
  2151.         jnz     su2
  2152.         call    get_mpu_in
  2153.         cmp     al, 0xfe
  2154.         jnz     su2
  2155. su3:
  2156.         call    is_output
  2157.         test    al, al
  2158.         jnz     su3
  2159.         mov     dx, word [midisp]
  2160.         mov     al, 0x3f
  2161.         out     dx, al
  2162.         ret
  2163. smn1:
  2164.         dec     ebx
  2165.         jnz     smn2
  2166. sm10:
  2167.         call    get_mpu_in
  2168.         call    is_output
  2169.         test    al, al
  2170.         jnz     sm10
  2171.         mov     al, bl
  2172.         call    put_mpu_out
  2173.         smn2:
  2174.         ret
  2175.  
  2176. detect_devices:
  2177. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2178. ;include 'detect/commouse.inc'
  2179. ;include 'detect/ps2mouse.inc'
  2180. ;include 'detect/dev_fd.inc'
  2181. ;include 'detect/dev_hdcd.inc'
  2182. ;include 'detect/sear_par.inc'
  2183. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2184.         ret
  2185.  
  2186. sys_end:
  2187. ;--------------------------------------
  2188.         cmp     [_display.select_cursor], 0
  2189.         je      @f
  2190. ; restore default cursor before killing
  2191.         pusha
  2192.         mov     ecx, [current_slot]
  2193.         call    restore_default_cursor_before_killing
  2194.         popa
  2195. @@:
  2196. ;--------------------------------------
  2197. ; kill all sockets this process owns
  2198.         pusha
  2199.         mov     edx, [TASK_BASE]
  2200.         mov     edx, [edx+TASKDATA.pid]
  2201.         call    SOCKET_process_end
  2202.         popa
  2203. ;--------------------------------------
  2204.         mov     ecx, [current_slot]
  2205.         mov     eax, [ecx+APPDATA.tls_base]
  2206.         test    eax, eax
  2207.         jz      @F
  2208.  
  2209.         stdcall user_free, eax
  2210. @@:
  2211.  
  2212.         mov     eax, [TASK_BASE]
  2213.         mov     [eax+TASKDATA.state], 3; terminate this program
  2214.         call    wakeup_osloop
  2215.  
  2216. .waitterm:            ; wait here for termination
  2217.         call    change_task
  2218.         jmp     .waitterm
  2219. ;------------------------------------------------------------------------------
  2220. align 4
  2221. restore_default_cursor_before_killing:
  2222.         pushfd
  2223.         cli
  2224.         mov     eax, [def_cursor]
  2225.         mov     [ecx+APPDATA.cursor], eax
  2226.  
  2227.         movzx   eax, word [MOUSE_Y]
  2228.         movzx   ebx, word [MOUSE_X]
  2229. ;        mov     ecx, [Screen_Max_X]
  2230. ;        inc     ecx
  2231. ;        mul     ecx
  2232.         mov     eax, [d_width_calc_area + eax*4]
  2233.  
  2234.         add     eax, [_WinMapAddress]
  2235.         movzx   edx, byte [ebx+eax]
  2236.         shl     edx, 8
  2237.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2238.  
  2239.         cmp     esi, [current_cursor]
  2240.         je      @f
  2241.  
  2242.         push    esi
  2243.         call    [_display.select_cursor]
  2244.         mov     [current_cursor], esi
  2245. @@:
  2246.         mov     [redrawmouse_unconditional], 1
  2247.         call    wakeup_osloop
  2248.         popfd
  2249.         ret
  2250. ;------------------------------------------------------------------------------
  2251. iglobal
  2252. align 4
  2253. sys_system_table:
  2254.         dd      sysfn_deactivate        ; 1 = deactivate window
  2255.         dd      sysfn_terminate         ; 2 = terminate thread
  2256.         dd      sysfn_activate          ; 3 = activate window
  2257.         dd      sysfn_getidletime       ; 4 = get idle time
  2258.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2259.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2260.         dd      sysfn_getactive         ; 7 = get active window
  2261.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2262.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2263.         dd      sysfn_minimize          ; 10 = minimize window
  2264.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2265.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2266.         dd      sysfn_getversion        ; 13 = get kernel version
  2267.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2268.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2269.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2270.         dd      sysfn_getallmem         ; 17 = get total memory size
  2271.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2272.                                         ;                 instead of slot
  2273.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2274.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2275.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2276.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2277.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2278.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2279. sysfn_num = ($ - sys_system_table)/4
  2280. endg
  2281. ;------------------------------------------------------------------------------
  2282. sys_system:
  2283.         dec     ebx
  2284.         cmp     ebx, sysfn_num
  2285.         jae     @f
  2286.         jmp     dword [sys_system_table + ebx*4]
  2287. @@:
  2288.         ret
  2289. ;------------------------------------------------------------------------------
  2290. sysfn_shutdown:          ; 18.9 = system shutdown
  2291.         cmp     ecx, 1
  2292.         jl      exit_for_anyone
  2293.         cmp     ecx, 4
  2294.         jg      exit_for_anyone
  2295.         mov     [BOOT_VARS+0x9030], cl
  2296.  
  2297.         mov     eax, [TASK_COUNT]
  2298.         mov     [SYS_SHUTDOWN], al
  2299.         mov     [shutdown_processes], eax
  2300.         call    wakeup_osloop
  2301.         and     dword [esp+32], 0
  2302.  exit_for_anyone:
  2303.         ret
  2304.   uglobal
  2305.    shutdown_processes:
  2306.                        dd 0x0
  2307.   endg
  2308. ;------------------------------------------------------------------------------
  2309. sysfn_terminate:        ; 18.2 = TERMINATE
  2310.         push    ecx
  2311.         cmp     ecx, 2
  2312.         jb      noprocessterminate
  2313.         mov     edx, [TASK_COUNT]
  2314.         cmp     ecx, edx
  2315.         ja      noprocessterminate
  2316.         mov     eax, [TASK_COUNT]
  2317.         shl     ecx, 5
  2318.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2319.         add     ecx, CURRENT_TASK+TASKDATA.state
  2320.         cmp     byte [ecx], 9
  2321.         jz      noprocessterminate
  2322.         push    ecx edx
  2323.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2324.         call    request_terminate
  2325.         pop     edx ecx
  2326.         test    eax, eax
  2327.         jz      noprocessterminate
  2328. ;--------------------------------------
  2329. ; terminate all network sockets it used
  2330.         pusha
  2331.         mov     eax, edx
  2332.         call    SOCKET_process_end
  2333.         popa
  2334. ;--------------------------------------
  2335.         cmp     [_display.select_cursor], 0
  2336.         je      .restore_end
  2337. ; restore default cursor before killing
  2338.         pusha
  2339.         mov     ecx, [esp+32]
  2340.         shl     ecx, 8
  2341.         add     ecx, SLOT_BASE
  2342.         mov     eax, [def_cursor]
  2343.         cmp     [ecx+APPDATA.cursor], eax
  2344.         je      @f
  2345.         call    restore_default_cursor_before_killing
  2346. @@:
  2347.         popa
  2348. .restore_end:
  2349. ;--------------------------------------
  2350.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2351.         mov     [ecx], byte 3; clear possible i40's
  2352.         call    wakeup_osloop
  2353.      ;call MEM_Heap_UnLock
  2354.  
  2355.         cmp     edx, [application_table_owner]; clear app table stat
  2356.         jne     noatsc
  2357.         call    unlock_application_table
  2358. noatsc:
  2359. noprocessterminate:
  2360.         add     esp, 4
  2361.         ret
  2362. ;------------------------------------------------------------------------------
  2363. sysfn_terminate2:
  2364. ;lock application_table_status mutex
  2365. .table_status:
  2366.         call    lock_application_table
  2367.         mov     eax, ecx
  2368.         call    pid_to_slot
  2369.         test    eax, eax
  2370.         jz      .not_found
  2371.         mov     ecx, eax
  2372.         cli
  2373.         call    sysfn_terminate
  2374.         call    unlock_application_table
  2375.         sti
  2376.         and     dword [esp+32], 0
  2377.         ret
  2378. .not_found:
  2379.         call    unlock_application_table
  2380.         or      dword [esp+32], -1
  2381.         ret
  2382. ;------------------------------------------------------------------------------
  2383. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2384.         cmp     ecx, 2
  2385.         jb      .nowindowdeactivate
  2386.         cmp     ecx, [TASK_COUNT]
  2387.         ja      .nowindowdeactivate
  2388.  
  2389.         movzx   esi, word [WIN_STACK + ecx*2]
  2390.         cmp     esi, 1
  2391.         je      .nowindowdeactivate ; already deactive
  2392.  
  2393.         mov     edi, ecx
  2394.         shl     edi, 5
  2395.         add     edi, window_data
  2396.         movzx   esi, word [WIN_STACK + ecx * 2]
  2397.         lea     esi, [WIN_POS + esi * 2]
  2398.         call    window._.window_deactivate
  2399.  
  2400.         call    syscall_display_settings._.calculate_whole_screen
  2401.         call    syscall_display_settings._.redraw_whole_screen
  2402. .nowindowdeactivate:
  2403.         ret
  2404. ;------------------------------------------------------------------------------
  2405. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2406.         cmp     ecx, 2
  2407.         jb      .nowindowactivate
  2408.         cmp     ecx, [TASK_COUNT]
  2409.         ja      .nowindowactivate
  2410. ;-------------------------------------
  2411. @@:
  2412. ; If the window is captured and moved by the user,
  2413. ; then you can't change the position in window stack!!!
  2414.         mov     al, [mouse.active_sys_window.action]
  2415.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2416.         test    al, al
  2417.         jz      @f
  2418.         call    change_task
  2419.         jmp     @b
  2420. @@:
  2421. ;-------------------------------------
  2422.         mov     [window_minimize], 2; restore window if minimized
  2423.         call    wakeup_osloop
  2424.  
  2425.         movzx   esi, word [WIN_STACK + ecx*2]
  2426.         cmp     esi, [TASK_COUNT]
  2427.         je      .nowindowactivate; already active
  2428.  
  2429.         mov     edi, ecx
  2430.         shl     edi, 5
  2431.         add     edi, window_data
  2432.         movzx   esi, word [WIN_STACK + ecx * 2]
  2433.         lea     esi, [WIN_POS + esi * 2]
  2434.         call    waredraw
  2435. .nowindowactivate:
  2436.         ret
  2437. ;------------------------------------------------------------------------------
  2438. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2439.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2440.         mov     [esp+32], eax
  2441.         ret
  2442. ;------------------------------------------------------------------------------
  2443. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2444.         mov     eax, dword [cpu_freq]
  2445.         mov     [esp+32], eax
  2446.         ret
  2447. ;------------------------------------------------------------------------------
  2448. get_cpu_freq:
  2449.         mov     eax, dword [cpu_freq]
  2450.         mov     edx, dword [cpu_freq+4]
  2451.         ret
  2452. ;  SAVE ramdisk to /hd/1/menuet.img
  2453. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2454.    include 'blkdev/rdsave.inc'
  2455. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2456. ;------------------------------------------------------------------------------
  2457. align 4
  2458. sysfn_getactive:        ; 18.7 = get active window
  2459.         mov     eax, [TASK_COUNT]
  2460.         movzx   eax, word [WIN_POS + eax*2]
  2461.         mov     [esp+32], eax
  2462.         ret
  2463. ;------------------------------------------------------------------------------
  2464. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2465. ;     cmp  ecx,1
  2466.         dec     ecx
  2467.         jnz     nogetsoundflag
  2468.         movzx   eax, byte [sound_flag]; get sound_flag
  2469.         mov     [esp+32], eax
  2470.         ret
  2471.  nogetsoundflag:
  2472. ;     cmp  ecx,2
  2473.         dec     ecx
  2474.         jnz     nosoundflag
  2475.         xor     byte [sound_flag], 1
  2476.  nosoundflag:
  2477.         ret
  2478. ;------------------------------------------------------------------------------
  2479. sysfn_minimize:         ; 18.10 = minimize window
  2480.         mov     [window_minimize], 1
  2481.         call    wakeup_osloop
  2482.         ret
  2483. ;------------------------------------------------------------------------------
  2484. align 4
  2485. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2486. ;     cmp  ecx,1
  2487.         dec     ecx
  2488.         jnz     full_table
  2489.   small_table:
  2490.         call    for_all_tables
  2491.         mov     ecx, 10
  2492.         cld
  2493.         rep movsb
  2494.         ret
  2495.    for_all_tables:
  2496.         mov     edi, edx
  2497.         mov     esi, DRIVE_DATA
  2498.         ret
  2499.   full_table:
  2500. ;     cmp  ecx,2
  2501.         dec     ecx
  2502.         jnz     exit_for_anyone
  2503.         call    for_all_tables
  2504.         mov     ecx, DRIVE_DATA_SIZE/4
  2505.         cld
  2506.         rep movsd
  2507.         ret
  2508. ;------------------------------------------------------------------------------
  2509. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2510.         and     dword [esp+32], 0
  2511.         ret
  2512. ;------------------------------------------------------------------------------
  2513. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2514.         mov     edi, ecx
  2515.         mov     esi, version_inf
  2516.         mov     ecx, version_end-version_inf
  2517.         rep movsb
  2518.         ret
  2519. ;------------------------------------------------------------------------------
  2520. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2521.      ;wait retrace functions
  2522.  sys_wait_retrace:
  2523.         mov     edx, 0x3da
  2524.  WaitRetrace_loop:
  2525.         in      al, dx
  2526.         test    al, 1000b
  2527.         jz      WaitRetrace_loop
  2528.         and     [esp+32], dword 0
  2529.         ret
  2530. ;------------------------------------------------------------------------------
  2531. align 4
  2532. sysfn_centermouse:      ; 18.15 = mouse centered
  2533. ; removed here by <Lrz>
  2534. ;     call  mouse_centered
  2535. ;* mouse centered - start code- Mario79
  2536. ;mouse_centered:
  2537. ;        push  eax
  2538.         mov     eax, [Screen_Max_X]
  2539.         shr     eax, 1
  2540.         mov     [MOUSE_X], ax
  2541.         mov     eax, [Screen_Max_Y]
  2542.         shr     eax, 1
  2543.         mov     [MOUSE_Y], ax
  2544.         call    wakeup_osloop
  2545. ;        ret
  2546. ;* mouse centered - end code- Mario79
  2547.         xor     eax, eax
  2548.         and     [esp+32], eax
  2549. ;        pop   eax
  2550.         ret
  2551. ;------------------------------------------------------------------------------
  2552. align 4
  2553. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2554.         test    ecx, ecx; get mouse speed factor
  2555.         jnz     .set_mouse_acceleration
  2556.         xor     eax, eax
  2557.         mov     ax, [mouse_speed_factor]
  2558.         mov     [esp+32], eax
  2559.         ret
  2560.  .set_mouse_acceleration:
  2561. ;     cmp  ecx,1  ; set mouse speed factor
  2562.         dec     ecx
  2563.         jnz     .get_mouse_delay
  2564.         mov     [mouse_speed_factor], dx
  2565.         ret
  2566.  .get_mouse_delay:
  2567. ;     cmp  ecx,2  ; get mouse delay
  2568.         dec     ecx
  2569.         jnz     .set_mouse_delay
  2570.         mov     eax, [mouse_delay]
  2571.         mov     [esp+32], eax
  2572.         ret
  2573.  .set_mouse_delay:
  2574. ;     cmp  ecx,3  ; set mouse delay
  2575.         dec     ecx
  2576.         jnz     .set_pointer_position
  2577.         mov     [mouse_delay], edx
  2578.         ret
  2579.  .set_pointer_position:
  2580. ;     cmp  ecx,4  ; set mouse pointer position
  2581.         dec     ecx
  2582.         jnz     .set_mouse_button
  2583.         cmp     dx, word[Screen_Max_Y]
  2584.         ja      .end
  2585.         rol     edx, 16
  2586.         cmp     dx, word[Screen_Max_X]
  2587.         ja      .end
  2588.         mov     [MOUSE_X], edx
  2589.         call    wakeup_osloop
  2590.         ret
  2591.  .set_mouse_button:
  2592. ;     cmp   ecx,5  ; set mouse button features
  2593.         dec     ecx
  2594.         jnz     .end
  2595.         mov     [BTN_DOWN], dl
  2596.         mov     [mouse_active], 1
  2597.         call    wakeup_osloop
  2598.  .end:
  2599.         ret
  2600. ;------------------------------------------------------------------------------
  2601. sysfn_getfreemem:
  2602.         mov     eax, [pg_data.pages_free]
  2603.         shl     eax, 2
  2604.         mov     [esp+32], eax
  2605.         ret
  2606. ;------------------------------------------------------------------------------
  2607. sysfn_getallmem:
  2608.         mov     eax, [MEM_AMOUNT]
  2609.         shr     eax, 10
  2610.         mov     [esp+32], eax
  2611.         ret
  2612. ;------------------------------------------------------------------------------
  2613. sysfn_pid_to_slot:
  2614.         mov     eax, ecx
  2615.         call    pid_to_slot
  2616.         mov     [esp+32], eax
  2617.         ret
  2618. ;------------------------------------------------------------------------------
  2619. sysfn_min_rest_window:
  2620.         pushad
  2621.         mov     eax, edx ; ebx - operating
  2622.         shr     ecx, 1
  2623.         jnc     @f
  2624.         call    pid_to_slot
  2625. @@:
  2626.         or      eax, eax ; eax - number of slot
  2627.         jz      .error
  2628.         cmp     eax, 255    ; varify maximal slot number
  2629.         ja      .error
  2630.         movzx   eax, word [WIN_STACK + eax*2]
  2631.         shr     ecx, 1
  2632.         jc      .restore
  2633.  ; .minimize:
  2634.         call    minimize_window
  2635.         jmp     .exit
  2636. .restore:
  2637.         call    restore_minimized_window
  2638. .exit:
  2639.         popad
  2640.         xor     eax, eax
  2641.         mov     [esp+32], eax
  2642.         ret
  2643. .error:
  2644.         popad
  2645.         xor     eax, eax
  2646.         dec     eax
  2647.         mov     [esp+32], eax
  2648.         ret
  2649. ;------------------------------------------------------------------------------
  2650. sysfn_min_windows:
  2651.         call    minimize_all_window
  2652.         mov     [esp+32], eax
  2653.         call    change_task
  2654.         ret
  2655. ;------------------------------------------------------------------------------
  2656. sysfn_set_screen_sizes:
  2657.         cmp     [SCR_MODE], word 0x13
  2658.         jbe     .exit
  2659.  
  2660.         cmp     [_display.select_cursor], select_cursor
  2661.         jne     .exit
  2662.  
  2663.         cmp     ecx, [display_width_standard]
  2664.         ja      .exit
  2665.  
  2666.         cmp     edx, [display_height_standard]
  2667.         ja      .exit
  2668.  
  2669.         pushfd
  2670.         cli
  2671.         mov     eax, ecx
  2672.         mov     ecx, [_display.pitch]
  2673.         mov     [_display.width], eax
  2674.         dec     eax
  2675.         mov     [_display.height], edx
  2676.         dec     edx
  2677. ; eax - new Screen_Max_X
  2678. ; edx - new Screen_Max_Y
  2679.         mov     [do_not_touch_winmap], 1
  2680.         call    set_screen
  2681.         mov     [do_not_touch_winmap], 0
  2682.         popfd
  2683.         call    change_task
  2684. .exit:
  2685.         ret
  2686. ;------------------------------------------------------------------------------
  2687. uglobal
  2688. screen_workarea RECT
  2689. display_width_standard dd 0
  2690. display_height_standard dd 0
  2691. do_not_touch_winmap db 0
  2692. window_minimize db 0
  2693. sound_flag      db 0
  2694.  
  2695. endg
  2696.  
  2697. UID_NONE=0
  2698. UID_MENUETOS=1   ;official
  2699. UID_KOLIBRI=2    ;russian
  2700.  
  2701. iglobal
  2702. version_inf:
  2703.         db 0,7,7,0  ; version 0.7.7.0
  2704.         db 0
  2705. .rev    dd __REV__
  2706. version_end:
  2707. endg
  2708. ;------------------------------------------------------------------------------
  2709. align 4
  2710. sys_cachetodiskette:
  2711.         cmp     ebx, 1
  2712.         jb      .no_floppy_save
  2713.         cmp     ebx, 2
  2714.         ja      .no_floppy_save
  2715.         call    save_image
  2716.         mov     [esp + 32], eax
  2717.         ret
  2718. .no_floppy_save:
  2719.         mov     [esp + 32], dword 1
  2720.         ret
  2721. ;------------------------------------------------------------------------------
  2722. uglobal
  2723. ;  bgrchanged  dd  0x0
  2724. align 4
  2725. bgrlockpid dd 0
  2726. bgrlock db 0
  2727. endg
  2728. ;------------------------------------------------------------------------------
  2729. align 4
  2730. sys_background:
  2731.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2732.         jnz     nosb1
  2733.         test    ecx, ecx
  2734.         jz      sbgrr
  2735.  
  2736.         test    edx, edx
  2737.         jz      sbgrr
  2738. ;--------------------------------------
  2739. align 4
  2740. @@:
  2741. ;;Maxis use atomic bts for mutexes  4.4.2009
  2742.         bts     dword [bgrlock], 0
  2743.         jnc     @f
  2744.         call    change_task
  2745.         jmp     @b
  2746. ;--------------------------------------
  2747. align 4
  2748. @@:
  2749.         mov     [BgrDataWidth], ecx
  2750.         mov     [BgrDataHeight], edx
  2751. ;    mov   [bgrchanged],1
  2752.  
  2753.         pushad
  2754. ; return memory for old background
  2755.         mov     eax, [img_background]
  2756.         cmp     eax, static_background_data
  2757.         jz      @f
  2758.         stdcall kernel_free, eax
  2759. ;--------------------------------------
  2760. align 4
  2761. @@:
  2762. ; calculate RAW size
  2763.         xor     eax, eax
  2764.         inc     eax
  2765.         cmp     [BgrDataWidth], eax
  2766.         jae     @f
  2767.         mov     [BgrDataWidth], eax
  2768. ;--------------------------------------
  2769. align 4
  2770. @@:
  2771.         cmp     [BgrDataHeight], eax
  2772.         jae     @f
  2773.         mov     [BgrDataHeight], eax
  2774. ;--------------------------------------
  2775. align 4
  2776. @@:
  2777.         mov     eax, [BgrDataWidth]
  2778.         imul    eax, [BgrDataHeight]
  2779.         lea     eax, [eax*3]
  2780. ; it is reserved with aligned to the boundary of 4 KB pages,
  2781. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2782. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2783.         shr     eax, 12
  2784.         inc     eax
  2785.         shl     eax, 12
  2786.         mov     [mem_BACKGROUND], eax
  2787. ; get memory for new background
  2788.         stdcall kernel_alloc, eax
  2789.         test    eax, eax
  2790.         jz      .memfailed
  2791.         mov     [img_background], eax
  2792.         jmp     .exit
  2793. ;--------------------------------------
  2794. align 4
  2795. .memfailed:
  2796. ; revert to static monotone data
  2797.         mov     [img_background], static_background_data
  2798.         xor     eax, eax
  2799.         inc     eax
  2800.         mov     [BgrDataWidth], eax
  2801.         mov     [BgrDataHeight], eax
  2802.         mov     [mem_BACKGROUND], 4
  2803. ;--------------------------------------
  2804. align 4
  2805. .exit:
  2806.         popad
  2807.         mov     [bgrlock], 0
  2808. ;--------------------------------------
  2809. align 4
  2810. sbgrr:
  2811.         ret
  2812. ;------------------------------------------------------------------------------
  2813. align 4
  2814. nosb1:
  2815.         cmp     ebx, 2                     ; SET PIXEL
  2816.         jnz     nosb2
  2817.  
  2818.         mov     eax, [img_background]
  2819.         test    ecx, ecx
  2820.         jz      @f
  2821.         cmp     eax, static_background_data
  2822.         jz      .ret
  2823. ;--------------------------------------
  2824. align 4
  2825. @@:
  2826.         mov     ebx, [mem_BACKGROUND]
  2827.         add     ebx, 4095
  2828.         and     ebx, -4096
  2829.         sub     ebx, 4
  2830.         cmp     ecx, ebx
  2831.         ja      .ret
  2832.  
  2833.         mov     ebx, [eax+ecx]
  2834.         and     ebx, 0xFF000000;255*256*256*256
  2835.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2836.         add     edx, ebx
  2837.         mov     [eax+ecx], edx
  2838. ;--------------------------------------
  2839. align 4
  2840. .ret:
  2841.         ret
  2842. ;------------------------------------------------------------------------------
  2843. align 4
  2844. nosb2:
  2845.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2846.         jnz     nosb3
  2847. ;--------------------------------------
  2848. align 4
  2849. draw_background_temp:
  2850.         mov     [background_defined], 1
  2851.         call    force_redraw_background
  2852. ;--------------------------------------
  2853. align 4
  2854. nosb31:
  2855.         ret
  2856. ;------------------------------------------------------------------------------
  2857. align 4
  2858. nosb3:
  2859.         cmp     ebx, 4                     ; TILED / STRETCHED
  2860.         jnz     nosb4
  2861.         cmp     ecx, [BgrDrawMode]
  2862.         je      nosb41
  2863.         mov     [BgrDrawMode], ecx
  2864. ;--------------------------------------
  2865. align 4
  2866. nosb41:
  2867.         ret
  2868. ;------------------------------------------------------------------------------
  2869. align 4
  2870. nosb4:
  2871.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2872.         jnz     nosb5
  2873.         cmp     [img_background], static_background_data
  2874.         jnz     @f
  2875.         test    edx, edx
  2876.         jnz     .fin
  2877.         cmp     esi, 4
  2878.         ja      .fin
  2879. ;--------------------------------------
  2880. align 4
  2881. @@:
  2882.   ; bughere
  2883.         mov     eax, ecx
  2884.         mov     ebx, edx
  2885.         add     ebx, [img_background];IMG_BACKGROUND
  2886.         mov     ecx, esi
  2887.         call    memmove
  2888. ;--------------------------------------
  2889. align 4