Subversion Repositories Kolibri OS

align 4

proc init_LFB

           locals

             pg_count dd ?

           endl

        cmp     dword [LFBAddress], -1

        jne     @f

        mov     [BOOT_VARS+BOOT_MTRR], byte 2

; max VGA=640*480*4=1228800 bytes

; + 32*640*4=81920 bytes for mouse pointer

        stdcall alloc_pages, ((1228800+81920)/4096)

        push    eax

        call    alloc_page

        stdcall map_page_table, LFB_BASE, eax

        pop     eax

        or      eax, PG_UWR

        mov     ebx, LFB_BASE

; max VGA=640*480*4=1228800 bytes

; + 32*640*4=81920 bytes for mouse pointer

        mov     ecx, (1228800+81920)/4096

        call    commit_pages

        mov     [LFBAddress], dword LFB_BASE

        ret

@@:

        test    [SCR_MODE], word 0100000000000000b

        jnz     @f

        mov     [BOOT_VARS+BOOT_MTRR], byte 2

        ret

@@:

        call    init_mtrr

        mov     edx, LFB_BASE

        mov     esi, [LFBAddress]

        mov     edi, 0x00C00000

        mov     dword [exp_lfb+4], edx

        shr     edi, 12

        mov     [pg_count], edi

        shr     edi, 10

        bt      [cpu_caps], CAPS_PSE

        jnc     .map_page_tables

        or      esi, PDE_LARGE+PG_UWR

        mov     edx, sys_proc+PROC.pdt_0+(LFB_BASE shr 20)

@@:

        mov     [edx], esi

        add     edx, 4

        add     esi, 0x00400000

        dec     edi

        jnz     @B

        bt      [cpu_caps], CAPS_PGE

        jnc     @F

        or      dword [sys_proc+PROC.pdt_0+(LFB_BASE shr 20)], PG_GLOBAL

@@:

        mov     dword [LFBAddress], LFB_BASE

        mov     eax, cr3      ;flush TLB

        mov     cr3, eax

        ret

.map_page_tables:

@@:

        call    alloc_page

        stdcall map_page_table, edx, eax

        add     edx, 0x00400000

        dec     edi

        jnz     @B

        mov     eax, [LFBAddress]

        mov     edi, page_tabs + (LFB_BASE shr 10)

        or      eax, PG_GLOBAL+PG_UWR

        and     eax, [pte_valid_mask]

        mov     ecx, [pg_count]

        cld

@@:

        stosd

        add     eax, 0x1000

        loop    @B

        mov     dword [LFBAddress], LFB_BASE

        mov     eax, cr3      ;flush TLB

        mov     cr3, eax

        ret

endp