WebSVN – Kolibri OS – Diff – /kernel/trunk/fs/ext.inc


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                              ;;
;; Copyright (C) KolibriOS team 2013-2016. All rights reserved. ;;
;;  Distributed under terms of the GNU General Public License.  ;;
;;                                                              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
$Revision: 6756 $
 
; EXT external functions
;   in:
; ebx -> parameter structure of sysfunc 70
; ebp -> EXTFS structure
; esi -> path string in UTF-8
;   out:
; eax, ebx = return values for sysfunc 70
iglobal
align 4
ext_user_functions:
        dd      ext_free
        dd      (ext_user_functions_end - ext_user_functions - 4) / 4
        dd      ext_ReadFile
        dd      ext_ReadFolder
        dd      ext_CreateFile
        dd      ext_WriteFile
        dd      ext_SetFileEnd
        dd      ext_GetFileInfo
        dd      ext_SetFileInfo
        dd      0
        dd      ext_Delete
        dd      ext_CreateFolder
ext_user_functions_end:
endg
 
struct DIRENTRY
inodeNumber     dd  ?
entryLength     dw  ?
nameLength      db  ?
fileType        db  ?
name            db  ?   ; rb [nameLength]
ends
 
struct INODE
accessMode      dw  ?
UID             dw  ?
fileSize        dd  ?
accessedTime    dd  ?
inodeModified   dd  ?
dataModified    dd  ?
deletedTime     dd  ?
GID             dw  ?
linksCount      dw  ?
sectorsUsed     dd  ?
featureFlags    dd  ?
reserved        dd  ?
blockNumbers    rd  12
addressBlock    dd  ?
doubleAddress   dd  ?
tripleAddress   dd  ?
generation      dd  ?
ACL             dd  ?
fileSizeHigh    dd  ?
ends
 
struct BGDESCR  ; block group descriptor
blockBitmap         dd  ?
inodeBitmap         dd  ?
inodeTable          dd  ?
blocksFree          dw  ?
inodesFree          dw  ?
directoriesCount    dw  ?
reserved            rb  14
ends
 
struct SUPERBLOCK
inodesTotal         dd  ?
blocksTotal         dd  ?
blocksReserved      dd  ?
blocksFree          dd  ?
inodesFree          dd  ?
firstGroupBlock     dd  ?
sectorsPerBlockLog  dd  ?   ; shift for 1024
fragmentSizeLog     dd  ?
blocksPerGroup      dd  ?
fragmentsPerGroup   dd  ?
inodesPerGroup      dd  ?
lastMountTime       dd  ?
lastWriteTime       dd  ?
mountCount          dw  ?
mountMax            dw  ?
magic               dw  ?
state               dw  ?
errorHandling       dw  ?
additionalVersion   dw  ?
lastCheck           dd  ?
checkInterval       dd  ?
creatorOS           dd  ?
dynamicVersionFlag  dd  ?
reservedUID         dw  ?
reservedGID         dw  ?
firstInode          dd  ?
inodeSize           dw  ?
thisBlockGroup      dw  ?
compatibleFlags     dd  ?
incompatibleFlags   dd  ?
RO_compatibleFlags  dd  ?
ends
 
; ext4 extent tree
struct NODEHEADER       ; tree node header
magic           dw  ?   ; 0xF30A
entriesFolow    dw  ?
entriesMax      dw  ?
currentDepth    dw  ?
generation      dd  ?
ends
 
struct INDEX    ; root/branch
fileBlock       dd  ?
nodeBlock       dd  ?
nodeBlockHigh   dw  ?
reserved        dw  ?
ends
 
struct EXTENT   ; leaf
fileBlock       dd  ?
blocksCount     dw  ?
fsBlockHigh     dw  ?
fsBlock         dd  ?
ends
 
ROOT_INODE = 2
PERMISSIONS = 110110110b
EXTENTS_USED = 80000h
TYPE_MASK = 0F000h
FLAG_FILE = 8000h
DIRECTORY = 4000h
DIR_FLAG_FILE = 1
DIR_DIRECTORY = 2
KOS_HIDDEN = 2
KOS_DIRECTORY = 10h
READ_ONLY = 1
 
; Implemented "incompatible" features:
; 2 = have file type in directory entry
; 40h = extents
; 200h = flexible block groups
INCOMPATIBLE_SUPPORT = 242h
; Read only support for "incompatible" features:
INCOMPATIBLE_READ_SUPPORT = 240h
 
; Implemented "read-only" features:
; 1 = sparse superblock
; 2 = 64-bit file size
READ_ONLY_SUPPORT = 3
 
struct EXTFS PARTITION
Lock                MUTEX
mountType           dd  ?
sectorsPerBlockLog  dd  ?   ; shift for 512
bytesPerBlock       dd  ?
sectorsPerBlock     dd  ?
dwordsPerBlock      dd  ?
dwordsPerBranch     dd  ?   ; dwordsPerBlock ^ 2
mainBlockBuffer     dd  ?
tempBlockBuffer     dd  ?
align0  rb  200h-EXTFS.align0
superblock          SUPERBLOCK
align1  rb  400h-EXTFS.align1
rootInodeBuffer     INODE
align2  rb  600h-EXTFS.align2
inodeBuffer         INODE
align3  rb  800h-EXTFS.align3
ends
 
; mount if it's a valid EXT partition
ext2_create_partition:
;   in:
; ebp -> PARTITION structure
; ebx -> boot sector
; ebx+512 -> buffer
;   out:
; eax -> EXTFS structure, 0 = not EXT
        push    ebx
        cmp     dword [esi+DISK.MediaInfo.SectorSize], 512
        jnz     .fail
        mov     eax, 2
        add     ebx, 512
        call    fs_read32_sys
        test    eax, eax
        jnz     .fail
        cmp     [ebx+SUPERBLOCK.magic], 0xEF53
        jne     .fail
        cmp     [ebx+SUPERBLOCK.state], 1
        ja      .fail
        test    [ebx+SUPERBLOCK.incompatibleFlags], not INCOMPATIBLE_SUPPORT
        jnz     .fail
        cmp     [ebx+SUPERBLOCK.sectorsPerBlockLog], 6  ; 64KB
        ja      .fail
        cmp     [ebx+SUPERBLOCK.inodeSize], 1024
        ja      .fail
        cmp     [ebx+SUPERBLOCK.blocksPerGroup], 0
        je      .fail
        cmp     [ebx+SUPERBLOCK.inodesPerGroup], 0
        je      .fail
        movi    eax, sizeof.EXTFS
        call    malloc
        test    eax, eax
        jz      .fail
        mov     ecx, dword [ebp+PARTITION.FirstSector]
        mov     dword [eax+EXTFS.FirstSector], ecx
        mov     ecx, dword [ebp+PARTITION.FirstSector+4]
        mov     dword [eax+EXTFS.FirstSector+4], ecx
        mov     ecx, dword [ebp+PARTITION.Length]
        mov     dword [eax+EXTFS.Length], ecx
        mov     ecx, dword [ebp+PARTITION.Length+4]
        mov     dword [eax+EXTFS.Length+4], ecx
        mov     ecx, [ebp+PARTITION.Disk]
        mov     [eax+EXTFS.Disk], ecx
        mov     [eax+EXTFS.FSUserFunctions], ext_user_functions
 
        push    ebp esi edi
        mov     ebp, eax
        lea     ecx, [eax+EXTFS.Lock]
        call    mutex_init
        mov     esi, ebx
        lea     edi, [ebp+EXTFS.superblock]
        mov     ecx, 512/4
        rep movsd   ; copy superblock
        mov     ecx, [ebx+SUPERBLOCK.sectorsPerBlockLog]
        inc     ecx
        mov     [ebp+EXTFS.sectorsPerBlockLog], ecx
        mov     eax, 1
        shl     eax, cl
        mov     [ebp+EXTFS.sectorsPerBlock], eax
        shl     eax, 9
        mov     [ebp+EXTFS.bytesPerBlock], eax
        shl     eax, 1
        push    eax
        shr     eax, 3
        mov     [ebp+EXTFS.dwordsPerBlock], eax
        mul     eax
        mov     [ebp+EXTFS.dwordsPerBranch], eax
        call    kernel_alloc
        test    eax, eax
        jz      .error
        mov     [ebp+EXTFS.mainBlockBuffer], eax
        add     eax, [ebp+EXTFS.bytesPerBlock]
        mov     [ebp+EXTFS.tempBlockBuffer], eax
        mov     [ebp+EXTFS.mountType], 0
        test    [ebx+SUPERBLOCK.RO_compatibleFlags], not READ_ONLY_SUPPORT
        jnz     .read_only
        test    [ebx+SUPERBLOCK.incompatibleFlags], INCOMPATIBLE_READ_SUPPORT
        jz      @f
.read_only:
        or      [ebp+EXTFS.mountType], READ_ONLY
@@: ; read root inode
        lea     ebx, [ebp+EXTFS.rootInodeBuffer]
        mov     eax, ROOT_INODE
        call    readInode
        test    eax, eax
        jnz     @f
        mov     eax, ebp
        pop     edi esi ebp ebx
        ret
 
@@:
        stdcall kernel_free, [ebp+EXTFS.mainBlockBuffer]
.error:
        mov     eax, ebp
        call    free
        pop     edi esi ebp
.fail:
        pop     ebx
        xor     eax, eax
        ret
 
; unmount EXT partition
ext_free:
; in: eax -> EXTFS structure
        push    eax
        stdcall kernel_free, [eax+EXTFS.mainBlockBuffer]
        pop     eax
        jmp     free
 
extfsWriteBlock:
        push    fs_write64_sys
        jmp     @f
; in: eax = block number, ebx -> buffer
extfsReadBlock:
        push    fs_read64_sys
@@:
        push    ecx edx
        mov     ecx, [ebp+EXTFS.sectorsPerBlock]
        mul     ecx
        call    dword[esp+8]
        pop     edx ecx
        add     esp, 4
        test    eax, eax
        jz      @f
        movi    eax, ERROR_DEVICE
        stc
@@:
        ret
 
extfsReadDescriptor:
; in: eax = block group number
; out: ebx -> block group descriptor
        push    ecx edx
        mov     edx, [ebp+EXTFS.superblock.firstGroupBlock]
        inc     edx
        mov     ecx, [ebp+EXTFS.sectorsPerBlockLog]
        shl     edx, cl
        shl     eax, 5
        mov     ecx, eax
 
 
        and     ecx, 511
 
 
 
        shr     eax, 9
        add     eax, edx
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        push    ecx
        call    fs_read32_sys
        pop     ecx
        add     ebx, ecx
        test    eax, eax
        jz      @f
        movi    eax, ERROR_DEVICE
        stc
@@:
        pop     edx ecx
        ret
 
 
 
 
 
 
 
extfsWriteDescriptor:
 
; in: eax = block group number
        push    ebx ecx edx
        mov     edx, [ebp+EXTFS.superblock.firstGroupBlock]
        inc     edx
        mov     ecx, [ebp+EXTFS.sectorsPerBlockLog]
        shl     edx, cl
        shr     eax, 9-5
        add     eax, edx
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    fs_write32_sys
        pop     edx ecx ebx
        ret
 
 
 
extfsExtentFree:
; in: eax = first block number, ecx = extent size
        push    ebx edx edi
        sub     eax, [ebp+EXTFS.superblock.firstGroupBlock]
        xor     edx, edx
        mov     ebx, [ebp+EXTFS.superblock.blocksPerGroup]
        div     ebx
        sub     ebx, edx
        sub     ebx, ecx
        jc      .ret
        push    edx eax
        call    extfsReadDescriptor
        jc      .fail2
        add     [ebx+BGDESCR.blocksFree], cx
        mov     edx, [ebx+BGDESCR.blockBitmap]
        pop     eax
        call    extfsWriteDescriptor
 
        mov     eax, edx
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .fail
        pop     eax
        push    ecx ebx edx
        add     [ebp+EXTFS.superblock.blocksFree], ecx
        mov     edi, eax
        shr     edi, 5
        shl     edi, 2
        add     edi, ebx
        and     eax, 31
        mov     edx, ecx
        mov     ecx, 32
        sub     ecx, eax
        sub     edx, ecx
        jnc     @f
        add     ecx, edx
        xor     edx, edx
@@:
        or      ebx, -1
        shl     ebx, cl
        not     ebx
        mov     ecx, eax
        shl     ebx, cl
        not     ebx
        and     [edi], ebx
        mov     ecx, edx
        jecxz   @f
        shr     ecx, 5
        add     edi, 4
        xor     eax, eax
        rep stosd
        and     edx, 31
        mov     ecx, edx
        jecxz   @f
 
 
        not     eax
 
        shl     eax, cl
        and     [edi], eax
 
@@:
        pop     eax ebx
        call    extfsWriteBlock
        pop     ecx
        mov     eax, ecx
        mul     [ebp+EXTFS.sectorsPerBlock]
        sub     [ebp+EXTFS.inodeBuffer.sectorsUsed], eax
.ret:
        pop     edi edx ebx
        xor     eax, eax
 
        ret
 
.fail2:
        pop     eax
.fail:
        pop     eax
        jmp     .ret
 
