WebSVN – Kolibri OS – Blame – /kernel/trunk/network/tcp_output.inc

Rev	Author	Line No.	Line
3545	hidnplayr	1	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
		2	;; ;;
6909	hidnplayr	3	;; Copyright (C) KolibriOS team 2004-2017. All rights reserved. ;;
3545	hidnplayr	4	;; Distributed under terms of the GNU General Public License ;;
		5	;; ;;
		6	;; Part of the TCP/IP network stack for KolibriOS ;;
		7	;; ;;
		8	;; Written by hidnplayr@kolibrios.org ;;
		9	;; ;;
		10	;; Based on the code of 4.4BSD ;;
		11	;; ;;
		12	;; GNU GENERAL PUBLIC LICENSE ;;
		13	;; Version 2, June 1991 ;;
		14	;; ;;
		15	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
		16
4850	mario79	17	$Revision: 6914 $
3545	hidnplayr	18
6476	hidnplayr	19	TCP_BIT_SENDALOT = 1 shl 0
		20
5976	hidnplayr	21	;-----------------------------------------------------------------;
		22	; ;
6011	hidnplayr	23	; tcp_output ;
5976	hidnplayr	24	; ;
		25	; IN: eax = socket pointer ;
		26	; ;
		27	; OUT: eax = 0 on success/errorcode ;
		28	; ;
		29	;-----------------------------------------------------------------;
3545	hidnplayr	30	align 4
6011	hidnplayr	31	proc tcp_output
3545	hidnplayr	32
4347	hidnplayr	33	locals
		34	temp_bits db ?
6474	hidnplayr	35	window dd ?
4347	hidnplayr	36	endl
		37
4366	hidnplayr	38	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: socket=%x state=%u\n", eax, [eax + TCP_SOCKET.t_state]
3545	hidnplayr	39
		40	push eax
		41	lea ecx, [eax + SOCKET.mutex]
		42	call mutex_lock
		43	pop eax
		44
3652	hidnplayr	45	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: socket locked\n"
		46
3545	hidnplayr	47	; We'll detect the length of the data to be transmitted, and flags to be used
		48	; If there is some data, or any critical controls to send (SYN / RST), then transmit
		49	; Otherwise, investigate further
		50
		51	mov ebx, [eax + TCP_SOCKET.SND_MAX]
		52	cmp ebx, [eax + TCP_SOCKET.SND_UNA]
		53	jbe .not_idle
		54
		55	mov ebx, [eax + TCP_SOCKET.t_idle]
		56	cmp ebx, [eax + TCP_SOCKET.t_rxtcur]
		57	jbe .not_idle
		58
		59	; We have been idle for a while and no ACKS are expected to clock out any data we send..
		60	; Slow start to get ack "clock" running again.
		61
		62	mov ebx, [eax + TCP_SOCKET.t_maxseg]
		63	mov [eax + TCP_SOCKET.SND_CWND], ebx
		64
		65	.not_idle:
		66	.again:
4347	hidnplayr	67	mov [temp_bits], 0
3545	hidnplayr	68
6476	hidnplayr	69	; Calculate offset
3545	hidnplayr	70
6476	hidnplayr	71	mov ebx, [eax + TCP_SOCKET.SND_NXT]
		72	sub ebx, [eax + TCP_SOCKET.SND_UNA]
3545	hidnplayr	73
6476	hidnplayr	74	; Determine window
3545	hidnplayr	75
6476	hidnplayr	76	mov ecx, [eax + TCP_SOCKET.SND_WND]
		77	cmp ecx, [eax + TCP_SOCKET.SND_CWND]
		78	jb @f
		79	mov ecx, [eax + TCP_SOCKET.SND_CWND]
		80	@@:
		81
		82	; get flags in dl
		83
		84	call tcp_outflags
		85
