WebSVN – Kolibri OS – Diff – /kernel/trunk/fs/ntfs.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                              ;;
;; Copyright (C) KolibriOS team 2004-2015. All rights reserved. ;;
;; Distributed under terms of the GNU General Public License    ;;
;;                                                              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 5994 $
 
; NTFS driver
 
; Basic concepts:
; File is a FileRecord in the $MFT.
; $MFT is a file, that consists of FileRecords and starts with FileRecord of itself.
; FileRecord (FILE) consists of a header and attributes.
; Attribute consists of a header and a body.
; Attribute's body can be inside (resident) or outside of FileRecord.
; File's data is a body of $Data (80h) attribute.
; FileRecords is a data of the $MFT file.
; Directory is a file, that consists of index nodes.
; Resident index node is always located in a body of $IndexRoot (90h) attribute.
; Body of $IndexAllocation (A0h) attribute is always non resident
;  and consists of IndexRecords.
; IndexRecord (INDX) consists of a header and an index node.
; Index node consists of a header and indexes.
; Index consists of a header and a copy of indexed attribute's body.
; Directories index $Filename (30h) attribute of all existing files.
; $IndexRoot and $IndexAllocation attributes of a directory has a name — $I30.
 
; Offsets:
    ; record header
updateSequenceOffset = 4
updateSequenceSize = 6
reuseCounter = 16
hardLinkCounter = 12h
attributeOffset = 14h
recordFlags = 16h
recordRealSize = 18h
recordAllocatedSize = 1ch
baseRecordReference = 20h       ; for auxiliary records
baseRecordReuse = 26h
newAttributeID = 28h
    ; attribute header
attributeType = 0
sizeWithHeader = 4
nonResidentFlag = 8
nameLength = 9
nameOffset = 10
attributeID = 14
sizeWithoutHeader = 16
attributeFlags = 16h
    ; non resident attribute header
lastVCN = 18h
dataRunsOffset = 20h
attributeAllocatedSize = 28h
attributeRealSize = 30h
initialDataSize = 38h
    ; $IndexRoot
collationRule = 4
indexRecordSize = 8
indexRecordSizeClus = 12
    ; node header
indexOffset = 0
nodeRealSize = 4
nodeAllocatedSize = 8
    ; $Filename index
fileRecordReference = 0
fileReferenceReuse = 6
indexAllocatedSize = 8
indexRawSize = 10
indexFlags = 12
directoryRecordReference = 16
directoryReferenceReuse = 16h
fileAllocatedSize = 38h
fileRealSize = 40h
fileFlags = 48h
fileNameLength = 50h
 
struct NTFS PARTITION
Lock                MUTEX   ?   ; Currently operations with one partition
; can not be executed in parallel since the legacy code is not ready.
sectors_per_cluster     dd  ?
mft_cluster             dd  ?   ; location
mftmirr_cluster         dd  ?   ; location
frs_size                dd  ?   ; in bytes
frs_buffer              dd  ?   ; MFT fileRecord buffer
mft_retrieval           dd  ?
mft_retrieval_size      dd  ?
mft_retrieval_alloc     dd  ?
mft_retrieval_end       dd  ?
cur_index_size          dd  ?   ; in sectors
cur_index_buf           dd  ?   ; index node buffer
BitmapBuffer            dd  ?
BitmapTotalSize         dd  ?   ; bytes reserved
BitmapSize              dd  ?   ; bytes readen
BitmapLocation          dd  ?   ; starting sector
BitmapStart             dd  ?   ; first byte after area, reserved for MFT
mftBitmapBuffer         dd  ?   ; one cluster
mftBitmapSize           dd  ?   ; bytes readen
mftBitmapLocation       dd  ?   ; starting sector
 
ntfs_cur_attr           dd  ?   ; attribute type
ntfs_cur_iRecord        dd  ?   ; number of fileRecord in MFT
ntfs_cur_offs           dd  ?   ; attribute VCN in sectors
ntfs_cur_size           dd  ?   ; max sectors to read
ntfs_cur_buf            dd  ?
ntfs_cur_read           dd  ?   ; bytes readen
ntfsLastRead            dd  ?   ; last readen block of sectors
newMftRecord            dd  ?   ; number of fileRecord in MFT
fileDataStart           dd  ?   ; starting cluster
fileDataSize            dd  ?   ; in clusters
fileRealSize            dd  ?   ; in bytes
indexOffset             dd  ?
nodeLastRead            dd  ?
ntfs_bCanContinue       db  ?
 
ntfsFolder              db  ?
ntfsWriteAttr           db  ?   ; Warning: Don't forget to turn off!!!
ntfsFragmentCount       db  ?
 
cur_subnode_size        dd  ?
ntfs_attr_iRecord       dd  ?
ntfs_attr_iBaseRecord   dd  ?
ntfs_attr_offs          dd  ?
ntfs_attr_list          dd  ?
ntfs_attr_size          dq  ?
ntfs_cur_tail           dd  ?
 
ntfs_attrlist_buf       rb  0x400
ntfs_attrlist_mft_buf   rb  0x400
ntfs_bitmap_buf         rb  0x400
ends
 
; NTFS external functions
;   in:
; ebx -> parameter structure of sysfunc 70
; ebp -> NTFS structure
; [esi]+[esp+4] = name
;   out:
; eax, ebx = return values for sysfunc 70
iglobal
align 4
ntfs_user_functions:
        dd      ntfs_free
        dd      (ntfs_user_functions_end - ntfs_user_functions - 4) / 4
        dd      ntfs_ReadFile
        dd      ntfs_ReadFolder
        dd      ntfs_CreateFile
        dd      ntfs_WriteFile
        dd      ntfs_SetFileEnd
        dd      ntfs_GetFileInfo
        dd      ntfs_SetFileInfo
        dd      0
        dd      ntfs_Delete
        dd      ntfs_CreateFolder
ntfs_user_functions_end:
endg
 
ntfs_test_bootsec:
; in: ebx -> buffer, edx = size of partition
; out: CF=1 -> invalid
; 1. Name=='NTFS    '
        cmp     dword [ebx+3], 'NTFS'
        jnz     .no
        cmp     dword [ebx+7], '    '
        jnz     .no
; 2. Number of bytes per sector is the same as for physical device
; (that is, 0x200 for hard disk)
        cmp     word [ebx+11], 0x200
        jnz     .no
; 3. Number of sectors per cluster must be power of 2
        movzx   eax, byte [ebx+13]
        dec     eax
        js      .no
        test    al, [ebx+13]
        jnz     .no
; 4. FAT parameters must be zero
        cmp     word [ebx+14], 0
        jnz     .no
        cmp     dword [ebx+16], 0
        jnz     .no
        cmp     byte [ebx+20], 0
        jnz     .no
        cmp     word [ebx+22], 0
        jnz     .no
        cmp     dword [ebx+32], 0
        jnz     .no
; 5. Number of sectors <= partition size
        cmp     dword [ebx+0x2C], 0
        ja      .no
        cmp     [ebx+0x28], edx
        ja      .no
; 6. $MFT and $MFTMirr clusters must be within partition
        cmp     dword [ebx+0x34], 0
        ja      .no
        push    edx
        movzx   eax, byte [ebx+13]
        mul     dword [ebx+0x30]
        test    edx, edx
        pop     edx
        jnz     .no
        cmp     eax, edx
        ja      .no
        cmp     dword [ebx+0x3C], 0
        ja      .no
        push    edx
        movzx   eax, byte [ebx+13]
        mul     dword [ebx+0x38]
        test    edx, edx
        pop     edx
        jnz     .no
        cmp     eax, edx
        ja      .no
; 7. Clusters per FRS must be either power of 2 or between -31 and -9
        movsx   eax, byte [ebx+0x40]
        cmp     al, -31
        jl      .no
        cmp     al, -9
        jle     @f
        dec     eax
        js      .no
        test    [ebx+0x40], al
        jnz     .no
@@:         ; 8. Same for clusters per IndexAllocationBuffer
        movsx   eax, byte [ebx+0x44]
        cmp     al, -31
        jl      .no
        cmp     al, -9
        jle     @f
        dec     eax
        js      .no
        test    [ebx+0x44], al
        jnz     .no
@@:         ; OK, this is correct NTFS bootsector
        clc
        ret
.no:        ; No, this bootsector isn't NTFS
        stc
        ret
 
ntfs_create_partition:
        cmp     dword [esi+DISK.MediaInfo.SectorSize], 512
        jnz     .nope
        mov     edx, dword [ebp+PARTITION.Length]
        cmp     dword [esp+4], 0
        jz      .boot_read_ok
        add     ebx, 512
        lea     eax, [edx-1]
        call    fs_read32_sys
        test    eax, eax
        jnz     @f
        call    ntfs_test_bootsec
        jnc     .ntfs_setup
@@:
        mov     eax, edx
        shr     eax, 1
        call    fs_read32_sys
        test    eax, eax
        jnz     .nope
.boot_read_ok:
        call    ntfs_test_bootsec
        jnc     .ntfs_setup
.nope:
        xor     eax, eax
        jmp     .exit
; By given bootsector, initialize some NTFS variables
.ntfs_setup:
        movi    eax, sizeof.NTFS
        call    malloc
        test    eax, eax
        jz      .exit
        mov     ecx, dword [ebp+PARTITION.FirstSector]
        mov     dword [eax+NTFS.FirstSector], ecx
        mov     ecx, dword [ebp+PARTITION.FirstSector+4]
        mov     dword [eax+NTFS.FirstSector+4], ecx
        mov     ecx, dword [ebp+PARTITION.Length]
        mov     dword [eax+NTFS.Length], ecx
        mov     ecx, dword [ebp+PARTITION.Length+4]
        mov     dword [eax+NTFS.Length+4], ecx
        mov     ecx, [ebp+PARTITION.Disk]
        mov     [eax+NTFS.Disk], ecx
        mov     [eax+NTFS.FSUserFunctions], ntfs_user_functions
        mov     [eax+NTFS.ntfsWriteAttr], 0
 
        push    ebx ebp esi
        mov     ebp, eax
        lea     ecx, [ebp+NTFS.Lock]
        call    mutex_init
        movzx   eax, byte [ebx+13]
        mov     [ebp+NTFS.sectors_per_cluster], eax
        mov     eax, [ebx+0x28]
        mov     dword [ebp+NTFS.Length], eax
        and     dword [ebp+NTFS.Length+4], 0
        mov     eax, [ebx+0x30]
        mov     [ebp+NTFS.mft_cluster], eax
        mov     eax, [ebx+0x38]
        mov     [ebp+NTFS.mftmirr_cluster], eax
        movsx   eax, byte [ebx+0x40]
        test    eax, eax
        js      @f
        mul     [ebp+NTFS.sectors_per_cluster]
        shl     eax, 9
        jmp     .1
@@:
        neg     eax
        mov     ecx, eax
        mov     eax, 1
        shl     eax, cl
.1:
        mov     [ebp+NTFS.frs_size], eax
        stdcall kernel_alloc, eax
        test    eax, eax
        jz      .fail_free
        mov     [ebp+NTFS.frs_buffer], eax
; read $MFT disposition
        mov     eax, [ebp+NTFS.mft_cluster]
        mul     [ebp+NTFS.sectors_per_cluster]
        call    ntfs_read_frs_sector
        test    eax, eax
        jnz     .usemirr
        cmp     dword [ebx], 'FILE'
        jnz     .usemirr
        call    ntfs_restore_usa_frs
        jnc     .mftok
.usemirr:
        mov     eax, [ebp+NTFS.mftmirr_cluster]
        mul     [ebp+NTFS.sectors_per_cluster]
        call    ntfs_read_frs_sector
        test    eax, eax
        jnz     .fail_free_frs
        cmp     dword [ebx], 'FILE'
        jnz     .fail_free_frs
        call    ntfs_restore_usa_frs
        jc      .fail_free_frs
.mftok:
; read $MFT table retrieval information
; start with one page, increase if not enough (when MFT too fragmented)
        push    ebx
        stdcall kernel_alloc, 0x1000
        pop     ebx
        test    eax, eax
        jz      .fail_free_frs
        mov     [ebp+NTFS.mft_retrieval], eax
        and     [ebp+NTFS.mft_retrieval_size], 0
        mov     [ebp+NTFS.mft_retrieval_alloc], 0x1000/8
; $MFT base record must contain unnamed non-resident $DATA attribute
        movzx   eax, word [ebx+14h]
        add     eax, ebx
.scandata:
        cmp     dword [eax], -1
        jz      .fail_free_mft
        cmp     dword [eax], 0x80
        jnz     @f
        cmp     byte [eax+9], 0
        jz      .founddata
@@:
        add     eax, [eax+4]
        jmp     .scandata
.founddata:
        cmp     byte [eax+8], 0
        jz      .fail_free_mft
; load first portion of $DATA attribute retrieval information
        mov     edx, [eax+0x18]
        mov     [ebp+NTFS.mft_retrieval_end], edx
        mov     esi, eax
        movzx   eax, word [eax+0x20]
        add     esi, eax
        sub     esp, 10h
.scanmcb:
        call    ntfs_decode_mcb_entry
        jnc     .scanmcbend
        call    .get_mft_retrieval_ptr
        mov     edx, [esp]      ; block length
        mov     [eax], edx
        mov     edx, [esp+8]    ; block addr (relative)
        mov     [eax+4], edx
        inc     [ebp+NTFS.mft_retrieval_size]
        jmp     .scanmcb
.scanmcbend:
        add     esp, 10h
; there may be other portions of $DATA attribute in auxiliary records;
; if they will be needed, they will be loaded later
        mov     [ebp+NTFS.cur_index_size], 0x1000/0x200
        stdcall kernel_alloc, 0x1000
        test    eax, eax
        jz      .fail_free_mft
        mov     [ebp+NTFS.cur_index_buf], eax
; reserve adress space for bitmap buffer and load some part of bitmap
        mov     eax, dword [ebp+NTFS.Length]
        xor     edx, edx
        div     [ebp+NTFS.sectors_per_cluster]
        shr     eax, 3
        mov     [ebp+NTFS.BitmapTotalSize], eax
        add     eax, 7FFFh
        and     eax, not 7FFFh
        push    eax
        call    alloc_kernel_space
        test    eax, eax
        jz      .failFreeIndex
        mov     [ebp+NTFS.BitmapBuffer], eax
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        mov     eax, [ebp+NTFS.BitmapTotalSize]
        add     eax, [ebp+NTFS.mft_cluster]
        shr     eax, 3+2        ; reserve 1/8 of partition for $MFT
        shl     eax, 2
        mov     [ebp+NTFS.BitmapStart], eax
        shr     eax, 15
        inc     eax
        shl     eax, 3
        push    eax
        push    eax
        shl     eax, 3
        mov     [ebp+NTFS.ntfs_cur_size], eax
        call    alloc_pages
        test    eax, eax
        pop     ecx
        jz      .failFreeBitmap
        add     eax, 3
        mov     ebx, [ebp+NTFS.BitmapBuffer]
        call    commit_pages
        mov     [ebp+NTFS.ntfs_cur_iRecord], 6
        mov     [ebp+NTFS.ntfs_cur_attr], 0x80
        mov     [ebp+NTFS.ntfs_cur_offs], 0
        call    ntfs_read_attr
        jc      .failFreeBitmap
        mov     eax, [ebp+NTFS.ntfs_cur_read]
        mov     [ebp+NTFS.BitmapSize], eax
        mov     eax, [ebp+NTFS.ntfsLastRead]
        mov     [ebp+NTFS.BitmapLocation], eax
; read MFT $BITMAP attribute
        mov     eax, [ebp+NTFS.sectors_per_cluster]
        mov     [ebp+NTFS.ntfs_cur_size], eax
        shl     eax, 9
        stdcall kernel_alloc, eax
        test    eax, eax
        jz      .failFreeBitmap
        mov     [ebp+NTFS.mftBitmapBuffer], eax
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        mov     [ebp+NTFS.ntfs_cur_iRecord], 0
        mov     [ebp+NTFS.ntfs_cur_attr], 0xB0
        mov     [ebp+NTFS.ntfs_cur_offs], 0
        call    ntfs_read_attr
        mov     eax, [ebp+NTFS.ntfs_cur_read]
        cmp     eax, 4
        jc      .failFreeBitmapMFT
        mov     [ebp+NTFS.mftBitmapSize], eax
        mov     eax, [ebp+NTFS.ntfsLastRead]
        mov     [ebp+NTFS.mftBitmapLocation], eax
 
        mov     eax, ebp
.pop_exit:
        pop     esi ebp ebx
.exit:
        cmp     dword [esp+4], 0
        jz      @f
        sub     ebx, 512
@@:
        ret
 
.failFreeBitmapMFT:
        stdcall kernel_free, [ebx+NTFS.mftBitmapBuffer]
.failFreeBitmap:
        stdcall kernel_free, [ebx+NTFS.BitmapBuffer]
.failFreeIndex:
        stdcall kernel_free, [ebp+NTFS.cur_index_buf]
