WebSVN – Kolibri OS – Diff – /kernel/trunk/network/tcp_input.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                                 ;;
;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.    ;;
;; Distributed under terms of the GNU General Public License       ;;
;;                                                                 ;;
;;  Part of the TCP/IP network stack for KolibriOS                 ;;
;;                                                                 ;;
;;   Written by hidnplayr@kolibrios.org                            ;;
;;                                                                 ;;
;;    Based on the code of 4.4BSD                                  ;;
;;                                                                 ;;
;;          GNU GENERAL PUBLIC LICENSE                             ;;
;;             Version 2, June 1991                                ;;
;;                                                                 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 3407 $
 
;-----------------------------------------------------------------
;
; TCP_input:
;
;       Add a segment to the incoming TCP queue
;
;  IN:  [esp] = ptr to buffer
;       [esp+4] = buffer size (dont care)
;       ebx = ptr to device struct
;       ecx = segment size
;       esi = ptr to TCP segment
;       edi = ptr to ipv4 source address, followed by ipv4 dest address
;
;  OUT: /
;
;-----------------------------------------------------------------
 
align 4
TCP_input:
 
; record the current time
        mov     eax, [timer_ticks]      ; in 1/100 seconds
        mov     [esp + 4], eax
 
        push    ebx ecx esi edi         ; mind the order
        mov     esi, esp
 
 
 
 
 
        add_to_queue TCP_queue, TCP_QUEUE_SIZE, sizeof.TCP_queue_entry, .fail
        add     esp, sizeof.TCP_queue_entry
 
        call    NET_ptr_to_num4
        inc     [TCP_segments_rx + edi]
 
        xor     edx, edx
        mov     eax, [TCP_input_event]
        mov     ebx, [eax + EVENT.id]
        xor     esi, esi
        call    raise_event
 
        ret
 
  .fail:
        popf
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP incoming queue is full, discarding packet!\n"
 
        call    NET_ptr_to_num4
        inc     [TCP_segments_missed + edi]
 
        add     esp, sizeof.TCP_queue_entry - 8
        call    NET_packet_free
        add     esp, 4
 
        ret
 
 
 
 
align 4
proc TCP_process_input
 
locals
        dataoffset      dd ?
        timestamp       dd ?
        temp_bits       db ?
endl
 
        xor     esi, esi
        mov     ecx, MANUAL_DESTROY
        call    create_event
        mov     [TCP_input_event], eax
 
  .wait:
        mov     eax, [TCP_input_event]
        mov     ebx, [eax + EVENT.id]
        call    wait_event
 
  .loop:
        get_from_queue TCP_queue, TCP_QUEUE_SIZE, sizeof.TCP_queue_entry, .wait
 
        push    [esi + TCP_queue_entry.timestamp]
        pop     [timestamp]
        push    [esi + TCP_queue_entry.buffer_ptr]
 
        mov     ebx, [esi + TCP_queue_entry.device_ptr]
        mov     ecx, [esi + TCP_queue_entry.segment_size]
        mov     edi, [esi + TCP_queue_entry.ip_ptr]                     ; ptr to ipv4 source address, followed by ipv4 destination address
        mov     esi, [esi + TCP_queue_entry.segment_ptr]                ; change esi last
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: size=%u time=%d\n", ecx, [timer_ticks]
 
        mov     edx, esi
 
        cmp     ebx, LOOPBACK_DEVICE
        je      .checksum_ok
 
; re-calculate the checksum (if not already done by hw)
        test    [ebx + NET_DEVICE.hwacc], NET_HWACC_TCP_IPv4_IN
        jnz     .checksum_ok
 
        push    ecx esi
        pushw   [esi + TCP_header.Checksum]
        mov     [esi + TCP_header.Checksum], 0
        TCP_checksum (edi), (edi+4)
        pop     cx                      ; previous checksum
        cmp     cx, dx
        pop     edx ecx
        jne     .drop_no_socket
  .checksum_ok:
 
; Verify the data offset
        movzx   eax, [edx + TCP_header.DataOffset]
        and     al, 0xf0                        ; Calculate TCP segment header size (throwing away unused reserved bits in TCP header)
        shr     al, 2
        cmp     al, sizeof.TCP_header           ; Now see if it's at least the size of a standard TCP header
        jb      .drop_no_socket                 ; If not, drop the packet
        mov     [dataoffset], eax
 
        sub     ecx, eax                                                ; substract TCP header size from total segment size
        jb      .drop_no_socket                                         ; If total segment size is less then the advertised header size, drop packet
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: %u bytes of data\n", ecx
 
;-------------------------------------------
; Convert Big-endian values to little endian
 
        ntohd   [edx + TCP_header.SequenceNumber]
        ntohd   [edx + TCP_header.AckNumber]
 
        ntohw   [edx + TCP_header.Window]
        ntohw   [edx + TCP_header.UrgentPointer]
 
;------------------------
; Find the socket pointer
 
; IP Packet TCP Destination Port = local Port
; (IP Packet SenderAddress = Remote IP)  OR  (Remote IP = 0)
; (IP Packet TCP Source Port = remote Port) OR (remote Port = 0)
 
  .findpcb:
        pusha
        mov     ecx, socket_mutex
        call    mutex_lock
        popa
 
        mov     ebx, net_sockets
        mov     si, [edx + TCP_header.DestinationPort]
 
  .socket_loop:
        mov     ebx, [ebx + SOCKET.NextPtr]
        or      ebx, ebx
        jz      .no_socket ;respond_seg_reset
 
        cmp     [ebx + SOCKET.Domain], AF_INET4
        jne     .socket_loop
 
        cmp     [ebx + SOCKET.Protocol], IP_PROTO_TCP
        jne     .socket_loop
 
        cmp     [ebx + TCP_SOCKET.LocalPort], si
        jne     .socket_loop
 
        mov     eax, [ebx + IP_SOCKET.RemoteIP]
        cmp     eax, [edi]                              ; Ipv4 source address
        je      @f
        test    eax, eax
        jnz     .socket_loop
       @@:
 
        mov     ax, [ebx + TCP_SOCKET.RemotePort]
        cmp     [edx + TCP_header.SourcePort], ax
        je      .found_socket
        test    ax, ax
        jnz     .socket_loop
  .found_socket:                                        ; ebx now contains the socketpointer
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: socket ptr=%x state=%u flags=%x\n", ebx, [ebx + TCP_SOCKET.t_state], [edx + TCP_header.Flags]:2
 
;----------------------------
; Check if socket isnt closed
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_CLOSED
        je      .drop_no_socket
 
;----------------
; Lock the socket
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_lock
        popa
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: socket locked\n"
 
;---------------------------
; disable all temporary bits
 
        mov     [temp_bits], 0
 
;---------------------------------------
; unscale the window into a 32 bit value
 
        movzx   eax, [edx + TCP_header.Window]
        push    ecx
        mov     cl, [ebx + TCP_SOCKET.SND_SCALE]
        shl     eax, cl
        mov     dword [edx + TCP_header.Window], eax    ; word after window is checksum, we dont need checksum anymore
        pop     ecx
 
;---------------------------------------
; Are we accepting incoming connections?
 
        test    [ebx + SOCKET.options], SO_ACCEPTCON
        jz      .no_accept
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Accepting new connection\n"
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        popa
 
        push    ecx edx esi edi         ;;;
        call    SOCKET_fork
        pop     edi esi edx ecx
 
        test    eax, eax
        jz      .drop_no_socket
 
        mov     ebx, eax
 
        mov     [temp_bits], TCP_BIT_DROPSOCKET
 
        push    dword [edi + 4]                         ; Ipv4 destination addres
        pop     [ebx + IP_SOCKET.LocalIP]
 
        push    [edx + TCP_header.DestinationPort]
        pop     [ebx + TCP_SOCKET.LocalPort]
 
        mov     [ebx + TCP_SOCKET.t_state], TCPS_LISTEN
  .no_accept:
 
 
;-------------------------------------
; Reset idle timer and keepalive timer
 
        mov     [ebx + TCP_SOCKET.t_idle], 0
        mov     [ebx + TCP_SOCKET.timer_keepalive], TCP_time_keep_idle
        or      [ebx + TCP_SOCKET.timer_flags], timer_flag_keepalive
 
;--------------------
; Process TCP options
 
;;; FIXME: for LISTEN, options should be called after we determined route, we need it for MSS
;;;        cmp     [ebx + TCP_SOCKET.t_state], TCPS_LISTEN ; no options when in listen state
;;;        jz      .not_uni_xfer                           ; also no header prediction
 
        push    ecx
 
        mov     ecx, [dataoffset]
        cmp     ecx, sizeof.TCP_header                  ; Does header contain any options?
        je      .no_options
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Segment has options\n"
 
        add     ecx, edx
        lea     esi, [edx + sizeof.TCP_header]
 
  .opt_loop:
        cmp     esi, ecx                        ; are we scanning outside of header?
        jae     .no_options
        lodsb
        cmp     al, TCP_OPT_EOL                 ; end of option list?
        je      .no_options
        cmp     al, TCP_OPT_NOP
        je      .opt_loop
        cmp     al, TCP_OPT_MAXSEG
        je      .opt_maxseg
        cmp     al, TCP_OPT_WINDOW
        je      .opt_window
        cmp     al, TCP_OPT_SACK_PERMIT
        je      .opt_sack_permit
;        cmp     al, TCP_OPT_SACK
;        je      .opt_sack
        cmp     al, TCP_OPT_TIMESTAMP
        je      .opt_timestamp
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: unknown option:%u\n", al
        jmp     .no_options                     ; If we reach here, some unknown options were received, skip them all!
 
  .opt_maxseg:
        lodsb
        cmp     al, 4
        jne     .no_options                     ; error occured, ignore all options!
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      @f
 
        xor     eax, eax
        lodsw
        rol     ax, 8
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Maxseg=%u\n", eax
        call    TCP_mss
       @@:
        jmp     .opt_loop
 
 
  .opt_window:
        lodsb
        cmp     al, 3
        jne     .no_options
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      @f
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Got window scale option\n"
        or      [ebx + TCP_SOCKET.t_flags], TF_RCVD_SCALE
 
        lodsb
        mov     [ebx + TCP_SOCKET.SND_SCALE], al
        ;;;;; TODO
 
       @@:
        jmp     .opt_loop
 
 
  .opt_sack_permit:
        lodsb
        cmp     al, 2
        jne     .no_options
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      @f
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Selective Acknowledgement permitted\n"
        or      [ebx + TCP_SOCKET.t_flags], TF_SACK_PERMIT
 
       @@:
        jmp     .opt_loop
 
 
  .opt_timestamp:
        lodsb
        cmp     al, 10                          ; length must be 10
        jne     .no_options
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Got timestamp option\n"
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      @f
        or      [ebx + TCP_SOCKET.t_flags], TF_RCVD_TSTMP
       @@:
 
        lodsd
        bswap   eax
        mov     [ebx + TCP_SOCKET.ts_val], eax
        lodsd                                   ; timestamp echo reply
        mov     [ebx + TCP_SOCKET.ts_ecr], eax
        or      [temp_bits], TCP_BIT_TIMESTAMP
 
        ; Since we have a timestamp, lets do the paws test right away!
 
        test    [edx + TCP_header.Flags], TH_RST
        jnz     .no_paws
 
        mov     eax, [ebx + TCP_SOCKET.ts_recent]
        test    eax, eax
        jz      .no_paws
        cmp     eax, [ebx + TCP_SOCKET.ts_val]
        jbe     .no_paws
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: PAWS: detected an old segment\n"
 
        mov     eax, [timestamp]
        sub     eax, [ebx + TCP_SOCKET.ts_recent_age]
 
        pop     ecx
        cmp     eax, TCP_PAWS_IDLE
        jle     .drop_after_ack                         ; TODO: update stats
        push    ecx
 
        mov     [ebx + TCP_SOCKET.ts_recent], 0         ; timestamp was invalid, fix it.
  .no_paws:
        jmp     .opt_loop
 
  .no_options:
 
        pop     ecx
 
