Subversion Repositories Kolibri OS

Rev

Rev 2287 | Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2012, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. convert_expression:
  7.         push    ebp
  8.         call    get_fp_value
  9.         jnc     fp_expression
  10.         mov     [current_offset],esp
  11.       expression_loop:
  12.         push    edi
  13.         mov     edi,single_operand_operators
  14.         call    get_operator
  15.         pop     edi
  16.         or      al,al
  17.         jz      expression_element
  18.         cmp     al,82h
  19.         je      expression_loop
  20.         push    eax
  21.         jmp     expression_loop
  22.       expression_element:
  23.         mov     al,[esi]
  24.         cmp     al,1Ah
  25.         je      expression_number
  26.         cmp     al,22h
  27.         je      expression_number
  28.         cmp     al,'('
  29.         je      expression_number
  30.         mov     al,'!'
  31.         stos    byte [edi]
  32.         jmp     expression_operator
  33.       expression_number:
  34.         call    convert_number
  35.       expression_operator:
  36.         push    edi
  37.         mov     edi,operators
  38.         call    get_operator
  39.         pop     edi
  40.         or      al,al
  41.         jz      expression_end
  42.       operators_loop:
  43.         cmp     esp,[current_offset]
  44.         je      push_operator
  45.         mov     bl,al
  46.         and     bl,0F0h
  47.         mov     bh,byte [esp]
  48.         and     bh,0F0h
  49.         cmp     bl,bh
  50.         ja      push_operator
  51.         pop     ebx
  52.         mov     byte [edi],bl
  53.         inc     edi
  54.         jmp     operators_loop
  55.       push_operator:
  56.         push    eax
  57.         jmp     expression_loop
  58.       expression_end:
  59.         cmp     esp,[current_offset]
  60.         je      expression_converted
  61.         pop     eax
  62.         stos    byte [edi]
  63.         jmp     expression_end
  64.       expression_converted:
  65.         pop     ebp
  66.         ret
  67.       fp_expression:
  68.         mov     al,'.'
  69.         stos    byte [edi]
  70.         mov     eax,[fp_value]
  71.         stos    dword [edi]
  72.         mov     eax,[fp_value+4]
  73.         stos    dword [edi]
  74.         mov     eax,[fp_value+8]
  75.         stos    dword [edi]
  76.         pop     ebp
  77.         ret
  78.  
  79. convert_number:
  80.         lea     eax,[edi-10h]
  81.         mov     edx,[memory_end]
  82.         cmp     [source_start],0
  83.         je      check_memory_for_number
  84.         mov     edx,[labels_list]
  85.       check_memory_for_number:
  86.         cmp     eax,edx
  87.         jae     out_of_memory
  88.         mov     eax,esp
  89.         sub     eax,100h
  90.         jc      stack_overflow
  91.         cmp     eax,[stack_limit]
  92.         jb      stack_overflow
  93.         cmp     byte [esi],'('
  94.         je      expression_value
  95.         inc     edi
  96.         call    get_number
  97.         jc      symbol_value
  98.         or      ebp,ebp
  99.         jz      valid_number
  100.         mov     byte [edi-1],0Fh
  101.         ret
  102.       valid_number:
  103.         cmp     dword [edi+4],0
  104.         jne     qword_number
  105.         cmp     word [edi+2],0
  106.         jne     dword_number
  107.         cmp     byte [edi+1],0
  108.         jne     word_number
  109.       byte_number:
  110.         mov     byte [edi-1],1
  111.         inc     edi
  112.         ret
  113.       qword_number:
  114.         mov     byte [edi-1],8
  115.         add     edi,8
  116.         ret
  117.       dword_number:
  118.         mov     byte [edi-1],4
  119.         scas    dword [edi]
  120.         ret
  121.       word_number:
  122.         mov     byte [edi-1],2
  123.         scas    word [edi]
  124.         ret
  125.       expression_value:
  126.         inc     esi
  127.         push    [current_offset]
  128.         call    convert_expression
  129.         pop     [current_offset]
  130.         lods    byte [esi]
  131.         cmp     al,')'
  132.         jne     invalid_expression
  133.         ret
  134.       symbol_value:
  135.         cmp     [source_start],0
  136.         je      preprocessor_value
  137.         push    edi
  138.         mov     edi,address_registers
  139.         call    get_operator
  140.         or      al,al
  141.         jnz     register_value
  142.         mov     edi,directive_operators
  143.         call    get_operator
  144.         pop     edi
  145.         or      al,al
  146.         jnz     broken_value
  147.         lods    byte [esi]
  148.         cmp     al,1Ah
  149.         jne     invalid_value
  150.         lods    byte [esi]
  151.         movzx   ecx,al
  152.         call    get_label_id
  153.       store_label_value:
  154.         mov     byte [edi-1],11h
  155.         stos    dword [edi]
  156.         ret
  157.       broken_value:
  158.         mov     eax,0Fh
  159.         jmp     store_label_value
  160.       register_value:
  161.         pop     edi
  162.         mov     byte [edi-1],10h
  163.         stos    byte [edi]
  164.         ret
  165.       preprocessor_value:
  166.         dec     edi
  167.         cmp     [hash_tree],0
  168.         je      invalid_value
  169.         lods    byte [esi]
  170.         cmp     al,1Ah
  171.         jne     invalid_value
  172.         lods    byte [esi]
  173.         mov     cl,al
  174.         mov     ch,10b
  175.         call    get_preprocessor_symbol
  176.         jc      invalid_value
  177.         push    esi
  178.         mov     esi,[edx+8]
  179.         push    [current_offset]
  180.         call    convert_expression
  181.         pop     [current_offset]
  182.         pop     esi
  183.         ret
  184.  
  185. get_number:
  186.         xor     ebp,ebp
  187.         lods    byte [esi]
  188.         cmp     al,22h
  189.         je      get_text_number
  190.         cmp     al,1Ah
  191.         jne     not_number
  192.         lods    byte [esi]
  193.         movzx   ecx,al
  194.         mov     [number_start],esi
  195.         mov     al,[esi]
  196.         cmp     al,'$'
  197.         je      number_begin
  198.         sub     al,30h
  199.         cmp     al,9
  200.         ja      invalid_number
  201.       number_begin:
  202.         mov     ebx,esi
  203.         add     esi,ecx
  204.         push    esi
  205.         dec     esi
  206.         mov     dword [edi],0
  207.         mov     dword [edi+4],0
  208.         cmp     byte [ebx],'$'
  209.         je      pascal_hex_number
  210.         cmp     word [ebx],'0x'
  211.         je      get_hex_number
  212.         mov     al,[esi]
  213.         dec     esi
  214.         cmp     al,'h'
  215.         je      get_hex_number
  216.         cmp     al,'b'
  217.         je      get_bin_number
  218.         cmp     al,'d'
  219.         je      get_dec_number
  220.         cmp     al,'o'
  221.         je      get_oct_number
  222.         cmp     al,'H'
  223.         je      get_hex_number
  224.         cmp     al,'B'
  225.         je      get_bin_number
  226.         cmp     al,'D'
  227.         je      get_dec_number
  228.         cmp     al,'O'
  229.         je      get_oct_number
  230.         inc     esi
  231.       get_dec_number:
  232.         mov     ebx,esi
  233.         mov     esi,[number_start]
  234.       get_dec_digit:
  235.         cmp     esi,ebx
  236.         ja      number_ok
  237.         cmp     byte [esi],27h
  238.         je      next_dec_digit
  239.         xor     edx,edx
  240.         mov     eax,[edi]
  241.         shld    edx,eax,2
  242.         shl     eax,2
  243.         add     eax,[edi]
  244.         adc     edx,0
  245.         add     eax,eax
  246.         adc     edx,edx
  247.         mov     [edi],eax
  248.         mov     eax,[edi+4]
  249.         add     eax,eax
  250.         jc      dec_out_of_range
  251.         add     eax,eax
  252.         jc      dec_out_of_range
  253.         add     eax,[edi+4]
  254.         jc      dec_out_of_range
  255.         add     eax,eax
  256.         jc      dec_out_of_range
  257.         add     eax,edx
  258.         jc      dec_out_of_range
  259.         mov     [edi+4],eax
  260.         movzx   eax,byte [esi]
  261.         sub     al,30h
  262.         jc      bad_number
  263.         cmp     al,9
  264.         ja      bad_number
  265.         add     [edi],eax
  266.         adc     dword [edi+4],0
  267.         jc      dec_out_of_range
  268.       next_dec_digit:
  269.         inc     esi
  270.         jmp     get_dec_digit
  271.       dec_out_of_range:
  272.         cmp     esi,ebx
  273.         ja      dec_out_of_range_finished
  274.         lods    byte [esi]
  275.         cmp     al,27h
  276.         je      bad_number
  277.         sub     al,30h
  278.         jc      bad_number
  279.         cmp     al,9
  280.         ja      bad_number
  281.         jmp     dec_out_of_range
  282.       dec_out_of_range_finished:
  283.         or      ebp,-1
  284.         jmp     number_ok
  285.       bad_number:
  286.         pop     eax
  287.       invalid_number:
  288.         mov     esi,[number_start]
  289.         dec     esi
  290.       not_number:
  291.         dec     esi
  292.         stc
  293.         ret
  294.       get_bin_number:
  295.         xor     bl,bl
  296.       get_bin_digit:
  297.         cmp     esi,[number_start]
  298.         jb      number_ok
  299.         movzx   eax,byte [esi]
  300.         cmp     al,27h
  301.         je      bin_digit_skip
  302.         sub     al,30h
  303.         cmp     al,1
  304.         ja      bad_number
  305.         xor     edx,edx
  306.         mov     cl,bl
  307.         dec     esi
  308.         cmp     bl,64
  309.         je      bin_out_of_range
  310.         inc     bl
  311.         cmp     cl,32
  312.         jae     bin_digit_high
  313.         shl     eax,cl
  314.         or      dword [edi],eax
  315.         jmp     get_bin_digit
  316.       bin_digit_high:
  317.         sub     cl,32
  318.         shl     eax,cl
  319.         or      dword [edi+4],eax
  320.         jmp     get_bin_digit
  321.       bin_out_of_range:
  322.         or      al,al
  323.         jz      get_bin_digit
  324.         or      ebp,-1
  325.         jmp     get_bin_digit
  326.       bin_digit_skip:
  327.         dec     esi
  328.         jmp     get_bin_digit
  329.       pascal_hex_number:
  330.         cmp     cl,1
  331.         je      bad_number
  332.       get_hex_number:
  333.         xor     bl,bl
  334.       get_hex_digit:
  335.         cmp     esi,[number_start]
  336.         jb      number_ok
  337.         movzx   eax,byte [esi]
  338.         cmp     al,27h
  339.         je      hex_digit_skip
  340.         cmp     al,'x'
  341.         je      hex_number_ok
  342.         cmp     al,'$'
  343.         je      pascal_hex_ok
  344.         sub     al,30h
  345.         cmp     al,9
  346.         jbe     hex_digit_ok
  347.         sub     al,7
  348.         cmp     al,15
  349.         jbe     hex_letter_digit_ok
  350.         sub     al,20h
  351.         cmp     al,15
  352.         ja      bad_number
  353.       hex_letter_digit_ok:
  354.         cmp     al,10
  355.         jb      bad_number
  356.       hex_digit_ok:
  357.         xor     edx,edx
  358.         mov     cl,bl
  359.         dec     esi
  360.         cmp     bl,64
  361.         je      hex_out_of_range
  362.         add     bl,4
  363.         cmp     cl,32
  364.         jae     hex_digit_high
  365.         shl     eax,cl
  366.         or      dword [edi],eax
  367.         jmp     get_hex_digit
  368.       hex_digit_high:
  369.         sub     cl,32
  370.         shl     eax,cl
  371.         or      dword [edi+4],eax
  372.         jmp     get_hex_digit
  373.       hex_out_of_range:
  374.         or      al,al
  375.         jz      get_hex_digit
  376.         or      ebp,-1
  377.         jmp     get_hex_digit
  378.       hex_digit_skip:
  379.         dec     esi
  380.         jmp     get_hex_digit
  381.       get_oct_number:
  382.         xor     bl,bl
  383.       get_oct_digit:
  384.         cmp     esi,[number_start]
  385.         jb      number_ok
  386.         movzx   eax,byte [esi]
  387.         cmp     al,27h
  388.         je      oct_digit_skip
  389.         sub     al,30h
  390.         cmp     al,7
  391.         ja      bad_number
  392.       oct_digit_ok:
  393.         xor     edx,edx
  394.         mov     cl,bl
  395.         dec     esi
  396.         cmp     bl,63
  397.         ja      oct_out_of_range
  398.         jne     oct_range_ok
  399.         cmp     al,1
  400.         ja      oct_out_of_range
  401.       oct_range_ok:
  402.         add     bl,3
  403.         cmp     cl,30
  404.         je      oct_digit_wrap
  405.         ja      oct_digit_high
  406.         shl     eax,cl
  407.         or      dword [edi],eax
  408.         jmp     get_oct_digit
  409.       oct_digit_wrap:
  410.         shl     eax,cl
  411.         adc     dword [edi+4],0
  412.         or      dword [edi],eax
  413.         jmp     get_oct_digit
  414.       oct_digit_high:
  415.         sub     cl,32
  416.         shl     eax,cl
  417.         or      dword [edi+4],eax
  418.         jmp     get_oct_digit
  419.       oct_digit_skip:
  420.         dec     esi
  421.         jmp     get_oct_digit
  422.       oct_out_of_range:
  423.         or      al,al
  424.         jz      get_oct_digit
  425.         or      ebp,-1
  426.         jmp     get_oct_digit
  427.       hex_number_ok:
  428.         dec     esi
  429.       pascal_hex_ok:
  430.         cmp     esi,[number_start]
  431.         jne     bad_number
  432.       number_ok:
  433.         pop     esi
  434.       number_done:
  435.         clc
  436.         ret
  437.       get_text_number:
  438.         lods    dword [esi]
  439.         mov     edx,eax
  440.         xor     bl,bl
  441.         mov     dword [edi],0
  442.         mov     dword [edi+4],0
  443.       get_text_character:
  444.         sub     edx,1
  445.         jc      number_done
  446.         movzx   eax,byte [esi]
  447.         inc     esi
  448.         mov     cl,bl
  449.         cmp     bl,64
  450.         je      text_out_of_range
  451.         add     bl,8
  452.         cmp     cl,32
  453.         jae     text_character_high
  454.         shl     eax,cl
  455.         or      dword [edi],eax
  456.         jmp     get_text_character
  457.       text_character_high:
  458.         sub     cl,32
  459.         shl     eax,cl
  460.         or      dword [edi+4],eax
  461.         jmp     get_text_character
  462.       text_out_of_range:
  463.         or      ebp,-1
  464.         jmp     get_text_character
  465.  
  466. get_fp_value:
  467.         push    edi esi
  468.         lods    byte [esi]
  469.         cmp     al,1Ah
  470.         je      fp_value_start
  471.         cmp     al,'-'
  472.         je      fp_sign_ok
  473.         cmp     al,'+'
  474.         jne     not_fp_value
  475.       fp_sign_ok:
  476.         lods    byte [esi]
  477.         cmp     al,1Ah
  478.         jne     not_fp_value
  479.       fp_value_start:
  480.         lods    byte [esi]
  481.         movzx   ecx,al
  482.         cmp     cl,1
  483.         jbe     not_fp_value
  484.         lea     edx,[esi+1]
  485.         xor     ah,ah
  486.       check_fp_value:
  487.         lods    byte [esi]
  488.         cmp     al,'.'
  489.         je      fp_character_dot
  490.         cmp     al,'E'
  491.         je      fp_character_exp
  492.         cmp     al,'e'
  493.         je      fp_character_exp
  494.         cmp     al,'F'
  495.         je      fp_last_character
  496.         cmp     al,'f'
  497.         je      fp_last_character
  498.       digit_expected:
  499.         cmp     al,'0'
  500.         jb      not_fp_value
  501.         cmp     al,'9'
  502.         ja      not_fp_value
  503.         jmp     fp_character_ok
  504.       fp_character_dot:
  505.         cmp     esi,edx
  506.         je      not_fp_value
  507.         or      ah,ah
  508.         jnz     not_fp_value
  509.         or      ah,1
  510.         lods    byte [esi]
  511.         loop    digit_expected
  512.       not_fp_value:
  513.         pop     esi edi
  514.         stc
  515.         ret
  516.       fp_last_character:
  517.         cmp     cl,1
  518.         jne     not_fp_value
  519.         or      ah,4
  520.         jmp     fp_character_ok
  521.       fp_character_exp:
  522.         cmp     esi,edx
  523.         je      not_fp_value
  524.         cmp     ah,1
  525.         ja      not_fp_value
  526.         or      ah,2
  527.         cmp     ecx,1
  528.         jne     fp_character_ok
  529.         cmp     byte [esi],'+'
  530.         je      fp_exp_sign
  531.         cmp     byte [esi],'-'
  532.         jne     fp_character_ok
  533.       fp_exp_sign:
  534.         inc     esi
  535.         cmp     byte [esi],1Ah
  536.         jne     not_fp_value
  537.         inc     esi
  538.         lods    byte [esi]
  539.         movzx   ecx,al
  540.         inc     ecx
  541.       fp_character_ok:
  542.         dec     ecx
  543.         jnz     check_fp_value
  544.         or      ah,ah
  545.         jz      not_fp_value
  546.         pop     esi
  547.         lods    byte [esi]
  548.         mov     [fp_sign],0
  549.         cmp     al,1Ah
  550.         je      fp_get
  551.         inc     esi
  552.         cmp     al,'+'
  553.         je      fp_get
  554.         mov     [fp_sign],1
  555.       fp_get:
  556.         lods    byte [esi]
  557.         movzx   ecx,al
  558.         xor     edx,edx
  559.         mov     edi,fp_value
  560.         mov     [edi],edx
  561.         mov     [edi+4],edx
  562.         mov     [edi+12],edx
  563.         call    fp_optimize
  564.         mov     [fp_format],0
  565.         mov     al,[esi]
  566.       fp_before_dot:
  567.         lods    byte [esi]
  568.         cmp     al,'.'
  569.         je      fp_dot
  570.         cmp     al,'E'
  571.         je      fp_exponent
  572.         cmp     al,'e'
  573.         je      fp_exponent
  574.         cmp     al,'F'
  575.         je      fp_done
  576.         cmp     al,'f'
  577.         je      fp_done
  578.         sub     al,30h
  579.         mov     edi,fp_value+16
  580.         xor     edx,edx
  581.         mov     dword [edi+12],edx
  582.         mov     dword [edi],edx
  583.         mov     dword [edi+4],edx
  584.         mov     [edi+7],al
  585.         mov     dl,7
  586.         mov     dword [edi+8],edx
  587.         call    fp_optimize
  588.         mov     edi,fp_value
  589.         push    ecx
  590.         mov     ecx,10
  591.         call    fp_mul
  592.         pop     ecx
  593.         mov     ebx,fp_value+16
  594.         call    fp_add
  595.         loop    fp_before_dot
  596.       fp_dot:
  597.         mov     edi,fp_value+16
  598.         xor     edx,edx
  599.         mov     [edi],edx
  600.         mov     [edi+4],edx
  601.         mov     byte [edi+7],80h
  602.         mov     [edi+8],edx
  603.         mov     dword [edi+12],edx
  604.         dec     ecx
  605.         jz      fp_done
  606.       fp_after_dot:
  607.         lods    byte [esi]
  608.         cmp     al,'E'
  609.         je      fp_exponent
  610.         cmp     al,'e'
  611.         je      fp_exponent
  612.         cmp     al,'F'
  613.         je      fp_done
  614.         cmp     al,'f'
  615.         je      fp_done
  616.         inc     [fp_format]
  617.         cmp     [fp_format],80h
  618.         jne     fp_counter_ok
  619.         mov     [fp_format],7Fh
  620.       fp_counter_ok:
  621.         dec     esi
  622.         mov     edi,fp_value+16
  623.         push    ecx
  624.         mov     ecx,10
  625.         call    fp_div
  626.         push    dword [edi]
  627.         push    dword [edi+4]
  628.         push    dword [edi+8]
  629.         push    dword [edi+12]
  630.         lods    byte [esi]
  631.         sub     al,30h
  632.         movzx   ecx,al
  633.         call    fp_mul
  634.         mov     ebx,edi
  635.         mov     edi,fp_value
  636.         call    fp_add
  637.         mov     edi,fp_value+16
  638.         pop     dword [edi+12]
  639.         pop     dword [edi+8]
  640.         pop     dword [edi+4]
  641.         pop     dword [edi]
  642.         pop     ecx
  643.         dec     ecx
  644.         jnz     fp_after_dot
  645.         jmp     fp_done
  646.       fp_exponent:
  647.         or      [fp_format],80h
  648.         xor     edx,edx
  649.         xor     ebp,ebp
  650.         dec     ecx
  651.         jnz     get_exponent
  652.         cmp     byte [esi],'+'
  653.         je      fp_exponent_sign
  654.         cmp     byte [esi],'-'
  655.         jne     fp_done
  656.         not     ebp
  657.       fp_exponent_sign:
  658.         add     esi,2
  659.         lods    byte [esi]
  660.         movzx   ecx,al
  661.       get_exponent:
  662.         movzx   eax,byte [esi]
  663.         inc     esi
  664.         sub     al,30h
  665.         cmp     al,10
  666.         jae     exponent_ok
  667.         imul    edx,10
  668.         cmp     edx,8000h
  669.         jae     value_out_of_range
  670.         add     edx,eax
  671.         loop    get_exponent
  672.       exponent_ok:
  673.         mov     edi,fp_value
  674.         or      edx,edx
  675.         jz      fp_done
  676.         mov     ecx,edx
  677.         or      ebp,ebp
  678.         jnz     fp_negative_power
  679.       fp_power:
  680.         push    ecx
  681.         mov     ecx,10
  682.         call    fp_mul
  683.         pop     ecx
  684.         loop    fp_power
  685.         jmp     fp_done
  686.       fp_negative_power:
  687.         push    ecx
  688.         mov     ecx,10
  689.         call    fp_div
  690.         pop     ecx
  691.         loop    fp_negative_power
  692.       fp_done:
  693.         mov     edi,fp_value
  694.         mov     al,[fp_format]
  695.         mov     [edi+10],al
  696.         mov     al,[fp_sign]
  697.         mov     [edi+11],al
  698.         test    byte [edi+15],80h
  699.         jz      fp_ok
  700.         add     dword [edi],1
  701.         adc     dword [edi+4],0
  702.         jnc     fp_ok
  703.         mov     eax,[edi+4]
  704.         shrd    [edi],eax,1
  705.         shr     eax,1
  706.         or      eax,80000000h
  707.         mov     [edi+4],eax
  708.         inc     word [edi+8]
  709.       fp_ok:
  710.         pop     edi
  711.         clc
  712.         ret
  713.       fp_mul:
  714.         or      ecx,ecx
  715.         jz      fp_zero
  716.         mov     eax,[edi+12]
  717.         mul     ecx
  718.         mov     [edi+12],eax
  719.         mov     ebx,edx
  720.         mov     eax,[edi]
  721.         mul     ecx
  722.         add     eax,ebx
  723.         adc     edx,0
  724.         mov     [edi],eax
  725.         mov     ebx,edx
  726.         mov     eax,[edi+4]
  727.         mul     ecx
  728.         add     eax,ebx
  729.         adc     edx,0
  730.         mov     [edi+4],eax
  731.       .loop:
  732.         or      edx,edx
  733.         jz      .done
  734.         mov     eax,[edi]
  735.         shrd    [edi+12],eax,1
  736.         mov     eax,[edi+4]
  737.         shrd    [edi],eax,1
  738.         shrd    eax,edx,1
  739.         mov     [edi+4],eax
  740.         shr     edx,1
  741.         inc     dword [edi+8]
  742.         cmp     dword [edi+8],8000h
  743.         jge     value_out_of_range
  744.         jmp     .loop
  745.       .done:
  746.         ret
  747.       fp_div:
  748.         mov     eax,[edi+4]
  749.         xor     edx,edx
  750.         div     ecx
  751.         mov     [edi+4],eax
  752.         mov     eax,[edi]
  753.         div     ecx
  754.         mov     [edi],eax
  755.         mov     eax,[edi+12]
  756.         div     ecx
  757.         mov     [edi+12],eax
  758.         mov     ebx,eax
  759.         or      ebx,[edi]
  760.         or      ebx,[edi+4]
  761.         jz      fp_zero
  762.       .loop:
  763.         test    byte [edi+7],80h
  764.         jnz     .exp_ok
  765.         mov     eax,[edi]
  766.         shld    [edi+4],eax,1
  767.         mov     eax,[edi+12]
  768.         shld    [edi],eax,1
  769.         add     eax,eax
  770.         mov     [edi+12],eax
  771.         dec     dword [edi+8]
  772.         add     edx,edx
  773.         jmp     .loop
  774.       .exp_ok:
  775.         mov     eax,edx
  776.         xor     edx,edx
  777.         div     ecx
  778.         add     [edi+12],eax
  779.         adc     dword [edi],0
  780.         adc     dword [edi+4],0
  781.         jnc     .done
  782.         mov     eax,[edi+4]
  783.         mov     ebx,[edi]
  784.         shrd    [edi],eax,1
  785.         shrd    [edi+12],ebx,1
  786.         shr     eax,1
  787.         or      eax,80000000h
  788.         mov     [edi+4],eax
  789.         inc     dword [edi+8]
  790.       .done:
  791.         ret
  792.       fp_add:
  793.         cmp     dword [ebx+8],8000h
  794.         je      .done
  795.         cmp     dword [edi+8],8000h
  796.         je      .copy
  797.         mov     eax,[ebx+8]
  798.         cmp     eax,[edi+8]
  799.         jge     .exp_ok
  800.         mov     eax,[edi+8]
  801.       .exp_ok:
  802.         call    .change_exp
  803.         xchg    ebx,edi
  804.         call    .change_exp
  805.         xchg    ebx,edi
  806.         mov     edx,[ebx+12]
  807.         mov     eax,[ebx]
  808.         mov     ebx,[ebx+4]
  809.         add     [edi+12],edx
  810.         adc     [edi],eax
  811.         adc     [edi+4],ebx
  812.         jnc     .done
  813.         mov     eax,[edi]
  814.         shrd    [edi+12],eax,1
  815.         mov     eax,[edi+4]
  816.         shrd    [edi],eax,1
  817.         shr     eax,1
  818.         or      eax,80000000h
  819.         mov     [edi+4],eax
  820.         inc     dword [edi+8]
  821.       .done:
  822.         ret
  823.       .copy:
  824.         mov     eax,[ebx]
  825.         mov     [edi],eax
  826.         mov     eax,[ebx+4]
  827.         mov     [edi+4],eax
  828.         mov     eax,[ebx+8]
  829.         mov     [edi+8],eax
  830.         mov     eax,[ebx+12]
  831.         mov     [edi+12],eax
  832.         ret
  833.       .change_exp:
  834.         push    ecx
  835.         mov     ecx,eax
  836.         sub     ecx,[ebx+8]
  837.         mov     edx,[ebx+4]
  838.         jecxz   .exp_done
  839.       .exp_loop:
  840.         mov     ebp,[ebx]
  841.         shrd    [ebx+12],ebp,1
  842.         shrd    [ebx],edx,1
  843.         shr     edx,1
  844.         inc     dword [ebx+8]
  845.         loop    .exp_loop
  846.       .exp_done:
  847.         mov     [ebx+4],edx
  848.         pop     ecx
  849.         ret
  850.       fp_optimize:
  851.         mov     eax,[edi]
  852.         mov     ebp,[edi+4]
  853.         or      ebp,[edi]
  854.         or      ebp,[edi+12]
  855.         jz      fp_zero
  856.       .loop:
  857.         test    byte [edi+7],80h
  858.         jnz     .done
  859.         shld    [edi+4],eax,1
  860.         mov     ebp,[edi+12]
  861.         shld    eax,ebp,1
  862.         mov     [edi],eax
  863.         shl     dword [edi+12],1
  864.         dec     dword [edi+8]
  865.         jmp     .loop
  866.       .done:
  867.         ret
  868.       fp_zero:
  869.         mov     dword [edi+8],8000h
  870.         ret
  871.  
  872. preevaluate_logical_expression:
  873.         xor     al,al
  874.   preevaluate_embedded_logical_expression:
  875.         mov     [logical_value_wrapping],al
  876.         push    edi
  877.         call    preevaluate_logical_value
  878.       preevaluation_loop:
  879.         cmp     al,0FFh
  880.         je      invalid_logical_expression
  881.         mov     dl,[esi]
  882.         inc     esi
  883.         cmp     dl,'|'
  884.         je      preevaluate_or
  885.         cmp     dl,'&'
  886.         je      preevaluate_and
  887.         cmp     dl,'}'
  888.         je      preevaluation_done
  889.         or      dl,dl
  890.         jnz     invalid_logical_expression
  891.       preevaluation_done:
  892.         pop     edx
  893.         dec     esi
  894.         ret
  895.       preevaluate_or:
  896.         cmp     al,'1'
  897.         je      quick_true
  898.         cmp     al,'0'
  899.         je      leave_only_following
  900.         push    edi
  901.         mov     al,dl
  902.         stos    byte [edi]
  903.         call    preevaluate_logical_value
  904.         pop     ebx
  905.         cmp     al,'0'
  906.         je      leave_only_preceding
  907.         cmp     al,'1'
  908.         jne     preevaluation_loop
  909.         stos    byte [edi]
  910.         xor     al,al
  911.         jmp     preevaluation_loop
  912.       preevaluate_and:
  913.         cmp     al,'0'
  914.         je      quick_false
  915.         cmp     al,'1'
  916.         je      leave_only_following
  917.         push    edi
  918.         mov     al,dl
  919.         stos    byte [edi]
  920.         call    preevaluate_logical_value
  921.         pop     ebx
  922.         cmp     al,'1'
  923.         je      leave_only_preceding
  924.         cmp     al,'0'
  925.         jne     preevaluation_loop
  926.         stos    byte [edi]
  927.         xor     al,al
  928.         jmp     preevaluation_loop
  929.       leave_only_following:
  930.         mov     edi,[esp]
  931.         call    preevaluate_logical_value
  932.         jmp     preevaluation_loop
  933.       leave_only_preceding:
  934.         mov     edi,ebx
  935.         xor     al,al
  936.         jmp     preevaluation_loop
  937.       quick_true:
  938.         call    skip_logical_value
  939.         jc      invalid_logical_expression
  940.         mov     edi,[esp]
  941.         mov     al,'1'
  942.         jmp     preevaluation_loop
  943.       quick_false:
  944.         call    skip_logical_value
  945.         jc      invalid_logical_expression
  946.         mov     edi,[esp]
  947.         mov     al,'0'
  948.         jmp     preevaluation_loop
  949.       invalid_logical_expression:
  950.         pop     edi
  951.         mov     esi,edi
  952.         mov     al,0FFh
  953.         stos    byte [edi]
  954.         ret
  955.   skip_logical_value:
  956.         cmp     byte [esi],'~'
  957.         jne     negation_skipped
  958.         inc     esi
  959.         jmp     skip_logical_value
  960.       negation_skipped:
  961.         mov     al,[esi]
  962.         cmp     al,'{'
  963.         jne     skip_simple_logical_value
  964.         inc     esi
  965.         xchg    al,[logical_value_wrapping]
  966.         push    eax
  967.       skip_logical_expression:
  968.         call    skip_logical_value
  969.         lods    byte [esi]
  970.         or      al,al
  971.         jz      wrongly_structured_logical_expression
  972.         cmp     al,0Fh
  973.         je      wrongly_structured_logical_expression
  974.         cmp     al,'|'
  975.         je      skip_logical_expression
  976.         cmp     al,'&'
  977.         je      skip_logical_expression
  978.         cmp     al,'}'
  979.         jne     wrongly_structured_logical_expression
  980.         pop     eax
  981.         mov     [logical_value_wrapping],al
  982.       logical_value_skipped:
  983.         clc
  984.         ret
  985.       wrongly_structured_logical_expression:
  986.         pop     eax
  987.         stc
  988.         ret
  989.       skip_simple_logical_value:
  990.         mov     [logical_value_parentheses],0
  991.       find_simple_logical_value_end:
  992.         mov     al,[esi]
  993.         or      al,al
  994.         jz      logical_value_skipped
  995.         cmp     al,0Fh
  996.         je      logical_value_skipped
  997.         cmp     al,'|'
  998.         je      logical_value_skipped
  999.         cmp     al,'&'
  1000.         je      logical_value_skipped
  1001.         cmp     al,'{'
  1002.         je      skip_logical_value_internal_parenthesis
  1003.         cmp     al,'}'
  1004.         jne     skip_logical_value_symbol
  1005.         sub     [logical_value_parentheses],1
  1006.         jnc     skip_logical_value_symbol
  1007.         cmp     [logical_value_wrapping],'{'
  1008.         jne     skip_logical_value_symbol
  1009.         jmp     logical_value_skipped
  1010.       skip_logical_value_internal_parenthesis:
  1011.         inc     [logical_value_parentheses]
  1012.       skip_logical_value_symbol:
  1013.         call    skip_symbol
  1014.         jmp     find_simple_logical_value_end
  1015.   preevaluate_logical_value:
  1016.         mov     ebp,edi
  1017.       preevaluate_negation:
  1018.         cmp     byte [esi],'~'
  1019.         jne     preevaluate_negation_ok
  1020.         movs    byte [edi],[esi]
  1021.         jmp     preevaluate_negation
  1022.       preevaluate_negation_ok:
  1023.         mov     ebx,esi
  1024.         cmp     byte [esi],'{'
  1025.         jne     preevaluate_simple_logical_value
  1026.         lods    byte [esi]
  1027.         stos    byte [edi]
  1028.         push    ebp
  1029.         mov     dl,[logical_value_wrapping]
  1030.         push    edx
  1031.         call    preevaluate_embedded_logical_expression
  1032.         pop     edx
  1033.         mov     [logical_value_wrapping],dl
  1034.         pop     ebp
  1035.         cmp     al,0FFh
  1036.         je      invalid_logical_value
  1037.         cmp     byte [esi],'}'
  1038.         jne     invalid_logical_value
  1039.         or      al,al
  1040.         jnz     preevaluated_expression_value
  1041.         movs    byte [edi],[esi]
  1042.         ret
  1043.       preevaluated_expression_value:
  1044.         inc     esi
  1045.         lea     edx,[edi-1]
  1046.         sub     edx,ebp
  1047.         test    edx,1
  1048.         jz      expression_negation_ok
  1049.         xor     al,1
  1050.       expression_negation_ok:
  1051.         mov     edi,ebp
  1052.         ret
  1053.       invalid_logical_value:
  1054.         mov     edi,ebp
  1055.         mov     al,0FFh
  1056.         ret
  1057.       preevaluate_simple_logical_value:
  1058.         xor     edx,edx
  1059.         mov     [logical_value_parentheses],edx
  1060.       find_logical_value_boundaries:
  1061.         mov     al,[esi]
  1062.         or      al,al
  1063.         jz      logical_value_boundaries_found
  1064.         cmp     al,'{'
  1065.         je      logical_value_internal_parentheses
  1066.         cmp     al,'}'
  1067.         je      logical_value_boundaries_parenthesis_close
  1068.         cmp     al,'|'
  1069.         je      logical_value_boundaries_found
  1070.         cmp     al,'&'
  1071.         je      logical_value_boundaries_found
  1072.         or      edx,edx
  1073.         jnz     next_symbol_in_logical_value
  1074.         cmp     al,0F0h
  1075.         je      preevaluable_logical_operator
  1076.         cmp     al,0F7h
  1077.         je      preevaluable_logical_operator
  1078.         cmp     al,0F6h
  1079.         jne     next_symbol_in_logical_value
  1080.       preevaluable_logical_operator:
  1081.         mov     edx,esi
  1082.       next_symbol_in_logical_value:
  1083.         call    skip_symbol
  1084.         jmp     find_logical_value_boundaries
  1085.       logical_value_internal_parentheses:
  1086.         inc     [logical_value_parentheses]
  1087.         jmp     next_symbol_in_logical_value
  1088.       logical_value_boundaries_parenthesis_close:
  1089.         sub     [logical_value_parentheses],1
  1090.         jnc     next_symbol_in_logical_value
  1091.         cmp     [logical_value_wrapping],'{'
  1092.         jne     next_symbol_in_logical_value
  1093.       logical_value_boundaries_found:
  1094.         or      edx,edx
  1095.         jz      non_preevaluable_logical_value
  1096.         mov     al,[edx]
  1097.         cmp     al,0F0h
  1098.         je      compare_symbols
  1099.         cmp     al,0F7h
  1100.         je      compare_symbol_types
  1101.         cmp     al,0F6h
  1102.         je      scan_symbols_list
  1103.       non_preevaluable_logical_value:
  1104.         mov     ecx,esi
  1105.         mov     esi,ebx
  1106.         sub     ecx,esi
  1107.         jz      invalid_logical_value
  1108.         cmp     esi,edi
  1109.         je      leave_logical_value_intact
  1110.         rep     movs byte [edi],[esi]
  1111.         xor     al,al
  1112.         ret
  1113.       leave_logical_value_intact:
  1114.         add     edi,ecx
  1115.         add     esi,ecx
  1116.         xor     al,al
  1117.         ret
  1118.       compare_symbols:
  1119.         lea     ecx,[esi-1]
  1120.         sub     ecx,edx
  1121.         mov     eax,edx
  1122.         sub     eax,ebx
  1123.         cmp     ecx,eax
  1124.         jne     preevaluated_false
  1125.         push    esi edi
  1126.         mov     esi,ebx
  1127.         lea     edi,[edx+1]
  1128.         repe    cmps byte [esi],[edi]
  1129.         pop     edi esi
  1130.         je      preevaluated_true
  1131.       preevaluated_false:
  1132.         mov     eax,edi
  1133.         sub     eax,ebp
  1134.         test    eax,1
  1135.         jnz     store_true
  1136.       store_false:
  1137.         mov     edi,ebp
  1138.         mov     al,'0'
  1139.         ret
  1140.       preevaluated_true:
  1141.         mov     eax,edi
  1142.         sub     eax,ebp
  1143.         test    eax,1
  1144.         jnz     store_false
  1145.       store_true:
  1146.         mov     edi,ebp
  1147.         mov     al,'1'
  1148.         ret
  1149.       compare_symbol_types:
  1150.         push    esi
  1151.         lea     esi,[edx+1]
  1152.       type_comparison:
  1153.         cmp     esi,[esp]
  1154.         je      types_compared
  1155.         mov     al,[esi]
  1156.         cmp     al,[ebx]
  1157.         jne     different_type
  1158.         cmp     al,'('
  1159.         jne     equal_type
  1160.         mov     al,[esi+1]
  1161.         mov     ah,[ebx+1]
  1162.         cmp     al,ah
  1163.         je      equal_type
  1164.         or      al,al
  1165.         jz      different_type
  1166.         or      ah,ah
  1167.         jz      different_type
  1168.         cmp     al,'.'
  1169.         je      different_type
  1170.         cmp     ah,'.'
  1171.         je      different_type
  1172.       equal_type:
  1173.         call    skip_symbol
  1174.         xchg    esi,ebx
  1175.         call    skip_symbol
  1176.         xchg    esi,ebx
  1177.         jmp     type_comparison
  1178.       types_compared:
  1179.         pop     esi
  1180.         cmp     byte [ebx],0F7h
  1181.         jne     preevaluated_false
  1182.         jmp     preevaluated_true
  1183.       different_type:
  1184.         pop     esi
  1185.         jmp     preevaluated_false
  1186.       scan_symbols_list:
  1187.         push    edi esi
  1188.         lea     esi,[edx+1]
  1189.         sub     edx,ebx
  1190.         lods    byte [esi]
  1191.         cmp     al,'<'
  1192.         jne     invalid_symbols_list
  1193.       get_next_from_list:
  1194.         mov     edi,esi
  1195.       get_from_list:
  1196.         cmp     byte [esi],','
  1197.         je      compare_in_list
  1198.         cmp     byte [esi],'>'
  1199.         je      compare_in_list
  1200.         cmp     esi,[esp]
  1201.         jae     invalid_symbols_list
  1202.         call    skip_symbol
  1203.         jmp     get_from_list
  1204.       compare_in_list:
  1205.         mov     ecx,esi
  1206.         sub     ecx,edi
  1207.         cmp     ecx,edx
  1208.         jne     not_equal_length_in_list
  1209.         mov     esi,ebx
  1210.         repe    cmps byte [esi],[edi]
  1211.         mov     esi,edi
  1212.         jne     not_equal_in_list
  1213.       skip_rest_of_list:
  1214.         cmp     byte [esi],'>'
  1215.         je      check_list_end
  1216.         cmp     esi,[esp]
  1217.         jae     invalid_symbols_list
  1218.         call    skip_symbol
  1219.         jmp     skip_rest_of_list
  1220.       check_list_end:
  1221.         inc     esi
  1222.         cmp     esi,[esp]
  1223.         jne     invalid_symbols_list
  1224.         pop     esi edi
  1225.         jmp     preevaluated_true
  1226.       not_equal_in_list:
  1227.         add     esi,ecx
  1228.       not_equal_length_in_list:
  1229.         lods    byte [esi]
  1230.         cmp     al,','
  1231.         je      get_next_from_list
  1232.         cmp     esi,[esp]
  1233.         jne     invalid_symbols_list
  1234.         pop     esi edi
  1235.         jmp     preevaluated_false
  1236.       invalid_symbols_list:
  1237.         pop     esi edi
  1238.         jmp     invalid_logical_value
  1239.