Subversion Repositories Kolibri OS

Rev

Rev 8097 | Rev 9579 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. (*
  2.     BSD 2-Clause License
  3.  
  4.     Copyright (c) 2018-2021, Anton Krotov
  5.     All rights reserved.
  6. *)
  7.  
  8. MODULE PARS;
  9.  
  10. IMPORT PROG, SCAN, ARITH, STRINGS, ERRORS, LISTS, IL, CONSOLE, PATHS, UTILS,
  11.        C := COLLECTIONS, TARGETS, THUMB, MSP430;
  12.  
  13.  
  14. CONST
  15.  
  16.     eCONST*   =  1;  eTYPE*   =  2;  eVAR*     =  3;  eEXPR*    =  4;
  17.     eVREC*    =  5;  ePROC*   =  6;  eVPAR*    =  7;  ePARAM*   =  8;
  18.     eSTPROC*  =  9;  eSTFUNC* = 10;  eSYSFUNC* = 11;  eSYSPROC* = 12;
  19.     eIMP*     = 13;
  20.  
  21.  
  22. TYPE
  23.  
  24.     PATH* = PATHS.PATH;
  25.  
  26.     PARSER* = POINTER TO rPARSER;
  27.  
  28.     POSITION* = RECORD (SCAN.POSITION)
  29.  
  30.         parser*: PARSER
  31.  
  32.     END;
  33.  
  34.     EXPR* = RECORD
  35.  
  36.         obj*:         INTEGER;
  37.         _type*:       PROG._TYPE;
  38.         value*:       ARITH.VALUE;
  39.         stproc*:      INTEGER;
  40.         readOnly*:    BOOLEAN;
  41.         ident*:       PROG.IDENT
  42.  
  43.     END;
  44.  
  45.     STATPROC  = PROCEDURE (parser: PARSER);
  46.     EXPRPROC  = PROCEDURE (parser: PARSER; VAR e: EXPR);
  47.     RETPROC   = PROCEDURE (parser: PARSER; e: EXPR; t: PROG._TYPE; pos: POSITION): BOOLEAN;
  48.  
  49.     rPARSER = RECORD (C.ITEM)
  50.  
  51.         fname*:      PATH;
  52.         path:        PATH;
  53.         lib_path:    PATH;
  54.         ext:         PATH;
  55.         modname:     PATH;
  56.         scanner:     SCAN.SCANNER;
  57.         lex*:        SCAN.LEX;
  58.         sym*:        INTEGER;
  59.         unit*:       PROG.UNIT;
  60.         constexp*:   BOOLEAN;
  61.         main*:       BOOLEAN;
  62.  
  63.         open*:       PROCEDURE (parser: PARSER; modname, FileExt: ARRAY OF CHAR): BOOLEAN;
  64.         parse*:      PROCEDURE (parser: PARSER);
  65.         StatSeq*:    STATPROC;
  66.         expression*: EXPRPROC;
  67.         designator*: EXPRPROC;
  68.         chkreturn:   RETPROC;
  69.  
  70.         create*:     PROCEDURE (path, lib_path: PATH; StatSeq: STATPROC; expression, designator: EXPRPROC; chkreturn: RETPROC): PARSER
  71.  
  72.     END;
  73.  
  74.  
  75. VAR
  76.  
  77.     parsers: C.COLLECTION;
  78.  
  79.     lines*, modules: INTEGER;
  80.  
  81.  
  82. PROCEDURE destroy* (VAR parser: PARSER);
  83. BEGIN
  84.     IF parser.scanner # NIL THEN
  85.         SCAN.close(parser.scanner)
  86.     END;
  87.  
  88.     C.push(parsers, parser);
  89.     parser := NIL
  90. END destroy;
  91.  
  92.  
  93. PROCEDURE getpos (parser: PARSER; VAR pos: POSITION);
  94. BEGIN
  95.     pos.line   := parser.lex.pos.line;
  96.     pos.col    := parser.lex.pos.col;
  97.     pos.parser := parser
  98. END getpos;
  99.  
  100.  
  101. PROCEDURE error* (pos: POSITION; errno: INTEGER);
  102. BEGIN
  103.     ERRORS.ErrorMsg(pos.parser.fname, pos.line, pos.col, errno)
  104. END error;
  105.  
  106.  
  107. PROCEDURE check* (condition: BOOLEAN; pos: POSITION; errno: INTEGER);
  108. BEGIN
  109.     IF ~condition THEN
  110.         error(pos, errno)
  111.     END
  112. END check;
  113.  
  114.  
  115. PROCEDURE check1* (condition: BOOLEAN; parser: PARSER; errno: INTEGER);
  116. VAR
  117.     pos: POSITION;
  118.  
  119. BEGIN
  120.     IF ~condition THEN
  121.         getpos(parser, pos);
  122.         error(pos, errno)
  123.     END
  124. END check1;
  125.  
  126.  
  127. PROCEDURE Next* (parser: PARSER);
  128. VAR
  129.     errno: INTEGER;
  130.  
  131. BEGIN
  132.     SCAN.Next(parser.scanner, parser.lex);
  133.     errno := parser.lex.error;
  134.     IF errno = 0 THEN
  135.         IF (TARGETS.RealSize = 0) & (parser.lex.sym = SCAN.lxFLOAT) THEN
  136.             errno := -SCAN.lxERROR13
  137.         ELSIF (TARGETS.BitDepth = 16) & (parser.lex.sym = SCAN.lxCHAR) & (parser.lex.value.typ = ARITH.tWCHAR) THEN
  138.             errno := -SCAN.lxERROR10
  139.         END
  140.     END;
  141.  
  142.     IF errno # 0 THEN
  143.         check1(FALSE, parser, errno)
  144.     END;
  145.     parser.sym := parser.lex.sym
  146. END Next;
  147.  
  148.  
  149. PROCEDURE NextPos (parser: PARSER; VAR pos: POSITION);
  150. BEGIN
  151.     Next(parser);
  152.     getpos(parser, pos)
  153. END NextPos;
  154.  
  155.  
  156. PROCEDURE checklex* (parser: PARSER; sym: INTEGER);
  157. VAR
  158.     err: INTEGER;
  159.  
  160. BEGIN
  161.  
  162.     IF parser.sym # sym THEN
  163.  
  164.         CASE sym OF
  165.         |SCAN.lxCOMMA:   err := 65
  166.         |SCAN.lxRROUND:  err := 33
  167.         |SCAN.lxPOINT:   err := 26
  168.         |SCAN.lxIDENT:   err := 22
  169.         |SCAN.lxRSQUARE: err := 71
  170.         |SCAN.lxRCURLY:  err := 35
  171.         |SCAN.lxUNDEF:   err := 34
  172.         |SCAN.lxTHEN:    err := 88
  173.         |SCAN.lxEND:     err := 27
  174.         |SCAN.lxDO:      err := 89
  175.         |SCAN.lxUNTIL:   err := 90
  176.         |SCAN.lxCOLON:   err := 53
  177.         |SCAN.lxOF:      err := 67
  178.         |SCAN.lxASSIGN:  err := 96
  179.         |SCAN.lxTO:      err := 57
  180.         |SCAN.lxLROUND:  err := 64
  181.         |SCAN.lxEQ:      err := 32
  182.         |SCAN.lxSEMI:    err := 24
  183.         |SCAN.lxRETURN:  err := 38
  184.         |SCAN.lxMODULE:  err := 21
  185.         END;
  186.  
  187.         check1(FALSE, parser, err)
  188.     END
  189. END checklex;
  190.  
  191.  
  192. PROCEDURE ExpectSym* (parser: PARSER; sym: INTEGER);
  193. BEGIN
  194.     Next(parser);
  195.     checklex(parser, sym)
  196. END ExpectSym;
  197.  
  198.  
  199. PROCEDURE ImportList (parser: PARSER);
  200. VAR
  201.     fname, path, ext, _name: PATH;
  202.     name:    SCAN.IDENT;
  203.     parser2: PARSER;
  204.     pos:     POSITION;
  205.     alias, _in: BOOLEAN;
  206.     unit:    PROG.UNIT;
  207.     ident:   PROG.IDENT;
  208.  
  209. BEGIN
  210.     alias := FALSE;
  211.  
  212.     REPEAT
  213.  
  214.         ExpectSym(parser, SCAN.lxIDENT);
  215.         name := parser.lex.ident;
  216.  
  217.         getpos(parser, pos);
  218.  
  219.         IF ~alias THEN
  220.             ident := PROG.addIdent(parser.unit, name, PROG.idMODULE);
  221.             check(ident # NIL, pos, 30)
  222.         END;
  223.  
  224.         Next(parser);
  225.  
  226.         path := parser.path;
  227.         fname := "";
  228.         ext := UTILS.FILE_EXT;
  229.         COPY(name.s, _name);
  230.         _in := FALSE;
  231.  
  232.         IF parser.sym = SCAN.lxIN THEN
  233.             _in := TRUE;
  234.             Next(parser);
  235.             IF parser.sym = SCAN.lxSTRING THEN
  236.                 STRINGS.trim(parser.lex.string.s, fname)
  237.             ELSIF parser.sym = SCAN.lxCHAR THEN
  238.                 fname[0] := CHR(ARITH.Int(parser.lex.value));
  239.                 fname[1] := 0X
  240.             ELSE
  241.                 check1(FALSE, parser, 117)
  242.             END;
  243.             STRINGS.replace(fname, "/", UTILS.slash);
  244.             STRINGS.replace(fname, "\", UTILS.slash);
  245.             PATHS.DelSlashes(fname);
  246.             PATHS.split(fname, path, _name, ext);
  247.             IF PATHS.isRelative(path) THEN
  248.                 PATHS.RelPath(parser.path, path, fname);
  249.                 STRINGS.append(fname, _name);
  250.                 STRINGS.append(fname, ext);
  251.                 PATHS.split(fname, path, _name, ext)
  252.             END;
  253.             Next(parser)
  254.         END;
  255.  
  256.         IF (parser.sym = SCAN.lxCOMMA) OR (parser.sym = SCAN.lxSEMI) THEN
  257.             alias := FALSE;
  258.             IF (fname = "") & ((_name = "SYSTEM") OR PROG.LowerCase & (_name = "system")) THEN
  259.                 unit := PROG.program.sysunit
  260.             ELSE
  261.                 IF fname # "" THEN
  262.                     unit := PROG.getUnit(fname)
  263.                 ELSE
  264.                     fname := path;
  265.                     STRINGS.append(fname, _name);
  266.                     STRINGS.append(fname, UTILS.FILE_EXT);
  267.                     unit := PROG.getUnit(fname);
  268.                     IF unit = NIL THEN
  269.                         fname := parser.lib_path;
  270.                         STRINGS.append(fname, _name);
  271.                         STRINGS.append(fname, UTILS.FILE_EXT);
  272.                         unit := PROG.getUnit(fname)
  273.                     END
  274.                 END
  275.             END;
  276.  
  277.             IF unit # NIL THEN
  278.                 check(unit.closed, pos, 31)
  279.             ELSE
  280.                 parser2 := parser.create(path, parser.lib_path,
  281.                     parser.StatSeq, parser.expression, parser.designator, parser.chkreturn);
  282.  
  283.                 IF ~parser2.open(parser2, _name, ext) THEN
  284.                     IF (path # parser.lib_path) & ~_in THEN
  285.                         destroy(parser2);
  286.                         parser2 := parser.create(parser.lib_path, parser.lib_path,
  287.                             parser.StatSeq, parser.expression, parser.designator, parser.chkreturn);
  288.                         check(parser2.open(parser2, _name, ext), pos, 29)
  289.                     ELSE
  290.                         error(pos, 29)
  291.                     END
  292.                 END;
  293.  
  294.                 parser2.parse(parser2);
  295.                 unit := parser2.unit;
  296.                 unit.fname := parser2.fname;
  297.                 destroy(parser2)
  298.             END;
  299.             IF unit = PROG.program.sysunit THEN
  300.                 parser.unit.sysimport := TRUE
  301.             END;
  302.             ident.unit := unit
  303.  
  304.         ELSIF parser.sym = SCAN.lxASSIGN THEN
  305.             alias := TRUE
  306.  
  307.         ELSE
  308.             check1(FALSE, parser, 28)
  309.         END
  310.  
  311.     UNTIL parser.sym = SCAN.lxSEMI;
  312.  
  313.     Next(parser)
  314.  
  315. END ImportList;
  316.  
  317.  
  318. PROCEDURE QIdent (parser: PARSER; forward: BOOLEAN): PROG.IDENT;
  319. VAR
  320.     ident: PROG.IDENT;
  321.     unit:  PROG.UNIT;
  322.  
  323. BEGIN
  324.     ASSERT(parser.sym = SCAN.lxIDENT);
  325.  
  326.     ident := PROG.getIdent(parser.unit, parser.lex.ident, FALSE);
  327.  
  328.     IF ~forward THEN
  329.         check1(ident # NIL, parser, 48)
  330.     END;
  331.  
  332.     IF (ident # NIL) & (ident.typ = PROG.idMODULE) THEN
  333.         unit := ident.unit;
  334.         ExpectSym(parser, SCAN.lxPOINT);
  335.         ExpectSym(parser, SCAN.lxIDENT);
  336.         ident := PROG.getIdent(unit, parser.lex.ident, FALSE);
  337.         check1((ident # NIL) & ident.export, parser, 48)
  338.     END
  339.  
  340.     RETURN ident
  341. END QIdent;
  342.  
  343.  
  344. PROCEDURE strcmp* (VAR v: ARITH.VALUE; v2: ARITH.VALUE; operator: INTEGER);
  345. VAR
  346.     str: SCAN.TEXTSTR;
  347.     string1, string2: SCAN.STRING;
  348.     bool: BOOLEAN;
  349.  
  350. BEGIN
  351.  
  352.     IF v.typ = ARITH.tCHAR THEN
  353.         ASSERT(v2.typ = ARITH.tSTRING);
  354.         ARITH.charToStr(v, str);
  355.         string1 := SCAN.enterStr(str);
  356.         string2 := v2.string(SCAN.STRING)
  357.     END;
  358.  
  359.     IF v2.typ = ARITH.tCHAR THEN
  360.         ASSERT(v.typ = ARITH.tSTRING);
  361.         ARITH.charToStr(v2, str);
  362.         string2 := SCAN.enterStr(str);
  363.         string1 := v.string(SCAN.STRING)
  364.     END;
  365.  
  366.     IF v.typ = v2.typ THEN
  367.         string1 := v.string(SCAN.STRING);
  368.         string2 := v2.string(SCAN.STRING)
  369.     END;
  370.  
  371.     CASE operator OF
  372.     |SCAN.lxEQ: bool := string1.s =  string2.s
  373.     |SCAN.lxNE: bool := string1.s #  string2.s
  374.     |SCAN.lxLT: bool := string1.s <  string2.s
  375.     |SCAN.lxGT: bool := string1.s >  string2.s
  376.     |SCAN.lxLE: bool := string1.s <= string2.s
  377.     |SCAN.lxGE: bool := string1.s >= string2.s
  378.     END;
  379.  
  380.     ARITH.setbool(v, bool)
  381. END strcmp;
  382.  
  383.  
  384. PROCEDURE ConstExpression* (parser: PARSER; VAR v: ARITH.VALUE);
  385. VAR
  386.     e: EXPR;
  387.     pos: POSITION;
  388.  
  389. BEGIN
  390.     getpos(parser, pos);
  391.     parser.constexp := TRUE;
  392.     parser.expression(parser, e);
  393.     parser.constexp := FALSE;
  394.     check(e.obj = eCONST, pos, 62);
  395.     v := e.value
  396. END ConstExpression;
  397.  
  398.  
  399. PROCEDURE FieldList (parser: PARSER; rec: PROG._TYPE);
  400. VAR
  401.     name:   SCAN.IDENT;
  402.     export: BOOLEAN;
  403.     pos:    POSITION;
  404.  
  405. BEGIN
  406.     ASSERT(parser.sym = SCAN.lxIDENT);
  407.  
  408.     WHILE parser.sym = SCAN.lxIDENT DO
  409.  
  410.         getpos(parser, pos);
  411.  
  412.         name := parser.lex.ident;
  413.  
  414.         Next(parser);
  415.  
  416.         export := parser.sym = SCAN.lxMUL;
  417.  
  418.         IF export THEN
  419.             check1(parser.unit.scopeLvl = 0, parser, 61);
  420.             Next(parser)
  421.         END;
  422.  
  423.         check(PROG.addField(rec, name, export), pos, 30);
  424.  
  425.         IF parser.sym = SCAN.lxCOMMA THEN
  426.             ExpectSym(parser, SCAN.lxIDENT)
  427.         ELSE
  428.             checklex(parser, SCAN.lxCOLON)
  429.         END
  430.  
  431.     END
  432.  
  433. END FieldList;
  434.  
  435.  
  436. PROCEDURE FormalParameters (parser: PARSER; _type: PROG._TYPE);
  437. VAR
  438.     ident: PROG.IDENT;
  439.  
  440.  
  441.     PROCEDURE FPSection (parser: PARSER; _type: PROG._TYPE);
  442.     VAR
  443.         ident:   PROG.IDENT;
  444.         exit:    BOOLEAN;
  445.         vPar:    BOOLEAN;
  446.         dim:     INTEGER;
  447.         t0, t1:  PROG._TYPE;
  448.  
  449.     BEGIN
  450.         vPar := parser.sym = SCAN.lxVAR;
  451.         IF vPar THEN
  452.             Next(parser)
  453.         END;
  454.  
  455.         checklex(parser, SCAN.lxIDENT);
  456.         exit := FALSE;
  457.  
  458.         WHILE (parser.sym = SCAN.lxIDENT) & ~exit DO
  459.             check1(PROG.addParam(_type, parser.lex.ident, vPar), parser, 30);
  460.             Next(parser);
  461.             IF parser.sym = SCAN.lxCOMMA THEN
  462.                 ExpectSym(parser, SCAN.lxIDENT)
  463.             ELSIF parser.sym = SCAN.lxCOLON THEN
  464.                 Next(parser);
  465.                 dim := 0;
  466.                 WHILE parser.sym = SCAN.lxARRAY DO
  467.                     INC(dim);
  468.                     check1(dim <= PROG.MAXARRDIM, parser, 84);
  469.                     ExpectSym(parser, SCAN.lxOF);
  470.                     Next(parser)
  471.                 END;
  472.                 checklex(parser, SCAN.lxIDENT);
  473.                 ident := QIdent(parser, FALSE);
  474.                 check1(ident.typ = PROG.idTYPE, parser, 68);
  475.  
  476.                 t0 := ident._type;
  477.                 t1 := t0;
  478.  
  479.                 WHILE dim > 0 DO
  480.                     t1 := PROG.enterType(PROG.tARRAY, -1, 0, parser.unit);
  481.                     t1.base := t0;
  482.                     t0 := t1;
  483.                     DEC(dim)
  484.                 END;
  485.  
  486.                 PROG.setParams(_type, t1);
  487.                 Next(parser);
  488.                 exit := TRUE
  489.             ELSE
  490.                 checklex(parser, SCAN.lxCOLON)
  491.             END
  492.         END
  493.  
  494.     END FPSection;
  495.  
  496.  
  497. BEGIN
  498.     IF parser.sym = SCAN.lxLROUND THEN
  499.  
  500.         Next(parser);
  501.  
  502.         IF (parser.sym = SCAN.lxVAR) OR (parser.sym = SCAN.lxIDENT) THEN
  503.             FPSection(parser, _type);
  504.             WHILE parser.sym = SCAN.lxSEMI DO
  505.                 Next(parser);
  506.                 FPSection(parser, _type)
  507.             END
  508.         END;
  509.  
  510.         checklex(parser, SCAN.lxRROUND);
  511.         Next(parser);
  512.  
  513.         IF parser.sym = SCAN.lxCOLON THEN
  514.             ExpectSym(parser, SCAN.lxIDENT);
  515.             ident := QIdent(parser, FALSE);
  516.             check1(ident.typ = PROG.idTYPE, parser, 68);
  517.             check1(~(ident._type.typ IN {PROG.tRECORD, PROG.tARRAY}), parser, 69);
  518.             check1( ~(ODD(_type.call) & (ident._type.typ = PROG.tREAL)), parser, 113);
  519.             _type.base := ident._type;
  520.             Next(parser)
  521.         ELSE
  522.             _type.base := NIL
  523.         END
  524.  
  525.     END
  526. END FormalParameters;
  527.  
  528.  
  529. PROCEDURE sysflag (parser: PARSER; proc: BOOLEAN): INTEGER;
  530. VAR
  531.     res, sf: INTEGER;
  532.  
  533. BEGIN
  534.     checklex(parser, SCAN.lxIDENT);
  535.     IF parser.lex.ident.s = "stdcall" THEN
  536.         sf := PROG.sf_stdcall
  537.     ELSIF parser.lex.ident.s = "cdecl" THEN
  538.         sf := PROG.sf_cdecl
  539.     ELSIF parser.lex.ident.s = "ccall" THEN
  540.         sf := PROG.sf_ccall
  541.     ELSIF parser.lex.ident.s = "win64" THEN
  542.         sf := PROG.sf_win64
  543.     ELSIF parser.lex.ident.s = "systemv" THEN
  544.         sf := PROG.sf_systemv
  545.     ELSIF parser.lex.ident.s = "windows" THEN
  546.         sf := PROG.sf_windows
  547.     ELSIF parser.lex.ident.s = "linux" THEN
  548.         sf := PROG.sf_linux
  549.     ELSIF parser.lex.ident.s = "code" THEN
  550.         sf := PROG.sf_code
  551.     ELSIF parser.lex.ident.s = "oberon" THEN
  552.         sf := PROG.sf_oberon
  553.     ELSIF parser.lex.ident.s = "noalign" THEN
  554.         sf := PROG.sf_noalign
  555.     ELSE
  556.         check1(FALSE, parser, 124)
  557.     END;
  558.  
  559.     check1(sf IN PROG.program.sysflags, parser, 125);
  560.  
  561.     IF proc THEN
  562.         check1(sf IN PROG.proc_flags, parser, 123)
  563.     ELSE
  564.         check1(sf IN PROG.rec_flags, parser, 123)
  565.     END;
  566.  
  567.     CASE sf OF
  568.     |PROG.sf_stdcall:
  569.         res := PROG.stdcall
  570.     |PROG.sf_cdecl:
  571.         res := PROG.cdecl
  572.     |PROG.sf_ccall:
  573.         IF TARGETS.OS IN {TARGETS.osWIN32, TARGETS.osLINUX32, TARGETS.osKOS} THEN
  574.             res := PROG.ccall
  575.         ELSIF TARGETS.OS = TARGETS.osWIN64 THEN
  576.             res := PROG.win64
  577.         ELSIF TARGETS.OS = TARGETS.osLINUX64 THEN
  578.             res := PROG.systemv
  579.         END
  580.     |PROG.sf_win64:
  581.         res := PROG.win64
  582.     |PROG.sf_systemv:
  583.         res := PROG.systemv
  584.     |PROG.sf_code:
  585.         res := PROG.code
  586.     |PROG.sf_oberon:
  587.         IF TARGETS.OS IN {TARGETS.osWIN32, TARGETS.osLINUX32, TARGETS.osKOS} THEN
  588.             res := PROG.default32
  589.         ELSIF TARGETS.OS IN {TARGETS.osWIN64, TARGETS.osLINUX64} THEN
  590.             res := PROG.default64
  591.         END
  592.     |PROG.sf_windows:
  593.         IF TARGETS.OS = TARGETS.osWIN32 THEN
  594.             res := PROG.stdcall
  595.         ELSIF TARGETS.OS = TARGETS.osWIN64 THEN
  596.             res := PROG.win64
  597.         END
  598.     |PROG.sf_linux:
  599.         IF TARGETS.OS = TARGETS.osLINUX32 THEN
  600.             res := PROG.ccall
  601.         ELSIF TARGETS.OS = TARGETS.osLINUX64 THEN
  602.             res := PROG.systemv
  603.         END
  604.     |PROG.sf_noalign:
  605.         res := PROG.noalign
  606.     END
  607.  
  608.     RETURN res
  609. END sysflag;
  610.  
  611.  
  612. PROCEDURE procflag (parser: PARSER; VAR _import: IL.IMPORT_PROC; isProc: BOOLEAN): INTEGER;
  613. VAR
  614.     call: INTEGER;
  615.     dll, proc: SCAN.TEXTSTR;
  616.     pos: POSITION;
  617.  
  618.  
  619.     PROCEDURE getStr (parser: PARSER; VAR name: SCAN.TEXTSTR);
  620.     VAR
  621.         pos: POSITION;
  622.         str: ARITH.VALUE;
  623.  
  624.     BEGIN
  625.         getpos(parser, pos);
  626.         ConstExpression(parser, str);
  627.         IF str.typ = ARITH.tSTRING THEN
  628.             name := str.string(SCAN.STRING).s
  629.         ELSIF str.typ = ARITH.tCHAR THEN
  630.             ARITH.charToStr(str, name)
  631.         ELSE
  632.             check(FALSE, pos, 117)
  633.         END
  634.     END getStr;
  635.  
  636.  
  637. BEGIN
  638.     _import := NIL;
  639.  
  640.     IF parser.sym = SCAN.lxLSQUARE THEN
  641.         getpos(parser, pos);
  642.         check1(parser.unit.sysimport, parser, 54);
  643.         Next(parser);
  644.         call := sysflag(parser, TRUE);
  645.         Next(parser);
  646.         IF parser.sym = SCAN.lxMINUS THEN
  647.             Next(parser);
  648.             INC(call)
  649.         END;
  650.  
  651.         IF isProc & (parser.sym = SCAN.lxCOMMA) THEN
  652.             Next(parser);
  653.             getStr(parser, dll);
  654.             STRINGS.UpCase(dll);
  655.             checklex(parser, SCAN.lxCOMMA);
  656.             Next(parser);
  657.             getStr(parser, proc);
  658.             _import := IL.AddImp(dll, proc)
  659.         END;
  660.  
  661.         checklex(parser, SCAN.lxRSQUARE);
  662.         Next(parser)
  663.     ELSE
  664.         CASE TARGETS.BitDepth OF
  665.         |16: call := PROG.default16
  666.         |32: IF TARGETS.CPU = TARGETS.cpuX86 THEN
  667.                  call := PROG.default32
  668.              ELSE
  669.                  call := PROG.cdecl
  670.              END
  671.         |64: IF TARGETS.CPU = TARGETS.cpuAMD64 THEN
  672.                  call := PROG.default64
  673.              ELSE
  674.                  call := PROG.cdecl
  675.              END
  676.         END
  677.     END;
  678.  
  679.     IF _import # NIL THEN
  680.         check(TARGETS.Import, pos, 70)
  681.     END
  682.  
  683.     RETURN call
  684. END procflag;
  685.  
  686.  
  687. PROCEDURE _type (parser: PARSER; VAR t: PROG._TYPE; flags: SET);
  688. CONST
  689.     comma   = 0;
  690.     closed  = 1;
  691.     forward = 2;
  692.  
  693. VAR
  694.     arrLen:     ARITH.VALUE;
  695.     typeSize:   ARITH.VALUE;
  696.     ident:      PROG.IDENT;
  697.     unit:       PROG.UNIT;
  698.     pos, pos2:  POSITION;
  699.     fieldType:  PROG._TYPE;
  700.     baseIdent:  SCAN.IDENT;
  701.     a, b:       INTEGER;
  702.     RecFlag:    INTEGER;
  703.     _import:     IL.IMPORT_PROC;
  704.  
  705. BEGIN
  706.     unit := parser.unit;
  707.     t := NIL;
  708.  
  709.     IF parser.sym = SCAN.lxIDENT THEN
  710.         ident := QIdent(parser, forward IN flags);
  711.  
  712.         IF ident # NIL THEN
  713.             check1(ident.typ = PROG.idTYPE, parser, 49);
  714.             t := ident._type;
  715.             check1(t # NIL, parser, 50);
  716.             IF closed IN flags THEN
  717.                 check1(t.closed, parser, 50)
  718.             END
  719.         END;
  720.  
  721.         Next(parser)
  722.  
  723.     ELSIF (parser.sym = SCAN.lxARRAY) OR ((parser.sym = SCAN.lxCOMMA) & (comma IN flags)) THEN
  724.  
  725.         IF parser.sym = SCAN.lxARRAY THEN
  726.             getpos(parser, pos2)
  727.         END;
  728.         NextPos(parser, pos);
  729.  
  730.         ConstExpression(parser, arrLen);
  731.  
  732.         check(arrLen.typ = ARITH.tINTEGER, pos, 43);
  733.         check(ARITH.check(arrLen),         pos, 39);
  734.         check(ARITH.getInt(arrLen) > 0,    pos, 51);
  735.  
  736.         t := PROG.enterType(PROG.tARRAY, -1, ARITH.getInt(arrLen), unit);
  737.  
  738.         IF parser.sym = SCAN.lxCOMMA THEN
  739.             _type(parser, t.base, {comma, closed})
  740.         ELSIF parser.sym = SCAN.lxOF THEN
  741.             Next(parser);
  742.             _type(parser, t.base, {closed})
  743.         ELSE
  744.             check1(FALSE, parser, 47)
  745.         END;
  746.  
  747.         t.align := t.base.align;
  748.  
  749.         a := t.length;
  750.         b := t.base.size;
  751.         check(ARITH.mulInt(a, b), pos2, 104);
  752.         check(ARITH.setInt(typeSize, a), pos2, 104);
  753.         t.size := a;
  754.  
  755.         t.closed := TRUE
  756.  
  757.     ELSIF parser.sym = SCAN.lxRECORD THEN
  758.         getpos(parser, pos2);
  759.         Next(parser);
  760.  
  761.         t := PROG.enterType(PROG.tRECORD, 0, 0, unit);
  762.         t.align := 1;
  763.  
  764.         IF parser.sym = SCAN.lxLSQUARE THEN
  765.             check1(parser.unit.sysimport, parser, 54);
  766.             Next(parser);
  767.             RecFlag := sysflag(parser, FALSE);
  768.             t.noalign := RecFlag = PROG.noalign;
  769.             ExpectSym(parser, SCAN.lxRSQUARE);
  770.             Next(parser)
  771.         END;
  772.  
  773.         IF parser.sym = SCAN.lxLROUND THEN
  774.             check1(~t.noalign, parser, 111);
  775.             ExpectSym(parser, SCAN.lxIDENT);
  776.             getpos(parser, pos);
  777.  
  778.             _type(parser, t.base, {closed});
  779.  
  780.             check(t.base.typ IN {PROG.tRECORD, PROG.tPOINTER}, pos, 52);
  781.  
  782.             IF t.base.typ = PROG.tPOINTER THEN
  783.                 t.base := t.base.base;
  784.                 check(t.base # NIL, pos, 55)
  785.             END;
  786.  
  787.             check(~t.base.noalign, pos, 112);
  788.  
  789.             checklex(parser, SCAN.lxRROUND);
  790.             Next(parser);
  791.  
  792.             t.size := t.base.size;
  793.             IF t.base.align > t.align THEN
  794.                 t.align := t.base.align
  795.             END
  796.         ELSE
  797.             t.base := PROG.program.stTypes.tANYREC
  798.         END;
  799.  
  800.         WHILE parser.sym = SCAN.lxIDENT DO
  801.             FieldList(parser, t);
  802.  
  803.             ASSERT(parser.sym = SCAN.lxCOLON);
  804.             Next(parser);
  805.  
  806.             _type(parser, fieldType, {closed});
  807.             check(PROG.setFields(t, fieldType), pos2, 104);
  808.  
  809.             IF (fieldType.align > t.align) & ~t.noalign THEN
  810.                 t.align := fieldType.align
  811.             END;
  812.  
  813.             IF parser.sym = SCAN.lxSEMI THEN
  814.                 ExpectSym(parser, SCAN.lxIDENT)
  815.             ELSE
  816.                 checklex(parser, SCAN.lxEND)
  817.             END
  818.         END;
  819.  
  820.         t.closed := TRUE;
  821.  
  822.         IL.AddRec(t.base.num);
  823.  
  824.         IF ~t.noalign THEN
  825.             check(UTILS.Align(t.size, t.align), pos2, 104);
  826.             check(ARITH.setInt(typeSize, t.size), pos2, 104)
  827.         END;
  828.  
  829.         checklex(parser, SCAN.lxEND);
  830.         Next(parser)
  831.  
  832.     ELSIF parser.sym = SCAN.lxPOINTER THEN
  833.         ExpectSym(parser, SCAN.lxTO);
  834.         Next(parser);
  835.  
  836.         t := PROG.enterType(PROG.tPOINTER, TARGETS.AdrSize, 0, unit);
  837.         t.align := TARGETS.AdrSize;
  838.  
  839.         getpos(parser, pos);
  840.  
  841.         IF parser.sym = SCAN.lxIDENT THEN
  842.             baseIdent := parser.lex.ident
  843.         END;
  844.  
  845.         _type(parser, t.base, {forward});
  846.  
  847.         IF t.base # NIL THEN
  848.             check(t.base.typ = PROG.tRECORD, pos, 58)
  849.         ELSE
  850.             PROG.frwPtr(unit, t, baseIdent, pos)
  851.         END
  852.  
  853.     ELSIF parser.sym = SCAN.lxPROCEDURE THEN
  854.         NextPos(parser, pos);
  855.         t := PROG.enterType(PROG.tPROCEDURE, TARGETS.AdrSize, 0, unit);
  856.         t.align := TARGETS.AdrSize;
  857.         t.call := procflag(parser, _import, FALSE);
  858.         FormalParameters(parser, t)
  859.     ELSE
  860.         check1(FALSE, parser, 49)
  861.     END
  862.  
  863. END _type;
  864.  
  865.  
  866. PROCEDURE IdentDef (parser: PARSER; typ: INTEGER; VAR name: SCAN.IDENT): PROG.IDENT;
  867. VAR
  868.     ident:  PROG.IDENT;
  869.     pos:    POSITION;
  870.  
  871. BEGIN
  872.     ASSERT(parser.sym = SCAN.lxIDENT);
  873.  
  874.     name := parser.lex.ident;
  875.     getpos(parser, pos);
  876.     ident := PROG.addIdent(parser.unit, name, typ);
  877.     check(ident # NIL, pos, 30);
  878.     ident.pos := pos;
  879.     Next(parser);
  880.  
  881.     IF parser.sym = SCAN.lxMUL THEN
  882.         check1(ident.global, parser, 61);
  883.         ident.export := TRUE;
  884.         Next(parser)
  885.     END
  886.  
  887.     RETURN ident
  888. END IdentDef;
  889.  
  890.  
  891. PROCEDURE ConstTypeDeclaration (parser: PARSER; _const: BOOLEAN);
  892. VAR
  893.     ident: PROG.IDENT;
  894.     name:  SCAN.IDENT;
  895.     pos:   POSITION;
  896.  
  897. BEGIN
  898.     IF _const THEN
  899.         ident := IdentDef(parser, PROG.idNONE, name)
  900.     ELSE
  901.         ident := IdentDef(parser, PROG.idTYPE, name)
  902.     END;
  903.  
  904.     checklex(parser, SCAN.lxEQ);
  905.     NextPos(parser, pos);
  906.  
  907.     IF _const THEN
  908.         ConstExpression(parser, ident.value);
  909.         IF ident.value.typ = ARITH.tINTEGER THEN
  910.             check(ARITH.check(ident.value), pos, 39)
  911.         ELSIF ident.value.typ = ARITH.tREAL THEN
  912.             check(ARITH.check(ident.value), pos, 40)
  913.         END;
  914.         ident.typ  := PROG.idCONST;
  915.         ident._type := PROG.getType(ident.value.typ)
  916.     ELSE
  917.         _type(parser, ident._type, {})
  918.     END;
  919.  
  920.     checklex(parser, SCAN.lxSEMI);
  921.     Next(parser)
  922.  
  923. END ConstTypeDeclaration;
  924.  
  925.  
  926. PROCEDURE VarDeclaration (parser: PARSER);
  927. VAR
  928.     ident: PROG.IDENT;
  929.     name:  SCAN.IDENT;
  930.     t:     PROG._TYPE;
  931.  
  932. BEGIN
  933.  
  934.     REPEAT
  935.         ident := IdentDef(parser, PROG.idVAR, name);
  936.  
  937.         IF parser.sym = SCAN.lxCOMMA THEN
  938.             ExpectSym(parser, SCAN.lxIDENT)
  939.         ELSIF parser.sym = SCAN.lxCOLON THEN
  940.             Next(parser);
  941.             _type(parser, t, {});
  942.             PROG.setVarsType(parser.unit, t);
  943.             checklex(parser, SCAN.lxSEMI);
  944.             Next(parser)
  945.         ELSE
  946.             checklex(parser, SCAN.lxCOLON)
  947.         END
  948.  
  949.     UNTIL parser.sym # SCAN.lxIDENT
  950.  
  951. END VarDeclaration;
  952.  
  953.  
  954. PROCEDURE DeclarationSequence (parser: PARSER): BOOLEAN;
  955. VAR
  956.     ptr: PROG.FRWPTR;
  957.     endmod: BOOLEAN;
  958.     pos: POSITION;
  959.  
  960.  
  961.     PROCEDURE ProcDeclaration (parser: PARSER): BOOLEAN;
  962.     VAR
  963.         proc:       PROG.IDENT;
  964.         endname,
  965.         name:       SCAN.IDENT;
  966.         param:      PROG.PARAM;
  967.         unit:       PROG.UNIT;
  968.         ident:      PROG.IDENT;
  969.         e:          EXPR;
  970.         pos, pos1,
  971.         pos2:       POSITION;
  972.         label:      INTEGER;
  973.         enter:      IL.COMMAND;
  974.         call:       INTEGER;
  975.         t:          PROG._TYPE;
  976.         _import:    IL.IMPORT_PROC;
  977.         endmod, b:  BOOLEAN;
  978.         fparams:    SET;
  979.         int, flt:   INTEGER;
  980.         comma:      BOOLEAN;
  981.         code, iv:   ARITH.VALUE;
  982.         codeProc,
  983.         handler:    BOOLEAN;
  984.         line:       INTEGER;
  985.  
  986.     BEGIN
  987.         endmod := FALSE;
  988.         handler := FALSE;
  989.  
  990.         unit := parser.unit;
  991.  
  992.         call := procflag(parser, _import, TRUE);
  993.  
  994.         getpos(parser, pos);
  995.         pos1 := pos;
  996.         checklex(parser, SCAN.lxIDENT);
  997.         line := pos.line;
  998.  
  999.         IF _import # NIL THEN
  1000.             proc := IdentDef(parser, PROG.idIMP, name);
  1001.             proc._import := _import;
  1002.             IF _import.name = "" THEN
  1003.                 COPY(name.s, _import.name)
  1004.             END;
  1005.             PROG.program.procs.last(PROG.PROC)._import := _import
  1006.         ELSE
  1007.             proc := IdentDef(parser, PROG.idPROC, name)
  1008.         END;
  1009.  
  1010.         check(PROG.openScope(unit, proc.proc), pos, 116);
  1011.  
  1012.         proc._type := PROG.enterType(PROG.tPROCEDURE, TARGETS.AdrSize, 0, unit);
  1013.         t := proc._type;
  1014.         t.align := TARGETS.AdrSize;
  1015.         t.call  := call;
  1016.  
  1017.         FormalParameters(parser, t);
  1018.  
  1019.         IF parser.sym = SCAN.lxLSQUARE THEN
  1020.             getpos(parser, pos2);
  1021.             check((TARGETS.CPU = TARGETS.cpuTHUMB) & (TARGETS.OS = TARGETS.osNONE), pos2, 24);
  1022.             Next(parser);
  1023.             getpos(parser, pos2);
  1024.             ConstExpression(parser, iv);
  1025.             check(iv.typ = ARITH.tINTEGER, pos2, 43);
  1026.             check((0 <= ARITH.Int(iv)) & (ARITH.Int(iv) <= THUMB.maxIVT), pos2, 46);
  1027.             check(THUMB.SetIV(ARITH.Int(iv)), pos2, 121);
  1028.             checklex(parser, SCAN.lxRSQUARE);
  1029.             Next(parser);
  1030.             handler := TRUE
  1031.         END;
  1032.  
  1033.         codeProc := call IN {PROG.code, PROG._code};
  1034.  
  1035.         IF call IN {PROG.systemv, PROG._systemv} THEN
  1036.             check(t.parSize <= PROG.MAXSYSVPARAM, pos, 120)
  1037.         END;
  1038.  
  1039.         param := t.params.first(PROG.PARAM);
  1040.         WHILE param # NIL DO
  1041.             ident := PROG.addIdent(unit, param.name, PROG.idPARAM);
  1042.             ASSERT(ident # NIL);
  1043.             ident._type := param._type;
  1044.             ident.offset := param.offset;
  1045.             IF param.vPar THEN
  1046.                 ident.typ := PROG.idVPAR
  1047.             END;
  1048.             param := param.next(PROG.PARAM)
  1049.         END;
  1050.  
  1051.         IF _import = NIL THEN
  1052.             label := IL.NewLabel();
  1053.             proc.proc.label := label;
  1054.             proc.proc.used  := handler;
  1055.             IF handler THEN
  1056.                 IL.AddCmd2(IL.opHANDLER, label, ARITH.Int(iv))
  1057.             END
  1058.         END;
  1059.  
  1060.         IF codeProc THEN
  1061.             enter := IL.EnterC(label);
  1062.             comma := FALSE;
  1063.             WHILE (parser.sym # SCAN.lxSEMI) OR comma DO
  1064.                 getpos(parser, pos2);
  1065.                 ConstExpression(parser, code);
  1066.                 check(code.typ = ARITH.tINTEGER, pos2, 43);
  1067.                 IF TARGETS.WordSize > TARGETS.InstrSize THEN
  1068.                     CASE TARGETS.InstrSize OF
  1069.                     |1: check(ARITH.range(code, 0, 255), pos, 42)
  1070.                     |2: check(ARITH.range(code, 0, 65535), pos, 110)
  1071.                     END
  1072.                 END;
  1073.                 IL.AddCmd(IL.opCODE, ARITH.getInt(code));
  1074.                 comma := parser.sym = SCAN.lxCOMMA;
  1075.                 IF comma THEN
  1076.                     Next(parser)
  1077.                 ELSE
  1078.                     checklex(parser, SCAN.lxSEMI)
  1079.                 END
  1080.             END
  1081.         END;
  1082.  
  1083.         checklex(parser, SCAN.lxSEMI);
  1084.         Next(parser);
  1085.  
  1086.         IF _import = NIL THEN
  1087.  
  1088.             IF parser.main & proc.export & TARGETS.Dll THEN
  1089.                 IF TARGETS.target = TARGETS.KolibriOSDLL THEN
  1090.                     check((proc.name.s # "lib_init") & (proc.name.s # "version"), pos, 114)
  1091.                 END;
  1092.                 IL.AddExp(label, proc.name.s);
  1093.                 proc.proc.used := TRUE
  1094.             END;
  1095.  
  1096.             IF ~codeProc THEN
  1097.                 b := DeclarationSequence(parser)
  1098.             END;
  1099.  
  1100.             PROG.ResetLocSize;
  1101.             IF call IN {PROG._win64, PROG.win64} THEN
  1102.                 fparams := PROG.getFloatParamsPos(proc._type, 3, int, flt);
  1103.                 enter := IL.Enter(label, LSL(ORD(fparams), 5) + MIN(proc._type.parSize, 4))
  1104.             ELSIF call IN {PROG._systemv, PROG.systemv} THEN
  1105.                 fparams := PROG.getFloatParamsPos(proc._type, PROG.MAXSYSVPARAM - 1, int, flt);
  1106.                 enter := IL.Enter(label, -(LSL(ORD(fparams), 5) + proc._type.parSize))
  1107.             ELSIF codeProc THEN
  1108.  
  1109.             ELSE
  1110.                 enter := IL.Enter(label, 0)
  1111.             END;
  1112.             proc.proc.enter := enter;
  1113.  
  1114.             IF ~codeProc & (parser.sym = SCAN.lxBEGIN) THEN
  1115.                 Next(parser);
  1116.                 parser.StatSeq(parser)
  1117.             END;
  1118.  
  1119.             IF ~codeProc & (t.base # NIL) THEN
  1120.                 checklex(parser, SCAN.lxRETURN);
  1121.                 NextPos(parser, pos);
  1122.                 parser.expression(parser, e);
  1123.                 check(parser.chkreturn(parser, e, t.base, pos), pos, 87)
  1124.             END;
  1125.  
  1126.             IF ~codeProc THEN
  1127.                 proc.proc.leave := IL.Leave(t.base # NIL, (t.base # NIL) & (t.base.typ = PROG.tREAL), PROG.program.locsize,
  1128.                     t.parSize * ORD((t.call IN PROG.callee_clean_up) OR (t.call IN {PROG.systemv, PROG._systemv})));
  1129.                 enter.param2 := PROG.program.locsize;
  1130.                 checklex(parser, SCAN.lxEND)
  1131.             ELSE
  1132.                 proc.proc.leave := IL.LeaveC()
  1133.             END;
  1134.  
  1135.             IF (TARGETS.CPU = TARGETS.cpuMSP430) & ~codeProc THEN
  1136.                 check(MSP430.CheckProcDataSize(enter.param2 + proc._type.parSize, PROG.program.options.ram), pos1, 63);
  1137.                 enter.param2 := enter.param2 * 65536 + line;
  1138.                 enter.param3 := IL.codes.errlabels[10]
  1139.             END
  1140.         END;
  1141.  
  1142.         IF parser.sym = SCAN.lxEND THEN
  1143.             Next(parser);
  1144.             IF parser.sym = SCAN.lxIDENT THEN
  1145.                 getpos(parser, pos);
  1146.                 endname := parser.lex.ident;
  1147.                 IF ~codeProc & (_import = NIL) THEN
  1148.                     check(PROG.IdEq(endname, name), pos, 60);
  1149.                     ExpectSym(parser, SCAN.lxSEMI);
  1150.                     Next(parser)
  1151.                 ELSE
  1152.                     IF PROG.IdEq(endname, parser.unit.name) THEN
  1153.                         ExpectSym(parser, SCAN.lxPOINT);
  1154.                         Next(parser);
  1155.                         endmod := TRUE
  1156.                     ELSIF PROG.IdEq(endname, name) THEN
  1157.                         ExpectSym(parser, SCAN.lxSEMI);
  1158.                         Next(parser)
  1159.                     ELSE
  1160.                         error(pos, 60)
  1161.                     END
  1162.                 END
  1163.             ELSIF parser.sym = SCAN.lxSEMI THEN
  1164.                 Next(parser)
  1165.             ELSE
  1166.                 checklex(parser, SCAN.lxIDENT)
  1167.             END
  1168.         END;
  1169.  
  1170.         PROG.closeScope(unit);
  1171.  
  1172.         RETURN endmod
  1173.     END ProcDeclaration;
  1174.  
  1175.  
  1176. BEGIN
  1177.     IF parser.sym = SCAN.lxCONST THEN
  1178.         Next(parser);
  1179.         WHILE parser.sym = SCAN.lxIDENT DO
  1180.             ConstTypeDeclaration(parser, TRUE)
  1181.         END
  1182.     END;
  1183.  
  1184.     IF parser.sym = SCAN.lxTYPE THEN
  1185.         Next(parser);
  1186.         WHILE parser.sym = SCAN.lxIDENT DO
  1187.             ConstTypeDeclaration(parser, FALSE)
  1188.         END
  1189.     END;
  1190.  
  1191.     ptr := PROG.linkPtr(parser.unit);
  1192.     IF ptr # NIL THEN
  1193.         pos.line := ptr.pos.line;
  1194.         pos.col  := ptr.pos.col;
  1195.         pos.parser := parser;
  1196.         IF ptr.notRecord THEN
  1197.             error(pos, 58)
  1198.         ELSE
  1199.             error(pos, 48)
  1200.         END
  1201.     END;
  1202.  
  1203.     IF parser.sym = SCAN.lxVAR THEN
  1204.         Next(parser);
  1205.         IF parser.sym = SCAN.lxIDENT THEN
  1206.             VarDeclaration(parser)
  1207.         END
  1208.     END;
  1209.  
  1210.     endmod := FALSE;
  1211.     WHILE ~endmod & (parser.sym = SCAN.lxPROCEDURE) DO
  1212.         Next(parser);
  1213.         endmod := ProcDeclaration(parser)
  1214.     END
  1215.  
  1216.     RETURN endmod
  1217. END DeclarationSequence;
  1218.  
  1219.  
  1220. PROCEDURE parse (parser: PARSER);
  1221. VAR
  1222.     unit:     PROG.UNIT;
  1223.     label:    INTEGER;
  1224.     name:     INTEGER;
  1225.     endmod:   BOOLEAN;
  1226.     errlabel: INTEGER;
  1227.     errno:    INTEGER;
  1228.  
  1229. BEGIN
  1230.     ASSERT(parser # NIL);
  1231.     ASSERT(parser.scanner # NIL);
  1232.  
  1233.     ExpectSym(parser, SCAN.lxMODULE);
  1234.     ExpectSym(parser, SCAN.lxIDENT);
  1235.  
  1236.     IF ~parser.main THEN
  1237.         check1(parser.lex.ident.s = parser.modname, parser, 23)
  1238.     END;
  1239.  
  1240.     unit := PROG.newUnit(parser.lex.ident);
  1241.     unit.fname := parser.fname;
  1242.     parser.unit := unit;
  1243.  
  1244.     ExpectSym(parser, SCAN.lxSEMI);
  1245.  
  1246.     Next(parser);
  1247.     IF parser.sym = SCAN.lxIMPORT THEN
  1248.         ImportList(parser)
  1249.     END;
  1250.  
  1251.     INC(modules);
  1252.  
  1253.     CONSOLE.String("compiling ");
  1254.     CONSOLE.String("("); CONSOLE.Int(modules); CONSOLE.String(") ");
  1255.     CONSOLE.String(unit.name.s);
  1256.     IF parser.unit.sysimport THEN
  1257.         CONSOLE.String(" (SYSTEM)")
  1258.     END;
  1259.     CONSOLE.Ln;
  1260.  
  1261.     IF TARGETS.CPU IN {TARGETS.cpuX86, TARGETS.cpuAMD64} THEN
  1262.         IL.fname(parser.fname)
  1263.     END;
  1264.  
  1265.     label := IL.NewLabel();
  1266.     IL.Jmp(IL.opJMP, label);
  1267.  
  1268.     name := IL.putstr(unit.name.s);
  1269.  
  1270.     errlabel := IL.NewLabel();
  1271.     IL.SetLabel(errlabel);
  1272.     IL.StrAdr(name);
  1273.     IL.Param1;
  1274.     IL.AddCmd(IL.opPUSHC, modules);
  1275.     IL.AddCmd0(IL.opERR);
  1276.  
  1277.     FOR errno := 1 TO LEN(IL.codes.errlabels) - 1 DO
  1278.         IL.SetErrLabel(errno);
  1279.         IL.AddCmd(IL.opPUSHC, errno);
  1280.         IL.Jmp(IL.opJMP, errlabel)
  1281.     END;
  1282.  
  1283.     endmod := DeclarationSequence(parser);
  1284.  
  1285.     IL.SetLabel(label);
  1286.  
  1287.     IF ~endmod THEN
  1288.  
  1289.         IF parser.sym = SCAN.lxBEGIN THEN
  1290.             Next(parser);
  1291.             parser.StatSeq(parser)
  1292.         END;
  1293.  
  1294.         checklex(parser, SCAN.lxEND);
  1295.  
  1296.         ExpectSym(parser, SCAN.lxIDENT);
  1297.         check1(parser.lex.ident.s = unit.name.s, parser, 25);
  1298.         ExpectSym(parser, SCAN.lxPOINT)
  1299.     END;
  1300.  
  1301.     INC(lines, parser.lex.pos.line);
  1302.     PROG.closeUnit(unit)
  1303. END parse;
  1304.  
  1305.  
  1306. PROCEDURE open (parser: PARSER; modname, FileExt: ARRAY OF CHAR): BOOLEAN;
  1307. BEGIN
  1308.     ASSERT(parser # NIL);
  1309.  
  1310.     STRINGS.append(parser.fname, modname);
  1311.     STRINGS.append(parser.fname, FileExt);
  1312.     STRINGS.append(parser.modname, modname);
  1313.  
  1314.     parser.scanner := SCAN.open(parser.fname)
  1315.  
  1316.     RETURN parser.scanner # NIL
  1317. END open;
  1318.  
  1319.  
  1320. PROCEDURE NewParser (): PARSER;
  1321. VAR
  1322.     pars:  PARSER;
  1323.     citem: C.ITEM;
  1324.  
  1325. BEGIN
  1326.     citem := C.pop(parsers);
  1327.     IF citem = NIL THEN
  1328.         NEW(pars)
  1329.     ELSE
  1330.         pars := citem(PARSER)
  1331.     END
  1332.  
  1333.     RETURN pars
  1334. END NewParser;
  1335.  
  1336.  
  1337. PROCEDURE create* (path, lib_path: PATH; StatSeq: STATPROC; expression, designator: EXPRPROC; chkreturn: RETPROC): PARSER;
  1338. VAR
  1339.     parser: PARSER;
  1340.  
  1341. BEGIN
  1342.     parser := NewParser();
  1343.  
  1344.     parser.path     := path;
  1345.     parser.lib_path := lib_path;
  1346.     parser.ext      := UTILS.FILE_EXT;
  1347.     parser.fname    := path;
  1348.     parser.modname  := "";
  1349.     parser.scanner  := NIL;
  1350.     parser.unit     := NIL;
  1351.     parser.constexp := FALSE;
  1352.     parser.main     := FALSE;
  1353.  
  1354.     parser.open       := open;
  1355.     parser.parse      := parse;
  1356.     parser.StatSeq    := StatSeq;
  1357.     parser.expression := expression;
  1358.     parser.designator := designator;
  1359.     parser.chkreturn  := chkreturn;
  1360.     parser.create     := create
  1361.  
  1362.     RETURN parser
  1363. END create;
  1364.  
  1365.  
  1366. PROCEDURE init* (options: PROG.OPTIONS);
  1367. BEGIN
  1368.     PROG.create(options);
  1369.     parsers := C.create();
  1370.     lines   := 0;
  1371.     modules := 0
  1372. END init;
  1373.  
  1374.  
  1375. END PARS.