Subversion Repositories Kolibri OS

Rev

Rev 1717 | Rev 1910 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. format MS COFF
  2. public EXPORTS
  3. section '.flat' code readable align 16
  4.  
  5. include '../../../../macros.inc'
  6. include '../../../../proc32.inc'
  7.  
  8. ;-----------------------------------------------------------------------------
  9. mem.alloc   dd ? ;функция для выделения памяти
  10. mem.free    dd ? ;функция для освобождения памяти
  11. mem.realloc dd ? ;функция для перераспределения памяти
  12. dll.load    dd ?
  13.  
  14. BUF_STRUCT_SIZE equ 21
  15. buf2d_data equ dword[edi] ;данные буфера изображения
  16. buf2d_w equ dword[edi+8] ;ширина буфера
  17. buf2d_h equ dword[edi+12] ;высота буфера
  18. buf2d_l equ word[edi+4]
  19. buf2d_t equ word[edi+6] ;отступ сверху
  20. buf2d_size_lt equ dword[edi+4] ;отступ слева и справа для буфера
  21. buf2d_color equ dword[edi+16] ;цвет фона буфера
  22. buf2d_bits equ byte[edi+20] ;количество бит в 1-й точке изображения
  23.  
  24. struct buf_2d_header
  25.         img_data dd ?
  26.         left dw ? ;+4 left
  27.         top dw ? ;+6 top
  28.         size_x dd ? ;+8 w
  29.         size_y dd ? ;+12 h
  30.         color dd ? ;+16 color
  31.         bit_pp db ? ;+21 bit in pixel
  32. ends
  33.  
  34. macro swap v1, v2 {
  35.   push v1
  36.   push v2
  37.   pop v1
  38.   pop v2
  39. }
  40.  
  41. ;флаги, для функции обрезания буфера
  42. BUF2D_OPT_CROP_TOP equ 1 ;обрезка сверху
  43. BUF2D_OPT_CROP_LEFT equ 2 ;обрезка слева
  44. BUF2D_OPT_CROP_BOTTOM equ 4 ;обрезка снизу
  45. BUF2D_OPT_CROP_RIGHT equ 8 ;обрезка справа
  46. BUF2D_BIT_OPT_CROP_TOP equ 0
  47. BUF2D_BIT_OPT_CROP_LEFT equ 1
  48. BUF2D_BIT_OPT_CROP_BOTTOM equ 2
  49. BUF2D_BIT_OPT_CROP_RIGHT equ 3
  50.  
  51. ;input:
  52. ; eax = указатель на функцию выделения памяти
  53. ; ebx = ... освобождения памяти
  54. ; ecx = ... перераспределения памяти
  55. ; edx = ... загрузки библиотеки (пока не используется)
  56. align 16
  57. lib_init:
  58.         mov dword[mem.alloc], eax
  59.         mov dword[mem.free], ebx
  60.         mov dword[mem.realloc], ecx
  61.         mov dword[dll.load], edx
  62.         ret
  63.  
  64. ;input:
  65. ; ebx = coord x
  66. ; ecx = coord y
  67. ; edx = pixel color
  68. ; edi = pointer to buffer struct
  69. align 4
  70. draw_pixel:
  71.         ;cmp buf2d_bits,24
  72.         ;jne @f
  73.         bt ebx,31
  74.         jc @f
  75.         bt ecx,31
  76.         jc @f
  77.         cmp ebx,buf2d_w
  78.         jge @f
  79.         cmp ecx,buf2d_h
  80.         jge @f
  81.         push esi
  82.                 mov esi,buf2d_w ;size x
  83.                 imul esi,ecx ;size_x*y
  84.                 add esi,ebx      ;size_x*y+x
  85.                 lea esi,[esi+esi*2] ;(size_x*y+x)*3
  86.                 add esi,buf2d_data  ;ptr+(size_x*y+x)*3
  87.  
  88.                 mov word[esi],dx ;copy pixel color
  89.                 ror edx,16
  90.                 mov byte[esi+2],dl
  91.                 ror edx,16
  92.         pop esi
  93.         @@:
  94.         ret
  95.  
  96. ;input:
  97. ; ebx = coord x
  98. ; ecx = coord y
  99. ; edi = pointer to buffer struct
  100. ;output:
  101. ; eax = цвет точки
  102. ; в случае ошибки eax = 0xffffffff
  103. align 4
  104. get_pixel_24:
  105.         mov eax,0xffffffff
  106.  
  107.         bt ebx,31
  108.         jc @f
  109.         bt ecx,31
  110.         jc @f
  111.         cmp ebx,buf2d_w
  112.         jge @f
  113.         cmp ecx,buf2d_h
  114.         jge @f
  115.         push esi
  116.                 mov esi,buf2d_w ;size x
  117.                 imul esi,ecx ;size_x*y
  118.                 add esi,ebx      ;size_x*y+x
  119.                 lea esi,[esi+esi*2] ;(size_x*y+x)*3
  120.                 add esi,buf2d_data  ;ptr+(size_x*y+x)*3
  121.  
  122.                 xor eax,eax
  123.                 mov ax,word[esi] ;copy pixel color
  124.                 ror eax,16
  125.                 mov al,byte[esi+2]
  126.                 ror eax,16
  127.         pop esi
  128.         @@:
  129.         ret
  130.  
  131.  
  132. ;создание буфера
  133. align 4
  134. proc buf_create, buf_struc:dword
  135.         pushad
  136.         mov edi,dword[buf_struc]
  137.         mov ecx,buf2d_w
  138.         mov ebx,buf2d_h
  139.         imul ecx,ebx
  140.         cmp buf2d_bits,24
  141.         jne @f
  142.                 lea ecx,[ecx+ecx*2] ; 24 bit = 3
  143.                 ;;;inc ecx ;запасной байт в конце буфера, что-бы не глючили некоторые функции на изображениях кратных 4К
  144.         @@:
  145.         cmp buf2d_bits,32
  146.         jne @f
  147.                 shl ecx,2 ; 32 bit = 4
  148.         @@:
  149.         invoke mem.alloc,ecx
  150.         mov buf2d_data,eax
  151.  
  152.         stdcall buf_clear,edi,buf2d_color ;очистка буфера фоновым цветом
  153.         popad
  154.         ret
  155. endp
  156.  
  157. ;создание буфера на основе изображения rgb
  158. align 4
  159. proc buf_create_f_img, buf_struc:dword, rgb_data:dword
  160.         pushad
  161.         mov edi,dword[buf_struc]
  162.         mov ecx,buf2d_w
  163.         mov ebx,buf2d_h
  164.         imul ecx,ebx
  165.         cmp buf2d_bits,24
  166.         jne @f
  167.                 lea ecx,[ecx+ecx*2] ; 24 bit = 3
  168.                 ;;;inc ecx ;запасной байт в конце буфера, что-бы не глючили некоторые функции на изображениях кратных 4К
  169.         @@:
  170.         cmp buf2d_bits,32
  171.         jne @f
  172.                 shl ecx,2 ; 32 bit = 4
  173.         @@:
  174.         invoke mem.alloc,ecx
  175.         mov buf2d_data,eax
  176.  
  177.         cmp buf2d_bits,24
  178.         jne @f
  179.                 cld
  180.                 mov esi,[rgb_data]
  181.                 mov edi,eax ;eax=buf2d_data
  182.                 rep movsb ;копируем биты изображения в буфер
  183.                 jmp .end_create
  184.         @@:
  185.                 stdcall buf_clear,edi,buf2d_color ;очистка буфера фоновым цветом
  186.         .end_create:
  187.         popad
  188.         ret
  189. endp
  190.  
  191. align 4
  192. proc buf_clear, buf_struc:dword, color:dword ;очистка буфера заданым цветом
  193.         pushad
  194.         mov edi,dword[buf_struc]
  195.  
  196.         mov ecx,buf2d_w
  197.         mov ebx,buf2d_h
  198.         imul ecx,ebx
  199.  
  200.         cld
  201.  
  202.         cmp buf2d_bits,8
  203.         jne .end_clear_8
  204.                 mov edi,buf2d_data
  205.                 mov al,byte[color]
  206.                 rep stosb
  207.                 jmp .end_clear_32
  208.         .end_clear_8:
  209.  
  210.         cmp buf2d_bits,24
  211.         jne .end_clear_24
  212.                 mov edi,buf2d_data
  213.                 mov eax,dword[color]
  214.                 mov ebx,eax
  215.                 shr ebx,16
  216.                 @@:
  217.                         stosw
  218.                         mov byte[edi],bl
  219.                         inc edi
  220.                         loop @b
  221.                 jmp .end_clear_32
  222.         .end_clear_24:
  223.  
  224.         cmp buf2d_bits,32
  225.         jne .end_clear_32
  226.                 mov edi,buf2d_data
  227.                 mov eax,dword[color]
  228.                 rep stosd
  229.                 ;jmp .end_clear_32
  230.         .end_clear_32:
  231.         popad
  232.         ret
  233. endp
  234.  
  235. ;функция для обрезания буферов 8 и 24 битных, по заданому цвету.
  236. ;параметр opt задается комбинацией констант:
  237. ; BUF2D_OPT_CROP_TOP - обрезка сверху
  238. ; BUF2D_OPT_CROP_LEFT - обрезка слева
  239. ; BUF2D_OPT_CROP_BOTTOM - обрезка снизу
  240. ; BUF2D_OPT_CROP_RIGHT - обрезка справа
  241. align 4
  242. proc buf_crop_color, buf_struc:dword, color:dword, opt:dword
  243. locals
  244.         crop_r dd ?
  245. endl
  246.         pushad
  247.         mov edi,dword[buf_struc]
  248.         cmp buf2d_bits,24
  249.         jne .24end_f
  250.  
  251.         bt dword[opt],BUF2D_BIT_OPT_CROP_BOTTOM
  252.         jae .24no_crop_bottom
  253.                 mov eax,dword[color]
  254.                 mov edx,eax ;ax = colors - r,g
  255.                 shr edx,16 ;dl = color - b
  256.                 mov ecx,buf2d_h
  257.                 cmp ecx,1
  258.                 jle .24no_crop_bottom ;проверяем на случай если высота буфера 1 пиксель
  259.                 mov ebx,buf2d_w
  260.                 imul ecx,ebx
  261.                 lea esi,[ecx+ecx*2] ;esi=3*ecx
  262.                 add esi,buf2d_data
  263.                 cld
  264.                 @@:
  265.                         sub esi,3
  266.                         cmp word[esi],ax
  267.                         jne @f
  268.                         cmp byte[esi+2],dl
  269.                         jne @f
  270.                         loop @b
  271.                 @@:
  272.                 lea ebx,[ebx+ebx*2]
  273.                 xor edx,edx
  274.                 mov eax,buf2d_h
  275.                 imul eax,ebx
  276.                 add eax,buf2d_data ;eax - указатель на конец буфера изображения
  277.                 @@:
  278.                         add esi,ebx
  279.                         cmp esi,eax
  280.                         jge @f
  281.                         inc edx ;вычисляем число полных строк для обрезания
  282.                         loop @b
  283.                 @@:
  284.                 cmp edx,0
  285.                 je .24no_crop_bottom
  286.                         cmp edx,buf2d_h
  287.                         jge .24no_crop_bottom ;что-бы не получить пустой буфер
  288.                         sub buf2d_h,edx ;уменьшаем высоту буфера
  289.                         mov ecx,buf2d_h
  290.                         imul ecx,ebx ;ecx = новый размер изображения
  291.                         invoke mem.realloc,buf2d_data,ecx
  292.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  293.         .24no_crop_bottom:
  294.  
  295.         bt dword[opt],BUF2D_BIT_OPT_CROP_TOP
  296.         jae .24no_crop_top
  297.                 mov eax,dword[color]
  298.                 mov edx,eax ;ax = colors - r,g
  299.                 shr edx,16 ;dl = color - b
  300.                 mov esi,buf2d_data
  301.                 mov ecx,buf2d_h
  302.                 cmp ecx,1
  303.                 jle .24no_crop_top ;проверяем на случай если высота буфера 1 пиксель
  304.                 dec ecx ;при обрезании должна остаться минимум 1-на строка пикселей
  305.                 mov ebx,buf2d_w
  306.                 imul ecx,ebx
  307.                 cld
  308.                 @@:
  309.                         cmp word[esi],ax
  310.                         jne @f
  311.                         cmp byte[esi+2],dl
  312.                         jne @f
  313.                         add esi,3
  314.                         loop @b
  315.                 @@:
  316.                 lea ebx,[ebx+ebx*2]
  317.                 xor edx,edx
  318.                 @@:
  319.                         sub esi,ebx
  320.                         cmp esi,buf2d_data
  321.                         jl @f
  322.                         inc edx ;вычисляем число полных строк для обрезания
  323.                         loop @b
  324.                 @@:
  325.                 cmp edx,0
  326.                 je .24no_crop_top
  327.                         xor eax,eax
  328.                         sub eax,edx
  329.                         mov ebx,buf2d_h
  330.                         sub ebx,edx
  331.                         stdcall buf_offset_h, edi, eax, edx, ebx ;сдвигаем изображение в буфере вверх (eax<0)
  332.                         sub buf2d_h,edx ;уменьшаем высоту буфера
  333.                         mov ecx,buf2d_h
  334.                         add buf2d_t,dx ;сдвигаем отступ вниз, на число обрезанных строк
  335.                         mov ebx,buf2d_w
  336.                         imul ecx,ebx
  337.                         lea ecx,[ecx+ecx*2]
  338.                         invoke mem.realloc,buf2d_data,ecx
  339.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  340.         .24no_crop_top:
  341.  
  342.         bt dword[opt],BUF2D_BIT_OPT_CROP_RIGHT
  343.         jae .24no_crop_right
  344.                 mov eax,dword[color]
  345.                 mov edx,eax ;ax = colors - r,g
  346.                 shr edx,16 ;dl = color - b
  347.                 mov ebx,buf2d_w
  348.                 cmp ebx,1
  349.                 jle .24no_crop_right ;на случай если ширина буфера 1 пиксель
  350.                 lea ebx,[ebx+ebx*2]
  351.                 mov esi,ebx
  352.                 imul esi,buf2d_h
  353.                 add esi,buf2d_data ;esi - указатель на конец буфера изображения
  354.                 mov dword[crop_r],0
  355.                 cld
  356.                 .24found_beg_right:
  357.                 sub esi,3 ;двигаемся на 1-ну колонку влево
  358.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  359.                 @@:
  360.                         cmp word[esi],ax
  361.                         jne .24found_right
  362.                         cmp byte[esi+2],dl
  363.                         jne .24found_right
  364.                         sub esi,ebx ;прыгаем на верхнюю строку
  365.                         loop @b
  366.                 inc dword[crop_r]
  367.  
  368.                 mov ecx,buf2d_w
  369.                 dec ecx ;1 колонка на запас
  370.                 cmp dword[crop_r],ecx
  371.                 jge .24found_right
  372.  
  373.                 sub esi,3 ;двигаемся на 1-ну колонку влево
  374.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  375.                 @@:
  376.                         add esi,ebx ;прыгаем на нижнюю строку
  377.                         cmp word[esi],ax
  378.                         jne .24found_right
  379.                         cmp byte[esi+2],dl
  380.                         jne .24found_right
  381.                         loop @b
  382.                 inc dword[crop_r]
  383.  
  384.                 mov ecx,buf2d_w
  385.                 dec ecx ;1 колонка на запас
  386.                 cmp dword[crop_r],ecx
  387.                 jl .24found_beg_right
  388.  
  389.                 .24found_right:
  390.                 cmp dword[crop_r],0
  391.                 je .24no_crop_right
  392.                         mov ecx,buf2d_w
  393.                         sub ecx,dword[crop_r]
  394.                         stdcall img_rgb_crop_r, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  395.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  396.                         mov ebx,buf2d_h
  397.                         imul ecx,ebx
  398.                         lea ecx,[ecx+ecx*2]
  399.                         invoke mem.realloc,buf2d_data,ecx
  400.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  401.         .24no_crop_right:
  402.  
  403.         bt dword[opt],BUF2D_BIT_OPT_CROP_LEFT
  404.         jae .24no_crop_left
  405.                 mov eax,dword[color]
  406.                 mov edx,eax ;ax = colors - r,g
  407.                 shr edx,16 ;dl = color - b
  408.                 mov ebx,buf2d_w
  409.                 cmp ebx,1
  410.                 jle .24no_crop_left ;на случай если ширина буфера 1 пиксель
  411.                 lea ebx,[ebx+ebx*2]
  412.                 mov esi,buf2d_data ;esi - указатель на начоло буфера изображения
  413.                 mov dword[crop_r],0
  414.                 cld
  415.                 .24found_beg_left:
  416.  
  417.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  418.                 @@:
  419.                         cmp word[esi],ax
  420.                         jne .24found_left
  421.                         cmp byte[esi+2],dl
  422.                         jne .24found_left
  423.                         add esi,ebx ;прыгаем на нижнюю строку
  424.                         loop @b
  425.                 inc dword[crop_r]
  426.                 add esi,3 ;двигаемся на 1-ну колонку вправо
  427.  
  428.                 mov ecx,buf2d_w
  429.                 dec ecx ;1 колонка на запас
  430.                 cmp dword[crop_r],ecx
  431.                 jge .24found_left
  432.  
  433.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  434.                 @@:
  435.                         sub esi,ebx ;прыгаем на верхнюю строку
  436.                         cmp word[esi],ax
  437.                         jne .24found_left
  438.                         cmp byte[esi+2],dl
  439.                         jne .24found_left
  440.                         loop @b
  441.                 inc dword[crop_r]
  442.                 add esi,3 ;двигаемся на 1-ну колонку вправо
  443.  
  444.                 mov ecx,buf2d_w
  445.                 dec ecx ;1 колонка на запас
  446.                 cmp dword[crop_r],ecx
  447.                 jl .24found_beg_left
  448.  
  449.                 .24found_left:
  450.                 cmp dword[crop_r],0
  451.                 je .24no_crop_left
  452.                         mov ecx,buf2d_w
  453.                         sub ecx,dword[crop_r]
  454.                         stdcall img_rgb_crop_l, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  455.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  456.                         mov ebx,buf2d_h
  457.                         imul ecx,ebx
  458.                         lea ecx,[ecx+ecx*2]
  459.                         invoke mem.realloc,buf2d_data,ecx
  460.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  461.                         mov eax,dword[crop_r]
  462.                         add buf2d_l,ax
  463.         .24no_crop_left:
  464.  
  465.         .24end_f:
  466.  
  467.  
  468.         cmp buf2d_bits,8
  469.         jne .8end_f
  470.  
  471.         bt dword[opt],BUF2D_BIT_OPT_CROP_BOTTOM
  472.         jae .8no_crop_bottom
  473.                 mov eax,dword[color]
  474.                 mov esi,buf2d_data
  475.                 mov ecx,buf2d_h
  476.                 cmp ecx,1
  477.                 jle .8no_crop_bottom ;проверяем на случай если высота буфера 1 пиксель
  478.                 mov ebx,buf2d_w
  479.                 imul ecx,ebx
  480.                 mov esi,ecx
  481.                 add esi,buf2d_data
  482.                 cld
  483.                 @@:
  484.                         dec esi
  485.                         cmp byte[esi],al
  486.                         jne @f
  487.                         loop @b
  488.                 @@:
  489.                 xor edx,edx
  490.                 mov eax,buf2d_h
  491.                 imul eax,ebx
  492.                 add eax,buf2d_data ;eax - указатель на конец буфера изображения
  493.                 @@:
  494.                         add esi,ebx
  495.                         cmp esi,eax
  496.                         jge @f
  497.                         inc edx
  498.                         loop @b
  499.                 @@:
  500.                 cmp edx,0
  501.                 je .8no_crop_bottom
  502.                         cmp edx,buf2d_h
  503.                         jge .8no_crop_bottom ;что-бы не получить пустой буфер
  504.                         sub buf2d_h,edx ;уменьшаем высоту буфера
  505.                         mov ecx,buf2d_h
  506.                         imul ecx,ebx ;ecx = новый размер изображения
  507.                         invoke mem.realloc,buf2d_data,ecx
  508.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  509.         .8no_crop_bottom:
  510.  
  511.         bt dword[opt],BUF2D_BIT_OPT_CROP_TOP
  512.         jae .8no_crop_top
  513.                 mov eax,dword[color]
  514.                 mov esi,buf2d_data
  515.                 mov ecx,buf2d_h
  516.                 cmp ecx,1
  517.                 jle .8no_crop_top ;проверяем на случай если высота буфера 1 пиксель
  518.                 dec ecx ;при обрезании должна остаться минимум 1-на строка пикселей
  519.                 mov ebx,buf2d_w
  520.                 imul ecx,ebx
  521.                 cld
  522.                 @@:
  523.                         cmp byte[esi],al
  524.                         jne @f
  525.                         inc esi
  526.                         loop @b
  527.                 @@:
  528.                 xor edx,edx
  529.                 @@:
  530.                         sub esi,ebx
  531.                         cmp esi,buf2d_data
  532.                         jl @f
  533.                         inc edx
  534.                         loop @b
  535.                 @@:
  536.                 cmp edx,0
  537.                 je .8no_crop_top
  538.                         xor eax,eax
  539.                         sub eax,edx
  540.                         mov ebx,buf2d_h
  541.                         sub ebx,edx
  542.                         stdcall buf_offset_h, edi, eax, edx, ebx
  543.                         mov ecx,buf2d_h
  544.                         sub ecx,edx
  545.                         mov buf2d_h,ecx ;уменьшаем высоту буфера
  546.                         add buf2d_t,dx ;сдвигаем отступ вниз, на число обрезанных строк
  547.                         mov ebx,buf2d_w
  548.                         imul ecx,ebx
  549.                         invoke mem.realloc,buf2d_data,ecx
  550.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  551.         .8no_crop_top:
  552.  
  553.         bt dword[opt],BUF2D_BIT_OPT_CROP_RIGHT
  554.         jae .8no_crop_right
  555.                 mov eax,dword[color]
  556.                 mov ebx,buf2d_w
  557.                 cmp ebx,1
  558.                 jle .8no_crop_right ;на случай если ширина буфера 1 пиксель
  559.                 mov esi,ebx
  560.                 imul esi,buf2d_h
  561.                 add esi,buf2d_data ;esi - указатель на конец буфера изображения
  562.                 xor edx,edx
  563.                 cld
  564.  
  565.                 .8found_beg:
  566.                 dec esi ;двигаемся на 1-ну колонку влево
  567.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  568.                 @@:
  569.                         cmp byte[esi],al
  570.                         jne .8found
  571.                         sub esi,ebx ;прыгаем на верхнюю строку
  572.                         loop @b
  573.                 inc edx
  574.                 mov ecx,buf2d_w
  575.                 dec ecx ;1 колонка на запас
  576.                 cmp edx,ecx
  577.                 jge .8found
  578.  
  579.                 dec esi ;двигаемся на 1-ну колонку влево
  580.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  581.                 @@:
  582.                         add esi,ebx ;прыгаем на нижнюю строку
  583.                         cmp byte[esi],al
  584.                         jne .8found
  585.                         loop @b
  586.                 inc edx
  587.  
  588.                 mov ecx,buf2d_w
  589.                 dec ecx ;1 колонка на запас
  590.                 cmp edx,ecx
  591.                 jl .8found_beg
  592.  
  593.                 .8found:
  594.                 cmp edx,0
  595.                 je .8no_crop_right
  596.                         mov ecx,buf2d_w
  597.                         sub ecx,edx
  598.                         stdcall img_gray_crop_r, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  599.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  600.                         mov ebx,buf2d_h
  601.                         imul ecx,ebx
  602.                         invoke mem.realloc,buf2d_data,ecx
  603.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  604.         .8no_crop_right:
  605.  
  606.         bt dword[opt],BUF2D_BIT_OPT_CROP_LEFT
  607.         jae .8no_crop_left
  608.                 mov eax,dword[color]
  609.                 mov ebx,buf2d_w
  610.                 cmp ebx,1
  611.                 jle .8no_crop_left ;на случай если ширина буфера 1 пиксель
  612.                 mov esi,buf2d_data ;esi - указатель на начоло буфера изображения
  613.                 mov edx,0
  614.                 cld
  615.                 .8found_beg_left:
  616.  
  617.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  618.                 @@:
  619.                         cmp word[esi],ax
  620.                         jne .8found_left
  621.                         add esi,ebx ;прыгаем на нижнюю строку
  622.                         loop @b
  623.                 inc edx
  624.                 inc esi ;двигаемся на 1-ну колонку вправо
  625.  
  626.                 mov ecx,buf2d_w
  627.                 dec ecx ;1 колонка на запас
  628.                 cmp edx,ecx
  629.                 jge .8found_left
  630.  
  631.                 mov ecx,buf2d_h ;восстановление ecx для нового цикла
  632.                 @@:
  633.                         sub esi,ebx ;прыгаем на верхнюю строку
  634.                         cmp word[esi],ax
  635.                         jne .8found_left
  636.                         loop @b
  637.                 inc edx
  638.                 inc esi ;двигаемся на 1-ну колонку вправо
  639.  
  640.                 mov ecx,buf2d_w
  641.                 dec ecx ;1 колонка на запас
  642.                 cmp edx,ecx
  643.                 jl .8found_beg_left
  644.  
  645.                 .8found_left:
  646.                 cmp edx,0
  647.                 je .8no_crop_left
  648.                         mov ecx,buf2d_w
  649.                         sub ecx,edx
  650.                         stdcall img_gray_crop_l, buf2d_data, buf2d_w, ecx, buf2d_h ;обрезаем буфер, по новому размеру
  651.                         mov buf2d_w,ecx ;ставим новую ширину для буфера
  652.                         mov ebx,buf2d_h
  653.                         imul ecx,ebx
  654.                         invoke mem.realloc,buf2d_data,ecx
  655.                         mov buf2d_data,eax ;на случай если изменился указатель на данные
  656.                         mov eax,edx
  657.                         add buf2d_l,ax
  658.         .8no_crop_left:
  659.  
  660.         .8end_f:
  661.  
  662.         popad
  663.         ret
  664. endp
  665.  
  666. ;обрезаем цветное изображение с правой стороны
  667. ;input:
  668. ;data_rgb - pointer to rgb data
  669. ;size_w_old - width img in pixels
  670. ;size_w_new - new width img in pixels
  671. ;size_h - height img in pixels
  672. align 4
  673. proc img_rgb_crop_r, data_rgb:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  674.         pushad
  675.         mov eax, dword[size_w_old]
  676.         lea eax, dword[eax+eax*2] ;eax = width(old) * 3(rgb)
  677.         mov ebx, dword[size_w_new]
  678.         lea ebx, dword[ebx+ebx*2] ;ebx = width(new) * 3(rgb)
  679.         mov edx, dword[size_h]
  680.         mov edi, dword[data_rgb] ;edi - получает данные
  681.         mov esi, edi
  682.         add edi, ebx
  683.         add esi, eax
  684.         cld
  685.         @@:
  686.                 dec edx ;уменьшаем счетчик оставшихся строк на 1
  687.                 cmp edx,0
  688.                 jle @f
  689.                 mov ecx, ebx
  690.                 rep movsb ;перенос (копирование) строки пикселей
  691.                 add esi,eax ;переход на новую строчку изображения
  692.                 sub esi,ebx
  693.                 jmp @b
  694.         @@:
  695.         popad
  696.         ret
  697. endp
  698.  
  699. ;обрезаем серое изображение с правой стороны
  700. ;input:
  701. ;data_gray - pointer to gray data
  702. ;size_w_old - width img in pixels
  703. ;size_w_new - new width img in pixels
  704. ;size_h - height img in pixels
  705. align 4
  706. proc img_gray_crop_r, data_gray:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  707.         pushad
  708.         mov eax, dword[size_w_old]
  709.         mov ebx, dword[size_w_new]
  710.         mov edx, dword[size_h]
  711.         mov edi, dword[data_gray] ;edi - получает данные
  712.         mov esi, edi
  713.         add edi, ebx
  714.         add esi, eax
  715.         cld
  716.         @@:
  717.                 dec edx ;уменьшаем счетчик оставшихся строк на 1
  718.                 cmp edx,0
  719.                 jle @f
  720.                 mov ecx, ebx
  721.                 rep movsb ;перенос (копирование) строки пикселей
  722.                 add esi,eax ;переход на новую строчку изображения
  723.                 sub esi,ebx
  724.                 jmp @b
  725.         @@:
  726.         popad
  727.         ret
  728. endp
  729.  
  730. ;обрезаем цветное изображение с левой стороны
  731. ;input:
  732. ;data_rgb - pointer to rgb data
  733. ;size_w_old - width img in pixels
  734. ;size_w_new - new width img in pixels
  735. ;size_h - height img in pixels
  736. align 4
  737. proc img_rgb_crop_l, data_rgb:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  738.         pushad
  739.         mov edi,dword[data_rgb]
  740.         mov esi,edi
  741.         mov eax,dword[size_w_old]
  742.         mov ebx,dword[size_w_new]
  743.         cmp eax,ebx
  744.         jle .end_f ;старый размер изображения не может быть меньше нового (при условии обрезания картинки)
  745.                 lea eax,[eax+eax*2]
  746.                 lea ebx,[ebx+ebx*2]
  747.                 sub eax,ebx
  748.                 mov edx,dword[size_h] ;высота изображения
  749.                 cld
  750.                 @@:
  751.                         add esi,eax
  752.                         mov ecx,ebx
  753.                         rep movsb
  754.                         dec edx
  755.                         cmp edx,0
  756.                         jg @b
  757.         .end_f:
  758.         popad
  759.         ret
  760. endp
  761.  
  762. ;обрезаем серое изображение с левой стороны
  763. ;input:
  764. ;data_gray - pointer to gray data
  765. ;size_w_old - width img in pixels
  766. ;size_w_new - new width img in pixels
  767. ;size_h - height img in pixels
  768. align 4
  769. proc img_gray_crop_l, data_gray:dword, size_w_old:dword, size_w_new:dword, size_h:dword
  770.         pushad
  771.         mov edi,dword[data_gray]
  772.         mov esi,edi
  773.         mov eax,dword[size_w_old]
  774.         mov ebx,dword[size_w_new]
  775.         cmp eax,ebx
  776.         jle .end_f ;старый размер изображения не может быть меньше нового (при условии обрезания картинки)
  777.                 sub eax,ebx
  778.                 mov edx,dword[size_h] ;высота изображения
  779.                 cld
  780.                 @@:
  781.                         add esi,eax
  782.                         mov ecx,ebx
  783.                         rep movsb
  784.                         dec edx
  785.                         cmp edx,0
  786.                         jg @b
  787.         .end_f:
  788.         popad
  789.         ret
  790. endp
  791.  
  792. ;hoffs - колличество пикселей на котрые поднимается/опускается изображение
  793. ;img_t - высота, с которой начинается двигающаяся часть изображения
  794. align 4
  795. proc buf_offset_h, buf_struc:dword, hoffs:dword, img_t:dword, img_h:dword ;сдвигает изображение по высоте
  796.         pushad
  797.         mov edi,dword[buf_struc]
  798.         cmp buf2d_bits,24
  799.         jne .end_move_24
  800.  
  801.         mov eax,[hoffs]
  802.         cmp eax,0
  803.         je .end_move_24
  804.                 mov ebx,buf2d_w
  805.                 mov edx,dword[img_t]
  806.                         mov ecx,dword[img_h] ;ecx - высота сдвигаемых данных
  807.                         cmp ecx,buf2d_h
  808.                         jge .end_f ;ошибочное условие, высота изображения меньше чем высота сдвигаемого изображения
  809.                         imul ecx,ebx ;ecx - колличество пикселей в сдвигаемых данных
  810.                         lea ecx,[ecx+ecx*2]
  811.                 imul ebx,edx
  812.                 lea ebx,[ebx+ebx*2]
  813.                 mov esi,buf2d_data
  814.                 add esi,ebx
  815.  
  816.                 add edx,eax ;edx = img_t+hoffs (hoffs<0)
  817.                 mov ebx,buf2d_w
  818.                 imul ebx,edx
  819.                 lea ebx,[ebx+ebx*2]
  820.                 mov edi,buf2d_data ;позиция, куда будет двигаться изображение
  821.                 add edi,ebx
  822.  
  823.                 cmp eax,0
  824.                 jg .move_down_24
  825.                         ;двигаем изображение вверх
  826.                         cld
  827.                         rep movsb
  828.                         jmp .end_f
  829.                 .move_down_24:
  830.                         ;двигаем изображение вниз
  831.                         add esi,ecx
  832.                         dec esi
  833.                         add edi,ecx
  834.                         dec edi
  835.                         std
  836.                         rep movsb
  837.                         jmp .end_f
  838.         .end_move_24:
  839.  
  840. ;stdcall print_err,sz_buf2d_offset_h,txt_err_n24b
  841.  
  842.         cmp buf2d_bits,8
  843.         jne .end_move_8
  844.  
  845.         mov eax,[hoffs]
  846.         cmp eax,0
  847.         je .end_move_8
  848.                 ;двигаем изображение вверх
  849.                 mov ebx,buf2d_w
  850.                 mov edx,dword[img_t]
  851.                         mov ecx,dword[img_h] ;ecx - высота сдвигаемых данных
  852.                         cmp ecx,buf2d_h
  853.                         jge .end_f ;ошибочное условие, высота изображения меньше чем высота сдвигаемого изображения
  854.                         imul ecx,ebx ;ecx - колличество пикселей в сдвигаемых данных
  855.                 imul ebx,edx
  856.                 mov esi,buf2d_data
  857.                 add esi,ebx
  858.  
  859.                 add edx,eax ;edx = img_t+hoffs (hoffs<0)
  860.                 mov ebx,buf2d_w
  861.                 imul ebx,edx
  862.                 mov edi,buf2d_data ;позиция, куда будет двигаться изображение
  863.                 add edi,ebx
  864.  
  865.                 cmp eax,0
  866.                 jg .move_down_8
  867.                         cld
  868.                         rep movsb
  869.                         jmp .end_f
  870.                 .move_down_8:
  871.                         ;двигаем изображение вниз
  872.                         add esi,ecx
  873.                         dec esi
  874.                         add edi,ecx
  875.                         dec edi
  876.                         std
  877.                         rep movsb
  878.                         jmp .end_f
  879.         .end_move_8:
  880.  
  881.         .end_f:
  882.         popad
  883.         ret
  884. endp
  885.  
  886.  
  887. align 4
  888. proc buf_draw_buf, buf_struc:dword
  889.         pushad
  890.         mov edi,dword[buf_struc]
  891.         cmp buf2d_bits,24
  892.         jne .error
  893.                 mov eax,7
  894.                 mov ebx,buf2d_data
  895.  
  896.                 mov ecx,buf2d_w
  897.                 ror ecx,16
  898.                 mov edx,buf2d_h
  899.                 mov cx,dx
  900.  
  901.                 mov edx,buf2d_size_lt
  902.                 ror edx,16
  903.                 int 0x40
  904.                 jmp .end_draw_24
  905.         .error:
  906.                 stdcall print_err,sz_buf2d_draw,txt_err_n24b
  907.         .end_draw_24:
  908.         popad
  909.         ret
  910. endp
  911.  
  912. align 4
  913. proc buf_delete, buf_struc:dword
  914.         push edi
  915.         mov edi,dword[buf_struc]
  916.         invoke mem.free,buf2d_data
  917.         pop edi
  918.         ret
  919. endp
  920.  
  921. align 4
  922. proc buf_line_brs, buf_struc:dword, coord_x0:dword, coord_y0:dword, coord_x1:dword, coord_y1:dword, color:dword
  923. locals
  924.         loc_1 dd ?
  925.         loc_2 dd ?
  926.         napravl db ?
  927. endl
  928.         pushad
  929.                 mov edx,dword[color]
  930.  
  931.                 mov eax,dword[coord_x1]
  932.                 sub eax,dword[coord_x0]
  933.                 bt eax,31
  934.                 jae @f
  935.                         neg eax
  936.                         inc eax
  937.                 @@:
  938.                 mov ebx,dword[coord_y1]
  939.                 sub ebx,dword[coord_y0]
  940.                 bt ebx,31
  941.                 jae @f
  942.                         neg ebx
  943.                         inc ebx
  944.                 @@:
  945.  
  946.                 mov [napravl],byte 0 ;bool steep=false
  947.                 cmp eax,ebx
  948.                 jle @f
  949.                         mov [napravl],byte 1 ;bool steep=true
  950.                         swap dword[coord_x0],dword[coord_y0] ;swap(x0, y0);
  951.                         swap dword[coord_x1],dword[coord_y1] ;swap(x1, y1);
  952.                 @@:
  953.                 mov eax,dword[coord_y0] ;x0
  954.                 cmp eax,dword[coord_y1] ;if(x0>x1)
  955.                 jle @f
  956.                         swap dword[coord_y0],dword[coord_y1] ;swap(x0, x1);
  957.                         swap dword[coord_x0],dword[coord_x1] ;swap(y0, y1);
  958.                 @@:
  959.  
  960. ; int deltax esi
  961. ; int deltay edi
  962. ; int error  ebp-6
  963. ; int ystep  ebp-8
  964.  
  965.                 mov eax,dword[coord_y0]
  966.                 mov esi,dword[coord_y1]
  967.                 sub esi,eax ;deltax = y1-y0
  968.                 mov ebx,esi
  969.                 shr ebx,1
  970.                 mov [loc_1],ebx ;error = deltax/2
  971.  
  972.                 mov eax,dword[coord_x0]
  973.                 mov edi,dword[coord_x1]
  974.                 mov [loc_2],dword -1 ;ystep = -1
  975.                 cmp eax,edi ;if (x0<x1) ystep = 1;
  976.                 jge @f
  977.                         mov [loc_2],dword 1 ;ystep = 1
  978.                 @@:
  979.                 sub edi,eax ;x1-x0
  980.  
  981.                 bts edi,31
  982.                 jae @f
  983.                         neg edi
  984.                         inc edi
  985.                 @@:
  986.                 and edi,0x7fffffff ;deltay = abs(x1-x0)
  987.  
  988.                 mov eax,edi
  989.                 mov edi,[buf_struc]
  990.                 cmp buf2d_bits,24
  991.                 jne .coord_end
  992.  
  993.                 cmp [napravl],0
  994.                 jne .coord_yx
  995.                         mov ebx,dword[coord_x0]
  996.                         mov ecx,dword[coord_y0]
  997.  
  998.                         @@: ;for (x=x0 ; x<x1; x++) ;------------------------------------
  999.                                 cmp ecx,dword[coord_y1]
  1000.                                 jg @f ;jge ???
  1001.                                 call draw_pixel
  1002.  
  1003.                                 sub dword[loc_1],eax ;error -= deltay
  1004.                                 cmp dword[loc_1],0 ;if(error<0)
  1005.                                 jge .if0
  1006.                                         add ebx,[loc_2] ;y += ystep
  1007.                                         add [loc_1],esi ;error += deltax
  1008.                                 .if0:
  1009.                                 inc ecx
  1010.                                 jmp @b
  1011.                         @@:
  1012.                         jmp .coord_end
  1013.                 .coord_yx:
  1014.                         mov ebx,dword[coord_y0]
  1015.                         mov ecx,dword[coord_x0]
  1016.  
  1017.                         @@: ;for (x=x0 ; x<x1; x++) ;------------------------------------
  1018.                                 cmp ebx,dword[coord_y1]
  1019.                                 jg @f ;jge ???
  1020.                                 call draw_pixel
  1021.  
  1022.                                 sub dword[loc_1],eax ;error -= deltay
  1023.                                 cmp dword[loc_1],0 ;if(error<0)
  1024.                                 jge .if1
  1025.                                         add ecx,[loc_2] ;y += ystep
  1026.                                         add [loc_1],esi ;error += deltax
  1027.                                 .if1:
  1028.                                 inc ebx
  1029.                                 jmp @b
  1030.                         @@:
  1031.         .coord_end:
  1032.         popad
  1033.         ret
  1034. endp
  1035.  
  1036. ;рисование горизонтальной линии, потому нет параметра coord_y1
  1037. align 4
  1038. proc buf_line_h, buf_struc:dword, coord_x0:dword, coord_y0:dword, coord_x1:dword, color:dword
  1039.         pushad
  1040.                 mov edi,[buf_struc]
  1041.                 cmp buf2d_bits,24
  1042.                 jne .end24
  1043.  
  1044.                 mov ebx,dword[coord_x0]
  1045.                 mov ecx,dword[coord_y0]
  1046.                 mov edx,dword[color]
  1047.                 mov esi,dword[coord_x1]
  1048.                 cmp ebx,esi
  1049.                 jle @f
  1050.                         xchg ebx,esi ;если x0 > x1 то меняем местами x0 и x1
  1051.  
  1052.                 @@: ;цикл по оси x от x0 до x1
  1053.                         cmp ebx,esi
  1054.                         jge @f
  1055.                         call draw_pixel
  1056.                         inc ebx
  1057.                         jmp @b
  1058.                 @@:
  1059.                 .end24:
  1060.         popad
  1061.         ret
  1062. endp
  1063.  
  1064. align 4
  1065. proc buf_rect_by_size, buf_struc:dword, coord_x:dword,coord_y:dword,w:dword,h:dword, color:dword
  1066. pushad
  1067.         mov edi,[buf_struc]
  1068.         cmp buf2d_bits,24
  1069.         jne .coord_end
  1070.  
  1071.                 mov eax,[coord_x]
  1072.                 mov ebx,[coord_y]
  1073.                 mov ecx,[w]
  1074.                 cmp ecx,1
  1075.                 jl .coord_end
  1076.                 add ecx,eax
  1077.                 dec ecx
  1078.                 mov edx,[h]
  1079.                 cmp edx,1
  1080.                 jl .coord_end
  1081.  
  1082.                 add edx,ebx
  1083.                 dec edx
  1084.                 mov esi,dword[color]
  1085.                 stdcall buf_line_h, edi, eax, ebx, ecx, esi ;линия -
  1086.                 stdcall buf_line_brs, edi, eax, ebx, eax, edx, esi ;линия |
  1087.                 stdcall buf_line_h, edi, eax, edx, ecx, esi ;линия -
  1088.                 stdcall buf_line_brs, edi, ecx, ebx, ecx, edx, esi ;линия |
  1089.         .coord_end:
  1090. popad
  1091.         ret
  1092. endp
  1093.  
  1094. align 4
  1095. proc buf_filled_rect_by_size, buf_struc:dword, coord_x:dword,coord_y:dword,w:dword,h:dword, color:dword
  1096. pushad
  1097.         mov edi,[buf_struc]
  1098.         cmp buf2d_bits,24
  1099.         jne .coord_end
  1100.                 mov eax,[coord_x]
  1101.                 mov ebx,[coord_y]
  1102.                 mov edx,[w]
  1103.                 add edx,eax
  1104.                 mov ecx,[h]
  1105.                 cmp ecx,1 ;сравнение с минимально возможной высотой
  1106.                 jl .coord_end ;если высота меньше 1-го пикселя
  1107.                 mov esi,dword[color]
  1108.                 cld
  1109.                 @@:
  1110.                         stdcall buf_line_h, edi, eax, ebx, edx, esi ;линия -
  1111.                         inc ebx
  1112.                         loop @b
  1113.         .coord_end:
  1114. popad
  1115.         ret
  1116. endp
  1117.  
  1118. align 4
  1119. proc buf_circle, buf_struc:dword, coord_x:dword, coord_y:dword, r:dword, color:dword
  1120. locals
  1121.         po_x dd ?
  1122.         po_y dd ?
  1123. endl
  1124.         pushad
  1125.         mov edi,dword[buf_struc]
  1126.         cmp buf2d_bits,24
  1127.         jne .error
  1128.                 mov edx,dword[color]
  1129.  
  1130.                 finit
  1131.                 fild dword[coord_x]
  1132.                 fild dword[coord_y]
  1133.                 fild dword[r]
  1134.                 fldz ;px=0
  1135.                 fld st1 ;py=r
  1136.  
  1137.                 fldpi
  1138.                 fmul st0,st3
  1139.                 fistp dword[po_x]
  1140.                 mov esi,dword[po_x] ;esi=pi*r
  1141.                 shl esi,1 ;esi=2*pi*r
  1142.  
  1143.                 ;st0 = py
  1144.                 ;st1 = px
  1145.                 ;st2 = r
  1146.                 ;st3 = y
  1147.                 ;st4 = x
  1148.  
  1149.                 @@:
  1150.                         ;Point(px + x, y - py)
  1151.                         fld st1 ;st0=px
  1152.                         fadd st0,st5 ;st0=px+x
  1153.                         fistp dword[po_x]
  1154.                         mov ebx,dword[po_x]
  1155.                         fld st3 ;st0=y
  1156.                         fsub st0,st1 ;st0=y-py
  1157.                         fistp dword[po_y]
  1158.                         mov ecx,dword[po_y]
  1159.                         call draw_pixel
  1160.                         ;px += py/r
  1161.                         fld st0 ;st0=py
  1162.                         fdiv st0,st3 ;st0=py/r
  1163.                         faddp st2,st0 ;st3+=st0
  1164.                         ;py -= px/r
  1165.                         fld st1 ;st0=px
  1166.                         fdiv st0,st3 ;st0=px/r
  1167.                         fsubp st1,st0 ;st2-=st0
  1168.  
  1169.                         dec esi
  1170.                         cmp esi,0
  1171.                         jge @b
  1172.                 jmp .exit_fun
  1173.         .error:
  1174.                 stdcall print_err,sz_buf2d_circle,txt_err_n24b
  1175.         .exit_fun:
  1176.  
  1177.         popad
  1178.         ret
  1179. endp
  1180.  
  1181. ;функция для заливки области выбранным цветом
  1182. align 4
  1183. proc buf_flood_fill, buf_struc:dword, coord_x:dword, coord_y:dword, mode:dword, color_f:dword, color_b:dword
  1184.         pushad
  1185.                 mov edi,[buf_struc]
  1186.                 cmp buf2d_bits,24
  1187.                 jne .end24
  1188.  
  1189.                         mov ebx,dword[coord_x]
  1190.                         mov ecx,dword[coord_y]
  1191.                         mov edx,dword[color_f]
  1192.                         mov esi,dword[color_b]
  1193.  
  1194.                         cmp dword[mode],1 ;в зависимости от 'mode' определяем каким алгоритмом будем пользоваться
  1195.                         je @f
  1196.                                 call buf_flood_fill_recurs_0 ;заливаем до пикселей цвета esi
  1197.                                 jmp .end24
  1198.                         @@:
  1199.                                 call buf_flood_fill_recurs_1 ;заливаем пиксели имеющие цвет esi
  1200.  
  1201.                 .end24:
  1202.         popad
  1203.         ret
  1204. endp
  1205.  
  1206. ;input:
  1207. ; ebx = coord_x
  1208. ; ecx = coord_y
  1209. ; edx = цвет заливки
  1210. ; esi = цвет границы, до которой будет ити заливка
  1211. ; edi = buf_struc
  1212. ;output:
  1213. ; eax = портится
  1214. align 4
  1215. buf_flood_fill_recurs_0:
  1216.         call get_pixel_24
  1217.         cmp eax,0xffffffff ;if error coords
  1218.         je .end_fun
  1219.         cmp eax,edx ;если цвет пикселя совпал с цветом заливки, значит заливка в этой области уже была сделана
  1220.         je .end_fun
  1221.  
  1222.                 call draw_pixel
  1223.  
  1224.                 dec ebx
  1225.                 call get_pixel_24
  1226.                 cmp eax,esi
  1227.                 je @f
  1228.                         call buf_flood_fill_recurs_0
  1229.                 @@:
  1230.                 inc ebx
  1231.  
  1232.  
  1233.                 inc ebx
  1234.                 call get_pixel_24
  1235.                 cmp eax,esi
  1236.                 je @f
  1237.                         call buf_flood_fill_recurs_0
  1238.                 @@:
  1239.                 dec ebx
  1240.  
  1241.                 dec ecx
  1242.                 call get_pixel_24
  1243.                 cmp eax,esi
  1244.                 je @f
  1245.                         call buf_flood_fill_recurs_0
  1246.                 @@:
  1247.                 inc ecx
  1248.  
  1249.                 inc ecx
  1250.                 call get_pixel_24
  1251.                 cmp eax,esi
  1252.                 je @f
  1253.                         call buf_flood_fill_recurs_0
  1254.                 @@:
  1255.                 dec ecx
  1256.  
  1257.         .end_fun:
  1258.         ret
  1259.  
  1260. ;input:
  1261. ; ebx = coord_x
  1262. ; ecx = coord_y
  1263. ; edx = цвет заливки
  1264. ; esi = цвет пикселей, по которым будет ити заливка
  1265. ; edi = buf_struc
  1266. ;output:
  1267. ; eax = портится
  1268. align 4
  1269. buf_flood_fill_recurs_1:
  1270.         call get_pixel_24
  1271.         cmp eax,0xffffffff ;if error coords
  1272.         je .end_fun
  1273.         cmp eax,edx ;если цвет пикселя совпал с цветом заливки, значит заливка в этой области уже была сделана
  1274.         je .end_fun
  1275.         cmp eax,esi ;если цвет пикселя не совпал с заливаемым цветом заливки, то прекращаем заливку
  1276.         jne .end_fun
  1277.  
  1278.                 call draw_pixel
  1279.  
  1280.                 dec ebx
  1281.                 call get_pixel_24
  1282.                 cmp eax,esi
  1283.                 jne @f
  1284.                         call buf_flood_fill_recurs_1
  1285.                 @@:
  1286.                 inc ebx
  1287.  
  1288.  
  1289.                 inc ebx
  1290.                 call get_pixel_24
  1291.                 cmp eax,esi
  1292.                 jne @f
  1293.                         call buf_flood_fill_recurs_1
  1294.                 @@:
  1295.                 dec ebx
  1296.  
  1297.                 dec ecx
  1298.                 call get_pixel_24
  1299.                 cmp eax,esi
  1300.                 jne @f
  1301.                         call buf_flood_fill_recurs_1
  1302.                 @@:
  1303.                 inc ecx
  1304.  
  1305.                 inc ecx
  1306.                 call get_pixel_24
  1307.                 cmp eax,esi
  1308.                 jne @f
  1309.                         call buf_flood_fill_recurs_1
  1310.                 @@:
  1311.                 dec ecx
  1312.  
  1313.         .end_fun:
  1314.         ret
  1315.  
  1316. align 4
  1317. proc buf_img_wdiv2, buf_struc:dword
  1318.         pushad
  1319.         mov edi,dword[buf_struc]
  1320.         cmp buf2d_bits,24
  1321.         jne .end_draw_24
  1322.                 mov eax,buf2d_w
  1323.                 mov ecx,buf2d_h
  1324.                 imul ecx,eax
  1325.                 stdcall img_rgb24_wdiv2, buf2d_data,ecx
  1326.         .end_draw_24:
  1327.         popad
  1328.         ret
  1329. endp
  1330.  
  1331. ;input:
  1332. ;data_rgb - pointer to rgb data
  1333. ;size - count img pixels (size img data / 3(rgb) )
  1334. align 4
  1335. proc img_rgb24_wdiv2 data_rgb:dword, size:dword
  1336.   ;push eax ebx ecx edx
  1337.   mov eax,dword[data_rgb]
  1338.   mov ecx,dword[size] ;ecx = size
  1339.   lea ecx,[ecx+ecx*2]
  1340.   cld
  1341.   @@: ;затемнение цвета пикселей
  1342.                 shr byte[eax],1
  1343.                 inc eax
  1344.                 loop @b
  1345.  
  1346.   mov eax,dword[data_rgb]
  1347.   mov ecx,dword[size] ;ecx = size
  1348.   shr ecx,1
  1349.   @@: ;сложение цветов пикселей
  1350.                 mov bx,word[eax+3] ;копируем цвет соседнего пикселя
  1351.                 add word[eax],bx
  1352.                 mov bl,byte[eax+5] ;копируем цвет соседнего пикселя
  1353.                 add byte[eax+2],bl
  1354.                 add eax,6 ;=2*3
  1355.                 loop @b
  1356.  
  1357.   mov eax,dword[data_rgb]
  1358.   add eax,3
  1359.   mov ebx,eax
  1360.   add ebx,3
  1361.   mov ecx,dword[size] ;ecx = size
  1362.   shr ecx,1
  1363.   dec ecx ;лишний пиксель
  1364.   @@: ;поджатие пикселей
  1365.                 mov edx,dword[ebx]
  1366.                 mov word[eax],dx
  1367.                 shr edx,16
  1368.                 mov byte[eax+2],dl
  1369.  
  1370.                 add eax,3
  1371.                 add ebx,6
  1372.                 loop @b
  1373.   ;pop edx ecx ebx eax
  1374.   ret
  1375. endp
  1376.  
  1377. align 4
  1378. proc buf_img_hdiv2, buf_struc:dword
  1379.         pushad
  1380.         mov edi,dword[buf_struc]
  1381.         cmp buf2d_bits,24
  1382.         jne .end_draw_24
  1383.                 mov eax,buf2d_w
  1384.                 mov ecx,buf2d_h
  1385.                 imul ecx,eax
  1386.                 stdcall img_rgb24_hdiv2, buf2d_data,ecx,eax
  1387.         .end_draw_24:
  1388.         popad
  1389.         ret
  1390. endp
  1391.  
  1392. ;input:
  1393. ;data_rgb - pointer to rgb data
  1394. ;size - count img pixels (size img data / 3(rgb) )
  1395. ;size_w - width img in pixels
  1396. align 4
  1397. proc img_rgb24_hdiv2, data_rgb:dword, size:dword, size_w:dword
  1398.   ;pushad
  1399.  
  1400.   mov eax,dword[data_rgb] ;eax =
  1401.   mov ecx,dword[size]     ;ecx = size
  1402.   lea ecx,[ecx+ecx*2]
  1403.   cld
  1404.   @@: ;затемнение цвета пикселей
  1405.     shr byte[eax],1
  1406.     inc eax
  1407.     loop @b
  1408.  
  1409.   mov eax,dword[data_rgb] ;eax =
  1410.   mov edi,dword[size_w]
  1411.   lea esi,[edi+edi*2] ;esi = width*3(rgb)
  1412.   mov ebx,esi
  1413.   add ebx,eax
  1414.   mov ecx,dword[size]  ;ecx = size
  1415.   shr ecx,1
  1416.   xor edi,edi
  1417.   @@: ;сложение цветов пикселей
  1418.     mov dx,word[ebx] ;копируем цвет нижнего пикселя
  1419.     add word[eax],dx
  1420.     mov dl,byte[ebx+2] ;копируем цвет нижнего пикселя
  1421.     add byte[eax+2],dl
  1422.  
  1423.     add eax,3
  1424.     add ebx,3
  1425.     inc edi
  1426.     cmp edi,dword[size_w]
  1427.     jl .old_line
  1428.       add eax,esi
  1429.       add ebx,esi
  1430.       xor edi,edi
  1431.     .old_line:
  1432.     loop @b
  1433.  
  1434.  
  1435.   mov eax,dword[data_rgb] ;eax =
  1436.   add eax,esi ;esi = width*3(rgb)
  1437.   mov ebx,esi
  1438.   add ebx,eax
  1439.   mov ecx,dword[size] ;ecx = size
  1440.   shr ecx,1
  1441.   sub ecx,dword[size_w] ;лишняя строка пикселей
  1442.   xor edi,edi
  1443.   @@: ;поджатие пикселей
  1444.     mov edx,dword[ebx] ;копируем цвет нижнего пикселя
  1445.     mov word[eax],dx
  1446.     shr edx,16
  1447.     mov byte[eax+2],dl
  1448.  
  1449.     add eax,3
  1450.     add ebx,3
  1451.     inc edi
  1452.     cmp edi,dword[size_w]
  1453.     jl .old_line_2
  1454.       add ebx,esi
  1455.       xor edi,edi
  1456.     .old_line_2:
  1457.     loop @b
  1458.  
  1459.   ;popad
  1460.   ret
  1461. endp
  1462.  
  1463. ;преобразование буфера из 24-битного в 8-битный
  1464. ; spectr - определяет какой спектр брать при преобразовании 0-синий, 1-зеленый, 2-красный
  1465. align 4
  1466. proc buf_conv_24_to_8, buf_struc:dword, spectr:dword
  1467.         pushad
  1468.         mov edi,dword[buf_struc]
  1469.         cmp buf2d_bits,24
  1470.         jne .error
  1471.                 mov eax,buf2d_w
  1472.                 mov ecx,buf2d_h
  1473.                 imul ecx,eax
  1474.                 mov esi,ecx
  1475.                 ;ebx - память из которой копируется
  1476.                 ;edx - память куда копируется
  1477.                 mov edx,buf2d_data
  1478.                 mov ebx,edx
  1479.                 cmp [spectr],3
  1480.                 jge @f
  1481.                         add ebx,[spectr]
  1482.                 @@:
  1483.                         mov al,byte[ebx]
  1484.                         mov byte[edx],al
  1485.                         add ebx,3
  1486.                         inc edx
  1487.                         loop @b
  1488.                 mov buf2d_bits,8
  1489.                 invoke mem.realloc,buf2d_data,esi ;уменьшаем память занимаемую буфером
  1490.                 jmp .end_conv
  1491.         .error:
  1492.                 stdcall print_err,sz_buf2d_conv_24_to_8,txt_err_n24b
  1493.         .end_conv:
  1494.         popad
  1495.         ret
  1496. endp
  1497.  
  1498. ;преобразование буфера из 24-битного в 32-битный
  1499. align 4
  1500. proc buf_conv_24_to_32, buf_struc:dword, buf_str8:dword
  1501.         pushad
  1502.         mov edi,dword[buf_struc]
  1503.         cmp buf2d_bits,24
  1504.         jne .error1
  1505.                 mov ecx,buf2d_w
  1506.                 mov ebx,buf2d_h
  1507.                 imul ebx,ecx
  1508.                 mov ecx,ebx ;ecx = size  8 b
  1509.                 shl ebx,2   ;ebx = size 32 b
  1510.                 invoke mem.realloc,buf2d_data,ebx ;увеличиваем память занимаемую буфером
  1511.                 mov buf2d_data,eax ;на случай если изменился указатель на данные
  1512.                 mov buf2d_bits,32
  1513.                 mov edx,ebx ;edx = size 32 b
  1514.                 sub ebx,ecx ;ebx = size 24 b
  1515.                 mov eax,ecx
  1516.                 ;eax - размер  8 битных данных
  1517.                 ;ebx - размер 24 битных данных
  1518.                 ;edx - размер 32 битных данных
  1519.                 add ebx,buf2d_data
  1520.                 add edx,buf2d_data
  1521.                 mov edi,dword[buf_str8]
  1522.                 cmp buf2d_bits,8
  1523.                 jne .error2
  1524.                 add eax,buf2d_data
  1525.                 mov edi,edx
  1526.                 ;eax - указатель на конец  8 битных данных
  1527.                 ;ebx - указатель на конец 24 битных данных
  1528.                 ;edi - указатель на конец 32 битных данных
  1529.                 @@:
  1530.                         sub edi,4 ;отнимаем в начале цикла,
  1531.                         sub ebx,3 ; потому, что указатели стоят
  1532.                         dec eax   ; за пределами буферов
  1533.                         mov edx,dword[ebx]
  1534.                         mov dword[edi],edx
  1535.                         mov dl,byte[eax]
  1536.                         mov byte[edi+3],dl
  1537.                         loop @b
  1538.  
  1539.                 jmp .end_conv
  1540.         .error1:
  1541.                 stdcall print_err,sz_buf2d_conv_24_to_32,txt_err_n24b
  1542.                 jmp .end_conv
  1543.         .error2:
  1544.                 stdcall print_err,sz_buf2d_conv_24_to_32,txt_err_n8b
  1545.         .end_conv:
  1546.         popad
  1547.         ret
  1548. endp
  1549.  
  1550. ;функция копирует изображение из буфера buf_source (24b|32b) в buf_destination (24b)
  1551. ; указываются координаты вставки буфера buf_source относительно buf_destination
  1552. ; прозрачность при копировании не учитывается
  1553. align 4
  1554. proc buf_bit_blt, buf_destination:dword, coord_x:dword, coord_y:dword, buf_source:dword
  1555.         locals
  1556.                 right_bytes dd ?
  1557.         endl
  1558.         pushad
  1559.  
  1560.         mov edi,[buf_source]
  1561.         cmp buf2d_bits,24
  1562.         je .sou24
  1563.         cmp buf2d_bits,32
  1564.         je .sou32
  1565.                 jmp .copy_end ;формат буфера не поодерживается
  1566.  
  1567.         .sou24: ;в источнике 24 битная картинка
  1568.         mov eax,buf2d_w
  1569.         mov edx,buf2d_h ;высота копируемой картинки
  1570.         mov esi,buf2d_data ;данные копируемой картинки
  1571.  
  1572.         mov edi,[buf_destination]
  1573.         cmp buf2d_bits,24
  1574.         jne .copy_end ;формат буфера не поодерживается
  1575.         mov ebx,[coord_x] ;в ebx временно ставим отступ изображения (для проверки)
  1576.         cmp ebx,buf2d_w   ;проверяем влазит ли изображение по ширине
  1577.         jge .copy_end     ;если изображение полностью вылазит за правую сторону
  1578.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1579.                 mov ecx,[coord_y]
  1580.                 cmp ecx,ebx
  1581.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1582.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1583.                 cmp ecx,ebx
  1584.                 jle @f
  1585.                         sub ecx,ebx
  1586.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1587.                 @@:
  1588.                 mov ebx,buf2d_w
  1589.                 mov ecx,ebx ;ecx используем для временных целей
  1590.                 imul ecx,[coord_y]
  1591.                 add ecx,[coord_x]
  1592.                 lea ecx,[ecx+ecx*2]
  1593.                 add ecx,buf2d_data
  1594.                 sub ebx,eax
  1595.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1596.  
  1597.         mov [right_bytes],0
  1598.         mov ecx,[coord_x]
  1599.         cmp ecx,ebx
  1600.         jl @f
  1601.                 sub ecx,ebx
  1602.                 sub eax,ecx ;укорачиваем копируемую строку
  1603.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1604.                 lea ecx,[ecx+ecx*2] ;ecx - число байт в 1-й строке картинки, которые вылазят за правую сторону
  1605.                 mov [right_bytes],ecx
  1606.         @@:
  1607.  
  1608.         lea eax,[eax+eax*2] ;колличество байт в 1-й строке копируемой картинки
  1609.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1610.  
  1611.         cld
  1612.         cmp [right_bytes],0
  1613.         jg .copy_1
  1614.         .copy_0: ;простое копирование
  1615.                 mov ecx,eax
  1616.                 rep movsb
  1617.                 add edi,ebx
  1618.                 dec edx
  1619.                 cmp edx,0
  1620.                 jg .copy_0
  1621.         jmp .copy_end
  1622.         .copy_1: ;не простое копирование (картинка вылазит за правую сторону)
  1623.                 mov ecx,eax
  1624.                 rep movsb
  1625.                 add edi,ebx
  1626.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  1627.                 dec edx
  1628.                 cmp edx,0
  1629.                 jg .copy_1
  1630.         jmp .copy_end
  1631.  
  1632.         .sou32: ;в источнике 32 битная картинка
  1633.         mov eax,buf2d_w
  1634.         mov edx,buf2d_h ;высота копируемой картинки
  1635.         mov esi,buf2d_data ;данные копируемой картинки
  1636.  
  1637.         mov edi,[buf_destination]
  1638.         cmp buf2d_bits,24
  1639.         jne .copy_end ;формат буфера не поодерживается
  1640.         mov ebx,[coord_x] ;в ebx временно ставим отступ изображения (для проверки)
  1641.         cmp ebx,buf2d_w   ;проверяем влазит ли изображение по ширине
  1642.         jge .copy_end     ;если изображение полностью вылазит за правую сторону
  1643.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1644.                 mov ecx,[coord_y]
  1645.                 cmp ecx,ebx
  1646.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1647.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1648.                 cmp ecx,ebx
  1649.                 jle @f
  1650.                         sub ecx,ebx
  1651.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1652.                 @@:
  1653.                 mov ebx,buf2d_w
  1654.                 mov ecx,ebx ;ecx используем для временных целей
  1655.                 imul ecx,[coord_y]
  1656.                 add ecx,[coord_x]
  1657.                 lea ecx,[ecx+ecx*2]
  1658.                 add ecx,buf2d_data
  1659.                 sub ebx,eax
  1660.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1661.  
  1662.         mov [right_bytes],0
  1663.         mov ecx,[coord_x]
  1664.         cmp ecx,ebx
  1665.         jl @f
  1666.                 sub ecx,ebx
  1667.                 sub eax,ecx ;укорачиваем копируемую строку
  1668.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1669.                 shl ecx,2 ;ecx - число байт в 1-й строке картинки, которые вылазят за правую сторону
  1670.                 mov [right_bytes],ecx
  1671.         @@:
  1672.  
  1673.         ;eax - колличество пикселей в 1-й строке копируемой картинки
  1674.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1675.  
  1676.         cld
  1677.         cmp [right_bytes],0
  1678.         jg .copy_3
  1679.         .copy_2: ;простое копирование
  1680.                 mov ecx,eax
  1681.                 @@:
  1682.                         movsw
  1683.                         movsb
  1684.                         inc esi
  1685.                         loop @b
  1686.                 add edi,ebx
  1687.                 dec edx
  1688.                 cmp edx,0
  1689.                 jg .copy_2
  1690.         jmp .copy_end
  1691.         .copy_3: ;не простое копирование (картинка вылазит за правую сторону)
  1692.                 mov ecx,eax
  1693.                 @@:
  1694.                         movsw
  1695.                         movsb
  1696.                         inc esi
  1697.                         loop @b
  1698.                 add edi,ebx
  1699.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  1700.                 dec edx
  1701.                 cmp edx,0
  1702.                 jg .copy_3
  1703.  
  1704.         .copy_end:
  1705.         popad
  1706.         ret
  1707. endp
  1708.  
  1709. ;input:
  1710. ; esi = pointer to color1 + transparent
  1711. ; edi = pointer to background color2
  1712. ;output:
  1713. ; [edi] = combine color
  1714. align 4
  1715. combine_colors:
  1716.         push ax bx cx dx
  1717.         mov bx,0x00ff ;---get transparent---
  1718.         mov cl,byte[esi+3] ;pro
  1719.         xor ch,ch
  1720.         sub bx,cx ;256-pro
  1721.         ;---blye---
  1722.         xor ah,ah
  1723.         mov al,byte[esi]
  1724.         imul ax,bx
  1725.         xor dh,dh
  1726.         mov dl,byte[edi]
  1727.         imul dx,cx
  1728.         add ax,dx
  1729.         mov byte[edi],ah
  1730.         ;---green---
  1731.         xor ah,ah
  1732.         mov al,byte[esi+1]
  1733.         imul ax,bx
  1734.         xor dh,dh
  1735.         mov dl,byte[edi+1]
  1736.         imul dx,cx
  1737.         add ax,dx
  1738.         mov byte[edi+1],ah
  1739.         ;---red---
  1740.         xor ah,ah
  1741.         mov al,byte[esi+2]
  1742.         imul ax,bx
  1743.         xor dh,dh
  1744.         mov dl,byte[edi+2]
  1745.         imul dx,cx
  1746.         add ax,dx
  1747.         mov byte[edi+2],ah
  1748.  
  1749.         pop dx cx bx ax
  1750.         ret
  1751.  
  1752. ;функция копирует изображение из буфера buf_source (32b) в buf_destination (24b)
  1753. ; указываются координаты вставки буфера buf_source относительно buf_destination
  1754. ; при копировании учитывается прозрачность
  1755. align 4
  1756. proc buf_bit_blt_transp, buf_destination:dword, coord_x:dword, coord_y:dword, buf_source:dword
  1757.         locals
  1758.                 right_bytes dd ?
  1759.         endl
  1760.         pushad
  1761.  
  1762.         mov edi,[buf_source]
  1763.         cmp buf2d_bits,32
  1764.         jne .copy_end ;формат буфера не поодерживается
  1765.         mov eax,buf2d_w
  1766.         mov edx,buf2d_h ;высота копируемой картинки
  1767.         mov esi,buf2d_data ;данные копируемой картинки
  1768.  
  1769.         mov edi,[buf_destination]
  1770.         cmp buf2d_bits,24
  1771.         jne .copy_end ;формат буфера не поодерживается
  1772.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1773.                 mov ecx,[coord_y]
  1774.                 cmp ecx,ebx
  1775.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1776.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1777.                 cmp ecx,ebx
  1778.                 jle @f
  1779.                         sub ecx,ebx
  1780.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1781.                 @@:
  1782.                 mov ebx,buf2d_w
  1783.                 mov ecx,ebx ;ecx используем для временных целей
  1784.                 imul ecx,[coord_y]
  1785.                 add ecx,[coord_x]
  1786.                 lea ecx,[ecx+ecx*2]
  1787.                 add ecx,buf2d_data
  1788.                 sub ebx,eax
  1789.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1790.  
  1791.         mov [right_bytes],0
  1792.         mov ecx,[coord_x]
  1793.         cmp ecx,ebx
  1794.         jl @f
  1795.                 sub ecx,ebx
  1796.                 sub eax,ecx ;укорачиваем копируемую строку
  1797.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1798.                 shl ecx,2 ;ecx - число байт в 1-й строке картинки, которые вылазят за правую сторону
  1799.                 mov [right_bytes],ecx
  1800.         @@:
  1801.  
  1802.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1803.  
  1804.         cld
  1805.         cmp [right_bytes],0
  1806.         jg .copy_1
  1807.         .copy_0: ;простое копирование
  1808.                 mov ecx,eax
  1809.                 @@:
  1810.                         call combine_colors
  1811.                         add edi,3
  1812.                         add esi,4
  1813.                         loop @b
  1814.                 add edi,ebx
  1815.                 dec edx
  1816.                 cmp edx,0
  1817.                 jg .copy_0
  1818.         jmp .copy_end
  1819.         .copy_1: ;не простое копирование (картинка вылазит за правую сторону)
  1820.                 mov ecx,eax
  1821.                 @@:
  1822.                         call combine_colors
  1823.                         add edi,3
  1824.                         add esi,4
  1825.                         loop @b
  1826.                 add edi,ebx
  1827.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  1828.                 dec edx
  1829.                 cmp edx,0
  1830.                 jg .copy_1
  1831.  
  1832.         .copy_end:
  1833.         popad
  1834.         ret
  1835. endp
  1836.  
  1837. ;input:
  1838. ; ebx - color1
  1839. ; esi = pointer to transparent
  1840. ; edi = pointer to background color2
  1841. ;output:
  1842. ; [edi] = combine color
  1843. align 4
  1844. combine_colors_2:
  1845.         push ax ebx cx dx si
  1846.         mov cl,byte[esi] ;pro
  1847.         xor ch,ch
  1848.         mov si,0x00ff ;---get transparent---
  1849.         sub si,cx ;256-pro
  1850.  
  1851.                 ;---blye---
  1852.                 mov al,bl
  1853.                 xor ah,ah
  1854.                 shr ebx,8
  1855.                 imul ax,si
  1856.                 xor dh,dh
  1857.                 mov dl,byte[edi]
  1858.                 imul dx,cx
  1859.                 add ax,dx
  1860.                 mov byte[edi],ah
  1861.                 ;---green---
  1862.                 mov al,bl
  1863.                 xor ah,ah
  1864.                 shr ebx,8
  1865.                 imul ax,si
  1866.                 xor dh,dh
  1867.                 mov dl,byte[edi+1]
  1868.                 imul dx,cx
  1869.                 add ax,dx
  1870.                 mov byte[edi+1],ah
  1871.                 ;---red---
  1872.                 mov al,bl
  1873.                 xor ah,ah
  1874.                 imul ax,si
  1875.                 xor dh,dh
  1876.                 mov dl,byte[edi+2]
  1877.                 imul dx,cx
  1878.                 add ax,dx
  1879.                 mov byte[edi+2],ah
  1880.  
  1881.         pop si dx cx ebx ax
  1882.         ret
  1883.  
  1884. ;функция копирует изображение из буфера buf_source (8b) в buf_destination (24b)
  1885. ; указываются координаты вставки буфера buf_source относительно buf_destination
  1886. align 4
  1887. proc buf_bit_blt_alpha, buf_destination:dword, coord_x:dword, coord_y:dword, buf_source:dword, color:dword
  1888.         locals
  1889.                 right_bytes dd ?
  1890.                 dest_w_bytes dd ? ;колличество байт в буфере приемнике по ширине - ширина вставляемой картинки
  1891.         endl
  1892.         pushad
  1893.  
  1894.         mov edi,[buf_source]
  1895.         cmp buf2d_bits,8
  1896.         jne .error1 ;формат буфера не поодерживается
  1897.         mov eax,buf2d_w
  1898.         mov edx,buf2d_h ;высота копируемой картинки
  1899.         mov esi,buf2d_data ;данные копируемой картинки
  1900.  
  1901.         mov edi,[buf_destination]
  1902.         cmp buf2d_bits,24
  1903.         jne .error2 ;формат буфера не поодерживается
  1904.         mov ebx,[coord_x] ;в ebx временно ставим отступ изображения (для проверки)
  1905.         cmp ebx,buf2d_w   ;проверяем влазит ли изображение по ширине
  1906.         jge .copy_end     ;если изображение полностью вылазит за правую сторону
  1907.                 mov ebx,buf2d_h ;ebx - высота основного буфера
  1908.                 mov ecx,[coord_y]
  1909.                 cmp ecx,ebx
  1910.                 jge .copy_end ;если координата 'y' больше высоты буфера
  1911.                 add ecx,edx ;ecx - нижняя координата копируемой картинки
  1912.                 cmp ecx,ebx
  1913.                 jle @f
  1914.                         sub ecx,ebx
  1915.                         sub edx,ecx ;уменьшаем высоту копируемой картинки, в случе когда она вылазит за нижнюю границу
  1916.                 @@:
  1917.                 mov ebx,buf2d_w
  1918.                 mov ecx,ebx ;ecx используем для временных целей
  1919.                 imul ecx,[coord_y]
  1920.                 add ecx,[coord_x]
  1921.                 lea ecx,[ecx+ecx*2]
  1922.                 add ecx,buf2d_data
  1923.                 sub ebx,eax
  1924.                 mov edi,ecx ;edi указатель на данные буфера, куда будет производится копирование
  1925.  
  1926.         mov [right_bytes],0
  1927.         mov ecx,[coord_x]
  1928.         cmp ecx,ebx
  1929.         jl @f
  1930.                 sub ecx,ebx
  1931.                 sub eax,ecx ;укорачиваем копируемую строку
  1932.                 add ebx,ecx ;удлинняем строку для сдвига главной картинки буфера
  1933.                 ;ecx - число пикселей в 1-й строке картинки, которые вылазят за правую сторону
  1934.                 mov [right_bytes],ecx
  1935.         @@:
  1936.  
  1937.         lea ebx,[ebx+ebx*2] ;колличество байт в 1-й строке буфера минус число байт в 1-й строке копируемой картинки
  1938.         mov [dest_w_bytes],ebx
  1939.         mov ebx,[color]
  1940.  
  1941.         cld
  1942.         cmp [right_bytes],0
  1943.         jg .copy_1
  1944.         .copy_0: ;простое копирование
  1945.                 mov ecx,eax
  1946.                 @@:
  1947.                         call combine_colors_2
  1948.                         add edi,3
  1949.                         inc esi
  1950.                         loop @b
  1951.                 add edi,[dest_w_bytes]
  1952.                 dec edx
  1953.                 cmp edx,0
  1954.                 jg .copy_0
  1955.         jmp .copy_end
  1956.         .copy_1: ;не простое копирование (картинка вылазит за правую сторону)
  1957.                 mov ecx,eax
  1958.                 @@:
  1959.                         call combine_colors_2
  1960.                         add edi,3
  1961.                         inc esi
  1962.                         loop @b
  1963.                 add edi,[dest_w_bytes]
  1964.                 add esi,[right_bytes] ;добавляем байты, которые вылазят за правую границу
  1965.                 dec edx
  1966.                 cmp edx,0
  1967.                 jg .copy_1
  1968.  
  1969.         jmp .copy_end
  1970.         .error1:
  1971.                 stdcall print_err,sz_buf2d_bit_blt_alpha,txt_err_n8b
  1972.                 jmp .copy_end
  1973.         .error2:
  1974.                 stdcall print_err,sz_buf2d_bit_blt_alpha,txt_err_n24b
  1975.         .copy_end:
  1976.         popad
  1977.         ret
  1978. endp
  1979.  
  1980. ;преобразование 8-битного буфера размером 16*16 в размер 1*256 символов
  1981. align 4
  1982. proc buf_convert_text_matrix, buf_struc:dword
  1983.         locals
  1984.                 tmp_mem dd ?
  1985.                 c1 dw ?
  1986.                 c2 dd ?
  1987.                 c3 dw ?
  1988.         endl
  1989.         pushad
  1990.         mov edi,dword[buf_struc]
  1991.         cmp buf2d_bits,8
  1992.         jne .error
  1993.                 mov ecx,buf2d_h
  1994.                 mov ebx,ecx
  1995.                 shr ebx,4 ;предполагаем что в буфере 16 строк с символами, потому делим на 2^4
  1996.                 mov edx,buf2d_w
  1997.                 imul ecx,edx ;ecx = size  8 b
  1998.                 invoke mem.alloc,ecx ;выделяем временную память
  1999.                 mov [tmp_mem],eax ;eax - new memory
  2000.  
  2001.                 shr edx,4 ;предполагаем что в буфере 16 колонок с символами, потому делим на 2^4
  2002.                 mov eax,ebx
  2003.                 imul ebx,edx ;вычисляем кооличество пикселей на 1 символ
  2004.                 ;eax = bhe - высота буквы
  2005.                 ;ebx = bwi*bhe - колличество пикселей в 1-й букве
  2006.                 ;edx = bwi - ширина буквы
  2007.                 ;ecx,esi,edi - используются в цикле .c_0
  2008.                 shr buf2d_w,4
  2009.                 shl buf2d_h,4 ;преобразовываем размеры буфера
  2010.  
  2011.                 cld
  2012.                 mov esi,buf2d_data
  2013.                 mov edi,[tmp_mem]
  2014.                 mov word[c3],16
  2015.                 .c_3:
  2016.                         mov dword[c2],eax
  2017.                         .c_2:
  2018.                                 mov word[c1],16
  2019.                                 .c_1:
  2020.                                         mov ecx,edx ;.c_0:
  2021.                                         rep movsb
  2022.                                         add edi,ebx
  2023.                                         sub edi,edx ;edi+=(bwi*bhe-bwi)
  2024.                                         dec word[c1]
  2025.                                         cmp word[c1],0
  2026.                                         jg .c_1
  2027.                                 add edi,edx
  2028.                                 shl ebx,4
  2029.                                 sub edi,ebx ;edi-=(16*bwi*bhe-bwi)
  2030.                                 shr ebx,4
  2031.                                 dec dword[c2]
  2032.                                 cmp dword[c2],0
  2033.                                 jg .c_2
  2034.                         sub edi,ebx
  2035.                         shl ebx,4
  2036.                         add edi,ebx ;edi+=(15*bwi*bhe)
  2037.                         shr ebx,4
  2038.                         dec word[c3]
  2039.                         cmp word[c3],0
  2040.                         jg .c_3
  2041.  
  2042.                 mov edi,dword[buf_struc] ;копирование новой матрицы в основной буфер
  2043.                 mov edi,buf2d_data
  2044.                 mov esi,[tmp_mem]
  2045.                 mov ecx,ebx
  2046.                 shl ecx,8
  2047.                 rep movsb
  2048.                 invoke mem.free,[tmp_mem] ;чистим временную память
  2049.                 jmp .end_conv
  2050.         .error:
  2051.                 stdcall print_err,sz_buf2d_convert_text_matrix,txt_err_n8b
  2052.         .end_conv:
  2053.         popad
  2054.         ret
  2055. endp
  2056.  
  2057. align 4
  2058. buf_s_matr buf_2d_header ? ;локальная матрица символа
  2059.  
  2060. align 4
  2061. proc buf_draw_text, buf_struc:dword, buf_t_matr:dword, text:dword, coord_x:dword, coord_y:dword, color:dword
  2062.         locals
  2063.                 buf_t_matr_offs dd ?
  2064.         endl
  2065.         pushad
  2066.         mov edi,dword[buf_struc]
  2067.         cmp buf2d_bits,24
  2068.         jne .error2
  2069.         mov edi,dword[buf_t_matr]
  2070.         cmp buf2d_bits,8
  2071.         jne .error1
  2072.                 mov edx,buf2d_data
  2073.                 mov [buf_t_matr_offs],edx
  2074.                 mov ecx,BUF_STRUCT_SIZE ;копируем структуру текстовой матрицы
  2075.                 mov esi,edi
  2076.                 lea edi,[buf_s_matr]
  2077.                 cld
  2078.                 rep movsb
  2079.                 lea edi,[buf_s_matr]
  2080.                 shr buf2d_h,8 ;делим высоту символьного буфера на 256, для нахождения высоты 1-го символа
  2081.                 mov ebx,buf2d_h ;берем высоту символа
  2082.                 mov ecx,buf2d_w ;берем ширину символа
  2083.  
  2084.                 mov eax,[coord_x]
  2085.                 mov esi,[text]
  2086.                 cmp byte[esi],0
  2087.                 je .end_draw ;если пустая строка
  2088.                 @@:
  2089.                         xor edx,edx
  2090.                         mov dl,byte[esi] ;берем код символа
  2091.                         imul edx,ebx ;умножаем его на высоту символа
  2092.                         imul edx,ecx ;умножаем на ширину символа
  2093.                         add edx,[buf_t_matr_offs] ;прибавляем смещение 0-го символа, т. е. получается смещение выводимого символа
  2094.                         mov buf2d_data,edx ;в локальный буфер символа, ставим указатель на нужный символ из буфера buf_t_matr
  2095.                         stdcall buf_bit_blt_alpha, [buf_struc], eax,[coord_y], edi,[color]
  2096.                         add eax,ecx
  2097.                         .new_s:
  2098.                                 inc esi
  2099.                                 cmp byte[esi],13
  2100.                                 jne .no_13
  2101.                                         mov eax,[coord_x]
  2102.                                         add [coord_y],ebx
  2103.                                         jmp .new_s
  2104.                                 .no_13:
  2105.                         cmp byte[esi],0
  2106.                         jne @b
  2107.                 jmp .end_draw
  2108.         .error1:
  2109.                 stdcall print_err,sz_buf2d_draw_text,txt_err_n8b
  2110.                 jmp .end_draw
  2111.         .error2:
  2112.                 stdcall print_err,sz_buf2d_draw_text,txt_err_n24b
  2113.         .end_draw:
  2114.         popad
  2115.         ret
  2116. endp
  2117.  
  2118. align 4
  2119. proc print_err, fun:dword, mes:dword ;выводим сообщение об шибке на доску отладки
  2120.         pushad
  2121.         mov eax,63
  2122.         mov ebx,1
  2123.  
  2124.         mov esi,[fun]
  2125.         @@:
  2126.                 mov cl,byte[esi]
  2127.                 int 0x40
  2128.                 inc esi
  2129.                 cmp byte[esi],0
  2130.                 jne @b
  2131.         mov cl,':'
  2132.         int 0x40
  2133.         mov cl,' '
  2134.         int 0x40
  2135.         mov esi,[mes]
  2136.         @@:
  2137.                 mov cl,byte[esi]
  2138.                 int 0x40
  2139.                 inc esi
  2140.                 cmp byte[esi],0
  2141.                 jne @b
  2142.         popad
  2143.         ret
  2144. endp
  2145.  
  2146. ;input:
  2147. ; ebp+8  = p0
  2148. ; ebp+12 = p1
  2149. align 4
  2150. line_len4i:
  2151.         push ebp
  2152.         mov ebp,esp
  2153.                 finit
  2154.                 fild word [ebp+8]
  2155.                 fisub word [ebp+12]
  2156.                 fmul st0,st0 ;st0=x^2
  2157.                 fild word [ebp+10]
  2158.                 fisub word [ebp+14]
  2159.                 fmul st0,st0 ;st0=y^2
  2160.                 fadd st0,st1
  2161.                 fsqrt
  2162.                 fstp dword [ebp+12]
  2163.         pop ebp
  2164.         ret 4 ;8
  2165.  
  2166. align 4
  2167. proc buf_curve_bezier, buffer:dword, coord_p0:dword,coord_p1:dword,coord_p2:dword, color:dword
  2168.         locals
  2169.                 delt_t dd ?
  2170.                 opr_param dd ?
  2171.                 v_poi_0 dd ?
  2172.         endl
  2173.         pushad
  2174.  
  2175. ;float t, xt,yt;
  2176. ;for(t=.0;t<1.;t+=.005){
  2177. ;  xt=pow(1.-t,2)*x0+2*t*(1.-t)*x1+pow(t,2)*x2;
  2178. ;  yt=pow(1.-t,2)*y0+2*t*(1.-t)*y1+pow(t,2)*y2;
  2179. ;  dc.SetPixel(xt,yt,255L);
  2180. ;}
  2181.  
  2182.         mov edx,[color] ;set curve color
  2183.         mov edi,[buffer]
  2184.         xor ebx,ebx
  2185.         xor ecx,ecx
  2186.  
  2187.         finit
  2188.  
  2189.         ; calculate delta t
  2190.         stdcall line_len4i, dword[coord_p1],dword[coord_p0]
  2191.         fadd dword[esp]
  2192.         add esp,4 ;pop ...
  2193.  
  2194.         stdcall line_len4i, dword[coord_p2],dword[coord_p1]
  2195.         fadd dword[esp]
  2196.         add esp,4 ;pop ...
  2197.  
  2198.         fadd st0,st0 ; len*=2
  2199.         ftst
  2200.         fstsw ax
  2201.  
  2202.         fld1
  2203.         sahf
  2204.         jle @f ;избегаем деления на 0
  2205.                 fdiv st0,st1
  2206.         @@:
  2207.         fstp dword[delt_t]
  2208.  
  2209.         finit
  2210.  
  2211.         ;fild word[coord_p2+2] ;y2
  2212.         fild word[coord_p1+2] ;y1
  2213.         fild word[coord_p0+2] ;y0
  2214.         fild word[coord_p2] ;x2
  2215.         fild word[coord_p1] ;x1
  2216.         fild word[coord_p0] ;x0
  2217.         fld dword[delt_t]
  2218.         fldz ;t=.0
  2219.  
  2220.         @@:
  2221.                 fld1
  2222.                 fsub st0,st1 ;1.-t
  2223.                 fmul st0,st0 ;pow(1.-t,2)
  2224.                 fmul st0,st3 ;...*x0
  2225.                 fstp dword[opr_param]
  2226.  
  2227.                 fld1
  2228.                 fsub st0,st1 ;1.-t
  2229.                 fmul st0,st1 ;(1.-t)*t
  2230.                 fadd st0,st0
  2231.                 fmul st0,st4 ;...*x1
  2232.                 mov esi,dword[opr_param]
  2233.                 fstp dword[opr_param]
  2234.  
  2235.                 fldz
  2236.                 fadd st0,st1 ;0+t
  2237.                 fmul st0,st0 ;t*t
  2238.                 fmul st0,st5 ;...*x2
  2239.  
  2240.                 fadd dword[opr_param]
  2241.                 mov dword[opr_param],esi
  2242.                 fadd dword[opr_param]
  2243.                 fistp word[v_poi_0] ;x
  2244.  
  2245.                 fld1
  2246.                 fsub st0,st1 ;1.-t
  2247.                 fmul st0,st0 ;pow(1.-t,2)
  2248.                 fmul st0,st6 ;...*y0
  2249.                 fstp dword[opr_param]
  2250.  
  2251.                 fld1
  2252.                 fsub st0,st1 ;1.-t
  2253.                 fmul st0,st1 ;(1.-t)*t
  2254.                 fadd st0,st0
  2255.                 fmul st0,st7 ;...*y1
  2256.                 mov esi,dword[opr_param]
  2257.                 fstp dword[opr_param]
  2258.  
  2259.                 fldz
  2260.                 fadd st0,st1 ;0+t
  2261.                 fmul st0,st0 ;t*t
  2262.                 fimul word[coord_p2+2] ;...*y2
  2263.  
  2264.                 fadd dword[opr_param]
  2265.                 mov dword[opr_param],esi
  2266.                 fadd dword[opr_param]
  2267.                 fistp word[v_poi_0+2] ;y
  2268.  
  2269.                 mov eax,1
  2270.                 mov bx,word[v_poi_0+2]
  2271.                 mov cx,word[v_poi_0]
  2272.                 call draw_pixel
  2273.  
  2274.                 fadd st0,st1 ;t+dt
  2275.  
  2276.                 fld1
  2277.                 fcomp
  2278.                 fstsw ax
  2279.                 sahf
  2280.         jae @b
  2281.  
  2282.         popad
  2283.         ret
  2284. endp
  2285.  
  2286. txt_err_n8b db 'need buffer 8 bit',13,10,0
  2287. txt_err_n24b db 'need buffer 24 bit',13,10,0
  2288.  
  2289. align 16
  2290. EXPORTS:
  2291.         dd sz_lib_init, lib_init
  2292.         dd sz_buf2d_create, buf_create
  2293.         dd sz_buf2d_create_f_img, buf_create_f_img
  2294.         dd sz_buf2d_clear, buf_clear
  2295.         dd sz_buf2d_draw, buf_draw_buf
  2296.         dd sz_buf2d_delete, buf_delete
  2297.         dd sz_buf2d_line, buf_line_brs
  2298.         dd sz_buf2d_rect_by_size, buf_rect_by_size
  2299.         dd sz_buf2d_filled_rect_by_size, buf_filled_rect_by_size
  2300.         dd sz_buf2d_circle, buf_circle
  2301.         dd sz_buf2d_img_hdiv2, buf_img_hdiv2
  2302.         dd sz_buf2d_img_wdiv2, buf_img_wdiv2
  2303.         dd sz_buf2d_conv_24_to_8, buf_conv_24_to_8
  2304.         dd sz_buf2d_conv_24_to_32, buf_conv_24_to_32
  2305.         dd sz_buf2d_bit_blt, buf_bit_blt
  2306.         dd sz_buf2d_bit_blt_transp, buf_bit_blt_transp
  2307.         dd sz_buf2d_bit_blt_alpha, buf_bit_blt_alpha
  2308.         dd sz_buf2d_curve_bezier, buf_curve_bezier
  2309.         dd sz_buf2d_convert_text_matrix, buf_convert_text_matrix
  2310.         dd sz_buf2d_draw_text, buf_draw_text
  2311.         dd sz_buf2d_crop_color, buf_crop_color
  2312.         dd sz_buf2d_offset_h, buf_offset_h
  2313.         dd sz_buf2d_flood_fill, buf_flood_fill
  2314.         dd 0,0
  2315.         sz_lib_init db 'lib_init',0
  2316.         sz_buf2d_create db 'buf2d_create',0
  2317.         sz_buf2d_create_f_img db 'buf2d_create_f_img',0
  2318.         sz_buf2d_clear db 'buf2d_clear',0 ;очистка буфера указанным цветом
  2319.         sz_buf2d_draw db 'buf2d_draw',0
  2320.         sz_buf2d_delete db 'buf2d_delete',0
  2321.         sz_buf2d_line db 'buf2d_line',0 ;рисование линии
  2322.         sz_buf2d_rect_by_size db 'buf2d_rect_by_size',0 ;рисование рамки прямоугольника, 2-я координата задана по размеру
  2323.         sz_buf2d_filled_rect_by_size db 'buf2d_filled_rect_by_size',0 ;рисование залитого прямоугольника, 2-я координата задана по размеру
  2324.         sz_buf2d_circle db 'buf2d_circle',0 ;рисование окружности
  2325.         sz_buf2d_img_hdiv2 db 'buf2d_img_hdiv2',0 ;сжатие изображения по высоте в 2 раза (размер буфера не меняется)
  2326.         sz_buf2d_img_wdiv2 db 'buf2d_img_wdiv2',0 ;сжатие изображения по ширине в 2 раза (размер буфера не меняется)
  2327.         sz_buf2d_conv_24_to_8 db 'buf2d_conv_24_to_8',0
  2328.         sz_buf2d_conv_24_to_32 db 'buf2d_conv_24_to_32',0
  2329.         sz_buf2d_bit_blt db 'buf2d_bit_blt',0
  2330.         sz_buf2d_bit_blt_transp db 'buf2d_bit_blt_transp',0
  2331.         sz_buf2d_bit_blt_alpha db 'buf2d_bit_blt_alpha',0
  2332.         sz_buf2d_curve_bezier db 'buf2d_curve_bezier',0
  2333.         sz_buf2d_convert_text_matrix db 'buf2d_convert_text_matrix',0
  2334.         sz_buf2d_draw_text db 'buf2d_draw_text',0
  2335.         sz_buf2d_crop_color db 'buf2d_crop_color',0
  2336.         sz_buf2d_offset_h db 'buf2d_offset_h',0
  2337.         sz_buf2d_flood_fill db 'buf2d_flood_fill',0
  2338.  
  2339.