Subversion Repositories Kolibri OS

; The macros for load any library/libraries:

; Copyright (c) 2009, 

; All rights reserved.

macro @use_library mem_alloc,mem_free,mem_realloc,dll_load

{

local lp1

local lp2

local lp3

local lp4

local lp5

local lp6

local file_name

local l_lib_m1

local l_lib_m2

local l_lib_m3

local l_lib_m4

library_fun_memory_alloc equ mem_alloc

library_fun_memory_free equ mem_free

library_fun_memory_realloc equ mem_realloc

library_fun_dll_load equ dll_load

align 4

arrea_xx dd 0

file_name db '/sys/@notify',0

if lang eq ru

	l_lib_m1 db '"���⥬��� �訡��',13,10,'�� ������� ������⥪� ',39,0

	l_lib_m2 db '"���⥬��� �訡��',13,10,'�訡�� �� ������ ������⥪� ',39,0

	l_lib_m3 db 39,13,10,'�� ������� �㭪�� ',39,0

	l_lib_m4 db 39,'" -tE',0

else if lang eq it

	l_lib_m1 db '"Errore di sistema',13,10,'Non trovato ',39,0

	l_lib_m2 db '"Errore di sistema',13,10,'Import errato ',39,0

	l_lib_m3 db 39,13,10,'funzione non trovata ',39,0

	l_lib_m4 db 39,'" -tE',0

else

	l_lib_m1 db '"System error',13,10,'Sorry I cannot found library ',39,0

	l_lib_m2 db '"System error',13,10,'Error on load import library ',39,0

	l_lib_m3 db 39,13,10,'cannot found function ',39,0

	l_lib_m4 db 39,'" -tE',0

end if

align 4

run_notify_struct:

	.Function dd 7

	.Position dd 0

	.Flags dd ?

	.Count dd 0

	.Buffer dd 0

		db 0

	.FileName dd file_name

;description:

; ��⮢�� ⥪�� ��� ������ �१ @notify:

; 1) �뤥�塞 ������ � [arrea_xx] �� �� ����� ������ ࠧ�

; 2) �����㥬 ��������� (�᫨ ���� ��� �㭪樨 � ������塞 ��� � ���������) � ⥪�� ᮮ�饭�� � [arrea_xx]

;input:

; ebp+8  - library name

; ebp+12 - 0 ��� ��� �㭪樨, ������ �� 㤠���� ��ᯮ��஢���

;output:

; eax = -1

align 4

l_lib_init_error_window:

	push ebp

	mov ebp,esp

	cmp dword[arrea_xx],0

	jne .no_msg ;�᫨ ࠭�� �뫮 ᮧ���� ��㣮� ᮮ�饭��

	pushad

	mcall SF_SYS_MISC,SSF_HEAP_INIT

	mcall SF_SYS_MISC,SSF_MEM_ALLOC,4096

	mov [arrea_xx],eax

	mov edi,eax

	mov esi,l_lib_m2 ;ᮮ�饭�� �᫨ �� 㤠���� ������஢��� �㭪��

	cmp dword[ebp+12],0

	je @f

	mov esi,l_lib_m1 ;ᮮ�饭�� �᫨ �� 㤠���� ����㧨�� ������⥪�

align 4

@@:

	movsb

	cmp byte[esi],0

	jne @b

	;������塞 ��� ������⥪�

	mov esi,[ebp+8]

align 4

@@:

	movsb

	cmp byte[esi],0

	jne @b

	cmp dword[ebp+12],0

	je .lp1

	;������塞 �।��� ᮮ�饭��

	mov esi,l_lib_m3

align 4

@@:

	movsb

	cmp byte[esi],0

	jne @b

	;������塞 ��� �㭪樨

	mov esi,[ebp+12]

align 4

@@:

	movsb

	cmp byte[esi],0

	jne @b

	.lp1: ;ᮮ�饭�� �᫨ �� 㤠���� ����㧨�� ������⥪�

	;������塞 ����� ᮮ�饭��

	mov esi,l_lib_m4

align 4

@@:

	movsb

	cmp byte[esi],0

	jne @b

	mov byte[edi],0

	popad

	.no_msg:

	or eax,-1

	pop ebp

	ret 8

@library_name     equ    dword [esp+16]

@cur_dir_path     equ    dword [esp+12]

@library_path     equ    dword [esp+8]

@point_dir_name   equ    dword [esp+4]

align 4

@copy_path:

	mov     esi,@cur_dir_path

	mov     edi,@library_path

	xor     eax,eax

	cld

