Subversion Repositories Kolibri OS

(*

    Copyright 2021 Anton Krotov

    This file is part of CEdit.

    CEdit is free software: you can redistribute it and/or modify

    it under the terms of the GNU General Public License as published by

    the Free Software Foundation, either version 3 of the License, or

    (at your option) any later version.

    CEdit is distributed in the hope that it will be useful,

    but WITHOUT ANY WARRANTY; without even the implied warranty of

    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License

    along with CEdit. If not, see .

*)

MODULE CEdit;

IMPORT

    OpenDlg, K := KolibriOS,

    U := Utils, Lines, Menu, List,

    G := Graph, T := Text, E := Encodings,

    CB := Clipboard, Languages,

    ChangeLog, Scroll, CheckBox,

    RW, Ini, EB := EditBox, Tabs, Toolbar;

CONST

    HEADER = "CEdit (20-dec-2021)";

    ShellFilter = "";

    EditFilter = "SH|INC|TXT|ASM|OB07|C|CPP|H|PAS|PP|LUA|INI|JSON";

    fontWidth = K.fontWidth;

    fontHeight = K.fontHeight;

    scrollWidth = 22;

    btnClose = 1;

    btnNew = 20;

    btnOpen = 21;

    btnSave = 22;

    btnSearch = 23;

    btnUndo = 24;

    btnRedo = 25;

    btnUpper = 26;

    btnLower = 27;

    btnBuild = 28;

    btnRun = 29;

    btnYes = 40;

    btnNo = 41;

    btnFindNext = 42;

    btnReplace = 43;

    btnReplaceAll = 44;

    btnGoto = 45;

    btnCloseSearch = 46;

    btnHideSearch = 47;

    mainMenuBtn = 60;

    btnHeight = 25;

    btnWidth = 75;

    toolbarTop = Menu.MainMenuHeight + 3;

    TOP = toolbarTop + Toolbar.BtnSize + 10 + Tabs.tabHeight;

    RIGHT = scrollWidth - 2;

    BOTTOM = scrollWidth + 18;

    minWinWidth = 635; minWinHeight = 550;

    SEARCH_PADDING = 10;

    searchLeft = 0;

    EditBox_Width = 180;

    EDITBOX_MAXCHARS = 500;

    menuFileX = searchLeft;

    menuEditX = menuFileX + 4*fontWidth + 9;

    menuSearchX = menuEditX + 4*fontWidth + 9;

    menuEncodingX = menuSearchX + 6*fontWidth + 9;

    menuViewX = menuEncodingX + 8*fontWidth + 9;

    menuLanguageX = menuViewX + 4*fontWidth + 9;

    menuProgramX = menuLanguageX + 8*fontWidth + 9;

    menuToolsX = menuProgramX + 7*fontWidth + 9;

    menuCut = 1;

    menuCopy = 2;

    menuPaste = 3;

    menuDelete = 4;

    menuSelectAll = 5;

    menuUndo = 6;

    menuRedo = 7;

    menuCurLine = 100;

    menuIndent = 110;

    menuCase = 120;

    menuNew = 10;

    menuOpen = 11;

    menuSave = 12;

    menuSaveAs = 13;

    menuSaveAll = 14;

    menuFolder = 15;

    menuClose = 16;

    menuExit = 17;

    menuNumbers = 20;

    menuFontSize = 21;

    menuColors = 1000;

    menuMaxColors = menuColors + Ini.MAX_SECTIONS - 1;

    menuText = 30;

    menuC = 31;

    menuFasm = 32;

    menuIni = 33;

    menuJSON = 34;

    menuLua = 35;

    menuOberon = 36;

    menuPascal = 37;

    menuBuild = 50;

    menuBuildScript = 51;

    menuRun = 52;

    menuRunScript = 53;

    menuDebug = 54;

    menuDebugScript = 55;

    menuUTF8BOM = 60;

    menuUTF8 = 61;

    menuCP866 = 62;

    menuWin1251 = 63;

    menuEOL = 140;

    menuPipet = 70;

    menuBoard = 71;

    menuSysFunc = 72;

    menuFind = 80;

    menuFindNext = 81;

    menuFindPrev = 82;

    menuGoto = 83;

    menuBookmark = 130;

    menuMoveUp = 101;

    menuMoveDown = 102;

    menuDuplicate = 103;

    menuRemove = 104;

    menuIncInd = 111;

    menuDecInd = 112;

    menuUpper = 121;

    menuLower = 122;

    menuToggleBookmark = 131;

    menuNextBookmark = 132;

    menuPrevBookmark = 133;

    menuLF = 141;

    menuCRLF = 142;

    menuCR = 143;

    maxTexts = 32;

