WebSVN – Kolibri OS – Diff – /kernel/trunk/gui/mouse.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                              ;;
;; Copyright (C) KolibriOS team 2010-2015. All rights reserved. ;;
;; Distributed under terms of the GNU General Public License    ;;
;;                                                              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 6585 $
 
include 'mousepointer.inc'
 
;================================
;/////// public functions ///////
;================================
 
mouse.LEFT_BUTTON_FLAG   = 0001b
mouse.RIGHT_BUTTON_FLAG  = 0010b
mouse.MIDDLE_BUTTON_FLAG = 0100b
 
mouse.BUTTONS_MASK = \
  mouse.LEFT_BUTTON_FLAG or \
  mouse.RIGHT_BUTTON_FLAG or \
  mouse.MIDDLE_BUTTON_FLAG
 
mouse.WINDOW_RESIZE_N_FLAG = 000001b
mouse.WINDOW_RESIZE_W_FLAG = 000010b
mouse.WINDOW_RESIZE_S_FLAG = 000100b
mouse.WINDOW_RESIZE_E_FLAG = 001000b
mouse.WINDOW_MOVE_FLAG     = 010000b
 
mouse.WINDOW_RESIZE_SW_FLAG = \
  mouse.WINDOW_RESIZE_S_FLAG or \
  mouse.WINDOW_RESIZE_W_FLAG
mouse.WINDOW_RESIZE_SE_FLAG = \
  mouse.WINDOW_RESIZE_S_FLAG or \
  mouse.WINDOW_RESIZE_E_FLAG
 
align 4
;-----------------------------------------------------------------
mouse_check_events:
; Check if mouse buttons state or cursor position has changed
        push    eax ebx
        mov     al, [BTN_DOWN]
        mov     bl, [mouse.state.buttons]
        and     al, mouse.BUTTONS_MASK
        mov     cl, al
        xchg    cl, [mouse.state.buttons]
        xor     bl, al
        push    eax ebx
 
        ; did any mouse button changed its state?
        or      bl, bl
        jz      .check_position
 
        ; yes it did, is that the first button of all pressed down?
        or      cl, cl
        jnz     .check_buttons_released
 
        ; yes it is, activate window user is pointing at, if needed
        call    mouse._.activate_sys_window_under_cursor
 
 
 
 
 
 
        ; is there any system button under cursor?
        call    mouse._.find_sys_button_under_cursor
        or      eax, eax
        jz      .check_buttons_released
 
        ; yes there is, activate it and exit
        mov     [mouse.active_sys_button.pbid], eax
        mov     [mouse.active_sys_button.coord], ebx
        mov     cl, [mouse.state.buttons]
        mov     [mouse.active_sys_button.buttons], cl
        call    sys_button_activate_handler
        jmp     .exit
 
  .check_buttons_released:
        cmp     [mouse.state.buttons], 0
        jnz     .buttons_changed
 
        ; did we press some button earlier?
        cmp     [mouse.active_sys_button.pbid], 0
        je      .buttons_changed
 
        ; yes we did, deactivate it
        xor     eax, eax
        xchg    eax, [mouse.active_sys_button.pbid]
        mov     ebx, [mouse.active_sys_button.coord]
        mov     cl, [mouse.active_sys_button.buttons]
        push    eax ebx
        call    sys_button_deactivate_handler
        pop     edx ecx
 
        ; is the button under cursor the one we deactivated?
        call    mouse._.find_sys_button_under_cursor
        cmp     eax, ecx
        jne     .exit
        cmp     ebx, edx
        jne     .exit
 
        ; yes it is, perform associated action
        mov     cl, [mouse.active_sys_button.buttons]
        call    sys_button_perform_handler
        jmp     .exit
 
  .buttons_changed:
        test    byte[esp], mouse.LEFT_BUTTON_FLAG
        jz      @f
        mov     eax, [esp + 4]
        call    .call_left_button_handler
 
    @@:
        test    byte[esp], mouse.RIGHT_BUTTON_FLAG
        jz      @f
        mov     eax, [esp + 4]
        call    .call_right_button_handler
 
    @@:
        test    byte[esp], mouse.MIDDLE_BUTTON_FLAG
        jz      .check_position
        mov     eax, [esp + 4]
        call    .call_middle_button_handler
 
  .check_position:
        movzx   eax, word[MOUSE_X]
        movzx   ebx, word[MOUSE_Y]
        cmp     eax, [mouse.state.pos.x]
        jne     .position_changed
        cmp     ebx, [mouse.state.pos.y]
        je      .exit
 
  .position_changed:
        xchg    eax, [mouse.state.pos.x]
        xchg    ebx, [mouse.state.pos.y]
 
        call    mouse._.move_handler
 
  .exit:
        add     esp, 8
        pop     ebx eax
        ret
 
  .call_left_button_handler:
        test    eax, mouse.LEFT_BUTTON_FLAG
        jnz     mouse._.left_button_press_handler
        jmp     mouse._.left_button_release_handler
 
  .call_right_button_handler:
        test    eax, mouse.RIGHT_BUTTON_FLAG
        jnz     mouse._.right_button_press_handler
        jmp     mouse._.right_button_release_handler
 
  .call_middle_button_handler:
        test    eax, mouse.MIDDLE_BUTTON_FLAG
        jnz     mouse._.middle_button_press_handler
        jmp     mouse._.middle_button_release_handler
 
;===============================
;////// private functions //////
;===============================
 
uglobal
  mouse.state:
    .pos     POINT
    .buttons db ?
 
; NOTE: since there's no unique and lifetime-constant button identifiers,
; we are using two dwords to identify each of them:
;   * pbid - process slot (high 8 bits) and button id (low 24 bits) pack
;   * coord - left (high 16 bits) and top (low 16 bits) coordinates pack
  align 4
  mouse.active_sys_button:
    .pbid    dd ?
    .coord   dd ?
    .buttons db ?
 
  align 4
  mouse.active_sys_window:
    .pslot      dd ?
    .old_box    BOX
    .new_box    BOX
    .delta      POINT
    .last_ticks dd ?
    .action     db ?
endg
 
iglobal
        fl_moving db 0
        rb 3
endg
 
align 4
;-----------------------------------------------------------------
mouse._.left_button_press_handler:
; Called when left mouse button has been pressed down
        bts     word [BTN_DOWN], 8
        mov     eax, [timer_ticks]
        mov     ebx, eax
        xchg    ebx, [mouse.active_sys_window.last_ticks]
        sub     eax, ebx
        movzx   ebx, [mouse_doubleclick_delay]
        cmp     eax, ebx
        jg      @f
        bts     dword [BTN_DOWN], 24
