Subversion Repositories Kolibri OS

Compare Revisions

No changes between revisions

Regard whitespace Rev 30 → Rev 31

/programs/movback/trunk/build_en.bat
0,0 → 1,4
@erase lang.inc
@echo lang fix en >lang.inc
@fasm movback.asm movback
@pause
/programs/movback/trunk/build_ru.bat
0,0 → 1,4
@erase lang.inc
@echo lang fix ru >lang.inc
@fasm movback.asm movback
@pause
/programs/movback/trunk/macros.inc
0,0 → 1,267
; new application structure
macro meos_app_start
{
use32
org 0x0
 
db 'MENUET01'
dd 0x01
dd __start
dd __end
dd __memory
dd __stack
 
if used __params & ~defined __params
dd __params
else
dd 0x0
end if
 
dd 0x0
}
MEOS_APP_START fix meos_app_start
 
macro code
{
__start:
}
CODE fix code
 
macro data
{
__data:
}
DATA fix data
 
macro udata
{
if used __params & ~defined __params
__params:
db 0
__end:
rb 255
else
__end:
end if
__udata:
}
UDATA fix udata
 
macro meos_app_end
{
align 32
rb 2048
__stack:
__memory:
}
MEOS_APP_END fix meos_app_end
 
 
; macro for defining multiline text data
struc mstr [sstring]
{
forward
local ssize
virtual at 0
db sstring
ssize = $
end virtual
dd ssize
db sstring
common
dd -1
}
 
 
; strings
macro sz name,[data] { ; from MFAR [mike.dld]
common
if used name
label name
end if
forward
if used name
db data
end if
common
if used name
.size = $-name
end if
}
 
macro lsz name,[lng,data] { ; from MFAR [mike.dld]
common
if used name
label name
end if
forward
if (used name)&(lang eq lng)
db data
end if
common
if used name
.size = $-name
end if
}
 
 
 
; easy system call macro
macro mpack dest, hsrc, lsrc
{
if (hsrc eqtype 0) & (lsrc eqtype 0)
mov dest, (hsrc) shl 16 + lsrc
else
if (hsrc eqtype 0) & (~lsrc eqtype 0)
mov dest, (hsrc) shl 16
add dest, lsrc
else
mov dest, hsrc
shl dest, 16
add dest, lsrc
end if
end if
}
 
macro __mov reg,a,b { ; mike.dld
if (~a eq)&(~b eq)
mpack reg,a,b
else if (~a eq)&(b eq)
mov reg,a
end if
}
 
macro mcall a,b,c,d,e,f { ; mike.dld
__mov eax,a
__mov ebx,b
__mov ecx,c
__mov edx,d
__mov esi,e
__mov edi,f
int 0x40
}
 
 
 
 
 
 
 
; optimize the code for size
__regs fix <eax,ebx,ecx,edx,esi,edi,ebp,esp>
 
macro add arg1,arg2
{
if (arg2 eqtype 0)
if (arg2) = 1
inc arg1
else
add arg1,arg2
end if
else
add arg1,arg2
end if
}
 
macro sub arg1,arg2
{
if (arg2 eqtype 0)
if (arg2) = 1
dec arg1
else
sub arg1,arg2
end if
else
sub arg1,arg2
end if
}
 
macro mov arg1,arg2
{
if (arg1 in __regs) & (arg2 eqtype 0)
if (arg2) = 0
xor arg1,arg1
else if (arg2) = 1
xor arg1,arg1
inc arg1
else if (arg2) = -1
or arg1,-1
else if (arg2) > -128 & (arg2) < 128
push arg2
pop arg1
else
mov arg1,arg2
end if
else
mov arg1,arg2
end if
}
 
 
macro struct name
{
virtual at 0
name name
sizeof.#name = $ - name
end virtual
}
 
; structures used in MeOS
struc process_information
{
.cpu_usage dd ? ; +0
.window_stack_position dw ? ; +4
.window_stack_value dw ? ; +6
.not_used1 dw ? ; +8
.process_name rb 12 ; +10
.memory_start dd ? ; +22
.used_memory dd ? ; +26
.PID dd ? ; +30
.x_start dd ? ; +34
.y_start dd ? ; +38
.x_size dd ? ; +42
.y_size dd ? ; +46
.slot_state dw ? ; +50
rb (1024-52)
}
struct process_information
 
struc system_colors
{
.frame dd ?
.grab dd ?
.grab_button dd ?
.grab_button_text dd ?
.grab_text dd ?
.work dd ?
.work_button dd ?
.work_button_text dd ?
.work_text dd ?
.work_graph dd ?
}
struct system_colors
 
 
; constants
 