extfsInodeAlloc:
; in: eax = parent inode number
; out: ebx = allocated inode number
        push    ecx edx esi edi
        dec     eax
        xor     edx, edx
        div     [ebp+EXTFS.superblock.inodesPerGroup]
        push    eax eax
        mov     esi, .forward   ; search forward, then backward
.test_block_group:
        call    extfsReadDescriptor
        jc      .fail
        dec     [ebx+BGDESCR.inodesFree]
        js      .next
        mov     edx, [ebx+BGDESCR.inodeBitmap]
        mov     eax, [esp]
        call    extfsWriteDescriptor
 
        mov     eax, edx
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        mov     edi, ebx
        call    extfsReadBlock
        jc      .fail
        mov     ecx, [ebp+EXTFS.superblock.inodesPerGroup]
        or      eax, -1
        shr     ecx, 5
        repz scasd
        jz      .next
        sub     edi, 4
        mov     eax, [edi]
        not     eax
        bsf     eax, eax
        bts     [edi], eax
        sub     edi, [ebp+EXTFS.tempBlockBuffer]
        shl     edi, 3
        add     eax, edi
        mov     ecx, eax
        mov     eax, edx
        call    extfsWriteBlock
 
        pop     eax
        mul     [ebp+EXTFS.superblock.inodesPerGroup]
 
        dec     [ebp+EXTFS.superblock.inodesFree]
        lea     ebx, [eax+ecx+1]
 
        xor     eax, eax
.ret:
        pop     edi edi esi edx ecx
        ret
 
 
 
 
 
 
.next:
        jmp     esi
 
.forward:
        inc     dword[esp]
        mov     eax, [esp]
        mul     [ebp+EXTFS.superblock.inodesPerGroup]
        cmp     eax, [ebp+EXTFS.superblock.inodesTotal]
        ja      @f
        mov     eax, [esp]
        jmp     .test_block_group
 
@@:
        mov     eax, [esp+4]
        mov     [esp], eax
        mov     esi, .backward
.backward:
        sub     dword[esp], 1
 
        mov     eax, [esp]
        jnc     .test_block_group
        movi    eax, ERROR_DISK_FULL
.fail:
        pop     edi
        jmp     .ret
 
 
extfsExtentAlloc:
 
 
; in: eax = parent inode number, ecx = blocks max
 
; out: ebx = first block number, ecx = blocks allocated
        push    edx esi edi ecx
        dec     eax
        xor     edx, edx
        div     [ebp+EXTFS.superblock.inodesPerGroup]
        push    eax eax
.test_block_group:
        call    extfsReadDescriptor
        jc      .fail
        dec     [ebx+BGDESCR.blocksFree]
        js      .next
        mov     eax, [ebx+BGDESCR.blockBitmap]
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        mov     edx, eax
        mov     edi, ebx
        call    extfsReadBlock
        jc      .fail
        mov     ecx, [ebp+EXTFS.superblock.blocksPerGroup]
        shr     ecx, 5
        or      eax, -1
        repz scasd
        jz      .next
        mov     esi, edi
        sub     esi, 4
        push    edx ecx
        mov     eax, [esi]
        not     eax
        bsf     ecx, eax
        not     eax
        shr     eax, cl
        shl     eax, cl
 
        bsf     ebx, eax
        jnz     @f
        mov     ebx, 32
@@:
        sub     ebx, ecx
        mov     eax, [esp+16]
        cmp     ebx, eax
        jc      @f
        mov     ebx, eax
@@:
        xchg    ebx, ecx
        or      eax, -1
        shl     eax, cl
        not     eax
        xchg    ebx, ecx
        shl     eax, cl
        or      [esi], eax
        sub     esi, [ebp+EXTFS.tempBlockBuffer]
        shl     esi, 3
        add     esi, ecx
        mov     eax, [esp+16]
        sub     eax, ebx
        mov     [esp+16], ebx
        add     ebx, ecx
        pop     ecx
        test    eax, eax
        jz      .done
        cmp     ebx, 32
        jnz     .done
        jecxz   .done
        mov     ebx, eax
        shr     eax, 5
        inc     eax
        and     ebx, 31
        cmp     ecx, eax
        jnc     @f
        mov     eax, ecx
        mov     bl, 32
@@:
        mov     ecx, eax
        shl     eax, 5
        add     [esp+12], eax
        xor     eax, eax
        push    edi
        repz scasd
        jz      @f
        mov     eax, [edi-4]
        bsf     eax, eax
        xchg    eax, ebx
        test    ecx, ecx
        jnz     @f
        cmp     ebx, eax
        jc      @f
        mov     ebx, eax
@@:
        inc     ecx
        shl     ecx, 5
        sub     ecx, ebx
        sub     [esp+16], ecx
        mov     ecx, edi
        pop     edi
        sub     ecx, edi
        shr     ecx, 2
        dec     ecx
        or      eax, -1
        rep stosd
        mov     ecx, ebx
        shl     eax, cl
        not     eax
        or      [edi], eax
.done:
        pop     eax
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsWriteBlock
 
        mov     eax, [esp]
        call    extfsReadDescriptor
        jc      .fail
        mov     ecx, [esp+8]
        sub     [ebx+BGDESCR.blocksFree], cx
        jc      .fail
        sub     [ebp+EXTFS.superblock.blocksFree], ecx
        mov     eax, [esp]
        call    extfsWriteDescriptor
 
        pop     eax ebx
        mul     [ebp+EXTFS.superblock.blocksPerGroup]
        mov     ebx, eax
        add     ebx, esi
        add     ebx, [ebp+EXTFS.superblock.firstGroupBlock]
        pop     ecx
        mov     eax, ecx
        mul     [ebp+EXTFS.sectorsPerBlock]
        add     [ebp+EXTFS.inodeBuffer.sectorsUsed], eax
        xor     eax, eax
.ret:
        pop     edi esi edx
        ret
 
 
 
 
 
 
 
.next:      ; search forward, then backward
        pop     eax
        cmp     eax, [esp]
        jc      .backward
        inc     eax
        push    eax
        mul     [ebp+EXTFS.superblock.blocksPerGroup]
        cmp     eax, [ebp+EXTFS.superblock.blocksTotal]
        ja      @f
        mov     eax, [esp]
        jmp     .test_block_group
 
@@:
        pop     eax eax
        push    eax
.backward:
        dec     eax
        push    eax
        jns     .test_block_group
 
        movi    eax, ERROR_DISK_FULL
.fail:
        add     esp, 12
        xor     ecx, ecx
        stc
        jmp     .ret
 
extfsGetExtent:
; in: ecx = starting file block
; out: eax = first block number, ecx = extent size
        push    ebx edx esi
        lea     esi, [ebp+EXTFS.inodeBuffer]
        test    [esi+INODE.featureFlags], EXTENTS_USED
        jz      .listTreeSearch
        add     esi, INODE.blockNumbers
.extentTreeSearch:
        cmp     word [esi+NODEHEADER.magic], 0xF30A
        jne     .fail
        movzx   ebx, [esi+NODEHEADER.entriesFolow]
        add     esi, sizeof.NODEHEADER
        test    ebx, ebx
        jz      .noBlock
        cmp     word [esi-sizeof.NODEHEADER+NODEHEADER.currentDepth], 0
        je      .leaf_block
        dec     ebx
        jz      .end_search_index
@@:
        cmp     ecx, [esi+sizeof.INDEX+INDEX.fileBlock]
        jb      .end_search_index
        add     esi, sizeof.INDEX
        dec     ebx
        jnz     @b
.end_search_index:
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        mov     eax, [esi+INDEX.nodeBlock]
        call    extfsReadBlock
        jc      .fail2
        mov     esi, ebx
        jmp     .extentTreeSearch
 
.fail:
        movi    eax, ERROR_FS_FAIL
        jmp     .fail2
 
.leaf_block:
        movzx   edx, [esi+EXTENT.blocksCount]
        add     edx, [esi+EXTENT.fileBlock]
        sub     edx, ecx
        ja      .end_search_extent
        add     esi, sizeof.EXTENT
        dec     ebx
        jnz     .leaf_block
.noBlock:
        movi    eax, ERROR_END_OF_FILE
.fail2:
        pop     esi edx ebx
        stc
        ret
 
.end_search_extent:
        sub     ecx, [esi+EXTENT.fileBlock]
        jc      .fail
        add     ecx, [esi+EXTENT.fsBlock]
        mov     eax, ecx
        mov     ecx, edx
        pop     esi edx ebx
        ret
 
.listTreeSearch:
        cmp     ecx, 12
        jb      .get_direct_block
        sub     ecx, 12
        cmp     ecx, [ebp+EXTFS.dwordsPerBlock]
        jb      .get_indirect_block
        sub     ecx, [ebp+EXTFS.dwordsPerBlock]
        cmp     ecx, [ebp+EXTFS.dwordsPerBranch]
        jb      .get_double_indirect_block
; triply-indirect blocks
        sub     ecx, [ebp+EXTFS.dwordsPerBranch]
        mov     eax, [esi+INODE.tripleAddress]
        test    eax, eax
        jz      .noBlock
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .fail2
        xor     edx, edx
        mov     eax, ecx
        div     [ebp+EXTFS.dwordsPerBranch]
; eax = number in triply-indirect block, edx = number in branch
        mov     eax, [ebx+eax*4]
        test    eax, eax
        jz      .noBlock
        call    extfsReadBlock
        jc      .fail2
        mov     eax, edx
        jmp     @f
 
.get_direct_block:
        mov     edx, ecx
        mov     cl, 12
        lea     ebx, [esi+INODE.blockNumbers]
        jmp     .calculateExtent
 
.get_indirect_block:
        mov     eax, [esi+INODE.addressBlock]
        test    eax, eax
        jz      .noBlock
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .fail2
        mov     edx, ecx
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        jmp     .calculateExtent
 
.get_double_indirect_block:
        mov     eax, [esi+INODE.doubleAddress]
        test    eax, eax
        jz      .noBlock
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .fail2
        mov     eax, ecx
@@:
        xor     edx, edx
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        div     ecx
; eax = number in doubly-indirect block, edx = number in indirect block
        mov     eax, [ebx+eax*4]
        test    eax, eax
        jz      .noBlock
        call    extfsReadBlock
        jc      .fail2
.calculateExtent:
        lea     esi, [ebx+edx*4]
        lodsd
        test    eax, eax
        jz      .noBlock
        mov     ebx, eax
        sub     ecx, edx
        xor     edx, edx
@@:
        inc     edx
        dec     ecx
        jz      @f
        lodsd
        sub     eax, ebx
        sub     eax, edx
        jz      @b
@@:
        mov     eax, ebx
        mov     ecx, edx
        pop     esi edx ebx
        clc
        ret
 
getInodeLocation:
; in: eax = inode number
; out: eax = inode sector, edx = offset in sector
        dec     eax
        xor     edx, edx
        div     [ebp+EXTFS.superblock.inodesPerGroup]
 
 
 
 
 
 
 
        call    extfsReadDescriptor
        jc      @f
 
        mov     ebx, [ebx+BGDESCR.inodeTable]
 
        mov     ecx, [ebp+EXTFS.sectorsPerBlockLog]
        shl     ebx, cl
        mov     eax, edx
        mul     [ebp+EXTFS.superblock.inodeSize]
        mov     edx, eax
        shr     eax, 9
        and     edx, 511
        add     eax, ebx
 
@@:
        ret
 
writeInode:
; in: eax = inode number, ebx -> inode data
        push    edx edi esi ecx ebx eax
        mov     edi, ebx
        call    fsGetTime
        add     eax, 978307200
        mov     [edi+INODE.inodeModified], eax
        pop     eax
        call    getInodeLocation
        jc      .ret
 
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        mov     ecx, eax
        call    fs_read32_sys
        test    eax, eax
        jnz     @f
        mov     eax, ecx
        mov     esi, edi
        movzx   ecx, [ebp+EXTFS.superblock.inodeSize]
        mov     edi, edx
        add     edi, ebx
        rep movsb
        call    fs_write32_sys
.ret:
        pop     ebx ecx esi edi edx
        ret
 
@@:
        movi    eax, ERROR_DEVICE
        stc
        jmp     .ret
 
readInode:
; in: eax = inode number, ebx -> inode buffer
        push    edx edi esi ecx ebx
        mov     edi, ebx
        call    getInodeLocation
        jc      @f
 
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    fs_read32_sys
        test    eax, eax
        jnz     @b
        movzx   ecx, [ebp+EXTFS.superblock.inodeSize]
        mov     esi, edx
        add     esi, ebx
        rep movsb
        xor     eax, eax
@@:
        pop     ebx ecx esi edi edx
        ret
 
indirectBlockAlloc:
;   in:
; edi -> indirect block number
; ebx = starting extent block
; ecx = extent size
; edx = starting file block
        mov     eax, [edi]
        test    eax, eax
        jz      .newBlock
        push    edi ebx ecx
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .err2
        lea     edi, [ebx+edx*4]
        test    edx, edx
        jz      @f
        cmp     dword[edi-4], 0
        jnz     @f
        pop     ecx ebx edi
.err:
        mov     al, ERROR_FS_FAIL
        stc
        ret
 
.err2:
        pop     ecx ebx edi
        ret
 