VAR

    canvas: G.tCanvas;

    font, font1, font2: G.tFont;

    tabs: Tabs.tTabs;

    text: T.tText;

    texts: ARRAY maxTexts OF T.tText;

    textsCount, curText: INTEGER;

    winWidth, winHeight: INTEGER;

    AppPath, runScript, buildScript, debugScript: RW.tFileName;

    OD: OpenDlg.Dialog;

    confirm, notFound, menuFindClicked, search, searchOpened, modified: BOOLEAN;

    eol, enc: INTEGER;

    switch, closing: BOOLEAN;

    leftButton: BOOLEAN;

    LEFT: INTEGER;

    FindEdit, ReplaceEdit, GotoEdit: EB.tEditBox;

    hScroll, vScroll: Scroll.tScroll;

    CS, WH, BKW: CheckBox.tCheckBox;

    new_searchText, searchText, replaceText, gotoText: T.tString;

    cs, whole: BOOLEAN;

    replaced: INTEGER;

    mainTID: INTEGER;

    context, menuFile, menuEdit, menuSearch, menuEncoding,

    menuView, menuLanguage, menuProgram, menuTools,

    subCurLine, subIndent, subCase, subBookmark, subEOL: Menu.tMenu;

    mainMenu: Menu.tMain;

    menuActive: BOOLEAN;

    toolbar: Toolbar.tToolbar;

    IPC: ARRAY 64 OF INTEGER;

    CursorTime, CurrentTime: INTEGER;

    timerEnabled: BOOLEAN;

PROCEDURE WritePos (y: INTEGER);

VAR

    s1, s2: ARRAY 32 OF WCHAR;

    line, col: INTEGER;

BEGIN

    T.getPos(text, col, line);

    U.int2str(line, s1);

    U.int2str(col, s2);

    U.append(s1, ": ");

    U.append(s1, s2);

    K.DrawText(LEFT, y, K.textColor, s1)

END WritePos;

PROCEDURE EditBox_Focus (edit: EB.tEditBox): BOOLEAN;

	RETURN 1 IN edit.flags

END EditBox_Focus;

PROCEDURE resetTimer;

BEGIN

	IF EditBox_Focus(FindEdit) OR EditBox_Focus(ReplaceEdit) OR EditBox_Focus(GotoEdit) THEN

		T.hideCursor;

		timerEnabled := FALSE

	ELSE

		T.showCursor;

		timerEnabled := TRUE

	END;

	CursorTime := CurrentTime

END resetTimer;

PROCEDURE EditBox_SetFocus (VAR edit: EB.tEditBox; value: BOOLEAN);

BEGIN

    IF value THEN

    	INCL(edit.flags, 1)

    ELSE

    	EXCL(edit.flags, 1)

    END;

    IF search & searchOpened THEN

        EB.paint(edit)

    END

END EditBox_SetFocus;

PROCEDURE SetFocus (VAR edit: EB.tEditBox; value: BOOLEAN);

BEGIN

    EditBox_SetFocus(FindEdit, FALSE);

    EditBox_SetFocus(ReplaceEdit, FALSE);

    EditBox_SetFocus(GotoEdit, FALSE);

    EditBox_SetFocus(edit, value);

  	resetTimer

END SetFocus;

PROCEDURE Rect (left, top, right, bottom, color: INTEGER);

BEGIN

    K.DrawLine(left, top, right, top, color);

    K.DrawLine(left, bottom, right, bottom, color);

    K.DrawLine(left, top, left, bottom, color);

    K.DrawLine(right, top, right, bottom, color);

END Rect;

PROCEDURE Message (s: ARRAY OF WCHAR);

CONST

    minWidth = 30;

    height = 40;

    borderColor = 808080H;

VAR

    top, left, right, bottom, x, y, width: INTEGER;

