Subversion Repositories Kolibri OS

Rev

Rev 4478 | Go to most recent revision | Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2016, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. convert_expression:
  7.         push    ebp
  8.         call    get_fp_value
  9.         jnc     fp_expression
  10.         mov     [current_offset],esp
  11.       expression_loop:
  12.         push    edi
  13.         mov     edi,single_operand_operators
  14.         call    get_operator
  15.         pop     edi
  16.         or      al,al
  17.         jz      expression_element
  18.         cmp     al,82h
  19.         je      expression_loop
  20.         push    eax
  21.         jmp     expression_loop
  22.       expression_element:
  23.         mov     al,[esi]
  24.         cmp     al,1Ah
  25.         je      expression_number
  26.         cmp     al,22h
  27.         je      expression_number
  28.         cmp     al,'('
  29.         je      expression_number
  30.         mov     al,'!'
  31.         stos    byte [edi]
  32.         jmp     expression_operator
  33.       expression_number:
  34.         call    convert_number
  35.       expression_operator:
  36.         push    edi
  37.         mov     edi,operators
  38.         call    get_operator
  39.         pop     edi
  40.         or      al,al
  41.         jz      expression_end
  42.       operators_loop:
  43.         cmp     esp,[current_offset]
  44.         je      push_operator
  45.         mov     bl,al
  46.         and     bl,0F0h
  47.         mov     bh,byte [esp]
  48.         and     bh,0F0h
  49.         cmp     bl,bh
  50.         ja      push_operator
  51.         pop     ebx
  52.         mov     byte [edi],bl
  53.         inc     edi
  54.         jmp     operators_loop
  55.       push_operator:
  56.         push    eax
  57.         jmp     expression_loop
  58.       expression_end:
  59.         cmp     esp,[current_offset]
  60.         je      expression_converted
  61.         pop     eax
  62.         stos    byte [edi]
  63.         jmp     expression_end
  64.       expression_converted:
  65.         pop     ebp
  66.         ret
  67.       fp_expression:
  68.         mov     al,'.'
  69.         stos    byte [edi]
  70.         mov     eax,[fp_value]
  71.         stos    dword [edi]
  72.         mov     eax,[fp_value+4]
  73.         stos    dword [edi]
  74.         mov     eax,[fp_value+8]
  75.         stos    dword [edi]
  76.         pop     ebp
  77.         ret
  78.  
  79. convert_number:
  80.         lea     eax,[edi+20h]
  81.         mov     edx,[memory_end]
  82.         cmp     [source_start],0
  83.         je      check_memory_for_number
  84.         mov     edx,[labels_list]
  85.       check_memory_for_number:
  86.         cmp     eax,edx
  87.         jae     out_of_memory
  88.         mov     eax,esp
  89.         sub     eax,100h
  90.         jc      stack_overflow
  91.         cmp     eax,[stack_limit]
  92.         jb      stack_overflow
  93.         cmp     byte [esi],'('
  94.         je      expression_value
  95.         inc     edi
  96.         call    get_number
  97.         jc      symbol_value
  98.         or      ebp,ebp
  99.         jz      valid_number
  100.         mov     byte [edi-1],0Fh
  101.         ret
  102.       valid_number:
  103.         cmp     dword [edi+4],0
  104.         jne     qword_number
  105.         cmp     word [edi+2],0
  106.         jne     dword_number
  107.         cmp     byte [edi+1],0
  108.         jne     word_number
  109.       byte_number:
  110.         mov     byte [edi-1],1
  111.         inc     edi
  112.         ret
  113.       qword_number:
  114.         mov     byte [edi-1],8
  115.         add     edi,8
  116.         ret
  117.       dword_number:
  118.         mov     byte [edi-1],4
  119.         scas    dword [edi]
  120.         ret
  121.       word_number:
  122.         mov     byte [edi-1],2
  123.         scas    word [edi]
  124.         ret
  125.       expression_value:
  126.         inc     esi
  127.         push    [current_offset]
  128.         call    convert_expression
  129.         pop     [current_offset]
  130.         lods    byte [esi]
  131.         cmp     al,')'
  132.         je      subexpression_closed
  133.         dec     esi
  134.         mov     al,'!'
  135.         stosb
  136.       subexpression_closed:
  137.         ret
  138.       symbol_value:
  139.         cmp     [source_start],0
  140.         je      preprocessor_value
  141.         push    edi esi
  142.         lods    word [esi]
  143.         cmp     al,1Ah
  144.         jne     no_address_register
  145.         movzx   ecx,ah
  146.         call    get_symbol
  147.         jc      no_address_register
  148.         cmp     al,10h
  149.         jne     no_address_register
  150.         mov     al,ah
  151.         shr     ah,4
  152.         cmp     ah,4
  153.         je      register_value
  154.         and     ah,not 1
  155.         cmp     ah,8
  156.         je      register_value
  157.         cmp     ah,0Ch
  158.         jae     register_value
  159.         cmp     ah,6
  160.         je      register_value
  161.         cmp     al,23h
  162.         je      register_value
  163.         cmp     al,25h
  164.         je      register_value
  165.         cmp     al,26h
  166.         je      register_value
  167.         cmp     al,27h
  168.         je      register_value
  169.       no_address_register:
  170.         pop     esi
  171.         mov     edi,directive_operators
  172.         call    get_operator
  173.         pop     edi
  174.         or      al,al
  175.         jnz     broken_value
  176.         lods    byte [esi]
  177.         cmp     al,1Ah
  178.         jne     invalid_value
  179.         lods    byte [esi]
  180.         movzx   ecx,al
  181.         call    get_label_id
  182.       store_label_value:
  183.         mov     byte [edi-1],11h
  184.         stos    dword [edi]
  185.         ret
  186.       broken_value:
  187.         mov     eax,0Fh
  188.         jmp     store_label_value
  189.       register_value:
  190.         pop     edx edi
  191.         mov     byte [edi-1],10h
  192.         stos    byte [edi]
  193.         ret
  194.       preprocessor_value:
  195.         dec     edi
  196.         cmp     [hash_tree],0
  197.         je      invalid_value
  198.         lods    byte [esi]
  199.         cmp     al,1Ah
  200.         jne     invalid_value
  201.         lods    byte [esi]
  202.         mov     cl,al
  203.         mov     ch,10b
  204.         call    get_preprocessor_symbol
  205.         jc      invalid_value
  206.         push    esi
  207.         mov     esi,[edx+8]
  208.         push    [current_offset]
  209.         call    convert_expression
  210.         pop     [current_offset]
  211.         pop     esi
  212.         ret
  213.  
  214. get_number:
  215.         xor     ebp,ebp
  216.         lods    byte [esi]
  217.         cmp     al,22h
  218.         je      get_text_number
  219.         cmp     al,1Ah
  220.         jne     not_number
  221.         lods    byte [esi]
  222.         movzx   ecx,al
  223.         mov     [number_start],esi
  224.         mov     al,[esi]
  225.         cmp     al,'$'
  226.         je      number_begin
  227.         sub     al,30h
  228.         cmp     al,9
  229.         ja      invalid_number
  230.       number_begin:
  231.         mov     ebx,esi
  232.         add     esi,ecx
  233.         push    esi
  234.         dec     esi
  235.         mov     dword [edi],0
  236.         mov     dword [edi+4],0
  237.         cmp     byte [ebx],'$'
  238.         je      pascal_hex_number
  239.         cmp     word [ebx],'0x'
  240.         je      get_hex_number
  241.         mov     al,[esi]
  242.         dec     esi
  243.         cmp     al,'h'
  244.         je      get_hex_number
  245.         cmp     al,'b'
  246.         je      get_bin_number
  247.         cmp     al,'d'
  248.         je      get_dec_number
  249.         cmp     al,'o'
  250.         je      get_oct_number
  251.         cmp     al,'H'
  252.         je      get_hex_number
  253.         cmp     al,'B'
  254.         je      get_bin_number
  255.         cmp     al,'D'
  256.         je      get_dec_number
  257.         cmp     al,'O'
  258.         je      get_oct_number
  259.         inc     esi
  260.       get_dec_number:
  261.         mov     ebx,esi
  262.         mov     esi,[number_start]
  263.       get_dec_digit:
  264.         cmp     esi,ebx
  265.         ja      number_ok
  266.         cmp     byte [esi],27h
  267.         je      next_dec_digit
  268.         xor     edx,edx
  269.         mov     eax,[edi]
  270.         shld    edx,eax,2
  271.         shl     eax,2
  272.         add     eax,[edi]
  273.         adc     edx,0
  274.         add     eax,eax
  275.         adc     edx,edx
  276.         mov     [edi],eax
  277.         mov     eax,[edi+4]
  278.         add     eax,eax
  279.         jc      dec_out_of_range
  280.         add     eax,eax
  281.         jc      dec_out_of_range
  282.         add     eax,[edi+4]
  283.         jc      dec_out_of_range
  284.         add     eax,eax
  285.         jc      dec_out_of_range
  286.         add     eax,edx
  287.         jc      dec_out_of_range
  288.         mov     [edi+4],eax
  289.         movzx   eax,byte [esi]
  290.         sub     al,30h
  291.         jc      bad_number
  292.         cmp     al,9
  293.         ja      bad_number
  294.         add     [edi],eax
  295.         adc     dword [edi+4],0
  296.         jc      dec_out_of_range
  297.       next_dec_digit:
  298.         inc     esi
  299.         jmp     get_dec_digit
  300.       dec_out_of_range:
  301.         cmp     esi,ebx
  302.         ja      dec_out_of_range_finished
  303.         lods    byte [esi]
  304.         cmp     al,27h
  305.         je      bad_number
  306.         sub     al,30h
  307.         jc      bad_number
  308.         cmp     al,9
  309.         ja      bad_number
  310.         jmp     dec_out_of_range
  311.       dec_out_of_range_finished:
  312.         or      ebp,-1
  313.         jmp     number_ok
  314.       bad_number:
  315.         pop     eax
  316.       invalid_number:
  317.         mov     esi,[number_start]
  318.         dec     esi
  319.       not_number:
  320.         dec     esi
  321.         stc
  322.         ret
  323.       get_bin_number:
  324.         xor     bl,bl
  325.       get_bin_digit:
  326.         cmp     esi,[number_start]
  327.         jb      number_ok
  328.         movzx   eax,byte [esi]
  329.         cmp     al,27h
  330.         je      bin_digit_skip
  331.         sub     al,30h
  332.         cmp     al,1
  333.         ja      bad_number
  334.         xor     edx,edx
  335.         mov     cl,bl
  336.         dec     esi
  337.         cmp     bl,64
  338.         je      bin_out_of_range
  339.         inc     bl
  340.         cmp     cl,32
  341.         jae     bin_digit_high
  342.         shl     eax,cl
  343.         or      dword [edi],eax
  344.         jmp     get_bin_digit
  345.       bin_digit_high:
  346.         sub     cl,32
  347.         shl     eax,cl
  348.         or      dword [edi+4],eax
  349.         jmp     get_bin_digit
  350.       bin_out_of_range:
  351.         or      al,al
  352.         jz      get_bin_digit
  353.         or      ebp,-1
  354.         jmp     get_bin_digit
  355.       bin_digit_skip:
  356.         dec     esi
  357.         jmp     get_bin_digit
  358.       pascal_hex_number:
  359.         cmp     cl,1
  360.         je      bad_number
  361.       get_hex_number:
  362.         xor     bl,bl
  363.       get_hex_digit:
  364.         cmp     esi,[number_start]
  365.         jb      number_ok
  366.         movzx   eax,byte [esi]
  367.         cmp     al,27h
  368.         je      hex_digit_skip
  369.         cmp     al,'x'
  370.         je      hex_number_ok
  371.         cmp     al,'$'
  372.         je      pascal_hex_ok
  373.         sub     al,30h
  374.         cmp     al,9
  375.         jbe     hex_digit_ok
  376.         sub     al,7
  377.         cmp     al,15
  378.         jbe     hex_letter_digit_ok
  379.         sub     al,20h
  380.         cmp     al,15
  381.         ja      bad_number
  382.       hex_letter_digit_ok:
  383.         cmp     al,10
  384.         jb      bad_number
  385.       hex_digit_ok:
  386.         xor     edx,edx
  387.         mov     cl,bl
  388.         dec     esi
  389.         cmp     bl,64
  390.         je      hex_out_of_range
  391.         add     bl,4
  392.         cmp     cl,32
  393.         jae     hex_digit_high
  394.         shl     eax,cl
  395.         or      dword [edi],eax
  396.         jmp     get_hex_digit
  397.       hex_digit_high:
  398.         sub     cl,32
  399.         shl     eax,cl
  400.         or      dword [edi+4],eax
  401.         jmp     get_hex_digit
  402.       hex_out_of_range:
  403.         or      al,al
  404.         jz      get_hex_digit
  405.         or      ebp,-1
  406.         jmp     get_hex_digit
  407.       hex_digit_skip:
  408.         dec     esi
  409.         jmp     get_hex_digit
  410.       get_oct_number:
  411.         xor     bl,bl
  412.       get_oct_digit:
  413.         cmp     esi,[number_start]
  414.         jb      number_ok
  415.         movzx   eax,byte [esi]
  416.         cmp     al,27h
  417.         je      oct_digit_skip
  418.         sub     al,30h
  419.         cmp     al,7
  420.         ja      bad_number
  421.       oct_digit_ok:
  422.         xor     edx,edx
  423.         mov     cl,bl
  424.         dec     esi
  425.         cmp     bl,63
  426.         ja      oct_out_of_range
  427.         jne     oct_range_ok
  428.         cmp     al,1
  429.         ja      oct_out_of_range
  430.       oct_range_ok:
  431.         add     bl,3
  432.         cmp     cl,30
  433.         je      oct_digit_wrap
  434.         ja      oct_digit_high
  435.         shl     eax,cl
  436.         or      dword [edi],eax
  437.         jmp     get_oct_digit
  438.       oct_digit_wrap:
  439.         shl     eax,cl
  440.         adc     dword [edi+4],0
  441.         or      dword [edi],eax
  442.         jmp     get_oct_digit
  443.       oct_digit_high:
  444.         sub     cl,32
  445.         shl     eax,cl
  446.         or      dword [edi+4],eax
  447.         jmp     get_oct_digit
  448.       oct_digit_skip:
  449.         dec     esi
  450.         jmp     get_oct_digit
  451.       oct_out_of_range:
  452.         or      al,al
  453.         jz      get_oct_digit
  454.         or      ebp,-1
  455.         jmp     get_oct_digit
  456.       hex_number_ok:
  457.         dec     esi
  458.       pascal_hex_ok:
  459.         cmp     esi,[number_start]
  460.         jne     bad_number
  461.       number_ok:
  462.         pop     esi
  463.       number_done:
  464.         clc
  465.         ret
  466.       get_text_number:
  467.         lods    dword [esi]
  468.         mov     edx,eax
  469.         xor     bl,bl
  470.         mov     dword [edi],0
  471.         mov     dword [edi+4],0
  472.       get_text_character:
  473.         sub     edx,1
  474.         jc      number_done
  475.         movzx   eax,byte [esi]
  476.         inc     esi
  477.         mov     cl,bl
  478.         cmp     bl,64
  479.         je      text_out_of_range
  480.         add     bl,8
  481.         cmp     cl,32
  482.         jae     text_character_high
  483.         shl     eax,cl
  484.         or      dword [edi],eax
  485.         jmp     get_text_character
  486.       text_character_high:
  487.         sub     cl,32
  488.         shl     eax,cl
  489.         or      dword [edi+4],eax
  490.         jmp     get_text_character
  491.       text_out_of_range:
  492.         or      ebp,-1
  493.         jmp     get_text_character
  494.  
  495. get_fp_value:
  496.         push    edi esi
  497.         lods    byte [esi]
  498.         cmp     al,1Ah
  499.         je      fp_value_start
  500.         cmp     al,'-'
  501.         je      fp_sign_ok
  502.         cmp     al,'+'
  503.         jne     not_fp_value
  504.       fp_sign_ok:
  505.         lods    byte [esi]
  506.         cmp     al,1Ah
  507.         jne     not_fp_value
  508.       fp_value_start:
  509.         lods    byte [esi]
  510.         movzx   ecx,al
  511.         cmp     cl,1
  512.         jbe     not_fp_value
  513.         lea     edx,[esi+1]
  514.         xor     ah,ah
  515.       check_fp_value:
  516.         lods    byte [esi]
  517.         cmp     al,'.'
  518.         je      fp_character_dot
  519.         cmp     al,'E'
  520.         je      fp_character_exp
  521.         cmp     al,'e'
  522.         je      fp_character_exp
  523.         cmp     al,'F'
  524.         je      fp_last_character
  525.         cmp     al,'f'
  526.         je      fp_last_character
  527.       digit_expected:
  528.         cmp     al,'0'
  529.         jb      not_fp_value
  530.         cmp     al,'9'
  531.         ja      not_fp_value
  532.         jmp     fp_character_ok
  533.       fp_character_dot:
  534.         cmp     esi,edx
  535.         je      not_fp_value
  536.         or      ah,ah
  537.         jnz     not_fp_value
  538.         or      ah,1
  539.         lods    byte [esi]
  540.         loop    digit_expected
  541.       not_fp_value:
  542.         pop     esi edi
  543.         stc
  544.         ret
  545.       fp_last_character:
  546.         cmp     cl,1
  547.         jne     not_fp_value
  548.         or      ah,4
  549.         jmp     fp_character_ok
  550.       fp_character_exp:
  551.         cmp     esi,edx
  552.         je      not_fp_value
  553.         cmp     ah,1
  554.         ja      not_fp_value
  555.         or      ah,2
  556.         cmp     ecx,1
  557.         jne     fp_character_ok
  558.         cmp     byte [esi],'+'
  559.         je      fp_exp_sign
  560.         cmp     byte [esi],'-'
  561.         jne     fp_character_ok
  562.       fp_exp_sign:
  563.         inc     esi
  564.         cmp     byte [esi],1Ah
  565.         jne     not_fp_value
  566.         inc     esi
  567.         lods    byte [esi]
  568.         movzx   ecx,al
  569.         inc     ecx
  570.       fp_character_ok:
  571.         dec     ecx
  572.         jnz     check_fp_value
  573.         or      ah,ah
  574.         jz      not_fp_value
  575.         pop     esi
  576.         lods    byte [esi]
  577.         mov     [fp_sign],0
  578.         cmp     al,1Ah
  579.         je      fp_get
  580.         inc     esi
  581.         cmp     al,'+'
  582.         je      fp_get
  583.         mov     [fp_sign],1
  584.       fp_get:
  585.         lods    byte [esi]
  586.         movzx   ecx,al
  587.         xor     edx,edx
  588.         mov     edi,fp_value
  589.         mov     [edi],edx
  590.         mov     [edi+4],edx
  591.         mov     [edi+12],edx
  592.         call    fp_optimize
  593.         mov     [fp_format],0
  594.         mov     al,[esi]
  595.       fp_before_dot:
  596.         lods    byte [esi]
  597.         cmp     al,'.'
  598.         je      fp_dot
  599.         cmp     al,'E'
  600.         je      fp_exponent
  601.         cmp     al,'e'
  602.         je      fp_exponent
  603.         cmp     al,'F'
  604.         je      fp_done
  605.         cmp     al,'f'
  606.         je      fp_done
  607.         sub     al,30h
  608.         mov     edi,fp_value+16
  609.         xor     edx,edx
  610.         mov     dword [edi+12],edx
  611.         mov     dword [edi],edx
  612.         mov     dword [edi+4],edx
  613.         mov     [edi+7],al
  614.         mov     dl,7
  615.         mov     dword [edi+8],edx
  616.         call    fp_optimize
  617.         mov     edi,fp_value
  618.         push    ecx
  619.         mov     ecx,10
  620.         call    fp_mul
  621.         pop     ecx
  622.         mov     ebx,fp_value+16
  623.         call    fp_add
  624.         loop    fp_before_dot
  625.       fp_dot:
  626.         mov     edi,fp_value+16
  627.         xor     edx,edx
  628.         mov     [edi],edx
  629.         mov     [edi+4],edx
  630.         mov     byte [edi+7],80h
  631.         mov     [edi+8],edx
  632.         mov     dword [edi+12],edx
  633.         dec     ecx
  634.         jz      fp_done
  635.       fp_after_dot:
  636.         lods    byte [esi]
  637.         cmp     al,'E'
  638.         je      fp_exponent
  639.         cmp     al,'e'
  640.         je      fp_exponent
  641.         cmp     al,'F'
  642.         je      fp_done
  643.         cmp     al,'f'
  644.         je      fp_done
  645.         inc     [fp_format]
  646.         cmp     [fp_format],80h
  647.         jne     fp_counter_ok
  648.         mov     [fp_format],7Fh
  649.       fp_counter_ok:
  650.         dec     esi
  651.         mov     edi,fp_value+16
  652.         push    ecx
  653.         mov     ecx,10
  654.         call    fp_div
  655.         push    dword [edi]
  656.         push    dword [edi+4]
  657.         push    dword [edi+8]
  658.         push    dword [edi+12]
  659.         lods    byte [esi]
  660.         sub     al,30h
  661.         movzx   ecx,al
  662.         call    fp_mul
  663.         mov     ebx,edi
  664.         mov     edi,fp_value
  665.         call    fp_add
  666.         mov     edi,fp_value+16
  667.         pop     dword [edi+12]
  668.         pop     dword [edi+8]
  669.         pop     dword [edi+4]
  670.         pop     dword [edi]
  671.         pop     ecx
  672.         dec     ecx
  673.         jnz     fp_after_dot
  674.         jmp     fp_done
  675.       fp_exponent:
  676.         or      [fp_format],80h
  677.         xor     edx,edx
  678.         xor     ebp,ebp
  679.         dec     ecx
  680.         jnz     get_exponent
  681.         cmp     byte [esi],'+'
  682.         je      fp_exponent_sign
  683.         cmp     byte [esi],'-'
  684.         jne     fp_done
  685.         not     ebp
  686.       fp_exponent_sign:
  687.         add     esi,2
  688.         lods    byte [esi]
  689.         movzx   ecx,al
  690.       get_exponent:
  691.         movzx   eax,byte [esi]
  692.         inc     esi
  693.         sub     al,30h
  694.         cmp     al,10
  695.         jae     exponent_ok
  696.         imul    edx,10
  697.         cmp     edx,8000h
  698.         jae     value_out_of_range
  699.         add     edx,eax
  700.         loop    get_exponent
  701.       exponent_ok:
  702.         mov     edi,fp_value
  703.         or      edx,edx
  704.         jz      fp_done
  705.         mov     ecx,edx
  706.         or      ebp,ebp
  707.         jnz     fp_negative_power
  708.       fp_power:
  709.         push    ecx
  710.         mov     ecx,10
  711.         call    fp_mul
  712.         pop     ecx
  713.         loop    fp_power
  714.         jmp     fp_done
  715.       fp_negative_power:
  716.         push    ecx
  717.         mov     ecx,10
  718.         call    fp_div
  719.         pop     ecx
  720.         loop    fp_negative_power
  721.       fp_done:
  722.         mov     edi,fp_value
  723.         mov     al,[fp_format]
  724.         mov     [edi+10],al
  725.         mov     al,[fp_sign]
  726.         mov     [edi+11],al
  727.         test    byte [edi+15],80h
  728.         jz      fp_ok
  729.         add     dword [edi],1
  730.         adc     dword [edi+4],0
  731.         jnc     fp_ok
  732.         mov     eax,[edi+4]
  733.         shrd    [edi],eax,1
  734.         shr     eax,1
  735.         or      eax,80000000h
  736.         mov     [edi+4],eax
  737.         inc     word [edi+8]
  738.       fp_ok:
  739.         pop     edi
  740.         clc
  741.         ret
  742.       fp_mul:
  743.         or      ecx,ecx
  744.         jz      fp_zero
  745.         mov     eax,[edi+12]
  746.         mul     ecx
  747.         mov     [edi+12],eax
  748.         mov     ebx,edx
  749.         mov     eax,[edi]
  750.         mul     ecx
  751.         add     eax,ebx
  752.         adc     edx,0
  753.         mov     [edi],eax
  754.         mov     ebx,edx
  755.         mov     eax,[edi+4]
  756.         mul     ecx
  757.         add     eax,ebx
  758.         adc     edx,0
  759.         mov     [edi+4],eax
  760.       .loop:
  761.         or      edx,edx
  762.         jz      .done
  763.         mov     eax,[edi]
  764.         shrd    [edi+12],eax,1
  765.         mov     eax,[edi+4]
  766.         shrd    [edi],eax,1
  767.         shrd    eax,edx,1
  768.         mov     [edi+4],eax
  769.         shr     edx,1
  770.         inc     dword [edi+8]
  771.         cmp     dword [edi+8],8000h
  772.         jge     value_out_of_range
  773.         jmp     .loop
  774.       .done:
  775.         ret
  776.       fp_div:
  777.         mov     eax,[edi+4]
  778.         xor     edx,edx
  779.         div     ecx
  780.         mov     [edi+4],eax
  781.         mov     eax,[edi]
  782.         div     ecx
  783.         mov     [edi],eax
  784.         mov     eax,[edi+12]
  785.         div     ecx
  786.         mov     [edi+12],eax
  787.         mov     ebx,eax
  788.         or      ebx,[edi]
  789.         or      ebx,[edi+4]
  790.         jz      fp_zero
  791.       .loop:
  792.         test    byte [edi+7],80h
  793.         jnz     .exp_ok
  794.         mov     eax,[edi]
  795.         shld    [edi+4],eax,1
  796.         mov     eax,[edi+12]
  797.         shld    [edi],eax,1
  798.         add     eax,eax
  799.         mov     [edi+12],eax
  800.         dec     dword [edi+8]
  801.         add     edx,edx
  802.         jmp     .loop
  803.       .exp_ok:
  804.         mov     eax,edx
  805.         xor     edx,edx
  806.         div     ecx
  807.         add     [edi+12],eax
  808.         adc     dword [edi],0
  809.         adc     dword [edi+4],0
  810.         jnc     .done
  811.         mov     eax,[edi+4]
  812.         mov     ebx,[edi]
  813.         shrd    [edi],eax,1
  814.         shrd    [edi+12],ebx,1
  815.         shr     eax,1
  816.         or      eax,80000000h
  817.         mov     [edi+4],eax
  818.         inc     dword [edi+8]
  819.       .done:
  820.         ret
  821.       fp_add:
  822.         cmp     dword [ebx+8],8000h
  823.         je      .done
  824.         cmp     dword [edi+8],8000h
  825.         je      .copy
  826.         mov     eax,[ebx+8]
  827.         cmp     eax,[edi+8]
  828.         jge     .exp_ok
  829.         mov     eax,[edi+8]
  830.       .exp_ok:
  831.         call    .change_exp
  832.         xchg    ebx,edi
  833.         call    .change_exp
  834.         xchg    ebx,edi
  835.         mov     edx,[ebx+12]
  836.         mov     eax,[ebx]
  837.         mov     ebx,[ebx+4]
  838.         add     [edi+12],edx
  839.         adc     [edi],eax
  840.         adc     [edi+4],ebx
  841.         jnc     .done
  842.         mov     eax,[edi]
  843.         shrd    [edi+12],eax,1
  844.         mov     eax,[edi+4]
  845.         shrd    [edi],eax,1
  846.         shr     eax,1
  847.         or      eax,80000000h
  848.         mov     [edi+4],eax
  849.         inc     dword [edi+8]
  850.       .done:
  851.         ret
  852.       .copy:
  853.         mov     eax,[ebx]
  854.         mov     [edi],eax
  855.         mov     eax,[ebx+4]
  856.         mov     [edi+4],eax
  857.         mov     eax,[ebx+8]
  858.         mov     [edi+8],eax
  859.         mov     eax,[ebx+12]
  860.         mov     [edi+12],eax
  861.         ret
  862.       .change_exp:
  863.         push    ecx
  864.         mov     ecx,eax
  865.         sub     ecx,[ebx+8]
  866.         mov     edx,[ebx+4]
  867.         jecxz   .exp_done
  868.       .exp_loop:
  869.         mov     ebp,[ebx]
  870.         shrd    [ebx+12],ebp,1
  871.         shrd    [ebx],edx,1
  872.         shr     edx,1
  873.         inc     dword [ebx+8]
  874.         loop    .exp_loop
  875.       .exp_done:
  876.         mov     [ebx+4],edx
  877.         pop     ecx
  878.         ret
  879.       fp_optimize:
  880.         mov     eax,[edi]
  881.         mov     ebp,[edi+4]
  882.         or      ebp,[edi]
  883.         or      ebp,[edi+12]
  884.         jz      fp_zero
  885.       .loop:
  886.         test    byte [edi+7],80h
  887.         jnz     .done
  888.         shld    [edi+4],eax,1
  889.         mov     ebp,[edi+12]
  890.         shld    eax,ebp,1
  891.         mov     [edi],eax
  892.         shl     dword [edi+12],1
  893.         dec     dword [edi+8]
  894.         jmp     .loop
  895.       .done:
  896.         ret
  897.       fp_zero:
  898.         mov     dword [edi+8],8000h
  899.         ret
  900.  
  901. preevaluate_logical_expression:
  902.         xor     al,al
  903.   preevaluate_embedded_logical_expression:
  904.         mov     [logical_value_wrapping],al
  905.         push    edi
  906.         call    preevaluate_logical_value
  907.       preevaluation_loop:
  908.         cmp     al,0FFh
  909.         je      invalid_logical_expression
  910.         mov     dl,[esi]
  911.         inc     esi
  912.         cmp     dl,'|'
  913.         je      preevaluate_or
  914.         cmp     dl,'&'
  915.         je      preevaluate_and
  916.         cmp     dl,92h
  917.         je      preevaluation_done
  918.         or      dl,dl
  919.         jnz     invalid_logical_expression
  920.       preevaluation_done:
  921.         pop     edx
  922.         dec     esi
  923.         ret
  924.       preevaluate_or:
  925.         cmp     al,'1'
  926.         je      quick_true
  927.         cmp     al,'0'
  928.         je      leave_only_following
  929.         push    edi
  930.         mov     al,dl
  931.         stos    byte [edi]
  932.         call    preevaluate_logical_value
  933.         pop     ebx
  934.         cmp     al,'0'
  935.         je      leave_only_preceding
  936.         cmp     al,'1'
  937.         jne     preevaluation_loop
  938.         stos    byte [edi]
  939.         xor     al,al
  940.         jmp     preevaluation_loop
  941.       preevaluate_and:
  942.         cmp     al,'0'
  943.         je      quick_false
  944.         cmp     al,'1'
  945.         je      leave_only_following
  946.         push    edi
  947.         mov     al,dl
  948.         stos    byte [edi]
  949.         call    preevaluate_logical_value
  950.         pop     ebx
  951.         cmp     al,'1'
  952.         je      leave_only_preceding
  953.         cmp     al,'0'
  954.         jne     preevaluation_loop
  955.         stos    byte [edi]
  956.         xor     al,al
  957.         jmp     preevaluation_loop
  958.       leave_only_following:
  959.         mov     edi,[esp]
  960.         call    preevaluate_logical_value
  961.         jmp     preevaluation_loop
  962.       leave_only_preceding:
  963.         mov     edi,ebx
  964.         xor     al,al
  965.         jmp     preevaluation_loop
  966.       quick_true:
  967.         call    skip_logical_value
  968.         jc      invalid_logical_expression
  969.         mov     edi,[esp]
  970.         mov     al,'1'
  971.         jmp     preevaluation_loop
  972.       quick_false:
  973.         call    skip_logical_value
  974.         jc      invalid_logical_expression
  975.         mov     edi,[esp]
  976.         mov     al,'0'
  977.         jmp     preevaluation_loop
  978.       invalid_logical_expression:
  979.         pop     edi
  980.         mov     esi,edi
  981.         mov     al,0FFh
  982.         stos    byte [edi]
  983.         ret
  984.   skip_logical_value:
  985.         cmp     byte [esi],'~'
  986.         jne     negation_skipped
  987.         inc     esi
  988.         jmp     skip_logical_value
  989.       negation_skipped:
  990.         mov     al,[esi]
  991.         cmp     al,91h
  992.         jne     skip_simple_logical_value
  993.         inc     esi
  994.         xchg    al,[logical_value_wrapping]
  995.         push    eax
  996.       skip_logical_expression:
  997.         call    skip_logical_value
  998.         lods    byte [esi]
  999.         or      al,al
  1000.         jz      wrongly_structured_logical_expression
  1001.         cmp     al,0Fh
  1002.         je      wrongly_structured_logical_expression
  1003.         cmp     al,'|'
  1004.         je      skip_logical_expression
  1005.         cmp     al,'&'
  1006.         je      skip_logical_expression
  1007.         cmp     al,92h
  1008.         jne     wrongly_structured_logical_expression
  1009.         pop     eax
  1010.         mov     [logical_value_wrapping],al
  1011.       logical_value_skipped:
  1012.         clc
  1013.         ret
  1014.       wrongly_structured_logical_expression:
  1015.         pop     eax
  1016.         stc
  1017.         ret
  1018.       skip_simple_logical_value:
  1019.         mov     [logical_value_parentheses],0
  1020.       find_simple_logical_value_end:
  1021.         mov     al,[esi]
  1022.         or      al,al
  1023.         jz      logical_value_skipped
  1024.         cmp     al,0Fh
  1025.         je      logical_value_skipped
  1026.         cmp     al,'|'
  1027.         je      logical_value_skipped
  1028.         cmp     al,'&'
  1029.         je      logical_value_skipped
  1030.         cmp     al,91h
  1031.         je      skip_logical_value_internal_parenthesis
  1032.         cmp     al,92h
  1033.         jne     skip_logical_value_symbol
  1034.         sub     [logical_value_parentheses],1
  1035.         jnc     skip_logical_value_symbol
  1036.         cmp     [logical_value_wrapping],91h
  1037.         jne     skip_logical_value_symbol
  1038.         jmp     logical_value_skipped
  1039.       skip_logical_value_internal_parenthesis:
  1040.         inc     [logical_value_parentheses]
  1041.       skip_logical_value_symbol:
  1042.         call    skip_symbol
  1043.         jmp     find_simple_logical_value_end
  1044.   preevaluate_logical_value:
  1045.         mov     ebp,edi
  1046.       preevaluate_negation:
  1047.         cmp     byte [esi],'~'
  1048.         jne     preevaluate_negation_ok
  1049.         movs    byte [edi],[esi]
  1050.         jmp     preevaluate_negation
  1051.       preevaluate_negation_ok:
  1052.         mov     ebx,esi
  1053.         cmp     byte [esi],91h
  1054.         jne     preevaluate_simple_logical_value
  1055.         lods    byte [esi]
  1056.         stos    byte [edi]
  1057.         push    ebp
  1058.         mov     dl,[logical_value_wrapping]
  1059.         push    edx
  1060.         call    preevaluate_embedded_logical_expression
  1061.         pop     edx
  1062.         mov     [logical_value_wrapping],dl
  1063.         pop     ebp
  1064.         cmp     al,0FFh
  1065.         je      invalid_logical_value
  1066.         cmp     byte [esi],92h
  1067.         jne     invalid_logical_value
  1068.         or      al,al
  1069.         jnz     preevaluated_expression_value
  1070.         movs    byte [edi],[esi]
  1071.         ret
  1072.       preevaluated_expression_value:
  1073.         inc     esi
  1074.         lea     edx,[edi-1]
  1075.         sub     edx,ebp
  1076.         test    edx,1
  1077.         jz      expression_negation_ok
  1078.         xor     al,1
  1079.       expression_negation_ok:
  1080.         mov     edi,ebp
  1081.         ret
  1082.       invalid_logical_value:
  1083.         mov     edi,ebp
  1084.         mov     al,0FFh
  1085.         ret
  1086.       preevaluate_simple_logical_value:
  1087.         xor     edx,edx
  1088.         mov     [logical_value_parentheses],edx
  1089.       find_logical_value_boundaries:
  1090.         mov     al,[esi]
  1091.         or      al,al
  1092.         jz      logical_value_boundaries_found
  1093.         cmp     al,91h
  1094.         je      logical_value_internal_parentheses
  1095.         cmp     al,92h
  1096.         je      logical_value_boundaries_parenthesis_close
  1097.         cmp     al,'|'
  1098.         je      logical_value_boundaries_found
  1099.         cmp     al,'&'
  1100.         je      logical_value_boundaries_found
  1101.         or      edx,edx
  1102.         jnz     next_symbol_in_logical_value
  1103.         cmp     al,0F0h
  1104.         je      preevaluable_logical_operator
  1105.         cmp     al,0F7h
  1106.         je      preevaluable_logical_operator
  1107.         cmp     al,0F6h
  1108.         jne     next_symbol_in_logical_value
  1109.       preevaluable_logical_operator:
  1110.         mov     edx,esi
  1111.       next_symbol_in_logical_value:
  1112.         call    skip_symbol
  1113.         jmp     find_logical_value_boundaries
  1114.       logical_value_internal_parentheses:
  1115.         inc     [logical_value_parentheses]
  1116.         jmp     next_symbol_in_logical_value
  1117.       logical_value_boundaries_parenthesis_close:
  1118.         sub     [logical_value_parentheses],1
  1119.         jnc     next_symbol_in_logical_value
  1120.         cmp     [logical_value_wrapping],91h
  1121.         jne     next_symbol_in_logical_value
  1122.       logical_value_boundaries_found:
  1123.         or      edx,edx
  1124.         jz      non_preevaluable_logical_value
  1125.         mov     al,[edx]
  1126.         cmp     al,0F0h
  1127.         je      compare_symbols
  1128.         cmp     al,0F7h
  1129.         je      compare_symbol_types
  1130.         cmp     al,0F6h
  1131.         je      scan_symbols_list
  1132.       non_preevaluable_logical_value:
  1133.         mov     ecx,esi
  1134.         mov     esi,ebx
  1135.         sub     ecx,esi
  1136.         jz      invalid_logical_value
  1137.         cmp     esi,edi
  1138.         je      leave_logical_value_intact
  1139.         rep     movs byte [edi],[esi]
  1140.         xor     al,al
  1141.         ret
  1142.       leave_logical_value_intact:
  1143.         add     edi,ecx
  1144.         add     esi,ecx
  1145.         xor     al,al
  1146.         ret
  1147.       compare_symbols:
  1148.         lea     ecx,[esi-1]
  1149.         sub     ecx,edx
  1150.         mov     eax,edx
  1151.         sub     eax,ebx
  1152.         cmp     ecx,eax
  1153.         jne     preevaluated_false
  1154.         push    esi edi
  1155.         mov     esi,ebx
  1156.         lea     edi,[edx+1]
  1157.         repe    cmps byte [esi],[edi]
  1158.         pop     edi esi
  1159.         je      preevaluated_true
  1160.       preevaluated_false:
  1161.         mov     eax,edi
  1162.         sub     eax,ebp
  1163.         test    eax,1
  1164.         jnz     store_true
  1165.       store_false:
  1166.         mov     edi,ebp
  1167.         mov     al,'0'
  1168.         ret
  1169.       preevaluated_true:
  1170.         mov     eax,edi
  1171.         sub     eax,ebp
  1172.         test    eax,1
  1173.         jnz     store_false
  1174.       store_true:
  1175.         mov     edi,ebp
  1176.         mov     al,'1'
  1177.         ret
  1178.       compare_symbol_types:
  1179.         push    esi
  1180.         lea     esi,[edx+1]
  1181.       type_comparison:
  1182.         cmp     esi,[esp]
  1183.         je      types_compared
  1184.         mov     al,[esi]
  1185.         cmp     al,[ebx]
  1186.         jne     different_type
  1187.         cmp     al,'('
  1188.         jne     equal_type
  1189.         mov     al,[esi+1]
  1190.         mov     ah,[ebx+1]
  1191.         cmp     al,ah
  1192.         je      equal_type
  1193.         or      al,al
  1194.         jz      different_type
  1195.         or      ah,ah
  1196.         jz      different_type
  1197.         cmp     al,'.'
  1198.         je      different_type
  1199.         cmp     ah,'.'
  1200.         je      different_type
  1201.       equal_type:
  1202.         call    skip_symbol
  1203.         xchg    esi,ebx
  1204.         call    skip_symbol
  1205.         xchg    esi,ebx
  1206.         jmp     type_comparison
  1207.       types_compared:
  1208.         pop     esi
  1209.         cmp     byte [ebx],0F7h
  1210.         jne     preevaluated_false
  1211.         jmp     preevaluated_true
  1212.       different_type:
  1213.         pop     esi
  1214.         jmp     preevaluated_false
  1215.       scan_symbols_list:
  1216.         push    edi esi
  1217.         lea     esi,[edx+1]
  1218.         sub     edx,ebx
  1219.         lods    byte [esi]
  1220.         cmp     al,'<'
  1221.         jne     invalid_symbols_list
  1222.       get_next_from_list:
  1223.         mov     edi,esi
  1224.       get_from_list:
  1225.         cmp     byte [esi],','
  1226.         je      compare_in_list
  1227.         cmp     byte [esi],'>'
  1228.         je      compare_in_list
  1229.         cmp     esi,[esp]
  1230.         jae     invalid_symbols_list
  1231.         call    skip_symbol
  1232.         jmp     get_from_list
  1233.       compare_in_list:
  1234.         mov     ecx,esi
  1235.         sub     ecx,edi
  1236.         cmp     ecx,edx
  1237.         jne     not_equal_length_in_list
  1238.         mov     esi,ebx
  1239.         repe    cmps byte [esi],[edi]
  1240.         mov     esi,edi
  1241.         jne     not_equal_in_list
  1242.       skip_rest_of_list:
  1243.         cmp     byte [esi],'>'
  1244.         je      check_list_end
  1245.         cmp     esi,[esp]
  1246.         jae     invalid_symbols_list
  1247.         call    skip_symbol
  1248.         jmp     skip_rest_of_list
  1249.       check_list_end:
  1250.         inc     esi
  1251.         cmp     esi,[esp]
  1252.         jne     invalid_symbols_list
  1253.         pop     esi edi
  1254.         jmp     preevaluated_true
  1255.       not_equal_in_list:
  1256.         add     esi,ecx
  1257.       not_equal_length_in_list:
  1258.         lods    byte [esi]
  1259.         cmp     al,','
  1260.         je      get_next_from_list
  1261.         cmp     esi,[esp]
  1262.         jne     invalid_symbols_list
  1263.         pop     esi edi
  1264.         jmp     preevaluated_false
  1265.       invalid_symbols_list:
  1266.         pop     esi edi
  1267.         jmp     invalid_logical_value
  1268.