Subversion Repositories Kolibri OS

Rev

Rev 684 | Rev 753 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                              ;;
  3. ;; Copyright (C) KolibriOS team 2004-2008. All rights reserved. ;;
  4. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa      ;;
  5. ;; Distributed under terms of the GNU General Public License    ;;
  6. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  7.  
  8. $Revision: 709 $
  9.  
  10.  
  11. get_titlebar_height: ; edi = window draw_data pointer
  12.         mov     al,[edi+WDATA.fl_wstyle]
  13.         and     al,0x0F
  14.         cmp     al,0x03
  15.         jne     @f
  16.         mov     eax,[_skinh]
  17.         ret
  18.     @@: mov     eax,21
  19.         ret
  20.  
  21. get_rolledup_height: ; edi = window draw_data pointer
  22.         mov     al,[edi+WDATA.fl_wstyle]
  23.         and     al,0x0F
  24.         cmp     al,0x03
  25.         jne     @f
  26.         mov     eax,[_skinh]
  27.         add     eax,3
  28.         ret
  29.     @@: or      al,al
  30.         jnz     @f
  31.         mov     eax,21
  32.         ret
  33.     @@: mov     eax,21+2
  34.         ret
  35.  
  36.  
  37. setwindowdefaults:
  38.         pushad
  39.  
  40.         xor   eax,eax
  41.         mov   ecx,WIN_STACK
  42.        @@:
  43.         inc   eax
  44.         add   ecx,2
  45.         mov   [ecx+0x000],ax          ; process no
  46.         mov   [ecx+0x400],ax          ; positions in stack
  47.         cmp   ecx,WIN_POS-2            ; the more high, the more surface
  48.         jnz   @b
  49.  
  50.         popad
  51.         ret
  52.  
  53.  
  54.  
  55. ; eax = cx
  56. ; ebx = cy
  57. ; ecx = ex
  58. ; edx = ey
  59. ; èäåÿ: ïåðåáðàòü âñå îêíà, íà÷èíàÿ ñ ñàìîãî íèæíåãî,
  60. ;       è äëÿ ïîïàâøèõ â çàäàííóþ îáëàñòü
  61. ;       ÷àñòåé îêîí âûçâàòü setscreen
  62. align 4
  63. calculatescreen:
  64.         pushad
  65.         pushfd
  66.         cli
  67.  
  68.         push    edx ecx ebx eax
  69.  
  70.         mov     esi, 1
  71.         call    setscreen
  72.  
  73.         mov     ebp, [TASK_COUNT]        ; number of processes
  74.         cmp     ebp, 1
  75.         jbe     .finish
  76.         align 4
  77.       .new_wnd:
  78.         movzx   edi, word [WIN_POS + esi * 2]
  79.         shl     edi, 5
  80.  
  81.         cmp     [CURRENT_TASK+edi+TASKDATA.state], byte 9
  82.         je      .not_wnd
  83.  
  84.         add     edi, window_data
  85.         test    [edi+WDATA.fl_wstate], WSTATE_MINIMIZED
  86.         jnz     .not_wnd
  87.  
  88.         mov     eax,[edi+WDATA.box.left]
  89.         cmp     eax, [esp+RECT.right]
  90.         ja      .out_of_bounds
  91.         mov     ebx,[edi+WDATA.box.top]
  92.         cmp     ebx, [esp+RECT.bottom]
  93.         ja      .out_of_bounds
  94.         mov     ecx,[edi+WDATA.box.width]
  95.         add     ecx, eax
  96.         cmp     ecx, [esp+RECT.left]
  97.         jb      .out_of_bounds
  98.         mov     edx,[edi+WDATA.box.height]
  99.         add     edx, ebx
  100.         cmp     edx, [esp+RECT.top]
  101.         jb      .out_of_bounds
  102.  
  103.     cmp     eax, [esp+RECT.left]
  104.         jae     @f
  105.         mov     eax, [esp+RECT.left]
  106.      @@:
  107.     cmp     ebx, [esp+RECT.top]
  108.         jae     @f
  109.         mov     ebx, [esp+RECT.top]
  110.      @@:
  111.     cmp     ecx, [esp+RECT.right]
  112.         jbe     @f
  113.         mov     ecx, [esp+RECT.right]
  114.      @@:
  115.     cmp     edx, [esp+RECT.bottom]
  116.         jbe     @f
  117.         mov     edx, [esp+RECT.bottom]
  118.      @@:
  119.  
  120.         push    esi
  121.         movzx   esi, word [WIN_POS + esi * 2]
  122.         call    setscreen
  123.         pop     esi
  124.  
  125.       .not_wnd:
  126.       .out_of_bounds:
  127.         inc     esi
  128.         dec     ebp
  129.         jnz     .new_wnd
  130.       .finish:
  131.  
  132.     pop     eax ebx ecx edx
  133.  
  134.         popfd
  135.         popad
  136. ret
  137.  
  138.  
  139.  
  140. virtual at esp
  141.   ff_x     dd ?
  142.   ff_y     dd ?
  143.   ff_width dd ?
  144.   ff_xsz   dd ?
  145.   ff_ysz   dd ?
  146.   ff_scale dd ?
  147. end virtual
  148.  
  149. align 4
  150. ; ðåçåðâèðóåò ìåñòî ïîä îêíî çàäàííîãî ïðîöåññà
  151. setscreen:
  152. ;  eax  x start
  153. ;  ebx  y start
  154. ;  ecx  x end
  155. ;  edx  y end
  156. ;  esi  process number
  157. pushad
  158. ; \begin{diamond}[29.08.2006]
  159.         cmp     esi, 1
  160.         jz      @f
  161.         mov     edi, esi
  162.         shl     edi, 5
  163.         cmp     [edi+window_data+WDATA.box.width], 0
  164.         jnz     @f
  165.         cmp     [edi+window_data+WDATA.box.height], 0
  166.         jz      .ret
  167. @@:
  168. ; \end{diamond}[29.08.2006]
  169.         mov edi, esi ;;;word [esi*2+WIN_POS]
  170.         shl   edi, 8
  171.         add   edi, SLOT_BASE  ; address of random shaped window area
  172.         cmp   [edi+APPDATA.wnd_shape], dword 0
  173.         jne   .free_form
  174.  
  175.         ; get x&y size
  176.         sub   ecx, eax
  177.         sub   edx, ebx
  178.         inc   ecx
  179.         inc   edx
  180.  
  181.         ; get WinMap start
  182.         mov   edi, [ScreenWidth] ; screen_sx
  183.         inc   edi
  184.         imul  edi, ebx
  185.         add   edi, eax
  186.         add   edi, WinMapAddress
  187.  
  188.   .new_y:
  189.         push  ecx ; sx
  190.         push  edx
  191.  
  192.         mov   edx, esi
  193.         align 4
  194.   .new_x:
  195.         mov   byte [edi], dl
  196.         inc   edi
  197.         dec   ecx
  198.         jnz   .new_x
  199.  
  200.         pop   edx
  201.         pop   ecx
  202.         add   edi, [ScreenWidth]
  203.         inc   edi
  204.         sub   edi, ecx
  205.         dec   edx
  206.         jnz   .new_y
  207. .ret:
  208.  popad
  209.  ret
  210.   .read_byte:
  211.    ;eax - address
  212.    ;esi - slot
  213.         push  eax
  214.         push  ebx
  215.         push  ecx
  216.         push  edx
  217.         mov   edx,eax
  218.         mov   eax,esi
  219.         lea   ebx,[esp+12]
  220.         mov   ecx,1
  221.         call  read_process_memory
  222.         pop   edx
  223.         pop   ecx
  224.         pop   ebx
  225.         pop   eax
  226.         ret
  227.   .free_form:
  228.  
  229.         ;  for (y=0; y <= x_size; y++)
  230.         ;      for (x=0; x <= x_size; x++)
  231.         ;          if (shape[coord(x,y,scale)]==1)
  232.         ;             set_pixel(x, y, process_number);
  233.  
  234.         sub  ecx, eax
  235.         sub  edx, ebx
  236.         inc  ecx
  237.         inc  edx
  238.  
  239.         push  dword [edi+APPDATA.wnd_shape_scale]  ; push scale first -> for loop
  240.  
  241.         ; get WinMap start  -> ebp
  242.         push  eax
  243.         mov   eax, [ScreenWidth] ; screen_sx
  244.         inc   eax
  245.         imul  eax, ebx
  246.         add   eax, [esp]
  247.         add   eax, WinMapAddress
  248.         mov   ebp, eax
  249.  
  250.         mov   edi, [edi+APPDATA.wnd_shape]
  251.         pop   eax
  252.  
  253.         ; eax = x_start
  254.         ; ebx = y_start
  255.         ; ecx = x_size
  256.         ; edx = y_size
  257.         ; esi = process_number
  258.         ; edi = &shape
  259.         ;       [scale]
  260.         push edx ecx ; for loop - x,y size
  261.  
  262.         mov  ecx, esi
  263.         shl  ecx, 5
  264.         mov  edx, [window_data+ecx+WDATA.box.top]
  265.         push [window_data+ecx+WDATA.box.width]      ; for loop - width
  266.         mov  ecx, [window_data+ecx+WDATA.box.left]
  267.         sub  ebx, edx
  268.         sub  eax, ecx
  269.         push ebx eax ; for loop - x,y
  270.  
  271.         add  [ff_xsz], eax
  272.         add  [ff_ysz], ebx
  273.  
  274.         mov  ebx, [ff_y]
  275.  
  276.       .ff_new_y:
  277.         mov  edx, [ff_x]
  278.  
  279.       .ff_new_x:
  280.         ; -- body --
  281.         mov  ecx, [ff_scale]
  282.         mov  eax, [ff_width]
  283.         inc  eax
  284.         shr  eax, cl
  285.         push ebx edx
  286.         shr  ebx, cl
  287.         shr  edx, cl
  288.         imul eax, ebx
  289.         add  eax, edx
  290.         pop  edx ebx
  291.         add  eax, edi
  292.         call .read_byte
  293.         test al,al
  294.         jz   @f
  295.         mov  eax, esi
  296.         mov  [ebp], al
  297.        @@:
  298.         ; -- end body --
  299.         inc  ebp
  300.         inc  edx
  301.         cmp  edx, [ff_xsz]
  302.         jb   .ff_new_x
  303.         sub  ebp, [ff_xsz]
  304.         add  ebp, [ff_x]
  305.         add  ebp, [ScreenWidth]  ; screen.x
  306.         inc  ebp
  307.         inc  ebx
  308.         cmp  ebx, [ff_ysz]
  309.         jb   .ff_new_y
  310.  
  311.         add  esp, 24
  312. popad
  313. ret
  314.  
  315.  
  316. display_settings:
  317.  
  318. ;    eax = 0         ; DISPLAY redraw
  319. ;          ebx = 0   ; all
  320. ;
  321. ;    eax = 1         ; BUTTON type
  322. ;          ebx = 0   ; flat
  323. ;          ebx = 1   ; 3D
  324. ;    eax = 2         ; set WINDOW colours
  325. ;          ebx = pointer to table
  326. ;          ecx = number of bytes define
  327. ;    eax = 3         ; get WINDOW colours
  328. ;          ebx = pointer to table
  329. ;          ecx = number of bytes wanted
  330. ;    eax = 4         ; get skin height
  331. ;          input  : nothing
  332. ;          output : eax = skin height in pixel
  333. ;    eax = 5         ; get screen workarea
  334. ;          input  : nothing
  335. ;          output : eax = [left]*65536+[right]
  336. ;                   ebx = [top]*65536+[bottom]
  337. ;    eax = 6         ; set screen workarea
  338. ;          input  : ecx = [left]*65536+[right]
  339. ;                   edx = [top]*65536+[bottom]
  340. ;          output : nothing
  341. ;    eax = 7         ; get skin margins
  342. ;          input  : nothing
  343. ;          output : eax = [left]*65536+[right]
  344. ;                   ebx = [top]*65536+[bottom]
  345. ;    eax = 8         ; set window skin
  346. ;          input  : ecx = pointer to file info block
  347. ;          output : eax = FS error code
  348.  
  349.  
  350.      pushad
  351.  
  352.      test eax, eax      ; redraw display
  353.      jnz  dspl0
  354.      test ebx, ebx
  355.      jnz  dspl0
  356.      cmp  [windowtypechanged],dword 1
  357.      jne  dspl00
  358.      mov  [windowtypechanged],dword 0
  359.   redraw_screen_direct:
  360.      mov  [dlx],dword 0
  361.      mov  [dly],dword 0
  362.      mov  eax,[ScreenWidth]
  363.      mov  [dlxe],eax
  364.      mov  eax,[ScreenHeight]
  365.      mov  [dlye],eax
  366.      mov  eax,window_data
  367.      call redrawscreen
  368.    dspl00:
  369.      popad
  370.      ret
  371.    dspl0:
  372.  
  373.      cmp  eax,1       ; button type
  374.      jne  dspl1
  375.      and  ebx,1
  376.      cmp  ebx,[buttontype]
  377.      je   dspl9
  378.      mov  [buttontype],ebx
  379.      mov  [windowtypechanged],dword 1
  380.     dspl9:
  381.      popad
  382.      ret
  383.    dspl1:
  384.  
  385.      cmp  eax,2       ; set common window colours
  386.      jne  no_com_colours
  387.      mov  [windowtypechanged],dword 1
  388.      mov  esi,[TASK_BASE]
  389.      add  esi,TASKDATA.mem_start
  390.      add  ebx,[esi]
  391.      mov  esi,ebx
  392.      mov  edi,common_colours
  393.      and  ecx,127
  394.      cld
  395.      rep  movsb
  396.      popad
  397.      ret
  398.    no_com_colours:
  399.  
  400.      cmp  eax,3       ; get common window colours
  401.      jne  no_get_com
  402.      mov  esi,[TASK_BASE]
  403.      add  esi,TASKDATA.mem_start
  404.      add  ebx,[esi]
  405.      mov  edi,ebx
  406.      mov  esi,common_colours
  407.      and  ecx,127
  408.      cld
  409.      rep  movsb
  410.      popad
  411.      ret
  412.    no_get_com:
  413.  
  414.      cmp  eax,4       ; get skin height
  415.      jne  no_skin_height
  416.      popad
  417.      mov  eax,[_skinh]
  418.      mov  [esp+36],eax
  419.      ret
  420.    no_skin_height:
  421.  
  422.         cmp     eax,5       ; get screen workarea
  423.         jne     no_get_workarea
  424.         popad
  425.         mov     eax,[screen_workarea.left-2]
  426.         mov     ax,word[screen_workarea.right]
  427.         mov     [esp+36],eax
  428.         mov     eax,[screen_workarea.top-2]
  429.         mov     ax,word[screen_workarea.bottom]
  430.         mov     [esp+24],eax
  431.         ret
  432.    no_get_workarea:
  433.  
  434.         cmp     eax,6       ; set screen workarea
  435.         jne     no_set_workarea
  436.         movsx   eax,word[esp+16+2]
  437.         movsx   ebx,word[esp+16]
  438.         cmp     eax,ebx
  439.         jge     .lp1
  440.         or      eax,eax;[ScreenWidth]
  441.         jl      @f
  442.         mov     [screen_workarea.left],eax
  443.     @@: cmp     ebx,[ScreenWidth]
  444.         jg      .lp1
  445.         mov     [screen_workarea.right],ebx
  446.   .lp1: movsx   eax,word[esp+24+2]
  447.         movsx   ebx,word[esp+24]
  448.         cmp     eax,ebx
  449.         jge     .lp2
  450.         or      eax,eax;[0xFE04]
  451.         jl      @f
  452.         mov     [screen_workarea.top],eax
  453.     @@: cmp     ebx,[ScreenHeight]
  454.         jg      .lp2
  455.         mov     [screen_workarea.bottom],ebx
  456.   .lp2: call    repos_windows
  457.         mov     eax, 0
  458.         mov     ebx, 0
  459.         mov     ecx, [ScreenWidth]
  460.         mov     edx, [ScreenHeight]
  461.     call    calculatescreen
  462. ;    jmp    redraw_screen_direct
  463.     .exit:
  464.         popad
  465.         ret
  466.    no_set_workarea:
  467.  
  468.         cmp     eax,7       ; get skin margins
  469.         jne     no_get_skinmargins
  470.         popad
  471.         mov     eax,dword[_skinmargins+0]
  472.         mov     [esp+36],eax
  473.         mov     eax,dword[_skinmargins+4]
  474.         mov     [esp+24],eax
  475.         ret
  476.    no_get_skinmargins:
  477.  
  478.         cmp     eax,8       ; set window skin
  479.         jne     no_set_skin
  480.         call    read_skin_file
  481.         mov     [esp+32+36], eax
  482.         test    eax, eax
  483.         jnz     .ret
  484.         xor     eax, eax
  485.         xor     ebx, ebx
  486.         mov     ecx, [ScreenWidth]
  487.         mov     edx, [ScreenHeight]
  488.         call    calculatescreen
  489.         jmp     redraw_screen_direct
  490. .ret:
  491.         popad
  492.         ret
  493.    no_set_skin:
  494.  
  495.      popad
  496.      ret
  497.  
  498.  
  499. repos_windows:
  500.         mov     ecx,[TASK_COUNT]
  501.         mov     edi, OS_BASE+0x20*2
  502.         call    force_redraw_background
  503.         dec     ecx
  504.         jge    @f
  505.         ret
  506.     @@: mov     [edi+WDATA.fl_redraw],1
  507.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  508.         jz      .lp2
  509.         mov     eax,[screen_workarea.left]
  510.         mov     [edi+WDATA.box.left],eax
  511.         sub     eax,[screen_workarea.right]
  512.         neg     eax
  513.         mov     [edi+WDATA.box.width],eax
  514.         mov     eax,[screen_workarea.top]
  515.         mov     [edi+WDATA.box.top],eax
  516.         test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  517.         jnz     .lp1
  518.         sub     eax,[screen_workarea.bottom]
  519.         neg     eax
  520.         mov     [edi+WDATA.box.height],eax
  521.   .lp1:
  522.  
  523.         call    set_window_clientbox
  524.         add     edi,0x20
  525.         loop    @b
  526.         ret
  527.   .lp2: mov     eax,[edi+WDATA.box.left]
  528.         add     eax,[edi+WDATA.box.width]
  529.     mov    ebx,[ScreenWidth]
  530. ;    inc    ebx
  531.     cmp    eax,ebx
  532.     jle    .lp4
  533.         mov     eax,[edi+WDATA.box.width]
  534.     sub    eax,ebx
  535.     jle    .lp3
  536.         mov     [edi+WDATA.box.width],ebx
  537.   .lp3: sub     ebx,[edi+WDATA.box.width]
  538.         mov     [edi+WDATA.box.left],ebx
  539.   .lp4: mov     eax,[edi+WDATA.box.top]
  540.         add     eax,[edi+WDATA.box.height]
  541.     mov    ebx,[ScreenHeight]
  542. ;    inc    ebx
  543.     cmp    eax,ebx
  544.     jle    .lp6
  545.         mov     eax,[edi+WDATA.box.height]
  546.     sub    eax,ebx
  547.     jle    .lp5
  548.         mov     [edi+WDATA.box.height],ebx
  549.   .lp5: sub     ebx,[edi+WDATA.box.height]
  550.         mov     [edi+WDATA.box.top],ebx
  551.   .lp6: jmp     .lp1
  552.  
  553. uglobal
  554.   common_colours:
  555.      times 128 db 0x0
  556. endg
  557.  
  558.  
  559.  
  560.  
  561. check_window_position:
  562.  
  563.     pushad                           ; window inside screen ?
  564.  
  565.     movzx eax,word [edi+WDATA.box.left]
  566.     movzx ebx,word [edi+WDATA.box.top]
  567.     movzx ecx,word [edi+WDATA.box.width]
  568.     movzx edx,word [edi+WDATA.box.height]
  569.  
  570.     mov   esi,ecx             ; check x pos
  571.     add   esi,eax
  572.     cmp   esi,[ScreenWidth]
  573.     jbe   x_pos_ok
  574.     mov   [edi+WDATA.box.left],dword 0
  575.     xor   eax, eax
  576.   x_pos_ok:
  577.  
  578.     mov   esi,edx             ; check y pos
  579.     add   esi,ebx
  580.     cmp   esi,[ScreenHeight]
  581.     jbe   y_pos_ok
  582.     mov   [edi+WDATA.box.top],dword 0
  583.     mov   ebx,0
  584.   y_pos_ok:
  585.  
  586.     mov   esi,ecx             ; check x size
  587.     add   esi,eax
  588.     cmp   esi,[ScreenWidth]
  589.     jbe   x_size_ok
  590.     mov   ecx,[ScreenWidth]
  591.     mov   [edi+WDATA.box.width],ecx
  592.   x_size_ok:
  593.  
  594.     mov   esi,edx             ; check y size
  595.     add   esi,ebx
  596.     cmp   esi,[ScreenHeight]
  597.     jbe   y_size_ok
  598.     mov   edx,[ScreenHeight]
  599.     mov   [edi+WDATA.box.height],edx
  600.   y_size_ok:
  601.  
  602.     popad
  603.  
  604.     ret
  605.  
  606.  
  607. uglobal
  608.   new_window_starting dd 0
  609. endg
  610.  
  611.  
  612. sys_window_mouse:
  613.  
  614.     push  eax
  615.  
  616.     mov   eax,[timer_ticks]
  617.     cmp   [new_window_starting],eax
  618.     jb    swml1
  619.  
  620.     mov   [MOUSE_BACKGROUND],byte 0  ; no mouse background
  621.     mov   [DONT_DRAW_MOUSE],byte 0  ; draw mouse
  622.  
  623.     mov   [new_window_starting],eax
  624.  
  625.   swml1:
  626.  
  627.     pop   eax
  628.  
  629.     ret
  630.  
  631.  
  632.  
  633.  
  634. drawwindow_I_caption:
  635.  
  636.         mov   ecx,[edx+WDATA.cl_titlebar]   ; grab bar
  637.         push  ecx
  638.         mov   esi,edx
  639.         mov   edx,[esi+WDATA.box.top]
  640.         add   edx,1
  641.         mov   ebx,[esi+WDATA.box.top]
  642.         add   ebx,21
  643.         mov   eax,[esi+WDATA.box.top]
  644.         add   eax,[esi+WDATA.box.height]
  645.         cmp   ebx,eax
  646.         jb    .wdsizeok
  647.         mov   ebx,eax
  648.   .wdsizeok:
  649.         push  ebx
  650.   .drwi:
  651.         mov   ebx,edx
  652.         shl   ebx,16
  653.         add   ebx,edx
  654.         mov   eax,[esi+WDATA.box.left]
  655.         inc   eax
  656.         shl   eax,16
  657.         add   eax,[esi+WDATA.box.left]
  658.         add   eax,[esi+WDATA.box.width]
  659.         sub   eax,1
  660.         push  edx
  661.         mov   edx,0x80000000
  662.         mov   ecx,[esi+WDATA.cl_titlebar]
  663.         and   ecx,edx
  664.         cmp   ecx,edx
  665.         jnz   .nofa
  666.         mov   ecx,[esi+WDATA.cl_titlebar]
  667.         sub   ecx,0x00040404
  668.         mov   [esi+WDATA.cl_titlebar],ecx
  669.         and   ecx,0x00ffffff
  670.         jmp   .faj
  671.   .nofa:
  672.         mov   ecx,[esi+WDATA.cl_titlebar]
  673.         and   ecx,0x00ffffff
  674.   .faj:
  675.         pop   edx
  676.         mov   edi,0
  677.         call  [draw_line]
  678.         inc   edx
  679.         cmp   edx,[esp]
  680.         jb    .drwi
  681.         add   esp,4
  682.         pop   ecx
  683.         mov   [esi+WDATA.cl_titlebar],ecx
  684.  
  685.         ret
  686.  
  687.  
  688. drawwindow_I:
  689.  
  690.         pushad
  691.         or      [edx+WDATA.fl_wdrawn], 4
  692.  
  693.         mov   esi,[edx+WDATA.cl_frames]   ; rectangle
  694.         mov   eax,[edx+WDATA.box.left]
  695.         shl   eax,16
  696.         add   eax,[edx+WDATA.box.left]
  697.         add   eax,[edx+WDATA.box.width]
  698.         mov   ebx,[edx+WDATA.box.top]
  699.         shl   ebx,16
  700.         add   ebx,[edx+WDATA.box.top]
  701.         add   ebx,[edx+WDATA.box.height]
  702.         call  draw_rectangle
  703.  
  704.         and     [edx+WDATA.fl_wdrawn], not 4
  705.         test    [edx+WDATA.fl_wdrawn], 2
  706.         jz      @f
  707.         call    drawwindowframes2
  708. @@:
  709.  
  710.         call    drawwindow_I_caption
  711.  
  712.         mov   edx,[esi+WDATA.box.top]      ; inside work area
  713.         add   edx,21+5
  714.         mov   ebx,[esi+WDATA.box.top]
  715.         add   ebx,[esi+WDATA.box.height]
  716.         cmp   edx,ebx
  717.         jg    noinside
  718.         mov   eax,1
  719.         mov   ebx,21
  720.         mov   ecx,[esi+WDATA.box.width]
  721.         mov   edx,[esi+WDATA.box.height]
  722.         mov   edi,[esi+WDATA.cl_workarea]
  723.         test  edi,0x40000000
  724.         jnz   noinside
  725.         call  [drawbar]
  726.       noinside:
  727.  
  728.         popad
  729.  
  730.         ret
  731.  
  732.  
  733. draw_rectangle:
  734.  
  735. r_eax equ [esp+28]   ; x start
  736. r_ax  equ [esp+30]   ; x end
  737. r_ebx equ [esp+16]   ; y start
  738. r_bx  equ [esp+18]   ; y end
  739. ;esi                 ; color
  740.  
  741.         pushad
  742.  
  743.         mov   ecx,esi          ; yb,xb -> yb,xe
  744.         mov   eax, r_eax
  745.         rol   eax, 16
  746.         mov   ebx,r_ebx
  747.         shl   ebx,16
  748.         mov   bx,r_ebx
  749.         xor   edi, edi
  750.         call  [draw_line]
  751.  
  752.         mov   ebx,r_bx         ; ye,xb -> ye,xe
  753.         shl   ebx,16
  754.         mov   bx,r_bx
  755.         call  [draw_line]
  756.  
  757.         mov   ecx,esi          ; ya,xa -> ye,xa
  758.         mov   eax,r_eax
  759.         shl   eax,16
  760.         mov   ax,r_eax
  761.         mov   ebx,r_ebx
  762.         shl   ebx,16
  763.         mov   bx,r_bx
  764.         mov   edi,0
  765.         call  [draw_line]
  766.  
  767.         mov   eax,r_ax       ; ya,xe -> ye,xe
  768.         shl   eax,16
  769.         mov   ax,r_ax
  770.         call  [draw_line]
  771.  
  772.         popad
  773.         ret
  774.  
  775.  
  776. drawwindow_III_caption:
  777.  
  778.         mov   ecx,[edx+WDATA.cl_titlebar]                       ; GRAB BAR
  779.         push  ecx
  780.         mov   esi,edx
  781.         mov   edx,[esi+WDATA.box.top]
  782.         add   edx,4
  783.         mov   ebx,[esi+WDATA.box.top]
  784.         add   ebx,20
  785.         mov   eax,[esi+WDATA.box.top]
  786.         add   eax,[esi+WDATA.box.height]
  787.         cmp   ebx,eax
  788.         jb    .wdsizeok
  789.         mov   ebx,eax
  790.   .wdsizeok:
  791.         push  ebx
  792.   .drwi:
  793.         mov   ebx,edx
  794.         shl   ebx,16
  795.         add   ebx,edx
  796.         mov   eax,[esi+WDATA.box.left]
  797.         shl   eax,16
  798.         add   eax,[esi+WDATA.box.left]
  799.         add   eax,[esi+WDATA.box.width]
  800.         add   eax,4*65536-4
  801.         mov   ecx,[esi+WDATA.cl_titlebar]
  802.         test  ecx,0x40000000
  803.         jz    .nofa
  804.         add   ecx,0x040404
  805.   .nofa:
  806.         test  ecx,0x80000000
  807.         jz    .nofa2
  808.         sub   ecx,0x040404
  809.   .nofa2:
  810.         mov   [esi+WDATA.cl_titlebar],ecx
  811.         and   ecx,0xffffff
  812.         xor   edi, edi
  813.         call  [draw_line]
  814.         inc   edx
  815.         cmp   edx,[esp]
  816.         jb    .drwi
  817.         add   esp,4
  818.         pop   ecx
  819.         mov   [esi+WDATA.cl_titlebar],ecx
  820.  
  821.         ret
  822.  
  823.  
  824. drawwindow_III:
  825.  
  826.         pushad
  827.  
  828.         mov   edi,edx                              ; RECTANGLE
  829.         mov   eax,[edi+WDATA.box.left]
  830.         shl   eax,16
  831.     mov   ax, word [edi+WDATA.box.left]
  832.     add   ax, word [edi+WDATA.box.width]
  833.         mov   ebx,[edi+WDATA.box.top]
  834.         shl   ebx,16
  835.     mov   bx, word [edi+WDATA.box.top]
  836.     add   bx, word [edi+WDATA.box.height]
  837.         mov   esi,[edi+WDATA.cl_frames]
  838.         shr   esi,1
  839.         and   esi,0x007f7f7f
  840.         push  esi
  841.         or      [edi+WDATA.fl_wdrawn], 4
  842.         call  draw_rectangle
  843.         and     [edi+WDATA.fl_wdrawn], not 4
  844.         test    [edi+WDATA.fl_wdrawn], 2
  845.         jz      @f
  846.         call    drawwindowframes2
  847. @@:
  848.         mov   ecx,3
  849.       dw3l:
  850.         add   eax,1*65536-1
  851.         add   ebx,1*65536-1
  852.         mov   esi,[edi+WDATA.cl_frames]
  853.         call  draw_rectangle
  854.         dec   ecx
  855.         jnz   dw3l
  856.         pop   esi
  857.         add   eax,1*65536-1
  858.         add   ebx,1*65536-1
  859.         call  draw_rectangle
  860.  
  861.         call    drawwindow_III_caption
  862.  
  863.         mov   edx,[esi+WDATA.box.top]                       ; WORK AREA
  864.         add   edx,21+5
  865.         mov   ebx,[esi+WDATA.box.top]
  866.         add   ebx,[esi+WDATA.box.height]
  867.         cmp   edx,ebx
  868.         jg    noinside2
  869.         mov   eax,5
  870.         mov   ebx,20
  871.         mov   ecx,[esi+WDATA.box.width]
  872.         mov   edx,[esi+WDATA.box.height]
  873.         sub   ecx,4
  874.         sub   edx,4
  875.         mov   edi,[esi+WDATA.cl_workarea]
  876.         test  edi,0x40000000
  877.         jnz   noinside2
  878.         call  [drawbar]
  879.       noinside2:
  880.  
  881.         popad
  882.  
  883.         ret
  884.  
  885.  
  886.  
  887. ; activate window
  888. align 4
  889. windowactivate:
  890.  
  891.         ; esi = abs mem position in stack 0xC400+
  892.  
  893.         pushad
  894.  
  895.      ; if type of current active window is 3,
  896.      ; it must be redrawn
  897.         mov   eax, [TASK_COUNT]
  898.         movzx eax, word [WIN_POS + eax*2]
  899.         shl   eax, 5
  900.         add   eax, window_data
  901.         mov   ebx, [eax + WDATA.cl_workarea]
  902.         and   ebx, 0x0f000000
  903.         cmp   ebx, 0x03000000
  904.         je   .set_WDATA_fl_redraw   ; for 3 and 4 style
  905.         cmp   ebx, 0x04000000
  906.         je   .set_WDATA_fl_redraw
  907.         jmp @f
  908.         .set_WDATA_fl_redraw:
  909.         mov   [eax + WDATA.fl_redraw], byte 1
  910.      @@:
  911.  
  912.         push   esi
  913.       movzx   eax, word [esi] ; ax <- process no
  914.       movzx   eax, word [WIN_STACK+eax*2] ; ax <- position in window stack
  915.  
  916.         xor   esi, esi        ; drop others
  917.       waloop:
  918.         cmp   esi, dword [TASK_COUNT]
  919.         jae   wacont
  920.         inc   esi
  921.         lea   edi, [WIN_STACK + esi*2]
  922.         mov   bx, [edi] ; position of the current process
  923.         cmp   bx, ax
  924.         jbe   @f
  925.         dec   bx       ; upper? => drop!
  926.         mov   [edi], bx
  927.       @@:
  928.         jmp   waloop
  929.       wacont:
  930.                             ; set to no 1
  931.         pop   esi           ;   esi = pointer at 0xC400
  932.  
  933.       movzx   eax, word [esi]
  934.         mov   bx, [TASK_COUNT]  ; number of processes
  935.         mov   [WIN_STACK+eax*2], bx     ; this is the last (and the upper)
  936.  
  937.         ; update on screen -window stack
  938.         xor   esi, esi
  939.       waloop2:
  940.         mov   edi, [TASK_COUNT]
  941.         cmp   esi, edi
  942.         jae   wacont2
  943.         inc   esi
  944.         movzx ebx, word [esi*2 + WIN_STACK]
  945.         mov   [ebx*2 + WIN_POS], si
  946.         jmp   waloop2
  947.       wacont2:
  948.         mov   [KEY_COUNT], byte 0             ; empty keyboard buffer
  949.         mov   [BTN_COUNT], byte 0             ; empty button buffer
  950.         mov   [MOUSE_SCROLL_H], word 0  ; zero mouse z-index
  951.         mov   [MOUSE_SCROLL_V], word 0  ; zero mouse z-index
  952.         popad
  953.         ret
  954.  
  955.  
  956. ; check if window is necessary to draw
  957.  
  958. checkwindowdraw:
  959.  
  960.         ; edi = position in window_data+
  961.  
  962.         mov   eax, [edi + WDATA.cl_workarea]
  963.         and   eax, 0x0f000000
  964.         cmp   eax, 0x03000000
  965.         je    .return_yes      ; window type 3
  966.         cmp   eax, 0x04000000
  967.         je    .return_yes      ; window type 4
  968.  
  969.         mov   esi, edi
  970.         sub   esi, window_data
  971.         shr   esi, 5
  972.  
  973.         ; esi = process number
  974.  
  975.         movzx eax, word [WIN_STACK + esi * 2] ; get value of the curr process
  976.         lea   esi, [WIN_POS + eax * 2]      ; get address of this process at 0xC400
  977.  
  978.         push  esi
  979.  
  980.       .new_check:
  981.  
  982.         pop   esi
  983.         add   esi, 2
  984.         push  esi
  985.  
  986.         mov   eax, [TASK_COUNT]
  987.         lea   eax, word [WIN_POS + eax * 2] ; number of the upper window
  988.  
  989.         cmp   esi, eax
  990.         ja    .all_wnds_to_top
  991.  
  992.         movzx eax, word [esi]
  993.         shl   eax, 5
  994.         cmp   [CURRENT_TASK + eax + TASKDATA.state], byte 9
  995.         je    .new_check                    ; skip dead windows
  996.  
  997.         lea   esi, [eax+window_data]
  998.  
  999.         mov   ebx, [edi+WDATA.box.top]  ; y0
  1000.         mov   edx, [edi+WDATA.box.height]
  1001.         add   edx, ebx      ; y0e
  1002.  
  1003.         mov   ecx, [esi+WDATA.box.top]  ; y  ; y check
  1004.         cmp   ecx, edx
  1005.         jae   .new_check     ; y < y0e
  1006.         mov   eax, [esi+WDATA.box.height]
  1007.         add   ecx, eax       ; ye
  1008.         cmp   ebx, ecx       ; y0 >= ye
  1009.         ja    .new_check
  1010.  
  1011.         mov   eax, [edi+WDATA.box.left]   ; x0
  1012.         mov   ecx, [edi+WDATA.box.width]
  1013.         add   ecx, eax       ; x0e
  1014.  
  1015.         mov   edx, [esi+WDATA.box.left]   ; x ; x check
  1016.         cmp   edx, ecx
  1017.         jae   .new_check     ; x < x0e
  1018.         mov   ecx, [esi+WDATA.box.width]
  1019.         add   edx, ecx
  1020.         cmp   eax, edx
  1021.         ja    .new_check
  1022.  
  1023.         pop   esi
  1024.   .return_yes:
  1025.         mov   ecx,1   ; overlap some window
  1026.         ret
  1027.  
  1028.   .all_wnds_to_top:
  1029.  
  1030.         pop   esi
  1031.  
  1032.         xor   ecx, ecx       ; passed all windows to top
  1033.         ret
  1034.  
  1035.  
  1036.  
  1037.  
  1038. waredraw:     ; if redraw necessary at activate
  1039.  
  1040.         pushad
  1041.  
  1042.         call  checkwindowdraw      ; draw window on activation ?
  1043.         test  ecx, ecx
  1044.         jz    .do_not_draw
  1045.  
  1046.         popad
  1047.         mov   [MOUSE_DOWN], byte 1     ; do draw mouse
  1048.         call  windowactivate
  1049.  
  1050.         ; update screen info
  1051.         pushad
  1052.         mov   edi, [TASK_COUNT] ; the last process (number)
  1053.         movzx esi, word [WIN_POS + edi * 2]
  1054.         shl   esi, 5
  1055.         add   esi, window_data
  1056.  
  1057.         ; coordinates of the upper window
  1058.     mov   eax, [esi + WDATA.box.left]   ; cx
  1059.     mov   ebx, [esi + WDATA.box.top]    ; cy
  1060.     mov   ecx, [esi + WDATA.box.width]  ; sx
  1061.     mov   edx, [esi + WDATA.box.height] ; sy
  1062.  
  1063.         add   ecx, eax       ; ecx = x_end
  1064.         add   edx, ebx       ; edx = y_end
  1065.  
  1066.         mov   edi, [TASK_COUNT]
  1067.         movzx esi, word [WIN_POS + edi * 2]
  1068.         call  setscreen
  1069.         popad
  1070.  
  1071.     mov   [edi + WDATA.fl_redraw], 1  ; redraw flag for app
  1072.     mov   [MOUSE_DOWN],byte 0             ; mouse down checks
  1073.  
  1074.         ret
  1075.  
  1076.      .do_not_draw:
  1077.  
  1078.         popad
  1079.  
  1080.         call  windowactivate
  1081.         mov   [MOUSE_DOWN],byte 0  ; mouse down checks
  1082.         mov   [MOUSE_BACKGROUND],byte 0  ; no mouse background
  1083.         mov   [DONT_DRAW_MOUSE],byte 0  ; draw mouse
  1084.         ret
  1085.  
  1086.  
  1087. ; eax = window number on screen
  1088. ; corrupts registers and [dl*]
  1089. minimize_window:
  1090.         movzx eax, word [WIN_POS+eax*2]
  1091.         shl   eax, 5
  1092.         add   eax, window_data
  1093.         test  [eax+WDATA.fl_wstate], WSTATE_MINIMIZED
  1094.         jnz   .skip_redrawings
  1095.         pushfd
  1096.         cli
  1097.         or    [eax+WDATA.fl_wstate], WSTATE_MINIMIZED
  1098.         mov   edi, eax
  1099.         ;call  calculatescreen
  1100.         mov   eax, [edi+WDATA.box.left]
  1101.         mov   [dlx], eax
  1102.         mov   ecx, eax
  1103.         add   ecx, [edi+WDATA.box.width]
  1104.         mov   [dlxe], ecx
  1105.         mov   ebx, [edi+WDATA.box.top]
  1106.         mov   [dly], ebx
  1107.         mov   edx, ebx
  1108.         add   edx, [edi+WDATA.box.height]
  1109.         mov   [dlye], edx
  1110.         call  calculatescreen
  1111.         xor   esi, esi
  1112.         xor   eax, eax
  1113.         call  redrawscreen
  1114.         popfd
  1115. .skip_redrawings:
  1116.         ret
  1117.  
  1118. ; eax = window number on screen
  1119. ; corrupts registers and [dl*]
  1120. restore_minimized_window:
  1121.         pushfd
  1122.         cli
  1123.         movzx esi, word [WIN_POS+eax*2]
  1124.         mov   edi, esi
  1125.         shl   edi, 5
  1126.         add   edi, window_data
  1127.         test  [edi+WDATA.fl_wstate], WSTATE_MINIMIZED
  1128.         jz    .skip_redrawings
  1129.         mov   [edi+WDATA.fl_redraw], 1
  1130.         and   [edi+WDATA.fl_wstate], not WSTATE_MINIMIZED
  1131.         cmp   eax, [TASK_COUNT] ; the uppermost window
  1132.         jnz   .no_uppermost
  1133.         mov   eax, [edi+WDATA.box.left]
  1134.         mov   ebx, [edi+WDATA.box.top]
  1135.         mov   ecx, eax
  1136.         mov   edx, ebx
  1137.         add   ecx, [edi+WDATA.box.width]
  1138.         add   edx, [edi+WDATA.box.height]
  1139.         call  setscreen
  1140.         jmp   .done
  1141. .no_uppermost:
  1142.         mov   eax, [edi+WDATA.box.left]
  1143.         mov   ebx, [edi+WDATA.box.top]
  1144.         mov   ecx, eax
  1145.         mov   edx, ebx
  1146.         add   ecx, [edi+WDATA.box.width]
  1147.         add   edx, [edi+WDATA.box.height]
  1148.         call  calculatescreen
  1149. .done:
  1150.         mov   [MOUSE_BACKGROUND],byte 0 ; no mouse under
  1151. .skip_redrawings:
  1152.         popfd
  1153.         ret
  1154.  
  1155.  
  1156. iglobal
  1157.   window_moving   db 'K : Window - move/resize',13,10,0
  1158.   window_moved    db 'K : Window - done',13,10,0
  1159. endg
  1160.  
  1161. ; check window touch
  1162. align 4
  1163. checkwindows:
  1164.         pushad
  1165.  
  1166.         cmp   [window_minimize], 0
  1167.         je    .no_minimizing
  1168.         mov   eax, [TASK_COUNT]       ; the uppermost window
  1169.         mov   bl, 0
  1170.         xchg  [window_minimize], bl
  1171.         cmp   bl, 1
  1172.         jne   .restore
  1173.         call  minimize_window
  1174.         jmp   .continue
  1175.   .restore:
  1176.         call  restore_minimized_window
  1177.   .continue:
  1178.   .no_minimizing:
  1179.  
  1180.         cmp   [BTN_DOWN],byte 0    ; mouse buttons pressed ?
  1181.         jne  .mouse_buttons_pressed
  1182. ;..................................... start 1/4 : modified by vhanla .................
  1183.         mov [bPressedMouseXY_W],0
  1184. ;..................................... end 1/4 : modified by vhanla ...................
  1185.         popad
  1186.         ret
  1187.     .mouse_buttons_pressed:
  1188. ;..................................... start 2/4 : modified by vhanla .................
  1189.         jmp @f
  1190.         bPressedMouseXY_W db 0x0
  1191.         @@:
  1192. ;..................................... end 2/4 : modified by vhanla ...................
  1193.         mov   esi,[TASK_COUNT]
  1194.         inc   esi
  1195.  
  1196. ;..................................... start 3/4 : modified by vhanla .................
  1197.         push ax
  1198.         cmp [bPressedMouseXY_W],0
  1199.         jnz @f
  1200.         mov [bPressedMouseXY_W],1
  1201.         mov ax,[MOUSE_X]
  1202.         mov [mx],ax
  1203.         mov ax,[MOUSE_Y]
  1204.         mov [my],ax
  1205.         @@:
  1206.         pop ax
  1207. ;..................................... end 3/4 : modified by vhanla ...................
  1208.  
  1209.       cwloop:
  1210.         cmp   esi,2
  1211.         jb   .exit
  1212.  
  1213.         dec   esi
  1214.         movzx edi, word [WIN_POS + esi * 2] ; ebx
  1215.         shl   edi, 5
  1216.         add   edi, window_data
  1217. ;        mov   edi, ebx
  1218.     mov   ecx, [edi + WDATA.box.left]
  1219.     mov   edx, [edi + WDATA.box.top]
  1220.  
  1221.         mov   eax,ecx
  1222.         mov   ebx,edx
  1223.         test    [edi+WDATA.fl_wstate],WSTATE_MINIMIZED
  1224.         jnz     cwloop
  1225.  
  1226. ;..................................... start 4/4 : modified by vhanla .................
  1227.        movzx  eax, word [mx]; movzx eax,word[MOUSE_X]
  1228.        movzx  ebx, word [my]; movzx ebx,word[MOUSE_Y]
  1229. ;..................................... endt 4/4 : modified by vhanla ..................
  1230.         cmp   ecx, eax
  1231.         jae   cwloop
  1232.         cmp   edx, ebx
  1233.         jae   cwloop
  1234.     add   ecx, [edi + WDATA.box.width]
  1235.     add   edx, [edi + WDATA.box.height]
  1236.         cmp   eax, ecx
  1237.         jae   cwloop
  1238.         cmp   ebx, edx
  1239.         jae   cwloop
  1240.  
  1241.         pushad
  1242.         mov   eax, esi
  1243.         mov   ebx, [TASK_COUNT]
  1244.         cmp   eax, ebx      ; is this window active?
  1245.         jz    .move_resize_window
  1246.  
  1247.         ; eax = position in windowing stack
  1248.         ; redraw must ?
  1249.         lea   esi, [WIN_POS + esi * 2]
  1250.         call  waredraw
  1251.         add   esp, 32
  1252.  
  1253.       .exit:
  1254.         popad
  1255.         ret
  1256.  
  1257.    .move_resize_window:    ; MOVE OR RESIZE WINDOW
  1258.         popad
  1259.  
  1260.         ; Check for user enabled fixed window
  1261.     mov   edx, [edi + WDATA.cl_titlebar]
  1262.         and   edx, 0x0f000000
  1263.         cmp   edx, 0x01000000
  1264.         jne   .window_move_enabled_for_user
  1265.         popad
  1266.         ret
  1267.       .window_move_enabled_for_user:
  1268.  
  1269.     test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1270.         jnz     .no_resize_2
  1271.  
  1272.         mov   [do_resize_from_corner],byte 0   ; resize for skinned window
  1273.     mov   edx, [edi + WDATA.cl_workarea]
  1274.         and   edx, 0x0f000000
  1275.         cmp   edx, 0x00000000                                           ;{test for resized}
  1276.         je    .no_resize_2
  1277.         cmp   edx, 0x01000000                                           ;{test for resized}
  1278.         je    .no_resize_2
  1279.         cmp   edx, 0x04000000                                           ;{test for resized}                                    
  1280.         je    .no_resize_2
  1281. ;       jb    .no_resize_2 ; not type 2 wnd
  1282.  
  1283.     mov   edx, [edi + WDATA.box.top]
  1284.     add   edx, [edi + WDATA.box.height]
  1285.         sub   edx, 6       ; edx = y_end - 6
  1286.         cmp   ebx, edx     ; ebx = mouse_y
  1287.         jb    .no_resize_2
  1288.         mov   [do_resize_from_corner],byte 1
  1289.         jmp   .continue
  1290.       .no_resize_2:
  1291.  
  1292.         push    eax
  1293.         call    get_titlebar_height
  1294.     add     eax,[edi + WDATA.box.top]
  1295.         cmp     ebx,eax
  1296.         pop     eax
  1297.         jae     .exit
  1298.  
  1299.      .continue:
  1300.  
  1301.         push  esi
  1302.         mov   esi, window_moving
  1303.         call  sys_msg_board_str
  1304.         pop   esi
  1305.  
  1306.         mov   ecx, [timer_ticks]     ; double-click ?
  1307.         mov   edx, ecx
  1308.         sub   edx, [latest_window_touch]
  1309.         mov   [latest_window_touch], ecx
  1310.         mov   [latest_window_touch_delta], edx
  1311.  
  1312.         mov   cl, [BTN_DOWN]     ; save for shade check
  1313.         mov   [do_resize], cl
  1314.      no_emulation_righ_button:
  1315.     mov   ecx, [edi + WDATA.box.left]
  1316.     mov   edx, [edi + WDATA.box.top]
  1317.  
  1318.         push  eax ecx edx
  1319.         mov   [dlx], ecx      ; save for drawlimits
  1320.         mov   [dly], edx
  1321.     mov   eax, [edi + WDATA.box.width]
  1322.         add   ecx, eax
  1323.     mov   eax, [edi + WDATA.box.height]
  1324.         add   edx, eax
  1325.         mov   [dlxe], ecx
  1326.         mov   [dlye], edx
  1327.         pop   edx ecx eax
  1328.  
  1329.         sub   eax, ecx
  1330.         sub   ebx, edx
  1331.  
  1332.         mov   esi, [MOUSE_X]
  1333.         mov   [WIN_TEMP_XY], esi
  1334.  
  1335.         pushad           ; wait for putimages to finish
  1336. ;        mov   ebx,5
  1337. ;        call  delay_hs
  1338.     mov   eax,[edi + WDATA.box.left]
  1339.         mov   [npx],eax
  1340.     mov   eax,[edi + WDATA.box.top]
  1341.         mov   [npy],eax
  1342.         popad
  1343.  
  1344.         push eax                  ; save old coordinates
  1345.     mov   ax, word [edi + WDATA.box.left]
  1346.         mov   word [oldc+BOX.left],ax
  1347.     mov   ax, word [edi + WDATA.box.top]
  1348.         mov   word [oldc+BOX.top],ax
  1349.     mov   ax, word [edi + WDATA.box.width]
  1350.         mov   word [oldc+BOX.width],ax
  1351.         mov   word [npxe],ax
  1352.     mov   ax, word [edi + WDATA.box.height]
  1353.         mov   word [oldc+BOX.height],ax
  1354.         mov   word [npye],ax
  1355.         pop eax
  1356.  
  1357.         call  drawwindowframes
  1358.  
  1359.         mov   [reposition],0
  1360.         mov   [MOUSE_DOWN],byte 1   ; no reaction to mouse up/down
  1361.  
  1362.         ; move window
  1363.  
  1364.       newchm:
  1365.  
  1366.         mov   [DONT_DRAW_MOUSE],byte 1
  1367.  
  1368.         call  checkidle
  1369.  
  1370.         call  checkVga_N13
  1371.  
  1372.         mov   [MOUSE_BACKGROUND],byte 0
  1373.  
  1374.         call  [draw_pointer]
  1375.  
  1376.         pushad
  1377.         call   stack_handler
  1378.         popad
  1379.  
  1380.         mov   esi,[WIN_TEMP_XY]
  1381.         cmp   esi,[MOUSE_X]
  1382.         je    cwb
  1383.  
  1384.         mov   cx,[MOUSE_X]
  1385.         mov   dx,[MOUSE_Y]
  1386.         sub   cx,ax
  1387.         sub   dx,bx
  1388.  
  1389.         push  ax
  1390.         push  bx
  1391.  
  1392.         call  drawwindowframes
  1393.  
  1394.         mov   ax,[ScreenWidth]
  1395.         mov   bx,[ScreenHeight]
  1396.  
  1397.         cmp   [do_resize_from_corner],1
  1398.         je    no_new_position
  1399.  
  1400.         mov   word [npx],word 0     ; x repos ?
  1401.         cmp   ax,cx
  1402.         jb    noreposx
  1403.         mov   [reposition],1
  1404.         sub   ax,word [npxe]
  1405.         mov   word [npx],ax
  1406.         cmp   ax,cx
  1407.         jb    noreposx
  1408.         mov   word [npx],cx
  1409.       noreposx:
  1410.  
  1411.         mov   word [npy],word 0     ; y repos ?
  1412.         cmp   bx,dx
  1413.         jb    noreposy
  1414.         mov   [reposition],1
  1415.         sub   bx,word [npye]
  1416.         mov   word [npy],bx
  1417.         cmp   bx,dx
  1418.         jb    noreposy
  1419.         mov   word [npy],dx
  1420.       noreposy:
  1421.  
  1422.       no_new_position:
  1423.  
  1424.         cmp   [do_resize_from_corner],0    ; resize from right corner
  1425.         je    norepos_size
  1426.         pushad
  1427.  
  1428.         mov   edx,edi
  1429.         sub   edx,window_data
  1430.         ;shr   edx,5
  1431.         ;shl   edx,8
  1432.         ;add   edx,0x80000                 ; process base at 0x80000+
  1433.     lea   edx, [SLOT_BASE + edx*8]
  1434.  
  1435.         movzx eax,word [MOUSE_X]
  1436.     cmp   eax,[edi + WDATA.box.left]
  1437.         jb    nnepx
  1438.     sub   eax,[edi + WDATA.box.left]
  1439.         cmp   eax,32 ; [edx+0x90+8]
  1440.         jge   nnepx2
  1441.         mov   eax,32 ; [edx+0x90+8]
  1442.       nnepx2:
  1443.         mov   [npxe],eax
  1444.       nnepx:
  1445.  
  1446.         call    get_rolledup_height
  1447.         mov     ebx,eax
  1448.         movzx eax,word [MOUSE_Y]
  1449.     cmp   eax,[edi + WDATA.box.top]
  1450.         jb    nnepy
  1451.     sub   eax,[edi + WDATA.box.top]
  1452.         cmp     eax,ebx ; [edx+0x90+12]
  1453.         jge     nnepy2
  1454.         mov     eax,ebx ; [edx+0x90+12]
  1455.       nnepy2:
  1456.         mov   [npye],eax
  1457.       nnepy:
  1458.  
  1459.         mov   [reposition],1
  1460.  
  1461.         popad
  1462.       norepos_size:
  1463.  
  1464.         pop   bx
  1465.         pop   ax
  1466.         call  drawwindowframes
  1467.  
  1468.         mov   esi,[MOUSE_X]
  1469.         mov   [WIN_TEMP_XY],esi
  1470.  
  1471.       cwb:
  1472.         cmp   [BTN_DOWN],byte 0
  1473.         jne   newchm
  1474.                                      ; new position done
  1475.         mov     [DONT_DRAW_MOUSE],byte 1
  1476.         mov     cl,0
  1477.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1478.         jnz     @f
  1479.         mov     cl,[reposition]
  1480.         call    drawwindowframes
  1481.  
  1482.         mov   eax,[npx]
  1483.     mov   [edi + WDATA.box.left],eax
  1484.         mov   eax,[npy]
  1485.     mov   [edi + WDATA.box.top],eax
  1486.         mov   eax,[npxe]
  1487.     mov   [edi + WDATA.box.width],eax
  1488.         mov   eax,[npye]
  1489.     mov   [edi + WDATA.box.height],eax
  1490.         call    set_window_clientbox
  1491.  
  1492.     @@: mov     [reposition],cl
  1493.  
  1494.         cmp   [reposition],1         ; save new position and size
  1495.         jne   no_bounds_save
  1496.         push  esi edi ecx
  1497.         mov   esi,edi
  1498.         mov   ecx,2
  1499.         test  [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP or WSTATE_MAXIMIZED
  1500.         jnz   @f
  1501.         add   ecx,2
  1502.     @@: sub   edi,window_data
  1503.         shr   edi,5
  1504.         shl   edi,8
  1505.         add   edi,SLOT_BASE+APPDATA.saved_box
  1506.         cld
  1507.         rep   movsd
  1508.         pop   ecx edi esi
  1509.       no_bounds_save:
  1510.  
  1511.         pushad                             ; WINDOW SHADE/FULLSCREEN
  1512.  
  1513.         ;{doule click not worked for 4 type window}
  1514.     mov   edx, [edi + WDATA.cl_workarea]
  1515.         and   edx, 0x0f000000
  1516.         cmp   edx, 0x00000000
  1517.         je    no_fullscreen_restore
  1518.         cmp   edx, 0x01000000
  1519.         je    no_fullscreen_restore
  1520.  
  1521.         cmp   [reposition],1
  1522.         je    no_window_sizing
  1523.         mov   edx,edi
  1524.         sub   edx,window_data
  1525.         shr   edx,5
  1526.         shl   edx,8
  1527.         add   edx,SLOT_BASE                 ; process base at 0x80000+
  1528.  
  1529.         cmp   [do_resize],2               ; window shade ?
  1530.         jne   no_window_shade
  1531.         mov   [reposition],1
  1532.  
  1533.         test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1534.         jnz     wnd_rolldown
  1535.   wnd_rollup:
  1536.         or      [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1537.         call    get_rolledup_height
  1538.         jmp     @f
  1539.   wnd_rolldown:
  1540.         and     [edi+WDATA.fl_wstate],not WSTATE_ROLLEDUP
  1541.     mov     eax,[edx + APPDATA.saved_box.height] ; 0x90+BOX.height
  1542.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1543.         jz      @f
  1544.         mov     eax,[screen_workarea.bottom]
  1545.         sub     eax,[screen_workarea.top]
  1546.     @@: mov     [edi+WDATA.box.height],eax
  1547.         add     eax, [edi+WDATA.box.top]
  1548.         cmp     eax, [ScreenHeight]
  1549.         jbe     @f
  1550.         mov     eax, [ScreenHeight]
  1551.         sub     eax, [edi+WDATA.box.height]
  1552.         mov     [edi+WDATA.box.top], eax
  1553.     @@: call    check_window_position
  1554.         call    set_window_clientbox
  1555.  
  1556.       no_window_shade:
  1557.  
  1558.         push edx
  1559.         mov   edx, [edi + WDATA.cl_workarea]
  1560.         and   edx, 0x0f000000
  1561.         cmp   edx, 0x04000000
  1562.         pop edx
  1563.         je    no_fullscreen_restore
  1564.  
  1565.         cmp   [do_resize],1               ; fullscreen/restore ?
  1566.         jne   no_fullscreen_restore
  1567.         cmp   [latest_window_touch_delta],dword 50
  1568.         jg    no_fullscreen_restore
  1569.         mov   [reposition],1
  1570.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1571.         jnz     restore_from_fullscreen
  1572.         or      [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1573.         mov     eax,[screen_workarea.left]
  1574.         mov     [edi+WDATA.box.left],eax
  1575.         sub     eax,[screen_workarea.right]
  1576.         neg     eax
  1577.         mov     [edi+WDATA.box.width],eax
  1578.         mov     eax,[screen_workarea.top]
  1579.         mov     [edi+WDATA.box.top],eax
  1580.         test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1581.         jnz     @f
  1582.         sub     eax,[screen_workarea.bottom]
  1583.         neg     eax
  1584.         mov     [edi+WDATA.box.height],eax
  1585.     @@:
  1586.         jmp     restore_from_fullscreen.clientbox
  1587.       restore_from_fullscreen:
  1588.         and     [edi+WDATA.fl_wstate],not WSTATE_MAXIMIZED
  1589.         push    [edi+WDATA.box.height]
  1590.         push  edi                         ; restore
  1591.         lea   esi, [edx + APPDATA.saved_box]
  1592.         mov   ecx,4
  1593.         cld
  1594.         rep   movsd
  1595.         pop   edi
  1596.         pop     eax
  1597.         test    [edi+WDATA.fl_wstate],WSTATE_ROLLEDUP
  1598.         jz      @f
  1599.         mov     [edi+WDATA.box.height],eax
  1600.     @@:
  1601.     .clientbox:
  1602.         call    set_window_clientbox
  1603.  
  1604.       no_fullscreen_restore:
  1605.  
  1606.         mov   eax,[edi+WDATA.box.top]                 ; check Y inside screen
  1607.         add   eax,[edi+WDATA.box.height]
  1608.         cmp   eax,[ScreenHeight]
  1609.         jbe   no_window_sizing
  1610.         mov   eax,[edi+WDATA.box.left]                 ; check X inside screen
  1611.         add   eax,[edi+WDATA.box.width]
  1612.         cmp   eax,[ScreenWidth]
  1613.         jbe   no_window_sizing
  1614.         mov   eax,[ScreenWidth]
  1615.         sub   eax,[edi+WDATA.box.width]
  1616.         mov   [edi+WDATA.box.left],eax
  1617.         mov   eax,[ScreenHeight]
  1618.         sub   eax,[edi+WDATA.box.height]
  1619.         mov   [edi+WDATA.box.top],eax
  1620.         call  set_window_clientbox
  1621.       no_window_sizing:
  1622.  
  1623.         popad
  1624.  
  1625.         cmp   [reposition],0
  1626.         je    retwm
  1627.  
  1628.         mov   [DONT_DRAW_MOUSE],byte 1 ; no mouse
  1629.  
  1630.  
  1631.         push  eax ebx ecx edx
  1632.         mov   eax,[edi+WDATA.box.left]
  1633.         mov   ebx,[edi+WDATA.box.top]
  1634.         mov   ecx,[edi+WDATA.box.width]
  1635.         mov   edx,[edi+WDATA.box.height]
  1636.         add   ecx,eax
  1637.         add   edx,ebx
  1638.         call  calculatescreen
  1639.  
  1640.         mov   eax,[oldc+BOX.left]
  1641.         mov   ebx,[oldc+BOX.top]
  1642.         mov   ecx,[oldc+BOX.width]
  1643.         mov   edx,[oldc+BOX.height]
  1644.         add   ecx,eax
  1645.         add   edx,ebx
  1646.         call  calculatescreen
  1647.         pop   edx ecx ebx eax
  1648.  
  1649.         mov   eax,edi
  1650.         call  redrawscreen
  1651.  
  1652.  
  1653.         mov     [edi+WDATA.fl_redraw],1
  1654.  
  1655.         mov   ecx,100         ; wait to avoid mouse residuals
  1656.       waitre2:
  1657.         mov   [DONT_DRAW_MOUSE],byte 1
  1658.         call  checkidle
  1659.         cmp     [edi+WDATA.fl_redraw],0
  1660.         jz    retwm
  1661.         loop  waitre2
  1662.  
  1663.       retwm:
  1664.  
  1665.         mov   [DONT_DRAW_MOUSE],byte 0 ; mouse pointer
  1666.         mov   [MOUSE_BACKGROUND],byte 0 ; no mouse under
  1667.         mov   [MOUSE_DOWN],byte 0 ; react to mouse up/down
  1668.  
  1669.         mov    esi,window_moved
  1670.         call   sys_msg_board_str
  1671.  
  1672.         popad
  1673.  
  1674.         ret
  1675.  
  1676.  
  1677. uglobal
  1678.   add_window_data            dd  0
  1679.   do_resize_from_corner      db  0x0
  1680.   reposition                 db  0x0
  1681.   latest_window_touch        dd  0x0
  1682.   latest_window_touch_delta  dd  0x0
  1683.  
  1684.   do_resize db 0x0
  1685.  
  1686.   oldc    dd 0x0,0x0,0x0,0x0
  1687.  
  1688.   dlx     dd 0x0
  1689.   dly     dd 0x0
  1690.   dlxe    dd 0x0
  1691.   dlye    dd 0x0
  1692.  
  1693.   npx     dd 0x0
  1694.   npy     dd 0x0
  1695.   npxe    dd 0x0
  1696.   npye    dd 0x0
  1697.  
  1698.   mpx     dd 0x0
  1699.   mpy     dd 0x0
  1700. endg
  1701.  
  1702.  
  1703. ; draw negative window frames
  1704. drawwindowframes2:
  1705.         pushad
  1706.         cli
  1707.         jmp     drawwindowframes.do
  1708. drawwindowframes:
  1709.         pushad
  1710.         cli
  1711.  
  1712.         test    [edi+WDATA.fl_wstate],WSTATE_MAXIMIZED
  1713.         jnz     .ret
  1714.         mov     eax, [npx]
  1715.         cmp     eax, [edi+WDATA.box.left]
  1716.         jnz     .nowndframe
  1717.         mov     eax, [npxe]
  1718.         cmp     eax, [edi+WDATA.box.width]
  1719.         jnz     .nowndframe
  1720.         mov     eax, [npy]
  1721.         cmp     eax, [edi+WDATA.box.top]
  1722.         jnz     .nowndframe
  1723.         mov     eax, [npye]
  1724.         cmp     eax, [edi+WDATA.box.height]
  1725.         jnz     .nowndframe
  1726.         xor     [edi+WDATA.fl_wdrawn], 2
  1727.         test    [edi+WDATA.fl_wdrawn], 4
  1728.         jnz     .ret
  1729.  
  1730. .nowndframe:
  1731. .do:
  1732.         mov     edi, 1
  1733.         mov     ecx, 0x01000000
  1734.         mov   eax,[npx]
  1735.         shl   eax,16
  1736.         add   eax,[npx]
  1737.         add   eax,[npxe]
  1738.         add   eax,65536*1-1
  1739.         mov   ebx,[npy]
  1740.         shl   ebx,16
  1741.         add   ebx,[npy]
  1742.         call  [draw_line]
  1743.  
  1744.         mov   eax,[npx]
  1745.         shl   eax,16
  1746.         add   eax,[npx]
  1747.         add   eax,[npxe]
  1748.         add   eax,65536*1-1
  1749.         mov   ebx,[npy]
  1750.         add   ebx,[npye]
  1751.         shl   ebx,16
  1752.         add   ebx,[npy]
  1753.         add   ebx,[npye]
  1754.         call  [draw_line]
  1755.  
  1756.         mov   eax,[npx]
  1757.         shl   eax,16
  1758.         add   eax,[npx]
  1759.         mov   ebx,[npy]
  1760.         shl   ebx,16
  1761.         add   ebx,[npy]
  1762.         add   ebx,[npye]
  1763.         call  [draw_line]
  1764.  
  1765.         mov   eax,[npx]
  1766.         add   eax,[npxe]
  1767.         shl   eax,16
  1768.         add   eax,[npx]
  1769.         add   eax,[npxe]
  1770.         mov   ebx,[npy]
  1771.         shl   ebx,16
  1772.         add   ebx,[npy]
  1773.         add   ebx,[npye]
  1774.         call  [draw_line]
  1775.  
  1776. .ret:
  1777.         sti
  1778.         popad
  1779.         ret
  1780.  
  1781.  
  1782.  
  1783. random_shaped_window:
  1784.  
  1785. ;
  1786. ;  eax = 0    giving address of data area
  1787. ;      ebx    address
  1788. ;  eax = 1    shape area scale
  1789. ;      ebx    2^ebx scale
  1790.  
  1791.      test eax, eax
  1792.      jne  rsw_no_address
  1793.      mov  eax,[current_slot]
  1794.      mov  [eax+APPDATA.wnd_shape],ebx
  1795. rsw_no_address:
  1796.  
  1797.      cmp  eax,1
  1798.      jne  rsw_no_scale
  1799.      mov  eax,[current_slot]
  1800.      mov  byte [eax+APPDATA.wnd_shape_scale], bl
  1801. rsw_no_scale:
  1802.  
  1803.      ret
  1804.  
  1805.  
  1806.