BEGIN

	timerEnabled := FALSE;

	CursorTime := CurrentTime;

    width := minWidth + LENGTH(s)*fontWidth;

    left := (canvas.width - width) DIV 2 + LEFT;

    top := (canvas.height - height) DIV 2 + TOP;

    bottom := top + height - 1;

    right := left + width - 1;

    x := minWidth DIV 2 + left;

    y := (height - fontHeight) DIV 2 + top;

    K.DrawRect(left, top, width, height, K.winColor);

    Rect(left, top, right, bottom, borderColor);

    K.DrawText(x, y, K.textColor, s);

END Message;

PROCEDURE NotFound;

BEGIN

    IF notFound THEN

        Message("not found");

        IF menuFindClicked THEN

        	menuFindClicked := FALSE

        ELSE

        	notFound := FALSE

        END;

        SetFocus(FindEdit, TRUE)

    END

END NotFound;

PROCEDURE Replaced;

VAR

    s, s1: ARRAY 32 OF WCHAR;

BEGIN

    IF replaced # 0 THEN

        s := "replaced: ";

        U.int2str(replaced, s1);

        U.append(s, s1);

        Message(s);

        replaced := 0;

        SetFocus(FindEdit, TRUE)

    END

END Replaced;

PROCEDURE getIdx (text: T.tText): INTEGER;

VAR

    i: INTEGER;

BEGIN

    i := 0;

    WHILE texts[i] # text DO

        INC(i)

    END

    RETURN i

END getIdx;

PROCEDURE MarkModified;

BEGIN

    modified := text.modified;

    Tabs.modify(tabs, getIdx(text), modified)

END MarkModified;

PROCEDURE SetCaption (fileName: RW.tFileName);

VAR

	header: RW.tFileName;

BEGIN

    header := HEADER;

    IF text.fileName # "" THEN

    	U.append8(header, " - ");

    	U.append8(header, text.fileName)

    END;

    K.SetCaption(header)

END SetCaption;

PROCEDURE DrawState (text: T.tText; width, height: INTEGER);

VAR

    y: INTEGER;

    s: ARRAY 24 OF WCHAR;

BEGIN

	eol := T.getEol(text);

	enc := T.getEnc(text);

    s := "";

    U.append(s, RW.eolNames[eol]);

    U.append(s, 20X + 20X);

    U.append(s, E.names[enc]);

    SetCaption(text.fileName);

    K.DrawRect(LEFT + 16*fontWidth, TOP + canvas.height + scrollWidth, width - (LEFT + 16*fontWidth), BOTTOM - scrollWidth + 1, K.winColor);

    y := height - (BOTTOM - scrollWidth) + (BOTTOM - scrollWidth - 16) DIV 2;

    K.DrawText(width - LENGTH(s)*fontWidth, y, K.textColor, s);

    MarkModified

END DrawState;

PROCEDURE DrawScroll (VAR scroll: Scroll.tScroll; left, top, value, maxVal: INTEGER);

BEGIN

	scroll.maxVal := maxVal;

    scroll.left := left;

    scroll.top := top;

    Scroll.setValue(scroll, value);

    Scroll.paint(scroll)

END DrawScroll;

PROCEDURE repaint;

VAR

    width, height, scrollX, scrollY, y: INTEGER;

