Subversion Repositories Kolibri OS

PORT_OPEN        equ 1

PORT_CLOSE       equ 2

PORT_RESET       equ 3

PORT_SETMODE     equ 4

PORT_GETMODE     equ 5

PORT_SETMCR      equ 6

PORT_GETMCR      equ 7

PORT_READ        equ 8

PORT_WRITE       equ 9

LCR_8BIT         equ  0x03

MCR_OUT_2        equ  0x08

io.code          equ esp+4

io.input         equ esp+8

io.inp_size      equ esp+12

io.output        equ esp+16

io.out_size      equ esp+20

;  ebx= service version

;  eax= error code

;    0= no error

;   -1= common error

init_uart:

           mov eax, 68

           mov ebx, 16

           mov ecx, szUart

           int 0x40

           test eax, eax

           jz .fail

           mov eax, esp

           xor ebx, ebx

           push eax            ;.output

           push ebx            ;.inp_size

           push ebx            ;.input

           push SRV_GETVERSION ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp

           int 0x40

           add esp, 24

           pop ebx             ;version

           ret

.fail:

           or eax, -1

           ret

;  eax= port

;

; retval

;  ebx= connection

;  eax= error code

uart_open:

           mov ebx, esp

           push eax            ;port

           mov eax, esp

           push ebx            ;.output

           push 4              ;.inp_size

           push eax            ;.input

           push PORT_OPEN      ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp

           int 0x40

           add esp, 28         ;io_control+port

           pop ebx             ;connection

           ret

;  eax= connection

;

; retval

;  eax= error code

uart_close:

           push eax            ;connection

           mov eax, esp

           xor ebx, ebx

           push ebx            ;.output

           push 4              ;.inp_size

           push eax            ;.input

           push PORT_CLOSE     ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp        ;io_contol

           int 0x40

           add esp, 24+4       ;io_control

           ret

;  eax= connection

;

; retval

;  eax= error code

uart_reset:

           push eax            ;connection

           mov eax, esp

           xor ebx, ebx

           push ebx            ;.output

           push 4              ;.inp_size

           push eax            ;.input

           push PORT_RESET     ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp        ;io_contol

           int 0x40

           add esp, 24+4       ;io_control

           ret

;  eax= connection

;  ebx= rate

;  ecx= mode

;

; retval

;  eax= error code

uart_setmode:

           push ecx            ;mode

           push ebx            ;rate

           push eax            ;connection

           mov eax, esp

           xor ecx, ecx

           push ecx            ;.output

           push 12             ;.inp_size

           push eax            ;.input

           push PORT_SETMODE   ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp        ;io_contol

           int 0x40

           add esp, 24+12      ;io_control

           ret

;  eax= connection

;  ebx= modem control value

;

; retval

;  eax= error code

uart_set_mcr:

           push ebx            ;mcr

           push eax            ;connection

           mov eax, esp

           xor ecx, ecx

           push ecx            ;.output

           push 8              ;.inp_size

           push eax            ;.input

           push PORT_SETMCR    ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp        ;io_contol

           int 0x40

           add esp, 24+8       ;io_control

           ret

;  eax= connection

;  ebx= buffer

;  ecx= size

;

; retval

;  ebx= bytes read

;  eax= error code

uart_read:

           push 0              ;bytes read

           push ecx            ;size

           push ebx            ;buffer

           push eax            ;connection

           mov eax, esp

           lea ebx, [esp+12]

           push ebx            ;.output

           push 12             ;.inp_size

           push eax            ;.input

           push PORT_READ      ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp        ;io_contol

           int 0x40

           add esp, 24+12      ;io_control

           pop ebx

           ret

;  eax= connection

;  ebx= buffer

;  ecx= size

;

; retval

;  eax= error code

uart_write:

           push ecx            ;size

           push ebx            ;buffer

           push eax            ;connection

           mov eax, esp

           xor ecx, ecx

           push ecx            ;.output

           push 12             ;.inp_size

           push eax            ;.input

           push PORT_WRITE     ;.code

           push [Uart]         ;.handle

           mov ebx, 17

           mov ecx, esp        ;io_contol

           int 0x40

           add esp, 24+12      ;io_control

           ret

Uart        rd 1