.newBlock:
        test    edx, edx
        jnz     .err
        mov     [edi], ebx
        inc     ebx
        dec     ecx
        push    edi ebx ecx
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        mov     edi, [ebp+EXTFS.tempBlockBuffer]
        push    edi
        rep stosd
        pop     edi
@@:
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        sub     ecx, edx
        pop     ebx eax
        sub     ebx, ecx
        jnc     @f
        add     ecx, ebx
        xor     ebx, ebx
@@:
        jecxz   .done
        add     edx, ecx
@@:
        stosd
        inc     eax
        loop    @b
.done:
        pop     edi
        push    eax ebx
        mov     eax, [edi]
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsWriteBlock
        pop     ecx ebx
        ret
 
doublyIndirectBlockAlloc:
;   in:
; edi -> indirect block number
; edx = starting file block
; ebx = starting extent block
; ecx = extent size
; [esp+4] = rest of size
; [esp+8] = parent inode number
        mov     eax, [edi]
        test    eax, eax
        jz      .newBlock
        push    edi ecx ebx
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    extfsReadBlock
        jc      .err2
        mov     eax, edx
        xor     edx, edx
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        div     ecx
        lea     edi, [ebx+eax*4]
        pop     ebx
        test    eax, eax
        jz      @f
        cmp     dword[edi-4], 0
        jnz     @f
        pop     ecx edi
.err:
        mov     al, ERROR_FS_FAIL
        stc
        ret
 
.err2:
        pop     ebx ecx edi
        ret
 
.newBlock:
        test    edx, edx
        jnz     .err
        mov     [edi], ebx
        inc     ebx
        dec     ecx
        inc     dword[esp+4]
        push    edi ecx
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        mov     edi, [ebp+EXTFS.mainBlockBuffer]
        push    ecx edi
        rep stosd
        pop     edi ecx
@@:
        sub     ecx, eax
        xchg    [esp], ecx
.loop:
        cmp     dword[edi], 0
        jnz     @f
        inc     dword[esp+12]
@@:
        jecxz   .extentAlloc
        call    indirectBlockAlloc
        jc      .end
        cmp     edx, [ebp+EXTFS.dwordsPerBlock]
        jnz     @b
        add     edi, 4
        xor     edx, edx
        dec     dword[esp]
        jnz     .loop
.end:
        pop     edi edi
        push    ebx eax
        mov     eax, [edi]
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    extfsWriteBlock
        pop     ebx
        add     eax, ebx
        xor     ebx, ebx
        cmp     ebx, eax
        pop     ebx
        ret
 
.extentAlloc:
        mov     ecx, [esp+12]
        xor     eax, eax
        jecxz   .end
        mov     eax, [esp+16]
        call    extfsExtentAlloc
        jc      .end
        sub     [esp+12], ecx
 
 
 
        jmp     @b
 
extfsExtendFile:
;   in:
; [ebp+EXTFS.inodeBuffer] = inode
; eax = inode number
; ecx = new size
        push    ebx ecx edx esi edi eax
        lea     esi, [ebp+EXTFS.inodeBuffer]
        mov     eax, ecx
        mov     edx, [esi+INODE.fileSize]
        cmp     edx, eax
        jnc     .ret
        mov     [esi+INODE.fileSize], eax
        mov     ecx, [ebp+EXTFS.sectorsPerBlockLog]
        add     ecx, 9
        dec     eax
        shr     eax, cl
        inc     eax
        sub     edx, 1
        jc      @f
        shr     edx, cl
@@:
        inc     edx
        sub     eax, edx
        jz      .ret
        push    eax
@@:
        mov     ecx, [esp]
        mov     eax, [esp+4]
        test    ecx, ecx
        jz      .done
        call    extfsExtentAlloc
        jc      .errDone
        sub     [esp], ecx
 
 
 
        cmp     edx, 12
        jc      .directBlocks
        sub     edx, 12
        cmp     edx, [ebp+EXTFS.dwordsPerBlock]
        jc      .indirectBlocks
        sub     edx, [ebp+EXTFS.dwordsPerBlock]
        cmp     edx, [ebp+EXTFS.dwordsPerBranch]
        jc      .doublyIndirectBlock
        sub     edx, [ebp+EXTFS.dwordsPerBranch]
        jmp     .triplyIndirectBlock
 
.newExtent:
        jmp     @b
 
.directBlocks:
        lea     edi, [esi+INODE.blockNumbers+edx*4]
        test    edx, edx
        jz      @f
        cmp     dword[edi-4], 0
        jz      .errDone
@@:
        mov     eax, ebx
        mov     ebx, ecx
        mov     ecx, 12
        sub     ecx, edx
        sub     ebx, ecx
        jnc     @f
        add     ecx, ebx
        xor     ebx, ebx
@@:
        add     edx, ecx
@@:
        stosd
        inc     eax
        loop    @b
        mov     ecx, ebx
        mov     ebx, eax
        jecxz   .newExtent
        xor     edx, edx
.indirectBlocks:
        lea     edi, [esi+INODE.addressBlock]
        cmp     dword[edi], 0
        jnz     @f
        inc     dword[esp]
@@:
        call    indirectBlockAlloc
        jc      .errDone
        add     edx, 12
        jecxz   .newExtent
        xor     edx, edx
.doublyIndirectBlock:
        lea     edi, [esi+INODE.doubleAddress]
        call    doublyIndirectBlockAlloc
        jc      .errDone
        mov     edx, [ebp+EXTFS.dwordsPerBranch]
        add     edx, [ebp+EXTFS.dwordsPerBlock]
        add     edx, 12
        jecxz   .newExtent
        xor     edx, edx
.triplyIndirectBlock:
        push    ecx ebx edx
        stdcall kernel_alloc, [ebp+EXTFS.bytesPerBlock]
        pop     edx
        mov     esi, eax
        mov     eax, [ebp+EXTFS.inodeBuffer.tripleAddress]
        test    eax, eax
        jz      .newBlock
        mov     ebx, esi
        call    extfsReadBlock
        pop     ebx ecx
        jc      .errFree
        mov     eax, edx
        xor     edx, edx
        div     [ebp+EXTFS.dwordsPerBranch]
        lea     edi, [esi+eax*4]
        test    eax, eax
        jz      @f
        cmp     dword[edi-4], 0
        jnz     @f
        mov     al, ERROR_FS_FAIL
.errFree:
        push    ecx eax
        stdcall kernel_free, esi
        pop     eax ecx
.errDone:
        imul    ecx, [ebp+EXTFS.sectorsPerBlock]
        sub     [ebp+EXTFS.inodeBuffer.sectorsUsed], ecx
        pop     ebx
        imul    ebx, [ebp+EXTFS.sectorsPerBlock]
        add     ebx, ecx
        shl     ebx, 9
        sub     [ebp+EXTFS.inodeBuffer.fileSize], ebx
        stc
        jmp     .ret
 
.newBlock:
        pop     ebx ecx
        mov     al, ERROR_FS_FAIL
        test    edx, edx
        jnz     .errFree
        mov     [ebp+EXTFS.inodeBuffer.tripleAddress], ebx
        inc     ebx
        dec     ecx
        inc     dword[esp]
        push    ecx
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        mov     edi, esi
        xor     eax, eax
        rep stosd
        mov     edi, esi
        pop     ecx
@@:
        jecxz   .extentAlloc
        call    doublyIndirectBlockAlloc
        jc      .errSave
        add     edi, 4
        jmp     @b
 
.extentAlloc:
        mov     ecx, [esp]
        mov     eax, [esp+4]
        jecxz   @f
        call    extfsExtentAlloc
        jc      .errSave
        sub     [esp], ecx
 
 
 
        jmp     @b
 
@@:
        mov     eax, [ebp+EXTFS.inodeBuffer.tripleAddress]
        mov     ebx, esi
        call    extfsWriteBlock
        stdcall kernel_free, esi
.done:
        xor     eax, eax
        pop     edi
.ret:
        pop     edi edi esi edx ecx ebx
        ret
 
.errSave:
        push    eax
        mov     eax, [ebp+EXTFS.inodeBuffer.tripleAddress]
        mov     ebx, esi
        call    extfsWriteBlock
        pop     eax
        jmp     .errFree
 
freeIndirectBlock:
; in: edi -> indirect block number, edx = starting block
; out: edi = edi+4, eax=-1 -> done, eax=0 -> end
        pushd   ecx 0 edi edx
        mov     eax, [edi]
        test    eax, eax
        jz      .ret
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    extfsReadBlock
        jc      .ret
        lea     edi, [ebx+edx*4]
        neg     edx
        add     edx, [ebp+EXTFS.dwordsPerBlock]
.freeExtent:
        mov     ebx, [edi]
        test    ebx, ebx
        jz      .end
        xor     eax, eax
        xor     ecx, ecx
@@:
 
 
 
 
        stosd
        inc     ecx
        dec     edx
        jz      @f
        mov     eax, [edi]
        sub     eax, ebx
        sub     eax, ecx
        jz      @b
@@:
        mov     eax, ebx
        call    extfsExtentFree
        test    edx, edx
        jnz     .freeExtent
        dec     dword[esp+8]
.end:
        pop     edx edi
        mov     eax, [edi]
        test    edx, edx
        jnz     @f
        xor     ecx, ecx
        inc     ecx
        call    extfsExtentFree
        stosd
        jmp     .done
 
@@:
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    extfsWriteBlock
        add     edi, 4
.done:
        pop     eax ecx
        xor     edx, edx
        ret
 
.ret:
        pop     edi edi edx ecx
        ret
 
freeDoublyIndirectBlock:
; in: edi -> doubly-indirect block number, edx = starting block
; out: edi = edi+4, eax=-1 -> done, eax=0 -> end
        mov     eax, [edi]
        test    eax, eax
        jz      .ret
        push    ecx eax edx
        stdcall kernel_alloc, [ebp+EXTFS.bytesPerBlock]
        mov     ebx, eax
        pop     edx eax
        pushd   0 ebx edx
        call    extfsReadBlock
        jc      .err
        mov     eax, edx
        xor     edx, edx
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        div     ecx
        sub     ecx, eax
        push    edi
        lea     edi, [ebx+eax*4]
@@:
        call    freeIndirectBlock
        test    eax, eax
        jz      .end
        dec     ecx
        jnz     @b
        dec     dword[esp+12]
.end:
        pop     edi edx
        mov     eax, [edi]
        test    edx, edx
        jnz     @f
        xor     ecx, ecx
        inc     ecx
        call    extfsExtentFree
        stosd
        jmp     .done
 
@@:
        mov     ebx, [esp]
        call    extfsWriteBlock
        add     edi, 4
        jmp     .done
 
.err:
        mov     [esp+8], eax
        pop     eax
.done:
        call    kernel_free
        pop     eax ecx
.ret:
        xor     edx, edx
        ret
 
extfsTruncateFile:
 
; in: ecx = new size, [ebp+EXTFS.inodeBuffer] = inode
 
        push    ebx ecx edx esi edi
        lea     esi, [ebp+EXTFS.inodeBuffer]
        cmp     ecx, [esi+INODE.fileSize]
        jnc     .ret
        mov     [esi+INODE.fileSize], ecx
        mov     edx, ecx
        jecxz   .directBlocks
        dec     edx
        mov     ecx, [ebp+EXTFS.sectorsPerBlockLog]
        add     ecx, 9
        shr     edx, cl
        inc     edx
        cmp     edx, 12
        jc      .directBlocks
        sub     edx, 12
        cmp     edx, [ebp+EXTFS.dwordsPerBlock]
        jc      .indirectBlocks
        sub     edx, [ebp+EXTFS.dwordsPerBlock]
        cmp     edx, [ebp+EXTFS.dwordsPerBranch]
        jc      .doublyIndirectBlock
        sub     edx, [ebp+EXTFS.dwordsPerBranch]
        jmp     .triplyIndirectBlock
 
.directBlocks:
        lea     edi, [esi+INODE.blockNumbers+edx*4]
        neg     edx
        add     edx, 12
        xor     ecx, ecx
        inc     ecx
@@:
        mov     eax, [edi]
        test    eax, eax
        jz      .ret
        call    extfsExtentFree
        stosd
        dec     edx
        jnz     @b
.indirectBlocks:
        lea     edi, [esi+INODE.addressBlock]
        call    freeIndirectBlock
        test    eax, eax
        jz      .ret
.doublyIndirectBlock:
        lea     edi, [esi+INODE.doubleAddress]
        call    freeDoublyIndirectBlock
        test    eax, eax
        jz      .ret
.triplyIndirectBlock:
        mov     eax, [esi+INODE.tripleAddress]
        test    eax, eax
        jz      .ret
        push    eax edx
        stdcall kernel_alloc, [ebp+EXTFS.bytesPerBlock]
        mov     ebx, eax
        pop     edx eax
        push    ebx eax edx
        call    extfsReadBlock
        jc      .err
        mov     eax, edx
        xor     edx, edx
        div     [ebp+EXTFS.dwordsPerBranch]
        mov     ecx, [ebp+EXTFS.dwordsPerBlock]
        sub     ecx, eax
        lea     edi, [ebx+eax*4]
@@:
        call    freeDoublyIndirectBlock
        test    eax, eax
        jz      .end
        dec     ecx
        jnz     @b
