Subversion Repositories Kolibri OS

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;                                                                 ;;

;; Copyright (C) KolibriOS team 2009-2013. All rights reserved.    ;;

;; Distributed under terms of the GNU General Public License       ;;

;;                                                                 ;;

;;  downloader.asm - HTTP client for KolibriOS                     ;;

;;                                                                 ;;

;;  Based on HTTPC.asm for menuetos by ville turjanmaa             ;;

;;                                                                 ;;

;;  Programmers: Barsuk, Clevermouse, Marat Zakiyanov,             ;;

;;      Kirill Lipatov, dunkaist, HidnPlayr                        ;;

;;                                                                 ;;

;;          GNU GENERAL PUBLIC LICENSE                             ;;

;;             Version 2, June 1991                                ;;

;;                                                                 ;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

URLMAXLEN               = 1024

BUFFERSIZE              = 4096

__DEBUG__       = 1

__DEBUG_LEVEL__ = 2

format binary as ""

use32

        org     0x0

        db      'MENUET01'      ; header

        dd      0x01            ; header version

        dd      START           ; entry point

        dd      IM_END          ; image size

        dd      I_END+0x100     ; required memory

        dd      I_END+0x100     ; esp

        dd      params          ; I_PARAM

        dd      0x0             ; I_Path

include '../macros.inc'

include '../proc32.inc'

include '../network.inc'

include '../../develop/libraries/box_lib/trunk/box_lib.mac'

include '../dll.inc'

include '../debug-fdo.inc'

START:

        mcall   68, 11                  ; init heap so we can allocate memory dynamically

        mcall   40, EV_STACK

; load libraries

        stdcall dll.Load, @IMPORT

        test    eax, eax

        jnz     exit

; prepare webAddr area

        mov     al, ' '

        mov     edi, webAddr

        mov     ecx, URLMAXLEN

        rep     stosb

        xor     eax, eax

        stosb

; prepare document area

        mov     al, '/'

        mov     edi, document

        stosb

        mov     al, ' '

        mov     ecx, URLMAXLEN-1

        rep     stosb

        call    load_settings

        cmp     byte[params], 0

        je      prepare_event   ;red

; we have an url

        mov     edi, document_user

        mov     al, ' '

        mov     ecx, URLMAXLEN

        rep     stosb

        mov     esi, params

        mov     edi, document_user

; copy untill space or 0

  .copy_param:

        mov     al, [esi]

        test    al, al

        jz      .done

        cmp     al, ' '

        jz      .done_inc

        mov     [edi], al

        inc     esi

        inc     edi

        jmp     .copy_param

  .done_inc:

; url is followed by shared memory name.

        inc     esi

  .done:

        mov     [shared_name], esi

        jmp     download

prepare_event:

; Report events

; Stack 8 + defaults

        mcall   40, 10100111b

red:    ; redraw

        call    draw_window

still:

        cmp     byte [params], 0

        jne     exit

        mcall   10      ; wait here for event

        cmp     eax, 1  ; redraw request ?

        je      red

        cmp     eax, 2  ; key in buffer ?

        je      key

        cmp     eax, 3  ; button in buffer ?

        je      button

        cmp     eax, 6  ; mouse in buffer ?

        je      mouse

        jmp     still

key:

        mcall   2       ; read key

        stdcall [edit_box_key], dword edit1

        cmp     ax, 13 shl 8

        je      download

        jmp     still

button:

        mcall   17      ; get id

        cmp     ah, 26

        jne     @f

        call    save_to_file

        jmp     still

  @@:

        cmp     ah, 1   ; button id=1 ?

        je      exit

        jmp     download

mouse:

        stdcall [edit_box_mouse], edit1

        jmp     still

exit:

        or      eax, -1  ; close this program

        mcall

download:

        DEBUGF  1, "Starting download\n"

        call    parse_url

        call    open_socket

        call    send_request

        mcall   68, 12, BUFFERSIZE

        mov     [buf_ptr], eax

        mov     [buf_size], 0

        call    read_incoming_data

        mcall   close, [socketnum]

        call    parse_result

        call    save

        mcall   68, 13, [final_buffer]

        jmp     still

save:

        mov     ecx, [shared_name]

        test    ecx, ecx

        jz      @f

        cmp     [ecx], byte 0

        jnz     save_in_shared

    @@:

        call    save_to_file

; if called from command line, then exit

        cmp     byte[params], 0

        jne     exit

        ret

save_in_shared:

        mov     esi, 1   ; SHM_OPEN+SHM_WRITE

        mcall   68, 22

        test    eax, eax

        jz      exit

        sub     edx, 4

        jbe     exit

        mov     ecx, [final_size]

        cmp     ecx, edx

        jb      @f

        mov     ecx, edx

    @@:

        mov     [eax], ecx

        lea     edi, [eax+4]

        mov     esi, [final_buffer]

        mov     edx, ecx

        shr     ecx, 2

        rep     movsd

        mov     ecx, edx

        and     ecx, 3

        rep     movsb

        jmp     exit