;-----------------------------------------------------------------------
; Time to do some header prediction (Original Principle by Van Jacobson)
 
; There are two common cases for an uni-directional data transfer.
;
; General rule: the packets has no control flags, is in-sequence,
;   window width didnt change and we're not retransmitting.
;
; Second rules:
;  -  If the length is 0 and the ACK moved forward, we're the sender side of the transfer.
;      In this case we'll free the ACK'ed data and notify higher levels that we have free space in buffer
;
;  -  If the length is not 0 and the ACK didn't move, we're the receiver side of the transfer.
;      If the packets are in order (data queue is empty), add the data to the socket buffer and request a delayed ACK
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_ESTABLISHED
        jnz     .not_uni_xfer
 
        test    [edx + TCP_header.Flags], TH_SYN + TH_FIN + TH_RST + TH_URG
        jnz     .not_uni_xfer
 
        test    [edx + TCP_header.Flags], TH_ACK
        jz      .not_uni_xfer
 
        mov     eax, [edx + TCP_header.SequenceNumber]
        cmp     eax, [ebx + TCP_SOCKET.RCV_NXT]
        jne     .not_uni_xfer
 
        mov     eax, dword [edx + TCP_header.Window]
        cmp     eax, [ebx + TCP_SOCKET.SND_WND]
        jne     .not_uni_xfer
 
        mov     eax, [ebx + TCP_SOCKET.SND_NXT]
        cmp     eax, [ebx + TCP_SOCKET.SND_MAX]
        jne     .not_uni_xfer
 
;---------------------------------------
; check if we are sender in the uni-xfer
 
; If the following 4 conditions are all true, this segment is a pure ACK.
;
; - The segment contains no data.
        test    ecx, ecx
        jnz     .not_sender
 
; - The congestion window is greater than or equal to the current send window.
;     This test is true only if the window is fully open, that is, the connection is not in the middle of slow start or congestion avoidance.
        mov     eax, [ebx + TCP_SOCKET.SND_CWND]
        cmp     eax, [ebx + TCP_SOCKET.SND_WND]
        jb      .not_uni_xfer
 
; - The acknowledgment field in the segment is less than or equal to the maximum sequence number sent.
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.SND_MAX]
        ja      .not_uni_xfer
 
; - The acknowledgment field in the segment is greater than the largest unacknowledged sequence number.
        sub     eax, [ebx + TCP_SOCKET.SND_UNA]
        jbe     .not_uni_xfer
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Header prediction: we are sender\n"
 
;---------------------------------
; Packet is a pure ACK, process it
 
; Delete acknowledged bytes from send buffer
        pusha
        mov     ecx, eax
        lea     eax, [ebx + STREAM_SOCKET.snd]
        call    SOCKET_ring_free
        popa
 
; Update RTT estimators
 
        test    [temp_bits], TCP_BIT_TIMESTAMP
        jz      .no_timestamp_rtt
        mov     eax, [timestamp]
        sub     eax, [ebx + TCP_SOCKET.ts_ecr]
        inc     eax
        call    TCP_xmit_timer
        jmp     .rtt_done
 
  .no_timestamp_rtt:
        cmp     [ebx + TCP_SOCKET.t_rtt], 0
        je      .rtt_done
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.t_rtseq]
        jbe     .rtt_done
        mov     eax, [ebx + TCP_SOCKET.t_rtt]
        call    TCP_xmit_timer
 
  .rtt_done:
 
; update window pointers
        mov     eax, [edx + TCP_header.AckNumber]
        mov     [ebx + TCP_SOCKET.SND_UNA], eax
 
; Stop retransmit timer
        and     [ebx + TCP_SOCKET.timer_flags], not timer_flag_retransmission
 
; Unlock the socket
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        popa
 
; Awaken waiting processes
        mov     eax, ebx
        call    SOCKET_notify
 
; Generate more output
        call    TCP_output
 
        jmp     .drop_no_socket
 
;-------------------------------------------------
; maybe we are the receiver in the uni-xfer then..
 
  .not_sender:
; - The amount of data in the segment is greater than 0 (data count is in ecx)
 
; - The acknowledgment field equals the largest unacknowledged sequence number. This means no data is acknowledged by this segment.
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.SND_UNA]
        jne     .not_uni_xfer
 
; - The reassembly list of out-of-order segments for the connection is empty (seg_next equals tp).
 
;;; TODO
 
;       jnz     .not_uni_xfer
 
; Complete processing of received data
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Header prediction: we are receiving %u bytes\n", ecx
 
        mov     esi, [dataoffset]
        add     esi, edx
        lea     eax, [ebx + STREAM_SOCKET.rcv]
        call    SOCKET_ring_write                       ; Add the data to the socket buffer
        add     [ebx + TCP_SOCKET.RCV_NXT], ecx         ; Update sequence number with number of bytes we have copied
 
        mov     eax, ebx
        call    SOCKET_notify
 
        or      [ebx + TCP_SOCKET.t_flags], TF_DELACK   ; Set delayed ack flag
 
        jmp     .drop
 
;--------------------------------------------------
; Header prediction failed, do it the slow way
 
  .not_uni_xfer:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Header prediction failed\n"
 
; Calculate receive window size
        push    edx
        mov     eax, SOCKET_MAXDATA
        sub     eax, [ebx + STREAM_SOCKET.rcv.size]
        DEBUGF  DEBUG_NETWORK_VERBOSE, "Space in receive buffer=%d\n", eax
        mov     edx, [ebx + TCP_SOCKET.RCV_ADV]
        sub     edx, [ebx + TCP_SOCKET.RCV_NXT]
        DEBUGF  DEBUG_NETWORK_VERBOSE, "Current advertised window=%d\n", edx
        cmp     eax, edx
        jg      @f
        mov     eax, edx
       @@:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "Receive window size=%d\n", eax
        mov     [ebx + TCP_SOCKET.RCV_WND], eax
        pop     edx
 
; If we are in listen or syn_sent state, go to that specific code right away
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_LISTEN
        je      .LISTEN
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_SYN_SENT
        je      .SYN_SENT
 
;----------------------------
; trim any data not in window
 
; 1. Check for duplicate data at beginning of segment
 
; Calculate number of bytes we need to drop
        mov     eax, [ebx + TCP_SOCKET.RCV_NXT]
        sub     eax, [edx + TCP_header.SequenceNumber]
        jle     .no_duplicate
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: %u bytes duplicate data!\n", eax
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      .no_dup_syn
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: got duplicate syn\n"
 
        and     [edx + TCP_header.Flags], not (TH_SYN)
        inc     [edx + TCP_header.SequenceNumber]
 
        cmp     [edx + TCP_header.UrgentPointer], 1
        jbe     @f
        dec     [edx + TCP_header.UrgentPointer]
        jmp     .dup_syn
       @@:
        and     [edx + TCP_header.Flags], not (TH_URG)
  .dup_syn:
        dec     eax
  .no_dup_syn:
 
; 2. Check for entire duplicate segment
        cmp     eax, ecx                ; eax holds number of bytes to drop, ecx is data size
        jb      .duplicate
        jnz     @f
        test    [edx + TCP_header.Flags], TH_FIN
        jnz     .duplicate
       @@:
 
; Any valid FIN must be to the left of the window.
; At this point the FIN must be out of sequence or a duplicate, drop it
        and     [edx + TCP_header.Flags], not TH_FIN
 
; send an ACK and resynchronize and drop any data.
; But keep on processing for RST or ACK
        or      [ebx + TCP_SOCKET.t_flags], TF_ACKNOW
        mov     eax, ecx
 
;;; TODO: update stats
 
;-----------------------------------------------
; Remove duplicate data and update urgent offset
 
  .duplicate:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: trimming duplicate data\n"
 
; Trim data from left side of window
        add     [dataoffset], eax
        add     [edx + TCP_header.SequenceNumber], eax
        sub     ecx, eax
 
        sub     [edx + TCP_header.UrgentPointer], ax
        jg      @f
        and     [edx + TCP_header.Flags], not (TH_URG)
        mov     [edx + TCP_header.UrgentPointer], 0
       @@:
 
;--------------------------------------------------
; Handle data that arrives after process terminates
 
  .no_duplicate:
        cmp     [ebx + SOCKET.PID], 0                   ;;; TODO: use socket flags instead??
        jne     .not_terminated
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_CLOSE_WAIT
        jbe     .not_terminated
        test    ecx, ecx
        jz      .not_terminated
 
        mov     eax, ebx
        call    TCP_close
;;; TODO: update stats
        jmp     .respond_seg_reset
 
;----------------------------------------
; Remove data beyond right edge of window
 
  .not_terminated:
        mov     eax, [edx + TCP_header.SequenceNumber]
        add     eax, ecx
        sub     eax, [ebx + TCP_SOCKET.RCV_NXT]
        sub     eax, [ebx + TCP_SOCKET.RCV_WND]         ; eax now holds the number of bytes to drop
        jle     .no_excess_data
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "%d bytes beyond right edge of window\n", eax
 
;;; TODO: update stats
        cmp     eax, ecx
        jl      .dont_drop_all
; If a new connection request is received while in TIME_WAIT, drop the old connection and start over,
; if the sequence numbers are above the previous ones
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      .no_new_request
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_TIMED_WAIT
        jne     .no_new_request
;        mov     edx, [ebx + TCP_SOCKET.RCV_NXT]
;        cmp     edx, [edx + TCP_header.SequenceNumber]
;        add     edx, 64000      ; TCP_ISSINCR   FIXME
        mov     eax, ebx
        call    TCP_close
        jmp     .findpcb        ; FIXME: skip code for unscaling window, ...
  .no_new_request:
 
