Subversion Repositories Kolibri OS

Rev

Rev 2665 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2013, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. preprocessor:
  7.         mov     edi,characters
  8.         xor     al,al
  9.       make_characters_table:
  10.         stosb
  11.         inc     al
  12.         jnz     make_characters_table
  13.         mov     esi,characters+'a'
  14.         mov     edi,characters+'A'
  15.         mov     ecx,26
  16.         rep     movsb
  17.         mov     edi,characters
  18.         mov     esi,symbol_characters+1
  19.         movzx   ecx,byte [esi-1]
  20.         xor     eax,eax
  21.       mark_symbol_characters:
  22.         lodsb
  23.         mov     byte [edi+eax],0
  24.         loop    mark_symbol_characters
  25.         mov     edi,locals_counter
  26.         mov     ax,1 + '0' shl 8
  27.         stos    word [edi]
  28.         mov     edi,[memory_start]
  29.         mov     [include_paths],edi
  30.         mov     esi,include_variable
  31.         call    get_environment_variable
  32.         xor     al,al
  33.         stos    byte [edi]
  34.         mov     [memory_start],edi
  35.         mov     eax,[additional_memory]
  36.         mov     [free_additional_memory],eax
  37.         mov     eax,[additional_memory_end]
  38.         mov     [labels_list],eax
  39.         xor     eax,eax
  40.         mov     [source_start],eax
  41.         mov     [tagged_blocks],eax
  42.         mov     [hash_tree],eax
  43.         mov     [error],eax
  44.         mov     [macro_status],al
  45.         mov     esi,[input_file]
  46.         mov     edx,esi
  47.         call    open
  48.         jc      main_file_not_found
  49.         mov     edi,[memory_start]
  50.         call    preprocess_file
  51.         mov     eax,[error_line]
  52.         mov     [current_line],eax
  53.         cmp     [macro_status],0
  54.         jne     incomplete_macro
  55.         mov     [source_start],edi
  56.         ret
  57.  
  58. preprocess_file:
  59.         push    [memory_end]
  60.         push    esi
  61.         mov     al,2
  62.         xor     edx,edx
  63.         call    lseek
  64.         push    eax
  65.         xor     al,al
  66.         xor     edx,edx
  67.         call    lseek
  68.         pop     ecx
  69.         mov     edx,[memory_end]
  70.         dec     edx
  71.         mov     byte [edx],1Ah
  72.         sub     edx,ecx
  73.         jc      out_of_memory
  74.         mov     esi,edx
  75.         cmp     edx,edi
  76.         jbe     out_of_memory
  77.         mov     [memory_end],edx
  78.         call    read
  79.         call    close
  80.         pop     edx
  81.         xor     ecx,ecx
  82.         mov     ebx,esi
  83.       preprocess_source:
  84.         inc     ecx
  85.         mov     [current_line],edi
  86.         mov     eax,edx
  87.         stos    dword [edi]
  88.         mov     eax,ecx
  89.         stos    dword [edi]
  90.         mov     eax,esi
  91.         sub     eax,ebx
  92.         stos    dword [edi]
  93.         xor     eax,eax
  94.         stos    dword [edi]
  95.         push    ebx edx
  96.         call    convert_line
  97.         call    preprocess_line
  98.         pop     edx ebx
  99.       next_line:
  100.         cmp     byte [esi-1],0
  101.         je      file_end
  102.         cmp     byte [esi-1],1Ah
  103.         jne     preprocess_source
  104.       file_end:
  105.         pop     [memory_end]
  106.         clc
  107.         ret
  108.  
  109. convert_line:
  110.         push    ecx
  111.         test    [macro_status],0Fh
  112.         jz      convert_line_data
  113.         mov     ax,3Bh
  114.         stos    word [edi]
  115.       convert_line_data:
  116.         cmp     edi,[memory_end]
  117.         jae     out_of_memory
  118.         lods    byte [esi]
  119.         cmp     al,20h
  120.         je      convert_line_data
  121.         cmp     al,9
  122.         je      convert_line_data
  123.         mov     ah,al
  124.         mov     ebx,characters
  125.         xlat    byte [ebx]
  126.         or      al,al
  127.         jz      convert_separator
  128.         cmp     ah,27h
  129.         je      convert_string
  130.         cmp     ah,22h
  131.         je      convert_string
  132.         mov     byte [edi],1Ah
  133.         scas    word [edi]
  134.         xchg    al,ah
  135.         stos    byte [edi]
  136.         mov     ebx,characters
  137.         xor     ecx,ecx
  138.       convert_symbol:
  139.         lods    byte [esi]
  140.         stos    byte [edi]
  141.         xlat    byte [ebx]
  142.         or      al,al
  143.         loopnzd convert_symbol
  144.         neg     ecx
  145.         cmp     ecx,255
  146.         ja      name_too_long
  147.         mov     ebx,edi
  148.         sub     ebx,ecx
  149.         mov     byte [ebx-2],cl
  150.       found_separator:
  151.         dec     edi
  152.         mov     ah,[esi-1]
  153.       convert_separator:
  154.         xchg    al,ah
  155.         cmp     al,20h
  156.         jb      control_character
  157.         je      convert_line_data
  158.       symbol_character:
  159.         cmp     al,3Bh
  160.         je      ignore_comment
  161.         cmp     al,5Ch
  162.         je      backslash_character
  163.         stos    byte [edi]
  164.         jmp     convert_line_data
  165.       control_character:
  166.         cmp     al,1Ah
  167.         je      line_end
  168.         cmp     al,0Dh
  169.         je      cr_character
  170.         cmp     al,0Ah
  171.         je      lf_character
  172.         cmp     al,9
  173.         je      convert_line_data
  174.         or      al,al
  175.         jnz     symbol_character
  176.         jmp     line_end
  177.       lf_character:
  178.         lods    byte [esi]
  179.         cmp     al,0Dh
  180.         je      line_end
  181.         dec     esi
  182.         jmp     line_end
  183.       cr_character:
  184.         lods    byte [esi]
  185.         cmp     al,0Ah
  186.         je      line_end
  187.         dec     esi
  188.         jmp     line_end
  189.       convert_string:
  190.         mov     al,22h
  191.         stos    byte [edi]
  192.         scas    dword [edi]
  193.         mov     ebx,edi
  194.       copy_string:
  195.         lods    byte [esi]
  196.         stos    byte [edi]
  197.         cmp     al,0Ah
  198.         je      no_end_quote
  199.         cmp     al,0Dh
  200.         je      no_end_quote
  201.         or      al,al
  202.         jz      no_end_quote
  203.         cmp     al,1Ah
  204.         je      no_end_quote
  205.         cmp     al,ah
  206.         jne     copy_string
  207.         lods    byte [esi]
  208.         cmp     al,ah
  209.         je      copy_string
  210.         dec     esi
  211.         dec     edi
  212.         mov     eax,edi
  213.         sub     eax,ebx
  214.         mov     [ebx-4],eax
  215.         jmp     convert_line_data
  216.       backslash_character:
  217.         mov     byte [edi],0
  218.         lods    byte [esi]
  219.         cmp     al,20h
  220.         je      concatenate_lines
  221.         cmp     al,9
  222.         je      concatenate_lines
  223.         cmp     al,1Ah
  224.         je      unexpected_end_of_file
  225.         or      al,al
  226.         jz      unexpected_end_of_file
  227.         cmp     al,0Ah
  228.         je      concatenate_lf
  229.         cmp     al,0Dh
  230.         je      concatenate_cr
  231.         cmp     al,3Bh
  232.         je      find_concatenated_line
  233.         mov     al,1Ah
  234.         stos    byte [edi]
  235.         mov     ecx,edi
  236.         mov     ax,5C01h
  237.         stos    word [edi]
  238.         dec     esi
  239.       group_backslashes:
  240.         lods    byte [esi]
  241.         cmp     al,5Ch
  242.         jne     backslashed_symbol
  243.         stos    byte [edi]
  244.         inc     byte [ecx]
  245.         jmp     group_backslashes
  246.       no_end_quote:
  247.         mov     byte [ebx-5],0
  248.         jmp     missing_end_quote
  249.       backslashed_symbol:
  250.         cmp     al,1Ah
  251.         je      unexpected_end_of_file
  252.         or      al,al
  253.         jz      unexpected_end_of_file
  254.         cmp     al,0Ah
  255.         je      extra_characters_on_line
  256.         cmp     al,0Dh
  257.         je      extra_characters_on_line
  258.         cmp     al,20h
  259.         je      extra_characters_on_line
  260.         cmp     al,9
  261.         je      extra_characters_on_line
  262.         cmp     al,22h
  263.         je      extra_characters_on_line
  264.         cmp     al,27h
  265.         je      extra_characters_on_line
  266.         cmp     al,3Bh
  267.         je      extra_characters_on_line
  268.         mov     ah,al
  269.         mov     ebx,characters
  270.         xlat    byte [ebx]
  271.         or      al,al
  272.         jz      backslashed_symbol_character
  273.         mov     al,ah
  274.       convert_backslashed_symbol:
  275.         stos    byte [edi]
  276.         xlat    byte [ebx]
  277.         or      al,al
  278.         jz      found_separator
  279.         inc     byte [ecx]
  280.         jz      name_too_long
  281.         lods    byte [esi]
  282.         jmp     convert_backslashed_symbol
  283.       backslashed_symbol_character:
  284.         mov     al,ah
  285.         stos    byte [edi]
  286.         inc     byte [ecx]
  287.         jmp     convert_line_data
  288.       concatenate_lines:
  289.         lods    byte [esi]
  290.         cmp     al,20h
  291.         je      concatenate_lines
  292.         cmp     al,9
  293.         je      concatenate_lines
  294.         cmp     al,1Ah
  295.         je      unexpected_end_of_file
  296.         or      al,al
  297.         jz      unexpected_end_of_file
  298.         cmp     al,0Ah
  299.         je      concatenate_lf
  300.         cmp     al,0Dh
  301.         je      concatenate_cr
  302.         cmp     al,3Bh
  303.         jne     extra_characters_on_line
  304.       find_concatenated_line:
  305.         lods    byte [esi]
  306.         cmp     al,0Ah
  307.         je      concatenate_lf
  308.         cmp     al,0Dh
  309.         je      concatenate_cr
  310.         or      al,al
  311.         jz      concatenate_ok
  312.         cmp     al,1Ah
  313.         jne     find_concatenated_line
  314.         jmp     unexpected_end_of_file
  315.       concatenate_lf:
  316.         lods    byte [esi]
  317.         cmp     al,0Dh
  318.         je      concatenate_ok
  319.         dec     esi
  320.         jmp     concatenate_ok
  321.       concatenate_cr:
  322.         lods    byte [esi]
  323.         cmp     al,0Ah
  324.         je      concatenate_ok
  325.         dec     esi
  326.       concatenate_ok:
  327.         inc     dword [esp]
  328.         jmp     convert_line_data
  329.       ignore_comment:
  330.         lods    byte [esi]
  331.         cmp     al,0Ah
  332.         je      lf_character
  333.         cmp     al,0Dh
  334.         je      cr_character
  335.         or      al,al
  336.         jz      line_end
  337.         cmp     al,1Ah
  338.         jne     ignore_comment
  339.       line_end:
  340.         xor     al,al
  341.         stos    byte [edi]
  342.         pop     ecx
  343.         ret
  344.  
  345. lower_case:
  346.         mov     edi,converted
  347.         mov     ebx,characters
  348.       convert_case:
  349.         lods    byte [esi]
  350.         xlat    byte [ebx]
  351.         stos    byte [edi]
  352.         loop    convert_case
  353.       case_ok:
  354.         ret
  355.  
  356. get_directive:
  357.         push    edi
  358.         mov     edx,esi
  359.         mov     ebp,ecx
  360.         call    lower_case
  361.         pop     edi
  362.       scan_directives:
  363.         mov     esi,converted
  364.         movzx   eax,byte [edi]
  365.         or      al,al
  366.         jz      no_directive
  367.         mov     ecx,ebp
  368.         inc     edi
  369.         mov     ebx,edi
  370.         add     ebx,eax
  371.         mov     ah,[esi]
  372.         cmp     ah,[edi]
  373.         jb      no_directive
  374.         ja      next_directive
  375.         cmp     cl,al
  376.         jne     next_directive
  377.         repe    cmps byte [esi],[edi]
  378.         jb      no_directive
  379.         je      directive_ok
  380.       next_directive:
  381.         mov     edi,ebx
  382.         add     edi,2
  383.         jmp     scan_directives
  384.       no_directive:
  385.         mov     esi,edx
  386.         mov     ecx,ebp
  387.         stc
  388.         ret
  389.       directive_ok:
  390.         lea     esi,[edx+ebp]
  391.         call    directive_handler
  392.       directive_handler:
  393.         pop     ecx
  394.         movzx   eax,word [ebx]
  395.         add     eax,ecx
  396.         clc
  397.         ret
  398.  
  399. preprocess_line:
  400.         mov     eax,esp
  401.         sub     eax,100h
  402.         jc      stack_overflow
  403.         cmp     eax,[stack_limit]
  404.         jb      stack_overflow
  405.         push    ecx esi
  406.       preprocess_current_line:
  407.         mov     esi,[current_line]
  408.         add     esi,16
  409.         cmp     word [esi],3Bh
  410.         jne     line_start_ok
  411.         add     esi,2
  412.       line_start_ok:
  413.         test    [macro_status],0F0h
  414.         jnz     macro_preprocessing
  415.         cmp     byte [esi],1Ah
  416.         jne     not_fix_constant
  417.         movzx   edx,byte [esi+1]
  418.         lea     edx,[esi+2+edx]
  419.         cmp     word [edx],031Ah
  420.         jne     not_fix_constant
  421.         mov     ebx,characters
  422.         movzx   eax,byte [edx+2]
  423.         xlat    byte [ebx]
  424.         ror     eax,8
  425.         mov     al,[edx+3]
  426.         xlat    byte [ebx]
  427.         ror     eax,8
  428.         mov     al,[edx+4]
  429.         xlat    byte [ebx]
  430.         ror     eax,16
  431.         cmp     eax,'fix'
  432.         je      define_fix_constant
  433.       not_fix_constant:
  434.         call    process_fix_constants
  435.         jmp     initial_preprocessing_ok
  436.       macro_preprocessing:
  437.         call    process_macro_operators
  438.       initial_preprocessing_ok:
  439.         mov     esi,[current_line]
  440.         add     esi,16
  441.         mov     al,[macro_status]
  442.         test    al,2
  443.         jnz     skip_macro_block
  444.         test    al,1
  445.         jnz     find_macro_block
  446.       preprocess_instruction:
  447.         mov     [current_offset],esi
  448.         lods    byte [esi]
  449.         movzx   ecx,byte [esi]
  450.         inc     esi
  451.         cmp     al,1Ah
  452.         jne     not_preprocessor_symbol
  453.         cmp     cl,3
  454.         jb      not_preprocessor_directive
  455.         push    edi
  456.         mov     edi,preprocessor_directives
  457.         call    get_directive
  458.         pop     edi
  459.         jc      not_preprocessor_directive
  460.         mov     byte [edx-2],3Bh
  461.         jmp     near eax
  462.       not_preprocessor_directive:
  463.         xor     ch,ch
  464.         call    get_preprocessor_symbol
  465.         jc      not_macro
  466.         mov     byte [ebx-2],3Bh
  467.         mov     [struc_name],0
  468.         jmp     use_macro
  469.       not_macro:
  470.         mov     [struc_name],esi
  471.         add     esi,ecx
  472.         lods    byte [esi]
  473.         cmp     al,':'
  474.         je      preprocess_label
  475.         cmp     al,1Ah
  476.         jne     not_preprocessor_symbol
  477.         lods    byte [esi]
  478.         cmp     al,3
  479.         jne     not_symbolic_constant
  480.         mov     ebx,characters
  481.         movzx   eax,byte [esi]
  482.         xlat    byte [ebx]
  483.         ror     eax,8
  484.         mov     al,[esi+1]
  485.         xlat    byte [ebx]
  486.         ror     eax,8
  487.         mov     al,[esi+2]
  488.         xlat    byte [ebx]
  489.         ror     eax,16
  490.         cmp     eax,'equ'
  491.         je      define_equ_constant
  492.         mov     al,3
  493.       not_symbolic_constant:
  494.         mov     ch,1
  495.         mov     cl,al
  496.         call    get_preprocessor_symbol
  497.         jc      not_preprocessor_symbol
  498.         push    edx esi
  499.         mov     esi,[struc_name]
  500.         mov     [struc_label],esi
  501.         sub     [struc_label],2
  502.         mov     cl,[esi-1]
  503.         mov     ch,10b
  504.         call    get_preprocessor_symbol
  505.         jc      struc_name_ok
  506.         mov     ecx,[edx+12]
  507.         add     ecx,3
  508.         lea     ebx,[edi+ecx]
  509.         mov     ecx,edi
  510.         sub     ecx,[struc_label]
  511.         lea     esi,[edi-1]
  512.         lea     edi,[ebx-1]
  513.         std
  514.         rep     movs byte [edi],[esi]
  515.         cld
  516.         mov     edi,[struc_label]
  517.         mov     esi,[edx+8]
  518.         mov     ecx,[edx+12]
  519.         add     [struc_name],ecx
  520.         add     [struc_name],3
  521.         call    move_data
  522.         mov     al,3Ah
  523.         stos    byte [edi]
  524.         mov     ax,3Bh
  525.         stos    word [edi]
  526.         mov     edi,ebx
  527.         pop     esi
  528.         add     esi,[edx+12]
  529.         add     esi,3
  530.         pop     edx
  531.         jmp     use_macro
  532.       struc_name_ok:
  533.         mov     edx,[struc_name]
  534.         movzx   eax,byte [edx-1]
  535.         add     edx,eax
  536.         push    edi
  537.         lea     esi,[edi-1]
  538.         mov     ecx,edi
  539.         sub     ecx,edx
  540.         std
  541.         rep     movs byte [edi],[esi]
  542.         cld
  543.         pop     edi
  544.         inc     edi
  545.         mov     al,3Ah
  546.         mov     [edx],al
  547.         inc     al
  548.         mov     [edx+1],al
  549.         pop     esi edx
  550.         inc     esi
  551.         jmp     use_macro
  552.       preprocess_label:
  553.         dec     esi
  554.         sub     esi,ecx
  555.         lea     ebp,[esi-2]
  556.         mov     ch,10b
  557.         call    get_preprocessor_symbol
  558.         jnc     symbolic_constant_in_label
  559.         lea     esi,[esi+ecx+1]
  560.         cmp     byte [esi],':'
  561.         jne     preprocess_instruction
  562.         inc     esi
  563.         jmp     preprocess_instruction
  564.       symbolic_constant_in_label:
  565.         mov     ebx,[edx+8]
  566.         mov     ecx,[edx+12]
  567.         add     ecx,ebx
  568.       check_for_broken_label:
  569.         cmp     ebx,ecx
  570.         je      label_broken
  571.         cmp     byte [ebx],1Ah
  572.         jne     label_broken
  573.         movzx   eax,byte [ebx+1]
  574.         lea     ebx,[ebx+2+eax]
  575.         cmp     ebx,ecx
  576.         je      label_constant_ok
  577.         cmp     byte [ebx],':'
  578.         jne     label_broken
  579.         inc     ebx
  580.         cmp     byte [ebx],':'
  581.         jne     check_for_broken_label
  582.         inc     ebx
  583.         jmp     check_for_broken_label
  584.       label_broken:
  585.         push    line_preprocessed
  586.         jmp     replace_symbolic_constant
  587.       label_constant_ok:
  588.         mov     ecx,edi
  589.         sub     ecx,esi
  590.         mov     edi,[edx+12]
  591.         add     edi,ebp
  592.         push    edi
  593.         lea     eax,[edi+ecx]
  594.         push    eax
  595.         cmp     esi,edi
  596.         je      replace_label
  597.         jb      move_rest_of_line_up
  598.         rep     movs byte [edi],[esi]
  599.         jmp     replace_label
  600.       move_rest_of_line_up:
  601.         lea     esi,[esi+ecx-1]
  602.         lea     edi,[edi+ecx-1]
  603.         std
  604.         rep     movs byte [edi],[esi]
  605.         cld
  606.       replace_label:
  607.         mov     ecx,[edx+12]
  608.         mov     edi,[esp+4]
  609.         sub     edi,ecx
  610.         mov     esi,[edx+8]
  611.         rep     movs byte [edi],[esi]
  612.         pop     edi esi
  613.         inc     esi
  614.         jmp     preprocess_instruction
  615.       not_preprocessor_symbol:
  616.         mov     esi,[current_offset]
  617.         call    process_equ_constants
  618.       line_preprocessed:
  619.         pop     esi ecx
  620.         ret
  621.  
  622. get_preprocessor_symbol:
  623.         push    ebp edi esi
  624.         mov     ebp,ecx
  625.         shl     ebp,22
  626.         movzx   ecx,cl
  627.         mov     ebx,hash_tree
  628.         mov     edi,10
  629.       follow_hashes_roots:
  630.         mov     edx,[ebx]
  631.         or      edx,edx
  632.         jz      preprocessor_symbol_not_found
  633.         xor     eax,eax
  634.         shl     ebp,1
  635.         adc     eax,0
  636.         lea     ebx,[edx+eax*4]
  637.         dec     edi
  638.         jnz     follow_hashes_roots
  639.         mov     edi,ebx
  640.         call    calculate_hash
  641.         mov     ebp,eax
  642.         and     ebp,3FFh
  643.         shl     ebp,10
  644.         xor     ebp,eax
  645.         mov     ebx,edi
  646.         mov     edi,22
  647.       follow_hashes_tree:
  648.         mov     edx,[ebx]
  649.         or      edx,edx
  650.         jz      preprocessor_symbol_not_found
  651.         xor     eax,eax
  652.         shl     ebp,1
  653.         adc     eax,0
  654.         lea     ebx,[edx+eax*4]
  655.         dec     edi
  656.         jnz     follow_hashes_tree
  657.         mov     al,cl
  658.         mov     edx,[ebx]
  659.         or      edx,edx
  660.         jz      preprocessor_symbol_not_found
  661.       compare_with_preprocessor_symbol:
  662.         mov     edi,[edx+4]
  663.         cmp     edi,1
  664.         jbe     next_equal_hash
  665.         repe    cmps byte [esi],[edi]
  666.         je      preprocessor_symbol_found
  667.         mov     cl,al
  668.         mov     esi,[esp]
  669.       next_equal_hash:
  670.         mov     edx,[edx]
  671.         or      edx,edx
  672.         jnz     compare_with_preprocessor_symbol
  673.       preprocessor_symbol_not_found:
  674.         pop     esi edi ebp
  675.         stc
  676.         ret
  677.       preprocessor_symbol_found:
  678.         pop     ebx edi ebp
  679.         clc
  680.         ret
  681.       calculate_hash:
  682.         xor     ebx,ebx
  683.         mov     eax,2166136261
  684.         mov     ebp,16777619
  685.       fnv1a_hash:
  686.         xor     al,[esi+ebx]
  687.         mul     ebp
  688.         inc     bl
  689.         cmp     bl,cl
  690.         jb      fnv1a_hash
  691.         ret
  692. add_preprocessor_symbol:
  693.         push    edi esi
  694.         cmp     ch,11b
  695.         je      preprocessor_symbol_name_ok
  696.         push    ecx
  697.         movzx   ecx,cl
  698.         mov     edi,preprocessor_directives
  699.         call    get_directive
  700.         jnc     reserved_word_used_as_symbol
  701.         pop     ecx
  702.       preprocessor_symbol_name_ok:
  703.         call    calculate_hash
  704.         mov     ebp,eax
  705.         and     ebp,3FFh
  706.         shr     eax,10
  707.         xor     ebp,eax
  708.         shl     ecx,22
  709.         or      ebp,ecx
  710.         mov     ebx,hash_tree
  711.         mov     ecx,32
  712.       find_leave_for_symbol:
  713.         mov     edx,[ebx]
  714.         or      edx,edx
  715.         jz      extend_hashes_tree
  716.         xor     eax,eax
  717.         rol     ebp,1
  718.         adc     eax,0
  719.         lea     ebx,[edx+eax*4]
  720.         dec     ecx
  721.         jnz     find_leave_for_symbol
  722.         mov     edx,[ebx]
  723.         or      edx,edx
  724.         jz      add_symbol_entry
  725.         shr     ebp,30
  726.         cmp     ebp,11b
  727.         je      reuse_symbol_entry
  728.         cmp     dword [edx+4],0
  729.         jne     add_symbol_entry
  730.       find_entry_to_reuse:
  731.         mov     edi,[edx]
  732.         or      edi,edi
  733.         jz      reuse_symbol_entry
  734.         cmp     dword [edi+4],0
  735.         jne     reuse_symbol_entry
  736.         mov     edx,edi
  737.         jmp     find_entry_to_reuse
  738.       add_symbol_entry:
  739.         mov     eax,edx
  740.         mov     edx,[labels_list]
  741.         sub     edx,16
  742.         cmp     edx,[free_additional_memory]
  743.         jb      out_of_memory
  744.         mov     [labels_list],edx
  745.         mov     [edx],eax
  746.         mov     [ebx],edx
  747.       reuse_symbol_entry:
  748.         pop     esi edi
  749.         mov     [edx+4],esi
  750.         ret
  751.       extend_hashes_tree:
  752.         mov     edx,[labels_list]
  753.         sub     edx,8
  754.         cmp     edx,[free_additional_memory]
  755.         jb      out_of_memory
  756.         mov     [labels_list],edx
  757.         xor     eax,eax
  758.         mov     [edx],eax
  759.         mov     [edx+4],eax
  760.         shl     ebp,1
  761.         adc     eax,0
  762.         mov     [ebx],edx
  763.         lea     ebx,[edx+eax*4]
  764.         dec     ecx
  765.         jnz     extend_hashes_tree
  766.         mov     edx,[labels_list]
  767.         sub     edx,16
  768.         cmp     edx,[free_additional_memory]
  769.         jb      out_of_memory
  770.         mov     [labels_list],edx
  771.         mov     dword [edx],0
  772.         mov     [ebx],edx
  773.         pop     esi edi
  774.         mov     [edx+4],esi
  775.         ret
  776.  
  777. define_fix_constant:
  778.         add     edx,5
  779.         add     esi,2
  780.         push    edx
  781.         mov     ch,11b
  782.         jmp     define_preprocessor_constant
  783. define_equ_constant:
  784.         add     esi,3
  785.         push    esi
  786.         call    process_equ_constants
  787.         mov     esi,[struc_name]
  788.         mov     ch,10b
  789.       define_preprocessor_constant:
  790.         mov     byte [esi-2],3Bh
  791.         mov     cl,[esi-1]
  792.         call    add_preprocessor_symbol
  793.         pop     ebx
  794.         mov     ecx,edi
  795.         dec     ecx
  796.         sub     ecx,ebx
  797.         mov     [edx+8],ebx
  798.         mov     [edx+12],ecx
  799.         jmp     line_preprocessed
  800. define_symbolic_constant:
  801.         lods    byte [esi]
  802.         cmp     al,1Ah
  803.         jne     invalid_name
  804.         lods    byte [esi]
  805.         mov     cl,al
  806.         mov     ch,10b
  807.         call    add_preprocessor_symbol
  808.         movzx   eax,byte [esi-1]
  809.         add     esi,eax
  810.         lea     ecx,[edi-1]
  811.         sub     ecx,esi
  812.         mov     [edx+8],esi
  813.         mov     [edx+12],ecx
  814.         jmp     line_preprocessed
  815.  
  816. define_struc:
  817.         mov     ch,1
  818.         jmp     make_macro
  819. define_macro:
  820.         xor     ch,ch
  821.       make_macro:
  822.         lods    byte [esi]
  823.         cmp     al,1Ah
  824.         jne     invalid_name
  825.         lods    byte [esi]
  826.         mov     cl,al
  827.         call    add_preprocessor_symbol
  828.         mov     eax,[current_line]
  829.         mov     [edx+12],eax
  830.         movzx   eax,byte [esi-1]
  831.         add     esi,eax
  832.         mov     [edx+8],esi
  833.         mov     al,[macro_status]
  834.         and     al,0F0h
  835.         or      al,1
  836.         mov     [macro_status],al
  837.         mov     eax,[current_line]
  838.         mov     [error_line],eax
  839.         xor     ebp,ebp
  840.         lods    byte [esi]
  841.         or      al,al
  842.         jz      line_preprocessed
  843.         cmp     al,'{'
  844.         je      found_macro_block
  845.         dec     esi
  846.       skip_macro_arguments:
  847.         lods    byte [esi]
  848.         cmp     al,1Ah
  849.         je      skip_macro_argument
  850.         cmp     al,'['
  851.         jne     invalid_macro_arguments
  852.         or      ebp,-1
  853.         jz      invalid_macro_arguments
  854.         lods    byte [esi]
  855.         cmp     al,1Ah
  856.         jne     invalid_macro_arguments
  857.       skip_macro_argument:
  858.         movzx   eax,byte [esi]
  859.         inc     esi
  860.         add     esi,eax
  861.         lods    byte [esi]
  862.         cmp     al,'='
  863.         je      macro_argument_with_default_value
  864.         cmp     al,'*'
  865.         jne     macro_argument_end
  866.         lods    byte [esi]
  867.       macro_argument_end:
  868.         cmp     al,','
  869.         je      skip_macro_arguments
  870.         cmp     al,']'
  871.         jne     end_macro_arguments
  872.         lods    byte [esi]
  873.         not     ebp
  874.       end_macro_arguments:
  875.         or      ebp,ebp
  876.         jnz     invalid_macro_arguments
  877.         or      al,al
  878.         jz      line_preprocessed
  879.         cmp     al,'{'
  880.         je      found_macro_block
  881.         jmp     invalid_macro_arguments
  882.       macro_argument_with_default_value:
  883.         or      [default_argument_value],-1
  884.         call    skip_macro_argument_value
  885.         inc     esi
  886.         jmp     macro_argument_end
  887.       skip_macro_argument_value:
  888.         cmp     byte [esi],'<'
  889.         jne     simple_argument
  890.         mov     ecx,1
  891.         inc     esi
  892.       enclosed_argument:
  893.         lods    byte [esi]
  894.         or      al,al
  895.         jz      invalid_macro_arguments
  896.         cmp     al,1Ah
  897.         je      enclosed_symbol
  898.         cmp     al,22h
  899.         je      enclosed_string
  900.         cmp     al,'>'
  901.         je      enclosed_argument_end
  902.         cmp     al,'<'
  903.         jne     enclosed_argument
  904.         inc     ecx
  905.         jmp     enclosed_argument
  906.       enclosed_symbol:
  907.         movzx   eax,byte [esi]
  908.         inc     esi
  909.         add     esi,eax
  910.         jmp     enclosed_argument
  911.       enclosed_string:
  912.         lods    dword [esi]
  913.         add     esi,eax
  914.         jmp     enclosed_argument
  915.       enclosed_argument_end:
  916.         loop    enclosed_argument
  917.         lods    byte [esi]
  918.         or      al,al
  919.         jz      argument_value_end
  920.         cmp     al,','
  921.         je      argument_value_end
  922.         cmp     [default_argument_value],0
  923.         je      invalid_macro_arguments
  924.         cmp     al,'{'
  925.         je      argument_value_end
  926.         or      ebp,ebp
  927.         jz      invalid_macro_arguments
  928.         cmp     al,']'
  929.         je      argument_value_end
  930.         jmp     invalid_macro_arguments
  931.       simple_argument:
  932.         lods    byte [esi]
  933.         or      al,al
  934.         jz      argument_value_end
  935.         cmp     al,','
  936.         je      argument_value_end
  937.         cmp     al,22h
  938.         je      argument_string
  939.         cmp     al,1Ah
  940.         je      argument_symbol
  941.         cmp     [default_argument_value],0
  942.         je      simple_argument
  943.         cmp     al,'{'
  944.         je      argument_value_end
  945.         or      ebp,ebp
  946.         jz      simple_argument
  947.         cmp     al,']'
  948.         je      argument_value_end
  949.       argument_symbol:
  950.         movzx   eax,byte [esi]
  951.         inc     esi
  952.         add     esi,eax
  953.         jmp     simple_argument
  954.       argument_string:
  955.         lods    dword [esi]
  956.         add     esi,eax
  957.         jmp     simple_argument
  958.       argument_value_end:
  959.         dec     esi
  960.         ret
  961.       find_macro_block:
  962.         add     esi,2
  963.         lods    byte [esi]
  964.         or      al,al
  965.         jz      line_preprocessed
  966.         cmp     al,'{'
  967.         jne     unexpected_characters
  968.       found_macro_block:
  969.         or      [macro_status],2
  970.       skip_macro_block:
  971.         lods    byte [esi]
  972.         cmp     al,1Ah
  973.         je      skip_macro_symbol
  974.         cmp     al,3Bh
  975.         je      skip_macro_symbol
  976.         cmp     al,22h
  977.         je      skip_macro_string
  978.         or      al,al
  979.         jz      line_preprocessed
  980.         cmp     al,'}'
  981.         jne     skip_macro_block
  982.         mov     al,[macro_status]
  983.         and     [macro_status],0F0h
  984.         test    al,8
  985.         jnz     use_instant_macro
  986.         cmp     byte [esi],0
  987.         je      line_preprocessed
  988.         mov     ecx,edi
  989.         sub     ecx,esi
  990.         mov     edx,esi
  991.         lea     esi,[esi+ecx-1]
  992.         lea     edi,[edi+1+16]
  993.         mov     ebx,edi
  994.         dec     edi
  995.         std
  996.         rep     movs byte [edi],[esi]
  997.         cld
  998.         mov     edi,edx
  999.         xor     al,al
  1000.         stos    byte [edi]
  1001.         mov     esi,[current_line]
  1002.         mov     [current_line],edi
  1003.         mov     ecx,4
  1004.         rep     movs dword [edi],[esi]
  1005.         mov     edi,ebx
  1006.         jmp     initial_preprocessing_ok
  1007.       skip_macro_symbol:
  1008.         movzx   eax,byte [esi]
  1009.         inc     esi
  1010.         add     esi,eax
  1011.         jmp     skip_macro_block
  1012.       skip_macro_string:
  1013.         lods    dword [esi]
  1014.         add     esi,eax
  1015.         jmp     skip_macro_block
  1016. rept_directive:
  1017.         mov     [base_code],0
  1018.         jmp     define_instant_macro
  1019. irp_directive:
  1020.         mov     [base_code],1
  1021.         jmp     define_instant_macro
  1022. irps_directive:
  1023.         mov     [base_code],2
  1024.         jmp     define_instant_macro
  1025. match_directive:
  1026.         mov     [base_code],10h
  1027. define_instant_macro:
  1028.         mov     al,[macro_status]
  1029.         and     al,0F0h
  1030.         or      al,8+1
  1031.         mov     [macro_status],al
  1032.         mov     eax,[current_line]
  1033.         mov     [error_line],eax
  1034.         mov     [instant_macro_start],esi
  1035.         cmp     [base_code],10h
  1036.         je      prepare_match
  1037.       skip_parameters:
  1038.         lods    byte [esi]
  1039.         or      al,al
  1040.         jz      parameters_skipped
  1041.         cmp     al,'{'
  1042.         je      parameters_skipped
  1043.         cmp     al,22h
  1044.         je      skip_quoted_parameter
  1045.         cmp     al,1Ah
  1046.         jne     skip_parameters
  1047.         lods    byte [esi]
  1048.         movzx   eax,al
  1049.         add     esi,eax
  1050.         jmp     skip_parameters
  1051.       skip_quoted_parameter:
  1052.         lods    dword [esi]
  1053.         add     esi,eax
  1054.         jmp     skip_parameters
  1055.       parameters_skipped:
  1056.         dec     esi
  1057.         mov     [parameters_end],esi
  1058.         lods    byte [esi]
  1059.         cmp     al,'{'
  1060.         je      found_macro_block
  1061.         or      al,al
  1062.         jnz     invalid_macro_arguments
  1063.         jmp     line_preprocessed
  1064. prepare_match:
  1065.         call    skip_pattern
  1066.         mov     [value_type],80h+10b
  1067.         call    process_symbolic_constants
  1068.         jmp     parameters_skipped
  1069.       skip_pattern:
  1070.         lods    byte [esi]
  1071.         or      al,al
  1072.         jz      invalid_macro_arguments
  1073.         cmp     al,','
  1074.         je      pattern_skipped
  1075.         cmp     al,22h
  1076.         je      skip_quoted_string_in_pattern
  1077.         cmp     al,1Ah
  1078.         je      skip_symbol_in_pattern
  1079.         cmp     al,'='
  1080.         jne     skip_pattern
  1081.         mov     al,[esi]
  1082.         cmp     al,1Ah
  1083.         je      skip_pattern
  1084.         cmp     al,22h
  1085.         je      skip_pattern
  1086.         inc     esi
  1087.         jmp     skip_pattern
  1088.       skip_symbol_in_pattern:
  1089.         lods    byte [esi]
  1090.         movzx   eax,al
  1091.         add     esi,eax
  1092.         jmp     skip_pattern
  1093.       skip_quoted_string_in_pattern:
  1094.         lods    dword [esi]
  1095.         add     esi,eax
  1096.         jmp     skip_pattern
  1097.       pattern_skipped:
  1098.         ret
  1099.  
  1100. purge_macro:
  1101.         xor     ch,ch
  1102.         jmp     restore_preprocessor_symbol
  1103. purge_struc:
  1104.         mov     ch,1
  1105.         jmp     restore_preprocessor_symbol
  1106. restore_equ_constant:
  1107.         mov     ch,10b
  1108.       restore_preprocessor_symbol:
  1109.         push    ecx
  1110.         lods    byte [esi]
  1111.         cmp     al,1Ah
  1112.         jne     invalid_name
  1113.         lods    byte [esi]
  1114.         mov     cl,al
  1115.         call    get_preprocessor_symbol
  1116.         jc      no_symbol_to_restore
  1117.         mov     dword [edx+4],0
  1118.         jmp     symbol_restored
  1119.       no_symbol_to_restore:
  1120.         add     esi,ecx
  1121.       symbol_restored:
  1122.         pop     ecx
  1123.         lods    byte [esi]
  1124.         cmp     al,','
  1125.         je      restore_preprocessor_symbol
  1126.         or      al,al
  1127.         jnz     extra_characters_on_line
  1128.         jmp     line_preprocessed
  1129.  
  1130. process_fix_constants:
  1131.         mov     [value_type],11b
  1132.         jmp     process_symbolic_constants
  1133. process_equ_constants:
  1134.         mov     [value_type],10b
  1135.       process_symbolic_constants:
  1136.         mov     ebp,esi
  1137.         lods    byte [esi]
  1138.         cmp     al,1Ah
  1139.         je      check_symbol
  1140.         cmp     al,22h
  1141.         je      ignore_string
  1142.         cmp     al,'{'
  1143.         je      check_brace
  1144.         or      al,al
  1145.         jnz     process_symbolic_constants
  1146.         ret
  1147.       ignore_string:
  1148.         lods    dword [esi]
  1149.         add     esi,eax
  1150.         jmp     process_symbolic_constants
  1151.       check_brace:
  1152.         test    [value_type],80h
  1153.         jz      process_symbolic_constants
  1154.         ret
  1155.       no_replacing:
  1156.         movzx   ecx,byte [esi-1]
  1157.         add     esi,ecx
  1158.         jmp     process_symbolic_constants
  1159.       check_symbol:
  1160.         mov     cl,[esi]
  1161.         inc     esi
  1162.         mov     ch,[value_type]
  1163.         call    get_preprocessor_symbol
  1164.         jc      no_replacing
  1165.         mov     [current_section],edi
  1166.       replace_symbolic_constant:
  1167.         mov     ecx,[edx+12]
  1168.         mov     edx,[edx+8]
  1169.         xchg    esi,edx
  1170.         call    move_data
  1171.         mov     esi,edx
  1172.       process_after_replaced:
  1173.         lods    byte [esi]
  1174.         cmp     al,1Ah
  1175.         je      symbol_after_replaced
  1176.         stos    byte [edi]
  1177.         cmp     al,22h
  1178.         je      string_after_replaced
  1179.         cmp     al,'{'
  1180.         je      brace_after_replaced
  1181.         or      al,al
  1182.         jnz     process_after_replaced
  1183.         mov     ecx,edi
  1184.         sub     ecx,esi
  1185.         mov     edi,ebp
  1186.         call    move_data
  1187.         mov     esi,edi
  1188.         ret
  1189.       move_data:
  1190.         lea     eax,[edi+ecx]
  1191.         cmp     eax,[memory_end]
  1192.         jae     out_of_memory
  1193.         shr     ecx,1
  1194.         jnc     movsb_ok
  1195.         movs    byte [edi],[esi]
  1196.       movsb_ok:
  1197.         shr     ecx,1
  1198.         jnc     movsw_ok
  1199.         movs    word [edi],[esi]
  1200.       movsw_ok:
  1201.         rep     movs dword [edi],[esi]
  1202.         ret
  1203.       string_after_replaced:
  1204.         lods    dword [esi]
  1205.         stos    dword [edi]
  1206.         mov     ecx,eax
  1207.         call    move_data
  1208.         jmp     process_after_replaced
  1209.       brace_after_replaced:
  1210.         test    [value_type],80h
  1211.         jz      process_after_replaced
  1212.         mov     edx,edi
  1213.         mov     ecx,[current_section]
  1214.         sub     edx,ecx
  1215.         sub     ecx,esi
  1216.         rep     movs byte [edi],[esi]
  1217.         mov     ecx,edi
  1218.         sub     ecx,esi
  1219.         mov     edi,ebp
  1220.         call    move_data
  1221.         lea     esi,[ebp+edx]
  1222.         ret
  1223.       symbol_after_replaced:
  1224.         mov     cl,[esi]
  1225.         inc     esi
  1226.         mov     ch,[value_type]
  1227.         call    get_preprocessor_symbol
  1228.         jnc     replace_symbolic_constant
  1229.         movzx   ecx,byte [esi-1]
  1230.         mov     al,1Ah
  1231.         mov     ah,cl
  1232.         stos    word [edi]
  1233.         call    move_data
  1234.         jmp     process_after_replaced
  1235. process_macro_operators:
  1236.         xor     dl,dl
  1237.         mov     ebp,edi
  1238.       before_macro_operators:
  1239.         mov     edi,esi
  1240.         lods    byte [esi]
  1241.         cmp     al,'`'
  1242.         je      symbol_conversion
  1243.         cmp     al,'#'
  1244.         je      concatenation
  1245.         cmp     al,1Ah
  1246.         je      symbol_before_macro_operators
  1247.         cmp     al,3Bh
  1248.         je      no_more_macro_operators
  1249.         cmp     al,22h
  1250.         je      string_before_macro_operators
  1251.         xor     dl,dl
  1252.         or      al,al
  1253.         jnz     before_macro_operators
  1254.         mov     edi,esi
  1255.         ret
  1256.       no_more_macro_operators:
  1257.         mov     edi,ebp
  1258.         ret
  1259.       symbol_before_macro_operators:
  1260.         mov     dl,1Ah
  1261.         mov     ebx,esi
  1262.         lods    byte [esi]
  1263.         movzx   ecx,al
  1264.         jecxz   symbol_before_macro_operators_ok
  1265.         mov     edi,esi
  1266.         cmp     byte [esi],'\'
  1267.         je      escaped_symbol
  1268.       symbol_before_macro_operators_ok:
  1269.         add     esi,ecx
  1270.         jmp     before_macro_operators
  1271.       string_before_macro_operators:
  1272.         mov     dl,22h
  1273.         mov     ebx,esi
  1274.         lods    dword [esi]
  1275.         add     esi,eax
  1276.         jmp     before_macro_operators
  1277.       escaped_symbol:
  1278.         dec     byte [edi-1]
  1279.         dec     ecx
  1280.         inc     esi
  1281.         cmp     ecx,1
  1282.         rep     movs byte [edi],[esi]
  1283.         jne     after_macro_operators
  1284.         mov     al,[esi-1]
  1285.         mov     ecx,ebx
  1286.         mov     ebx,characters
  1287.         xlat    byte [ebx]
  1288.         mov     ebx,ecx
  1289.         or      al,al
  1290.         jnz     after_macro_operators
  1291.         sub     edi,3
  1292.         mov     al,[esi-1]
  1293.         stos    byte [edi]
  1294.         xor     dl,dl
  1295.         jmp     after_macro_operators
  1296.       reduce_symbol_conversion:
  1297.         inc     esi
  1298.       symbol_conversion:
  1299.         mov     edx,esi
  1300.         mov     al,[esi]
  1301.         cmp     al,1Ah
  1302.         jne     symbol_character_conversion
  1303.         lods    word [esi]
  1304.         movzx   ecx,ah
  1305.         lea     ebx,[edi+3]
  1306.         jecxz   convert_to_quoted_string
  1307.         cmp     byte [esi],'\'
  1308.         jne     convert_to_quoted_string
  1309.         inc     esi
  1310.         dec     ecx
  1311.         dec     ebx
  1312.         jmp     convert_to_quoted_string
  1313.       symbol_character_conversion:
  1314.         cmp     al,22h
  1315.         je      after_macro_operators
  1316.         cmp     al,'`'
  1317.         je      reduce_symbol_conversion
  1318.         lea     ebx,[edi+5]
  1319.         xor     ecx,ecx
  1320.         or      al,al
  1321.         jz      convert_to_quoted_string
  1322.         cmp     al,'#'
  1323.         je      convert_to_quoted_string
  1324.         inc     ecx
  1325.       convert_to_quoted_string:
  1326.         sub     ebx,edx
  1327.         ja      shift_line_data
  1328.         mov     al,22h
  1329.         mov     dl,al
  1330.         stos    byte [edi]
  1331.         mov     ebx,edi
  1332.         mov     eax,ecx
  1333.         stos    dword [edi]
  1334.         rep     movs byte [edi],[esi]
  1335.         cmp     edi,esi
  1336.         je      before_macro_operators
  1337.         jmp     after_macro_operators
  1338.       shift_line_data:
  1339.         push    ecx
  1340.         mov     edx,esi
  1341.         lea     esi,[ebp-1]
  1342.         add     ebp,ebx
  1343.         lea     edi,[ebp-1]
  1344.         lea     ecx,[esi+1]
  1345.         sub     ecx,edx
  1346.         std
  1347.         rep     movs byte [edi],[esi]
  1348.         cld
  1349.         pop     eax
  1350.         sub     edi,3
  1351.         mov     dl,22h
  1352.         mov     [edi-1],dl
  1353.         mov     ebx,edi
  1354.         mov     [edi],eax
  1355.         lea     esi,[edi+4+eax]
  1356.         jmp     before_macro_operators
  1357.       concatenation:
  1358.         cmp     dl,1Ah
  1359.         je      symbol_concatenation
  1360.         cmp     dl,22h
  1361.         je      string_concatenation
  1362.       no_concatenation:
  1363.         cmp     esi,edi
  1364.         je      before_macro_operators
  1365.         jmp     after_macro_operators
  1366.       symbol_concatenation:
  1367.         cmp     byte [esi],1Ah
  1368.         jne     no_concatenation
  1369.         inc     esi
  1370.         lods    byte [esi]
  1371.         movzx   ecx,al
  1372.         jecxz   do_symbol_concatenation
  1373.         cmp     byte [esi],'\'
  1374.         je      concatenate_escaped_symbol
  1375.       do_symbol_concatenation:
  1376.         add     [ebx],cl
  1377.         jc      name_too_long
  1378.         rep     movs byte [edi],[esi]
  1379.         jmp     after_macro_operators
  1380.       concatenate_escaped_symbol:
  1381.         inc     esi
  1382.         dec     ecx
  1383.         jz      do_symbol_concatenation
  1384.         movzx   eax,byte [esi]
  1385.         cmp     byte [characters+eax],0
  1386.         jne     do_symbol_concatenation
  1387.         sub     esi,3
  1388.         jmp     no_concatenation
  1389.       string_concatenation:
  1390.         cmp     byte [esi],22h
  1391.         je      do_string_concatenation
  1392.         cmp     byte [esi],'`'
  1393.         jne     no_concatenation
  1394.       concatenate_converted_symbol:
  1395.         inc     esi
  1396.         mov     al,[esi]
  1397.         cmp     al,'`'
  1398.         je      concatenate_converted_symbol
  1399.         cmp     al,22h
  1400.         je      do_string_concatenation
  1401.         cmp     al,1Ah
  1402.         jne     concatenate_converted_symbol_character
  1403.         inc     esi
  1404.         lods    byte [esi]
  1405.         movzx   ecx,al
  1406.         jecxz   finish_concatenating_converted_symbol
  1407.         cmp     byte [esi],'\'
  1408.         jne     finish_concatenating_converted_symbol
  1409.         inc     esi
  1410.         dec     ecx
  1411.       finish_concatenating_converted_symbol:
  1412.         add     [ebx],ecx
  1413.         rep     movs byte [edi],[esi]
  1414.         jmp     after_macro_operators
  1415.       concatenate_converted_symbol_character:
  1416.         or      al,al
  1417.         jz      after_macro_operators
  1418.         cmp     al,'#'
  1419.         je      after_macro_operators
  1420.         inc     dword [ebx]
  1421.         movs    byte [edi],[esi]
  1422.         jmp     after_macro_operators
  1423.       do_string_concatenation:
  1424.         inc     esi
  1425.         lods    dword [esi]
  1426.         mov     ecx,eax
  1427.         add     [ebx],eax
  1428.         rep     movs byte [edi],[esi]
  1429.       after_macro_operators:
  1430.         lods    byte [esi]
  1431.         cmp     al,'`'
  1432.         je      symbol_conversion
  1433.         cmp     al,'#'
  1434.         je      concatenation
  1435.         stos    byte [edi]
  1436.         cmp     al,1Ah
  1437.         je      symbol_after_macro_operators
  1438.         cmp     al,3Bh
  1439.         je      no_more_macro_operators
  1440.         cmp     al,22h
  1441.         je      string_after_macro_operators
  1442.         xor     dl,dl
  1443.         or      al,al
  1444.         jnz     after_macro_operators
  1445.         ret
  1446.       symbol_after_macro_operators:
  1447.         mov     dl,1Ah
  1448.         mov     ebx,edi
  1449.         lods    byte [esi]
  1450.         stos    byte [edi]
  1451.         movzx   ecx,al
  1452.         jecxz   symbol_after_macro_operatorss_ok
  1453.         cmp     byte [esi],'\'
  1454.         je      escaped_symbol
  1455.       symbol_after_macro_operatorss_ok:
  1456.         rep     movs byte [edi],[esi]
  1457.         jmp     after_macro_operators
  1458.       string_after_macro_operators:
  1459.         mov     dl,22h
  1460.         mov     ebx,edi
  1461.         lods    dword [esi]
  1462.         stos    dword [edi]
  1463.         mov     ecx,eax
  1464.         rep     movs byte [edi],[esi]
  1465.         jmp     after_macro_operators
  1466.  
  1467. use_macro:
  1468.         push    [free_additional_memory]
  1469.         push    [macro_symbols]
  1470.         mov     [macro_symbols],0
  1471.         push    [counter_limit]
  1472.         push    dword [edx+4]
  1473.         mov     dword [edx+4],1
  1474.         push    edx
  1475.         mov     ebx,esi
  1476.         mov     esi,[edx+8]
  1477.         mov     eax,[edx+12]
  1478.         mov     [macro_line],eax
  1479.         mov     [counter_limit],0
  1480.         xor     ebp,ebp
  1481.       process_macro_arguments:
  1482.         mov     al,[esi]
  1483.         or      al,al
  1484.         jz      arguments_end
  1485.         cmp     al,'{'
  1486.         je      arguments_end
  1487.         inc     esi
  1488.         cmp     al,'['
  1489.         jne     get_macro_arguments
  1490.         mov     ebp,esi
  1491.         inc     esi
  1492.         inc     [counter_limit]
  1493.       get_macro_arguments:
  1494.         call    get_macro_argument
  1495.         lods    byte [esi]
  1496.         cmp     al,','
  1497.         je      next_argument
  1498.         cmp     al,']'
  1499.         je      next_arguments_group
  1500.         dec     esi
  1501.         jmp     arguments_end
  1502.       next_argument:
  1503.         cmp     byte [ebx],','
  1504.         jne     process_macro_arguments
  1505.         inc     ebx
  1506.         jmp     process_macro_arguments
  1507.       next_arguments_group:
  1508.         cmp     byte [ebx],','
  1509.         jne     arguments_end
  1510.         inc     ebx
  1511.         inc     [counter_limit]
  1512.         mov     esi,ebp
  1513.         jmp     process_macro_arguments
  1514.       get_macro_argument:
  1515.         lods    byte [esi]
  1516.         movzx   ecx,al
  1517.         mov     eax,[counter_limit]
  1518.         call    add_macro_symbol
  1519.         add     esi,ecx
  1520.         xchg    esi,ebx
  1521.         mov     [edx+12],esi
  1522.         mov     [default_argument_value],0
  1523.         call    skip_macro_argument_value
  1524.         call    finish_macro_argument
  1525.         xchg    esi,ebx
  1526.         cmp     byte [esi],'='
  1527.         je      argument_with_default_value
  1528.         cmp     byte [esi],'*'
  1529.         jne     macro_argument_ok
  1530.         cmp     dword [edx+8],0
  1531.         je      invalid_macro_arguments
  1532.         inc     esi
  1533.       macro_argument_ok:
  1534.         ret
  1535.       finish_macro_argument:
  1536.         mov     eax,[edx+12]
  1537.         mov     ecx,esi
  1538.         sub     ecx,eax
  1539.         cmp     byte [eax],'<'
  1540.         jne     argument_value_length_ok
  1541.         inc     dword [edx+12]
  1542.         sub     ecx,2
  1543.         or      ecx,80000000h
  1544.       argument_value_length_ok:
  1545.         mov     [edx+8],ecx
  1546.         ret
  1547.       argument_with_default_value:
  1548.         inc     esi
  1549.         push    esi
  1550.         or      [default_argument_value],-1
  1551.         call    skip_macro_argument_value
  1552.         pop     eax
  1553.         cmp     dword [edx+8],0
  1554.         jne     macro_argument_ok
  1555.         mov     [edx+12],eax
  1556.         call    finish_macro_argument
  1557.         jmp     macro_argument_ok
  1558.       arguments_end:
  1559.         cmp     byte [ebx],0
  1560.         jne     invalid_macro_arguments
  1561.         mov     eax,[esp+4]
  1562.         dec     eax
  1563.         call    process_macro
  1564.         pop     edx
  1565.         pop     dword [edx+4]
  1566.         pop     [counter_limit]
  1567.         pop     [macro_symbols]
  1568.         pop     [free_additional_memory]
  1569.         jmp     line_preprocessed
  1570. use_instant_macro:
  1571.         push    edi [current_line] esi
  1572.         mov     eax,[error_line]
  1573.         mov     [current_line],eax
  1574.         mov     [macro_line],eax
  1575.         mov     esi,[instant_macro_start]
  1576.         cmp     [base_code],10h
  1577.         jae     do_match
  1578.         cmp     [base_code],0
  1579.         jne     do_irp
  1580.         call    precalculate_value
  1581.         cmp     eax,0
  1582.         jl      value_out_of_range
  1583.         push    [free_additional_memory]
  1584.         push    [macro_symbols]
  1585.         mov     [macro_symbols],0
  1586.         push    [counter_limit]
  1587.         mov     [struc_name],0
  1588.         mov     [counter_limit],eax
  1589.         lods    byte [esi]
  1590.         or      al,al
  1591.         jz      rept_counters_ok
  1592.         cmp     al,'{'
  1593.         je      rept_counters_ok
  1594.         cmp     al,1Ah
  1595.         jne     invalid_macro_arguments
  1596.       add_rept_counter:
  1597.         lods    byte [esi]
  1598.         movzx   ecx,al
  1599.         xor     eax,eax
  1600.         call    add_macro_symbol
  1601.         add     esi,ecx
  1602.         xor     eax,eax
  1603.         mov     dword [edx+12],eax
  1604.         inc     eax
  1605.         mov     dword [edx+8],eax
  1606.         lods    byte [esi]
  1607.         cmp     al,':'
  1608.         jne     rept_counter_added
  1609.         push    edx
  1610.         call    precalculate_value
  1611.         mov     edx,eax
  1612.         add     edx,[counter_limit]
  1613.         jo      value_out_of_range
  1614.         pop     edx
  1615.         mov     dword [edx+8],eax
  1616.         lods    byte [esi]
  1617.       rept_counter_added:
  1618.         cmp     al,','
  1619.         jne     rept_counters_ok
  1620.         lods    byte [esi]
  1621.         cmp     al,1Ah
  1622.         jne     invalid_macro_arguments
  1623.         jmp     add_rept_counter
  1624.       rept_counters_ok:
  1625.         dec     esi
  1626.         cmp     [counter_limit],0
  1627.         je      instant_macro_finish
  1628.       instant_macro_parameters_ok:
  1629.         xor     eax,eax
  1630.         call    process_macro
  1631.       instant_macro_finish:
  1632.         pop     [counter_limit]
  1633.         pop     [macro_symbols]
  1634.         pop     [free_additional_memory]
  1635.       instant_macro_done:
  1636.         pop     ebx esi edx
  1637.         cmp     byte [ebx],0
  1638.         je      line_preprocessed
  1639.         mov     [current_line],edi
  1640.         mov     ecx,4
  1641.         rep     movs dword [edi],[esi]
  1642.         test    [macro_status],0Fh
  1643.         jz      instant_macro_attached_line
  1644.         mov     ax,3Bh
  1645.         stos    word [edi]
  1646.       instant_macro_attached_line:
  1647.         mov     esi,ebx
  1648.         sub     edx,ebx
  1649.         mov     ecx,edx
  1650.         call    move_data
  1651.         jmp     initial_preprocessing_ok
  1652.       precalculate_value:
  1653.         push    edi
  1654.         call    convert_expression
  1655.         mov     al,')'
  1656.         stosb
  1657.         push    esi
  1658.         mov     esi,[esp+4]
  1659.         mov     [error_line],0
  1660.         mov     [value_size],0
  1661.         call    calculate_expression
  1662.         cmp     [error_line],0
  1663.         je      value_precalculated
  1664.         jmp     [error]
  1665.       value_precalculated:
  1666.         mov     eax,[edi]
  1667.         mov     ecx,[edi+4]
  1668.         cdq
  1669.         cmp     edx,ecx
  1670.         jne     value_out_of_range
  1671.         cmp     dl,[edi+13]
  1672.         jne     value_out_of_range
  1673.         pop     esi edi
  1674.         ret
  1675. do_irp:
  1676.         cmp     byte [esi],1Ah
  1677.         jne     invalid_macro_arguments
  1678.         movzx   eax,byte [esi+1]
  1679.         lea     esi,[esi+2+eax]
  1680.         lods    byte [esi]
  1681.         cmp     [base_code],1
  1682.         ja      irps_name_ok
  1683.         cmp     al,'='
  1684.         je      irp_with_default_value
  1685.         cmp     al,'*'
  1686.         jne     irp_name_ok
  1687.         lods    byte [esi]
  1688.       irp_name_ok:
  1689.         cmp     al,','
  1690.         jne     invalid_macro_arguments
  1691.         jmp     irp_parameters_start
  1692.       irp_with_default_value:
  1693.         xor     ebp,ebp
  1694.         or      [default_argument_value],-1
  1695.         call    skip_macro_argument_value
  1696.         inc     esi
  1697.         jmp     irp_parameters_start
  1698.       irps_name_ok:
  1699.         cmp     al,','
  1700.         jne     invalid_macro_arguments
  1701.         mov     al,[esi]
  1702.         or      al,al
  1703.         jz      instant_macro_done
  1704.         cmp     al,'{'
  1705.         je      instant_macro_done
  1706.       irp_parameters_start:
  1707.         xor     eax,eax
  1708.         push    [free_additional_memory]
  1709.         push    [macro_symbols]
  1710.         mov     [macro_symbols],eax
  1711.         push    [counter_limit]
  1712.         mov     [counter_limit],eax
  1713.         mov     [struc_name],eax
  1714.         mov     ebx,esi
  1715.         cmp     [base_code],1
  1716.         ja      get_irps_parameter
  1717.         mov     edx,[parameters_end]
  1718.         mov     al,[edx]
  1719.         push    eax
  1720.         mov     byte [edx],0
  1721.       get_irp_parameter:
  1722.         inc     [counter_limit]
  1723.         mov     esi,[instant_macro_start]
  1724.         inc     esi
  1725.         call    get_macro_argument
  1726.         cmp     byte [ebx],','
  1727.         jne     irp_parameters_end
  1728.         inc     ebx
  1729.         jmp     get_irp_parameter
  1730.       irp_parameters_end:
  1731.         mov     esi,ebx
  1732.         pop     eax
  1733.         mov     [esi],al
  1734.         jmp     instant_macro_parameters_ok
  1735.       get_irps_parameter:
  1736.         mov     esi,[instant_macro_start]
  1737.         inc     esi
  1738.         lods    byte [esi]
  1739.         movzx   ecx,al
  1740.         inc     [counter_limit]
  1741.         mov     eax,[counter_limit]
  1742.         call    add_macro_symbol
  1743.         mov     [edx+12],ebx
  1744.         cmp     byte [ebx],1Ah
  1745.         je      irps_symbol
  1746.         cmp     byte [ebx],22h
  1747.         je      irps_quoted_string
  1748.         mov     eax,1
  1749.         jmp     irps_parameter_ok
  1750.       irps_quoted_string:
  1751.         mov     eax,[ebx+1]
  1752.         add     eax,1+4
  1753.         jmp     irps_parameter_ok
  1754.       irps_symbol:
  1755.         movzx   eax,byte [ebx+1]
  1756.         add     eax,1+1
  1757.       irps_parameter_ok:
  1758.         mov     [edx+8],eax
  1759.         add     ebx,eax
  1760.         cmp     byte [ebx],0
  1761.         je      irps_parameters_end
  1762.         cmp     byte [ebx],'{'
  1763.         jne     get_irps_parameter
  1764.       irps_parameters_end:
  1765.         mov     esi,ebx
  1766.         jmp     instant_macro_parameters_ok
  1767. do_match:
  1768.         mov     ebx,esi
  1769.         call    skip_pattern
  1770.         call    exact_match
  1771.         mov     edx,edi
  1772.         mov     al,[ebx]
  1773.         cmp     al,1Ah
  1774.         je      free_match
  1775.         cmp     al,','
  1776.         jne     instant_macro_done
  1777.         cmp     esi,[parameters_end]
  1778.         je      matched_pattern
  1779.         jmp     instant_macro_done
  1780.       free_match:
  1781.         add     edx,12
  1782.         cmp     edx,[memory_end]
  1783.         ja      out_of_memory
  1784.         mov     [edx-12],ebx
  1785.         mov     [edx-8],esi
  1786.         call    skip_match_element
  1787.         jc      try_different_matching
  1788.         mov     [edx-4],esi
  1789.         movzx   eax,byte [ebx+1]
  1790.         lea     ebx,[ebx+2+eax]
  1791.         cmp     byte [ebx],1Ah
  1792.         je      free_match
  1793.       find_exact_match:
  1794.         call    exact_match
  1795.         cmp     esi,[parameters_end]
  1796.         je      end_matching
  1797.         cmp     byte [ebx],1Ah
  1798.         je      free_match
  1799.         mov     ebx,[edx-12]
  1800.         movzx   eax,byte [ebx+1]
  1801.         lea     ebx,[ebx+2+eax]
  1802.         mov     esi,[edx-4]
  1803.         jmp     match_more_elements
  1804.       try_different_matching:
  1805.         sub     edx,12
  1806.         cmp     edx,edi
  1807.         je      instant_macro_done
  1808.         mov     ebx,[edx-12]
  1809.         movzx   eax,byte [ebx+1]
  1810.         lea     ebx,[ebx+2+eax]
  1811.         cmp     byte [ebx],1Ah
  1812.         je      try_different_matching
  1813.         mov     esi,[edx-4]
  1814.       match_more_elements:
  1815.         call    skip_match_element
  1816.         jc      try_different_matching
  1817.         mov     [edx-4],esi
  1818.         jmp     find_exact_match
  1819.       skip_match_element:
  1820.         cmp     esi,[parameters_end]
  1821.         je      cannot_match
  1822.         mov     al,[esi]
  1823.         cmp     al,1Ah
  1824.         je      skip_match_symbol
  1825.         cmp     al,22h
  1826.         je      skip_match_quoted_string
  1827.         add     esi,1
  1828.         ret
  1829.       skip_match_quoted_string:
  1830.         mov     eax,[esi+1]
  1831.         add     esi,5
  1832.         jmp     skip_match_ok
  1833.       skip_match_symbol:
  1834.         movzx   eax,byte [esi+1]
  1835.         add     esi,2
  1836.       skip_match_ok:
  1837.         add     esi,eax
  1838.         ret
  1839.       cannot_match:
  1840.         stc
  1841.         ret
  1842.       exact_match:
  1843.         cmp     esi,[parameters_end]
  1844.         je      exact_match_complete
  1845.         mov     ah,[esi]
  1846.         mov     al,[ebx]
  1847.         cmp     al,','
  1848.         je      exact_match_complete
  1849.         cmp     al,1Ah
  1850.         je      exact_match_complete
  1851.         cmp     al,'='
  1852.         je      match_verbatim
  1853.         call    match_elements
  1854.         je      exact_match
  1855.       exact_match_complete:
  1856.         ret
  1857.       match_verbatim:
  1858.         inc     ebx
  1859.         call    match_elements
  1860.         je      exact_match
  1861.         dec     ebx
  1862.         ret
  1863.       match_elements:
  1864.         mov     al,[ebx]
  1865.         cmp     al,1Ah
  1866.         je      match_symbols
  1867.         cmp     al,22h
  1868.         je      match_quoted_strings
  1869.         cmp     al,ah
  1870.         je      symbol_characters_matched
  1871.         ret
  1872.       symbol_characters_matched:
  1873.         lea     ebx,[ebx+1]
  1874.         lea     esi,[esi+1]
  1875.         ret
  1876.       match_quoted_strings:
  1877.         mov     ecx,[ebx+1]
  1878.         add     ecx,5
  1879.         jmp     compare_elements
  1880.       match_symbols:
  1881.         movzx   ecx,byte [ebx+1]
  1882.         add     ecx,2
  1883.       compare_elements:
  1884.         mov     eax,esi
  1885.         mov     ebp,edi
  1886.         mov     edi,ebx
  1887.         repe    cmps byte [esi],[edi]
  1888.         jne     elements_mismatch
  1889.         mov     ebx,edi
  1890.         mov     edi,ebp
  1891.         ret
  1892.       elements_mismatch:
  1893.         mov     esi,eax
  1894.         mov     edi,ebp
  1895.         ret
  1896.       end_matching:
  1897.         cmp     byte [ebx],','
  1898.         jne     instant_macro_done
  1899.       matched_pattern:
  1900.         xor     eax,eax
  1901.         push    [free_additional_memory]
  1902.         push    [macro_symbols]
  1903.         mov     [macro_symbols],eax
  1904.         push    [counter_limit]
  1905.         mov     [counter_limit],eax
  1906.         mov     [struc_name],eax
  1907.         push    esi edi edx
  1908.       add_matched_symbol:
  1909.         cmp     edi,[esp]
  1910.         je      matched_symbols_ok
  1911.         mov     esi,[edi]
  1912.         inc     esi
  1913.         lods    byte [esi]
  1914.         movzx   ecx,al
  1915.         xor     eax,eax
  1916.         call    add_macro_symbol
  1917.         mov     eax,[edi+4]
  1918.         mov     dword [edx+12],eax
  1919.         mov     ecx,[edi+8]
  1920.         sub     ecx,eax
  1921.         mov     dword [edx+8],ecx
  1922.         add     edi,12
  1923.         jmp     add_matched_symbol
  1924.       matched_symbols_ok:
  1925.         pop     edx edi esi
  1926.         jmp     instant_macro_parameters_ok
  1927.  
  1928. process_macro:
  1929.         push    dword [macro_status]
  1930.         or      [macro_status],10h
  1931.         push    [counter]
  1932.         push    [macro_block]
  1933.         push    [macro_block_line]
  1934.         push    [macro_block_line_number]
  1935.         push    [struc_label]
  1936.         push    [struc_name]
  1937.         push    eax
  1938.         push    [current_line]
  1939.         lods    byte [esi]
  1940.         cmp     al,'{'
  1941.         je      macro_instructions_start
  1942.         or      al,al
  1943.         jnz     unexpected_characters
  1944.       find_macro_instructions:
  1945.         mov     [macro_line],esi
  1946.         add     esi,16+2
  1947.         lods    byte [esi]
  1948.         or      al,al
  1949.         jz      find_macro_instructions
  1950.         cmp     al,'{'
  1951.         je      macro_instructions_start
  1952.         cmp     al,3Bh
  1953.         jne     unexpected_characters
  1954.         call    skip_foreign_symbol
  1955.         jmp     find_macro_instructions
  1956.       macro_instructions_start:
  1957.         mov     ecx,80000000h
  1958.         mov     [macro_block],esi
  1959.         mov     eax,[macro_line]
  1960.         mov     [macro_block_line],eax
  1961.         mov     [macro_block_line_number],ecx
  1962.         xor     eax,eax
  1963.         mov     [counter],eax
  1964.         cmp     [counter_limit],eax
  1965.         je      process_macro_line
  1966.         inc     [counter]
  1967.       process_macro_line:
  1968.         lods    byte [esi]
  1969.         or      al,al
  1970.         jz      process_next_line
  1971.         cmp     al,'}'
  1972.         je      macro_block_processed
  1973.         dec     esi
  1974.         mov     [current_line],edi
  1975.         lea     eax,[edi+10h]
  1976.         cmp     eax,[memory_end]
  1977.         jae     out_of_memory
  1978.         mov     eax,[esp+4]
  1979.         or      eax,eax
  1980.         jz      instant_macro_line_header
  1981.         stos    dword [edi]
  1982.         mov     eax,ecx
  1983.         stos    dword [edi]
  1984.         mov     eax,[esp]
  1985.         stos    dword [edi]
  1986.         mov     eax,[macro_line]
  1987.         stos    dword [edi]
  1988.         jmp     macro_line_header_ok
  1989.       instant_macro_line_header:
  1990.         mov     eax,[macro_line]
  1991.         add     eax,16+1
  1992.         stos    dword [edi]
  1993.         mov     eax,ecx
  1994.         stos    dword [edi]
  1995.         mov     eax,[macro_line]
  1996.         stos    dword [edi]
  1997.         stos    dword [edi]
  1998.       macro_line_header_ok:
  1999.         or      [macro_status],20h
  2000.         push    ebx ecx
  2001.         test    [macro_status],0Fh
  2002.         jz      process_macro_line_element
  2003.         mov     ax,3Bh
  2004.         stos    word [edi]
  2005.       process_macro_line_element:
  2006.         lea     eax,[edi+100h]
  2007.         cmp     eax,[memory_end]
  2008.         jae     out_of_memory
  2009.         lods    byte [esi]
  2010.         cmp     al,'}'
  2011.         je      macro_line_processed
  2012.         or      al,al
  2013.         jz      macro_line_processed
  2014.         cmp     al,1Ah
  2015.         je      process_macro_symbol
  2016.         cmp     al,3Bh
  2017.         je      macro_foreign_line
  2018.         and     [macro_status],not 20h
  2019.         stos    byte [edi]
  2020.         cmp     al,22h
  2021.         jne     process_macro_line_element
  2022.       copy_macro_string:
  2023.         mov     ecx,[esi]
  2024.         add     ecx,4
  2025.         call    move_data
  2026.         jmp     process_macro_line_element
  2027.       process_macro_symbol:
  2028.         push    esi edi
  2029.         test    [macro_status],20h
  2030.         jz      not_macro_directive
  2031.         movzx   ecx,byte [esi]
  2032.         inc     esi
  2033.         mov     edi,macro_directives
  2034.         call    get_directive
  2035.         jnc     process_macro_directive
  2036.         dec     esi
  2037.         jmp     not_macro_directive
  2038.       process_macro_directive:
  2039.         mov     edx,eax
  2040.         pop     edi eax
  2041.         mov     byte [edi],0
  2042.         inc     edi
  2043.         pop     ecx ebx
  2044.         jmp     near edx
  2045.       not_macro_directive:
  2046.         and     [macro_status],not 20h
  2047.         movzx   ecx,byte [esi]
  2048.         inc     esi
  2049.         mov     eax,[counter]
  2050.         call    get_macro_symbol
  2051.         jnc     group_macro_symbol
  2052.         xor     eax,eax
  2053.         cmp     [counter],eax
  2054.         je      multiple_macro_symbol_values
  2055.         call    get_macro_symbol
  2056.         jc      not_macro_symbol
  2057.       replace_macro_symbol:
  2058.         pop     edi eax
  2059.         mov     ecx,[edx+8]
  2060.         mov     edx,[edx+12]
  2061.         or      edx,edx
  2062.         jz      replace_macro_counter
  2063.         and     ecx,not 80000000h
  2064.         xchg    esi,edx
  2065.         call    move_data
  2066.         mov     esi,edx
  2067.         jmp     process_macro_line_element
  2068.       group_macro_symbol:
  2069.         xor     eax,eax
  2070.         cmp     [counter],eax
  2071.         je      replace_macro_symbol
  2072.         push    esi edx
  2073.         sub     esi,ecx
  2074.         call    get_macro_symbol
  2075.         mov     ebx,edx
  2076.         pop     edx esi
  2077.         jc      replace_macro_symbol
  2078.         cmp     edx,ebx
  2079.         ja      replace_macro_symbol
  2080.         mov     edx,ebx
  2081.         jmp     replace_macro_symbol
  2082.       multiple_macro_symbol_values:
  2083.         inc     eax
  2084.         push    eax
  2085.         call    get_macro_symbol
  2086.         pop     eax
  2087.         jc      not_macro_symbol
  2088.         pop     edi
  2089.         push    ecx
  2090.         mov     ecx,[edx+8]
  2091.         mov     edx,[edx+12]
  2092.         xchg    esi,edx
  2093.         btr     ecx,31
  2094.         jc      enclose_macro_symbol_value
  2095.         rep     movs byte [edi],[esi]
  2096.         jmp     macro_symbol_value_ok
  2097.       enclose_macro_symbol_value:
  2098.         mov     byte [edi],'<'
  2099.         inc     edi
  2100.         rep     movs byte [edi],[esi]
  2101.         mov     byte [edi],'>'
  2102.         inc     edi
  2103.       macro_symbol_value_ok:
  2104.         cmp     eax,[counter_limit]
  2105.         je      multiple_macro_symbol_values_ok
  2106.         mov     byte [edi],','
  2107.         inc     edi
  2108.         mov     esi,edx
  2109.         pop     ecx
  2110.         push    edi
  2111.         sub     esi,ecx
  2112.         jmp     multiple_macro_symbol_values
  2113.       multiple_macro_symbol_values_ok:
  2114.         pop     ecx eax
  2115.         mov     esi,edx
  2116.         jmp     process_macro_line_element
  2117.       replace_macro_counter:
  2118.         mov     eax,[counter]
  2119.         and     eax,not 80000000h
  2120.         jz      group_macro_counter
  2121.         add     ecx,eax
  2122.         dec     ecx
  2123.         call    store_number_symbol
  2124.         jmp     process_macro_line_element
  2125.       group_macro_counter:
  2126.         mov     edx,ecx
  2127.         xor     ecx,ecx
  2128.       multiple_macro_counter_values:
  2129.         push    ecx edx
  2130.         add     ecx,edx
  2131.         call    store_number_symbol
  2132.         pop     edx ecx
  2133.         inc     ecx
  2134.         cmp     ecx,[counter_limit]
  2135.         je      process_macro_line_element
  2136.         mov     byte [edi],','
  2137.         inc     edi
  2138.         jmp     multiple_macro_counter_values
  2139.       store_number_symbol:
  2140.         cmp     ecx,0
  2141.         jge     numer_symbol_sign_ok
  2142.         neg     ecx
  2143.         mov     al,'-'
  2144.         stos    byte [edi]
  2145.       numer_symbol_sign_ok:
  2146.         mov     ax,1Ah
  2147.         stos    word [edi]
  2148.         push    edi
  2149.         mov     eax,ecx
  2150.         mov     ecx,1000000000
  2151.         xor     edx,edx
  2152.         xor     bl,bl
  2153.       store_number_digits:
  2154.         div     ecx
  2155.         push    edx
  2156.         or      bl,bl
  2157.         jnz     store_number_digit
  2158.         cmp     ecx,1
  2159.         je      store_number_digit
  2160.         or      al,al
  2161.         jz      number_digit_ok
  2162.         not     bl
  2163.       store_number_digit:
  2164.         add     al,30h
  2165.         stos    byte [edi]
  2166.       number_digit_ok:
  2167.         mov     eax,ecx
  2168.         xor     edx,edx
  2169.         mov     ecx,10
  2170.         div     ecx
  2171.         mov     ecx,eax
  2172.         pop     eax
  2173.         or      ecx,ecx
  2174.         jnz     store_number_digits
  2175.         pop     ebx
  2176.         mov     eax,edi
  2177.         sub     eax,ebx
  2178.         mov     [ebx-1],al
  2179.         ret
  2180.       not_macro_symbol:
  2181.         pop     edi esi
  2182.         mov     al,1Ah
  2183.         stos    byte [edi]
  2184.         mov     al,[esi]
  2185.         inc     esi
  2186.         stos    byte [edi]
  2187.         cmp     byte [esi],'.'
  2188.         jne     copy_raw_symbol
  2189.         mov     ebx,[esp+8+8]
  2190.         or      ebx,ebx
  2191.         jz      copy_raw_symbol
  2192.         cmp     al,1
  2193.         je      copy_struc_name
  2194.         xchg    esi,ebx
  2195.         movzx   ecx,byte [esi-1]
  2196.         add     [edi-1],cl
  2197.         jc      name_too_long
  2198.         rep     movs byte [edi],[esi]
  2199.         xchg    esi,ebx
  2200.       copy_raw_symbol:
  2201.         movzx   ecx,al
  2202.         rep     movs byte [edi],[esi]
  2203.         jmp     process_macro_line_element
  2204.       copy_struc_name:
  2205.         inc     esi
  2206.         xchg    esi,ebx
  2207.         movzx   ecx,byte [esi-1]
  2208.         mov     [edi-1],cl
  2209.         rep     movs byte [edi],[esi]
  2210.         xchg    esi,ebx
  2211.         mov     eax,[esp+8+12]
  2212.         cmp     byte [eax],3Bh
  2213.         je      process_macro_line_element
  2214.         cmp     byte [eax],1Ah
  2215.         jne     disable_replaced_struc_name
  2216.         mov     byte [eax],3Bh
  2217.         jmp     process_macro_line_element
  2218.       disable_replaced_struc_name:
  2219.         mov     ebx,[esp+8+8]
  2220.         push    esi edi
  2221.         lea     edi,[ebx-3]
  2222.         lea     esi,[edi-2]
  2223.         lea     ecx,[esi+1]
  2224.         sub     ecx,eax
  2225.         std
  2226.         rep     movs byte [edi],[esi]
  2227.         cld
  2228.         mov     word [eax],3Bh
  2229.         pop     edi esi
  2230.         jmp     process_macro_line_element
  2231.       skip_foreign_symbol:
  2232.         lods    byte [esi]
  2233.         movzx   eax,al
  2234.         add     esi,eax
  2235.       skip_foreign_line:
  2236.         lods    byte [esi]
  2237.         cmp     al,1Ah
  2238.         je      skip_foreign_symbol
  2239.         cmp     al,3Bh
  2240.         je      skip_foreign_symbol
  2241.         cmp     al,22h
  2242.         je      skip_foreign_string
  2243.         or      al,al
  2244.         jnz     skip_foreign_line
  2245.         ret
  2246.       skip_foreign_string:
  2247.         lods    dword [esi]
  2248.         add     esi,eax
  2249.         jmp     skip_foreign_line
  2250.       macro_foreign_line:
  2251.         call    skip_foreign_symbol
  2252.       macro_line_processed:
  2253.         mov     byte [edi],0
  2254.         inc     edi
  2255.         push    eax
  2256.         call    preprocess_line
  2257.         pop     eax
  2258.         pop     ecx ebx
  2259.         cmp     al,'}'
  2260.         je      macro_block_processed
  2261.       process_next_line:
  2262.         inc     ecx
  2263.         mov     [macro_line],esi
  2264.         add     esi,16+2
  2265.         jmp     process_macro_line
  2266.       macro_block_processed:
  2267.         call    close_macro_block
  2268.         jc      process_macro_line
  2269.         pop     [current_line]
  2270.         add     esp,12
  2271.         pop     [macro_block_line_number]
  2272.         pop     [macro_block_line]
  2273.         pop     [macro_block]
  2274.         pop     [counter]
  2275.         pop     eax
  2276.         and     al,0F0h
  2277.         and     [macro_status],0Fh
  2278.         or      [macro_status],al
  2279.         ret
  2280.  
  2281. local_symbols:
  2282.         lods    byte [esi]
  2283.         cmp     al,1Ah
  2284.         jne     invalid_argument
  2285.         mov     byte [edi-1],3Bh
  2286.         xor     al,al
  2287.         stos    byte [edi]
  2288.       make_local_symbol:
  2289.         push    ecx
  2290.         lods    byte [esi]
  2291.         movzx   ecx,al
  2292.         mov     eax,[counter]
  2293.         call    add_macro_symbol
  2294.         mov     [edx+12],edi
  2295.         movzx   eax,[locals_counter]
  2296.         add     eax,ecx
  2297.         inc     eax
  2298.         cmp     eax,100h
  2299.         jae     name_too_long
  2300.         lea     ebp,[edi+2+eax]
  2301.         cmp     ebp,[memory_end]
  2302.         jae     out_of_memory
  2303.         mov     ah,al
  2304.         mov     al,1Ah
  2305.         stos    word [edi]
  2306.         rep     movs byte [edi],[esi]
  2307.         mov     al,'?'
  2308.         stos    byte [edi]
  2309.         push    esi
  2310.         mov     esi,locals_counter+1
  2311.         movzx   ecx,[locals_counter]
  2312.         rep     movs byte [edi],[esi]
  2313.         pop     esi
  2314.         mov     eax,edi
  2315.         sub     eax,[edx+12]
  2316.         mov     [edx+8],eax
  2317.         xor     al,al
  2318.         stos    byte [edi]
  2319.         mov     eax,locals_counter
  2320.         movzx   ecx,byte [eax]
  2321.       counter_loop:
  2322.         inc     byte [eax+ecx]
  2323.         cmp     byte [eax+ecx],'9'+1
  2324.         jb      counter_ok
  2325.         jne     letter_digit
  2326.         mov     byte [eax+ecx],'A'
  2327.         jmp     counter_ok
  2328.       letter_digit:
  2329.         cmp     byte [eax+ecx],'Z'+1
  2330.         jb      counter_ok
  2331.         jne     small_letter_digit
  2332.         mov     byte [eax+ecx],'a'
  2333.         jmp     counter_ok
  2334.       small_letter_digit:
  2335.         cmp     byte [eax+ecx],'z'+1
  2336.         jb      counter_ok
  2337.         mov     byte [eax+ecx],'0'
  2338.         loop    counter_loop
  2339.         inc     byte [eax]
  2340.         movzx   ecx,byte [eax]
  2341.         mov     byte [eax+ecx],'0'
  2342.       counter_ok:
  2343.         pop     ecx
  2344.         lods    byte [esi]
  2345.         cmp     al,'}'
  2346.         je      macro_block_processed
  2347.         or      al,al
  2348.         jz      process_next_line
  2349.         cmp     al,','
  2350.         jne     extra_characters_on_line
  2351.         dec     edi
  2352.         lods    byte [esi]
  2353.         cmp     al,1Ah
  2354.         je      make_local_symbol
  2355.         jmp     invalid_argument
  2356. common_block:
  2357.         call    close_macro_block
  2358.         jc      process_macro_line
  2359.         mov     [counter],0
  2360.         jmp     new_macro_block
  2361. forward_block:
  2362.         cmp     [counter_limit],0
  2363.         je      common_block
  2364.         call    close_macro_block
  2365.         jc      process_macro_line
  2366.         mov     [counter],1
  2367.         jmp     new_macro_block
  2368. reverse_block:
  2369.         cmp     [counter_limit],0
  2370.         je      common_block
  2371.         call    close_macro_block
  2372.         jc      process_macro_line
  2373.         mov     eax,[counter_limit]
  2374.         or      eax,80000000h
  2375.         mov     [counter],eax
  2376.       new_macro_block:
  2377.         mov     [macro_block],esi
  2378.         mov     eax,[macro_line]
  2379.         mov     [macro_block_line],eax
  2380.         mov     [macro_block_line_number],ecx
  2381.         jmp     process_macro_line
  2382. close_macro_block:
  2383.         cmp     [counter],0
  2384.         je      block_closed
  2385.         jl      reverse_counter
  2386.         mov     eax,[counter]
  2387.         cmp     eax,[counter_limit]
  2388.         je      block_closed
  2389.         inc     [counter]
  2390.         jmp     continue_block
  2391.       reverse_counter:
  2392.         mov     eax,[counter]
  2393.         dec     eax
  2394.         cmp     eax,80000000h
  2395.         je      block_closed
  2396.         mov     [counter],eax
  2397.       continue_block:
  2398.         mov     esi,[macro_block]
  2399.         mov     eax,[macro_block_line]
  2400.         mov     [macro_line],eax
  2401.         mov     ecx,[macro_block_line_number]
  2402.         stc
  2403.         ret
  2404.       block_closed:
  2405.         clc
  2406.         ret
  2407. get_macro_symbol:
  2408.         push    ecx
  2409.         call    find_macro_symbol_leaf
  2410.         jc      macro_symbol_not_found
  2411.         mov     edx,[ebx]
  2412.         mov     ebx,esi
  2413.       try_macro_symbol:
  2414.         or      edx,edx
  2415.         jz      macro_symbol_not_found
  2416.         mov     ecx,[esp]
  2417.         mov     edi,[edx+4]
  2418.         repe    cmps byte [esi],[edi]
  2419.         je      macro_symbol_found
  2420.         mov     esi,ebx
  2421.         mov     edx,[edx]
  2422.         jmp     try_macro_symbol
  2423.       macro_symbol_found:
  2424.         pop     ecx
  2425.         clc
  2426.         ret
  2427.       macro_symbol_not_found:
  2428.         pop     ecx
  2429.         stc
  2430.         ret
  2431.       find_macro_symbol_leaf:
  2432.         shl     eax,8
  2433.         mov     al,cl
  2434.         mov     ebp,eax
  2435.         mov     ebx,macro_symbols
  2436.       follow_macro_symbols_tree:
  2437.         mov     edx,[ebx]
  2438.         or      edx,edx
  2439.         jz      no_such_macro_symbol
  2440.         xor     eax,eax
  2441.         shr     ebp,1
  2442.         adc     eax,0
  2443.         lea     ebx,[edx+eax*4]
  2444.         or      ebp,ebp
  2445.         jnz     follow_macro_symbols_tree
  2446.         add     ebx,8
  2447.         clc
  2448.         ret
  2449.       no_such_macro_symbol:
  2450.         stc
  2451.         ret
  2452. add_macro_symbol:
  2453.         push    ebx ebp
  2454.         call    find_macro_symbol_leaf
  2455.         jc      extend_macro_symbol_tree
  2456.         mov     eax,[ebx]
  2457.       make_macro_symbol:
  2458.         mov     edx,[free_additional_memory]
  2459.         add     edx,16
  2460.         cmp     edx,[labels_list]
  2461.         ja      out_of_memory
  2462.         xchg    edx,[free_additional_memory]
  2463.         mov     [ebx],edx
  2464.         mov     [edx],eax
  2465.         mov     [edx+4],esi
  2466.         pop     ebp ebx
  2467.         ret
  2468.       extend_macro_symbol_tree:
  2469.         mov     edx,[free_additional_memory]
  2470.         add     edx,16
  2471.         cmp     edx,[labels_list]
  2472.         ja      out_of_memory
  2473.         xchg    edx,[free_additional_memory]
  2474.         xor     eax,eax
  2475.         mov     [edx],eax
  2476.         mov     [edx+4],eax
  2477.         mov     [edx+8],eax
  2478.         mov     [edx+12],eax
  2479.         shr     ebp,1
  2480.         adc     eax,0
  2481.         mov     [ebx],edx
  2482.         lea     ebx,[edx+eax*4]
  2483.         or      ebp,ebp
  2484.         jnz     extend_macro_symbol_tree
  2485.         add     ebx,8
  2486.         xor     eax,eax
  2487.         jmp     make_macro_symbol
  2488.  
  2489. include_file:
  2490.         lods    byte [esi]
  2491.         cmp     al,22h
  2492.         jne     invalid_argument
  2493.         lods    dword [esi]
  2494.         cmp     byte [esi+eax],0
  2495.         jne     extra_characters_on_line
  2496.         push    esi
  2497.         push    edi
  2498.         mov     ebx,[current_line]
  2499.       find_current_file_path:
  2500.         mov     esi,[ebx]
  2501.         test    byte [ebx+7],80h
  2502.         jz      copy_current_file_path
  2503.         mov     ebx,[ebx+8]
  2504.         jmp     find_current_file_path
  2505.       copy_current_file_path:
  2506.         lods    byte [esi]
  2507.         stos    byte [edi]
  2508.         or      al,al
  2509.         jnz     copy_current_file_path
  2510.       cut_current_file_name:
  2511.         cmp     edi,[esp]
  2512.         je      current_file_path_ok
  2513.         cmp     byte [edi-1],'\'
  2514.         je      current_file_path_ok
  2515.         cmp     byte [edi-1],'/'
  2516.         je      current_file_path_ok
  2517.         dec     edi
  2518.         jmp     cut_current_file_name
  2519.       current_file_path_ok:
  2520.         mov     esi,[esp+4]
  2521.         call    expand_path
  2522.         pop     edx
  2523.         mov     esi,edx
  2524.         call    open
  2525.         jnc     include_path_ok
  2526.         mov     ebp,[include_paths]
  2527.       try_include_directories:
  2528.         mov     edi,esi
  2529.         mov     esi,ebp
  2530.         cmp     byte [esi],0
  2531.         je      try_in_current_directory
  2532.         push    ebp
  2533.         push    edi
  2534.         call    get_include_directory
  2535.         mov     [esp+4],esi
  2536.         mov     esi,[esp+8]
  2537.         call    expand_path
  2538.         pop     edx
  2539.         mov     esi,edx
  2540.         call    open
  2541.         pop     ebp
  2542.         jnc     include_path_ok
  2543.         jmp     try_include_directories
  2544.         mov     edi,esi
  2545.       try_in_current_directory:
  2546.         mov     esi,[esp]
  2547.         push    edi
  2548.         call    expand_path
  2549.         pop     edx
  2550.         mov     esi,edx
  2551.         call    open
  2552.         jc      file_not_found
  2553.       include_path_ok:
  2554.         mov     edi,[esp]
  2555.       copy_preprocessed_path:
  2556.         lods    byte [esi]
  2557.         stos    byte [edi]
  2558.         or      al,al
  2559.         jnz     copy_preprocessed_path
  2560.         pop     esi
  2561.         lea     ecx,[edi-1]
  2562.         sub     ecx,esi
  2563.         mov     [esi-4],ecx
  2564.         push    dword [macro_status]
  2565.         and     [macro_status],0Fh
  2566.         call    preprocess_file
  2567.         pop     eax
  2568.         and     al,0F0h
  2569.         and     [macro_status],0Fh
  2570.         or      [macro_status],al
  2571.         jmp     line_preprocessed
  2572.