align 4

.lp1:

	lodsb

	stosb

	test    eax,eax

	jnz     .lp1

	mov     esi,edi

	dec     esi ;���室 �� ᨬ��� ���� ��ப� @cur_dir_path

	std

align 4

.lp2:

	lodsb

	cmp     al,'/'

	jnz     .lp2

	mov     edi,esi

	add     edi,2

	cld

	mov     esi,@point_dir_name

	test    esi,esi

	jz      .str_lp4

	;�஢�ઠ �⭮�⥫��� ��⥩ c ���� �窠�� '../'

	cmp word[esi],'..'

	jne .lp3

	dec edi ;��� ���室� �� '/'

.lp6:

		add esi,3 ;�ய�᪠�� ���� �����⨥ '../'

.lp5:

		dec edi ;���� �� ������

		cmp byte[edi],'/'

		jnz .lp5

	cmp word[esi],'..'

	je .lp6

	inc edi ;��� ���室� �� '/'

	;����஢���� �⭮�⥫쭮�� ���

align 4

.lp3:

	lodsb

	stosb

	test    eax,eax

	jnz     .lp3

	dec     edi

.str_lp4:

	mov     esi,@library_name

align 4

.lp4:

	lodsb

	stosb

	test    eax,eax

	jnz     .lp4

	ret

}

;---------------------------------------------------------------------

macro sys_load_library library_name__, library_path__, system_path__, myimport, point_dir_name__

{

local i_begin

local i_error

local i_exit

	push ebx

	mcall	SF_SYS_MISC,SSF_LOAD_DLL,system_path__   ; load of sys directory

	test	eax,eax

	jnz		i_begin

if point_dir_name__ eq

		copy_path   library_name__, [32], library_path__,0

else

		;the macros making way /current path a program/ + name system library

		copy_path   library_name__, [32], library_path__,point_dir_name__

end if

		mcall	SF_SYS_MISC,SSF_LOAD_DLL,library_path__ ; load of alternative

		test	eax,eax

		jnz		i_begin

		jmp		i_error

align 4

	i_begin:

		import_boxlib myimport

		test	eax,eax

		jz		i_exit

	i_error:

		push	eax

		push	dword library_name__

		call	l_lib_init_error_window

		notify_window_run [arrea_xx] ; ᮧ���� ���� @notify

	i_exit:

	pop ebx

}

;---------------------------------------------------------------------

;output:

; eax - �᫨ 㤠筮 � 0

macro load_library library_name__, library_path__, system_path__, myimport, point_dir_name__

{

local i_begin

local i_error

local i_exit

	push ebx

if point_dir_name__ eq

		copy_path   library_name__, [32], library_path__,0

else

		;the macros making way /current path a program/ + name system library

		copy_path   library_name__, [32], library_path__,point_dir_name__

end if

		mcall	SF_SYS_MISC,SSF_LOAD_DLL,library_path__ ; load of alternative

		test	eax,eax

		jnz		i_begin

		mcall	SF_SYS_MISC,SSF_LOAD_DLL,system_path__ ; load of sys directory

		test	eax,eax

		jnz		i_begin

		jmp		i_error

align 4

	i_begin:

		import_boxlib myimport

		test	eax,eax

		jz		i_exit

	i_error:

		push	eax

		push	dword library_name__

		call	l_lib_init_error_window

		notify_window_run [arrea_xx] ; ᮧ���� ���� @notify

	i_exit:

	pop ebx

;---------------------------------------------------------------------

}

;description:

; ����� ����㧪� ������⥪ �� ��⥬��� �����, �᫨ ������⥪� �� �������

; ⮣�� ���� ���� � ⥪�饩 ����� � �ணࠬ���

macro sys_load_libraries _start,_end