; If window is closed, we can only take segments at window edge, and have to drop data and PUSH from
; incoming segments. Continue processing, but remember to ACK. Otherwise drop segment and ACK
 
        cmp     [ebx + TCP_SOCKET.RCV_WND], 0
        jne     .drop_after_ack
        mov     esi, [edx + TCP_header.SequenceNumber]
        cmp     esi, [ebx + TCP_SOCKET.RCV_NXT]
        jne     .drop_after_ack
 
        or      [ebx + TCP_SOCKET.t_flags], TF_ACKNOW
;;; TODO: update stats
  .dont_drop_all:
;;; TODO: update stats
        DEBUGF  DEBUG_NETWORK_VERBOSE, "Trimming %u bytes from the right of the window\n"
        sub     ecx, eax        ; remove data from the right side of window (decrease data length)
        and     [edx + TCP_header.Flags], not (TH_PUSH or TH_FIN)
  .no_excess_data:
 
;-----------------
; Record timestamp
 
; If last ACK falls within this segments sequence numbers, record its timestamp
        test    [temp_bits], TCP_BIT_TIMESTAMP
        jz      .no_timestamp
        mov     eax, [ebx + TCP_SOCKET.last_ack_sent]
        sub     eax, [edx + TCP_header.SequenceNumber]
        jb      .no_timestamp
        test    [ebx + TCP_header.Flags], TH_SYN or TH_FIN      ; syn and fin occupy one byte
        jz      @f
        dec     eax
       @@:
        sub     eax, ecx
        jae     .no_timestamp
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "Recording timestamp\n"
 
        mov     eax, [timestamp]
        mov     [ebx + TCP_SOCKET.ts_recent_age], eax
        mov     eax, [ebx + TCP_SOCKET.ts_val]
        mov     [ebx + TCP_SOCKET.ts_recent], eax
  .no_timestamp:
 
;------------------
; Process RST flags
 
        test    [edx + TCP_header.Flags], TH_RST
        jz      .no_rst
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Got an RST flag\n"
 
        mov     eax, [ebx + TCP_SOCKET.t_state]
        shl     eax, 2
        jmp     dword [eax + .rst_sw_list]
 
  .rst_sw_list:
        dd      .no_rst         ; TCPS_CLOSED
        dd      .no_rst         ; TCPS_LISTEN
        dd      .no_rst         ; TCPS_SYN_SENT
        dd      .econnrefused   ; TCPS_SYN_RECEIVED
        dd      .econnreset     ; TCPS_ESTABLISHED
        dd      .econnreset     ; TCPS_CLOSE_WAIT
        dd      .econnreset     ; TCPS_FIN_WAIT_1
        dd      .rst_close      ; TCPS_CLOSING
        dd      .rst_close      ; TCPS_LAST_ACK
        dd      .econnreset     ; TCPS_FIN_WAIT_2
        dd      .rst_close      ; TCPS_TIMED_WAIT
 
  .econnrefused:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Connection refused\n"
 
        mov     [ebx + SOCKET.errorcode], ECONNREFUSED
        jmp     .close
 
  .econnreset:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Connection reset\n"
 
        mov     [ebx + SOCKET.errorcode], ECONNRESET
 
  .close:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Closing connection\n"
 
        mov     [ebx + TCP_SOCKET.t_state], TCPS_CLOSED
;;; TODO: update stats (tcp drops)
        mov     eax, ebx
        call    TCP_close
        jmp     .drop_no_socket
 
  .rst_close:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Closing with reset\n"
 
        mov     eax, ebx
        call    TCP_close
        jmp     .drop_no_socket
 
  .no_rst:
 
;--------------------------------------
; handle SYN-full and ACK-less segments
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      .not_syn_full
 
        mov     eax, ebx
        mov     ebx, ECONNRESET
        call    TCP_drop
        jmp     .drop_with_reset
  .not_syn_full:
 
;---------------
; ACK processing
 
        test    [edx + TCP_header.Flags], TH_ACK
        jz      .drop
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_SYN_RECEIVED
        jb      .ack_processed                                  ; states: closed, listen, syn_sent
        ja      .no_syn_rcv                                     ; established, fin_wait_1, fin_wait_2, close_wait, closing, last_ack, time_wait
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: state=syn_received\n"
 
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     [ebx + TCP_SOCKET.SND_UNA], eax
        ja      .drop_with_reset
        cmp     eax, [ebx + TCP_SOCKET.SND_MAX]
        ja      .drop_with_reset
 
;;; TODO: update stats
 
        mov     eax, ebx
        call    SOCKET_is_connected
        mov     [ebx + TCP_SOCKET.t_state], TCPS_ESTABLISHED
 
; Do window scaling?
 
        test    [ebx + TCP_SOCKET.t_flags], TF_RCVD_SCALE
        jz      @f
        test    [ebx + TCP_SOCKET.t_flags], TF_REQ_SCALE
        jz      @f
 
        push    word [ebx + TCP_SOCKET.requested_s_scale]       ; Set send and receive scale factors to the received values
        pop     word [ebx + TCP_SOCKET.SND_SCALE]
       @@:
 
;;; TODO: call TCP_reassemble
 
        mov     eax, [edx + TCP_header.SequenceNumber]
        dec     eax
        mov     [ebx + TCP_SOCKET.SND_WL1], eax
 
  .no_syn_rcv:
 
;-------------------------
; check for duplicate ACKs
 
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.SND_UNA]
        ja      .not_dup_ack
 
        test    ecx, ecx
        jnz     .reset_dupacks
 
        mov     eax, dword [edx + TCP_header.Window]
        cmp     eax, [ebx + TCP_SOCKET.SND_WND]
        jne     .reset_dupacks
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Processing duplicate ACK\n"
 
; If we have outstanding data, other than a window probe, this is a completely duplicate ACK
; (window info didnt change) The ACK is the biggest we've seen and we've seen exactly our rexmt threshold of them,
; assume a packet has been dropped and retransmit it. Kludge snd_nxt & the congestion window so we send only this one packet.
 
        test    [ebx + TCP_SOCKET.timer_flags], timer_flag_retransmission
        jz      @f
 
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.SND_UNA]
        je      .dup_ack
 
       @@:
        mov     [ebx + TCP_SOCKET.t_dupacks], 0
        jmp     .not_dup_ack
 
  .dup_ack:
        inc     [ebx + TCP_SOCKET.t_dupacks]
        cmp     [ebx + TCP_SOCKET.t_dupacks], TCP_re_xmit_thresh
        jne     .no_re_xmit
 
        push    [ebx + TCP_SOCKET.SND_NXT]              ; >>>>
 
        mov     eax, [ebx + TCP_SOCKET.SND_WND]
        cmp     eax, [ebx + TCP_SOCKET.SND_CWND]
        jbe     @f
        mov     eax, [ebx + TCP_SOCKET.SND_CWND]
  @@:
        shr     eax, 1
        push    edx
        xor     edx, edx
        div     [ebx + TCP_SOCKET.t_maxseg]
        cmp     eax, 2
        ja      @f
        xor     eax, eax
        mov     al, 2
       @@:
        mul     [ebx + TCP_SOCKET.t_maxseg]
        pop     edx
        mov     [ebx + TCP_SOCKET.SND_SSTHRESH], eax
 
        and     [ebx + TCP_SOCKET.timer_flags], not timer_flag_retransmission   ; turn off retransmission timer
        mov     [ebx + TCP_SOCKET.t_rtt], 0
        mov     eax, [edx + TCP_header.AckNumber]
        mov     [ebx + TCP_SOCKET.SND_NXT], eax
        mov     eax, [ebx + TCP_SOCKET.t_maxseg]
        mov     [ebx + TCP_SOCKET.SND_CWND], eax
 
; Unlock the socket
        push    ebx
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
 
; retransmit missing segment
        mov     eax, [esp]
        call    TCP_output
 
; Lock the socket again
        mov     ecx, [esp]
        add     ecx, SOCKET.mutex
        call    mutex_lock
        pop     ebx
 
; Continue processing
        xor     edx, edx
        mov     eax, [ebx + TCP_SOCKET.t_maxseg]
        mul     [ebx + TCP_SOCKET.t_dupacks]
        add     eax, [ebx + TCP_SOCKET.SND_SSTHRESH]
        mov     [ebx + TCP_SOCKET.SND_CWND], eax
 
        pop     eax                                     ; <<<<
        cmp     eax, [ebx + TCP_SOCKET.SND_NXT]
        jb      @f
        mov     [ebx + TCP_SOCKET.SND_NXT], eax
       @@:
 
        jmp     .drop
 
 
  .no_re_xmit:
        jbe     .not_dup_ack
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Increasing congestion window\n"
 
        mov     eax, [ebx + TCP_SOCKET.t_maxseg]
        add     [ebx + TCP_SOCKET.SND_CWND], eax
 
; Unlock the socket
        push    ebx
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
 
; retransmit missing segment
        mov     eax, [esp]
        call    TCP_output
 
; Lock the socket again
        mov     ecx, [esp]
        add     ecx, SOCKET.mutex
        call    mutex_lock
        pop     ebx
 
        jmp     .drop
 
 
  .not_dup_ack:
 
;-------------------------------------------------
; If the congestion window was inflated to account
; for the other side's cached packets, retract it
 
        mov     eax, [ebx + TCP_SOCKET.SND_SSTHRESH]
        cmp     eax, [ebx + TCP_SOCKET.SND_CWND]
        ja      @f
        cmp     [ebx + TCP_SOCKET.t_dupacks], TCP_re_xmit_thresh
        jbe     @f
        mov     [ebx + TCP_SOCKET.SND_CWND], eax
       @@:
 
        mov     [ebx + TCP_SOCKET.t_dupacks], 0
 
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.SND_MAX]
        jbe     @f
 
        ;;; TODO: update stats
        jmp     .drop_after_ack
 
       @@:
 
        mov     edi, [edx + TCP_header.AckNumber]
        sub     edi, [ebx + TCP_SOCKET.SND_UNA]         ; now we got the number of acked bytes in edi
 
        ;;; TODO: update stats
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: acceptable ACK for %u bytes\n", edi
 
;------------------------------------------
; RTT measurements and retransmission timer
 
; If we have a timestamp, update smoothed RTT
 
        test    [temp_bits], TCP_BIT_TIMESTAMP
        jz      .timestamp_not_present
        mov     eax, [timestamp]
        sub     eax, [ebx + TCP_SOCKET.ts_ecr]
        inc     eax
        call    TCP_xmit_timer
        jmp     .rtt_done_
 
; If no timestamp but transmit timer is running and timed sequence number was acked,
; update smoothed RTT. Since we now have an RTT measurement, cancel the timer backoff
; (Phil Karn's retransmit algo)
; Recompute the initial retransmit timer
 
  .timestamp_not_present:
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.t_rtseq]
        jbe     .rtt_done_
        mov     eax, [ebx + TCP_SOCKET.t_rtt]
        test    eax, eax
        jz      .rtt_done_
        call    TCP_xmit_timer
 
  .rtt_done_:
 