3545	hidnplayr	86	;------------------------
		87	; data being forced out ?
		88
		89	; If in persist timeout with window of 0, send 1 byte.
		90	; Otherwise, if window is small but nonzero, and timer expired,
		91	; we will send what we can and go to transmit state
		92
		93	cmp [eax + TCP_SOCKET.t_force], 0
		94	je .no_force
		95
3556	hidnplayr	96	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: forcing data out\n"
3545	hidnplayr	97
		98	test ecx, ecx
		99	jnz .no_zero_window
		100
		101	cmp ebx, [eax + STREAM_SOCKET.snd.size]
		102	jae @f
		103	and dl, not (TH_FIN)
5442	hidnplayr	104	@@:
3545	hidnplayr	105
		106	inc ecx
		107	jmp .no_force
		108
		109	.no_zero_window:
3603	hidnplayr	110	and [eax + TCP_SOCKET.timer_flags], not timer_flag_persist
3545	hidnplayr	111	mov [eax + TCP_SOCKET.t_rxtshift], 0
		112
		113	.no_force:
		114
		115	;--------------------------------
6476	hidnplayr	116	; Calculate how much data to send
3545	hidnplayr	117
		118	mov esi, [eax + STREAM_SOCKET.snd.size]
		119	cmp esi, ecx
		120	jb @f
		121	mov esi, ecx
		122	@@:
		123	sub esi, ebx
		124
		125	;------------------------
6476	hidnplayr	126	; check for window shrink
3545	hidnplayr	127
6476	hidnplayr	128	; If FIN has been sent, but not ACKed, but we havent been called to retransmit, esi will be -1
3545	hidnplayr	129	; Otherwise, window shrank after we sent into it.
		130
		131	jae .not_persist
		132
		133	; enter persist state
6476	hidnplayr	134
3545	hidnplayr	135	xor esi, esi
		136
		137	; If window shrank to 0
6476	hidnplayr	138
3545	hidnplayr	139	test ecx, ecx
		140	jnz @f
		141
		142	; cancel pending retransmit
6476	hidnplayr	143
3603	hidnplayr	144	and [eax + TCP_SOCKET.timer_flags], not timer_flag_retransmission
3545	hidnplayr	145
		146	; pull SND_NXT back to (closed) window, We will enter persist state below.
6476	hidnplayr	147
3545	hidnplayr	148	push [eax + TCP_SOCKET.SND_UNA]
		149	pop [eax + TCP_SOCKET.SND_NXT]
		150	@@:
		151
		152	; If window didn't close completely, just wait for an ACK
		153
		154	.not_persist:
		155
		156	;---------------------------
6476	hidnplayr	157	; Send one segment at a time
3545	hidnplayr	158
		159	cmp esi, [eax + TCP_SOCKET.t_maxseg]
		160	jbe @f
		161	mov esi, [eax + TCP_SOCKET.t_maxseg]
4347	hidnplayr	162	or [temp_bits], TCP_BIT_SENDALOT
3545	hidnplayr	163	@@:
		164
		165	;--------------------------------------------
6476	hidnplayr	166	; Turn of FIN flag if send buffer not emptied
3545	hidnplayr	167
		168	mov edi, [eax + TCP_SOCKET.SND_NXT]
		169	add edi, esi
		170	sub edi, [eax + TCP_SOCKET.SND_UNA]
		171	cmp edi, [eax + STREAM_SOCKET.snd.size]
		172	jae @f
		173	and dl, not (TH_FIN)
		174	@@:
		175
		176	;-------------------------------
6476	hidnplayr	177	; calculate window advertisement
3545	hidnplayr	178
6413	hidnplayr	179	mov ecx, SOCKET_BUFFER_SIZE
3545	hidnplayr	180	sub ecx, [eax + STREAM_SOCKET.rcv.size]
		181
		182	;------------------------------
6476	hidnplayr	183	; Sender silly window avoidance
3545	hidnplayr	184
		185	test esi, esi
		186	jz .len_zero
		187
		188	cmp esi, [eax + TCP_SOCKET.t_maxseg]
