Subversion Repositories Kolibri OS

Rev

Blame | Last modification | View Log | RSS feed

  1. /*
  2.  * Copyright © <2010>, Intel Corporation.
  3.  *
  4.  * This program is licensed under the terms and conditions of the
  5.  * Eclipse Public License (EPL), version 1.0.  The full text of the EPL is at
  6.  * http://www.opensource.org/licenses/eclipse-1.0.php.
  7.  *
  8.  */
  9. // Modual name: IntraFrame.asm
  10. //
  11. // Make intra predition estimation for Intra frame
  12. //
  13.  
  14. //
  15. //  Now, begin source code....
  16. //
  17.  
  18. /*
  19.  * __START
  20.  */
  21. __INTER_START:
  22. mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  23. mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  24. mov  (16) tmp_reg3.0<1>:UD      0x0:UD {align1};
  25.  
  26. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  27. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  28. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  29. mov  (1) read0_header.8<1>:UD   BLOCK_32X1 {align1};
  30. mov  (1) read0_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  31.  
  32. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  33. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  34. mov  (1) read1_header.8<1>:UD   BLOCK_4X16 {align1};
  35. mov  (1) read1_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  36.        
  37. shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* Source =  (x, y) * 16 */
  38.  
  39. cmp.z.f0.0 (1)  null<1>:uw      quality_level_ub<0,1,0>:ub              LOW_QUALITY_LEVEL:uw   {align1};
  40. (f0.0) jmpi (1) __low_quality_search;
  41.  
  42. __high_quality_search:
  43. #ifdef DEV_SNB
  44. shl  (2) vme_m0.0<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    
  45. add  (1) vme_m0.0<1>:W          vme_m0.0<0,1,0>:W -16:W {align1};               /* Reference = (x-16,y-12)-(x+32,y+24) */
  46. add  (1) vme_m0.2<1>:W          vme_m0.2<0,1,0>:W -12:W {align1};
  47. #else
  48. mov  (1) vme_m0.0<1>:W          -16:W {align1} ;                /* Reference = (x-16,y-12)-(x+32,y+24) */
  49. mov  (1) vme_m0.2<1>:W          -12:W {align1} ;
  50. #endif
  51.        
  52. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR + SUB_PEL_MODE_QUARTER:UD {align1};    /* 16x16 Source, 1/4 pixel, harr */
  53. mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  54. mov  (1) vme_m0.22<1>:UW        REF_REGION_SIZE {align1};               /* Reference Width&Height, 48x40 */
  55. jmpi __vme_msg1;
  56.  
  57.  
  58. __low_quality_search:
  59. #ifdef DEV_SNB
  60. shl  (2) vme_m0.0<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    
  61. add  (1) vme_m0.0<1>:W          vme_m0.0<0,1,0>:W -8:W {align1};
  62. add  (1) vme_m0.2<1>:W          vme_m0.2<0,1,0>:W -8:W {align1};
  63. #else
  64. mov  (1) vme_m0.0<1>:W          -8:W {align1} ;
  65. mov  (1) vme_m0.2<1>:W          -8:W {align1} ;
  66. #endif
  67.        
  68. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR + SUB_PEL_MODE_HALF:UD {align1};    /* 16x16 Source, 1/2 pixel, harr */
  69. mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  70. mov  (1) vme_m0.22<1>:UW        MIN_REF_REGION_SIZE {align1};               /* Reference Width&Height, 32x32 */
  71.  
  72. __vme_msg1:
  73. mov  (1) vme_m1.0<1>:UD         ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
  74. mov  (1) vme_m1.4<1>:UD         FB_PRUNING_ENABLE:UD {align1};
  75. /* MV num is passed by constant buffer. R4.28 */
  76. mov  (1) vme_m1.4<1>:UB         r4.28<0,1,0>:UB {align1};
  77. mov  (1) vme_m1.8<1>:UD         START_CENTER + SEARCH_PATH_LEN:UD {align1};
  78.  
  79. mul  (1) obw_m0.8<1>:UD         w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
  80. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
  81. mul  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
  82. mov  (1) obw_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  83.  
  84. __VME_LOOP:    
  85.  
  86. /*
  87.  * Media Read Message -- fetch neighbor edge pixels
  88.  */
  89. /* ROW */
  90. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  91. send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  92.  
  93. /* COL */
  94. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  95. send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  96.        
  97. /*
  98.  * VME message
  99.  */
  100. /* m0 */
  101. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  102.        
  103. /* m1 */
  104. mov  (1) intra_flag<1>:UW       0x0:UW {align1}                     ;
  105. and.z.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
  106. (f0.0) mov  (1) intra_part_mask_ub<1>:UB  LUMA_INTRA_8x8_DISABLE {align1};
  107.  
  108. cmp.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB 0:UW {align1};                                                   /* X != 0 */
  109. (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_AE {align1};         /* A */
  110.  
  111. cmp.nz.f0.0 (1) null<1>:UW orig_y_ub<0,1,0>:UB 0:UW {align1};                                                   /* Y != 0 */
  112. (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_B {align1};          /* B */
  113.  
  114. mul.nz.f0.0 (1) null<1>:UW orig_x_ub<0,1,0>:UB orig_y_ub<0,1,0>:UB {align1};                                    /* X * Y != 0 */
  115. (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_D {align1};          /* D */
  116.  
  117. add  (1) tmp_x_w<1>:W orig_x_ub<0,1,0>:UB 1:UW {align1};                                                        /* X + 1 */
  118. add  (1) tmp_x_w<1>:W w_in_mb_uw<0,1,0>:UW -tmp_x_w<0,1,0>:W {align1};                                          /* width - (X + 1) */
  119. mul.nz.f0.0 (1) null<1>:UD tmp_x_w<0,1,0>:W orig_y_ub<0,1,0>:UB {align1};                                       /* (width - (X + 1)) * Y != 0 */
  120. (f0.0) add (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB INTRA_PRED_AVAIL_FLAG_C {align1};          /* C */
  121.  
  122. and.nz.f0.0 (1) null<1>:UW slice_edge_ub<0,1,0>:UB 2:UW {align1};
  123. (f0.0) and (1) mb_intra_struct_ub<1>:UB mb_intra_struct_ub<0,1,0>:UB  0xE0 {align1};                            /* slice edge disable B,C,D*/
  124.        
  125. mov  (8) vme_msg_1<1>:UD        vme_m1.0<8,8,1>:UD {align1};
  126.        
  127. /* m2 */        
  128. mov  (8) vme_msg_2<1>:UD        0x0:UD {align1};
  129.  
  130. /* m3 */
  131. mov  (1) INEP_ROW.0<1>:UD       0x0:UD {align1};
  132. and  (1) INEP_ROW.4<1>:UD       INEP_ROW.4<0,1,0>:UD            0xFF000000:UD {align1};
  133. mov  (8) vme_msg_3<1>:UD        INEP_ROW.0<8,8,1>:UD {align1};        
  134.  
  135. /* m4 */
  136. mov  (8) vme_msg_4<1>:UD        0x0 {align1};
  137. mov (16) vme_msg_4.0<1>:UB      INEP_COL0.3<32,8,4>:UB {align1};
  138. mov  (1) vme_msg_4.16<1>:UD     INTRA_PREDICTORE_MODE {align1};
  139.  
  140. send (8)
  141.         vme_msg_ind
  142.         vme_wb
  143.         null
  144.         vme(
  145.                 BIND_IDX_VME,
  146.                 0,
  147.                 0,
  148.                 VME_MESSAGE_TYPE_MIXED
  149.         )
  150.         mlen vme_msg_length
  151.         rlen vme_inter_wb_length
  152.         {align1};
  153. /*
  154.  * Oword Block Write message
  155.  */
  156.  
  157. /* MV pairs */        
  158. mov  (8) msg_reg0.0<1>:UD       obw_m0.0<8,8,1>:UD {align1};
  159.  
  160. #ifdef DEV_SNB        
  161. mov  (16) obw_m1.0<1>:UW        vme_wb1.0<16,16,1>:UB  {align1};
  162. add  (8) obw_m1.0<2>:W          obw_m1.0<16,8,2>:W -64:W {align1};
  163. add  (8) obw_m1.2<2>:W          obw_m1.2<16,8,2>:W -48:W {align1};
  164. mov  (16) obw_m2.0<1>:UW        vme_wb1.16<16,16,1>:UB  {align1};
  165. add  (8) obw_m2.0<2>:W          obw_m2.0<16,8,2>:W -64:W {align1};
  166. add  (8) obw_m2.2<2>:W          obw_m2.2<16,8,2>:W -48:W {align1};
  167. mov  (16) obw_m3.0<1>:UW        vme_wb2.0<16,16,1>:UB  {align1};
  168. add  (8) obw_m3.0<2>:W          obw_m3.0<16,8,2>:W -64:W {align1};
  169. add  (8) obw_m3.2<2>:W          obw_m3.2<16,8,2>:W -48:W {align1};
  170. mov  (16) obw_m4.0<1>:UW        vme_wb2.16<16,16,1>:UB  {align1};
  171. add  (8) obw_m4.0<2>:W          obw_m4.0<16,8,2>:W -64:W {align1};
  172. add  (8) obw_m4.2<2>:W          obw_m4.2<16,8,2>:W -48:W {align1};
  173. #else
  174. mov  (8) obw_m1.0<1>:ud         vme_wb1.0<8,8,1>:ud {align1};
  175. mov  (8) obw_m2.0<1>:ud         vme_wb2.0<8,8,1>:ud {align1};
  176. mov  (8) obw_m3.0<1>:ud         vme_wb3.0<8,8,1>:ud {align1};
  177. mov  (8) obw_m4.0<1>:ud         vme_wb4.0<8,8,1>:ud {align1};                
  178. #endif      
  179.        
  180. mov  (8) msg_reg1.0<1>:UD       obw_m1.0<8,8,1>:UD   {align1};
  181.  
  182. mov  (8) msg_reg2.0<1>:UD       obw_m2.0<8,8,1>:UD   {align1};
  183.  
  184. mov  (8) msg_reg3.0<1>:UD       obw_m3.0<8,8,1>:UD   {align1};
  185.  
  186. mov  (8) msg_reg4.0<1>:UD       obw_m4.0<8,8,1>:UD   {align1};                
  187.  
  188. /* bind index 3, write 8 oword, msg type: 8(OWord Block Write) */
  189. send (16)
  190.         msg_ind
  191.         obw_wb
  192.         null
  193.         data_port(
  194.                 OBW_CACHE_TYPE,
  195.                 OBW_MESSAGE_TYPE,
  196.                 OBW_CONTROL_4,
  197.                 OBW_BIND_IDX,
  198.                 OBW_WRITE_COMMIT_CATEGORY,
  199.                 OBW_HEADER_PRESENT
  200.         )
  201.         mlen 5
  202.         rlen obw_wb_length
  203.         {align1};
  204.  
  205. /* other info */        
  206. add             (1)     msg_reg0.8<1>:UD        obw_m0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1} ;
  207.  
  208. and.z.f0.0      (1)     null<1>:ud              vme_wb0.0<0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
  209.  
  210. (-f0.0)jmpi     (1)     __INTRA_INFO ;
  211.  
  212. __INTER_INFO:  
  213. mov             (1)     tmp_uw1<1>:uw           0:uw {align1} ;
  214. mov             (1)     tmp_ud1<1>:ud           0:ud {align1} ;
  215. (f0.0)and       (1)     tmp_uw1<1>:uw           vme_wb0.2<0,1,0>:uw     MV32_BIT_MASK:uw {align1} ;
  216. (f0.0)shr       (1)     tmp_uw1<1>:uw           tmp_uw1<1>:uw           MV32_BIT_SHIFT:uw {align1} ;
  217. (f0.0)mul       (1)     tmp_ud1<1>:ud           tmp_uw1<0,1,0>:uw       96:uw {align1} ;
  218. (f0.0)add       (1)     tmp_ud1<1>:ud           tmp_ud1<0,1,0>:ud       32:uw {align1} ;
  219. (f0.0)shl       (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       MFC_MV32_BIT_SHIFT:uw {align1} ;
  220. (f0.0)add       (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       MVSIZE_UW_BASE:uw {align1} ;
  221. add             (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       CBP_DC_YUV_UW:uw {align1} ;
  222.  
  223. mov             (1)     msg_reg1.0<1>:uw        vme_wb0.0<0,1,0>:uw     {align1} ;
  224. mov             (1)     msg_reg1.2<1>:uw        tmp_uw1<0,1,0>:uw       {align1} ;
  225. mov             (1)     msg_reg1.4<1>:UD        vme_wb0.28<0,1,0>:UD    {align1};
  226. mov             (1)     msg_reg1.8<1>:ud        tmp_ud1<0,1,0>:ud       {align1} ;
  227.  
  228. jmpi            (1)     __OUTPUT_INFO ;
  229.        
  230. __INTRA_INFO:
  231. mov             (1)     msg_reg1.0<1>:UD        vme_wb.0<0,1,0>:UD      {align1};
  232. mov             (1)     msg_reg1.4<1>:UD        vme_wb.16<0,1,0>:UD     {align1};
  233. mov             (1)     msg_reg1.8<1>:UD        vme_wb.20<0,1,0>:UD     {align1};
  234. mov             (1)     msg_reg1.12<1>:UD       vme_wb.24<0,1,0>:UD     {align1};
  235.  
  236. __OUTPUT_INFO:  
  237. /* bind index 3, write 1 oword, msg type: 8(OWord Block Write) */
  238. send (16)
  239.         msg_ind
  240.         obw_wb
  241.         null
  242.         data_port(
  243.                 OBW_CACHE_TYPE,
  244.                 OBW_MESSAGE_TYPE,
  245.                 OBW_CONTROL_0,
  246.                 OBW_BIND_IDX,
  247.                 OBW_WRITE_COMMIT_CATEGORY,
  248.                 OBW_HEADER_PRESENT
  249.         )
  250.         mlen 2
  251.         rlen obw_wb_length
  252.         {align1};
  253.  
  254. add             (1)     orig_x_ub<1>:ub         orig_x_ub<0,1,0>:ub             1:uw {align1} ;
  255. add             (1)     vme_m0.8<1>:UW          vme_m0.8<0,1,0>:UW              16:UW {align1};    /* X += 16 */
  256. #ifdef DEV_SNB        
  257. add             (1)     vme_m0.0<1>:W           vme_m0.0<0,1,0>:W               16:W {align1};     /* X += 16 */
  258. #endif
  259.  
  260. cmp.e.f0.0      (1)     null<1>:uw              w_in_mb_uw<0,1,0>:uw            orig_x_ub<0,1,0>:ub {align1};
  261. /* (0, y + 1) */        
  262. (f0.0)mov       (1)     orig_x_ub<1>:ub         0:uw {align1} ;
  263. (f0.0)add       (1)     orig_y_ub<1>:ub orig_y_ub<0,1,0>:ub             1:uw {align1} ;
  264. (f0.0)mov       (1)     vme_m0.8<1>:uw          0:uw {align1} ;
  265. (f0.0)add       (1)     vme_m0.10<1>:uw         vme_m0.10<0,1,0>:uw             16:uw {align1} ;
  266. #ifdef DEV_SNB        
  267. (f0.0)mov       (1)     vme_m0.0<1>:w           -16:W {align1};                 /* Reference = (x-16,y-12)-(x+32,y+24) */
  268. (f0.0)add       (1)     vme_m0.2<1>:w           vme_m0.2<0,1,0>:w               16:w {align1};
  269. #endif
  270.  
  271. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  272. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  273. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  274.  
  275. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  276. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  277.  
  278. shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* Source =  (x, y) * 16 */
  279.  
  280. add             (1)     obw_m0.8<1>:UD          obw_m0.8<0,1,0>:UD              INTER_VME_OUTPUT_IN_OWS:UW {align1} ;
  281.        
  282. add.z.f0.1      (1)     num_macroblocks<1>:w    num_macroblocks<0,1,0>:w        -1:w {align1} ;
  283. (-f0.1)jmpi     (1)     __VME_LOOP ;
  284.        
  285. __EXIT:
  286.        
  287. /*
  288.  * kill thread
  289.  */        
  290. mov  (8) msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
  291. send (16) msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
  292.