; If all outstanding data is acked, stop retransmit timer and remember to restart (more output or persist)
; If there is more data to be acked, restart retransmit timer, using current (possible backed-off) value.
 
        mov     eax, [ebx + TCP_SOCKET.SND_MAX]
        cmp     eax, [edx + TCP_header.AckNumber]
        jne     .more_data
        and     [ebx + TCP_SOCKET.timer_flags], not timer_flag_retransmission
        or      [temp_bits], TCP_BIT_NEEDOUTPUT
        jmp     .no_restart
  .more_data:
        test    [ebx + TCP_SOCKET.timer_flags], timer_flag_persist
        jnz     .no_restart
 
        mov     eax, [ebx + TCP_SOCKET.t_rxtcur]
        mov     [ebx + TCP_SOCKET.timer_retransmission], eax
        or      [ebx + TCP_SOCKET.timer_flags], timer_flag_retransmission
  .no_restart:
 
 
;-------------------------------------------
; Open congestion window in response to ACKs
 
        mov     esi, [ebx + TCP_SOCKET.SND_CWND]
        mov     eax, [ebx + TCP_SOCKET.t_maxseg]
 
        cmp     esi, [ebx + TCP_SOCKET.SND_SSTHRESH]
        jbe     @f
        push    edx
        push    eax
        mul     eax
        div     esi
        pop     edx
        shr     edx, 3
        add     eax, edx
        pop     edx
       @@:
 
        add     esi, eax
 
        push    ecx
        mov     cl, [ebx + TCP_SOCKET.SND_SCALE]
        mov     eax, TCP_max_win
        shl     eax, cl
        pop     ecx
 
        cmp     esi, eax
        jbe     @f
        mov     esi, eax
  @@:
        mov     [ebx + TCP_SOCKET.SND_CWND], esi
 
;------------------------------------------
; Remove acknowledged data from send buffer
 
        cmp     edi, [ebx + STREAM_SOCKET.snd.size]
        jbe     .finiacked
 
        push    ecx edx ebx
        mov     ecx, [ebx + STREAM_SOCKET.snd.size]
        lea     eax, [ebx + STREAM_SOCKET.snd]
        sub     [ebx + TCP_SOCKET.SND_WND], ecx
        call    SOCKET_ring_free
        pop     ebx edx ecx
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: our FIN is acked\n"
        stc
 
        jmp     .wakeup
 
  .finiacked:
 
        push    ecx edx ebx
        mov     ecx, edi
        lea     eax, [ebx + STREAM_SOCKET.snd]
        call    SOCKET_ring_free
        pop     ebx
        sub     [ebx + TCP_SOCKET.SND_WND], ecx
        pop     edx ecx
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: our FIN is not acked\n"
        clc
 
;----------------------------------------
; Wake up process waiting on send buffer
 
  .wakeup:
 
        pushf                   ; Keep the flags (Carry flag)
        mov     eax, ebx
        call    SOCKET_notify
 
; Update TCPS
 
        mov     eax, [edx + TCP_header.AckNumber]
        mov     [ebx + TCP_SOCKET.SND_UNA], eax
        cmp     eax, [ebx + TCP_SOCKET.SND_NXT]
        jb      @f
        mov     [ebx + TCP_SOCKET.SND_NXT], eax
       @@:
 
        popf
 
; General ACK handling complete
; Now do the state-specific ones
; Carry flag is set when our FIN is acked
 
        mov     eax, [ebx + TCP_SOCKET.t_state]
        jmp     dword [eax*4 + .ACK_sw_list]
 
  .ACK_sw_list:
        dd      .ack_processed  ; TCPS_CLOSED
        dd      .ack_processed  ; TCPS_LISTEN
        dd      .ack_processed  ; TCPS_SYN_SENT
        dd      .ack_processed  ; TCPS_SYN_RECEIVED
        dd      .ack_processed  ; TCPS_ESTABLISHED
        dd      .ack_processed  ; TCPS_CLOSE_WAIT
        dd      .ack_fw1        ; TCPS_FIN_WAIT_1
        dd      .ack_c          ; TCPS_CLOSING
        dd      .ack_la         ; TCPS_LAST_ACK
        dd      .ack_processed  ; TCPS_FIN_WAIT_2
        dd      .ack_tw         ; TCPS_TIMED_WAIT
 
 
  .ack_fw1:
        jnc     .ack_processed
 
        test    [ebx + SOCKET.state], SS_CANTRCVMORE
        jnz     @f
        mov     eax, ebx
        call    SOCKET_is_disconnected
        mov     [ebx + TCP_SOCKET.timer_timed_wait], TCP_time_max_idle
        or      [ebx + TCP_SOCKET.timer_flags], timer_flag_wait
       @@:
        mov     [ebx + TCP_SOCKET.t_state], TCPS_FIN_WAIT_2
        jmp     .ack_processed
 
  .ack_c:
        jnc     .ack_processed
 
        mov     [ebx + TCP_SOCKET.t_state], TCPS_TIMED_WAIT
        mov     eax, ebx
        call    TCP_cancel_timers
        mov     [ebx + TCP_SOCKET.timer_timed_wait], 2 * TCP_time_MSL
        or      [ebx + TCP_SOCKET.timer_flags], timer_flag_wait
        mov     eax, ebx
        call    SOCKET_is_disconnected
        jmp     .ack_processed
 
  .ack_la:
        jnc     .ack_processed
 
        push    ebx
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        pop     ebx
 
        mov     eax, ebx
        call    TCP_close
        jmp     .drop_no_socket
 
  .ack_tw:
        mov     [ebx + TCP_SOCKET.timer_timed_wait], 2 * TCP_time_MSL
        or      [ebx + TCP_SOCKET.timer_flags], timer_flag_wait
        jmp     .drop_after_ack
 
  .reset_dupacks:               ; We got a new ACK, reset duplicate ACK counter
        mov     [ebx + TCP_SOCKET.t_dupacks], 0
        jmp     .ack_processed
 
;-------
; LISTEN
 
align 4
  .LISTEN:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: state=listen\n"
 
        test    [edx + TCP_header.Flags], TH_RST
        jnz     .drop
 
        test    [edx + TCP_header.Flags], TH_ACK
        jnz     .drop_with_reset
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      .drop
 
;;; TODO: check if it's a broadcast or multicast, and drop if so
 
        push    dword [edi]                             ; Ipv4 source addres
        pop     [ebx + IP_SOCKET.RemoteIP]
 
        push    [edx + TCP_header.SourcePort]
        pop     [ebx + TCP_SOCKET.RemotePort]
 
        push    [edx + TCP_header.SequenceNumber]
        pop     [ebx + TCP_SOCKET.IRS]
 
        mov     eax, [TCP_sequence_num]
        add     [TCP_sequence_num], 64000 / 2
        mov     [ebx + TCP_SOCKET.ISS], eax
        mov     [ebx + TCP_SOCKET.SND_NXT], eax
 
        TCP_sendseqinit ebx
        TCP_rcvseqinit ebx
 
        mov     [ebx + TCP_SOCKET.t_state], TCPS_SYN_RECEIVED
        or      [ebx + TCP_SOCKET.t_flags], TF_ACKNOW
        mov     [ebx + TCP_SOCKET.timer_keepalive], TCP_time_keep_interval  ;;;; macro
        or      [ebx + TCP_SOCKET.timer_flags], timer_flag_keepalive
 
        lea     eax, [ebx + STREAM_SOCKET.snd]
        call    SOCKET_ring_create
 
        lea     eax, [ebx + STREAM_SOCKET.rcv]
        call    SOCKET_ring_create
 
        and     [temp_bits], not TCP_BIT_DROPSOCKET
 
        pusha
        mov     eax, ebx
        call    SOCKET_notify
        popa
 
        jmp     .trim_then_step6
 
;------------
; Active Open
 
align 4
  .SYN_SENT:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: state=syn_sent\n"
 
        test    [edx + TCP_header.Flags], TH_ACK
        jz      @f
 
        mov     eax, [edx + TCP_header.AckNumber]
        cmp     eax, [ebx + TCP_SOCKET.ISS]
        jbe     .drop_with_reset
 
        cmp     eax, [ebx + TCP_SOCKET.SND_MAX]
        ja      .drop_with_reset
       @@:
 
        test    [edx + TCP_header.Flags], TH_RST
        jz      @f
 
        test    [edx + TCP_header.Flags], TH_ACK
        jz      .drop
 
        mov     eax, ebx
        mov     ebx, ECONNREFUSED
        call    TCP_drop
 
        jmp     .drop
       @@:
 
        test    [edx + TCP_header.Flags], TH_SYN
        jz      .drop
 
; at this point, segment seems to be valid
 
        test    [edx + TCP_header.Flags], TH_ACK
        jz      .no_syn_ack
 
; now, process received SYN in response to an active open
 
        mov     eax, [edx + TCP_header.AckNumber]
        mov     [ebx + TCP_SOCKET.SND_UNA], eax
        cmp     eax, [ebx + TCP_SOCKET.SND_NXT]
        jbe     @f
        mov     [ebx + TCP_SOCKET.SND_NXT], eax
       @@:
 
  .no_syn_ack:
        and     [ebx + TCP_SOCKET.timer_flags], not timer_flag_retransmission   ; disable retransmission timer
 
        push    [edx + TCP_header.SequenceNumber]
        pop     [ebx + TCP_SOCKET.IRS]
 
        TCP_rcvseqinit ebx
 
        or      [ebx + TCP_SOCKET.t_flags], TF_ACKNOW
 
        mov     eax, [ebx + TCP_SOCKET.SND_UNA]
        cmp     eax, [ebx + TCP_SOCKET.ISS]
        jbe     .simultaneous_open
 
        test    [edx + TCP_header.Flags], TH_ACK
        jz      .simultaneous_open
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: active open\n"
 
;;; TODO: update stats
 
; set socket state to connected
        push    eax
        mov     eax, ebx
        call    SOCKET_is_connected
        pop     eax
        mov     [ebx + TCP_SOCKET.t_state], TCPS_ESTABLISHED
 
; Do window scaling on this connection ?
        mov     eax, [ebx + TCP_SOCKET.t_flags]
        and     eax, TF_REQ_SCALE or TF_RCVD_SCALE
        cmp     eax, TF_REQ_SCALE or TF_RCVD_SCALE
        jne     .no_scaling
 
        mov     ax, word [ebx + TCP_SOCKET.requested_s_scale]
        mov     word [ebx + TCP_SOCKET.SND_SCALE], ax
  .no_scaling:
 
;;; TODO: reassemble packets queue
 
        mov     eax, [ebx + TCP_SOCKET.t_rtt]
        test    eax, eax
        je      .trim_then_step6
        call    TCP_xmit_timer
        jmp     .trim_then_step6
 
  .simultaneous_open:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: simultaneous open\n"
; We have received a syn but no ACK, so we are having a simultaneous open..
        mov     [ebx + TCP_SOCKET.t_state], TCPS_SYN_RECEIVED
 