.end:
        pop     edx eax
        test    edx, edx
        jnz     @f
        xor     ecx, ecx
        inc     ecx
        call    extfsExtentFree
        mov     [esi+INODE.tripleAddress], eax
        jmp     .done
 
@@:
        mov     ebx, [esp]
        call    extfsWriteBlock
        jmp     .done
 
.err:
        pop     eax eax
.done:
        call    kernel_free
.ret:
        pop     edi esi edx ecx ebx
        ret
 
linkInode:
;   in:
; eax = inode on which to link
; ebx = inode to link
; esi -> name in UTF-8
;  dl = file type
        push    esi edi ebx ecx eax edx
        call    strlen
        add     ecx, 8  ; directory entry size
        push    esi ebx ecx
        xor     ecx, ecx
        lea     esi, [ebp+EXTFS.inodeBuffer]
        mov     ebx, esi
        call    readInode
        jc      .error_inode_read
        mov     ecx, [ebp+EXTFS.sectorsPerBlockLog]
        add     ecx, 9
        mov     eax, [esi+INODE.fileSize]
        shr     eax, cl
        xor     ecx, ecx
.searchBlock:
        push    eax     ; blocks total
        push    ecx     ; current file block number
        cmp     eax, ecx
        jz      .alloc_block
        call    extfsGetExtent
        jc      .error_get_inode_block
        push    eax
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .error_block_read
        mov     ecx, [esp+12]
        mov     edi, [ebp+EXTFS.tempBlockBuffer]
        mov     edx, edi
        add     edx, [ebp+EXTFS.bytesPerBlock]
.searchSpace:
        movzx   eax, [edi+DIRENTRY.entryLength]
        test    eax, eax
        jz      .zeroLength
        cmp     [edi+DIRENTRY.inodeNumber], 0
        je      .unusedEntry
        movzx   ebx, [edi+DIRENTRY.nameLength]
        add     ebx, 8+3
        and     ebx, -4
        sub     eax, ebx
        add     edi, ebx
        cmp     eax, ecx
        jb      .nextEntry
        sub     edi, ebx
        mov     [edi+DIRENTRY.entryLength], bx
        add     edi, ebx
        mov     [edi+DIRENTRY.entryLength], ax
        jmp     .found
 
.unusedEntry:
        cmp     eax, ecx
        jge     .found
.nextEntry:
        add     edi, eax
        cmp     edi, edx
        jb      .searchSpace
        pop     ecx ecx eax
        inc     ecx
        jmp     .searchBlock
 
.zeroLength:
        mov     [edi+DIRENTRY.entryLength], cx
        mov     eax, edx
        sub     eax, edi
        cmp     eax, ecx
        jge     .found
        mov     [edi+DIRENTRY.inodeNumber], 0
        mov     [edi+DIRENTRY.entryLength], ax
; this block wasn't linking to the next one, so write it, and use the next block
        pop     eax
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsWriteBlock
 
        pop     ecx
        inc     ecx
        cmp     ecx, [esp]
        push    ecx
        jnz     @f
.alloc_block:
        mov     ecx, [esi+INODE.fileSize]
        add     ecx, [ebp+EXTFS.bytesPerBlock]
        mov     eax, [esp+24]
        call    extfsExtendFile
        jc      .error_get_inode_block
        mov     eax, [esp+24]
        mov     ebx, esi
        call    writeInode
        jc      .error_get_inode_block
        mov     ecx, [esp]
@@:
        call    extfsGetExtent
        jc      .error_get_inode_block
        push    eax
        mov     edi, [ebp+EXTFS.tempBlockBuffer]
        mov     eax, [ebp+EXTFS.bytesPerBlock]
        mov     [edi+DIRENTRY.entryLength], ax
.found:
        pop     edx ecx ecx ecx ebx esi
        push    ebx
        mov     [edi+DIRENTRY.inodeNumber], ebx
        sub     ecx, 8
        mov     word [edi+DIRENTRY.nameLength], cx
        cmp     [ebp+EXTFS.superblock.dynamicVersionFlag], 0
        je      .name
        mov     eax, [esp+4]
        mov     [edi+DIRENTRY.fileType], al
.name:
        add     edi, 8
        rep movsb
        mov     eax, edx
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsWriteBlock
 
        mov     eax, [esp]
        lea     ebx, [ebp+EXTFS.inodeBuffer]
        call    readInode
        jc      .error_block_write
        pop     eax
        inc     [ebx+INODE.linksCount]
        call    writeInode
        jc      @f
        xor     eax, eax
@@:
        pop     edx ecx ecx ebx edi esi
        ret
 
.error_block_read:
        pop     ebx
.error_get_inode_block:
        pop     ebx ebx
.error_inode_read:
        pop     ebx ebx
.error_block_write:
        pop     ebx
        jmp     @b
 
unlinkInode:
 
; in: eax = inode from which to unlink, ebx = inode to unlink
 
 
; out: eax = current number of links to inode, -1 = error
        push    edx ebx
        lea     ebx, [ebp+EXTFS.inodeBuffer]
        call    readInode
        jc      .fail
        push    eax
.loop:
        mov     ecx, [esp]
        call    extfsGetExtent
        jc      .fail_loop
        mov     edi, eax
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .fail_loop
.first_dir_entry:   ; edi -> block
        mov     eax, [esp+4]
        cmp     [ebx+DIRENTRY.inodeNumber], eax
        jne     @f
        mov     [ebx+DIRENTRY.inodeNumber], 0
        mov     word [ebx+DIRENTRY.nameLength], 0   ; fileType = 0
        jmp     .write_block
 
@@:
        mov     edx, ebx
        add     edx, [ebp+EXTFS.bytesPerBlock]
        push    edx
        mov     edx, ebx
        movzx   ecx, [ebx+DIRENTRY.entryLength]
        add     ebx, ecx
.dir_entry:
        cmp     [ebx+DIRENTRY.inodeNumber], eax
        jne     @f
        mov     cx, [ebx+DIRENTRY.entryLength]
        add     [edx+DIRENTRY.entryLength], cx
        pop     eax
        jmp     .write_block
 
@@:
        mov     edx, ebx
        movzx   ecx, [ebx+DIRENTRY.entryLength]
        test    ecx, ecx
        jz      .fail_inode
        add     ebx, ecx
        cmp     ebx, [esp]
        jb      .dir_entry
        pop     ecx
        inc     dword[esp]
        jmp     .loop
 
.fail_inode:
        pop     eax
.fail_loop:
        pop     eax
.fail:
        or      eax, -1
        jmp     @f
 
.write_block:
        pop     eax
        mov     eax, edi
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsWriteBlock
 
        mov     eax, [esp]
        lea     ebx, [ebp+EXTFS.inodeBuffer]
        call    readInode
        jc      .fail
        dec     word [ebx+INODE.linksCount]
        mov     eax, [esp]
        call    writeInode
        jc      .fail
        movzx   eax, word [ebx+INODE.linksCount]
@@:
        pop     ebx edx
        ret
 
findInode:
; in: esi -> path string in UTF-8
;   out:
; edi -> file name in UTF-8
; esi = last inode number
; [ebp+EXTFS.inodeBuffer] = last inode
; ecx = parent inode number
; CF=1 -> file not found, edi=0 -> error
        push    esi
        lea     esi, [ebp+EXTFS.rootInodeBuffer]
        lea     edi, [ebp+EXTFS.inodeBuffer]
        movzx   ecx, [ebp+EXTFS.superblock.inodeSize]
        mov     edx, esi
        rep movsb
        pop     esi
        pushd   0 ROOT_INODE
        mov     edi, esi
        cmp     [edx+INODE.fileSize], 0
        jz      .not_found
        cmp     byte [esi], 0
        jnz     .next_path_part
        xor     eax, eax
        pop     esi ecx
        ret
 
@@:
        pop     esi esi
.error:
        pop     esi ecx
        xor     edi, edi
        stc
        ret
 
.next_path_part:
        push    [edx+INODE.fileSize]
        xor     ecx, ecx
.folder_block_cycle:
        push    ecx
        call    extfsGetExtent
        jc      @b
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    extfsReadBlock
        jc      @b
        push    esi edx
        mov     edx, ebx
        add     edx, [ebp+EXTFS.bytesPerBlock]
.start_rec:
        cmp     [ebx+DIRENTRY.inodeNumber], 0
        jz      .next_rec
        push    esi
        movzx   ecx, [ebx+DIRENTRY.nameLength]
        lea     edi, [ebx+DIRENTRY.name]
        repz cmpsb
        jz      .test_find
@@: ; doesn't match
        pop     esi
.next_rec:
        movzx   eax, [ebx+DIRENTRY.entryLength]
        add     ebx, eax
        cmp     ebx, edx
        jb      .start_rec
        push    eax
        jmp     @f
 
.test_find:
        cmp     byte [esi], 0
        je      @f
        cmp     byte [esi], '/'
        jne     @b
        inc     esi
@@:
        pop     edx edx edi ecx eax
; ebx -> matched directory entry, esi -> name without parent, or not changed
        cmp     edi, esi
        jnz     @f
        sub     eax, [ebp+EXTFS.bytesPerBlock]
        jle     .not_found
        push    eax
        inc     ecx
        jmp     .folder_block_cycle
 
@@:
        pop     eax
        mov     [esp], eax
        mov     eax, [ebx+DIRENTRY.inodeNumber]
        lea     ebx, [ebp+EXTFS.inodeBuffer]
        push    eax
        call    readInode
        jc      .error
        cmp     byte [esi], 0
        je      .ret
        mov     edx, ebx
        movzx   eax, [ebx+INODE.accessMode]
        and     eax, TYPE_MASK
        cmp     eax, DIRECTORY
        jz      .next_path_part
        xor     edi, edi    ; path folder is a file
        jmp     @f
 
.not_found:
        mov     esi, edi
        call    strlen
        mov     al, '/'
        repnz scasb
        mov     edi, esi
        jnz     @f
        xor     edi, edi    ; path folder not found
@@:
        movi    eax, ERROR_FILE_NOT_FOUND
        stc
.ret:
        pop     esi ecx
        ret
 
writeSuperblock:
        push    ebx
        mov     eax, 2
        lea     ebx, [ebp+EXTFS.superblock]
        call    fs_write32_sys
        pop     ebx
        ret
 
extfsWritingInit:
        movi    eax, ERROR_ACCESS_DENIED
        cmp     byte [esi], 0
        jz      @f
        movi    eax, ERROR_UNSUPPORTED_FS
        test    [ebp+EXTFS.mountType], READ_ONLY
        jnz     @f
ext_lock:
        lea     ecx, [ebp+EXTFS.Lock]
        jmp     mutex_lock
 
@@:
        pop     ebx
        xor     ebx, ebx
        ret
 
ext_unlock:
        lea     ecx, [ebp+EXTFS.Lock]
        jmp     mutex_unlock
 
;----------------------------------------------------------------
ext_ReadFolder:
        call    ext_lock
        cmp     byte [esi], 0
        jz      .root_folder
        push    ebx
        call    findInode
        pop     ebx
        jc      .error_ret
        lea     esi, [ebp+EXTFS.inodeBuffer]
        test    [esi+INODE.accessMode], FLAG_FILE
        jnz     .error_not_found
        jmp     @f
 
.root_folder:
        lea     esi, [ebp+EXTFS.rootInodeBuffer]
        lea     edi, [ebp+EXTFS.inodeBuffer]
        movzx   ecx, [ebp+EXTFS.superblock.inodeSize]
        shr     ecx, 2
        push    edi
        rep movsd
        pop     esi
@@:
        cmp     [esi+INODE.fileSize], 0
        je      .error_empty_dir
        mov     edx, [ebx+16]
        push    edx         ; [edi+28] result buffer
        push    0           ; [edi+24] end of the current block in folder
        pushd   [ebx+12]    ; [edi+20] files to read
        pushd   [ebx+4]     ; [edi+16] first wanted file
        pushd   [ebx+8]     ; [edi+12] flags
        push    0           ; [edi+8]  read files
        push    0           ; [edi+4]  files in folder
        push    0           ; [edi]    current block index
        mov     edi, esp    ; edi -> local variables
        add     edx, 32
        xor     ecx, ecx
        call    extfsGetExtent
        jc      .error_get_block
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    extfsReadBlock
        jc      .error_get_block
        mov     eax, ebx
        add     eax, [ebp+EXTFS.bytesPerBlock]
        mov     [edi+24], eax
        mov     ecx, [edi+16]
.find_wanted_start:
        jecxz   .find_wanted_end
.find_wanted_cycle:
        cmp     [ebx+DIRENTRY.inodeNumber], 0
        jz      @f
        inc     dword [edi+4]
        dec     ecx
@@:
        movzx   eax, [ebx+DIRENTRY.entryLength]
        cmp     eax, 12     ; minimum entry length
        jb      .error_bad_len
        test    eax, 3      ; length must be aligned
        jnz     .error_bad_len
        sub     [esi+INODE.fileSize], eax
        add     ebx, eax
        cmp     ebx, [edi+24]
        jb      .find_wanted_start
        push    .find_wanted_start