4387	hidnplayr	189	je .send
3545	hidnplayr	190
		191	add ebx, esi ; offset + length
		192	cmp ebx, [eax + STREAM_SOCKET.snd.size]
		193	jb @f
		194
		195	test [eax + TCP_SOCKET.t_flags], TF_NODELAY
4387	hidnplayr	196	jnz .send
3545	hidnplayr	197
		198	mov ebx, [eax + TCP_SOCKET.SND_MAX]
		199	cmp ebx, [eax + TCP_SOCKET.SND_UNA]
4387	hidnplayr	200	je .send
3545	hidnplayr	201	@@:
		202
		203	test [eax + TCP_SOCKET.t_force], -1 ;;;
4387	hidnplayr	204	jnz .send
3545	hidnplayr	205
		206	mov ebx, [eax + TCP_SOCKET.max_sndwnd]
		207	shr ebx, 1
		208	cmp esi, ebx
4387	hidnplayr	209	jae .send
3545	hidnplayr	210
		211	mov ebx, [eax + TCP_SOCKET.SND_NXT]
		212	cmp ebx, [eax + TCP_SOCKET.SND_MAX]
4387	hidnplayr	213	jb .send
3545	hidnplayr	214
		215	.len_zero:
		216
		217	;----------------------------------------
6476	hidnplayr	218	; Check if a window update should be sent
3545	hidnplayr	219
3556	hidnplayr	220	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: window=%d\n", ecx
3545	hidnplayr	221
		222	; Compare available window to amount of window known to peer (as advertised window less next expected input)
		223	; If the difference is at least two max size segments, or at least 50% of the maximum possible window,
		224	; Then we want to send a window update to the peer.
		225
		226	test ecx, ecx
		227	jz .no_window
		228
		229	push ecx
		230	mov cl, [eax + TCP_SOCKET.RCV_SCALE]
		231	mov ebx, TCP_max_win
		232	shl ebx, cl
		233	pop ecx
3652	hidnplayr	234
3545	hidnplayr	235	cmp ebx, ecx
		236	jb @f
		237	mov ebx, ecx
		238	@@:
		239	sub ebx, [eax + TCP_SOCKET.RCV_ADV]
		240	add ebx, [eax + TCP_SOCKET.RCV_NXT]
		241
6476	hidnplayr	242	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: we can increase window by %d bytes\n", ebx
		243
3545	hidnplayr	244	mov edi, [eax + TCP_SOCKET.t_maxseg]
		245	shl edi, 1
4387	hidnplayr	246	cmp ebx, edi
		247	jae .send
3545	hidnplayr	248
4387	hidnplayr	249	shl ebx, 1
3545	hidnplayr	250	; cmp ebx, [eax + TCP_SOCKET.] ;;; TODO: check with receive buffer high water mark
		251	; jae TCP_send
		252
		253	.no_window:
		254
		255	;--------------------------
6476	hidnplayr	256	; Should a segment be sent?
3545	hidnplayr	257
6476	hidnplayr	258	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: Should a segment be sent?\n"
		259
3545	hidnplayr	260	test [eax + TCP_SOCKET.t_flags], TF_ACKNOW ; we need to ACK
4387	hidnplayr	261	jnz .send
3545	hidnplayr	262
		263	test dl, TH_SYN + TH_RST ; we need to send a SYN or RST
4387	hidnplayr	264	jnz .send
3545	hidnplayr	265
		266	mov ebx, [eax + TCP_SOCKET.SND_UP] ; when urgent pointer is beyond start of send bufer
		267	cmp ebx, [eax + TCP_SOCKET.SND_UNA]
4387	hidnplayr	268	ja .send
3545	hidnplayr	269
6476	hidnplayr	270	; Do we need to send a FIN according to our state?
		271
3545	hidnplayr	272	test dl, TH_FIN
6476	hidnplayr	273	jz .enter_persist ; no reason to send, enter persist state
3545	hidnplayr	274
6476	hidnplayr	275	; Do so if we didnt do it already
3545	hidnplayr	276
		277	test [eax + TCP_SOCKET.t_flags], TF_SENTFIN