.fail_free_mft:
        stdcall kernel_free, [ebp+NTFS.mft_retrieval]
.fail_free_frs:
        stdcall kernel_free, [ebp+NTFS.frs_buffer]
.fail_free:
        mov     eax, ebp
        call    free
        xor     eax, eax
        jmp     .pop_exit
 
.get_mft_retrieval_ptr:
        pushad
        mov     eax, [ebp+NTFS.mft_retrieval_size]
        cmp     eax, [ebp+NTFS.mft_retrieval_alloc]
        jnz     .ok
        add     eax, 0x1000/8
        mov     [ebp+NTFS.mft_retrieval_alloc], eax
        shl     eax, 3
        stdcall kernel_alloc, eax
        test    eax, eax
        jnz     @f
        popad
        add     esp, 14h
        jmp     .fail_free_mft
@@:
        mov     esi, [ebp+NTFS.mft_retrieval]
        mov     edi, eax
        mov     ecx, [ebp+NTFS.mft_retrieval_size]
        add     ecx, ecx
        rep movsd
        push    [ebp+NTFS.mft_retrieval]
        mov     [ebp+NTFS.mft_retrieval], eax
        call    kernel_free
        mov     eax, [ebp+NTFS.mft_retrieval_size]
.ok:
        shl     eax, 3
        add     eax, [ebp+NTFS.mft_retrieval]
        mov     [esp+28], eax
        popad
        ret
 
ntfs_free:
        push    ebx
        mov     ebx, eax
        stdcall kernel_free, [ebx+NTFS.frs_buffer]
        stdcall kernel_free, [ebx+NTFS.mft_retrieval]
        stdcall kernel_free, [ebx+NTFS.cur_index_buf]
        stdcall kernel_free, [ebx+NTFS.mftBitmapBuffer]
        stdcall kernel_free, [ebx+NTFS.BitmapBuffer]
        mov     eax, ebx
        pop     ebx
        jmp     free
 
ntfs_lock:
        lea     ecx, [ebp+NTFS.Lock]
        jmp     mutex_lock
 
ntfs_unlock:
        lea     ecx, [ebp+NTFS.Lock]
        jmp     mutex_unlock
 
ntfs_read_frs_sector:
        push    ecx
        mov     ebx, [ebp+NTFS.frs_buffer]
        push    ebx
        mov     ecx, [ebp+NTFS.frs_size]
        shr     ecx, 9
        push    ecx
        mov     ecx, eax
@@:
        mov     eax, ecx
        call    fs_read32_sys
        test    eax, eax
        jnz     .fail
        add     ebx, 0x200
        inc     ecx
        dec     dword [esp]
        jnz     @b
        pop     eax
.fail:
        pop     ebx
        pop     ecx
        ret
 
ntfs_read_attr:
; [ebp+NTFS.ntfsWriteAttr]=1 -> write attribute
;   in:
; [ebp+NTFS.ntfs_cur_iRecord] = number of fileRecord
; [ebp+NTFS.ntfs_cur_attr] = attribute type
; [ebp+NTFS.ntfs_cur_offs] = attribute VCN in sectors
; [ebp+NTFS.ntfs_cur_buf] -> buffer for data
; [ebp+NTFS.ntfs_cur_size] = max sectors to read
;   out:
; [ebp+NTFS.ntfs_cur_read] = bytes readen
; CF=1 -> failed, eax = disk error code, eax=0 -> something with FS
        xor     eax, eax
        pushad
        and     [ebp+NTFS.ntfs_cur_read], 0
        cmp     [ebp+NTFS.ntfs_cur_iRecord], 0
        jnz     .nomft
        cmp     [ebp+NTFS.ntfs_cur_attr], 0x80
        jnz     .nomft
        mov     eax, [ebp+NTFS.mft_retrieval_end]
        inc     eax
        mul     [ebp+NTFS.sectors_per_cluster]
        cmp     eax, [ebp+NTFS.ntfs_cur_offs]
        jbe     .nomft
; precalculated part of $Mft $DATA
        mov     esi, [ebp+NTFS.mft_retrieval]
        mov     eax, [ebp+NTFS.ntfs_cur_offs]
        xor     edx, edx
        div     [ebp+NTFS.sectors_per_cluster]
; eax = VCN, edx = offset in sectors from beginning of cluster
        xor     ecx, ecx        ; ecx will contain LCN
.mftscan:
        add     ecx, [esi+4]
        sub     eax, [esi]
        jb      @f
        add     esi, 8
        push    eax
        mov     eax, [ebp+NTFS.mft_retrieval_end]
        shl     eax, 3
        add     eax, [ebp+NTFS.mft_retrieval]
        cmp     eax, esi
        pop     eax
        jnz     .mftscan
        jmp     .nomft
@@:
        push    ecx
        add     ecx, eax
        add     ecx, [esi]
        push    eax
        push    edx
        mov     eax, [ebp+NTFS.sectors_per_cluster]
        mul     ecx
; eax = sector on partition
        pop     edx
        add     eax, edx
        mov     ebx, [ebp+NTFS.ntfs_cur_buf]
        pop     ecx
        neg     ecx
        imul    ecx, [ebp+NTFS.sectors_per_cluster]
        sub     ecx, edx
        mov     [ebp+NTFS.ntfsLastRead], eax
        cmp     ecx, [ebp+NTFS.ntfs_cur_size]
        jb      @f
        mov     ecx, [ebp+NTFS.ntfs_cur_size]
@@:
; ecx = number of sequential sectors to read
        push    eax
        call    fs_read32_sys
        pop     edx
        test    eax, eax
        jnz     .errread
        add     [ebp+NTFS.ntfs_cur_read], 0x200
        dec     [ebp+NTFS.ntfs_cur_size]
        inc     [ebp+NTFS.ntfs_cur_offs]
        add     ebx, 0x200
        mov     [ebp+NTFS.ntfs_cur_buf], ebx
        lea     eax, [edx+1]
        loop    @b
        pop     ecx
        xor     eax, eax
        xor     edx, edx
        cmp     [ebp+NTFS.ntfs_cur_size], eax
        jz      @f
        add     esi, 8
        push    eax
        mov     eax, [ebp+NTFS.mft_retrieval_end]
        shl     eax, 3
        add     eax, [ebp+NTFS.mft_retrieval]
        cmp     eax, esi
        pop     eax
        jz      .nomft
        jmp     .mftscan
@@:
        popad
        ret
.errread:
        pop     ecx
.errret:
        mov     [esp+28], eax
        stc
        popad
        ret
.nomft:
; 1. Read file record.
; N.B. This will do recursive call of read_attr for $MFT::$Data.
        mov     eax, [ebp+NTFS.ntfs_cur_iRecord]
        mov     [ebp+NTFS.ntfs_attr_iRecord], eax
        and     [ebp+NTFS.ntfs_attr_list], 0
        or      dword [ebp+NTFS.ntfs_attr_size], -1
        or      dword [ebp+NTFS.ntfs_attr_size+4], -1
        or      [ebp+NTFS.ntfs_attr_iBaseRecord], -1
        call    ntfs_read_file_record
        jc      .errret
; 2. Find required attribute.
        mov     eax, [ebp+NTFS.frs_buffer]
; a) For auxiliary records, read base record
; N.B. If base record is present,
;      base iRecord may be 0 (for $Mft), but SequenceNumber is nonzero
        cmp     dword [eax+24h], 0
        jz      @f
        mov     eax, [eax+20h]
;        test    eax, eax
;        jz      @f
.beginfindattr:
        mov     [ebp+NTFS.ntfs_attr_iRecord], eax
        call    ntfs_read_file_record
        jc      .errret
@@:
; b) Scan for required attribute and for $ATTR_LIST
        mov     eax, [ebp+NTFS.frs_buffer]
        movzx   ecx, word [eax+14h]
        add     eax, ecx
        mov     ecx, [ebp+NTFS.ntfs_cur_attr]
        and     [ebp+NTFS.ntfs_attr_offs], 0
.scanattr:
        cmp     dword [eax], -1
        jz      .scandone
        cmp     dword [eax], ecx
        jz      .okattr
        cmp     [ebp+NTFS.ntfs_attr_iBaseRecord], -1
        jnz     .scancont
        cmp     dword [eax], 0x20       ; $ATTR_LIST
        jnz     .scancont
        mov     [ebp+NTFS.ntfs_attr_list], eax
        jmp     .scancont
.okattr:
; ignore named $DATA attributes (aka NTFS streams)
        cmp     ecx, 0x80
        jnz     @f
        cmp     byte [eax+9], 0
        jnz     .scancont
@@:
        mov     [ebp+NTFS.ntfs_attr_offs], eax
.scancont:
        add     eax, [eax+4]
        jmp     .scanattr
.continue:
        pushad
        and     [ebp+NTFS.ntfs_cur_read], 0
.scandone:
; c) Check for required offset and length
        mov     ecx, [ebp+NTFS.ntfs_attr_offs]
        jecxz   .noattr
        push    [ebp+NTFS.ntfs_cur_size]
        push    [ebp+NTFS.ntfs_cur_read]
        call    .doreadattr
        pop     edx
        pop     ecx
        jc      @f
        cmp     [ebp+NTFS.ntfs_bCanContinue], 0
        jz      @f
        sub     edx, [ebp+NTFS.ntfs_cur_read]
        neg     edx
        shr     edx, 9
        sub     ecx, edx
        mov     [ebp+NTFS.ntfs_cur_size], ecx
        jnz     .not_in_cur
@@:
        popad
        ret
.noattr:
.not_in_cur:
        cmp     [ebp+NTFS.ntfs_cur_attr], 0x20
        jz      @f
        mov     ecx, [ebp+NTFS.ntfs_attr_list]
        test    ecx, ecx
        jnz     .lookattr
.ret_is_attr:
        and     dword [esp+28], 0
        cmp     [ebp+NTFS.ntfs_attr_offs], 1     ; CF set <=> ntfs_attr_offs == 0
        popad
        ret
.lookattr:
; required attribute or required offset was not found in base record;
; it may be present in auxiliary records;
; scan $ATTR_LIST
        mov     eax, [ebp+NTFS.ntfs_attr_iBaseRecord]
        cmp     eax, -1
        jz      @f
        call    ntfs_read_file_record
        jc      .errret
        or      [ebp+NTFS.ntfs_attr_iBaseRecord], -1
@@:
        push    [ebp+NTFS.ntfs_cur_offs]
        push    [ebp+NTFS.ntfs_cur_size]
        push    [ebp+NTFS.ntfs_cur_read]
        push    [ebp+NTFS.ntfs_cur_buf]
        push    dword [ebp+NTFS.ntfs_attr_size]
        push    dword [ebp+NTFS.ntfs_attr_size+4]
        or      dword [ebp+NTFS.ntfs_attr_size], -1
        or      dword [ebp+NTFS.ntfs_attr_size+4], -1
        and     [ebp+NTFS.ntfs_cur_offs], 0
        mov     [ebp+NTFS.ntfs_cur_size], 2
        and     [ebp+NTFS.ntfs_cur_read], 0
        lea     eax, [ebp+NTFS.ntfs_attrlist_buf]
        cmp     [ebp+NTFS.ntfs_cur_iRecord], 0
        jnz     @f
        lea     eax, [ebp+NTFS.ntfs_attrlist_mft_buf]
@@:
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        push    eax
        call    .doreadattr
        pop     esi
        mov     edx, 1
        pop     dword [ebp+NTFS.ntfs_attr_size+4]
        pop     dword [ebp+NTFS.ntfs_attr_size]
        mov     ecx, [ebp+NTFS.ntfs_cur_read]
        pop     [ebp+NTFS.ntfs_cur_buf]
        pop     [ebp+NTFS.ntfs_cur_read]
        pop     [ebp+NTFS.ntfs_cur_size]
        pop     [ebp+NTFS.ntfs_cur_offs]
        jc      .errret
        or      edi, -1
        lea     ecx, [ecx+esi-1Ah]
.scanliststart:
        push    ecx
        mov     eax, [ebp+NTFS.ntfs_cur_attr]
.scanlist:
        cmp     esi, [esp]
        jae     .scanlistdone
        cmp     eax, [esi]
        jz      @f
.scanlistcont:
        movzx   ecx, word [esi+4]
        add     esi, ecx
        jmp     .scanlist
@@:
; ignore named $DATA attributes (aka NTFS streams)
        cmp     eax, 0x80
        jnz     @f
        cmp     byte [esi+6], 0
        jnz     .scanlistcont
@@:
        push    eax
        mov     eax, [esi+8]
        test    eax, eax
        jnz     .testf
        mov     eax, dword [ebp+NTFS.ntfs_attr_size]
        and     eax, dword [ebp+NTFS.ntfs_attr_size+4]
        cmp     eax, -1
        jnz     .testfz
; if attribute is in auxiliary records, its size is defined only in first
        mov     eax, [esi+10h]
        call    ntfs_read_file_record
        jnc     @f
.errret_pop:
        pop     ecx ecx
        jmp     .errret
.errret2_pop:
        xor     eax, eax
        jmp     .errret_pop
@@:
        mov     eax, [ebp+NTFS.frs_buffer]
        movzx   ecx, word [eax+14h]
        add     eax, ecx
        mov     ecx, [ebp+NTFS.ntfs_cur_attr]
@@:
        cmp     dword [eax], -1
        jz      .errret2_pop
        cmp     dword [eax], ecx
        jz      @f
.l1:
        add     eax, [eax+4]
        jmp     @b
@@:
        cmp     eax, 0x80
        jnz     @f
        cmp     byte [eax+9], 0
        jnz     .l1
@@:
        cmp     byte [eax+8], 0
        jnz     .sdnores
        mov     eax, [eax+10h]
        mov     dword [ebp+NTFS.ntfs_attr_size], eax
        and     dword [ebp+NTFS.ntfs_attr_size+4], 0
        jmp     .testfz
.sdnores:
        mov     ecx, [eax+30h]
        mov     dword [ebp+NTFS.ntfs_attr_size], ecx
        mov     ecx, [eax+34h]
        mov     dword [ebp+NTFS.ntfs_attr_size+4], ecx
.testfz:
        xor     eax, eax
.testf:
        imul    eax, [ebp+NTFS.sectors_per_cluster]
        cmp     eax, [ebp+NTFS.ntfs_cur_offs]
        pop     eax
        ja      @f
        mov     edi, [esi+10h]  ; keep previous iRecord
        jmp     .scanlistcont
@@:
        pop     ecx
.scanlistfound:
        cmp     edi, -1
        jnz     @f
        popad
        ret
@@:
        mov     eax, [ebp+NTFS.ntfs_cur_iRecord]
        mov     [ebp+NTFS.ntfs_attr_iBaseRecord], eax
        mov     eax, edi
        jmp     .beginfindattr
.scanlistdone:
        pop     ecx
        sub     ecx, ebp
        sub     ecx, NTFS.ntfs_attrlist_buf-1Ah
        cmp     [ebp+NTFS.ntfs_cur_iRecord], 0
        jnz     @f
        sub     ecx, NTFS.ntfs_attrlist_mft_buf-NTFS.ntfs_attrlist_buf
@@:
        cmp     ecx, 0x400
        jnz     .scanlistfound
        inc     edx
        push    esi edi
        lea     esi, [ebp+NTFS.ntfs_attrlist_buf+0x200]
        lea     edi, [ebp+NTFS.ntfs_attrlist_buf]
        cmp     [ebp+NTFS.ntfs_cur_iRecord], 0
        jnz     @f
        lea     esi, [ebp+NTFS.ntfs_attrlist_mft_buf+0x200]
        lea     edi, [ebp+NTFS.ntfs_attrlist_mft_buf]
@@:
        mov     ecx, 0x200/4
        rep movsd
        mov     eax, edi
        pop     edi esi
        sub     esi, 0x200
        push    [ebp+NTFS.ntfs_cur_offs]
        push    [ebp+NTFS.ntfs_cur_size]
        push    [ebp+NTFS.ntfs_cur_read]
        push    [ebp+NTFS.ntfs_cur_buf]
        push    dword [ebp+NTFS.ntfs_attr_size]
        push    dword [ebp+NTFS.ntfs_attr_size+4]
        or      dword [ebp+NTFS.ntfs_attr_size], -1
        or      dword [ebp+NTFS.ntfs_attr_size+4], -1
        mov     [ebp+NTFS.ntfs_cur_offs], edx
        mov     [ebp+NTFS.ntfs_cur_size], 1
        and     [ebp+NTFS.ntfs_cur_read], 0
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        mov     ecx, [ebp+NTFS.ntfs_attr_list]
        push    esi edx edi
        call    .doreadattr
        pop     edi edx esi
        mov     ecx, [ebp+NTFS.ntfs_cur_read]
        pop     dword [ebp+NTFS.ntfs_attr_size+4]
        pop     dword [ebp+NTFS.ntfs_attr_size]
        pop     [ebp+NTFS.ntfs_cur_buf]
        pop     [ebp+NTFS.ntfs_cur_read]
        pop     [ebp+NTFS.ntfs_cur_size]
        pop     [ebp+NTFS.ntfs_cur_offs]
        jc      .errret
        lea     ecx, [ecx+ebp+NTFS.ntfs_attrlist_buf+0x200-0x1A]
        cmp     [ebp+NTFS.ntfs_cur_iRecord], 0
        jnz     .scanliststart
        add     ecx, NTFS.ntfs_attrlist_mft_buf-NTFS.ntfs_attrlist_buf
        jmp     .scanliststart
 