@@:
        test    [mouse.state.buttons], not mouse.LEFT_BUTTON_FLAG
        jnz     .exit
 
        call    mouse._.find_sys_window_under_cursor
        call    mouse._.check_sys_window_actions
        mov     [mouse.active_sys_window.action], al
        or      eax, eax
        jz      .exit
 
        xchg    eax, edx
        test    dl, mouse.WINDOW_MOVE_FLAG
        jz      @f
 
        bt      dword [BTN_DOWN], 24
        jnc     @f
 
        mov     [mouse.active_sys_window.last_ticks], 0
        call    sys_window_maximize_handler
        jmp     .exit
 
    @@:
        test    [edi + WDATA.fl_wstate], WSTATE_MAXIMIZED
        jnz     .exit
        mov     [mouse.active_sys_window.pslot], esi
        lea     eax, [edi + WDATA.box]
        mov     ebx, mouse.active_sys_window.old_box
        mov     ecx, sizeof.BOX
        call    memmove
        mov     ebx, mouse.active_sys_window.new_box
        call    memmove
        test    edx, mouse.WINDOW_MOVE_FLAG
        jz      @f
 
        call    .calculate_n_delta
        call    .calculate_w_delta
        jmp     .call_window_handler
 
    @@:
        test    dl, mouse.WINDOW_RESIZE_W_FLAG
        jz      @f
        call    .calculate_w_delta
 
    @@:
        test    dl, mouse.WINDOW_RESIZE_S_FLAG
        jz      @f
        call    .calculate_s_delta
 
    @@:
        test    dl, mouse.WINDOW_RESIZE_E_FLAG
        jz      .call_window_handler
        call    .calculate_e_delta
 
  .call_window_handler:
  .exit:
        ret
 
  .calculate_n_delta:
        mov     eax, [mouse.state.pos.y]
        sub     eax, [mouse.active_sys_window.old_box.top]
        mov     [mouse.active_sys_window.delta.y], eax
        ret
 
  .calculate_w_delta:
        mov     eax, [mouse.state.pos.x]
        sub     eax, [mouse.active_sys_window.old_box.left]
        mov     [mouse.active_sys_window.delta.x], eax
        ret
 
  .calculate_s_delta:
        mov     eax, [mouse.active_sys_window.old_box.top]
        add     eax, [mouse.active_sys_window.old_box.height]
        sub     eax, [mouse.state.pos.y]
        mov     [mouse.active_sys_window.delta.y], eax
        ret
 
  .calculate_e_delta:
        mov     eax, [mouse.active_sys_window.old_box.left]
        add     eax, [mouse.active_sys_window.old_box.width]
        sub     eax, [mouse.state.pos.x]
        mov     [mouse.active_sys_window.delta.x], eax
        ret
 
align 4
;-----------------------------------------------------------------
mouse._.left_button_release_handler:
; Called when left mouse button has been released
        bts     dword [BTN_DOWN], 16
        xor     esi, esi
        xchg    esi, [mouse.active_sys_window.pslot]
        or      esi, esi
        jz      .exit
 
        mov     eax, esi
        shl     eax, 5
        add     eax, window_data + WDATA.box
        mov     ebx, mouse.active_sys_window.old_box
        mov     ecx, sizeof.BOX
        call    memmove
 
        mov     eax, mouse.active_sys_window.old_box
        mov     ebx, mouse.active_sys_window.new_box
        call    sys_window_end_moving_handler
 
  .exit:
        and     [mouse.active_sys_window.action], 0
        mov     [fl_moving], 0
        ret
 
mouse._.right_button_press_handler:
        bts     word [BTN_DOWN], 9
        test    [mouse.state.buttons], not mouse.RIGHT_BUTTON_FLAG
        jnz     @f
        call    mouse._.find_sys_window_under_cursor
        call    mouse._.check_sys_window_actions
        test    al, mouse.WINDOW_MOVE_FLAG
        jz      @f
        jmp     sys_window_rollup_handler
 
mouse._.right_button_release_handler:
        bts     dword [BTN_DOWN], 17
@@:
        ret
 
mouse._.middle_button_press_handler:
        bts     word [BTN_DOWN], 10
        ret
 
mouse._.middle_button_release_handler:
        bts     dword [BTN_DOWN], 18
        ret
 
align 4
;-----------------------------------------------------------------
mouse._.move_handler:
; Called when cursor has been moved
;> eax = old x coord
;> ebx = old y coord
        cmp     [mouse.active_sys_button.pbid], 0
        jnz     .exit
 
        mov     esi, [mouse.active_sys_window.pslot]
        or      esi, esi
        jz      .exit
 
        mov     eax, mouse.active_sys_window.new_box
        mov     ebx, mouse.active_sys_window.old_box
        mov     ecx, sizeof.BOX
        call    memmove
 
        mov     dl, [mouse.active_sys_window.action]
        test    dl, mouse.WINDOW_MOVE_FLAG
        jz      .check_resize_w
 
        mov     eax, [mouse.state.pos.x]
        sub     eax, [mouse.active_sys_window.delta.x]
        mov     [mouse.active_sys_window.new_box.left], eax
        mov     eax, [mouse.state.pos.y]
        sub     eax, [mouse.active_sys_window.delta.y]
        mov     [mouse.active_sys_window.new_box.top], eax
 
        mov     eax, [mouse.active_sys_window.new_box.left]
        or      eax, eax
        jge     @f
        xor     eax, eax
        mov     [mouse.active_sys_window.new_box.left], eax
    @@:
        add     eax, [mouse.active_sys_window.new_box.width]
        cmp     eax, [_display.width]
        jl      @f
        sub     eax, [_display.width]
        sub     [mouse.active_sys_window.new_box.left], eax
    @@:
        mov     eax, [mouse.active_sys_window.new_box.top]
        or      eax, eax
        jge     @f
        xor     eax, eax
        mov     [mouse.active_sys_window.new_box.top], eax
    @@:
        add     eax, [mouse.active_sys_window.new_box.height]
        cmp     eax, [_display.height]
        jl      .call_window_handler
        sub     eax, [_display.height]
        sub     [mouse.active_sys_window.new_box.top], eax
        jmp     .call_window_handler
 
  .check_resize_w:
        test    dl, mouse.WINDOW_RESIZE_W_FLAG
        jz      .check_resize_s
 
        mov     eax, [mouse.state.pos.x]
        sub     eax, [mouse.active_sys_window.delta.x]
        mov     [mouse.active_sys_window.new_box.left], eax
        sub     eax, [mouse.active_sys_window.old_box.left]
        sub     [mouse.active_sys_window.new_box.width], eax
 
        mov     eax, [mouse.active_sys_window.new_box.width]
        sub     eax, 127
        jge     @f
        add     [mouse.active_sys_window.new_box.left], eax
        mov     [mouse.active_sys_window.new_box.width], 127
    @@:
        mov     eax, [mouse.active_sys_window.new_box.left]
        or      eax, eax
        jge     .check_resize_s
        add     [mouse.active_sys_window.new_box.width], eax
        xor     eax, eax
        mov     [mouse.active_sys_window.new_box.left], eax
 
  .check_resize_s:
        test    dl, mouse.WINDOW_RESIZE_S_FLAG
        jz      .check_resize_e
 
        mov     eax, [mouse.state.pos.y]
        add     eax, [mouse.active_sys_window.delta.y]
        sub     eax, [mouse.active_sys_window.old_box.top]
        mov     [mouse.active_sys_window.new_box.height], eax
 
        push    eax
        mov     edi, esi
        shl     edi, 5
        add     edi, window_data
        call    window._.get_rolledup_height
        mov     ecx, eax
        pop     eax
        mov     eax, [mouse.active_sys_window.new_box.height]
        cmp     eax, ecx
        jge     @f
        mov     eax, ecx
        mov     [mouse.active_sys_window.new_box.height], eax
    @@:
        add     eax, [mouse.active_sys_window.new_box.top]
        cmp     eax, [_display.height]
        jl      .check_resize_e
        sub     eax, [_display.height]
        neg     eax
        add     [mouse.active_sys_window.new_box.height], eax
        mov     ecx, [_display.height]
        cmp     ecx, eax
        jg      .check_resize_e
        mov     [mouse.active_sys_window.new_box.height], ecx
 
  .check_resize_e:
        test    dl, mouse.WINDOW_RESIZE_E_FLAG
        jz      .call_window_handler
 
        mov     eax, [mouse.state.pos.x]
        add     eax, [mouse.active_sys_window.delta.x]
        sub     eax, [mouse.active_sys_window.old_box.left]
        mov     [mouse.active_sys_window.new_box.width], eax
 
        mov     eax, [mouse.active_sys_window.new_box.width]
        cmp     eax, 127
        jge     @f
        mov     eax, 127
        mov     [mouse.active_sys_window.new_box.width], eax
    @@:
        add     eax, [mouse.active_sys_window.new_box.left]
        cmp     eax, [_display.width]
        jl      .call_window_handler
        sub     eax, [_display.width]
        neg     eax
        add     [mouse.active_sys_window.new_box.width], eax
        mov     ecx, [_display.width]
        cmp     ecx, eax
        jg      .call_window_handler
        mov     [mouse.active_sys_window.new_box.width], ecx
 
  .call_window_handler:
        mov     eax, mouse.active_sys_window.old_box
        mov     ebx, mouse.active_sys_window.new_box
 
        push    esi
        mov     esi, mouse.active_sys_window.old_box
        mov     edi, mouse.active_sys_window.new_box
        mov     ecx, sizeof.BOX / 4
        repe
        cmpsd
        pop     esi
        je      .exit
 
        test    [fl_moving], 1
        jnz     @f
 
        mov     [fl_moving], 1
        push    edi
        mov     edi, esi
        shl     edi, 5
        add     edi, WDATA.box + window_data
        call    window._.draw_negative_box
        pop     edi
     @@:
 
 
        mov     [mouse.active_sys_window.last_ticks], 0
        call    sys_window_moving_handler
 
  .exit:
        ret
 