;-------------------------------------
; Common processing for receipt of SYN
 
  .trim_then_step6:
 
        inc     [edx + TCP_header.SequenceNumber]
 
; Drop any received data that doesnt fit in the receive window.
        cmp     ecx, [ebx + TCP_SOCKET.RCV_WND]
        jbe     .dont_trim
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: received data does not fit in window, trimming %u bytes\n", eax
        mov     ecx, [ebx + TCP_SOCKET.RCV_WND]
        and     [edx + TCP_header.Flags], not (TH_FIN)
;;; TODO: update stats
 
  .dont_trim:
 
        mov     eax, [edx + TCP_header.SequenceNumber]
        mov     [ebx + TCP_SOCKET.RCV_UP], eax
        dec     eax
        mov     [ebx + TCP_SOCKET.SND_WL1], eax
 
;-------
; step 6
 
  .ack_processed:
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: ACK processed\n"
 
;----------------------------------------------
; check if we need to update window information
 
        test    [edx + TCP_header.Flags], TH_ACK
        jz      .no_window_update
 
        mov     eax, [ebx + TCP_SOCKET.SND_WL1]
        cmp     eax, [edx + TCP_header.SequenceNumber]
        jb      .update_window
        ja      @f
 
        mov     eax, [ebx + TCP_SOCKET.SND_WL2]
        cmp     eax, [edx + TCP_header.AckNumber]
        jb      .update_window
        ja      .no_window_update
       @@:
 
        mov     eax, dword [edx + TCP_header.Window]
        cmp     eax, [ebx + TCP_SOCKET.SND_WND]
        jbe     .no_window_update
 
  .update_window:
 
;;; TODO: update stats (Keep track of pure window updates)
 
        mov     eax, dword [edx + TCP_header.Window]
        cmp     eax, [ebx + TCP_SOCKET.max_sndwnd]
        jbe     @f
        mov     [ebx + TCP_SOCKET.max_sndwnd], eax
       @@:
        mov     [ebx + TCP_SOCKET.SND_WND], eax
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Updating window to %u\n", eax
 
        push    [edx + TCP_header.SequenceNumber]
        pop     [ebx + TCP_SOCKET.SND_WL1]
 
        push    [edx + TCP_header.AckNumber]
        pop     [ebx + TCP_SOCKET.SND_WL2]
 
        or      [temp_bits], TCP_BIT_NEEDOUTPUT
 
  .no_window_update:
 
;-----------------
; process URG flag
 
        test    [edx + TCP_header.Flags], TH_URG
        jz      .not_urgent
 
        cmp     [edx + TCP_header.UrgentPointer], 0
        jz      .not_urgent
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_TIMED_WAIT
        je      .not_urgent
 
; Ignore bogus urgent offsets
 
        movzx   eax, [edx + TCP_header.UrgentPointer]
        add     eax, [ebx + STREAM_SOCKET.rcv.size]
        cmp     eax, SOCKET_MAXDATA
        jbe     .not_urgent
 
        mov     [edx + TCP_header.UrgentPointer], 0
        and     [edx + TCP_header.Flags], not (TH_URG)
        jmp     .do_data
 
  .not_urgent:
 
; processing of received urgent pointer
 
        ;;; TODO (1051-1093)
 
 
;---------------------------------------
; process the data in the segment (1094)
 
  .do_data:
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_TIMED_WAIT
        jae     .final_processing
 
        test    [edx + TCP_header.Flags], TH_FIN
        jnz     @f
 
        test    ecx, ecx
        jz      .final_processing
       @@:
 
; The segment is in order?
        mov     eax, [edx + TCP_header.SequenceNumber]
        cmp     eax, [ebx + TCP_SOCKET.RCV_NXT]
        jne     .out_of_order
 
; The reassembly queue is empty?
        cmp     [ebx + TCP_SOCKET.seg_next], 0
        jne     .out_of_order
 
; The connection is established?
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_ESTABLISHED
        jne     .out_of_order
 
; Ok, lets do this..  Set delayed ACK flag and copy data into socket buffer
        or      [ebx + TCP_SOCKET.t_flags], TF_DELACK
 
        pusha
        mov     esi, [dataoffset]
        add     esi, edx
        lea     eax, [ebx + STREAM_SOCKET.rcv]
        call    SOCKET_ring_write                       ; Add the data to the socket buffer
        add     [ebx + TCP_SOCKET.RCV_NXT], ecx         ; Update sequence number with number of bytes we have copied
        popa
 
; Wake up the sleeping process
        mov     eax, ebx
        call    SOCKET_notify
 
        jmp     .data_done
 
  .out_of_order:
        DEBUGF  DEBUG_NETWORK_VERBOSE,  "TCP data is out of order!\nSequencenumber is %u, we expected %u.\n", \
        [edx + TCP_header.SequenceNumber], [ebx + TCP_SOCKET.RCV_NXT]
 
; Uh-oh, some data is out of order, lets call TCP reassemble for help
 
        call    TCP_reassemble
 
; Generate ACK immediately, to let the other end know that a segment was received out of order,
; and to tell it what sequence number is expected. This aids the fast-retransmit algorithm.
        or      [ebx + TCP_SOCKET.t_flags], TF_ACKNOW
  .data_done:
 
;---------------
; FIN processing
 
        test    [edx + TCP_header.Flags], TH_FIN
        jz      .final_processing
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Processing FIN\n"
 
        cmp     [ebx + TCP_SOCKET.t_state], TCPS_TIMED_WAIT
        jae     .not_first_fin
 
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: First FIN for this connection\n"
 
        mov     eax, ebx
        call    SOCKET_cant_recv_more
 
        or      [ebx + TCP_SOCKET.t_flags], TF_ACKNOW
        inc     [ebx + TCP_SOCKET.RCV_NXT]
 
  .not_first_fin:
        mov     eax, [ebx + TCP_SOCKET.t_state]
        shl     eax, 2
        jmp     dword [eax + .FIN_sw_list]
 
  .FIN_sw_list:
        dd      .final_processing       ; TCPS_CLOSED
        dd      .final_processing       ; TCPS_LISTEN
        dd      .final_processing       ; TCPS_SYN_SENT
        dd      .fin_syn_est            ; TCPS_SYN_RECEIVED
        dd      .fin_syn_est            ; TCPS_ESTABLISHED
        dd      .final_processing       ; TCPS_CLOSE_WAIT
        dd      .fin_wait1              ; TCPS_FIN_WAIT_1
        dd      .final_processing       ; TCPS_CLOSING
        dd      .final_processing       ; TCPS_LAST_ACK
        dd      .fin_wait2              ; TCPS_FIN_WAIT_2
        dd      .fin_timed              ; TCPS_TIMED_WAIT
 
  .fin_syn_est:
        mov     [ebx + TCP_SOCKET.t_state], TCPS_CLOSE_WAIT
        jmp     .final_processing
 
  .fin_wait1:
        mov     [ebx + TCP_SOCKET.t_state], TCPS_CLOSING
        jmp     .final_processing
 
  .fin_wait2:
        mov     [ebx + TCP_SOCKET.t_state], TCPS_TIMED_WAIT
        mov     eax, ebx
        call    TCP_cancel_timers
        call    SOCKET_is_disconnected
 
  .fin_timed:
        mov     [ebx + TCP_SOCKET.timer_timed_wait], 2 * TCP_time_MSL
        or      [ebx + TCP_SOCKET.timer_flags], timer_flag_wait
 
;-----------------
; Final processing
 
  .final_processing:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Final processing\n"
 
        push    ebx
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        pop     eax
 
        test    [temp_bits], TCP_BIT_NEEDOUTPUT
        jnz     .need_output
 
        test    [eax + TCP_SOCKET.t_flags], TF_ACKNOW
        jz      .dumpit
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: ACK now!\n"
 
  .need_output:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: need output\n"
        call    TCP_output
 
  .dumpit:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: dumping\n"
 
        call    NET_packet_free
        jmp     .loop
 
 
;-----------------
; Drop the segment
 
 
  .drop_after_ack:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Drop after ACK\n"
 
        push    edx ebx
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        pop     eax edx
 
        test    [edx + TCP_header.Flags], TH_RST
        jnz     .dumpit
 
        or      [eax + TCP_SOCKET.t_flags], TF_ACKNOW
        jmp     .need_output
 
  .drop_with_reset:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Drop with reset\n"
 
        push    ebx edx
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        pop     edx ebx
 
        test    [edx + TCP_header.Flags], TH_RST
        jnz     .dumpit
 
        ;;; if its a multicast/broadcast, also drop
 
        test    [edx + TCP_header.Flags], TH_ACK
        jnz     .respond_ack
 
        test    [edx + TCP_header.Flags], TH_SYN
        jnz     .respond_syn
        jmp     .dumpit
 
;---------
; Respond
 
  .respond_ack:
        push    ebx
        mov     cl, TH_RST
        call    TCP_respond
        pop     ebx
        jmp     .destroy_new_socket
 
  .respond_syn:
        push    ebx
        mov     cl, TH_RST + TH_ACK
        call    TCP_respond
        pop     ebx
        jmp     .destroy_new_socket
 
  .no_socket:
 
        pusha
        mov     ecx, socket_mutex
        call    mutex_unlock
        popa
 
  .respond_seg_reset:
        test    [edx + TCP_header.Flags], TH_RST
        jnz     .drop_no_socket
 
        ;;; TODO: if its a multicast/broadcast, also drop
 
        test    [edx + TCP_header.Flags], TH_ACK
        jnz     .respond_seg_ack
 
        test    [edx + TCP_header.Flags], TH_SYN
        jnz     .respond_seg_syn
 
        jmp     .drop_no_socket
 
  .respond_seg_ack:
        mov     cl, TH_RST
        call    TCP_respond_segment
        jmp     .drop_no_socket
 
  .respond_seg_syn:
        mov     cl, TH_RST + TH_ACK
        call    TCP_respond_segment
        jmp     .drop_no_socket
 
;-----
; Drop
 
  .drop:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Dropping segment\n"
 
        pusha
        lea     ecx, [ebx + SOCKET.mutex]
        call    mutex_unlock
        popa
 
  .destroy_new_socket:
        test    [temp_bits], TCP_BIT_DROPSOCKET
        jz      .drop_no_socket
 
        mov     eax, ebx
        call    SOCKET_free
 
  .drop_no_socket:
        DEBUGF  DEBUG_NETWORK_VERBOSE, "TCP_input: Drop (no socket)\n"
 
        call    NET_packet_free
        jmp     .loop
 
endp
>
>
>
>