.end_block: ; read next block
        cmp     [esi+INODE.fileSize], 0
        jle     .end_dir
        inc     dword [edi]
        push    ecx
        mov     ecx, [edi]
        call    extfsGetExtent
        jc      .error_get_block
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    extfsReadBlock
        jc      .error_get_block
        pop     ecx
        mov     eax, ebx
        add     eax, [ebp+EXTFS.bytesPerBlock]
        mov     [edi+24], eax
        ret
 
.wanted_end:
        loop    .find_wanted_cycle
.find_wanted_end:
        mov     ecx, [edi+20]
.wanted_start:
        jecxz   .wanted_end
        cmp     [ebx+DIRENTRY.inodeNumber], 0
        jz      .empty_rec
        inc     dword [edi+8]
        inc     dword [edi+4]
        push    ebx edi ecx esi edx edi
        pushd   [edi+12]
        mov     edi, edx
        xor     eax, eax
        mov     ecx, 40 / 4
        rep stosd
        popd    [edx+4] edi
        mov     eax, [ebx+DIRENTRY.inodeNumber]
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    readInode
        jc      .error_read_subinode
        mov     esi, ebx
        lea     edi, [edx+8]
        mov     eax, [ebx+INODE.inodeModified]
        sub     eax, 978307200  ; 01.01.1970-01.01.2001 = (365*31+8)*24*60*60
        call    fsTime2bdfe
 
        mov     eax, [esi+INODE.accessedTime]
        sub     eax, 978307200
        call    fsTime2bdfe
 
        mov     eax, [esi+INODE.dataModified]
        sub     eax, 978307200
        call    fsTime2bdfe
        pop     edx
        or      dword [edx], KOS_DIRECTORY
        test    [esi+INODE.accessMode], FLAG_FILE
        jz      @f
        xor     dword [edx], KOS_DIRECTORY  ; mark as file
        mov     eax, [esi+INODE.fileSize]
        stosd
        mov     eax, [esi+INODE.fileSizeHigh]
        stosd
@@:
        mov     esi, [esp+12]
        movzx   ecx, [esi+DIRENTRY.nameLength]
        lea     esi, [esi+DIRENTRY.name]
        add     ecx, esi
        cmp     byte [esi], '.'
        jnz     @f
        or      byte [edx], KOS_HIDDEN
@@:
        lea     edi, [edx+40]
        cmp     byte [edx+4], 1
        jz      .utf16
@@:
        call    utf8to16
        call    uni2ansi_char
        stosb
        cmp     esi, ecx
        jc      @b
        and     byte [edi], 0
        add     edx, 40+264
@@:
        pop     esi ecx edi ebx
        dec     ecx
.empty_rec:
        movzx   eax, [ebx+DIRENTRY.entryLength]
        cmp     eax, 12
        jb      .error_bad_len
        test    eax, 3
        jnz     .error_bad_len
        sub     [esi+INODE.fileSize], eax
        add     ebx, eax
        cmp     ebx, [edi+24]
        jb      .wanted_start
        push    .wanted_start
        jmp     .end_block
 
.utf16:
        call    utf8to16
        stosw
        cmp     esi, ecx
        jc      .utf16
        and     word [edi], 0
        add     edx, 40+520
        jmp     @b
 
.end_dir:
        call    ext_unlock
        mov     edx, [edi+28]
        mov     ebx, [edi+8]
        mov     ecx, [edi+4]
        mov     dword [edx], 1  ; version
        mov     [edx+4], ebx
        mov     [edx+8], ecx
        lea     esp, [edi+32]
        mov     ecx, 20/4
        lea     edi, [edx+12]
        xor     eax, eax
        rep stosd
        ret
 
.error_bad_len:
        movi    eax, ERROR_FS_FAIL
.error_read_subinode:
.error_get_block:
        lea     esp, [edi+32]
.error_ret:
        or      ebx, -1
        push    eax
        call    ext_unlock
        pop     eax
        ret
 
.error_empty_dir:
        movi    eax, ERROR_FS_FAIL
        jmp     .error_ret
 
.error_not_found:
        movi    eax, ERROR_FILE_NOT_FOUND
        jmp     .error_ret
 
;----------------------------------------------------------------
ext_ReadFile:
        call    ext_lock
        pushd   0 ERROR_ACCESS_DENIED
        cmp     byte [esi], 0
        jz      .ret  ; root
        mov     [esp], ebx
        call    findInode
        pop     ebx
        push    eax
        jc      .ret
        lea     esi, [ebp+EXTFS.inodeBuffer]
        mov     byte [esp], ERROR_ACCESS_DENIED
        test    [esi+INODE.accessMode], FLAG_FILE
        jz      .ret    ; not a file
        mov     byte [esp], ERROR_END_OF_FILE
        mov     eax, [esi+INODE.fileSize]
        mov     edx, [esi+INODE.fileSizeHigh]
        sub     eax, [ebx+4]
        sbb     edx, [ebx+8]
        jc      .ret
        mov     ecx, [ebx+12]
        sub     eax, ecx
        sbb     edx, 0
        jc      @f
        xor     eax, eax
        mov     [esp], eax
@@:
        add     ecx, eax
        mov     eax, [ebx+4]
        mov     edx, [ebx+8]
        mov     edi, [ebx+16]
        div     [ebp+EXTFS.bytesPerBlock]
        test    edx, edx
        jz      .aligned
.piece:
        push    eax ecx
        mov     esi, edx
        mov     ecx, eax
        call    extfsGetExtent
        jc      .errorGet
        mov     ecx, [ebp+EXTFS.sectorsPerBlock]
        mul     ecx
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    fs_read64_sys
        test    eax, eax
        jnz     .errorRead
        pop     eax
        mov     ecx, [ebp+EXTFS.bytesPerBlock]
        sub     ecx, esi
        sub     eax, ecx
        jnc     @f
        add     ecx, eax
        xor     eax, eax
@@:
        add     esi, ebx
        add     [esp+8], ecx
        rep movsb
        mov     ecx, eax
        pop     eax
        inc     eax
        xor     edx, edx
        jecxz   .ret
.aligned:
        xchg    eax, ecx
        div     [ebp+EXTFS.bytesPerBlock]
        push    edx
        mov     edx, eax
.writeExtent:
        test    edx, edx
        jz      .end
        push    ecx
        call    extfsGetExtent
        jc      .errorGet
        sub     edx, ecx
        jnc     @f
        add     ecx, edx
        xor     edx, edx
@@:
        add     [esp], ecx
        imul    ecx, [ebp+EXTFS.sectorsPerBlock]
        mov     ebx, edi
        push    edx ecx
        mul     [ebp+EXTFS.sectorsPerBlock]
        call    fs_read64_sys
        pop     ecx edx
        test    eax, eax
        jnz     .errorRead
        shl     ecx, 9
        add     edi, ecx
        add     [esp+12], ecx
        pop     ecx
        jmp     .writeExtent
 
.end:
        mov     eax, ecx
        pop     ecx
        jecxz   .ret
        jmp     .piece
 
.errorRead:
        movi    eax, ERROR_DEVICE
.errorGet:
        pop     ebx ebx
        mov     [esp], eax
.ret:
        call    ext_unlock
        pop     eax ebx
        ret
 
;----------------------------------------------------------------
ext_GetFileInfo:
        call    ext_lock
        mov     edx, [ebx+16]
        cmp     byte [esi], 0
        jz      .is_root
        push    edx
        call    findInode
        pop     edx
        lea     esi, [ebp+EXTFS.inodeBuffer]
        jnc     @f
        push    eax
        call    ext_unlock
        pop     eax
        ret
 
.is_root:
        mov     edi, esi
        lea     esi, [ebp+EXTFS.rootInodeBuffer]
@@:
        mov     bl, [edi]
        xor     eax, eax
        mov     edi, edx
        mov     ecx, 40/4
        rep stosd
        cmp     bl, '.'
        jne     @f
        or      dword [edx], KOS_HIDDEN
@@:
        or      dword [edx], KOS_DIRECTORY
        test    [esi+INODE.accessMode], FLAG_FILE
        jz      @f
        xor     dword [edx], KOS_DIRECTORY  ; mark as file
        mov     eax, [esi+INODE.fileSize]
        mov     ebx, [esi+INODE.fileSizeHigh]
        mov     dword [edx+32], eax
        mov     dword [edx+36], ebx
@@:
        lea     edi, [edx+8]
        mov     eax, [esi+INODE.inodeModified]
        sub     eax, 978307200  ; 01.01.1970-01.01.2001 = (365*31+8)*24*60*60
        call    fsTime2bdfe
 
        mov     eax, [esi+INODE.accessedTime]
        sub     eax, 978307200
        call    fsTime2bdfe
 
        mov     eax, [esi+INODE.dataModified]
        sub     eax, 978307200
        call    fsTime2bdfe
        call    ext_unlock
        xor     eax, eax
        ret
 
;----------------------------------------------------------------
ext_SetFileInfo:
        call    extfsWritingInit
        pushd   [ebx+16]
        call    findInode
        pop     edx
        jc      @f
        push    esi     ; inode number
        lea     esi, [edx+16]
        lea     edi, [ebp+EXTFS.inodeBuffer]
        call    fsCalculateTime
        add     eax, 978307200  ; 01.01.1970-01.01.2001 = (365*31+8)*24*60*60
        mov     [edi+INODE.accessedTime], eax
 
        add     esi, 8
        call    fsCalculateTime
        add     eax, 978307200
        mov     [edi+INODE.dataModified], eax
        mov     ebx, edi
        pop     eax
        call    writeInode
@@:
        push    eax
        jc      @f
        call    writeSuperblock
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
@@:
        call    ext_unlock
        pop     eax
        ret
 
;----------------------------------------------------------------
ext_Delete:
        call    extfsWritingInit
        call    findInode
        mov     ebx, esi
        push    eax
        jc      .ret
        pop     eax
        lea     edx, [ebp+EXTFS.inodeBuffer]
        movzx   edx, [edx+INODE.accessMode]
        and     edx, TYPE_MASK
        cmp     edx, DIRECTORY
        jne     .file
        push    ebx ecx edx
        xor     ecx, ecx
.checkDirectory:
        push    ecx
        call    extfsGetExtent
        jc      .empty
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .not_empty_eax
        mov     edx, ebx
        add     edx, [ebp+EXTFS.bytesPerBlock]
        movzx   ecx, [ebx+DIRENTRY.entryLength]
        add     ebx, ecx
.dir_entry:
        cmp     byte [ebx+DIRENTRY.nameLength], 1
        jne     @f
        cmp     byte [ebx+DIRENTRY.name], '.'
        jne     .not_empty
@@:
        cmp     byte [ebx+DIRENTRY.nameLength], 2
        jne     .not_empty
        cmp     word [ebx+DIRENTRY.name], '..'
        jne     .not_empty
        movzx   ecx, [ebx+DIRENTRY.entryLength]
        add     ebx, ecx
        cmp     ebx, edx
        jb      .dir_entry
        pop     ecx
        inc     ecx
        jmp     .checkDirectory
 
.not_empty:
        pop     eax eax
.error_stack8:
        pop     eax eax
        push    ERROR_ACCESS_DENIED
        jmp     .ret
 
.empty:
        cmp     eax, ERROR_END_OF_FILE
        jnz     .not_empty_eax
        pop     edx edx ecx ebx
.file:
        mov     eax, ecx
        push    ebx ecx
        call    unlinkInode
        cmp     eax, -1
        je      .error_stack8
        pop     ebx
        test    eax, eax
        jz      @f
        xor     eax, eax
        cmp     edx, DIRECTORY
        jnz     .error_stack4_eax   ; hardlinks
        mov     eax, [esp]
        call    unlinkInode
@@:
        mov     eax, [esp]
        lea     ebx, [ebp+EXTFS.inodeBuffer]
        call    readInode
        jc      .error_stack4_eax
        xor     ecx, ecx
        call    extfsTruncateFile   ; free file's data
        xor     eax, eax
        movzx   ecx, [ebp+EXTFS.superblock.inodeSize]
        rep stosb
        lea     edi, [ebp+EXTFS.inodeBuffer]
        push    edx
        call    fsGetTime
        pop     edx
        add     eax, 978307200
        mov     [edi+INODE.deletedTime], eax
        mov     eax, [esp]
        mov     ebx, edi
        call    writeInode
        jc      .error_stack4_eax
 
        pop     eax
 
        dec     eax
        mov     ecx, edx
        xor     edx, edx
        div     [ebp+EXTFS.superblock.inodesPerGroup]
        push    edx eax
        call    extfsReadDescriptor
        jc      .error_stack8_eax
        cmp     ecx, DIRECTORY
        jnz     @f
        dec     [ebx+BGDESCR.directoriesCount]
@@:
        inc     [ebx+BGDESCR.inodesFree]
        mov     ecx, [ebx+BGDESCR.inodeBitmap]
        pop     eax
        call    extfsWriteDescriptor
        mov     eax, ecx
        mov     ebx, [ebp+EXTFS.tempBlockBuffer]
        call    extfsReadBlock
        jc      .error_stack4_eax
        pop     eax
        mov     edx, eax
        and     edx, 31
        shr     eax, 5
        shl     eax, 2
        add     eax, ebx
        btr     [eax], edx
        mov     eax, ecx
        call    extfsWriteBlock
        inc     [ebp+EXTFS.superblock.inodesFree]
        push    eax