align 4
;-----------------------------------------------------------------
mouse._.find_sys_window_under_cursor:
; Find system window object which is currently visible on screen
; and has mouse cursor within its bounds
;< esi = process slot
;< edi = pointer to WDATA struct
        mov     esi, [mouse.state.pos.y]
        mov     esi, [d_width_calc_area + esi*4]
 
        add     esi, [_display.win_map]
        add     esi, [mouse.state.pos.x]
        movzx   esi, byte[esi]
        mov     edi, esi
        shl     edi, 5
        add     edi, window_data
        ret
 
align 4
;-----------------------------------------------------------------
mouse._.activate_sys_window_under_cursor:
; activate and redraw window under cursor (if necessary)
        call    mouse._.find_sys_window_under_cursor
        movzx   esi, word[WIN_STACK + esi * 2]
        lea     esi, [WIN_POS + esi * 2]
        jmp     waredraw
 
align 4
;-----------------------------------------------------------------
mouse._.find_sys_button_under_cursor:
; Find system button object which is currently visible on screen
; and has mouse cursor within its bounds
;< eax = pack[8(process slot), 24(button id)] or 0
;< ebx = pack[16(button x coord), 16(button y coord)]
        push    ecx edx esi edi
 
        call    mouse._.find_sys_window_under_cursor
        mov     edx, esi
 
        ; check if any process button contains cursor
        mov     eax, [BTN_ADDR]
        mov     ecx, [eax]
        imul    esi, ecx, sizeof.SYS_BUTTON
        add     esi, eax
        inc     ecx
        add     esi, sizeof.SYS_BUTTON
 
  .next_button:
        dec     ecx
        jz      .not_found
 
        add     esi, -sizeof.SYS_BUTTON
 
        ; does it belong to our process?
        cmp     dx, [esi + SYS_BUTTON.pslot]
        jne     .next_button
 
        ; does it contain cursor coordinates?
        mov     eax, [mouse.state.pos.x]
        sub     eax, [edi + WDATA.box.left]
        sub     ax, [esi + SYS_BUTTON.left]
        jl      .next_button
        sub     ax, [esi + SYS_BUTTON.width]
        jge     .next_button
        mov     eax, [mouse.state.pos.y]
        sub     eax, [edi + WDATA.box.top]
        sub     ax, [esi + SYS_BUTTON.top]
        jl      .next_button
        sub     ax, [esi + SYS_BUTTON.height]
        jge     .next_button
 
        ; okay, return it
        shl     edx, 24
        mov     eax, dword[esi + SYS_BUTTON.id_hi - 2]
        mov     ax, [esi + SYS_BUTTON.id_lo]
        and     eax, 0x0ffffff
        or      eax, edx
        mov     ebx, dword[esi + SYS_BUTTON.left - 2]
        mov     bx, [esi + SYS_BUTTON.top]
        jmp     .exit
 
  .not_found:
        xor     eax, eax
        xor     ebx, ebx
 
  .exit:
        pop     edi esi edx ecx
        ret
 
align 4
;-----------------------------------------------------------------
mouse._.check_sys_window_actions:
;< eax = action flags or 0
        ; is window movable?
        test    byte[edi + WDATA.cl_titlebar + 3], 0x01
        jnz     .no_action
 
        mov     eax, [mouse.state.pos.x]
        mov     ebx, [mouse.state.pos.y]
        sub     eax, [edi + WDATA.box.left]
        sub     ebx, [edi + WDATA.box.top]
 
        ; is there a window titlebar under cursor?
        push    eax
        call    window._.get_titlebar_height
        cmp     ebx, eax
        pop     eax
        jl      .move_action
 
        ; no there isn't, can it be resized then?
        mov     dl, [edi + WDATA.fl_wstyle]
        and     dl, 0x0f