4387	hidnplayr	278	jz .send
3545	hidnplayr	279
6476	hidnplayr	280	; Or when we need to retransmit the FIN
		281
3545	hidnplayr	282	mov ebx, [eax + TCP_SOCKET.SND_NXT]
		283	cmp ebx, [eax + TCP_SOCKET.SND_UNA]
4387	hidnplayr	284	je .send
3545	hidnplayr	285
		286	;--------------------
6476	hidnplayr	287	; Enter persist state
3545	hidnplayr	288
		289	.enter_persist:
		290
3600	hidnplayr	291	cmp [eax + STREAM_SOCKET.snd.size], 0 ; Data ready to send?
3545	hidnplayr	292	jne @f
3603	hidnplayr	293	and [eax + TCP_SOCKET.timer_flags], not timer_flag_retransmission
3545	hidnplayr	294	jne @f
		295
3603	hidnplayr	296	test [eax + TCP_SOCKET.timer_flags], timer_flag_persist ; Persist timer already expired?
3600	hidnplayr	297	jnz @f
		298
3556	hidnplayr	299	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: Entering persist state\n"
3545	hidnplayr	300
		301	mov [eax + TCP_SOCKET.t_rxtshift], 0
6011	hidnplayr	302	call tcp_set_persist
3545	hidnplayr	303	@@:
		304
		305	;----------------------------
6476	hidnplayr	306	; No reason to send a segment
3545	hidnplayr	307
3556	hidnplayr	308	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_output: No reason to send a segment\n"
3545	hidnplayr	309
		310	pusha
		311	lea ecx, [eax + SOCKET.mutex]
		312	call mutex_unlock
		313	popa
		314
6914	hidnplayr	315	xor eax, eax
3545	hidnplayr	316	ret
		317
		318
		319	;-----------------------------------------------
		320	;
6476	hidnplayr	321	; Send a segment
3545	hidnplayr	322	;
		323	; eax = socket pointer
		324	; esi = data len
		325	; dl = flags
		326	;
		327	;-----------------------------------------------
4387	hidnplayr	328	.send:
3545	hidnplayr	329
3556	hidnplayr	330	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: socket=%x length=%u flags=%x\n", eax, esi, dl
3545	hidnplayr	331
		332	push eax ; save socket ptr
		333	push esi ; and data length too
		334	mov edi, sizeof.TCP_header ; edi will contain headersize
		335
		336	;------------------------------------
		337	; Send options with first SYN segment
		338
		339	test dl, TH_SYN
		340	jz .options_done
		341
		342	push [eax + TCP_SOCKET.ISS]
		343	pop [eax + TCP_SOCKET.SND_NXT]
		344
		345	test [eax + TCP_SOCKET.t_flags], TF_NOOPT
		346	jnz .options_done
		347
		348	mov ecx, 1460 ;;;; FIXME: use routing blablabla to determine MSS
		349	or ecx, TCP_OPT_MAXSEG shl 24 + 4 shl 16
		350	bswap ecx
		351	push ecx
		352	add di, 4
		353
3556	hidnplayr	354	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: added maxseg option\n"
3545	hidnplayr	355
		356	test [eax + TCP_SOCKET.t_flags], TF_REQ_SCALE
		357	jz .no_scale
		358
		359	test dl, TH_ACK
		360	jz .scale_opt
		361
		362	test [eax + TCP_SOCKET.t_flags], TF_RCVD_SCALE
		363	jz .no_scale
		364
		365	.scale_opt:
		366	mov cl, [eax + TCP_SOCKET.request_r_scale]
		367	mov ch, TCP_OPT_NOP
		368	pushw cx
		369	pushw TCP_OPT_WINDOW + 3 shl 8
		370	add di, 4
		371