.disk_sync:
        call    writeSuperblock
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
.ret:
        call    ext_unlock
        xor     ebx, ebx
        pop     eax
        ret
 
 
 
 
 
 
 
 
.not_empty_eax:
        pop     ebx ebx
.error_stack8_eax:
        pop     ebx
.error_stack4_eax:
        pop     ebx
        push    eax
        jmp     .disk_sync
 
;----------------------------------------------------------------
ext_CreateFolder:
        call    extfsWritingInit
        call    findInode
        jnc     .success    ; exist
        test    edi, edi
        jz      .error
        mov     eax, esi
        call    extfsInodeAlloc
        jc      .error
 
        push    ebx esi edi
        xor     al, al
        lea     edi, [ebp+EXTFS.inodeBuffer]
        movzx   ecx, [ebp+EXTFS.superblock.inodeSize]
        rep stosb
        lea     edi, [ebp+EXTFS.inodeBuffer]
        call    fsGetTime
        add     eax, 978307200
        mov     [edi+INODE.accessedTime], eax
        mov     [edi+INODE.dataModified], eax
        mov     ebx, edi
        pop     edi esi edx
; edx = allocated inode number, edi -> filename, esi = parent inode number
        mov     [ebx+INODE.accessMode], DIRECTORY or PERMISSIONS
        mov     eax, edx
        call    writeInode
        jc      .error
; link to self
        push    edx esi
        mov     eax, edx
        mov     ebx, eax
        mov     dl, DIR_DIRECTORY
        mov     esi, self_link
        call    linkInode
        pop     esi edx
        jc      .error
; link to parent
        push    edx esi
        mov     eax, ebx
        mov     ebx, esi
        mov     dl, DIR_DIRECTORY
        mov     esi, parent_link
        call    linkInode
        pop     esi edx
        jc      .error
; link parent to child
        mov     eax, esi
        mov     ebx, edx
        mov     esi, edi
        mov     dl, DIR_DIRECTORY
        call    linkInode
        jc      .error
        mov     eax, ebx
        dec     eax
        xor     edx, edx
        div     [ebp+EXTFS.superblock.inodesPerGroup]
        mov     edx, eax
        call    extfsReadDescriptor
        jc      .error
        inc     [ebx+BGDESCR.directoriesCount]
        mov     eax, edx
        call    extfsWriteDescriptor
.success:
.error:
        push    eax
        call    writeSuperblock
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
        call    ext_unlock
        pop     eax
        ret
 
 
 
 
 
self_link   db ".", 0
parent_link db "..", 0
 
;----------------------------------------------------------------
ext_CreateFile:
        call    extfsWritingInit
        pushd   0 0 ebx
        call    findInode
        jnc     .exist
        test    edi, edi
        jz      .error
        mov     eax, esi
        call    extfsInodeAlloc
        jc      .error
 
        push    ebx ebx esi edi
        xor     al, al
        lea     edi, [ebp+EXTFS.inodeBuffer]
        movzx   ecx, [ebp+EXTFS.superblock.inodeSize]
        rep stosb
        lea     edi, [ebp+EXTFS.inodeBuffer]
        call    fsGetTime
        add     eax, 978307200
        mov     [edi+INODE.accessedTime], eax
        mov     [edi+INODE.dataModified], eax
        mov     ebx, edi
        pop     edi esi edx
; edx = allocated inode number, edi -> filename, esi = parent inode number
        mov     [ebx+INODE.accessMode], FLAG_FILE or PERMISSIONS
        mov     eax, edx
        call    writeInode
        jc      .error2
; link parent to child
        mov     eax, esi
        mov     ebx, edx
        mov     esi, edi
        mov     dl, DIR_FLAG_FILE
        call    linkInode
        jc      .error2
        pop     esi ebx
        mov     ecx, [ebx+12]
        jmp     ext_WriteFile.start
 
.exist:
        movi    eax, ERROR_ACCESS_DENIED
        test    [ebp+EXTFS.inodeBuffer.accessMode], FLAG_FILE
        jz      .error  ; not a file
        pop     ebx
        mov     ecx, [ebx+12]
        call    extfsTruncateFile
        jmp     ext_WriteFile.start
 
.error2:
        pop     ebx
.error:
        push    eax
        call    ext_unlock
        pop     eax ebx ebx ebx
        ret
 
;----------------------------------------------------------------
ext_WriteFile:
        call    extfsWritingInit
        push    ebx
        call    findInode
        pop     ebx
        pushd   0 eax
        jc      .ret
        mov     byte [esp], ERROR_ACCESS_DENIED
        test    [ebp+EXTFS.inodeBuffer.accessMode], FLAG_FILE
        jz      .ret    ; not a file
        mov     ecx, [ebx+4]
        add     ecx, [ebx+12]
.start:
        push    esi
        mov     eax, esi
        call    extfsExtendFile
        jc      .errorExtend
        mov     eax, [ebx+4]
        mov     ecx, [ebx+12]
        mov     esi, [ebx+16]
.write:
        xor     edx, edx
        div     [ebp+EXTFS.bytesPerBlock]
        test    edx, edx
        jz      .aligned
.piece:
        mov     ebx, ecx
        mov     edi, edx
        mov     ecx, eax
        push    eax
        call    extfsGetExtent
        jc      .errorGet
        mov     ecx, [ebp+EXTFS.sectorsPerBlock]
        mul     ecx
        push    ecx eax ebx
        mov     ebx, [ebp+EXTFS.mainBlockBuffer]
        call    fs_read64_sys
        test    eax, eax
        jnz     .errorDevice
        pop     eax
        mov     ecx, [ebp+EXTFS.bytesPerBlock]
        sub     ecx, edi
        sub     eax, ecx
        jnc     @f
        add     ecx, eax
        xor     eax, eax
@@:
        add     edi, ebx
        add     [esp+20], ecx
        rep movsb
        mov     edi, eax
        pop     eax ecx
        xor     edx, edx
        call    fs_write64_sys
        mov     ecx, edi
        pop     eax
        inc     eax
        xor     edx, edx
        jecxz   .done
.aligned:
        xchg    eax, ecx
        div     [ebp+EXTFS.bytesPerBlock]
        push    edx
        mov     edx, eax
.writeExtent:
        test    edx, edx
        jz      .end
        push    ecx
        call    extfsGetExtent
        jc      .errorGet2
        sub     edx, ecx
        jnc     @f
        add     ecx, edx
        xor     edx, edx
@@:
        add     [esp], ecx
        imul    ecx, [ebp+EXTFS.sectorsPerBlock]
        mov     ebx, esi
        push    edx ecx
        mul     [ebp+EXTFS.sectorsPerBlock]
        call    fs_write64_sys
        test    eax, eax
        jnz     .errorDevice
        pop     ebx edx ecx
        shl     ebx, 9
        add     esi, ebx
        add     [esp+12], ebx
        jmp     .writeExtent
 
.end:
        mov     eax, ecx
        pop     ecx
        jecxz   .done
        jmp     .piece
 
.errorDevice:
        pop     eax eax
        movi    eax, ERROR_DEVICE
.errorGet2:
        pop     ebx
.errorGet:
        pop     ebx
.errorExtend:
        mov     [esp+4], eax
.done:
        lea     ebx, [ebp+EXTFS.inodeBuffer]
        pop     eax
        call    writeInode
        add     [esp], eax
        call    writeSuperblock
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
.ret:
        call    ext_unlock
        pop     eax ebx
        ret
 
.erase:
        push    eax eax edx
        mov     eax, ebx
        jmp     .write
 
;----------------------------------------------------------------
ext_SetFileEnd:
        call    extfsWritingInit
        pushd   [ebx+4]
        call    findInode
        pop     ecx
        jc      .error2
        lea     edi, [ebp+EXTFS.inodeBuffer]
        movi    eax, ERROR_ACCESS_DENIED
        test    [edi+INODE.accessMode], FLAG_FILE
        jz      .error2 ; not a file
        push    esi
        mov     ebx, [edi+INODE.fileSize]
        mov     eax, esi
        cmp     ebx, ecx
        jnc     @f
        call    extfsExtendFile
        jc      .error
        sub     ecx, ebx
        cmp     ecx, 1000001h
        jnc     .done
        push    ecx
        stdcall kernel_alloc, ecx
        pop     ecx
        test    eax, eax
        jz      .error
        push    ecx
        add     ecx, 3
        shr     ecx, 2
        mov     esi, eax
        mov     edi, eax
        xor     eax, eax
        rep stosd
        pop     ecx edx
        push    esi
        call    ext_WriteFile.erase
        call    kernel_free
        xor     eax, eax
        ret
 
@@:
        call    extfsTruncateFile
.done:
        xor     eax, eax
.error:
        xchg    eax, [esp]
        lea     ebx, [ebp+EXTFS.inodeBuffer]
        call    writeInode
        add     [esp], eax
        call    writeSuperblock
        mov     esi, [ebp+PARTITION.Disk]
        call    disk_sync
        pop     eax
.error2:
        push    eax
        call    ext_unlock
        pop     eax
        ret