; NOTE: dangerous optimization, revise if window types changed
; this currently implies only types 2 and 3 could be resized
        test    dl, 2
        jz      .no_action
 
        mov     ecx, [edi + WDATA.box.width]
        add     ecx, -window.BORDER_SIZE
        mov     edx, [edi + WDATA.box.height]
        add     edx, -window.BORDER_SIZE
 
        ; is it rolled up?
        test    [edi + WDATA.fl_wstate], WSTATE_ROLLEDUP
        jnz     .resize_w_or_e_action
 
        cmp     eax, window.BORDER_SIZE
        jl      .resize_w_action
        cmp     eax, ecx
        jg      .resize_e_action
        cmp     ebx, edx
        jle     .no_action
 
  .resize_s_action:
        cmp     eax, window.BORDER_SIZE + 10
        jl      .resize_sw_action
        add     ecx, -10
        cmp     eax, ecx
        jge     .resize_se_action
        mov     eax, mouse.WINDOW_RESIZE_S_FLAG
        jmp     .exit
 
  .resize_w_or_e_action:
        cmp     eax, window.BORDER_SIZE + 10
        jl      .resize_w_action.direct
        add     ecx, -10
        cmp     eax, ecx
        jg      .resize_e_action.direct
        jmp     .no_action
 
  .resize_w_action:
        add     edx, -10
        cmp     ebx, edx
        jge     .resize_sw_action
  .resize_w_action.direct:
        mov     eax, mouse.WINDOW_RESIZE_W_FLAG
        jmp     .exit
 
  .resize_e_action:
        add     edx, -10
        cmp     ebx, edx
        jge     .resize_se_action
  .resize_e_action.direct:
        mov     eax, mouse.WINDOW_RESIZE_E_FLAG
        jmp     .exit
 
  .resize_sw_action:
        mov     eax, mouse.WINDOW_RESIZE_SW_FLAG
        jmp     .exit
 
  .resize_se_action:
        mov     eax, mouse.WINDOW_RESIZE_SE_FLAG
        jmp     .exit
 
  .move_action:
        mov     eax, mouse.WINDOW_MOVE_FLAG
        jmp     .exit
 
  .no_action:
        xor     eax, eax
 
  .exit:
        ret