3556	hidnplayr	372	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: added scale option\n"
3545	hidnplayr	373
		374	.no_scale:
		375	.no_syn:
		376
		377	;------------------------------------
		378	; Make the timestamp option if needed
		379
		380	test [eax + TCP_SOCKET.t_flags], TF_REQ_TSTMP
		381	jz .no_timestamp
		382
		383	test dl, TH_RST
		384	jnz .no_timestamp
		385
		386	test dl, TH_ACK
		387	jz .timestamp
		388
		389	test [eax + TCP_SOCKET.t_flags], TF_RCVD_TSTMP
		390	jz .no_timestamp
		391
		392	.timestamp:
		393	pushd 0
		394	pushd [timer_ticks]
		395	pushd TCP_OPT_NOP + TCP_OPT_NOP shl 8 + TCP_OPT_TIMESTAMP shl 16 + 10 shl 24
		396	add di, 12
		397
3556	hidnplayr	398	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: added timestamp\n"
3545	hidnplayr	399
		400	.no_timestamp:
		401
		402	;
		403
		404	.options_done:
		405
		406	; eax = socket ptr
		407	; edx = flags
		408	; edi = header size
		409	; esi = data len
		410
		411	;---------------------------------------------
6476	hidnplayr	412	; check if we dont exceed the max segment size
3545	hidnplayr	413
		414	add esi, edi ; total TCP segment size
		415	cmp esi, [eax + TCP_SOCKET.t_maxseg]
		416	jbe .no_overflow
		417
		418	mov esi, [eax + TCP_SOCKET.t_maxseg]
4347	hidnplayr	419	or [temp_bits], TCP_BIT_SENDALOT
3545	hidnplayr	420	.no_overflow:
		421
5442	hidnplayr	422	; Update stats
6476	hidnplayr	423
5442	hidnplayr	424	test esi, esi
		425	jz .zero_data
		426
		427	cmp [eax + TCP_SOCKET.t_force], 1
		428	jne @f
		429	cmp esi, 1
		430	jne @f
		431	inc [TCPS_sndprobe]
		432	jmp .eos
		433	@@:
		434
		435	mov ebx, [eax + TCP_SOCKET.SND_NXT]
		436	cmp ebx, [eax + TCP_SOCKET.SND_MAX]
		437	jae @f
		438	inc [TCPS_sndrexmitpack]
		439	add [TCPS_sndrexmitbyte], esi
		440	jmp .eos
		441	@@:
		442	inc [TCPS_sndpack]
		443	add [TCPS_sndbyte], esi
		444	jmp .eos
		445
		446	.zero_data:
		447	test [eax + TCP_SOCKET.t_flags], TF_ACKNOW
		448	jz @f
		449	inc [TCPS_sndacks]
		450	jmp .eos
		451	@@:
		452	test dl, TH_SYN + TH_FIN + TH_RST
		453	jz @f
		454	inc [TCPS_sndctrl]
		455	jmp .eos
		456	@@:
		457	mov ebx, [eax + TCP_SOCKET.SND_UP]
		458	cmp ebx, [eax + TCP_SOCKET.SND_UNA]
		459	jb @f
		460	inc [TCPS_sndurg]
		461	jmp .eos
		462	@@:
		463	inc [TCPS_sndwinup]
		464
		465	.eos:
		466
6914	hidnplayr	467	;---------------------------------------------------
		468	; Dont increase sequence number when resending a FIN
		469
		470	test dl, TH_FIN
		471	jz .no_fin_retransmit
		472
		473	test [eax + TCP_SOCKET.t_flags], TF_SENTFIN
		474	jz .no_fin_retransmit
		475
		476	mov ebx, [eax + TCP_SOCKET.SND_NXT]
		477	cmp ebx, [eax + TCP_SOCKET.SND_MAX]
		478	jne .no_fin_retransmit
		479
		480	dec [eax + TCP_SOCKET.SND_NXT]
		481
		482	.no_fin_retransmit:
		483
4347	hidnplayr	484	;----------------------------------------------------
		485	; Calculate the receive window.
		486	; Dont shrink window, but avoid silly window syndrome
		487
