Subversion Repositories Kolibri OS

Rev

Blame | Last modification | View Log | RSS feed

  1. /*
  2.  * Copyright © <2013>, Intel Corporation.
  3.  *
  4.  * Permission is hereby granted, free of charge, to any person obtaining a
  5.  * copy of this software and associated documentation files (the
  6.  * "Software"), to deal in the Software without restriction, including
  7.  * without limitation the rights to use, copy, modify, merge, publish,
  8.  * distribute, sub license, and/or sell copies of the Software, and to
  9.  * permit persons to whom the Software is furnished to do so, subject to
  10.  * the following conditions:
  11.  *
  12.  * The above copyright notice and this permission notice (including the
  13.  * next paragraph) shall be included in all copies or substantial portions
  14.  * of the Software.
  15.  *
  16.  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  17.  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  18.  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  19.  * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  20.  * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  21.  * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  22.  * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  23.  *
  24.  */
  25. // Modual name: Inter_frame_gen8.asm
  26. //
  27. // Make inter predition estimation for Inter-frame on gen8
  28. //
  29.  
  30. //
  31. //  Now, begin source code....
  32. //
  33.  
  34. #define SAVE_RET        add (1) RETURN_REG<1>:ud   ip:ud        32:ud
  35. #define RETURN          mov (1) ip:ud   RETURN_REG<0,1,0>:ud
  36.  
  37. /*
  38.  * __START
  39.  */
  40. __INTER_START:
  41. mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  42. mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  43. mov  (16) tmp_reg4.0<1>:UD      0x0:UD {align1} ;
  44. mov  (16) tmp_reg6.0<1>:UD      0x0:UD {align1} ;
  45.  
  46. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  47. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  48. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  49. mov  (1) read0_header.8<1>:UD   BLOCK_32X1 {align1};
  50. mov  (1) read0_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  51.  
  52. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  53. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  54. mov  (1) read1_header.8<1>:UD   BLOCK_4X16 {align1};
  55. mov  (1) read1_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  56.        
  57. shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  58. mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  59.  
  60. mul  (1) obw_m0.8<1>:UD         w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
  61. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
  62. mul  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 24:UD {align1};
  63. mov  (1) obw_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  64.        
  65. /*
  66.  * Media Read Message -- fetch Luma neighbor edge pixels
  67.  */
  68. /* ROW */
  69. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  70. send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  71.  
  72. /* COL */
  73. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  74. send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  75.        
  76. /*
  77.  * Media Read Message -- fetch Chroma neighbor edge pixels
  78.  */
  79. /* ROW */
  80. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 3:UW {align1};    /* x * 16 , y * 8 */
  81. mul  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D  2:W {align1};
  82. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  83. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  84. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  85. send (8) msg_ind CHROMA_ROW<1>:UB null read(BIND_IDX_CBCR, 0, 0, 4) mlen 1 rlen 1 {align1};
  86.  
  87. /* COL */
  88. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 3:UW {align1};    /* x * 16, y * 8 */
  89. mul  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D  2:W {align1};
  90. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  91. mov  (1) read1_header.8<1>:UD   BLOCK_8X4 {align1};
  92. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  93. send (8) msg_ind CHROMA_COL<1>:UB null read(BIND_IDX_CBCR, 0, 0, 4) mlen 1 rlen 1 {align1};
  94.  
  95. mov  (8) mb_mvp_ref.0<1>:ud     0:ud            {align1};
  96. mov  (8) mb_ref_win.0<1>:ud     0:ud            {align1};
  97. and.z.f0.0 (1)          null:uw mb_hwdep<0,1,0>:uw              0x04:uw   {align1};
  98. (f0.0) jmpi (1) __mb_hwdep_end;
  99. /* read back the data for MB A */
  100. /* the layout of MB result is: rx.0(Available). rx.4(MVa), rX.8(MVb), rX.16(Pred_L0 flag),
  101. *  rX.18 (Pred_L1 flag), rX.20(Forward reference ID), rX.22(Backwared reference ID)
  102. */
  103. mov  (8) mba_result.0<1>:ud     0x0:ud          {align1};
  104. mov  (8) mbb_result.0<1>:ud     0x0:ud          {align1};
  105. mov  (8) mbc_result.0<1>:ud     0x0:ud          {align1};
  106. mba_start:
  107. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  108. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  109. /* MB A doesn't exist. Zero MV. mba_flag is zero and ref ID = -1 */
  110. (f0.0)  mov  (2)        mba_result.20<1>:w      -1:w    {align1};
  111. (f0.0)  jmpi (1)        mbb_start;
  112. mov  (1) mba_result.0<1>:d      MB_AVAIL                {align1};      
  113. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  114. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     -1:w    {align1};
  115. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  116. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  117. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  118. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  119.  
  120. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  121. send (16)
  122.        mb_ind
  123.        mb_wb.0<1>:ud
  124.         NULL
  125.        data_port(
  126.                OBR_CACHE_TYPE,
  127.                OBR_MESSAGE_TYPE,
  128.                OBR_CONTROL_4,
  129.                OBR_BIND_IDX,
  130.                OBR_WRITE_COMMIT_CATEGORY,
  131.                OBR_HEADER_PRESENT
  132.        )
  133.        mlen 1
  134.        rlen 2
  135.        {align1};
  136.  
  137. /* TODO: RefID is required after multi-references are added */
  138. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  139. (f0.0)   mov (2)        mba_result.20<1>:w                      -1:w    {align1};
  140. (f0.0)   jmpi   (1)     mbb_start;
  141.  
  142. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  143. /* Read MV for MB A */
  144. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  145. send (16)
  146.        mb_ind
  147.        mb_mv0.0<1>:ud
  148.         NULL
  149.        data_port(
  150.                OBR_CACHE_TYPE,
  151.                OBR_MESSAGE_TYPE,
  152.                OBR_CONTROL_8,
  153.                OBR_BIND_IDX,
  154.                OBR_WRITE_COMMIT_CATEGORY,
  155.                OBR_HEADER_PRESENT
  156.        )
  157.        mlen 1
  158.        rlen 4
  159.        {align1};
  160. /* TODO: RefID is required after multi-references are added */
  161. /* MV */
  162. mov        (2)          mba_result.4<1>:ud              mb_mv1.8<2,2,1>:ud      {align1};
  163. mov        (1)          mba_result.16<1>:w              MB_PRED_FLAG            {align1};
  164.  
  165. mbb_start:
  166. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  167. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  168. /* MB B doesn't exist. Zero MV. mba_flag is zero */
  169. /* If MB B doesn't exist, neither MB C nor D exists */
  170. (f0.0)  mov  (2)        mbb_result.20<1>:w      -1:w            {align1};
  171. (f0.0)  mov  (2)        mbc_result.20<1>:w      -1:w            {align1};
  172. (f0.0)  jmpi (1)        mb_mvp_start;
  173. mov  (1) mbb_result.0<1>:d      MB_AVAIL                {align1};      
  174. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  175. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  176. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  177. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  178. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  179. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  180.  
  181. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  182. send (16)
  183.        mb_ind
  184.        mb_wb.0<1>:ud
  185.         NULL
  186.        data_port(
  187.                OBR_CACHE_TYPE,
  188.                OBR_MESSAGE_TYPE,
  189.                OBR_CONTROL_4,
  190.                OBR_BIND_IDX,
  191.                OBR_WRITE_COMMIT_CATEGORY,
  192.                OBR_HEADER_PRESENT
  193.        )
  194.        mlen 1
  195.        rlen 2
  196.        {align1};
  197.  
  198. /* TODO: RefID is required after multi-references are added */
  199. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  200. (f0.0)   mov (2)        mbb_result.20<1>:w                      -1:w    {align1};
  201. (f0.0)   jmpi   (1)     mbc_start;
  202. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  203. /* Read MV for MB B */
  204. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  205. send (16)
  206.        mb_ind
  207.        mb_mv0.0<1>:ud
  208.         NULL
  209.        data_port(
  210.                OBR_CACHE_TYPE,
  211.                OBR_MESSAGE_TYPE,
  212.                OBR_CONTROL_8,
  213.                OBR_BIND_IDX,
  214.                OBR_WRITE_COMMIT_CATEGORY,
  215.                OBR_HEADER_PRESENT
  216.        )
  217.        mlen 1
  218.        rlen 4
  219.        {align1};
  220. /* TODO: RefID is required after multi-references are added */
  221. mov        (2)          mbb_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  222. mov        (1)          mbb_result.16<1>:w              MB_PRED_FLAG            {align1};
  223.  
  224. mbc_start:
  225. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  226. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_C:uw   {align1};
  227. /* MB C doesn't exist. Zero MV. mba_flag is zero */
  228. /* Based on h264 spec the MB D will be replaced if MB C doesn't exist */
  229. (f0.0)  jmpi (1)        mbd_start;
  230. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  231. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  232. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  233. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     1:w     {align1};
  234. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  235. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  236. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  237. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  238.  
  239. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  240. send (16)
  241.        mb_ind
  242.        mb_wb.0<1>:ud
  243.         NULL
  244.        data_port(
  245.                OBR_CACHE_TYPE,
  246.                OBR_MESSAGE_TYPE,
  247.                OBR_CONTROL_4,
  248.                OBR_BIND_IDX,
  249.                OBR_WRITE_COMMIT_CATEGORY,
  250.                OBR_HEADER_PRESENT
  251.        )
  252.        mlen 1
  253.        rlen 2
  254.        {align1};
  255.  
  256. /* TODO: RefID is required after multi-references are added */
  257. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  258. (f0.0)   mov (2)        mbc_result.20<1>:w                      -1:w    {align1};
  259. (f0.0)   jmpi   (1)     mb_mvp_start;
  260. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  261. /* Read MV for MB C */
  262. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  263. send (16)
  264.        mb_ind
  265.        mb_mv0.0<1>:ud
  266.         NULL
  267.        data_port(
  268.                OBR_CACHE_TYPE,
  269.                OBR_MESSAGE_TYPE,
  270.                OBR_CONTROL_8,
  271.                OBR_BIND_IDX,
  272.                OBR_WRITE_COMMIT_CATEGORY,
  273.                OBR_HEADER_PRESENT
  274.        )
  275.        mlen 1
  276.        rlen 4
  277.        {align1};
  278. /* TODO: RefID is required after multi-references are added */
  279. /* Forward MV */
  280. mov        (2)          mbc_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  281. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  282.  
  283. jmpi   (1)    mb_mvp_start;
  284. mbd_start:
  285. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  286. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_D:uw   {align1};
  287. (f0.0)  mov (2) mbc_result.20<1>:w      -1:w    {align1};
  288. (f0.0)  jmpi (1)        mb_mvp_start;
  289. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  290. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  291. add  (2) tmp_reg0.0<1>:w        tmp_reg0.0<2,2,1>:w     -1:w    {align1};
  292. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  293. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  294. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  295. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  296.  
  297. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  298. send (16)
  299.        mb_ind
  300.        mb_wb.0<1>:ud
  301.         NULL
  302.        data_port(
  303.                OBR_CACHE_TYPE,
  304.                OBR_MESSAGE_TYPE,
  305.                OBR_CONTROL_4,
  306.                OBR_BIND_IDX,
  307.                OBR_WRITE_COMMIT_CATEGORY,
  308.                OBR_HEADER_PRESENT
  309.        )
  310.        mlen 1
  311.        rlen 2
  312.        {align1};
  313.  
  314. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  315. (f0.0)   mov (2)        mbc_result.20<1>:w                      -1:w    {align1};
  316. (f0.0)   jmpi   (1)     mb_mvp_start;
  317.  
  318. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  319. /* Read MV for MB D */
  320. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  321. send (16)
  322.        mb_ind
  323.        mb_mv0.0<1>:ub
  324.         NULL
  325.        data_port(
  326.                OBR_CACHE_TYPE,
  327.                OBR_MESSAGE_TYPE,
  328.                OBR_CONTROL_8,
  329.                OBR_BIND_IDX,
  330.                OBR_WRITE_COMMIT_CATEGORY,
  331.                OBR_HEADER_PRESENT
  332.        )
  333.        mlen 1
  334.        rlen 4
  335.        {align1};
  336.  
  337. /* TODO: RefID is required after multi-references are added */
  338.  
  339. /* Forward MV */
  340. mov        (2)          mbc_result.4<1>:ud              mb_mv3.24<2,2,1>:ud     {align1};
  341. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  342.        
  343. mb_mvp_start:
  344. /*TODO: Add the skip prediction */
  345. /* Check whether both MB B and C are inavailable */
  346. add     (1)     tmp_reg0.0<1>:d         mbb_result.0<0,1,0>:d   mbc_result.0<0,1,0>:d   {align1};
  347. cmp.z.f0.0 (1)  null:d                  tmp_reg0.0<0,1,0>:d     0:d     {align1};
  348. (-f0.0) jmpi (1)        mb_median_start;
  349. cmp.nz.f0.0 (1) null:d  mba_result.0<0,1,0>:d           0:d             {align1};
  350. (f0.0)  mov     (1)     mbb_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  351. (f0.0)  mov     (1)     mbc_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  352. (f0.0)  mov     (1)     mbb_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  353. (f0.0)  mov     (1)     mbc_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  354. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud              mba_result.4<0,1,0>:ud  {align1};
  355. (-f0.0) mov     (1)     mb_mvp_ref.0<1>:ud              0:ud                    {align1};
  356. jmpi    (1)     __mb_hwdep_end;
  357.        
  358. mb_median_start:
  359. /* check whether only one neighbour MB has the same ref ID with the current MB */
  360. mov (8) tmp_reg0.0<1>:ud                0:ud            {align1};
  361. cmp.z.f0.0      (1)     null:d  mba_result.20<0,1,0>:w  0:w     {align1};
  362. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<0,1,0>:w     1:w     {align1};
  363. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mba_result.4<0,1,0>:ud  {align1};
  364. cmp.z.f0.0      (1)     null:d  mbb_result.20<0,1,0>:w  0:w     {align1};
  365. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<0,1,0>:w     1:w     {align1};
  366. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbb_result.4<0,1,0>:ud  {align1};
  367. cmp.z.f0.0      (1)     null:d  mbc_result.20<0,1,0>:w  0:w     {align1};
  368. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<0,1,0>:w     1:w     {align1};
  369. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbc_result.4<0,1,0>:ud  {align1};
  370. cmp.e.f0.0      (1)     null:d  tmp_reg0.0<0,1,0>:w      1:w    {align1};
  371. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud      tmp_reg0.4<0,1,0>:ud    {align1};
  372. (f0.0)  jmpi (1)  __mb_hwdep_end;
  373.  
  374. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.4<0,1,0>:w   {align1};
  375. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.4<0,1,0>:w   {align1};
  376. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.4<0,1,0>:w   {align1};
  377. SAVE_RET        {align1};
  378.  jmpi   (1)     word_imedian;
  379. mov     (1)     mb_mvp_ref.0<1>:w               RET_ARG<0,1,0>:w        {align1};
  380. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.6<0,1,0>:w   {align1};
  381. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.6<0,1,0>:w   {align1};
  382. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.6<0,1,0>:w   {align1};
  383. SAVE_RET        {align1};
  384. jmpi    (1)     word_imedian;
  385. mov     (1)     mb_mvp_ref.2<1>:w               RET_ARG<0,1,0>:w        {align1};
  386.  
  387. __mb_hwdep_end:
  388. asr     (2)     mb_ref_win.0<1>:w       mb_mvp_ref.0<2,2,1>:w   2:w     {align1};
  389. add     (2)     mb_ref_win.8<1>:w       mb_ref_win.0<2,2,1>:w   3:w     {align1};
  390. and     (2)     mb_ref_win.16<1>:uw     mb_ref_win.8<2,2,1>:uw  0xFFFC:uw {align1};
  391. /* m2, get the MV/Mb cost passed from constant buffer when
  392. spawning thread by MEDIA_OBJECT */      
  393. mov (8) vme_m2<1>:UD            r1.0<8,8,1>:UD {align1};
  394.  
  395. mov (8) vme_msg_2<1>:UD         vme_m2.0<8,8,1>:UD {align1};
  396.  
  397. /* m3 FWD/BWD cost center*/
  398. mov (8) vme_msg_3<1>:UD         0x0:UD {align1};               
  399.  
  400. /* m4 skip center*/
  401. mov (8) vme_msg_4<1>:UD         0x0:UD {align1};               
  402.  
  403. /* m5 */
  404. mov  (1) INEP_ROW.0<1>:UD       0x0:UD {align1};
  405. and  (1) INEP_ROW.4<1>:UD       INEP_ROW.4<0,1,0>:UD            0xFF000000:UD {align1};
  406. mov  (8) vme_msg_5<1>:UD         INEP_ROW.0<8,8,1>:UD {align1};
  407.  
  408.  
  409. /* Use the Luma mode */
  410. mov  (1) tmp_reg0.0<1>:UW       LUMA_INTRA_MODE:UW {align1};
  411. mov  (1) vme_msg_5.5<1>:UB      tmp_reg0.0<0,1,0>:UB {align1};
  412.  
  413. /* m6 */        
  414. mov  (8) vme_msg_6<1>:UD         0x0:UD {align1};
  415. mov (16) vme_msg_6.0<1>:UB       INEP_COL0.3<32,8,4>:UB {align1};
  416. mov  (1) vme_msg_6.16<1>:UD      INTRA_PREDICTORE_MODE {align1};
  417.  
  418. /* the penalty for Intra mode */
  419. mov  (1) vme_msg_6.28<1>:UD     0x010101:UD {align1};
  420. mov  (1) vme_msg_6.20<1>:UW      CHROMA_ROW.6<0,1,0>:UW {align1};
  421.  
  422.  
  423. /* m7 */
  424.  
  425. mov  (4) vme_msg_7.16<1>:UD      CHROMA_ROW.8<4,4,1>:UD {align1};
  426. mov  (8) vme_msg_7.0<1>:UW       CHROMA_COL.2<16,8,2>:UW {align1};
  427.  
  428. /*
  429. * SIC VME message
  430. */
  431.  
  432. /* m1 */
  433. mov  (1) intra_flag<1>:UW       0x0:UW {align1}                     ;
  434. and.z.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
  435. (f0.0) mov  (1) intra_part_mask_ub<1>:UB  LUMA_INTRA_8x8_DISABLE {align1};
  436.  
  437. /* assign MB intra struct from the thread payload*/
  438. mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
  439.  
  440. /* Disable DC HAAR component when calculating HARR SATD block */
  441. mov  (1) tmp_reg0.0<1>:UW       DC_HARR_DISABLE:UW              {align1};
  442. mov  (1) vme_m1.30<1>:UB        tmp_reg0.0<0,1,0>:UB  {align1};
  443. mov  (8) vme_msg_1<1>:UD        vme_m1.0<8,8,1>:UD {align1};
  444.  
  445. /* m0 */        
  446. mov  (1) vme_m0.12<1>:UD        INTRA_SAD_HAAR:UD {align1};    /* 16x16 Source, Intra_harr */
  447. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  448.  
  449. /* after verification it will be passed by using payload */
  450. send (8)
  451.        vme_msg_ind
  452.        vme_wb<1>:UD
  453.        null
  454.        cre(
  455.                BIND_IDX_VME,
  456.                VME_SIC_MESSAGE_TYPE
  457.        )
  458.        mlen sic_vme_msg_length
  459.        rlen vme_wb_length
  460.        {align1};
  461. /*
  462. * Oword Block Write message
  463. */
  464. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  465.        
  466. mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
  467. mov  (1) msg_reg1.4<1>:UD       vme_wb.16<0,1,0>:UD     {align1};
  468. mov  (1) msg_reg1.8<1>:UD       vme_wb.20<0,1,0>:UD     {align1};
  469. mov  (1) msg_reg1.12<1>:UD      vme_wb.24<0,1,0>:UD     {align1};
  470.  
  471. /* Distortion, Intra (17-16), */
  472. mov  (1) msg_reg1.16<1>:UW      vme_wb.12<0,1,0>:UW     {align1};
  473.  
  474. mov  (1) msg_reg1.20<1>:UD      vme_wb.8<0,1,0>:UD     {align1};
  475. /* VME clock counts */
  476. mov  (1) msg_reg1.24<1>:UD      vme_wb.28<0,1,0>:UD     {align1};
  477.  
  478. mov  (1) msg_reg1.28<1>:UD      obw_m0.8<0,1,0>:UD     {align1};
  479.  
  480. /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
  481. send (16)
  482.        msg_ind
  483.        obw_wb
  484.        null
  485.        data_port(
  486.                OBW_CACHE_TYPE,
  487.                OBW_MESSAGE_TYPE,
  488.                OBW_CONTROL_2,
  489.                OBW_BIND_IDX,
  490.                OBW_WRITE_COMMIT_CATEGORY,
  491.                OBW_HEADER_PRESENT
  492.        )
  493.        mlen 2
  494.        rlen obw_wb_length
  495.        {align1};
  496.  
  497. /* IME search */
  498. cmp.z.f0.0 (1)          null<1>:uw      quality_level_ub<0,1,0>:ub              LOW_QUALITY_LEVEL:uw   {align1};
  499. (f0.0) jmpi (1) __low_quality_search;
  500.  
  501. __high_quality_search:
  502. /* M3/M4 search path */
  503. mov  (1) vme_msg_3.0<1>:UD      0x01010101:UD {align1};
  504. mov  (1) vme_msg_3.4<1>:UD      0x10010101:UD {align1};
  505. mov  (1) vme_msg_3.8<1>:UD      0x0F0F0F0F:UD {align1};
  506. mov  (1) vme_msg_3.12<1>:UD     0x100F0F0F:UD {align1};
  507. mov  (1) vme_msg_3.16<1>:UD     0x01010101:UD {align1};
  508. mov  (1) vme_msg_3.20<1>:UD     0x10010101:UD {align1};
  509. mov  (1) vme_msg_3.24<1>:UD     0x0F0F0F0F:UD {align1};
  510. mov  (1) vme_msg_3.28<1>:UD     0x100F0F0F:UD {align1};
  511. mov  (1) vme_msg_4.0<1>:UD      0x01010101:UD {align1};
  512. mov  (1) vme_msg_4.4<1>:UD      0x10010101:UD {align1};
  513. mov  (1) vme_msg_4.8<1>:UD      0x0F0F0F0F:UD {align1};
  514. mov  (1) vme_msg_4.12<1>:UD     0x000F0F0F:UD {align1};
  515. mov  (4) vme_msg_4.16<1>:UD     0x0:UD {align1};
  516.  
  517. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1};    /* 16x16 Source, harr */
  518. mov  (1) vme_m0.22<1>:UW        REF_REGION_SIZE {align1};         /* Reference Width&Height, 48x40 */
  519. mov  (1) vme_m0.0<1>:W          -16:W                   {align1};
  520. mov  (1) vme_m0.2<1>:W          -12:W                   {align1};
  521.  
  522. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  523. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       12:w    {align1};
  524. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  525. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       8:w     {align1};
  526. jmpi (1) __vme_msg;
  527.  
  528. __low_quality_search:
  529. /* M3/M4 search path */
  530. mov  (1) vme_msg_3.0<1>:UD      0x10010101:UD {align1};
  531. mov  (1) vme_msg_3.4<1>:UD      0x100F0F0F:UD {align1};
  532. mov  (1) vme_msg_3.8<1>:UD      0x10010101:UD {align1};
  533. mov  (1) vme_msg_3.12<1>:UD     0x000F0F0F:UD {align1};
  534. mov  (4) vme_msg_3.16<1>:UD     0x0:UD {align1};
  535. mov  (8) vme_msg_4.16<1>:UD     0x0:UD {align1};
  536.  
  537. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1};    /* 16x16 Source, harr */
  538. mov  (1) vme_m0.22<1>:UW        MIN_REF_REGION_SIZE {align1};         /* Reference Width&Height, 32x32 */
  539. mov  (1) vme_m0.0<1>:W          -8:W                    {align1};
  540. mov  (1) vme_m0.2<1>:W          -8:W                    {align1};
  541.  
  542. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  543. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       4:w     {align1};
  544. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  545. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       4:w     {align1};
  546.  
  547. __vme_msg:
  548. mov  (1) vme_m0.4<1>:UD         vme_m0.0<0,1,0>:UD      {align1};
  549. add  (2) vme_m0.0<1>:w          vme_m0.0<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  550. add  (2) vme_m0.4<1>:w          vme_m0.4<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  551. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  552.  
  553. mov  (1) vme_m1.0<1>:UD         ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
  554. /* the Max MV number is passed by constant buffer */
  555. mov  (1) vme_m1.4<1>:UB         r4.28<0,1,0>:UB {align1};          
  556. mov  (1) vme_m1.8<1>:UD         START_CENTER + SEARCH_PATH_LEN:UD {align1};
  557. mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD {align1};
  558.  
  559. /* Setup the Cost center */
  560. /* currently four 8x8 share the same cost center */
  561. mov  (4) vme_m3.0<2>:ud         mb_mvp_ref.0<0,1,0>:ud  {align1};
  562. mov  (4) vme_m3.4<2>:ud         mb_mvp_ref.0<0,1,0>:ud  {align1};
  563.  
  564. mov (8) vme_msg_3<1>:UD         vme_m3.0<8,8,1>:UD {align1};
  565. mov (8) vme_msg_2<1>:UD         vme_m2.0<8,8,1>:UD {align1};
  566.  
  567. /* M4/M5 search path */
  568. mov  (1) vme_msg_4.0<1>:UD      0x01010101:UD {align1};
  569. mov  (1) vme_msg_4.4<1>:UD      0x10010101:UD {align1};
  570. mov  (1) vme_msg_4.8<1>:UD      0x0F0F0F0F:UD {align1};
  571. mov  (1) vme_msg_4.12<1>:UD     0x100F0F0F:UD {align1};
  572. mov  (1) vme_msg_4.16<1>:UD     0x01010101:UD {align1};
  573. mov  (1) vme_msg_4.20<1>:UD     0x10010101:UD {align1};
  574. mov  (1) vme_msg_4.24<1>:UD     0x0F0F0F0F:UD {align1};
  575. mov  (1) vme_msg_4.28<1>:UD     0x100F0F0F:UD {align1};
  576.  
  577. mov  (1) vme_msg_5.0<1>:UD      0x01010101:UD {align1};
  578. mov  (1) vme_msg_5.4<1>:UD      0x10010101:UD {align1};
  579. mov  (1) vme_msg_5.8<1>:UD      0x0F0F0F0F:UD {align1};
  580. mov  (1) vme_msg_5.12<1>:UD     0x000F0F0F:UD {align1};
  581.  
  582. mov  (4) vme_msg_5.16<1>:UD     0x0:UD {align1};
  583.  
  584. send (8)
  585.        vme_msg_ind
  586.        vme_wb<1>:UD
  587.        null
  588.        vme(
  589.                BIND_IDX_VME,
  590.                0,
  591.                0,
  592.                VME_IME_MESSAGE_TYPE
  593.        )
  594.        mlen ime_vme_msg_length
  595.        rlen vme_wb_length {align1};
  596.  
  597. /* Set Macroblock-shape/mode for FBR */
  598.  
  599. mov  (1) vme_m2.20<1>:UD        0x0:UD {align1};
  600. mov  (1) vme_m2.21<1>:UB        vme_wb.25<0,1,0>:UB     {align1};
  601. mov  (1) vme_m2.22<1>:UB        vme_wb.26<0,1,0>:UB     {align1};
  602.  
  603. and  (1) tmp_reg0.0<1>:UW       vme_wb.0<0,1,0>:UW      0x03:UW {align1};
  604. mov  (1) vme_m2.20<1>:UB        tmp_reg0.0<0,1,0>:UB    {align1};
  605.  
  606. /* Send FBR message into CRE */
  607.  
  608. mov  (8) vme_msg_4.0<1>:UD       vme_wb1.0<8,8,1>:UD {align1};
  609. mov  (8) vme_msg_5.0<1>:ud       vme_wb2.0<8,8,1>:ud {align1};
  610. mov  (8) vme_msg_6.0<1>:ud       vme_wb3.0<8,8,1>:ud {align1};
  611. mov  (8) vme_msg_7.0<1>:ud       vme_wb4.0<8,8,1>:ud {align1};                
  612.  
  613. mov  (1) vme_m0.12<1>:UD        INTER_SAD_HAAR + SUB_PEL_MODE_QUARTER + FBR_BME_DISABLE:UD {align1};    /* 16x16 Source, 1/4 pixel, harr, BME disable */
  614. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD  {align1};
  615. mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD  {align1};
  616.  
  617. mov  (8) vme_msg_2.0<1>:UD              vme_m2.0<8,8,1>:UD      {align1};
  618. mov  (8) vme_msg_3.0<1>:UD              vme_m3.0<8,8,1>:UD      {align1};
  619.  
  620. /* after verification it will be passed by using payload */
  621. send (8)
  622.        vme_msg_ind
  623.        vme_wb<1>:UD
  624.        null
  625.        cre(
  626.                BIND_IDX_VME,
  627.                VME_FBR_MESSAGE_TYPE
  628.        )
  629.        mlen fbr_vme_msg_length
  630.        rlen vme_wb_length
  631.        {align1};
  632.  
  633. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x02:UD {align1};
  634. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  635. /* write FME info */
  636. mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
  637.  
  638. mov  (1) msg_reg1.4<1>:UD       vme_wb.24<0,1,0>:UD     {align1};
  639. /* Inter distortion of FME */
  640. mov  (1) msg_reg1.8<1>:UD       vme_wb.8<0,1,0>:UD     {align1};
  641.  
  642. mov  (1) msg_reg1.12<1>:UD      vme_m2.20<0,1,0>:UD {align1};
  643.  
  644. /* bind index 3, write  oword (16bytes), msg type: 8(OWord Block Write) */
  645. send (16)
  646.        msg_ind
  647.        obw_wb
  648.        null
  649.        data_port(
  650.                OBW_CACHE_TYPE,
  651.                OBW_MESSAGE_TYPE,
  652.                OBW_CONTROL_0,
  653.                OBW_BIND_IDX,
  654.                OBW_WRITE_COMMIT_CATEGORY,
  655.                OBW_HEADER_PRESENT
  656.        )
  657.        mlen 2
  658.        rlen obw_wb_length
  659.        {align1};
  660.  
  661. /* Write FME/BME MV */
  662. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x01:UD {align1};
  663. mov  (8) msg_reg0.0<1>:UD       obw_m0.0<8,8,1>:UD {align1};
  664.  
  665.  
  666. mov  (8) msg_reg1.0<1>:UD       vme_wb1.0<8,8,1>:UD {align1};
  667. mov  (8) msg_reg2.0<1>:ud       vme_wb2.0<8,8,1>:ud {align1};
  668. mov  (8) msg_reg3.0<1>:ud       vme_wb3.0<8,8,1>:ud {align1};
  669. mov  (8) msg_reg4.0<1>:ud       vme_wb4.0<8,8,1>:ud {align1};                
  670. /* bind index 3, write  8 oword (128 bytes), msg type: 8(OWord Block Write) */
  671. send (16)
  672.        msg_ind
  673.        obw_wb
  674.        null
  675.        data_port(
  676.                OBW_CACHE_TYPE,
  677.                OBW_MESSAGE_TYPE,
  678.                OBW_CONTROL_8,
  679.                OBW_BIND_IDX,
  680.                OBW_WRITE_COMMIT_CATEGORY,
  681.                OBW_HEADER_PRESENT
  682.        )
  683.        mlen 5
  684.        rlen obw_wb_length
  685.        {align1};
  686.  
  687. /* Write FME/BME RefID */
  688. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x08:UD {align1};
  689. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  690.  
  691. mov  (8) msg_reg1.0<1>:UD       vme_wb6.0<8,8,1>:UD {align1};
  692.  
  693. /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
  694. send (16)
  695.        msg_ind
  696.        obw_wb
  697.        null
  698.        data_port(
  699.                OBW_CACHE_TYPE,
  700.                OBW_MESSAGE_TYPE,
  701.                OBW_CONTROL_2,
  702.                OBW_BIND_IDX,
  703.                OBW_WRITE_COMMIT_CATEGORY,
  704.                OBW_HEADER_PRESENT
  705.        )
  706.        mlen 2
  707.        rlen obw_wb_length
  708.        {align1};
  709.  
  710. /* Issue message fence so that the previous write message is committed */
  711. send (16)
  712.        mb_ind
  713.        mb_wb.0<1>:ud
  714.         NULL
  715.        data_port(
  716.                OBR_CACHE_TYPE,
  717.                OBR_MESSAGE_FENCE,
  718.                OBR_MF_COMMIT,
  719.                OBR_BIND_IDX,
  720.                OBR_WRITE_COMMIT_CATEGORY,
  721.                OBR_HEADER_PRESENT
  722.        )
  723.        mlen 1
  724.        rlen 1
  725.        {align1};
  726.  
  727. __EXIT:
  728. /*
  729. * kill thread
  730. */        
  731. mov  (8) ts_msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
  732. send (16) ts_msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
  733.  
  734.  
  735.         nop             ;
  736.         nop             ;
  737. /* Compare three word data to get the min value */
  738. word_imin:
  739.         cmp.le.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  740.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  741.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  742.         cmp.le.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  743.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  744.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  745.         RETURN          {align1};      
  746.        
  747. /* Compare three word data to get the max value */
  748. word_imax:
  749.         cmp.ge.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  750.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  751.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  752.         cmp.ge.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  753.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  754.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  755.         RETURN          {align1};      
  756.        
  757. word_imedian:
  758.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.4<0,1,0>:w {align1};
  759.         (f0.0)  jmpi (1) cmp_a_ge_b;
  760.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  761.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  762.         (f0.0) jmpi (1) cmp_end;
  763.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  764.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  765.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  766.         jmpi (1) cmp_end;
  767. cmp_a_ge_b:
  768.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  769.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  770.         (f0.0) jmpi (1) cmp_end;
  771.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  772.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  773.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  774. cmp_end:
  775.         RETURN  {align1};
  776.  
  777.