Subversion Repositories Kolibri OS

Rev

Blame | Last modification | View Log | Download | RSS feed

  1.  
  2. ; flat assembler core
  3. ; Copyright (c) 1999-2009, Tomasz Grysztar.
  4. ; All rights reserved.
  5.  
  6. convert_expression:
  7.         push    ebp
  8.         call    get_fp_value
  9.         jnc     fp_expression
  10.         mov     [current_offset],esp
  11.       expression_loop:
  12.         push    edi
  13.         mov     edi,single_operand_operators
  14.         call    get_operator
  15.         pop     edi
  16.         or      al,al
  17.         jz      expression_element
  18.         push    eax
  19.         jmp     expression_loop
  20.       expression_element:
  21.         mov     al,[esi]
  22.         cmp     al,1Ah
  23.         je      expression_number
  24.         cmp     al,22h
  25.         je      expression_number
  26.         cmp     al,'('
  27.         je      expression_number
  28.         mov     al,'!'
  29.         stos    byte [edi]
  30.         jmp     expression_operator
  31.       expression_number:
  32.         call    convert_number
  33.       expression_operator:
  34.         push    edi
  35.         mov     edi,operators
  36.         call    get_operator
  37.         pop     edi
  38.         or      al,al
  39.         jz      expression_end
  40.       operators_loop:
  41.         cmp     esp,[current_offset]
  42.         je      push_operator
  43.         mov     bl,al
  44.         and     bl,0F0h
  45.         mov     bh,byte [esp]
  46.         and     bh,0F0h
  47.         cmp     bl,bh
  48.         ja      push_operator
  49.         pop     ebx
  50.         mov     byte [edi],bl
  51.         inc     edi
  52.         jmp     operators_loop
  53.       push_operator:
  54.         push    eax
  55.         jmp     expression_loop
  56.       expression_end:
  57.         cmp     esp,[current_offset]
  58.         je      expression_converted
  59.         pop     eax
  60.         stos    byte [edi]
  61.         jmp     expression_end
  62.       expression_converted:
  63.         pop     ebp
  64.         ret
  65.       fp_expression:
  66.         mov     al,'.'
  67.         stos    byte [edi]
  68.         mov     eax,[fp_value]
  69.         stos    dword [edi]
  70.         mov     eax,[fp_value+4]
  71.         stos    dword [edi]
  72.         mov     eax,[fp_value+8]
  73.         stos    dword [edi]
  74.         pop     ebp
  75.         ret
  76.  
  77. convert_number:
  78.         lea     eax,[edi-10h]
  79.         cmp     eax,[labels_list]
  80.         jae     out_of_memory
  81.         cmp     byte [esi],'('
  82.         je      expression_value
  83.         inc     edi
  84.         call    get_number
  85.         jc      symbol_value
  86.         or      ebp,ebp
  87.         jz      valid_number
  88.         mov     byte [edi-1],0Fh
  89.         ret
  90.       valid_number:
  91.         cmp     dword [edi+4],0
  92.         jne     qword_number
  93.         cmp     word [edi+2],0
  94.         jne     dword_number
  95.         cmp     byte [edi+1],0
  96.         jne     word_number
  97.       byte_number:
  98.         mov     byte [edi-1],1
  99.         inc     edi
  100.         ret
  101.       qword_number:
  102.         mov     byte [edi-1],8
  103.         add     edi,8
  104.         ret
  105.       dword_number:
  106.         mov     byte [edi-1],4
  107.         scas    dword [edi]
  108.         ret
  109.       word_number:
  110.         mov     byte [edi-1],2
  111.         scas    word [edi]
  112.         ret
  113.       expression_value:
  114.         mov     eax,esp
  115.         sub     eax,100h
  116.         jc      stack_overflow
  117.         cmp     eax,[stack_limit]
  118.         jb      stack_overflow
  119.         inc     esi
  120.         push    [current_offset]
  121.         call    convert_expression
  122.         pop     [current_offset]
  123.         lods    byte [esi]
  124.         cmp     al,')'
  125.         jne     invalid_expression
  126.         ret
  127.       symbol_value:
  128.         push    edi
  129.         mov     edi,address_registers
  130.         call    get_operator
  131.         or      al,al
  132.         jnz     register_value
  133.         mov     edi,directive_operators
  134.         call    get_operator
  135.         pop     edi
  136.         or      al,al
  137.         jnz     broken_value
  138.         lods    byte [esi]
  139.         cmp     al,1Ah
  140.         jne     invalid_value
  141.         lods    byte [esi]
  142.         movzx   ecx,al
  143.         call    get_label_id
  144.       store_label_value:
  145.         mov     byte [edi-1],11h
  146.         stos    dword [edi]
  147.         ret
  148.       broken_value:
  149.         mov     eax,0Fh
  150.         jmp     store_label_value
  151.       register_value:
  152.         pop     edi
  153.         mov     byte [edi-1],10h
  154.         stos    byte [edi]
  155.         ret
  156.  
  157. get_number:
  158.         xor     ebp,ebp
  159.         lods    byte [esi]
  160.         cmp     al,22h
  161.         je      get_text_number
  162.         cmp     al,1Ah
  163.         jne     not_number
  164.         lods    byte [esi]
  165.         movzx   ecx,al
  166.         mov     [number_start],esi
  167.         mov     al,[esi]
  168.         cmp     al,'$'
  169.         je      number_begin
  170.         sub     al,30h
  171.         cmp     al,9
  172.         ja      invalid_number
  173.       number_begin:
  174.         mov     ebx,esi
  175.         add     esi,ecx
  176.         push    esi
  177.         dec     esi
  178.         mov     dword [edi],0
  179.         mov     dword [edi+4],0
  180.         cmp     byte [ebx],'$'
  181.         je      pascal_hex_number
  182.         cmp     word [ebx],'0x'
  183.         je      get_hex_number
  184.         mov     al,[esi]
  185.         dec     esi
  186.         cmp     al,'h'
  187.         je      get_hex_number
  188.         cmp     al,'b'
  189.         je      get_bin_number
  190.         cmp     al,'d'
  191.         je      get_dec_number
  192.         cmp     al,'o'
  193.         je      get_oct_number
  194.         cmp     al,'H'
  195.         je      get_hex_number
  196.         cmp     al,'B'
  197.         je      get_bin_number
  198.         cmp     al,'D'
  199.         je      get_dec_number
  200.         cmp     al,'O'
  201.         je      get_oct_number
  202.         inc     esi
  203.       get_dec_number:
  204.         mov     ebx,esi
  205.         mov     esi,[number_start]
  206.       get_dec_digit:
  207.         cmp     esi,ebx
  208.         ja      number_ok
  209.         cmp     byte [esi],27h
  210.         je      next_dec_digit
  211.         xor     edx,edx
  212.         mov     eax,[edi]
  213.         shld    edx,eax,2
  214.         shl     eax,2
  215.         add     eax,[edi]
  216.         adc     edx,0
  217.         add     eax,eax
  218.         adc     edx,edx
  219.         mov     [edi],eax
  220.         mov     eax,[edi+4]
  221.         add     eax,eax
  222.         jc      dec_out_of_range
  223.         add     eax,eax
  224.         jc      dec_out_of_range
  225.         add     eax,[edi+4]
  226.         jc      dec_out_of_range
  227.         add     eax,eax
  228.         jc      dec_out_of_range
  229.         add     eax,edx
  230.         jc      dec_out_of_range
  231.         mov     [edi+4],eax
  232.         movzx   eax,byte [esi]
  233.         sub     al,30h
  234.         cmp     al,9
  235.         ja      bad_number
  236.         add     [edi],eax
  237.         adc     dword [edi+4],0
  238.         jc      dec_out_of_range
  239.       next_dec_digit:
  240.         inc     esi
  241.         jmp     get_dec_digit
  242.       dec_out_of_range:
  243.         or      ebp,-1
  244.         inc     esi
  245.         jmp     get_dec_digit
  246.       bad_number:
  247.         pop     eax
  248.       invalid_number:
  249.         mov     esi,[number_start]
  250.         dec     esi
  251.       not_number:
  252.         dec     esi
  253.         stc
  254.         ret
  255.       get_bin_number:
  256.         xor     bl,bl
  257.       get_bin_digit:
  258.         cmp     esi,[number_start]
  259.         jb      number_ok
  260.         movzx   eax,byte [esi]
  261.         cmp     al,27h
  262.         je      bin_digit_skip
  263.         sub     al,30h
  264.         cmp     al,1
  265.         ja      bad_number
  266.         xor     edx,edx
  267.         mov     cl,bl
  268.         dec     esi
  269.         cmp     bl,64
  270.         je      bin_out_of_range
  271.         inc     bl
  272.         cmp     cl,32
  273.         jae     bin_digit_high
  274.         shl     eax,cl
  275.         or      dword [edi],eax
  276.         jmp     get_bin_digit
  277.       bin_digit_high:
  278.         sub     cl,32
  279.         shl     eax,cl
  280.         or      dword [edi+4],eax
  281.         jmp     get_bin_digit
  282.       bin_out_of_range:
  283.         or      al,al
  284.         jz      get_bin_digit
  285.         or      ebp,-1
  286.         jmp     get_bin_digit
  287.       bin_digit_skip:
  288.         dec     esi
  289.         jmp     get_bin_digit
  290.       pascal_hex_number:
  291.         cmp     cl,1
  292.         je      bad_number
  293.       get_hex_number:
  294.         xor     bl,bl
  295.       get_hex_digit:
  296.         cmp     esi,[number_start]
  297.         jb      number_ok
  298.         movzx   eax,byte [esi]
  299.         cmp     al,27h
  300.         je      hex_digit_skip
  301.         cmp     al,'x'
  302.         je      hex_number_ok
  303.         cmp     al,'$'
  304.         je      pascal_hex_ok
  305.         sub     al,30h
  306.         cmp     al,9
  307.         jbe     hex_digit_ok
  308.         sub     al,7
  309.         cmp     al,15
  310.         jbe     hex_letter_digit_ok
  311.         sub     al,20h
  312.         cmp     al,15
  313.         ja      bad_number
  314.       hex_letter_digit_ok:
  315.         cmp     al,10
  316.         jb      bad_number
  317.       hex_digit_ok:
  318.         xor     edx,edx
  319.         mov     cl,bl
  320.         dec     esi
  321.         cmp     bl,64
  322.         je      hex_out_of_range
  323.         add     bl,4
  324.         cmp     cl,32
  325.         jae     hex_digit_high
  326.         shl     eax,cl
  327.         or      dword [edi],eax
  328.         jmp     get_hex_digit
  329.       hex_digit_high:
  330.         sub     cl,32
  331.         shl     eax,cl
  332.         or      dword [edi+4],eax
  333.         jmp     get_hex_digit
  334.       hex_out_of_range:
  335.         or      al,al
  336.         jz      get_hex_digit
  337.         or      ebp,-1
  338.         jmp     get_hex_digit
  339.       hex_digit_skip:
  340.         dec     esi
  341.         jmp     get_hex_digit
  342.       get_oct_number:
  343.         xor     bl,bl
  344.       get_oct_digit:
  345.         cmp     esi,[number_start]
  346.         jb      number_ok
  347.         movzx   eax,byte [esi]
  348.         cmp     al,27h
  349.         je      oct_digit_skip
  350.         sub     al,30h
  351.         cmp     al,7
  352.         ja      bad_number
  353.       oct_digit_ok:
  354.         xor     edx,edx
  355.         mov     cl,bl
  356.         dec     esi
  357.         cmp     bl,64
  358.         jae     oct_out_of_range
  359.         add     bl,3
  360.         cmp     cl,30
  361.         je      oct_digit_wrap
  362.         ja      oct_digit_high
  363.         shl     eax,cl
  364.         or      dword [edi],eax
  365.         jmp     get_oct_digit
  366.       oct_digit_wrap:
  367.         shl     eax,cl
  368.         adc     dword [edi+4],0
  369.         or      dword [edi],eax
  370.         jmp     get_oct_digit
  371.       oct_digit_high:
  372.         sub     cl,32
  373.         shl     eax,cl
  374.         or      dword [edi+4],eax
  375.         jmp     get_oct_digit
  376.       oct_digit_skip:
  377.         dec     esi
  378.         jmp     get_oct_digit
  379.       oct_out_of_range:
  380.         or      al,al
  381.         jz      get_oct_digit
  382.         or      ebp,-1
  383.         jmp     get_oct_digit
  384.       hex_number_ok:
  385.         dec     esi
  386.       pascal_hex_ok:
  387.         cmp     esi,[number_start]
  388.         jne     bad_number
  389.       number_ok:
  390.         pop     esi
  391.       number_done:
  392.         clc
  393.         ret
  394.       get_text_number:
  395.         lods    dword [esi]
  396.         mov     edx,eax
  397.         xor     bl,bl
  398.         mov     dword [edi],0
  399.         mov     dword [edi+4],0
  400.       get_text_character:
  401.         sub     edx,1
  402.         jc      number_done
  403.         movzx   eax,byte [esi]
  404.         inc     esi
  405.         mov     cl,bl
  406.         cmp     bl,64
  407.         je      text_out_of_range
  408.         add     bl,8
  409.         cmp     cl,32
  410.         jae     text_character_high
  411.         shl     eax,cl
  412.         or      dword [edi],eax
  413.         jmp     get_text_character
  414.       text_character_high:
  415.         sub     cl,32
  416.         shl     eax,cl
  417.         or      dword [edi+4],eax
  418.         jmp     get_text_character
  419.       text_out_of_range:
  420.         or      ebp,-1
  421.         jmp     get_text_character
  422.  
  423. get_fp_value:
  424.         push    edi esi
  425.         lods    byte [esi]
  426.         cmp     al,1Ah
  427.         je      fp_value_start
  428.         cmp     al,'-'
  429.         je      fp_sign_ok
  430.         cmp     al,'+'
  431.         jne     not_fp_value
  432.       fp_sign_ok:
  433.         lods    byte [esi]
  434.         cmp     al,1Ah
  435.         jne     not_fp_value
  436.       fp_value_start:
  437.         lods    byte [esi]
  438.         movzx   ecx,al
  439.         cmp     cl,1
  440.         jbe     not_fp_value
  441.         lea     edx,[esi+1]
  442.         xor     ah,ah
  443.       check_fp_value:
  444.         lods    byte [esi]
  445.         cmp     al,'.'
  446.         je      fp_character_dot
  447.         cmp     al,'E'
  448.         je      fp_character_exp
  449.         cmp     al,'e'
  450.         je      fp_character_exp
  451.         cmp     al,'F'
  452.         je      fp_last_character
  453.         cmp     al,'f'
  454.         je      fp_last_character
  455.       digit_expected:
  456.         cmp     al,'0'
  457.         jb      not_fp_value
  458.         cmp     al,'9'
  459.         ja      not_fp_value
  460.         jmp     fp_character_ok
  461.       fp_character_dot:
  462.         cmp     esi,edx
  463.         je      not_fp_value
  464.         or      ah,ah
  465.         jnz     not_fp_value
  466.         or      ah,1
  467.         lods    byte [esi]
  468.         loop    digit_expected
  469.       not_fp_value:
  470.         pop     esi edi
  471.         stc
  472.         ret
  473.       fp_last_character:
  474.         cmp     cl,1
  475.         jne     not_fp_value
  476.         or      ah,4
  477.         jmp     fp_character_ok
  478.       fp_character_exp:
  479.         cmp     esi,edx
  480.         je      not_fp_value
  481.         cmp     ah,1
  482.         ja      not_fp_value
  483.         or      ah,2
  484.         cmp     ecx,1
  485.         jne     fp_character_ok
  486.         cmp     byte [esi],'+'
  487.         je      fp_exp_sign
  488.         cmp     byte [esi],'-'
  489.         jne     fp_character_ok
  490.       fp_exp_sign:
  491.         inc     esi
  492.         cmp     byte [esi],1Ah
  493.         jne     not_fp_value
  494.         inc     esi
  495.         lods    byte [esi]
  496.         movzx   ecx,al
  497.         inc     ecx
  498.       fp_character_ok:
  499.         dec     ecx
  500.         jnz     check_fp_value
  501.         or      ah,ah
  502.         jz      not_fp_value
  503.         pop     esi
  504.         lods    byte [esi]
  505.         mov     [fp_sign],0
  506.         cmp     al,1Ah
  507.         je      fp_get
  508.         inc     esi
  509.         cmp     al,'+'
  510.         je      fp_get
  511.         mov     [fp_sign],1
  512.       fp_get:
  513.         lods    byte [esi]
  514.         movzx   ecx,al
  515.         xor     edx,edx
  516.         mov     edi,fp_value
  517.         mov     [edi],edx
  518.         mov     [edi+4],edx
  519.         mov     [edi+12],edx
  520.         call    fp_optimize
  521.         mov     [fp_format],0
  522.         mov     al,[esi]
  523.       fp_before_dot:
  524.         lods    byte [esi]
  525.         cmp     al,'.'
  526.         je      fp_dot
  527.         cmp     al,'E'
  528.         je      fp_exponent
  529.         cmp     al,'e'
  530.         je      fp_exponent
  531.         cmp     al,'F'
  532.         je      fp_done
  533.         cmp     al,'f'
  534.         je      fp_done
  535.         sub     al,30h
  536.         mov     edi,fp_value+16
  537.         xor     edx,edx
  538.         mov     dword [edi+12],edx
  539.         mov     dword [edi],edx
  540.         mov     dword [edi+4],edx
  541.         mov     [edi+7],al
  542.         mov     dl,7
  543.         mov     dword [edi+8],edx
  544.         call    fp_optimize
  545.         mov     edi,fp_value
  546.         push    ecx
  547.         mov     ecx,10
  548.         call    fp_mul
  549.         pop     ecx
  550.         mov     ebx,fp_value+16
  551.         call    fp_add
  552.         loop    fp_before_dot
  553.       fp_dot:
  554.         mov     edi,fp_value+16
  555.         xor     edx,edx
  556.         mov     [edi],edx
  557.         mov     [edi+4],edx
  558.         mov     byte [edi+7],80h
  559.         mov     [edi+8],edx
  560.         mov     dword [edi+12],edx
  561.         dec     ecx
  562.         jz      fp_done
  563.       fp_after_dot:
  564.         lods    byte [esi]
  565.         cmp     al,'E'
  566.         je      fp_exponent
  567.         cmp     al,'e'
  568.         je      fp_exponent
  569.         cmp     al,'F'
  570.         je      fp_done
  571.         cmp     al,'f'
  572.         je      fp_done
  573.         inc     [fp_format]
  574.         cmp     [fp_format],80h
  575.         jne     fp_counter_ok
  576.         mov     [fp_format],7Fh
  577.       fp_counter_ok:
  578.         dec     esi
  579.         mov     edi,fp_value+16
  580.         push    ecx
  581.         mov     ecx,10
  582.         call    fp_div
  583.         push    dword [edi]
  584.         push    dword [edi+4]
  585.         push    dword [edi+8]
  586.         push    dword [edi+12]
  587.         lods    byte [esi]
  588.         sub     al,30h
  589.         movzx   ecx,al
  590.         call    fp_mul
  591.         mov     ebx,edi
  592.         mov     edi,fp_value
  593.         call    fp_add
  594.         mov     edi,fp_value+16
  595.         pop     dword [edi+12]
  596.         pop     dword [edi+8]
  597.         pop     dword [edi+4]
  598.         pop     dword [edi]
  599.         pop     ecx
  600.         dec     ecx
  601.         jnz     fp_after_dot
  602.         jmp     fp_done
  603.       fp_exponent:
  604.         or      [fp_format],80h
  605.         xor     edx,edx
  606.         xor     ebp,ebp
  607.         dec     ecx
  608.         jnz     get_exponent
  609.         cmp     byte [esi],'+'
  610.         je      fp_exponent_sign
  611.         cmp     byte [esi],'-'
  612.         jne     fp_done
  613.         not     ebp
  614.       fp_exponent_sign:
  615.         add     esi,2
  616.         lods    byte [esi]
  617.         movzx   ecx,al
  618.       get_exponent:
  619.         movzx   eax,byte [esi]
  620.         inc     esi
  621.         sub     al,30h
  622.         cmp     al,10
  623.         jae     exponent_ok
  624.         imul    edx,10
  625.         cmp     edx,8000h
  626.         jae     value_out_of_range
  627.         add     edx,eax
  628.         loop    get_exponent
  629.       exponent_ok:
  630.         mov     edi,fp_value
  631.         or      edx,edx
  632.         jz      fp_done
  633.         mov     ecx,edx
  634.         or      ebp,ebp
  635.         jnz     fp_negative_power
  636.       fp_power:
  637.         push    ecx
  638.         mov     ecx,10
  639.         call    fp_mul
  640.         pop     ecx
  641.         loop    fp_power
  642.         jmp     fp_done
  643.       fp_negative_power:
  644.         push    ecx
  645.         mov     ecx,10
  646.         call    fp_div
  647.         pop     ecx
  648.         loop    fp_negative_power
  649.       fp_done:
  650.         mov     edi,fp_value
  651.         mov     al,[fp_format]
  652.         mov     [edi+10],al
  653.         mov     al,[fp_sign]
  654.         mov     [edi+11],al
  655.         test    byte [edi+15],80h
  656.         jz      fp_ok
  657.         add     dword [edi],1
  658.         adc     dword [edi+4],0
  659.         jnc     fp_ok
  660.         mov     eax,[edi+4]
  661.         shrd    [edi],eax,1
  662.         shr     eax,1
  663.         or      eax,80000000h
  664.         mov     [edi+4],eax
  665.         inc     word [edi+8]
  666.       fp_ok:
  667.         pop     edi
  668.         clc
  669.         ret
  670.       fp_mul:
  671.         or      ecx,ecx
  672.         jz      fp_zero
  673.         mov     eax,[edi+12]
  674.         mul     ecx
  675.         mov     [edi+12],eax
  676.         mov     ebx,edx
  677.         mov     eax,[edi]
  678.         mul     ecx
  679.         add     eax,ebx
  680.         adc     edx,0
  681.         mov     [edi],eax
  682.         mov     ebx,edx
  683.         mov     eax,[edi+4]
  684.         mul     ecx
  685.         add     eax,ebx
  686.         adc     edx,0
  687.         mov     [edi+4],eax
  688.       .loop:
  689.         or      edx,edx
  690.         jz      .done
  691.         mov     eax,[edi]
  692.         shrd    [edi+12],eax,1
  693.         mov     eax,[edi+4]
  694.         shrd    [edi],eax,1
  695.         shrd    eax,edx,1
  696.         mov     [edi+4],eax
  697.         shr     edx,1
  698.         inc     dword [edi+8]
  699.         cmp     dword [edi+8],8000h
  700.         jge     value_out_of_range
  701.         jmp     .loop
  702.       .done:
  703.         ret
  704.       fp_div:
  705.         mov     eax,[edi+4]
  706.         xor     edx,edx
  707.         div     ecx
  708.         mov     [edi+4],eax
  709.         mov     eax,[edi]
  710.         div     ecx
  711.         mov     [edi],eax
  712.         mov     eax,[edi+12]
  713.         div     ecx
  714.         mov     [edi+12],eax
  715.         mov     ebx,eax
  716.         or      ebx,[edi]
  717.         or      ebx,[edi+4]
  718.         jz      fp_zero
  719.       .loop:
  720.         test    byte [edi+7],80h
  721.         jnz     .exp_ok
  722.         mov     eax,[edi]
  723.         shld    [edi+4],eax,1
  724.         mov     eax,[edi+12]
  725.         shld    [edi],eax,1
  726.         add     eax,eax
  727.         mov     [edi+12],eax
  728.         dec     dword [edi+8]
  729.         add     edx,edx
  730.         jmp     .loop
  731.       .exp_ok:
  732.         mov     eax,edx
  733.         xor     edx,edx
  734.         div     ecx
  735.         add     [edi+12],eax
  736.         adc     dword [edi],0
  737.         adc     dword [edi+4],0
  738.         jnc     .done
  739.         mov     eax,[edi+4]
  740.         mov     ebx,[edi]
  741.         shrd    [edi],eax,1
  742.         shrd    [edi+12],ebx,1
  743.         shr     eax,1
  744.         or      eax,80000000h
  745.         mov     [edi+4],eax
  746.         inc     dword [edi+8]
  747.       .done:
  748.         ret
  749.       fp_add:
  750.         cmp     dword [ebx+8],8000h
  751.         je      .done
  752.         cmp     dword [edi+8],8000h
  753.         je      .copy
  754.         mov     eax,[ebx+8]
  755.         cmp     eax,[edi+8]
  756.         jge     .exp_ok
  757.         mov     eax,[edi+8]
  758.       .exp_ok:
  759.         call    .change_exp
  760.         xchg    ebx,edi
  761.         call    .change_exp
  762.         xchg    ebx,edi
  763.         mov     edx,[ebx+12]
  764.         mov     eax,[ebx]
  765.         mov     ebx,[ebx+4]
  766.         add     [edi+12],edx
  767.         adc     [edi],eax
  768.         adc     [edi+4],ebx
  769.         jnc     .done
  770.         mov     eax,[edi]
  771.         shrd    [edi+12],eax,1
  772.         mov     eax,[edi+4]
  773.         shrd    [edi],eax,1
  774.         shr     eax,1
  775.         or      eax,80000000h
  776.         mov     [edi+4],eax
  777.         inc     dword [edi+8]
  778.       .done:
  779.         ret
  780.       .copy:
  781.         mov     eax,[ebx]
  782.         mov     [edi],eax
  783.         mov     eax,[ebx+4]
  784.         mov     [edi+4],eax
  785.         mov     eax,[ebx+8]
  786.         mov     [edi+8],eax
  787.         mov     eax,[ebx+12]
  788.         mov     [edi+12],eax
  789.         ret
  790.       .change_exp:
  791.         push    ecx
  792.         mov     ecx,eax
  793.         sub     ecx,[ebx+8]
  794.         mov     edx,[ebx+4]
  795.         jecxz   .exp_done
  796.       .exp_loop:
  797.         mov     ebp,[ebx]
  798.         shrd    [ebx+12],ebp,1
  799.         shrd    [ebx],edx,1
  800.         shr     edx,1
  801.         inc     dword [ebx+8]
  802.         loop    .exp_loop
  803.       .exp_done:
  804.         mov     [ebx+4],edx
  805.         pop     ecx
  806.         ret
  807.       fp_optimize:
  808.         mov     eax,[edi]
  809.         mov     ebp,[edi+4]
  810.         or      ebp,[edi]
  811.         or      ebp,[edi+12]
  812.         jz      fp_zero
  813.       .loop:
  814.         test    byte [edi+7],80h
  815.         jnz     .done
  816.         shld    [edi+4],eax,1
  817.         mov     ebp,[edi+12]
  818.         shld    eax,ebp,1
  819.         mov     [edi],eax
  820.         shl     dword [edi+12],1
  821.         dec     dword [edi+8]
  822.         jmp     .loop
  823.       .done:
  824.         ret
  825.       fp_zero:
  826.         mov     dword [edi+8],8000h
  827.         ret
  828.  
  829. calculate_expression:
  830.         mov     [current_offset],edi
  831.         mov     [value_undefined],0
  832.         cmp     byte [esi],0
  833.         je      get_string_value
  834.         cmp     byte [esi],'.'
  835.         je      convert_fp
  836.       calculation_loop:
  837.         lods    byte [esi]
  838.         cmp     al,1
  839.         je      get_byte_number
  840.         cmp     al,2
  841.         je      get_word_number
  842.         cmp     al,4
  843.         je      get_dword_number
  844.         cmp     al,8
  845.         je      get_qword_number
  846.         cmp     al,0Fh
  847.         je      value_out_of_range
  848.         cmp     al,10h
  849.         je      get_register
  850.         cmp     al,11h
  851.         je      get_label
  852.         cmp     al,')'
  853.         je      expression_calculated
  854.         cmp     al,']'
  855.         je      expression_calculated
  856.         cmp     al,'!'
  857.         je      invalid_expression
  858.         sub     edi,14h
  859.         mov     ebx,edi
  860.         sub     ebx,14h
  861.         cmp     al,0E0h
  862.         je      calculate_rva
  863.         cmp     al,0E1h
  864.         je      calculate_plt
  865.         cmp     al,0D0h
  866.         je      calculate_not
  867.         cmp     al,083h
  868.         je      calculate_neg
  869.         mov     dx,[ebx+8]
  870.         or      dx,[edi+8]
  871.         cmp     al,80h
  872.         je      calculate_add
  873.         cmp     al,81h
  874.         je      calculate_sub
  875.         mov     ah,[ebx+12]
  876.         or      ah,[edi+12]
  877.         jz      absolute_values_calculation
  878.         cmp     [error_line],0
  879.         jne     absolute_values_calculation
  880.         mov     eax,[current_line]
  881.         mov     [error_line],eax
  882.         mov     [error],invalid_use_of_symbol
  883.       absolute_values_calculation:
  884.         cmp     al,90h
  885.         je      calculate_mul
  886.         cmp     al,91h
  887.         je      calculate_div
  888.         or      dx,dx
  889.         jnz     invalid_expression
  890.         cmp     al,0A0h
  891.         je      calculate_mod
  892.         cmp     al,0B0h
  893.         je      calculate_and
  894.         cmp     al,0B1h
  895.         je      calculate_or
  896.         cmp     al,0B2h
  897.         je      calculate_xor
  898.         cmp     al,0C0h
  899.         je      calculate_shl
  900.         cmp     al,0C1h
  901.         je      calculate_shr
  902.         jmp     invalid_expression
  903.       expression_calculated:
  904.         sub     edi,14h
  905.         cmp     [value_undefined],0
  906.         je      expression_value_ok
  907.         xor     eax,eax
  908.         mov     [edi],eax
  909.         mov     [edi+4],eax
  910.         mov     [edi+12],al
  911.       expression_value_ok:
  912.         ret
  913.       get_byte_number:
  914.         xor     eax,eax
  915.         lods    byte [esi]
  916.         stos    dword [edi]
  917.         xor     al,al
  918.         stos    dword [edi]
  919.       got_number:
  920.         mov     word [edi-8+8],0
  921.         mov     byte [edi-8+12],0
  922.         mov     dword [edi-8+16],0
  923.         add     edi,0Ch
  924.         jmp     calculation_loop
  925.       get_word_number:
  926.         xor     eax,eax
  927.         lods    word [esi]
  928.         stos    dword [edi]
  929.         xor     ax,ax
  930.         stos    dword [edi]
  931.         jmp     got_number
  932.       get_dword_number:
  933.         movs    dword [edi],[esi]
  934.         xor     eax,eax
  935.         stos    dword [edi]
  936.         jmp     got_number
  937.       get_qword_number:
  938.         movs    dword [edi],[esi]
  939.         movs    dword [edi],[esi]
  940.         jmp     got_number
  941.       get_register:
  942.         mov     byte [edi+9],0
  943.         mov     byte [edi+12],0
  944.         lods    byte [esi]
  945.         mov     [edi+8],al
  946.         mov     byte [edi+10],1
  947.         xor     eax,eax
  948.         mov     [edi+16],eax
  949.         stos    dword [edi]
  950.         stos    dword [edi]
  951.         add     edi,0Ch
  952.         jmp     calculation_loop
  953.       get_label:
  954.         xor     eax,eax
  955.         mov     [edi+8],eax
  956.         mov     [edi+12],al
  957.         mov     [edi+20],eax
  958.         lods    dword [esi]
  959.         cmp     eax,0Fh
  960.         jb      predefined_label
  961.         je      reserved_word_used_as_symbol
  962.         mov     ebx,eax
  963.         mov     ax,[current_pass]
  964.         mov     [ebx+18],ax
  965.         or      byte [ebx+8],8
  966.         test    byte [ebx+8],1
  967.         jz      label_undefined
  968.         cmp     ax,[ebx+16]
  969.         je      label_defined
  970.         test    byte [ebx+8],4
  971.         jnz     label_out_of_scope
  972.         test    byte [ebx+9],1
  973.         jz      label_defined
  974.         mov     eax,[ebx]
  975.         sub     eax,dword [adjustment]
  976.         stos    dword [edi]
  977.         mov     eax,[ebx+4]
  978.         sbb     eax,dword [adjustment+4]
  979.         stos    dword [edi]
  980.         mov     eax,dword [adjustment]
  981.         or      eax,dword [adjustment+4]
  982.         jz      got_label
  983.         or      [next_pass_needed],-1
  984.         jmp     got_label
  985.       label_defined:
  986.         mov     eax,[ebx]
  987.         stos    dword [edi]
  988.         mov     eax,[ebx+4]
  989.         stos    dword [edi]
  990.       got_label:
  991.         mov     al,[ebx+11]
  992.         mov     [edi-8+12],al
  993.         mov     eax,[ebx+12]
  994.         mov     [edi-8+8],eax
  995.         mov     eax,[ebx+20]
  996.         mov     [edi-8+16],eax
  997.         add     edi,0Ch
  998.         mov     al,[ebx+10]
  999.         or      al,al
  1000.         jz      calculation_loop
  1001.         cmp     [size_override],-1
  1002.         je      calculation_loop
  1003.         cmp     [size_override],0
  1004.         je      check_size
  1005.         cmp     [operand_size],0
  1006.         jne     calculation_loop
  1007.         mov     [operand_size],al
  1008.         jmp     calculation_loop
  1009.       check_size:
  1010.         xchg    [operand_size],al
  1011.         or      al,al
  1012.         jz      calculation_loop
  1013.         cmp     al,[operand_size]
  1014.         jne     operand_sizes_do_not_match
  1015.         jmp     calculation_loop
  1016.       current_offset_label:
  1017.         mov     eax,[current_offset]
  1018.       make_current_offset_label:
  1019.         xor     edx,edx
  1020.         sub     eax,dword [org_origin]
  1021.         sbb     edx,dword [org_origin+4]
  1022.         stos    dword [edi]
  1023.         mov     eax,edx
  1024.         stos    dword [edi]
  1025.         mov     eax,[org_registers]
  1026.         stos    dword [edi]
  1027.         mov     al,[labels_type]
  1028.         mov     [edi-12+12],al
  1029.         mov     eax,[org_symbol]
  1030.         mov     [edi-12+16],eax
  1031.         add     edi,8
  1032.         jmp     calculation_loop
  1033.       org_origin_label:
  1034.         mov     eax,[org_start]
  1035.         jmp     make_current_offset_label
  1036.       counter_label:
  1037.         mov     eax,[counter]
  1038.       make_dword_label_value:
  1039.         stos    dword [edi]
  1040.         xor     eax,eax
  1041.         stos    dword [edi]
  1042.         add     edi,0Ch
  1043.         jmp     calculation_loop
  1044.       timestamp_label:
  1045.         call    make_timestamp
  1046.         jmp     make_dword_label_value
  1047.       predefined_label:
  1048.         or      eax,eax
  1049.         jz      current_offset_label
  1050.         cmp     eax,1
  1051.         je      counter_label
  1052.         cmp     eax,2
  1053.         je      timestamp_label
  1054.         cmp     eax,3
  1055.         je      org_origin_label
  1056.         mov     edx,invalid_value
  1057.         jmp     error_undefined
  1058.       label_out_of_scope:
  1059.         mov     edx,symbol_out_of_scope
  1060.         mov     eax,[ebx+24]
  1061.         cmp     [error_line],0
  1062.         jne     error_undefined
  1063.         mov     [error_info],eax
  1064.         jmp     error_undefined
  1065.       label_undefined:
  1066.         mov     edx,undefined_symbol
  1067.         cmp     [error_line],0
  1068.         jne     error_undefined
  1069.         mov     eax,[ebx+24]
  1070.         mov     [error_info],eax
  1071.       error_undefined:
  1072.         cmp     [current_pass],1
  1073.         ja      undefined_value
  1074.       force_next_pass:
  1075.         or      [next_pass_needed],-1
  1076.       undefined_value:
  1077.         mov     byte [edi+12],0
  1078.         or      [value_undefined],-1
  1079.         xor     eax,eax
  1080.         stos    dword [edi]
  1081.         stos    dword [edi]
  1082.         add     edi,0Ch
  1083.         cmp     [error_line],0
  1084.         jne     calculation_loop
  1085.         mov     eax,[current_line]
  1086.         mov     [error_line],eax
  1087.         mov     [error],edx
  1088.         jmp     calculation_loop
  1089.       calculate_add:
  1090.         mov     ecx,[ebx+16]
  1091.         cmp     byte [edi+12],0
  1092.         je      add_values
  1093.         mov     ecx,[edi+16]
  1094.         cmp     byte [ebx+12],0
  1095.         je      add_values
  1096.         cmp     [error_line],0
  1097.         jne     add_values
  1098.         mov     eax,[current_line]
  1099.         mov     [error_line],eax
  1100.         mov     [error],invalid_use_of_symbol
  1101.       add_values:
  1102.         mov     al,[edi+12]
  1103.         or      [ebx+12],al
  1104.         mov     [ebx+16],ecx
  1105.         mov     eax,[edi]
  1106.         add     [ebx],eax
  1107.         mov     eax,[edi+4]
  1108.         adc     [ebx+4],eax
  1109.         or      dx,dx
  1110.         jz      calculation_loop
  1111.         push    esi
  1112.         mov     esi,ebx
  1113.         lea     ebx,[edi+10]
  1114.         mov     cl,[edi+8]
  1115.         call    add_register
  1116.         lea     ebx,[edi+11]
  1117.         mov     cl,[edi+9]
  1118.         call    add_register
  1119.         pop     esi
  1120.         jmp     calculation_loop
  1121.       add_register:
  1122.         or      cl,cl
  1123.         jz      add_register_done
  1124.       add_register_start:
  1125.         cmp     [esi+8],cl
  1126.         jne     add_in_second_slot
  1127.         mov     al,[ebx]
  1128.         add     [esi+10],al
  1129.         jnz     add_register_done
  1130.         mov     byte [esi+8],0
  1131.         ret
  1132.       add_in_second_slot:
  1133.         cmp     [esi+9],cl
  1134.         jne     create_in_first_slot
  1135.         mov     al,[ebx]
  1136.         add     [esi+11],al
  1137.         jnz     add_register_done
  1138.         mov     byte [esi+9],0
  1139.         ret
  1140.       create_in_first_slot:
  1141.         cmp     byte [esi+8],0
  1142.         jne     create_in_second_slot
  1143.         mov     [esi+8],cl
  1144.         mov     al,[ebx]
  1145.         mov     [esi+10],al
  1146.         ret
  1147.       create_in_second_slot:
  1148.         cmp     byte [esi+9],0
  1149.         jne     invalid_expression
  1150.         mov     [esi+9],cl
  1151.         mov     al,[ebx]
  1152.         mov     [esi+11],al
  1153.       add_register_done:
  1154.         ret
  1155.       calculate_sub:
  1156.         xor     ah,ah
  1157.         mov     ah,[ebx+12]
  1158.         mov     al,[edi+12]
  1159.         or      al,al
  1160.         jz      sub_values
  1161.         cmp     al,ah
  1162.         jne     invalid_sub
  1163.         xor     ah,ah
  1164.         mov     ecx,[edi+16]
  1165.         cmp     ecx,[ebx+16]
  1166.         jne     invalid_sub
  1167.       sub_values:
  1168.         mov     [ebx+12],ah
  1169.         mov     eax,[edi]
  1170.         sub     [ebx],eax
  1171.         mov     eax,[edi+4]
  1172.         sbb     [ebx+4],eax
  1173.         or      dx,dx
  1174.         jz      calculation_loop
  1175.         push    esi
  1176.         mov     esi,ebx
  1177.         lea     ebx,[edi+10]
  1178.         mov     cl,[edi+8]
  1179.         call    sub_register
  1180.         lea     ebx,[edi+11]
  1181.         mov     cl,[edi+9]
  1182.         call    sub_register
  1183.         pop     esi
  1184.         jmp     calculation_loop
  1185.       invalid_sub:
  1186.         cmp     [error_line],0
  1187.         jne     sub_values
  1188.         mov     eax,[current_line]
  1189.         mov     [error_line],eax
  1190.         mov     [error],invalid_use_of_symbol
  1191.         jmp     sub_values
  1192.       sub_register:
  1193.         or      cl,cl
  1194.         jz      add_register_done
  1195.         neg     byte [ebx]
  1196.         jmp     add_register_start
  1197.       calculate_mul:
  1198.         or      dx,dx
  1199.         jz      mul_start
  1200.         cmp     word [ebx+8],0
  1201.         jne     mul_start
  1202.         mov     eax,[ebx]
  1203.         xchg    eax,[edi]
  1204.         mov     [ebx],eax
  1205.         mov     eax,[ebx+4]
  1206.         xchg    eax,[edi+4]
  1207.         mov     [ebx+4],eax
  1208.         mov     eax,[ebx+8]
  1209.         xchg    eax,[edi+8]
  1210.         mov     [ebx+8],eax
  1211.         mov     eax,[ebx+12]
  1212.         xchg    eax,[edi+12]
  1213.         mov     [ebx+12],eax
  1214.       mul_start:
  1215.         push    esi edx
  1216.         mov     esi,ebx
  1217.         xor     bl,bl
  1218.         bt      dword [esi+4],31
  1219.         jnc     mul_first_sign_ok
  1220.         not     dword [esi]
  1221.         not     dword [esi+4]
  1222.         add     dword [esi],1
  1223.         adc     dword [esi+4],0
  1224.         not     bl
  1225.       mul_first_sign_ok:
  1226.         bt      dword [edi+4],31
  1227.         jnc     mul_second_sign_ok
  1228.         not     dword [edi]
  1229.         not     dword [edi+4]
  1230.         add     dword [edi],1
  1231.         adc     dword [edi+4],0
  1232.         not     bl
  1233.       mul_second_sign_ok:
  1234.         cmp     dword [esi+4],0
  1235.         jz      mul_numbers
  1236.         cmp     dword [edi+4],0
  1237.         jnz     value_out_of_range
  1238.       mul_numbers:
  1239.         mov     eax,[esi+4]
  1240.         mul     dword [edi]
  1241.         or      edx,edx
  1242.         jnz     value_out_of_range
  1243.         mov     ecx,eax
  1244.         mov     eax,[esi]
  1245.         mul     dword [edi+4]
  1246.         or      edx,edx
  1247.         jnz     value_out_of_range
  1248.         add     ecx,eax
  1249.         jc      value_out_of_range
  1250.         mov     eax,[esi]
  1251.         mul     dword [edi]
  1252.         add     edx,ecx
  1253.         jc      value_out_of_range
  1254.         test    edx,1 shl 31
  1255.         jnz     value_out_of_range
  1256.         mov     [esi],eax
  1257.         mov     [esi+4],edx
  1258.         or      bl,bl
  1259.         jz      mul_ok
  1260.         not     dword [esi]
  1261.         not     dword [esi+4]
  1262.         add     dword [esi],1
  1263.         adc     dword [esi+4],0
  1264.       mul_ok:
  1265.         pop     edx
  1266.         or      dx,dx
  1267.         jz      mul_calculated
  1268.         cmp     word [edi+8],0
  1269.         jne     invalid_value
  1270.         cmp     byte [esi+8],0
  1271.         je      mul_first_register_ok
  1272.         mov     al,[edi]
  1273.         cbw
  1274.         cwde
  1275.         cdq
  1276.         cmp     edx,[edi+4]
  1277.         jne     value_out_of_range
  1278.         cmp     eax,[edi]
  1279.         jne     value_out_of_range
  1280.         imul    byte [esi+10]
  1281.         mov     dl,ah
  1282.         cbw
  1283.         cmp     ah,dl
  1284.         jne     value_out_of_range
  1285.         mov     [esi+10],al
  1286.         or      al,al
  1287.         jnz     mul_first_register_ok
  1288.         mov     [esi+8],al
  1289.       mul_first_register_ok:
  1290.         cmp     byte [esi+9],0
  1291.         je      mul_calculated
  1292.         mov     al,[edi]
  1293.         cbw
  1294.         cwde
  1295.         cdq
  1296.         cmp     edx,[edi+4]
  1297.         jne     value_out_of_range
  1298.         cmp     eax,[edi]
  1299.         jne     value_out_of_range
  1300.         imul    byte [esi+11]
  1301.         mov     dl,ah
  1302.         cbw
  1303.         cmp     ah,dl
  1304.         jne     value_out_of_range
  1305.         mov     [esi+11],al
  1306.         or      al,al
  1307.         jnz     mul_calculated
  1308.         mov     [esi+9],al
  1309.       mul_calculated:
  1310.         pop     esi
  1311.         jmp     calculation_loop
  1312.       calculate_div:
  1313.         push    esi edx
  1314.         mov     esi,ebx
  1315.         call    div_64
  1316.         pop     edx
  1317.         or      dx,dx
  1318.         jz      div_calculated
  1319.         cmp     byte [esi+8],0
  1320.         je      div_first_register_ok
  1321.         mov     al,[edi]
  1322.         cbw
  1323.         cwde
  1324.         cdq
  1325.         cmp     edx,[edi+4]
  1326.         jne     value_out_of_range
  1327.         cmp     eax,[edi]
  1328.         jne     value_out_of_range
  1329.         or      al,al
  1330.         jz      value_out_of_range
  1331.         mov     al,[esi+10]
  1332.         cbw
  1333.         idiv    byte [edi]
  1334.         or      ah,ah
  1335.         jnz     invalid_use_of_symbol
  1336.         mov     [esi+10],al
  1337.       div_first_register_ok:
  1338.         cmp     byte [esi+9],0
  1339.         je      div_calculated
  1340.         mov     al,[edi]
  1341.         cbw
  1342.         cwde
  1343.         cdq
  1344.         cmp     edx,[edi+4]
  1345.         jne     value_out_of_range
  1346.         cmp     eax,[edi]
  1347.         jne     value_out_of_range
  1348.         or      al,al
  1349.         jz      value_out_of_range
  1350.         mov     al,[esi+11]
  1351.         cbw
  1352.         idiv    byte [edi]
  1353.         or      ah,ah
  1354.         jnz     invalid_use_of_symbol
  1355.         mov     [esi+11],al
  1356.       div_calculated:
  1357.         pop     esi
  1358.         jmp     calculation_loop
  1359.       calculate_mod:
  1360.         push    esi
  1361.         mov     esi,ebx
  1362.         call    div_64
  1363.         mov     [esi],eax
  1364.         mov     [esi+4],edx
  1365.         pop     esi
  1366.         jmp     calculation_loop
  1367.       calculate_and:
  1368.         mov     eax,[edi]
  1369.         and     [ebx],eax
  1370.         mov     eax,[edi+4]
  1371.         and     [ebx+4],eax
  1372.         jmp     calculation_loop
  1373.       calculate_or:
  1374.         mov     eax,[edi]
  1375.         or      [ebx],eax
  1376.         mov     eax,[edi+4]
  1377.         or      [ebx+4],eax
  1378.         jmp     calculation_loop
  1379.       calculate_xor:
  1380.         mov     eax,[edi]
  1381.         xor     [ebx],eax
  1382.         mov     eax,[edi+4]
  1383.         xor     [ebx+4],eax
  1384.         jmp     calculation_loop
  1385.       shr_negative:
  1386.         not     dword [edi]
  1387.         not     dword [edi+4]
  1388.         add     dword [edi],1
  1389.         adc     dword [edi+4],0
  1390.       calculate_shl:
  1391.         mov     eax,dword [edi+4]
  1392.         bt      eax,31
  1393.         jc      shl_negative
  1394.         or      eax,eax
  1395.         jnz     zero_value
  1396.         mov     ecx,[edi]
  1397.         cmp     ecx,64
  1398.         jae     zero_value
  1399.         cmp     ecx,32
  1400.         jae     shl_high
  1401.         mov     edx,[ebx+4]
  1402.         mov     eax,[ebx]
  1403.         shld    edx,eax,cl
  1404.         shl     eax,cl
  1405.         mov     [ebx],eax
  1406.         mov     [ebx+4],edx
  1407.         jmp     calculation_loop
  1408.       shl_high:
  1409.         sub     cl,32
  1410.         mov     eax,[ebx]
  1411.         shl     eax,cl
  1412.         mov     [ebx+4],eax
  1413.         mov     dword [ebx],0
  1414.         jmp     calculation_loop
  1415.       shl_negative:
  1416.         not     dword [edi]
  1417.         not     dword [edi+4]
  1418.         add     dword [edi],1
  1419.         adc     dword [edi+4],0
  1420.       calculate_shr:
  1421.         mov     eax,dword [edi+4]
  1422.         bt      eax,31
  1423.         jc      shr_negative
  1424.         or      eax,eax
  1425.         jnz     zero_value
  1426.         mov     ecx,[edi]
  1427.         cmp     ecx,64
  1428.         jae     zero_value
  1429.         cmp     ecx,32
  1430.         jae     shr_high
  1431.         mov     edx,[ebx+4]
  1432.         mov     eax,[ebx]
  1433.         shrd    eax,edx,cl
  1434.         shr     edx,cl
  1435.         mov     [ebx],eax
  1436.         mov     [ebx+4],edx
  1437.         jmp     calculation_loop
  1438.       shr_high:
  1439.         sub     cl,32
  1440.         mov     eax,[ebx+4]
  1441.         shr     eax,cl
  1442.         mov     [ebx],eax
  1443.         mov     dword [ebx+4],0
  1444.         jmp     calculation_loop
  1445.       zero_value:
  1446.         mov     dword [ebx],0
  1447.         mov     dword [ebx+4],0
  1448.         jmp     calculation_loop
  1449.       calculate_not:
  1450.         cmp     word [edi+8],0
  1451.         jne     invalid_expression
  1452.         cmp     byte [edi+12],0
  1453.         je      not_ok
  1454.         cmp     [error_line],0
  1455.         jne     not_ok
  1456.         mov     eax,[current_line]
  1457.         mov     [error_line],eax
  1458.         mov     [error],invalid_use_of_symbol
  1459.       not_ok:
  1460.         cmp     [value_size],1
  1461.         je      not_byte
  1462.         cmp     [value_size],2
  1463.         je      not_word
  1464.         cmp     [value_size],4
  1465.         je      not_dword
  1466.         cmp     [value_size],6
  1467.         je      not_pword
  1468.       not_qword:
  1469.         not     dword [edi]
  1470.         not     dword [edi+4]
  1471.         add     edi,14h
  1472.         jmp     calculation_loop
  1473.       not_byte:
  1474.         cmp     dword [edi+4],0
  1475.         jne     not_qword
  1476.         cmp     word [edi+2],0
  1477.         jne     not_qword
  1478.         cmp     byte [edi+1],0
  1479.         jne     not_qword
  1480.         not     byte [edi]
  1481.         add     edi,14h
  1482.         jmp     calculation_loop
  1483.       not_word:
  1484.         cmp     dword [edi+4],0
  1485.         jne     not_qword
  1486.         cmp     word [edi+2],0
  1487.         jne     not_qword
  1488.         not     word [edi]
  1489.         add     edi,14h
  1490.         jmp     calculation_loop
  1491.       not_dword:
  1492.         cmp     dword [edi+4],0
  1493.         jne     not_qword
  1494.         not     dword [edi]
  1495.         add     edi,14h
  1496.         jmp     calculation_loop
  1497.       not_pword:
  1498.         cmp     word [edi+6],0
  1499.         jne     not_qword
  1500.         not     dword [edi]
  1501.         not     word [edi+4]
  1502.         add     edi,14h
  1503.         jmp     calculation_loop
  1504.       calculate_neg:
  1505.         cmp     word [edi+8],0
  1506.         jne     invalid_expression
  1507.         cmp     byte [edi+12],0
  1508.         je      neg_ok
  1509.         cmp     [error_line],0
  1510.         jne     neg_ok
  1511.         mov     eax,[current_line]
  1512.         mov     [error_line],eax
  1513.         mov     [error],invalid_use_of_symbol
  1514.       neg_ok:
  1515.         mov     eax,[edi]
  1516.         mov     edx,[edi+4]
  1517.         mov     dword [edi],0
  1518.         mov     dword [edi+4],0
  1519.         sub     [edi],eax
  1520.         sbb     [edi+4],edx
  1521.         add     edi,14h
  1522.         jmp     calculation_loop
  1523.       calculate_rva:
  1524.         cmp     word [edi+8],0
  1525.         jne     invalid_expression
  1526.         cmp     [output_format],5
  1527.         je      calculate_gotoff
  1528.         cmp     [output_format],4
  1529.         je      calculate_coff_rva
  1530.         cmp     [output_format],3
  1531.         jne     invalid_expression
  1532.         test    [format_flags],8
  1533.         jnz     pe64_rva
  1534.         mov     al,2
  1535.         bt      [resolver_flags],0
  1536.         jc      rva_type_ok
  1537.         xor     al,al
  1538.       rva_type_ok:
  1539.         cmp     byte [edi+12],al
  1540.         je      rva_ok
  1541.         cmp     [error_line],0
  1542.         jne     rva_ok
  1543.         mov     eax,[current_line]
  1544.         mov     [error_line],eax
  1545.         mov     [error],invalid_use_of_symbol
  1546.       rva_ok:
  1547.         mov     byte [edi+12],0
  1548.         mov     eax,[code_start]
  1549.         mov     eax,[eax+34h]
  1550.         cdq
  1551.         sub     [edi],eax
  1552.         sbb     [edi+4],edx
  1553.         add     edi,14h
  1554.         jmp     calculation_loop
  1555.       pe64_rva:
  1556.         mov     al,4
  1557.         bt      [resolver_flags],0
  1558.         jc      pe64_rva_type_ok
  1559.         xor     al,al
  1560.       pe64_rva_type_ok:
  1561.         cmp     byte [edi+12],al
  1562.         je      pe64_rva_ok
  1563.         cmp     [error_line],0
  1564.         jne     pe64_rva_ok
  1565.         mov     eax,[current_line]
  1566.         mov     [error_line],eax
  1567.         mov     [error],invalid_use_of_symbol
  1568.       pe64_rva_ok:
  1569.         mov     byte [edi+12],0
  1570.         mov     eax,[code_start]
  1571.         mov     edx,[eax+34h]
  1572.         mov     eax,[eax+30h]
  1573.         sub     [edi],eax
  1574.         sbb     [edi+4],edx
  1575.         add     edi,14h
  1576.         jmp     calculation_loop
  1577.       calculate_gotoff:
  1578.         test    [format_flags],8+1
  1579.         jnz     invalid_expression
  1580.       calculate_coff_rva:
  1581.         mov     dl,5
  1582.         cmp     byte [edi+12],2
  1583.         je      change_value_type
  1584.       incorrect_change_of_value_type:
  1585.         cmp     [error_line],0
  1586.         jne     change_value_type
  1587.         mov     eax,[current_line]
  1588.         mov     [error_line],eax
  1589.         mov     [error],invalid_use_of_symbol
  1590.       change_value_type:
  1591.         mov     byte [edi+12],dl
  1592.         add     edi,14h
  1593.         jmp     calculation_loop
  1594.       calculate_plt:
  1595.         cmp     word [edi+8],0
  1596.         jne     invalid_expression
  1597.         cmp     [output_format],5
  1598.         jne     invalid_expression
  1599.         test    [format_flags],1
  1600.         jnz     invalid_expression
  1601.         mov     dl,6
  1602.         mov     dh,2
  1603.         test    [format_flags],8
  1604.         jz      check_value_for_plt
  1605.         mov     dh,4
  1606.       check_value_for_plt:
  1607.         mov     eax,[edi]
  1608.         or      eax,[edi+4]
  1609.         jnz     incorrect_change_of_value_type
  1610.         cmp     byte [edi+12],dh
  1611.         jne     incorrect_change_of_value_type
  1612.         mov     eax,[edi+16]
  1613.         cmp     byte [eax],80h
  1614.         jne     incorrect_change_of_value_type
  1615.         jmp     change_value_type
  1616.       div_64:
  1617.         xor     ebx,ebx
  1618.         cmp     dword [edi],0
  1619.         jne     divider_ok
  1620.         cmp     dword [edi+4],0
  1621.         jne     divider_ok
  1622.         cmp     [next_pass_needed],0
  1623.         je      value_out_of_range
  1624.         jmp     div_done
  1625.       divider_ok:
  1626.         bt      dword [esi+4],31
  1627.         jnc     div_first_sign_ok
  1628.         not     dword [esi]
  1629.         not     dword [esi+4]
  1630.         add     dword [esi],1
  1631.         adc     dword [esi+4],0
  1632.         not     bx
  1633.       div_first_sign_ok:
  1634.         bt      dword [edi+4],31
  1635.         jnc     div_second_sign_ok
  1636.         not     dword [edi]
  1637.         not     dword [edi+4]
  1638.         add     dword [edi],1
  1639.         adc     dword [edi+4],0
  1640.         not     bl
  1641.       div_second_sign_ok:
  1642.         cmp     dword [edi+4],0
  1643.         jne     div_high
  1644.         mov     ecx,[edi]
  1645.         mov     eax,[esi+4]
  1646.         xor     edx,edx
  1647.         div     ecx
  1648.         mov     [esi+4],eax
  1649.         mov     eax,[esi]
  1650.         div     ecx
  1651.         mov     [esi],eax
  1652.         mov     eax,edx
  1653.         xor     edx,edx
  1654.         jmp     div_done
  1655.       div_high:
  1656.         mov     eax,[esi+4]
  1657.         xor     edx,edx
  1658.         div     dword [edi+4]
  1659.         mov     ebx,[esi]
  1660.         mov     [esi],eax
  1661.         mov     dword [esi+4],0
  1662.         mov     ecx,edx
  1663.         mul     dword [edi]
  1664.       div_high_loop:
  1665.         cmp     ecx,edx
  1666.         ja      div_high_done
  1667.         jb      div_high_large_correction
  1668.         cmp     ebx,eax
  1669.         jae     div_high_done
  1670.       div_high_correction:
  1671.         dec     dword [esi]
  1672.         sub     eax,[edi]
  1673.         sbb     edx,[edi+4]
  1674.         jnc     div_high_loop
  1675.       div_high_done:
  1676.         sub     ebx,eax
  1677.         sbb     ecx,edx
  1678.         mov     edx,ecx
  1679.         mov     eax,ebx
  1680.         ret
  1681.       div_high_large_correction:
  1682.         push    eax edx
  1683.         mov     eax,edx
  1684.         sub     eax,ecx
  1685.         xor     edx,edx
  1686.         div     dword [edi+4]
  1687.         shr     eax,1
  1688.         jz      div_high_small_correction
  1689.         sub     [esi],eax
  1690.         push    eax
  1691.         mul     dword [edi+4]
  1692.         sub     dword [esp+4],eax
  1693.         pop     eax
  1694.         mul     dword [edi]
  1695.         sub     dword [esp+4],eax
  1696.         sbb     dword [esp],edx
  1697.         pop     edx eax
  1698.         jmp     div_high_loop
  1699.       div_high_small_correction:
  1700.         pop     edx eax
  1701.         jmp     div_high_correction
  1702.       div_done:
  1703.         or      bh,bh
  1704.         jz      remainder_ok
  1705.         not     eax
  1706.         not     edx
  1707.         add     eax,1
  1708.         adc     edx,0
  1709.       remainder_ok:
  1710.         or      bl,bl
  1711.         jz      div_ok
  1712.         not     dword [esi]
  1713.         not     dword [esi+4]
  1714.         add     dword [esi],1
  1715.         adc     dword [esi+4],0
  1716.       div_ok:
  1717.         ret
  1718.       convert_fp:
  1719.         inc     esi
  1720.         mov     word [edi+8],0
  1721.         mov     byte [edi+12],0
  1722.         mov     al,[value_size]
  1723.         cmp     al,4
  1724.         je      convert_fp_dword
  1725.         cmp     al,8
  1726.         je      convert_fp_qword
  1727.         jmp     invalid_value
  1728.       convert_fp_dword:
  1729.         xor     eax,eax
  1730.         cmp     word [esi+8],8000h
  1731.         je      fp_dword_store
  1732.         mov     bx,[esi+8]
  1733.         mov     eax,[esi+4]
  1734.         shl     eax,1
  1735.         shr     eax,9
  1736.         jnc     fp_dword_ok
  1737.         inc     eax
  1738.         bt      eax,23
  1739.         jnc     fp_dword_ok
  1740.         and     eax,1 shl 23 - 1
  1741.         inc     bx
  1742.         shr     eax,1
  1743.       fp_dword_ok:
  1744.         add     bx,7Fh
  1745.         cmp     bx,0FFh
  1746.         jge     value_out_of_range
  1747.         cmp     bx,0
  1748.         jg      fp_dword_exp_ok
  1749.         or      eax,1 shl 23
  1750.         mov     cx,bx
  1751.         neg     cx
  1752.         inc     cx
  1753.         cmp     cx,23
  1754.         ja      value_out_of_range
  1755.         xor     bx,bx
  1756.         shr     eax,cl
  1757.         jnc     fp_dword_exp_ok
  1758.         inc     eax
  1759.         test    eax,1 shl 23
  1760.         jz      fp_dword_exp_ok
  1761.         and     eax,1 shl 23 - 1
  1762.         inc     bx
  1763.       fp_dword_exp_ok:
  1764.         shl     ebx,23
  1765.         or      eax,ebx
  1766.       fp_dword_store:
  1767.         mov     bl,[esi+11]
  1768.         shl     ebx,31
  1769.         or      eax,ebx
  1770.         mov     [edi],eax
  1771.         xor     eax,eax
  1772.         mov     [edi+4],eax
  1773.         add     esi,13
  1774.         ret
  1775.       convert_fp_qword:
  1776.         xor     eax,eax
  1777.         xor     edx,edx
  1778.         cmp     word [esi+8],8000h
  1779.         je      fp_qword_store
  1780.         mov     bx,[esi+8]
  1781.         mov     eax,[esi]
  1782.         mov     edx,[esi+4]
  1783.         add     eax,eax
  1784.         adc     edx,edx
  1785.         mov     ecx,edx
  1786.         shr     edx,12
  1787.         shrd    eax,ecx,12
  1788.         jnc     fp_qword_ok
  1789.         add     eax,1
  1790.         adc     edx,0
  1791.         bt      edx,20
  1792.         jnc     fp_qword_ok
  1793.         and     edx,1 shl 20 - 1
  1794.         inc     bx
  1795.         shr     edx,1
  1796.         rcr     eax,1
  1797.       fp_qword_ok:
  1798.         add     bx,3FFh
  1799.         cmp     bx,7FFh
  1800.         jge     value_out_of_range
  1801.         cmp     bx,0
  1802.         jg      fp_qword_exp_ok
  1803.         or      edx,1 shl 20
  1804.         mov     cx,bx
  1805.         neg     cx
  1806.         inc     cx
  1807.         cmp     cx,52
  1808.         ja      value_out_of_range
  1809.         cmp     cx,32
  1810.         jbe     fp_qword_small_shift
  1811.         sub     cx,32
  1812.         mov     eax,edx
  1813.         xor     edx,edx
  1814.         shr     eax,cl
  1815.         jmp     fp_qword_shift_done
  1816.       fp_qword_small_shift:
  1817.         mov     ebx,edx
  1818.         shr     edx,cl
  1819.         shrd    eax,ebx,cl
  1820.       fp_qword_shift_done:
  1821.         mov     bx,0
  1822.         jnc     fp_qword_exp_ok
  1823.         add     eax,1
  1824.         adc     edx,0
  1825.         test    edx,1 shl 20
  1826.         jz      fp_qword_exp_ok
  1827.         and     edx,1 shl 20 - 1
  1828.         inc     bx
  1829.       fp_qword_exp_ok:
  1830.         shl     ebx,20
  1831.         or      edx,ebx
  1832.       fp_qword_store:
  1833.         mov     bl,[esi+11]
  1834.         shl     ebx,31
  1835.         or      edx,ebx
  1836.         mov     [edi],eax
  1837.         mov     [edi+4],edx
  1838.         add     esi,13
  1839.         ret
  1840.       get_string_value:
  1841.         inc     esi
  1842.         lods    dword [esi]
  1843.         mov     ecx,eax
  1844.         cmp     ecx,8
  1845.         ja      value_out_of_range
  1846.         mov     edx,edi
  1847.         xor     eax,eax
  1848.         stos    dword [edi]
  1849.         stos    dword [edi]
  1850.         mov     edi,edx
  1851.         rep     movs byte [edi],[esi]
  1852.         mov     edi,edx
  1853.         inc     esi
  1854.         mov     word [edi+8],0
  1855.         mov     byte [edi+12],0
  1856.         ret
  1857.  
  1858. get_byte_value:
  1859.         mov     [value_size],1
  1860.         mov     [size_override],-1
  1861.         call    calculate_expression
  1862.         mov     eax,[edi+16]
  1863.         mov     [symbol_identifier],eax
  1864.         mov     [value_type],0
  1865.         cmp     word [edi+8],0
  1866.         jne     invalid_value
  1867.         cmp     byte [edi+12],0
  1868.         je      check_byte_value
  1869.         cmp     [error_line],0
  1870.         jne     check_byte_value
  1871.         mov     eax,[current_line]
  1872.         mov     [error_line],eax
  1873.         mov     [error],invalid_use_of_symbol
  1874.       check_byte_value:
  1875.         mov     eax,[edi]
  1876.         mov     edx,[edi+4]
  1877.         or      edx,edx
  1878.         jz      byte_positive
  1879.         cmp     edx,-1
  1880.         jne     range_exceeded
  1881.         cmp     eax,-80h
  1882.         jb      range_exceeded
  1883.         ret
  1884.       byte_positive:
  1885.         cmp     eax,100h
  1886.         jae     range_exceeded
  1887.       return_byte_value:
  1888.         ret
  1889.       range_exceeded:
  1890.         xor     eax,eax
  1891.         xor     edx,edx
  1892.         cmp     [error_line],0
  1893.         jne     return_byte_value
  1894.         mov     ecx,[current_line]
  1895.         mov     [error_line],ecx
  1896.         mov     [error],value_out_of_range
  1897.         ret
  1898. get_word_value:
  1899.         mov     [value_size],2
  1900.         mov     [size_override],-1
  1901.         call    calculate_expression
  1902.         cmp     word [edi+8],0
  1903.         jne     invalid_value
  1904.         mov     eax,[edi+16]
  1905.         mov     [symbol_identifier],eax
  1906.         mov     al,[edi+12]
  1907.         mov     [value_type],al
  1908.         cmp     al,2
  1909.         jb      check_word_value
  1910.         cmp     [error_line],0
  1911.         jne     check_word_value
  1912.         mov     eax,[current_line]
  1913.         mov     [error_line],eax
  1914.         mov     [error],invalid_use_of_symbol
  1915.       check_word_value:
  1916.         mov     eax,[edi]
  1917.         mov     edx,[edi+4]
  1918.         or      edx,edx
  1919.         jz      word_positive
  1920.         cmp     edx,-1
  1921.         jne     range_exceeded
  1922.         cmp     eax,-8000h
  1923.         jb      range_exceeded
  1924.         ret
  1925.       word_positive:
  1926.         cmp     eax,10000h
  1927.         jae     range_exceeded
  1928.         ret
  1929. get_dword_value:
  1930.         mov     [value_size],4
  1931.         mov     [size_override],-1
  1932.         call    calculate_expression
  1933.         cmp     word [edi+8],0
  1934.         jne     invalid_value
  1935.         mov     eax,[edi+16]
  1936.         mov     [symbol_identifier],eax
  1937.         mov     al,[edi+12]
  1938.         mov     [value_type],al
  1939.         cmp     al,4
  1940.         jne     check_dword_value
  1941.         mov     [value_type],2
  1942.         mov     eax,[edi]
  1943.         cdq
  1944.         cmp     edx,[edi+4]
  1945.         jne     range_exceeded
  1946.         ret
  1947.       check_dword_value:
  1948.         mov     eax,[edi]
  1949.         mov     edx,[edi+4]
  1950.         or      edx,edx
  1951.         jz      dword_positive
  1952.         cmp     edx,-1
  1953.         jne     range_exceeded
  1954.         bt      eax,31
  1955.         jnc     range_exceeded
  1956.       dword_positive:
  1957.         ret
  1958. get_pword_value:
  1959.         mov     [value_size],6
  1960.         mov     [size_override],-1
  1961.         call    calculate_expression
  1962.         mov     eax,[edi+16]
  1963.         mov     [symbol_identifier],eax
  1964.         cmp     word [edi+8],0
  1965.         jne     invalid_value
  1966.         mov     al,[edi+12]
  1967.         mov     [value_type],al
  1968.         cmp     al,4
  1969.         jne     check_pword_value
  1970.         cmp     [error_line],0
  1971.         jne     check_pword_value
  1972.         mov     eax,[current_line]
  1973.         mov     [error_line],eax
  1974.         mov     [error],invalid_use_of_symbol
  1975.       check_pword_value:
  1976.         mov     eax,[edi]
  1977.         mov     edx,[edi+4]
  1978.         cmp     edx,10000h
  1979.         jge     range_exceeded
  1980.         cmp     edx,-8000h
  1981.         jl      range_exceeded
  1982.         ret
  1983. get_qword_value:
  1984.         mov     [value_size],8
  1985.         mov     [size_override],-1
  1986.         call    calculate_expression
  1987.         cmp     word [edi+8],0
  1988.         jne     invalid_value
  1989.         mov     eax,[edi+16]
  1990.         mov     [symbol_identifier],eax
  1991.         mov     al,[edi+12]
  1992.         mov     [value_type],al
  1993.       check_qword_value:
  1994.         mov     eax,[edi]
  1995.         mov     edx,[edi+4]
  1996.         ret
  1997. get_value:
  1998.         mov     [operand_size],0
  1999.         lods    byte [esi]
  2000.         call    get_size_operator
  2001.         cmp     al,'('
  2002.         jne     invalid_value
  2003.         mov     al,[operand_size]
  2004.         cmp     al,1
  2005.         je      value_byte
  2006.         cmp     al,2
  2007.         je      value_word
  2008.         cmp     al,4
  2009.         je      value_dword
  2010.         cmp     al,6
  2011.         je      value_pword
  2012.         cmp     al,8
  2013.         je      value_qword
  2014.         or      al,al
  2015.         jnz     invalid_value
  2016.       value_qword:
  2017.         call    get_qword_value
  2018.         ret
  2019.       value_pword:
  2020.         call    get_pword_value
  2021.         movzx   edx,dx
  2022.         ret
  2023.       value_dword:
  2024.         call    get_dword_value
  2025.         xor     edx,edx
  2026.         ret
  2027.       value_word:
  2028.         call    get_word_value
  2029.         xor     edx,edx
  2030.         movzx   eax,ax
  2031.         ret
  2032.       value_byte:
  2033.         call    get_byte_value
  2034.         xor     edx,edx
  2035.         movzx   eax,al
  2036.         ret
  2037. get_address_word_value:
  2038.         mov     [address_size],2
  2039.         mov     [value_size],2
  2040.         jmp     calculate_address
  2041. get_address_dword_value:
  2042.         mov     [address_size],4
  2043.         mov     [value_size],4
  2044.         jmp     calculate_address
  2045. get_address_qword_value:
  2046.         mov     [address_size],8
  2047.         mov     [value_size],8
  2048.         jmp     calculate_address
  2049. get_address_value:
  2050.         mov     [address_size],0
  2051.         mov     [value_size],8
  2052.       calculate_address:
  2053.         cmp     byte [esi],'.'
  2054.         je      invalid_address
  2055.         call    calculate_expression
  2056.         mov     eax,[edi+16]
  2057.         mov     [address_symbol],eax
  2058.         mov     al,[edi+12]
  2059.         mov     [value_type],al
  2060.         cmp     al,6
  2061.         je      special_address_type_32bit
  2062.         cmp     al,5
  2063.         je      special_address_type_32bit
  2064.         ja      invalid_use_of_symbol
  2065.         test    al,1
  2066.         jnz     invalid_use_of_symbol
  2067.         or      al,al
  2068.         jz      address_size_ok
  2069.         shl     al,5
  2070.         jmp     address_symbol_ok
  2071.       special_address_type_32bit:
  2072.         mov     al,40h
  2073.       address_symbol_ok:
  2074.         mov     ah,[address_size]
  2075.         or      [address_size],al
  2076.         shr     al,4
  2077.         or      ah,ah
  2078.         jz      address_size_ok
  2079.         cmp     al,ah
  2080.         je      address_size_ok
  2081.         cmp     ax,0804h
  2082.         jne     address_sizes_do_not_agree
  2083.         cmp     [value_type],2
  2084.         ja      value_type_correction_ok
  2085.         mov     [value_type],2
  2086.       value_type_correction_ok:
  2087.         mov     eax,[edi]
  2088.         cdq
  2089.         cmp     edx,[edi+4]
  2090.         je      address_size_ok
  2091.         cmp     [error_line],0
  2092.         jne     address_size_ok
  2093.         mov     ecx,[current_line]
  2094.         mov     [error_line],ecx
  2095.         mov     [error],value_out_of_range
  2096.       address_size_ok:
  2097.         xor     ebx,ebx
  2098.         xor     ecx,ecx
  2099.         mov     cl,[value_type]
  2100.         shl     ecx,16
  2101.         mov     ch,[address_size]
  2102.         cmp     word [edi+8],0
  2103.         je      check_immediate_address
  2104.         mov     al,[edi+8]
  2105.         mov     dl,[edi+10]
  2106.         call    get_address_register
  2107.         mov     al,[edi+9]
  2108.         mov     dl,[edi+11]
  2109.         call    get_address_register
  2110.         mov     ax,bx
  2111.         shr     ah,4
  2112.         shr     al,4
  2113.         or      bh,bh
  2114.         jz      check_address_registers
  2115.         or      bl,bl
  2116.         jz      check_address_registers
  2117.         cmp     al,ah
  2118.         jne     invalid_address
  2119.       check_address_registers:
  2120.         or      al,ah
  2121.         mov     ah,[address_size]
  2122.         and     ah,0Fh
  2123.         jz      address_registers_sizes_ok
  2124.         cmp     al,ah
  2125.         jne     address_sizes_do_not_match
  2126.       address_registers_sizes_ok:
  2127.         cmp     al,4
  2128.         je      sib_allowed
  2129.         cmp     al,8
  2130.         je      sib_allowed
  2131.         cmp     al,0Fh
  2132.         je      check_ip_relative_address
  2133.         or      cl,cl
  2134.         jz      check_word_value
  2135.         cmp     cl,1
  2136.         je      check_word_value
  2137.         jmp     invalid_address
  2138.       address_sizes_do_not_match:
  2139.         cmp     al,0Fh
  2140.         jne     invalid_address
  2141.         mov     al,bh
  2142.         and     al,0Fh
  2143.         cmp     al,ah
  2144.         jne     invalid_address
  2145.       check_ip_relative_address:
  2146.         cmp     bh,0F4h
  2147.         je      check_dword_value
  2148.         cmp     bh,0F8h
  2149.         jne     invalid_address
  2150.         mov     eax,[edi]
  2151.         cdq
  2152.         cmp     edx,[edi+4]
  2153.         jne     range_exceeded
  2154.         ret
  2155.       get_address_register:
  2156.         or      al,al
  2157.         jz      address_register_ok
  2158.         cmp     dl,1
  2159.         jne     scaled_register
  2160.         or      bh,bh
  2161.         jnz     scaled_register
  2162.         mov     bh,al
  2163.       address_register_ok:
  2164.         ret
  2165.       scaled_register:
  2166.         or      bl,bl
  2167.         jnz     invalid_address
  2168.         mov     bl,al
  2169.         mov     cl,dl
  2170.         jmp     address_register_ok
  2171.       sib_allowed:
  2172.         or      bh,bh
  2173.         jnz     check_index_scale
  2174.         cmp     cl,2
  2175.         je      special_index_scale
  2176.         cmp     cl,3
  2177.         je      special_index_scale
  2178.         cmp     cl,5
  2179.         je      special_index_scale
  2180.         cmp     cl,9
  2181.         je      special_index_scale
  2182.       check_index_scale:
  2183.         or      cl,cl
  2184.         jz      check_immediate_address
  2185.         cmp     cl,1
  2186.         je      check_immediate_address
  2187.         cmp     cl,2
  2188.         je      check_immediate_address
  2189.         cmp     cl,4
  2190.         je      check_immediate_address
  2191.         cmp     cl,8
  2192.         je      check_immediate_address
  2193.         jmp     invalid_address
  2194.       special_index_scale:
  2195.         mov     bh,bl
  2196.         dec     cl
  2197.       check_immediate_address:
  2198.         mov     al,[address_size]
  2199.         and     al,0Fh
  2200.         cmp     al,2
  2201.         je      check_word_value
  2202.         cmp     al,4
  2203.         je      check_dword_value
  2204.         cmp     al,8
  2205.         je      check_qword_value
  2206.         or      al,al
  2207.         jnz     invalid_value
  2208.         cmp     [code_type],64
  2209.         jne     check_dword_value
  2210.         jmp     check_qword_value
  2211. calculate_relative_offset:
  2212.         cmp     [value_undefined],0
  2213.         jne     relative_offset_ok
  2214.         test    bh,bh
  2215.         setne   ch
  2216.         cmp     bx,word [org_registers]
  2217.         je      origin_registers_ok
  2218.         xchg    bh,bl
  2219.         xchg    ch,cl
  2220.         cmp     bx,word [org_registers]
  2221.         jne     invalid_value
  2222.       origin_registers_ok:
  2223.         cmp     cx,word [org_registers+2]
  2224.         jne     invalid_value
  2225.         add     eax,dword [org_origin]
  2226.         adc     edx,dword [org_origin+4]
  2227.         sub     eax,edi
  2228.         sbb     edx,0
  2229.         mov     bl,[value_type]
  2230.         or      bl,bl
  2231.         je      relative_offset_ok
  2232.         test    bl,1
  2233.         jnz     invalid_use_of_symbol
  2234.         mov     ecx,[address_symbol]
  2235.         mov     [symbol_identifier],ecx
  2236.         cmp     bl,6
  2237.         je      plt_relative_offset
  2238.         cmp     bl,[labels_type]
  2239.         jne     invalid_use_of_symbol
  2240.         mov     [value_type],0
  2241.         cmp     ecx,[org_symbol]
  2242.         je      relative_offset_ok
  2243.         mov     [value_type],3
  2244.       relative_offset_ok:
  2245.         ret
  2246.       plt_relative_offset:
  2247.         mov     [value_type],7
  2248.         ret
  2249.  
  2250. preevaluate_logical_expression:
  2251.         xor     al,al
  2252.   preevaluate_embedded_logical_expression:
  2253.         mov     [logical_value_wrapping],al
  2254.         push    edi
  2255.         call    preevaluate_logical_value
  2256.       preevaluation_loop:
  2257.         cmp     al,0FFh
  2258.         je      invalid_logical_expression
  2259.         mov     dl,[esi]
  2260.         inc     esi
  2261.         cmp     dl,'|'
  2262.         je      preevaluate_or
  2263.         cmp     dl,'&'
  2264.         je      preevaluate_and
  2265.         cmp     dl,'}'
  2266.         je      preevaluation_done
  2267.         or      dl,dl
  2268.         jnz     invalid_logical_expression
  2269.       preevaluation_done:
  2270.         pop     edx
  2271.         dec     esi
  2272.         ret
  2273.       preevaluate_or:
  2274.         cmp     al,'1'
  2275.         je      quick_true
  2276.         cmp     al,'0'
  2277.         je      leave_only_following
  2278.         push    edi
  2279.         mov     al,dl
  2280.         stos    byte [edi]
  2281.         call    preevaluate_logical_value
  2282.         pop     ebx
  2283.         cmp     al,'0'
  2284.         je      leave_only_preceding
  2285.         cmp     al,'1'
  2286.         jne     preevaluation_loop
  2287.         stos    byte [edi]
  2288.         xor     al,al
  2289.         jmp     preevaluation_loop
  2290.       preevaluate_and:
  2291.         cmp     al,'0'
  2292.         je      quick_false
  2293.         cmp     al,'1'
  2294.         je      leave_only_following
  2295.         push    edi
  2296.         mov     al,dl
  2297.         stos    byte [edi]
  2298.         call    preevaluate_logical_value
  2299.         pop     ebx
  2300.         cmp     al,'1'
  2301.         je      leave_only_preceding
  2302.         cmp     al,'0'
  2303.         jne     preevaluation_loop
  2304.         stos    byte [edi]
  2305.         xor     al,al
  2306.         jmp     preevaluation_loop
  2307.       leave_only_following:
  2308.         mov     edi,[esp]
  2309.         call    preevaluate_logical_value
  2310.         jmp     preevaluation_loop
  2311.       leave_only_preceding:
  2312.         mov     edi,ebx
  2313.         xor     al,al
  2314.         jmp     preevaluation_loop
  2315.       quick_true:
  2316.         call    skip_logical_value
  2317.         jc      invalid_logical_expression
  2318.         mov     edi,[esp]
  2319.         mov     al,'1'
  2320.         jmp     preevaluation_loop
  2321.       quick_false:
  2322.         call    skip_logical_value
  2323.         jc      invalid_logical_expression
  2324.         mov     edi,[esp]
  2325.         mov     al,'0'
  2326.         jmp     preevaluation_loop
  2327.       invalid_logical_expression:
  2328.         pop     edi
  2329.         mov     esi,edi
  2330.         mov     al,0FFh
  2331.         stos    byte [edi]
  2332.         ret
  2333.   skip_logical_value:
  2334.         cmp     byte [esi],'~'
  2335.         jne     negation_skipped
  2336.         inc     esi
  2337.         jmp     skip_logical_value
  2338.       negation_skipped:
  2339.         mov     al,[esi]
  2340.         cmp     al,'{'
  2341.         jne     skip_simple_logical_value
  2342.         inc     esi
  2343.         xchg    al,[logical_value_wrapping]
  2344.         push    eax
  2345.       skip_logical_expression:
  2346.         call    skip_logical_value
  2347.         lods    byte [esi]
  2348.         or      al,al
  2349.         jz      wrongly_structured_logical_expression
  2350.         cmp     al,0Fh
  2351.         je      wrongly_structured_logical_expression
  2352.         cmp     al,'|'
  2353.         je      skip_logical_expression
  2354.         cmp     al,'&'
  2355.         je      skip_logical_expression
  2356.         cmp     al,'}'
  2357.         jne     wrongly_structured_logical_expression
  2358.         pop     eax
  2359.         mov     [logical_value_wrapping],al
  2360.       logical_value_skipped:
  2361.         clc
  2362.         ret
  2363.       wrongly_structured_logical_expression:
  2364.         pop     eax
  2365.         stc
  2366.         ret
  2367.       skip_simple_logical_value:
  2368.         mov     [logical_value_parentheses],0
  2369.       find_simple_logical_value_end:
  2370.         mov     al,[esi]
  2371.         or      al,al
  2372.         jz      logical_value_skipped
  2373.         cmp     al,0Fh
  2374.         je      logical_value_skipped
  2375.         cmp     al,'|'
  2376.         je      logical_value_skipped
  2377.         cmp     al,'&'
  2378.         je      logical_value_skipped
  2379.         cmp     al,'{'
  2380.         je      skip_logical_value_internal_parenthesis
  2381.         cmp     al,'}'
  2382.         jne     skip_logical_value_symbol
  2383.         sub     [logical_value_parentheses],1
  2384.         jnc     skip_logical_value_symbol
  2385.         cmp     [logical_value_wrapping],'{'
  2386.         jne     skip_logical_value_symbol
  2387.         jmp     logical_value_skipped
  2388.       skip_logical_value_internal_parenthesis:
  2389.         inc     [logical_value_parentheses]
  2390.       skip_logical_value_symbol:
  2391.         call    skip_symbol
  2392.         jmp     find_simple_logical_value_end
  2393.   preevaluate_logical_value:
  2394.         mov     ebp,edi
  2395.       preevaluate_negation:
  2396.         cmp     byte [esi],'~'
  2397.         jne     preevaluate_negation_ok
  2398.         movs    byte [edi],[esi]
  2399.         jmp     preevaluate_negation
  2400.       preevaluate_negation_ok:
  2401.         mov     ebx,esi
  2402.         cmp     byte [esi],'{'
  2403.         jne     preevaluate_simple_logical_value
  2404.         lods    byte [esi]
  2405.         stos    byte [edi]
  2406.         push    ebp
  2407.         mov     dl,[logical_value_wrapping]
  2408.         push    edx
  2409.         call    preevaluate_embedded_logical_expression
  2410.         pop     edx
  2411.         mov     [logical_value_wrapping],dl
  2412.         pop     ebp
  2413.         cmp     al,0FFh
  2414.         je      invalid_logical_value
  2415.         cmp     byte [esi],'}'
  2416.         jne     invalid_logical_value
  2417.         or      al,al
  2418.         jnz     preevaluated_expression_value
  2419.         movs    byte [edi],[esi]
  2420.         ret
  2421.       preevaluated_expression_value:
  2422.         inc     esi
  2423.         lea     edx,[edi-1]
  2424.         sub     edx,ebp
  2425.         test    edx,1
  2426.         jz      expression_negation_ok
  2427.         xor     al,1
  2428.       expression_negation_ok:
  2429.         mov     edi,ebp
  2430.         ret
  2431.       invalid_logical_value:
  2432.         mov     edi,ebp
  2433.         mov     al,0FFh
  2434.         ret
  2435.       preevaluate_simple_logical_value:
  2436.         xor     edx,edx
  2437.         mov     [logical_value_parentheses],edx
  2438.       find_logical_value_boundaries:
  2439.         mov     al,[esi]
  2440.         or      al,al
  2441.         jz      logical_value_boundaries_found
  2442.         cmp     al,'{'
  2443.         je      logical_value_internal_parentheses
  2444.         cmp     al,'}'
  2445.         je      logical_value_boundaries_parenthesis_close
  2446.         cmp     al,'|'
  2447.         je      logical_value_boundaries_found
  2448.         cmp     al,'&'
  2449.         je      logical_value_boundaries_found
  2450.         or      edx,edx
  2451.         jnz     next_symbol_in_logical_value
  2452.         cmp     al,0F0h
  2453.         je      preevaluable_logical_operator
  2454.         cmp     al,0F7h
  2455.         je      preevaluable_logical_operator
  2456.         cmp     al,0F6h
  2457.         jne     next_symbol_in_logical_value
  2458.       preevaluable_logical_operator:
  2459.         mov     edx,esi
  2460.       next_symbol_in_logical_value:
  2461.         call    skip_symbol
  2462.         jmp     find_logical_value_boundaries
  2463.       logical_value_internal_parentheses:
  2464.         inc     [logical_value_parentheses]
  2465.         jmp     next_symbol_in_logical_value
  2466.       logical_value_boundaries_parenthesis_close:
  2467.         sub     [logical_value_parentheses],1
  2468.         jnc     next_symbol_in_logical_value
  2469.         cmp     [logical_value_wrapping],'{'
  2470.         jne     next_symbol_in_logical_value
  2471.       logical_value_boundaries_found:
  2472.         or      edx,edx
  2473.         jz      non_preevaluable_logical_value
  2474.         mov     al,[edx]
  2475.         cmp     al,0F0h
  2476.         je      compare_symbols
  2477.         cmp     al,0F7h
  2478.         je      compare_symbol_types
  2479.         cmp     al,0F6h
  2480.         je      scan_symbols_list
  2481.       non_preevaluable_logical_value:
  2482.         mov     ecx,esi
  2483.         mov     esi,ebx
  2484.         sub     ecx,esi
  2485.         jz      invalid_logical_value
  2486.         cmp     esi,edi
  2487.         je      leave_logical_value_intact
  2488.         rep     movs byte [edi],[esi]
  2489.         xor     al,al
  2490.         ret
  2491.       leave_logical_value_intact:
  2492.         add     edi,ecx
  2493.         add     esi,ecx
  2494.         xor     al,al
  2495.         ret
  2496.       compare_symbols:
  2497.         lea     ecx,[esi-1]
  2498.         sub     ecx,edx
  2499.         mov     eax,edx
  2500.         sub     eax,ebx
  2501.         cmp     ecx,eax
  2502.         jne     preevaluated_false
  2503.         push    esi edi
  2504.         mov     esi,ebx
  2505.         lea     edi,[edx+1]
  2506.         repe    cmps byte [esi],[edi]
  2507.         pop     edi esi
  2508.         je      preevaluated_true
  2509.       preevaluated_false:
  2510.         mov     eax,edi
  2511.         sub     eax,ebp
  2512.         test    eax,1
  2513.         jnz     store_true
  2514.       store_false:
  2515.         mov     edi,ebp
  2516.         mov     al,'0'
  2517.         ret
  2518.       preevaluated_true:
  2519.         mov     eax,edi
  2520.         sub     eax,ebp
  2521.         test    eax,1
  2522.         jnz     store_false
  2523.       store_true:
  2524.         mov     edi,ebp
  2525.         mov     al,'1'
  2526.         ret