6413	hidnplayr	488	mov ebx, SOCKET_BUFFER_SIZE
4347	hidnplayr	489	sub ebx, [eax + STREAM_SOCKET.rcv.size]
		490
6413	hidnplayr	491	cmp ebx, SOCKET_BUFFER_SIZE/4
4347	hidnplayr	492	jae @f
		493	cmp ebx, [eax + TCP_SOCKET.t_maxseg]
		494	jae @f
		495	xor ebx, ebx
		496	@@:
		497
		498	cmp ebx, TCP_max_win
		499	jbe @f
		500	mov ebx, TCP_max_win
		501	@@:
		502
		503	mov ecx, [eax + TCP_SOCKET.RCV_ADV]
		504	sub ecx, [eax + TCP_SOCKET.RCV_NXT]
		505	cmp ebx, ecx
6909	hidnplayr	506	jg @f
4347	hidnplayr	507	mov ebx, ecx
		508	@@:
		509
6474	hidnplayr	510	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: window=%u\n", ebx
		511	mov [window], ebx
4347	hidnplayr	512
		513	mov cl, [eax + TCP_SOCKET.RCV_SCALE]
		514	shr ebx, cl
		515	xchg bl, bh
		516
3545	hidnplayr	517	;-----------------------------------------------------------------
		518	; Start by pushing all TCP header values in reverse order on stack
		519	; (essentially, creating the tcp header on the stack!)
		520
6476	hidnplayr	521	pushw 0 ; UrgentPointer
		522	pushw 0 ; Checksum
		523	pushw bx ; Window
		524	shl edi, 2 ; DataOffset
3545	hidnplayr	525	shl dx, 8
6476	hidnplayr	526	or dx, di ; Flags
3545	hidnplayr	527	pushw dx
6476	hidnplayr	528	shr edi, 2 ; DataOffset
3545	hidnplayr	529
6476	hidnplayr	530	push [eax + TCP_SOCKET.RCV_NXT] ; AckNumber
3545	hidnplayr	531	ntohd [esp]
		532
6476	hidnplayr	533	push [eax + TCP_SOCKET.SND_NXT] ; SequenceNumber
3545	hidnplayr	534	ntohd [esp]
		535
6476	hidnplayr	536	push [eax + TCP_SOCKET.RemotePort] ; DestinationPort
		537	push [eax + TCP_SOCKET.LocalPort] ; SourcePort
3545	hidnplayr	538
6476	hidnplayr	539	push edi ; header size
3545	hidnplayr	540
		541	;---------------------
		542	; Create the IP packet
		543
		544	mov ecx, esi
5842	hidnplayr	545	mov ebx, [eax + IP_SOCKET.device]
3545	hidnplayr	546	mov edx, [eax + IP_SOCKET.LocalIP] ; source ip
5842	hidnplayr	547	mov edi, [eax + IP_SOCKET.RemoteIP] ; dest ip
		548	mov al, [eax + IP_SOCKET.ttl]
		549	mov ah, IP_PROTO_TCP
6011	hidnplayr	550	call ipv4_output
3545	hidnplayr	551	jz .ip_error
		552
5442	hidnplayr	553	;------------------------------------------
		554	; Move TCP header from stack to TCP segment
3545	hidnplayr	555
		556	push ecx
		557	mov ecx, [esp + 4]
		558	lea esi, [esp + 8]
6474	hidnplayr	559	shr ecx, 2 ; count is in bytes, we will work with dwords
3711	clevermous	560	rep movsd
6474	hidnplayr	561	pop ecx ; full TCP packet size
3545	hidnplayr	562
6474	hidnplayr	563	pop esi ; headersize
		564	add esp, esi ; remove it from stack
3545	hidnplayr	565
6474	hidnplayr	566	push eax ; packet ptr for send proc
3545	hidnplayr	567
6474	hidnplayr	568	mov edx, edi ; begin of data
		569	sub edx, esi ; begin of packet (edi = begin of data)