{

local cycle0

local end_steep

local cycle0n

local cycle1

local cycle1n

local cycle1e

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

library_name__            equ [ebp]

library_path__            equ [ebp+4]

system_path__             equ [ebp+8]

my_import                 equ [ebp+12]

point_dir_name__          equ [ebp+16]

adr_load_lib              equ dword [ebp+20]

status_lib                equ dword [ebp+24]

	mov	ebp,_start

	mov	ecx,(_end-_start)/ll_struc_size

align 4

	cycle0:

		push	ecx

        mcall   SF_SYS_MISC,SSF_LOAD_DLL,system_path__   ; load of sys directory

        test    eax,eax

        jnz     end_steep

        ;the macros making way /current path a program/ + name system library

		copy_path  library_name__, [32], library_path__,point_dir_name__

        mcall   SF_SYS_MISC,SSF_LOAD_DLL,library_path__ ; load of alternative

        test    eax,eax

        jnz     end_steep

        or      status_lib,1          ; status of code - enable error - not found library

		push	eax

		push	dword library_name__

		call	l_lib_init_error_window

        jmp		cycle0n

align 4

	end_steep:

		mov		adr_load_lib,eax        ;save adr lib in memory

		import_boxlib my_import

		test	eax,eax

		jz		cycle0n

		or		status_lib,2          ; status of code - enable error - import error

		push	eax

		push	dword library_name__

		call	l_lib_init_error_window

	cycle0n:

		pop     ecx

		add     ebp,ll_struc_size

		dec     ecx

		jnz     cycle0

	;�뢮� ᮮ�饭�� �� �訡�� �� ����㧪�

	mov     ebp,_start

	mov     ecx,(_end-_start)/ll_struc_size

align 4

	cycle1:

		mov     eax,status_lib

		test    eax,eax

		jz      cycle1n

		notify_window_run [arrea_xx] ; ᮧ���� ���� @notify

		mov		eax,-1

		jmp		cycle1e

align 4

		cycle1n:

		add     ebp,ll_struc_size

		dec     ecx

		jnz     cycle1

	cycle1e:

}

;description:

; ����� ����㧪� ������⥪ �� ⥪�饩 ����� � �ணࠬ���, �᫨ ������⥪� �� �������

; ⮣�� ���� ���� � ��⥬��� �����

macro load_libraries _start,_end

{

local cycle0

local end_steep

local cycle0n

local cycle1

local cycle1n

local cycle1e

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

library_name__            equ [ebp]

library_path__            equ [ebp+4]

system_path__             equ [ebp+8]

my_import                 equ [ebp+12]

point_dir_name__          equ [ebp+16]

adr_load_lib              equ dword [ebp+20]

status_lib                equ dword [ebp+24]

	mov	ebp,_start

	mov	ecx,(_end-_start)/ll_struc_size

align 4

	cycle0:

		push	ecx

		;the macros making way /current path a program/ + name system library

		copy_path    library_name__, [32], library_path__,point_dir_name__

		mcall	SF_SYS_MISC,SSF_LOAD_DLL,library_path__  ; load of alternative

		test	eax,eax

		jnz		end_steep

		mcall	SF_SYS_MISC,SSF_LOAD_DLL,system_path__   ; load of sys directory

		test	eax,eax

		jnz		end_steep

		or		status_lib,1          ; status of code - enable error - not found library

		push	eax

		push	dword library_name__

		call	l_lib_init_error_window

		jmp		cycle0n

align 4

	end_steep:

		mov		adr_load_lib,eax        ;save adr lib in memory

		import_boxlib my_import

		test	eax,eax

		jz		cycle0n

		or		status_lib,2          ; status of code - enable error - import error

		push	eax

		push	dword library_name__

		call	l_lib_init_error_window

	cycle0n:

		pop     ecx

		add     ebp,ll_struc_size

		dec     ecx

		jnz     cycle0

	;�뢮� ᮮ�饭�� �� �訡�� �� ����㧪�

	mov     ebp,_start

	mov     ecx,(_end-_start)/ll_struc_size

align 4

	cycle1:

		mov     eax,status_lib

		test    eax,eax

		jz      cycle1n

		notify_window_run [arrea_xx] ; ᮧ���� ���� @notify

		mov		eax,-1

		jmp		cycle1e

align 4

		cycle1n:

		add     ebp,ll_struc_size

		dec     ecx

		jnz     cycle1

	cycle1e:

}

macro copy_path lib_name,dir_path,lib_path,point_dir_name

{

pushad  ;save all registers

	push dword lib_name

	push dword dir_path

	push dword lib_path

	push dword point_dir_name

	call @copy_path

	add  esp,16

	;notify_window_run lib_path ;unblok for test load path

popad   ;restore all registers

}

; ����砥� ����� ᮮ�饭�� �१ @notify:

macro notify_window_run message

{

push eax ebx

	mov eax,message ;��ࠬ���� ��� ��������� ��ப�

	mov [run_notify_struct.Flags],eax

	mcall SF_FILE,run_notify_struct

pop ebx eax

}

;input:

; eax - ���� ������⥪� � �����

; myimport - �������㥬� �㭪樨

;output:

; eax - �᫨ 㤠筮 � 0 ��� 㪠��⥫� �� ��� �㭪樨 ������ �� 㤠���� ����㧨��

