Subversion Repositories Kolibri OS

Rev

Rev 31 | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2006, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. preprocessor:
  7.         mov     edi,characters
  8.         mov     ecx,100h
  9.         xor     al,al
  10.       make_characters_table:
  11.         stosb
  12.         inc     al
  13.         loop    make_characters_table
  14.         mov     esi,characters+'a'
  15.         mov     edi,characters+'A'
  16.         mov     ecx,26
  17.         rep     movsb
  18.         mov     edi,characters
  19.         mov     esi,symbol_characters+1
  20.         movzx   ecx,byte [esi-1]
  21.         xor     eax,eax
  22.       mark_symbol_characters:
  23.         lodsb
  24.         mov     byte [edi+eax],0
  25.         loop    mark_symbol_characters
  26.         mov     edi,locals_counter
  27.         mov     al,7
  28.         stos    byte [edi]
  29.         movzx   ecx,al
  30.         mov     al,'0'
  31.         rep     stos byte [edi]
  32.         mov     edi,[memory_start]
  33.         mov     [include_paths],edi
  34.         mov     esi,include_variable
  35.         call    get_environment_variable
  36.         xor     al,al
  37.         stosb
  38.         mov     [memory_start],edi
  39.         mov     eax,[additional_memory]
  40.         mov     [free_additional_memory],eax
  41.         mov     eax,[additional_memory_end]
  42.         mov     [labels_list],eax
  43.         xor     eax,eax
  44.         mov     [display_buffer],eax
  45.         mov     [hash_tree],eax
  46.         mov     [macro_status],al
  47.         mov     esi,[input_file]
  48.         mov     edx,esi
  49.         call    open
  50.         jc      main_file_not_found
  51.         mov     edi,[memory_start]
  52.         call    preprocess_file
  53.         mov     eax,[error_line]
  54.         mov     [current_line],eax
  55.         cmp     [macro_status],0
  56.         jne     incomplete_macro
  57.         mov     [source_start],edi
  58.         ret
  59.  
  60. preprocess_file:
  61.         push    [memory_end]
  62.         push    esi
  63.         mov     al,2
  64.         xor     edx,edx
  65.         call    lseek
  66.         push    eax
  67.         xor     al,al
  68.         xor     edx,edx
  69.         call    lseek
  70.         pop     ecx
  71.         mov     edx,[memory_end]
  72.         dec     edx
  73.         mov     byte [edx],1Ah
  74.         sub     edx,ecx
  75.         jc      out_of_memory
  76.         mov     esi,edx
  77.         cmp     edx,edi
  78.         jbe     out_of_memory
  79.         mov     [memory_end],edx
  80.         call    read
  81.         call    close
  82.         pop     edx
  83.         xor     ecx,ecx
  84.         mov     ebx,esi
  85.       preprocess_source:
  86.         inc     ecx
  87.         mov     [current_line],edi
  88.         mov     eax,edx
  89.         stos    dword [edi]
  90.         mov     eax,ecx
  91.         stos    dword [edi]
  92.         mov     eax,esi
  93.         sub     eax,ebx
  94.         stos    dword [edi]
  95.         xor     eax,eax
  96.         stos    dword [edi]
  97.         push    ebx edx
  98.         call    convert_line
  99.         call    preprocess_line
  100.         pop     edx ebx
  101.       next_line:
  102.         cmp     byte [esi-1],1Ah
  103.         jne     preprocess_source
  104.       file_end:
  105.         pop     [memory_end]
  106.         clc
  107.         ret
  108.  
  109. convert_line:
  110.         push    ecx
  111.         test    [macro_status],0Fh
  112.         jz      convert_line_data
  113.         mov     ax,3Bh
  114.         stos    word [edi]
  115.       convert_line_data:
  116.         cmp     edi,[memory_end]
  117.         jae     out_of_memory
  118.         lods    byte [esi]
  119.         cmp     al,20h
  120.         je      convert_line_data
  121.         cmp     al,9
  122.         je      convert_line_data
  123.         mov     ah,al
  124.         mov     ebx,characters
  125.         xlat    byte [ebx]
  126.         or      al,al
  127.         jz      convert_separator
  128.         cmp     ah,27h
  129.         je      convert_string
  130.         cmp     ah,22h
  131.         je      convert_string
  132.         mov     byte [edi],1Ah
  133.         scas    word [edi]
  134.         xchg    al,ah
  135.         stos    byte [edi]
  136.         mov     ebx,characters
  137.         xor     ecx,ecx
  138.       convert_symbol:
  139.         lods    byte [esi]
  140.         stos    byte [edi]
  141.         xlat    byte [ebx]
  142.         or      al,al
  143.         loopnzd convert_symbol
  144.         neg     ecx
  145.         cmp     ecx,255
  146.         ja      name_too_long
  147.         mov     ebx,edi
  148.         sub     ebx,ecx
  149.         mov     byte [ebx-2],cl
  150.       found_separator:
  151.         dec     edi
  152.         mov     ah,[esi-1]
  153.       convert_separator:
  154.         xchg    al,ah
  155.         cmp     al,20h
  156.         jb      control_character
  157.         je      convert_line_data
  158.       symbol_character:
  159.         cmp     al,3Bh
  160.         je      ignore_comment
  161.         cmp     al,5Ch
  162.         je      backslash_character
  163.         stos    byte [edi]
  164.         jmp     convert_line_data
  165.       control_character:
  166.         cmp     al,1Ah
  167.         je      line_end
  168.         cmp     al,0Dh
  169.         je      cr_character
  170.         cmp     al,0Ah
  171.         je      lf_character
  172.         cmp     al,9
  173.         je      convert_line_data
  174.         or      al,al
  175.         jnz     symbol_character
  176.         jmp     line_end
  177.       lf_character:
  178.         lods    byte [esi]
  179.         cmp     al,0Dh
  180.         je      line_end
  181.         dec     esi
  182.         jmp     line_end
  183.       cr_character:
  184.         lods    byte [esi]
  185.         cmp     al,0Ah
  186.         je      line_end
  187.         dec     esi
  188.         jmp     line_end
  189.       convert_string:
  190.         mov     al,22h
  191.         stos    byte [edi]
  192.         scas    dword [edi]
  193.         mov     ebx,edi
  194.       copy_string:
  195.         lods    byte [esi]
  196.         stos    byte [edi]
  197.         cmp     al,0Ah
  198.         je      missing_end_quote
  199.         cmp     al,0Dh
  200.         je      missing_end_quote
  201.         or      al,al
  202.         jz      missing_end_quote
  203.         cmp     al,1Ah
  204.         je      missing_end_quote
  205.         cmp     al,ah
  206.         jne     copy_string
  207.         lods    byte [esi]
  208.         cmp     al,ah
  209.         je      copy_string
  210.         dec     esi
  211.         dec     edi
  212.         mov     eax,edi
  213.         sub     eax,ebx
  214.         mov     [ebx-4],eax
  215.         jmp     convert_line_data
  216.       backslash_character:
  217.         mov     byte [edi],0
  218.         lods    byte [esi]
  219.         cmp     al,20h
  220.         je      concatenate_lines
  221.         cmp     al,9
  222.         je      concatenate_lines
  223.         cmp     al,1Ah
  224.         je      unexpected_end_of_file
  225.         cmp     al,0Ah
  226.         je      concatenate_lf
  227.         cmp     al,0Dh
  228.         je      concatenate_cr
  229.         cmp     al,3Bh
  230.         je      find_concatenated_line
  231.         mov     al,1Ah
  232.         stos    byte [edi]
  233.         mov     ecx,edi
  234.         mov     ax,5C01h
  235.         stos    word [edi]
  236.         dec     esi
  237.       group_backslashes:
  238.         lods    byte [esi]
  239.         cmp     al,5Ch
  240.         jne     backslashed_symbol
  241.         stos    byte [edi]
  242.         inc     byte [ecx]
  243.         jmp     group_backslashes
  244.       backslashed_symbol:
  245.         cmp     al,1Ah
  246.         je      unexpected_end_of_file
  247.         cmp     al,0Ah
  248.         je      extra_characters_on_line
  249.         cmp     al,0Dh
  250.         je      extra_characters_on_line
  251.         cmp     al,20h
  252.         je      extra_characters_on_line
  253.         cmp     al,9
  254.         je      extra_characters_on_line
  255.         cmp     al,22h
  256.         je      extra_characters_on_line
  257.         cmp     al,27h
  258.         je      extra_characters_on_line
  259.         cmp     al,3Bh
  260.         je      extra_characters_on_line
  261.         mov     ah,al
  262.         mov     ebx,characters
  263.         xlat    byte [ebx]
  264.         or      al,al
  265.         jz      backslashed_symbol_character
  266.         mov     al,ah
  267.       convert_backslashed_symbol:
  268.         stos    byte [edi]
  269.         xlat    byte [ebx]
  270.         or      al,al
  271.         jz      found_separator
  272.         inc     byte [ecx]
  273.         jz      name_too_long
  274.         lods    byte [esi]
  275.         jmp     convert_backslashed_symbol
  276.       backslashed_symbol_character:
  277.         mov     al,ah
  278.         stos    byte [edi]
  279.         inc     byte [ecx]
  280.         jmp     convert_line_data
  281.       concatenate_lines:
  282.         lods    byte [esi]
  283.         cmp     al,20h
  284.         je      concatenate_lines
  285.         cmp     al,9
  286.         je      concatenate_lines
  287.         cmp     al,1Ah
  288.         je      unexpected_end_of_file
  289.         cmp     al,0Ah
  290.         je      concatenate_lf
  291.         cmp     al,0Dh
  292.         je      concatenate_cr
  293.         cmp     al,3Bh
  294.         jne     extra_characters_on_line
  295.       find_concatenated_line:
  296.         lods    byte [esi]
  297.         cmp     al,0Ah
  298.         je      concatenate_lf
  299.         cmp     al,0Dh
  300.         je      concatenate_cr
  301.         or      al,al
  302.         jz      concatenate_ok
  303.         cmp     al,1Ah
  304.         jne     find_concatenated_line
  305.         jmp     unexpected_end_of_file
  306.       concatenate_lf:
  307.         lods    byte [esi]
  308.         cmp     al,0Dh
  309.         je      concatenate_ok
  310.         dec     esi
  311.         jmp     concatenate_ok
  312.       concatenate_cr:
  313.         lods    byte [esi]
  314.         cmp     al,0Ah
  315.         je      concatenate_ok
  316.         dec     esi
  317.       concatenate_ok:
  318.         inc     dword [esp]
  319.         jmp     convert_line_data
  320.       ignore_comment:
  321.         lods    byte [esi]
  322.         cmp     al,0Ah
  323.         je      lf_character
  324.         cmp     al,0Dh
  325.         je      cr_character
  326.         or      al,al
  327.         jz      line_end
  328.         cmp     al,1Ah
  329.         jne     ignore_comment
  330.       line_end:
  331.         xor     al,al
  332.         stos    byte [edi]
  333.         pop     ecx
  334.         ret
  335.  
  336. lower_case:
  337.         mov     edi,converted
  338.         mov     ebx,characters
  339.       convert_case:
  340.         lods    byte [esi]
  341.         xlat    byte [ebx]
  342.         stos    byte [edi]
  343.         loop    convert_case
  344.       case_ok:
  345.         ret
  346.  
  347. get_directive:
  348.         push    edi
  349.         mov     edx,esi
  350.         mov     ebp,ecx
  351.         call    lower_case
  352.         pop     edi
  353.       scan_directives:
  354.         mov     esi,converted
  355.         movzx   eax,byte [edi]
  356.         or      al,al
  357.         jz      no_directive
  358.         mov     ecx,ebp
  359.         inc     edi
  360.         mov     ebx,edi
  361.         add     ebx,eax
  362.         mov     ah,[esi]
  363.         cmp     ah,[edi]
  364.         jb      no_directive
  365.         ja      next_directive
  366.         cmp     cl,al
  367.         jne     next_directive
  368.         repe    cmps byte [esi],[edi]
  369.         jb      no_directive
  370.         je      directive_ok
  371.       next_directive:
  372.         mov     edi,ebx
  373.         add     edi,2
  374.         jmp     scan_directives
  375.       no_directive:
  376.         mov     esi,edx
  377.         mov     ecx,ebp
  378.         stc
  379.         ret
  380.       directive_ok:
  381.         lea     esi,[edx+ebp]
  382.         movzx   eax,word [ebx]
  383.         add     eax,preprocessor
  384.         clc
  385.         ret
  386.  
  387.  
  388. preprocess_line:
  389.         mov     eax,esp
  390.         sub     eax,100h
  391.         jc      stack_overflow
  392.         cmp     eax,[stack_limit]
  393.         jb      stack_overflow
  394.         push    ecx esi
  395.       preprocess_current_line:
  396.         mov     esi,[current_line]
  397.         add     esi,16
  398.         cmp     word [esi],3Bh
  399.         jne     line_start_ok
  400.         add     esi,2
  401.       line_start_ok:
  402.         test    [macro_status],0F0h
  403.         jnz     macro_preprocessing
  404.         cmp     byte [esi],1Ah
  405.         jne     not_fix_constant
  406.         movzx   edx,byte [esi+1]
  407.         lea     edx,[esi+2+edx]
  408.         cmp     word [edx],031Ah
  409.         jne     not_fix_constant
  410.         mov     ebx,characters
  411.         movzx   eax,byte [edx+2]
  412.         xlat    byte [ebx]
  413.         ror     eax,8
  414.         mov     al,[edx+3]
  415.         xlat    byte [ebx]
  416.         ror     eax,8
  417.         mov     al,[edx+4]
  418.         xlat    byte [ebx]
  419.         ror     eax,16
  420.         cmp     eax,'fix'
  421.         je      define_fix_constant
  422.       not_fix_constant:
  423.         call    process_fix_constants
  424.         jmp     initial_preprocessing_ok
  425.       macro_preprocessing:
  426.         call    process_macro_operators
  427.       initial_preprocessing_ok:
  428.         mov     esi,[current_line]
  429.         add     esi,16
  430.         mov     al,[macro_status]
  431.         test    al,2
  432.         jnz     skip_macro_block
  433.         test    al,1
  434.         jnz     find_macro_block
  435.       preprocess_instruction:
  436.         mov     [current_offset],esi
  437.         lods    byte [esi]
  438.         movzx   ecx,byte [esi]
  439.         inc     esi
  440.         cmp     al,1Ah
  441.         jne     not_preprocessor_symbol
  442.         cmp     cl,3
  443.         jb      not_preprocessor_directive
  444.         push    edi
  445.         mov     edi,preprocessor_directives
  446.         call    get_directive
  447.         pop     edi
  448.         jc      not_preprocessor_directive
  449.         mov     byte [edx-2],3Bh
  450.         jmp     near eax
  451.       not_preprocessor_directive:
  452.         xor     ch,ch
  453.         call    get_preprocessor_symbol
  454.         jc      not_macro
  455.         mov     byte [ebx-2],3Bh
  456.         mov     [struc_name],0
  457.         jmp     use_macro
  458.       not_macro:
  459.         mov     [struc_name],esi
  460.         add     esi,ecx
  461.         lods    byte [esi]
  462.         cmp     al,':'
  463.         je      preprocess_label
  464.         cmp     al,1Ah
  465.         jne     not_preprocessor_symbol
  466.         lods    byte [esi]
  467.         cmp     al,3
  468.         jne     not_symbolic_constant
  469.         mov     ebx,characters
  470.         movzx   eax,byte [esi]
  471.         xlat    byte [ebx]
  472.         ror     eax,8
  473.         mov     al,[esi+1]
  474.         xlat    byte [ebx]
  475.         ror     eax,8
  476.         mov     al,[esi+2]
  477.         xlat    byte [ebx]
  478.         ror     eax,16
  479.         cmp     eax,'equ'
  480.         je      define_equ_constant
  481.         mov     al,3
  482.       not_symbolic_constant:
  483.         mov     ch,1
  484.         mov     cl,al
  485.         call    get_preprocessor_symbol
  486.         jc      not_preprocessor_symbol
  487.         push    edx esi
  488.         mov     esi,[struc_name]
  489.         mov     [struc_label],esi
  490.         sub     [struc_label],2
  491.         mov     cl,[esi-1]
  492.         mov     ch,10b
  493.         call    get_preprocessor_symbol
  494.         jc      struc_name_ok
  495.         mov     ecx,[edx+12]
  496.         add     ecx,3
  497.         lea     ebx,[edi+ecx]
  498.         mov     ecx,edi
  499.         sub     ecx,[struc_label]
  500.         lea     esi,[edi-1]
  501.         lea     edi,[ebx-1]
  502.         std
  503.         rep     movs byte [edi],[esi]
  504.         cld
  505.         mov     edi,[struc_label]
  506.         mov     esi,[edx+8]
  507.         mov     ecx,[edx+12]
  508.         add     [struc_name],ecx
  509.         add     [struc_name],3
  510.         call    move_data
  511.         mov     al,3Ah
  512.         stos    byte [edi]
  513.         mov     ax,3Bh
  514.         stos    word [edi]
  515.         mov     edi,ebx
  516.         pop     esi
  517.         add     esi,[edx+12]
  518.         add     esi,3
  519.         pop     edx
  520.         jmp     use_macro
  521.       struc_name_ok:
  522.         mov     edx,[struc_name]
  523.         movzx   eax,byte [edx-1]
  524.         add     edx,eax
  525.         mov     al,3Ah
  526.         mov     [edx],al
  527.         inc     al
  528.         xchg    al,[edx+1]
  529.         dec     al
  530.         mov     [edx+2],al
  531.         pop     esi edx
  532.         jmp     use_macro
  533.       preprocess_label:
  534.         dec     esi
  535.         sub     esi,ecx
  536.         lea     ebp,[esi-2]
  537.         mov     ch,10b
  538.         call    get_preprocessor_symbol
  539.         jnc     symbolic_constant_in_label
  540.         lea     esi,[esi+ecx+1]
  541.         jmp     preprocess_instruction
  542.       symbolic_constant_in_label:
  543.         mov     ebx,[edx+8]
  544.         mov     ecx,[edx+12]
  545.         add     ecx,ebx
  546.       check_for_broken_label:
  547.         cmp     ebx,ecx
  548.         je      label_broken
  549.         cmp     byte [ebx],1Ah
  550.         jne     label_broken
  551.         movzx   eax,byte [ebx+1]
  552.         lea     ebx,[ebx+2+eax]
  553.         cmp     ebx,ecx
  554.         je      label_constant_ok
  555.         cmp     byte [ebx],':'
  556.         jne     label_broken
  557.         inc     ebx
  558.         jmp     check_for_broken_label
  559.       label_broken:
  560.         push    line_preprocessed
  561.         jmp     replace_symbolic_constant
  562.       label_constant_ok:
  563.         mov     ecx,edi
  564.         sub     ecx,esi
  565.         mov     edi,[edx+12]
  566.         add     edi,ebp
  567.         push    edi
  568.         lea     eax,[edi+ecx]
  569.         push    eax
  570.         cmp     esi,edi
  571.         je      replace_label
  572.         jb      move_rest_of_line_up
  573.         rep     movs byte [edi],[esi]
  574.         jmp     replace_label
  575.       move_rest_of_line_up:
  576.         lea     esi,[esi+ecx-1]
  577.         lea     edi,[edi+ecx-1]
  578.         std
  579.         rep     movs byte [edi],[esi]
  580.         cld
  581.       replace_label:
  582.         mov     ecx,[edx+12]
  583.         mov     edi,[esp+4]
  584.         sub     edi,ecx
  585.         mov     esi,[edx+8]
  586.         rep     movs byte [edi],[esi]
  587.         pop     edi esi
  588.         inc     esi
  589.         jmp     preprocess_instruction
  590.       not_preprocessor_symbol:
  591.         mov     esi,[current_offset]
  592.         call    process_equ_constants
  593.       line_preprocessed:
  594.         pop     esi ecx
  595.         ret
  596.  
  597. get_preprocessor_symbol:
  598.         push    ebp edi esi
  599.         mov     ebp,ecx
  600.         shl     ebp,22
  601.         movzx   ecx,cl
  602.         mov     ebx,hash_tree
  603.         mov     edi,10
  604.       follow_hashes_roots:
  605.         mov     edx,[ebx]
  606.         or      edx,edx
  607.         jz      preprocessor_symbol_not_found
  608.         xor     eax,eax
  609.         shl     ebp,1
  610.         adc     eax,0
  611.         lea     ebx,[edx+eax*4]
  612.         dec     edi
  613.         jnz     follow_hashes_roots
  614.         mov     edi,ebx
  615.         call    calculate_hash
  616.         mov     ebp,eax
  617.         and     ebp,3FFh
  618.         shl     ebp,10
  619.         xor     ebp,eax
  620.         mov     ebx,edi
  621.         mov     edi,22
  622.       follow_hashes_tree:
  623.         mov     edx,[ebx]
  624.         or      edx,edx
  625.         jz      preprocessor_symbol_not_found
  626.         xor     eax,eax
  627.         shl     ebp,1
  628.         adc     eax,0
  629.         lea     ebx,[edx+eax*4]
  630.         dec     edi
  631.         jnz     follow_hashes_tree
  632.         mov     al,cl
  633.         mov     edx,[ebx]
  634.         or      edx,edx
  635.         jz      preprocessor_symbol_not_found
  636.       compare_with_preprocessor_symbol:
  637.         mov     edi,[edx+4]
  638.         cmp     edi,1
  639.         jbe     next_equal_hash
  640.         repe    cmps byte [esi],[edi]
  641.         je      preprocessor_symbol_found
  642.         mov     cl,al
  643.         mov     esi,[esp]
  644.       next_equal_hash:
  645.         mov     edx,[edx]
  646.         or      edx,edx
  647.         jnz     compare_with_preprocessor_symbol
  648.       preprocessor_symbol_not_found:
  649.         pop     esi edi ebp
  650.         stc
  651.         ret
  652.       preprocessor_symbol_found:
  653.         pop     ebx edi ebp
  654.         clc
  655.         ret
  656.       calculate_hash:
  657.         xor     ebx,ebx
  658.         mov     eax,2166136261
  659.         mov     ebp,16777619
  660.       fnv1a_hash:
  661.         xor     al,[esi+ebx]
  662.         mul     ebp
  663.         inc     bl
  664.         cmp     bl,cl
  665.         jb      fnv1a_hash
  666.         ret
  667. add_preprocessor_symbol:
  668.         push    edi esi
  669.         call    calculate_hash
  670.         mov     ebp,eax
  671.         and     ebp,3FFh
  672.         shr     eax,10
  673.         xor     ebp,eax
  674.         shl     ecx,22
  675.         or      ebp,ecx
  676.         mov     ebx,hash_tree
  677.         mov     ecx,32
  678.       find_leave_for_symbol:
  679.         mov     edx,[ebx]
  680.         or      edx,edx
  681.         jz      extend_hashes_tree
  682.         xor     eax,eax
  683.         rol     ebp,1
  684.         adc     eax,0
  685.         lea     ebx,[edx+eax*4]
  686.         dec     ecx
  687.         jnz     find_leave_for_symbol
  688.         mov     edx,[ebx]
  689.         or      edx,edx
  690.         jz      add_symbol_entry
  691.         shr     ebp,30
  692.         cmp     ebp,11b
  693.         je      reuse_symbol_entry
  694.         cmp     dword [edx+4],0
  695.         jne     add_symbol_entry
  696.       find_entry_to_reuse:
  697.         mov     edi,[edx]
  698.         or      edi,edi
  699.         jz      reuse_symbol_entry
  700.         cmp     dword [edi+4],0
  701.         jne     reuse_symbol_entry
  702.         mov     edx,edi
  703.         jmp     find_entry_to_reuse
  704.       add_symbol_entry:
  705.         mov     eax,edx
  706.         mov     edx,[labels_list]
  707.         sub     edx,16
  708.         cmp     edx,[free_additional_memory]
  709.         jb      out_of_memory
  710.         mov     [labels_list],edx
  711.         mov     [edx],eax
  712.         mov     [ebx],edx
  713.       reuse_symbol_entry:
  714.         pop     esi edi
  715.         mov     [edx+4],esi
  716.         ret
  717.       extend_hashes_tree:
  718.         mov     edx,[labels_list]
  719.         sub     edx,8
  720.         cmp     edx,[free_additional_memory]
  721.         jb      out_of_memory
  722.         mov     [labels_list],edx
  723.         xor     eax,eax
  724.         mov     [edx],eax
  725.         mov     [edx+4],eax
  726.         shl     ebp,1
  727.         adc     eax,0
  728.         mov     [ebx],edx
  729.         lea     ebx,[edx+eax*4]
  730.         dec     ecx
  731.         jnz     extend_hashes_tree
  732.         mov     edx,[labels_list]
  733.         sub     edx,16
  734.         cmp     edx,[free_additional_memory]
  735.         jb      out_of_memory
  736.         mov     [labels_list],edx
  737.         mov     dword [edx],0
  738.         mov     [ebx],edx
  739.         pop     esi edi
  740.         mov     [edx+4],esi
  741.         ret
  742.  
  743. define_fix_constant:
  744.         add     edx,5
  745.         add     esi,2
  746.         push    edx esi
  747.         mov     esi,edx
  748.         call    skip_parameters
  749.         xchg    esi,[esp]
  750.         mov     ch,11b
  751.         jmp     define_preprocessor_constant
  752. define_equ_constant:
  753.         add     esi,3
  754.         push    esi
  755.         call    process_equ_constants
  756.         push    esi
  757.         mov     esi,[struc_name]
  758.         mov     ch,10b
  759.       define_preprocessor_constant:
  760.         mov     byte [esi-2],3Bh
  761.         mov     cl,[esi-1]
  762.         call    add_preprocessor_symbol
  763.         pop     esi ebx
  764.         mov     ecx,edi
  765.         dec     ecx
  766.         sub     ecx,ebx
  767.         mov     [edx+8],ebx
  768.         mov     [edx+12],ecx
  769.         jmp     line_preprocessed
  770. define_symbolic_constant:
  771.         lods    byte [esi]
  772.         cmp     al,1Ah
  773.         jne     invalid_name
  774.         lods    byte [esi]
  775.         mov     cl,al
  776.         mov     ch,10b
  777.         call    add_preprocessor_symbol
  778.         movzx   eax,byte [esi-1]
  779.         add     esi,eax
  780.         push    esi edx
  781.         call    skip_parameters
  782.         pop     edx ebx
  783.         lea     ecx,[esi-1]
  784.         sub     ecx,ebx
  785.         mov     [edx+8],ebx
  786.         mov     [edx+12],ecx
  787.         jmp     line_preprocessed
  788.       skip_parameters:
  789.         lods    byte [esi]
  790.         or      al,al
  791.         jz      parameters_skipped
  792.         cmp     al,'{'
  793.         je      parameters_skipped
  794.         cmp     al,22h
  795.         je      skip_quoted_parameter
  796.         cmp     al,1Ah
  797.         jne     skip_parameters
  798.         lods    byte [esi]
  799.         movzx   eax,al
  800.         add     esi,eax
  801.         jmp     skip_parameters
  802.       skip_quoted_parameter:
  803.         lods    dword [esi]
  804.         add     esi,eax
  805.         jmp     skip_parameters
  806.       parameters_skipped:
  807.         ret
  808.  
  809. define_struc:
  810.         mov     ch,1
  811.         jmp     make_macro
  812. define_macro:
  813.         xor     ch,ch
  814.       make_macro:
  815.         lods    byte [esi]
  816.         cmp     al,1Ah
  817.         jne     invalid_name
  818.         lods    byte [esi]
  819.         mov     cl,al
  820.         call    add_preprocessor_symbol
  821.         mov     eax,[current_line]
  822.         mov     [edx+12],eax
  823.         movzx   eax,byte [esi-1]
  824.         add     esi,eax
  825.         mov     [edx+8],esi
  826.         mov     al,[macro_status]
  827.         and     al,0F0h
  828.         or      al,1
  829.         mov     [macro_status],al
  830.         mov     eax,[current_line]
  831.         mov     [error_line],eax
  832.         xor     bl,bl
  833.         lods    byte [esi]
  834.         or      al,al
  835.         jz      line_preprocessed
  836.         cmp     al,'{'
  837.         je      found_macro_block
  838.         dec     esi
  839.       skip_macro_arguments:
  840.         lods    byte [esi]
  841.         cmp     al,1Ah
  842.         je      skip_macro_argument
  843.         cmp     al,'['
  844.         jne     invalid_macro_arguments
  845.         xor     bl,-1
  846.         jz      invalid_macro_arguments
  847.         lods    byte [esi]
  848.         cmp     al,1Ah
  849.         jne     invalid_macro_arguments
  850.       skip_macro_argument:
  851.         movzx   eax,byte [esi]
  852.         inc     esi
  853.         add     esi,eax
  854.         lods    byte [esi]
  855.         cmp     al,'*'
  856.         jne     macro_argument_end
  857.         lods    byte [esi]
  858.       macro_argument_end:
  859.         cmp     al,','
  860.         je      skip_macro_arguments
  861.         cmp     al,']'
  862.         jne     end_macro_arguments
  863.         lods    byte [esi]
  864.         not     bl
  865.       end_macro_arguments:
  866.         or      bl,bl
  867.         jnz     invalid_macro_arguments
  868.         or      al,al
  869.         jz      line_preprocessed
  870.         cmp     al,'{'
  871.         je      found_macro_block
  872.         jmp     invalid_macro_arguments
  873.       find_macro_block:
  874.         add     esi,2
  875.         lods    byte [esi]
  876.         or      al,al
  877.         jz      line_preprocessed
  878.         cmp     al,'{'
  879.         jne     unexpected_characters
  880.       found_macro_block:
  881.         or      [macro_status],2
  882.       skip_macro_block:
  883.         lods    byte [esi]
  884.         cmp     al,1Ah
  885.         je      skip_macro_symbol
  886.         cmp     al,3Bh
  887.         je      skip_macro_symbol
  888.         cmp     al,22h
  889.         je      skip_macro_string
  890.         or      al,al
  891.         jz      line_preprocessed
  892.         cmp     al,'}'
  893.         jne     skip_macro_block
  894.         mov     al,[macro_status]
  895.         and     [macro_status],0F0h
  896.         test    al,8
  897.         jnz     use_instant_macro
  898.         cmp     byte [esi],0
  899.         je      line_preprocessed
  900.         mov     ecx,edi
  901.         sub     ecx,esi
  902.         mov     edx,esi
  903.         lea     esi,[esi+ecx-1]
  904.         lea     edi,[edi+1+16]
  905.         mov     ebx,edi
  906.         dec     edi
  907.         std
  908.         rep     movs byte [edi],[esi]
  909.         cld
  910.         mov     edi,edx
  911.         xor     al,al
  912.         stos    byte [edi]
  913.         mov     esi,[current_line]
  914.         mov     [current_line],edi
  915.         mov     ecx,4
  916.         rep     movs dword [edi],[esi]
  917.         mov     edi,ebx
  918.         jmp     preprocess_current_line
  919.       skip_macro_symbol:
  920.         movzx   eax,byte [esi]
  921.         inc     esi
  922.         add     esi,eax
  923.         jmp     skip_macro_block
  924.       skip_macro_string:
  925.         lods    dword [esi]
  926.         add     esi,eax
  927.         jmp     skip_macro_block
  928. rept_directive:
  929.         mov     [base_code],0
  930.         jmp     define_instant_macro
  931. irp_directive:
  932.         mov     [base_code],1
  933.         jmp     define_instant_macro
  934. irps_directive:
  935.         mov     [base_code],2
  936.         jmp     define_instant_macro
  937. match_directive:
  938.         mov     [base_code],10h
  939. define_instant_macro:
  940.         mov     al,[macro_status]
  941.         and     al,0F0h
  942.         or      al,8+1
  943.         mov     [macro_status],al
  944.         mov     eax,[current_line]
  945.         mov     [error_line],eax
  946.         mov     [instant_macro_start],esi
  947.         cmp     [base_code],10h
  948.         je      prepare_match
  949.         call    skip_parameters
  950.       instant_macro_parameters_skipped:
  951.         dec     esi
  952.         mov     [parameters_end],esi
  953.         lods    byte [esi]
  954.         cmp     al,'{'
  955.         je      found_macro_block
  956.         or      al,al
  957.         jnz     invalid_macro_arguments
  958.         jmp     line_preprocessed
  959. prepare_match:
  960.         call    skip_pattern
  961.         mov     [value_type],80h+10b
  962.         call    process_symbolic_constants
  963.         jmp     instant_macro_parameters_skipped
  964.       skip_pattern:
  965.         lods    byte [esi]
  966.         or      al,al
  967.         jz      invalid_macro_arguments
  968.         cmp     al,','
  969.         je      pattern_skipped
  970.         cmp     al,22h
  971.         je      skip_quoted_string_in_pattern
  972.         cmp     al,1Ah
  973.         je      skip_symbol_in_pattern
  974.         cmp     al,'='
  975.         jne     skip_pattern
  976.         mov     al,[esi]
  977.         cmp     al,1Ah
  978.         je      skip_pattern
  979.         cmp     al,22h
  980.         je      skip_pattern
  981.         inc     esi
  982.         jmp     skip_pattern
  983.       skip_symbol_in_pattern:
  984.         lods    byte [esi]
  985.         movzx   eax,al
  986.         add     esi,eax
  987.         jmp     skip_pattern
  988.       skip_quoted_string_in_pattern:
  989.         lods    dword [esi]
  990.         add     esi,eax
  991.         jmp     skip_pattern
  992.       pattern_skipped:
  993.         ret
  994.  
  995. purge_macro:
  996.         xor     ch,ch
  997.         jmp     restore_preprocessor_symbol
  998. purge_struc:
  999.         mov     ch,1
  1000.         jmp     restore_preprocessor_symbol
  1001. restore_equ_constant:
  1002.         mov     ch,10b
  1003.       restore_preprocessor_symbol:
  1004.         push    ecx
  1005.         lods    byte [esi]
  1006.         cmp     al,1Ah
  1007.         jne     invalid_name
  1008.         lods    byte [esi]
  1009.         mov     cl,al
  1010.         call    get_preprocessor_symbol
  1011.         jc      no_symbol_to_restore
  1012.         mov     dword [edx+4],0
  1013.         jmp     symbol_restored
  1014.       no_symbol_to_restore:
  1015.         add     esi,ecx
  1016.       symbol_restored:
  1017.         pop     ecx
  1018.         lods    byte [esi]
  1019.         cmp     al,','
  1020.         je      restore_preprocessor_symbol
  1021.         or      al,al
  1022.         jnz     extra_characters_on_line
  1023.         jmp     line_preprocessed
  1024.  
  1025. process_fix_constants:
  1026.         mov     [value_type],11b
  1027.         jmp     process_symbolic_constants
  1028. process_equ_constants:
  1029.         mov     [value_type],10b
  1030.       process_symbolic_constants:
  1031.         mov     ebp,esi
  1032.         lods    byte [esi]
  1033.         cmp     al,1Ah
  1034.         je      check_symbol
  1035.         cmp     al,22h
  1036.         je      ignore_string
  1037.         cmp     al,'{'
  1038.         je      check_brace
  1039.         or      al,al
  1040.         jnz     process_symbolic_constants
  1041.         ret
  1042.       ignore_string:
  1043.         lods    dword [esi]
  1044.         add     esi,eax
  1045.         jmp     process_symbolic_constants
  1046.       check_brace:
  1047.         test    [value_type],80h
  1048.         jz      process_symbolic_constants
  1049.         ret
  1050.       no_replacing:
  1051.         movzx   ecx,byte [esi-1]
  1052.         add     esi,ecx
  1053.         jmp     process_symbolic_constants
  1054.       check_symbol:
  1055.         mov     cl,[esi]
  1056.         inc     esi
  1057.         mov     ch,[value_type]
  1058.         call    get_preprocessor_symbol
  1059.         jc      no_replacing
  1060.         mov     [current_section],edi
  1061.       replace_symbolic_constant:
  1062.         mov     ecx,[edx+12]
  1063.         mov     edx,[edx+8]
  1064.         xchg    esi,edx
  1065.         call    move_data
  1066.         mov     esi,edx
  1067.       process_after_replaced:
  1068.         lods    byte [esi]
  1069.         cmp     al,1Ah
  1070.         je      symbol_after_replaced
  1071.         stos    byte [edi]
  1072.         cmp     al,22h
  1073.         je      string_after_replaced
  1074.         cmp     al,'{'
  1075.         je      brace_after_replaced
  1076.         or      al,al
  1077.         jnz     process_after_replaced
  1078.         mov     ecx,edi
  1079.         sub     ecx,esi
  1080.         mov     edi,ebp
  1081.         call    move_data
  1082.         mov     esi,edi
  1083.         ret
  1084.       move_data:
  1085.         lea     eax,[edi+ecx]
  1086.         cmp     eax,[memory_end]
  1087.         jae     out_of_memory
  1088.         shr     ecx,1
  1089.         jnc     movsb_ok
  1090.         movs    byte [edi],[esi]
  1091.       movsb_ok:
  1092.         shr     ecx,1
  1093.         jnc     movsw_ok
  1094.         movs    word [edi],[esi]
  1095.       movsw_ok:
  1096.         rep     movs dword [edi],[esi]
  1097.         ret
  1098.       string_after_replaced:
  1099.         lods    dword [esi]
  1100.         stos    dword [edi]
  1101.         mov     ecx,eax
  1102.         call    move_data
  1103.         jmp     process_after_replaced
  1104.       brace_after_replaced:
  1105.         test    [value_type],80h
  1106.         jz      process_after_replaced
  1107.         mov     edx,edi
  1108.         mov     ecx,[current_section]
  1109.         sub     edx,ecx
  1110.         sub     ecx,esi
  1111.         rep     movs byte [edi],[esi]
  1112.         mov     ecx,edi
  1113.         sub     ecx,esi
  1114.         mov     edi,ebp
  1115.         call    move_data
  1116.         lea     esi,[ebp+edx]
  1117.         ret
  1118.       symbol_after_replaced:
  1119.         mov     cl,[esi]
  1120.         inc     esi
  1121.         mov     ch,[value_type]
  1122.         call    get_preprocessor_symbol
  1123.         jnc     replace_symbolic_constant
  1124.         movzx   ecx,byte [esi-1]
  1125.         mov     al,1Ah
  1126.         mov     ah,cl
  1127.         stos    word [edi]
  1128.         call    move_data
  1129.         jmp     process_after_replaced
  1130. process_macro_operators:
  1131.         xor     dl,dl
  1132.         mov     ebp,edi
  1133.       before_macro_operators:
  1134.         mov     edi,esi
  1135.         lods    byte [esi]
  1136.         cmp     al,'`'
  1137.         je      symbol_conversion
  1138.         cmp     al,'#'
  1139.         je      concatenation
  1140.         cmp     al,1Ah
  1141.         je      symbol_before_macro_operators
  1142.         cmp     al,3Bh
  1143.         je      no_more_macro_operators
  1144.         cmp     al,22h
  1145.         je      string_before_macro_operators
  1146.         xor     dl,dl
  1147.         or      al,al
  1148.         jnz     before_macro_operators
  1149.         mov     edi,esi
  1150.         ret
  1151.       no_more_macro_operators:
  1152.         mov     edi,ebp
  1153.         ret
  1154.       symbol_before_macro_operators:
  1155.         mov     dl,1Ah
  1156.         mov     ebx,esi
  1157.         lods    byte [esi]
  1158.         movzx   ecx,al
  1159.         jecxz   symbol_before_macro_operators_ok
  1160.         mov     edi,esi
  1161.         cmp     byte [esi],'\'
  1162.         je      escaped_symbol
  1163.       symbol_before_macro_operators_ok:
  1164.         add     esi,ecx
  1165.         jmp     before_macro_operators
  1166.       string_before_macro_operators:
  1167.         mov     dl,22h
  1168.         mov     ebx,esi
  1169.         lods    dword [esi]
  1170.         add     esi,eax
  1171.         jmp     before_macro_operators
  1172.       escaped_symbol:
  1173.         dec     byte [edi-1]
  1174.         dec     ecx
  1175.         inc     esi
  1176.         cmp     ecx,1
  1177.         rep     movs byte [edi],[esi]
  1178.         jne     after_macro_operators
  1179.         mov     al,[esi-1]
  1180.         mov     ecx,ebx
  1181.         mov     ebx,characters
  1182.         xlat    byte [ebx]
  1183.         mov     ebx,ecx
  1184.         or      al,al
  1185.         jnz     after_macro_operators
  1186.         sub     edi,3
  1187.         mov     al,[esi-1]
  1188.         stos    byte [edi]
  1189.         xor     dl,dl
  1190.         jmp     after_macro_operators
  1191.       reduce_symbol_conversion:
  1192.         inc     esi
  1193.       symbol_conversion:
  1194.         mov     edx,esi
  1195.         mov     al,[esi]
  1196.         cmp     al,1Ah
  1197.         jne     symbol_character_conversion
  1198.         lods    word [esi]
  1199.         movzx   ecx,ah
  1200.         lea     ebx,[edi+3]
  1201.         jmp     convert_to_quoted_string
  1202.       symbol_character_conversion:
  1203.         cmp     al,22h
  1204.         je      after_macro_operators
  1205.         cmp     al,'`'
  1206.         je      reduce_symbol_conversion
  1207.         lea     ebx,[edi+5]
  1208.         xor     ecx,ecx
  1209.         or      al,al
  1210.         jz      convert_to_quoted_string
  1211.         cmp     al,'#'
  1212.         je      convert_to_quoted_string
  1213.         inc     ecx
  1214.       convert_to_quoted_string:
  1215.         sub     ebx,edx
  1216.         ja      shift_line_data
  1217.         mov     al,22h
  1218.         mov     dl,al
  1219.         stos    byte [edi]
  1220.         mov     ebx,edi
  1221.         mov     eax,ecx
  1222.         stos    dword [edi]
  1223.         rep     movs byte [edi],[esi]
  1224.         cmp     edi,esi
  1225.         je      before_macro_operators
  1226.         jmp     after_macro_operators
  1227.       shift_line_data:
  1228.         push    ecx
  1229.         mov     edx,esi
  1230.         lea     esi,[ebp-1]
  1231.         add     ebp,ebx
  1232.         lea     edi,[ebp-1]
  1233.         lea     ecx,[esi+1]
  1234.         sub     ecx,edx
  1235.         std
  1236.         rep     movs byte [edi],[esi]
  1237.         cld
  1238.         pop     eax
  1239.         sub     edi,3
  1240.         mov     dl,22h
  1241.         mov     [edi-1],dl
  1242.         mov     ebx,edi
  1243.         mov     [edi],eax
  1244.         lea     esi,[edi+4+eax]
  1245.         jmp     before_macro_operators
  1246.       concatenation:
  1247.         cmp     dl,1Ah
  1248.         je      symbol_concatenation
  1249.         cmp     dl,22h
  1250.         je      string_concatenation
  1251.       no_concatenation:
  1252.         cmp     esi,edi
  1253.         je      before_macro_operators
  1254.         jmp     after_macro_operators
  1255.       symbol_concatenation:
  1256.         cmp     byte [esi],1Ah
  1257.         jne     no_concatenation
  1258.         inc     esi
  1259.         lods    byte [esi]
  1260.         movzx   ecx,al
  1261.         jecxz   do_symbol_concatenation
  1262.         cmp     byte [esi],'\'
  1263.         jne     do_symbol_concatenation
  1264.         sub     esi,2
  1265.         jmp     no_concatenation
  1266.       do_symbol_concatenation:
  1267.         add     [ebx],al
  1268.         jc      name_too_long
  1269.         rep     movs byte [edi],[esi]
  1270.         jmp     after_macro_operators
  1271.       string_concatenation:
  1272.         cmp     byte [esi],22h
  1273.         je      do_string_concatenation
  1274.         cmp     byte [esi],'`'
  1275.         jne     no_concatenation
  1276.       concatenate_converted_symbol:
  1277.         inc     esi
  1278.         mov     al,[esi]
  1279.         cmp     al,'`'
  1280.         je      concatenate_converted_symbol
  1281.         cmp     al,22h
  1282.         je      do_string_concatenation
  1283.         cmp     al,1Ah
  1284.         jne     concatenate_converted_symbol_character
  1285.         inc     esi
  1286.         lods    byte [esi]
  1287.         movzx   ecx,al
  1288.         add     [ebx],ecx
  1289.         rep     movs byte [edi],[esi]
  1290.         jmp     after_macro_operators
  1291.       concatenate_converted_symbol_character:
  1292.         or      al,al
  1293.         jz      after_macro_operators
  1294.         cmp     al,'#'
  1295.         je      after_macro_operators
  1296.         inc     dword [ebx]
  1297.         movs    byte [edi],[esi]
  1298.         jmp     after_macro_operators
  1299.       do_string_concatenation:
  1300.         inc     esi
  1301.         lods    dword [esi]
  1302.         mov     ecx,eax
  1303.         add     [ebx],eax
  1304.         rep     movs byte [edi],[esi]
  1305.       after_macro_operators:
  1306.         lods    byte [esi]
  1307.         cmp     al,'`'
  1308.         je      symbol_conversion
  1309.         cmp     al,'#'
  1310.         je      concatenation
  1311.         stos    byte [edi]
  1312.         cmp     al,1Ah
  1313.         je      symbol_after_macro_operators
  1314.         cmp     al,3Bh
  1315.         je      no_more_macro_operators
  1316.         cmp     al,22h
  1317.         je      string_after_macro_operators
  1318.         xor     dl,dl
  1319.         or      al,al
  1320.         jnz     after_macro_operators
  1321.         ret
  1322.       symbol_after_macro_operators:
  1323.         mov     dl,1Ah
  1324.         mov     ebx,edi
  1325.         lods    byte [esi]
  1326.         stos    byte [edi]
  1327.         movzx   ecx,al
  1328.         jecxz   symbol_after_macro_operatorss_ok
  1329.         cmp     byte [esi],'\'
  1330.         je      escaped_symbol
  1331.       symbol_after_macro_operatorss_ok:
  1332.         rep     movs byte [edi],[esi]
  1333.         jmp     after_macro_operators
  1334.       string_after_macro_operators:
  1335.         mov     dl,22h
  1336.         mov     ebx,edi
  1337.         lods    dword [esi]
  1338.         stos    dword [edi]
  1339.         mov     ecx,eax
  1340.         rep     movs byte [edi],[esi]
  1341.         jmp     after_macro_operators
  1342.  
  1343. use_macro:
  1344.         push    [free_additional_memory]
  1345.         push    [macro_symbols]
  1346.         mov     [macro_symbols],0
  1347.         push    [counter_limit]
  1348.         push    dword [edx+4]
  1349.         mov     dword [edx+4],1
  1350.         push    edx
  1351.         mov     ebx,esi
  1352.         mov     esi,[edx+8]
  1353.         mov     eax,[edx+12]
  1354.         mov     [macro_line],eax
  1355.         mov     [counter_limit],0
  1356.       process_macro_arguments:
  1357.         mov     al,[esi]
  1358.         or      al,al
  1359.         jz      arguments_end
  1360.         cmp     al,'{'
  1361.         je      arguments_end
  1362.         inc     esi
  1363.         cmp     al,'['
  1364.         jne     get_macro_arguments
  1365.         mov     ebp,esi
  1366.         inc     esi
  1367.         inc     [counter_limit]
  1368.       get_macro_arguments:
  1369.         call    get_macro_argument
  1370.         lods    byte [esi]
  1371.         cmp     al,','
  1372.         je      next_argument
  1373.         cmp     al,']'
  1374.         je      next_arguments_group
  1375.         dec     esi
  1376.         jmp     arguments_end
  1377.       next_argument:
  1378.         cmp     byte [ebx],','
  1379.         jne     process_macro_arguments
  1380.         inc     ebx
  1381.         jmp     process_macro_arguments
  1382.       next_arguments_group:
  1383.         cmp     byte [ebx],','
  1384.         jne     arguments_end
  1385.         inc     ebx
  1386.         inc     [counter_limit]
  1387.         mov     esi,ebp
  1388.         jmp     process_macro_arguments
  1389.       get_macro_argument:
  1390.         lods    byte [esi]
  1391.         movzx   ecx,al
  1392.         mov     eax,[counter_limit]
  1393.         call    add_macro_symbol
  1394.         add     esi,ecx
  1395.         xchg    esi,ebx
  1396.         mov     [edx+12],esi
  1397.         cmp     byte [esi],'<'
  1398.         jne     simple_argument
  1399.         inc     esi
  1400.         mov     [edx+12],esi
  1401.         mov     ecx,1
  1402.       enclosed_argument:
  1403.         lods    byte [esi]
  1404.         or      al,al
  1405.         jz      invalid_macro_arguments
  1406.         cmp     al,1Ah
  1407.         je      enclosed_symbol
  1408.         cmp     al,22h
  1409.         je      enclosed_string
  1410.         cmp     al,'>'
  1411.         je      enclosed_argument_end
  1412.         cmp     al,'<'
  1413.         jne     enclosed_argument
  1414.         inc     ecx
  1415.         jmp     enclosed_argument
  1416.       enclosed_symbol:
  1417.         movzx   eax,byte [esi]
  1418.         inc     esi
  1419.         add     esi,eax
  1420.         jmp     enclosed_argument
  1421.       enclosed_string:
  1422.         lods    dword [esi]
  1423.         add     esi,eax
  1424.         jmp     enclosed_argument
  1425.       enclosed_argument_end:
  1426.         loop    enclosed_argument
  1427.         mov     al,[esi]
  1428.         or      al,al
  1429.         jz      enclosed_argument_ok
  1430.         cmp     al,','
  1431.         jne     invalid_macro_arguments
  1432.       enclosed_argument_ok:
  1433.         mov     eax,esi
  1434.         sub     eax,[edx+12]
  1435.         dec     eax
  1436.         or      eax,80000000h
  1437.         mov     [edx+8],eax
  1438.         jmp     argument_value_ok
  1439.       simple_argument:
  1440.         lods    byte [esi]
  1441.         or      al,al
  1442.         jz      argument_value_end
  1443.         cmp     al,','
  1444.         je      argument_value_end
  1445.         cmp     al,22h
  1446.         je      argument_string
  1447.         cmp     al,1Ah
  1448.         jne     simple_argument
  1449.         movzx   eax,byte [esi]
  1450.         inc     esi
  1451.         add     esi,eax
  1452.         jmp     simple_argument
  1453.       argument_string:
  1454.         lods    dword [esi]
  1455.         add     esi,eax
  1456.         jmp     simple_argument
  1457.       argument_value_end:
  1458.         dec     esi
  1459.         mov     eax,esi
  1460.         sub     eax,[edx+12]
  1461.         mov     [edx+8],eax
  1462.       argument_value_ok:
  1463.         xchg    esi,ebx
  1464.         cmp     byte [esi],'*'
  1465.         jne     macro_argument_ok
  1466.         cmp     dword [edx+8],0
  1467.         je      invalid_macro_arguments
  1468.         inc     esi
  1469.       macro_argument_ok:
  1470.         ret
  1471.       arguments_end:
  1472.         cmp     byte [ebx],0
  1473.         jne     invalid_macro_arguments
  1474.         mov     eax,[esp+4]
  1475.         dec     eax
  1476.         call    process_macro
  1477.         pop     edx
  1478.         pop     dword [edx+4]
  1479.         pop     [counter_limit]
  1480.         pop     [macro_symbols]
  1481.         pop     [free_additional_memory]
  1482.         jmp     line_preprocessed
  1483. use_instant_macro:
  1484.         push    edi [current_line] esi
  1485.         mov     eax,[error_line]
  1486.         mov     [current_line],eax
  1487.         mov     [macro_line],eax
  1488.         mov     esi,[instant_macro_start]
  1489.         cmp     [base_code],10h
  1490.         jae     do_match
  1491.         cmp     [base_code],0
  1492.         jne     do_irp
  1493.         call    get_number
  1494.         jc      invalid_value
  1495.         or      ebp,ebp
  1496.         jnz     invalid_value
  1497.         cmp     dword [edi+4],0
  1498.         jne     value_out_of_range
  1499.         mov     eax,[edi]
  1500.         or      eax,eax
  1501.         jz      instant_macro_done
  1502.         cmp     eax,80000000h
  1503.         jae     value_out_of_range
  1504.         push    [free_additional_memory]
  1505.         push    [macro_symbols]
  1506.         mov     [macro_symbols],0
  1507.         push    [counter_limit]
  1508.         mov     [struc_name],0
  1509.         mov     [counter_limit],eax
  1510.         lods    byte [esi]
  1511.         or      al,al
  1512.         jz      rept_counters_ok
  1513.         cmp     al,'{'
  1514.         je      rept_counters_ok
  1515.         cmp     al,1Ah
  1516.         jne     invalid_macro_arguments
  1517.       add_rept_counter:
  1518.         lods    byte [esi]
  1519.         movzx   ecx,al
  1520.         xor     eax,eax
  1521.         call    add_macro_symbol
  1522.         add     esi,ecx
  1523.         xor     eax,eax
  1524.         mov     dword [edx+12],eax
  1525.         inc     eax
  1526.         mov     dword [edx+8],eax
  1527.         lods    byte [esi]
  1528.         cmp     al,':'
  1529.         jne     rept_counter_added
  1530.         push    edx
  1531.         call    get_number
  1532.         jc      invalid_value
  1533.         or      ebp,ebp
  1534.         jnz     invalid_value
  1535.         cmp     dword [edi+4],0
  1536.         jne     value_out_of_range
  1537.         mov     eax,[edi]
  1538.         mov     edx,eax
  1539.         add     edx,[counter_limit]
  1540.         jc      value_out_of_range
  1541.         pop     edx
  1542.         mov     dword [edx+8],eax
  1543.         lods    byte [esi]
  1544.       rept_counter_added:
  1545.         cmp     al,','
  1546.         jne     rept_counters_ok
  1547.         lods    byte [esi]
  1548.         cmp     al,1Ah
  1549.         jne     invalid_macro_arguments
  1550.         jmp     add_rept_counter
  1551.       rept_counters_ok:
  1552.         dec     esi
  1553.       instant_macro_parameters_ok:
  1554.         xor     eax,eax
  1555.         call    process_macro
  1556.         pop     [counter_limit]
  1557.         pop     [macro_symbols]
  1558.         pop     [free_additional_memory]
  1559.       instant_macro_done:
  1560.         pop     ebx esi edx
  1561.         cmp     byte [ebx],0
  1562.         je      line_preprocessed
  1563.         mov     [current_line],edi
  1564.         mov     ecx,4
  1565.         rep     movs dword [edi],[esi]
  1566.         test    [macro_status],0Fh
  1567.         jz      instant_macro_attached_line
  1568.         mov     ax,3Bh
  1569.         stos    word [edi]
  1570.       instant_macro_attached_line:
  1571.         mov     esi,ebx
  1572.         sub     edx,ebx
  1573.         mov     ecx,edx
  1574.         call    move_data
  1575.         jmp     preprocess_current_line
  1576. do_irp:
  1577.         cmp     byte [esi],1Ah
  1578.         jne     invalid_macro_arguments
  1579.         movzx   eax,byte [esi+1]
  1580.         lea     esi,[esi+2+eax]
  1581.         lods    byte [esi]
  1582.         cmp     [base_code],1
  1583.         ja      irps_name_ok
  1584.         cmp     al,'*'
  1585.         jne     irp_name_ok
  1586.         lods    byte [esi]
  1587.       irp_name_ok:
  1588.         cmp     al,','
  1589.         jne     invalid_macro_arguments
  1590.         jmp     irp_parameters_start
  1591.       irps_name_ok:
  1592.         cmp     al,','
  1593.         jne     invalid_macro_arguments
  1594.         mov     al,[esi]
  1595.         or      al,al
  1596.         jz      instant_macro_done
  1597.         cmp     al,'{'
  1598.         je      instant_macro_done
  1599.       irp_parameters_start:
  1600.         xor     eax,eax
  1601.         push    [free_additional_memory]
  1602.         push    [macro_symbols]
  1603.         mov     [macro_symbols],eax
  1604.         push    [counter_limit]
  1605.         mov     [counter_limit],eax
  1606.         mov     [struc_name],eax
  1607.         mov     ebx,esi
  1608.         cmp     [base_code],1
  1609.         ja      get_irps_parameter
  1610.         mov     edx,[parameters_end]
  1611.         mov     al,[edx]
  1612.         push    eax
  1613.         mov     byte [edx],0
  1614.       get_irp_parameter:
  1615.         inc     [counter_limit]
  1616.         mov     esi,[instant_macro_start]
  1617.         inc     esi
  1618.         call    get_macro_argument
  1619.         cmp     byte [ebx],','
  1620.         jne     irp_parameters_end
  1621.         inc     ebx
  1622.         jmp     get_irp_parameter
  1623.       irp_parameters_end:
  1624.         mov     esi,ebx
  1625.         pop     eax
  1626.         mov     [esi],al
  1627.         jmp     instant_macro_parameters_ok
  1628.       get_irps_parameter:
  1629.         mov     esi,[instant_macro_start]
  1630.         inc     esi
  1631.         lods    byte [esi]
  1632.         movzx   ecx,al
  1633.         inc     [counter_limit]
  1634.         mov     eax,[counter_limit]
  1635.         call    add_macro_symbol
  1636.         mov     [edx+12],ebx
  1637.         cmp     byte [ebx],1Ah
  1638.         je      irps_symbol
  1639.         cmp     byte [ebx],22h
  1640.         je      irps_quoted_string
  1641.         mov     eax,1
  1642.         jmp     irps_parameter_ok
  1643.       irps_quoted_string:
  1644.         mov     eax,[ebx+1]
  1645.         add     eax,1+4
  1646.         jmp     irps_parameter_ok
  1647.       irps_symbol:
  1648.         movzx   eax,byte [ebx+1]
  1649.         add     eax,1+1
  1650.       irps_parameter_ok:
  1651.         mov     [edx+8],eax
  1652.         add     ebx,eax
  1653.         cmp     byte [ebx],0
  1654.         je      irps_parameters_end
  1655.         cmp     byte [ebx],'{'
  1656.         jne     get_irps_parameter
  1657.       irps_parameters_end:
  1658.         mov     esi,ebx
  1659.         jmp     instant_macro_parameters_ok
  1660. do_match:
  1661.         mov     ebx,esi
  1662.         call    skip_pattern
  1663.         call    exact_match
  1664.         mov     edx,edi
  1665.         mov     al,[ebx]
  1666.         cmp     al,1Ah
  1667.         je      free_match
  1668.         cmp     al,','
  1669.         jne     instant_macro_done
  1670.         cmp     esi,[parameters_end]
  1671.         je      matched_pattern
  1672.         jmp     instant_macro_done
  1673.       free_match:
  1674.         add     edx,12
  1675.         cmp     edx,[memory_end]
  1676.         ja      out_of_memory
  1677.         mov     [edx-12],ebx
  1678.         mov     [edx-8],esi
  1679.         call    skip_match_element
  1680.         jc      try_different_matching
  1681.         mov     [edx-4],esi
  1682.         movzx   eax,byte [ebx+1]
  1683.         lea     ebx,[ebx+2+eax]
  1684.         cmp     byte [ebx],1Ah
  1685.         je      free_match
  1686.       find_exact_match:
  1687.         call    exact_match
  1688.         cmp     esi,[parameters_end]
  1689.         je      end_matching
  1690.         cmp     byte [ebx],1Ah
  1691.         je      free_match
  1692.         mov     ebx,[edx-12]
  1693.         movzx   eax,byte [ebx+1]
  1694.         lea     ebx,[ebx+2+eax]
  1695.         mov     esi,[edx-4]
  1696.         jmp     match_more_elements
  1697.       try_different_matching:
  1698.         sub     edx,12
  1699.         cmp     edx,edi
  1700.         je      instant_macro_done
  1701.         mov     ebx,[edx-12]
  1702.         movzx   eax,byte [ebx+1]
  1703.         lea     ebx,[ebx+2+eax]
  1704.         cmp     byte [ebx],1Ah
  1705.         je      try_different_matching
  1706.         mov     esi,[edx-4]
  1707.       match_more_elements:
  1708.         call    skip_match_element
  1709.         jc      try_different_matching
  1710.         mov     [edx-4],esi
  1711.         jmp     find_exact_match
  1712.       skip_match_element:
  1713.         cmp     esi,[parameters_end]
  1714.         je      cannot_match
  1715.         mov     al,[esi]
  1716.         cmp     al,1Ah
  1717.         je      skip_match_symbol
  1718.         cmp     al,22h
  1719.         je      skip_match_quoted_string
  1720.         add     esi,1
  1721.         ret
  1722.       skip_match_quoted_string:
  1723.         mov     eax,[esi+1]
  1724.         add     esi,5
  1725.         jmp     skip_match_ok
  1726.       skip_match_symbol:
  1727.         movzx   eax,byte [esi+1]
  1728.         add     esi,2
  1729.       skip_match_ok:
  1730.         add     esi,eax
  1731.         ret
  1732.       cannot_match:
  1733.         stc
  1734.         ret
  1735.       exact_match:
  1736.         cmp     esi,[parameters_end]
  1737.         je      exact_match_complete
  1738.         mov     ah,[esi]
  1739.         mov     al,[ebx]
  1740.         cmp     al,','
  1741.         je      exact_match_complete
  1742.         cmp     al,1Ah
  1743.         je      exact_match_complete
  1744.         cmp     al,'='
  1745.         je      match_verbatim
  1746.         call    match_elements
  1747.         je      exact_match
  1748.       exact_match_complete:
  1749.         ret
  1750.       match_verbatim:
  1751.         inc     ebx
  1752.         call    match_elements
  1753.         je      exact_match
  1754.         dec     ebx
  1755.         ret
  1756.       match_elements:
  1757.         mov     al,[ebx]
  1758.         cmp     al,1Ah
  1759.         je      match_symbols
  1760.         cmp     al,22h
  1761.         je      match_quoted_strings
  1762.         cmp     al,ah
  1763.         je      symbol_characters_matched
  1764.         ret
  1765.       symbol_characters_matched:
  1766.         lea     ebx,[ebx+1]
  1767.         lea     esi,[esi+1]
  1768.         ret
  1769.       match_quoted_strings:
  1770.         mov     ecx,[ebx+1]
  1771.         add     ecx,5
  1772.         jmp     compare_elements
  1773.       match_symbols:
  1774.         movzx   ecx,byte [ebx+1]
  1775.         add     ecx,2
  1776.       compare_elements:
  1777.         mov     eax,esi
  1778.         mov     ebp,edi
  1779.         mov     edi,ebx
  1780.         repe    cmps byte [esi],[edi]
  1781.         jne     elements_mismatch
  1782.         mov     ebx,edi
  1783.         mov     edi,ebp
  1784.         ret
  1785.       elements_mismatch:
  1786.         mov     esi,eax
  1787.         mov     edi,ebp
  1788.         ret
  1789.       end_matching:
  1790.         cmp     byte [ebx],','
  1791.         jne     instant_macro_done
  1792.       matched_pattern:
  1793.         xor     eax,eax
  1794.         push    [free_additional_memory]
  1795.         push    [macro_symbols]
  1796.         mov     [macro_symbols],eax
  1797.         push    [counter_limit]
  1798.         mov     [counter_limit],eax
  1799.         mov     [struc_name],eax
  1800.         push    esi edi edx
  1801.       add_matched_symbol:
  1802.         cmp     edi,[esp]
  1803.         je      matched_symbols_ok
  1804.         mov     esi,[edi]
  1805.         inc     esi
  1806.         lods    byte [esi]
  1807.         movzx   ecx,al
  1808.         xor     eax,eax
  1809.         call    add_macro_symbol
  1810.         mov     eax,[edi+4]
  1811.         mov     dword [edx+12],eax
  1812.         mov     ecx,[edi+8]
  1813.         sub     ecx,eax
  1814.         mov     dword [edx+8],ecx
  1815.         add     edi,12
  1816.         jmp     add_matched_symbol
  1817.       matched_symbols_ok:
  1818.         pop     edx edi esi
  1819.         jmp     instant_macro_parameters_ok
  1820.  
  1821. process_macro:
  1822.         push    dword [macro_status]
  1823.         or      [macro_status],10h
  1824.         push    [counter]
  1825.         push    [macro_block]
  1826.         push    [macro_block_line]
  1827.         push    [macro_block_line_number]
  1828.         push    [struc_label]
  1829.         push    [struc_name]
  1830.         push    eax
  1831.         push    [current_line]
  1832.         lods    byte [esi]
  1833.         cmp     al,'{'
  1834.         je      macro_instructions_start
  1835.         or      al,al
  1836.         jnz     unexpected_characters
  1837.       find_macro_instructions:
  1838.         mov     [macro_line],esi
  1839.         add     esi,16+2
  1840.         lods    byte [esi]
  1841.         or      al,al
  1842.         jz      find_macro_instructions
  1843.         cmp     al,'{'
  1844.         je      macro_instructions_start
  1845.         cmp     al,3Bh
  1846.         jne     unexpected_characters
  1847.         call    skip_foreign_symbol
  1848.         jmp     find_macro_instructions
  1849.       macro_instructions_start:
  1850.         mov     ecx,80000000h
  1851.         mov     [macro_block],esi
  1852.         mov     eax,[macro_line]
  1853.         mov     [macro_block_line],eax
  1854.         mov     [macro_block_line_number],ecx
  1855.         xor     eax,eax
  1856.         mov     [counter],eax
  1857.         cmp     [counter_limit],eax
  1858.         je      process_macro_line
  1859.         inc     [counter]
  1860.       process_macro_line:
  1861.         mov     [current_line],edi
  1862.         lea     eax,[edi+10h]
  1863.         cmp     eax,[memory_end]
  1864.         jae     out_of_memory
  1865.         mov     eax,[esp+4]
  1866.         or      eax,eax
  1867.         jz      instant_macro_line_header
  1868.         stos    dword [edi]
  1869.         mov     eax,ecx
  1870.         stos    dword [edi]
  1871.         mov     eax,[esp]
  1872.         stos    dword [edi]
  1873.         mov     eax,[macro_line]
  1874.         stos    dword [edi]
  1875.         jmp     macro_line_header_ok
  1876.       instant_macro_line_header:
  1877.         mov     edx,[macro_line]
  1878.         mov     eax,[edx]
  1879.         stos    dword [edi]
  1880.         mov     eax,[edx+4]
  1881.         stos    dword [edi]
  1882.         mov     eax,[edx+8]
  1883.         stos    dword [edi]
  1884.         mov     eax,[edx+12]
  1885.         stos    dword [edi]
  1886.       macro_line_header_ok:
  1887.         or      [macro_status],20h
  1888.         push    ebx ecx
  1889.         test    [macro_status],0Fh
  1890.         jz      process_macro_line_element
  1891.         mov     ax,3Bh
  1892.         stos    word [edi]
  1893.       process_macro_line_element:
  1894.         lea     eax,[edi+100h]
  1895.         cmp     eax,[memory_end]
  1896.         jae     out_of_memory
  1897.         lods    byte [esi]
  1898.         cmp     al,'}'
  1899.         je      macro_line_processed
  1900.         or      al,al
  1901.         jz      macro_line_processed
  1902.         cmp     al,1Ah
  1903.         je      process_macro_symbol
  1904.         cmp     al,3Bh
  1905.         je      macro_foreign_line
  1906.         and     [macro_status],not 20h
  1907.         stos    byte [edi]
  1908.         cmp     al,22h
  1909.         jne     process_macro_line_element
  1910.       copy_macro_string:
  1911.         mov     ecx,[esi]
  1912.         add     ecx,4
  1913.         call    move_data
  1914.         jmp     process_macro_line_element
  1915.       process_macro_symbol:
  1916.         push    esi edi
  1917.         test    [macro_status],20h
  1918.         jz      not_macro_directive
  1919.         movzx   ecx,byte [esi]
  1920.         inc     esi
  1921.         mov     edi,macro_directives
  1922.         call    get_directive
  1923.         jnc     process_macro_directive
  1924.         dec     esi
  1925.         jmp     not_macro_directive
  1926.       process_macro_directive:
  1927.         mov     edx,eax
  1928.         pop     edi eax
  1929.         mov     byte [edi],0
  1930.         inc     edi
  1931.         pop     ecx ebx
  1932.         jmp     near edx
  1933.       not_macro_directive:
  1934.         and     [macro_status],not 20h
  1935.         movzx   ecx,byte [esi]
  1936.         inc     esi
  1937.         mov     eax,[counter]
  1938.         call    get_macro_symbol
  1939.         jnc     group_macro_symbol
  1940.         xor     eax,eax
  1941.         cmp     [counter],eax
  1942.         je      multiple_macro_symbol_values
  1943.         call    get_macro_symbol
  1944.         jc      not_macro_symbol
  1945.       replace_macro_symbol:
  1946.         pop     edi eax
  1947.         mov     ecx,[edx+8]
  1948.         and     ecx,not 80000000h
  1949.         mov     edx,[edx+12]
  1950.         or      edx,edx
  1951.         jz      replace_macro_counter
  1952.         xchg    esi,edx
  1953.         call    move_data
  1954.         mov     esi,edx
  1955.         jmp     process_macro_line_element
  1956.       group_macro_symbol:
  1957.         xor     eax,eax
  1958.         cmp     [counter],eax
  1959.         je      replace_macro_symbol
  1960.         push    esi edx
  1961.         sub     esi,ecx
  1962.         call    get_macro_symbol
  1963.         mov     ebx,edx
  1964.         pop     edx esi
  1965.         jc      replace_macro_symbol
  1966.         cmp     edx,ebx
  1967.         ja      replace_macro_symbol
  1968.         mov     edx,ebx
  1969.         jmp     replace_macro_symbol
  1970.       multiple_macro_symbol_values:
  1971.         inc     eax
  1972.         push    eax
  1973.         call    get_macro_symbol
  1974.         pop     eax
  1975.         jc      not_macro_symbol
  1976.         pop     edi
  1977.         push    ecx
  1978.         mov     ecx,[edx+8]
  1979.         mov     edx,[edx+12]
  1980.         xchg    esi,edx
  1981.         btr     ecx,31
  1982.         jc      enclose_macro_symbol_value
  1983.         rep     movs byte [edi],[esi]
  1984.         jmp     macro_symbol_value_ok
  1985.       enclose_macro_symbol_value:
  1986.         mov     byte [edi],'<'
  1987.         inc     edi
  1988.         rep     movs byte [edi],[esi]
  1989.         mov     byte [edi],'>'
  1990.         inc     edi
  1991.       macro_symbol_value_ok:
  1992.         cmp     eax,[counter_limit]
  1993.         je      multiple_macro_symbol_values_ok
  1994.         mov     byte [edi],','
  1995.         inc     edi
  1996.         mov     esi,edx
  1997.         pop     ecx
  1998.         push    edi
  1999.         sub     esi,ecx
  2000.         jmp     multiple_macro_symbol_values
  2001.       multiple_macro_symbol_values_ok:
  2002.         pop     ecx eax
  2003.         mov     esi,edx
  2004.         jmp     process_macro_line_element
  2005.       replace_macro_counter:
  2006.         mov     eax,[counter]
  2007.         and     eax,not 80000000h
  2008.         jz      group_macro_counter
  2009.         add     ecx,eax
  2010.         dec     ecx
  2011.         call    store_number_symbol
  2012.         jmp     process_macro_line_element
  2013.       group_macro_counter:
  2014.         mov     edx,ecx
  2015.         xor     ecx,ecx
  2016.       multiple_macro_counter_values:
  2017.         push    ecx edx
  2018.         add     ecx,edx
  2019.         call    store_number_symbol
  2020.         pop     edx ecx
  2021.         inc     ecx
  2022.         cmp     ecx,[counter_limit]
  2023.         je      process_macro_line_element
  2024.         mov     byte [edi],','
  2025.         inc     edi
  2026.         jmp     multiple_macro_counter_values
  2027.       store_number_symbol:
  2028.         mov     ax,1Ah
  2029.         stos    word [edi]
  2030.         push    edi
  2031.         mov     eax,ecx
  2032.         mov     ecx,1000000000
  2033.         xor     edx,edx
  2034.         xor     bl,bl
  2035.       store_number_digits:
  2036.         div     ecx
  2037.         push    edx
  2038.         or      bl,bl
  2039.         jnz     store_number_digit
  2040.         cmp     ecx,1
  2041.         je      store_number_digit
  2042.         or      al,al
  2043.         jz      number_digit_ok
  2044.         not     bl
  2045.       store_number_digit:
  2046.         add     al,30h
  2047.         stos    byte [edi]
  2048.       number_digit_ok:
  2049.         mov     eax,ecx
  2050.         xor     edx,edx
  2051.         mov     ecx,10
  2052.         div     ecx
  2053.         mov     ecx,eax
  2054.         pop     eax
  2055.         or      ecx,ecx
  2056.         jnz     store_number_digits
  2057.         pop     ebx
  2058.         mov     eax,edi
  2059.         sub     eax,ebx
  2060.         mov     [ebx-1],al
  2061.         ret
  2062.       not_macro_symbol:
  2063.         pop     edi esi
  2064.         mov     al,1Ah
  2065.         stos    byte [edi]
  2066.         mov     al,[esi]
  2067.         inc     esi
  2068.         stos    byte [edi]
  2069.         cmp     byte [esi],'.'
  2070.         jne     copy_raw_symbol
  2071.         mov     ebx,[esp+8+8]
  2072.         or      ebx,ebx
  2073.         jz      copy_raw_symbol
  2074.         cmp     al,1
  2075.         je      copy_struc_name
  2076.         xchg    esi,ebx
  2077.         movzx   ecx,byte [esi-1]
  2078.         add     [edi-1],cl
  2079.         jc      name_too_long
  2080.         rep     movs byte [edi],[esi]
  2081.         xchg    esi,ebx
  2082.       copy_raw_symbol:
  2083.         movzx   ecx,al
  2084.         rep     movs byte [edi],[esi]
  2085.         jmp     process_macro_line_element
  2086.       copy_struc_name:
  2087.         inc     esi
  2088.         xchg    esi,ebx
  2089.         movzx   ecx,byte [esi-1]
  2090.         mov     [edi-1],cl
  2091.         rep     movs byte [edi],[esi]
  2092.         xchg    esi,ebx
  2093.         mov     eax,[esp+8+12]
  2094.         cmp     byte [eax],3Bh
  2095.         je      process_macro_line_element
  2096.         cmp     byte [eax],1Ah
  2097.         jne     disable_replaced_struc_name
  2098.         mov     byte [eax],3Bh
  2099.         jmp     process_macro_line_element
  2100.       disable_replaced_struc_name:
  2101.         mov     ebx,[esp+8+8]
  2102.         push    esi edi
  2103.         lea     edi,[ebx-3]
  2104.         lea     esi,[edi-2]
  2105.         lea     ecx,[esi+1]
  2106.         sub     ecx,eax
  2107.         std
  2108.         rep     movs byte [edi],[esi]
  2109.         cld
  2110.         mov     word [eax],3Bh
  2111.         pop     edi esi
  2112.         jmp     process_macro_line_element
  2113.       skip_foreign_symbol:
  2114.         lods    byte [esi]
  2115.         movzx   eax,al
  2116.         add     esi,eax
  2117.       skip_foreign_line:
  2118.         lods    byte [esi]
  2119.         cmp     al,1Ah
  2120.         je      skip_foreign_symbol
  2121.         cmp     al,3Bh
  2122.         je      skip_foreign_symbol
  2123.         cmp     al,22h
  2124.         je      skip_foreign_string
  2125.         or      al,al
  2126.         jnz     skip_foreign_line
  2127.         ret
  2128.       skip_foreign_string:
  2129.         lods    dword [esi]
  2130.         add     esi,eax
  2131.         jmp     skip_foreign_line
  2132.       macro_foreign_line:
  2133.         call    skip_foreign_symbol
  2134.       macro_line_processed:
  2135.         mov     byte [edi],0
  2136.         inc     edi
  2137.         push    eax
  2138.         call    preprocess_line
  2139.         pop     eax
  2140.         pop     ecx ebx
  2141.         cmp     al,'}'
  2142.         je      macro_block_processed
  2143.       process_next_line:
  2144.         inc     ecx
  2145.         mov     [macro_line],esi
  2146.         add     esi,16+2
  2147.         jmp     process_macro_line
  2148.       macro_block_processed:
  2149.         call    close_macro_block
  2150.         jc      process_macro_line
  2151.         pop     [current_line]
  2152.         add     esp,12
  2153.         pop     [macro_block_line_number]
  2154.         pop     [macro_block_line]
  2155.         pop     [macro_block]
  2156.         pop     [counter]
  2157.         pop     eax
  2158.         and     al,0F0h
  2159.         and     [macro_status],0Fh
  2160.         or      [macro_status],al
  2161.         ret
  2162.  
  2163. local_symbols:
  2164.         lods    byte [esi]
  2165.         cmp     al,1Ah
  2166.         jne     invalid_argument
  2167.         mov     byte [edi-1],3Bh
  2168.         xor     al,al
  2169.         stos    byte [edi]
  2170.       make_local_symbol:
  2171.         push    ecx
  2172.         lods    byte [esi]
  2173.         movzx   ecx,al
  2174.         mov     eax,[counter]
  2175.         call    add_macro_symbol
  2176.         mov     [edx+12],edi
  2177.         movzx   eax,[locals_counter]
  2178.         add     eax,ecx
  2179.         inc     eax
  2180.         cmp     eax,100h
  2181.         jae     name_too_long
  2182.         lea     ebp,[edi+2+eax]
  2183.         cmp     ebp,[memory_end]
  2184.         jae     out_of_memory
  2185.         mov     ah,al
  2186.         mov     al,1Ah
  2187.         stos    word [edi]
  2188.         rep     movs byte [edi],[esi]
  2189.         mov     al,'?'
  2190.         stos    byte [edi]
  2191.         push    esi
  2192.         mov     esi,locals_counter+1
  2193.         movzx   ecx,[locals_counter]
  2194.         rep     movs byte [edi],[esi]
  2195.         pop     esi
  2196.         mov     eax,edi
  2197.         sub     eax,[edx+12]
  2198.         mov     [edx+8],eax
  2199.         xor     al,al
  2200.         stos    byte [edi]
  2201.         mov     eax,locals_counter
  2202.         movzx   ecx,byte [eax]
  2203.       counter_loop:
  2204.         inc     byte [eax+ecx]
  2205.         cmp     byte [eax+ecx],':'
  2206.         jb      counter_ok
  2207.         jne     letter_digit
  2208.         mov     byte [eax+ecx],'A'
  2209.         jmp     counter_ok
  2210.       letter_digit:
  2211.         cmp     byte [eax+ecx],'F'
  2212.         jbe     counter_ok
  2213.         mov     byte [eax+ecx],'0'
  2214.         loop    counter_loop
  2215.       counter_ok:
  2216.         pop     ecx
  2217.         lods    byte [esi]
  2218.         cmp     al,'}'
  2219.         je      macro_block_processed
  2220.         or      al,al
  2221.         jz      process_next_line
  2222.         cmp     al,','
  2223.         jne     extra_characters_on_line
  2224.         dec     edi
  2225.         lods    byte [esi]
  2226.         cmp     al,1Ah
  2227.         je      make_local_symbol
  2228.         jmp     invalid_argument
  2229. common_block:
  2230.         call    close_macro_block
  2231.         jc      process_macro_line
  2232.         mov     [counter],0
  2233.         jmp     new_macro_block
  2234. forward_block:
  2235.         cmp     [counter_limit],0
  2236.         je      common_block
  2237.         call    close_macro_block
  2238.         jc      process_macro_line
  2239.         mov     [counter],1
  2240.         jmp     new_macro_block
  2241. reverse_block:
  2242.         cmp     [counter_limit],0
  2243.         je      common_block
  2244.         call    close_macro_block
  2245.         jc      process_macro_line
  2246.         mov     eax,[counter_limit]
  2247.         or      eax,80000000h
  2248.         mov     [counter],eax
  2249.       new_macro_block:
  2250.         mov     [macro_block],esi
  2251.         mov     eax,[macro_line]
  2252.         mov     [macro_block_line],eax
  2253.         mov     [macro_block_line_number],ecx
  2254.         jmp     process_macro_line
  2255. close_macro_block:
  2256.         cmp     [counter],0
  2257.         je      block_closed
  2258.         jl      reverse_counter
  2259.         mov     eax,[counter]
  2260.         cmp     eax,[counter_limit]
  2261.         je      block_closed
  2262.         inc     [counter]
  2263.         jmp     continue_block
  2264.       reverse_counter:
  2265.         mov     eax,[counter]
  2266.         dec     eax
  2267.         cmp     eax,80000000h
  2268.         je      block_closed
  2269.         mov     [counter],eax
  2270.       continue_block:
  2271.         mov     esi,[macro_block]
  2272.         mov     eax,[macro_block_line]
  2273.         mov     [macro_line],eax
  2274.         mov     ecx,[macro_block_line_number]
  2275.         stc
  2276.         ret
  2277.       block_closed:
  2278.         clc
  2279.         ret
  2280. get_macro_symbol:
  2281.         push    ecx
  2282.         call    find_macro_symbol_leaf
  2283.         jc      macro_symbol_not_found
  2284.         mov     edx,[ebx]
  2285.         mov     ebx,esi
  2286.       try_macro_symbol:
  2287.         or      edx,edx
  2288.         jz      macro_symbol_not_found
  2289.         mov     ecx,[esp]
  2290.         mov     edi,[edx+4]
  2291.         repe    cmps byte [esi],[edi]
  2292.         je      macro_symbol_found
  2293.         mov     esi,ebx
  2294.         mov     edx,[edx]
  2295.         jmp     try_macro_symbol
  2296.       macro_symbol_found:
  2297.         pop     ecx
  2298.         clc
  2299.         ret
  2300.       macro_symbol_not_found:
  2301.         pop     ecx
  2302.         stc
  2303.         ret
  2304.       find_macro_symbol_leaf:
  2305.         shl     eax,8
  2306.         mov     al,cl
  2307.         mov     ebp,eax
  2308.         mov     ebx,macro_symbols
  2309.       follow_macro_symbols_tree:
  2310.         mov     edx,[ebx]
  2311.         or      edx,edx
  2312.         jz      no_such_macro_symbol
  2313.         xor     eax,eax
  2314.         shr     ebp,1
  2315.         adc     eax,0
  2316.         lea     ebx,[edx+eax*4]
  2317.         or      ebp,ebp
  2318.         jnz     follow_macro_symbols_tree
  2319.         add     ebx,8
  2320.         clc
  2321.         ret
  2322.       no_such_macro_symbol:
  2323.         stc
  2324.         ret
  2325. add_macro_symbol:
  2326.         push    ebx ebp
  2327.         call    find_macro_symbol_leaf
  2328.         jc      extend_macro_symbol_tree
  2329.         mov     eax,[ebx]
  2330.       make_macro_symbol:
  2331.         mov     edx,[free_additional_memory]
  2332.         add     edx,16
  2333.         cmp     edx,[labels_list]
  2334.         ja      out_of_memory
  2335.         xchg    edx,[free_additional_memory]
  2336.         mov     [ebx],edx
  2337.         mov     [edx],eax
  2338.         mov     [edx+4],esi
  2339.         pop     ebp ebx
  2340.         ret
  2341.       extend_macro_symbol_tree:
  2342.         mov     edx,[free_additional_memory]
  2343.         add     edx,16
  2344.         cmp     edx,[labels_list]
  2345.         ja      out_of_memory
  2346.         xchg    edx,[free_additional_memory]
  2347.         xor     eax,eax
  2348.         mov     [edx],eax
  2349.         mov     [edx+4],eax
  2350.         mov     [edx+8],eax
  2351.         mov     [edx+12],eax
  2352.         shr     ebp,1
  2353.         adc     eax,0
  2354.         mov     [ebx],edx
  2355.         lea     ebx,[edx+eax*4]
  2356.         or      ebp,ebp
  2357.         jnz     extend_macro_symbol_tree
  2358.         add     ebx,8
  2359.         xor     eax,eax
  2360.         jmp     make_macro_symbol
  2361.  
  2362. include_file:
  2363.         lods    byte [esi]
  2364.         cmp     al,22h
  2365.         jne     invalid_argument
  2366.         lods    dword [esi]
  2367.         cmp     byte [esi+eax],0
  2368.         jne     extra_characters_on_line
  2369.         push    esi
  2370.         push    edi
  2371.         mov     ebx,[current_line]
  2372.       find_current_file_path:
  2373.         mov     esi,[ebx]
  2374.         test    byte [ebx+7],80h
  2375.         jz      copy_current_file_path
  2376.         mov     ebx,[ebx+8]
  2377.         jmp     find_current_file_path
  2378.       copy_current_file_path:
  2379.         lods    byte [esi]
  2380.         stos    byte [edi]
  2381.         or      al,al
  2382.         jnz     copy_current_file_path
  2383.       cut_current_file_name:
  2384.         cmp     edi,[esp]
  2385.         je      current_file_path_ok
  2386.         cmp     byte [edi-1],'\'
  2387.         je      current_file_path_ok
  2388.         cmp     byte [edi-1],'/'
  2389.         je      current_file_path_ok
  2390.         dec     edi
  2391.         jmp     cut_current_file_name
  2392.       current_file_path_ok:
  2393.         mov     esi,[esp+4]
  2394.         call    preprocess_path
  2395.         pop     edx
  2396.         mov     esi,edx
  2397.         call    open
  2398.         jnc     include_path_ok
  2399.         mov     ebp,[include_paths]
  2400.       try_include_directories:
  2401.         mov     edi,esi
  2402.         mov     esi,ebp
  2403.         cmp     byte [esi],0
  2404.         je      try_in_current_directory
  2405.         push    ebp
  2406.         push    edi
  2407.       copy_include_directory:
  2408.         lods    byte [esi]
  2409.         cmp     al,';'
  2410.         je      include_directory_ok
  2411.         stos    byte [edi]
  2412.         or      al,al
  2413.         jnz     copy_include_directory
  2414.         dec     esi
  2415.         dec     edi
  2416.       include_directory_ok:
  2417.         cmp     byte [edi-1],'/'
  2418.         je      path_separator_ok
  2419.         cmp     byte [edi-1],'\'
  2420.         je      path_separator_ok
  2421.         mov     al,'/'
  2422.         stos    byte [edi]
  2423.       path_separator_ok:
  2424.         mov     [esp+4],esi
  2425.         mov     esi,[esp+8]
  2426.         call    preprocess_path
  2427.         pop     edx
  2428.         mov     esi,edx
  2429.         call    open
  2430.         pop     ebp
  2431.         jnc     include_path_ok
  2432.         jmp     try_include_directories
  2433.         mov     edi,esi
  2434.       try_in_current_directory:
  2435.         mov     esi,[esp]
  2436.         push    edi
  2437.         call    preprocess_path
  2438.         pop     edx
  2439.         mov     esi,edx
  2440.         call    open
  2441.         jc      file_not_found
  2442.       include_path_ok:
  2443.         mov     edi,[esp]
  2444.       copy_preprocessed_path:
  2445.         lods    byte [esi]
  2446.         stos    byte [edi]
  2447.         or      al,al
  2448.         jnz     copy_preprocessed_path
  2449.         pop     esi
  2450.         lea     ecx,[edi-1]
  2451.         sub     ecx,esi
  2452.         mov     [esi-4],ecx
  2453.         push    dword [macro_status]
  2454.         and     [macro_status],0Fh
  2455.         call    preprocess_file
  2456.         pop     eax
  2457.         mov     [macro_status],al
  2458.         jmp     line_preprocessed
  2459.       preprocess_path:
  2460.         lods    byte [esi]
  2461.         cmp     al,'%'
  2462.         je      environment_variable
  2463.         stos    byte [edi]
  2464.         or      al,al
  2465.         jnz     preprocess_path
  2466.         cmp     edi,[memory_end]
  2467.         ja      out_of_memory
  2468.         ret
  2469.       environment_variable:
  2470.         mov     ebx,esi
  2471.       find_variable_end:
  2472.         lods    byte [esi]
  2473.         or      al,al
  2474.         jz      not_environment_variable
  2475.         cmp     al,'%'
  2476.         jne     find_variable_end
  2477.         mov     byte [esi-1],0
  2478.         push    esi
  2479.         mov     esi,ebx
  2480.         call    get_environment_variable
  2481.         pop     esi
  2482.         mov     byte [esi-1],'%'
  2483.         jmp     preprocess_path
  2484.       not_environment_variable:
  2485.         mov     al,'%'
  2486.         stos    byte [edi]
  2487.         mov     esi,ebx
  2488.         jmp     preprocess_path
  2489.