Subversion Repositories Kolibri OS

Rev

Rev 3870 | Rev 3936 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 3927 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_BIOS32
  287. ; MEMORY MODEL
  288.         call    mem_test
  289.         call    init_mem
  290.         call    init_page_map
  291.  
  292. ; ENABLE PAGING
  293.  
  294.         mov     eax, sys_pgdir-OS_BASE
  295.         mov     cr3, eax
  296.  
  297.         mov     eax, cr0
  298.         or      eax, CR0_PG+CR0_WP
  299.         mov     cr0, eax
  300.  
  301.         lgdt    [gdts]
  302.         jmp     pword os_code:high_code
  303.  
  304. align 4
  305. bios32_entry    dd ?
  306. tmp_page_tabs   dd ?
  307.  
  308. use16
  309. org $-0x10000
  310. include "boot/shutdown.inc" ; shutdown or restart
  311. org $+0x10000
  312. use32
  313.  
  314. __DEBUG__ fix 1
  315. __DEBUG_LEVEL__ fix 1
  316. include 'init.inc'
  317.  
  318. org OS_BASE+$
  319.  
  320. include 'fdo.inc'
  321.  
  322. align 4
  323. high_code:
  324.         mov     ax, os_stack
  325.         mov     bx, app_data
  326.         mov     cx, app_tls
  327.         mov     ss, ax
  328.         add     esp, OS_BASE
  329.  
  330.         mov     ds, bx
  331.         mov     es, bx
  332.         mov     fs, cx
  333.         mov     gs, bx
  334.  
  335.         bt      [cpu_caps], CAPS_PGE
  336.         jnc     @F
  337.  
  338.         or      dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  339.  
  340.         mov     ebx, cr4
  341.         or      ebx, CR4_PGE
  342.         mov     cr4, ebx
  343. @@:
  344.         xor     eax, eax
  345.         mov     dword [sys_pgdir], eax
  346.         mov     dword [sys_pgdir+4], eax
  347.  
  348.         mov     eax, cr3
  349.         mov     cr3, eax          ; flush TLB
  350.  
  351.         mov     ecx, pg_data.mutex
  352.         call    mutex_init
  353.  
  354.         mov     ecx, disk_list_mutex
  355.         call    mutex_init
  356.  
  357.         mov     ecx, keyboard_list_mutex
  358.         call    mutex_init
  359.  
  360.         mov     ecx, unpack_mutex
  361.         call    mutex_init
  362.  
  363.         mov     ecx, application_table_mutex
  364.         call    mutex_init
  365.  
  366.         mov     ecx, ide_mutex
  367.         call    mutex_init
  368.         mov     ecx, ide_channel1_mutex
  369.         call    mutex_init
  370.         mov     ecx, ide_channel2_mutex
  371.         call    mutex_init
  372. ;-----------------------------------------------------------------------------
  373. ; SAVE REAL MODE VARIABLES
  374. ;-----------------------------------------------------------------------------
  375. save_variables_IDE_controller:
  376.         xor     eax, eax
  377.         mov     ax, [BOOT_VARS + BOOT_IDE_INTERR_16]
  378.         mov     [IDE_Interrupt], ax
  379. ;--------------------------------------
  380.         mov     ax, [BOOT_VARS + BOOT_IDE_PI_16]
  381.         mov     [IDEContrProgrammingInterface], ax
  382. ;--------------------------------------
  383.         mov     ax, [BOOT_VARS + BOOT_IDE_BASE_ADDR]
  384.         mov     [IDEContrRegsBaseAddr], ax
  385. ;--------------------------------------
  386.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR0_16]
  387.         cmp     ax, 0
  388.         je      @f
  389.         cmp     ax, 1
  390.         jne     .no_PATA_BAR0
  391. @@:
  392.         mov     ax, 0x1F0
  393.         jmp     @f
  394. .no_PATA_BAR0:
  395.         and     ax, 0xFFFC
  396. @@:
  397.         mov     [StandardATABases], ax
  398.         mov     [hd_address_table], eax
  399.         mov     [hd_address_table+8], eax
  400.         mov     [IDE_BAR0_val], ax
  401. ;--------------------------------------
  402.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR1_16]
  403.         cmp     ax, 0
  404.         je      @f
  405.         cmp     ax, 1
  406.         jne     .no_PATA_BAR1
  407. @@:
  408.         mov     ax, 0x3F4
  409.         jmp     @f
  410. .no_PATA_BAR1:
  411.         and     ax, 0xFFFC
  412. @@:
  413.         mov     [IDE_BAR1_val], ax
  414. ;--------------------------------------
  415.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR2_16]
  416.         cmp     ax, 0
  417.         je      @f
  418.         cmp     ax, 1
  419.         jne     .no_PATA_BAR2
  420. @@:
  421.         mov     ax, 0x170
  422.         jmp     @f
  423. .no_PATA_BAR2:
  424.         and     ax, 0xFFFC
  425. @@:
  426.         mov     [StandardATABases+2], ax
  427.         mov     [hd_address_table+16], eax
  428.         mov     [hd_address_table+24], eax
  429.         mov     [IDE_BAR2_val], ax
  430. ;--------------------------------------
  431.         mov     ax, [BOOT_VARS + BOOT_IDE_BAR3_16]
  432.         cmp     ax, 0
  433.         je      @f
  434.         cmp     ax, 1
  435.         jne     .no_PATA_BAR3
  436. @@:
  437.         mov     ax, 0x374
  438.         jmp     @f
  439. .no_PATA_BAR3:
  440.         and     ax, 0xFFFC
  441. @@:
  442.         mov     [IDE_BAR3_val], ax
  443.  
  444. ; --------------- APM ---------------------
  445.  
  446. ; init selectors
  447.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  448.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  449.                                                                                 ; protected-mode 32-bit code segment
  450.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  451.                                                                                 ; protected-mode 16-bit code segment
  452.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  453.                                                                                 ; protected-mode 16-bit data segment
  454.  
  455.         shl     eax, 4
  456.         mov     [dword apm_code_32 + 2], ax
  457.         shr     eax, 16
  458.         mov     [dword apm_code_32 + 4], al
  459.  
  460.         shl     ecx, 4
  461.         mov     [dword apm_code_16 + 2], cx
  462.         shr     ecx, 16
  463.         mov     [dword apm_code_16 + 4], cl
  464.  
  465.         shl     edx, 4
  466.         mov     [dword apm_data_16 + 2], dx
  467.         shr     edx, 16
  468.         mov     [dword apm_data_16 + 4], dl
  469.  
  470.         mov     dword[apm_entry], ebx
  471.         mov     word [apm_entry + 4], apm_code_32 - gdts
  472.  
  473.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  474.         mov     [apm_vf], eax
  475. ; -----------------------------------------
  476.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  477.         mov     [allow_dma_access], al
  478.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  479.         mov     [_display.bpp], eax
  480.         mov     [_display.vrefresh], 60
  481.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  482.         mov     [debug_direct_print], al
  483.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  484.         mov     [launcher_start], al
  485.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  486.         mov     [_display.width], eax
  487.         mov     [display_width_standard], eax
  488.         dec     eax
  489.         mov     [Screen_Max_X], eax
  490.         mov     [screen_workarea.right], eax
  491.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  492.         mov     [_display.height], eax
  493.         mov     [display_height_standard], eax
  494.         dec     eax
  495.         mov     [Screen_Max_Y], eax
  496.         mov     [screen_workarea.bottom], eax
  497.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  498.         mov     dword [SCR_MODE], eax
  499. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  500. ;        mov     [BANK_SWITCH], eax
  501.         mov     eax, 640 *4                         ; Bytes PerScanLine
  502.         cmp     [SCR_MODE], word 0x13               ; 320x200
  503.         je      @f
  504.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  505.         je      @f
  506.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  507. @@:
  508.         mov     [_display.pitch], eax
  509.         mov     eax, [_display.width]
  510.         mul     [_display.height]
  511.         mov     [_WinMapSize], eax
  512.  
  513.         call    calculate_fast_getting_offset_for_WinMapAddress
  514. ; for Qemu or non standart video cards
  515. ; Unfortunately [BytesPerScanLine] does not always
  516. ;                             equal to [_display.width] * [ScreenBPP] / 8
  517.         call    calculate_fast_getting_offset_for_LFB
  518.  
  519.         mov     esi, BOOT_VARS+0x9080
  520.         movzx   ecx, byte [esi-1]
  521.         mov     [NumBiosDisks], ecx
  522.         mov     edi, BiosDisksData
  523.         rep movsd
  524.  
  525. ; GRAPHICS ADDRESSES
  526.  
  527.         mov     eax, [BOOT_VARS+BOOT_LFB]
  528.         mov     [LFBAddress], eax
  529.  
  530.         cmp     [SCR_MODE], word 0100000000000000b
  531.         jge     setvesa20
  532.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  533.         je      v20ga32
  534.         jmp     v20ga24
  535.  
  536. setvesa20:
  537.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  538.         mov     [GETPIXEL], dword Vesa20_getpixel24
  539.         cmp     byte [_display.bpp], 24
  540.         jz      v20ga24
  541. v20ga32:
  542.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  543.         mov     [GETPIXEL], dword Vesa20_getpixel32
  544.         jmp     no_mode_0x12
  545. v20ga24:
  546.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  547.         jne     no_mode_0x12
  548.         mov     [PUTPIXEL], dword VGA_putpixel
  549.         mov     [GETPIXEL], dword Vesa20_getpixel32
  550. no_mode_0x12:
  551.  
  552.         mov     [MOUSE_PICTURE], dword mousepointer
  553.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  554.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  555.  
  556. ; -------- Fast System Call init ----------
  557. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  558.         bt      [cpu_caps], CAPS_SEP
  559.         jnc     .SEnP  ; SysEnter not Present
  560.         xor     edx, edx
  561.         mov     ecx, MSR_SYSENTER_CS
  562.         mov     eax, os_code
  563.         wrmsr
  564.         mov     ecx, MSR_SYSENTER_ESP
  565. ;           mov eax, sysenter_stack ; Check it
  566.         xor     eax, eax
  567.         wrmsr
  568.         mov     ecx, MSR_SYSENTER_EIP
  569.         mov     eax, sysenter_entry
  570.         wrmsr
  571. .SEnP:
  572. ; AMD SYSCALL/SYSRET
  573.         cmp     byte[cpu_vendor], 'A'
  574.         jne     .noSYSCALL
  575.         mov     eax, 0x80000001
  576.         cpuid
  577.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  578.         jz      .noSYSCALL
  579.         mov     ecx, MSR_AMD_EFER
  580.         rdmsr
  581.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  582.         wrmsr
  583.  
  584.         ; !!!! It`s dirty hack, fix it !!!
  585.         ; Bits of EDX :
  586.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  587.         ;  and the contents of this field, plus 8, are copied into the SS register.
  588.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  589.         ;  and the contents of this field, plus 8, are copied into the SS register.
  590.  
  591.         ; mov   edx, (os_code + 16) * 65536 + os_code
  592.         mov     edx, 0x1B0008
  593.  
  594.         mov     eax, syscall_entry
  595.         mov     ecx, MSR_AMD_STAR
  596.         wrmsr
  597. .noSYSCALL:
  598. ; -----------------------------------------
  599.         stdcall alloc_page
  600.         stdcall map_page, tss-0xF80, eax, PG_SW
  601.         stdcall alloc_page
  602.         stdcall map_page, tss+0x80, eax, PG_SW
  603.         stdcall alloc_page
  604.         stdcall map_page, tss+0x1080, eax, PG_SW
  605.  
  606. ; LOAD IDT
  607.  
  608.         call    build_interrupt_table ;lidt is executed
  609.           ;lidt [idtreg]
  610.  
  611.         call    init_kernel_heap
  612.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  613.         mov     [os_stack_seg], eax
  614.  
  615.         lea     esp, [eax+RING0_STACK_SIZE]
  616.  
  617.         mov     [tss._ss0], os_stack
  618.         mov     [tss._esp0], esp
  619.         mov     [tss._esp], esp
  620.         mov     [tss._cs], os_code
  621.         mov     [tss._ss], os_stack
  622.         mov     [tss._ds], app_data
  623.         mov     [tss._es], app_data
  624.         mov     [tss._fs], app_data
  625.         mov     [tss._gs], app_data
  626.         mov     [tss._io], 128
  627. ;Add IO access table - bit array of permitted ports
  628.         mov     edi, tss._io_map_0
  629.         xor     eax, eax
  630.         not     eax
  631.         mov     ecx, 8192/4
  632.         rep stosd                    ; access to 4096*8=65536 ports
  633.  
  634.         mov     ax, tss0
  635.         ltr     ax
  636.  
  637.         mov     [LFBSize], 0xC00000
  638.         call    init_LFB
  639.         call    init_fpu
  640.         call    init_malloc
  641.  
  642.         stdcall alloc_kernel_space, 0x51000
  643.         mov     [default_io_map], eax
  644.  
  645.         add     eax, 0x2000
  646.         mov     [ipc_tmp], eax
  647.         mov     ebx, 0x1000
  648.  
  649.         add     eax, 0x40000
  650.         mov     [proc_mem_map], eax
  651.  
  652.         add     eax, 0x8000
  653.         mov     [proc_mem_pdir], eax
  654.  
  655.         add     eax, ebx
  656.         mov     [proc_mem_tab], eax
  657.  
  658.         add     eax, ebx
  659.         mov     [tmp_task_pdir], eax
  660.  
  661.         add     eax, ebx
  662.         mov     [tmp_task_ptab], eax
  663.  
  664.         add     eax, ebx
  665.         mov     [ipc_pdir], eax
  666.  
  667.         add     eax, ebx
  668.         mov     [ipc_ptab], eax
  669.  
  670.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  671.                 (unpack.lc+unpack.lp)))*4
  672.  
  673.         mov     [unpack.p], eax
  674.  
  675.         call    init_events
  676.         mov     eax, srv.fd-SRV.fd
  677.         mov     [srv.fd], eax
  678.         mov     [srv.bk], eax
  679.  
  680. ;Set base of graphic segment to linear address of LFB
  681.         mov     eax, [LFBAddress]         ; set for gs
  682.         mov     [graph_data_l+2], ax
  683.         shr     eax, 16
  684.         mov     [graph_data_l+4], al
  685.         mov     [graph_data_l+7], ah
  686.  
  687.         stdcall kernel_alloc, [_WinMapSize]
  688.         mov     [_WinMapAddress], eax
  689.  
  690.         xor     eax, eax
  691.         inc     eax
  692.  
  693. ; set background
  694.  
  695.         mov     [BgrDrawMode], eax
  696.         mov     [BgrDataWidth], eax
  697.         mov     [BgrDataHeight], eax
  698.         mov     [mem_BACKGROUND], 4
  699.         mov     [img_background], static_background_data
  700.  
  701. ; SET UP OS TASK
  702.  
  703.         mov     esi, boot_setostask
  704.         call    boot_log
  705.  
  706.         mov     edx, SLOT_BASE+256
  707.         mov     ebx, [os_stack_seg]
  708.         add     ebx, 0x2000
  709.         call    setup_os_slot
  710.         mov     dword [edx], 'IDLE'
  711.         sub     [edx+APPDATA.saved_esp], 4
  712.         mov     eax, [edx+APPDATA.saved_esp]
  713.         mov     dword [eax], idle_thread
  714.         mov     ecx, IDLE_PRIORITY
  715.         call    scheduler_add_thread
  716.  
  717.         mov     edx, SLOT_BASE+256*2
  718.         mov     ebx, [os_stack_seg]
  719.         call    setup_os_slot
  720.         mov     dword [edx], 'OS'
  721.         xor     ecx, ecx
  722.         call    scheduler_add_thread
  723.  
  724.         mov     dword [CURRENT_TASK], 2
  725.         mov     dword [TASK_COUNT], 2
  726.         mov     dword [current_slot], SLOT_BASE + 256*2
  727.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  728.  
  729.  
  730. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  731.         mov     esi, boot_initirq
  732.         call    boot_log
  733.         call    init_irqs
  734.  
  735.         mov     esi, boot_picinit
  736.         call    boot_log
  737.         call    PIC_init
  738.  
  739.         mov     esi, boot_v86machine
  740.         call    boot_log
  741. ; Initialize system V86 machine
  742.         call    init_sys_v86
  743.  
  744.         mov     esi, boot_inittimer
  745.         call    boot_log
  746. ; Initialize system timer (IRQ0)
  747.         call    PIT_init
  748.  
  749. ; CALCULATE FAT CHAIN FOR RAMDISK
  750.  
  751.         call    calculatefatchain
  752.  
  753.         mov     esi, boot_initapic
  754.         call    boot_log
  755. ; Try to Initialize APIC
  756.         call    APIC_init
  757.  
  758.         mov     esi, boot_enableirq
  759.         call    boot_log
  760. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  761. ; they are used: when partitions are scanned, hd_read relies on timer
  762.         call    unmask_timer
  763.         stdcall enable_irq, 2               ; @#$%! PIC
  764.         stdcall enable_irq, 13              ; co-processor
  765.  
  766.         cmp     [IDEContrProgrammingInterface], 0
  767.         je      @f
  768.  
  769.         mov     esi, boot_disabling_ide
  770.         call    boot_log
  771. ;--------------------------------------
  772. ; Disable IDE interrupts, because the search
  773. ; for IDE partitions is in the PIO mode.
  774. ;--------------------------------------
  775. .disable_IDE_interrupt:
  776. ; Disable interrupts in IDE controller for PIO
  777.         mov     al, 2
  778.         mov     dx, [IDE_BAR1_val] ;0x3F4
  779.         add     dx, 2 ;0x3F6
  780.         out     dx, al
  781.         mov     dx, [IDE_BAR3_val] ;0x374
  782.         add     dx, 2 ;0x376
  783.         out     dx, al
  784. @@:
  785. ;-----------------------------------------------------------------------------
  786. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  787. ;        mov     esi, boot_detectdisks
  788. ;        call    boot_log
  789. ;include 'detect/disks.inc'
  790.         mov     esi, boot_detectfloppy
  791.         call    boot_log
  792. include 'detect/dev_fd.inc'
  793.         mov     esi, boot_detecthdcd
  794.         call    boot_log
  795. include 'detect/dev_hdcd.inc'
  796.         mov     esi, boot_getcache
  797.         call    boot_log
  798. include 'detect/getcache.inc'
  799.         mov     esi, boot_detectpart
  800.         call    boot_log
  801. include 'detect/sear_par.inc'
  802. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  803.  
  804.         mov     esi, boot_init_sys
  805.         call    boot_log
  806.         call    Parser_params
  807.  
  808. if ~ defined extended_primary_loader
  809. ; ramdisk image should be loaded by extended primary loader if it exists
  810. ; READ RAMDISK IMAGE FROM HD
  811.  
  812. ;!!!!!!!!!!!!!!!!!!!!!!!
  813. include 'boot/rdload.inc'
  814. ;!!!!!!!!!!!!!!!!!!!!!!!
  815. end if
  816. ;    mov    [dma_hdd],1
  817.  
  818. if 0
  819.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  820.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  821.         je      no_lib_load
  822.  
  823.         mov     esi, boot_loadlibs
  824.         call    boot_log
  825. ; LOADING LIBRARES
  826.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  827.         call    load_file_parse_table       ; prepare file parse table
  828.         call    set_kernel_conf             ; configure devices and gui
  829. no_lib_load:
  830. end if
  831.  
  832. ; Display APIC status
  833.         mov     esi, boot_APIC_found
  834.         cmp     [irq_mode], IRQ_APIC
  835.         je      @f
  836.         mov     esi, boot_APIC_nfound
  837. @@:
  838.         call    boot_log
  839.  
  840. ; PRINT AMOUNT OF MEMORY
  841.         mov     esi, boot_memdetect
  842.         call    boot_log
  843.  
  844.         movzx   ecx, word [boot_y]
  845.         if lang eq ru
  846.         or      ecx, (10+30*6) shl 16
  847.         else if lang eq sp
  848.         or      ecx, (10+33*6) shl 16
  849.         else
  850.         or      ecx, (10+29*6) shl 16
  851.         end if
  852.         sub     ecx, 10
  853.         mov     edx, 0xFFFFFF
  854.         mov     ebx, [MEM_AMOUNT]
  855.         shr     ebx, 20
  856.         xor     edi, edi
  857.         mov     eax, 0x00040000
  858.         inc     edi
  859.         call    display_number_force
  860.  
  861. ; BUILD SCHEDULER
  862.  
  863. ;        call    build_scheduler; sys32.inc
  864.  
  865. ;        mov     esi, boot_devices
  866. ;        call    boot_log
  867.  
  868.         mov     [pci_access_enabled], 1
  869.         call    pci_enum
  870.  
  871.         stdcall load_driver, szVidintel
  872.  
  873.         call    usb_init
  874.  
  875. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  876.  
  877.         mov     esi, boot_windefs
  878.         call    boot_log
  879.         call    set_window_defaults
  880.  
  881. ; SET BACKGROUND DEFAULTS
  882.  
  883.         mov     esi, boot_bgr
  884.         call    boot_log
  885.         call    init_background
  886.         call    calculatebackground
  887.  
  888. ; RESERVE SYSTEM IRQ'S JA PORT'S
  889.  
  890.         mov     esi, boot_resirqports
  891.         call    boot_log
  892.         call    reserve_irqs_ports
  893.  
  894.         call    init_display
  895.         mov     eax, [def_cursor]
  896.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  897.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  898.  
  899. ; PRINT CPU FREQUENCY
  900.  
  901.         mov     esi, boot_cpufreq
  902.         call    boot_log
  903.  
  904.         cli                         ;FIXME check IF
  905.         rdtsc
  906.         mov     ecx, eax
  907.         mov     esi, 250            ; wait 1/4 a second
  908.         call    delay_ms
  909.         rdtsc
  910.  
  911.         sub     eax, ecx
  912.         xor     edx, edx
  913.         shld    edx, eax, 2
  914.         shl     eax, 2
  915.         mov     dword [cpu_freq], eax
  916.         mov     dword [cpu_freq+4], edx
  917.         mov     ebx, 1000000
  918.         div     ebx
  919.         mov     ebx, eax
  920.  
  921.         movzx   ecx, word [boot_y]
  922.         if lang eq ru
  923.         add     ecx, (10+19*6) shl 16 - 10
  924.         else if lang eq sp
  925.         add     ecx, (10+25*6) shl 16 - 10
  926.         else
  927.         add     ecx, (10+17*6) shl 16 - 10
  928.         end if
  929.  
  930.         mov     edx, 0xFFFFFF
  931.         xor     edi, edi
  932.         mov     eax, 0x00040000
  933.         inc     edi
  934.         call    display_number_force
  935.  
  936. ; SET VARIABLES
  937.  
  938.         call    set_variables
  939.  
  940. ; STACK AND FDC
  941.  
  942.         call    stack_init
  943.         call    fdc_init
  944.  
  945. ; PALETTE FOR 320x200 and 640x480 16 col
  946.  
  947.         cmp     [SCR_MODE], word 0x12
  948.         jne     no_pal_vga
  949.         mov     esi, boot_pal_vga
  950.         call    boot_log
  951.         call    paletteVGA
  952.       no_pal_vga:
  953.  
  954.         cmp     [SCR_MODE], word 0x13
  955.         jne     no_pal_ega
  956.         mov     esi, boot_pal_ega
  957.         call    boot_log
  958.         call    palette320x200
  959.       no_pal_ega:
  960.  
  961. ; LOAD DEFAULT SKIN
  962.  
  963.         call    load_default_skin
  964.  
  965. ;protect io permission map
  966.  
  967.         mov     esi, [default_io_map]
  968.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  969.         add     esi, 0x1000
  970.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  971.  
  972.         stdcall map_page, tss._io_map_0, \
  973.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  974.         stdcall map_page, tss._io_map_1, \
  975.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  976.  
  977. ; LOAD FIRST APPLICATION
  978.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  979.         jnz     first_app_found
  980.  
  981.         cli
  982.         mov     ebp, firstapp
  983.         call    fs_execute_from_sysdir
  984.         test    eax, eax
  985.         jns     first_app_found
  986.  
  987.         mov     esi, boot_failed
  988.         call    boot_log
  989.  
  990.         mov     eax, 0xDEADBEEF      ; otherwise halt
  991.         hlt
  992.  
  993. first_app_found:
  994.  
  995.         cli
  996.  
  997. ; SET KEYBOARD PARAMETERS
  998.         mov     al, 0xf6       ; reset keyboard, scan enabled
  999.         call    kb_write
  1000.         test    ah, ah
  1001.         jnz     .no_keyboard
  1002.  
  1003.         ; wait until 8042 is ready
  1004.         xor     ecx, ecx
  1005.       @@:
  1006.         in      al, 64h
  1007.         and     al, 00000010b
  1008.         loopnz  @b
  1009.  
  1010. iglobal
  1011. align 4
  1012. ps2_keyboard_functions:
  1013.         dd      .end - $
  1014.         dd      0       ; no close
  1015.         dd      ps2_set_lights
  1016. .end:
  1017. endg
  1018.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1019.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1020.        ; call  kb_write
  1021.        ; call  kb_read
  1022.        ; mov   al, 111b
  1023.        ; call  kb_write
  1024.        ; call  kb_read
  1025.  
  1026.         mov     al, 0xF3     ; set repeat rate & delay
  1027.         call    kb_write
  1028. ;        call  kb_read
  1029.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1030.         call    kb_write
  1031. ;        call  kb_read
  1032.      ;// mike.dld [
  1033.         call    set_lights
  1034.      ;// mike.dld ]
  1035.         stdcall attach_int_handler, 1, irq1, 0
  1036.         DEBUGF  1, "K : IRQ1 error code %x\n", eax
  1037. .no_keyboard:
  1038.  
  1039. ; SET MOUSE
  1040.  
  1041.         stdcall load_driver, szPS2MDriver
  1042. ;        stdcall load_driver, szCOM_MDriver
  1043.  
  1044.         mov     esi, boot_setmouse
  1045.         call    boot_log
  1046.         call    setmouse
  1047.  
  1048. ; Setup serial output console (if enabled)
  1049.  
  1050. if defined debug_com_base
  1051.  
  1052.         ; enable Divisor latch
  1053.  
  1054.         mov     dx, debug_com_base+3
  1055.         mov     al, 1 shl 7
  1056.         out     dx, al
  1057.  
  1058.         ; Set speed to 115200 baud (max speed)
  1059.  
  1060.         mov     dx, debug_com_base
  1061.         mov     al, 0x01
  1062.         out     dx, al
  1063.  
  1064.         mov     dx, debug_com_base+1
  1065.         mov     al, 0x00
  1066.         out     dx, al
  1067.  
  1068.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  1069.  
  1070.         mov     dx, debug_com_base+3
  1071.         mov     al, 3
  1072.         out     dx, al
  1073.  
  1074.         ; disable interrupts
  1075.  
  1076.         mov     dx, debug_com_base+1
  1077.         mov     al, 0
  1078.         out     dx, al
  1079.  
  1080.         ; clear +  enable fifo (64 bits)
  1081.  
  1082.         mov     dx, debug_com_base+2
  1083.         mov     al, 0x7 + 1 shl 5
  1084.         out     dx, al
  1085.  
  1086.  
  1087. end if
  1088.         mov     eax, [version_inf.rev]
  1089.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  1090.  
  1091.         mov     eax, [cpu_count]
  1092.         test    eax, eax
  1093.         jnz     @F
  1094.         mov     al, 1                             ; at least one CPU
  1095. @@:
  1096.         DEBUGF  1, "K : %d CPU detected\n", eax
  1097.  
  1098.         DEBUGF  1, "K : BAR0 %x \n", [IDE_BAR0_val]:4
  1099.         DEBUGF  1, "K : BAR1 %x \n", [IDE_BAR1_val]:4
  1100.         DEBUGF  1, "K : BAR2 %x \n", [IDE_BAR2_val]:4
  1101.         DEBUGF  1, "K : BAR3 %x \n", [IDE_BAR3_val]:4
  1102.         DEBUGF  1, "K : BAR4 %x \n", [IDEContrRegsBaseAddr]:4
  1103.         DEBUGF  1, "K : IDEContrProgrammingInterface %x \n", [IDEContrProgrammingInterface]:4
  1104.         DEBUGF  1, "K : IDE_Interrupt %x \n", [IDE_Interrupt]:4
  1105. ; START MULTITASKING
  1106.  
  1107. ; A 'All set - press ESC to start' messages if need
  1108. if preboot_blogesc
  1109.         mov     esi, boot_tasking
  1110.         call    boot_log
  1111. .bll1:
  1112.         in      al, 0x60        ; wait for ESC key press
  1113.         cmp     al, 129
  1114.         jne     .bll1
  1115. end if
  1116.  
  1117.         push    eax edx
  1118.         mov     dx, [IDEContrRegsBaseAddr]
  1119.         xor     eax, eax
  1120.         add     dx, 2
  1121.         in      al, dx
  1122.         DEBUGF  1, "K : Primary Bus Master IDE Status Register %x\n", eax
  1123.  
  1124.         add     dx, 8
  1125.         in      al, dx
  1126.         DEBUGF  1, "K : Secondary Bus Master IDE Status Register %x\n", eax
  1127.         pop     edx eax
  1128.  
  1129.         cmp     [IDEContrRegsBaseAddr], 0
  1130.         setnz   [dma_hdd]
  1131.  
  1132.         cmp     [IDEContrProgrammingInterface], 0
  1133.         je      set_interrupts_for_IDE_controllers.continue
  1134.  
  1135.         mov     ax, [IDE_Interrupt]
  1136.         cmp     al, 0xff
  1137.         jne     @f
  1138.  
  1139.         mov     [dma_hdd], 0
  1140.         jmp     set_interrupts_for_IDE_controllers.end_set_interrupts
  1141. @@:
  1142. ;-----------------------------------------------------------------------------
  1143. ; set interrupts for IDE Controller
  1144. ;-----------------------------------------------------------------------------
  1145.         mov     esi, boot_set_int_IDE
  1146.         call    boot_log
  1147. set_interrupts_for_IDE_controllers:
  1148.         mov     ax, [IDEContrProgrammingInterface]
  1149.         cmp     ax, 0x0180
  1150.         je      .pata_ide
  1151.  
  1152.         cmp     ax, 0x018a
  1153.         jne     .sata_ide
  1154. ;--------------------------------------
  1155. .pata_ide:
  1156.         cmp     [IDEContrRegsBaseAddr], 0
  1157.         je      .end_set_interrupts
  1158.  
  1159.         stdcall attach_int_handler, 14, IDE_irq_14_handler, 0
  1160.         DEBUGF  1, "K : Set IDE IRQ14 return code %x\n", eax
  1161.         stdcall attach_int_handler, 15, IDE_irq_15_handler, 0
  1162.         DEBUGF  1, "K : Set IDE IRQ15 return code %x\n", eax
  1163.         jmp     .enable_IDE_interrupt
  1164. ;--------------------------------------
  1165. .sata_ide:
  1166.         cmp     ax, 0x0185
  1167.         je      .sata_ide_1
  1168.  
  1169.         cmp     ax, 0x018f
  1170.         jne     .end_set_interrupts
  1171. ;--------------------------------------
  1172. .sata_ide_1:
  1173.         cmp     [IDEContrRegsBaseAddr], 0
  1174.         je      .end_set_interrupts
  1175.  
  1176.         mov     ax, [IDE_Interrupt]
  1177.         movzx   eax, al
  1178.         stdcall attach_int_handler, eax, IDE_common_irq_handler, 0
  1179.         DEBUGF  1, "K : Set IDE IRQ%d return code %x\n", [IDE_Interrupt]:1, eax
  1180. ;--------------------------------------
  1181. .enable_IDE_interrupt:
  1182.         mov     esi, boot_enabling_ide
  1183.         call    boot_log
  1184. ; Enable interrupts in IDE controller for DMA
  1185.         mov     al, 0
  1186.         mov     dx, [IDE_BAR1_val] ;0x3F4
  1187.         add     dx, 2 ;0x3F6
  1188.         out     dx, al
  1189.         mov     dx, [IDE_BAR3_val] ;0x374
  1190.         add     dx, 2 ;0x376
  1191.         out     dx, al
  1192. ;--------------------------------------
  1193. .end_set_interrupts:
  1194. ;-----------------------------------------------------------------------------
  1195.         cmp     [dma_hdd], 0
  1196.         je      .print_pio
  1197. .print_dma:
  1198.         DEBUGF  1, "K : IDE DMA mode\n"
  1199.         jmp     .continue
  1200.  
  1201. .print_pio:
  1202.         DEBUGF  1, "K : IDE PIO mode\n"
  1203. .continue:
  1204.  
  1205.         mov     [timer_ticks_enable], 1         ; for cd driver
  1206.  
  1207.         sti
  1208. ;        call    change_task
  1209.  
  1210.         jmp     osloop
  1211.  
  1212.  
  1213.         ; Fly :)
  1214.  
  1215. include 'unpacker.inc'
  1216.  
  1217. align 4
  1218. boot_log:
  1219.         pushad
  1220.  
  1221.         mov     ebx, 10*65536
  1222.         mov     bx, word [boot_y]
  1223.         add     [boot_y], dword 10
  1224.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1225.         xor     edi, edi
  1226.         mov     edx, esi
  1227.         inc     edi
  1228.         call    dtext
  1229.  
  1230.         mov     [novesachecksum], 1000
  1231.         call    checkVga_N13
  1232.  
  1233.         popad
  1234.  
  1235.         ret
  1236.  
  1237. ; in: edx -> APPDATA for OS/IDLE slot
  1238. ; in: ebx = stack base
  1239. proc setup_os_slot
  1240.         xor     eax, eax
  1241.         mov     ecx, 256/4
  1242.         mov     edi, edx
  1243.         rep stosd
  1244.  
  1245.         mov     eax, tss+0x80
  1246.         call    get_pg_addr
  1247.         inc     eax
  1248.         mov     [edx+APPDATA.io_map], eax
  1249.         mov     eax, tss+0x1080
  1250.         call    get_pg_addr
  1251.         inc     eax
  1252.         mov     [edx+APPDATA.io_map+4], eax
  1253.  
  1254.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1255.         lea     edi, [ebx+0x2000-512]
  1256.         mov     dword [edx+APPDATA.fpu_state], edi
  1257.         mov     dword [edx+APPDATA.saved_esp0], edi
  1258.         mov     dword [edx+APPDATA.saved_esp], edi
  1259.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1260.  
  1261.         mov     esi, fpu_data
  1262.         mov     ecx, 512/4
  1263.         cld
  1264.         rep movsd
  1265.  
  1266.         lea     eax, [edx+APP_OBJ_OFFSET]
  1267.         mov     dword [edx+APPDATA.fd_obj], eax
  1268.         mov     dword [edx+APPDATA.bk_obj], eax
  1269.  
  1270.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1271.  
  1272.         mov     [edx + APPDATA.dir_table], sys_pgdir - OS_BASE
  1273.  
  1274.         mov     eax, edx
  1275.         shr     eax, 3
  1276.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1277.         mov     [eax+TASKDATA.wnd_number], dh
  1278.         mov     byte [eax+TASKDATA.pid], dh
  1279.  
  1280.         ret
  1281. endp
  1282.  
  1283. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1284. ;                                                                    ;
  1285. ;                    MAIN OS LOOP START                              ;
  1286. ;                                                                    ;
  1287. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1288. align 32
  1289. osloop:
  1290.         mov     edx, osloop_has_work?
  1291.         xor     ecx, ecx
  1292.         call    Wait_events
  1293.         xor     eax, eax
  1294.         xchg    eax, [osloop_nonperiodic_work]
  1295.         test    eax, eax
  1296.         jz      .no_periodic
  1297. ;        call    [draw_pointer]
  1298.         call    __sys_draw_pointer
  1299.         call    window_check_events
  1300.         call    mouse_check_events
  1301.         call    checkmisc
  1302.         call    checkVga_N13
  1303. .no_periodic:
  1304.         call    stack_handler
  1305.         call    check_fdd_motor_status
  1306.         call    check_ATAPI_device_event
  1307.         call    check_lights_state
  1308.         call    check_timers
  1309.         jmp     osloop
  1310. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1311. ;                                                                    ;
  1312. ;                      MAIN OS LOOP END                              ;
  1313. ;                                                                    ;
  1314. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1315. proc osloop_has_work?
  1316.         cmp     [osloop_nonperiodic_work], 0
  1317.         jnz     .yes
  1318.         call    stack_handler_has_work?
  1319.         jnz     .yes
  1320. ;        call    check_fdd_motor_status_has_work?
  1321. ;        jnz     .yes
  1322.         call    check_ATAPI_device_event_has_work?
  1323.         jnz     .yes
  1324.         call    check_lights_state_has_work?
  1325.         jnz     .yes
  1326.         call    check_timers_has_work?
  1327.         jnz     .yes
  1328. .no:
  1329.         xor     eax, eax
  1330.         ret
  1331. .yes:
  1332.         xor     eax, eax
  1333.         inc     eax
  1334.         ret
  1335. endp
  1336.  
  1337. proc wakeup_osloop
  1338.         mov     [osloop_nonperiodic_work], 1
  1339.         ret
  1340. endp
  1341.  
  1342. uglobal
  1343. align 4
  1344. osloop_nonperiodic_work dd      ?
  1345. endg
  1346.  
  1347. align 4
  1348. idle_thread:
  1349.         sti
  1350. idle_loop:
  1351.         hlt
  1352.         jmp     idle_loop
  1353.  
  1354.  
  1355.  
  1356. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1357. ;                                                                      ;
  1358. ;                   INCLUDED SYSTEM FILES                              ;
  1359. ;                                                                      ;
  1360. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1361.  
  1362.  
  1363. include "kernel32.inc"
  1364.  
  1365.  
  1366. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1367. ;                                                                      ;
  1368. ;                       KERNEL FUNCTIONS                               ;
  1369. ;                                                                      ;
  1370. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1371.  
  1372. reserve_irqs_ports:
  1373.  
  1374.  
  1375. ; RESERVE PORTS
  1376.         mov     eax, RESERVED_PORTS
  1377.         mov     ecx, 1
  1378.  
  1379.         mov     [eax], dword 4
  1380.  
  1381.         mov     [eax+16], ecx
  1382.         mov     [eax+16+4], dword 0
  1383.         mov     [eax+16+8], dword 0x2D
  1384.  
  1385.         mov     [eax+32], ecx
  1386.         mov     [eax+32+4], dword 0x30
  1387.         mov     [eax+32+8], dword 0x4D
  1388.  
  1389.         mov     [eax+48], ecx
  1390.         mov     [eax+48+4], dword 0x50
  1391.         mov     [eax+48+8], dword 0xDF
  1392.  
  1393.         mov     [eax+64], ecx
  1394.         mov     [eax+64+4], dword 0xE5
  1395.         mov     [eax+64+8], dword 0xFF
  1396.  
  1397.         ret
  1398.  
  1399.  
  1400. iglobal
  1401.   process_number dd 0x2
  1402. endg
  1403.  
  1404. set_variables:
  1405.  
  1406.         mov     ecx, 0x16                    ; flush port 0x60
  1407. .fl60:
  1408.         in      al, 0x60
  1409.         loop    .fl60
  1410.         push    eax
  1411.  
  1412.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1413.         shr     ax, 1
  1414.         shl     eax, 16
  1415.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1416.         shr     ax, 1
  1417.         mov     [MOUSE_X], eax
  1418.         call    wakeup_osloop
  1419.  
  1420.         xor     eax, eax
  1421.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1422.  
  1423.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1424.         mov     byte [BTN_COUNT], al              ; button buffer
  1425. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1426.  
  1427.         pop     eax
  1428.         ret
  1429.  
  1430. align 4
  1431. ;input  eax=43,bl-byte of output, ecx - number of port
  1432. sys_outport:
  1433.  
  1434.         mov     edi, ecx   ; separate flag for read / write
  1435.         and     ecx, 65535
  1436.  
  1437.         mov     eax, [RESERVED_PORTS]
  1438.         test    eax, eax
  1439.         jnz     .sopl8
  1440.         inc     eax
  1441.         mov     [esp+32], eax
  1442.         ret
  1443.  
  1444.   .sopl8:
  1445.         mov     edx, [TASK_BASE]
  1446.         mov     edx, [edx+0x4]
  1447.     ;and   ecx,65535
  1448.     ;cld - set on interrupt 0x40
  1449.   .sopl1:
  1450.  
  1451.         mov     esi, eax
  1452.         shl     esi, 4
  1453.         add     esi, RESERVED_PORTS
  1454.         cmp     edx, [esi+0]
  1455.         jne     .sopl2
  1456.         cmp     ecx, [esi+4]
  1457.         jb      .sopl2
  1458.         cmp     ecx, [esi+8]
  1459.         jg      .sopl2
  1460. .sopl3:
  1461.  
  1462.         test    edi, 0x80000000; read ?
  1463.         jnz     .sopl4
  1464.  
  1465.         mov     eax, ebx
  1466.         mov     dx, cx   ; write
  1467.         out     dx, al
  1468.         and     [esp+32], dword 0
  1469.         ret
  1470.  
  1471.         .sopl2:
  1472.  
  1473.         dec     eax
  1474.         jnz     .sopl1
  1475.         inc     eax
  1476.         mov     [esp+32], eax
  1477.         ret
  1478.  
  1479.  
  1480.   .sopl4:
  1481.  
  1482.         mov     dx, cx   ; read
  1483.         in      al, dx
  1484.         and     eax, 0xff
  1485.         and     [esp+32], dword 0
  1486.         mov     [esp+20], eax
  1487.         ret
  1488.  
  1489. display_number:
  1490. ;It is not optimization
  1491.         mov     eax, ebx
  1492.         mov     ebx, ecx
  1493.         mov     ecx, edx
  1494.         mov     edx, esi
  1495.         mov     esi, edi
  1496. ; eax = print type, al=0 -> ebx is number
  1497. ;                   al=1 -> ebx is pointer
  1498. ;                   ah=0 -> display decimal
  1499. ;                   ah=1 -> display hexadecimal
  1500. ;                   ah=2 -> display binary
  1501. ;                   eax bits 16-21 = number of digits to display (0-32)
  1502. ;                   eax bits 22-31 = reserved
  1503. ;
  1504. ; ebx = number or pointer
  1505. ; ecx = x shl 16 + y
  1506. ; edx = color
  1507.         xor     edi, edi
  1508. display_number_force:
  1509.         push    eax
  1510.         and     eax, 0x3fffffff
  1511.         cmp     eax, 0xffff     ; length > 0 ?
  1512.         pop     eax
  1513.         jge     cont_displ
  1514.         ret
  1515.    cont_displ:
  1516.         push    eax
  1517.         and     eax, 0x3fffffff
  1518.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1519.         pop     eax
  1520.         jb      cont_displ2
  1521.         ret
  1522.    cont_displ2:
  1523.  
  1524.         pushad
  1525.  
  1526.         cmp     al, 1            ; ecx is a pointer ?
  1527.         jne     displnl1
  1528.         mov     ebp, ebx
  1529.         add     ebp, 4
  1530.         mov     ebp, [ebp+std_application_base_address]
  1531.         mov     ebx, [ebx+std_application_base_address]
  1532.  displnl1:
  1533.         sub     esp, 64
  1534.  
  1535.         test    ah, ah            ; DECIMAL
  1536.         jnz     no_display_desnum
  1537.         shr     eax, 16
  1538.         and     eax, 0xC03f
  1539. ;     and   eax,0x3f
  1540.         push    eax
  1541.         and     eax, 0x3f
  1542.         mov     edi, esp
  1543.         add     edi, 4+64-1
  1544.         mov     ecx, eax
  1545.         mov     eax, ebx
  1546.         mov     ebx, 10
  1547.  d_desnum:
  1548.         xor     edx, edx
  1549.         call    division_64_bits
  1550.         div     ebx
  1551.         add     dl, 48
  1552.         mov     [edi], dl
  1553.         dec     edi
  1554.         loop    d_desnum
  1555.         pop     eax
  1556.         call    normalize_number
  1557.         call    draw_num_text
  1558.         add     esp, 64
  1559.         popad
  1560.         ret
  1561.    no_display_desnum:
  1562.  
  1563.         cmp     ah, 0x01         ; HEXADECIMAL
  1564.         jne     no_display_hexnum
  1565.         shr     eax, 16
  1566.         and     eax, 0xC03f
  1567. ;     and   eax,0x3f
  1568.         push    eax
  1569.         and     eax, 0x3f
  1570.         mov     edi, esp
  1571.         add     edi, 4+64-1
  1572.         mov     ecx, eax
  1573.         mov     eax, ebx
  1574.         mov     ebx, 16
  1575.    d_hexnum:
  1576.         xor     edx, edx
  1577.         call    division_64_bits
  1578.         div     ebx
  1579.    hexletters = __fdo_hexdigits
  1580.         add     edx, hexletters
  1581.         mov     dl, [edx]
  1582.         mov     [edi], dl
  1583.         dec     edi
  1584.         loop    d_hexnum
  1585.         pop     eax
  1586.         call    normalize_number
  1587.         call    draw_num_text
  1588.         add     esp, 64
  1589.         popad
  1590.         ret
  1591.    no_display_hexnum:
  1592.  
  1593.         cmp     ah, 0x02         ; BINARY
  1594.         jne     no_display_binnum
  1595.         shr     eax, 16
  1596.         and     eax, 0xC03f
  1597. ;     and   eax,0x3f
  1598.         push    eax
  1599.         and     eax, 0x3f
  1600.         mov     edi, esp
  1601.         add     edi, 4+64-1
  1602.         mov     ecx, eax
  1603.         mov     eax, ebx
  1604.         mov     ebx, 2
  1605.    d_binnum:
  1606.         xor     edx, edx
  1607.         call    division_64_bits
  1608.         div     ebx
  1609.         add     dl, 48
  1610.         mov     [edi], dl
  1611.         dec     edi
  1612.         loop    d_binnum
  1613.         pop     eax
  1614.         call    normalize_number
  1615.         call    draw_num_text
  1616.         add     esp, 64
  1617.         popad
  1618.         ret
  1619.    no_display_binnum:
  1620.  
  1621.         add     esp, 64
  1622.         popad
  1623.         ret
  1624.  
  1625. normalize_number:
  1626.         test    ah, 0x80
  1627.         jz      .continue
  1628.         mov     ecx, 48
  1629.         and     eax, 0x3f
  1630. @@:
  1631.         inc     edi
  1632.         cmp     [edi], cl
  1633.         jne     .continue
  1634.         dec     eax
  1635.         cmp     eax, 1
  1636.         ja      @r
  1637.         mov     al, 1
  1638. .continue:
  1639.         and     eax, 0x3f
  1640.         ret
  1641.  
  1642. division_64_bits:
  1643.         test    [esp+1+4], byte 0x40
  1644.         jz      .continue
  1645.         push    eax
  1646.         mov     eax, ebp
  1647.         div     ebx
  1648.         mov     ebp, eax
  1649.         pop     eax
  1650. .continue:
  1651.         ret
  1652.  
  1653. draw_num_text:
  1654.         mov     esi, eax
  1655.         mov     edx, 64+4
  1656.         sub     edx, eax
  1657.         add     edx, esp
  1658.         mov     ebx, [esp+64+32-8+4]
  1659. ; add window start x & y
  1660.         mov     ecx, [TASK_BASE]
  1661.  
  1662.         mov     edi, [CURRENT_TASK]
  1663.         shl     edi, 8
  1664.  
  1665.         mov     eax, [ecx-twdw+WDATA.box.left]
  1666.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1667.         shl     eax, 16
  1668.         add     eax, [ecx-twdw+WDATA.box.top]
  1669.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1670.         add     ebx, eax
  1671.         mov     ecx, [esp+64+32-12+4]
  1672.         and     ecx, not 0x80000000     ; force counted string
  1673.         mov     eax, [esp+64+8]         ; background color (if given)
  1674.         mov     edi, [esp+64+4]
  1675.         jmp     dtext
  1676.  
  1677. align 4
  1678.  
  1679. sys_setup:
  1680.  
  1681. ; 1=roland mpu midi base , base io address
  1682. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1683. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1684. ; 5=system language, 1eng 2fi 3ger 4rus
  1685. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1686. ; 8=fat32 partition in hd
  1687. ; 9
  1688. ; 10 = sound dma channel
  1689. ; 11 = enable lba read
  1690. ; 12 = enable pci access
  1691.  
  1692.  
  1693.         and     [esp+32], dword 0
  1694.         dec     ebx                             ; MIDI
  1695.         jnz     nsyse1
  1696.         cmp     ecx, 0x100
  1697.  
  1698.         jb      nsyse1
  1699.         mov     esi, 65535
  1700.         cmp     esi, ecx
  1701.  
  1702.         jb      nsyse1
  1703.         mov     [midi_base], cx ;bx
  1704.         mov     word [mididp], cx;bx
  1705.         inc     cx              ;bx
  1706.         mov     word [midisp], cx;bx
  1707.         ret
  1708.  
  1709. iglobal
  1710. midi_base dw 0
  1711. endg
  1712.  
  1713.    nsyse1:
  1714.         dec     ebx                              ; KEYBOARD
  1715.         jnz     nsyse2
  1716.         mov     edi, [TASK_BASE]
  1717.         mov     eax, [edi+TASKDATA.mem_start]
  1718.         add     eax, edx
  1719.  
  1720.         dec     ecx
  1721.         jnz     kbnobase
  1722.         mov     ebx, keymap
  1723.         mov     ecx, 128
  1724.         call    memmove
  1725.         ret
  1726.    kbnobase:
  1727.         dec     ecx
  1728.         jnz     kbnoshift
  1729.  
  1730.         mov     ebx, keymap_shift
  1731.         mov     ecx, 128
  1732.         call    memmove
  1733.         ret
  1734.    kbnoshift:
  1735.         dec     ecx
  1736.         jnz     kbnoalt
  1737.         mov     ebx, keymap_alt
  1738.         mov     ecx, 128
  1739.         call    memmove
  1740.         ret
  1741.    kbnoalt:
  1742.         sub     ecx, 6
  1743.         jnz     kbnocountry
  1744.         mov     word [keyboard], dx
  1745.         ret
  1746.    kbnocountry:
  1747.         mov     [esp+32], dword 1
  1748.         ret
  1749.    nsyse2:
  1750.         dec     ebx                         ; CD
  1751.         jnz     nsyse4
  1752.  
  1753.         test    ecx, ecx
  1754.         jz      nosesl
  1755.  
  1756.         cmp     ecx, 4
  1757.         ja      nosesl
  1758.         mov     [cd_base], cl
  1759.  
  1760.         dec     ecx
  1761.         jnz     noprma
  1762.         mov     eax, [hd_address_table]
  1763.         mov     [cdbase], eax   ;0x1f0
  1764.         mov     [cdid], 0xa0
  1765.    noprma:
  1766.  
  1767.         dec     ecx
  1768.         jnz     noprsl
  1769.         mov     eax, [hd_address_table]
  1770.         mov     [cdbase], eax   ;0x1f0
  1771.         mov     [cdid], 0xb0
  1772.    noprsl:
  1773.         dec     ecx
  1774.         jnz     nosema
  1775.         mov     eax, [hd_address_table+16]
  1776.         mov     [cdbase], eax   ;0x170
  1777.         mov     [cdid], 0xa0
  1778.    nosema:
  1779.         dec     ecx
  1780.         jnz     nosesl
  1781.         mov     eax, [hd_address_table+16]
  1782.         mov     [cdbase], eax   ;0x170
  1783.         mov     [cdid], 0xb0
  1784.    nosesl:
  1785.         ret
  1786.  
  1787. iglobal
  1788. cd_base db 0
  1789.  
  1790. endg
  1791.    nsyse4:
  1792.  
  1793.         sub     ebx, 2           ; SYSTEM LANGUAGE
  1794.         jnz     nsyse5
  1795.         mov     [syslang], ecx
  1796.         ret
  1797.    nsyse5:
  1798.  
  1799.         sub     ebx, 2          ; HD BASE - obsolete
  1800.         jnz     nsyse7
  1801.  
  1802.    nosethd:
  1803.         ret
  1804.  
  1805. nsyse7:
  1806.  
  1807. ;     cmp  eax,8                      ; HD PARTITION - obsolete
  1808.         dec     ebx
  1809.         jnz     nsyse8
  1810.         ret
  1811.  
  1812. nsyse8:
  1813. ;     cmp  eax,11                     ; ENABLE LBA READ
  1814.         and     ecx, 1
  1815.         sub     ebx, 3
  1816.         jnz     no_set_lba_read
  1817.         mov     [lba_read_enabled], ecx
  1818.         ret
  1819.  
  1820. no_set_lba_read:
  1821. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1822.         dec     ebx
  1823.         jnz     sys_setup_err
  1824.         mov     [pci_access_enabled], ecx
  1825.         ret
  1826.  
  1827. sys_setup_err:
  1828.         or      [esp+32], dword -1
  1829.         ret
  1830.  
  1831. align 4
  1832.  
  1833. sys_getsetup:
  1834.  
  1835. ; 1=roland mpu midi base , base io address
  1836. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1837. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1838. ; 5=system language, 1eng 2fi 3ger 4rus
  1839. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1840. ; 8=fat32 partition in hd
  1841. ; 9=get hs timer tic
  1842.  
  1843. ;     cmp  eax,1
  1844.         dec     ebx
  1845.         jnz     ngsyse1
  1846.         movzx   eax, [midi_base]
  1847.         mov     [esp+32], eax
  1848.         ret
  1849. ngsyse1:
  1850. ;     cmp  eax,2
  1851.         dec     ebx
  1852.         jnz     ngsyse2
  1853.  
  1854.         mov     edi, [TASK_BASE]
  1855.         mov     ebx, [edi+TASKDATA.mem_start]
  1856.         add     ebx, edx
  1857.  
  1858. ;     cmp  ebx,1
  1859.         dec     ecx
  1860.         jnz     kbnobaseret
  1861.         mov     eax, keymap
  1862.         mov     ecx, 128
  1863.         call    memmove
  1864.         ret
  1865. kbnobaseret:
  1866. ;     cmp  ebx,2
  1867.         dec     ecx
  1868.         jnz     kbnoshiftret
  1869.  
  1870.         mov     eax, keymap_shift
  1871.         mov     ecx, 128
  1872.         call    memmove
  1873.         ret
  1874. kbnoshiftret:
  1875. ;     cmp  ebx,3
  1876.         dec     ecx
  1877.         jne     kbnoaltret
  1878.  
  1879.         mov     eax, keymap_alt
  1880.         mov     ecx, 128
  1881.         call    memmove
  1882.         ret
  1883. kbnoaltret:
  1884. ;     cmp  ebx,9
  1885.         sub     ecx, 6
  1886.         jnz     ngsyse2
  1887.         movzx   eax, word [keyboard]
  1888.         mov     [esp+32], eax
  1889.         ret
  1890.  
  1891.  
  1892. ngsyse2:
  1893. ;         cmp  eax,3
  1894.         dec     ebx
  1895.         jnz     ngsyse3
  1896.         movzx   eax, [cd_base]
  1897.         mov     [esp+32], eax
  1898.         ret
  1899. ngsyse3:
  1900. ;         cmp  eax,5
  1901.         sub     ebx, 2
  1902.         jnz     ngsyse5
  1903.         mov     eax, [syslang]
  1904.         mov     [esp+32], eax
  1905.         ret
  1906. ngsyse5:
  1907. ;     cmp  eax,7
  1908.         sub     ebx, 2
  1909.         jnz     ngsyse7
  1910.         xor     eax, eax
  1911.         mov     [esp+32], eax
  1912.         ret
  1913. ngsyse7:
  1914. ;     cmp  eax,8
  1915.         dec     ebx
  1916.         jnz     ngsyse8
  1917.         mov     eax, [fat32part]
  1918.         mov     [esp+32], eax
  1919.         ret
  1920. ngsyse8:
  1921. ;     cmp  eax,9
  1922.         dec     ebx
  1923.         jnz     ngsyse9
  1924.         mov     eax, [timer_ticks];[0xfdf0]
  1925.         mov     [esp+32], eax
  1926.         ret
  1927. ngsyse9:
  1928. ;     cmp  eax,11
  1929.         sub     ebx, 2
  1930.         jnz     ngsyse11
  1931.         mov     eax, [lba_read_enabled]
  1932.         mov     [esp+32], eax
  1933.         ret
  1934. ngsyse11:
  1935. ;     cmp  eax,12
  1936.         dec     ebx
  1937.         jnz     ngsyse12
  1938.         mov     eax, [pci_access_enabled]
  1939.         mov     [esp+32], eax
  1940.         ret
  1941. ngsyse12:
  1942.         mov     [esp+32], dword 1
  1943.         ret
  1944.  
  1945.  
  1946. get_timer_ticks:
  1947.         mov     eax, [timer_ticks]
  1948.         ret
  1949.  
  1950. iglobal
  1951. align 4
  1952. mousefn dd msscreen, mswin, msbutton, msset
  1953.         dd app_load_cursor
  1954.         dd app_set_cursor
  1955.         dd app_delete_cursor
  1956.         dd msz
  1957. endg
  1958.  
  1959. readmousepos:
  1960.  
  1961. ; eax=0 screen relative
  1962. ; eax=1 window relative
  1963. ; eax=2 buttons pressed
  1964. ; eax=3 set mouse pos   ; reserved
  1965. ; eax=4 load cursor
  1966. ; eax=5 set cursor
  1967. ; eax=6 delete cursor   ; reserved
  1968. ; eax=7 get mouse_z
  1969.  
  1970.         cmp     ebx, 7
  1971.         ja      msset
  1972.         jmp     [mousefn+ebx*4]
  1973. msscreen:
  1974.         mov     eax, [MOUSE_X]
  1975.         shl     eax, 16
  1976.         mov     ax, [MOUSE_Y]
  1977.         mov     [esp+36-4], eax
  1978.         ret
  1979. mswin:
  1980.         mov     eax, [MOUSE_X]
  1981.         shl     eax, 16
  1982.         mov     ax, [MOUSE_Y]
  1983.         mov     esi, [TASK_BASE]
  1984.         mov     bx, word [esi-twdw+WDATA.box.left]
  1985.         shl     ebx, 16
  1986.         mov     bx, word [esi-twdw+WDATA.box.top]
  1987.         sub     eax, ebx
  1988.  
  1989.         mov     edi, [CURRENT_TASK]
  1990.         shl     edi, 8
  1991.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1992.         rol     eax, 16
  1993.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1994.         rol     eax, 16
  1995.         mov     [esp+36-4], eax
  1996.         ret
  1997. msbutton:
  1998.         movzx   eax, byte [BTN_DOWN]
  1999.         mov     [esp+36-4], eax
  2000.         ret
  2001. msz:
  2002.         mov     edi, [TASK_COUNT]
  2003.         movzx   edi, word [WIN_POS + edi*2]
  2004.         cmp     edi, [CURRENT_TASK]
  2005.         jne     @f
  2006.         mov     ax, [MOUSE_SCROLL_H]
  2007.         shl     eax, 16
  2008.         mov     ax, [MOUSE_SCROLL_V]
  2009.         mov     [esp+36-4], eax
  2010.         and     [MOUSE_SCROLL_H], word 0
  2011.         and     [MOUSE_SCROLL_V], word 0
  2012.         ret
  2013.        @@:
  2014.         and     [esp+36-4], dword 0
  2015. ;           ret
  2016. msset:
  2017.         ret
  2018.  
  2019. app_load_cursor:
  2020.         cmp     ecx, OS_BASE
  2021.         jae     msset
  2022.         stdcall load_cursor, ecx, edx
  2023.         mov     [esp+36-4], eax
  2024.         ret
  2025.  
  2026. app_set_cursor:
  2027.         stdcall set_cursor, ecx
  2028.         mov     [esp+36-4], eax
  2029.         ret
  2030.  
  2031. app_delete_cursor:
  2032.         stdcall delete_cursor, ecx
  2033.         mov     [esp+36-4], eax
  2034.         ret
  2035.  
  2036. is_input:
  2037.  
  2038.         push    edx
  2039.         mov     dx, word [midisp]
  2040.         in      al, dx
  2041.         and     al, 0x80
  2042.         pop     edx
  2043.         ret
  2044.  
  2045. is_output:
  2046.  
  2047.         push    edx
  2048.         mov     dx, word [midisp]
  2049.         in      al, dx
  2050.         and     al, 0x40
  2051.         pop     edx
  2052.         ret
  2053.  
  2054.  
  2055. get_mpu_in:
  2056.  
  2057.         push    edx
  2058.         mov     dx, word [mididp]
  2059.         in      al, dx
  2060.         pop     edx
  2061.         ret
  2062.  
  2063.  
  2064. put_mpu_out:
  2065.  
  2066.         push    edx
  2067.         mov     dx, word [mididp]
  2068.         out     dx, al
  2069.         pop     edx
  2070.         ret
  2071.  
  2072.  
  2073.  
  2074. align 4
  2075.  
  2076. sys_midi:
  2077.         cmp     [mididp], 0
  2078.         jnz     sm0
  2079.         mov     [esp+36], dword 1
  2080.         ret
  2081. sm0:
  2082.         and     [esp+36], dword 0
  2083.         dec     ebx
  2084.         jnz     smn1
  2085.  ;    call setuart
  2086. su1:
  2087.         call    is_output
  2088.         test    al, al
  2089.         jnz     su1
  2090.         mov     dx, word [midisp]
  2091.         mov     al, 0xff
  2092.         out     dx, al
  2093. su2:
  2094.         mov     dx, word [midisp]
  2095.         mov     al, 0xff
  2096.         out     dx, al
  2097.         call    is_input
  2098.         test    al, al
  2099.         jnz     su2
  2100.         call    get_mpu_in
  2101.         cmp     al, 0xfe
  2102.         jnz     su2
  2103. su3:
  2104.         call    is_output
  2105.         test    al, al
  2106.         jnz     su3
  2107.         mov     dx, word [midisp]
  2108.         mov     al, 0x3f
  2109.         out     dx, al
  2110.         ret
  2111. smn1:
  2112.         dec     ebx
  2113.         jnz     smn2
  2114. sm10:
  2115.         call    get_mpu_in
  2116.         call    is_output
  2117.         test    al, al
  2118.         jnz     sm10
  2119.         mov     al, bl
  2120.         call    put_mpu_out
  2121.         smn2:
  2122.         ret
  2123.  
  2124. detect_devices:
  2125. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2126. ;include 'detect/commouse.inc'
  2127. ;include 'detect/ps2mouse.inc'
  2128. ;include 'detect/dev_fd.inc'
  2129. ;include 'detect/dev_hdcd.inc'
  2130. ;include 'detect/sear_par.inc'
  2131. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2132.         ret
  2133.  
  2134. sys_end:
  2135. ;--------------------------------------
  2136.         cmp     [_display.select_cursor], 0
  2137.         je      @f
  2138. ; restore default cursor before killing
  2139.         pusha
  2140.         mov     ecx, [current_slot]
  2141.         call    restore_default_cursor_before_killing
  2142.         popa
  2143. @@:
  2144. ;--------------------------------------
  2145. ; kill all sockets this process owns
  2146.         pusha
  2147.         mov     edx, [TASK_BASE]
  2148.         mov     edx, [edx+TASKDATA.pid]
  2149.         call    SOCKET_process_end
  2150.         popa
  2151. ;--------------------------------------
  2152.         mov     ecx, [current_slot]
  2153.         mov     eax, [ecx+APPDATA.tls_base]
  2154.         test    eax, eax
  2155.         jz      @F
  2156.  
  2157.         stdcall user_free, eax
  2158. @@:
  2159.  
  2160.         mov     eax, [TASK_BASE]
  2161.         mov     [eax+TASKDATA.state], 3; terminate this program
  2162.         call    wakeup_osloop
  2163.  
  2164. .waitterm:            ; wait here for termination
  2165.         call    change_task
  2166.         jmp     .waitterm
  2167. ;------------------------------------------------------------------------------
  2168. align 4
  2169. restore_default_cursor_before_killing:
  2170.         pushfd
  2171.         cli
  2172.         mov     eax, [def_cursor]
  2173.         mov     [ecx+APPDATA.cursor], eax
  2174.  
  2175.         movzx   eax, word [MOUSE_Y]
  2176.         movzx   ebx, word [MOUSE_X]
  2177. ;        mov     ecx, [Screen_Max_X]
  2178. ;        inc     ecx
  2179. ;        mul     ecx
  2180.         mov     eax, [d_width_calc_area + eax*4]
  2181.  
  2182.         add     eax, [_WinMapAddress]
  2183.         movzx   edx, byte [ebx+eax]
  2184.         shl     edx, 8
  2185.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2186.  
  2187.         cmp     esi, [current_cursor]
  2188.         je      @f
  2189.  
  2190.         push    esi
  2191.         call    [_display.select_cursor]
  2192.         mov     [current_cursor], esi
  2193. @@:
  2194.         mov     [redrawmouse_unconditional], 1
  2195.         call    wakeup_osloop
  2196.         popfd
  2197.         ret
  2198. ;------------------------------------------------------------------------------
  2199. iglobal
  2200. align 4
  2201. sys_system_table:
  2202.         dd      sysfn_deactivate        ; 1 = deactivate window
  2203.         dd      sysfn_terminate         ; 2 = terminate thread
  2204.         dd      sysfn_activate          ; 3 = activate window
  2205.         dd      sysfn_getidletime       ; 4 = get idle time
  2206.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2207.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2208.         dd      sysfn_getactive         ; 7 = get active window
  2209.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2210.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2211.         dd      sysfn_minimize          ; 10 = minimize window
  2212.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2213.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2214.         dd      sysfn_getversion        ; 13 = get kernel version
  2215.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2216.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2217.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2218.         dd      sysfn_getallmem         ; 17 = get total memory size
  2219.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2220.                                         ;                 instead of slot
  2221.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2222.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2223.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2224.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2225.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2226.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2227. sysfn_num = ($ - sys_system_table)/4
  2228. endg
  2229. ;------------------------------------------------------------------------------
  2230. sys_system:
  2231.         dec     ebx
  2232.         cmp     ebx, sysfn_num
  2233.         jae     @f
  2234.         jmp     dword [sys_system_table + ebx*4]
  2235. @@:
  2236.         ret
  2237. ;------------------------------------------------------------------------------
  2238. sysfn_shutdown:          ; 18.9 = system shutdown
  2239.         cmp     ecx, 1
  2240.         jl      exit_for_anyone
  2241.         cmp     ecx, 4
  2242.         jg      exit_for_anyone
  2243.         mov     [BOOT_VARS+0x9030], cl
  2244.  
  2245.         mov     eax, [TASK_COUNT]
  2246.         mov     [SYS_SHUTDOWN], al
  2247.         mov     [shutdown_processes], eax
  2248.         call    wakeup_osloop
  2249.         and     dword [esp+32], 0
  2250.  exit_for_anyone:
  2251.         ret
  2252.   uglobal
  2253.    shutdown_processes:
  2254.                        dd 0x0
  2255.   endg
  2256. ;------------------------------------------------------------------------------
  2257. sysfn_terminate:        ; 18.2 = TERMINATE
  2258.         push    ecx
  2259.         cmp     ecx, 2
  2260.         jb      noprocessterminate
  2261.         mov     edx, [TASK_COUNT]
  2262.         cmp     ecx, edx
  2263.         ja      noprocessterminate
  2264.         mov     eax, [TASK_COUNT]
  2265.         shl     ecx, 5
  2266.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2267.         add     ecx, CURRENT_TASK+TASKDATA.state
  2268.         cmp     byte [ecx], 9
  2269.         jz      noprocessterminate
  2270.         push    ecx edx
  2271.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2272.         call    request_terminate
  2273.         pop     edx ecx
  2274.         test    eax, eax
  2275.         jz      noprocessterminate
  2276. ;--------------------------------------
  2277. ; terminate all network sockets it used
  2278.         pusha
  2279.         mov     eax, edx
  2280.         call    SOCKET_process_end
  2281.         popa
  2282. ;--------------------------------------
  2283.         cmp     [_display.select_cursor], 0
  2284.         je      .restore_end
  2285. ; restore default cursor before killing
  2286.         pusha
  2287.         mov     ecx, [esp+32]
  2288.         shl     ecx, 8
  2289.         add     ecx, SLOT_BASE
  2290.         mov     eax, [def_cursor]
  2291.         cmp     [ecx+APPDATA.cursor], eax
  2292.         je      @f
  2293.         call    restore_default_cursor_before_killing
  2294. @@:
  2295.         popa
  2296. .restore_end:
  2297. ;--------------------------------------
  2298.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2299.         mov     [ecx], byte 3; clear possible i40's
  2300.         call    wakeup_osloop
  2301.      ;call MEM_Heap_UnLock
  2302.  
  2303.         cmp     edx, [application_table_owner]; clear app table stat
  2304.         jne     noatsc
  2305.         call    unlock_application_table
  2306. noatsc:
  2307. noprocessterminate:
  2308.         add     esp, 4
  2309.         ret
  2310. ;------------------------------------------------------------------------------
  2311. sysfn_terminate2:
  2312. ;lock application_table_status mutex
  2313. .table_status:
  2314.         call    lock_application_table
  2315.         mov     eax, ecx
  2316.         call    pid_to_slot
  2317.         test    eax, eax
  2318.         jz      .not_found
  2319.         mov     ecx, eax
  2320.         cli
  2321.         call    sysfn_terminate
  2322.         call    unlock_application_table
  2323.         sti
  2324.         and     dword [esp+32], 0
  2325.         ret
  2326. .not_found:
  2327.         call    unlock_application_table
  2328.         or      dword [esp+32], -1
  2329.         ret
  2330. ;------------------------------------------------------------------------------
  2331. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2332.         cmp     ecx, 2
  2333.         jb      .nowindowdeactivate
  2334.         cmp     ecx, [TASK_COUNT]
  2335.         ja      .nowindowdeactivate
  2336.  
  2337.         movzx   esi, word [WIN_STACK + ecx*2]
  2338.         cmp     esi, 1
  2339.         je      .nowindowdeactivate ; already deactive
  2340.  
  2341.         mov     edi, ecx
  2342.         shl     edi, 5
  2343.         add     edi, window_data
  2344.         movzx   esi, word [WIN_STACK + ecx * 2]
  2345.         lea     esi, [WIN_POS + esi * 2]
  2346.         call    window._.window_deactivate
  2347.  
  2348.         call    syscall_display_settings._.calculate_whole_screen
  2349.         call    syscall_display_settings._.redraw_whole_screen
  2350. .nowindowdeactivate:
  2351.         ret
  2352. ;------------------------------------------------------------------------------
  2353. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2354.         cmp     ecx, 2
  2355.         jb      .nowindowactivate
  2356.         cmp     ecx, [TASK_COUNT]
  2357.         ja      .nowindowactivate
  2358. ;-------------------------------------
  2359. @@:
  2360. ; If the window is captured and moved by the user,
  2361. ; then you can't change the position in window stack!!!
  2362.         mov     al, [mouse.active_sys_window.action]
  2363.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2364.         test    al, al
  2365.         jz      @f
  2366.         call    change_task
  2367.         jmp     @b
  2368. @@:
  2369. ;-------------------------------------
  2370.         mov     [window_minimize], 2; restore window if minimized
  2371.         call    wakeup_osloop
  2372.  
  2373.         movzx   esi, word [WIN_STACK + ecx*2]
  2374.         cmp     esi, [TASK_COUNT]
  2375.         je      .nowindowactivate; already active
  2376.  
  2377.         mov     edi, ecx
  2378.         shl     edi, 5
  2379.         add     edi, window_data
  2380.         movzx   esi, word [WIN_STACK + ecx * 2]
  2381.         lea     esi, [WIN_POS + esi * 2]
  2382.         call    waredraw
  2383. .nowindowactivate:
  2384.         ret
  2385. ;------------------------------------------------------------------------------
  2386. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2387.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2388.         mov     [esp+32], eax
  2389.         ret
  2390. ;------------------------------------------------------------------------------
  2391. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2392.         mov     eax, dword [cpu_freq]
  2393.         mov     [esp+32], eax
  2394.         ret
  2395. ;------------------------------------------------------------------------------
  2396. get_cpu_freq:
  2397.         mov     eax, dword [cpu_freq]
  2398.         mov     edx, dword [cpu_freq+4]
  2399.         ret
  2400. ;  SAVE ramdisk to /hd/1/menuet.img
  2401. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2402.    include 'blkdev/rdsave.inc'
  2403. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2404. ;------------------------------------------------------------------------------
  2405. align 4
  2406. sysfn_getactive:        ; 18.7 = get active window
  2407.         mov     eax, [TASK_COUNT]
  2408.         movzx   eax, word [WIN_POS + eax*2]
  2409.         mov     [esp+32], eax
  2410.         ret
  2411. ;------------------------------------------------------------------------------
  2412. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2413. ;     cmp  ecx,1
  2414.         dec     ecx
  2415.         jnz     nogetsoundflag
  2416.         movzx   eax, byte [sound_flag]; get sound_flag
  2417.         mov     [esp+32], eax
  2418.         ret
  2419.  nogetsoundflag:
  2420. ;     cmp  ecx,2
  2421.         dec     ecx
  2422.         jnz     nosoundflag
  2423.         xor     byte [sound_flag], 1
  2424.  nosoundflag:
  2425.         ret
  2426. ;------------------------------------------------------------------------------
  2427. sysfn_minimize:         ; 18.10 = minimize window
  2428.         mov     [window_minimize], 1
  2429.         call    wakeup_osloop
  2430.         ret
  2431. ;------------------------------------------------------------------------------
  2432. align 4
  2433. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2434. ;     cmp  ecx,1
  2435.         dec     ecx
  2436.         jnz     full_table
  2437.   small_table:
  2438.         call    for_all_tables
  2439.         mov     ecx, 10
  2440.         cld
  2441.         rep movsb
  2442.         ret
  2443.    for_all_tables:
  2444.         mov     edi, edx
  2445.         mov     esi, DRIVE_DATA
  2446.         ret
  2447.   full_table:
  2448. ;     cmp  ecx,2
  2449.         dec     ecx
  2450.         jnz     exit_for_anyone
  2451.         call    for_all_tables
  2452.         mov     ecx, DRIVE_DATA_SIZE/4
  2453.         cld
  2454.         rep movsd
  2455.         ret
  2456. ;------------------------------------------------------------------------------
  2457. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2458.         and     dword [esp+32], 0
  2459.         ret
  2460. ;------------------------------------------------------------------------------
  2461. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2462.         mov     edi, ecx
  2463.         mov     esi, version_inf
  2464.         mov     ecx, version_end-version_inf
  2465.         rep movsb
  2466.         ret
  2467. ;------------------------------------------------------------------------------
  2468. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2469.      ;wait retrace functions
  2470.  sys_wait_retrace:
  2471.         mov     edx, 0x3da
  2472.  WaitRetrace_loop:
  2473.         in      al, dx
  2474.         test    al, 1000b
  2475.         jz      WaitRetrace_loop
  2476.         and     [esp+32], dword 0
  2477.         ret
  2478. ;------------------------------------------------------------------------------
  2479. align 4
  2480. sysfn_centermouse:      ; 18.15 = mouse centered
  2481. ; removed here by <Lrz>
  2482. ;     call  mouse_centered
  2483. ;* mouse centered - start code- Mario79
  2484. ;mouse_centered:
  2485. ;        push  eax
  2486.         mov     eax, [Screen_Max_X]
  2487.         shr     eax, 1
  2488.         mov     [MOUSE_X], ax
  2489.         mov     eax, [Screen_Max_Y]
  2490.         shr     eax, 1
  2491.         mov     [MOUSE_Y], ax
  2492.         call    wakeup_osloop
  2493. ;        ret
  2494. ;* mouse centered - end code- Mario79
  2495.         xor     eax, eax
  2496.         and     [esp+32], eax
  2497. ;        pop   eax
  2498.         ret
  2499. ;------------------------------------------------------------------------------
  2500. align 4
  2501. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2502.         test    ecx, ecx; get mouse speed factor
  2503.         jnz     .set_mouse_acceleration
  2504.         xor     eax, eax
  2505.         mov     ax, [mouse_speed_factor]
  2506.         mov     [esp+32], eax
  2507.         ret
  2508.  .set_mouse_acceleration:
  2509. ;     cmp  ecx,1  ; set mouse speed factor
  2510.         dec     ecx
  2511.         jnz     .get_mouse_delay
  2512.         mov     [mouse_speed_factor], dx
  2513.         ret
  2514.  .get_mouse_delay:
  2515. ;     cmp  ecx,2  ; get mouse delay
  2516.         dec     ecx
  2517.         jnz     .set_mouse_delay
  2518.         mov     eax, [mouse_delay]
  2519.         mov     [esp+32], eax
  2520.         ret
  2521.  .set_mouse_delay:
  2522. ;     cmp  ecx,3  ; set mouse delay
  2523.         dec     ecx
  2524.         jnz     .set_pointer_position
  2525.         mov     [mouse_delay], edx
  2526.         ret
  2527.  .set_pointer_position:
  2528. ;     cmp  ecx,4  ; set mouse pointer position
  2529.         dec     ecx
  2530.         jnz     .set_mouse_button
  2531.         cmp     dx, word[Screen_Max_Y]
  2532.         ja      .end
  2533.         rol     edx, 16
  2534.         cmp     dx, word[Screen_Max_X]
  2535.         ja      .end
  2536.         mov     [MOUSE_X], edx
  2537.         call    wakeup_osloop
  2538.         ret
  2539.  .set_mouse_button:
  2540. ;     cmp   ecx,5  ; set mouse button features
  2541.         dec     ecx
  2542.         jnz     .end
  2543.         mov     [BTN_DOWN], dl
  2544.         mov     [mouse_active], 1
  2545.         call    wakeup_osloop
  2546.  .end:
  2547.         ret
  2548. ;------------------------------------------------------------------------------
  2549. sysfn_getfreemem:
  2550.         mov     eax, [pg_data.pages_free]
  2551.         shl     eax, 2
  2552.         mov     [esp+32], eax
  2553.         ret
  2554. ;------------------------------------------------------------------------------
  2555. sysfn_getallmem:
  2556.         mov     eax, [MEM_AMOUNT]
  2557.         shr     eax, 10
  2558.         mov     [esp+32], eax
  2559.         ret
  2560. ;------------------------------------------------------------------------------
  2561. sysfn_pid_to_slot:
  2562.         mov     eax, ecx
  2563.         call    pid_to_slot
  2564.         mov     [esp+32], eax
  2565.         ret
  2566. ;------------------------------------------------------------------------------
  2567. sysfn_min_rest_window:
  2568.         pushad
  2569.         mov     eax, edx ; ebx - operating
  2570.         shr     ecx, 1
  2571.         jnc     @f
  2572.         call    pid_to_slot
  2573. @@:
  2574.         or      eax, eax ; eax - number of slot
  2575.         jz      .error
  2576.         cmp     eax, 255    ; varify maximal slot number
  2577.         ja      .error
  2578.         movzx   eax, word [WIN_STACK + eax*2]
  2579.         shr     ecx, 1
  2580.         jc      .restore
  2581.  ; .minimize:
  2582.         call    minimize_window
  2583.         jmp     .exit
  2584. .restore:
  2585.         call    restore_minimized_window
  2586. .exit:
  2587.         popad
  2588.         xor     eax, eax
  2589.         mov     [esp+32], eax
  2590.         ret
  2591. .error:
  2592.         popad
  2593.         xor     eax, eax
  2594.         dec     eax
  2595.         mov     [esp+32], eax
  2596.         ret
  2597. ;------------------------------------------------------------------------------
  2598. sysfn_min_windows:
  2599.         call    minimize_all_window
  2600.         mov     [esp+32], eax
  2601.         call    change_task
  2602.         ret
  2603. ;------------------------------------------------------------------------------
  2604. sysfn_set_screen_sizes:
  2605.         cmp     [SCR_MODE], word 0x13
  2606.         jbe     .exit
  2607.  
  2608.         cmp     [_display.select_cursor], select_cursor
  2609.         jne     .exit
  2610.  
  2611.         cmp     ecx, [display_width_standard]
  2612.         ja      .exit
  2613.  
  2614.         cmp     edx, [display_height_standard]
  2615.         ja      .exit
  2616.  
  2617.         pushfd
  2618.         cli
  2619.         mov     eax, ecx
  2620.         mov     ecx, [_display.pitch]
  2621.         mov     [_display.width], eax
  2622.         dec     eax
  2623.         mov     [_display.height], edx
  2624.         dec     edx
  2625. ; eax - new Screen_Max_X
  2626. ; edx - new Screen_Max_Y
  2627.         mov     [do_not_touch_winmap], 1
  2628.         call    set_screen
  2629.         mov     [do_not_touch_winmap], 0
  2630.         popfd
  2631.         call    change_task
  2632. .exit:
  2633.         ret
  2634. ;------------------------------------------------------------------------------
  2635. uglobal
  2636. screen_workarea RECT
  2637. display_width_standard dd 0
  2638. display_height_standard dd 0
  2639. do_not_touch_winmap db 0
  2640. window_minimize db 0
  2641. sound_flag      db 0
  2642.  
  2643. endg
  2644.  
  2645. UID_NONE=0
  2646. UID_MENUETOS=1   ;official
  2647. UID_KOLIBRI=2    ;russian
  2648.  
  2649. iglobal
  2650. version_inf:
  2651.         db 0,7,7,0  ; version 0.7.7.0
  2652.         db 0
  2653. .rev    dd __REV__
  2654. version_end:
  2655. endg
  2656. ;------------------------------------------------------------------------------
  2657. align 4
  2658. sys_cachetodiskette:
  2659.         cmp     ebx, 1
  2660.         jne     .no_floppy_a_save
  2661.         mov     [flp_number], 1
  2662.         jmp     .save_image_on_floppy
  2663. ;--------------------------------------
  2664. align 4
  2665. .no_floppy_a_save:
  2666.         cmp     ebx, 2
  2667.         jne     .no_floppy_b_save
  2668.         mov     [flp_number], 2
  2669. ;--------------------------------------
  2670. align 4
  2671. .save_image_on_floppy:
  2672.         call    save_image
  2673.         mov     [esp + 32], dword 0
  2674.         cmp     [FDC_Status], 0
  2675.         je      .yes_floppy_save
  2676. ;--------------------------------------
  2677. align 4
  2678. .no_floppy_b_save:
  2679.         mov     [esp + 32], dword 1
  2680. ;--------------------------------------
  2681. align 4
  2682. .yes_floppy_save:
  2683.         ret
  2684. ;------------------------------------------------------------------------------
  2685. uglobal
  2686. ;  bgrchanged  dd  0x0
  2687. align 4
  2688. bgrlockpid dd 0
  2689. bgrlock db 0
  2690. endg
  2691. ;------------------------------------------------------------------------------
  2692. align 4
  2693. sys_background:
  2694.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2695.         jnz     nosb1
  2696.         test    ecx, ecx
  2697.         jz      sbgrr
  2698.  
  2699.         test    edx, edx
  2700.         jz      sbgrr
  2701. ;--------------------------------------
  2702. align 4
  2703. @@:
  2704. ;;Maxis use atomic bts for mutexes  4.4.2009
  2705.         bts     dword [bgrlock], 0
  2706.         jnc     @f
  2707.         call    change_task
  2708.         jmp     @b
  2709. ;--------------------------------------
  2710. align 4
  2711. @@:
  2712.         mov     [BgrDataWidth], ecx
  2713.         mov     [BgrDataHeight], edx
  2714. ;    mov   [bgrchanged],1
  2715.  
  2716.         pushad
  2717. ; return memory for old background
  2718.         mov     eax, [img_background]
  2719.         cmp     eax, static_background_data
  2720.         jz      @f
  2721.         stdcall kernel_free, eax
  2722. ;--------------------------------------
  2723. align 4
  2724. @@:
  2725. ; calculate RAW size
  2726.         xor     eax, eax
  2727.         inc     eax
  2728.         cmp     [BgrDataWidth], eax
  2729.         jae     @f
  2730.         mov     [BgrDataWidth], eax
  2731. ;--------------------------------------
  2732. align 4
  2733. @@:
  2734.         cmp     [BgrDataHeight], eax
  2735.         jae     @f
  2736.         mov     [BgrDataHeight], eax
  2737. ;--------------------------------------
  2738. align 4
  2739. @@:
  2740.         mov     eax, [BgrDataWidth]
  2741.         imul    eax, [BgrDataHeight]
  2742.         lea     eax, [eax*3]
  2743. ; it is reserved with aligned to the boundary of 4 KB pages,
  2744. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2745. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2746.         shr     eax, 12
  2747.         inc     eax
  2748.         shl     eax, 12
  2749.         mov     [mem_BACKGROUND], eax
  2750. ; get memory for new background
  2751.         stdcall kernel_alloc, eax
  2752.         test    eax, eax
  2753.         jz      .memfailed
  2754.         mov     [img_background], eax
  2755.         jmp     .exit
  2756. ;--------------------------------------
  2757. align 4
  2758. .memfailed:
  2759. ; revert to static monotone data
  2760.         mov     [img_background], static_background_data
  2761.         xor     eax, eax
  2762.         inc     eax
  2763.         mov     [BgrDataWidth], eax
  2764.         mov     [BgrDataHeight], eax
  2765.         mov     [mem_BACKGROUND], 4
  2766. ;--------------------------------------
  2767. align 4
  2768. .exit:
  2769.         popad
  2770.         mov     [bgrlock], 0
  2771. ;--------------------------------------
  2772. align 4
  2773. sbgrr:
  2774.         ret
  2775. ;------------------------------------------------------------------------------
  2776. align 4
  2777. nosb1:
  2778.         cmp     ebx, 2                     ; SET PIXEL
  2779.         jnz     nosb2
  2780.  
  2781.         mov     eax, [img_background]
  2782.         test    ecx, ecx
  2783.         jz      @f
  2784.         cmp     eax, static_background_data
  2785.         jz      .ret
  2786. ;--------------------------------------
  2787. align 4
  2788. @@:
  2789.         mov     ebx, [mem_BACKGROUND]
  2790.         add     ebx, 4095
  2791.         and     ebx, -4096
  2792.         sub     ebx, 4
  2793.         cmp     ecx, ebx
  2794.         ja      .ret
  2795.  
  2796.         mov     ebx, [eax+ecx]
  2797.         and     ebx, 0xFF000000;255*256*256*256
  2798.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2799.         add     edx, ebx
  2800.         mov     [eax+ecx], edx
  2801. ;--------------------------------------
  2802. align 4
  2803. .ret:
  2804.         ret
  2805. ;------------------------------------------------------------------------------
  2806. align 4
  2807. nosb2:
  2808.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2809.         jnz     nosb3
  2810. ;--------------------------------------
  2811. align 4
  2812. draw_background_temp:
  2813.         mov     [background_defined], 1
  2814.         call    force_redraw_background
  2815. ;--------------------------------------
  2816. align 4
  2817. nosb31:
  2818.         ret
  2819. ;------------------------------------------------------------------------------
  2820. align 4
  2821. nosb3:
  2822.         cmp     ebx, 4                     ; TILED / STRETCHED
  2823.         jnz     nosb4
  2824.         cmp     ecx, [BgrDrawMode]
  2825.         je      nosb41
  2826.         mov     [BgrDrawMode], ecx
  2827. ;--------------------------------------
  2828. align 4
  2829. nosb41:
  2830.         ret
  2831. ;------------------------------------------------------------------------------
  2832. align 4
  2833. nosb4:
  2834.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2835.         jnz     nosb5
  2836.         cmp     [img_background], static_background_data
  2837.         jnz     @f
  2838.         test    edx, edx
  2839.         jnz     .fin
  2840.         cmp     esi, 4
  2841.         ja      .fin
  2842. ;--------------------------------------
  2843. align 4
  2844. @@:
  2845.   ; bughere
  2846.         mov     eax, ecx
  2847.         mov     ebx, edx
  2848.         add     ebx, [img_background];IMG_BACKGROUND
  2849.         mov     ecx, esi
  2850.         call    memmove
  2851. ;--------------------------------------
  2852. align 4
  2853. .fin:
  2854.         ret
  2855. ;------------------------------------------------------------------------------
  2856. align 4
  2857. nosb5:
  2858.         cmp     ebx, 6
  2859.         jnz     nosb6
  2860. ;--------------------------------------
  2861. align 4
  2862. ;;Maxis use atomic bts for mutex 4.4.2009
  2863. @@:
  2864.         bts     dword [bgrlock], 0
  2865.         jnc     @f
  2866.         call    change_task
  2867.         jmp     @b
  2868. ;--------------------------------------
  2869. align 4
  2870. @@:
  2871.         mov     eax, [CURRENT_TASK]
  2872.         mov     [bgrlockpid], eax
  2873.         cmp     [img_background], static_background_data
  2874.         jz      .nomem
  2875.         stdcall user_alloc, [mem_BACKGROUND]
  2876.         mov     [esp+32], eax
  2877.         test    eax, eax
  2878.         jz      .nomem
  2879.         mov     ebx, eax
  2880.         shr     ebx, 12
  2881.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2882.         mov     esi, [img_background]
  2883.         shr     esi, 12
  2884.         mov     ecx, [mem_BACKGROUND]
  2885.         add     ecx, 0xFFF
  2886.         shr     ecx, 12
  2887. ;--------------------------------------
  2888. align