Subversion Repositories Kolibri OS

Rev

Rev 4128 | Rev 4991 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;Огромная благодарность всем, кто помогал: кодом/советом/дизайном ...
  2.  
  3. use32
  4.   org 0x0
  5.   db 'MENUET01' ;идентиф. исполняемого файла всегда 8 байт
  6.   dd 0x01
  7.   dd start
  8.   dd i_end ; размер приложения
  9.   dd mem
  10.   dd stacktop
  11.   dd file_name ; command line
  12.   dd sys_path
  13.  
  14. MAX_COLOR_WORD_LEN equ 40
  15. maxChars equ 100002 ;(...+2)
  16. BUF_SIZE equ 4096 ;buffer for copy|paste
  17. maxSyntaxFileSize equ 410000
  18. TOOLBAR_ICONS_SIZE equ 1200*20
  19.  
  20. include '../../proc32.inc'
  21. ;include '../../config.inc'
  22. include '../../macros.inc'
  23. include '../../dll.inc'
  24. include '../../develop/libraries/box_lib/load_lib.mac'
  25. include '../../develop/libraries/box_lib/trunk/box_lib.mac'
  26. include '../../system/desktop/trunk/kglobals.inc'
  27. include '../../system/desktop/trunk/unpacker.inc'
  28. include 'lang.inc'
  29.  
  30. include 't_data.inc'
  31. include 'strlen.inc'
  32. include 't_draw.inc' ;draw main window functions
  33. include 't_button.inc' ;text work functions
  34. include 'wnd_k_words.inc'
  35.  
  36. @use_library_mem mem.Alloc,mem.Free,mem.ReAlloc,dll.Load
  37.  
  38.  
  39. ;Макрос для загрузки изображений с использованием библиотеки libimg.obj
  40. ;для использования макроса нужны переменные:
  41. ; - run_file_70 FileInfoBlock
  42. ; - image_data dd 0
  43. macro load_image_file path,buf,size
  44. {
  45.         ;path - может быть переменной или строковым параметром
  46.         if path eqtype '' ;проверяем задан ли строкой параметр path
  47.                 jmp @f
  48.                         local .path_str
  49.                         .path_str db path ;формируем локальную переменную
  50.                         db 0
  51.                 @@:
  52.                 ;32 - стандартный адрес по которому должен быть буфер с системным путем
  53.                 copy_path .path_str,[32],file_name,0x0
  54.         else
  55.                 copy_path path,[32],file_name,0x0 ;формируем полный путь к файлу изображения, подразумеваем что он в одной папке с программой
  56.         end if
  57.  
  58.         stdcall mem.Alloc, dword size ;выделяем память для изображения
  59.         mov [buf],eax
  60.  
  61.         mov eax,70 ;70-я функция работа с файлами
  62.         mov [run_file_70.Function], 0
  63.         mov [run_file_70.Position], 0
  64.         mov [run_file_70.Flags], 0
  65.         mov [run_file_70.Count], dword size
  66.         m2m [run_file_70.Buffer], [buf]
  67.         mov byte[run_file_70+20], 0
  68.         mov [run_file_70.FileName], file_name
  69.         mov ebx,run_file_70
  70.         int 0x40 ;загружаем файл изображения
  71.         cmp ebx,0xffffffff
  72.         je @f
  73.                 ;определяем вид изображения и переводим его во временный буфер image_data
  74.                 stdcall dword[img_decode], dword[buf],ebx,0
  75.                 mov dword[image_data],eax
  76.                 ;преобразуем изображение к формату rgb
  77.                 stdcall dword[img_to_rgb2], dword[image_data],dword[buf]
  78.                 ;удаляем временный буфер image_data
  79.                 stdcall dword[img_destroy], dword[image_data]
  80.         @@:
  81. }
  82.  
  83. image_data dd 0 ;указатель на временную память. для нужен преобразования изображения
  84. icon_tl_sys dd 0 ;указатель на память для хранения системных иконок
  85.  
  86. align 4
  87. start:
  88.         mcall 48,3,sc,sizeof.system_colors
  89.  
  90.         mcall 68,11
  91.         or eax,eax
  92.         jz button.exit
  93.  
  94.         mcall 66,1,1 ;scan code
  95.         mcall 40,0xC0000027
  96.  
  97.         mov esi,file_name
  98.         call strlen
  99.         mov ecx,eax
  100.         mov edi,openfile_path
  101.         cld
  102.         rep movsb ;копируем имя файла в буфер openfile_path
  103.  
  104. load_libraries l_libs_start,load_lib_end
  105.  
  106. ;проверка на сколько удачно загузились библиотеки
  107. mov     ebp,lib0
  108. .test_lib_open:
  109.         cmp     dword [ebp+ll_struc_size-4],0
  110.         jz      @f
  111.         mcall -1 ;exit not correct
  112. @@:
  113.         add ebp,ll_struc_size
  114.         cmp ebp,load_lib_end
  115.         jl .test_lib_open
  116.  
  117. ;---------------------------------------------------------------------
  118.         stdcall [ted_init], tedit0
  119.         stdcall dword[tl_data_init], tree1
  120.  
  121. ; OpenDialog initialisation
  122.         stdcall [OpenDialog_Init],OpenDialog_data
  123.         mov eax,[sc.work_button_text]
  124.         mov [PathShow_data_1.font_color],eax
  125.         mov eax,[sc.work_button]
  126.         mov [PathShow_data_1.background_color],eax
  127.  
  128. ; init toolbar file
  129.         load_image_file 'te_icon.png', bmp_icon,TOOLBAR_ICONS_SIZE*2 ;умножение на 2 для серых кнопок
  130.         mov eax,[bmp_icon]
  131.         add eax,TOOLBAR_ICONS_SIZE
  132.         stdcall img_to_gray, [bmp_icon],eax,(TOOLBAR_ICONS_SIZE)/3
  133. ;---------------------------------------------------------------------
  134. ; читаем файл с курсорами и линиями
  135.         load_image_file 'tl_sys_16.png', icon_tl_sys,54+3*256*13
  136.         mov eax,dword[icon_tl_sys]
  137.         mov dword[tree1.data_img_sys],eax
  138. ;---------------------------------------------------------------------
  139. ; читаем файл с иконками узлов
  140.         load_image_file 'tl_nod_16.png', icon_tl_sys,54+3*256*2
  141.         mov eax,dword[icon_tl_sys]
  142.         mov dword[tree1.data_img],eax
  143. ;------------------------------------------------------------------------------
  144.   copy_path fn_syntax_dir,sys_path,file_name,0x0 ;берем путь к папке с файлами синтаксиса
  145.   mov eax,70
  146.   mov ebx,tree_file_struct
  147.   int 0x40
  148.  
  149. cmp ebx,-1
  150. je .end_dir_init
  151.  
  152.   mov eax,dir_mem
  153.   add eax,32+4+1+3+4*6+8
  154. mov ecx,ebx
  155. @@:
  156.   cmp byte[eax],'.' ;фильтруем файлы с именами '.' и '..'
  157.   je .filter
  158.     ;0x10000 ;1*2^16 - где 1 номер иконки с книгой
  159.     stdcall dword[tl_node_add], eax,0x10000, tree1
  160.  
  161.     stdcall dword[tl_cur_next], tree1
  162.   .filter:
  163.   add eax,304
  164.   loop @b
  165.   stdcall dword[tl_cur_beg],tree1 ;ставим курсор на начало списка
  166. .end_dir_init:
  167.  
  168. ;--- load ini file ---
  169.         copy_path ini_name,sys_path,file_name,0
  170.         ;window startup pozition
  171.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_l,ini_def_window_l
  172.         mov word[wnd_s_pos+2],ax
  173.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_w,ini_def_window_w
  174.         mov word[wnd_s_pos],ax
  175.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_t,ini_def_window_t
  176.         mov word[wnd_s_pos+6],ax
  177.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_window_h,ini_def_window_h
  178.         mov word[wnd_s_pos+4],ax
  179.         ;scrool type
  180.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_scroll_type,ini_def_scroll_type
  181.         mov [wScr.type],eax
  182.         mov [hScr.type],eax
  183.         mov [ws_dir_lbox.type],eax
  184.     mov [w_scr_t3.type],eax
  185.         ;symbol size
  186.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_symbol_w,ini_def_symbol_w
  187.         mov dword[tedit0.rec.width],eax
  188.         stdcall dword[ini_get_int],file_name,ini_sec_window,key_symbol_h,ini_def_symbol_h
  189.         mov dword[tedit0.rec.height],eax
  190.         lea eax,[eax+eax*2]
  191.         mov dword[tedit0.rec.top],eax
  192.         ;файловые расширения
  193.         xor edx,edx
  194.         mov ebx,synt_auto_open
  195.         @@:
  196.                 ;берем имя файла
  197.                 stdcall dword[ini_get_str],file_name,ini_sec_options,key_synt_file,ebx,32,ini_def_synt_f
  198.                 cmp byte[ebx],0
  199.                 je @f
  200.                 inc byte[key_synt_file.numb]
  201.                 add ebx,32
  202.                 ;берем расширения
  203.                 stdcall dword[ini_get_str],file_name,ini_sec_options,key_synt_ext,ebx,32,ini_def_synt_f
  204.                 inc byte[key_synt_ext.numb]
  205.                 add ebx,32
  206.                 inc edx
  207.                 cmp edx,max_synt_auto_open
  208.                 jl @b
  209.         @@:
  210.  
  211. ;--- load color option file ---
  212.         mov ebx,dword[fn_col_option]
  213.         call open_unpac_synt_file
  214.  
  215. ;--- get cmd line ---
  216.         cmp byte[openfile_path+3],0 ;openfile_path
  217.         je @f ;if file names exist
  218.                 mov esi,openfile_path
  219.                 call strlen ;eax=strlen
  220.                 call but_no_msg_OpenFile
  221.         @@:
  222.  
  223.  
  224.  
  225. align 4
  226. red_win:
  227.   call draw_window
  228.  
  229. align 4
  230. still:
  231.         mcall 10
  232.  
  233.         cmp al,1 ;изменилось положение окна
  234.         jz red_win
  235.         cmp al,2
  236.         jz key
  237.         cmp al,3
  238.         jz button
  239.         cmp al,6 ;мышь
  240.         jne @f
  241.                 jmp mouse
  242.         @@:
  243.         jmp still
  244.  
  245. align 4
  246. draw_window:
  247.         mcall 12,1
  248.  
  249.         mov edx,[sc.work]
  250.         or  edx,0x73000000
  251.         mov edi,hed
  252.         mcall 0,dword[wnd_s_pos],dword[wnd_s_pos+4]
  253.  
  254.         mcall 9,procinfo,-1
  255.         mov edi,tedit0 ;значение edi нужно для EvSize и ted_wnd_t
  256.         call EvSize
  257.  
  258.         mov eax,13 ;верхний прямоугольник, для очистки верхней панели
  259.         xor ebx,ebx
  260.         mov ecx,ted_wnd_t
  261.         mov bx,word[procinfo.client_box.width]
  262.         inc bx
  263.         int 0x40
  264.  
  265.         mov eax,4
  266.         mov ebx,185*65536+9
  267.         mov ecx,[sc.work_text]
  268.         or  ecx,0x80000000
  269.         mov edx,txtFile
  270.         int 0x40
  271.  
  272.         stdcall [PathShow_draw], dword PathShow_data_1
  273.         stdcall [menu_bar_draw], dword menu_data_1
  274.  
  275.         call draw_but_toolbar
  276.  
  277.         stdcall [ted_draw], tedit0
  278.  
  279.         mcall 12,2
  280.         ret
  281.  
  282. align 4
  283. mouse:
  284.         stdcall [ted_mouse], tedit0
  285.  
  286.         cmp byte[tedit0.panel_id],TED_PANEL_FIND ;if not panel
  287.         jne @f
  288.                 stdcall [edit_box_mouse], dword edit2
  289.         @@:
  290.         cmp byte[tedit0.panel_id],TED_PANEL_SYNTAX ;if not panel
  291.         jne .menu_bar_1 ;@f
  292.         stdcall [tl_mouse], tree1
  293. ;-----------------------------------------------
  294. .menu_bar_1:
  295.         mov [menu_data_1.get_mouse_flag],1
  296. ; mouse event for Menu 1
  297.         stdcall [menu_bar_mouse],dword menu_data_1
  298.         cmp dword[menu_data_1.click],1
  299.         jne .mnu_1
  300.         cmp dword[menu_data_1.cursor_out],4
  301.         je button.exit 
  302.         cmp dword[menu_data_1.cursor_out],3
  303.         jne @f
  304.                 call ted_but_save_file
  305.         @@:
  306.         cmp dword[menu_data_1.cursor_out],2
  307.         jne @f
  308.                 call ted_but_open_file
  309.         @@:
  310.         cmp dword[menu_data_1.cursor_out],1
  311.         jne @f
  312.                 call ted_but_new_file
  313.         @@:
  314. .mnu_1:
  315.         jmp still
  316. ;---------------------------------------------------------------------
  317.  
  318. ;output:
  319. ; ah = symbol
  320. align 4
  321. proc KeyConvertToASCII, table:dword
  322.   push ebx
  323.   mov ebx,dword[table] ;convert scan to ascii
  324.   ror ax,8
  325.   xor ah,ah
  326.   add bx,ax
  327.   mov ah,byte[ebx]
  328.   pop ebx
  329.   ret
  330. endp
  331.  
  332. align 4
  333. key:
  334.   mcall 66,3 ;66.3 получить состояние управляющих клавиш
  335.   xor esi,esi
  336.   mov ecx,1
  337.   test al,0x03 ;[Shift]
  338.   jz @f
  339.     mov cl,2
  340.     or esi,KM_SHIFT
  341.   @@:
  342.   test al,0x0c ;[Ctrl]
  343.   jz @f
  344.     or esi,KM_CTRL
  345.   @@:
  346.   test al,0x30 ;[Alt]
  347.   jz @f
  348.     mov cl,3
  349.     or esi,KM_ALT
  350.   @@:
  351.   test al,0x80 ;[NumLock]
  352.   jz @f
  353.     or esi,KM_NUMLOCK
  354.   @@:
  355.  
  356.   mcall 26,2,,conv_tabl ;26.2 получить раскладку клавиатуры
  357.   mcall 2 ;получаем код нажатой клавиши
  358.   stdcall [tl_key], tree1
  359.  
  360.   test word [edit2.flags],10b;ed_focus ; если не в фокусе, выходим
  361.   je @f
  362.     cmp ah,0x80 ;if key up
  363.     ja still
  364.     cmp ah,42 ;[Shift] (left)
  365.     je still
  366.     cmp ah,54 ;[Shift] (right)
  367.     je still
  368.     cmp ah,56 ;[Alt]
  369.     je still
  370.     cmp ah,29 ;[Ctrl]
  371.     je still
  372.     cmp ah,69 ;[Pause Break]
  373.     je still
  374.  
  375.     stdcall KeyConvertToASCII, dword conv_tabl
  376.     stdcall [edit_box_key], dword edit2
  377.     jmp still
  378.   @@:
  379.  
  380.   stdcall [ted_key], tedit0, conv_tabl,esi
  381.   jmp still
  382.  
  383. align 4
  384. button:
  385. ;  cmp [menu_active],1 ;если нажали меню, то сначала реакция на меню
  386. ;  jne @f ;mouse.menu_bar_1
  387. ;    mov [menu_active],0
  388. ;    jmp still
  389. ;  @@:
  390.  
  391.   mcall 17 ;получить код нажатой кнопки
  392.   cmp ah,3
  393.   jne @f
  394.     call ted_but_new_file
  395.   @@:
  396.   cmp ah,4
  397.   jne @f
  398.     call ted_but_open_file
  399.   @@:
  400.   cmp ah,5
  401.   jne @f
  402.     call ted_but_save_file
  403.   @@:
  404.   cmp ah,6
  405.   jne @f
  406.     stdcall [ted_but_select_word], tedit0
  407.   @@:
  408.   cmp ah,7
  409.   jne @f
  410.     stdcall [ted_but_cut], tedit0
  411.   @@:
  412.   cmp ah,8
  413.   jne @f
  414.     stdcall [ted_but_copy], tedit0
  415.   @@:
  416.   cmp ah,9
  417.   jne @f
  418.     stdcall [ted_but_paste], tedit0
  419.   @@:
  420.   cmp ah,10
  421.   jne @f
  422.     call ted_but_find
  423.   @@:
  424.   cmp ah,11
  425.   jne @f
  426.     call but_replace
  427.   @@:
  428.   cmp ah,12
  429.   jne @f
  430.     call but_find_key_w
  431.   @@:
  432.   cmp ah,13
  433.   jne @f
  434.     stdcall [ted_but_sumb_upper], tedit0
  435.   @@:
  436.   cmp ah,14
  437.   jne @f
  438.     stdcall [ted_but_sumb_lover], tedit0
  439.   @@:
  440.   cmp ah,15
  441.   jne @f
  442.     stdcall [ted_but_reverse], tedit0
  443.   @@:
  444.   cmp ah,16
  445.   jne @f
  446.     stdcall [ted_but_undo], tedit0
  447.   @@:
  448.   cmp ah,17
  449.   jne @f
  450.     stdcall [ted_but_redo], tedit0
  451.   @@:
  452.   cmp ah,18
  453.   jne @f
  454.     stdcall but_sumb_invis, tedit0
  455.   @@:
  456.   cmp ah,19
  457.   jne @f
  458.     stdcall but_k_words_show, tedit0
  459.   @@:
  460.   cmp ah,20
  461.   jne @f
  462.     stdcall but_synt_show, tedit0
  463.   @@:
  464.   cmp ah,21
  465.   jne @f
  466.     stdcall [ted_but_convert_by_table],tedit0,tbl_1251_866
  467.   @@:
  468.   cmp ah,22
  469.   jne @f
  470.     stdcall [ted_but_convert_by_table],tedit0,tbl_866_1251
  471.   @@:
  472.  
  473.   cmp ah,200
  474.   jne @f
  475.     stdcall ted_but_open_syntax, tedit0
  476.   @@:
  477.   cmp ah,201
  478.   jne @f
  479.     stdcall [ted_but_find_next], tedit0
  480.   @@:
  481.  
  482.   cmp ah,1
  483.   jne still
  484. .exit:
  485.         stdcall [ted_can_save], tedit0
  486.         cmp al,1
  487.         jne @f
  488.                 stdcall [mb_create],msgbox_8,thread ;message: save changes in file?
  489.                 jmp still
  490.         @@:
  491.         stdcall mem.Free,[bmp_icon]
  492.         cmp dword[unpac_mem],0
  493.         je @f
  494.                 stdcall mem.Free,[unpac_mem]
  495.         @@:
  496.  
  497.         stdcall [ted_delete], tedit0
  498.         stdcall dword[tl_data_clear], tree1
  499.         mcall -1 ;выход из программы
  500.  
  501. PathShow_data_1:
  502. .type                   dd 0    ;+0
  503. .start_y                dw 9    ;+4
  504. .start_x                dw 222  ;+6
  505. .font_size_x            dw 6    ;+8     ; 6 - for font 0, 8 - for font 1
  506. .area_size_x            dw 200  ;+10
  507. .font_number            dd 0    ;+12    ; 0 - monospace, 1 - variable
  508. .background_flag        dd 1    ;+16
  509. .font_color             dd 0x0  ;+20
  510. .background_color       dd 0xffffff     ;+24
  511. .text_pointer           dd openfile_path        ;+28
  512. .work_area_pointer      dd text_work_area       ;+32
  513. .temp_text_length       dd 0    ;+36
  514.  
  515. edit2 edit_box TED_PANEL_WIDTH-1, 0, 20, 0xffffff, 0xff80, 0xff0000, 0xff, 0x4080, 300, buf_find, mouse_dd, 0
  516.  
  517. unpac_mem dd 0
  518.  
  519. if lang eq ru
  520.   head_f_i:
  521.   head_f_l db 'Системная ошибка',0
  522.   err_message_found_lib0 db 'Не найдена библиотека ',39,'box_lib.obj',39,0
  523.   err_message_import0 db 'Ошибка при импорте библиотеки ',39,'box_lib.obj',39,0
  524.   err_message_found_lib1 db 'Не найдена библиотека ',39,'msgbox.obj',39,0
  525.   err_message_import1 db 'Ошибка при импорте библиотеки ',39,'msgbox.obj',39,0
  526.   err_message_found_lib2 db 'Не найдена библиотека ',39,'proc_lib.obj',39,0
  527.   err_message_import2 db 'Ошибка при импорте библиотеки ',39,'proc_lib.obj',39,0
  528.   err_message_found_lib_3 db 'Не найдена библиотека ',39,'libimg.obj',39,0
  529.   err_message_import_3 db 'Ошибка при импорте библиотеки ',39,'libimg.obj',39,0
  530.   err_message_found_lib_4 db 'Не найдена библиотека ',39,'libini.obj',39,0
  531.   err_message_import_4 db 'Ошибка при импорте библиотеки ',39,'libini.obj',39,0
  532. else
  533.   head_f_i:
  534.   head_f_l db 'System error',0
  535.   err_message_found_lib0 db 'Sorry I cannot found library ',39,'box_lib.obj',39,0
  536.   err_message_import0 db 'Error on load import library ',39,'box_lib.obj',39,0
  537.   err_message_found_lib1 db 'Sorry I cannot found library ',39,'msgbox.obj',39,0
  538.   err_message_import1 db 'Error on load import library ',39,'msgbox.obj',39,0
  539.   err_message_found_lib2 db 'Sorry I cannot found library ',39,'proc_lib.obj',39,0
  540.   err_message_import2 db 'Error on load import library ',39,'proc_lib.obj',39,0
  541.   err_message_found_lib_3 db 'Sorry I cannot found library ',39,'libimg.obj',39,0
  542.   err_message_import_3 db 'Error on load import library ',39,'libimg.obj',39,0
  543.   err_message_found_lib_4 db 'Sorry I cannot found library ',39,'libini.obj',39,0
  544.   err_message_import_4 db 'Error on load import library ',39,'libini.obj',39,0
  545. end if
  546.  
  547. ;library structures
  548. l_libs_start:
  549.         lib0 l_libs lib_name_0, sys_path, file_name, system_dir_0,\
  550.                 err_message_found_lib0, head_f_l, import_box_lib,err_message_import0, head_f_i
  551.         lib1 l_libs lib_name_1, sys_path, file_name, system_dir_1,\
  552.                 err_message_found_lib1, head_f_l, import_msgbox_lib, err_message_import1, head_f_i
  553.         lib2 l_libs lib_name_2, sys_path, file_name, system_dir_2,\
  554.                 err_message_found_lib2, head_f_l, import_proclib, err_message_import2, head_f_i
  555.         lib3 l_libs lib_name_3, sys_path, file_name, system_dir_3,\
  556.                 err_message_found_lib_3, head_f_l, import_libimg, err_message_import_3, head_f_i
  557.         lib4 l_libs lib_name_4, sys_path, file_name, system_dir_4,\
  558.                 err_message_found_lib_4, head_f_l, import_libini, err_message_import_4, head_f_i
  559. load_lib_end:
  560.  
  561. IncludeIGlobals
  562. i_end:
  563.         dir_mem rb 32+304*count_of_dir_list_files
  564.         wnd_s_pos: ;место для настроек стартовой позиции окна
  565.                 rq 1
  566.         last_open_synt_file rb 32 ;имя последнего подключенного файла синтаксиса
  567.         buf rb BUF_SIZE ;буфер для копирования и вставки
  568.         buf_find rb 302 ;буфер для поиска текста
  569. IncludeUGlobals
  570.         align 16
  571.         procinfo process_information
  572.                 rb 1024
  573.         thread:
  574.         rb 1024
  575.     thread_coords:
  576.         rb 1024
  577. stacktop:
  578.         sys_path: ;путь откуда запустился исполняемый файл
  579.                 rb 4096
  580.         file_name: ;параметры запуска
  581.                 rb 4096
  582.         syntax_path: ;имя подключаемого файла синтаксиса
  583.                 rb 4096
  584.         plugin_path:
  585.                 rb 4096
  586.         openfile_path: ;полный путь к файлу с которым идет работа
  587.                 rb 4096
  588.         text_work_area: ;путь к файлу, который показывается в окне
  589.                 rb 4096
  590.         filename_area: ;имя файла для диалога открытия/закрытия
  591.                 rb 256
  592.         file_info:
  593.                 rb 40
  594. mem:
  595.