; ebx - ࠧ��蠥���

macro import_boxlib myimport

{

local import_loop

local import_find

local lp

local import_find_next

local import_found

local import_done

local exit

local import_not_found

; initialize import

	push esi

        mov     edx, eax

        mov     esi, myimport

		cld

import_loop:

        lodsd	;mov eax,dword[esi] ;add esi,4 ;����砥� � eax 㪠��⥫� �� ��� �������㥬�� �㭪樨

        test    eax, eax

        jz      import_done ;�᫨ 㪠��⥫� �� ��� �㭪樨 = 0 (� ���짮��⥫�᪮� �ணࠬ��)

        push    edx ;��࠭塞 ��砫� ���������� 㪠��⥫�� �� �㭪樨

import_find:

        mov     ebx, [edx]

        test    ebx, ebx

        jz      import_not_found ;�᫨ 㪠��⥫� �� ��� �㭪樨 = 0 (� ������⥪�)

        push    eax ;eax - 㪠��⥫� �� ��� ��ᯮ���㥬�� �㭪樨 (� ���짮��⥫�᪮� �ணࠬ��)

align 4

lp:

        mov     cl, [eax]

        cmp     cl, [ebx] ;�ࠢ������ ����� �㭪権 � ������⥪� � � ���짮��⥫�᪮� �ணࠬ��

        jnz     import_find_next ;�᫨ �������� �� ᮢ����

        test    cl, cl

        jz      import_found ;�᫨ �������� ᮢ����, � 㦥 ����� ��ப� (cl=0)

        inc     eax

        inc     ebx

        jmp     lp

import_find_next:

        pop     eax

        add     edx, 8 ;8 = 4 ���� 㪠��⥫� �� �������� � 4 ���� 㪠��⥫� �� �㭪��

        jmp     import_find

import_found:

        pop     ebx ;���⠭�������� 㪠��⥫� �� ��� �㭪樨 (����� �� � eax) � �᢮������� �⥪

        mov     eax, [edx+4] ;eax = 㪠��⥫� �� �㭪�� (� ������⥪�)

        mov     [esi-4], eax ;�����㥬 㪠��⥫� (�� �㭪��) � �ணࠬ��, -4 �⠢�� ��⮬� �� esi �뫮 ᤢ���� �������� lodsd

        pop     edx ;��⠭�������� edx �� ��砫� ���������� �㭪権

;--- �஢��塞 ᮢ������ �� ��� ��ᯮ��஢����� �㭪樨 � 'lib_init'

if library_fun_memory_alloc eq

else

		cmp dword[ebx],'lib_'

		jne		import_loop

		cmp dword[ebx+4],'init'

		jne		import_loop

		;cmp  byte[ebx+8],0

		;jne		import_loop

;--- �᫨ ��� �㭪樨 ᮢ���� � 'lib_init' �������� �

		;������祭�� �㭪権 ��� ࠡ��� � �������

		;push eax

		;call dll.Init

		pushad

		mov esi,eax

		mov	eax,library_fun_memory_alloc

		mov	ebx,library_fun_memory_free

		mov	ecx,library_fun_memory_realloc

		mov	edx,library_fun_dll_load

		call dword esi

		popad

end if

        jmp     import_loop

import_not_found:

        add     esp,4

        jmp     exit

import_done:

        xor     eax,eax ;=0 �� ����㧨���� 㤠筮

exit:

	pop esi

}

;---------------------------------------------------------------------

ll_struc_size = 28;($-library_name__)    ; constant   size of struct

struc l_libs library_name__, library_path__, system_path__, my_import, point_dir_name; struct for loading libraries

{

.library_name__           dd library_name__        ; ��� ����㦠���� ������⥪�

.library_path__           dd library_path__        ; 㪠��⥫� �� ���� � ���஬ �㤥� ��ਬ�஢�� ���� � ������⥪�, �᫨ �㦭� ���᫨�� ���� �� ���� � ���� ����᪠ �ணࠬ��, ���筮 �㦭�, � �����, �᫨ ���� �ᯮ������ � ⮩ �� �����

.complete_path            dd system_path__         ; ���� ����� �⪮ ᮤ�ন� ����

.my_import                dd my_import

if point_dir_name eq

.point_dir_name__	dd 0

else

.point_dir_name__	dd point_dir_name	   ; ��� ��������� ���४�ਨ � ��ன �࠭����� �����㦠��� ���㫨.

end if

.adr_load_lib           dd 0

.status_lib             dd 0          ;status of load library

;

}