Subversion Repositories Kolibri OS

Rev

Go to most recent revision | Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. format MS COFF
  3.  
  4.  
  5. include 'proc32.inc'
  6.  
  7. DEBUG       equ 1
  8.  
  9. CPU_FREQ    equ  2000d   ;cpu freq in MHz
  10.  
  11. BIT0  EQU 0x00000001
  12. BIT1  EQU 0x00000002
  13. BIT2  EQU 0x00000004
  14. BIT3  EQU 0x00000008
  15. BIT4  EQU 0x00000010
  16. BIT5  EQU 0x00000020
  17. BIT6  EQU 0x00000040
  18. BIT7  EQU 0x00000080
  19. BIT8  EQU 0x00000100
  20. BIT9  EQU 0x00000200
  21. BIT10 EQU 0x00000400
  22. BIT11 EQU 0x00000800
  23. BIT12 EQU 0x00001000
  24. BIT13 EQU 0x00002000
  25. BIT14 EQU 0x00004000
  26. BIT15 EQU 0x00008000
  27. BIT16 EQU 0x00010000
  28. BIT17 EQU 0x00020000
  29. BIT18 EQU 0x00040000
  30. BIT19 EQU 0x00080000
  31. BIT20 EQU 0x00100000
  32. BIT21 EQU 0x00200000
  33. BIT22 EQU 0x00400000
  34. BIT23 EQU 0x00800000
  35. BIT24 EQU 0x00100000
  36. BIT25 EQU 0x02000000
  37. BIT26 EQU 0x04000000
  38. BIT27 EQU 0x08000000
  39. BIT28 EQU 0x10000000
  40. BIT29 EQU 0x20000000
  41. BIT30 EQU 0x40000000
  42. BIT31 EQU 0x80000000
  43.  
  44. VID_SIS           equ 0x1039
  45. CTRL_SIS          equ 0x7012
  46.  
  47. PCM_OUT_BDL       equ  0x10      ; PCM out buffer descriptors list
  48. PCM_OUT_CR_REG    equ  0x1b      ; PCM out Control Register
  49. PCM_OUT_LVI_REG   equ  0x15      ; PCM last valid index
  50. PCM_OUT_SR_REG    equ  0x18      ; PCM out Status register
  51. PCM_OUT_PIV_REG   equ  0x1a      ; PCM out prefetched index
  52. PCM_OUT_CIV_REG   equ  0x14      ; PCM out current index
  53.  
  54. PCM_IN_CR_REG     equ  0x0b      ; PCM in Control Register
  55. MC_IN_CR_REG      equ  0x2b      ; MIC in Control Register
  56. RR                equ  BIT1      ; reset registers.  Nukes all regs
  57.  
  58. CODEC_MASTER_VOL_REG            equ     0x02
  59. CODEC_AUX_VOL                   equ     0x04    ;
  60. CODEC_PCM_OUT_REG               equ     18h     ; PCM output volume
  61. CODEC_EXT_AUDIO_REG             equ     28h     ; extended audio
  62. CODEC_EXT_AUDIO_CTRL_REG        equ     2ah     ; extended audio control
  63. CODEC_PCM_FRONT_DACRATE_REG     equ     2ch     ; PCM out sample rate
  64. CODEC_PCM_SURND_DACRATE_REG     equ     2eh     ; surround sound sample rate
  65. CODEC_PCM_LFE_DACRATE_REG       equ     30h     ; LFE sample rate
  66.  
  67.  
  68. GLOB_CTRL      equ  0x2C        ;   Global Control
  69. CTRL_STAT       equ  0x30        ;   Global Status
  70. CTRL_CAS        equ  0x34        ;   Codec Access Semiphore
  71.  
  72. CAS_FLAG       equ  0x01        ;   Codec Access Semiphore Bit
  73.  
  74. CTRL_ST_CREADY  equ  BIT8+BIT9+BIT28 ;   Primary Codec Ready
  75.  
  76. CTRL_ST_RCS     equ  0x00008000  ;   Read Completion Status
  77.  
  78. CTRL_CNT_CRIE   equ  BIT4+BIT5+BIT6  ;   Codecs Resume Interrupt Enable
  79. CTRL_CNT_AC_OFF equ  0x00000008  ;   ACLINK Off
  80. CTRL_CNT_WARM   equ  0x00000004  ;   AC97 Warm Reset
  81. CTRL_CNT_COLD   equ  0x00000002  ;   AC97 Cold Reset
  82. CTRL_CNT_GIE    equ  0x00000001  ;   GPI Interrupt Enable
  83.  
  84. CODEC_REG_POWERDOWN   equ 0x26
  85. CODEC_REG_ST          equ 0x26
  86.  
  87.  
  88. DEV_PLAY              equ  1
  89. DEV_STOP              equ  2
  90. DEV_CALLBACK          equ  3
  91. DEV_SET_BUFF          equ  4
  92. DEV_NOTIFY            equ  5
  93. DEV_SET_MASTERVOL     equ  6
  94. DEV_GET_MASTERVOL     equ  7
  95. DEV_GET_INFO          equ  8
  96.  
  97. struc AC_CNTRL              ;AC controller base class
  98. { .bus                dd 0
  99.   .devfn              dd 0
  100.  
  101.   .vendor             dd 0
  102.   .dev_id             dd 0
  103.   .pci_cmd            dd 0
  104.   .pci_stat           dd 0
  105.  
  106.   .codec_io_base      dd 0
  107.   .codec_mem_base     dd 0
  108.  
  109.   .ctrl_io_base       dd 0
  110.   .ctrl_mem_base      dd 0
  111.   .cfg_reg            dd 0
  112.   .int_line           dd 0
  113.  
  114.   .vendor_ids         dd 0    ;vendor id string
  115.   .ctrl_ids           dd 0    ;hub id string
  116.  
  117.   .buffer             dd 0
  118.  
  119.   .notify_pos         dd 0
  120.   .notify_task        dd 0
  121.  
  122.   .lvi_reg            dd 0
  123.   .ctrl_setup         dd 0
  124.   .user_callback      dd 0
  125.   .codec_read16       dd 0
  126.   .codec_write16      dd 0
  127.  
  128.   .ctrl_read8         dd 0
  129.   .ctrl_read16        dd 0
  130.   .ctrl_read32        dd 0
  131.  
  132.   .ctrl_write8        dd 0
  133.   .ctrl_write16       dd 0
  134.   .ctrl_write32       dd 0
  135. }
  136.  
  137. struc CODEC                ;Audio Chip base class
  138. {
  139.   .chip_id            dd 0
  140.   .flags              dd 0
  141.   .status             dd 0
  142.  
  143.   .ac_vendor_ids      dd 0    ;ac vendor id string
  144.   .chip_ids           dd 0    ;chip model string
  145.  
  146.   .shadow_flag        dd 0
  147.                       dd 0
  148.  
  149.   .regs               dw 0     ; codec registers
  150.   .reg_master_vol     dw 0     ;0x02
  151.   .reg_aux_out_vol    dw 0     ;0x04
  152.   .reg_mone_vol       dw 0     ;0x06
  153.   .reg_master_tone    dw 0     ;0x08
  154.   .reg_beep_vol       dw 0     ;0x0A
  155.   .reg_phone_vol      dw 0     ;0x0C
  156.   .reg_mic_vol        dw 0     ;0x0E
  157.   .reg_line_in_vol    dw 0     ;0x10
  158.   .reg_cd_vol         dw 0     ;0x12
  159.   .reg_video_vol      dw 0     ;0x14
  160.   .reg_aux_in_vol     dw 0     ;0x16
  161.   .reg_pcm_out_vol    dw 0     ;0x18
  162.   .reg_rec_select     dw 0     ;0x1A
  163.   .reg_rec_gain       dw 0     ;0x1C
  164.   .reg_rec_gain_mic   dw 0     ;0x1E
  165.   .reg_gen            dw 0     ;0x20
  166.   .reg_3d_ctrl        dw 0     ;0X22
  167.   .reg_page           dw 0     ;0X24
  168.   .reg_powerdown      dw 0     ;0x26
  169.   .reg_ext_audio      dw 0     ;0x28
  170.   .reg_ext_st         dw 0     ;0x2a
  171.   .reg_pcm_front_rate dw 0     ;0x2c
  172.   .reg_pcm_surr_rate  dw 0     ;0x2e
  173.   .reg_lfe_rate       dw 0     ;0x30
  174.   .reg_pcm_in_rate    dw 0     ;0x32
  175.                       dw 0     ;0x34
  176.   .reg_cent_lfe_vol   dw 0     ;0x36
  177.   .reg_surr_vol       dw 0     ;0x38
  178.   .reg_spdif_ctrl     dw 0     ;0x3A
  179.                       dw 0     ;0x3C
  180.                       dw 0     ;0x3E
  181.                       dw 0     ;0x40
  182.                       dw 0     ;0x42
  183.                       dw 0     ;0x44
  184.                       dw 0     ;0x46
  185.                       dw 0     ;0x48
  186.                       dw 0     ;0x4A
  187.                       dw 0     ;0x4C
  188.                       dw 0     ;0x4E
  189.                       dw 0     ;0x50
  190.                       dw 0     ;0x52
  191.                       dw 0     ;0x54
  192.                       dw 0     ;0x56
  193.                       dw 0     ;0x58
  194.                       dw 0     ;0x5A
  195.                       dw 0     ;0x5C
  196.                       dw 0     ;0x5E
  197.   .reg_page_0         dw 0     ;0x60
  198.   .reg_page_1         dw 0     ;0x62
  199.   .reg_page_2         dw 0     ;0x64
  200.   .reg_page_3         dw 0     ;0x66
  201.   .reg_page_4         dw 0     ;0x68
  202.   .reg_page_5         dw 0     ;0x6A
  203.   .reg_page_6         dw 0     ;0x6C
  204.   .reg_page_7         dw 0     ;0x6E
  205.                       dw 0     ;0x70
  206.                       dw 0     ;0x72
  207.                       dw 0     ;0x74
  208.                       dw 0     ;0x76
  209.                       dw 0     ;0x78
  210.                       dw 0     ;0x7A
  211.   .reg_vendor_id_1    dw 0     ;0x7C
  212.   .reg_vendor_id_2    dw 0     ;0x7E
  213.  
  214.  
  215.   .reset              dd 0    ;virual
  216.   .set_master_vol     dd 0
  217. }
  218.  
  219. struc CTRL_INFO
  220. {   .pci_cmd        dd  ?
  221.     .irq            dd  ?
  222.     .glob_cntrl     dd  ?
  223.     .glob_sta       dd  ?
  224.     .codec_io_base  dd  ?
  225.     .ctrl_io_base   dd  ?
  226.     .codec_mem_base dd  ?
  227.     .ctrl_mem_base  dd  ?
  228.     .codec_id       dd  ?
  229. }
  230.  
  231. struc IOCTL
  232. {  .handle           dd ?
  233.    .io_code          dd ?
  234.    .input            dd ?
  235.    .inp_size         dd ?
  236.    .output           dd ?
  237.    .out_size         dd ?
  238. }
  239.  
  240. virtual at 0
  241.   IOCTL IOCTL
  242. end virtual
  243.  
  244. EVENT_NOTIFY          equ 0x00000200
  245.  
  246. OS_BASE               equ 0;  0x80400000
  247. new_app_base          equ 0x60400000;   0x01000000
  248. PROC_BASE             equ OS_BASE+0x0080000
  249.  
  250.  
  251. public service_proc
  252. public START
  253. public IMPORTS
  254.  
  255. section '.flat' align 16
  256.  
  257. START:
  258.      if DEBUG
  259.            mov esi, msgInit
  260.            call   [SysMsgBoardStr]
  261.      end if
  262.  
  263.            call detect_controller
  264.            test eax, eax
  265.            jz .fail
  266.  
  267.      if DEBUG
  268.            mov esi,[ctrl.vendor_ids]
  269.            call [SysMsgBoardStr]
  270.            mov  esi, [ctrl.ctrl_ids]
  271.            call [SysMsgBoardStr]
  272.      end if
  273.  
  274.            call init_controller
  275.            test eax, eax
  276.            jz .fail
  277.  
  278.      if DEBUG
  279.            mov esi, msgInitCodec
  280.            call [SysMsgBoardStr]
  281.      end if
  282.  
  283.            call init_codec
  284.            test eax, eax
  285.            jz .fail
  286.  
  287.      if DEBUG
  288.            mov esi, [codec.ac_vendor_ids]
  289.            call   [SysMsgBoardStr]
  290.  
  291.            mov esi, [codec.chip_ids]
  292.            call   [SysMsgBoardStr]
  293.      end if
  294.  
  295.            call reset_controller
  296.            call setup_codec
  297.  
  298.            mov esi, msgPrimBuff
  299.            call [SysMsgBoardStr]
  300.  
  301.            call create_primary_buff
  302.  
  303.            stdcall [AttachIntHandler], [ctrl.int_line], ac97_irq
  304.  
  305.            stdcall [RegService], sz_sound_srv, service_proc
  306.  
  307.            mov esi, msgOk
  308.            call [SysMsgBoardStr]
  309.  
  310.            ret
  311.  
  312. .fail:
  313.    if DEBUG
  314.            mov esi, msgFail
  315.            call   [SysMsgBoardStr]
  316.    end if
  317.  
  318.            xor eax, eax
  319.            ret
  320.  
  321. handle     equ  IOCTL.handle
  322. io_code    equ  IOCTL.io_code
  323. input      equ  IOCTL.input
  324. inp_size   equ  IOCTL.inp_size
  325. output     equ  IOCTL.output
  326. out_size   equ  IOCTL.out_size
  327.  
  328. align 4
  329. proc service_proc stdcall, ioctl:dword
  330.  
  331.            mov edi, [ioctl]
  332.            mov eax, [edi+io_code]
  333.            cmp eax, DEV_PLAY
  334.            jne @F
  335.      if DEBUG
  336.            mov esi, msgPlay
  337.            call   [SysMsgBoardStr]
  338.      end if
  339.            call play
  340.            ret
  341. @@:
  342.            cmp eax, DEV_STOP
  343.            jne @F
  344.      if DEBUG
  345.            mov esi, msgStop
  346.            call   [SysMsgBoardStr]
  347.      end if
  348.            call stop
  349.            ret
  350. @@:
  351.            cmp eax, DEV_CALLBACK
  352.            jne @F
  353.            mov ebx, [edi+input]
  354.            stdcall set_callback, [ebx]
  355.            ret
  356. @@:
  357.            cmp eax, DEV_SET_MASTERVOL
  358.            jne @F
  359.            mov ebx, [edi+input]
  360.            stdcall set_master_vol, [ebx]
  361.            ret
  362. @@:
  363.            cmp eax, DEV_GET_MASTERVOL
  364.            jne @F
  365.            mov ebx, [edi+output]
  366.            test ebx, ebx
  367.            jz .fail
  368.  
  369.            stdcall get_master_vol, ebx
  370.            ret
  371. @@:
  372.            cmp eax, DEV_GET_INFO
  373.            jne @F
  374.            mov ebx, [edi+output]
  375.            stdcall get_dev_info, ebx
  376.            ret
  377. @@:
  378. .fail:
  379.            xor eax, eax
  380.            ret
  381. endp
  382.  
  383. restore   handle
  384. restore   io_code
  385. restore   input
  386. restore   inp_size
  387. restore   output
  388. restore   out_size
  389.  
  390. align 4
  391. proc ac97_irq
  392.  
  393. ;     if DEBUG
  394. ;           mov esi, msgIRQ
  395. ;           call   [SysMsgBoardStr]
  396. ;     end if
  397.  
  398.            mov edx, PCM_OUT_CR_REG
  399.            mov al, 0x14
  400.            call [ctrl.ctrl_write8]
  401.  
  402.            mov ax, 0x1c
  403.            mov edx, PCM_OUT_SR_REG
  404.            call [ctrl.ctrl_write16]
  405.  
  406.            mov edx, PCM_OUT_CIV_REG
  407.            call [ctrl.ctrl_read8]
  408.  
  409.            and eax, 0x1F
  410.            cmp eax, [civ_val]
  411.            je .skip
  412.  
  413.            mov [civ_val], eax
  414.            dec eax
  415.            and eax, 0x1F
  416.            mov [ctrl.lvi_reg], eax
  417.  
  418.            mov edx, PCM_OUT_LVI_REG
  419.            call [ctrl.ctrl_write8]
  420.  
  421.            mov edx, PCM_OUT_CR_REG
  422.            mov ax, 0x1D
  423.            call [ctrl.ctrl_write8]
  424.  
  425.            mov eax, [civ_val]
  426.            add eax, 2
  427.            and eax, 31
  428.            mov ebx, dword [buff_list+eax*4]
  429.  
  430.            cmp [ctrl.user_callback], 0
  431.            je @f
  432.  
  433.            stdcall [ctrl.user_callback], ebx
  434. @@:
  435.            ret
  436.  
  437. .skip:
  438.            mov edx, PCM_OUT_CR_REG
  439.            mov ax, 0x1D
  440.            call [ctrl.ctrl_write8]
  441.            ret
  442. endp
  443.  
  444. align 4
  445. proc create_primary_buff
  446.  
  447.            stdcall [KernelAlloc], 0x10000
  448.            mov [ctrl.buffer], eax
  449.  
  450.            mov edi, eax
  451.            mov ecx, 0x10000/4
  452.            xor eax, eax
  453.            rep stosd
  454.  
  455.            stdcall [GetPgAddr], [ctrl.buffer]
  456.  
  457.            mov ebx, 0xC0004000
  458.            mov ecx, 4
  459.            mov edi, pcmout_bdl
  460. @@:
  461.            mov [edi], eax
  462.            mov [edi+4], ebx
  463.  
  464.            mov [edi+32], eax
  465.            mov [edi+4+32], ebx
  466.  
  467.            mov [edi+64], eax
  468.            mov [edi+4+64], ebx
  469.  
  470.            mov [edi+96], eax
  471.            mov [edi+4+96], ebx
  472.  
  473.            mov [edi+128], eax
  474.            mov [edi+4+128], ebx
  475.  
  476.            mov [edi+160], eax
  477.            mov [edi+4+160], ebx
  478.  
  479.            mov [edi+192], eax
  480.            mov [edi+4+192], ebx
  481.  
  482.            mov [edi+224], eax
  483.            mov [edi+4+224], ebx
  484.  
  485.            add eax, 0x4000
  486.            add edi, 8
  487.            loop @B
  488.  
  489.            mov edi, buff_list
  490.            mov eax, [ctrl.buffer]
  491.            mov ecx, 4
  492. @@:
  493.            mov [edi], eax
  494.            mov [edi+16], eax
  495.            mov [edi+32], eax
  496.            mov [edi+48], eax
  497.            mov [edi+64], eax
  498.            mov [edi+80], eax
  499.            mov [edi+96], eax
  500.            mov [edi+112], eax
  501.  
  502.            add eax, 0x4000
  503.            add edi, 4
  504.            loop @B
  505.  
  506.            mov ecx, pcmout_bdl
  507.            stdcall [GetPgAddr], ecx
  508.            and ecx, 0xFFF
  509.            add eax, ecx
  510.  
  511.            mov edx, PCM_OUT_BDL
  512.            call [ctrl.ctrl_write32]
  513.  
  514.            mov eax, 16
  515.            mov [ctrl.lvi_reg], eax
  516.            mov edx, PCM_OUT_LVI_REG
  517.            call [ctrl.ctrl_write8]
  518.  
  519.            mov edx, GLOB_CTRL
  520.            call [ctrl.ctrl_read32]
  521.            and eax, not 0x000000C0
  522.            mov edx, GLOB_CTRL
  523.            call [ctrl.ctrl_write32]
  524.  
  525.  
  526.            ret
  527. endp
  528.  
  529. align 4
  530. proc detect_controller
  531.            locals
  532.              last_bus dd ?
  533.              bus      dd ?
  534.              devfn    dd ?
  535.            endl
  536.  
  537.            xor eax, eax
  538.            mov [bus], eax
  539.            inc eax
  540.            call [PciApi]
  541.            cmp eax, -1
  542.            je .err
  543.  
  544.            mov [last_bus], eax
  545.  
  546. .next_bus:
  547.            and [devfn], 0
  548. .next_dev:
  549.            stdcall [PciRead32], [bus], [devfn], dword 0
  550.            test eax, eax
  551.            jz .next
  552.            cmp eax, -1
  553.            je .next
  554.  
  555.            mov edi, devices
  556. @@:
  557.            mov ebx, [edi]
  558.            test ebx, ebx
  559.            jz .next
  560.  
  561.            cmp eax, ebx
  562.            je .found
  563.            add edi, 12
  564.            jmp @B
  565.  
  566. .next:     inc [devfn]
  567.            cmp [devfn], 256
  568.            jb  .next_dev
  569.            mov eax, [bus]
  570.            inc eax
  571.            mov [bus], eax
  572.            cmp eax, [last_bus]
  573.            jna .next_bus
  574.            xor eax, eax
  575.            ret
  576. .found:
  577.            mov ebx, [bus]
  578.            mov [ctrl.bus], ebx
  579.  
  580.            mov ecx, [devfn]
  581.            mov [ctrl.devfn], ecx
  582.  
  583.            mov edx, eax
  584.            and edx, 0xFFFF
  585.            mov [ctrl.vendor], edx
  586.            shr eax, 16
  587.            mov [ctrl.dev_id], eax
  588.  
  589.            mov ebx, [edi+4]
  590.            mov [ctrl.ctrl_ids], ebx
  591.            mov [ctrl.vendor_ids], msg_SIS
  592.  
  593.            mov esi, [edi+8]
  594.            mov [ctrl.ctrl_setup], esi
  595.  
  596.            ret
  597. .err:
  598.            xor eax, eax
  599.            ret
  600. endp
  601.  
  602. align 4
  603. proc init_controller
  604.  
  605.            stdcall [PciRead32], [ctrl.bus], [ctrl.devfn], dword 4
  606.            mov ebx, eax
  607.            and eax, 0xFFFF
  608.            mov [ctrl.pci_cmd], eax
  609.            shr ebx, 16
  610.            mov [ctrl.pci_stat], ebx
  611.  
  612.            stdcall [PciRead32], [ctrl.bus], [ctrl.devfn], dword 0x10
  613.            and eax,0xFFFE
  614.            mov [ctrl.codec_io_base], eax
  615.  
  616.            stdcall [PciRead32], [ctrl.bus], [ctrl.devfn], dword 0x14
  617.            and eax, 0xFFC0
  618.            mov [ctrl.ctrl_io_base], eax
  619.  
  620.            stdcall [PciRead32], [ctrl.bus], [ctrl.devfn], dword 0x18
  621.            mov [ctrl.codec_mem_base], eax
  622.  
  623.            stdcall [PciRead32], [ctrl.bus], [ctrl.devfn], dword 0x1C
  624.            mov [ctrl.ctrl_mem_base], eax
  625.  
  626.            stdcall [PciRead32], [ctrl.bus], [ctrl.devfn], dword 0x3C
  627.            and eax, 0xFF
  628.            mov [ctrl.int_line], eax
  629.  
  630.            stdcall [PciRead8], [ctrl.bus], [ctrl.devfn], dword 0x41
  631.            and eax, 0xFF
  632.            mov [ctrl.cfg_reg], eax
  633.  
  634.            call [ctrl.ctrl_setup]
  635.            xor eax, eax
  636.            inc eax
  637.            ret
  638. endp
  639.  
  640. align 4
  641. proc set_SIS
  642.            mov [ctrl.codec_read16],  codec_io_r16    ;virtual
  643.            mov [ctrl.codec_write16], codec_io_w16    ;virtual
  644.  
  645.            mov [ctrl.ctrl_read8 ],  ctrl_io_r8       ;virtual
  646.            mov [ctrl.ctrl_read16],  ctrl_io_r16      ;virtual
  647.            mov [ctrl.ctrl_read32],  ctrl_io_r32      ;virtual
  648.  
  649.            mov [ctrl.ctrl_write8 ], ctrl_io_w8       ;virtual
  650.            mov [ctrl.ctrl_write16], ctrl_io_w16      ;virtual
  651.            mov [ctrl.ctrl_write32], ctrl_io_w32      ;virtual
  652.            ret
  653. endp
  654.  
  655. align 4
  656. proc reset_controller
  657.  
  658.            xor eax, eax
  659.            mov edx, PCM_IN_CR_REG
  660.            call [ctrl.ctrl_write8]
  661.  
  662.            mov edx, PCM_OUT_CR_REG
  663.            call [ctrl.ctrl_write8]
  664.  
  665.            mov edx, MC_IN_CR_REG
  666.            call [ctrl.ctrl_write8]
  667.  
  668.            mov eax, RR
  669.            mov edx, PCM_IN_CR_REG
  670.            call [ctrl.ctrl_write8]
  671.  
  672.            mov edx, PCM_OUT_CR_REG
  673.            call [ctrl.ctrl_write8]
  674.  
  675.            mov  edx, MC_IN_CR_REG
  676.            call [ctrl.ctrl_write8]
  677.  
  678.  
  679.            ret
  680. endp
  681.  
  682. align 4
  683. proc init_codec
  684.            locals
  685.              counter dd ?
  686.            endl
  687.  
  688.            call reset_codec
  689.            and eax, eax
  690.            jz .err
  691.  
  692.            xor edx, edx                   ;ac_reg_0
  693.            call [ctrl.codec_write16]
  694.  
  695.            xor eax, eax
  696.            mov edx, CODEC_REG_POWERDOWN
  697.            call [ctrl.codec_write16]
  698.  
  699.            mov [counter], 200       ; total 200*5 ms = 1s
  700. .wait:
  701.            mov edx, CODEC_REG_POWERDOWN
  702.            call [ctrl.codec_read16]
  703.            and eax, 0x0F
  704.            cmp eax, 0x0F
  705.            jz .ready
  706.  
  707.            mov eax, 5000          ; wait 5 ms
  708.            call StallExec
  709.            sub [counter] , 1
  710.            jnz .wait
  711. .err:
  712.            xor eax, eax        ; timeout error
  713.            ret
  714. .ready:
  715.            call detect_codec
  716.  
  717.            xor eax, eax
  718.            inc eax
  719.            ret
  720. endp
  721.  
  722. align 4
  723. proc reset_codec
  724.            mov edx, GLOB_CTRL
  725.            call [ctrl.ctrl_read32]
  726.  
  727.            test eax, 0x02
  728.            jz .cold
  729.  
  730.            call warm_reset
  731.            jnc .ok
  732. .cold:
  733.            call cold_reset
  734.            jnc .ok
  735.  
  736.      if DEBUG
  737.            mov esi, msgCFail
  738.            call [SysMsgBoardStr]
  739.      end if
  740.            xor eax, eax            ; timeout error
  741.            ret
  742. .ok:
  743.            xor eax, eax
  744.            inc eax
  745.            ret
  746. endp
  747.  
  748. align 4
  749. proc warm_reset
  750.            locals
  751.              counter dd ?
  752.            endl
  753.  
  754.            mov eax, 0x06
  755.            mov edx, GLOB_CTRL
  756.            call [ctrl.ctrl_write32]
  757.  
  758.      if DEBUG
  759.            mov esi, msgWarm
  760.            call [SysMsgBoardStr]
  761.      end if
  762.  
  763.            mov [counter], 10       ; total 10*100 ms = 1s
  764. .wait:
  765.            mov eax, 100000         ; wait 100 ms
  766.            call StallExec
  767.  
  768.            mov edx, GLOB_CTRL
  769.            call [ctrl.ctrl_read32]
  770.            test eax, 4
  771.            jz .ok
  772.            sub [counter], 1
  773.            jnz .wait
  774.  
  775.      if DEBUG
  776.            mov esi, msgWRFail
  777.            call [SysMsgBoardStr]
  778.      end if
  779.  
  780.            stc
  781.            ret
  782. .ok:
  783.            mov edx, CTRL_STAT
  784.            call [ctrl.ctrl_read32]
  785.            and eax, CTRL_ST_CREADY
  786.            jz .fail
  787.            clc
  788.            ret
  789. .fail:
  790.            stc
  791.            ret
  792. endp
  793.  
  794. align 4
  795. proc cold_reset
  796.            locals
  797.              counter dd ?
  798.            endl
  799.  
  800.            xor eax, eax
  801.            mov edx, GLOB_CTRL
  802.            call [ctrl.ctrl_write32]
  803.  
  804.      if DEBUG
  805.            mov esi, msgCold
  806.            call [SysMsgBoardStr]
  807.      end if
  808.  
  809.            mov eax, 1000000        ; wait 1 s
  810.            call StallExec
  811.  
  812.            mov eax, 2
  813.            mov edx, GLOB_CTRL
  814.            call [ctrl.ctrl_write32]
  815.  
  816.            mov [counter], 10       ; total 10*100 ms = 1s
  817. .wait:
  818.            mov eax, 100000         ; wait 100 ms
  819.            call StallExec
  820.  
  821.            mov edx, GLOB_CTRL
  822.            call [ctrl.ctrl_read32]
  823.            test eax, 4
  824.            jz .ok
  825.            sub [counter], 1
  826.            jnz .wait
  827.  
  828.      if DEBUG
  829.            mov esi, msgCRFail
  830.            call [SysMsgBoardStr]
  831.      end if
  832.            stc
  833.            ret
  834. .ok:
  835.            mov edx, CTRL_STAT
  836.            call [ctrl.ctrl_read32]
  837.            and eax, CTRL_ST_CREADY
  838.            jz .fail
  839.            clc
  840.            ret
  841. .fail:
  842.            stc
  843.            ret
  844. endp
  845.  
  846. align 4
  847. proc play
  848.            xor eax, eax
  849.            mov [civ_val], eax
  850.            mov edx, PCM_OUT_CIV_REG
  851.            call [ctrl.ctrl_write8]
  852.  
  853.            mov eax, 16
  854.            mov [ctrl.lvi_reg], eax
  855.            mov edx, PCM_OUT_LVI_REG
  856.            call [ctrl.ctrl_write8]
  857.  
  858.            mov edx, PCM_OUT_CR_REG
  859.            mov ax, 0x1D
  860.            call [ctrl.ctrl_write8]
  861.            ret
  862. endp
  863.  
  864. align 4
  865. proc stop
  866.            mov edx, PCM_OUT_CR_REG
  867.            mov ax, 0x14
  868.            call [ctrl.ctrl_write8]
  869.  
  870.            mov eax, 16
  871.            mov [ctrl.lvi_reg], eax
  872.            mov edx, PCM_OUT_LVI_REG
  873.            call [ctrl.ctrl_write8]
  874.  
  875.            ret
  876. endp
  877.  
  878. align 4
  879. proc get_dev_info stdcall, p_info:dword
  880.            virtual at esi
  881.              CTRL_INFO CTRL_INFO
  882.            end virtual
  883.  
  884.            mov esi, [p_info]
  885.            mov eax, [ctrl.int_line]
  886.            mov ebx, [ctrl.codec_io_base]
  887.            mov ecx, [ctrl.ctrl_io_base]
  888.            mov edx, [ctrl.codec_mem_base]
  889.            mov edi, [ctrl.ctrl_mem_base]
  890.  
  891.            mov [CTRL_INFO.irq], eax
  892.            mov [CTRL_INFO.codec_io_base], ebx
  893.            mov [CTRL_INFO.ctrl_io_base], ecx
  894.            mov [CTRL_INFO.codec_mem_base], edx
  895.            mov [CTRL_INFO.ctrl_mem_base], edi
  896.  
  897.            mov eax, [codec.chip_id]
  898.            mov [CTRL_INFO.codec_id], eax
  899.  
  900.            mov edx, GLOB_CTRL
  901.            call [ctrl.ctrl_read32]
  902.            mov [CTRL_INFO.glob_cntrl], eax
  903.  
  904.            mov edx, CTRL_STAT
  905.            call [ctrl.ctrl_read32]
  906.            mov [CTRL_INFO.glob_sta], eax
  907.  
  908.            mov ebx, [ctrl.pci_cmd]
  909.            mov [CTRL_INFO.pci_cmd], ebx
  910.  
  911.            ret
  912. endp
  913.  
  914. align 4
  915. proc set_callback stdcall, handler:dword
  916.            mov eax, [handler]
  917.            mov [ctrl.user_callback], eax
  918.            ret
  919. endp
  920.  
  921. align 4
  922. proc codec_read stdcall, ac_reg:dword      ; reg = edx, reval = eax
  923.  
  924.            mov edx, [ac_reg]
  925.  
  926.            mov ebx, edx
  927.            shr ebx, 1
  928.            bt [codec.shadow_flag], ebx
  929.            jc .use_shadow
  930.  
  931.            call [ctrl.codec_read16]  ;change edx !!!
  932.            mov ecx, eax
  933.  
  934.            mov edx, CTRL_STAT
  935.            call [ctrl.ctrl_read32]
  936.            test eax, CTRL_ST_RCS
  937.            jz .read_ok
  938.  
  939.            mov edx, CTRL_STAT
  940.            call [ctrl.ctrl_write32]
  941.            xor eax,eax
  942.            not eax              ;timeout
  943.            ret
  944. .read_ok:
  945.            mov edx, [ac_reg]
  946.            mov [codec.regs+edx], cx
  947.            bts [codec.shadow_flag], ebx
  948.            mov eax, ecx
  949.            ret
  950. .use_shadow:
  951.            movzx eax, word [codec.regs+edx]
  952.            ret
  953. endp
  954.  
  955. align 4
  956. proc codec_write stdcall, ac_reg:dword
  957.            push eax
  958.            call check_semafore
  959.            and eax, eax
  960.            jz .err
  961.            pop eax
  962.  
  963.            mov esi, [ac_reg]
  964.            mov edx, esi
  965.            call [ctrl.codec_write16]
  966.            mov [codec.regs+esi], ax
  967.            shr esi, 1
  968.            bts [codec.shadow_flag], esi
  969.            ret
  970. .err:
  971.            pop eax
  972.            ret
  973. endp
  974.  
  975.  
  976. align 4
  977. proc codec_check_ready
  978.  
  979.           mov edx, CTRL_ST
  980.           call [ctrl.ctrl_read32]
  981.           and eax, CTRL_ST_CREADY
  982.           jz .not_ready
  983.  
  984.           xor eax, wax
  985.           inc eax
  986.           ret
  987.  
  988. align 4
  989. .not_ready:
  990.           xor eax, eax
  991.           ret
  992. endp
  993.  
  994.  
  995. align 4
  996. proc check_semafore
  997.            local counter:DWORD
  998.  
  999.            mov [counter], 100
  1000. .l1:
  1001.            mov edx, CTRL_CAS
  1002.            call [ctrl.ctrl_read8]
  1003.            and eax, CAS_FLAG
  1004.            jz .ok
  1005.  
  1006.            mov eax, 1
  1007.            call StallExec
  1008.            sub [counter], 1
  1009.            jnz .l1
  1010.            xor eax, eax
  1011.            ret
  1012. align 4
  1013. .ok:
  1014.            xor eax,eax
  1015.            inc eax
  1016.            ret
  1017. endp
  1018.  
  1019. align 4
  1020. proc StallExec
  1021.            push ecx
  1022.            push edx
  1023.            push ebx
  1024.            push eax
  1025.  
  1026.            mov ecx, CPU_FREQ
  1027.            mul ecx
  1028.            mov ebx, eax       ;low
  1029.            mov ecx, edx       ;high
  1030.            rdtsc
  1031.            add ebx, eax
  1032.            adc ecx,edx
  1033. @@:
  1034.            rdtsc
  1035.            sub eax, ebx
  1036.            sbb edx, ecx
  1037.            jb @B
  1038.  
  1039.            pop eax
  1040.            pop ebx
  1041.            pop edx
  1042.            pop ecx
  1043.            ret
  1044. endp
  1045.  
  1046. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1047. ;          CONTROLLER IO functions
  1048. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1049.  
  1050. align 4
  1051. proc codec_io_r16
  1052.         add edx, [ctrl.codec_io_base]
  1053.         in  ax, dx
  1054.         ret
  1055. endp
  1056.  
  1057. align 4
  1058. proc codec_io_w16
  1059.         add edx, [ctrl.codec_io_base]
  1060.         out dx, ax
  1061.         ret
  1062. endp
  1063.  
  1064. align 4
  1065. proc ctrl_io_r8
  1066.         add edx, [ctrl.ctrl_io_base]
  1067.         in  al, dx
  1068.         ret
  1069. endp
  1070.  
  1071. align 4
  1072. proc ctrl_io_r16
  1073.         add edx, [ctrl.ctrl_io_base]
  1074.         in  ax, dx
  1075.         ret
  1076. endp
  1077.  
  1078. align 4
  1079. proc ctrl_io_r32
  1080.         add edx, [ctrl.ctrl_io_base]
  1081.         in  eax, dx
  1082.         ret
  1083. endp
  1084.  
  1085. align 4
  1086. proc ctrl_io_w8
  1087.         add edx, [ctrl.ctrl_io_base]
  1088.         out dx, al
  1089.         ret
  1090. endp
  1091.  
  1092. align 4
  1093. proc ctrl_io_w16
  1094.         add edx, [ctrl.ctrl_io_base]
  1095.         out dx, ax
  1096.         ret
  1097. endp
  1098.  
  1099. align 4
  1100. proc ctrl_io_w32
  1101.         add edx, [ctrl.ctrl_io_base]
  1102.         out dx, eax
  1103.         ret
  1104. endp
  1105.  
  1106. include "codec.inc"
  1107.  
  1108.  
  1109. align 16
  1110. pcmout_bdl       dq 32 dup(0)
  1111. buff_list        dd 32 dup(0)
  1112.  
  1113. align 16
  1114. ctrl AC_CNTRL
  1115.  
  1116. align 16
  1117. codec CODEC
  1118.  
  1119. civ_val    dd 0
  1120.  
  1121. align 16
  1122. devices dd (CTRL_SIS  shl 16)+VID_SIS,msg_AC, set_SIS
  1123.         dd 0
  1124.  
  1125. align 16
  1126. imp_table:
  1127. IMPORTS:
  1128.  
  1129. AttachIntHandler   dd szAttachIntHandler
  1130. SysMsgBoardStr     dd szSysMsgBoardStr
  1131. PciApi             dd szPciApi
  1132. PciRead32          dd szPciRead32
  1133. PciRead8           dd szPciRead8
  1134. PciWrite8          dd szPciWrite8
  1135. AllocKernelSpace   dd szAllocKernelSpace
  1136. MapPage            dd szMapPage
  1137. KernelAlloc        dd szKernelAlloc
  1138. GetPgAddr          dd szGetPgAddr
  1139. RegService         dd szRegService
  1140. GetCurrentTask     dd szGetCurrentTask
  1141.                    dd 0
  1142.  
  1143. msg_AC    db '7012 AC97 controller',13,10, 0
  1144. msg_SIS   db 'Silicon Integrated Systems',13,10, 0
  1145.  
  1146. szKernel            db 'KERNEL', 0
  1147. szAttachIntHandler  db 'AttachIntHandler',0
  1148. szSysMsgBoardStr    db 'SysMsgBoardStr', 0
  1149. szPciApi            db 'PciApi', 0
  1150. szPciRead32         db 'PciRead32', 0
  1151. szPciRead8          db 'PciRead8', 0
  1152. szPciWrite8         db 'PciWrite8',0
  1153. szAllocKernelSpace  db 'AllocKernelSpace',0
  1154. szMapPage           db 'MapPage',0
  1155. szRegService        db 'RegService',0
  1156. szKernelAlloc       db 'KernelAlloc',0
  1157. szGetPgAddr         db 'GetPgAddr',0
  1158. szGetCurrentTask    db 'GetCurrentTask ',0
  1159.  
  1160. sz_sound_srv        db 'SOUND',0
  1161.  
  1162. msgInit      db 'detect hardware...',13,10,0
  1163. msgFail      db 'device not found',13,10,0
  1164. msgPlay      db 'start play', 13,10,0
  1165. msgStop      db 'stop play',  13,10,0
  1166. msgNotify    db 'call notify',13,10,0
  1167. msgIRQ       db 'AC97 IRQ', 13,10,0
  1168. msgInitCtrl  db 'init controller',13,10,0
  1169. msgInitCodec db 'init codec',13,10,0
  1170. msgPrimBuff  db 'create primary buffer',13,10,0
  1171. msgReg       db 'set service handler',13,10,0
  1172. msgOk        db 'service installed',13,10,0
  1173. msgCold      db 'cold resret',13,10,0
  1174. msgWarm      db 'warm reset',13,10,0
  1175. msgWRFail    db 'warm reset failed',13,10,0
  1176. msgCRFail    db 'cold reset failed',13,10,0
  1177. msgCFail     db 'codec not ready',13,10,0
  1178.