Subversion Repositories Kolibri OS

Rev

Rev 3927 | Rev 4105 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 3936 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_BIOS32
  287. ; MEMORY MODEL
  288.         call    mem_test
  289.         call    init_mem
  290.         call    init_page_map
  291.  
  292. ; ENABLE PAGING
  293.  
  294.         mov     eax, sys_pgdir-OS_BASE
  295.         mov     cr3, eax
  296.  
  297.         mov     eax, cr0
  298.         or      eax, CR0_PG+CR0_WP
  299.         mov     cr0, eax
  300.  
  301.         lgdt    [gdts]
  302.         jmp     pword os_code:high_code
  303.  
  304. align 4
  305. bios32_entry    dd ?
  306. tmp_page_tabs   dd ?
  307.  
  308. use16
  309. org $-0x10000
  310. include "boot/shutdown.inc" ; shutdown or restart
  311. org $+0x10000
  312. use32
  313.  
  314. __DEBUG__ fix 1
  315. __DEBUG_LEVEL__ fix 1
  316. include 'init.inc'
  317.  
  318. org OS_BASE+$
  319.  
  320. include 'fdo.inc'
  321.  
  322. align 4
  323. high_code:
  324.         mov     ax, os_stack
  325.         mov     bx, app_data
  326.         mov     cx, app_tls
  327.         mov     ss, ax
  328.         add     esp, OS_BASE
  329.  
  330.         mov     ds, bx
  331.         mov     es, bx
  332.         mov     fs, cx
  333.         mov     gs, bx
  334.  
  335.         bt      [cpu_caps], CAPS_PGE
  336.         jnc     @F
  337.  
  338.         or      dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  339.  
  340.         mov     ebx, cr4
  341.         or      ebx, CR4_PGE
  342.         mov     cr4, ebx
  343. @@:
  344.         xor     eax, eax
  345.         mov     dword [sys_pgdir], eax
  346.         mov     dword [sys_pgdir+4], eax
  347.  
  348.         mov     eax, cr3
  349.         mov     cr3, eax          ; flush TLB
  350.  
  351.         mov     ecx, pg_data.mutex
  352.         call    mutex_init
  353.  
  354.         mov     ecx, disk_list_mutex
  355.         call    mutex_init
  356.  
  357.         mov     ecx, keyboard_list_mutex
  358.         call    mutex_init
  359.  
  360.         mov     ecx, unpack_mutex
  361.         call    mutex_init
  362.  
  363.         mov     ecx, application_table_mutex
  364.         call    mutex_init
  365.  
  366.         mov     ecx, ide_mutex
  367.         call    mutex_init
  368.         mov     ecx, ide_channel1_mutex
  369.         call    mutex_init
  370.         mov     ecx, ide_channel2_mutex
  371.         call    mutex_init
  372. ;-----------------------------------------------------------------------------
  373. ; SAVE REAL MODE VARIABLES
  374. ;-----------------------------------------------------------------------------
  375. save_variables_IDE_controller:
  376.         xor     eax, eax
  377.         mov     ax, [BOOT_VARS + BOOT_IDE_INTERR_16]
  378.         mov     [IDE_Interrupt], ax
  379. ;--------------------------------------
  380.         mov     ax, [BOOT_VARS + BOOT_IDE_PI_16]
  381.         mov     [IDEContrProgrammingInterface], ax
  382. ;--------------------------------------
  383.         mov     ax, [BOOT_VARS + BOOT_IDE_BASE_ADDR]
  384.         mov     [IDEContrRegsBaseAddr], ax
  385. ;--------------------------------------
  386.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR0_16]
  387.         cmp     ax, 0
  388.         je      @f
  389.         cmp     ax, 1
  390.         jne     .no_PATA_BAR0
  391. @@:
  392.         mov     ax, 0x1F0
  393.         jmp     @f
  394. .no_PATA_BAR0:
  395.         and     ax, 0xFFFC
  396. @@:
  397.         mov     [StandardATABases], ax
  398.         mov     [hd_address_table], eax
  399.         mov     [hd_address_table+8], eax
  400.         mov     [IDE_BAR0_val], ax
  401. ;--------------------------------------
  402.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR1_16]
  403.         cmp     ax, 0
  404.         je      @f
  405.         cmp     ax, 1
  406.         jne     .no_PATA_BAR1
  407. @@:
  408.         mov     ax, 0x3F4
  409.         jmp     @f
  410. .no_PATA_BAR1:
  411.         and     ax, 0xFFFC
  412. @@:
  413.         mov     [IDE_BAR1_val], ax
  414. ;--------------------------------------
  415.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR2_16]
  416.         cmp     ax, 0
  417.         je      @f
  418.         cmp     ax, 1
  419.         jne     .no_PATA_BAR2
  420. @@:
  421.         mov     ax, 0x170
  422.         jmp     @f
  423. .no_PATA_BAR2:
  424.         and     ax, 0xFFFC
  425. @@:
  426.         mov     [StandardATABases+2], ax
  427.         mov     [hd_address_table+16], eax
  428.         mov     [hd_address_table+24], eax
  429.         mov     [IDE_BAR2_val], ax
  430. ;--------------------------------------
  431.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR3_16]
  432.         cmp     ax, 0
  433.         je      @f
  434.         cmp     ax, 1
  435.         jne     .no_PATA_BAR3
  436. @@:
  437.         mov     ax, 0x374
  438.         jmp     @f
  439. .no_PATA_BAR3:
  440.         and     ax, 0xFFFC
  441. @@:
  442.         mov     [IDE_BAR3_val], ax
  443.  
  444. ; --------------- APM ---------------------
  445.  
  446. ; init selectors
  447.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  448.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  449.                                                                                 ; protected-mode 32-bit code segment
  450.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  451.                                                                                 ; protected-mode 16-bit code segment
  452.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  453.                                                                                 ; protected-mode 16-bit data segment
  454.  
  455.         shl     eax, 4
  456.         mov     [dword apm_code_32 + 2], ax
  457.         shr     eax, 16
  458.         mov     [dword apm_code_32 + 4], al
  459.  
  460.         shl     ecx, 4
  461.         mov     [dword apm_code_16 + 2], cx
  462.         shr     ecx, 16
  463.         mov     [dword apm_code_16 + 4], cl
  464.  
  465.         shl     edx, 4
  466.         mov     [dword apm_data_16 + 2], dx
  467.         shr     edx, 16
  468.         mov     [dword apm_data_16 + 4], dl
  469.  
  470.         mov     dword[apm_entry], ebx
  471.         mov     word [apm_entry + 4], apm_code_32 - gdts
  472.  
  473.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  474.         mov     [apm_vf], eax
  475. ; -----------------------------------------
  476.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  477.         mov     [allow_dma_access], al
  478.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  479.         mov     [_display.bpp], eax
  480.         mov     [_display.vrefresh], 60
  481.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  482.         mov     [debug_direct_print], al
  483.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  484.         mov     [launcher_start], al
  485.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  486.         mov     [_display.width], eax
  487.         mov     [display_width_standard], eax
  488.         dec     eax
  489.         mov     [Screen_Max_X], eax
  490.         mov     [screen_workarea.right], eax
  491.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  492.         mov     [_display.height], eax
  493.         mov     [display_height_standard], eax
  494.         dec     eax
  495.         mov     [Screen_Max_Y], eax
  496.         mov     [screen_workarea.bottom], eax
  497.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  498.         mov     dword [SCR_MODE], eax
  499. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  500. ;        mov     [BANK_SWITCH], eax
  501.         mov     eax, 640 *4                         ; Bytes PerScanLine
  502.         cmp     [SCR_MODE], word 0x13               ; 320x200
  503.         je      @f
  504.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  505.         je      @f
  506.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  507. @@:
  508.         mov     [_display.pitch], eax
  509.         mov     eax, [_display.width]
  510.         mul     [_display.height]
  511.         mov     [_WinMapSize], eax
  512.  
  513.         call    calculate_fast_getting_offset_for_WinMapAddress
  514. ; for Qemu or non standart video cards
  515. ; Unfortunately [BytesPerScanLine] does not always
  516. ;                             equal to [_display.width] * [ScreenBPP] / 8
  517.         call    calculate_fast_getting_offset_for_LFB
  518.  
  519.         mov     esi, BOOT_VARS+0x9080
  520.         movzx   ecx, byte [esi-1]
  521.         mov     [NumBiosDisks], ecx
  522.         mov     edi, BiosDisksData
  523.         rep movsd
  524.  
  525. ; GRAPHICS ADDRESSES
  526.  
  527.         mov     eax, [BOOT_VARS+BOOT_LFB]
  528.         mov     [LFBAddress], eax
  529.  
  530.         cmp     [SCR_MODE], word 0100000000000000b
  531.         jge     setvesa20
  532.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  533.         je      v20ga32
  534.         jmp     v20ga24
  535.  
  536. setvesa20:
  537.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  538.         mov     [GETPIXEL], dword Vesa20_getpixel24
  539.         cmp     byte [_display.bpp], 24
  540.         jz      v20ga24
  541. v20ga32:
  542.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  543.         mov     [GETPIXEL], dword Vesa20_getpixel32
  544.         jmp     no_mode_0x12
  545. v20ga24:
  546.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  547.         jne     no_mode_0x12
  548.         mov     [PUTPIXEL], dword VGA_putpixel
  549.         mov     [GETPIXEL], dword Vesa20_getpixel32
  550. no_mode_0x12:
  551.  
  552.         mov     [MOUSE_PICTURE], dword mousepointer
  553.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  554.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  555.  
  556. ; -------- Fast System Call init ----------
  557. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  558.         bt      [cpu_caps], CAPS_SEP
  559.         jnc     .SEnP  ; SysEnter not Present
  560.         xor     edx, edx
  561.         mov     ecx, MSR_SYSENTER_CS
  562.         mov     eax, os_code
  563.         wrmsr
  564.         mov     ecx, MSR_SYSENTER_ESP
  565. ;           mov eax, sysenter_stack ; Check it
  566.         xor     eax, eax
  567.         wrmsr
  568.         mov     ecx, MSR_SYSENTER_EIP
  569.         mov     eax, sysenter_entry
  570.         wrmsr
  571. .SEnP:
  572. ; AMD SYSCALL/SYSRET
  573.         cmp     byte[cpu_vendor], 'A'
  574.         jne     .noSYSCALL
  575.         mov     eax, 0x80000001
  576.         cpuid
  577.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  578.         jz      .noSYSCALL
  579.         mov     ecx, MSR_AMD_EFER
  580.         rdmsr
  581.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  582.         wrmsr
  583.  
  584.         ; !!!! It`s dirty hack, fix it !!!
  585.         ; Bits of EDX :
  586.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  587.         ;  and the contents of this field, plus 8, are copied into the SS register.
  588.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  589.         ;  and the contents of this field, plus 8, are copied into the SS register.
  590.  
  591.         ; mov   edx, (os_code + 16) * 65536 + os_code
  592.         mov     edx, 0x1B0008
  593.  
  594.         mov     eax, syscall_entry
  595.         mov     ecx, MSR_AMD_STAR
  596.         wrmsr
  597. .noSYSCALL:
  598. ; -----------------------------------------
  599.         stdcall alloc_page
  600.         stdcall map_page, tss-0xF80, eax, PG_SW
  601.         stdcall alloc_page
  602.         stdcall map_page, tss+0x80, eax, PG_SW
  603.         stdcall alloc_page
  604.         stdcall map_page, tss+0x1080, eax, PG_SW
  605.  
  606. ; LOAD IDT
  607.  
  608.         call    build_interrupt_table ;lidt is executed
  609.           ;lidt [idtreg]
  610.  
  611.         call    init_kernel_heap
  612.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  613.         mov     [os_stack_seg], eax
  614.  
  615.         lea     esp, [eax+RING0_STACK_SIZE]
  616.  
  617.         mov     [tss._ss0], os_stack
  618.         mov     [tss._esp0], esp
  619.         mov     [tss._esp], esp
  620.         mov     [tss._cs], os_code
  621.         mov     [tss._ss], os_stack
  622.         mov     [tss._ds], app_data
  623.         mov     [tss._es], app_data
  624.         mov     [tss._fs], app_data
  625.         mov     [tss._gs], app_data
  626.         mov     [tss._io], 128
  627. ;Add IO access table - bit array of permitted ports
  628.         mov     edi, tss._io_map_0
  629.         xor     eax, eax
  630.         not     eax
  631.         mov     ecx, 8192/4
  632.         rep stosd                    ; access to 4096*8=65536 ports
  633.  
  634.         mov     ax, tss0
  635.         ltr     ax
  636.  
  637.         mov     [LFBSize], 0xC00000
  638.         call    init_LFB
  639.         call    init_fpu
  640.         call    init_malloc
  641.  
  642.         stdcall alloc_kernel_space, 0x51000
  643.         mov     [default_io_map], eax
  644.  
  645.         add     eax, 0x2000
  646.         mov     [ipc_tmp], eax
  647.         mov     ebx, 0x1000
  648.  
  649.         add     eax, 0x40000
  650.         mov     [proc_mem_map], eax
  651.  
  652.         add     eax, 0x8000
  653.         mov     [proc_mem_pdir], eax
  654.  
  655.         add     eax, ebx
  656.         mov     [proc_mem_tab], eax
  657.  
  658.         add     eax, ebx
  659.         mov     [tmp_task_pdir], eax
  660.  
  661.         add     eax, ebx
  662.         mov     [tmp_task_ptab], eax
  663.  
  664.         add     eax, ebx
  665.         mov     [ipc_pdir], eax
  666.  
  667.         add     eax, ebx
  668.         mov     [ipc_ptab], eax
  669.  
  670.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  671.                 (unpack.lc+unpack.lp)))*4
  672.  
  673.         mov     [unpack.p], eax
  674.  
  675.         call    init_events
  676.         mov     eax, srv.fd-SRV.fd
  677.         mov     [srv.fd], eax
  678.         mov     [srv.bk], eax
  679.  
  680. ;Set base of graphic segment to linear address of LFB
  681.         mov     eax, [LFBAddress]         ; set for gs
  682.         mov     [graph_data_l+2], ax
  683.         shr     eax, 16
  684.         mov     [graph_data_l+4], al
  685.         mov     [graph_data_l+7], ah
  686.  
  687.         stdcall kernel_alloc, [_WinMapSize]
  688.         mov     [_WinMapAddress], eax
  689.  
  690.         xor     eax, eax
  691.         inc     eax
  692.  
  693. ; set background
  694.  
  695.         mov     [BgrDrawMode], eax
  696.         mov     [BgrDataWidth], eax
  697.         mov     [BgrDataHeight], eax
  698.         mov     [mem_BACKGROUND], 4
  699.         mov     [img_background], static_background_data
  700.  
  701. ; SET UP OS TASK
  702.  
  703.         mov     esi, boot_setostask
  704.         call    boot_log
  705.  
  706.         mov     edx, SLOT_BASE+256
  707.         mov     ebx, [os_stack_seg]
  708.         add     ebx, 0x2000
  709.         call    setup_os_slot
  710.         mov     dword [edx], 'IDLE'
  711.         sub     [edx+APPDATA.saved_esp], 4
  712.         mov     eax, [edx+APPDATA.saved_esp]
  713.         mov     dword [eax], idle_thread
  714.         mov     ecx, IDLE_PRIORITY
  715.         call    scheduler_add_thread
  716.  
  717.         mov     edx, SLOT_BASE+256*2
  718.         mov     ebx, [os_stack_seg]
  719.         call    setup_os_slot
  720.         mov     dword [edx], 'OS'
  721.         xor     ecx, ecx
  722.         call    scheduler_add_thread
  723.  
  724.         mov     dword [CURRENT_TASK], 2
  725.         mov     dword [TASK_COUNT], 2
  726.         mov     dword [current_slot], SLOT_BASE + 256*2
  727.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  728.  
  729.  
  730. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  731.         mov     esi, boot_initirq
  732.         call    boot_log
  733.         call    init_irqs
  734.  
  735.         mov     esi, boot_picinit
  736.         call    boot_log
  737.         call    PIC_init
  738.  
  739.         mov     esi, boot_v86machine
  740.         call    boot_log
  741. ; Initialize system V86 machine
  742.         call    init_sys_v86
  743.  
  744.         mov     esi, boot_inittimer
  745.         call    boot_log
  746. ; Initialize system timer (IRQ0)
  747.         call    PIT_init
  748.  
  749. ; CALCULATE FAT CHAIN FOR RAMDISK
  750.  
  751.         call    calculatefatchain
  752.  
  753.         mov     esi, boot_initapic
  754.         call    boot_log
  755. ; Try to Initialize APIC
  756.         call    APIC_init
  757.  
  758.         mov     esi, boot_enableirq
  759.         call    boot_log
  760. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  761. ; they are used: when partitions are scanned, hd_read relies on timer
  762.         call    unmask_timer
  763.         stdcall enable_irq, 2               ; @#$%! PIC
  764.         stdcall enable_irq, 13              ; co-processor
  765.  
  766.         cmp     [IDEContrProgrammingInterface], 0
  767.         je      @f
  768.  
  769.         mov     esi, boot_disabling_ide
  770.         call    boot_log
  771. ;--------------------------------------
  772. ; Disable IDE interrupts, because the search
  773. ; for IDE partitions is in the PIO mode.
  774. ;--------------------------------------
  775. .disable_IDE_interrupt:
  776. ; Disable interrupts in IDE controller for PIO
  777.         mov     al, 2
  778.         mov     dx, [IDE_BAR1_val] ;0x3F4
  779.         add     dx, 2 ;0x3F6
  780.         out     dx, al
  781.         mov     dx, [IDE_BAR3_val] ;0x374
  782.         add     dx, 2 ;0x376
  783.         out     dx, al
  784. @@:
  785. ;-----------------------------------------------------------------------------
  786. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  787. ;        mov     esi, boot_detectdisks
  788. ;        call    boot_log
  789. ;include 'detect/disks.inc'
  790.         mov     esi, boot_detectfloppy
  791.         call    boot_log
  792. include 'detect/dev_fd.inc'
  793.         mov     esi, boot_detecthdcd
  794.         call    boot_log
  795. include 'detect/dev_hdcd.inc'
  796.         mov     esi, boot_getcache
  797.         call    boot_log
  798. include 'detect/getcache.inc'
  799.         mov     esi, boot_detectpart
  800.         call    boot_log
  801. include 'detect/sear_par.inc'
  802. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  803.  
  804.         mov     esi, boot_init_sys
  805.         call    boot_log
  806.         call    Parser_params
  807.  
  808. if ~ defined extended_primary_loader
  809. ; ramdisk image should be loaded by extended primary loader if it exists
  810. ; READ RAMDISK IMAGE FROM HD
  811.  
  812. ;!!!!!!!!!!!!!!!!!!!!!!!
  813. include 'boot/rdload.inc'
  814. ;!!!!!!!!!!!!!!!!!!!!!!!
  815. end if
  816. ;    mov    [dma_hdd],1
  817.  
  818. if 0
  819.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  820.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  821.         je      no_lib_load
  822.  
  823.         mov     esi, boot_loadlibs
  824.         call    boot_log
  825. ; LOADING LIBRARES
  826.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  827.         call    load_file_parse_table       ; prepare file parse table
  828.         call    set_kernel_conf             ; configure devices and gui
  829. no_lib_load:
  830. end if
  831.  
  832. ; Display APIC status
  833.         mov     esi, boot_APIC_found
  834.         cmp     [irq_mode], IRQ_APIC
  835.         je      @f
  836.         mov     esi, boot_APIC_nfound
  837. @@:
  838.         call    boot_log
  839.  
  840. ; PRINT AMOUNT OF MEMORY
  841.         mov     esi, boot_memdetect
  842.         call    boot_log
  843.  
  844.         movzx   ecx, word [boot_y]
  845.         if lang eq ru
  846.         or      ecx, (10+30*6) shl 16
  847.         else if lang eq sp
  848.         or      ecx, (10+33*6) shl 16
  849.         else
  850.         or      ecx, (10+29*6) shl 16
  851.         end if
  852.         sub     ecx, 10
  853.         mov     edx, 0xFFFFFF
  854.         mov     ebx, [MEM_AMOUNT]
  855.         shr     ebx, 20
  856.         xor     edi, edi
  857.         mov     eax, 0x00040000
  858.         inc     edi
  859.         call    display_number_force
  860.  
  861. ; BUILD SCHEDULER
  862.  
  863. ;        call    build_scheduler; sys32.inc
  864.  
  865. ;        mov     esi, boot_devices
  866. ;        call    boot_log
  867.  
  868.         mov     [pci_access_enabled], 1
  869.         call    pci_enum
  870.  
  871.         stdcall load_driver, szVidintel
  872.  
  873.         call    usb_init
  874.  
  875. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  876.  
  877.         mov     esi, boot_windefs
  878.         call    boot_log
  879.         call    set_window_defaults
  880.  
  881. ; SET BACKGROUND DEFAULTS
  882.  
  883.         mov     esi, boot_bgr
  884.         call    boot_log
  885.         call    init_background
  886.         call    calculatebackground
  887.  
  888. ; RESERVE SYSTEM IRQ'S JA PORT'S
  889.  
  890.         mov     esi, boot_resirqports
  891.         call    boot_log
  892.         call    reserve_irqs_ports
  893.  
  894.         call    init_display
  895.         mov     eax, [def_cursor]
  896.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  897.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  898.  
  899. ; PRINT CPU FREQUENCY
  900.  
  901.         mov     esi, boot_cpufreq
  902.         call    boot_log
  903.  
  904.         cli                         ;FIXME check IF
  905.         rdtsc
  906.         mov     ecx, eax
  907.         mov     esi, 250            ; wait 1/4 a second
  908.         call    delay_ms
  909.         rdtsc
  910.  
  911.         sub     eax, ecx
  912.         xor     edx, edx
  913.         shld    edx, eax, 2
  914.         shl     eax, 2
  915.         mov     dword [cpu_freq], eax
  916.         mov     dword [cpu_freq+4], edx
  917.         mov     ebx, 1000000
  918.         div     ebx
  919.         mov     ebx, eax
  920.  
  921.         movzx   ecx, word [boot_y]
  922.         if lang eq ru
  923.         add     ecx, (10+19*6) shl 16 - 10
  924.         else if lang eq sp
  925.         add     ecx, (10+25*6) shl 16 - 10
  926.         else
  927.         add     ecx, (10+17*6) shl 16 - 10
  928.         end if
  929.  
  930.         mov     edx, 0xFFFFFF
  931.         xor     edi, edi
  932.         mov     eax, 0x00040000
  933.         inc     edi
  934.         call    display_number_force
  935.  
  936. ; SET VARIABLES
  937.  
  938.         call    set_variables
  939.  
  940. ; STACK AND FDC
  941.  
  942.         call    stack_init
  943.         call    fdc_init
  944.  
  945. ; PALETTE FOR 320x200 and 640x480 16 col
  946.  
  947.         cmp     [SCR_MODE], word 0x12
  948.         jne     no_pal_vga
  949.         mov     esi, boot_pal_vga
  950.         call    boot_log
  951.         call    paletteVGA
  952.       no_pal_vga:
  953.  
  954.         cmp     [SCR_MODE], word 0x13
  955.         jne     no_pal_ega
  956.         mov     esi, boot_pal_ega
  957.         call    boot_log
  958.         call    palette320x200
  959.       no_pal_ega:
  960.  
  961. ; LOAD DEFAULT SKIN
  962.  
  963.         call    load_default_skin
  964.  
  965. ;protect io permission map
  966.  
  967.         mov     esi, [default_io_map]
  968.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  969.         add     esi, 0x1000
  970.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  971.  
  972.         stdcall map_page, tss._io_map_0, \
  973.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  974.         stdcall map_page, tss._io_map_1, \
  975.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  976.  
  977. ; LOAD FIRST APPLICATION
  978.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  979.         jnz     first_app_found
  980.  
  981.         cli
  982.         mov     ebp, firstapp
  983.         call    fs_execute_from_sysdir
  984.         test    eax, eax
  985.         jns     first_app_found
  986.  
  987.         mov     esi, boot_failed
  988.         call    boot_log
  989.  
  990.         mov     eax, 0xDEADBEEF      ; otherwise halt
  991.         hlt
  992.  
  993. first_app_found:
  994.  
  995.         cli
  996.  
  997. ; SET KEYBOARD PARAMETERS
  998.         mov     al, 0xf6       ; reset keyboard, scan enabled
  999.         call    kb_write
  1000.         test    ah, ah
  1001.         jnz     .no_keyboard
  1002.  
  1003.         ; wait until 8042 is ready
  1004.         xor     ecx, ecx
  1005.       @@:
  1006.         in      al, 64h
  1007.         and     al, 00000010b
  1008.         loopnz  @b
  1009.  
  1010. iglobal
  1011. align 4
  1012. ps2_keyboard_functions:
  1013.         dd      .end - $
  1014.         dd      0       ; no close
  1015.         dd      ps2_set_lights
  1016. .end:
  1017. endg
  1018.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1019.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1020.        ; call  kb_write
  1021.        ; call  kb_read
  1022.        ; mov   al, 111b
  1023.        ; call  kb_write
  1024.        ; call  kb_read
  1025.  
  1026.         mov     al, 0xF3     ; set repeat rate & delay
  1027.         call    kb_write
  1028. ;        call  kb_read
  1029.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1030.         call    kb_write
  1031. ;        call  kb_read
  1032.      ;// mike.dld [
  1033.         call    set_lights
  1034.      ;// mike.dld ]
  1035.         stdcall attach_int_handler, 1, irq1, 0
  1036.         DEBUGF  1, "K : IRQ1 error code %x\n", eax
  1037. .no_keyboard:
  1038.  
  1039. ; SET MOUSE
  1040.  
  1041.         stdcall load_driver, szPS2MDriver
  1042. ;        stdcall load_driver, szCOM_MDriver
  1043.  
  1044.         mov     esi, boot_setmouse
  1045.         call    boot_log
  1046.         call    setmouse
  1047.  
  1048. ; Setup serial output console (if enabled)
  1049.  
  1050. if defined debug_com_base
  1051.  
  1052.         ; enable Divisor latch
  1053.  
  1054.         mov     dx, debug_com_base+3
  1055.         mov     al, 1 shl 7
  1056.         out     dx, al
  1057.  
  1058.         ; Set speed to 115200 baud (max speed)
  1059.  
  1060.         mov     dx, debug_com_base
  1061.         mov     al, 0x01
  1062.         out     dx, al
  1063.  
  1064.         mov     dx, debug_com_base+1
  1065.         mov     al, 0x00
  1066.         out     dx, al
  1067.  
  1068.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  1069.  
  1070.         mov     dx, debug_com_base+3
  1071.         mov     al, 3
  1072.         out     dx, al
  1073.  
  1074.         ; disable interrupts
  1075.  
  1076.         mov     dx, debug_com_base+1
  1077.         mov     al, 0
  1078.         out     dx, al
  1079.  
  1080.         ; clear +  enable fifo (64 bits)
  1081.  
  1082.         mov     dx, debug_com_base+2
  1083.         mov     al, 0x7 + 1 shl 5
  1084.         out     dx, al
  1085.  
  1086.  
  1087. end if
  1088.         mov     eax, [version_inf.rev]
  1089.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  1090.  
  1091.         mov     eax, [cpu_count]
  1092.         test    eax, eax
  1093.         jnz     @F
  1094.         mov     al, 1                             ; at least one CPU
  1095. @@:
  1096.         DEBUGF  1, "K : %d CPU detected\n", eax
  1097.  
  1098.         DEBUGF  1, "K : BAR0 %x \n", [IDE_BAR0_val]:4
  1099.         DEBUGF  1, "K : BAR1 %x \n", [IDE_BAR1_val]:4
  1100.         DEBUGF  1, "K : BAR2 %x \n", [IDE_BAR2_val]:4
  1101.         DEBUGF  1, "K : BAR3 %x \n", [IDE_BAR3_val]:4
  1102.         DEBUGF  1, "K : BAR4 %x \n", [IDEContrRegsBaseAddr]:4
  1103.         DEBUGF  1, "K : IDEContrProgrammingInterface %x \n", [IDEContrProgrammingInterface]:4
  1104.         DEBUGF  1, "K : IDE_Interrupt %x \n", [IDE_Interrupt]:4
  1105.  
  1106. ; START MULTITASKING
  1107.  
  1108. ; A 'All set - press ESC to start' messages if need
  1109. if preboot_blogesc
  1110.         mov     esi, boot_tasking
  1111.         call    boot_log
  1112. .bll1:
  1113.         in      al, 0x60        ; wait for ESC key press
  1114.         cmp     al, 129
  1115.         jne     .bll1
  1116. end if
  1117.  
  1118.         push    eax edx
  1119.         mov     dx, [IDEContrRegsBaseAddr]
  1120.         xor     eax, eax
  1121.         add     dx, 2
  1122.         in      al, dx
  1123.         DEBUGF  1, "K : Primary Bus Master IDE Status Register %x\n", eax
  1124.  
  1125.         add     dx, 8
  1126.         in      al, dx
  1127.         DEBUGF  1, "K : Secondary Bus Master IDE Status Register %x\n", eax
  1128.         pop     edx eax
  1129.  
  1130.         cmp     [IDEContrRegsBaseAddr], 0
  1131.         setnz   [dma_hdd]
  1132.  
  1133.         cmp     [IDEContrProgrammingInterface], 0
  1134.         je      set_interrupts_for_IDE_controllers.continue
  1135.  
  1136.         mov     ax, [IDE_Interrupt]
  1137.         cmp     al, 0xff
  1138.         jne     @f
  1139.  
  1140.         mov     [dma_hdd], 0
  1141.         jmp     set_interrupts_for_IDE_controllers.end_set_interrupts
  1142. @@:
  1143. ;-----------------------------------------------------------------------------
  1144. ; set interrupts for IDE Controller
  1145. ;-----------------------------------------------------------------------------
  1146.         mov     esi, boot_set_int_IDE
  1147.         call    boot_log
  1148. set_interrupts_for_IDE_controllers:
  1149.         mov     ax, [IDEContrProgrammingInterface]
  1150.         cmp     ax, 0x0180
  1151.         je      .pata_ide
  1152.  
  1153.         cmp     ax, 0x018a
  1154.         jne     .sata_ide
  1155. ;--------------------------------------
  1156. .pata_ide:
  1157.         cmp     [IDEContrRegsBaseAddr], 0
  1158.         je      .end_set_interrupts
  1159.  
  1160.         stdcall attach_int_handler, 14, IDE_irq_14_handler, 0
  1161.         DEBUGF  1, "K : Set IDE IRQ14 return code %x\n", eax
  1162.         stdcall attach_int_handler, 15, IDE_irq_15_handler, 0
  1163.         DEBUGF  1, "K : Set IDE IRQ15 return code %x\n", eax
  1164.         jmp     .enable_IDE_interrupt
  1165. ;--------------------------------------
  1166. .sata_ide:
  1167.         cmp     ax, 0x0185
  1168.         je      .sata_ide_1
  1169.  
  1170.         cmp     ax, 0x018f
  1171.         jne     .end_set_interrupts
  1172. ;--------------------------------------
  1173. .sata_ide_1:
  1174.         cmp     [IDEContrRegsBaseAddr], 0
  1175.         je      .end_set_interrupts
  1176.  
  1177.         mov     ax, [IDE_Interrupt]
  1178.         movzx   eax, al
  1179.         stdcall attach_int_handler, eax, IDE_common_irq_handler, 0
  1180.         DEBUGF  1, "K : Set IDE IRQ%d return code %x\n", [IDE_Interrupt]:1, eax
  1181. ;--------------------------------------
  1182. .enable_IDE_interrupt:
  1183.         mov     esi, boot_enabling_ide
  1184.         call    boot_log
  1185. ; Enable interrupts in IDE controller for DMA
  1186.         mov     al, 0
  1187.         mov     dx, [IDE_BAR1_val] ;0x3F4
  1188.         add     dx, 2 ;0x3F6
  1189.         out     dx, al
  1190.         mov     dx, [IDE_BAR3_val] ;0x374
  1191.         add     dx, 2 ;0x376
  1192.         out     dx, al
  1193. ;--------------------------------------
  1194. .end_set_interrupts:
  1195. ;-----------------------------------------------------------------------------
  1196.         cmp     [dma_hdd], 0
  1197.         je      .print_pio
  1198. .print_dma:
  1199.         DEBUGF  1, "K : IDE DMA mode\n"
  1200.         jmp     .continue
  1201.  
  1202. .print_pio:
  1203.         DEBUGF  1, "K : IDE PIO mode\n"
  1204. .continue:
  1205.  
  1206.         mov     [timer_ticks_enable], 1         ; for cd driver
  1207.  
  1208.         sti
  1209. ;        call    change_task
  1210.  
  1211.         jmp     osloop
  1212.  
  1213.  
  1214.         ; Fly :)
  1215.  
  1216. include 'unpacker.inc'
  1217.  
  1218. align 4
  1219. boot_log:
  1220.         pushad
  1221.  
  1222.         mov     ebx, 10*65536
  1223.         mov     bx, word [boot_y]
  1224.         add     [boot_y], dword 10
  1225.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1226.         xor     edi, edi
  1227.         mov     edx, esi
  1228.         inc     edi
  1229.         call    dtext
  1230.  
  1231.         mov     [novesachecksum], 1000
  1232.         call    checkVga_N13
  1233.  
  1234.         popad
  1235.  
  1236.         ret
  1237.  
  1238. ; in: edx -> APPDATA for OS/IDLE slot
  1239. ; in: ebx = stack base
  1240. proc setup_os_slot
  1241.         xor     eax, eax
  1242.         mov     ecx, 256/4
  1243.         mov     edi, edx
  1244.         rep stosd
  1245.  
  1246.         mov     eax, tss+0x80
  1247.         call    get_pg_addr
  1248.         inc     eax
  1249.         mov     [edx+APPDATA.io_map], eax
  1250.         mov     eax, tss+0x1080
  1251.         call    get_pg_addr
  1252.         inc     eax
  1253.         mov     [edx+APPDATA.io_map+4], eax
  1254.  
  1255.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1256.         lea     edi, [ebx+0x2000-512]
  1257.         mov     dword [edx+APPDATA.fpu_state], edi
  1258.         mov     dword [edx+APPDATA.saved_esp0], edi
  1259.         mov     dword [edx+APPDATA.saved_esp], edi
  1260.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1261.  
  1262.         mov     esi, fpu_data
  1263.         mov     ecx, 512/4
  1264.         cld
  1265.         rep movsd
  1266.  
  1267.         lea     eax, [edx+APP_OBJ_OFFSET]
  1268.         mov     dword [edx+APPDATA.fd_obj], eax
  1269.         mov     dword [edx+APPDATA.bk_obj], eax
  1270.  
  1271.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1272.  
  1273.         mov     [edx + APPDATA.dir_table], sys_pgdir - OS_BASE
  1274.  
  1275.         mov     eax, edx
  1276.         shr     eax, 3
  1277.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1278.         mov     [eax+TASKDATA.wnd_number], dh
  1279.         mov     byte [eax+TASKDATA.pid], dh
  1280.  
  1281.         ret
  1282. endp
  1283.  
  1284. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1285. ;                                                                    ;
  1286. ;                    MAIN OS LOOP START                              ;
  1287. ;                                                                    ;
  1288. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1289. align 32
  1290. osloop:
  1291.         mov     edx, osloop_has_work?
  1292.         xor     ecx, ecx
  1293.         call    Wait_events
  1294.         xor     eax, eax
  1295.         xchg    eax, [osloop_nonperiodic_work]
  1296.         test    eax, eax
  1297.         jz      .no_periodic
  1298. ;        call    [draw_pointer]
  1299.         call    __sys_draw_pointer
  1300.         call    window_check_events
  1301.         call    mouse_check_events
  1302.         call    checkmisc
  1303.         call    checkVga_N13
  1304. .no_periodic:
  1305.         call    stack_handler
  1306.         call    check_fdd_motor_status
  1307.         call    check_ATAPI_device_event
  1308.         call    check_lights_state
  1309.         call    check_timers
  1310.         jmp     osloop
  1311. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1312. ;                                                                    ;
  1313. ;                      MAIN OS LOOP END                              ;
  1314. ;                                                                    ;
  1315. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1316. proc osloop_has_work?
  1317.         cmp     [osloop_nonperiodic_work], 0
  1318.         jnz     .yes
  1319.         call    stack_handler_has_work?
  1320.         jnz     .yes
  1321. ;        call    check_fdd_motor_status_has_work?
  1322. ;        jnz     .yes
  1323.         call    check_ATAPI_device_event_has_work?
  1324.         jnz     .yes
  1325.         call    check_lights_state_has_work?
  1326.         jnz     .yes
  1327.         call    check_timers_has_work?
  1328.         jnz     .yes
  1329. .no:
  1330.         xor     eax, eax
  1331.         ret
  1332. .yes:
  1333.         xor     eax, eax
  1334.         inc     eax
  1335.         ret
  1336. endp
  1337.  
  1338. proc wakeup_osloop
  1339.         mov     [osloop_nonperiodic_work], 1
  1340.         ret
  1341. endp
  1342.  
  1343. uglobal
  1344. align 4
  1345. osloop_nonperiodic_work dd      ?
  1346. endg
  1347.  
  1348. align 4
  1349. idle_thread:
  1350.         sti
  1351. idle_loop:
  1352.         hlt
  1353.         jmp     idle_loop
  1354.  
  1355.  
  1356.  
  1357. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1358. ;                                                                      ;
  1359. ;                   INCLUDED SYSTEM FILES                              ;
  1360. ;                                                                      ;
  1361. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1362.  
  1363.  
  1364. include "kernel32.inc"
  1365.  
  1366.  
  1367. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1368. ;                                                                      ;
  1369. ;                       KERNEL FUNCTIONS                               ;
  1370. ;                                                                      ;
  1371. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1372.  
  1373. reserve_irqs_ports:
  1374.  
  1375.  
  1376. ; RESERVE PORTS
  1377.         mov     eax, RESERVED_PORTS
  1378.         mov     ecx, 1
  1379.  
  1380.         mov     [eax], dword 4
  1381.  
  1382.         mov     [eax+16], ecx
  1383.         mov     [eax+16+4], dword 0
  1384.         mov     [eax+16+8], dword 0x2D
  1385.  
  1386.         mov     [eax+32], ecx
  1387.         mov     [eax+32+4], dword 0x30
  1388.         mov     [eax+32+8], dword 0x4D
  1389.  
  1390.         mov     [eax+48], ecx
  1391.         mov     [eax+48+4], dword 0x50
  1392.         mov     [eax+48+8], dword 0xDF
  1393.  
  1394.         mov     [eax+64], ecx
  1395.         mov     [eax+64+4], dword 0xE5
  1396.         mov     [eax+64+8], dword 0xFF
  1397.  
  1398.         ret
  1399.  
  1400.  
  1401. iglobal
  1402.   process_number dd 0x2
  1403. endg
  1404.  
  1405. set_variables:
  1406.  
  1407.         mov     ecx, 0x16                    ; flush port 0x60
  1408. .fl60:
  1409.         in      al, 0x60
  1410.         loop    .fl60
  1411.         push    eax
  1412.  
  1413.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1414.         shr     ax, 1
  1415.         shl     eax, 16
  1416.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1417.         shr     ax, 1
  1418.         mov     [MOUSE_X], eax
  1419.         call    wakeup_osloop
  1420.  
  1421.         xor     eax, eax
  1422.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1423.  
  1424.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1425.         mov     byte [BTN_COUNT], al              ; button buffer
  1426. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1427.  
  1428.         pop     eax
  1429.         ret
  1430.  
  1431. align 4
  1432. ;input  eax=43,bl-byte of output, ecx - number of port
  1433. sys_outport:
  1434.  
  1435.         mov     edi, ecx   ; separate flag for read / write
  1436.         and     ecx, 65535
  1437.  
  1438.         mov     eax, [RESERVED_PORTS]
  1439.         test    eax, eax
  1440.         jnz     .sopl8
  1441.         inc     eax
  1442.         mov     [esp+32], eax
  1443.         ret
  1444.  
  1445.   .sopl8:
  1446.         mov     edx, [TASK_BASE]
  1447.         mov     edx, [edx+0x4]
  1448.     ;and   ecx,65535
  1449.     ;cld - set on interrupt 0x40
  1450.   .sopl1:
  1451.  
  1452.         mov     esi, eax
  1453.         shl     esi, 4
  1454.         add     esi, RESERVED_PORTS
  1455.         cmp     edx, [esi+0]
  1456.         jne     .sopl2
  1457.         cmp     ecx, [esi+4]
  1458.         jb      .sopl2
  1459.         cmp     ecx, [esi+8]
  1460.         jg      .sopl2
  1461. .sopl3:
  1462.  
  1463.         test    edi, 0x80000000; read ?
  1464.         jnz     .sopl4
  1465.  
  1466.         mov     eax, ebx
  1467.         mov     dx, cx   ; write
  1468.         out     dx, al
  1469.         and     [esp+32], dword 0
  1470.         ret
  1471.  
  1472.         .sopl2:
  1473.  
  1474.         dec     eax
  1475.         jnz     .sopl1
  1476.         inc     eax
  1477.         mov     [esp+32], eax
  1478.         ret
  1479.  
  1480.  
  1481.   .sopl4:
  1482.  
  1483.         mov     dx, cx   ; read
  1484.         in      al, dx
  1485.         and     eax, 0xff
  1486.         and     [esp+32], dword 0
  1487.         mov     [esp+20], eax
  1488.         ret
  1489.  
  1490. display_number:
  1491. ;It is not optimization
  1492.         mov     eax, ebx
  1493.         mov     ebx, ecx
  1494.         mov     ecx, edx
  1495.         mov     edx, esi
  1496.         mov     esi, edi
  1497. ; eax = print type, al=0 -> ebx is number
  1498. ;                   al=1 -> ebx is pointer
  1499. ;                   ah=0 -> display decimal
  1500. ;                   ah=1 -> display hexadecimal
  1501. ;                   ah=2 -> display binary
  1502. ;                   eax bits 16-21 = number of digits to display (0-32)
  1503. ;                   eax bits 22-31 = reserved
  1504. ;
  1505. ; ebx = number or pointer
  1506. ; ecx = x shl 16 + y
  1507. ; edx = color
  1508.         xor     edi, edi
  1509. display_number_force:
  1510.         push    eax
  1511.         and     eax, 0x3fffffff
  1512.         cmp     eax, 0xffff     ; length > 0 ?
  1513.         pop     eax
  1514.         jge     cont_displ
  1515.         ret
  1516.    cont_displ:
  1517.         push    eax
  1518.         and     eax, 0x3fffffff
  1519.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1520.         pop     eax
  1521.         jb      cont_displ2
  1522.         ret
  1523.    cont_displ2:
  1524.  
  1525.         pushad
  1526.  
  1527.         cmp     al, 1            ; ecx is a pointer ?
  1528.         jne     displnl1
  1529.         mov     ebp, ebx
  1530.         add     ebp, 4
  1531.         mov     ebp, [ebp+std_application_base_address]
  1532.         mov     ebx, [ebx+std_application_base_address]
  1533.  displnl1:
  1534.         sub     esp, 64
  1535.  
  1536.         test    ah, ah            ; DECIMAL
  1537.         jnz     no_display_desnum
  1538.         shr     eax, 16
  1539.         and     eax, 0xC03f
  1540. ;     and   eax,0x3f
  1541.         push    eax
  1542.         and     eax, 0x3f
  1543.         mov     edi, esp
  1544.         add     edi, 4+64-1
  1545.         mov     ecx, eax
  1546.         mov     eax, ebx
  1547.         mov     ebx, 10
  1548.  d_desnum:
  1549.         xor     edx, edx
  1550.         call    division_64_bits
  1551.         div     ebx
  1552.         add     dl, 48
  1553.         mov     [edi], dl
  1554.         dec     edi
  1555.         loop    d_desnum
  1556.         pop     eax
  1557.         call    normalize_number
  1558.         call    draw_num_text
  1559.         add     esp, 64
  1560.         popad
  1561.         ret
  1562.    no_display_desnum:
  1563.  
  1564.         cmp     ah, 0x01         ; HEXADECIMAL
  1565.         jne     no_display_hexnum
  1566.         shr     eax, 16
  1567.         and     eax, 0xC03f
  1568. ;     and   eax,0x3f
  1569.         push    eax
  1570.         and     eax, 0x3f
  1571.         mov     edi, esp
  1572.         add     edi, 4+64-1
  1573.         mov     ecx, eax
  1574.         mov     eax, ebx
  1575.         mov     ebx, 16
  1576.    d_hexnum:
  1577.         xor     edx, edx
  1578.         call    division_64_bits
  1579.         div     ebx
  1580.    hexletters = __fdo_hexdigits
  1581.         add     edx, hexletters
  1582.         mov     dl, [edx]
  1583.         mov     [edi], dl
  1584.         dec     edi
  1585.         loop    d_hexnum
  1586.         pop     eax
  1587.         call    normalize_number
  1588.         call    draw_num_text
  1589.         add     esp, 64
  1590.         popad
  1591.         ret
  1592.    no_display_hexnum:
  1593.  
  1594.         cmp     ah, 0x02         ; BINARY
  1595.         jne     no_display_binnum
  1596.         shr     eax, 16
  1597.         and     eax, 0xC03f
  1598. ;     and   eax,0x3f
  1599.         push    eax
  1600.         and     eax, 0x3f
  1601.         mov     edi, esp
  1602.         add     edi, 4+64-1
  1603.         mov     ecx, eax
  1604.         mov     eax, ebx
  1605.         mov     ebx, 2
  1606.    d_binnum:
  1607.         xor     edx, edx
  1608.         call    division_64_bits
  1609.         div     ebx
  1610.         add     dl, 48
  1611.         mov     [edi], dl
  1612.         dec     edi
  1613.         loop    d_binnum
  1614.         pop     eax
  1615.         call    normalize_number
  1616.         call    draw_num_text
  1617.         add     esp, 64
  1618.         popad
  1619.         ret
  1620.    no_display_binnum:
  1621.  
  1622.         add     esp, 64
  1623.         popad
  1624.         ret
  1625.  
  1626. normalize_number:
  1627.         test    ah, 0x80
  1628.         jz      .continue
  1629.         mov     ecx, 48
  1630.         and     eax, 0x3f
  1631. @@:
  1632.         inc     edi
  1633.         cmp     [edi], cl
  1634.         jne     .continue
  1635.         dec     eax
  1636.         cmp     eax, 1
  1637.         ja      @r
  1638.         mov     al, 1
  1639. .continue:
  1640.         and     eax, 0x3f
  1641.         ret
  1642.  
  1643. division_64_bits:
  1644.         test    [esp+1+4], byte 0x40
  1645.         jz      .continue
  1646.         push    eax
  1647.         mov     eax, ebp
  1648.         div     ebx
  1649.         mov     ebp, eax
  1650.         pop     eax
  1651. .continue:
  1652.         ret
  1653.  
  1654. draw_num_text:
  1655.         mov     esi, eax
  1656.         mov     edx, 64+4
  1657.         sub     edx, eax
  1658.         add     edx, esp
  1659.         mov     ebx, [esp+64+32-8+4]
  1660. ; add window start x & y
  1661.         mov     ecx, [TASK_BASE]
  1662.  
  1663.         mov     edi, [CURRENT_TASK]
  1664.         shl     edi, 8
  1665.  
  1666.         mov     eax, [ecx-twdw+WDATA.box.left]
  1667.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1668.         shl     eax, 16
  1669.         add     eax, [ecx-twdw+WDATA.box.top]
  1670.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1671.         add     ebx, eax
  1672.         mov     ecx, [esp+64+32-12+4]
  1673.         and     ecx, not 0x80000000     ; force counted string
  1674.         mov     eax, [esp+64+8]         ; background color (if given)
  1675.         mov     edi, [esp+64+4]
  1676.         jmp     dtext
  1677.  
  1678. align 4
  1679.  
  1680. sys_setup:
  1681.  
  1682. ; 1=roland mpu midi base , base io address
  1683. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1684. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1685. ; 5=system language, 1eng 2fi 3ger 4rus
  1686. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1687. ; 8=fat32 partition in hd
  1688. ; 9
  1689. ; 10 = sound dma channel
  1690. ; 11 = enable lba read
  1691. ; 12 = enable pci access
  1692.  
  1693.  
  1694.         and     [esp+32], dword 0
  1695.         dec     ebx                             ; MIDI
  1696.         jnz     nsyse1
  1697.         cmp     ecx, 0x100
  1698.  
  1699.         jb      nsyse1
  1700.         mov     esi, 65535
  1701.         cmp     esi, ecx
  1702.  
  1703.         jb      nsyse1
  1704.         mov     [midi_base], cx ;bx
  1705.         mov     word [mididp], cx;bx
  1706.         inc     cx              ;bx
  1707.         mov     word [midisp], cx;bx
  1708.         ret
  1709.  
  1710. iglobal
  1711. midi_base dw 0
  1712. endg
  1713.  
  1714.    nsyse1:
  1715.         dec     ebx                              ; KEYBOARD
  1716.         jnz     nsyse2
  1717.         mov     edi, [TASK_BASE]
  1718.         mov     eax, [edi+TASKDATA.mem_start]
  1719.         add     eax, edx
  1720.  
  1721.         dec     ecx
  1722.         jnz     kbnobase
  1723.         mov     ebx, keymap
  1724.         mov     ecx, 128
  1725.         call    memmove
  1726.         ret
  1727.    kbnobase:
  1728.         dec     ecx
  1729.         jnz     kbnoshift
  1730.  
  1731.         mov     ebx, keymap_shift
  1732.         mov     ecx, 128
  1733.         call    memmove
  1734.         ret
  1735.    kbnoshift:
  1736.         dec     ecx
  1737.         jnz     kbnoalt
  1738.         mov     ebx, keymap_alt
  1739.         mov     ecx, 128
  1740.         call    memmove
  1741.         ret
  1742.    kbnoalt:
  1743.         sub     ecx, 6
  1744.         jnz     kbnocountry
  1745.         mov     word [keyboard], dx
  1746.         ret
  1747.    kbnocountry:
  1748.         mov     [esp+32], dword 1
  1749.         ret
  1750.    nsyse2:
  1751.         dec     ebx                         ; CD
  1752.         jnz     nsyse4
  1753.  
  1754.         test    ecx, ecx
  1755.         jz      nosesl
  1756.  
  1757.         cmp     ecx, 4
  1758.         ja      nosesl
  1759.         mov     [cd_base], cl
  1760.  
  1761.         dec     ecx
  1762.         jnz     noprma
  1763.         mov     eax, [hd_address_table]
  1764.         mov     [cdbase], eax   ;0x1f0
  1765.         mov     [cdid], 0xa0
  1766.    noprma:
  1767.  
  1768.         dec     ecx
  1769.         jnz     noprsl
  1770.         mov     eax, [hd_address_table]
  1771.         mov     [cdbase], eax   ;0x1f0
  1772.         mov     [cdid], 0xb0
  1773.    noprsl:
  1774.         dec     ecx
  1775.         jnz     nosema
  1776.         mov     eax, [hd_address_table+16]
  1777.         mov     [cdbase], eax   ;0x170
  1778.         mov     [cdid], 0xa0
  1779.    nosema:
  1780.         dec     ecx
  1781.         jnz     nosesl
  1782.         mov     eax, [hd_address_table+16]
  1783.         mov     [cdbase], eax   ;0x170
  1784.         mov     [cdid], 0xb0
  1785.    nosesl:
  1786.         ret
  1787.  
  1788. iglobal
  1789. cd_base db 0
  1790.  
  1791. endg
  1792.    nsyse4:
  1793.  
  1794.         sub     ebx, 2           ; SYSTEM LANGUAGE
  1795.         jnz     nsyse5
  1796.         mov     [syslang], ecx
  1797.         ret
  1798.    nsyse5:
  1799.  
  1800.         sub     ebx, 2          ; HD BASE - obsolete
  1801.         jnz     nsyse7
  1802.  
  1803.    nosethd:
  1804.         ret
  1805.  
  1806. nsyse7:
  1807.  
  1808. ;     cmp  eax,8                      ; HD PARTITION - obsolete
  1809.         dec     ebx
  1810.         jnz     nsyse8
  1811.         ret
  1812.  
  1813. nsyse8:
  1814. ;     cmp  eax,11                     ; ENABLE LBA READ
  1815.         and     ecx, 1
  1816.         sub     ebx, 3
  1817.         jnz     no_set_lba_read
  1818.         mov     [lba_read_enabled], ecx
  1819.         ret
  1820.  
  1821. no_set_lba_read:
  1822. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1823.         dec     ebx
  1824.         jnz     sys_setup_err
  1825.         mov     [pci_access_enabled], ecx
  1826.         ret
  1827.  
  1828. sys_setup_err:
  1829.         or      [esp+32], dword -1
  1830.         ret
  1831.  
  1832. align 4
  1833.  
  1834. sys_getsetup:
  1835.  
  1836. ; 1=roland mpu midi base , base io address
  1837. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1838. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1839. ; 5=system language, 1eng 2fi 3ger 4rus
  1840. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1841. ; 8=fat32 partition in hd
  1842. ; 9=get hs timer tic
  1843.  
  1844. ;     cmp  eax,1
  1845.         dec     ebx
  1846.         jnz     ngsyse1
  1847.         movzx   eax, [midi_base]
  1848.         mov     [esp+32], eax
  1849.         ret
  1850. ngsyse1:
  1851. ;     cmp  eax,2
  1852.         dec     ebx
  1853.         jnz     ngsyse2
  1854.  
  1855.         mov     edi, [TASK_BASE]
  1856.         mov     ebx, [edi+TASKDATA.mem_start]
  1857.         add     ebx, edx
  1858.  
  1859. ;     cmp  ebx,1
  1860.         dec     ecx
  1861.         jnz     kbnobaseret
  1862.         mov     eax, keymap
  1863.         mov     ecx, 128
  1864.         call    memmove
  1865.         ret
  1866. kbnobaseret:
  1867. ;     cmp  ebx,2
  1868.         dec     ecx
  1869.         jnz     kbnoshiftret
  1870.  
  1871.         mov     eax, keymap_shift
  1872.         mov     ecx, 128
  1873.         call    memmove
  1874.         ret
  1875. kbnoshiftret:
  1876. ;     cmp  ebx,3
  1877.         dec     ecx
  1878.         jne     kbnoaltret
  1879.  
  1880.         mov     eax, keymap_alt
  1881.         mov     ecx, 128
  1882.         call    memmove
  1883.         ret
  1884. kbnoaltret:
  1885. ;     cmp  ebx,9
  1886.         sub     ecx, 6
  1887.         jnz     ngsyse2
  1888.         movzx   eax, word [keyboard]
  1889.         mov     [esp+32], eax
  1890.         ret
  1891.  
  1892.  
  1893. ngsyse2:
  1894. ;         cmp  eax,3
  1895.         dec     ebx
  1896.         jnz     ngsyse3
  1897.         movzx   eax, [cd_base]
  1898.         mov     [esp+32], eax
  1899.         ret
  1900. ngsyse3:
  1901. ;         cmp  eax,5
  1902.         sub     ebx, 2
  1903.         jnz     ngsyse5
  1904.         mov     eax, [syslang]
  1905.         mov     [esp+32], eax
  1906.         ret
  1907. ngsyse5:
  1908. ;     cmp  eax,7
  1909.         sub     ebx, 2
  1910.         jnz     ngsyse7
  1911.         xor     eax, eax
  1912.         mov     [esp+32], eax
  1913.         ret
  1914. ngsyse7:
  1915. ;     cmp  eax,8
  1916.         dec     ebx
  1917.         jnz     ngsyse8
  1918.         mov     eax, [fat32part]
  1919.         mov     [esp+32], eax
  1920.         ret
  1921. ngsyse8:
  1922. ;     cmp  eax,9
  1923.         dec     ebx
  1924.         jnz     ngsyse9
  1925.         mov     eax, [timer_ticks];[0xfdf0]
  1926.         mov     [esp+32], eax
  1927.         ret
  1928. ngsyse9:
  1929. ;     cmp  eax,11
  1930.         sub     ebx, 2
  1931.         jnz     ngsyse11
  1932.         mov     eax, [lba_read_enabled]
  1933.         mov     [esp+32], eax
  1934.         ret
  1935. ngsyse11:
  1936. ;     cmp  eax,12
  1937.         dec     ebx
  1938.         jnz     ngsyse12
  1939.         mov     eax, [pci_access_enabled]
  1940.         mov     [esp+32], eax
  1941.         ret
  1942. ngsyse12:
  1943.         mov     [esp+32], dword 1
  1944.         ret
  1945.  
  1946.  
  1947. get_timer_ticks:
  1948.         mov     eax, [timer_ticks]
  1949.         ret
  1950.  
  1951. iglobal
  1952. align 4
  1953. mousefn dd msscreen, mswin, msbutton, msset
  1954.         dd app_load_cursor
  1955.         dd app_set_cursor
  1956.         dd app_delete_cursor
  1957.         dd msz
  1958. endg
  1959.  
  1960. readmousepos:
  1961.  
  1962. ; eax=0 screen relative
  1963. ; eax=1 window relative
  1964. ; eax=2 buttons pressed
  1965. ; eax=3 set mouse pos   ; reserved
  1966. ; eax=4 load cursor
  1967. ; eax=5 set cursor
  1968. ; eax=6 delete cursor   ; reserved
  1969. ; eax=7 get mouse_z
  1970.  
  1971.         cmp     ebx, 7
  1972.         ja      msset
  1973.         jmp     [mousefn+ebx*4]
  1974. msscreen:
  1975.         mov     eax, [MOUSE_X]
  1976.         shl     eax, 16
  1977.         mov     ax, [MOUSE_Y]
  1978.         mov     [esp+36-4], eax
  1979.         ret
  1980. mswin:
  1981.         mov     eax, [MOUSE_X]
  1982.         shl     eax, 16
  1983.         mov     ax, [MOUSE_Y]
  1984.         mov     esi, [TASK_BASE]
  1985.         mov     bx, word [esi-twdw+WDATA.box.left]
  1986.         shl     ebx, 16
  1987.         mov     bx, word [esi-twdw+WDATA.box.top]
  1988.         sub     eax, ebx
  1989.  
  1990.         mov     edi, [CURRENT_TASK]
  1991.         shl     edi, 8
  1992.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1993.         rol     eax, 16
  1994.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1995.         rol     eax, 16
  1996.         mov     [esp+36-4], eax
  1997.         ret
  1998. msbutton:
  1999.         movzx   eax, byte [BTN_DOWN]
  2000.         mov     [esp+36-4], eax
  2001.         ret
  2002. msz:
  2003.         mov     edi, [TASK_COUNT]
  2004.         movzx   edi, word [WIN_POS + edi*2]
  2005.         cmp     edi, [CURRENT_TASK]
  2006.         jne     @f
  2007.         mov     ax, [MOUSE_SCROLL_H]
  2008.         shl     eax, 16
  2009.         mov     ax, [MOUSE_SCROLL_V]
  2010.         mov     [esp+36-4], eax
  2011.         and     [MOUSE_SCROLL_H], word 0
  2012.         and     [MOUSE_SCROLL_V], word 0
  2013.         ret
  2014.        @@:
  2015.         and     [esp+36-4], dword 0
  2016. ;           ret
  2017. msset:
  2018.         ret
  2019.  
  2020. app_load_cursor:
  2021.         cmp     ecx, OS_BASE
  2022.         jae     msset
  2023.         stdcall load_cursor, ecx, edx
  2024.         mov     [esp+36-4], eax
  2025.         ret
  2026.  
  2027. app_set_cursor:
  2028.         stdcall set_cursor, ecx
  2029.         mov     [esp+36-4], eax
  2030.         ret
  2031.  
  2032. app_delete_cursor:
  2033.         stdcall delete_cursor, ecx
  2034.         mov     [esp+36-4], eax
  2035.         ret
  2036.  
  2037. is_input:
  2038.  
  2039.         push    edx
  2040.         mov     dx, word [midisp]
  2041.         in      al, dx
  2042.         and     al, 0x80
  2043.         pop     edx
  2044.         ret
  2045.  
  2046. is_output:
  2047.  
  2048.         push    edx
  2049.         mov     dx, word [midisp]
  2050.         in      al, dx
  2051.         and     al, 0x40
  2052.         pop     edx
  2053.         ret
  2054.  
  2055.  
  2056. get_mpu_in:
  2057.  
  2058.         push    edx
  2059.         mov     dx, word [mididp]
  2060.         in      al, dx
  2061.         pop     edx
  2062.         ret
  2063.  
  2064.  
  2065. put_mpu_out:
  2066.  
  2067.         push    edx
  2068.         mov     dx, word [mididp]
  2069.         out     dx, al
  2070.         pop     edx
  2071.         ret
  2072.  
  2073.  
  2074.  
  2075. align 4
  2076.  
  2077. sys_midi:
  2078.         cmp     [mididp], 0
  2079.         jnz     sm0
  2080.         mov     [esp+36], dword 1
  2081.         ret
  2082. sm0:
  2083.         and     [esp+36], dword 0
  2084.         dec     ebx
  2085.         jnz     smn1
  2086.  ;    call setuart
  2087. su1:
  2088.         call    is_output
  2089.         test    al, al
  2090.         jnz     su1
  2091.         mov     dx, word [midisp]
  2092.         mov     al, 0xff
  2093.         out     dx, al
  2094. su2:
  2095.         mov     dx, word [midisp]
  2096.         mov     al, 0xff
  2097.         out     dx, al
  2098.         call    is_input
  2099.         test    al, al
  2100.         jnz     su2
  2101.         call    get_mpu_in
  2102.         cmp     al, 0xfe
  2103.         jnz     su2
  2104. su3:
  2105.         call    is_output
  2106.         test    al, al
  2107.         jnz     su3
  2108.         mov     dx, word [midisp]
  2109.         mov     al, 0x3f
  2110.         out     dx, al
  2111.         ret
  2112. smn1:
  2113.         dec     ebx
  2114.         jnz     smn2
  2115. sm10:
  2116.         call    get_mpu_in
  2117.         call    is_output
  2118.         test    al, al
  2119.         jnz     sm10
  2120.         mov     al, bl
  2121.         call    put_mpu_out
  2122.         smn2:
  2123.         ret
  2124.  
  2125. detect_devices:
  2126. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2127. ;include 'detect/commouse.inc'
  2128. ;include 'detect/ps2mouse.inc'
  2129. ;include 'detect/dev_fd.inc'
  2130. ;include 'detect/dev_hdcd.inc'
  2131. ;include 'detect/sear_par.inc'
  2132. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2133.         ret
  2134.  
  2135. sys_end:
  2136. ;--------------------------------------
  2137.         cmp     [_display.select_cursor], 0
  2138.         je      @f
  2139. ; restore default cursor before killing
  2140.         pusha
  2141.         mov     ecx, [current_slot]
  2142.         call    restore_default_cursor_before_killing
  2143.         popa
  2144. @@:
  2145. ;--------------------------------------
  2146. ; kill all sockets this process owns
  2147.         pusha
  2148.         mov     edx, [TASK_BASE]
  2149.         mov     edx, [edx+TASKDATA.pid]
  2150.         call    SOCKET_process_end
  2151.         popa
  2152. ;--------------------------------------
  2153.         mov     ecx, [current_slot]
  2154.         mov     eax, [ecx+APPDATA.tls_base]
  2155.         test    eax, eax
  2156.         jz      @F
  2157.  
  2158.         stdcall user_free, eax
  2159. @@:
  2160.  
  2161.         mov     eax, [TASK_BASE]
  2162.         mov     [eax+TASKDATA.state], 3; terminate this program
  2163.         call    wakeup_osloop
  2164.  
  2165. .waitterm:            ; wait here for termination
  2166.         call    change_task
  2167.         jmp     .waitterm
  2168. ;------------------------------------------------------------------------------
  2169. align 4
  2170. restore_default_cursor_before_killing:
  2171.         pushfd
  2172.         cli
  2173.         mov     eax, [def_cursor]
  2174.         mov     [ecx+APPDATA.cursor], eax
  2175.  
  2176.         movzx   eax, word [MOUSE_Y]
  2177.         movzx   ebx, word [MOUSE_X]
  2178. ;        mov     ecx, [Screen_Max_X]
  2179. ;        inc     ecx
  2180. ;        mul     ecx
  2181.         mov     eax, [d_width_calc_area + eax*4]
  2182.  
  2183.         add     eax, [_WinMapAddress]
  2184.         movzx   edx, byte [ebx+eax]
  2185.         shl     edx, 8
  2186.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2187.  
  2188.         cmp     esi, [current_cursor]
  2189.         je      @f
  2190.  
  2191.         push    esi
  2192.         call    [_display.select_cursor]
  2193.         mov     [current_cursor], esi
  2194. @@:
  2195.         mov     [redrawmouse_unconditional], 1
  2196.         call    wakeup_osloop
  2197.         popfd
  2198.         ret
  2199. ;------------------------------------------------------------------------------
  2200. iglobal
  2201. align 4
  2202. sys_system_table:
  2203.         dd      sysfn_deactivate        ; 1 = deactivate window
  2204.         dd      sysfn_terminate         ; 2 = terminate thread
  2205.         dd      sysfn_activate          ; 3 = activate window
  2206.         dd      sysfn_getidletime       ; 4 = get idle time
  2207.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2208.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2209.         dd      sysfn_getactive         ; 7 = get active window
  2210.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2211.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2212.         dd      sysfn_minimize          ; 10 = minimize window
  2213.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2214.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2215.         dd      sysfn_getversion        ; 13 = get kernel version
  2216.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2217.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2218.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2219.         dd      sysfn_getallmem         ; 17 = get total memory size
  2220.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2221.                                         ;                 instead of slot
  2222.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2223.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2224.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2225.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2226.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2227.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2228. sysfn_num = ($ - sys_system_table)/4
  2229. endg
  2230. ;------------------------------------------------------------------------------
  2231. sys_system:
  2232.         dec     ebx
  2233.         cmp     ebx, sysfn_num
  2234.         jae     @f
  2235.         jmp     dword [sys_system_table + ebx*4]
  2236. @@:
  2237.         ret
  2238. ;------------------------------------------------------------------------------
  2239. sysfn_shutdown:          ; 18.9 = system shutdown
  2240.         cmp     ecx, 1
  2241.         jl      exit_for_anyone
  2242.         cmp     ecx, 4
  2243.         jg      exit_for_anyone
  2244.         mov     [BOOT_VARS+0x9030], cl
  2245.  
  2246.         mov     eax, [TASK_COUNT]
  2247.         mov     [SYS_SHUTDOWN], al
  2248.         mov     [shutdown_processes], eax
  2249.         call    wakeup_osloop
  2250.         and     dword [esp+32], 0
  2251.  exit_for_anyone:
  2252.         ret
  2253.   uglobal
  2254.    shutdown_processes:
  2255.                        dd 0x0
  2256.   endg
  2257. ;------------------------------------------------------------------------------
  2258. sysfn_terminate:        ; 18.2 = TERMINATE
  2259.         push    ecx
  2260.         cmp     ecx, 2
  2261.         jb      noprocessterminate
  2262.         mov     edx, [TASK_COUNT]
  2263.         cmp     ecx, edx
  2264.         ja      noprocessterminate
  2265.         mov     eax, [TASK_COUNT]
  2266.         shl     ecx, 5
  2267.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2268.         add     ecx, CURRENT_TASK+TASKDATA.state
  2269.         cmp     byte [ecx], 9
  2270.         jz      noprocessterminate
  2271.         push    ecx edx
  2272.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2273.         call    request_terminate
  2274.         pop     edx ecx
  2275.         test    eax, eax
  2276.         jz      noprocessterminate
  2277. ;--------------------------------------
  2278. ; terminate all network sockets it used
  2279.         pusha
  2280.         mov     eax, edx
  2281.         call    SOCKET_process_end
  2282.         popa
  2283. ;--------------------------------------
  2284.         cmp     [_display.select_cursor], 0
  2285.         je      .restore_end
  2286. ; restore default cursor before killing
  2287.         pusha
  2288.         mov     ecx, [esp+32]
  2289.         shl     ecx, 8
  2290.         add     ecx, SLOT_BASE
  2291.         mov     eax, [def_cursor]
  2292.         cmp     [ecx+APPDATA.cursor], eax
  2293.         je      @f
  2294.         call    restore_default_cursor_before_killing
  2295. @@:
  2296.         popa
  2297. .restore_end:
  2298. ;--------------------------------------
  2299.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2300.         mov     [ecx], byte 3; clear possible i40's
  2301.         call    wakeup_osloop
  2302.      ;call MEM_Heap_UnLock
  2303.  
  2304.         cmp     edx, [application_table_owner]; clear app table stat
  2305.         jne     noatsc
  2306.         call    unlock_application_table
  2307. noatsc:
  2308. noprocessterminate:
  2309.         add     esp, 4
  2310.         ret
  2311. ;------------------------------------------------------------------------------
  2312. sysfn_terminate2:
  2313. ;lock application_table_status mutex
  2314. .table_status:
  2315.         call    lock_application_table
  2316.         mov     eax, ecx
  2317.         call    pid_to_slot
  2318.         test    eax, eax
  2319.         jz      .not_found
  2320.         mov     ecx, eax
  2321.         cli
  2322.         call    sysfn_terminate
  2323.         call    unlock_application_table
  2324.         sti
  2325.         and     dword [esp+32], 0
  2326.         ret
  2327. .not_found:
  2328.         call    unlock_application_table
  2329.         or      dword [esp+32], -1
  2330.         ret
  2331. ;------------------------------------------------------------------------------
  2332. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2333.         cmp     ecx, 2
  2334.         jb      .nowindowdeactivate
  2335.         cmp     ecx, [TASK_COUNT]
  2336.         ja      .nowindowdeactivate
  2337.  
  2338.         movzx   esi, word [WIN_STACK + ecx*2]
  2339.         cmp     esi, 1
  2340.         je      .nowindowdeactivate ; already deactive
  2341.  
  2342.         mov     edi, ecx
  2343.         shl     edi, 5
  2344.         add     edi, window_data
  2345.         movzx   esi, word [WIN_STACK + ecx * 2]
  2346.         lea     esi, [WIN_POS + esi * 2]
  2347.         call    window._.window_deactivate
  2348.  
  2349.         call    syscall_display_settings._.calculate_whole_screen
  2350.         call    syscall_display_settings._.redraw_whole_screen
  2351. .nowindowdeactivate:
  2352.         ret
  2353. ;------------------------------------------------------------------------------
  2354. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2355.         cmp     ecx, 2
  2356.         jb      .nowindowactivate
  2357.         cmp     ecx, [TASK_COUNT]
  2358.         ja      .nowindowactivate
  2359. ;-------------------------------------
  2360. @@:
  2361. ; If the window is captured and moved by the user,
  2362. ; then you can't change the position in window stack!!!
  2363.         mov     al, [mouse.active_sys_window.action]
  2364.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2365.         test    al, al
  2366.         jz      @f
  2367.         call    change_task
  2368.         jmp     @b
  2369. @@:
  2370. ;-------------------------------------
  2371.         mov     [window_minimize], 2; restore window if minimized
  2372.         call    wakeup_osloop
  2373.  
  2374.         movzx   esi, word [WIN_STACK + ecx*2]
  2375.         cmp     esi, [TASK_COUNT]
  2376.         je      .nowindowactivate; already active
  2377.  
  2378.         mov     edi, ecx
  2379.         shl     edi, 5
  2380.         add     edi, window_data
  2381.         movzx   esi, word [WIN_STACK + ecx * 2]
  2382.         lea     esi, [WIN_POS + esi * 2]
  2383.         call    waredraw
  2384. .nowindowactivate:
  2385.         ret
  2386. ;------------------------------------------------------------------------------
  2387. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2388.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2389.         mov     [esp+32], eax
  2390.         ret
  2391. ;------------------------------------------------------------------------------
  2392. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2393.         mov     eax, dword [cpu_freq]
  2394.         mov     [esp+32], eax
  2395.         ret
  2396. ;------------------------------------------------------------------------------
  2397. get_cpu_freq:
  2398.         mov     eax, dword [cpu_freq]
  2399.         mov     edx, dword [cpu_freq+4]
  2400.         ret
  2401. ;  SAVE ramdisk to /hd/1/menuet.img
  2402. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2403.    include 'blkdev/rdsave.inc'
  2404. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2405. ;------------------------------------------------------------------------------
  2406. align 4
  2407. sysfn_getactive:        ; 18.7 = get active window
  2408.         mov     eax, [TASK_COUNT]
  2409.         movzx   eax, word [WIN_POS + eax*2]
  2410.         mov     [esp+32], eax
  2411.         ret
  2412. ;------------------------------------------------------------------------------
  2413. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2414. ;     cmp  ecx,1
  2415.         dec     ecx
  2416.         jnz     nogetsoundflag
  2417.         movzx   eax, byte [sound_flag]; get sound_flag
  2418.         mov     [esp+32], eax
  2419.         ret
  2420.  nogetsoundflag:
  2421. ;     cmp  ecx,2
  2422.         dec     ecx
  2423.         jnz     nosoundflag
  2424.         xor     byte [sound_flag], 1
  2425.  nosoundflag:
  2426.         ret
  2427. ;------------------------------------------------------------------------------
  2428. sysfn_minimize:         ; 18.10 = minimize window
  2429.         mov     [window_minimize], 1
  2430.         call    wakeup_osloop
  2431.         ret
  2432. ;------------------------------------------------------------------------------
  2433. align 4
  2434. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2435. ;     cmp  ecx,1
  2436.         dec     ecx
  2437.         jnz     full_table
  2438.   small_table:
  2439.         call    for_all_tables
  2440.         mov     ecx, 10
  2441.         cld
  2442.         rep movsb
  2443.         ret
  2444.    for_all_tables:
  2445.         mov     edi, edx
  2446.         mov     esi, DRIVE_DATA
  2447.         ret
  2448.   full_table:
  2449. ;     cmp  ecx,2
  2450.         dec     ecx
  2451.         jnz     exit_for_anyone
  2452.         call    for_all_tables
  2453.         mov     ecx, DRIVE_DATA_SIZE/4
  2454.         cld
  2455.         rep movsd
  2456.         ret
  2457. ;------------------------------------------------------------------------------
  2458. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2459.         and     dword [esp+32], 0
  2460.         ret
  2461. ;------------------------------------------------------------------------------
  2462. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2463.         mov     edi, ecx
  2464.         mov     esi, version_inf
  2465.         mov     ecx, version_end-version_inf
  2466.         rep movsb
  2467.         ret
  2468. ;------------------------------------------------------------------------------
  2469. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2470.      ;wait retrace functions
  2471.  sys_wait_retrace:
  2472.         mov     edx, 0x3da
  2473.  WaitRetrace_loop:
  2474.         in      al, dx
  2475.         test    al, 1000b
  2476.         jz      WaitRetrace_loop
  2477.         and     [esp+32], dword 0
  2478.         ret
  2479. ;------------------------------------------------------------------------------
  2480. align 4
  2481. sysfn_centermouse:      ; 18.15 = mouse centered
  2482. ; removed here by <Lrz>
  2483. ;     call  mouse_centered
  2484. ;* mouse centered - start code- Mario79
  2485. ;mouse_centered:
  2486. ;        push  eax
  2487.         mov     eax, [Screen_Max_X]
  2488.         shr     eax, 1
  2489.         mov     [MOUSE_X], ax
  2490.         mov     eax, [Screen_Max_Y]
  2491.         shr     eax, 1
  2492.         mov     [MOUSE_Y], ax
  2493.         call    wakeup_osloop
  2494. ;        ret
  2495. ;* mouse centered - end code- Mario79
  2496.         xor     eax, eax
  2497.         and     [esp+32], eax
  2498. ;        pop   eax
  2499.         ret
  2500. ;------------------------------------------------------------------------------
  2501. align 4
  2502. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2503.         test    ecx, ecx; get mouse speed factor
  2504.         jnz     .set_mouse_acceleration
  2505.         xor     eax, eax
  2506.         mov     ax, [mouse_speed_factor]
  2507.         mov     [esp+32], eax
  2508.         ret
  2509.  .set_mouse_acceleration:
  2510. ;     cmp  ecx,1  ; set mouse speed factor
  2511.         dec     ecx
  2512.         jnz     .get_mouse_delay
  2513.         mov     [mouse_speed_factor], dx
  2514.         ret
  2515.  .get_mouse_delay:
  2516. ;     cmp  ecx,2  ; get mouse delay
  2517.         dec     ecx
  2518.         jnz     .set_mouse_delay
  2519.         mov     eax, [mouse_delay]
  2520.         mov     [esp+32], eax
  2521.         ret
  2522.  .set_mouse_delay:
  2523. ;     cmp  ecx,3  ; set mouse delay
  2524.         dec     ecx
  2525.         jnz     .set_pointer_position
  2526.         mov     [mouse_delay], edx
  2527.         ret
  2528.  .set_pointer_position:
  2529. ;     cmp  ecx,4  ; set mouse pointer position
  2530.         dec     ecx
  2531.         jnz     .set_mouse_button
  2532.         cmp     dx, word[Screen_Max_Y]
  2533.         ja      .end
  2534.         rol     edx, 16
  2535.         cmp     dx, word[Screen_Max_X]
  2536.         ja      .end
  2537.         mov     [MOUSE_X], edx
  2538.         call    wakeup_osloop
  2539.         ret
  2540.  .set_mouse_button:
  2541. ;     cmp   ecx,5  ; set mouse button features
  2542.         dec     ecx
  2543.         jnz     .end
  2544.         mov     [BTN_DOWN], dl
  2545.         mov     [mouse_active], 1
  2546.         call    wakeup_osloop
  2547.  .end:
  2548.         ret
  2549. ;------------------------------------------------------------------------------
  2550. sysfn_getfreemem:
  2551.         mov     eax, [pg_data.pages_free]
  2552.         shl     eax, 2
  2553.         mov     [esp+32], eax
  2554.         ret
  2555. ;------------------------------------------------------------------------------
  2556. sysfn_getallmem:
  2557.         mov     eax, [MEM_AMOUNT]
  2558.         shr     eax, 10
  2559.         mov     [esp+32], eax
  2560.         ret
  2561. ;------------------------------------------------------------------------------
  2562. sysfn_pid_to_slot:
  2563.         mov     eax, ecx
  2564.         call    pid_to_slot
  2565.         mov     [esp+32], eax
  2566.         ret
  2567. ;------------------------------------------------------------------------------
  2568. sysfn_min_rest_window:
  2569.         pushad
  2570.         mov     eax, edx ; ebx - operating
  2571.         shr     ecx, 1
  2572.         jnc     @f
  2573.         call    pid_to_slot
  2574. @@:
  2575.         or      eax, eax ; eax - number of slot
  2576.         jz      .error
  2577.         cmp     eax, 255    ; varify maximal slot number
  2578.         ja      .error
  2579.         movzx   eax, word [WIN_STACK + eax*2]
  2580.         shr     ecx, 1
  2581.         jc      .restore
  2582.  ; .minimize:
  2583.         call    minimize_window
  2584.         jmp     .exit
  2585. .restore:
  2586.         call    restore_minimized_window
  2587. .exit:
  2588.         popad
  2589.         xor     eax, eax
  2590.         mov     [esp+32], eax
  2591.         ret
  2592. .error:
  2593.         popad
  2594.         xor     eax, eax
  2595.         dec     eax
  2596.         mov     [esp+32], eax
  2597.         ret
  2598. ;------------------------------------------------------------------------------
  2599. sysfn_min_windows:
  2600.         call    minimize_all_window
  2601.         mov     [esp+32], eax
  2602.         call    change_task
  2603.         ret
  2604. ;------------------------------------------------------------------------------
  2605. sysfn_set_screen_sizes:
  2606.         cmp     [SCR_MODE], word 0x13
  2607.         jbe     .exit
  2608.  
  2609.         cmp     [_display.select_cursor], select_cursor
  2610.         jne     .exit
  2611.  
  2612.         cmp     ecx, [display_width_standard]
  2613.         ja      .exit
  2614.  
  2615.         cmp     edx, [display_height_standard]
  2616.         ja      .exit
  2617.  
  2618.         pushfd
  2619.         cli
  2620.         mov     eax, ecx
  2621.         mov     ecx, [_display.pitch]
  2622.         mov     [_display.width], eax
  2623.         dec     eax
  2624.         mov     [_display.height], edx
  2625.         dec     edx
  2626. ; eax - new Screen_Max_X
  2627. ; edx - new Screen_Max_Y
  2628.         mov     [do_not_touch_winmap], 1
  2629.         call    set_screen
  2630.         mov     [do_not_touch_winmap], 0
  2631.         popfd
  2632.         call    change_task
  2633. .exit:
  2634.         ret
  2635. ;------------------------------------------------------------------------------
  2636. uglobal
  2637. screen_workarea RECT
  2638. display_width_standard dd 0
  2639. display_height_standard dd 0
  2640. do_not_touch_winmap db 0
  2641. window_minimize db 0
  2642. sound_flag      db 0
  2643.  
  2644. endg
  2645.  
  2646. UID_NONE=0
  2647. UID_MENUETOS=1   ;official
  2648. UID_KOLIBRI=2    ;russian
  2649.  
  2650. iglobal
  2651. version_inf:
  2652.         db 0,7,7,0  ; version 0.7.7.0
  2653.         db 0
  2654. .rev    dd __REV__
  2655. version_end:
  2656. endg
  2657. ;------------------------------------------------------------------------------
  2658. align 4
  2659. sys_cachetodiskette:
  2660.         cmp     ebx, 1
  2661.         jne     .no_floppy_a_save
  2662.         mov     [flp_number], 1
  2663.         jmp     .save_image_on_floppy
  2664. ;--------------------------------------
  2665. align 4
  2666. .no_floppy_a_save:
  2667.         cmp     ebx, 2
  2668.         jne     .no_floppy_b_save
  2669.         mov     [flp_number], 2
  2670. ;--------------------------------------
  2671. align 4
  2672. .save_image_on_floppy:
  2673.         call    save_image
  2674.         mov     [esp + 32], dword 0
  2675.         cmp     [FDC_Status], 0
  2676.         je      .yes_floppy_save
  2677. ;--------------------------------------
  2678. align 4
  2679. .no_floppy_b_save:
  2680.         mov     [esp + 32], dword 1
  2681. ;--------------------------------------
  2682. align 4
  2683. .yes_floppy_save:
  2684.         ret
  2685. ;------------------------------------------------------------------------------
  2686. uglobal
  2687. ;  bgrchanged  dd  0x0
  2688. align 4
  2689. bgrlockpid dd 0
  2690. bgrlock db 0
  2691. endg
  2692. ;------------------------------------------------------------------------------
  2693. align 4
  2694. sys_background:
  2695.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2696.         jnz     nosb1
  2697.         test    ecx, ecx
  2698.         jz      sbgrr
  2699.  
  2700.         test    edx, edx
  2701.         jz      sbgrr
  2702. ;--------------------------------------
  2703. align 4
  2704. @@:
  2705. ;;Maxis use atomic bts for mutexes  4.4.2009
  2706.         bts     dword [bgrlock], 0
  2707.         jnc     @f
  2708.         call    change_task
  2709.         jmp     @b
  2710. ;--------------------------------------
  2711. align 4
  2712. @@:
  2713.         mov     [BgrDataWidth], ecx
  2714.         mov     [BgrDataHeight], edx
  2715. ;    mov   [bgrchanged],1
  2716.  
  2717.         pushad
  2718. ; return memory for old background
  2719.         mov     eax, [img_background]
  2720.         cmp     eax, static_background_data
  2721.         jz      @f
  2722.         stdcall kernel_free, eax
  2723. ;--------------------------------------
  2724. align 4
  2725. @@:
  2726. ; calculate RAW size
  2727.         xor     eax, eax
  2728.         inc     eax
  2729.         cmp     [BgrDataWidth], eax
  2730.         jae     @f
  2731.         mov     [BgrDataWidth], eax
  2732. ;--------------------------------------
  2733. align 4
  2734. @@:
  2735.         cmp     [BgrDataHeight], eax
  2736.         jae     @f
  2737.         mov     [BgrDataHeight], eax
  2738. ;--------------------------------------
  2739. align 4
  2740. @@:
  2741.         mov     eax, [BgrDataWidth]
  2742.         imul    eax, [BgrDataHeight]
  2743.         lea     eax, [eax*3]
  2744. ; it is reserved with aligned to the boundary of 4 KB pages,
  2745. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2746. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2747.         shr     eax, 12
  2748.         inc     eax
  2749.         shl     eax, 12
  2750.         mov     [mem_BACKGROUND], eax
  2751. ; get memory for new background
  2752.         stdcall kernel_alloc, eax
  2753.         test    eax, eax
  2754.         jz      .memfailed
  2755.         mov     [img_background], eax
  2756.         jmp     .exit
  2757. ;--------------------------------------
  2758. align 4
  2759. .memfailed:
  2760. ; revert to static monotone data
  2761.         mov     [img_background], static_background_data
  2762.         xor     eax, eax
  2763.         inc     eax
  2764.         mov     [BgrDataWidth], eax
  2765.         mov     [BgrDataHeight], eax
  2766.         mov     [mem_BACKGROUND], 4
  2767. ;--------------------------------------
  2768. align 4
  2769. .exit:
  2770.         popad
  2771.         mov     [bgrlock], 0
  2772. ;--------------------------------------
  2773. align 4
  2774. sbgrr:
  2775.         ret
  2776. ;------------------------------------------------------------------------------
  2777. align 4
  2778. nosb1:
  2779.         cmp     ebx, 2                     ; SET PIXEL
  2780.         jnz     nosb2
  2781.  
  2782.         mov     eax, [img_background]
  2783.         test    ecx, ecx
  2784.         jz      @f
  2785.         cmp     eax, static_background_data
  2786.         jz      .ret
  2787. ;--------------------------------------
  2788. align 4
  2789. @@:
  2790.         mov     ebx, [mem_BACKGROUND]
  2791.         add     ebx, 4095
  2792.         and     ebx, -4096
  2793.         sub     ebx, 4
  2794.         cmp     ecx, ebx
  2795.         ja      .ret
  2796.  
  2797.         mov     ebx, [eax+ecx]
  2798.         and     ebx, 0xFF000000;255*256*256*256
  2799.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2800.         add     edx, ebx
  2801.         mov     [eax+ecx], edx
  2802. ;--------------------------------------
  2803. align 4
  2804. .ret:
  2805.         ret
  2806. ;------------------------------------------------------------------------------
  2807. align 4
  2808. nosb2:
  2809.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2810.         jnz     nosb3
  2811. ;--------------------------------------
  2812. align 4
  2813. draw_background_temp:
  2814.         mov     [background_defined], 1
  2815.         call    force_redraw_background
  2816. ;--------------------------------------
  2817. align 4
  2818. nosb31:
  2819.         ret
  2820. ;------------------------------------------------------------------------------
  2821. align 4
  2822. nosb3:
  2823.         cmp     ebx, 4                     ; TILED / STRETCHED
  2824.         jnz     nosb4
  2825.         cmp     ecx, [BgrDrawMode]
  2826.         je      nosb41
  2827.         mov     [BgrDrawMode], ecx
  2828. ;--------------------------------------
  2829. align 4
  2830. nosb41:
  2831.         ret
  2832. ;------------------------------------------------------------------------------
  2833. align 4
  2834. nosb4:
  2835.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2836.         jnz     nosb5
  2837.         cmp     [img_background], static_background_data
  2838.         jnz     @f
  2839.         test    edx, edx
  2840.         jnz     .fin
  2841.         cmp     esi, 4
  2842.         ja      .fin
  2843. ;--------------------------------------
  2844. align 4
  2845. @@:
  2846.   ; bughere
  2847.         mov     eax, ecx
  2848.         mov     ebx, edx
  2849.         add     ebx, [img_background];IMG_BACKGROUND
  2850.         mov     ecx, esi
  2851.         call    memmove
  2852. ;--------------------------------------
  2853. align 4
  2854. .fin:
  2855.         ret
  2856. ;------------------------------------------------------------------------------
  2857. align 4
  2858. nosb5:
  2859.         cmp     ebx, 6
  2860.         jnz     nosb6
  2861. ;--------------------------------------
  2862. align 4
  2863. ;;Maxis use atomic bts for mutex 4.4.2009
  2864. @@:
  2865.         bts     dword [bgrlock], 0
  2866.         jnc     @f
  2867.         call    change_task
  2868.         jmp     @b
  2869. ;--------------------------------------
  2870. align 4
  2871. @@:
  2872.         mov     eax, [CURRENT_TASK]
  2873.         mov     [bgrlockpid], eax
  2874.         cmp     [img_background], static_background_data
  2875.         jz      .nomem
  2876.         stdcall user_alloc, [mem_BACKGROUND]
  2877.         mov     [esp+32], eax
  2878.         test    eax, eax
  2879.         jz      .nomem
  2880.         mov     ebx, eax
  2881.         shr     ebx, 12
  2882.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2883.         mov     esi, [img_background]
  2884.         shr     esi, 12
  2885.         mov     ecx, [mem_BACKGROUND]
  2886.         add     ecx, 0xFFF
  2887.         shr     ecx, 12
  2888. ;--------------------------------------