3545	hidnplayr	570	push ecx
6474	hidnplayr	571	sub ecx, esi ; data size
3545	hidnplayr	572
		573	;--------------
		574	; Copy the data
		575
		576	; eax = ptr to ring struct
		577	; ecx = buffer size
		578	; edi = ptr to buffer
		579
5522	hidnplayr	580	mov eax, [esp + 12] ; get socket ptr
3545	hidnplayr	581
		582	push edx
		583	push [eax + TCP_SOCKET.SND_NXT] ; we'll need this for timing the transmission
		584	test ecx, ecx
		585	jz .nodata
		586	mov edx, [eax + TCP_SOCKET.SND_NXT]
5442	hidnplayr	587	add [eax + TCP_SOCKET.SND_NXT], ecx ; update sequence number
3545	hidnplayr	588	sub edx, [eax + TCP_SOCKET.SND_UNA] ; offset
		589	add eax, STREAM_SOCKET.snd
6011	hidnplayr	590	call socket_ring_read
3545	hidnplayr	591	.nodata:
		592	pop edi
		593	pop esi ; begin of data
		594	pop ecx ; full packet size
5522	hidnplayr	595	mov eax, [esp + 8] ; socket ptr
3545	hidnplayr	596
6476	hidnplayr	597	;----------------------------
		598	; initialize retransmit timer
3545	hidnplayr	599
		600	;TODO: check t_force and persist
		601
		602	test [esi + TCP_header.Flags], TH_SYN + TH_FIN ; syn and fin take a sequence number
		603	jz @f
		604	inc [eax + TCP_SOCKET.SND_NXT]
		605	test [esi + TCP_header.Flags], TH_FIN
		606	jz @f
		607	or [eax + TCP_SOCKET.t_flags], TF_SENTFIN ; if we sent a fin, set the sentfin flag
		608	@@:
		609
		610	mov edx, [eax + TCP_SOCKET.SND_NXT]
		611	cmp edx, [eax + TCP_SOCKET.SND_MAX] ; is this a retransmission?
		612	jbe @f
		613	mov [eax + TCP_SOCKET.SND_MAX], edx ; [eax + TCP_SOCKET.SND_NXT] from before we updated it
		614
		615	cmp [eax + TCP_SOCKET.t_rtt], 0 ; are we currently timing anything?
		616	je @f
		617	mov [eax + TCP_SOCKET.t_rtt], 1 ; nope, start transmission timer
		618	mov [eax + TCP_SOCKET.t_rtseq], edi
5442	hidnplayr	619	inc [TCPS_segstimed]
3545	hidnplayr	620	@@:
		621
		622	; set retransmission timer if not already set, and not doing an ACK or keepalive probe
6476	hidnplayr	623
3600	hidnplayr	624	test [eax + TCP_SOCKET.timer_flags], timer_flag_retransmission
		625	jnz .retransmit_set
3545	hidnplayr	626
		627	cmp edx, [eax + TCP_SOCKET.SND_UNA] ; edx is still [eax + TCP_SOCKET.SND_NXT]
		628	je .retransmit_set
		629
		630	mov edx, [eax + TCP_SOCKET.t_rxtcur]
		631	mov [eax + TCP_SOCKET.timer_retransmission], edx
3603	hidnplayr	632	or [eax + TCP_SOCKET.timer_flags], timer_flag_retransmission
3545	hidnplayr	633
3600	hidnplayr	634	test [eax + TCP_SOCKET.timer_flags], timer_flag_persist
		635	jz .retransmit_set
3603	hidnplayr	636	and [eax + TCP_SOCKET.timer_flags], not timer_flag_persist
3545	hidnplayr	637	mov [eax + TCP_SOCKET.t_rxtshift], 0
		638	.retransmit_set:
		639
		640	;--------------------
		641	; Create the checksum
		642