Rev 4388	Rev 4510
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2004-2013. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2004-2013. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;; Part of the TCP/IP network stack for KolibriOS ;;	6	;; Part of the TCP/IP network stack for KolibriOS ;;
7	;; ;;	7	;; ;;
8	;; Written by hidnplayr@kolibrios.org ;;	8	;; Written by hidnplayr@kolibrios.org ;;
9	;; ;;	9	;; ;;
10	;; Based on the code of 4.4BSD ;;	10	;; Based on the code of 4.4BSD ;;
11	;; ;;	11	;; ;;
12	;; GNU GENERAL PUBLIC LICENSE ;;	12	;; GNU GENERAL PUBLIC LICENSE ;;
13	;; Version 2, June 1991 ;;	13	;; Version 2, June 1991 ;;
14	;; ;;	14	;; ;;
15	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	15	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
16		16
17	$Revision: 3407 $	17	$Revision: 3407 $
18		18
19	;-----------------------------------------------------------------	19	;-----------------------------------------------------------------
20	;	20	;
21	; TCP_input:	21	; TCP_input:
22	;	22	;
23	; Add a segment to the incoming TCP queue	23	; Add a segment to the incoming TCP queue
24	;	24	;
25	; IN: [esp] = ptr to buffer	25	; IN: [esp] = ptr to buffer
26	; [esp+4] = buffer size (dont care)	26	; [esp+4] = buffer size (dont care)
27	; ebx = ptr to device struct	27	; ebx = ptr to device struct
28	; ecx = segment size	28	; ecx = segment size
29	; esi = ptr to TCP segment	29	; esi = ptr to TCP segment
30	; edi = ptr to ipv4 source address, followed by ipv4 dest address	30	; edi = ptr to ipv4 source address, followed by ipv4 dest address
31	;	31	;
32	; OUT: /	32	; OUT: /
33	;	33	;
34	;-----------------------------------------------------------------	34	;-----------------------------------------------------------------
35		35
36	align 4	36	align 4
37	TCP_input:	37	TCP_input:
38		38
39	; record the current time	39	; record the current time
40	mov eax, [timer_ticks] ; in 1/100 seconds	40	mov eax, [timer_ticks] ; in 1/100 seconds
41	mov [esp + 4], eax	41	mov [esp + 4], eax
42		42
43	push ebx ecx esi edi ; mind the order	43	push ebx ecx esi edi ; mind the order
44	mov esi, esp	44	mov esi, esp
45		-
46	pushf	-
47	cli	45
48	add_to_queue TCP_queue, TCP_QUEUE_SIZE, sizeof.TCP_queue_entry, .fail	-
49	popf	-
50		46	add_to_queue TCP_queue, TCP_QUEUE_SIZE, sizeof.TCP_queue_entry, .fail
51	add esp, sizeof.TCP_queue_entry	47	add esp, sizeof.TCP_queue_entry
52		48
53	call NET_ptr_to_num4	49	call NET_ptr_to_num4
54	inc [TCP_segments_rx + edi]	50	inc [TCP_segments_rx + edi]
55		51
56	xor edx, edx	52	xor edx, edx
57	mov eax, [TCP_input_event]	53	mov eax, [TCP_input_event]
58	mov ebx, [eax + EVENT.id]	54	mov ebx, [eax + EVENT.id]
59	xor esi, esi	55	xor esi, esi
60	call raise_event	56	call raise_event
61		57
62	ret	58	ret
63		59
64	.fail:	60	.fail:
65	popf	61	popf
66	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP incoming queue is full, discarding packet!\n"	62	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP incoming queue is full, discarding packet!\n"
67		63
68	call NET_ptr_to_num4	64	call NET_ptr_to_num4
69	inc [TCP_segments_missed + edi]	65	inc [TCP_segments_missed + edi]
70		66
71	add esp, sizeof.TCP_queue_entry - 8	67	add esp, sizeof.TCP_queue_entry - 8
72	call NET_packet_free	68	call NET_packet_free
73	add esp, 4	69	add esp, 4
74		70
75	ret	71	ret
76		72
77		73
78		74
79		75
80	align 4	76	align 4
81	proc TCP_process_input	77	proc TCP_process_input
82		78
83	locals	79	locals
84	dataoffset dd ?	80	dataoffset dd ?
85	timestamp dd ?	81	timestamp dd ?
86	temp_bits db ?	82	temp_bits db ?
87	endl	83	endl
88		84
89	xor esi, esi	85	xor esi, esi
90	mov ecx, MANUAL_DESTROY	86	mov ecx, MANUAL_DESTROY
91	call create_event	87	call create_event
92	mov [TCP_input_event], eax	88	mov [TCP_input_event], eax
93		89
94	.wait:	90	.wait:
95	mov eax, [TCP_input_event]	91	mov eax, [TCP_input_event]
96	mov ebx, [eax + EVENT.id]	92	mov ebx, [eax + EVENT.id]
97	call wait_event	93	call wait_event
98		94
99	.loop:	95	.loop:
100	get_from_queue TCP_queue, TCP_QUEUE_SIZE, sizeof.TCP_queue_entry, .wait	96	get_from_queue TCP_queue, TCP_QUEUE_SIZE, sizeof.TCP_queue_entry, .wait
101		97
102	push [esi + TCP_queue_entry.timestamp]	98	push [esi + TCP_queue_entry.timestamp]
103	pop [timestamp]	99	pop [timestamp]
104	push [esi + TCP_queue_entry.buffer_ptr]	100	push [esi + TCP_queue_entry.buffer_ptr]
105		101
106	mov ebx, [esi + TCP_queue_entry.device_ptr]	102	mov ebx, [esi + TCP_queue_entry.device_ptr]
107	mov ecx, [esi + TCP_queue_entry.segment_size]	103	mov ecx, [esi + TCP_queue_entry.segment_size]
108	mov edi, [esi + TCP_queue_entry.ip_ptr] ; ptr to ipv4 source address, followed by ipv4 destination address	104	mov edi, [esi + TCP_queue_entry.ip_ptr] ; ptr to ipv4 source address, followed by ipv4 destination address
109	mov esi, [esi + TCP_queue_entry.segment_ptr] ; change esi last	105	mov esi, [esi + TCP_queue_entry.segment_ptr] ; change esi last
110		106
111	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: size=%u time=%d\n", ecx, [timer_ticks]	107	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: size=%u time=%d\n", ecx, [timer_ticks]
112		108
113	mov edx, esi	109	mov edx, esi
114		110
115	cmp ebx, LOOPBACK_DEVICE	111	cmp ebx, LOOPBACK_DEVICE
116	je .checksum_ok	112	je .checksum_ok
117		113
118	; re-calculate the checksum (if not already done by hw)	114	; re-calculate the checksum (if not already done by hw)
119	test [ebx + NET_DEVICE.hwacc], NET_HWACC_TCP_IPv4_IN	115	test [ebx + NET_DEVICE.hwacc], NET_HWACC_TCP_IPv4_IN
120	jnz .checksum_ok	116	jnz .checksum_ok
121		117
122	push ecx esi	118	push ecx esi
123	pushw [esi + TCP_header.Checksum]	119	pushw [esi + TCP_header.Checksum]
124	mov [esi + TCP_header.Checksum], 0	120	mov [esi + TCP_header.Checksum], 0
125	TCP_checksum (edi), (edi+4)	121	TCP_checksum (edi), (edi+4)
126	pop cx ; previous checksum	122	pop cx ; previous checksum
127	cmp cx, dx	123	cmp cx, dx
128	pop edx ecx	124	pop edx ecx
129	jne .drop_no_socket	125	jne .drop_no_socket
130	.checksum_ok:	126	.checksum_ok:
131		127
132	; Verify the data offset	128	; Verify the data offset
133	movzx eax, [edx + TCP_header.DataOffset]	129	movzx eax, [edx + TCP_header.DataOffset]
134	and al, 0xf0 ; Calculate TCP segment header size (throwing away unused reserved bits in TCP header)	130	and al, 0xf0 ; Calculate TCP segment header size (throwing away unused reserved bits in TCP header)
135	shr al, 2	131	shr al, 2
136	cmp al, sizeof.TCP_header ; Now see if it's at least the size of a standard TCP header	132	cmp al, sizeof.TCP_header ; Now see if it's at least the size of a standard TCP header
137	jb .drop_no_socket ; If not, drop the packet	133	jb .drop_no_socket ; If not, drop the packet
138	mov [dataoffset], eax	134	mov [dataoffset], eax
139		135
140	sub ecx, eax ; substract TCP header size from total segment size	136	sub ecx, eax ; substract TCP header size from total segment size
141	jb .drop_no_socket ; If total segment size is less then the advertised header size, drop packet	137	jb .drop_no_socket ; If total segment size is less then the advertised header size, drop packet
142	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: %u bytes of data\n", ecx	138	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: %u bytes of data\n", ecx
143		139
144	;-------------------------------------------	140	;-------------------------------------------
145	; Convert Big-endian values to little endian	141	; Convert Big-endian values to little endian
146		142
147	ntohd [edx + TCP_header.SequenceNumber]	143	ntohd [edx + TCP_header.SequenceNumber]
148	ntohd [edx + TCP_header.AckNumber]	144	ntohd [edx + TCP_header.AckNumber]
149		145
150	ntohw [edx + TCP_header.Window]	146	ntohw [edx + TCP_header.Window]
151	ntohw [edx + TCP_header.UrgentPointer]	147	ntohw [edx + TCP_header.UrgentPointer]
152		148
153	;------------------------	149	;------------------------
154	; Find the socket pointer	150	; Find the socket pointer
155		151
156	; IP Packet TCP Destination Port = local Port	152	; IP Packet TCP Destination Port = local Port
157	; (IP Packet SenderAddress = Remote IP) OR (Remote IP = 0)	153	; (IP Packet SenderAddress = Remote IP) OR (Remote IP = 0)
158	; (IP Packet TCP Source Port = remote Port) OR (remote Port = 0)	154	; (IP Packet TCP Source Port = remote Port) OR (remote Port = 0)
159		155
160	.findpcb:	156	.findpcb:
161	pusha	157	pusha
162	mov ecx, socket_mutex	158	mov ecx, socket_mutex
163	call mutex_lock	159	call mutex_lock
164	popa	160	popa
165		161
166	mov ebx, net_sockets	162	mov ebx, net_sockets
167	mov si, [edx + TCP_header.DestinationPort]	163	mov si, [edx + TCP_header.DestinationPort]
168		164
169	.socket_loop:	165	.socket_loop:
170	mov ebx, [ebx + SOCKET.NextPtr]	166	mov ebx, [ebx + SOCKET.NextPtr]
171	or ebx, ebx	167	or ebx, ebx
172	jz .no_socket ;respond_seg_reset	168	jz .no_socket ;respond_seg_reset
173		169
174	cmp [ebx + SOCKET.Domain], AF_INET4	170	cmp [ebx + SOCKET.Domain], AF_INET4
175	jne .socket_loop	171	jne .socket_loop
176		172
177	cmp [ebx + SOCKET.Protocol], IP_PROTO_TCP	173	cmp [ebx + SOCKET.Protocol], IP_PROTO_TCP
178	jne .socket_loop	174	jne .socket_loop
179		175
180	cmp [ebx + TCP_SOCKET.LocalPort], si	176	cmp [ebx + TCP_SOCKET.LocalPort], si
181	jne .socket_loop	177	jne .socket_loop
182		178
183	mov eax, [ebx + IP_SOCKET.RemoteIP]	179	mov eax, [ebx + IP_SOCKET.RemoteIP]
184	cmp eax, [edi] ; Ipv4 source address	180	cmp eax, [edi] ; Ipv4 source address
185	je @f	181	je @f
186	test eax, eax	182	test eax, eax
187	jnz .socket_loop	183	jnz .socket_loop
188	@@:	184	@@:
189		185
190	mov ax, [ebx + TCP_SOCKET.RemotePort]	186	mov ax, [ebx + TCP_SOCKET.RemotePort]
191	cmp [edx + TCP_header.SourcePort], ax	187	cmp [edx + TCP_header.SourcePort], ax
192	je .found_socket	188	je .found_socket
193	test ax, ax	189	test ax, ax
194	jnz .socket_loop	190	jnz .socket_loop
195	.found_socket: ; ebx now contains the socketpointer	191	.found_socket: ; ebx now contains the socketpointer
196	pusha	192	pusha
197	mov ecx, socket_mutex	193	mov ecx, socket_mutex
198	call mutex_unlock	194	call mutex_unlock
199	popa	195	popa
200		196
201	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: socket ptr=%x state=%u flags=%x\n", ebx, [ebx + TCP_SOCKET.t_state], [edx + TCP_header.Flags]:2	197	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: socket ptr=%x state=%u flags=%x\n", ebx, [ebx + TCP_SOCKET.t_state], [edx + TCP_header.Flags]:2
202		198
203	;----------------------------	199	;----------------------------
204	; Check if socket isnt closed	200	; Check if socket isnt closed
205		201
206	cmp [ebx + TCP_SOCKET.t_state], TCPS_CLOSED	202	cmp [ebx + TCP_SOCKET.t_state], TCPS_CLOSED
207	je .drop_no_socket	203	je .drop_no_socket
208		204
209	;----------------	205	;----------------
210	; Lock the socket	206	; Lock the socket
211		207
212	pusha	208	pusha
213	lea ecx, [ebx + SOCKET.mutex]	209	lea ecx, [ebx + SOCKET.mutex]
214	call mutex_lock	210	call mutex_lock
215	popa	211	popa
216		212
217	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: socket locked\n"	213	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: socket locked\n"
218		214
219	;---------------------------	215	;---------------------------
220	; disable all temporary bits	216	; disable all temporary bits
221		217
222	mov [temp_bits], 0	218	mov [temp_bits], 0
223		219
224	;---------------------------------------	220	;---------------------------------------
225	; unscale the window into a 32 bit value	221	; unscale the window into a 32 bit value
226		222
227	movzx eax, [edx + TCP_header.Window]	223	movzx eax, [edx + TCP_header.Window]
228	push ecx	224	push ecx
229	mov cl, [ebx + TCP_SOCKET.SND_SCALE]	225	mov cl, [ebx + TCP_SOCKET.SND_SCALE]
230	shl eax, cl	226	shl eax, cl
231	mov dword [edx + TCP_header.Window], eax ; word after window is checksum, we dont need checksum anymore	227	mov dword [edx + TCP_header.Window], eax ; word after window is checksum, we dont need checksum anymore
232	pop ecx	228	pop ecx
233		229
234	;---------------------------------------	230	;---------------------------------------
235	; Are we accepting incoming connections?	231	; Are we accepting incoming connections?
236		232
237	test [ebx + SOCKET.options], SO_ACCEPTCON	233	test [ebx + SOCKET.options], SO_ACCEPTCON
238	jz .no_accept	234	jz .no_accept
239		235
240	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Accepting new connection\n"	236	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Accepting new connection\n"
241		237
242	pusha	238	pusha
243	lea ecx, [ebx + SOCKET.mutex]	239	lea ecx, [ebx + SOCKET.mutex]
244	call mutex_unlock	240	call mutex_unlock
245	popa	241	popa
246		242
247	push ecx edx esi edi ;;;	243	push ecx edx esi edi ;;;
248	call SOCKET_fork	244	call SOCKET_fork
249	pop edi esi edx ecx	245	pop edi esi edx ecx
250		246
251	test eax, eax	247	test eax, eax
252	jz .drop_no_socket	248	jz .drop_no_socket
253		249
254	mov ebx, eax	250	mov ebx, eax
255		251
256	mov [temp_bits], TCP_BIT_DROPSOCKET	252	mov [temp_bits], TCP_BIT_DROPSOCKET
257		253
258	push dword [edi + 4] ; Ipv4 destination addres	254	push dword [edi + 4] ; Ipv4 destination addres
259	pop [ebx + IP_SOCKET.LocalIP]	255	pop [ebx + IP_SOCKET.LocalIP]
260		256
261	push [edx + TCP_header.DestinationPort]	257	push [edx + TCP_header.DestinationPort]
262	pop [ebx + TCP_SOCKET.LocalPort]	258	pop [ebx + TCP_SOCKET.LocalPort]
263		259
264	mov [ebx + TCP_SOCKET.t_state], TCPS_LISTEN	260	mov [ebx + TCP_SOCKET.t_state], TCPS_LISTEN
265	.no_accept:	261	.no_accept:
266		262
267		263
268	;-------------------------------------	264	;-------------------------------------
269	; Reset idle timer and keepalive timer	265	; Reset idle timer and keepalive timer
270		266
271	mov [ebx + TCP_SOCKET.t_idle], 0	267	mov [ebx + TCP_SOCKET.t_idle], 0
272	mov [ebx + TCP_SOCKET.timer_keepalive], TCP_time_keep_idle	268	mov [ebx + TCP_SOCKET.timer_keepalive], TCP_time_keep_idle
273	or [ebx + TCP_SOCKET.timer_flags], timer_flag_keepalive	269	or [ebx + TCP_SOCKET.timer_flags], timer_flag_keepalive
274		270
275	;--------------------	271	;--------------------
276	; Process TCP options	272	; Process TCP options
277		273
278	;;; FIXME: for LISTEN, options should be called after we determined route, we need it for MSS	274	;;; FIXME: for LISTEN, options should be called after we determined route, we need it for MSS
279	;;; cmp [ebx + TCP_SOCKET.t_state], TCPS_LISTEN ; no options when in listen state	275	;;; cmp [ebx + TCP_SOCKET.t_state], TCPS_LISTEN ; no options when in listen state
280	;;; jz .not_uni_xfer ; also no header prediction	276	;;; jz .not_uni_xfer ; also no header prediction
281		277
282	push ecx	278	push ecx
283		279
284	mov ecx, [dataoffset]	280	mov ecx, [dataoffset]
285	cmp ecx, sizeof.TCP_header ; Does header contain any options?	281	cmp ecx, sizeof.TCP_header ; Does header contain any options?
286	je .no_options	282	je .no_options
287		283
288	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Segment has options\n"	284	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Segment has options\n"
289		285
290	add ecx, edx	286	add ecx, edx
291	lea esi, [edx + sizeof.TCP_header]	287	lea esi, [edx + sizeof.TCP_header]
292		288
293	.opt_loop:	289	.opt_loop:
294	cmp esi, ecx ; are we scanning outside of header?	290	cmp esi, ecx ; are we scanning outside of header?
295	jae .no_options	291	jae .no_options
296	lodsb	292	lodsb
297	cmp al, TCP_OPT_EOL ; end of option list?	293	cmp al, TCP_OPT_EOL ; end of option list?
298	je .no_options	294	je .no_options
299	cmp al, TCP_OPT_NOP	295	cmp al, TCP_OPT_NOP
300	je .opt_loop	296	je .opt_loop
301	cmp al, TCP_OPT_MAXSEG	297	cmp al, TCP_OPT_MAXSEG
302	je .opt_maxseg	298	je .opt_maxseg
303	cmp al, TCP_OPT_WINDOW	299	cmp al, TCP_OPT_WINDOW
304	je .opt_window	300	je .opt_window
305	cmp al, TCP_OPT_SACK_PERMIT	301	cmp al, TCP_OPT_SACK_PERMIT
306	je .opt_sack_permit	302	je .opt_sack_permit
307	; cmp al, TCP_OPT_SACK	303	; cmp al, TCP_OPT_SACK
308	; je .opt_sack	304	; je .opt_sack
309	cmp al, TCP_OPT_TIMESTAMP	305	cmp al, TCP_OPT_TIMESTAMP
310	je .opt_timestamp	306	je .opt_timestamp
311	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: unknown option:%u\n", al	307	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: unknown option:%u\n", al
312	jmp .no_options ; If we reach here, some unknown options were received, skip them all!	308	jmp .no_options ; If we reach here, some unknown options were received, skip them all!
313		309
314	.opt_maxseg:	310	.opt_maxseg:
315	lodsb	311	lodsb
316	cmp al, 4	312	cmp al, 4
317	jne .no_options ; error occured, ignore all options!	313	jne .no_options ; error occured, ignore all options!
318		314
319	test [edx + TCP_header.Flags], TH_SYN	315	test [edx + TCP_header.Flags], TH_SYN
320	jz @f	316	jz @f
321		317
322	xor eax, eax	318	xor eax, eax
323	lodsw	319	lodsw
324	rol ax, 8	320	rol ax, 8
325	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Maxseg=%u\n", eax	321	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Maxseg=%u\n", eax
326	call TCP_mss	322	call TCP_mss
327	@@:	323	@@:
328	jmp .opt_loop	324	jmp .opt_loop
329		325
330		326
331	.opt_window:	327	.opt_window:
332	lodsb	328	lodsb
333	cmp al, 3	329	cmp al, 3
334	jne .no_options	330	jne .no_options
335		331
336	test [edx + TCP_header.Flags], TH_SYN	332	test [edx + TCP_header.Flags], TH_SYN
337	jz @f	333	jz @f
338		334
339	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Got window scale option\n"	335	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Got window scale option\n"
340	or [ebx + TCP_SOCKET.t_flags], TF_RCVD_SCALE	336	or [ebx + TCP_SOCKET.t_flags], TF_RCVD_SCALE
341		337
342	lodsb	338	lodsb
343	mov [ebx + TCP_SOCKET.SND_SCALE], al	339	mov [ebx + TCP_SOCKET.SND_SCALE], al
344	;;;;; TODO	340	;;;;; TODO
345		341
346	@@:	342	@@:
347	jmp .opt_loop	343	jmp .opt_loop
348		344
349		345
350	.opt_sack_permit:	346	.opt_sack_permit:
351	lodsb	347	lodsb
352	cmp al, 2	348	cmp al, 2
353	jne .no_options	349	jne .no_options
354		350
355	test [edx + TCP_header.Flags], TH_SYN	351	test [edx + TCP_header.Flags], TH_SYN
356	jz @f	352	jz @f
357		353
358	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Selective Acknowledgement permitted\n"	354	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Selective Acknowledgement permitted\n"
359	or [ebx + TCP_SOCKET.t_flags], TF_SACK_PERMIT	355	or [ebx + TCP_SOCKET.t_flags], TF_SACK_PERMIT
360		356
361	@@:	357	@@:
362	jmp .opt_loop	358	jmp .opt_loop
363		359
364		360
365	.opt_timestamp:	361	.opt_timestamp:
366	lodsb	362	lodsb
367	cmp al, 10 ; length must be 10	363	cmp al, 10 ; length must be 10
368	jne .no_options	364	jne .no_options
369		365
370	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Got timestamp option\n"	366	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Got timestamp option\n"
371		367
372	test [edx + TCP_header.Flags], TH_SYN	368	test [edx + TCP_header.Flags], TH_SYN
373	jz @f	369	jz @f
374	or [ebx + TCP_SOCKET.t_flags], TF_RCVD_TSTMP	370	or [ebx + TCP_SOCKET.t_flags], TF_RCVD_TSTMP
375	@@:	371	@@:
376		372
377	lodsd	373	lodsd
378	bswap eax	374	bswap eax
379	mov [ebx + TCP_SOCKET.ts_val], eax	375	mov [ebx + TCP_SOCKET.ts_val], eax
380	lodsd ; timestamp echo reply	376	lodsd ; timestamp echo reply
381	mov [ebx + TCP_SOCKET.ts_ecr], eax	377	mov [ebx + TCP_SOCKET.ts_ecr], eax
382	or [temp_bits], TCP_BIT_TIMESTAMP	378	or [temp_bits], TCP_BIT_TIMESTAMP
383		379
384	; Since we have a timestamp, lets do the paws test right away!	380	; Since we have a timestamp, lets do the paws test right away!
385		381
386	test [edx + TCP_header.Flags], TH_RST	382	test [edx + TCP_header.Flags], TH_RST
387	jnz .no_paws	383	jnz .no_paws
388		384
389	mov eax, [ebx + TCP_SOCKET.ts_recent]	385	mov eax, [ebx + TCP_SOCKET.ts_recent]
390	test eax, eax	386	test eax, eax
391	jz .no_paws	387	jz .no_paws
392	cmp eax, [ebx + TCP_SOCKET.ts_val]	388	cmp eax, [ebx + TCP_SOCKET.ts_val]
393	jbe .no_paws	389	jbe .no_paws
394		390
395	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: PAWS: detected an old segment\n"	391	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: PAWS: detected an old segment\n"
396		392
397	mov eax, [timestamp]	393	mov eax, [timestamp]
398	sub eax, [ebx + TCP_SOCKET.ts_recent_age]	394	sub eax, [ebx + TCP_SOCKET.ts_recent_age]
399		395
400	pop ecx	396	pop ecx
401	cmp eax, TCP_PAWS_IDLE	397	cmp eax, TCP_PAWS_IDLE
402	jle .drop_after_ack ; TODO: update stats	398	jle .drop_after_ack ; TODO: update stats
403	push ecx	399	push ecx
404		400
405	mov [ebx + TCP_SOCKET.ts_recent], 0 ; timestamp was invalid, fix it.	401	mov [ebx + TCP_SOCKET.ts_recent], 0 ; timestamp was invalid, fix it.
406	.no_paws:	402	.no_paws:
407	jmp .opt_loop	403	jmp .opt_loop
408		404
409	.no_options:	405	.no_options:
410		406
411	pop ecx	407	pop ecx
412		408
413	;-----------------------------------------------------------------------	409	;-----------------------------------------------------------------------
414	; Time to do some header prediction (Original Principle by Van Jacobson)	410	; Time to do some header prediction (Original Principle by Van Jacobson)
415		411
416	; There are two common cases for an uni-directional data transfer.	412	; There are two common cases for an uni-directional data transfer.
417	;	413	;
418	; General rule: the packets has no control flags, is in-sequence,	414	; General rule: the packets has no control flags, is in-sequence,
419	; window width didnt change and we're not retransmitting.	415	; window width didnt change and we're not retransmitting.
420	;	416	;
421	; Second rules:	417	; Second rules:
422	; - If the length is 0 and the ACK moved forward, we're the sender side of the transfer.	418	; - If the length is 0 and the ACK moved forward, we're the sender side of the transfer.
423	; In this case we'll free the ACK'ed data and notify higher levels that we have free space in buffer	419	; In this case we'll free the ACK'ed data and notify higher levels that we have free space in buffer
424	;	420	;
425	; - If the length is not 0 and the ACK didn't move, we're the receiver side of the transfer.	421	; - If the length is not 0 and the ACK didn't move, we're the receiver side of the transfer.
426	; If the packets are in order (data queue is empty), add the data to the socket buffer and request a delayed ACK	422	; If the packets are in order (data queue is empty), add the data to the socket buffer and request a delayed ACK
427		423
428	cmp [ebx + TCP_SOCKET.t_state], TCPS_ESTABLISHED	424	cmp [ebx + TCP_SOCKET.t_state], TCPS_ESTABLISHED
429	jnz .not_uni_xfer	425	jnz .not_uni_xfer
430		426
431	test [edx + TCP_header.Flags], TH_SYN + TH_FIN + TH_RST + TH_URG	427	test [edx + TCP_header.Flags], TH_SYN + TH_FIN + TH_RST + TH_URG
432	jnz .not_uni_xfer	428	jnz .not_uni_xfer
433		429
434	test [edx + TCP_header.Flags], TH_ACK	430	test [edx + TCP_header.Flags], TH_ACK
435	jz .not_uni_xfer	431	jz .not_uni_xfer
436		432
437	mov eax, [edx + TCP_header.SequenceNumber]	433	mov eax, [edx + TCP_header.SequenceNumber]
438	cmp eax, [ebx + TCP_SOCKET.RCV_NXT]	434	cmp eax, [ebx + TCP_SOCKET.RCV_NXT]
439	jne .not_uni_xfer	435	jne .not_uni_xfer
440		436
441	mov eax, dword [edx + TCP_header.Window]	437	mov eax, dword [edx + TCP_header.Window]
442	cmp eax, [ebx + TCP_SOCKET.SND_WND]	438	cmp eax, [ebx + TCP_SOCKET.SND_WND]
443	jne .not_uni_xfer	439	jne .not_uni_xfer
444		440
445	mov eax, [ebx + TCP_SOCKET.SND_NXT]	441	mov eax, [ebx + TCP_SOCKET.SND_NXT]
446	cmp eax, [ebx + TCP_SOCKET.SND_MAX]	442	cmp eax, [ebx + TCP_SOCKET.SND_MAX]
447	jne .not_uni_xfer	443	jne .not_uni_xfer
448		444
449	;---------------------------------------	445	;---------------------------------------
450	; check if we are sender in the uni-xfer	446	; check if we are sender in the uni-xfer
451		447
452	; If the following 4 conditions are all true, this segment is a pure ACK.	448	; If the following 4 conditions are all true, this segment is a pure ACK.
453	;	449	;
454	; - The segment contains no data.	450	; - The segment contains no data.
455	test ecx, ecx	451	test ecx, ecx
456	jnz .not_sender	452	jnz .not_sender
457		453
458	; - The congestion window is greater than or equal to the current send window.	454	; - The congestion window is greater than or equal to the current send window.
459	; This test is true only if the window is fully open, that is, the connection is not in the middle of slow start or congestion avoidance.	455	; This test is true only if the window is fully open, that is, the connection is not in the middle of slow start or congestion avoidance.
460	mov eax, [ebx + TCP_SOCKET.SND_CWND]	456	mov eax, [ebx + TCP_SOCKET.SND_CWND]
461	cmp eax, [ebx + TCP_SOCKET.SND_WND]	457	cmp eax, [ebx + TCP_SOCKET.SND_WND]
462	jb .not_uni_xfer	458	jb .not_uni_xfer
463		459
464	; - The acknowledgment field in the segment is less than or equal to the maximum sequence number sent.	460	; - The acknowledgment field in the segment is less than or equal to the maximum sequence number sent.
465	mov eax, [edx + TCP_header.AckNumber]	461	mov eax, [edx + TCP_header.AckNumber]
466	cmp eax, [ebx + TCP_SOCKET.SND_MAX]	462	cmp eax, [ebx + TCP_SOCKET.SND_MAX]
467	ja .not_uni_xfer	463	ja .not_uni_xfer
468		464
469	; - The acknowledgment field in the segment is greater than the largest unacknowledged sequence number.	465	; - The acknowledgment field in the segment is greater than the largest unacknowledged sequence number.
470	sub eax, [ebx + TCP_SOCKET.SND_UNA]	466	sub eax, [ebx + TCP_SOCKET.SND_UNA]
471	jbe .not_uni_xfer	467	jbe .not_uni_xfer
472		468
473	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Header prediction: we are sender\n"	469	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_input: Header prediction: we are sender\n"
474		470
475	;---------------------------------	471	;---------------------------------
476	; Packet is a pure ACK, process it	472	; Packet is a pure ACK, process it
477		473
478	; Delete acknowledged bytes from send buffer	474	; Delete acknowledged bytes from send buffer
479	pusha	475	pusha
480	mov ecx, eax	476	mov ecx, eax
481	lea eax, [ebx + STREAM_SOCKET.snd]	477	lea eax, [ebx + STREAM_SOCKET.snd]
482	call SOCKET_ring_free	478	call SOCKET_ring_free
483	popa	479	popa
484		480
485	; Update RTT estimators	481	; Update RTT estimators
486		482
487	test [temp_bits], TCP_BIT_TIMESTAMP	483	test [temp_bits], TCP_BIT_TIMESTAMP
488	jz .no_timestamp_rtt	484	jz .no_timestamp_rtt
489	mov eax, [timestamp]	485	mov eax, [timestamp]
490	sub eax, [ebx + TCP_SOCKET.ts_ecr]	486	sub eax, [ebx + TCP_SOCKET.ts_ecr]
491	inc eax	487	inc eax
492	call TCP_xmit_timer	488	call TCP_xmit_timer
493	jmp .rtt_done	489	jmp .rtt_done
494		490
495	.no_timestamp_rtt:	491	.no_timestamp_rtt:
496	cmp [ebx + TCP_SOCKET.t_rtt], 0	492	cmp [ebx + TCP_SOCKET.t_rtt], 0
497	je .rtt_done	493	je .rtt_done
498	mov eax, [edx + TCP_header.AckNumber]	494	mov eax, [edx + TCP_header.AckNumber]
499	cmp eax, [ebx + TCP_SOCKET.t_rtseq]	495	cmp eax, [ebx + TCP_SOCKET.t_rtseq]
500	jbe .rtt_done	496	jbe .rtt_done

Subversion Repositories Kolibri OS

(root)/kernel/trunk/network/tcp_input.inc – Rev 4388 → 4510