Subversion Repositories Kolibri OS

Rev

Rev 6169 | Rev 6256 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;Огромная благодарность всем, кто помогал: кодом/советом/дизайном ...
  2.  
  3. use32
  4.   org 0x0
  5.   db 'MENUET01' ;идентиф. исполняемого файла всегда 8 байт
  6.   dd 1, start, i_end, mem, stacktop
  7.   dd file_name ; command line
  8.   dd sys_path
  9.  
  10. MAX_COLOR_WORD_LEN equ 40
  11. maxChars equ 100002 ;(...+2)
  12. BUF_SIZE equ 4096 ;buffer for copy|paste
  13. maxSyntaxFileSize equ 410000
  14. TOOLBAR_ICONS_SIZE equ 1200*20
  15.  
  16. include '../../proc32.inc'
  17. include '../../macros.inc'
  18. include '../../KOSfuncs.inc'
  19. include '../../load_img.inc'
  20. include '../../develop/libraries/box_lib/trunk/box_lib.mac'
  21. include '../../system/skincfg/trunk/kglobals.inc'
  22. include '../../system/skincfg/trunk/unpacker.inc'
  23. include 'lang.inc'
  24.  
  25. include 't_data.inc'
  26. include 't_menu.inc'
  27. include 'strlen.inc'
  28. include 't_draw.inc' ;draw main window functions
  29. include 't_button.inc' ;text work functions
  30. include 'wnd_k_words.inc'
  31.  
  32. @use_library_mem mem.Alloc,mem.Free,mem.ReAlloc,dll.Load
  33.  
  34. icon_tl_sys dd 0 ;указатель на память для хранения системных иконок
  35.  
  36. align 4
  37. start:
  38.         mcall SF_STYLE_SETTINGS,SSF_GET_COLORS,sc,sizeof.system_colors
  39.  
  40.         mcall SF_SYS_MISC,SSF_HEAP_INIT
  41.         or eax,eax
  42.         jz button.exit
  43.  
  44.         mcall SF_KEYBOARD,SSF_SET_INPUT_MODE,1 ;scan code
  45.         mcall SF_SET_EVENTS_MASK,0xC0000027
  46.  
  47.         mov esi,file_name
  48.         call strlen
  49.         mov ecx,eax
  50.         mov edi,openfile_path
  51.         cld
  52.         rep movsb ;копируем имя файла в буфер openfile_path
  53.  
  54. load_libraries l_libs_start,load_lib_end
  55.  
  56. ;проверка на сколько удачно загузились библиотеки
  57. mov     ebp,lib0
  58. .test_lib_open:
  59.         cmp     dword [ebp+ll_struc_size-4],0
  60.         jz      @f
  61.         mcall SF_TERMINATE_PROCESS ;exit not correct
  62. @@:
  63.         add ebp,ll_struc_size
  64.         cmp ebp,load_lib_end
  65.         jl .test_lib_open
  66.  
  67. ;---------------------------------------------------------------------
  68.         stdcall [ted_init], tedit0
  69.         stdcall dword[tl_data_init], tree1
  70.  
  71. ; OpenDialog initialisation
  72.         stdcall [OpenDialog_Init],OpenDialog_data
  73.  
  74. ; kmenu initialisation 
  75.         stdcall [kmenu_init], sc
  76.        
  77.         stdcall [ksubmenu_new]
  78.         mov [main_menu], eax
  79.        
  80.         stdcall [ksubmenu_new]
  81.         mov [main_menu_file], eax
  82.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_File_New, 3
  83.         stdcall [ksubmenu_add], [main_menu_file], eax
  84.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_File_Open, 4
  85.         stdcall [ksubmenu_add], [main_menu_file], eax
  86.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_File_Save, 5
  87.         stdcall [ksubmenu_add], [main_menu_file], eax
  88.         stdcall [kmenuitem_new], KMENUITEM_SEPARATOR, 0, 0
  89.         stdcall [ksubmenu_add], [main_menu_file], eax
  90.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_File_Exit, 199
  91.         stdcall [ksubmenu_add], [main_menu_file], eax  
  92.         stdcall [kmenuitem_new], KMENUITEM_SUBMENU, sz_main_menu_File, [main_menu_file]
  93.         stdcall [ksubmenu_add], [main_menu], eax
  94.  
  95.         stdcall [ksubmenu_new]
  96.         mov [main_menu_changes], eax
  97.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Changes_Undo, 16
  98.         stdcall [ksubmenu_add], [main_menu_changes], eax
  99.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Changes_Redo, 17
  100.         stdcall [ksubmenu_add], [main_menu_changes], eax
  101.         stdcall [kmenuitem_new], KMENUITEM_SUBMENU, sz_main_menu_Changes, [main_menu_changes]
  102.         stdcall [ksubmenu_add], [main_menu], eax
  103.        
  104.         stdcall [ksubmenu_new]
  105.         mov [main_menu_buf], eax
  106.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Buf_Cut, 7
  107.         stdcall [ksubmenu_add], [main_menu_buf], eax
  108.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Buf_Copy, 8
  109.         stdcall [ksubmenu_add], [main_menu_buf], eax
  110.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Buf_Paste, 9
  111.         stdcall [ksubmenu_add], [main_menu_buf], eax   
  112.         stdcall [kmenuitem_new], KMENUITEM_SUBMENU, sz_main_menu_Buf, [main_menu_buf]
  113.         stdcall [ksubmenu_add], [main_menu], eax
  114.  
  115.         stdcall [ksubmenu_new]
  116.         mov [main_menu_search], eax
  117.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Search_Text, 10
  118.         stdcall [ksubmenu_add], [main_menu_search], eax
  119.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Search_Keywords, 12
  120.         stdcall [ksubmenu_add], [main_menu_search], eax
  121.         stdcall [kmenuitem_new], KMENUITEM_SUBMENU, sz_main_menu_Search, [main_menu_search]
  122.         stdcall [ksubmenu_add], [main_menu], eax
  123.  
  124.         stdcall [ksubmenu_new]
  125.         mov [main_menu_view], eax
  126.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Veiw_UseSyntax, 19
  127.         stdcall [ksubmenu_add], [main_menu_view], eax
  128.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Veiw_ChooseSyntax, 20
  129.         stdcall [ksubmenu_add], [main_menu_view], eax
  130.         stdcall [kmenuitem_new], KMENUITEM_SEPARATOR, 0, 0
  131.         stdcall [ksubmenu_add], [main_menu_view], eax
  132.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Veiw_LineBreak, 18
  133.         stdcall [ksubmenu_add], [main_menu_view], eax  
  134.         stdcall [kmenuitem_new], KMENUITEM_SUBMENU, sz_main_menu_View, [main_menu_view]
  135.         stdcall [ksubmenu_add], [main_menu], eax
  136.  
  137.         stdcall [ksubmenu_new]
  138.         mov [main_menu_encoding], eax
  139.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Encoding_1251to866, 21
  140.         stdcall [ksubmenu_add], [main_menu_encoding], eax
  141.         stdcall [kmenuitem_new], KMENUITEM_NORMAL, sz_main_menu_Encoding_866to1251, 22
  142.         stdcall [ksubmenu_add], [main_menu_encoding], eax      
  143.         stdcall [kmenuitem_new], KMENUITEM_SUBMENU, sz_main_menu_Encoding, [main_menu_encoding]
  144.         stdcall [ksubmenu_add], [main_menu], eax
  145.        
  146. ; init toolbar file
  147.         load_image_file 'te_icon.png', bmp_icon,,,6 ;6 для серых кнопок
  148.         mov eax,[bmp_icon]
  149.         add eax,TOOLBAR_ICONS_SIZE
  150.         stdcall img_to_gray, [bmp_icon],eax,(TOOLBAR_ICONS_SIZE)/3
  151. ;---------------------------------------------------------------------
  152. ; читаем файл с курсорами и линиями
  153.         load_image_file 'tl_sys_16.png', icon_tl_sys
  154.         mov eax,dword[icon_tl_sys]
  155.         mov dword[tree1.data_img_sys],eax
  156. ;---------------------------------------------------------------------
  157. ; читаем файл с иконками узлов
  158.         load_image_file 'tl_nod_16.png', icon_tl_sys
  159.         mov eax,dword[icon_tl_sys]
  160.         mov dword[tree1.data_img],eax
  161. ;------------------------------------------------------------------------------
  162.         copy_path fn_syntax_dir,sys_path,file_name,0 ;берем путь к папке с файлами синтаксиса
  163.         mcall SF_FILE,tree_file_struct
  164.  
  165.         cmp ebx,-1
  166.         je .end_dir_init
  167.                 mov eax,dir_mem
  168.                 add eax,32+4+1+3+4*6+8
  169.                 mov ecx,ebx
  170.                 @@:
  171.                         cmp byte[eax],'.' ;фильтруем файлы с именами '.' и '..'
  172.                         je .filter
  173.                         ;0x10000 ;1*2^16 - где 1 номер иконки с книгой
  174.                         stdcall dword[tl_node_add], tree1,0x10000,eax
  175.                         stdcall dword[tl_cur_next], tree1
  176.                         .filter:
  177.                         add eax,304
  178.                         loop @b
  179.                 stdcall dword[tl_cur_beg],tree1 ;ставим курсор на начало списка
  180.         .end_dir_init:
  181.  
  182. ;--- load ini file ---
  183.         copy_path ini_name,sys_path,file_name,0
  184.         ;window startup pozition
  185.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_l,ini_def_window_l
  186.         mov word[wnd_s_pos+2],ax
  187.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_w,ini_def_window_w
  188.         mov word[wnd_s_pos],ax
  189.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_t,ini_def_window_t
  190.         mov word[wnd_s_pos+6],ax
  191.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_h,ini_def_window_h
  192.         mov word[wnd_s_pos+4],ax
  193.         ;scrool type
  194.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_scroll_type,ini_def_scroll_type
  195.         mov [wScr.type],eax
  196.         mov [hScr.type],eax
  197.         mov [ws_dir_lbox.type],eax
  198.     mov [w_scr_t3.type],eax
  199.         ;symbol size
  200.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_symbol_w,ini_def_symbol_w
  201.         mov dword[tedit0.rec.width],eax
  202.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_symbol_h,ini_def_symbol_h
  203.         mov dword[tedit0.rec.height],eax
  204.         lea eax,[eax+eax*2]
  205.         mov dword[tedit0.rec.top],eax
  206.         ;файловые расширения
  207.         xor edx,edx
  208.         mov ebx,synt_auto_open
  209.         @@:
  210.                 ;берем имя файла
  211.                 stdcall dword[ini_get_str],file_name,ini_sec_options,key_synt_file,ebx,32,ini_def_synt_f
  212.                 cmp byte[ebx],0
  213.                 je @f
  214.                 inc byte[key_synt_file.numb]
  215.                 add ebx,32
  216.                 ;берем расширения
  217.                 stdcall dword[ini_get_str],file_name,ini_sec_options,key_synt_ext,ebx,32,ini_def_synt_f
  218.                 inc byte[key_synt_ext.numb]
  219.                 add ebx,32
  220.                 inc edx
  221.                 cmp edx,max_synt_auto_open
  222.                 jl @b
  223.         @@:
  224.  
  225. ;--- load color option file ---
  226.         stdcall open_unpac_synt_file,[fn_col_option]
  227.  
  228. ;--- get cmd line ---
  229.         cmp byte[openfile_path+3],0 ;openfile_path
  230.         je @f ;if file names exist
  231.                 mov esi,openfile_path
  232.                 stdcall auto_open_syntax,esi
  233.                 call strlen ;eax=strlen
  234.                 call but_no_msg_OpenFile
  235.         @@:
  236.  
  237.  
  238.  
  239. align 16
  240. red_win:
  241.         call draw_window
  242.  
  243. align 16
  244. still:
  245.         mcall SF_WAIT_EVENT
  246.         cmp dword[exit_code],1
  247.         je button.exit
  248.  
  249.         cmp al,1 ;изменилось положение окна
  250.         jz red_win
  251.         cmp al,2
  252.         jz key
  253.         cmp al,3
  254.         jz button
  255.         cmp al,6 ;мышь
  256.         jne @f
  257.                 jmp mouse
  258.         @@:
  259.         jmp still
  260.  
  261. align 16
  262. draw_window:
  263.         mcall SF_REDRAW,SSF_BEGIN_DRAW
  264.  
  265.         mov edx,[sc.work]
  266.         or  edx,0x73000000
  267.         mcall SF_CREATE_WINDOW,dword[wnd_s_pos],dword[wnd_s_pos+4],,,hed
  268.  
  269.         mcall SF_THREAD_INFO,procinfo,-1
  270.         mov edi,tedit0 ;значение edi нужно для EvSize и ted_wnd_t
  271.         call EvSize
  272.  
  273.         movzx ebx,word[procinfo.client_box.width]
  274.         inc bx
  275.         mcall SF_DRAW_RECT,,ted_wnd_t ;верхний прямоугольник, для очистки верхней панели
  276.         call draw_but_toolbar
  277.         stdcall [kmainmenu_draw], [main_menu]
  278.         stdcall [ted_draw], tedit0
  279.  
  280.         mcall SF_REDRAW,SSF_END_DRAW
  281.         ret
  282.  
  283. align 16
  284. mouse:
  285.         stdcall [kmainmenu_dispatch_cursorevent], [main_menu]
  286.  
  287.         mcall SF_MOUSE_GET,SSF_WINDOW_POSITION
  288.         cmp word[tedit0.wnd.top],ax
  289.         jg .no_edit
  290.         shr eax,16
  291.         cmp word[tedit0.wnd.left],ax
  292.         jg .no_edit
  293.         mcall SF_MOUSE_GET,SSF_BUTTON_EXT
  294.         bt eax,24 ;двойной щелчёк левой кнопкой
  295.         jnc @f
  296.                 stdcall [ted_but_select_word], tedit0
  297.                 jmp still
  298.         @@:
  299.                 stdcall [ted_mouse], tedit0
  300.         .no_edit:
  301.  
  302.         cmp byte[tedit0.panel_id],TED_PANEL_FIND ;if not panel
  303.         jne @f
  304.                 stdcall [edit_box_mouse], edit2
  305.         @@:
  306.         cmp byte[tedit0.panel_id],TED_PANEL_SYNTAX ;if not panel
  307.         jne @f
  308.                 stdcall [tl_mouse], tree1
  309.         @@:
  310.         jmp still
  311. ;---------------------------------------------------------------------
  312.  
  313. ;output:
  314. ; ah = symbol
  315. align 16
  316. proc KeyConvertToASCII uses ebx, table:dword
  317.         mov ebx,dword[table] ;convert scan to ascii
  318.         ror ax,8
  319.         xor ah,ah
  320.         add bx,ax
  321.         mov ah,byte[ebx]
  322.         ret
  323. endp
  324.  
  325. align 16
  326. key:
  327.         mcall SF_KEYBOARD,SSF_GET_CONTROL_KEYS ;66.3 получить состояние управляющих клавиш
  328.         xor esi,esi
  329.         mov ecx,1
  330.         test al,0x03 ;[Shift]
  331.         jz @f
  332.                 mov cl,2
  333.                 or esi,KM_SHIFT
  334.         @@:
  335.         test al,0x0c ;[Ctrl]
  336.         jz @f
  337.                 or esi,KM_CTRL
  338.         @@:
  339.         test al,0x30 ;[Alt]
  340.         jz @f
  341.                 mov cl,3
  342.                 or esi,KM_ALT
  343.         @@:
  344.         test al,0x80 ;[NumLock]
  345.         jz @f
  346.                 or esi,KM_NUMLOCK
  347.         @@:
  348.  
  349.         mcall SF_SYSTEM_GET,SSF_KEYBOARD_LAYOUT,,conv_tabl ;26.2 получить раскладку клавиатуры
  350.         mcall SF_GET_KEY
  351.         stdcall [tl_key], tree1
  352.  
  353.         test word [edit2.flags],10b;ed_focus ; если не в фокусе, выходим
  354.         je @f
  355.                 cmp ah,0x80 ;if key up
  356.                 ja still
  357.                 cmp ah,42 ;[Shift] (left)
  358.                 je still
  359.                 cmp ah,54 ;[Shift] (right)
  360.                 je still
  361.                 cmp ah,56 ;[Alt]
  362.                 je still
  363.                 cmp ah,29 ;[Ctrl]
  364.                 je still
  365.                 cmp ah,69 ;[Pause Break]
  366.                 je still
  367.  
  368.                 stdcall KeyConvertToASCII, dword conv_tabl
  369.                 stdcall [edit_box_key], dword edit2
  370.                 jmp still
  371.         @@:
  372.  
  373.         stdcall [ted_key], tedit0, conv_tabl,esi
  374.         jmp still
  375.  
  376. align 16
  377. button:
  378.         mcall SF_GET_BUTTON
  379.         cmp ah,3
  380.         jne @f
  381.                 call ted_but_new_file
  382.                 jmp still
  383.         @@:
  384.         cmp ah,4
  385.         jne @f
  386.                 call ted_but_open_file
  387.                 jmp still
  388.         @@:
  389.         cmp ah,5
  390.         jne @f
  391.                 call ted_but_save_file
  392.                 jmp still
  393.         @@:
  394.         cmp ah,6
  395.         jne @f
  396.                 stdcall [ted_but_select_word], tedit0
  397.                 jmp still
  398.         @@:
  399.         cmp ah,7
  400.         jne @f
  401.                 stdcall [ted_but_cut], tedit0
  402.                 jmp still
  403.         @@:
  404.         cmp ah,8
  405.         jne @f
  406.                 stdcall [ted_but_copy], tedit0
  407.                 jmp still
  408.         @@:
  409.         cmp ah,9
  410.         jne @f
  411.                 stdcall [ted_but_paste], tedit0
  412.                 jmp still
  413.         @@:
  414.         cmp ah,10
  415.         jne @f
  416.                 call ted_but_find
  417.                 jmp still
  418.         @@:
  419.         cmp ah,11
  420.         jne @f
  421.                 call but_replace
  422.                 jmp still
  423.         @@:
  424.         cmp ah,12
  425.         jne @f
  426.                 call but_find_key_w
  427.                 jmp still
  428.         @@:
  429.         cmp ah,13
  430.         jne @f
  431.                 stdcall [ted_but_sumb_upper], tedit0
  432.                 jmp still
  433.         @@:
  434.         cmp ah,14
  435.         jne @f
  436.                 stdcall [ted_but_sumb_lover], tedit0
  437.                 jmp still
  438.         @@:
  439.         cmp ah,15
  440.         jne @f
  441.                 stdcall [ted_but_reverse], tedit0
  442.                 jmp still
  443.         @@:
  444.         cmp ah,16
  445.         jne @f
  446.                 stdcall [ted_but_undo], tedit0
  447.                 jmp still
  448.         @@:
  449.         cmp ah,17
  450.         jne @f
  451.                 stdcall [ted_but_redo], tedit0
  452.                 jmp still
  453.         @@:
  454.         cmp ah,18
  455.         jne @f
  456.                 stdcall but_sumb_invis, tedit0
  457.                 jmp still
  458.         @@:
  459.         cmp ah,19
  460.         jne @f
  461.                 stdcall but_k_words_show, tedit0
  462.                 jmp still
  463.         @@:
  464.         cmp ah,20
  465.         jne @f
  466.                 stdcall but_synt_show, tedit0
  467.                 jmp still
  468.         @@:
  469.         cmp ah,21
  470.         jne @f
  471.                 stdcall [ted_but_convert_by_table],tedit0,tbl_1251_866
  472.                 jmp still
  473.         @@:
  474.         cmp ah,22
  475.         jne @f
  476.                 stdcall [ted_but_convert_by_table],tedit0,tbl_866_1251
  477.                 jmp still
  478.         @@:
  479.  
  480.         cmp ah,200
  481.         jne @f
  482.                 stdcall ted_but_open_syntax, tedit0
  483.                 jmp still
  484.         @@:
  485.         cmp ah,201
  486.         jne @f
  487.                 stdcall [ted_but_find_next], tedit0
  488.                 jmp still
  489.         @@:
  490.  
  491.         cmp ah,1
  492.         je .exit
  493.  
  494.         cmp ah,199
  495.         je .exit
  496.  
  497.         jmp still
  498. .exit:
  499.         cmp dword[exit_code],1
  500.         je @f
  501.         stdcall [ted_can_save], tedit0
  502.         cmp al,1
  503.         jne @f
  504.                 stdcall [mb_create],msgbox_2,thread ;message: save buf in file?
  505.                 stdcall [mb_setfunctions],msgbox_2E_funct
  506.                 jmp still
  507.         @@:
  508.         stdcall mem.Free,[bmp_icon]
  509.         cmp dword[unpac_mem],0
  510.         je @f
  511.                 stdcall mem.Free,[unpac_mem]
  512.         @@:
  513.  
  514.         stdcall [ted_delete], tedit0
  515.         stdcall [tl_data_clear], tree1
  516.         mcall SF_TERMINATE_PROCESS ;выход из программы
  517.  
  518. edit2 edit_box TED_PANEL_WIDTH-1, 0, 20, 0xffffff, 0xff80, 0xff0000, 0xff, 0x4080, 300, buf_find, mouse_dd, 0
  519.  
  520. unpac_mem dd 0
  521.  
  522. if lang eq ru
  523.   head_f_i:
  524.   head_f_l db 'Системная ошибка',0
  525.   err_message_found_lib0 db 'Не найдена библиотека ',39,'box_lib.obj',39,0
  526.   err_message_import0 db 'Ошибка при импорте библиотеки ',39,'box_lib.obj',39,0
  527.   err_message_found_lib1 db 'Не найдена библиотека ',39,'msgbox.obj',39,0
  528.   err_message_import1 db 'Ошибка при импорте библиотеки ',39,'msgbox.obj',39,0
  529.   err_message_found_lib2 db 'Не найдена библиотека ',39,'proc_lib.obj',39,0
  530.   err_message_import2 db 'Ошибка при импорте библиотеки ',39,'proc_lib.obj',39,0
  531.   err_message_found_lib_3 db 'Не найдена библиотека ',39,'libimg.obj',39,0
  532.   err_message_import_3 db 'Ошибка при импорте библиотеки ',39,'libimg.obj',39,0
  533.   err_message_found_lib_4 db 'Не найдена библиотека ',39,'libini.obj',39,0
  534.   err_message_import_4 db 'Ошибка при импорте библиотеки ',39,'libini.obj',39,0
  535.   err_message_found_lib_5 db 'Не найдена библиотека ',39,'libkmenu.obj',39,0
  536.   err_message_import_5 db 'Ошибка при импорте библиотеки ',39,'libkmenu.obj',39,0
  537. else
  538.   head_f_i:
  539.   head_f_l db 'System error',0
  540.   err_message_found_lib0 db 'Sorry I cannot found library ',39,'box_lib.obj',39,0
  541.   err_message_import0 db 'Error on load import library ',39,'box_lib.obj',39,0
  542.   err_message_found_lib1 db 'Sorry I cannot found library ',39,'msgbox.obj',39,0
  543.   err_message_import1 db 'Error on load import library ',39,'msgbox.obj',39,0
  544.   err_message_found_lib2 db 'Sorry I cannot found library ',39,'proc_lib.obj',39,0
  545.   err_message_import2 db 'Error on load import library ',39,'proc_lib.obj',39,0
  546.   err_message_found_lib_3 db 'Sorry I cannot found library ',39,'libimg.obj',39,0
  547.   err_message_import_3 db 'Error on load import library ',39,'libimg.obj',39,0
  548.   err_message_found_lib_4 db 'Sorry I cannot found library ',39,'libini.obj',39,0
  549.   err_message_import_4 db 'Error on load import library ',39,'libini.obj',39,0
  550.   err_message_found_lib_5 db 'Sorry I cannot found library ',39,'libkmenu.obj',39,0
  551.   err_message_import_5 db 'Error on load import library ',39,'libkmenu.obj',39,0
  552. end if
  553.  
  554. ;library structures
  555. l_libs_start:
  556.         lib0 l_libs lib_name_0, sys_path, file_name, system_dir_0,\
  557.                 err_message_found_lib0, head_f_l, import_box_lib,err_message_import0, head_f_i
  558.         lib1 l_libs lib_name_1, sys_path, file_name, system_dir_1,\
  559.                 err_message_found_lib1, head_f_l, import_msgbox_lib, err_message_import1, head_f_i
  560.         lib2 l_libs lib_name_2, sys_path, file_name, system_dir_2,\
  561.                 err_message_found_lib2, head_f_l, import_proclib, err_message_import2, head_f_i
  562.         lib3 l_libs lib_name_3, sys_path, file_name, system_dir_3,\
  563.                 err_message_found_lib_3, head_f_l, import_libimg, err_message_import_3, head_f_i
  564.         lib4 l_libs lib_name_4, sys_path, file_name, system_dir_4,\
  565.                 err_message_found_lib_4, head_f_l, import_libini, err_message_import_4, head_f_i
  566.         lib5 l_libs lib_name_5, sys_path, file_name, system_dir_5,\
  567.                 err_message_found_lib_5, head_f_l, import_libkmenu, err_message_import_5, head_f_i
  568. load_lib_end:
  569.  
  570. IncludeIGlobals
  571. hed db 'TextEdit '
  572. i_end:
  573.         openfile_path: ;полный путь к файлу с которым идет работа
  574.                 rb 4096
  575.         dir_mem rb 32+304*count_of_dir_list_files
  576.         wnd_s_pos: ;место для настроек стартовой позиции окна
  577.                 rq 1
  578.         last_open_synt_file rb 32 ;имя последнего подключенного файла синтаксиса
  579.         buf rb BUF_SIZE ;буфер для копирования и вставки
  580.         buf_find rb 302 ;буфер для поиска текста
  581.         run_file_70 FileInfoBlock
  582.         sc system_colors
  583.                 rb sizeof.system_colors
  584. IncludeUGlobals
  585.         align 16
  586.         procinfo process_information
  587.                 rb 1024
  588.         thread:
  589.         rb 1024
  590.     thread_coords:
  591.         rb 4096
  592. stacktop:
  593.         sys_path: ;путь откуда запустился исполняемый файл
  594.                 rb 4096
  595.         file_name: ;параметры запуска
  596.                 rb 4096
  597.         syntax_path: ;имя подключаемого файла синтаксиса
  598.                 rb 4096
  599.         plugin_path:
  600.                 rb 4096
  601.         text_work_area: ;путь к файлу, который показывается в окне
  602.                 rb 4096
  603.         filename_area: ;имя файла для диалога открытия/закрытия
  604.                 rb 256
  605.         file_info:
  606.                 rb 40
  607. mem:
  608.