BEGIN

    IF text # NIL THEN

        IF confirm THEN

            K.DeleteButton(btnYes);

            K.DeleteButton(btnNo);

            confirm := FALSE;

            resetTimer;

            closing := FALSE

        END;

        IF ~search OR (searchText = "") THEN

            T.wordSel(text)

        END;

        K.ClientSize(width, height);

        IF switch THEN

            DrawState(text, width, height);

            Tabs.draw(tabs);

            IF search & T.search(text, searchText, cs, whole) THEN END;

            switch := FALSE

        END;

        T.draw(text);

        y := height - (BOTTOM - scrollWidth) + (BOTTOM - scrollWidth - 16) DIV 2;

        K.DrawRect(LEFT, TOP + canvas.height + scrollWidth, 16*fontWidth, BOTTOM - scrollWidth + 1, K.winColor);

        WritePos(y);

        IF (enc # T.getEnc(text)) OR (eol # T.getEol(text)) THEN

        	DrawState(text, width, height)

        ELSIF modified # text.modified THEN

            MarkModified

        END;

        T.getScroll(text, scrollX, scrollY);

        DrawScroll(vScroll, LEFT + canvas.width, TOP - 1, scrollY, text.count - 1);

        DrawScroll(hScroll, LEFT, TOP + canvas.height, scrollX, text.maxLength);

        IF search & searchOpened THEN

	        CheckBox.paint(BKW);

	        CheckBox.paint(CS);

	        CheckBox.paint(WH);

        END;

        G.DrawCanvas(canvas, LEFT, TOP);

        NotFound;

        Replaced;

        Toolbar.enable(toolbar, btnSave,  text.modified);

        Toolbar.enable(toolbar, btnUndo,  ~ChangeLog.isFirstGuard(text.edition));

        Toolbar.enable(toolbar, btnRedo,  ~ChangeLog.isLastGuard(text.edition));

        Toolbar.enable(toolbar, btnUpper, T.selected(text));

        Toolbar.enable(toolbar, btnLower, T.selected(text));

        Toolbar.enable(toolbar, btnBuild, buildScript # "");

        Toolbar.enable(toolbar, btnRun,   runScript # "");

        Toolbar.drawIcons(toolbar)

    END

END repaint;

PROCEDURE resize;

VAR

    cliWidth, cliHeight: INTEGER;

BEGIN

    K.WinSize(winWidth, winHeight);

    IF winWidth < minWinWidth THEN

        winWidth := minWinWidth

    END;

    IF winHeight < minWinHeight THEN

        winHeight := minWinHeight

    END;

    K.SetWinSize(winWidth, winHeight);

    K.WinSize(winWidth, winHeight);

    K.ClientSize(cliWidth, cliHeight);

    G.destroy(canvas);

    canvas := G.CreateCanvas(cliWidth - (LEFT + RIGHT + 2), cliHeight - (TOP + BOTTOM + 1));

    Tabs.setArea(tabs, LEFT, TOP - Tabs.tabHeight, cliWidth - (LEFT + RIGHT + 2), Tabs.tabHeight);

    G.SetFont(canvas, font);

    T.setCanvas(canvas);

    T.resize(canvas.width, canvas.height);

    Scroll.resize(vScroll, vScroll.width, canvas.height + 2);

    Scroll.resize(hScroll, canvas.width + 1, hScroll.height);

END resize;

PROCEDURE SearchPanel (left, top: INTEGER);

VAR

    y, right, bottom, color: INTEGER;

BEGIN

    DEC(top, Tabs.tabHeight);

    right := left + EditBox_Width + SEARCH_PADDING*2;

    bottom := top + 395 + btnHeight + SEARCH_PADDING;

    color := K.borderColor;

    Rect(left, top, right, bottom, color);

    K.CreateButton(btnCloseSearch, right - 20, top, 20, 20, 0EF999FH, "");

    K.DrawLine(right - 14, top + 5, right - 5, top + 14, 0FFFFFFH);

    K.DrawLine(right - 15, top + 5, right - 5, top + 15, 0FFFFFFH);

    K.DrawLine(right - 15, top + 6, right - 6, top + 15, 0FFFFFFH);

    K.DrawLine(right - 15, top + 14, right - 6, top + 5, 0FFFFFFH);

    K.DrawLine(right - 15, top + 15, right - 5, top + 5, 0FFFFFFH);

    K.DrawLine(right - 14, top + 15, right - 5, top + 6, 0FFFFFFH);

    K.CreateButton(btnHideSearch, right - 40, top, 20, 20, K.btnColor, "");

    K.DrawLine(right - 34, top + 14, right - 26, top + 14, K.btnTextColor);

    K.DrawLine(right - 34, top + 15, right - 26, top + 15, K.btnTextColor);

    INC(top, 15);

    INC(left, SEARCH_PADDING);

    K.DrawText866(left, top, K.textColor, "find");

    K.DrawText866(left, top + 55, K.textColor, "replace with");

    K.DrawText866(left, top + 330, K.textColor, "go to line");

    BKW.top := top + 110;

    BKW.left := left;

    CS.top := top + 140;

    CS.left := left;

    WH.top := top + 170;

    WH.left := left;

    FindEdit.top := top + 20;

    ReplaceEdit.top := top + 75;

    GotoEdit.top := top + 350;

    FindEdit.left := left;

    ReplaceEdit.left := left;

    GotoEdit.left := left;

    EB.paint(FindEdit);

    EB.paint(ReplaceEdit);

    EB.paint(GotoEdit);

    y := top + 200;

    K.CreateButton(btnFindNext, left, y, btnWidth, btnHeight, K.btnColor, "next"); INC(y, btnHeight + 10);

    K.CreateButton(btnReplace, left, y, btnWidth, btnHeight, K.btnColor, "replace"); INC(y, btnHeight + 10);

    K.CreateButton(btnReplaceAll, left, y, btnWidth + 5*fontWidth - 2, btnHeight, K.btnColor, "replace all");

    K.CreateButton(btnGoto, left, top + 380, btnWidth, btnHeight, K.btnColor, "go");

END SearchPanel;

PROCEDURE draw_window;

VAR

    width, height: INTEGER;

BEGIN

    K.BeginDraw;

    K.CreateWindow(30 + K.GetTickCount() MOD 128, 30 + K.GetTickCount() MOD 128, winWidth, winHeight, K.winColor, 73H, 0, 0, "");

    IF (text # NIL) & ~K.RolledUp() THEN

    	IF confirm THEN

    		resetTimer

    	END;

        confirm := FALSE;

        K.ClientSize(width, height);

        K.DrawRect(0, 0, width, TOP, K.winColor);

        K.DrawRect(0, 0, LEFT, height, K.winColor);

        K.DrawRect(LEFT + canvas.width + 1, TOP + canvas.height, scrollWidth - 1, scrollWidth, K.winColor);

        Menu.DrawMain(mainMenu);

        Toolbar.draw(toolbar);

        DrawState(text, width, height);

        IF search & searchOpened THEN

            SearchPanel(searchLeft, TOP)

        END;

        Tabs.draw(tabs);

        repaint

    END;

    K.EndDraw

END draw_window;

PROCEDURE mouse (VAR x, y: INTEGER);

VAR

    msState: SET;

BEGIN

	K.mouse(msState, x, y);

	DEC(x, LEFT);

	DEC(y, TOP)

END mouse;

PROCEDURE stopTimer;

BEGIN

	T.hideCursor;

    timerEnabled := FALSE;

    CursorTime := CurrentTime;

    repaint

END stopTimer;

PROCEDURE OpenFile (VAR FileName: RW.tFileName; filter: ARRAY OF CHAR);

BEGIN

    stopTimer;

    OpenDlg.SetFilter(OD, filter);

    OpenDlg.Show(OD, 500, 400);

    WHILE OD.status = 2 DO

        K.Pause(30)

    END;

    IF OD.status = 1 THEN

        COPY(OD.FilePath, FileName)

    ELSE

        FileName := ""

    END;

    resetTimer

END OpenFile;

PROCEDURE error (s: RW.tFileName);

VAR

    temp: RW.tFileName;

BEGIN

	temp := "'CEdit: ";

	U.append8(temp, s);

	U.append8(temp, "' -E");

    K.Run("/rd/1/@notify", temp)

END error;

PROCEDURE saveError (name: RW.tFileName);

VAR

    s: RW.tFileName;

BEGIN

    s := "error saving file ";

    U.append8(s, name);

    error(s)

END saveError;

PROCEDURE saveAs (text: T.tText);

VAR

    fileName, name: RW.tFileName;

    ext: ARRAY 8 OF CHAR;

BEGIN

    OD._type := OpenDlg.tsave;

    U.getFileName(text.fileName, OD.FileName, U.SLASH);

    IF OD.FileName = "" THEN

        OD.FileName := "NewFile.";

        Languages.getExt(text.lang, ext);

        U.append8(OD.FileName, ext)

    END;

    OpenFile(fileName, EditFilter);

    IF fileName # "" THEN

        IF T.save(text, fileName) THEN

            T.setName(text, fileName);

            U.getFileName(fileName, name, U.SLASH);

            Tabs.rename(tabs, curText, name)

        ELSE

            saveError(fileName)

        END

    END

END saveAs;

PROCEDURE Switch (txt: T.tText);

BEGIN

    Tabs.switch(tabs, curText);

    text := txt;

    T.switch(txt);

    switch := TRUE

END Switch;

PROCEDURE save (text: T.tText);

BEGIN

    IF text.modified THEN

        IF text.fileName # "" THEN

            IF ~T.save(text, text.fileName) THEN

                saveError(text.fileName)

            END

        ELSE

            curText := getIdx(text);

            Switch(text);

            saveAs(text)

        END;

   		Tabs.modify(tabs, getIdx(text), text.modified)

    END

END save;

PROCEDURE saveAll;

VAR

    i: INTEGER;

    txt: T.tText;

BEGIN

    i := textsCount - 1;

    WHILE i >= 0 DO

    	txt := texts[i];

        IF txt.modified THEN

        	T.switch(txt);

            save(txt)

        END;

        DEC(i)

    END;

    T.switch(text)

END saveAll;

PROCEDURE insert (pos: INTEGER; txt: T.tText);

VAR

    i: INTEGER;

    name: RW.tFileName;

BEGIN

    FOR i := textsCount - 1 TO pos BY -1 DO

        texts[i + 1] := texts[i]

    END;

    texts[pos] := txt;

    INC(textsCount);

    curText := pos;

    IF txt.fileName = "" THEN

        name := "new"

    ELSE

        U.getFileName(txt.fileName, name, U.SLASH)

    END;

    Tabs.add(tabs, name);

    Switch(txt)

END insert;

PROCEDURE Confirm;

CONST

    width  = btnWidth*2 + 30;

    height = btnHeight*2 + 20;

    lineColor = 808080H;

VAR

    left, top, right, bottom: INTEGER;

BEGIN

	stopTimer;

    draw_window;

    confirm := TRUE;

    left := (canvas.width - width) DIV 2 + LEFT;

    top := (canvas.height - height) DIV 2 + TOP;

    right := left + width - 1;

    bottom := top + height - 1;

    K.DrawRect(left, top, width, height, K.winColor);

    Rect(left, top, right, bottom, lineColor);

    K.DrawText866(left + (width - 10*fontWidth) DIV 2, top + 10, K.textColor, "save file?");

    K.CreateButton(btnYes, left + 10, top + 35, btnWidth, btnHeight, K.btnColor, "yes");

    K.CreateButton(btnNo, left + 20 + btnWidth, top + 35, btnWidth, btnHeight, K.btnColor, "no");

END Confirm;

PROCEDURE closeFile (conf: BOOLEAN; n: INTEGER);

VAR

    i: INTEGER;

BEGIN

    IF texts[n].modified & conf THEN

        Confirm

    ELSE

        Tabs.delete(tabs, n);

        T.destroy(texts[n]);

        FOR i := n + 1 TO textsCount - 1 DO

            texts[i - 1] := texts[i]

        END;

        DEC(textsCount);

        IF (curText = textsCount) OR (n < curText) THEN

            DEC(curText)

        END;

        IF curText >= 0 THEN

            Switch(texts[curText])

        ELSE

            K.Exit

        END;

        draw_window

    END

END closeFile;

PROCEDURE NewFile;

VAR

    nov: T.tText;

BEGIN

    IF textsCount < maxTexts THEN

        nov := T.New();

        T.SetPos(nov, 0, 0);

        insert(textsCount, nov)

    ELSE

        error("too many files")

    END

END NewFile;

PROCEDURE getFileNum (fileName: RW.tFileName): INTEGER;

VAR

    i: INTEGER;

    PROCEDURE nameEq (name1, name2: RW.tFileName): BOOLEAN;

    VAR

        n1, n2: RW.tFileName;

    BEGIN

        n1 := name1;

        n2 := name2;

        U.upcase(n1);

        U.upcase(n2)

        RETURN n1 = n2

    END nameEq;

BEGIN

    i := 0;

    WHILE (i < textsCount) & ~nameEq(texts[i].fileName, fileName) DO

        INC(i)

    END;

    IF i = textsCount THEN

        i := -1

    END

    RETURN i

END getFileNum;

PROCEDURE SwitchTab (n: INTEGER);

BEGIN

    curText := n;

    Tabs.switch(tabs, n);

    Switch(texts[n]);

    resetTimer;

    draw_window

END SwitchTab;

PROCEDURE open;

VAR

    fileName: RW.tFileName;

    nov: T.tText;

    err, n: INTEGER;

BEGIN

    IF textsCount < maxTexts THEN

        OD._type := OpenDlg.topen;

        OpenFile(fileName, EditFilter);

        IF fileName # "" THEN

            n := getFileNum(fileName);

            IF n = -1 THEN

                nov := T.open(fileName, err);

                IF nov = NIL THEN

                    error("error opening file")

                ELSE

                	T.SetPos(nov, 0, 0);

                    insert(textsCount, nov);

                    Scroll.setValue(hScroll, 0);

                    Scroll.setValue(vScroll, 0)

                END

            ELSE

                SwitchTab(n)

            END

        END

    ELSE

        error("too many files")

    END

END open;

PROCEDURE createSearchForm;

BEGIN

	EB.create(searchLeft, TOP + 20, EditBox_Width, EDITBOX_MAXCHARS, FindEdit);

	EB.create(searchLeft, TOP + 20 + 55, EditBox_Width, EDITBOX_MAXCHARS, ReplaceEdit);

    EB.create(searchLeft, TOP + 20 + 330, EditBox_Width, EDITBOX_MAXCHARS, GotoEdit);

    INCL(GotoEdit.flags, 15);

    CheckBox.create("backward", BKW);

    CheckBox.create("match case", CS);

    CheckBox.create("whole word", WH);

END createSearchForm;

PROCEDURE EditBox_GetValue (edit: EB.tEditBox; VAR s: ARRAY OF WCHAR);

VAR

    str: ARRAY EDITBOX_MAXCHARS + 1 OF CHAR;

    i: INTEGER;

BEGIN

    EB.getValue(edit, str);

    i := 0;

    WHILE str[i] # 0X DO

        s[i] := WCHR(E.cp866[ORD(str[i])]);

        INC(i)

    END;

    s[i] := 0X

END EditBox_GetValue;

PROCEDURE Search;

BEGIN

    search := ~search;

    LEFT := searchLeft;

    IF search THEN

        searchOpened := TRUE;

        INC(LEFT, EditBox_Width + SEARCH_PADDING*2 + 5);

        IF T.search(text, searchText, cs, whole) THEN END

    ELSE

        IF T.search(text, "", FALSE, FALSE) THEN END

    END;

    SetFocus(FindEdit, search);

    resize;

    draw_window

END Search;

PROCEDURE click (x, y: INTEGER): INTEGER;

VAR

    scrollX, scrollY: INTEGER;

    shift, ctrl: BOOLEAN;

BEGIN

    K.getKBState(shift, ctrl);

    T.getScroll(text, scrollX, scrollY);

    T.scroll(text, hScroll.value - scrollX, vScroll.value - scrollY);

    IF U.between(0, x, canvas.width - 1) & U.between(0, y, canvas.height - 1) THEN

        leftButton := TRUE;

        SetFocus(FindEdit, FALSE);

        IF ~shift THEN

            T.resetSelect(text)

        END;

        T.mouse(text, x, y)

    END;

    repaint

    RETURN K.GetTickCount()

END click;

PROCEDURE Close;

VAR

    cont: BOOLEAN;

BEGIN

    closing := TRUE;

    cont := TRUE;

    WHILE (textsCount > 0) & cont DO

        IF text.modified THEN

            Confirm;

            cont := FALSE

        ELSE

            closeFile(FALSE, curText);

            repaint

        END

    END

END Close;

PROCEDURE CloseMenu;

BEGIN

    Menu.close(subEOL);

    Menu.close(subCurLine);

    Menu.close(subIndent);

    Menu.close(subCase);

    Menu.close(subBookmark);

    Menu.close(menuFile);

    Menu.close(menuEdit);

    Menu.close(menuSearch);

    Menu.close(menuEncoding);

    Menu.close(menuView);

    Menu.close(menuLanguage);

    Menu.close(menuProgram);

    Menu.close(menuTools);

    Menu.close(context)

END CloseMenu;

PROCEDURE MenuItemClick (menu: Menu.tMenu; id: INTEGER);

VAR

	msg: ARRAY 2 OF INTEGER;

BEGIN

	msg[0] := id;

	msg[1] := 8;

    K.SendIPC(mainTID, msg)

END MenuItemClick;

PROCEDURE goto;

VAR

    gotoVal: INTEGER;

BEGIN

    EditBox_GetValue(GotoEdit, gotoText);

    IF U.str2int(gotoText, gotoVal) & T.goto(text, gotoVal) THEN

    	SetFocus(GotoEdit, FALSE)

    END

END goto;

PROCEDURE Script (script: ARRAY OF CHAR);

BEGIN

    IF script # "" THEN

        K.Run("/rd/1/@open", script)

    END

END Script;

PROCEDURE ShowSearchPanel (goto: BOOLEAN);

VAR

	i: INTEGER;

BEGIN

	IF T.selected(text) & ~goto THEN

		T.getSelectedText(text, new_searchText);

		IF new_searchText # "" THEN

			i := 0;

			WHILE (new_searchText[i] # 0X) & (new_searchText[i] # Lines.TAB) DO

				INC(i)

			END;

			IF new_searchText[i] = 0X THEN

				searchText := new_searchText;

				EB.setValue(FindEdit, searchText);

				notFound := ~T.search(text, searchText, cs, whole);

			END

		END

	END;

    IF ~search THEN

        Search

    ELSIF ~searchOpened THEN

        search := FALSE;

        Search

    END;

    IF goto THEN

    	SetFocus(GotoEdit, TRUE)

    ELSE

    	SetFocus(FindEdit, TRUE)

    END

END ShowSearchPanel;

PROCEDURE CanvasToScreen (VAR x, y: INTEGER);

VAR

    cliX, cliY,

    winX, winY: INTEGER;

BEGIN

    K.WinPos(winX, winY);

    K.ClientPos(cliX, cliY);

    x := x + winX + cliX + LEFT;

    y := y + winY + cliY + TOP;

END CanvasToScreen;

PROCEDURE ShowMenu (menu: Menu.tMenu);

VAR

    winX, winY, cliX, cliY, x, y, i: INTEGER;

    selected, enabled: BOOLEAN;

BEGIN

    IF menu = context THEN

        mouse(x, y);

        IF ~(U.between(0, x, canvas.width - 1) & U.between(0, y, canvas.height - 1)) THEN

            menu := NIL

        END

    ELSE

        K.WinPos(winX, winY);

        K.ClientPos(cliX, cliY);

        x := winX + cliX;

        y := Menu.MainMenuHeight + winY + cliY

    END;

    selected := T.selected(text);

    IF menu = menuFile THEN

        Menu.setEnabled(menu, menuSave, text.modified);

        Menu.setEnabled(menu, menuFolder, text.fileName # "");

        i := 0;

        WHILE (i < textsCount) & ~texts[i].modified DO

            INC(i)

        END;

        Menu.setEnabled(menu, menuSaveAll, i < textsCount);

        INC(x, menuFileX)

    ELSIF (menu = menuEdit) OR (menu = context) THEN

        Menu.setEnabled(menu, menuUndo, ~ChangeLog.isFirstGuard(text.edition));

        Menu.setEnabled(menu, menuRedo, ~ChangeLog.isLastGuard(text.edition));

        Menu.setEnabled(menu, menuCut, selected);

        Menu.setEnabled(menu, menuCopy, selected);

        Menu.setEnabled(menu, menuDelete, selected);

        Menu.setEnabled(menu, menuPaste, CB.available());

        IF menu = menuEdit THEN

            INC(x, menuEditX)

        ELSE

            IF y + menu.height >= canvas.height THEN

                DEC(y, menu.height)

            END;

            IF x + menu.width >= canvas.width THEN

                DEC(x, menu.width)

            END;

            CanvasToScreen(x, y)

        END

    ELSIF menu = menuEncoding THEN

        Menu.option(menu, menuUTF8BOM, T.getEnc(text) = E.UTF8BOM);

        Menu.option(menu, menuUTF8,    T.getEnc(text) = E.UTF8);

        Menu.option(menu, menuCP866,   T.getEnc(text) = E.CP866);

        Menu.option(menu, menuWin1251, T.getEnc(text) = E.W1251);

        INC(x, menuEncodingX)

    ELSIF menu = menuView THEN

        Menu.check(menu, menuNumbers,  text.numbers);

        Menu.check(menu, menuFontSize, font = font2);

        FOR i := 0 TO Ini.sections.count - 1 DO

            Menu.option(menu, menuColors + i, Ini.curSectionNum = i)

        END;

        INC(x, menuViewX)

    ELSIF menu = menuLanguage THEN

        Menu.option(menu, menuText,   text.lang = Languages.langText);

        Menu.option(menu, menuC,      text.lang = Languages.langC);

        Menu.option(menu, menuFasm,   text.lang = Languages.langFasm);

        Menu.option(menu, menuIni,    text.lang = Languages.langIni);

        Menu.option(menu, menuJSON,   text.lang = Languages.langJSON);

        Menu.option(menu, menuLua,    text.lang = Languages.langLua);

        Menu.option(menu, menuOberon, text.lang = Languages.langOberon);

        Menu.option(menu, menuPascal, text.lang = Languages.langPascal);

        INC(x, menuLanguageX)

    ELSIF menu = menuProgram THEN

        Menu.setEnabled(menu, menuBuild, buildScript # "");