.doreadattr:
        mov     [ebp+NTFS.ntfs_bCanContinue], 0
        cmp     byte [ecx+8], 0
        jnz     .nonresident
        mov     eax, [ecx+10h]  ; length
        mov     esi, eax
        mov     edx, [ebp+NTFS.ntfs_cur_offs]
        shr     eax, 9
        cmp     eax, edx
        jb      .okret
        shl     edx, 9
        sub     esi, edx
        movzx   eax, word [ecx+14h]
        add     edx, eax
        add     edx, ecx        ; edx -> data
        mov     eax, [ebp+NTFS.ntfs_cur_size]
        cmp     eax, (0xFFFFFFFF shr 9)+1
        jbe     @f
        mov     eax, (0xFFFFFFFF shr 9)+1
@@:
        shl     eax, 9
        cmp     eax, esi
        jbe     @f
        mov     eax, esi
@@:
; eax = length, edx -> data
        mov     [ebp+NTFS.ntfs_cur_read], eax
        mov     ecx, eax
        mov     eax, edx
        mov     ebx, [ebp+NTFS.ntfs_cur_buf]
        call    memmove
        and     [ebp+NTFS.ntfs_cur_size], 0      ; CF=0
        ret
.nonresident:
; Not all auxiliary records contain correct FileSize info
        mov     eax, dword [ebp+NTFS.ntfs_attr_size]
        mov     edx, dword [ebp+NTFS.ntfs_attr_size+4]
        push    eax
        and     eax, edx
        cmp     eax, -1
        pop     eax
        jnz     @f
        mov     eax, [ecx+30h]  ; FileSize
        mov     edx, [ecx+34h]
        mov     dword [ebp+NTFS.ntfs_attr_size], eax
        mov     dword [ebp+NTFS.ntfs_attr_size+4], edx
@@:
        add     eax, 0x1FF
        adc     edx, 0
        shrd    eax, edx, 9
        sub     eax, [ebp+NTFS.ntfs_cur_offs]
        ja      @f
; return with nothing read
        and     [ebp+NTFS.ntfs_cur_size], 0
.okret:
        clc
        ret
@@:
; reduce read length
        and     [ebp+NTFS.ntfs_cur_tail], 0
        cmp     [ebp+NTFS.ntfs_cur_size], eax
        jb      @f
        mov     [ebp+NTFS.ntfs_cur_size], eax
        mov     eax, dword [ebp+NTFS.ntfs_attr_size]
        and     eax, 0x1FF
        mov     [ebp+NTFS.ntfs_cur_tail], eax
@@:
        cmp     [ebp+NTFS.ntfs_cur_size], 0
        jz      .okret
        mov     eax, [ebp+NTFS.ntfs_cur_offs]
        xor     edx, edx
        div     [ebp+NTFS.sectors_per_cluster]
        sub     eax, [ecx+10h]  ; first_vbo
        jb      .okret
; eax = cluster, edx = starting sector
        cmp     [ebp+NTFS.ntfs_cur_attr], 0x80
        jnz     .sys
        cmp     [ebp+NTFS.ntfs_cur_iRecord], 0
        jz      .sys
        push    fs_read64_app
        cmp     [ebp+NTFS.ntfsWriteAttr], 1
        jnz     @f
        mov     dword[esp], fs_write64_app
        jmp     @f
.sys:
        push    fs_read64_sys
@@:
        sub     esp, 10h
        movzx   esi, word [ecx+20h]     ; mcb_info_ofs
        add     esi, ecx
        xor     edi, edi
        mov     [ebp+NTFS.ntfsFragmentCount], 0
.readloop:
        call    ntfs_decode_mcb_entry
        jnc     .break
        add     edi, [esp+8]
        sub     eax, [esp]
        jae     .readloop
        push    ecx
        push    eax
        add     eax, [esp+8]
        add     eax, edi
        imul    eax, [ebp+NTFS.sectors_per_cluster]
        add     eax, edx
        pop     ecx
        neg     ecx
        imul    ecx, [ebp+NTFS.sectors_per_cluster]
        sub     ecx, edx
        cmp     ecx, [ebp+NTFS.ntfs_cur_size]
        jb      @f
        mov     ecx, [ebp+NTFS.ntfs_cur_size]
@@:
        mov     ebx, [ebp+NTFS.ntfs_cur_buf]
        mov     [ebp+NTFS.ntfsLastRead], eax
        push    ecx
        xor     edx, edx
 
 
 
 
        call    dword[esp+18h]
 
 
 
 
        pop     ecx
        test    eax, eax
        jnz     .errread2
        sub     [ebp+NTFS.ntfs_cur_size], ecx
        add     [ebp+NTFS.ntfs_cur_offs], ecx
        shl     ecx, 9
        add     [ebp+NTFS.ntfs_cur_read], ecx
        add     [ebp+NTFS.ntfs_cur_buf], ecx
        inc     [ebp+NTFS.ntfsFragmentCount]
        pop     ecx
        xor     eax, eax
        xor     edx, edx
        cmp     [ebp+NTFS.ntfs_cur_size], 0
        jnz     .readloop
        add     esp, 14h
        mov     eax, [ebp+NTFS.ntfs_cur_tail]
        test    eax, eax
        jz      @f
        sub     eax, 0x200
        add     [ebp+NTFS.ntfs_cur_read], eax
@@:
        clc
        ret
.errread2:
        pop     ecx
        add     esp, 14h
        stc
        ret
.break:
        add     esp, 14h        ; CF=0
        mov     [ebp+NTFS.ntfs_bCanContinue], 1
        ret
 
ntfs_read_file_record:
; in: eax = iRecord
; out: [ebp+NTFS.frs_buffer] = record data
; CF=1 -> failed, eax = disk error code, eax=0 -> something with FS
    ; Read attr $DATA of $Mft, starting from eax*[ebp+NTFS.frs_size]
        push    ecx edx
        mov     ecx, [ebp+NTFS.frs_size]
        mul     ecx
        shrd    eax, edx, 9
        shr     edx, 9
        jnz     .errret
        push    [ebp+NTFS.ntfs_attr_iRecord]
        push    [ebp+NTFS.ntfs_attr_iBaseRecord]
        push    [ebp+NTFS.ntfs_attr_offs]
        push    [ebp+NTFS.ntfs_attr_list]
        push    dword [ebp+NTFS.ntfs_attr_size+4]
        push    dword [ebp+NTFS.ntfs_attr_size]
        push    [ebp+NTFS.ntfs_cur_iRecord]
        push    [ebp+NTFS.ntfs_cur_attr]
        push    [ebp+NTFS.ntfs_cur_offs]
        push    [ebp+NTFS.ntfs_cur_size]
        push    [ebp+NTFS.ntfs_cur_buf]
        push    [ebp+NTFS.ntfs_cur_read]
        mov     [ebp+NTFS.ntfs_cur_attr], 0x80   ; $DATA
        and     [ebp+NTFS.ntfs_cur_iRecord], 0   ; $Mft
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        shr     ecx, 9
        mov     [ebp+NTFS.ntfs_cur_size], ecx
        mov     eax, [ebp+NTFS.frs_buffer]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    ntfs_read_attr
        mov     edx, [ebp+NTFS.ntfs_cur_read]
        pop     [ebp+NTFS.ntfs_cur_read]
        pop     [ebp+NTFS.ntfs_cur_buf]
        pop     [ebp+NTFS.ntfs_cur_size]
        pop     [ebp+NTFS.ntfs_cur_offs]
        pop     [ebp+NTFS.ntfs_cur_attr]
        pop     [ebp+NTFS.ntfs_cur_iRecord]
        pop     dword [ebp+NTFS.ntfs_attr_size]
        pop     dword [ebp+NTFS.ntfs_attr_size+4]
        pop     [ebp+NTFS.ntfs_attr_list]
        pop     [ebp+NTFS.ntfs_attr_offs]
        pop     [ebp+NTFS.ntfs_attr_iBaseRecord]
        pop     [ebp+NTFS.ntfs_attr_iRecord]
        jc      .ret
        cmp     edx, [ebp+NTFS.frs_size]
        jnz     .errret
        mov     eax, [ebp+NTFS.frs_buffer]
        cmp     dword [eax], 'FILE'
        jnz     .errret
        push    ebx
        mov     ebx, eax
        call    ntfs_restore_usa_frs
        pop     ebx
        jc      .errret
.ret:
        pop     edx ecx
        ret
.errret:
        pop     edx ecx
        xor     eax, eax
        stc
        ret
 
ntfs_restore_usa_frs:
        mov     eax, [ebp+NTFS.frs_size]
ntfs_restore_usa:
        pushad
        shr     eax, 9
        mov     ecx, eax
        inc     eax
        cmp     [ebx+6], ax
        jnz     .err
        movzx   eax, word [ebx+4]
        lea     esi, [eax+ebx]
        lodsw
        mov     edx, eax
        lea     edi, [ebx+0x1FE]
@@:
        cmp     [edi], dx
        jnz     .err
        lodsw
        stosw
        add     edi, 0x1FE
        loop    @b
        popad
        clc
        ret
.err:
        popad
        stc
        ret
 
ntfs_decode_mcb_entry:
        push    eax ecx edi
        lea     edi, [esp+16]
        xor     eax, eax
        lodsb
        test    al, al
        jz      .end
        mov     ecx, eax
        and     ecx, 0xF
        cmp     ecx, 8
        ja      .end
        push    ecx
        rep movsb
        pop     ecx
        sub     ecx, 8
        neg     ecx
        cmp     byte [esi-1], 80h
        jae     .end
        push    eax
        xor     eax, eax
        rep stosb
        pop     ecx
        shr     ecx, 4
        cmp     ecx, 8
        ja      .end
        push    ecx
        rep movsb
        pop     ecx
        sub     ecx, 8
        neg     ecx
        cmp     byte [esi-1], 80h
        cmc
        sbb     eax, eax
        rep stosb
        stc
.end:
        pop     edi ecx eax
        ret
 
unichar_toupper:
        push    eax
        call    uni2ansi_char
        cmp     al, '_'
        jz      .unk
        add     esp, 4
        call    char_toupper
        jmp     ansi2uni_char
.unk:
        pop     eax
        ret
 
ntfs_find_lfn:
; in: [esi]+[esp+4] = name
;   out:
; [ebp+NTFS.ntfs_cur_iRecord] = number of MFT fileRecord
; eax -> index in the parent index node
; CF=1 -> file not found, eax=0 -> error
        mov     [ebp+NTFS.ntfs_cur_iRecord], 5   ; start parse from root cluster
