Subversion Repositories Kolibri OS

; ìàêðîñ äëÿ ñèñòåìíîé áèáëèîòåêè box_lib.obj

; ýëåìåíò TreeList äëÿ Kolibri OS

; ôàéë ïîñëåäíèé ðàç èçìåíÿëñÿ 23.11.2009 IgorA

; íà êîä ïðèìåíåíà GPL2 ëèöåíçèÿ

sizeof.TreeList equ 20

;struct TreeList

;  type dw ? ;+ 0 òèï ýëåìåíòà, èëè èíäåêñ èêîíêè äëÿ óçëà

;  lev db ?  ;+ 2 óðîâåíü ýëåìåíòà

;  clo db ?  ;+ 3 ôëàã çàêðûòèÿ, èëè îòêðûòèÿ (èìååò ñìûñë äëÿ ðîäèòåëüñêîãî óçëà)

;  perv dd ? ;+ 4 èíäåêñ ïðåäûäóùåãî ýëåìåíòà

;  next dd ? ;+ 8 èíäåêñ ïîñëåäóþùåãî ýëåìåíòà

;  tc dd ?   ;+12 âðåì. ñîçäàíèÿ

;  td dd ?   ;+16 âðåì. óäàëåíèÿ

;ends

tl_info_size  equ  word[edi +4] ;ðàçìåð äàííûõ âûäåëÿåìûõ äëÿ êàæäîãî óçëà (ïîëüçîâàòåëüñüêèå äàííûå + òåêñò äëÿ ïîäïèñè)

tl_style      equ dword[edi+10] ;ñòèëè ýëåìåíòà

tl_data_nodes equ dword[edi+14] ;óêàçàòåëü íà ñòðóêòóðû óçëîâ

tl_img_cx     equ  word[edi+22] ;øèðèíà èêîíîê

tl_img_cy     equ  word[edi+24] ;âûñîòà èêîíîê

tl_data_img_sys equ dword[edi+26] ;óêàçàòåëü íà ñèñòåìíûå èçîáðàæåíèÿ (ñòðåëêè, ïëþñèêè)

tl_ch_tim     equ dword[edi+30] ;êîëè÷åñòâî èçìåíåíèé â ôàéëå

tl_tim_undo   equ dword[edi+38] ;êîëè÷åñòâî îòìåíåííûõ äåéñòâèé

tl_cur_pos    equ dword[edi+42] ;ïîçèöèÿ êóðñîðà

tl_col_bkg    equ dword[edi+46] ;öâåò ôîíà

tl_col_zag    equ dword[edi+50] ;öâåò çàãîëîâêà

tl_col_txt    equ dword[edi+54] ;öâåò òåêñòà

tl_box_left   equ dword[edi+58]

tl_box_top    equ dword[edi+62]

tl_box_width  equ dword[edi+66]

tl_box_height equ dword[edi+70]

tl_capt_cy    equ  word[edi+74] ;âûñîòà ïîäïèñè

tl_info_capt_offs equ dword[edi+76] ;ñäâèã äëÿ íà÷àëà òåêñòà (ïîäïèñè óçëà)

tl_el_focus   equ dword[edi+80] ;óêàçàòåëü íà ñòðóêòóðó ýëåìåíòà â ôîêóñå

tl_p_scrol    equ dword[edi+84] ;óêàçàòåëü íà ñòðóêòóðó ñêðîëëèíãà

tl_sb_draw    equ dword[edi+88] ;óêàçàòåëü íà ôóíêöèþ ïåðåðèñîâûâàþùóþ ñêðîëëèíã

tl_on_press   equ dword[edi+96] ;óêàçàòåëü íà ôóíêöèþ, êîòîðàÿ âûçûâàåòñÿ ïðè íàæàòèè Enter

;êîíñòàíòû ñòèëÿ

tl_key_no_edit   equ   1b ;ýëåìåíò íåëüçÿ ðåäàêòèðîâàòü íà êëàâèàòóðå (èçìåíÿòü óðîâíè, óäàëÿòü)

tl_draw_par_line equ  10b ;ðèñîâàòü ëèíèè ê ðîäèòåëüñêîìó óçëó

tl_list_box_mode equ 100b ;ñòèëü íå îòîáðàæàåò óðîâíè (êàê â ListBox âñå îäíîãî óðîâíÿ)

;data_info	 dd ? ;+ 0 óêàçàòåëü íà îñíîâíûå äàíûå

;info_max_count dd ? ;+ 6 ìàêñèìàëüíîå êîëëè÷åñòâî ñòðóêòóð

;data_img	 dd ? ;+18 óêàçàòåëü íà èçîáðàæåíèÿ

;ls_tim		dd ? ;+34 âðåìÿ ïîñëåäíåãî ñîõðàíåíèÿ