Rev 5870	Rev 6585
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2010-2015. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2010-2015. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License ;;	4	;; Distributed under terms of the GNU General Public License ;;
5	;; ;;	5	;; ;;
6	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	6	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
7		7
8	$Revision: 5870 $	8	$Revision: 6585 $
9		9
10	include 'mousepointer.inc'	10	include 'mousepointer.inc'
11		11
12	;================================	12	;================================
13	;/////// public functions ///////	13	;/////// public functions ///////
14	;================================	14	;================================
15		15
16	mouse.LEFT_BUTTON_FLAG = 0001b	16	mouse.LEFT_BUTTON_FLAG = 0001b
17	mouse.RIGHT_BUTTON_FLAG = 0010b	17	mouse.RIGHT_BUTTON_FLAG = 0010b
18	mouse.MIDDLE_BUTTON_FLAG = 0100b	18	mouse.MIDDLE_BUTTON_FLAG = 0100b
19		19
20	mouse.BUTTONS_MASK = \	20	mouse.BUTTONS_MASK = \
21	mouse.LEFT_BUTTON_FLAG or \	21	mouse.LEFT_BUTTON_FLAG or \
22	mouse.RIGHT_BUTTON_FLAG or \	22	mouse.RIGHT_BUTTON_FLAG or \
23	mouse.MIDDLE_BUTTON_FLAG	23	mouse.MIDDLE_BUTTON_FLAG
24		24
25	mouse.WINDOW_RESIZE_N_FLAG = 000001b	25	mouse.WINDOW_RESIZE_N_FLAG = 000001b
26	mouse.WINDOW_RESIZE_W_FLAG = 000010b	26	mouse.WINDOW_RESIZE_W_FLAG = 000010b
27	mouse.WINDOW_RESIZE_S_FLAG = 000100b	27	mouse.WINDOW_RESIZE_S_FLAG = 000100b
28	mouse.WINDOW_RESIZE_E_FLAG = 001000b	28	mouse.WINDOW_RESIZE_E_FLAG = 001000b
29	mouse.WINDOW_MOVE_FLAG = 010000b	29	mouse.WINDOW_MOVE_FLAG = 010000b
30		30
31	mouse.WINDOW_RESIZE_SW_FLAG = \	31	mouse.WINDOW_RESIZE_SW_FLAG = \
32	mouse.WINDOW_RESIZE_S_FLAG or \	32	mouse.WINDOW_RESIZE_S_FLAG or \
33	mouse.WINDOW_RESIZE_W_FLAG	33	mouse.WINDOW_RESIZE_W_FLAG
34	mouse.WINDOW_RESIZE_SE_FLAG = \	34	mouse.WINDOW_RESIZE_SE_FLAG = \
35	mouse.WINDOW_RESIZE_S_FLAG or \	35	mouse.WINDOW_RESIZE_S_FLAG or \
36	mouse.WINDOW_RESIZE_E_FLAG	36	mouse.WINDOW_RESIZE_E_FLAG
37		37
38	align 4	38	align 4
39	;-----------------------------------------------------------------	39	;-----------------------------------------------------------------
40	mouse_check_events:	40	mouse_check_events:
41	; Check if mouse buttons state or cursor position has changed	41	; Check if mouse buttons state or cursor position has changed
42	push eax ebx	42	push eax ebx
43	mov al, [BTN_DOWN]	43	mov al, [BTN_DOWN]
44	mov bl, [mouse.state.buttons]	44	mov bl, [mouse.state.buttons]
45	and al, mouse.BUTTONS_MASK	45	and al, mouse.BUTTONS_MASK
46	mov cl, al	46	mov cl, al
47	xchg cl, [mouse.state.buttons]	47	xchg cl, [mouse.state.buttons]
48	xor bl, al	48	xor bl, al
49	push eax ebx	49	push eax ebx
50		50
51	; did any mouse button changed its state?	51	; did any mouse button changed its state?
52	or bl, bl	52	or bl, bl
53	jz .check_position	53	jz .check_position
54		54
55	; yes it did, is that the first button of all pressed down?	55	; yes it did, is that the first button of all pressed down?
56	or cl, cl	56	or cl, cl
57	jnz .check_buttons_released	57	jnz .check_buttons_released
58		58
59	; yes it is, activate window user is pointing at, if needed	59	; yes it is, activate window user is pointing at, if needed
60	call mouse._.activate_sys_window_under_cursor	60	call mouse._.activate_sys_window_under_cursor
61		-
62	; NOTE: this code wouldn't be necessary if we knew	-
63	; that window did already redraw itself after call above	-
64	or eax, eax	-
65	jnz .exit	-
66		61
67	; is there any system button under cursor?	62	; is there any system button under cursor?
68	call mouse._.find_sys_button_under_cursor	63	call mouse._.find_sys_button_under_cursor
69	or eax, eax	64	or eax, eax
70	jz .check_buttons_released	65	jz .check_buttons_released
71		66
72	; yes there is, activate it and exit	67	; yes there is, activate it and exit
73	mov [mouse.active_sys_button.pbid], eax	68	mov [mouse.active_sys_button.pbid], eax
74	mov [mouse.active_sys_button.coord], ebx	69	mov [mouse.active_sys_button.coord], ebx
75	mov cl, [mouse.state.buttons]	70	mov cl, [mouse.state.buttons]
76	mov [mouse.active_sys_button.buttons], cl	71	mov [mouse.active_sys_button.buttons], cl
77	call sys_button_activate_handler	72	call sys_button_activate_handler
78	jmp .exit	73	jmp .exit
79		74
80	.check_buttons_released:	75	.check_buttons_released:
81	cmp [mouse.state.buttons], 0	76	cmp [mouse.state.buttons], 0
82	jnz .buttons_changed	77	jnz .buttons_changed
83		78
84	; did we press some button earlier?	79	; did we press some button earlier?
85	cmp [mouse.active_sys_button.pbid], 0	80	cmp [mouse.active_sys_button.pbid], 0
86	je .buttons_changed	81	je .buttons_changed
87		82
88	; yes we did, deactivate it	83	; yes we did, deactivate it
89	xor eax, eax	84	xor eax, eax
90	xchg eax, [mouse.active_sys_button.pbid]	85	xchg eax, [mouse.active_sys_button.pbid]
91	mov ebx, [mouse.active_sys_button.coord]	86	mov ebx, [mouse.active_sys_button.coord]
92	mov cl, [mouse.active_sys_button.buttons]	87	mov cl, [mouse.active_sys_button.buttons]
93	push eax ebx	88	push eax ebx
94	call sys_button_deactivate_handler	89	call sys_button_deactivate_handler
95	pop edx ecx	90	pop edx ecx
96		91
97	; is the button under cursor the one we deactivated?	92	; is the button under cursor the one we deactivated?
98	call mouse._.find_sys_button_under_cursor	93	call mouse._.find_sys_button_under_cursor
99	cmp eax, ecx	94	cmp eax, ecx
100	jne .exit	95	jne .exit
101	cmp ebx, edx	96	cmp ebx, edx
102	jne .exit	97	jne .exit
103		98
104	; yes it is, perform associated action	99	; yes it is, perform associated action
105	mov cl, [mouse.active_sys_button.buttons]	100	mov cl, [mouse.active_sys_button.buttons]
106	call sys_button_perform_handler	101	call sys_button_perform_handler
107	jmp .exit	102	jmp .exit
108		103
109	.buttons_changed:	104	.buttons_changed:
110	test byte[esp], mouse.LEFT_BUTTON_FLAG	105	test byte[esp], mouse.LEFT_BUTTON_FLAG
111	jz @f	106	jz @f
112	mov eax, [esp + 4]	107	mov eax, [esp + 4]
113	call .call_left_button_handler	108	call .call_left_button_handler
114		109
115	@@:	110	@@:
116	test byte[esp], mouse.RIGHT_BUTTON_FLAG	111	test byte[esp], mouse.RIGHT_BUTTON_FLAG
117	jz @f	112	jz @f
118	mov eax, [esp + 4]	113	mov eax, [esp + 4]
119	call .call_right_button_handler	114	call .call_right_button_handler
120		115
121	@@:	116	@@:
122	test byte[esp], mouse.MIDDLE_BUTTON_FLAG	117	test byte[esp], mouse.MIDDLE_BUTTON_FLAG
123	jz .check_position	118	jz .check_position
124	mov eax, [esp + 4]	119	mov eax, [esp + 4]
125	call .call_middle_button_handler	120	call .call_middle_button_handler
126		121
127	.check_position:	122	.check_position:
128	movzx eax, word[MOUSE_X]	123	movzx eax, word[MOUSE_X]
129	movzx ebx, word[MOUSE_Y]	124	movzx ebx, word[MOUSE_Y]
130	cmp eax, [mouse.state.pos.x]	125	cmp eax, [mouse.state.pos.x]
131	jne .position_changed	126	jne .position_changed
132	cmp ebx, [mouse.state.pos.y]	127	cmp ebx, [mouse.state.pos.y]
133	je .exit	128	je .exit
134		129
135	.position_changed:	130	.position_changed:
136	xchg eax, [mouse.state.pos.x]	131	xchg eax, [mouse.state.pos.x]
137	xchg ebx, [mouse.state.pos.y]	132	xchg ebx, [mouse.state.pos.y]
138		133
139	call mouse._.move_handler	134	call mouse._.move_handler
140		135
141	.exit:	136	.exit:
142	add esp, 8	137	add esp, 8
143	pop ebx eax	138	pop ebx eax
144	ret	139	ret
145		140
146	.call_left_button_handler:	141	.call_left_button_handler:
147	test eax, mouse.LEFT_BUTTON_FLAG	142	test eax, mouse.LEFT_BUTTON_FLAG
148	jnz mouse._.left_button_press_handler	143	jnz mouse._.left_button_press_handler
149	jmp mouse._.left_button_release_handler	144	jmp mouse._.left_button_release_handler
150		145
151	.call_right_button_handler:	146	.call_right_button_handler:
152	test eax, mouse.RIGHT_BUTTON_FLAG	147	test eax, mouse.RIGHT_BUTTON_FLAG
153	jnz mouse._.right_button_press_handler	148	jnz mouse._.right_button_press_handler
154	jmp mouse._.right_button_release_handler	149	jmp mouse._.right_button_release_handler
155		150
156	.call_middle_button_handler:	151	.call_middle_button_handler:
157	test eax, mouse.MIDDLE_BUTTON_FLAG	152	test eax, mouse.MIDDLE_BUTTON_FLAG
158	jnz mouse._.middle_button_press_handler	153	jnz mouse._.middle_button_press_handler
159	jmp mouse._.middle_button_release_handler	154	jmp mouse._.middle_button_release_handler
160		155
161	;===============================	156	;===============================
162	;////// private functions //////	157	;////// private functions //////
163	;===============================	158	;===============================
164		159
165	uglobal	160	uglobal
166	mouse.state:	161	mouse.state:
167	.pos POINT	162	.pos POINT
168	.buttons db ?	163	.buttons db ?
169		164
170	; NOTE: since there's no unique and lifetime-constant button identifiers,	165	; NOTE: since there's no unique and lifetime-constant button identifiers,
171	; we are using two dwords to identify each of them:	166	; we are using two dwords to identify each of them:
172	; * pbid - process slot (high 8 bits) and button id (low 24 bits) pack	167	; * pbid - process slot (high 8 bits) and button id (low 24 bits) pack
173	; * coord - left (high 16 bits) and top (low 16 bits) coordinates pack	168	; * coord - left (high 16 bits) and top (low 16 bits) coordinates pack
174	align 4	169	align 4
175	mouse.active_sys_button:	170	mouse.active_sys_button:
176	.pbid dd ?	171	.pbid dd ?
177	.coord dd ?	172	.coord dd ?
178	.buttons db ?	173	.buttons db ?
179		174
180	align 4	175	align 4
181	mouse.active_sys_window:	176	mouse.active_sys_window:
182	.pslot dd ?	177	.pslot dd ?
183	.old_box BOX	178	.old_box BOX
184	.new_box BOX	179	.new_box BOX
185	.delta POINT	180	.delta POINT
186	.last_ticks dd ?	181	.last_ticks dd ?
187	.action db ?	182	.action db ?
188	endg	183	endg
189		184
190	iglobal	185	iglobal
191	fl_moving db 0	186	fl_moving db 0
192	rb 3	187	rb 3
193	endg	188	endg
194		189
195	align 4	190	align 4
196	;-----------------------------------------------------------------	191	;-----------------------------------------------------------------
197	mouse._.left_button_press_handler:	192	mouse._.left_button_press_handler:
198	; Called when left mouse button has been pressed down	193	; Called when left mouse button has been pressed down
199	bts word [BTN_DOWN], 8	194	bts word [BTN_DOWN], 8
200	mov eax, [timer_ticks]	195	mov eax, [timer_ticks]
201	mov ebx, eax	196	mov ebx, eax
202	xchg ebx, [mouse.active_sys_window.last_ticks]	197	xchg ebx, [mouse.active_sys_window.last_ticks]
203	sub eax, ebx	198	sub eax, ebx
204	movzx ebx, [mouse_doubleclick_delay]	199	movzx ebx, [mouse_doubleclick_delay]
205	cmp eax, ebx	200	cmp eax, ebx
206	jg @f	201	jg @f
207	bts dword [BTN_DOWN], 24	202	bts dword [BTN_DOWN], 24
208	@@:	203	@@:
209	test [mouse.state.buttons], not mouse.LEFT_BUTTON_FLAG	204	test [mouse.state.buttons], not mouse.LEFT_BUTTON_FLAG
210	jnz .exit	205	jnz .exit
211		206
212	call mouse._.find_sys_window_under_cursor	207	call mouse._.find_sys_window_under_cursor
213	call mouse._.check_sys_window_actions	208	call mouse._.check_sys_window_actions
214	mov [mouse.active_sys_window.action], al	209	mov [mouse.active_sys_window.action], al
215	or eax, eax	210	or eax, eax
216	jz .exit	211	jz .exit
217		212
218	xchg eax, edx	213	xchg eax, edx
219	test dl, mouse.WINDOW_MOVE_FLAG	214	test dl, mouse.WINDOW_MOVE_FLAG
220	jz @f	215	jz @f
221		216
222	bt dword [BTN_DOWN], 24	217	bt dword [BTN_DOWN], 24
223	jnc @f	218	jnc @f
224		219
225	mov [mouse.active_sys_window.last_ticks], 0	220	mov [mouse.active_sys_window.last_ticks], 0
226	call sys_window_maximize_handler	221	call sys_window_maximize_handler
227	jmp .exit	222	jmp .exit
228		223
229	@@:	224	@@:
230	test [edi + WDATA.fl_wstate], WSTATE_MAXIMIZED	225	test [edi + WDATA.fl_wstate], WSTATE_MAXIMIZED
231	jnz .exit	226	jnz .exit
232	mov [mouse.active_sys_window.pslot], esi	227	mov [mouse.active_sys_window.pslot], esi
233	lea eax, [edi + WDATA.box]	228	lea eax, [edi + WDATA.box]
234	mov ebx, mouse.active_sys_window.old_box	229	mov ebx, mouse.active_sys_window.old_box
235	mov ecx, sizeof.BOX	230	mov ecx, sizeof.BOX
236	call memmove	231	call memmove
237	mov ebx, mouse.active_sys_window.new_box	232	mov ebx, mouse.active_sys_window.new_box
238	call memmove	233	call memmove
239	test edx, mouse.WINDOW_MOVE_FLAG	234	test edx, mouse.WINDOW_MOVE_FLAG
240	jz @f	235	jz @f
241		236
242	call .calculate_n_delta	237	call .calculate_n_delta
243	call .calculate_w_delta	238	call .calculate_w_delta
244	jmp .call_window_handler	239	jmp .call_window_handler
245		240
246	@@:	241	@@:
247	test dl, mouse.WINDOW_RESIZE_W_FLAG	242	test dl, mouse.WINDOW_RESIZE_W_FLAG
248	jz @f	243	jz @f
249	call .calculate_w_delta	244	call .calculate_w_delta
250		245
251	@@:	246	@@:
252	test dl, mouse.WINDOW_RESIZE_S_FLAG	247	test dl, mouse.WINDOW_RESIZE_S_FLAG
253	jz @f	248	jz @f
254	call .calculate_s_delta	249	call .calculate_s_delta
255		250
256	@@:	251	@@:
257	test dl, mouse.WINDOW_RESIZE_E_FLAG	252	test dl, mouse.WINDOW_RESIZE_E_FLAG
258	jz .call_window_handler	253	jz .call_window_handler
259	call .calculate_e_delta	254	call .calculate_e_delta
260		255
261	.call_window_handler:	256	.call_window_handler:
262	.exit:	257	.exit:
263	ret	258	ret
264		259
265	.calculate_n_delta:	260	.calculate_n_delta:
266	mov eax, [mouse.state.pos.y]	261	mov eax, [mouse.state.pos.y]
267	sub eax, [mouse.active_sys_window.old_box.top]	262	sub eax, [mouse.active_sys_window.old_box.top]
268	mov [mouse.active_sys_window.delta.y], eax	263	mov [mouse.active_sys_window.delta.y], eax
269	ret	264	ret
270		265
271	.calculate_w_delta:	266	.calculate_w_delta:
272	mov eax, [mouse.state.pos.x]	267	mov eax, [mouse.state.pos.x]
273	sub eax, [mouse.active_sys_window.old_box.left]	268	sub eax, [mouse.active_sys_window.old_box.left]
274	mov [mouse.active_sys_window.delta.x], eax	269	mov [mouse.active_sys_window.delta.x], eax
275	ret	270	ret
276		271
277	.calculate_s_delta:	272	.calculate_s_delta:
278	mov eax, [mouse.active_sys_window.old_box.top]	273	mov eax, [mouse.active_sys_window.old_box.top]
279	add eax, [mouse.active_sys_window.old_box.height]	274	add eax, [mouse.active_sys_window.old_box.height]
280	sub eax, [mouse.state.pos.y]	275	sub eax, [mouse.state.pos.y]
281	mov [mouse.active_sys_window.delta.y], eax	276	mov [mouse.active_sys_window.delta.y], eax
282	ret	277	ret
283		278
284	.calculate_e_delta:	279	.calculate_e_delta:
285	mov eax, [mouse.active_sys_window.old_box.left]	280	mov eax, [mouse.active_sys_window.old_box.left]
286	add eax, [mouse.active_sys_window.old_box.width]	281	add eax, [mouse.active_sys_window.old_box.width]
287	sub eax, [mouse.state.pos.x]	282	sub eax, [mouse.state.pos.x]
288	mov [mouse.active_sys_window.delta.x], eax	283	mov [mouse.active_sys_window.delta.x], eax
289	ret	284	ret
290		285
291	align 4	286	align 4
292	;-----------------------------------------------------------------	287	;-----------------------------------------------------------------
293	mouse._.left_button_release_handler:	288	mouse._.left_button_release_handler:
294	; Called when left mouse button has been released	289	; Called when left mouse button has been released
295	bts dword [BTN_DOWN], 16	290	bts dword [BTN_DOWN], 16
296	xor esi, esi	291	xor esi, esi
297	xchg esi, [mouse.active_sys_window.pslot]	292	xchg esi, [mouse.active_sys_window.pslot]
298	or esi, esi	293	or esi, esi
299	jz .exit	294	jz .exit
300		295
301	mov eax, esi	296	mov eax, esi
302	shl eax, 5	297	shl eax, 5
303	add eax, window_data + WDATA.box	298	add eax, window_data + WDATA.box
304	mov ebx, mouse.active_sys_window.old_box	299	mov ebx, mouse.active_sys_window.old_box
305	mov ecx, sizeof.BOX	300	mov ecx, sizeof.BOX
306	call memmove	301	call memmove
307		302
308	mov eax, mouse.active_sys_window.old_box	303	mov eax, mouse.active_sys_window.old_box
309	mov ebx, mouse.active_sys_window.new_box	304	mov ebx, mouse.active_sys_window.new_box
310	call sys_window_end_moving_handler	305	call sys_window_end_moving_handler
311		306
312	.exit:	307	.exit:
313	and [mouse.active_sys_window.action], 0	308	and [mouse.active_sys_window.action], 0
314	mov [fl_moving], 0	309	mov [fl_moving], 0
315	ret	310	ret
316		311
317	mouse._.right_button_press_handler:	312	mouse._.right_button_press_handler:
318	bts word [BTN_DOWN], 9	313	bts word [BTN_DOWN], 9
319	test [mouse.state.buttons], not mouse.RIGHT_BUTTON_FLAG	314	test [mouse.state.buttons], not mouse.RIGHT_BUTTON_FLAG
320	jnz @f	315	jnz @f
321	call mouse._.find_sys_window_under_cursor	316	call mouse._.find_sys_window_under_cursor
322	call mouse._.check_sys_window_actions	317	call mouse._.check_sys_window_actions
323	test al, mouse.WINDOW_MOVE_FLAG	318	test al, mouse.WINDOW_MOVE_FLAG
324	jz @f	319	jz @f
325	jmp sys_window_rollup_handler	320	jmp sys_window_rollup_handler
326		321
327	mouse._.right_button_release_handler:	322	mouse._.right_button_release_handler:
328	bts dword [BTN_DOWN], 17	323	bts dword [BTN_DOWN], 17
329	@@:	324	@@:
330	ret	325	ret
331		326
332	mouse._.middle_button_press_handler:	327	mouse._.middle_button_press_handler:
333	bts word [BTN_DOWN], 10	328	bts word [BTN_DOWN], 10
334	ret	329	ret
335		330
336	mouse._.middle_button_release_handler:	331	mouse._.middle_button_release_handler:
337	bts dword [BTN_DOWN], 18	332	bts dword [BTN_DOWN], 18
338	ret	333	ret
339		334
340	align 4	335	align 4
341	;-----------------------------------------------------------------	336	;-----------------------------------------------------------------
342	mouse._.move_handler:	337	mouse._.move_handler:
343	; Called when cursor has been moved	338	; Called when cursor has been moved
344	;> eax = old x coord	339	;> eax = old x coord
345	;> ebx = old y coord	340	;> ebx = old y coord
346	cmp [mouse.active_sys_button.pbid], 0	341	cmp [mouse.active_sys_button.pbid], 0
347	jnz .exit	342	jnz .exit
348		343
349	mov esi, [mouse.active_sys_window.pslot]	344	mov esi, [mouse.active_sys_window.pslot]
350	or esi, esi	345	or esi, esi
351	jz .exit	346	jz .exit
352		347
353	mov eax, mouse.active_sys_window.new_box	348	mov eax, mouse.active_sys_window.new_box
354	mov ebx, mouse.active_sys_window.old_box	349	mov ebx, mouse.active_sys_window.old_box
355	mov ecx, sizeof.BOX	350	mov ecx, sizeof.BOX
356	call memmove	351	call memmove
357		352
358	mov dl, [mouse.active_sys_window.action]	353	mov dl, [mouse.active_sys_window.action]
359	test dl, mouse.WINDOW_MOVE_FLAG	354	test dl, mouse.WINDOW_MOVE_FLAG
360	jz .check_resize_w	355	jz .check_resize_w
361		356
362	mov eax, [mouse.state.pos.x]	357	mov eax, [mouse.state.pos.x]
363	sub eax, [mouse.active_sys_window.delta.x]	358	sub eax, [mouse.active_sys_window.delta.x]
364	mov [mouse.active_sys_window.new_box.left], eax	359	mov [mouse.active_sys_window.new_box.left], eax
365	mov eax, [mouse.state.pos.y]	360	mov eax, [mouse.state.pos.y]
366	sub eax, [mouse.active_sys_window.delta.y]	361	sub eax, [mouse.active_sys_window.delta.y]
367	mov [mouse.active_sys_window.new_box.top], eax	362	mov [mouse.active_sys_window.new_box.top], eax
368		363
369	mov eax, [mouse.active_sys_window.new_box.left]	364	mov eax, [mouse.active_sys_window.new_box.left]
370	or eax, eax	365	or eax, eax
371	jge @f	366	jge @f
372	xor eax, eax	367	xor eax, eax
373	mov [mouse.active_sys_window.new_box.left], eax	368	mov [mouse.active_sys_window.new_box.left], eax
374	@@:	369	@@:
375	add eax, [mouse.active_sys_window.new_box.width]	370	add eax, [mouse.active_sys_window.new_box.width]
376	cmp eax, [_display.width]	371	cmp eax, [_display.width]
377	jl @f	372	jl @f
378	sub eax, [_display.width]	373	sub eax, [_display.width]
379	sub [mouse.active_sys_window.new_box.left], eax	374	sub [mouse.active_sys_window.new_box.left], eax
380	@@:	375	@@:
381	mov eax, [mouse.active_sys_window.new_box.top]	376	mov eax, [mouse.active_sys_window.new_box.top]
382	or eax, eax	377	or eax, eax
383	jge @f	378	jge @f
384	xor eax, eax	379	xor eax, eax
385	mov [mouse.active_sys_window.new_box.top], eax	380	mov [mouse.active_sys_window.new_box.top], eax
386	@@:	381	@@:
387	add eax, [mouse.active_sys_window.new_box.height]	382	add eax, [mouse.active_sys_window.new_box.height]
388	cmp eax, [_display.height]	383	cmp eax, [_display.height]
389	jl .call_window_handler	384	jl .call_window_handler
390	sub eax, [_display.height]	385	sub eax, [_display.height]
391	sub [mouse.active_sys_window.new_box.top], eax	386	sub [mouse.active_sys_window.new_box.top], eax
392	jmp .call_window_handler	387	jmp .call_window_handler
393		388
394	.check_resize_w:	389	.check_resize_w:
395	test dl, mouse.WINDOW_RESIZE_W_FLAG	390	test dl, mouse.WINDOW_RESIZE_W_FLAG
396	jz .check_resize_s	391	jz .check_resize_s
397		392
398	mov eax, [mouse.state.pos.x]	393	mov eax, [mouse.state.pos.x]
399	sub eax, [mouse.active_sys_window.delta.x]	394	sub eax, [mouse.active_sys_window.delta.x]
400	mov [mouse.active_sys_window.new_box.left], eax	395	mov [mouse.active_sys_window.new_box.left], eax
401	sub eax, [mouse.active_sys_window.old_box.left]	396	sub eax, [mouse.active_sys_window.old_box.left]
402	sub [mouse.active_sys_window.new_box.width], eax	397	sub [mouse.active_sys_window.new_box.width], eax
403		398
404	mov eax, [mouse.active_sys_window.new_box.width]	399	mov eax, [mouse.active_sys_window.new_box.width]
405	sub eax, 127	400	sub eax, 127
406	jge @f	401	jge @f
407	add [mouse.active_sys_window.new_box.left], eax	402	add [mouse.active_sys_window.new_box.left], eax
408	mov [mouse.active_sys_window.new_box.width], 127	403	mov [mouse.active_sys_window.new_box.width], 127
409	@@:	404	@@:
410	mov eax, [mouse.active_sys_window.new_box.left]	405	mov eax, [mouse.active_sys_window.new_box.left]
411	or eax, eax	406	or eax, eax
412	jge .check_resize_s	407	jge .check_resize_s
413	add [mouse.active_sys_window.new_box.width], eax	408	add [mouse.active_sys_window.new_box.width], eax
414	xor eax, eax	409	xor eax, eax
415	mov [mouse.active_sys_window.new_box.left], eax	410	mov [mouse.active_sys_window.new_box.left], eax
416		411
417	.check_resize_s:	412	.check_resize_s:
418	test dl, mouse.WINDOW_RESIZE_S_FLAG	413	test dl, mouse.WINDOW_RESIZE_S_FLAG
419	jz .check_resize_e	414	jz .check_resize_e
420		415
421	mov eax, [mouse.state.pos.y]	416	mov eax, [mouse.state.pos.y]
422	add eax, [mouse.active_sys_window.delta.y]	417	add eax, [mouse.active_sys_window.delta.y]
423	sub eax, [mouse.active_sys_window.old_box.top]	418	sub eax, [mouse.active_sys_window.old_box.top]
424	mov [mouse.active_sys_window.new_box.height], eax	419	mov [mouse.active_sys_window.new_box.height], eax
425		420
426	push eax	421	push eax
427	mov edi, esi	422	mov edi, esi
428	shl edi, 5	423	shl edi, 5
429	add edi, window_data	424	add edi, window_data
430	call window._.get_rolledup_height	425	call window._.get_rolledup_height
431	mov ecx, eax	426	mov ecx, eax
432	pop eax	427	pop eax
433	mov eax, [mouse.active_sys_window.new_box.height]	428	mov eax, [mouse.active_sys_window.new_box.height]
434	cmp eax, ecx	429	cmp eax, ecx
435	jge @f	430	jge @f
436	mov eax, ecx	431	mov eax, ecx
437	mov [mouse.active_sys_window.new_box.height], eax	432	mov [mouse.active_sys_window.new_box.height], eax
438	@@:	433	@@:
439	add eax, [mouse.active_sys_window.new_box.top]	434	add eax, [mouse.active_sys_window.new_box.top]
440	cmp eax, [_display.height]	435	cmp eax, [_display.height]
441	jl .check_resize_e	436	jl .check_resize_e
442	sub eax, [_display.height]	437	sub eax, [_display.height]
443	neg eax	438	neg eax
444	add [mouse.active_sys_window.new_box.height], eax	439	add [mouse.active_sys_window.new_box.height], eax
445	mov ecx, [_display.height]	440	mov ecx, [_display.height]
446	cmp ecx, eax	441	cmp ecx, eax
447	jg .check_resize_e	442	jg .check_resize_e
448	mov [mouse.active_sys_window.new_box.height], ecx	443	mov [mouse.active_sys_window.new_box.height], ecx
449		444
450	.check_resize_e:	445	.check_resize_e:
451	test dl, mouse.WINDOW_RESIZE_E_FLAG	446	test dl, mouse.WINDOW_RESIZE_E_FLAG
452	jz .call_window_handler	447	jz .call_window_handler
453		448
454	mov eax, [mouse.state.pos.x]	449	mov eax, [mouse.state.pos.x]
455	add eax, [mouse.active_sys_window.delta.x]	450	add eax, [mouse.active_sys_window.delta.x]
456	sub eax, [mouse.active_sys_window.old_box.left]	451	sub eax, [mouse.active_sys_window.old_box.left]
457	mov [mouse.active_sys_window.new_box.width], eax	452	mov [mouse.active_sys_window.new_box.width], eax
458		453
459	mov eax, [mouse.active_sys_window.new_box.width]	454	mov eax, [mouse.active_sys_window.new_box.width]
460	cmp eax, 127	455	cmp eax, 127
461	jge @f	456	jge @f
462	mov eax, 127	457	mov eax, 127
463	mov [mouse.active_sys_window.new_box.width], eax	458	mov [mouse.active_sys_window.new_box.width], eax
464	@@:	459	@@:
465	add eax, [mouse.active_sys_window.new_box.left]	460	add eax, [mouse.active_sys_window.new_box.left]
466	cmp eax, [_display.width]	461	cmp eax, [_display.width]
467	jl .call_window_handler	462	jl .call_window_handler
468	sub eax, [_display.width]	463	sub eax, [_display.width]
469	neg eax	464	neg eax
470	add [mouse.active_sys_window.new_box.width], eax	465	add [mouse.active_sys_window.new_box.width], eax
471	mov ecx, [_display.width]	466	mov ecx, [_display.width]
472	cmp ecx, eax	467	cmp ecx, eax
473	jg .call_window_handler	468	jg .call_window_handler
474	mov [mouse.active_sys_window.new_box.width], ecx	469	mov [mouse.active_sys_window.new_box.width], ecx
475		470
476	.call_window_handler:	471	.call_window_handler:
477	mov eax, mouse.active_sys_window.old_box	472	mov eax, mouse.active_sys_window.old_box
478	mov ebx, mouse.active_sys_window.new_box	473	mov ebx, mouse.active_sys_window.new_box
479		474
480	push esi	475	push esi
481	mov esi, mouse.active_sys_window.old_box	476	mov esi, mouse.active_sys_window.old_box
482	mov edi, mouse.active_sys_window.new_box	477	mov edi, mouse.active_sys_window.new_box
483	mov ecx, sizeof.BOX / 4	478	mov ecx, sizeof.BOX / 4
484	repe	479	repe
485	cmpsd	480	cmpsd
486	pop esi	481	pop esi
487	je .exit	482	je .exit
488		483
489	test [fl_moving], 1	484	test [fl_moving], 1
490	jnz @f	485	jnz @f
491		486
492	mov [fl_moving], 1	487	mov [fl_moving], 1
493	push edi	488	push edi
494	mov edi, esi	489	mov edi, esi
495	shl edi, 5	490	shl edi, 5
496	add edi, WDATA.box + window_data	491	add edi, WDATA.box + window_data
497	call window._.draw_negative_box	492	call window._.draw_negative_box
498	pop edi	493	pop edi
499	@@:	494	@@:
500		495

Subversion Repositories Kolibri OS

(root)/kernel/trunk/gui/mouse.inc – Rev 5870 → 6585