.doit2:
        mov     [ebp+NTFS.ntfs_cur_attr], 0x90   ; $INDEX_ROOT
        and     [ebp+NTFS.ntfs_cur_offs], 0
        mov     eax, [ebp+NTFS.cur_index_size]
        mov     [ebp+NTFS.ntfs_cur_size], eax
        mov     eax, [ebp+NTFS.cur_index_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    ntfs_read_attr
        mov     eax, 0
        jnc     @f
.ret:
        ret     4
@@:
 
        cmp     [ebp+NTFS.ntfs_cur_read], 0x20
        jc      .ret
        pushad
        mov     esi, [ebp+NTFS.cur_index_buf]
        mov     eax, [esi+14h]
        add     eax, 10h
        cmp     [ebp+NTFS.ntfs_cur_read], eax
        jae     .readok1
        add     eax, 1FFh
        shr     eax, 9
        cmp     eax, [ebp+NTFS.cur_index_size]
        ja      @f
.stc_ret:
        popad
        stc
        ret     4
@@:
; reallocate
        push    eax
        stdcall kernel_free, [ebp+NTFS.cur_index_buf]
        pop     eax
        mov     [ebp+NTFS.cur_index_size], eax
        stdcall kernel_alloc, eax
        test    eax, eax
        jnz     @f
        and     [ebp+NTFS.cur_index_size], 0
        and     [ebp+NTFS.cur_index_buf], 0
        jmp     .stc_ret
@@:
        mov     [ebp+NTFS.cur_index_buf], eax
        popad
        jmp     .doit2
.readok1:
        mov     edx, [esi+8]    ; subnode_size
        shr     edx, 9
        cmp     edx, [ebp+NTFS.cur_index_size]
        jbe     .ok2
        push    esi edx
        stdcall kernel_alloc, edx
        pop     edx esi
        test    eax, eax
        jz      .stc_ret
        mov     edi, eax
        mov     ecx, [ebp+NTFS.cur_index_size]
        shl     ecx, 9-2
        rep movsd
        mov     esi, eax
        mov     [ebp+NTFS.cur_index_size], edx
        push    esi edx
        stdcall kernel_free, [ebp+NTFS.cur_index_buf]
        pop     edx esi
        mov     [ebp+NTFS.cur_index_buf], esi
.ok2:
        add     esi, 10h
        mov     edi, [esp+4]
; edi -> name, esi -> current index data, edx = subnode size
.scanloop:
        add     esi, [esi]
.scanloopint:
        test    byte [esi+0Ch], 2
        jnz     .subnode
        push    esi
        add     esi, 0x52
        movzx   ecx, byte [esi-2]
        push    edi
@@:
        lodsw
        call    unichar_toupper
        push    eax
        mov     al, [edi]
        inc     edi
        cmp     al, '/'
        jz      .slash
        call    char_toupper
        call    ansi2uni_char
        cmp     ax, [esp]
        pop     eax
        loopz   @b
        jz      .found
        pop     edi
        pop     esi
        jb      .subnode
.scanloopcont:
        movzx   eax, word [esi+8]
        add     esi, eax
        jmp     .scanloopint
.slash:
        pop     eax
        pop     edi
        pop     esi
.subnode:
        test    byte [esi+0Ch], 1
        jz      .notfound
        movzx   eax, word [esi+8]
        mov     eax, [esi+eax-8]
        imul    eax, [ebp+NTFS.sectors_per_cluster]
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        mov     [ebp+NTFS.ntfs_cur_attr], 0xA0   ; $INDEX_ALLOCATION
        mov     [ebp+NTFS.ntfs_cur_size], edx
        mov     eax, [ebp+NTFS.cur_index_buf]
        mov     esi, eax
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        push    edx
        call    ntfs_read_attr
        pop     edx
        mov     eax, edx
        shl     eax, 9
        cmp     [ebp+NTFS.ntfs_cur_read], eax
        jnz     .err
        cmp     dword [esi], 'INDX'
        jnz     .err
        mov     [ebp+NTFS.ntfs_cur_buf], esi
        mov     ebx, esi
        call    ntfs_restore_usa
        jc      .err
        add     esi, 0x18
        jmp     .scanloop
.notfound:
 
        mov     [esp+1Ch], esi
.err:
        popad
        stc
        ret     4
.found:
        cmp     byte [edi], 0
        jz      .done
        cmp     byte [edi], '/'
        jz      .next
        pop     edi
        pop     esi
        jmp     .scanloopcont
.done:
.next:
        pop     esi
        pop     esi
        mov     eax, [esi]
        mov     [ebp+NTFS.ntfs_cur_iRecord], eax
        mov     [esp+1Ch], esi
        mov     [esp+4], edi
        popad
        inc     esi
        cmp     byte [esi-1], 0
        jnz     .doit2
        cmp     dword [esp+4], 0
        jz      @f
        mov     esi, [esp+4]
        mov     dword [esp+4], 0
        jmp     .doit2
@@:
        ret     4
 
;----------------------------------------------------------------
ntfs_ReadFile:
        cmp     byte [esi], 0
        jnz     @f
        or      ebx, -1
        movi    eax, ERROR_ACCESS_DENIED
        ret
@@:
        call    ntfs_lock
        stdcall ntfs_find_lfn, [esp+4]
        jnc     .found
        call    ntfs_unlock
        or      ebx, -1
        movi    eax, ERROR_FILE_NOT_FOUND
        ret
.found:
        mov     [ebp+NTFS.ntfs_cur_attr], 0x80   ; $DATA
        and     [ebp+NTFS.ntfs_cur_offs], 0
        and     [ebp+NTFS.ntfs_cur_size], 0
        call    ntfs_read_attr
        jnc     @f
        call    ntfs_unlock
        or      ebx, -1
        movi    eax, ERROR_ACCESS_DENIED
        ret
@@:
        pushad
        and     dword [esp+10h], 0
        xor     eax, eax
        cmp     dword [ebx+8], 0x200
        jb      @f
.eof0:
        popad
        xor     ebx, ebx
.eof:
        push    ERROR_END_OF_FILE
        call    ntfs_unlock
        pop     eax
        ret
@@:
        mov     ecx, [ebx+12]
        mov     edx, [ebx+16]
        mov     eax, [ebx+4]
        test    eax, 0x1FF
        jz      .alignedstart
        push    edx
        mov     edx, [ebx+8]
        shrd    eax, edx, 9
        pop     edx
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        mov     [ebp+NTFS.ntfs_cur_size], 1
        lea     eax, [ebp+NTFS.ntfs_bitmap_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    ntfs_read_attr.continue
        mov     eax, [ebx+4]
        and     eax, 0x1FF
        lea     esi, [ebp+NTFS.ntfs_bitmap_buf+eax]
        sub     eax, [ebp+NTFS.ntfs_cur_read]
        jae     .eof0
        neg     eax
        push    ecx
        cmp     ecx, eax
        jb      @f
        mov     ecx, eax
@@:
        mov     [esp+10h+4], ecx
        mov     edi, edx
        rep movsb
        mov     edx, edi
        pop     ecx
        sub     ecx, [esp+10h]
        jnz     @f
.retok:
        popad
        call    ntfs_unlock
        xor     eax, eax
        ret
@@:
        cmp     [ebp+NTFS.ntfs_cur_read], 0x200
        jz      .alignedstart
.eof_ebx:
        popad
        jmp     .eof
.alignedstart:
        mov     eax, [ebx+4]
        push    edx
        mov     edx, [ebx+8]
        add     eax, 511
        adc     edx, 0
        shrd    eax, edx, 9
        pop     edx
 
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        mov     [ebp+NTFS.ntfs_cur_buf], edx
        mov     eax, ecx
        shr     eax, 9
        mov     [ebp+NTFS.ntfs_cur_size], eax
        add     eax, [ebp+NTFS.ntfs_cur_offs]
        push    eax
        call    ntfs_read_attr.continue
        pop     [ebp+NTFS.ntfs_cur_offs]
        mov     eax, [ebp+NTFS.ntfs_cur_read]
        add     [esp+10h], eax
        mov     eax, ecx
        and     eax, not 0x1FF
        cmp     [ebp+NTFS.ntfs_cur_read], eax
        jnz     .eof_ebx
        and     ecx, 0x1FF
        jz      .retok
        add     edx, [ebp+NTFS.ntfs_cur_read]
        mov     [ebp+NTFS.ntfs_cur_size], 1
        lea     eax, [ebp+NTFS.ntfs_bitmap_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    ntfs_read_attr.continue
        cmp     [ebp+NTFS.ntfs_cur_read], ecx
        jb      @f
        mov     [ebp+NTFS.ntfs_cur_read], ecx
@@:
        xchg    ecx, [ebp+NTFS.ntfs_cur_read]
        push    ecx
        mov     edi, edx
        lea     esi, [ebp+NTFS.ntfs_bitmap_buf]
        add     [esp+10h+4], ecx
        rep movsb
        pop     ecx
        xor     eax, eax
        cmp     ecx, [ebp+NTFS.ntfs_cur_read]
        jz      @f
        mov     al, ERROR_END_OF_FILE
@@:
        mov     [esp+1Ch], eax
        call    ntfs_unlock
        popad
        ret
 
;----------------------------------------------------------------
ntfs_ReadFolder:
        call    ntfs_lock
        mov     eax, 5          ; root cluster
        cmp     byte [esi], 0
        jz      .doit
        stdcall ntfs_find_lfn, [esp+4]
        jnc     .doit2
.notfound:
        or      ebx, -1
        push    ERROR_FILE_NOT_FOUND
.pop_ret:
        call    ntfs_unlock
        pop     eax
        ret
.doit:
        mov     [ebp+NTFS.ntfs_cur_iRecord], eax
.doit2:
        mov     [ebp+NTFS.ntfs_cur_attr], 0x10   ; $STANDARD_INFORMATION
        and     [ebp+NTFS.ntfs_cur_offs], 0
        mov     [ebp+NTFS.ntfs_cur_size], 1
        lea     eax, [ebp+NTFS.ntfs_bitmap_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    ntfs_read_attr
        jc      .notfound
        mov     [ebp+NTFS.ntfs_cur_attr], 0x90   ; $INDEX_ROOT
        and     [ebp+NTFS.ntfs_cur_offs], 0
        mov     eax, [ebp+NTFS.cur_index_size]
        mov     [ebp+NTFS.ntfs_cur_size], eax
        mov     eax, [ebp+NTFS.cur_index_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    ntfs_read_attr
        jnc     .ok
        test    eax, eax
        jz      .notfound
        or      ebx, -1
        push    ERROR_DEVICE
        jmp     .pop_ret
.ok:
        cmp     [ebp+NTFS.ntfs_cur_read], 0x20
        jae     @f
        or      ebx, -1
.fserr:
        push    ERROR_FAT_TABLE
        jmp     .pop_ret
@@:
        pushad
        mov     esi, [ebp+NTFS.cur_index_buf]
        mov     eax, [esi+14h]
        add     eax, 10h
        cmp     [ebp+NTFS.ntfs_cur_read], eax
        jae     .readok1
        add     eax, 1FFh
        shr     eax, 9
        cmp     eax, [ebp+NTFS.cur_index_size]
        ja      @f
        popad
        jmp     .fserr
@@:
; reallocate
        push    eax
        stdcall kernel_free, [ebp+NTFS.cur_index_buf]
        pop     eax
        mov     [ebp+NTFS.cur_index_size], eax
        stdcall kernel_alloc, eax
        test    eax, eax
        jnz     @f
        and     [ebp+NTFS.cur_index_size], 0
        and     [ebp+NTFS.cur_index_buf], 0
.nomem:
        call    ntfs_unlock
        popad
        or      ebx, -1
        movi    eax, ERROR_OUT_OF_MEMORY
        ret
@@:
        mov     [ebp+NTFS.cur_index_buf], eax
        popad
        jmp     .doit2
.readok1:
        mov     edx, [esi+8]    ; subnode_size
        shr     edx, 9
        mov     [ebp+NTFS.cur_subnode_size], edx
        cmp     edx, [ebp+NTFS.cur_index_size]
        jbe     .ok2
        push    esi edx
        stdcall kernel_alloc, edx
        pop     edx esi
        test    eax, eax
        jz      .nomem
        mov     edi, eax
        mov     ecx, [ebp+NTFS.cur_index_size]
        shl     ecx, 9-2
        rep movsd
        mov     esi, eax
        mov     [ebp+NTFS.cur_index_size], edx
        stdcall kernel_free, [ebp+NTFS.cur_index_buf]
        mov     [ebp+NTFS.cur_index_buf], esi
.ok2:
        add     esi, 10h
        mov     edx, [ebx+16]
        push    dword [ebx+8]   ; read ANSI/UNICODE name
; init header
        mov     edi, edx
        mov     ecx, 32/4
        xor     eax, eax
        rep stosd
        mov     byte [edx], 1   ; version
        mov     ecx, [ebx+12]
        mov     ebx, [ebx+4]
        push    edx
        mov     edx, esp
; edi -> BDFE, esi -> current index data, ebx = first wanted block,
; ecx = number of blocks to read
; edx -> parameters block: dd , dd 
        cmp     [ebp+NTFS.ntfs_cur_iRecord], 5
        jz      .skip_specials
; dot and dotdot entries
        push    esi
        xor     esi, esi
        call    .add_special_entry
        inc     esi
        call    .add_special_entry
        pop     esi
.skip_specials:
; at first, dump index root
        add     esi, [esi]
.dump_root:
        test    byte [esi+0Ch], 2
        jnz     .dump_root_done
        call    .add_entry
        movzx   eax, word [esi+8]
        add     esi, eax
        jmp     .dump_root
.dump_root_done:
; now dump all subnodes
        push    ecx edi
        lea     edi, [ebp+NTFS.ntfs_bitmap_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], edi
        mov     ecx, 0x400/4
        xor     eax, eax
        rep stosd
        mov     [ebp+NTFS.ntfs_cur_attr], 0xB0   ; $BITMAP
        and     [ebp+NTFS.ntfs_cur_offs], 0
        mov     [ebp+NTFS.ntfs_cur_size], 2
        call    ntfs_read_attr
        pop     edi ecx
        push    0       ; save offset in $BITMAP attribute
        and     [ebp+NTFS.ntfs_cur_offs], 0
.dumploop:
        mov     [ebp+NTFS.ntfs_cur_attr], 0xA0
        mov     eax, [ebp+NTFS.cur_subnode_size]
        mov     [ebp+NTFS.ntfs_cur_size], eax
        mov     eax, [ebp+NTFS.cur_index_buf]
        mov     esi, eax
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        push    [ebp+NTFS.ntfs_cur_offs]
        mov     eax, [ebp+NTFS.ntfs_cur_offs]
        imul    eax, [ebp+NTFS.cur_subnode_size]
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        call    ntfs_read_attr
        pop     [ebp+NTFS.ntfs_cur_offs]
        mov     eax, [ebp+NTFS.cur_subnode_size]
        shl     eax, 9
        cmp     [ebp+NTFS.ntfs_cur_read], eax
        jnz     .done
        push    eax
        mov     eax, [ebp+NTFS.ntfs_cur_offs]
        and     eax, 0x400*8-1
        bt      dword [ebp+NTFS.ntfs_bitmap_buf], eax
        pop     eax
        jnc     .dump_subnode_done
        cmp     dword [esi], 'INDX'
        jnz     .dump_subnode_done
        push    ebx
        mov     ebx, esi
        call    ntfs_restore_usa
        pop     ebx
        jc      .dump_subnode_done
        add     esi, 0x18
        add     esi, [esi]
.dump_subnode:
        test    byte [esi+0Ch], 2
        jnz     .dump_subnode_done
        call    .add_entry
        movzx   eax, word [esi+8]
        add     esi, eax
        jmp     .dump_subnode
.dump_subnode_done:
        inc     [ebp+NTFS.ntfs_cur_offs]
        test    [ebp+NTFS.ntfs_cur_offs], 0x400*8-1
        jnz     .dumploop
        mov     [ebp+NTFS.ntfs_cur_attr], 0xB0
        push    ecx edi
        lea     edi, [ebp+NTFS.ntfs_bitmap_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], edi
        mov     ecx, 0x400/4
        xor     eax, eax
        rep stosd
        pop     edi ecx
        pop     eax
        push    [ebp+NTFS.ntfs_cur_offs]
        inc     eax
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        mov     [ebp+NTFS.ntfs_cur_size], 2
        push    eax
        call    ntfs_read_attr
        pop     eax
        pop     [ebp+NTFS.ntfs_cur_offs]
        push    eax
        jmp     .dumploop
.done:
        pop     eax
        pop     edx
        mov     ebx, [edx+4]
        pop     edx
        xor     eax, eax
        dec     ecx
        js      @f
        mov     al, ERROR_END_OF_FILE
@@:
        mov     [esp+1Ch], eax
        mov     [esp+10h], ebx
        call    ntfs_unlock
        popad
        ret
 
.add_special_entry:
        mov     eax, [edx]
        inc     dword [eax+8]   ; new file found
        dec     ebx
        jns     .ret
        dec     ecx
        js      .ret
        inc     dword [eax+4]   ; new file block copied
        mov     eax, [edx+4]
        mov     [edi+4], eax
;        mov     eax, dword [ntfs_bitmap_buf+0x20]
;        or      al, 0x10
        mov     eax, 0x10
        stosd
        scasd
        push    edx
        mov     eax, dword [ebp+NTFS.ntfs_bitmap_buf]
        mov     edx, dword [ebp+NTFS.ntfs_bitmap_buf+4]
        call    ntfs_datetime_to_bdfe
        mov     eax, dword [ebp+NTFS.ntfs_bitmap_buf+0x18]
        mov     edx, dword [ebp+NTFS.ntfs_bitmap_buf+0x1C]
        call    ntfs_datetime_to_bdfe
        mov     eax, dword [ebp+NTFS.ntfs_bitmap_buf+8]
        mov     edx, dword [ebp+NTFS.ntfs_bitmap_buf+0xC]
        call    ntfs_datetime_to_bdfe
        pop     edx
        xor     eax, eax
        stosd
        stosd
        mov     al, '.'
        push    edi ecx
        lea     ecx, [esi+1]
        test    byte [edi-0x24], 1
        jz      @f
        rep stosw
        pop     ecx
        xor     eax, eax
        stosw
        pop     edi
        add     edi, 520
        ret
@@:
        rep stosb
        pop     ecx
        xor     eax, eax
        stosb
        pop     edi
        add     edi, 264
.ret:
        ret
 
.add_entry:
; do not return DOS 8.3 names
        cmp     byte [esi+0x51], 2
        jz      .ret
; do not return system files
; ... note that there will be no bad effects if system files also were reported ...
        cmp     dword [esi], 0x10
        jb      .ret
        mov     eax, [edx]
        inc     dword [eax+8]   ; new file found
        dec     ebx
        jns     .ret
        dec     ecx
        js      .ret
        inc     dword [eax+4]   ; new file block copied
        mov     eax, [edx+4]    ; flags
        call    ntfs_direntry_to_bdfe
        push    ecx esi edi
        movzx   ecx, byte [esi+0x50]
        add     esi, 0x52
        test    byte [edi-0x24], 1
        jz      .ansi
        shr     ecx, 1
        rep movsd
        adc     ecx, ecx
        rep movsw
        and     word [edi], 0
        pop     edi
        add     edi, 520
        pop     esi ecx
        ret
.ansi:
        jecxz   .skip
@@:
        lodsw
        call    uni2ansi_char
        stosb
        loop    @b
.skip:
        xor     al, al
        stosb
        pop     edi
        add     edi, 264
        pop     esi ecx
        ret
 
ntfs_direntry_to_bdfe:
        mov     [edi+4], eax    ; ANSI/UNICODE name
        mov     eax, [esi+48h]
        test    eax, 0x10000000
        jz      @f
        and     eax, not 0x10000000
        or      al, 0x10
@@:
        stosd
        scasd
        push    edx
        mov     eax, [esi+0x18]
        mov     edx, [esi+0x1C]
        call    ntfs_datetime_to_bdfe
        mov     eax, [esi+0x30]
        mov     edx, [esi+0x34]
        call    ntfs_datetime_to_bdfe
        mov     eax, [esi+0x20]
        mov     edx, [esi+0x24]
        call    ntfs_datetime_to_bdfe
        pop     edx
        mov     eax, [esi+0x40]
        stosd
        mov     eax, [esi+0x44]
        stosd
        ret
 
iglobal
_24             dd      24
_60             dd      60
_10000000       dd      10000000
days400year     dd      365*400+100-4+1
days100year     dd      365*100+25-1
days4year       dd      365*4+1
days1year       dd      365
months  dd  31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31
months2 dd  31, 29, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31
_400            dd      400
_100            dd      100
endg
 
ntfs_datetime_to_bdfe:
; edx:eax = number of 100-nanosecond intervals since January 1, 1601, in UTC
        push    eax
        mov     eax, edx
        xor     edx, edx
        div     [_10000000]
        xchg    eax, [esp]
        div     [_10000000]
        pop     edx
    .sec:
; edx:eax = number of seconds since January 1, 1601
        push    eax
        mov     eax, edx
        xor     edx, edx
        div     [_60]
        xchg    eax, [esp]
        div     [_60]
        mov     [edi], dl
        pop     edx
; edx:eax = number of minutes
        div     [_60]
        mov     [edi+1], dl
; eax = number of hours (note that 2^64/(10^7*60*60) < 2^32)
        xor     edx, edx
        div     [_24]
        mov     [edi+2], dl
        mov     [edi+3], byte 0
; eax = number of days since January 1, 1601
        xor     edx, edx
        div     [days400year]
        imul    eax, 400
        add     eax, 1601
        mov     [edi+6], ax
        mov     eax, edx
        xor     edx, edx
        div     [days100year]
        cmp     al, 4
        jnz     @f
        dec     eax
        add     edx, [days100year]
@@:
        imul    eax, 100
        add     [edi+6], ax
        mov     eax, edx
        xor     edx, edx
        div     [days4year]
        shl     eax, 2
        add     [edi+6], ax
        mov     eax, edx
        xor     edx, edx
        div     [days1year]
        cmp     al, 4
        jnz     @f
        dec     eax
        add     edx, [days1year]
@@:
        add     [edi+6], ax
        push    esi edx
        mov     esi, months
        movzx   eax, word [edi+6]
        test    al, 3
        jnz     .noleap
        xor     edx, edx
        push    eax
        div     [_400]
        pop     eax
        test    edx, edx
        jz      .leap
        xor     edx, edx
        div     [_100]
        test    edx, edx
        jz      .noleap
.leap:
        mov     esi, months2
.noleap:
        pop     edx
        xor     eax, eax
        inc     eax
@@:
        sub     edx, [esi]
        jb      @f
        add     esi, 4
        inc     eax
        jmp     @b
@@:
        add     edx, [esi]
        pop     esi
        inc     edx
        mov     [edi+4], dl
        mov     [edi+5], al
        add     edi, 8
        ret
 
;----------------------------------------------------------------
ntfs_CreateFolder:
        mov     [ebp+NTFS.ntfsFolder], 1
        jmp     @f
 
ntfs_CreateFile:
        mov     [ebp+NTFS.ntfsFolder], 0
@@:
        cmp     byte [esi], 0
        jnz     @f
        xor     ebx, ebx
        movi    eax, ERROR_ACCESS_DENIED    ; root directory itself
        ret
@@: ; 1. Search file
        call    ntfs_lock
 
        stdcall ntfs_find_lfn, [esp+4]
        jnc     .found
        cmp     [ebp+NTFS.ntfsFragmentCount], 1
        jnz     @f      ; record fragmented
        test    eax, eax
        jnz     .notFound
        push    ERROR_FS_FAIL
        jmp     ntfsError
@@:
        push    ERROR_UNSUPPORTED_FS
        jmp     ntfsError
 
.found:     ; rewrite
        mov     [ebp+NTFS.ntfs_cur_attr], 0x80
        mov     [ebp+NTFS.ntfs_cur_offs], 0
        mov     [ebp+NTFS.ntfs_cur_size], 0
        call    ntfs_read_attr
        jnc     @f
        push    ERROR_ACCESS_DENIED
        jmp     ntfsError
@@:
        push    ERROR_UNSUPPORTED_FS
        mov     eax, [ebp+NTFS.frs_buffer]
        cmp     word [eax+baseRecordReuse], 0
        jnz     ntfsError       ; auxiliary record
        cmp     byte [eax+hardLinkCounter], 1
        jnz     ntfsError       ; file copying required
        mov     ecx, [ebp+NTFS.ntfs_attr_offs]
        cmp     byte [ecx+nonResidentFlag], 1
        jnz     ntfsError       ; resident $DATA
        mov     eax, [ebx+4]
        mov     edx, [ebx+8]
        add     eax, [ebx+12]
        adc     edx, 0
        cmp     edx, [ecx+attributeRealSize+4]
        jnz     ntfsError
        cmp     [ecx+attributeRealSize], eax
        jnz     ntfsError
        jmp     ntfs_WriteFile.write
 
.notFound:  ; create; check name
        cmp     dword [esp+4], 0
        jnz     .bad
        cmp     byte [esi], 0
        jnz     @f
.bad:       ; path folder not found
        push    ERROR_FILE_NOT_FOUND
        jmp     ntfsError
@@: ; 2. Prepair directory record
        mov     ecx, esi
@@:         ; count characters
        inc     ecx
        cmp     byte [ecx], '/'
        jz      .bad
        cmp     byte [ecx], 0
        jnz     @b
        sub     ecx, esi
        push    ecx
        lea     ecx, [ecx*2+52h]    ; precalculate index length
        add     ecx, 7              ; align 8
        and     ecx, not 7
        mov     edi, [ebp+NTFS.cur_index_buf]
        push    esi
        push    ecx
        cmp     dword [edi], 'INDX'         ; where are we?
        jz      .indexRecord
        mov     esi, [ebp+NTFS.frs_buffer]  ; mftRecord
        mov     edx, [esi+recordRealSize]
        add     edx, ecx
        cmp     [esi+recordAllocatedSize], edx
        jnc     @f
        add     esp, 12
        push    ERROR_UNSUPPORTED_FS    ; indexAllocation required
        jmp     ntfsError
@@:         ; index fits in the indexRoot
        mov     [esi+recordRealSize], edx
        mov     ecx, edx
        shr     ecx, 2
        rep movsd
        mov     edi, [ebp+NTFS.ntfs_attr_offs]
        sub     edi, [ebp+NTFS.frs_buffer]
        add     edi, [ebp+NTFS.cur_index_buf]
        mov     esi, [esp]
        add     [edi+sizeWithHeader], esi
        add     [edi+sizeWithoutHeader], esi
        mov     cx, [edi+attributeOffset]
        add     edi, ecx
        add     [edi+16+nodeRealSize], esi
        add     [edi+16+nodeAllocatedSize], esi
        sub     eax, [ebp+NTFS.cur_index_buf]
        add     eax, edi
        mov     edi, [ebp+NTFS.cur_index_buf]
        add     edi, edx
        sub     edi, 4
        jmp     .common
 
.indexRecord:
        mov     edx, [edi+1ch]
        add     edx, ecx
        cmp     [edi+20h], edx
        jnc     @f
        add     esp, 12
        push    ERROR_UNSUPPORTED_FS    ; new node required
        jmp     ntfsError
@@:         ; index fits in the node
        mov     [edi+1ch], edx
        lea     edi, [edi+edx+14h]
.common:
        mov     esi, edi
        sub     esi, [esp]
        mov     ecx, esi
        sub     ecx, eax    ; eax = pointer in the node
        shr     ecx, 2
        inc     ecx
        std
        rep movsd           ; move forward, make space
        mov     ecx, [esp]
        shr     ecx, 2
        xor     eax, eax
        rep stosd
        cld
        add     edi, 4
        pop     eax
        pop     esi
        mov     [edi+indexAllocatedSize], ax     ; fill index with data
        mov     eax, [esp]
        lea     eax, [eax*2+42h]
        mov     [edi+indexRawSize], ax
        mov     eax, [ebp+NTFS.ntfs_attr_iRecord]
        mov     [edi+directoryRecordReference], eax
        mov     eax, [ebp+NTFS.frs_buffer]
        mov     eax, [eax+reuseCounter]
        mov     [edi+directoryReferenceReuse], ax
        mov     eax, [ebx+12]
        mov     [ebp+NTFS.fileRealSize], eax
        mov     [edi+fileRealSize], eax
        mov     ecx, [ebp+NTFS.sectors_per_cluster]
        shl     ecx, 9
        add     eax, ecx
        dec     eax
        xor     edx, edx
        div     ecx
        mov     [ebp+NTFS.fileDataSize], eax
        mul     ecx
        mov     [edi+fileAllocatedSize], eax
        pop     ecx
        mov     [ebp+NTFS.indexOffset], edi
        mov     [edi+fileNameLength], cl
        add     edi, 52h
@@:         ; record filename
        lodsb
        call    ansi2uni_char
        stosw
        dec     ecx
        jnz     @b
        mov     eax, [ebp+NTFS.ntfsLastRead]
        mov     [ebp+NTFS.nodeLastRead], eax
        cmp     [ebp+NTFS.ntfsFolder], 0
        jz      @f
        mov     edi, [ebp+NTFS.indexOffset]
        mov     byte [edi+fileFlags+3], 16
        jmp     .mftBitmap
 
@@: ; 3. File data
        cmp     [ebp+NTFS.fileRealSize], 0
        jz      .mftBitmap
    ; One piece free space bitmap search engine
        mov     edi, [ebp+NTFS.BitmapBuffer]
        add     edi, [ebp+NTFS.BitmapStart]
        mov     eax, [ebp+NTFS.fileDataSize]
        shr     eax, 5
        jz      .small
        push    eax         ; bitmap dwords
        add     edi, 4
        xor     edx, edx
.start:
        mov     ecx, [ebp+NTFS.BitmapSize]
        mov     eax, edi
        sub     eax, [ebp+NTFS.BitmapBuffer]
        sub     ecx, eax
        shr     ecx, 2
@@:
        xor     eax, eax
        repnz scasd         ; search for empty dword
        jz      @f
        call    bitmapBuffering
        jmp     @b
@@:
        cmp     ecx, [esp]
        jnc     @f
        call    bitmapBuffering
        jmp     @b
@@:
        sub     edi, 4
        mov     ecx, [esp]
        mov     esi, edi
        xor     eax, eax
        repz scasd          ; check following dwords
        jnz     .start
        sub     esi, 4
        mov     eax, [esi]
        bsr     edx, eax
        inc     edx
        push    edx         ; starting bit
        push    esi         ; starting dword
        add     esi, 4
        neg     edx
        add     edx, 32
        mov     eax, [ebp+NTFS.fileDataSize]
        sub     eax, edx
        mov     edx, eax
        shr     eax, 5
        shl     eax, 2
        add     esi, eax
        mov     eax, [esi]
        bsf     ecx, eax    ; last dword
        jz      .done
        and     edx, 31
        cmp     ecx, edx
        jnc     .done
        add     esp, 8
        jmp     .start
 
.small:     ; less than 32 clusters
        mov     ecx, [ebp+NTFS.BitmapSize]
        sub     ecx, [ebp+NTFS.BitmapStart]
        shr     ecx, 2
.smStart:
        mov     eax, -1
        repz scasd          ; search for zero bits
        push    ecx
        test    ecx, ecx
        jnz     @f
        call    bitmapBuffering
        pop     eax
        jmp     .smStart
@@:
        sub     edi, 4
        mov     eax, [edi]
        not     eax
@@:
        bsf     ecx, eax    ; first 0
        jz      .again
        not     eax
        shr     eax, cl
        shl     eax, cl
        bsf     edx, eax    ; next 1
        jz      @f
        sub     edx, ecx
        cmp     edx, [ebp+NTFS.fileDataSize]
        jnc     .got        ; fits inside
        bsf     ecx, eax
        not     eax
        shr     eax, cl
        shl     eax, cl
        jmp     @b
@@:         ; next dword
        mov     eax, [edi+4]
        bsf     edx, eax
        jz      .got        ; empty
        add     edx, 32
        sub     edx, ecx
        cmp     edx, [ebp+NTFS.fileDataSize]
        jnc     .got        ; share between dwords
.again:
        add     edi, 4
        pop     ecx
        jmp     .smStart
 
.got:
        push    ecx         ; starting bit
        push    edi         ; starting dword
.done:      ; mark space
        mov     ecx, [esp+4]
        cmp     ecx, 32
        jc      @f
        xor     ecx, ecx
        add     dword [esp], 4
        mov     [esp+4], ecx
@@:
        mov     edi, [esp]
        mov     esi, [ebp+NTFS.fileDataSize]
        mov     edx, [edi]
        ror     edx, cl
        neg     ecx
        add     ecx, 32
        mov     eax, -1
        sub     esi, ecx
        jnc     @f
        mov     esi, ecx    ; fits inside
        mov     ecx, [ebp+NTFS.fileDataSize]
        shrd    edx, eax, cl
        sub     esi, ecx
        mov     ecx, esi
        ror     edx, cl
        mov     [edi], edx
        jmp     .writeData
 
@@:
        shrd    edx, eax, cl
        mov     [edi], edx
        mov     ecx, esi
        shr     ecx, 5
        add     edi, 4
        rep stosd
        mov     ecx, esi
        and     ecx, 31
        mov     edx, [edi]
        shr     edx, cl
        shld    edx, eax, cl
        mov     [edi], edx
.writeData:
        pop     edx
        sub     edx, [ebp+NTFS.BitmapBuffer]
        shl     edx, 3
        pop     eax
        add     eax, edx
        pop     edx
        mov     [ebp+NTFS.fileDataStart], eax
        mul     [ebp+NTFS.sectors_per_cluster]
        mov     ecx, [ebp+NTFS.fileRealSize]
        add     ecx, 511
        shr     ecx, 9
        mov     ebx, [ebx+16]
        call    fs_write64_app
        test    eax, eax
        jz      .mftBitmap
        push    ERROR_DEVICE
        jmp     ntfsError
 
    ; 4. MFT record
.mftBitmap: ; search for free record
        mov     edi, [ebp+NTFS.mftBitmapBuffer]
        mov     ecx, [ebp+NTFS.mftBitmapSize]
        mov     al, -1
        add     edi, 3
        sub     ecx, 3
        repz scasb
        dec     edi
        movzx   eax, byte [edi]
        not     al
        bsf     ecx, eax
        jnz     @f
        push    ERROR_UNSUPPORTED_FS    ; no free records
        jmp     ntfsError
@@:         ; mark record
        mov     al, [edi]
        bts     eax, ecx
        mov     [edi], al
    ; get record location
        sub     edi, [ebp+NTFS.mftBitmapBuffer]
        shl     edi, 3
        add     edi, ecx
        mov     [ebp+NTFS.newMftRecord], edi
        mov     eax, [ebp+NTFS.frs_size]
        shr     eax, 9
        mul     edi
        mov     [ebp+NTFS.ntfs_cur_iRecord], 0
        mov     [ebp+NTFS.ntfs_cur_attr], 0x80
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        mov     [ebp+NTFS.ntfs_cur_size], 1
        mov     eax, [ebp+NTFS.frs_buffer]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    ntfs_read_attr
        cmp     [ebp+NTFS.ntfs_cur_read], 0
        jnz     .mftRecord
    ; extend MFT $DATA
        mov     eax, [ebp+NTFS.mft_cluster]
        mul     [ebp+NTFS.sectors_per_cluster]
        push    ERROR_UNSUPPORTED_FS
        cmp     eax, [ebp+NTFS.ntfsLastRead]
        jnz     ntfsError       ; auxiliary record
        mov     edi, [ebp+NTFS.ntfs_attr_offs]
        mov     ebx, [ebp+NTFS.sectors_per_cluster]
        shl     ebx, 9+3
        add     dword [edi+lastVCN], 8
        add     [edi+attributeAllocatedSize], ebx
        adc     byte [edi+attributeAllocatedSize+4], 0
        add     [edi+attributeRealSize], ebx
        adc     byte [edi+attributeRealSize+4], 0
        add     [edi+initialDataSize], ebx
        adc     byte [edi+initialDataSize+4], 0
        add     edi, [edi+dataRunsOffset]
        movzx   eax, byte [edi]
        inc     edi
        shl     eax, 4
        shr     al, 4
        mov     cl, 4
        sub     cl, al
        shl     cl, 3
        add     ah, al
        shr     eax, 8
        cmp     byte [edi+eax], 0
        jnz     ntfsError       ; $MFT fragmented
        mov     al, 8
        mov     edx, [edi]
        rol     eax, cl
        rol     edx, cl
        add     eax, edx
        jc      ntfsError
        ror     eax, cl
        shr     edx, cl
        mov     [edi], eax
        add     edx, [ebp+NTFS.mft_cluster]
        mov     esi, edx
        mov     ecx, edx
        and     ecx, 7
        shr     edx, 3
        add     edx, [ebp+NTFS.BitmapBuffer]
        mov     ax, [edx]
        shr     ax, cl
        test    al, al
        jnz     ntfsError
        dec     al
        xchg    [edx], al
        mov     [edx+1], al
        pop     eax
        push    ERROR_OUT_OF_MEMORY
        stdcall kernel_alloc, ebx
        test    eax, eax
        jz      ntfsError
        mov     ecx, ebx
        shr     ecx, 2
        mov     edi, eax
        push    ebx
        mov     ebx, eax
        xor     eax, eax
        rep stosd
        mov     eax, esi
        mul     [ebp+NTFS.sectors_per_cluster]
        pop     ecx
        shr     ecx, 9
        call    fs_write64_sys  ; clear new records
        stdcall kernel_free, ebx
        pop     eax
        push    ERROR_DEVICE
        mov     eax, esi
        shr     eax, 3+9
        mov     ebx, eax
        shl     ebx, 9
        add     ebx, [ebp+NTFS.BitmapBuffer]
        add     eax, [ebp+NTFS.BitmapLocation]
        mov     ecx, 1
        xor     edx, edx
        call    fs_write64_app  ; partition bitmap
        test    eax, eax
        jnz     ntfsError
        mov     eax, [ebp+NTFS.frs_buffer]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    writeRecord     ; $MFT
        test    eax, eax
        jnz     ntfsError
        mov     eax, [ebp+NTFS.mftmirr_cluster]
        mul     [ebp+NTFS.sectors_per_cluster]
        mov     ebx, [ebp+NTFS.frs_buffer]
        movzx   ecx, word [ebx+updateSequenceSize]
        dec     ecx
        call    fs_write64_sys  ; $MFTMirr
        test    eax, eax
        jnz     ntfsError
        pop     eax
        mov     eax, [ebp+NTFS.ntfs_cur_offs]
        add     [ebp+NTFS.ntfsLastRead], eax
.mftRecord:
        mov     esi, [ebp+NTFS.indexOffset]
        mov     edi, [ebp+NTFS.frs_buffer]
        xor     eax, eax
        movzx   ecx, word [esi+indexAllocatedSize]
        add     ecx, 8+30h+48h+50h+8
        push    ecx
        shr     ecx, 2
        rep stosd
        mov     edi, [ebp+NTFS.frs_buffer]
    ; record header
        mov     dword[edi], 'FILE'
        mov     byte [edi+updateSequenceOffset], 2ah
        mov     byte [edi+updateSequenceSize], 3
        mov     byte [edi+hardLinkCounter], 1
        mov     byte [edi+attributeOffset], 30h
        pop     dword[edi+recordRealSize]
        mov     word [edi+recordAllocatedSize], 1024
        mov     byte [edi+newAttributeID], 3
        rdtsc
        mov     [edi+2ah], ax
        add     edi, 30h
    ; $StandardInformation
        mov     byte [edi+attributeType], 10h
        mov     byte [edi+sizeWithHeader], 48h
        mov     byte [edi+sizeWithoutHeader], 30h
        mov     byte [edi+attributeOffset], 18h
        add     edi, 48h
    ; $FileName
        mov     byte [edi+attributeType], 30h
        mov     byte [edi+attributeID], 1
        mov     cx, [esi+indexRawSize]
        mov     [edi+sizeWithoutHeader], ecx
        mov     cx, [esi+indexAllocatedSize]
        add     ecx, 8
        mov     [edi+sizeWithHeader], ecx
        mov     byte [edi+attributeOffset], 18h
        mov     byte [edi+attributeFlags], 1
        add     edi, 18h
        add     esi, 16
        sub     ecx, 18h
        shr     ecx, 2
        rep movsd
        cmp     [ebp+NTFS.ntfsFolder], 0
        jnz     @f
    ; $Data
        mov     byte [edi+attributeType], 80h
        cmp     [ebp+NTFS.fileRealSize], 0
        jz      .zeroSize
        mov     esi, [ebp+NTFS.indexOffset]
        mov     byte [edi+nonResidentFlag], 1
        mov     byte [edi+dataRunsOffset], 40h
        mov     eax, [esi+fileAllocatedSize]
        mov     [edi+attributeAllocatedSize], eax
        mov     eax, [esi+fileRealSize]
        mov     [edi+attributeRealSize], eax
        mov     [edi+initialDataSize], eax
        mov     byte [edi+40h], 44h
        mov     eax, [ebp+NTFS.fileDataSize]
        mov     [edi+41h], eax
        dec     eax
        mov     [edi+lastVCN], eax
        mov     eax, [ebp+NTFS.fileDataStart]
        mov     [edi+45h], eax
        mov     al, 1
        jmp     .writeMftRecord
 
.zeroSize:
        mov     byte [edi+attributeOffset], 18h
        mov     al, 1
        jmp     .writeMftRecord
 
@@: ; $IndexRoot
        mov     byte [edi+attributeType], 90h
        mov     byte [edi+nameLength], 4
        mov     byte [edi+nameOffset], 18h
        mov     byte [edi+sizeWithoutHeader], 30h
        mov     byte [edi+attributeOffset], 20h
        mov     dword[edi+18h], 490024h     ; unicode $I30
        mov     dword[edi+18h+4], 300033h
        add     edi, 20h
        mov     byte [edi+attributeType], 30h
        mov     byte [edi+collationRule], 1
        mov     eax, [ebp+NTFS.sectors_per_cluster]
        shl     eax, 9
        mov     [edi+indexRecordSize], eax
        mov     byte [edi+indexRecordSizeClus], 1
        mov     byte [edi+16+indexOffset], 16
        mov     byte [edi+16+nodeRealSize], 32
        mov     byte [edi+16+nodeAllocatedSize], 32
        mov     byte [edi+32+indexAllocatedSize], 16
        mov     byte [edi+32+indexFlags], 2
        sub     edi, 20h
        mov     al, 3
.writeMftRecord:
        mov     byte [edi+sizeWithHeader], 50h
        mov     byte [edi+attributeID], 2
        mov     dword[edi+50h], -1      ; $End
        mov     edi, [ebp+NTFS.frs_buffer]
        mov     [edi+recordFlags], al
        mov     [ebp+NTFS.ntfs_cur_buf], edi
        call    writeRecord
        test    eax, eax
        jz      @f
        push    ERROR_DEVICE
        jmp     ntfsError
@@:
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
    ; write MFT bitmap
        mov     eax, [ebp+NTFS.newMftRecord]
        shr     eax, 3+9
        mov     ebx, eax
        shl     ebx, 9
        add     eax, [ebp+NTFS.mftBitmapLocation]
        add     ebx, [ebp+NTFS.mftBitmapBuffer]
        mov     ecx, 1
        xor     edx, edx
        call    fs_write64_sys
        test    eax, eax
        jz      @f
        push    ERROR_DEVICE
        jmp     ntfsError
@@: ; 5. Write partition bitmap
        cmp     [ebp+NTFS.ntfsFolder], 0
        jnz     @f
        cmp     [ebp+NTFS.fileRealSize], 0
        jz      @f
        mov     ecx, [ebp+NTFS.fileDataStart]
        mov     eax, ecx
        add     ecx, [ebp+NTFS.fileDataSize]
        add     ecx, 4095
        shr     ecx, 3+9
        shr     eax, 3+9
        sub     ecx, eax
        mov     ebx, eax
        shl     ebx, 9
        add     eax, [ebp+NTFS.BitmapLocation]
        add     ebx, [ebp+NTFS.BitmapBuffer]
        xor     edx, edx
        call    fs_write64_app
        test    eax, eax
        jz      @f
        push    ERROR_DEVICE
        jmp     ntfsError
@@:
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
        mov     edi, [ebp+NTFS.indexOffset]
        mov     eax, [ebp+NTFS.newMftRecord]
        mov     [edi+fileRecordReference], eax
    ; 6. Write directory node
        mov     eax, [ebp+NTFS.nodeLastRead]
        mov     [ebp+NTFS.ntfsLastRead], eax
        mov     eax, [ebp+NTFS.cur_index_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], eax
        call    writeRecord
        push    eax
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
        call    ntfs_unlock
        pop     eax
        mov     ebx, [ebp+NTFS.fileRealSize]
        ret
 
writeRecord:
;   in:
; [ebp+NTFS.ntfs_cur_buf] = record
; [ebp+NTFS.ntfsLastRead] = partition sector
    ; making updateSequence
        mov     esi, [ebp+NTFS.ntfs_cur_buf]
        mov     edi, esi
        movzx   ecx, word [esi+updateSequenceOffset]
        add     edi, ecx
        mov     ax, [edi]
        add     edi, 2
        mov     cx, [esi+updateSequenceSize]
        dec     ecx
        push    ecx
@@:
        add     esi, 510
        movsw
        mov     [esi-2], ax
        dec     ecx
        jnz     @b
    ; writing to disk
        mov     eax, [ebp+NTFS.ntfsLastRead]
        mov     ebx, [ebp+NTFS.ntfs_cur_buf]
        pop     ecx
        xor     edx, edx
        jmp     fs_write64_sys
 
bitmapBuffering:
; Extend BitmapBuffer and read next 32kb of bitmap
; Warning: $Bitmap fragmentation is not foreseen
        push    ebx
        mov     eax, [ebp+NTFS.BitmapTotalSize]
        cmp     eax, [ebp+NTFS.BitmapSize]
        jz      .end
        stdcall alloc_pages, 8
        test    eax, eax
        jz      .end
        add     eax, 3
        mov     ebx, [ebp+NTFS.BitmapBuffer]
        add     ebx, [ebp+NTFS.BitmapSize]
        push    ebx
        mov     ecx, 8
        call    commit_pages
        mov     eax, [ebp+NTFS.BitmapSize]
        shr     eax, 9
        add     eax, [ebp+NTFS.BitmapLocation]
        pop     ebx
        mov     ecx, 64
        xor     edx, edx
        call    fs_read64_app
        test    eax, eax
        jnz     .err
        add     [ebp+NTFS.BitmapSize], 8000h
        mov     eax, [ebp+NTFS.BitmapTotalSize]
        cmp     eax, [ebp+NTFS.BitmapSize]
        jnc     @f
        mov     [ebp+NTFS.BitmapSize], eax
@@:
        mov     ecx, [ebp+NTFS.BitmapSize]
        mov     eax, edi
        sub     eax, [ebp+NTFS.BitmapBuffer]
        sub     ecx, eax
        shr     ecx, 2
        pop     ebx
        ret
 
.err:
        mov     eax, [ebp+NTFS.BitmapBuffer]
        add     eax, [ebp+NTFS.BitmapSize]
        mov     ecx, 8
        call    release_pages
.end:
        add     esp, 12     ; double ret
        push    ERROR_DISK_FULL
        jmp     ntfsError
 
;----------------------------------------------------------------
ntfs_WriteFile:
        cmp     byte [esi], 0
        jnz     @f
        xor     ebx, ebx
        movi    eax, ERROR_ACCESS_DENIED
        ret
@@:
        call    ntfs_lock
        stdcall ntfs_find_lfn, [esp+4]
        jnc     .found
        push    ERROR_FILE_NOT_FOUND
        jmp     ntfsError
.found:
        mov     [ebp+NTFS.ntfs_cur_attr], 0x80
        mov     [ebp+NTFS.ntfs_cur_offs], 0
        mov     [ebp+NTFS.ntfs_cur_size], 0
        call    ntfs_read_attr
        jnc     @f
        push    ERROR_ACCESS_DENIED
        jmp     ntfsError
@@:
        push    ERROR_UNSUPPORTED_FS
        mov     eax, [ebp+NTFS.frs_buffer]
        cmp     word [eax+baseRecordReuse], 0
        jnz     ntfsError       ; auxiliary record
        cmp     byte [eax+hardLinkCounter], 1
        jnz     ntfsError       ; file copying required
        mov     ecx, [ebp+NTFS.ntfs_attr_offs]
        cmp     byte [ecx+nonResidentFlag], 1
        jnz     ntfsError       ; resident $DATA
        mov     eax, [ebx+4]
        mov     edx, [ebx+8]
        add     eax, [ebx+12]
        adc     edx, 0
        cmp     edx, [ecx+attributeRealSize+4]
        jc      .write
        jnz     ntfsError       ; end of file
        cmp     [ecx+attributeRealSize], eax
        jc      ntfsError
.write:
        pop     eax
        push    ERROR_DEVICE
        mov     eax, [ebx+4]
        mov     edx, [ebx+8]
        mov     ecx, [ebx+12]
        mov     esi, [ebx+16]
        shrd    eax, edx, 9
        test    dword[ebx+4], 1FFh
        jz      .aligned
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        mov     [ebp+NTFS.ntfs_cur_size], 1
        lea     edi, [ebp+NTFS.ntfs_bitmap_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], edi
        call    ntfs_read_attr.continue
        jc      ntfsError
        mov     eax, [ebx+4]
        and     eax, 1FFh
        add     edi, eax
        sub     eax, [ebp+NTFS.ntfs_cur_read]
        neg     eax
        push    ecx
        cmp     ecx, eax
        jb      @f
        mov     ecx, eax
@@:
        sub     [esp], ecx
        rep movsb
        push    ebx
        mov     eax, [ebp+NTFS.ntfsLastRead]
        lea     ebx, [ebp+NTFS.ntfs_bitmap_buf]
        mov     ecx, 1
        xor     edx, edx
        call    fs_write64_app
        pop     ebx
        pop     ecx
        test    eax, eax
        jnz     ntfsError
        test    ecx, ecx
        jz      @f
        mov     eax, [ebx+4]
        mov     edx, [ebx+8]
        shrd    eax, edx, 9
        inc     eax
.aligned:
        push    ecx
        shr     ecx, 9
        mov     [ebp+NTFS.ntfs_cur_offs], eax
        mov     [ebp+NTFS.ntfs_cur_size], ecx
        mov     [ebp+NTFS.ntfs_cur_buf], esi
        add     eax, ecx
        push    eax
        mov     [ebp+NTFS.ntfsWriteAttr], 1
        call    ntfs_read_attr.continue
        mov     [ebp+NTFS.ntfsWriteAttr], 0
        pop     [ebp+NTFS.ntfs_cur_offs]
        pop     ecx
        jc      ntfsError
        and     ecx, 1FFh
        jz      @f
        add     esi, [ebp+NTFS.ntfs_cur_read]
        mov     [ebp+NTFS.ntfs_cur_size], 1
        lea     edi, [ebp+NTFS.ntfs_bitmap_buf]
        mov     [ebp+NTFS.ntfs_cur_buf], edi
        call    ntfs_read_attr.continue
        jc      ntfsError
        rep movsb
        push    ebx
        mov     eax, [ebp+NTFS.ntfsLastRead]
        lea     ebx, [ebp+NTFS.ntfs_bitmap_buf]
        mov     ecx, 1
        xor     edx, edx
        call    fs_write64_app
        pop     ebx
@@:
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
        call    ntfs_unlock
        pop     eax
        xor     eax, eax
        mov     ebx, [ebx+12]
        ret
 
;----------------------------------------------------------------
ntfs_SetFileEnd:
ntfs_SetFileInfo:
ntfs_Delete:
        mov     eax, ERROR_UNSUPPORTED_FS
        ret
 
;----------------------------------------------------------------
ntfs_GetFileInfo:
        cmp     byte [esi], 0
        jnz     @f
        movi    eax, ERROR_UNSUPPORTED_FS
        ret
@@:
        call    ntfs_lock
        stdcall ntfs_find_lfn, [esp+4]
        jnc     .found
 
        push    ERROR_FILE_NOT_FOUND
        test    eax, eax
        jnz     ntfsError
        pop     eax
        push    ERROR_FS_FAIL
        jmp     ntfsError
.found:
        push    esi edi
        mov     esi, eax
        mov     edi, [ebx+16]
        xor     eax, eax
        call    ntfs_direntry_to_bdfe
        pop     edi esi
        call    ntfs_unlock
        xor     eax, eax
        ret
 
ntfsError:
        call    ntfs_unlock
        xor     ebx, ebx
        pop     eax
        ret

Rev 5954	Rev 5994
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2004-2015. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2004-2015. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	6	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
7		7
8	$Revision: 5954 $	8	$Revision: 5994 $
9		9
10	; NTFS driver	10	; NTFS driver
11		11
12	; Basic concepts:	12	; Basic concepts:
13	; File is a FileRecord in the $MFT.	13	; File is a FileRecord in the $MFT.
14	; $MFT is a file, that consists of FileRecords and starts with FileRecord of itself.	14	; $MFT is a file, that consists of FileRecords and starts with FileRecord of itself.
15	; FileRecord (FILE) consists of a header and attributes.	15	; FileRecord (FILE) consists of a header and attributes.
16	; Attribute consists of a header and a body.	16	; Attribute consists of a header and a body.
17	; Attribute's body can be inside (resident) or outside of FileRecord.	17	; Attribute's body can be inside (resident) or outside of FileRecord.
18	; File's data is a body of $Data (80h) attribute.	18	; File's data is a body of $Data (80h) attribute.
19	; FileRecords is a data of the $MFT file.	19	; FileRecords is a data of the $MFT file.
20	; Directory is a file, that consists of index nodes.	20	; Directory is a file, that consists of index nodes.
21	; Resident index node is always located in a body of $IndexRoot (90h) attribute.	21	; Resident index node is always located in a body of $IndexRoot (90h) attribute.
22	; Body of $IndexAllocation (A0h) attribute is always non resident	22	; Body of $IndexAllocation (A0h) attribute is always non resident
23	; and consists of IndexRecords.	23	; and consists of IndexRecords.
24	; IndexRecord (INDX) consists of a header and an index node.	24	; IndexRecord (INDX) consists of a header and an index node.
25	; Index node consists of a header and indexes.	25	; Index node consists of a header and indexes.
26	; Index consists of a header and a copy of indexed attribute's body.	26	; Index consists of a header and a copy of indexed attribute's body.
27	; Directories index $Filename (30h) attribute of all existing files.	27	; Directories index $Filename (30h) attribute of all existing files.
28	; $IndexRoot and $IndexAllocation attributes of a directory has a name — $I30.	28	; $IndexRoot and $IndexAllocation attributes of a directory has a name — $I30.
29		29
30	; Offsets:	30	; Offsets:
31	; record header	31	; record header
32	updateSequenceOffset = 4	32	updateSequenceOffset = 4
33	updateSequenceSize = 6	33	updateSequenceSize = 6
34	reuseCounter = 16	34	reuseCounter = 16
35	hardLinkCounter = 12h	35	hardLinkCounter = 12h
36	attributeOffset = 14h	36	attributeOffset = 14h
37	recordFlags = 16h	37	recordFlags = 16h
38	recordRealSize = 18h	38	recordRealSize = 18h
39	recordAllocatedSize = 1ch	39	recordAllocatedSize = 1ch
-		40	baseRecordReference = 20h ; for auxiliary records
-		41	baseRecordReuse = 26h
40	newAttributeID = 28h	42	newAttributeID = 28h
41	; attribute header	43	; attribute header
42	attributeType = 0	44	attributeType = 0
43	sizeWithHeader = 4	45	sizeWithHeader = 4
44	nonResidentFlag = 8	46	nonResidentFlag = 8
45	nameLength = 9	47	nameLength = 9
46	nameOffset = 10	48	nameOffset = 10
47	attributeID = 14	49	attributeID = 14
48	sizeWithoutHeader = 16	50	sizeWithoutHeader = 16
49	attributeFlags = 16h	51	attributeFlags = 16h
50	; non resident attribute header	52	; non resident attribute header
51	lastVCN = 18h	53	lastVCN = 18h
52	dataRunsOffset = 20h	54	dataRunsOffset = 20h
53	attributeAllocatedSize = 28h	55	attributeAllocatedSize = 28h
54	attributeRealSize = 30h	56	attributeRealSize = 30h
55	initialDataSize = 38h	57	initialDataSize = 38h
56	; $IndexRoot	58	; $IndexRoot
57	collationRule = 4	59	collationRule = 4
58	indexRecordSize = 8	60	indexRecordSize = 8
59	indexRecordSizeClus = 12	61	indexRecordSizeClus = 12
60	; node header	62	; node header
61	indexOffset = 0	63	indexOffset = 0
62	nodeRealSize = 4	64	nodeRealSize = 4
63	nodeAllocatedSize = 8	65	nodeAllocatedSize = 8
64	; $Filename index	66	; $Filename index
65	fileRecordReference = 0	67	fileRecordReference = 0
66	fileReferenceReuse = 6	68	fileReferenceReuse = 6
67	indexAllocatedSize = 8	69	indexAllocatedSize = 8
68	indexRawSize = 10	70	indexRawSize = 10
69	indexFlags = 12	71	indexFlags = 12
70	directoryRecordReference = 16	72	directoryRecordReference = 16
71	directoryReferenceReuse = 16h	73	directoryReferenceReuse = 16h
72	fileAllocatedSize = 38h	74	fileAllocatedSize = 38h
73	fileRealSize = 40h	75	fileRealSize = 40h
74	fileFlags = 48h	76	fileFlags = 48h
75	fileNameLength = 50h	77	fileNameLength = 50h
76		78
77	struct NTFS PARTITION	79	struct NTFS PARTITION
78	Lock MUTEX ? ; Currently operations with one partition	80	Lock MUTEX ? ; Currently operations with one partition
79	; can not be executed in parallel since the legacy code is not ready.	81	; can not be executed in parallel since the legacy code is not ready.
80	sectors_per_cluster dd ?	82	sectors_per_cluster dd ?
81	mft_cluster dd ? ; location	83	mft_cluster dd ? ; location
82	mftmirr_cluster dd ? ; location	84	mftmirr_cluster dd ? ; location
83	frs_size dd ? ; in bytes	85	frs_size dd ? ; in bytes
84	frs_buffer dd ? ; MFT fileRecord buffer	86	frs_buffer dd ? ; MFT fileRecord buffer
85	mft_retrieval dd ?	87	mft_retrieval dd ?
86	mft_retrieval_size dd ?	88	mft_retrieval_size dd ?
87	mft_retrieval_alloc dd ?	89	mft_retrieval_alloc dd ?
88	mft_retrieval_end dd ?	90	mft_retrieval_end dd ?
89	cur_index_size dd ? ; in sectors	91	cur_index_size dd ? ; in sectors
90	cur_index_buf dd ? ; index node buffer	92	cur_index_buf dd ? ; index node buffer
91	BitmapBuffer dd ?	93	BitmapBuffer dd ?
92	BitmapTotalSize dd ? ; bytes reserved	94	BitmapTotalSize dd ? ; bytes reserved
93	BitmapSize dd ? ; bytes readen	95	BitmapSize dd ? ; bytes readen
94	BitmapLocation dd ? ; starting sector	96	BitmapLocation dd ? ; starting sector
95	BitmapStart dd ? ; first byte after area, reserved for MFT	97	BitmapStart dd ? ; first byte after area, reserved for MFT
96	mftBitmapBuffer dd ? ; one cluster	98	mftBitmapBuffer dd ? ; one cluster
97	mftBitmapSize dd ? ; bytes readen	99	mftBitmapSize dd ? ; bytes readen
98	mftBitmapLocation dd ? ; starting sector	100	mftBitmapLocation dd ? ; starting sector
99		101
100	ntfs_cur_attr dd ? ; attribute type	102	ntfs_cur_attr dd ? ; attribute type
101	ntfs_cur_iRecord dd ? ; number of fileRecord in MFT	103	ntfs_cur_iRecord dd ? ; number of fileRecord in MFT
102	ntfs_cur_offs dd ? ; attribute VCN in sectors	104	ntfs_cur_offs dd ? ; attribute VCN in sectors
103	ntfs_cur_size dd ? ; max sectors to read	105	ntfs_cur_size dd ? ; max sectors to read
104	ntfs_cur_buf dd ?	106	ntfs_cur_buf dd ?
105	ntfs_cur_read dd ? ; bytes readen	107	ntfs_cur_read dd ? ; bytes readen
106	ntfsLastRead dd ? ; last readen block of sectors	108	ntfsLastRead dd ? ; last readen block of sectors
107	newMftRecord dd ? ; number of fileRecord in MFT	109	newMftRecord dd ? ; number of fileRecord in MFT
108	fileDataStart dd ? ; starting cluster	110	fileDataStart dd ? ; starting cluster
109	fileDataSize dd ? ; in clusters	111	fileDataSize dd ? ; in clusters
110	fileRealSize dd ? ; in bytes	112	fileRealSize dd ? ; in bytes
111	indexOffset dd ?	113	indexOffset dd ?
112	nodeLastRead dd ?	114	nodeLastRead dd ?
113	ntfs_bCanContinue db ?	115	ntfs_bCanContinue db ?
114	ntfsNotFound db ?	-
115	ntfsFolder db ?	116	ntfsFolder db ?
-		117	ntfsWriteAttr db ? ; Warning: Don't forget to turn off!!!
116	ntfsFragmentCount db ?	118	ntfsFragmentCount db ?
117		119
118	cur_subnode_size dd ?	120	cur_subnode_size dd ?
119	ntfs_attr_iRecord dd ?	121	ntfs_attr_iRecord dd ?
120	ntfs_attr_iBaseRecord dd ?	122	ntfs_attr_iBaseRecord dd ?
121	ntfs_attr_offs dd ?	123	ntfs_attr_offs dd ?
122	ntfs_attr_list dd ?	124	ntfs_attr_list dd ?
123	ntfs_attr_size dq ?	125	ntfs_attr_size dq ?
124	ntfs_cur_tail dd ?	126	ntfs_cur_tail dd ?
125		127
126	ntfs_attrlist_buf rb 0x400	128	ntfs_attrlist_buf rb 0x400
127	ntfs_attrlist_mft_buf rb 0x400	129	ntfs_attrlist_mft_buf rb 0x400
128	ntfs_bitmap_buf rb 0x400	130	ntfs_bitmap_buf rb 0x400
129	ends	131	ends
130		132
131	; NTFS external functions	133	; NTFS external functions
132	; in:	134	; in:
133	; ebx -> parameter structure of sysfunc 70	135	; ebx -> parameter structure of sysfunc 70
134	; ebp -> NTFS structure	136	; ebp -> NTFS structure
135	; [esi]+[esp+4] = name	137	; [esi]+[esp+4] = name
136	; out:	138	; out:
137	; eax, ebx = return values for sysfunc 70	139	; eax, ebx = return values for sysfunc 70
138	iglobal	140	iglobal
139	align 4	141	align 4
140	ntfs_user_functions:	142	ntfs_user_functions:
141	dd ntfs_free	143	dd ntfs_free
142	dd (ntfs_user_functions_end - ntfs_user_functions - 4) / 4	144	dd (ntfs_user_functions_end - ntfs_user_functions - 4) / 4
143	dd ntfs_ReadFile	145	dd ntfs_ReadFile
144	dd ntfs_ReadFolder	146	dd ntfs_ReadFolder
145	dd ntfs_CreateFile	147	dd ntfs_CreateFile
146	dd ntfs_Write	148	dd ntfs_WriteFile
147	dd ntfs_SetFileEnd	149	dd ntfs_SetFileEnd
148	dd ntfs_GetFileInfo	150	dd ntfs_GetFileInfo
149	dd ntfs_SetFileInfo	151	dd ntfs_SetFileInfo
150	dd 0	152	dd 0
151	dd ntfs_Delete	153	dd ntfs_Delete
152	dd ntfs_CreateFolder	154	dd ntfs_CreateFolder
153	ntfs_user_functions_end:	155	ntfs_user_functions_end:
154	endg	156	endg
155		157
156	ntfs_test_bootsec:	158	ntfs_test_bootsec:
157	; in: ebx -> buffer, edx = size of partition	159	; in: ebx -> buffer, edx = size of partition
158	; out: CF=1 -> invalid	160	; out: CF=1 -> invalid
159	; 1. Name=='NTFS '	161	; 1. Name=='NTFS '
160	cmp dword [ebx+3], 'NTFS'	162	cmp dword [ebx+3], 'NTFS'
161	jnz .no	163	jnz .no
162	cmp dword [ebx+7], ' '	164	cmp dword [ebx+7], ' '
163	jnz .no	165	jnz .no
164	; 2. Number of bytes per sector is the same as for physical device	166	; 2. Number of bytes per sector is the same as for physical device
165	; (that is, 0x200 for hard disk)	167	; (that is, 0x200 for hard disk)
166	cmp word [ebx+11], 0x200	168	cmp word [ebx+11], 0x200
167	jnz .no	169	jnz .no
168	; 3. Number of sectors per cluster must be power of 2	170	; 3. Number of sectors per cluster must be power of 2
169	movzx eax, byte [ebx+13]	171	movzx eax, byte [ebx+13]
170	dec eax	172	dec eax
171	js .no	173	js .no
172	test al, [ebx+13]	174	test al, [ebx+13]
173	jnz .no	175	jnz .no
174	; 4. FAT parameters must be zero	176	; 4. FAT parameters must be zero
175	cmp word [ebx+14], 0	177	cmp word [ebx+14], 0
176	jnz .no	178	jnz .no
177	cmp dword [ebx+16], 0	179	cmp dword [ebx+16], 0
178	jnz .no	180	jnz .no
179	cmp byte [ebx+20], 0	181	cmp byte [ebx+20], 0
180	jnz .no	182	jnz .no
181	cmp word [ebx+22], 0	183	cmp word [ebx+22], 0
182	jnz .no	184	jnz .no
183	cmp dword [ebx+32], 0	185	cmp dword [ebx+32], 0
184	jnz .no	186	jnz .no
185	; 5. Number of sectors <= partition size	187	; 5. Number of sectors <= partition size
186	cmp dword [ebx+0x2C], 0	188	cmp dword [ebx+0x2C], 0
187	ja .no	189	ja .no
188	cmp [ebx+0x28], edx	190	cmp [ebx+0x28], edx
189	ja .no	191	ja .no
190	; 6. $MFT and $MFTMirr clusters must be within partition	192	; 6. $MFT and $MFTMirr clusters must be within partition
191	cmp dword [ebx+0x34], 0	193	cmp dword [ebx+0x34], 0
192	ja .no	194	ja .no
193	push edx	195	push edx
194	movzx eax, byte [ebx+13]	196	movzx eax, byte [ebx+13]
195	mul dword [ebx+0x30]	197	mul dword [ebx+0x30]
196	test edx, edx	198	test edx, edx
197	pop edx	199	pop edx
198	jnz .no	200	jnz .no
199	cmp eax, edx	201	cmp eax, edx
200	ja .no	202	ja .no
201	cmp dword [ebx+0x3C], 0	203	cmp dword [ebx+0x3C], 0
202	ja .no	204	ja .no
203	push edx	205	push edx
204	movzx eax, byte [ebx+13]	206	movzx eax, byte [ebx+13]
205	mul dword [ebx+0x38]	207	mul dword [ebx+0x38]
206	test edx, edx	208	test edx, edx
207	pop edx	209	pop edx
208	jnz .no	210	jnz .no
209	cmp eax, edx	211	cmp eax, edx
210	ja .no	212	ja .no
211	; 7. Clusters per FRS must be either power of 2 or between -31 and -9	213	; 7. Clusters per FRS must be either power of 2 or between -31 and -9
212	movsx eax, byte [ebx+0x40]	214	movsx eax, byte [ebx+0x40]
213	cmp al, -31	215	cmp al, -31
214	jl .no	216	jl .no
215	cmp al, -9	217	cmp al, -9
216	jle @f	218	jle @f
217	dec eax	219	dec eax
218	js .no	220	js .no
219	test [ebx+0x40], al	221	test [ebx+0x40], al
220	jnz .no	222	jnz .no
221	@@: ; 8. Same for clusters per IndexAllocationBuffer	223	@@: ; 8. Same for clusters per IndexAllocationBuffer
222	movsx eax, byte [ebx+0x44]	224	movsx eax, byte [ebx+0x44]
223	cmp al, -31	225	cmp al, -31
224	jl .no	226	jl .no
225	cmp al, -9	227	cmp al, -9
226	jle @f	228	jle @f
227	dec eax	229	dec eax
228	js .no	230	js .no
229	test [ebx+0x44], al	231	test [ebx+0x44], al
230	jnz .no	232	jnz .no
231	@@: ; OK, this is correct NTFS bootsector	233	@@: ; OK, this is correct NTFS bootsector
232	clc	234	clc
233	ret	235	ret
234	.no: ; No, this bootsector isn't NTFS	236	.no: ; No, this bootsector isn't NTFS
235	stc	237	stc
236	ret	238	ret
237		239
238	ntfs_create_partition:	240	ntfs_create_partition:
239	cmp dword [esi+DISK.MediaInfo.SectorSize], 512	241	cmp dword [esi+DISK.MediaInfo.SectorSize], 512
240	jnz .nope	242	jnz .nope
241	mov edx, dword [ebp+PARTITION.Length]	243	mov edx, dword [ebp+PARTITION.Length]
242	cmp dword [esp+4], 0	244	cmp dword [esp+4], 0
243	jz .boot_read_ok	245	jz .boot_read_ok
244	add ebx, 512	246	add ebx, 512
245	lea eax, [edx-1]	247	lea eax, [edx-1]
246	call fs_read32_sys	248	call fs_read32_sys
247	test eax, eax	249	test eax, eax
248	jnz @f	250	jnz @f
249	call ntfs_test_bootsec	251	call ntfs_test_bootsec
250	jnc .ntfs_setup	252	jnc .ntfs_setup
251	@@:	253	@@:
252	mov eax, edx	254	mov eax, edx
253	shr eax, 1	255	shr eax, 1
254	call fs_read32_sys	256	call fs_read32_sys
255	test eax, eax	257	test eax, eax
256	jnz .nope	258	jnz .nope
257	.boot_read_ok:	259	.boot_read_ok:
258	call ntfs_test_bootsec	260	call ntfs_test_bootsec
259	jnc .ntfs_setup	261	jnc .ntfs_setup
260	.nope:	262	.nope:
261	xor eax, eax	263	xor eax, eax
262	jmp .exit	264	jmp .exit
263	; By given bootsector, initialize some NTFS variables	265	; By given bootsector, initialize some NTFS variables
264	.ntfs_setup:	266	.ntfs_setup:
265	movi eax, sizeof.NTFS	267	movi eax, sizeof.NTFS
266	call malloc	268	call malloc
267	test eax, eax	269	test eax, eax
268	jz .exit	270	jz .exit
269	mov ecx, dword [ebp+PARTITION.FirstSector]	271	mov ecx, dword [ebp+PARTITION.FirstSector]
270	mov dword [eax+NTFS.FirstSector], ecx	272	mov dword [eax+NTFS.FirstSector], ecx
271	mov ecx, dword [ebp+PARTITION.FirstSector+4]	273	mov ecx, dword [ebp+PARTITION.FirstSector+4]
272	mov dword [eax+NTFS.FirstSector+4], ecx	274	mov dword [eax+NTFS.FirstSector+4], ecx
273	mov ecx, dword [ebp+PARTITION.Length]	275	mov ecx, dword [ebp+PARTITION.Length]
274	mov dword [eax+NTFS.Length], ecx	276	mov dword [eax+NTFS.Length], ecx
275	mov ecx, dword [ebp+PARTITION.Length+4]	277	mov ecx, dword [ebp+PARTITION.Length+4]
276	mov dword [eax+NTFS.Length+4], ecx	278	mov dword [eax+NTFS.Length+4], ecx
277	mov ecx, [ebp+PARTITION.Disk]	279	mov ecx, [ebp+PARTITION.Disk]
278	mov [eax+NTFS.Disk], ecx	280	mov [eax+NTFS.Disk], ecx
279	mov [eax+NTFS.FSUserFunctions], ntfs_user_functions	281	mov [eax+NTFS.FSUserFunctions], ntfs_user_functions
-		282	mov [eax+NTFS.ntfsWriteAttr], 0
280		283
281	push ebx ebp esi	284	push ebx ebp esi
282	mov ebp, eax	285	mov ebp, eax
283	lea ecx, [ebp+NTFS.Lock]	286	lea ecx, [ebp+NTFS.Lock]
284	call mutex_init	287	call mutex_init
285	movzx eax, byte [ebx+13]	288	movzx eax, byte [ebx+13]
286	mov [ebp+NTFS.sectors_per_cluster], eax	289	mov [ebp+NTFS.sectors_per_cluster], eax
287	mov eax, [ebx+0x28]	290	mov eax, [ebx+0x28]
288	mov dword [ebp+NTFS.Length], eax	291	mov dword [ebp+NTFS.Length], eax
289	and dword [ebp+NTFS.Length+4], 0	292	and dword [ebp+NTFS.Length+4], 0
290	mov eax, [ebx+0x30]	293	mov eax, [ebx+0x30]
291	mov [ebp+NTFS.mft_cluster], eax	294	mov [ebp+NTFS.mft_cluster], eax
292	mov eax, [ebx+0x38]	295	mov eax, [ebx+0x38]
293	mov [ebp+NTFS.mftmirr_cluster], eax	296	mov [ebp+NTFS.mftmirr_cluster], eax
294	movsx eax, byte [ebx+0x40]	297	movsx eax, byte [ebx+0x40]
295	test eax, eax	298	test eax, eax
296	js @f	299	js @f
297	mul [ebp+NTFS.sectors_per_cluster]	300	mul [ebp+NTFS.sectors_per_cluster]
298	shl eax, 9	301	shl eax, 9
299	jmp .1	302	jmp .1
300	@@:	303	@@:
301	neg eax	304	neg eax
302	mov ecx, eax	305	mov ecx, eax
303	mov eax, 1	306	mov eax, 1
304	shl eax, cl	307	shl eax, cl
305	.1:	308	.1:
306	mov [ebp+NTFS.frs_size], eax	309	mov [ebp+NTFS.frs_size], eax
307	stdcall kernel_alloc, eax	310	stdcall kernel_alloc, eax
308	test eax, eax	311	test eax, eax
309	jz .fail_free	312	jz .fail_free
310	mov [ebp+NTFS.frs_buffer], eax	313	mov [ebp+NTFS.frs_buffer], eax
311	; read $MFT disposition	314	; read $MFT disposition
312	mov eax, [ebp+NTFS.mft_cluster]	315	mov eax, [ebp+NTFS.mft_cluster]
313	mul [ebp+NTFS.sectors_per_cluster]	316	mul [ebp+NTFS.sectors_per_cluster]
314	call ntfs_read_frs_sector	317	call ntfs_read_frs_sector
315	test eax, eax	318	test eax, eax
316	jnz .usemirr	319	jnz .usemirr
317	cmp dword [ebx], 'FILE'	320	cmp dword [ebx], 'FILE'
318	jnz .usemirr	321	jnz .usemirr
319	call ntfs_restore_usa_frs	322	call ntfs_restore_usa_frs
320	jnc .mftok	323	jnc .mftok
321	.usemirr:	324	.usemirr:
322	mov eax, [ebp+NTFS.mftmirr_cluster]	325	mov eax, [ebp+NTFS.mftmirr_cluster]
323	mul [ebp+NTFS.sectors_per_cluster]	326	mul [ebp+NTFS.sectors_per_cluster]
324	call ntfs_read_frs_sector	327	call ntfs_read_frs_sector
325	test eax, eax	328	test eax, eax
326	jnz .fail_free_frs	329	jnz .fail_free_frs
327	cmp dword [ebx], 'FILE'	330	cmp dword [ebx], 'FILE'
328	jnz .fail_free_frs	331	jnz .fail_free_frs
329	call ntfs_restore_usa_frs	332	call ntfs_restore_usa_frs
330	jc .fail_free_frs	333	jc .fail_free_frs
331	.mftok:	334	.mftok:
332	; read $MFT table retrieval information	335	; read $MFT table retrieval information
333	; start with one page, increase if not enough (when MFT too fragmented)	336	; start with one page, increase if not enough (when MFT too fragmented)
334	push ebx	337	push ebx
335	stdcall kernel_alloc, 0x1000	338	stdcall kernel_alloc, 0x1000
336	pop ebx	339	pop ebx
337	test eax, eax	340	test eax, eax
338	jz .fail_free_frs	341	jz .fail_free_frs
339	mov [ebp+NTFS.mft_retrieval], eax	342	mov [ebp+NTFS.mft_retrieval], eax
340	and [ebp+NTFS.mft_retrieval_size], 0	343	and [ebp+NTFS.mft_retrieval_size], 0
341	mov [ebp+NTFS.mft_retrieval_alloc], 0x1000/8	344	mov [ebp+NTFS.mft_retrieval_alloc], 0x1000/8
342	; $MFT base record must contain unnamed non-resident $DATA attribute	345	; $MFT base record must contain unnamed non-resident $DATA attribute
343	movzx eax, word [ebx+14h]	346	movzx eax, word [ebx+14h]
344	add eax, ebx	347	add eax, ebx
345	.scandata:	348	.scandata:
346	cmp dword [eax], -1	349	cmp dword [eax], -1
347	jz .fail_free_mft	350	jz .fail_free_mft
348	cmp dword [eax], 0x80	351	cmp dword [eax], 0x80
349	jnz @f	352	jnz @f
350	cmp byte [eax+9], 0	353	cmp byte [eax+9], 0
351	jz .founddata	354	jz .founddata
352	@@:	355	@@:
353	add eax, [eax+4]	356	add eax, [eax+4]
354	jmp .scandata	357	jmp .scandata
355	.founddata:	358	.founddata:
356	cmp byte [eax+8], 0	359	cmp byte [eax+8], 0
357	jz .fail_free_mft	360	jz .fail_free_mft
358	; load first portion of $DATA attribute retrieval information	361	; load first portion of $DATA attribute retrieval information
359	mov edx, [eax+0x18]	362	mov edx, [eax+0x18]
360	mov [ebp+NTFS.mft_retrieval_end], edx	363	mov [ebp+NTFS.mft_retrieval_end], edx
361	mov esi, eax	364	mov esi, eax
362	movzx eax, word [eax+0x20]	365	movzx eax, word [eax+0x20]
363	add esi, eax	366	add esi, eax
364	sub esp, 10h	367	sub esp, 10h
365	.scanmcb:	368	.scanmcb:
366	call ntfs_decode_mcb_entry	369	call ntfs_decode_mcb_entry
367	jnc .scanmcbend	370	jnc .scanmcbend
368	call .get_mft_retrieval_ptr	371	call .get_mft_retrieval_ptr
369	mov edx, [esp] ; block length	372	mov edx, [esp] ; block length
370	mov [eax], edx	373	mov [eax], edx
371	mov edx, [esp+8] ; block addr (relative)	374	mov edx, [esp+8] ; block addr (relative)
372	mov [eax+4], edx	375	mov [eax+4], edx
373	inc [ebp+NTFS.mft_retrieval_size]	376	inc [ebp+NTFS.mft_retrieval_size]
374	jmp .scanmcb	377	jmp .scanmcb
375	.scanmcbend:	378	.scanmcbend:
376	add esp, 10h	379	add esp, 10h
377	; there may be other portions of $DATA attribute in auxiliary records;	380	; there may be other portions of $DATA attribute in auxiliary records;
378	; if they will be needed, they will be loaded later	381	; if they will be needed, they will be loaded later
379	mov [ebp+NTFS.cur_index_size], 0x1000/0x200	382	mov [ebp+NTFS.cur_index_size], 0x1000/0x200
380	stdcall kernel_alloc, 0x1000	383	stdcall kernel_alloc, 0x1000
381	test eax, eax	384	test eax, eax
382	jz .fail_free_mft	385	jz .fail_free_mft
383	mov [ebp+NTFS.cur_index_buf], eax	386	mov [ebp+NTFS.cur_index_buf], eax
384	; reserve adress space for bitmap buffer and load some part of bitmap	387	; reserve adress space for bitmap buffer and load some part of bitmap
385	mov eax, dword [ebp+NTFS.Length]	388	mov eax, dword [ebp+NTFS.Length]
386	xor edx, edx	389	xor edx, edx
387	div [ebp+NTFS.sectors_per_cluster]	390	div [ebp+NTFS.sectors_per_cluster]
388	shr eax, 3	391	shr eax, 3
389	mov [ebp+NTFS.BitmapTotalSize], eax	392	mov [ebp+NTFS.BitmapTotalSize], eax
390	add eax, 7FFFh	393	add eax, 7FFFh
391	and eax, not 7FFFh	394	and eax, not 7FFFh
392	push eax	395	push eax
393	call alloc_kernel_space	396	call alloc_kernel_space
394	test eax, eax	397	test eax, eax
395	jz .failFreeIndex	398	jz .failFreeIndex
396	mov [ebp+NTFS.BitmapBuffer], eax	399	mov [ebp+NTFS.BitmapBuffer], eax
397	mov [ebp+NTFS.ntfs_cur_buf], eax	400	mov [ebp+NTFS.ntfs_cur_buf], eax
398	mov eax, [ebp+NTFS.BitmapTotalSize]	401	mov eax, [ebp+NTFS.BitmapTotalSize]
399	add eax, [ebp+NTFS.mft_cluster]	402	add eax, [ebp+NTFS.mft_cluster]
400	shr eax, 3+2 ; reserve 1/8 of partition for $MFT	403	shr eax, 3+2 ; reserve 1/8 of partition for $MFT
401	shl eax, 2	404	shl eax, 2
402	mov [ebp+NTFS.BitmapStart], eax	405	mov [ebp+NTFS.BitmapStart], eax
403	shr eax, 15	406	shr eax, 15
404	inc eax	407	inc eax
405	shl eax, 3	408	shl eax, 3
406	push eax	409	push eax
407	push eax	410	push eax
408	shl eax, 3	411	shl eax, 3
409	mov [ebp+NTFS.ntfs_cur_size], eax	412	mov [ebp+NTFS.ntfs_cur_size], eax
410	call alloc_pages	413	call alloc_pages
411	test eax, eax	414	test eax, eax
412	pop ecx	415	pop ecx
413	jz .failFreeBitmap	416	jz .failFreeBitmap
414	add eax, 3	417	add eax, 3
415	mov ebx, [ebp+NTFS.BitmapBuffer]	418	mov ebx, [ebp+NTFS.BitmapBuffer]
416	call commit_pages	419	call commit_pages
417	mov [ebp+NTFS.ntfs_cur_iRecord], 6	420	mov [ebp+NTFS.ntfs_cur_iRecord], 6
418	mov [ebp+NTFS.ntfs_cur_attr], 0x80	421	mov [ebp+NTFS.ntfs_cur_attr], 0x80
419	mov [ebp+NTFS.ntfs_cur_offs], 0	422	mov [ebp+NTFS.ntfs_cur_offs], 0
420	call ntfs_read_attr	423	call ntfs_read_attr
421	jc .failFreeBitmap	424	jc .failFreeBitmap
422	mov eax, [ebp+NTFS.ntfs_cur_read]	425	mov eax, [ebp+NTFS.ntfs_cur_read]
423	mov [ebp+NTFS.BitmapSize], eax	426	mov [ebp+NTFS.BitmapSize], eax
424	mov eax, [ebp+NTFS.ntfsLastRead]	427	mov eax, [ebp+NTFS.ntfsLastRead]
425	mov [ebp+NTFS.BitmapLocation], eax	428	mov [ebp+NTFS.BitmapLocation], eax
426	; read MFT $BITMAP attribute	429	; read MFT $BITMAP attribute
427	mov eax, [ebp+NTFS.sectors_per_cluster]	430	mov eax, [ebp+NTFS.sectors_per_cluster]
428	mov [ebp+NTFS.ntfs_cur_size], eax	431	mov [ebp+NTFS.ntfs_cur_size], eax
429	shl eax, 9	432	shl eax, 9
430	stdcall kernel_alloc, eax	433	stdcall kernel_alloc, eax
431	test eax, eax	434	test eax, eax
432	jz .failFreeBitmap	435	jz .failFreeBitmap
433	mov [ebp+NTFS.mftBitmapBuffer], eax	436	mov [ebp+NTFS.mftBitmapBuffer], eax
434	mov [ebp+NTFS.ntfs_cur_buf], eax	437	mov [ebp+NTFS.ntfs_cur_buf], eax
435	mov [ebp+NTFS.ntfs_cur_iRecord], 0	438	mov [ebp+NTFS.ntfs_cur_iRecord], 0
436	mov [ebp+NTFS.ntfs_cur_attr], 0xB0	439	mov [ebp+NTFS.ntfs_cur_attr], 0xB0
437	mov [ebp+NTFS.ntfs_cur_offs], 0	440	mov [ebp+NTFS.ntfs_cur_offs], 0
438	call ntfs_read_attr	441	call ntfs_read_attr
439	mov eax, [ebp+NTFS.ntfs_cur_read]	442	mov eax, [ebp+NTFS.ntfs_cur_read]
440	cmp eax, 4	443	cmp eax, 4
441	jc .failFreeBitmapMFT	444	jc .failFreeBitmapMFT
442	mov [ebp+NTFS.mftBitmapSize], eax	445	mov [ebp+NTFS.mftBitmapSize], eax
443	mov eax, [ebp+NTFS.ntfsLastRead]	446	mov eax, [ebp+NTFS.ntfsLastRead]
444	mov [ebp+NTFS.mftBitmapLocation], eax	447	mov [ebp+NTFS.mftBitmapLocation], eax
445		448
446	mov eax, ebp	449	mov eax, ebp
447	.pop_exit:	450	.pop_exit:
448	pop esi ebp ebx	451	pop esi ebp ebx
449	.exit:	452	.exit:
450	cmp dword [esp+4], 0	453	cmp dword [esp+4], 0
451	jz @f	454	jz @f
452	sub ebx, 512	455	sub ebx, 512
453	@@:	456	@@:
454	ret	457	ret
455		458
456	.failFreeBitmapMFT:	459	.failFreeBitmapMFT:
457	stdcall kernel_free, [ebx+NTFS.mftBitmapBuffer]	460	stdcall kernel_free, [ebx+NTFS.mftBitmapBuffer]
458	.failFreeBitmap:	461	.failFreeBitmap:
459	stdcall kernel_free, [ebx+NTFS.BitmapBuffer]	462	stdcall kernel_free, [ebx+NTFS.BitmapBuffer]
460	.failFreeIndex:	463	.failFreeIndex:
461	stdcall kernel_free, [ebp+NTFS.cur_index_buf]	464	stdcall kernel_free, [ebp+NTFS.cur_index_buf]
462	.fail_free_mft:	465	.fail_free_mft:
463	stdcall kernel_free, [ebp+NTFS.mft_retrieval]	466	stdcall kernel_free, [ebp+NTFS.mft_retrieval]
464	.fail_free_frs:	467	.fail_free_frs:
465	stdcall kernel_free, [ebp+NTFS.frs_buffer]	468	stdcall kernel_free, [ebp+NTFS.frs_buffer]
466	.fail_free:	469	.fail_free:
467	mov eax, ebp	470	mov eax, ebp
468	call free	471	call free
469	xor eax, eax	472	xor eax, eax
470	jmp .pop_exit	473	jmp .pop_exit
471		474
472	.get_mft_retrieval_ptr:	475	.get_mft_retrieval_ptr:
473	pushad	476	pushad
474	mov eax, [ebp+NTFS.mft_retrieval_size]	477	mov eax, [ebp+NTFS.mft_retrieval_size]
475	cmp eax, [ebp+NTFS.mft_retrieval_alloc]	478	cmp eax, [ebp+NTFS.mft_retrieval_alloc]
476	jnz .ok	479	jnz .ok
477	add eax, 0x1000/8	480	add eax, 0x1000/8
478	mov [ebp+NTFS.mft_retrieval_alloc], eax	481	mov [ebp+NTFS.mft_retrieval_alloc], eax
479	shl eax, 3	482	shl eax, 3
480	stdcall kernel_alloc, eax	483	stdcall kernel_alloc, eax
481	test eax, eax	484	test eax, eax
482	jnz @f	485	jnz @f
483	popad	486	popad
484	add esp, 14h	487	add esp, 14h
485	jmp .fail_free_mft	488	jmp .fail_free_mft
486	@@:	489	@@:
487	mov esi, [ebp+NTFS.mft_retrieval]	490	mov esi, [ebp+NTFS.mft_retrieval]
488	mov edi, eax	491	mov edi, eax
489	mov ecx, [ebp+NTFS.mft_retrieval_size]	492	mov ecx, [ebp+NTFS.mft_retrieval_size]
490	add ecx, ecx	493	add ecx, ecx
491	rep movsd	494	rep movsd
492	push [ebp+NTFS.mft_retrieval]	495	push [ebp+NTFS.mft_retrieval]
493	mov [ebp+NTFS.mft_retrieval], eax	496	mov [ebp+NTFS.mft_retrieval], eax
494	call kernel_free	497	call kernel_free
495	mov eax, [ebp+NTFS.mft_retrieval_size]	498	mov eax, [ebp+NTFS.mft_retrieval_size]
496	.ok:	499	.ok:

Subversion Repositories Kolibri OS

(root)/kernel/trunk/fs/ntfs.inc – Rev 5954 → 5994