; events
EV_IDLE = 0
EV_TIMER = 0
EV_REDRAW = 1
EV_KEY = 2
EV_BUTTON = 3
EV_EXIT = 4
EV_BACKGROUND = 5
EV_MOUSE = 6
EV_IPC = 7
EV_STACK = 8
 
; event mask bits for function 40
EVM_REDRAW = 1b
EVM_KEY = 10b
EVM_BUTTON = 100b
EVM_EXIT = 1000b
EVM_BACKGROUND = 10000b
EVM_MOUSE = 100000b
EVM_IPC = 1000000b
EVM_STACK = 10000000b
Property changes:
Added: svn:eol-style
+native
\ No newline at end of property
/programs/movback/trunk/movback.asm
0,0 → 1,188
include "lang.inc"
include "macros.inc"
 
WND_SIZE_X = 320
WND_SIZE_Y = 200
 
VC_DELTA = 1
HC_DELTA = 2
 
MEOS_APP_START
CODE
fninit
call init_sinus_table
call init_background
call init_palette
mov eax,40
mov ebx,101b
int 0x40
jmp .paint_window
 
.event_loop:
mov eax,23
mov ebx,1
int 0x40
 
test eax,eax
je .draw_screen
dec eax
je .paint_window
 
or eax,-1
int 0x40
 
.draw_screen:
add word [ver_counter],VC_DELTA
add word [hor_counter],HC_DELTA
call handle_animation
mov eax,7
mov ebx,virtual_screen_32
mov ecx,(WND_SIZE_X shl 16)+WND_SIZE_Y
mov edx,(5 shl 16)+23
int 0x40
jmp .event_loop
 
.paint_window:
mov eax,12
mov ebx,1
int 0x40
 
xor eax,eax
mov ebx,(100 shl 16)+(WND_SIZE_X+9)
mov ecx,(100 shl 16)+(WND_SIZE_Y+28)
mov edx,0x03000000
int 0x40
 
mov eax,7
mov ebx,virtual_screen_32
mov ecx,(WND_SIZE_X shl 16)+WND_SIZE_Y
mov edx,(5 shl 16)+23
int 0x40
 
mov eax,4
mov ebx,0x00060006
mov ecx,0x10ffffff
mov edx,window_title
mov esi,window_title_len
int 0x40
 
mov eax,12
mov ebx,2
int 0x40
 
jmp .event_loop
 
init_palette:
mov ecx,256
mov edi,_palette
xor eax,eax
.next_pal:
mov al,ah
shr al,2
stosb
stosb
stosb
inc edi
inc ah
loop .next_pal
ret
 
init_sinus_table:
sub esp,4
mov ecx,256
mov edi,sinetable
.sin_loop:
fld dword [esp]
fld st0
fsin
fmul [scale_sin]
fistp word [edi]
fadd [delta_angle]
fstp dword [esp]
add edi,2
loop .sin_loop
add esp,4
ret
 
init_background:
mov edi,background
xor edx,edx
.ib_vertical:
xor ecx,ecx
.ib_horizontal:
mov eax,ecx
xor eax,edx
stosb
inc ecx
cmp ecx,256
jne .ib_horizontal
inc edx
cmp edx,256
jne .ib_vertical
ret
 
s_OFFX = 0
s_OFFY = 2
 
handle_animation:
sub esp,4
mov ebx,[ver_counter]
and ebx,255
add ebx,ebx
mov ax,[sinetable+ebx]
mov [esp+s_OFFY],ax
mov ebx,[hor_counter]
and ebx,255
add ebx,ebx
mov ax,[sinetable+ebx]
mov [esp+s_OFFX],ax
mov edi,virtual_screen_32
mov edx,WND_SIZE_Y-1
.a_ver:
mov ecx,WND_SIZE_X-1
mov bx,[esp+s_OFFY]
add bx,dx
and ebx,255
shl ebx,8
.a_hor:
mov ax,[esp+s_OFFX]
add ax,cx
and eax,255
lea esi,[background+ebx+eax]
mov al,[esi]
and eax,0xff
mov eax,[_palette+eax*4]
stosw
shr eax,16
stosb
dec ecx
jge .a_hor
dec edx
jge .a_ver
add esp,4
ret
 
DATA
delta_angle dd 0.0245436926066 ; pi/128
scale_sin dd 128.0
 
window_title:
db 'MoveBack'
window_title_len = $ - window_title
 
UDATA
ver_counter dd ?
hor_counter dd ?
 
_palette: rd 256
 
virtual_screen_32:
rb WND_SIZE_X*WND_SIZE_Y*3
 
background:
rb 256*256
 
sinetable:
rw 256
 
MEOS_APP_END
Property changes:
Added: svn:eol-style
+native
\ No newline at end of property