Subversion Repositories Kolibri OS

Rev

Rev 5715 | Rev 5717 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                                 ;;
  3. ;; Copyright (C) KolibriOS team 2010-2015. All rights reserved.    ;;
  4. ;; Distributed under terms of the GNU General Public License       ;;
  5. ;;                                                                 ;;
  6. ;;  VNC client for KolibriOS                                       ;;
  7. ;;                                                                 ;;
  8. ;;  Written by hidnplayr@kolibrios.org                             ;;
  9. ;;                                                                 ;;
  10. ;;          GNU GENERAL PUBLIC LICENSE                             ;;
  11. ;;             Version 2, June 1991                                ;;
  12. ;;                                                                 ;;
  13. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  14.  
  15. format binary as ""
  16.  
  17. __DEBUG__       = 1
  18. __DEBUG_LEVEL__ = 2
  19.  
  20. BITS_PER_PIXEL  = 8            ; 8, 16 24
  21.  
  22. use32
  23.  
  24.         org     0x0
  25.  
  26.         db      "MENUET01"      ; 8 byte id
  27.         dd      0x01            ; header version
  28.         dd      START           ; start of code
  29.         dd      I_END           ; size of image
  30.         dd      IM_END          ; memory for app
  31.         dd      IM_END          ; esp
  32.         dd      0x0, 0x0        ; I_Param , I_Path
  33.  
  34. include "../../macros.inc"
  35. include "../../debug-fdo.inc"
  36. include "../../proc32.inc"
  37. include "../../dll.inc"
  38. include "../../struct.inc"
  39. include "../../develop/libraries/box_lib/trunk/box_lib.mac"
  40. include "../../network.inc"
  41.  
  42. struct  pixel_format
  43.         bpp             db ?
  44.         depth           db ?
  45.         big_endian      db ?
  46.         true_color      db ?
  47.         red_max         dw ?
  48.         green_max       dw ?
  49.         blue_max        dw ?
  50.         red_shift       db ?
  51.         green_shift     db ?
  52.         blue_shift      db ?
  53.         padding         rb 3
  54. ends
  55.  
  56. struct  framebuffer
  57.         width           dw ?
  58.         height          dw ?
  59.         pixelformat     pixel_format
  60.         name_length     dd ?
  61.         name            rb 256
  62. ends
  63.  
  64. xpos                    = 4
  65. ypos                    = 21
  66.  
  67. TIMEOUT                 = 5             ; timeout in seconds
  68.  
  69. RECEIVE_BUFFER_SIZE     = 8*1024*1024   ; 8 Mib
  70.  
  71. STATUS_INITIAL          = 0
  72. STATUS_CONNECTING       = 1
  73. STATUS_REQ_LOGIN        = 2
  74. STATUS_LOGIN            = 3
  75. STATUS_CONNECTED        = 4
  76. STATUS_CLOSED           = 5
  77.  
  78. STATUS_DISCONNECTED     = 10
  79. STATUS_DNS_ERR          = 11
  80. STATUS_SOCK_ERR         = 12
  81. STATUS_CONNECT_ERR      = 13
  82. STATUS_PROTO_ERR        = 14
  83. STATUS_SECURITY_ERR     = 15
  84. STATUS_LIB_ERR          = 16
  85. STATUS_THREAD_ERR       = 17
  86. STATUS_LOGIN_FAILED     = 18
  87.  
  88. BYTES_PER_PIXEL = (BITS_PER_PIXEL + 7) / 8
  89.  
  90. include "keymap.inc"
  91. include "gui.inc"
  92. include "network.inc"
  93. include "raw.inc"
  94. include "copyrect.inc"
  95. include "rre.inc"
  96. include "trle.inc"
  97. include "des.inc"
  98.  
  99. START:
  100.  
  101.         mcall   68, 11                  ; init heap
  102.  
  103. ; Load libraries
  104.         stdcall dll.Load, @IMPORT
  105.         test    eax, eax
  106.         jz      @f
  107.         mov     [status], STATUS_LIB_ERR
  108.   @@:
  109.  
  110. ; Present the user with the GUI and wait for network connection
  111.         call    draw_gui
  112.  
  113. ; Create main window
  114.         mcall   71, 1, name             ; reset window caption (add server name)
  115.  
  116.         mov     edx, dword[screen]
  117.         movzx   esi, dx
  118.         shr     edx, 16
  119.         add     edx, 2*xpos
  120.         add     esi, ypos+xpos
  121.         mcall   67, 10, 10              ; resize the window
  122.  
  123.         mcall   40, EVM_MOUSE + EVM_MOUSE_FILTER + EVM_KEY + EVM_REDRAW + EVM_BUTTON
  124.  
  125.         mcall   66, 1, 1                ; Switch keyboard to scancode mode
  126.  
  127.         call    generate_keymap
  128.  
  129. redraw:
  130.         mcall   12, 1
  131.  
  132.         mov     ebx, dword[screen]
  133.         movzx   ecx, bx
  134.         shr     ebx, 16
  135.         mov     edx, 0x74ffffff
  136.         mov     edi, name
  137.         mcall   0                       ; draw window
  138.  
  139.         mcall   12, 2
  140.  
  141. draw_framebuffer:
  142.         mcall   7, framebuffer_data, dword[screen], 0
  143.         mov     [update_framebuffer], 0
  144.  
  145. mainloop:
  146.         cmp     [status], STATUS_CONNECTED
  147.         jne     draw_gui
  148.         cmp     [update_framebuffer], 0
  149.         jne     draw_framebuffer
  150.  
  151.         mcall   23, 10                  ; Check for event with 0,1s timeout
  152.  
  153.         dec     eax
  154.         jz      redraw
  155.         dec     eax
  156.         jz      key
  157.         dec     eax
  158.         jz      button
  159.         sub     eax, 3
  160.         jz      mouse
  161.         jmp     mainloop
  162.  
  163. key:
  164.         mcall   66, 3
  165.         mov     ebx, eax        ; get modifier keys
  166.  
  167.         mcall   2               ; get key scancode
  168.         cmp     ah, 224         ; extended keycode?
  169.         je      .extended
  170.  
  171.         xor     al, al
  172.         test    ah, 0x80        ; key up?
  173.         jnz     @f
  174.         inc     al
  175.   @@:
  176.         mov     byte[KeyEvent.down], al
  177.  
  178.         movzx   eax, ah
  179.  
  180.         test    ebx, 100000b    ; alt?
  181.         jz      .no_alt
  182.         mov     ax, [keymap_alt+eax*2]
  183.         jmp     .key
  184.   .no_alt:
  185.  
  186.         test    ebx, 11b        ; shift?
  187.         jz      .no_shift
  188.         mov     ax, [keymap_shift+eax*2]
  189.         jmp     .key
  190.   .no_shift:
  191.  
  192.         test    ebx, 10000000b  ; numlock ?
  193.         jz      .no_numlock
  194.         cmp     al, 71
  195.         jb      .no_numlock
  196.         cmp     al, 83
  197.         ja      .no_numlock
  198.         mov     ah, [keymap_numlock+eax-71]
  199.         xor     al, al
  200.         jmp     .key
  201.  
  202.   .extended:                    ; extended keys always use regular keymap
  203.         mcall   2
  204.         shr     eax, 8
  205.         jz      mainloop
  206.   .no_numlock:
  207.         mov     ax, [keymap+eax*2]
  208.   .key:
  209.         test    ax, ax
  210.         jz      mainloop
  211.         mov     word[KeyEvent.key+2], ax
  212.         DEBUGF  1, "Sending key: 0x%x\n", ax
  213.         mcall   send, [socketnum], KeyEvent, 8, 0
  214.         jmp     mainloop
  215.  
  216.  
  217.  
  218. mouse:
  219. ;        DEBUGF  1, "Sending pointer event\n"
  220.  
  221.         mcall   37, 1           ; get mouse pos
  222.         bswap   eax
  223.         mov     [PointerEvent.x], ax
  224.         shr     eax, 16
  225.         mov     [PointerEvent.y], ax
  226.  
  227.         mcall   37, 2           ; get mouse buttons
  228.         test    al, 00000010b   ; test if right button was pressed  (bit 1 in kolibri)
  229.         jz      @f
  230.         add     al, 00000010b   ; in RFB protocol it is bit 2, so if we add bit 2 again, we"ll get bit 3 and bit 1 will remain the same
  231.       @@:
  232.         mov     [PointerEvent.mask], al
  233.  
  234.         mcall   send, [socketnum], PointerEvent, 6, 0
  235.         jmp     mainloop
  236.  
  237. button:
  238.         mcall   17              ; get id
  239.         mov     [status], STATUS_CLOSED
  240.         mcall   close, [socketnum]
  241.         mcall   -1
  242.  
  243.  
  244. ; DATA AREA
  245.  
  246. include_debug_strings
  247.  
  248. keymap_numlock:
  249.         db      '7', '8', '9', '-'
  250.         db      '4', '5', '6', '+'
  251.         db      '1', '2', '3'
  252.         db      '0', '.'
  253.  
  254. HandShake               db "RFB 003.003", 10
  255.  
  256. ClientInit              db 0            ; not shared
  257.  
  258. SetPixelFormat32        db 0            ; setPixelformat
  259.                         db 0, 0, 0      ; padding
  260. .bpp                    db 32           ; bits per pixel
  261. .depth                  db 32           ; depth
  262. .big_endian             db 0            ; big-endian flag
  263. .true_color             db 1            ; true-colour flag
  264. .red_max                db 0, 255       ; red-max
  265. .green_max              db 0, 255       ; green-max
  266. .blue_max               db 0, 255       ; blue-max
  267. .red_shif               db 0            ; red-shift
  268. .green_shift            db 8            ; green-shift
  269. .blue_shift             db 16           ; blue-shift
  270.                         db 0, 0, 0      ; padding
  271.  
  272. SetPixelFormat24        db 0            ; setPixelformat
  273.                         db 0, 0, 0      ; padding
  274. .bpp                    db 24           ; bits per pixel
  275. .depth                  db 24           ; depth
  276. .big_endian             db 0            ; big-endian flag
  277. .true_color             db 1            ; true-colour flag
  278. .red_max                db 0, 255       ; red-max
  279. .green_max              db 0, 255       ; green-max
  280. .blue_max               db 0, 255       ; blue-max
  281. .red_shift              db 16           ; red-shift
  282. .green_shift            db 8            ; green-shift
  283. .blue_shift             db 0            ; blue-shift
  284.                         db 0, 0, 0      ; padding
  285.  
  286. SetPixelFormat16        db 0            ; setPixelformat
  287.                         db 0, 0, 0      ; padding
  288. .bpp                    db 16           ; bits per pixel
  289. .depth                  db 16           ; depth
  290. .big_endian             db 0            ; big-endian flag
  291. .true_color             db 1            ; true-colour flag
  292. .red_max                db 0, 31        ; red-max
  293. .green_max              db 0, 63        ; green-max
  294. .blue_max               db 0, 31        ; blue-max
  295. .red_shift              db 11           ; red-shift
  296. .green_shift            db 5            ; green-shift
  297. .blue_shift             db 0            ; blue-shift
  298.                         db 0, 0, 0      ; padding
  299.  
  300. SetPixelFormat8         db 0            ; setPixelformat
  301.                         db 0, 0, 0      ; padding
  302. .bpp                    db 8            ; bits per pixel
  303. .depth                  db 8            ; depth
  304. .big_endian             db 0            ; big-endian flag
  305. .true_color             db 1            ; true-colour flag
  306. .red_max                db 0, 7         ; red-max
  307. .green_max              db 0, 7         ; green-max
  308. .blue_max               db 0, 3         ; blue-max
  309. .red_shift              db 0            ; red-shift
  310. .green_shift            db 3            ; green-shift
  311. .blue_shift             db 6            ; blue-shift
  312.                         db 0, 0, 0      ; padding
  313.  
  314. SetEncodings            db 2            ; setEncodings
  315.                         db 0            ; padding
  316.                         db 0, 3         ; number of encodings
  317.                         db 0, 0, 0, 1   ; Copyrect encoding
  318.                         db 0, 0, 0, 2   ; RRE
  319.                         db 0, 0, 0, 0   ; raw encoding
  320. ;                        db 0, 0, 0, 5   ; HexTile
  321. ;                        db 0, 0, 0, 15  ; TRLE
  322. ;                        db 0, 0, 0, 16  ; ZRLE
  323.   .length = $ - SetEncodings
  324.  
  325. FramebufferUpdateRequest        db 3
  326. .inc                            db 0    ; incremental
  327. .x                              dw 0
  328. .y                              dw 0
  329. .width                          dw 0
  330. .height                         dw 0
  331.  
  332. KeyEvent                db 4            ; keyevent
  333. .down                   db 0            ; down-flag
  334.                         dw 0            ; padding
  335. .key                    dd 0            ; key
  336.  
  337. PointerEvent            db 5            ; pointerevent
  338. .mask                   db 0            ; button-mask
  339. .x                      dw 0            ; x-position
  340. .y                      dw 0            ; y-position
  341.  
  342.  
  343. sockaddr1:
  344.                 dw AF_INET4
  345. .port           dw 0x0c17               ; 5900
  346. .ip             dd 0
  347.                 rb 10
  348.  
  349. beep            db 0x85, 0x25, 0x85, 0x40, 0
  350.  
  351. status                  dd STATUS_INITIAL
  352. update_gui              dd 0
  353. mouse_dd                dd 0
  354. update_framebuffer      dd 0
  355.  
  356. URLbox          edit_box 235, 70, 20, 0xffffff, 0x6f9480, 0, 0, 0, 65535, serveraddr, mouse_dd, ed_focus, 0, 0
  357. USERbox         edit_box 215, 90, 10, 0xffffff, 0x6f9480, 0, 0, 0, 127, username, mouse_dd, ed_focus, 0, 0
  358. PASSbox         edit_box 215, 90, 30, 0xffffff, 0x6f9480, 0, 0, 0, 127, password, mouse_dd, ed_pass, 0, 0
  359.  
  360. serverstr       db "server:"
  361. userstr         db "username:"
  362. passstr         db "password:"
  363. connectstr      db "Connect"
  364. loginstr        db "Log in"
  365. loginstr_e:
  366.  
  367. sz_err_disconnected     db "Server closed connection unexpectedly.", 0
  368. sz_err_dns              db "Could not resolve hostname.", 0
  369. sz_err_sock             db "Could not open socket.", 0
  370. sz_err_connect          db "Could not connect to the server.", 0
  371. sz_err_proto            db "A protocol error has occured.", 0
  372. sz_err_security         db "Server requested an unsupported security type.", 0
  373. sz_err_library          db "Could not load needed libraries.", 0
  374. sz_err_thread           db "Could not create thread.", 0
  375. sz_err_login_failed     db "Login failed.", 0
  376.  
  377. err_msg         dd sz_err_disconnected
  378.                 dd sz_err_dns
  379.                 dd sz_err_sock
  380.                 dd sz_err_connect
  381.                 dd sz_err_proto
  382.                 dd sz_err_security
  383.                 dd sz_err_library
  384.                 dd sz_err_thread
  385.                 dd sz_err_login_failed
  386.  
  387. ; import
  388. align 4
  389. @IMPORT:
  390.  
  391. library network,                "network.obj",\
  392.         box_lib,                "box_lib.obj",\
  393.         archiver,               "archiver.obj"
  394.  
  395. import  network,\
  396.         getaddrinfo,            "getaddrinfo",  \
  397.         freeaddrinfo,           "freeaddrinfo", \
  398.         inet_ntoa,              "inet_ntoa"
  399.  
  400. import  box_lib,\
  401.         edit_box_draw,          "edit_box",\
  402.         edit_box_key,           "edit_box_key",\
  403.         edit_box_mouse,         "edit_box_mouse",\
  404.         scrollbar_v_draw,       "scrollbar_v_draw",\
  405.         scrollbar_v_mouse,      "scrollbar_v_mouse",\
  406.         scrollbar_h_draw,       "scrollbar_h_draw",\
  407.         scrollbar_h_mouse,      "scrollbar_h_mouse"
  408.  
  409. import  archiver,\
  410.         deflate_unpack,         "deflate_unpack"
  411.  
  412. name                    db "VNC viewer "
  413. .dash                   db 0, " "
  414.  
  415. I_END:
  416.  
  417. servername              rb 64+1
  418.  
  419. socketnum               dd ?
  420. datapointer             dd ?
  421.  
  422. rectangles              dw ?
  423.  
  424. rectangle:
  425. .x                      dd ?
  426. .y                      dd ?
  427. .width                  dd ?
  428. .height                 dd ?
  429.  
  430. subrectangles           dd ?
  431.  
  432. subrectangle:
  433. .x                      dd ?
  434. .y                      dd ?
  435. .width                  dd ?
  436. .height                 dd ?
  437.  
  438. screen:                 ; Remote screen resolution
  439. .height                 dw ?
  440. .width                  dw ?
  441.  
  442. palette                 rd 128  ; TRLE/ZRLE
  443. palettesize             db ?    ; TRLE/ZRLE
  444.  
  445. keymap                  rw 128
  446. keymap_shift            rw 128
  447. keymap_alt              rw 128
  448. username                rb 128
  449. password                rb 128
  450. keys                    rd 32*2         ; DES keys for VNC authentication
  451.  
  452. serveraddr              rb 65536
  453. receive_buffer          rb RECEIVE_BUFFER_SIZE
  454. framebuffer_data        rb 1280*1024*3  ; framebuffer
  455.  
  456.                         rb 0x1000
  457. thread_stack:
  458.                         rb 0x1000
  459. IM_END:
  460.  
  461.  
  462.