4387	hidnplayr	643	xor dx, dx
		644	test [ebx + NET_DEVICE.hwacc], NET_HWACC_TCP_IPv4_OUT
		645	jnz .checksum_ok
		646
6011	hidnplayr	647	tcp_checksum (eax + IP_SOCKET.LocalIP), (eax + IP_SOCKET.RemoteIP)
4387	hidnplayr	648
		649	.checksum_ok:
3545	hidnplayr	650	mov [esi + TCP_header.Checksum], dx
		651
		652	;----------------
		653	; Send the packet
		654
3556	hidnplayr	655	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: Sending with device %x\n", ebx
3545	hidnplayr	656	call [ebx + NET_DEVICE.transmit]
		657	jnz .send_error
		658
		659	;---------------
		660	; Ok, data sent!
		661
		662	pop ecx
		663	pop eax
		664
6011	hidnplayr	665	call net_ptr_to_num4
3644	hidnplayr	666	inc [TCP_segments_tx + edi]
5442	hidnplayr	667	inc [TCPS_sndtotal]
3545	hidnplayr	668
		669	; update advertised receive window
6474	hidnplayr	670
		671	mov ecx, [window]
3545	hidnplayr	672	test ecx, ecx
		673	jz @f
		674	add ecx, [eax + TCP_SOCKET.RCV_NXT]
		675	cmp ecx, [eax + TCP_SOCKET.RCV_ADV]
		676	jbe @f
		677	mov [eax + TCP_SOCKET.RCV_ADV], ecx
		678	@@:
		679
		680	; update last ack sent
6476	hidnplayr	681
3545	hidnplayr	682	push [eax + TCP_SOCKET.RCV_NXT]
		683	pop [eax + TCP_SOCKET.last_ack_sent]
		684
4347	hidnplayr	685	; clear the ACK flags
6476	hidnplayr	686
3545	hidnplayr	687	and [eax + TCP_SOCKET.t_flags], not (TF_ACKNOW + TF_DELACK)
		688
		689	;--------------
		690	; unlock socket
		691
3652	hidnplayr	692	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: unlocking socket 0x%x\n", eax
		693
3545	hidnplayr	694	push eax
		695	lea ecx, [eax + SOCKET.mutex]
		696	call mutex_unlock
		697	pop eax
		698
		699	;-----------------------------
		700	; Check if we need more output
		701
4347	hidnplayr	702	test [temp_bits], TCP_BIT_SENDALOT
6011	hidnplayr	703	jnz tcp_output.again
3545	hidnplayr	704
3556	hidnplayr	705	DEBUGF DEBUG_NETWORK_VERBOSE, "TCP_send: success!\n"
3545	hidnplayr	706
		707	xor eax, eax
		708	ret
		709
		710
		711	.ip_error:
		712	pop ecx
		713	add esp, ecx
		714	add esp, 4
		715	pop eax
		716
		717	mov [eax + TCP_SOCKET.timer_retransmission], TCP_time_re_min
3602	hidnplayr	718	or [eax + TCP_SOCKET.timer_flags], timer_flag_retransmission
3545	hidnplayr	719
		720	lea ecx, [eax + SOCKET.mutex]
		721	call mutex_unlock
		722
3602	hidnplayr	723	DEBUGF DEBUG_NETWORK_ERROR, "TCP_send: IP error\n"
3545	hidnplayr	724
		725	or eax, -1
		726	ret
		727
		728
		729	.send_error:
3652	hidnplayr	730	add esp, 4
		731	pop eax
3545	hidnplayr	732
		733	lea ecx, [eax + SOCKET.mutex]
		734	call mutex_unlock
		735
3602	hidnplayr	736	DEBUGF DEBUG_NETWORK_ERROR, "TCP_send: sending failed\n"
3545	hidnplayr	737
		738	or eax, -2
		739	ret
		740
		741
4347	hidnplayr	742	endp

Subversion Repositories Kolibri OS

(root)/kernel/trunk/network/tcp_output.inc – Rev 6914