Subversion Repositories Kolibri OS

Rev

Rev 5680 | Rev 5708 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                                 ;;
  3. ;; Copyright (C) KolibriOS team 2010-2015. All rights reserved.    ;;
  4. ;; Distributed under terms of the GNU General Public License       ;;
  5. ;;                                                                 ;;
  6. ;;  VNC client for KolibriOS                                       ;;
  7. ;;                                                                 ;;
  8. ;;  Written by hidnplayr@kolibrios.org                             ;;
  9. ;;                                                                 ;;
  10. ;;          GNU GENERAL PUBLIC LICENSE                             ;;
  11. ;;             Version 2, June 1991                                ;;
  12. ;;                                                                 ;;
  13. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  14.  
  15. format binary as ""
  16.  
  17. __DEBUG__       = 1
  18. __DEBUG_LEVEL__ = 2
  19.  
  20. BITS_PER_PIXEL  = 8             ; 8, 16 24
  21.  
  22. use32
  23.  
  24.         org     0x0
  25.  
  26.         db      "MENUET01"      ; 8 byte id
  27.         dd      0x01            ; header version
  28.         dd      START           ; start of code
  29.         dd      I_END           ; size of image
  30.         dd      IM_END          ; memory for app
  31.         dd      IM_END          ; esp
  32.         dd      0x0, 0x0        ; I_Param , I_Path
  33.  
  34. include "../../macros.inc"
  35. include "../../debug-fdo.inc"
  36. include "../../proc32.inc"
  37. include "../../dll.inc"
  38. include "../../struct.inc"
  39. include "../../develop/libraries/box_lib/trunk/box_lib.mac"
  40. include "../../network.inc"
  41.  
  42. struct  pixel_format
  43.         bpp             db ?
  44.         depth           db ?
  45.         big_endian      db ?
  46.         true_color      db ?
  47.         red_max         dw ?
  48.         green_max       dw ?
  49.         blue_max        dw ?
  50.         red_shift       db ?
  51.         green_shift     db ?
  52.         blue_shift      db ?
  53.         padding         rb 3
  54. ends
  55.  
  56. struct  framebuffer
  57.         width           dw ?
  58.         height          dw ?
  59.         pixelformat     pixel_format
  60.         name_length     dd ?
  61.         name            rb 256
  62. ends
  63.  
  64. xpos                    = 4
  65. ypos                    = 21
  66.  
  67. TIMEOUT                 = 5             ; timeout in seconds
  68.  
  69. RECEIVE_BUFFER_SIZE     = 8*1024*1024   ; 8 Mib
  70.  
  71. STATUS_INITIAL          = 0
  72. STATUS_CONNECTING       = 1
  73. STATUS_REQ_LOGIN        = 2
  74. STATUS_LOGIN            = 3
  75. STATUS_CONNECTED        = 4
  76. STATUS_CLOSED           = 5
  77.  
  78. STATUS_DISCONNECTED     = 10
  79. STATUS_DNS_ERR          = 11
  80. STATUS_SOCK_ERR         = 12
  81. STATUS_CONNECT_ERR      = 13
  82. STATUS_PROTO_ERR        = 14
  83. STATUS_SECURITY_ERR     = 15
  84. STATUS_LIB_ERR          = 16
  85. STATUS_THREAD_ERR       = 17
  86. STATUS_LOGIN_FAILED     = 18
  87.  
  88. include "keymap.inc"
  89. include "gui.inc"
  90. include "network.inc"
  91. include "raw.inc"
  92. include "copyrect.inc"
  93. include "rre.inc"
  94. include "des.inc"
  95.  
  96. START:
  97.  
  98.         mcall   68, 11                  ; init heap
  99.  
  100. ; Load libraries
  101.         stdcall dll.Load, @IMPORT
  102.         test    eax, eax
  103.         jz      @f
  104.         mov     [status], STATUS_LIB_ERR
  105.   @@:
  106.  
  107. ; Present the user with the GUI and wait for network connection
  108.         call    draw_gui
  109.  
  110. ; Create main window
  111.         mcall   71, 1, name             ; reset window caption (add server name)
  112.  
  113.         mov     edx, dword[screen]
  114.         movzx   esi, dx
  115.         shr     edx, 16
  116.         add     edx, 2*xpos
  117.         add     esi, ypos+xpos
  118.         mcall   67, 10, 10              ; resize the window
  119.  
  120.         mcall   40, EVM_MOUSE + EVM_MOUSE_FILTER + EVM_KEY + EVM_REDRAW + EVM_BUTTON
  121.  
  122.         mcall   66, 1, 1                ; Switch keyboard to scancode mode
  123.  
  124.         call    generate_keymap
  125.  
  126. redraw:
  127.         mcall   12, 1
  128.  
  129.         mov     ebx, dword[screen]
  130.         movzx   ecx, bx
  131.         shr     ebx, 16
  132.         mov     edx, 0x74ffffff
  133.         mov     edi, name
  134.         mcall   0                       ; draw window
  135.  
  136.         mcall   12, 2
  137.  
  138. draw_framebuffer:
  139.         mcall   7, framebuffer_data, dword[screen], 0
  140.         mov     [update_framebuffer], 0
  141.  
  142. mainloop:
  143.         cmp     [status], STATUS_CONNECTED
  144.         jne     draw_gui
  145.         cmp     [update_framebuffer], 0
  146.         jne     draw_framebuffer
  147.  
  148.         mcall   23, 10                  ; Check for event with 0,1s timeout
  149.  
  150.         dec     eax
  151.         jz      redraw
  152.         dec     eax
  153.         jz      key
  154.         dec     eax
  155.         jz      button
  156.         sub     eax, 3
  157.         jz      mouse
  158.         jmp     mainloop
  159.  
  160. key:
  161.         mcall   66, 3
  162.         mov     ebx, eax        ; get modifier keys
  163.  
  164.         mcall   2               ; get key scancode
  165.         cmp     ah, 224         ; extended keycode?
  166.         je      .extended
  167.  
  168.         xor     al, al
  169.         test    ah, 0x80        ; key up?
  170.         jnz     @f
  171.         inc     al
  172.   @@:
  173.         mov     byte[KeyEvent.down], al
  174.  
  175.         movzx   eax, ah
  176.  
  177.         test    ebx, 100000b    ; alt?
  178.         jz      .no_alt
  179.         mov     ax, [keymap_alt+eax*2]
  180.         jmp     .key
  181.   .no_alt:
  182.  
  183.         test    ebx, 11b        ; shift?
  184.         jz      .no_shift
  185.         mov     ax, [keymap_shift+eax*2]
  186.         jmp     .key
  187.   .no_shift:
  188.  
  189.         test    ebx, 10000000b  ; numlock ?
  190.         jz      .no_numlock
  191.         cmp     al, 71
  192.         jb      .no_numlock
  193.         cmp     al, 83
  194.         ja      .no_numlock
  195.         mov     ah, [keymap_numlock+eax-71]
  196.         xor     al, al
  197.         jmp     .key
  198.  
  199.   .extended:                    ; extended keys always use regular keymap
  200.         mcall   2
  201.         shr     eax, 8
  202.         jz      mainloop
  203.   .no_numlock:
  204.         mov     ax, [keymap+eax*2]
  205.   .key:
  206.         test    ax, ax
  207.         jz      mainloop
  208.         mov     word[KeyEvent.key+2], ax
  209.         DEBUGF  1, "Sending key: 0x%x\n", ax
  210.         mcall   send, [socketnum], KeyEvent, 8, 0
  211.         jmp     mainloop
  212.  
  213.  
  214.  
  215. mouse:
  216. ;        DEBUGF  1, "Sending pointer event\n"
  217.  
  218.         mcall   37, 1           ; get mouse pos
  219.         bswap   eax
  220.         mov     [PointerEvent.x], ax
  221.         shr     eax, 16
  222.         mov     [PointerEvent.y], ax
  223.  
  224.         mcall   37, 2           ; get mouse buttons
  225.         test    al, 00000010b   ; test if right button was pressed  (bit 1 in kolibri)
  226.         jz      @f
  227.         add     al, 00000010b   ; in RFB protocol it is bit 2, so if we add bit 2 again, we"ll get bit 3 and bit 1 will remain the same
  228.       @@:
  229.         mov     [PointerEvent.mask], al
  230.  
  231.         mcall   send, [socketnum], PointerEvent, 6, 0
  232.         jmp     mainloop
  233.  
  234. button:
  235.         mcall   17              ; get id
  236.         mov     [status], STATUS_CLOSED
  237.         mcall   close, [socketnum]
  238.         mcall   -1
  239.  
  240.  
  241. ; DATA AREA
  242.  
  243. include_debug_strings
  244.  
  245. keymap_numlock:
  246.         db      '7', '8', '9', '-'
  247.         db      '4', '5', '6', '+'
  248.         db      '1', '2', '3'
  249.         db      '0', '.'
  250.  
  251. HandShake               db "RFB 003.003", 10
  252.  
  253. ClientInit              db 0            ; not shared
  254.  
  255. SetPixelFormat32        db 0            ; setPixelformat
  256.                         db 0, 0, 0      ; padding
  257. .bpp                    db 32           ; bits per pixel
  258. .depth                  db 32           ; depth
  259. .big_endian             db 0            ; big-endian flag
  260. .true_color             db 1            ; true-colour flag
  261. .red_max                db 0, 255       ; red-max
  262. .green_max              db 0, 255       ; green-max
  263. .blue_max               db 0, 255       ; blue-max
  264. .red_shif               db 0            ; red-shift
  265. .green_shift            db 8            ; green-shift
  266. .blue_shift             db 16           ; blue-shift
  267.                         db 0, 0, 0      ; padding
  268.  
  269. SetPixelFormat24        db 0            ; setPixelformat
  270.                         db 0, 0, 0      ; padding
  271. .bpp                    db 24           ; bits per pixel
  272. .depth                  db 24           ; depth
  273. .big_endian             db 0            ; big-endian flag
  274. .true_color             db 1            ; true-colour flag
  275. .red_max                db 0, 255       ; red-max
  276. .green_max              db 0, 255       ; green-max
  277. .blue_max               db 0, 255       ; blue-max
  278. .red_shift              db 16           ; red-shift
  279. .green_shift            db 8            ; green-shift
  280. .blue_shift             db 0            ; blue-shift
  281.                         db 0, 0, 0      ; padding
  282.  
  283. SetPixelFormat16        db 0            ; setPixelformat
  284.                         db 0, 0, 0      ; padding
  285. .bpp                    db 16           ; bits per pixel
  286. .depth                  db 16           ; depth
  287. .big_endian             db 0            ; big-endian flag
  288. .true_color             db 1            ; true-colour flag
  289. .red_max                db 0, 31        ; red-max
  290. .green_max              db 0, 63        ; green-max
  291. .blue_max               db 0, 31        ; blue-max
  292. .red_shift              db 11           ; red-shift
  293. .green_shift            db 5            ; green-shift
  294. .blue_shift             db 0            ; blue-shift
  295.                         db 0, 0, 0      ; padding
  296.  
  297. SetPixelFormat8         db 0            ; setPixelformat
  298.                         db 0, 0, 0      ; padding
  299. .bpp                    db 8            ; bits per pixel
  300. .depth                  db 8            ; depth
  301. .big_endian             db 0            ; big-endian flag
  302. .true_color             db 1            ; true-colour flag
  303. .red_max                db 0, 7         ; red-max
  304. .green_max              db 0, 7         ; green-max
  305. .blue_max               db 0, 3         ; blue-max
  306. .red_shift              db 0            ; red-shift
  307. .green_shift            db 3            ; green-shift
  308. .blue_shift             db 6            ; blue-shift
  309.                         db 0, 0, 0      ; padding
  310.  
  311. SetEncodings            db 2            ; setEncodings
  312.                         db 0            ; padding
  313.                         db 0, 2         ; number of encodings
  314.                         db 0, 0, 0, 0   ; raw encoding        (DWORD, Big endian order)
  315.                         db 0, 0, 0, 1   ; Copyrect encoding
  316. ;                        db 0, 0, 0, 2   ; RRE
  317. ;                        db 0, 0, 0, 5   ; HexTile
  318. ;                        db 0, 0, 0, 15  ; TRLE
  319. ;                        db 0, 0, 0, 16  ; ZRLE
  320.  
  321. FramebufferUpdateRequest        db 3
  322. .inc                            db 0    ; incremental
  323. .x                              dw 0
  324. .y                              dw 0
  325. .width                          dw 0
  326. .height                         dw 0
  327.  
  328. KeyEvent                db 4            ; keyevent
  329. .down                   db 0            ; down-flag
  330.                         dw 0            ; padding
  331. .key                    dd 0            ; key
  332.  
  333. PointerEvent            db 5            ; pointerevent
  334. .mask                   db 0            ; button-mask
  335. .x                      dw 0            ; x-position
  336. .y                      dw 0            ; y-position
  337.  
  338.  
  339. sockaddr1:
  340.                 dw AF_INET4
  341. .port           dw 0x0c17               ; 5900
  342. .ip             dd 0
  343.                 rb 10
  344.  
  345. beep            db 0x85, 0x25, 0x85, 0x40, 0
  346.  
  347. status                  dd STATUS_INITIAL
  348. update_gui              dd 0
  349. mouse_dd                dd 0
  350. update_framebuffer      dd 0
  351.  
  352. URLbox          edit_box 235, 70, 20, 0xffffff, 0x6f9480, 0, 0, 0, 65535, serveraddr, mouse_dd, ed_focus, 0, 0
  353. USERbox         edit_box 215, 90, 10, 0xffffff, 0x6f9480, 0, 0, 0, 127, username, mouse_dd, ed_focus, 0, 0
  354. PASSbox         edit_box 215, 90, 30, 0xffffff, 0x6f9480, 0, 0, 0, 127, password, mouse_dd, ed_pass, 0, 0
  355.  
  356. serverstr       db "server:"
  357. userstr         db "username:"
  358. passstr         db "password:"
  359. connectstr      db "Connect"
  360. loginstr        db "Log in"
  361. loginstr_e:
  362.  
  363. sz_err_disconnected     db "Server closed connection unexpectedly.", 0
  364. sz_err_dns              db "Could not resolve hostname.", 0
  365. sz_err_sock             db "Could not open socket.", 0
  366. sz_err_connect          db "Could not connect to the server.", 0
  367. sz_err_proto            db "A protocol error has occured.", 0
  368. sz_err_security         db "Server requested an unsupported security type.", 0
  369. sz_err_library          db "Could not load needed libraries.", 0
  370. sz_err_thread           db "Could not create thread.", 0
  371. sz_err_login_failed     db "Login failed.", 0
  372.  
  373. err_msg         dd sz_err_disconnected
  374.                 dd sz_err_dns
  375.                 dd sz_err_sock
  376.                 dd sz_err_connect
  377.                 dd sz_err_proto
  378.                 dd sz_err_security
  379.                 dd sz_err_library
  380.                 dd sz_err_thread
  381.                 dd sz_err_login_failed
  382.  
  383. ; import
  384. align 4
  385. @IMPORT:
  386.  
  387. library network,                "network.obj",\
  388.         box_lib,                "box_lib.obj",\
  389.         archiver,               "archiver.obj"
  390.  
  391. import  network,\
  392.         getaddrinfo,            "getaddrinfo",  \
  393.         freeaddrinfo,           "freeaddrinfo", \
  394.         inet_ntoa,              "inet_ntoa"
  395.  
  396. import  box_lib,\
  397.         edit_box_draw,          "edit_box",\
  398.         edit_box_key,           "edit_box_key",\
  399.         edit_box_mouse,         "edit_box_mouse",\
  400.         scrollbar_v_draw,       "scrollbar_v_draw",\
  401.         scrollbar_v_mouse,      "scrollbar_v_mouse",\
  402.         scrollbar_h_draw,       "scrollbar_h_draw",\
  403.         scrollbar_h_mouse,      "scrollbar_h_mouse"
  404.  
  405. import  archiver,\
  406.         deflate_unpack,         "deflate_unpack"
  407.  
  408. name                    db "VNC viewer "
  409. .dash                   db 0, " "
  410.  
  411. I_END:
  412.  
  413. servername              rb 64+1
  414.  
  415. socketnum               dd ?
  416. datapointer             dd ?
  417.  
  418. rectangles              dw ?
  419.  
  420. rectangle:
  421. .x                      dd ?
  422. .y                      dd ?
  423. .width                  dd ?
  424. .height                 dd ?
  425.  
  426. subrectangles           dd ?
  427.  
  428. subrectangle:
  429. .x                      dd ?
  430. .y                      dd ?
  431. .width                  dd ?
  432. .height                 dd ?
  433.  
  434. screen:                 ; Remote screen resolution
  435. .height                 dw ?
  436. .width                  dw ?
  437.  
  438. keymap                  rw 128
  439. keymap_shift            rw 128
  440. keymap_alt              rw 128
  441. username                rb 128
  442. password                rb 128
  443. keys                    rd 32*2         ; DES keys for VNC authentication
  444.  
  445. serveraddr              rb 65536
  446. receive_buffer          rb RECEIVE_BUFFER_SIZE
  447. framebuffer_data        rb 1280*1024*3  ; framebuffer
  448.  
  449.                         rb 0x1000
  450. thread_stack:
  451.                         rb 0x1000
  452. IM_END:
  453.  
  454.  
  455.