Rev 6726	Rev 6756
1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2	;; ;;	2	;; ;;
3	;; Copyright (C) KolibriOS team 2013-2016. All rights reserved. ;;	3	;; Copyright (C) KolibriOS team 2013-2016. All rights reserved. ;;
4	;; Distributed under terms of the GNU General Public License. ;;	4	;; Distributed under terms of the GNU General Public License. ;;
5	;; ;;	5	;; ;;
6	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;	6	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
7		7
8	$Revision: 6726 $	8	$Revision: 6756 $
9		9
10	; EXT external functions	10	; EXT external functions
11	; in:	11	; in:
12	; ebx -> parameter structure of sysfunc 70	12	; ebx -> parameter structure of sysfunc 70
13	; ebp -> EXTFS structure	13	; ebp -> EXTFS structure
14	; esi -> path string in UTF-8	14	; esi -> path string in UTF-8
15	; out:	15	; out:
16	; eax, ebx = return values for sysfunc 70	16	; eax, ebx = return values for sysfunc 70
17	iglobal	17	iglobal
18	align 4	18	align 4
19	ext_user_functions:	19	ext_user_functions:
20	dd ext_free	20	dd ext_free
21	dd (ext_user_functions_end - ext_user_functions - 4) / 4	21	dd (ext_user_functions_end - ext_user_functions - 4) / 4
22	dd ext_ReadFile	22	dd ext_ReadFile
23	dd ext_ReadFolder	23	dd ext_ReadFolder
24	dd ext_CreateFile	24	dd ext_CreateFile
25	dd ext_WriteFile	25	dd ext_WriteFile
26	dd ext_SetFileEnd	26	dd ext_SetFileEnd
27	dd ext_GetFileInfo	27	dd ext_GetFileInfo
28	dd ext_SetFileInfo	28	dd ext_SetFileInfo
29	dd 0	29	dd 0
30	dd ext_Delete	30	dd ext_Delete
31	dd ext_CreateFolder	31	dd ext_CreateFolder
32	ext_user_functions_end:	32	ext_user_functions_end:
33	endg	33	endg
34		34
35	struct DIRENTRY	35	struct DIRENTRY
36	inodeNumber dd ?	36	inodeNumber dd ?
37	entryLength dw ?	37	entryLength dw ?
38	nameLength db ?	38	nameLength db ?
39	fileType db ?	39	fileType db ?
40	name db ? ; rb [nameLength]	40	name db ? ; rb [nameLength]
41	ends	41	ends
42		42
43	struct INODE	43	struct INODE
44	accessMode dw ?	44	accessMode dw ?
45	UID dw ?	45	UID dw ?
46	fileSize dd ?	46	fileSize dd ?
47	accessedTime dd ?	47	accessedTime dd ?
48	inodeModified dd ?	48	inodeModified dd ?
49	dataModified dd ?	49	dataModified dd ?
50	deletedTime dd ?	50	deletedTime dd ?
51	GID dw ?	51	GID dw ?
52	linksCount dw ?	52	linksCount dw ?
53	sectorsUsed dd ?	53	sectorsUsed dd ?
54	featureFlags dd ?	54	featureFlags dd ?
55	reserved dd ?	55	reserved dd ?
56	blockNumbers rd 12	56	blockNumbers rd 12
57	addressBlock dd ?	57	addressBlock dd ?
58	doubleAddress dd ?	58	doubleAddress dd ?
59	tripleAddress dd ?	59	tripleAddress dd ?
60	generation dd ?	60	generation dd ?
61	ACL dd ?	61	ACL dd ?
62	fileSizeHigh dd ?	62	fileSizeHigh dd ?
63	ends	63	ends
64		64
65	struct BGDESCR ; block group descriptor	65	struct BGDESCR ; block group descriptor
66	blockBitmap dd ?	66	blockBitmap dd ?
67	inodeBitmap dd ?	67	inodeBitmap dd ?
68	inodeTable dd ?	68	inodeTable dd ?
69	blocksFree dw ?	69	blocksFree dw ?
70	inodesFree dw ?	70	inodesFree dw ?
71	directoriesCount dw ?	71	directoriesCount dw ?
72	reserved rb 14	72	reserved rb 14
73	ends	73	ends
74		74
75	struct SUPERBLOCK	75	struct SUPERBLOCK
76	inodesTotal dd ?	76	inodesTotal dd ?
77	blocksTotal dd ?	77	blocksTotal dd ?
78	blocksReserved dd ?	78	blocksReserved dd ?
79	blocksFree dd ?	79	blocksFree dd ?
80	inodesFree dd ?	80	inodesFree dd ?
81	firstGroupBlock dd ?	81	firstGroupBlock dd ?
82	sectorsPerBlockLog dd ? ; shift for 1024	82	sectorsPerBlockLog dd ? ; shift for 1024
83	fragmentSizeLog dd ?	83	fragmentSizeLog dd ?
84	blocksPerGroup dd ?	84	blocksPerGroup dd ?
85	fragmentsPerGroup dd ?	85	fragmentsPerGroup dd ?
86	inodesPerGroup dd ?	86	inodesPerGroup dd ?
87	lastMountTime dd ?	87	lastMountTime dd ?
88	lastWriteTime dd ?	88	lastWriteTime dd ?
89	mountCount dw ?	89	mountCount dw ?
90	mountMax dw ?	90	mountMax dw ?
91	magic dw ?	91	magic dw ?
92	state dw ?	92	state dw ?
93	errorHandling dw ?	93	errorHandling dw ?
94	additionalVersion dw ?	94	additionalVersion dw ?
95	lastCheck dd ?	95	lastCheck dd ?
96	checkInterval dd ?	96	checkInterval dd ?
97	creatorOS dd ?	97	creatorOS dd ?
98	dynamicVersionFlag dd ?	98	dynamicVersionFlag dd ?
99	reservedUID dw ?	99	reservedUID dw ?
100	reservedGID dw ?	100	reservedGID dw ?
101	firstInode dd ?	101	firstInode dd ?
102	inodeSize dw ?	102	inodeSize dw ?
103	thisBlockGroup dw ?	103	thisBlockGroup dw ?
104	compatibleFlags dd ?	104	compatibleFlags dd ?
105	incompatibleFlags dd ?	105	incompatibleFlags dd ?
106	RO_compatibleFlags dd ?	106	RO_compatibleFlags dd ?
107	ends	107	ends
108		108
109	; ext4 extent tree	109	; ext4 extent tree
110	struct NODEHEADER ; tree node header	110	struct NODEHEADER ; tree node header
111	magic dw ? ; 0xF30A	111	magic dw ? ; 0xF30A
112	entriesFolow dw ?	112	entriesFolow dw ?
113	entriesMax dw ?	113	entriesMax dw ?
114	currentDepth dw ?	114	currentDepth dw ?
115	generation dd ?	115	generation dd ?
116	ends	116	ends
117		117
118	struct INDEX ; root/branch	118	struct INDEX ; root/branch
119	fileBlock dd ?	119	fileBlock dd ?
120	nodeBlock dd ?	120	nodeBlock dd ?
121	nodeBlockHigh dw ?	121	nodeBlockHigh dw ?
122	reserved dw ?	122	reserved dw ?
123	ends	123	ends
124		124
125	struct EXTENT ; leaf	125	struct EXTENT ; leaf
126	fileBlock dd ?	126	fileBlock dd ?
127	blocksCount dw ?	127	blocksCount dw ?
128	fsBlockHigh dw ?	128	fsBlockHigh dw ?
129	fsBlock dd ?	129	fsBlock dd ?
130	ends	130	ends
131		131
132	ROOT_INODE = 2	132	ROOT_INODE = 2
133	PERMISSIONS = 110110110b	133	PERMISSIONS = 110110110b
134	EXTENTS_USED = 80000h	134	EXTENTS_USED = 80000h
135	TYPE_MASK = 0F000h	135	TYPE_MASK = 0F000h
136	FLAG_FILE = 8000h	136	FLAG_FILE = 8000h
137	DIRECTORY = 4000h	137	DIRECTORY = 4000h
138	DIR_FLAG_FILE = 1	138	DIR_FLAG_FILE = 1
139	DIR_DIRECTORY = 2	139	DIR_DIRECTORY = 2
140	KOS_HIDDEN = 2	140	KOS_HIDDEN = 2
141	KOS_DIRECTORY = 10h	141	KOS_DIRECTORY = 10h
142	READ_ONLY = 1	142	READ_ONLY = 1
143		143
144	; Implemented "incompatible" features:	144	; Implemented "incompatible" features:
145	; 2 = have file type in directory entry	145	; 2 = have file type in directory entry
146	; 40h = extents	146	; 40h = extents
147	; 200h = flexible block groups	147	; 200h = flexible block groups
148	INCOMPATIBLE_SUPPORT = 242h	148	INCOMPATIBLE_SUPPORT = 242h
149	; Read only support for "incompatible" features:	149	; Read only support for "incompatible" features:
150	INCOMPATIBLE_READ_SUPPORT = 240h	150	INCOMPATIBLE_READ_SUPPORT = 240h
151		151
152	; Implemented "read-only" features:	152	; Implemented "read-only" features:
153	; 1 = sparse superblock	153	; 1 = sparse superblock
154	; 2 = 64-bit file size	154	; 2 = 64-bit file size
155	READ_ONLY_SUPPORT = 3	155	READ_ONLY_SUPPORT = 3
156		156
157	struct EXTFS PARTITION	157	struct EXTFS PARTITION
158	Lock MUTEX	158	Lock MUTEX
159	mountType dd ?	159	mountType dd ?
160	sectorsPerBlockLog dd ? ; shift for 512	160	sectorsPerBlockLog dd ? ; shift for 512
161	bytesPerBlock dd ?	161	bytesPerBlock dd ?
162	sectorsPerBlock dd ?	162	sectorsPerBlock dd ?
163	dwordsPerBlock dd ?	163	dwordsPerBlock dd ?
164	dwordsPerBranch dd ? ; dwordsPerBlock ^ 2	164	dwordsPerBranch dd ? ; dwordsPerBlock ^ 2
165	mainBlockBuffer dd ?	165	mainBlockBuffer dd ?
166	tempBlockBuffer dd ?	166	tempBlockBuffer dd ?
167	align0 rb 200h-EXTFS.align0	167	align0 rb 200h-EXTFS.align0
168	superblock SUPERBLOCK	168	superblock SUPERBLOCK
169	align1 rb 400h-EXTFS.align1	169	align1 rb 400h-EXTFS.align1
170	rootInodeBuffer INODE	170	rootInodeBuffer INODE
171	align2 rb 600h-EXTFS.align2	171	align2 rb 600h-EXTFS.align2
172	inodeBuffer INODE	172	inodeBuffer INODE
173	align3 rb 800h-EXTFS.align3	173	align3 rb 800h-EXTFS.align3
174	ends	174	ends
175		175
176	; mount if it's a valid EXT partition	176	; mount if it's a valid EXT partition
177	ext2_create_partition:	177	ext2_create_partition:
178	; in:	178	; in:
179	; ebp -> PARTITION structure	179	; ebp -> PARTITION structure
180	; ebx -> boot sector	180	; ebx -> boot sector
181	; ebx+512 -> buffer	181	; ebx+512 -> buffer
182	; out:	182	; out:
183	; eax -> EXTFS structure, 0 = not EXT	183	; eax -> EXTFS structure, 0 = not EXT
184	push ebx	184	push ebx
185	cmp dword [esi+DISK.MediaInfo.SectorSize], 512	185	cmp dword [esi+DISK.MediaInfo.SectorSize], 512
186	jnz .fail	186	jnz .fail
187	mov eax, 2	187	mov eax, 2
188	add ebx, 512	188	add ebx, 512
189	call fs_read32_sys	189	call fs_read32_sys
190	test eax, eax	190	test eax, eax
191	jnz .fail	191	jnz .fail
192	cmp [ebx+SUPERBLOCK.magic], 0xEF53	192	cmp [ebx+SUPERBLOCK.magic], 0xEF53
193	jne .fail	193	jne .fail
194	cmp [ebx+SUPERBLOCK.state], 1	194	cmp [ebx+SUPERBLOCK.state], 1
195	ja .fail	195	ja .fail
196	test [ebx+SUPERBLOCK.incompatibleFlags], not INCOMPATIBLE_SUPPORT	196	test [ebx+SUPERBLOCK.incompatibleFlags], not INCOMPATIBLE_SUPPORT
197	jnz .fail	197	jnz .fail
198	cmp [ebx+SUPERBLOCK.sectorsPerBlockLog], 6 ; 64KB	198	cmp [ebx+SUPERBLOCK.sectorsPerBlockLog], 6 ; 64KB
199	ja .fail	199	ja .fail
200	cmp [ebx+SUPERBLOCK.inodeSize], 1024	200	cmp [ebx+SUPERBLOCK.inodeSize], 1024
201	ja .fail	201	ja .fail
202	cmp [ebx+SUPERBLOCK.blocksPerGroup], 0	202	cmp [ebx+SUPERBLOCK.blocksPerGroup], 0
203	je .fail	203	je .fail
204	cmp [ebx+SUPERBLOCK.inodesPerGroup], 0	204	cmp [ebx+SUPERBLOCK.inodesPerGroup], 0
205	je .fail	205	je .fail
206	movi eax, sizeof.EXTFS	206	movi eax, sizeof.EXTFS
207	call malloc	207	call malloc
208	test eax, eax	208	test eax, eax
209	jz .fail	209	jz .fail
210	mov ecx, dword [ebp+PARTITION.FirstSector]	210	mov ecx, dword [ebp+PARTITION.FirstSector]
211	mov dword [eax+EXTFS.FirstSector], ecx	211	mov dword [eax+EXTFS.FirstSector], ecx
212	mov ecx, dword [ebp+PARTITION.FirstSector+4]	212	mov ecx, dword [ebp+PARTITION.FirstSector+4]
213	mov dword [eax+EXTFS.FirstSector+4], ecx	213	mov dword [eax+EXTFS.FirstSector+4], ecx
214	mov ecx, dword [ebp+PARTITION.Length]	214	mov ecx, dword [ebp+PARTITION.Length]
215	mov dword [eax+EXTFS.Length], ecx	215	mov dword [eax+EXTFS.Length], ecx
216	mov ecx, dword [ebp+PARTITION.Length+4]	216	mov ecx, dword [ebp+PARTITION.Length+4]
217	mov dword [eax+EXTFS.Length+4], ecx	217	mov dword [eax+EXTFS.Length+4], ecx
218	mov ecx, [ebp+PARTITION.Disk]	218	mov ecx, [ebp+PARTITION.Disk]
219	mov [eax+EXTFS.Disk], ecx	219	mov [eax+EXTFS.Disk], ecx
220	mov [eax+EXTFS.FSUserFunctions], ext_user_functions	220	mov [eax+EXTFS.FSUserFunctions], ext_user_functions
221		221
222	push ebp esi edi	222	push ebp esi edi
223	mov ebp, eax	223	mov ebp, eax
224	lea ecx, [eax+EXTFS.Lock]	224	lea ecx, [eax+EXTFS.Lock]
225	call mutex_init	225	call mutex_init
226	mov esi, ebx	226	mov esi, ebx
227	lea edi, [ebp+EXTFS.superblock]	227	lea edi, [ebp+EXTFS.superblock]
228	mov ecx, 512/4	228	mov ecx, 512/4
229	rep movsd ; copy superblock	229	rep movsd ; copy superblock
230	mov ecx, [ebx+SUPERBLOCK.sectorsPerBlockLog]	230	mov ecx, [ebx+SUPERBLOCK.sectorsPerBlockLog]
231	inc ecx	231	inc ecx
232	mov [ebp+EXTFS.sectorsPerBlockLog], ecx	232	mov [ebp+EXTFS.sectorsPerBlockLog], ecx
233	mov eax, 1	233	mov eax, 1
234	shl eax, cl	234	shl eax, cl
235	mov [ebp+EXTFS.sectorsPerBlock], eax	235	mov [ebp+EXTFS.sectorsPerBlock], eax
236	shl eax, 9	236	shl eax, 9
237	mov [ebp+EXTFS.bytesPerBlock], eax	237	mov [ebp+EXTFS.bytesPerBlock], eax
238	shl eax, 1	238	shl eax, 1
239	push eax	239	push eax
240	shr eax, 3	240	shr eax, 3
241	mov [ebp+EXTFS.dwordsPerBlock], eax	241	mov [ebp+EXTFS.dwordsPerBlock], eax
242	mul eax	242	mul eax
243	mov [ebp+EXTFS.dwordsPerBranch], eax	243	mov [ebp+EXTFS.dwordsPerBranch], eax
244	call kernel_alloc	244	call kernel_alloc
245	test eax, eax	245	test eax, eax
246	jz .error	246	jz .error
247	mov [ebp+EXTFS.mainBlockBuffer], eax	247	mov [ebp+EXTFS.mainBlockBuffer], eax
248	add eax, [ebp+EXTFS.bytesPerBlock]	248	add eax, [ebp+EXTFS.bytesPerBlock]
249	mov [ebp+EXTFS.tempBlockBuffer], eax	249	mov [ebp+EXTFS.tempBlockBuffer], eax
250	mov [ebp+EXTFS.mountType], 0	250	mov [ebp+EXTFS.mountType], 0
251	test [ebx+SUPERBLOCK.RO_compatibleFlags], not READ_ONLY_SUPPORT	251	test [ebx+SUPERBLOCK.RO_compatibleFlags], not READ_ONLY_SUPPORT
252	jnz .read_only	252	jnz .read_only
253	test [ebx+SUPERBLOCK.incompatibleFlags], INCOMPATIBLE_READ_SUPPORT	253	test [ebx+SUPERBLOCK.incompatibleFlags], INCOMPATIBLE_READ_SUPPORT
254	jz @f	254	jz @f
255	.read_only:	255	.read_only:
256	or [ebp+EXTFS.mountType], READ_ONLY	256	or [ebp+EXTFS.mountType], READ_ONLY
257	@@: ; read root inode	257	@@: ; read root inode
258	lea ebx, [ebp+EXTFS.rootInodeBuffer]	258	lea ebx, [ebp+EXTFS.rootInodeBuffer]
259	mov eax, ROOT_INODE	259	mov eax, ROOT_INODE
260	call readInode	260	call readInode
261	test eax, eax	261	test eax, eax
262	jnz @f	262	jnz @f
263	mov eax, ebp	263	mov eax, ebp
264	pop edi esi ebp ebx	264	pop edi esi ebp ebx
265	ret	265	ret
266		266
267	@@:	267	@@:
268	stdcall kernel_free, [ebp+EXTFS.mainBlockBuffer]	268	stdcall kernel_free, [ebp+EXTFS.mainBlockBuffer]
269	.error:	269	.error:
270	mov eax, ebp	270	mov eax, ebp
271	call free	271	call free
272	pop edi esi ebp	272	pop edi esi ebp
273	.fail:	273	.fail:
274	pop ebx	274	pop ebx
275	xor eax, eax	275	xor eax, eax
276	ret	276	ret
277		277
278	; unmount EXT partition	278	; unmount EXT partition
279	ext_free:	279	ext_free:
280	; in: eax -> EXTFS structure	280	; in: eax -> EXTFS structure
281	push eax	281	push eax
282	stdcall kernel_free, [eax+EXTFS.mainBlockBuffer]	282	stdcall kernel_free, [eax+EXTFS.mainBlockBuffer]
283	pop eax	283	pop eax
284	jmp free	284	jmp free
285		285
286	extfsWriteBlock:	286	extfsWriteBlock:
287	push fs_write64_sys	287	push fs_write64_sys
288	jmp @f	288	jmp @f
289	; in: eax = block number, ebx -> buffer	289	; in: eax = block number, ebx -> buffer
290	extfsReadBlock:	290	extfsReadBlock:
291	push fs_read64_sys	291	push fs_read64_sys
292	@@:	292	@@:
293	push ecx edx	293	push ecx edx
294	mov ecx, [ebp+EXTFS.sectorsPerBlock]	294	mov ecx, [ebp+EXTFS.sectorsPerBlock]
295	mul ecx	295	mul ecx
296	call dword[esp+8]	296	call dword[esp+8]
297	pop edx ecx	297	pop edx ecx
298	add esp, 4	298	add esp, 4
299	test eax, eax	299	test eax, eax
300	jz @f	300	jz @f
301	movi eax, ERROR_DEVICE	301	movi eax, ERROR_DEVICE
302	stc	302	stc
303	@@:	303	@@:
304	ret	304	ret
305		305
306	extfsReadDescriptor:	306	extfsReadDescriptor:
307	; in: eax = block group number	307	; in: eax = block group number
-		308	; out: ebx -> block group descriptor
308	; out:	309	push ecx edx
309	; [ebp+EXTFS.tempBlockBuffer] -> relevant block	310	mov edx, [ebp+EXTFS.superblock.firstGroupBlock]
-		311	inc edx
310	; eax -> block group descriptor, 0 = error	312	mov ecx, [ebp+EXTFS.sectorsPerBlockLog]
311	push edx ebx	313	shl edx, cl
312	shl eax, 5	314	shl eax, 5
313	xor edx, edx	315	mov ecx, eax
314	div [ebp+EXTFS.bytesPerBlock]	-
315	add eax, [ebp+EXTFS.superblock.firstGroupBlock]	-
316	inc eax	316	and ecx, 511
317	mov ebx, [ebp+EXTFS.tempBlockBuffer]	-
318	call extfsReadBlock	-
319	jc .fail	-
320	mov eax, ebx	317	shr eax, 9
321	add eax, edx	318	add eax, edx
-		319	mov ebx, [ebp+EXTFS.tempBlockBuffer]
-		320	push ecx
-		321	call fs_read32_sys
-		322	pop ecx
-		323	add ebx, ecx
-		324	test eax, eax
-		325	jz @f
-		326	movi eax, ERROR_DEVICE
-		327	stc
322	@@:	328	@@:
323	pop ebx edx	329	pop edx ecx
324	ret	330	ret
325		-
326	.fail:	-
327	xor eax, eax	-
328	stc	-
329	jmp @b	-
330		331
331	extfsWriteDescriptor:	-
332	; in:	332	extfsWriteDescriptor:
333	; eax = block group number	-
334	; [ebp+EXTFS.tempBlockBuffer] -> relevant block	333	; in: eax = block group number
335	push edx ebx	334	push ebx ecx edx
336	shl eax, 5	335	mov edx, [ebp+EXTFS.superblock.firstGroupBlock]
337	xor edx, edx	336	inc edx
338	div [ebp+EXTFS.bytesPerBlock]	337	mov ecx, [ebp+EXTFS.sectorsPerBlockLog]
-		338	shl edx, cl
339	add eax, [ebp+EXTFS.superblock.firstGroupBlock]	339	shr eax, 9-5
340	inc eax	340	add eax, edx
341	mov ebx, [ebp+EXTFS.tempBlockBuffer]	341	mov ebx, [ebp+EXTFS.tempBlockBuffer]
342	call extfsWriteBlock	342	call fs_write32_sys
343	pop ebx edx	343	pop edx ecx ebx
344	ret	344	ret
345		-
346	extfsResourceFree:	345
347	; in:	-
348	; ecx=0 -> block, ecx=1 -> inode	346	extfsExtentFree:
349	; eax = block/inode number	347	; in: eax = first block number, ecx = extent size
350	push ebx edx	348	push ebx edx edi
351	sub eax, [ebp+EXTFS.superblock.firstGroupBlock]	349	sub eax, [ebp+EXTFS.superblock.firstGroupBlock]
-		350	xor edx, edx
-		351	mov ebx, [ebp+EXTFS.superblock.blocksPerGroup]
-		352	div ebx
-		353	sub ebx, edx
352	xor edx, edx	354	sub ebx, ecx
353	div [ebp+EXTFS.superblock.blocksPerGroup]	355	jc .ret
354	push edx eax	356	push edx eax
355	call extfsReadDescriptor	357	call extfsReadDescriptor
356	jc .fail2	358	jc .fail2
357	inc [eax+BGDESCR.blocksFree+ecx*2]	359	add [ebx+BGDESCR.blocksFree], cx
358	mov edx, [eax+BGDESCR.blockBitmap+ecx*4]	360	mov edx, [ebx+BGDESCR.blockBitmap]
359	pop eax	361	pop eax
360	call extfsWriteDescriptor	362	call extfsWriteDescriptor
361	jc .fail	-
362	mov eax, edx	363	mov eax, edx
363	mov ebx, [ebp+EXTFS.tempBlockBuffer]	364	mov ebx, [ebp+EXTFS.tempBlockBuffer]
364	call extfsReadBlock	365	call extfsReadBlock
365	jc .fail	366	jc .fail
366	pop eax	367	pop eax
-		368	push ecx ebx edx
-		369	add [ebp+EXTFS.superblock.blocksFree], ecx
-		370	mov edi, eax
-		371	shr edi, 5
-		372	shl edi, 2
-		373	add edi, ebx
-		374	and eax, 31
-		375	mov edx, ecx
-		376	mov ecx, 32
-		377	sub ecx, eax
-		378	sub edx, ecx
-		379	jnc @f
-		380	add ecx, edx
-		381	xor edx, edx
-		382	@@:
-		383	or ebx, -1
-		384	shl ebx, cl
367	push edx	385	not ebx
368	mov edx, eax	386	mov ecx, eax
-		387	shl ebx, cl
-		388	not ebx
-		389	and [edi], ebx
-		390	mov ecx, edx
-		391	jecxz @f
-		392	shr ecx, 5
-		393	add edi, 4
-		394	xor eax, eax
-		395	rep stosd
369	and edx, 31	396	and edx, 31
370	shr eax, 5	397	mov ecx, edx
371	shl eax, 2	398	jecxz @f
372	add eax, [ebp+EXTFS.tempBlockBuffer]	-
373	btr [eax], edx	-
374	pop eax	399	not eax
375	mov ebx, [ebp+EXTFS.tempBlockBuffer]	-
376	call extfsWriteBlock	400	shl eax, cl
377	jc @f	401	and [edi], eax
378	inc [ebp+EXTFS.superblock.blocksFree+ecx*4]	-
379	@@:	402	@@:
-		403	pop eax ebx
-		404	call extfsWriteBlock
-		405	pop ecx
-		406	mov eax, ecx
-		407	mul [ebp+EXTFS.sectorsPerBlock]
-		408	sub [ebp+EXTFS.inodeBuffer.sectorsUsed], eax
-		409	.ret:
-		410	pop edi edx ebx
380	xor eax, eax	411	xor eax, eax
381	pop edx ebx	-
382	ret	412	ret
383		413
384	.fail2:	414	.fail2:
385	pop eax	415	pop eax
386	.fail:	416	.fail:
387	pop eax	417	pop eax
388	jmp @b	418	jmp .ret
389		419
390	extfsInodeAlloc:	420	extfsInodeAlloc:
391	; in: eax = parent inode number	421	; in: eax = parent inode number
392	; out: ebx = allocated inode number	422	; out: ebx = allocated inode number
393	push ecx edx esi edi	423	push ecx edx esi edi
394	dec eax	424	dec eax
395	xor edx, edx	425	xor edx, edx
396	div [ebp+EXTFS.superblock.inodesPerGroup]	426	div [ebp+EXTFS.superblock.inodesPerGroup]
397	push eax eax	427	push eax eax
398	mov esi, .forward ; search forward, then backward	428	mov esi, .forward ; search forward, then backward
399	.test_block_group:	429	.test_block_group:
400	call extfsReadDescriptor	430	call extfsReadDescriptor
401	jc .fail	431	jc .fail
402	dec [eax+BGDESCR.inodesFree]	432	dec [ebx+BGDESCR.inodesFree]
403	js .next	433	js .next
404	mov edx, [eax+BGDESCR.inodeBitmap]	434	mov edx, [ebx+BGDESCR.inodeBitmap]
405	mov eax, [esp]	435	mov eax, [esp]
406	call extfsWriteDescriptor	436	call extfsWriteDescriptor
407	jc .fail	-
408	mov eax, edx	437	mov eax, edx
409	mov ebx, [ebp+EXTFS.tempBlockBuffer]	438	mov ebx, [ebp+EXTFS.tempBlockBuffer]
410	mov edi, ebx	439	mov edi, ebx
411	call extfsReadBlock	440	call extfsReadBlock
412	jc .fail	441	jc .fail
413	mov ecx, [ebp+EXTFS.superblock.inodesPerGroup]	442	mov ecx, [ebp+EXTFS.superblock.inodesPerGroup]
414	or eax, -1	443	or eax, -1
415	shr ecx, 5	444	shr ecx, 5
416	repz scasd	445	repz scasd
417	jz .next	446	jz .next
418	sub edi, 4	447	sub edi, 4
419	mov eax, [edi]	448	mov eax, [edi]
420	not eax	449	not eax
421	bsf eax, eax	450	bsf eax, eax
422	bts [edi], eax	451	bts [edi], eax
423	sub edi, [ebp+EXTFS.tempBlockBuffer]	452	sub edi, [ebp+EXTFS.tempBlockBuffer]
424	shl edi, 3	453	shl edi, 3
425	add eax, edi	454	add eax, edi
426	mov ecx, eax	455	mov ecx, eax
427	mov eax, edx	456	mov eax, edx
428	call extfsWriteBlock	457	call extfsWriteBlock
429	jc .fail	-
430	pop eax	458	pop eax
431	mul [ebp+EXTFS.superblock.inodesPerGroup]	459	mul [ebp+EXTFS.superblock.inodesPerGroup]
432	add eax, ecx	-
433	dec [ebp+EXTFS.superblock.inodesFree]	460	dec [ebp+EXTFS.superblock.inodesFree]
434	mov ebx, eax	461	lea ebx, [eax+ecx+1]
435	pop eax	-
436	xor eax, eax	462	xor eax, eax
437	@@:	463	.ret:
438	pop edi esi edx ecx	464	pop edi edi esi edx ecx
439	ret	465	ret
440		-
441	.fail:	-
442	pop eax eax	-
443	movi eax, ERROR_DEVICE	-
444	jmp @b	-
445		466
446	.next:	467	.next:
447	jmp esi	468	jmp esi
448		469
449	.forward:	470	.forward:
450	inc dword[esp]	471	inc dword[esp]

Subversion Repositories Kolibri OS

(root)/kernel/trunk/fs/ext.inc @ 6726 – Rev 6726 → 6756