;on_activate dd ? ;+92 óêàçàòåëü íà ôóíêöèþ ïðè àêòèâèðîâàíèè óçëà

struc tree_list info_size,info_max_count,style, img_cx,img_cy,\

    col_bkg,col_zag,col_txt, box_l,box_t,box_w,box_h, capt_cy,info_capt_offs,\

    el_focus, p_scrol,p_sb_draw,on_press {

  .data_info	dd 0

  .info_size	dw info_size

  .info_max_count dd info_max_count

  .style	    dd style

  .data_nodes	dd 0

  .data_img	 dd 0

  .img_cx	   dw img_cx

  .img_cy	   dw img_cy

  .data_img_sys	 dd 0

  .ch_tim		  dd 0

  .ls_tim		  dd 0

  .tim_undo	 dd 0

  .cur_pos	  dd 0

  .col_bkg	  dd col_bkg

  .col_zag	  dd col_zag

  .col_txt	  dd col_txt

  .box_lert   dd box_l

  .box_top    dd box_t

  .box_width  dd box_w

  .box_height dd box_h

  .capt_cy	   dw capt_cy

  .info_capt_offs dd info_capt_offs

  .el_focus dd el_focus

  .p_scrol  dd p_scrol

  .p_sb_draw dd p_sb_draw

  .on_activate dd 0

  .on_press dd on_press

}

;-----------------------------------------------------------------------------

;ôóíêöèÿ äëÿ âûäåëåíèÿ ïàìÿòè

;input:

; ecx = size data

;otput:

; eax = pointer to memory

align 4

mem_Alloc:

  push ebx

  mov eax,68

  mov ebx,12

  int 0x40

  pop ebx

  ret

;-----------------------------------------------------------------------------

;ôóíêöèÿ äëÿ îñâîáîæäåíèÿ ïàìÿòè

;input:

; ecx = pointer to memory

align 4

mem_Free:

  push eax ebx

  cmp ecx,0

  jz @f

    mov eax,68

    mov ebx,13

    int 0x40

  @@:

  pop ebx eax

  ret

macro use_tree_list

