Subversion Repositories Kolibri OS

Rev

Blame | Last modification | View Log | RSS feed

  1. /*
  2.  * Copyright © <2013>, Intel Corporation.
  3.  *
  4.  * This program is licensed under the terms and conditions of the
  5.  * Eclipse Public License (EPL), version 1.0.  The full text of the EPL is at
  6.  * http://www.opensource.org/licenses/eclipse-1.0.php.
  7.  *
  8.  */
  9. // Modual name: Inter_frame_gen8.asm
  10. //
  11. // Make inter predition estimation for Inter-frame on gen8
  12. //
  13.  
  14. //
  15. //  Now, begin source code....
  16. //
  17.  
  18. #define SAVE_RET        add (1) RETURN_REG<1>:ud   ip:ud        32:ud
  19. #define RETURN          mov (1) ip:ud   RETURN_REG<0,1,0>:ud
  20.  
  21. /*
  22.  * __START
  23.  */
  24. __INTER_START:
  25. mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  26. mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  27. mov  (16) tmp_reg4.0<1>:UD      0x0:UD {align1} ;
  28. mov  (16) tmp_reg6.0<1>:UD      0x0:UD {align1} ;
  29.  
  30. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  31. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  32. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  33. mov  (1) read0_header.8<1>:UD   BLOCK_32X1 {align1};
  34. mov  (1) read0_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  35.  
  36. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  37. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  38. mov  (1) read1_header.8<1>:UD   BLOCK_4X16 {align1};
  39. mov  (1) read1_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  40.        
  41. shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  42. mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  43.  
  44. mul  (1) obw_m0.8<1>:UD         w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
  45. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
  46. mul  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 24:UD {align1};
  47. mov  (1) obw_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  48.        
  49. /*
  50.  * Media Read Message -- fetch Luma neighbor edge pixels
  51.  */
  52. /* ROW */
  53. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  54. send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  55.  
  56. /* COL */
  57. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  58. send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  59.        
  60. /*
  61.  * Media Read Message -- fetch Chroma neighbor edge pixels
  62.  */
  63. /* ROW */
  64. shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 3:UW {align1};    /* x * 16 , y * 8 */
  65. mul  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D  2:W {align1};
  66. add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  67. add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  68. mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};        
  69. send (8) msg_ind CHROMA_ROW<1>:UB null read(BIND_IDX_CBCR, 0, 0, 4) mlen 1 rlen 1 {align1};
  70.  
  71. /* COL */
  72. shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 3:UW {align1};    /* x * 16, y * 8 */
  73. mul  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D  2:W {align1};
  74. add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  75. mov  (1) read1_header.8<1>:UD   BLOCK_8X4 {align1};
  76. mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};                
  77. send (8) msg_ind CHROMA_COL<1>:UB null read(BIND_IDX_CBCR, 0, 0, 4) mlen 1 rlen 1 {align1};
  78.  
  79. mov  (8) mb_mvp_ref.0<1>:ud     0:ud            {align1};
  80. mov  (8) mb_ref_win.0<1>:ud     0:ud            {align1};
  81. and.z.f0.0 (1)          null:uw mb_hwdep<0,1,0>:uw              0x04:uw   {align1};
  82. (f0.0) jmpi (1) __mb_hwdep_end;
  83. /* read back the data for MB A */
  84. /* the layout of MB result is: rx.0(Available). rx.4(MVa), rX.8(MVb), rX.16(Pred_L0 flag),
  85. *  rX.18 (Pred_L1 flag), rX.20(Forward reference ID), rX.22(Backwared reference ID)
  86. */
  87. mov  (8) mba_result.0<1>:ud     0x0:ud          {align1};
  88. mov  (8) mbb_result.0<1>:ud     0x0:ud          {align1};
  89. mov  (8) mbc_result.0<1>:ud     0x0:ud          {align1};
  90. mba_start:
  91. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  92. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  93. /* MB A doesn't exist. Zero MV. mba_flag is zero and ref ID = -1 */
  94. (f0.0)  mov  (2)        mba_result.20<1>:w      -1:w    {align1};
  95. (f0.0)  jmpi (1)        mbb_start;
  96. mov  (1) mba_result.0<1>:d      MB_AVAIL                {align1};      
  97. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  98. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     -1:w    {align1};
  99. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  100. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  101. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  102. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  103.  
  104. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  105. send (16)
  106.        mb_ind
  107.        mb_wb.0<1>:ud
  108.         NULL
  109.        data_port(
  110.                OBR_CACHE_TYPE,
  111.                OBR_MESSAGE_TYPE,
  112.                OBR_CONTROL_4,
  113.                OBR_BIND_IDX,
  114.                OBR_WRITE_COMMIT_CATEGORY,
  115.                OBR_HEADER_PRESENT
  116.        )
  117.        mlen 1
  118.        rlen 2
  119.        {align1};
  120.  
  121. /* TODO: RefID is required after multi-references are added */
  122. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  123. (f0.0)   mov (2)        mba_result.20<1>:w                      -1:w    {align1};
  124. (f0.0)   jmpi   (1)     mbb_start;
  125.  
  126. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  127. /* Read MV for MB A */
  128. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  129. send (16)
  130.        mb_ind
  131.        mb_mv0.0<1>:ud
  132.         NULL
  133.        data_port(
  134.                OBR_CACHE_TYPE,
  135.                OBR_MESSAGE_TYPE,
  136.                OBR_CONTROL_8,
  137.                OBR_BIND_IDX,
  138.                OBR_WRITE_COMMIT_CATEGORY,
  139.                OBR_HEADER_PRESENT
  140.        )
  141.        mlen 1
  142.        rlen 4
  143.        {align1};
  144. /* TODO: RefID is required after multi-references are added */
  145. /* MV */
  146. mov        (2)          mba_result.4<1>:ud              mb_mv1.8<2,2,1>:ud      {align1};
  147. mov        (1)          mba_result.16<1>:w              MB_PRED_FLAG            {align1};
  148.  
  149. mbb_start:
  150. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  151. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  152. /* MB B doesn't exist. Zero MV. mba_flag is zero */
  153. /* If MB B doesn't exist, neither MB C nor D exists */
  154. (f0.0)  mov  (2)        mbb_result.20<1>:w      -1:w            {align1};
  155. (f0.0)  mov  (2)        mbc_result.20<1>:w      -1:w            {align1};
  156. (f0.0)  jmpi (1)        mb_mvp_start;
  157. mov  (1) mbb_result.0<1>:d      MB_AVAIL                {align1};      
  158. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  159. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  160. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  161. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  162. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  163. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  164.  
  165. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  166. send (16)
  167.        mb_ind
  168.        mb_wb.0<1>:ud
  169.         NULL
  170.        data_port(
  171.                OBR_CACHE_TYPE,
  172.                OBR_MESSAGE_TYPE,
  173.                OBR_CONTROL_4,
  174.                OBR_BIND_IDX,
  175.                OBR_WRITE_COMMIT_CATEGORY,
  176.                OBR_HEADER_PRESENT
  177.        )
  178.        mlen 1
  179.        rlen 2
  180.        {align1};
  181.  
  182. /* TODO: RefID is required after multi-references are added */
  183. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  184. (f0.0)   mov (2)        mbb_result.20<1>:w                      -1:w    {align1};
  185. (f0.0)   jmpi   (1)     mbc_start;
  186. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  187. /* Read MV for MB B */
  188. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  189. send (16)
  190.        mb_ind
  191.        mb_mv0.0<1>:ud
  192.         NULL
  193.        data_port(
  194.                OBR_CACHE_TYPE,
  195.                OBR_MESSAGE_TYPE,
  196.                OBR_CONTROL_8,
  197.                OBR_BIND_IDX,
  198.                OBR_WRITE_COMMIT_CATEGORY,
  199.                OBR_HEADER_PRESENT
  200.        )
  201.        mlen 1
  202.        rlen 4
  203.        {align1};
  204. /* TODO: RefID is required after multi-references are added */
  205. mov        (2)          mbb_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  206. mov        (1)          mbb_result.16<1>:w              MB_PRED_FLAG            {align1};
  207.  
  208. mbc_start:
  209. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  210. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_C:uw   {align1};
  211. /* MB C doesn't exist. Zero MV. mba_flag is zero */
  212. /* Based on h264 spec the MB D will be replaced if MB C doesn't exist */
  213. (f0.0)  jmpi (1)        mbd_start;
  214. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  215. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  216. add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
  217. add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     1:w     {align1};
  218. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  219. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  220. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  221. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  222.  
  223. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  224. send (16)
  225.        mb_ind
  226.        mb_wb.0<1>:ud
  227.         NULL
  228.        data_port(
  229.                OBR_CACHE_TYPE,
  230.                OBR_MESSAGE_TYPE,
  231.                OBR_CONTROL_4,
  232.                OBR_BIND_IDX,
  233.                OBR_WRITE_COMMIT_CATEGORY,
  234.                OBR_HEADER_PRESENT
  235.        )
  236.        mlen 1
  237.        rlen 2
  238.        {align1};
  239.  
  240. /* TODO: RefID is required after multi-references are added */
  241. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  242. (f0.0)   mov (2)        mbc_result.20<1>:w                      -1:w    {align1};
  243. (f0.0)   jmpi   (1)     mb_mvp_start;
  244. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  245. /* Read MV for MB C */
  246. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  247. send (16)
  248.        mb_ind
  249.        mb_mv0.0<1>:ud
  250.         NULL
  251.        data_port(
  252.                OBR_CACHE_TYPE,
  253.                OBR_MESSAGE_TYPE,
  254.                OBR_CONTROL_8,
  255.                OBR_BIND_IDX,
  256.                OBR_WRITE_COMMIT_CATEGORY,
  257.                OBR_HEADER_PRESENT
  258.        )
  259.        mlen 1
  260.        rlen 4
  261.        {align1};
  262. /* TODO: RefID is required after multi-references are added */
  263. /* Forward MV */
  264. mov        (2)          mbc_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
  265. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  266.  
  267. jmpi   (1)    mb_mvp_start;
  268. mbd_start:
  269. mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  270. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_D:uw   {align1};
  271. (f0.0)  mov (2) mbc_result.20<1>:w      -1:w    {align1};
  272. (f0.0)  jmpi (1)        mb_mvp_start;
  273. mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};      
  274. mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  275. add  (2) tmp_reg0.0<1>:w        tmp_reg0.0<2,2,1>:w     -1:w    {align1};
  276. mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  277. add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  278. mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD 24:UD {align1};
  279. mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  280.  
  281. /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
  282. send (16)
  283.        mb_ind
  284.        mb_wb.0<1>:ud
  285.         NULL
  286.        data_port(
  287.                OBR_CACHE_TYPE,
  288.                OBR_MESSAGE_TYPE,
  289.                OBR_CONTROL_4,
  290.                OBR_BIND_IDX,
  291.                OBR_WRITE_COMMIT_CATEGORY,
  292.                OBR_HEADER_PRESENT
  293.        )
  294.        mlen 1
  295.        rlen 2
  296.        {align1};
  297.  
  298. cmp.l.f0.0 (1)          null:w  mb_intra_wb.16<0,1,0>:uw        mb_inter_wb.8<0,1,0>:uw {align1};
  299. (f0.0)   mov (2)        mbc_result.20<1>:w                      -1:w    {align1};
  300. (f0.0)   jmpi   (1)     mb_mvp_start;
  301.  
  302. add   (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:ud     3:ud {align1};
  303. /* Read MV for MB D */
  304. /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
  305. send (16)
  306.        mb_ind
  307.        mb_mv0.0<1>:ub
  308.         NULL
  309.        data_port(
  310.                OBR_CACHE_TYPE,
  311.                OBR_MESSAGE_TYPE,
  312.                OBR_CONTROL_8,
  313.                OBR_BIND_IDX,
  314.                OBR_WRITE_COMMIT_CATEGORY,
  315.                OBR_HEADER_PRESENT
  316.        )
  317.        mlen 1
  318.        rlen 4
  319.        {align1};
  320.  
  321. /* TODO: RefID is required after multi-references are added */
  322.  
  323. /* Forward MV */
  324. mov        (2)          mbc_result.4<1>:ud              mb_mv3.24<2,2,1>:ud     {align1};
  325. mov        (1)          mbc_result.16<1>:w              MB_PRED_FLAG            {align1};
  326.        
  327. mb_mvp_start:
  328. /*TODO: Add the skip prediction */
  329. /* Check whether both MB B and C are inavailable */
  330. add     (1)     tmp_reg0.0<1>:d         mbb_result.0<0,1,0>:d   mbc_result.0<0,1,0>:d   {align1};
  331. cmp.z.f0.0 (1)  null:d                  tmp_reg0.0<0,1,0>:d     0:d     {align1};
  332. (-f0.0) jmpi (1)        mb_median_start;
  333. cmp.nz.f0.0 (1) null:d  mba_result.0<0,1,0>:d           0:d             {align1};
  334. (f0.0)  mov     (1)     mbb_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  335. (f0.0)  mov     (1)     mbc_result.4<1>:ud              mba_result.4<0,1,0>:ud  {align1};      
  336. (f0.0)  mov     (1)     mbb_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  337. (f0.0)  mov     (1)     mbc_result.20<1>:uw             mba_result.20<0,1,0>:uw {align1};      
  338. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud              mba_result.4<0,1,0>:ud  {align1};
  339. (-f0.0) mov     (1)     mb_mvp_ref.0<1>:ud              0:ud                    {align1};
  340. jmpi    (1)     __mb_hwdep_end;
  341.        
  342. mb_median_start:
  343. /* check whether only one neighbour MB has the same ref ID with the current MB */
  344. mov (8) tmp_reg0.0<1>:ud                0:ud            {align1};
  345. cmp.z.f0.0      (1)     null:d  mba_result.20<0,1,0>:w  0:w     {align1};
  346. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<0,1,0>:w     1:w     {align1};
  347. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mba_result.4<0,1,0>:ud  {align1};
  348. cmp.z.f0.0      (1)     null:d  mbb_result.20<0,1,0>:w  0:w     {align1};
  349. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<0,1,0>:w     1:w     {align1};
  350. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbb_result.4<0,1,0>:ud  {align1};
  351. cmp.z.f0.0      (1)     null:d  mbc_result.20<0,1,0>:w  0:w     {align1};
  352. (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<0,1,0>:w     1:w     {align1};
  353. (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbc_result.4<0,1,0>:ud  {align1};
  354. cmp.e.f0.0      (1)     null:d  tmp_reg0.0<0,1,0>:w      1:w    {align1};
  355. (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud      tmp_reg0.4<0,1,0>:ud    {align1};
  356. (f0.0)  jmpi (1)  __mb_hwdep_end;
  357.  
  358. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.4<0,1,0>:w   {align1};
  359. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.4<0,1,0>:w   {align1};
  360. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.4<0,1,0>:w   {align1};
  361. SAVE_RET        {align1};
  362.  jmpi   (1)     word_imedian;
  363. mov     (1)     mb_mvp_ref.0<1>:w               RET_ARG<0,1,0>:w        {align1};
  364. mov     (1)     INPUT_ARG0.0<1>:w       mba_result.6<0,1,0>:w   {align1};
  365. mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.6<0,1,0>:w   {align1};
  366. mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.6<0,1,0>:w   {align1};
  367. SAVE_RET        {align1};
  368. jmpi    (1)     word_imedian;
  369. mov     (1)     mb_mvp_ref.2<1>:w               RET_ARG<0,1,0>:w        {align1};
  370.  
  371. __mb_hwdep_end:
  372. asr     (2)     mb_ref_win.0<1>:w       mb_mvp_ref.0<2,2,1>:w   2:w     {align1};
  373. add     (2)     mb_ref_win.8<1>:w       mb_ref_win.0<2,2,1>:w   3:w     {align1};
  374. and     (2)     mb_ref_win.16<1>:uw     mb_ref_win.8<2,2,1>:uw  0xFFFC:uw {align1};
  375. /* m2, get the MV/Mb cost passed from constant buffer when
  376. spawning thread by MEDIA_OBJECT */      
  377. mov (8) vme_m2<1>:UD            r1.0<8,8,1>:UD {align1};
  378.  
  379. mov (8) vme_msg_2<1>:UD         vme_m2.0<8,8,1>:UD {align1};
  380.  
  381. /* m3 FWD/BWD cost center*/
  382. mov (8) vme_msg_3<1>:UD         0x0:UD {align1};               
  383.  
  384. /* m4 skip center*/
  385. mov (8) vme_msg_4<1>:UD         0x0:UD {align1};               
  386.  
  387. /* m5 */
  388. mov  (1) INEP_ROW.0<1>:UD       0x0:UD {align1};
  389. and  (1) INEP_ROW.4<1>:UD       INEP_ROW.4<0,1,0>:UD            0xFF000000:UD {align1};
  390. mov  (8) vme_msg_5<1>:UD         INEP_ROW.0<8,8,1>:UD {align1};
  391.  
  392.  
  393. /* Use the Luma mode */
  394. mov  (1) tmp_reg0.0<1>:UW       LUMA_INTRA_MODE:UW {align1};
  395. mov  (1) vme_msg_5.5<1>:UB      tmp_reg0.0<0,1,0>:UB {align1};
  396.  
  397. /* m6 */        
  398. mov  (8) vme_msg_6<1>:UD         0x0:UD {align1};
  399. mov (16) vme_msg_6.0<1>:UB       INEP_COL0.3<32,8,4>:UB {align1};
  400. mov  (1) vme_msg_6.16<1>:UD      INTRA_PREDICTORE_MODE {align1};
  401.  
  402. /* the penalty for Intra mode */
  403. mov  (1) vme_msg_6.28<1>:UD     0x010101:UD {align1};
  404. mov  (1) vme_msg_6.20<1>:UW      CHROMA_ROW.6<0,1,0>:UW {align1};
  405.  
  406.  
  407. /* m7 */
  408.  
  409. mov  (4) vme_msg_7.16<1>:UD      CHROMA_ROW.8<4,4,1>:UD {align1};
  410. mov  (8) vme_msg_7.0<1>:UW       CHROMA_COL.2<16,8,2>:UW {align1};
  411.  
  412. /*
  413. * SIC VME message
  414. */
  415.  
  416. /* m1 */
  417. mov  (1) intra_flag<1>:UW       0x0:UW {align1}                     ;
  418. and.z.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
  419. (f0.0) mov  (1) intra_part_mask_ub<1>:UB  LUMA_INTRA_8x8_DISABLE {align1};
  420.  
  421. /* assign MB intra struct from the thread payload*/
  422. mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
  423.  
  424. /* Disable DC HAAR component when calculating HARR SATD block */
  425. mov  (1) tmp_reg0.0<1>:UW       DC_HARR_DISABLE:UW              {align1};
  426. mov  (1) vme_m1.30<1>:UB        tmp_reg0.0<0,1,0>:UB  {align1};
  427. mov  (8) vme_msg_1<1>:UD        vme_m1.0<8,8,1>:UD {align1};
  428.  
  429. /* m0 */        
  430. mov  (1) vme_m0.12<1>:UD        INTRA_SAD_HAAR:UD {align1};    /* 16x16 Source, Intra_harr */
  431. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  432.  
  433. /* after verification it will be passed by using payload */
  434. send (8)
  435.        vme_msg_ind
  436.        vme_wb<1>:UD
  437.        null
  438.        cre(
  439.                BIND_IDX_VME,
  440.                VME_SIC_MESSAGE_TYPE
  441.        )
  442.        mlen sic_vme_msg_length
  443.        rlen vme_wb_length
  444.        {align1};
  445. /*
  446. * Oword Block Write message
  447. */
  448. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  449.        
  450. mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
  451. mov  (1) msg_reg1.4<1>:UD       vme_wb.16<0,1,0>:UD     {align1};
  452. mov  (1) msg_reg1.8<1>:UD       vme_wb.20<0,1,0>:UD     {align1};
  453. mov  (1) msg_reg1.12<1>:UD      vme_wb.24<0,1,0>:UD     {align1};
  454.  
  455. /* Distortion, Intra (17-16), */
  456. mov  (1) msg_reg1.16<1>:UW      vme_wb.12<0,1,0>:UW     {align1};
  457.  
  458. mov  (1) msg_reg1.20<1>:UD      vme_wb.8<0,1,0>:UD     {align1};
  459. /* VME clock counts */
  460. mov  (1) msg_reg1.24<1>:UD      vme_wb.28<0,1,0>:UD     {align1};
  461.  
  462. mov  (1) msg_reg1.28<1>:UD      obw_m0.8<0,1,0>:UD     {align1};
  463.  
  464. /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
  465. send (16)
  466.        msg_ind
  467.        obw_wb
  468.        null
  469.        data_port(
  470.                OBW_CACHE_TYPE,
  471.                OBW_MESSAGE_TYPE,
  472.                OBW_CONTROL_2,
  473.                OBW_BIND_IDX,
  474.                OBW_WRITE_COMMIT_CATEGORY,
  475.                OBW_HEADER_PRESENT
  476.        )
  477.        mlen 2
  478.        rlen obw_wb_length
  479.        {align1};
  480.  
  481. /* IME search */
  482. cmp.z.f0.0 (1)          null<1>:uw      quality_level_ub<0,1,0>:ub              LOW_QUALITY_LEVEL:uw   {align1};
  483. (f0.0) jmpi (1) __low_quality_search;
  484.  
  485. __high_quality_search:
  486. /* M3/M4 search path */
  487. mov  (1) vme_msg_3.0<1>:UD      0x01010101:UD {align1};
  488. mov  (1) vme_msg_3.4<1>:UD      0x10010101:UD {align1};
  489. mov  (1) vme_msg_3.8<1>:UD      0x0F0F0F0F:UD {align1};
  490. mov  (1) vme_msg_3.12<1>:UD     0x100F0F0F:UD {align1};
  491. mov  (1) vme_msg_3.16<1>:UD     0x01010101:UD {align1};
  492. mov  (1) vme_msg_3.20<1>:UD     0x10010101:UD {align1};
  493. mov  (1) vme_msg_3.24<1>:UD     0x0F0F0F0F:UD {align1};
  494. mov  (1) vme_msg_3.28<1>:UD     0x100F0F0F:UD {align1};
  495. mov  (1) vme_msg_4.0<1>:UD      0x01010101:UD {align1};
  496. mov  (1) vme_msg_4.4<1>:UD      0x10010101:UD {align1};
  497. mov  (1) vme_msg_4.8<1>:UD      0x0F0F0F0F:UD {align1};
  498. mov  (1) vme_msg_4.12<1>:UD     0x000F0F0F:UD {align1};
  499. mov  (4) vme_msg_4.16<1>:UD     0x0:UD {align1};
  500.  
  501. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1};    /* 16x16 Source, harr */
  502. mov  (1) vme_m0.22<1>:UW        REF_REGION_SIZE {align1};         /* Reference Width&Height, 48x40 */
  503. mov  (1) vme_m0.0<1>:W          -16:W                   {align1};
  504. mov  (1) vme_m0.2<1>:W          -12:W                   {align1};
  505.  
  506. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  507. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       12:w    {align1};
  508. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  509. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       8:w     {align1};
  510. jmpi (1) __vme_msg;
  511.  
  512. __low_quality_search:
  513. /* M3/M4 search path */
  514. mov  (1) vme_msg_3.0<1>:UD      0x10010101:UD {align1};
  515. mov  (1) vme_msg_3.4<1>:UD      0x100F0F0F:UD {align1};
  516. mov  (1) vme_msg_3.8<1>:UD      0x10010101:UD {align1};
  517. mov  (1) vme_msg_3.12<1>:UD     0x000F0F0F:UD {align1};
  518. mov  (4) vme_msg_3.16<1>:UD     0x0:UD {align1};
  519. mov  (8) vme_msg_4.16<1>:UD     0x0:UD {align1};
  520.  
  521. mov  (1) vme_m0.12<1>:UD        SEARCH_CTRL_SINGLE + INTER_PART_MASK + INTER_SAD_HAAR:UD {align1};    /* 16x16 Source, harr */
  522. mov  (1) vme_m0.22<1>:UW        MIN_REF_REGION_SIZE {align1};         /* Reference Width&Height, 32x32 */
  523. mov  (1) vme_m0.0<1>:W          -8:W                    {align1};
  524. mov  (1) vme_m0.2<1>:W          -8:W                    {align1};
  525.  
  526. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  527. (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       4:w     {align1};
  528. and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
  529. (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       4:w     {align1};
  530.  
  531. __vme_msg:
  532. mov  (1) vme_m0.4<1>:UD         vme_m0.0<0,1,0>:UD      {align1};
  533. add  (2) vme_m0.0<1>:w          vme_m0.0<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  534. add  (2) vme_m0.4<1>:w          vme_m0.4<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
  535. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
  536.  
  537. mov  (1) vme_m1.0<1>:UD         ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
  538. /* the Max MV number is passed by constant buffer */
  539. mov  (1) vme_m1.4<1>:UB         r4.28<0,1,0>:UB {align1};          
  540. mov  (1) vme_m1.8<1>:UD         START_CENTER + SEARCH_PATH_LEN:UD {align1};
  541. mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD {align1};
  542.  
  543. /* Setup the Cost center */
  544. /* currently four 8x8 share the same cost center */
  545. mov  (4) vme_m3.0<2>:ud         mb_mvp_ref.0<0,1,0>:ud  {align1};
  546. mov  (4) vme_m3.4<2>:ud         mb_mvp_ref.0<0,1,0>:ud  {align1};
  547.  
  548. mov (8) vme_msg_3<1>:UD         vme_m3.0<8,8,1>:UD {align1};
  549. mov (8) vme_msg_2<1>:UD         vme_m2.0<8,8,1>:UD {align1};
  550.  
  551. /* M4/M5 search path */
  552. mov  (1) vme_msg_4.0<1>:UD      0x01010101:UD {align1};
  553. mov  (1) vme_msg_4.4<1>:UD      0x10010101:UD {align1};
  554. mov  (1) vme_msg_4.8<1>:UD      0x0F0F0F0F:UD {align1};
  555. mov  (1) vme_msg_4.12<1>:UD     0x100F0F0F:UD {align1};
  556. mov  (1) vme_msg_4.16<1>:UD     0x01010101:UD {align1};
  557. mov  (1) vme_msg_4.20<1>:UD     0x10010101:UD {align1};
  558. mov  (1) vme_msg_4.24<1>:UD     0x0F0F0F0F:UD {align1};
  559. mov  (1) vme_msg_4.28<1>:UD     0x100F0F0F:UD {align1};
  560.  
  561. mov  (1) vme_msg_5.0<1>:UD      0x01010101:UD {align1};
  562. mov  (1) vme_msg_5.4<1>:UD      0x10010101:UD {align1};
  563. mov  (1) vme_msg_5.8<1>:UD      0x0F0F0F0F:UD {align1};
  564. mov  (1) vme_msg_5.12<1>:UD     0x000F0F0F:UD {align1};
  565.  
  566. mov  (4) vme_msg_5.16<1>:UD     0x0:UD {align1};
  567.  
  568. send (8)
  569.        vme_msg_ind
  570.        vme_wb<1>:UD
  571.        null
  572.        vme(
  573.                BIND_IDX_VME,
  574.                0,
  575.                0,
  576.                VME_IME_MESSAGE_TYPE
  577.        )
  578.        mlen ime_vme_msg_length
  579.        rlen vme_wb_length {align1};
  580.  
  581. /* Set Macroblock-shape/mode for FBR */
  582.  
  583. mov  (1) vme_m2.20<1>:UD        0x0:UD {align1};
  584. mov  (1) vme_m2.21<1>:UB        vme_wb.25<0,1,0>:UB     {align1};
  585. mov  (1) vme_m2.22<1>:UB        vme_wb.26<0,1,0>:UB     {align1};
  586.  
  587. and  (1) tmp_reg0.0<1>:UW       vme_wb.0<0,1,0>:UW      0x03:UW {align1};
  588. mov  (1) vme_m2.20<1>:UB        tmp_reg0.0<0,1,0>:UB    {align1};
  589.  
  590. /* Send FBR message into CRE */
  591.  
  592. mov  (8) vme_msg_4.0<1>:UD       vme_wb1.0<8,8,1>:UD {align1};
  593. mov  (8) vme_msg_5.0<1>:ud       vme_wb2.0<8,8,1>:ud {align1};
  594. mov  (8) vme_msg_6.0<1>:ud       vme_wb3.0<8,8,1>:ud {align1};
  595. mov  (8) vme_msg_7.0<1>:ud       vme_wb4.0<8,8,1>:ud {align1};                
  596.  
  597. mov  (1) vme_m0.12<1>:UD        INTER_SAD_HAAR + SUB_PEL_MODE_QUARTER + FBR_BME_DISABLE:UD {align1};    /* 16x16 Source, 1/4 pixel, harr, BME disable */
  598. mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD  {align1};
  599. mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD  {align1};
  600.  
  601. mov  (8) vme_msg_2.0<1>:UD              vme_m2.0<8,8,1>:UD      {align1};
  602. mov  (8) vme_msg_3.0<1>:UD              vme_m3.0<8,8,1>:UD      {align1};
  603.  
  604. /* after verification it will be passed by using payload */
  605. send (8)
  606.        vme_msg_ind
  607.        vme_wb<1>:UD
  608.        null
  609.        cre(
  610.                BIND_IDX_VME,
  611.                VME_FBR_MESSAGE_TYPE
  612.        )
  613.        mlen fbr_vme_msg_length
  614.        rlen vme_wb_length
  615.        {align1};
  616.  
  617. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x02:UD {align1};
  618. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  619. /* write FME info */
  620. mov  (1) msg_reg1.0<1>:UD       vme_wb.0<0,1,0>:UD      {align1};
  621.  
  622. mov  (1) msg_reg1.4<1>:UD       vme_wb.24<0,1,0>:UD     {align1};
  623. /* Inter distortion of FME */
  624. mov  (1) msg_reg1.8<1>:UD       vme_wb.8<0,1,0>:UD     {align1};
  625.  
  626. mov  (1) msg_reg1.12<1>:UD      vme_m2.20<0,1,0>:UD {align1};
  627.  
  628. /* bind index 3, write  oword (16bytes), msg type: 8(OWord Block Write) */
  629. send (16)
  630.        msg_ind
  631.        obw_wb
  632.        null
  633.        data_port(
  634.                OBW_CACHE_TYPE,
  635.                OBW_MESSAGE_TYPE,
  636.                OBW_CONTROL_0,
  637.                OBW_BIND_IDX,
  638.                OBW_WRITE_COMMIT_CATEGORY,
  639.                OBW_HEADER_PRESENT
  640.        )
  641.        mlen 2
  642.        rlen obw_wb_length
  643.        {align1};
  644.  
  645. /* Write FME/BME MV */
  646. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x01:UD {align1};
  647. mov  (8) msg_reg0.0<1>:UD       obw_m0.0<8,8,1>:UD {align1};
  648.  
  649.  
  650. mov  (8) msg_reg1.0<1>:UD       vme_wb1.0<8,8,1>:UD {align1};
  651. mov  (8) msg_reg2.0<1>:ud       vme_wb2.0<8,8,1>:ud {align1};
  652. mov  (8) msg_reg3.0<1>:ud       vme_wb3.0<8,8,1>:ud {align1};
  653. mov  (8) msg_reg4.0<1>:ud       vme_wb4.0<8,8,1>:ud {align1};                
  654. /* bind index 3, write  8 oword (128 bytes), msg type: 8(OWord Block Write) */
  655. send (16)
  656.        msg_ind
  657.        obw_wb
  658.        null
  659.        data_port(
  660.                OBW_CACHE_TYPE,
  661.                OBW_MESSAGE_TYPE,
  662.                OBW_CONTROL_8,
  663.                OBW_BIND_IDX,
  664.                OBW_WRITE_COMMIT_CATEGORY,
  665.                OBW_HEADER_PRESENT
  666.        )
  667.        mlen 5
  668.        rlen obw_wb_length
  669.        {align1};
  670.  
  671. /* Write FME/BME RefID */
  672. add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD 0x08:UD {align1};
  673. mov  (8) msg_reg0.0<1>:UD       obw_m0<8,8,1>:UD {align1};
  674.  
  675. mov  (8) msg_reg1.0<1>:UD       vme_wb6.0<8,8,1>:UD {align1};
  676.  
  677. /* bind index 3, write 2 oword (32bytes), msg type: 8(OWord Block Write) */
  678. send (16)
  679.        msg_ind
  680.        obw_wb
  681.        null
  682.        data_port(
  683.                OBW_CACHE_TYPE,
  684.                OBW_MESSAGE_TYPE,
  685.                OBW_CONTROL_2,
  686.                OBW_BIND_IDX,
  687.                OBW_WRITE_COMMIT_CATEGORY,
  688.                OBW_HEADER_PRESENT
  689.        )
  690.        mlen 2
  691.        rlen obw_wb_length
  692.        {align1};
  693.  
  694. /* Issue message fence so that the previous write message is committed */
  695. send (16)
  696.        mb_ind
  697.        mb_wb.0<1>:ud
  698.         NULL
  699.        data_port(
  700.                OBR_CACHE_TYPE,
  701.                OBR_MESSAGE_FENCE,
  702.                OBR_MF_COMMIT,
  703.                OBR_BIND_IDX,
  704.                OBR_WRITE_COMMIT_CATEGORY,
  705.                OBR_HEADER_PRESENT
  706.        )
  707.        mlen 1
  708.        rlen 1
  709.        {align1};
  710.  
  711. __EXIT:
  712. /*
  713. * kill thread
  714. */        
  715. mov  (8) ts_msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
  716. send (16) ts_msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
  717.  
  718.  
  719.         nop             ;
  720.         nop             ;
  721. /* Compare three word data to get the min value */
  722. word_imin:
  723.         cmp.le.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  724.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  725.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  726.         cmp.le.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  727.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  728.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  729.         RETURN          {align1};      
  730.        
  731. /* Compare three word data to get the max value */
  732. word_imax:
  733.         cmp.ge.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
  734.         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
  735.         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
  736.         cmp.ge.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
  737.         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
  738.         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
  739.         RETURN          {align1};      
  740.        
  741. word_imedian:
  742.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.4<0,1,0>:w {align1};
  743.         (f0.0)  jmpi (1) cmp_a_ge_b;
  744.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  745.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  746.         (f0.0) jmpi (1) cmp_end;
  747.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  748.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  749.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  750.         jmpi (1) cmp_end;
  751. cmp_a_ge_b:
  752.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  753.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
  754.         (f0.0) jmpi (1) cmp_end;
  755.         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
  756.         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
  757.         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
  758. cmp_end:
  759.         RETURN  {align1};
  760.  
  761.