{

align 4

tl_data_init: ;âûäåëíèå ïàìÿòè äëÿ ñòðóêòóð ñïèñêà è îñíîâíîé èíôîðìàöèè (êîíñòðóêòîð)

  push ebp

  mov ebp,esp

  push eax ecx edi

    mov edi,dword[ebp+8]

    xor ecx,ecx

    mov cx,tl_info_size

    imul ecx,dword[edi+6]

    call mem_Alloc

    mov dword[edi],eax ;êîïèðóåì óêàçàòåëü íà ïîëó÷åíóþ ïàìÿòü â ñòðóêòóðó

    mov dword[edi+18],0 ;îáíóëÿåì óêàçàòåëü 'data_img'

    mov tl_data_img_sys,0 ;îáíóëÿåì óêàçàòåëü 'data_img_sys'

    mov ecx,sizeof.TreeList

    imul ecx,dword[edi+6]

    call mem_Alloc

    mov tl_data_nodes,eax ;êîïèðóåì óêàçàòåëü íà ïîëó÷åíóþ ïàìÿòü â ñòðóêòóðó

    push dword edi

    call tl_info_clear

    ;íàñòðîéêè äî÷åðíåãî ñêðîëëèíãà

    cmp tl_p_scrol,0

    je @f

      mov eax,tl_p_scrol

      ;*** öâåòîâûå íàñòðîéêè ***

      mov ecx,tl_col_bkg

      mov dword[eax+28],ecx ;+28 .bckg_col

      mov ecx,tl_col_zag

      mov dword[eax+32],ecx ;+32 .frnt_col

      mov ecx,tl_col_txt

      mov dword[eax+36],ecx ;+32 .line_col

      ;*** íàñòðîéêè ðàçìåðîâ ***

      mov ecx,tl_box_left

      add ecx,tl_box_width

      mov word[eax+2],cx

      mov ecx,tl_box_height

      mov word[eax+4],cx

      mov ecx,tl_box_top

      mov word[eax+6],cx

    @@:

  pop edi ecx eax

  pop ebp

  ret 4

align 4

tl_data_clear: ;î÷èñòêà ïàìÿòè ýëåìåíòà (äåñòðóêòîð)

  push ebp

  mov ebp,esp

    push ecx edi

    mov edi,dword[ebp+8]

    cmp dword[edi+18],0 ;data_img

    je @f

      mov ecx,dword[edi+18]

      call mem_Free ;÷èñòêà ñèñòåìíûõ èêîíîê

    @@:

    cmp tl_data_img_sys,0

    je @f

      mov ecx,tl_data_img_sys

      call mem_Free ;÷èñòêà ñèñòåìíûõ èêîíîê

    @@:

    mov ecx,dword[edi]

    call mem_Free

    mov ecx,tl_data_nodes

    call mem_Free

    pop edi ecx

  pop ebp

  ret 4

align 4

tl_info_clear: ;î÷èñòêà ñïèñêà (èíôîðìàöèè)

  push ebp

  mov ebp,esp

    push eax ecx edi

    mov edi,dword[ebp+8]

    mov tl_ch_tim,0

    mov dword[edi+34],0 ;ls_tim

    mov tl_tim_undo,0

    mov tl_cur_pos,0

    ;xor ecx,ecx

    mov ecx,sizeof.TreeList

    imul ecx,dword[edi+6]

    mov eax,tl_data_nodes

    @@:

      mov byte[eax],0 ;÷èñòèì óçëû 0-ìè

      inc eax

      loop @b

    mov eax,tl_data_nodes ;óêàçàòåëü íà 0-é óçåë

    mov dword[eax+8],1 ;óêàçàòåëü next â 0-ì óçëå ïðèðàâíèâàåì ê 1

    call tb_scrol_resize ;îáðàáîòêà ñêðîëëèíãà

    pop edi ecx eax

  pop ebp

  ret 4

align 4

tl_key: ;ðåàêöèÿ íà êëàâèàòóðó

  push ebp

  mov ebp,esp

    push ebx edi

    mov edi,dword[ebp+8]

    mov ebx,tl_el_focus

    cmp dword[ebx],edi

    jne .no_focus ;ýëåìåíò íå â ôîêóñå

    xor bx,bx

    cmp ah,13 ;Enter

    jne @f

      cmp tl_on_press,0

      je @f

        call tl_on_press

    @@:

    cmp ah,32 ;Space

    jne @f

      push dword edi

      call tl_node_close_open

    @@:

    cmp ah,178 ;Up

    jne @f

      push dword edi

      call tl_cur_perv

    @@:

    cmp ah,177 ;Down

    jne @f

      push dword edi

      call tl_cur_next

    @@:

    bt tl_style,0 ;tl_key_no_edit

    jc .no_edit

      cmp ah,176 ;Left

      jne @f

	push dword edi

	call tl_node_lev_dec

	mov bx,1

      @@:

      cmp ah,179 ;Right

      jne @f

	push dword edi

	call tl_node_lev_inc

	mov bx,1

      @@:

      cmp ah,182 ;Delete

      jne @f

	push dword edi

	call tl_node_delete

	mov bx,1

      @@:

    .no_edit:

    cmp bx,1

    jne .no_focus

      push dword edi

      call tl_draw

    .no_focus:

    pop edi ebx

  pop ebp

  ret 4

align 4

tl_mouse: ;ðåàêöèÿ íà ìûøü

  push ebp

  mov ebp,esp

    push eax ebx ecx edx edi esi

    mov edi,dword[ebp+8]

    mov eax,37

    mov ebx,2

    int 0x40

    bt eax,0 ;left mouse button press

    jae .no_draw

    mov eax,37

    mov ebx,1

    int 0x40

    mov ebx,tl_box_left

    shl ebx,16

    cmp eax,ebx ;ëåâàÿ ãðàíèöà îêíà

    jl .no_in_wnd

    mov ebx,tl_box_left

    add ebx,tl_box_width

    shl ebx,16

    cmp eax,ebx ;ïðàâàÿ ãðàíèöà îêíà

    jg .no_in_wnd

    mov ebx,tl_box_top

    add ebx,tl_box_height

    cmp ax,bx ;íèæíÿÿ ãðàíèöà îêíà

    jg .no_in_wnd

    sub ebx,tl_box_height

    add bx,tl_capt_cy

    cmp ax,bx ;âåðõíÿÿ ãðàíèöà îêíà + âûñîòà ïîäïèñè

    jl .no_in_wnd

    mov esi,tl_el_focus

    mov dword[esi],edi ;set focus

    ; if '+' or '-' press

    mov esi,eax

    shr esi,16

    sub esi,tl_box_left ;esi = mouse x coord in element window

    and eax,0xffff

    sub ax,bx

    xor edx,edx

    xor ecx,ecx

    mov cx,tl_img_cy

    div ecx

    cmp tl_p_scrol,0 ;ó÷èòûâàåì ñêðîëëèíã

    je @f

      mov edx,tl_p_scrol

      add eax,dword[edx+24] ;äîáàâëÿåì ñêðîëëèíã íà âåðõó

    @@:

    mov ecx,eax

    call tl_get_node_count ;eax = node count

    cmp eax,ecx

    jl @f

      mov eax,ecx ;åñëè êóðñîð íå âûøåë çà ïðåäåëû óçëîâ, âîññòàíàâëèâàåì ñòàðîå çíà÷åíèå eax

    @@:

    cmp eax,tl_cur_pos ;åñëè íîâîå çíà÷åíèå êóðñîðà ñîâïàëî ñ ïðåäûäóùèì

    je @f ;òî íå ñòèðàåì êóðñîð

    push esi

      mov esi,tl_box_top

      add esi,tl_box_height ;esi = coord bottom border

      call tl_draw_null_cursor ;ñòèðàåì êóðñîð

    pop esi

    @@:

    mov tl_cur_pos,eax

    ; if '+' or '-' press

    call tl_get_cur_node_index ;eax = node index

    cmp eax,2

    jl .no_open_close ;êóðñîð ñòîèò íà ïóñòîì ìåñòå, áåç óçëîâ

    imul eax,sizeof.TreeList

    add eax,tl_data_nodes

    xor bx,bx

    mov bl,byte[eax+2] ;+2 lev ñîõðàíÿåì óðîâåíü òåêóùåãî óçëà

    inc bx ;+ ïîëå äëÿ êóðñîðà

    cmp si,tl_img_cx

    jl .no_open_close ;ìûøåé ïîïàëè íà ëåâîå ïîëå äëÿ êóðñîðà, ãäå òî÷íî íåò '+' è '-'

      mov eax,esi

      xor edx,edx

      xor ecx,ecx

      mov cx,tl_img_cx

      div ecx

      cmp ax,bx

      jne .no_open_close

      push dword edi

      call tl_node_close_open

    .no_open_close:

      mov esi,tl_box_top

      add esi,tl_box_height ;esi = coord bottom border

      call tl_draw_cursor ;ïåðåðèñîâêà êóðñîðà

      jmp .no_draw

    .no_in_wnd: ;íå ïîïàëè â îêíî - ïîòåðÿ ôîêóñà (ïðè óñëîâèè ÷òî ôîêóñ áûë íà äàííîì ýåëåìåíòå)

      mov ebx,tl_el_focus

      cmp dword[ebx],edi

      jne .no_draw ;ýëåìåíò íå â ôîêóñå

        mov dword[ebx],0 ;reset focus

    .no_draw:

    pop esi edi edx ecx ebx eax

  pop ebp

  ret 4

align 4

tl_info_undo: ;îòìåíà äåéñòâèÿ

  push ebp

  mov ebp,esp

  push eax edi

    mov edi,dword[ebp+8]

    mov eax,tl_tim_undo

    cmp tl_ch_tim,eax

    jbe @f

      inc tl_tim_undo

      call tb_scrol_resize ;îáðàáîòêà ñêðîëëèíãà

    @@:

  pop edi eax

  pop ebp

  ret 4

align 4

tl_info_redo: ;ïîâòîð äåéñòâèÿ

  push ebp

  mov ebp,esp

  push edi

    mov edi,dword[ebp+8]

    cmp tl_tim_undo,1

    jl @f

      dec tl_tim_undo

      call tb_scrol_resize ;îáðàáîòêà ñêðîëëèíãà

    @@:

  pop edi

  pop ebp

  ret 4

align 4

tl_info_set_undo: ;óäàëåíèå îòìåíåííûõ äåéñòâèé

;  push ebp

;  mov ebp,esp

;  push edi

;    mov edi,dword[ebp+8]

;  mov [dragk],0 ;çàêàí÷èâàåì âûäåëåíèå îò êëàâèàòóðû

  cmp tl_tim_undo,1

  jl .no_work

  push eax ebx ecx edx

  mov edx,tl_data_nodes

  mov ecx,edx

  add ecx,sizeof.TreeList

  call tl_move_next ;long i=node[0].next;

  mov eax,tl_tim_undo

  sub tl_ch_tim,eax ;ch_tim-=tim_undo;

  mov eax,tl_ch_tim

  cmp [edi+34],eax ;if(ls_tim>ch_tim)

  jle @f

    mov dword[edi+34],0 ;ls_tim=0

  @@:

    cmp edx,ecx

    jle @f

    ;if(node[i].tc>ch_tim){ // åñëè ñîçäàíèå ñèìâîëà áûëî îòìåíåíî

    cmp dword[edx+12],eax

    jle .no_u1

      mov dword[edx+12],0

      mov dword[edx+16],0

      mov ebx, dword[edx+4]

      imul ebx,sizeof.TreeList

      add ebx, tl_data_nodes ;.next

      push dword[edx+8] ;node[node[i].perv].next=node[i].next;

      pop dword[ebx+8]

      mov ebx, dword[edx+8]

      imul ebx,sizeof.TreeList

      add ebx, tl_data_nodes ;.perv

      push dword[edx+4] ;node[node[i].next].perv=node[i].perv;

      pop dword[ebx+4]

    .no_u1:

    ;else if(node[i].td>ch_tim) node[i].td=0; // åñëè óäàëåíèå ñèìâîëà áûëî îòìåíåíî

    cmp dword[edx+16],eax

    jle .no_u2

      mov dword[edx+16],0

    .no_u2:

    call tl_move_next

    jmp @b

  @@:

  mov tl_tim_undo,0

;  mov eax,[edi+?] ;co_tim

;  cmp tl_ch_tim,eax ;ch_tim

;  jge @f

;    mov [edi+?],0 ;co_tim

;  @@:

  pop edx ecx ebx eax

  .no_work:

;  pop edi

;  pop ebp

;  ret 4

  ret

align 4

tl_draw: ;âûâîä ñïèñêà íà ýêðàí

  push ebp

  mov ebp,esp

    push eax ebx ecx edx edi esi

    ;draw dir_list main rect

    mov edi,dword[ebp+8]

    mov ebx,tl_box_left

    shl ebx,16

    add ebx,tl_box_width

    mov ecx,tl_box_top

    shl ecx,16

    mov cx,tl_capt_cy

    mov edx,tl_col_zag

    mov eax,13

    int 0x40 ;draw window caption

    add ecx,tl_box_top

    shl ecx,16

    add ecx,tl_box_height

    sub cx,tl_capt_cy

    mov edx,tl_col_bkg

    int 0x40 ;draw window client rect

    cmp tl_capt_cy,9 ;9 - minimum caption height

    jl @f

    mov eax,4 ;draw text captions

    mov ebx,tl_box_left

    shl ebx,16

    add ebx,5*65536+3

    add ebx,tl_box_top

    mov ecx,tl_col_txt

    or	ecx,0x80000000

    lea edx,[txt_capt_cur]

    int 0x40

    mov ebx,tl_box_left

    shl ebx,16

    add ebx,100*65536+3

    add ebx,tl_box_top

    lea edx,[txt_capt_otm]

    int 0x40

    mov eax,47 ;draw

    mov ebx,0x40000

    mov ecx,tl_cur_pos

  inc ecx

    mov edx,tl_box_left

    shl edx,16

    add edx,50*65536+3

    add edx,tl_box_top

    mov esi,tl_col_txt

    int 0x40

    mov ecx,tl_tim_undo

    mov edx,tl_box_left

    shl edx,16

    add edx,140*65536+3

    add edx,tl_box_top

    mov esi,tl_col_txt

    int 0x40

    @@:

;---debug---

;mov ecx,0

;@@:

;call DebugSymb

;inc ecx

;cmp ecx,10

;jge @f

;jmp @b

;@@:

;---debug---

    ;cycle to nodes

    xor eax,eax

    mov edx,tl_data_nodes

    mov ecx,edx

    add ecx,sizeof.TreeList

    ;*** ïðîïóñê óçëîâ, êîòîðûå ïðîìîòàíû ñêðîëëèíãîì ***

    cmp tl_p_scrol,0 ;åñëè åñòü óêàçàòåëü íà ñêðîëëèíã

    je .end_c1

    mov esi,tl_p_scrol

    cmp dword[esi+24],0 ;åñëè ñêðîëëèíã íà âåðõó, âûõîäèì

    je .end_c1

      @@:

	call tl_iterat_next

	cmp edx,ecx

	jle .end_draw

	inc eax

	cmp eax,dword[esi+24]

	jge .end_c1

	jmp @b

    .end_c1:

    xor eax,eax

    mov esi,tl_box_top

    add esi,tl_box_height ;esi = coord bottom border

    @@:

      call tl_iterat_next

      cmp edx,ecx

      jle @f

      call tl_draw_node

      inc eax

      jmp @b

    @@:

    call tl_draw_cursor

    .end_draw:

    pop esi edi edx ecx ebx eax

  pop ebp

  ret 4

;input:

; ecx = pointer to 1 node struct

; edx = pointer to some node struct

; edi = pointer to 'TreeList' struct

align 4

tl_iterat_next:

  push bx

  mov bl,0x7f

  cmp byte[edx+3],1

  jne @f

    mov bl,byte[edx+2]

  @@:

  cmp tl_tim_undo,0

  je .else

  push eax

  .beg0:

    call tl_move_next

    cmp edx,ecx

    jle @f

    call tl_node_not_vis ;ïðîïóñê óäàëåííûõ è îòìåíåííûõ

    cmp al,1

    je .beg0

    cmp bl,byte[edx+2] ;ïðîïóñê çàêðûòûõ

    jl .beg0

  @@:

  pop eax

  pop bx

  ret

  .else:

    call tl_move_next

    cmp edx,ecx

    jle .endif

    cmp dword[edx+16],0 ;td = 'time delete' -> ïðîïóñê óäàëåííûõ

    jne .else

    cmp bl,byte[edx+2] ;ïðîïóñê çàêðûòûõ

    jl .else

  .endif:

  pop bx

  ret

;input:

; ecx = pointer to 1 node struct

; edx = pointer to some node struct

; edi = pointer to 'TreeList' struct

align 4

tl_iterat_next_all:

  cmp tl_tim_undo,0

  je .else

  push eax

  @@:

    call tl_move_next

    cmp edx,ecx

    jle @f

    call tl_node_not_vis

    cmp al,1

    je @b

  @@:

  pop eax

  ret

  .else:

    call tl_move_next

    cmp edx,ecx

    jle .endif

    cmp dword[edx+16],0 ;td -> time delete

    jne .else

  .endif:

  ret

;input:

; ecx = pointer to 1 node struct

; edx = pointer to some node struct

; edi = pointer to 'TreeList' struct

align 4

tl_iterat_perv:

  push bx

  mov bl,0x7f

  cmp byte[edx+3],1

  jne @f

    mov bl,byte[edx+2]

  @@:

  cmp tl_tim_undo,0

  je .else

  push eax

  .beg0:

    call tl_move_perv

    cmp edx,ecx

    jle @f

    call tl_node_not_vis ;ïðîïóñê óäàëåííûõ è îòìåíåííûõ

    cmp al,1

    je .beg0

    cmp bl,byte[edx+2] ;ïðîïóñê çàêðûòûõ

    jl .beg0

  @@:

  pop eax

  pop bx

  ret

  .else:

    call tl_move_perv

    cmp edx,ecx

    jle .endif

    cmp dword[edx+16],0 ;td = 'time delete' -> ïðîïóñê óäàëåííûõ

    jne .else

    cmp bl,byte[edx+2] ;ïðîïóñê çàêðûòûõ

    jl .else

  .endif:

  pop bx

  ret

;input:

; edx = pointer to some node struct

; edi = pointer to 'TreeList' struct

;output:

; edx = pointer to next node struct

align 4

tl_move_next:

  mov edx,dword[edx+8]

  imul edx,sizeof.TreeList

  add edx,tl_data_nodes

  ret

;input:

; edx = pointer to some node struct

; edi = pointer to 'TreeList' struct

;output:

; edx = pointer to perv node struct

align 4

tl_move_perv:

  mov edx,dword[edx+4]

  imul edx,sizeof.TreeList

  add edx,tl_data_nodes

  ret

;input:

; edx = pointer to symbol struct

; edi = pointer to 'TreeList' struct

;output:

; al = 1 if sumbol not visible

; (node[i].td+tim_Undo<=ch_tim && node[i].td) || (node[i].tc>ch_tim-tim_Undo)

align 4

tl_node_not_vis:

  cmp dword[edx+16],0

  je @f

  mov eax,dword[edx+16] ;eax=node[i].td

  add eax,tl_tim_undo

  cmp eax,tl_ch_tim

  jg @f

    mov al,1

    ret

  @@:

  mov eax,tl_ch_tim

  sub eax,tl_tim_undo

  cmp dword[edx+12],eax ;tc -> time create

  jle @f

    mov al,1

    ret

  @@:

  xor al,al

  ret

;input:

; edi = pointer to TreeInfo struct

; esi = coord bottom border

align 4

tl_draw_cursor: ;ðèñóåì êóðñîð íà ýêðàíå

  push eax ebx ecx edx esi

    call tl_get_display_cur_pos ;eax = cursor pos in screen

    cmp eax,0

    jl .end_f ;êóðñîð íàõîäèòñÿ âûøå îêíà, â îáëàñòè ïðîêðó÷åííîé ñêðîëëèíãîì

    cmp tl_data_img_sys,0 ;ñìîòðèì åñòü ëè óêàçàòåëü íà êàðòèíêó ñèñòåìíûõ èêîíîê

    jne @f

      mov ebx,tl_box_left

      shl ebx,16

      mov bx,tl_img_cx

      xor ecx,ecx

      mov cx,tl_img_cy

      imul ecx,eax

      add ecx,tl_box_top

      add cx,tl_capt_cy

      ;crop image if on the border

      cmp esi,ecx ;åñëè êóðñîð âíèçó è åãî âîîáùå íå âèäíî

      jl .end_f

      sub esi,ecx

      shl ecx,16

      mov cx,tl_img_cy

      cmp si,tl_img_cy

      jge .crop0

        mov cx,si ;åñëè êóðñîð âèäåí ÷àñòè÷íî (ïîïàë íà íèæíþþ ãðàíèöó)

      .crop0:

      mov edx,tl_col_txt

      mov eax,13

      int 0x40 ;ðèñóåì ïðîñòîé ïðÿìîóãîëüíèê, ò.ê. íåò ñèñòåìíûõ èêîíîê

      jmp .end_f

    @@:

      mov ebx,tl_data_img_sys

      imul ax,tl_img_cy

      mov cx,tl_img_cx

      shl ecx,16

      mov cx,tl_img_cy

      mov edx,tl_box_left

      shl edx,16

      mov dx,ax

      add edx,tl_box_top

      add dx,tl_capt_cy

      ;crop image if on the border

      cmp si,dx ;åñëè êóðñîð âíèçó è åãî âîîáùå íå âèäíî

      jl .end_f

      sub si,dx

      cmp si,tl_img_cy

      jge .crop1

	mov cx,si ;åñëè êóðñîð âèäåí ÷àñòè÷íî (ïîïàë íà íèæíþþ ãðàíèöó)

      .crop1:

      mov eax,7

      int 0x40 ;ðèñóåì èêîíêó êóðñîðà

    .end_f:

  pop esi edx ecx ebx eax

  ret

;input:

; edi = pointer to TreeInfo struct

; esi = coord bottom border

align 4

tl_draw_null_cursor: ;ñòèðàåì êóðñîð íà ýêðàíå

  push eax ebx ecx edx esi

    call tl_get_display_cur_pos ;eax = cursor pos in screen

    cmp eax,0

    jl .end_f ;êóðñîð íàõîäèòñÿ âûøå îêíà, â îáëàñòè ïðîêðó÷åííîé ñêðîëëèíãîì

    mov ebx,tl_box_left

    shl ebx,16

    mov bx,tl_img_cx

    xor ecx,ecx

    mov cx,tl_img_cy

    imul ecx,eax

    add ecx,tl_box_top

    add cx,tl_capt_cy

    ;crop image if on the border

    cmp esi,ecx ;åñëè êóðñîð âíèçó è åãî âîîáùå íå âèäíî

    jl .end_f

    sub esi,ecx

    shl ecx,16

    mov cx,tl_img_cy

    cmp si,tl_img_cy

    jge @f

      mov cx,si ;åñëè êóðñîð âèäåí ÷àñòè÷íî (ïîïàë íà íèæíþþ ãðàíèöó)

    @@:

    mov edx,tl_col_bkg

    mov eax,13

    int 0x40 ;ðèñóåì ïðîñòîé ïðÿìîóãîëüíèê ñ ôîíîâûì öâåòîì

    .end_f:

  pop esi edx ecx ebx eax

  ret

;input:

; edi = pointer to TreeInfo struct

;output:

; eax = index

align 4

tl_get_display_cur_pos: ;áåðåò ïîçèöèþ êóðñîðà, îòíîñèòåëüíî ýêðàíà

   mov eax,tl_cur_pos

   cmp tl_p_scrol,0

   je @f

     push ebx

       mov ebx,tl_p_scrol

       mov ebx,dword[ebx+24]

       sub eax,ebx ;îòíèìàåì ïîçèöèþ ñêðîëëèíãà

     pop ebx

  @@:

  ret

;input:

; eax = node position

; edx = pointer to some node struct

; edi = pointer to TreeInfo struct

; esi = coord of bottom border

align 4

tl_draw_node:

  push eax ebx ecx edx esi

    mov ebx,1 ;1 - ìåñòî ïîä êóðñîð è ïîä çíàê +,-

    bt tl_style,2 ;tl_list_box_mode

    jc @f

      inc ebx ;+1 - ìåñòî ïîä çíàê +,-

    @@:

    add bl,byte[edx+2];get level

    imul bx,tl_img_cx

    add ebx,tl_box_left

    shl ebx,16

    mov bx,tl_img_cx

    xor ecx,ecx

    mov cx,tl_img_cy

    imul ecx,eax

    add ecx,tl_box_top

    add cx,tl_capt_cy

    ;crop image if on the border

    cmp esi,ecx ;åñëè óçåë âíèçó è åãî âîîáùå íå âèäíî

    jl .end_draw

    sub esi,ecx

    shl ecx,16

    mov cx,tl_img_cy

    cmp si,tl_img_cy

    jge @f

      mov cx,si ;åñëè óçåë âèäåí ÷àñòè÷íî (ïîïàë íà íèæíþþ ãðàíèöó)

      jmp .crop ;ïðîïóñêàåì ðèñîâàíèå íàäïèñè, êîòîðàÿ ñêîðåå âñåãî òîæå âûëåçåò çà íèæíþþ ãðàíèöó

    @@:

      call tl_draw_node_caption

    .crop:

    mov esi,ecx ;save ecx

    cmp dword[edi+18],0 ;data_img

    jne .draw_img_n

    push edx

      mov edx,tl_col_txt

      mov eax,13

      int 0x40 ;draw node rect

    pop edx

    jmp @f

    .draw_img_n:

    push ebx edx esi

      xor esi,esi

      mov si,word[edx] ;get icon type

      mov edx,ebx

      ror ecx,16

      mov dx,cx

      mov cx,bx

      ror ecx,16

      mov ebx,3 ;rgb = 3 bytes

      imul bx,tl_img_cx

      imul bx,tl_img_cy

      imul ebx,esi ;esi = icon index

      add ebx,dword[edi+18] ;data_img

      mov eax,7

      int 0x40 ;draw node icon '-'

    pop esi edx ebx

    @@:

    mov al,byte[edx+2] ;draw minus '-'

    mov ecx,tl_data_nodes

    add ecx,sizeof.TreeList

    mov ah,10 ;get icon index '+' or '-' ?

    cmp byte[edx+3],1

    jne .close

      dec ah

    .close:

    call tl_draw_node_icon_opn_clo

    bt tl_style,1

    jae .end_draw

      call tl_draw_node_icon_par_lin

    .end_draw:

  pop esi edx ecx ebx eax

  ret

;input:

; ecx = pointer to 1 node struct

;...

align 4

tl_draw_node_icon_opn_clo:

  push eax ebx ecx edx esi

    inc al

    call tl_iterat_next_all ;get next visible item

    cmp edx,ecx

    jle @f

      mov ecx,esi ;load ecx

      cmp al,byte[edx+2]

      jne @f

      ror ebx,16

      sub bx,tl_img_cx

      ror ebx,16

      cmp tl_data_img_sys,0

      jne .draw_img_s

	mov edx,tl_col_txt

	mov eax,13

	int 0x40 ;draw minus rect, if not system icons

	jmp @f

      .draw_img_s:

      mov ecx,esi ;load ecx

      mov edx,ebx

      ror ecx,16

      mov dx,cx

      mov cx,bx

      ror ecx,16

      mov ebx,3 ;rgb = 3 bytes

      imul bx,tl_img_cx

      imul bx,tl_img_cy

      shr eax,8

      and eax,0xff

      imul ebx,eax ;eax = icon index

      add ebx,tl_data_img_sys

      mov eax,7

      int 0x40 ;draw minus icon '-'

    @@:

  pop esi edx ecx ebx eax

  ret

;input:

;...

align 4

tl_draw_node_icon_par_lin:

  cmp byte[edx+3],1

  je .close

  push eax ebx ecx edx esi

    cmp al,0

    je @f

;    dec al

;    call tl_iterat_perv ;get perv visible item

    call tl_iterat_next_all ;get next visible item

    cmp edx,ecx

    jle .line3 ;if end of list

      cmp al,byte[edx+2]

      jne .line3 ;jg ???

      mov eax,3 ;line in middle element

      jmp .line2

    .line3:

      mov eax,6 ;line in end element

    .line2:

      mov ecx,esi ;load ecx

      ror ebx,16

      sub bx,tl_img_cx

      ror ebx,16

      cmp tl_data_img_sys,0

      jne .draw_img_s

	mov edx,tl_col_txt

	mov eax,13

	int 0x40 ;draw minus rect, if not system icons

	jmp @f

      .draw_img_s:

      mov ecx,esi ;load ecx

      mov edx,ebx

      ror ecx,16

      mov dx,cx

      mov cx,bx

      ror ecx,16

      mov ebx,3 ;rgb = 3 bytes

      imul bx,tl_img_cx

      imul bx,tl_img_cy

;      shr eax,8

;      and eax,0xff

      imul ebx,eax ;eax = icon index

      add ebx,tl_data_img_sys

      mov eax,7

      int 0x40 ;draw line icon

    @@:

  pop esi edx ecx ebx eax

  .close:

  ret

;input:

; edi = pointer to TreeInfo struct

;output:

; eax = rows

align 4

tl_get_rows_count:

  push ecx edx

    mov eax,tl_box_height

    sub ax,tl_capt_cy

    xor ecx,ecx

    mov cx,tl_img_cy

    xor edx,edx

    div ecx

  pop edx ecx

  ret

;input:

; eax = node position

; ebx = [êîîðäèíàòà ïî îñè x]*65536 + [img_cx]

; ecx = [êîîðäèíàòà ïî îñè y]*65536 + [img_cy]

; edx = pointer to some node struct

; edi = pointer to TreeInfo struct

align 4

tl_draw_node_caption:

    push ebx ecx edx esi

    xor esi,esi

    mov si,tl_info_size

    cmp esi,tl_info_capt_offs

    jle @f ;if caption size <= 0

    push eax

      call tl_get_node_index ;eax = node index

      imul esi,eax

    pop eax

      add esi,dword[edi]