Subversion Repositories Kolibri OS

Rev

Blame | Last modification | View Log | Download | RSS feed

  1. \ 80386 DISASSEMBLER
  2. \ ANDREW MCKEWAN, APRIL 1994
  3. \ TOM ZIMMER,  05/18/94 PORT TO WIN32F
  4. \ MODIFIED TO WORD IN DECIMAL 08/03/94 10:04 TJZ
  5. \ 06-??-95 SMUB NEXT SEQUENCE DEFINED IN FKERNEL
  6. \ 06-21-95 SMUB REMOVED REDUNDANT COUNT CALLS FROM TXB, LXS.
  7. \ 04-??-97 EXTENDED BY C.L. TO INCLUDE P6 AND MMX INSTRUCTIONS
  8. \ 14-11-2000 Adapted from SPFOPT (Michael Maximov) by Dmitry Yakimov
  9.  
  10. \ ??-11-2000 Fixed FE. FF. (Bandaletov) and H.R (Yakimov)
  11. \ 15-11-2000 Fixed MV2 (Yakimov)
  12. \ 25-12-2000 Added float literals recognition (Yakimov)
  13. \ 26-07-2001 Fixed MVX (Maksimov)
  14. \ 11-05-2004 Fixed FDA and CMV (Serguei Jidkov)
  15.  
  16. CR .( Loading Intel Pentium MMX disassembler...)
  17.  
  18. WARNING @
  19. BASE @
  20. GET-CURRENT
  21. ( warn base wid )
  22.  
  23. WARNING 0!
  24. DECIMAL
  25.  
  26. REQUIRE [DEFINED] lib/include/tools.f
  27. \ REQUIRE [IF] ~mak\CompIF.f
  28. REQUIRE CASE lib/ext/case.f
  29. \ REQUIRE WITHIN lib\include\core-ext.f
  30. REQUIRE NextNFA lib/ext/vocs.f
  31.  
  32. : DEFER VECT ;
  33.  
  34. : DUP>R R> OVER >R >R ;
  35.  
  36. : UMAX ( D1 D2  -- FLAG )
  37.    2DUP U< IF NIP ELSE DROP THEN ;
  38.  
  39.  
  40. 80 CONSTANT MAXSTRING
  41.  
  42. 255 CONSTANT MAXCOUNTED   \ maximum length of contents of a counted string
  43.  
  44. : 0X  BASE @ HEX >R BL WORD ?LITERAL
  45.       R> BASE ! ; IMMEDIATE
  46.  
  47. : "CLIP"        ( a1 n1 -- a1 n1' )   \ clip a string to between 0 and MAXCOUNTED
  48.                MAXCOUNTED MIN 0 MAX ;
  49.  
  50. : PLACE         ( addr len dest -- )
  51.                SWAP "CLIP" SWAP
  52.                2DUP 2>R
  53.                CHAR+ SWAP MOVE
  54.                2R> C! ;
  55.  
  56. : +PLACE        ( addr len dest -- ) \ append string addr,len to counted
  57.                                     \ string dest
  58.                >R "CLIP" MAXCOUNTED  R@ C@ -  MIN R>
  59.                                        \ clip total to MAXCOUNTED string
  60.                2DUP 2>R
  61.  
  62.                COUNT CHARS + SWAP MOVE
  63.                2R> +! ;
  64.  
  65. : C+PLACE       ( c1 a1 -- )    \ append char c1 to the counted string at a1
  66.                DUP 1+! COUNT + 1- C! ;
  67.  
  68.  
  69. : OFF     0! ;
  70.  
  71. : BLANK         ( addr len -- )     \ fill addr for len with spaces (blanks)
  72.                BL FILL ;
  73.  
  74. 128 CONSTANT SPCS-MAX  ( optimization for SPACES )
  75.  
  76. CREATE SPCS  SPCS-MAX ALLOT
  77.       SPCS  SPCS-MAX BLANK
  78.  
  79. C" UPC" FIND NIP 0=
  80. [IF]
  81. : UPC  ( c -- c' )
  82.    DUP [CHAR] Z U>
  83.    IF  0xDF AND
  84.    THEN   ;
  85. [THEN]
  86.  
  87. : (D.)          ( d -- addr len )       TUCK DABS  <# #S ROT SIGN #> ;
  88.  
  89.  
  90. 80 VALUE COLS
  91.  
  92. : H.R           ( n1 n2 -- )    \ display n1 as a hex number right
  93.                                 \ justified in a field of n2 characters
  94.                 BASE @ >R HEX >R
  95.                 0 <# #S #> R> OVER - 0 MAX SPACES TYPE
  96.                 R> BASE ! ;
  97.  
  98. : H.N           ( n1 n2 -- )    \ display n1 as a HEX number of n2 digits
  99.                 BASE @ >R HEX >R
  100.                 0 <# R> 0 ?DO # LOOP #> TYPE
  101.                 R> BASE ! ;
  102.  
  103. 0 VALUE DEFAULT-16BIT?
  104.  
  105. : DEFAULT-16BIT ( -- )
  106.                 TRUE TO DEFAULT-16BIT? ;
  107.  
  108. : DEFAULT-32BIT ( -- )
  109.                 FALSE TO DEFAULT-16BIT? ;
  110.  
  111.       DEFER SHOW-NAME   ( CFA -- )      \ DISPLAY NEAREST SYMBOL
  112.  
  113. 0 VALUE BASE-ADDR
  114.  
  115. VOCABULARY DISASSEMBLER
  116. ALSO DISASSEMBLER DEFINITIONS
  117.  
  118. CREATE S-BUF MAXSTRING ALLOT
  119.  
  120. : >S            ( A1 N1 -- )
  121.                 S-BUF +PLACE ;
  122.  
  123. : 0>S           ( -- )  \ RESET S-BUF
  124.                 S-BUF OFF ;
  125.  
  126. : SSPACES       ( N1 -- )
  127.                 SPCS SWAP S-BUF  +PLACE ;
  128.  
  129. : SSPACE        ( -- )
  130.                 1 SSPACES ;
  131.  
  132. : EMIT>S        ( C1 -- )
  133.                 S-BUF C+PLACE ;
  134.  
  135. : S>            ( -- A1 N1 )
  136.                 S-BUF COUNT ;
  137.  
  138. : (.S")         ( addr len -- )
  139.                S-BUF +PLACE ;
  140.  
  141. : .S"           ( 'TEXT' -- )
  142.                 [CHAR] " PARSE
  143.                POSTPONE SLITERAL
  144.                POSTPONE (.S")  ; IMMEDIATE
  145.  
  146.  
  147. : D.R>S         ( D W -- )
  148.                 >R (D.) R> OVER - SSPACES >S ;
  149.  
  150. : .R>S          ( N W -- )
  151.                 >R  S>D  R>  D.R>S ;
  152.  
  153. : U.R>S         ( U W -- )
  154.                 0 SWAP D.R>S ;
  155.  
  156. : H.>S          ( U -- )
  157.                 BASE @ SWAP  HEX 0 (D.) >S SSPACE   BASE ! ;
  158.  
  159. : H.R>S           ( N1 N2 -- )
  160.                 BASE @ >R HEX >R
  161.                 0 <# #S #> R> OVER - SSPACES >S
  162.                 R> BASE ! ;
  163.  
  164. : ?.NAME>S      ( CFA -- )
  165. \ ELIMINATE " 0X"
  166.                 DUP   1 H.R>S SSPACE
  167.                 NEAR_NFA
  168.                 >R DUP
  169.                 IF .S"  ( " DUP COUNT >S
  170.                      NAME> R> - DUP
  171.                      IF   DUP .S" +" NEGATE H.>S
  172.                      THEN DROP        .S"  ) "
  173.                 ELSE RDROP DROP
  174.                 THEN
  175.                 ;
  176.  
  177. ' ?.NAME>S TO SHOW-NAME
  178.  
  179. \ 32 CONSTANT COMMENT-COL
  180.  
  181. 0 VALUE SIZE
  182. 0 VALUE 16-BIT-DATA
  183. 0 VALUE 16-BIT-ADDR
  184. 0 VALUE PREFIX-OP
  185. 0 VALUE MMX-REG
  186.  
  187. : @+  ( ADDR -- ADDR N )  DUP CELL+ SWAP @ ;
  188. : W@+ ( ADDR -- ADDR N )  DUP 2 + SWAP W@ ;
  189.  
  190. : SEXT  ( BYTE -- N )  DUP 128 AND IF 0xFFFFFF00 OR THEN ;
  191. : MOD/SIB ( MOD-R-R/M -- R/M R MOD ) \ R INCLUDING GENERAL, SPECIAL, SEGMENT, MMX
  192.          ( MOD-OP-R/M -- R/M OP MOD )
  193.          ( S-I-B -- B I S )
  194.          255 AND 8 /MOD 8 /MOD ;
  195.  
  196. : ???   ( N1 -- )
  197.        .S" ??? " DROP ;
  198.  
  199. : SS. ( N ADR LEN W )  >R DROP  SWAP R@ * +  R> >S SSPACE ;
  200.  
  201. : TTTN ( CODE -- ) 15 AND S" O NOB AEE NEBEA S NSP NPL GELEG " 2 SS. ;
  202.  
  203. : SREG  ( SREG -- )  3 RSHIFT 7 AND S" ESCSSSDSFSGSXXXX" 2 SS. ;
  204. : CREG  ( EEE --  )  3 RSHIFT 7 AND S" CR0???CR2CR3CR4?????????" 3 SS. ;
  205. : DREG  ( EEE --  )  3 RSHIFT 7 AND S" DR0DR1DR2DR3??????DR6DR7" 3 SS. ;
  206. : TREG  ( EEE --  )  3 RSHIFT 7 AND S" ?????????TR3TR4TR5TR6TR7" 3 SS. ; \ OBSOLETE
  207. : MREG  ( N -- )  7 AND S" MM0MM1MM2MM3MM4MM5MM6MM7" 3 SS. ;
  208.  
  209. : REG8  ( N -- )  7 AND S" ALCLDLBLAHCHDHBH" 2 SS. ;
  210. : REG16 ( N -- )  7 AND S" AXCXDXBXSPBPSIDI" 2 SS. ;
  211. : REG32 ( N -- )  7 AND S" EAXECXEDXEBXESPEBPESIEDI" 3 SS. ;
  212. : REG16/32      ( N -- )
  213.                16-BIT-DATA
  214.                IF   REG16
  215.                ELSE REG32
  216.                THEN  ;
  217. : REG   ( A N -- A )
  218.        MMX-REG
  219.        IF   MREG
  220.        ELSE SIZE
  221.             IF   REG16/32
  222.             ELSE REG8
  223.             THEN
  224.        THEN
  225. ;
  226.  
  227. : [BASE16] ( R/M -- )   4 - S" [SI][DI][BP][BX]" 4 SS. ;
  228.                        \ R/M = 4 , 5 , 6 , 7
  229. : [IND16]  ( R/M -- )   S" [BX+SI][BX+DI][BP+SI][BP+DI]" 7 SS. ;
  230.                        \ R/M = 0  ,   1  ,   2  ,   3
  231. : [REG16]  ( R/M -- )   DUP 4 <
  232.                        IF    [IND16]
  233.                        ELSE  [BASE16]
  234.                        THEN ;
  235. : [REG32]  ( N -- )     7 AND S" [EAX][ECX][EDX][EBX][ESP][EBP][ESI][EDI]" 5 SS. ;
  236.  
  237.  
  238. : [REG*2]  ( I -- )     S" [EAX*2][ECX*2][EDX*2][EBX*2][XXX*2][EBP*2][ESI*2][EDI*2]" 7 SS. ;
  239. : [REG*4]  ( I -- )     S" [EAX*4][ECX*4][EDX*4][EBX*4][XXX*4][EBP*4][ESI*4][EDI*4]" 7 SS. ;
  240. : [REG*8]  ( I -- )     S" [EAX*8][ECX*8][EDX*8][EBX*8][XXX*8][EBP*8][ESI*8][EDI*8]" 7 SS. ;
  241. : [INDEX]  ( SIB -- )   MOD/SIB OVER 4 =
  242.                        IF    2DROP                     \ NO ESP SCALED INDEX
  243.                        ELSE  CASE ( S )
  244.                                0 OF [REG32] ENDOF
  245.                                1 OF [REG*2] ENDOF
  246.                                2 OF [REG*4] ENDOF
  247.                                3 OF [REG*8] ENDOF
  248.                              ENDCASE
  249.                        THEN DROP ;
  250.  
  251. : DISP8  ( ADR -- ADR' )  COUNT H.>S ;
  252. : DISP16 ( ADR -- ADR' )  W@+ SHOW-NAME ;
  253. : DISP32 ( ADR -- ADR' ) @+ ( BODY> ) SHOW-NAME ;
  254. : DISP16/32 ( ADR -- ADR' )
  255.            16-BIT-ADDR
  256.            IF   DISP16
  257.            ELSE DISP32
  258.            THEN ;
  259.  
  260. : .,     ( -- )           .S" , " ;
  261.  
  262. : .#  ., .S" # " ;
  263.  
  264. : IMM8   ( ADR -- ADR' )  .# COUNT H.>S ;
  265.  
  266. \ : IMM16  ( ADR -- ADR' )  .# W@+ H.>S ;
  267.  
  268. : IMM16/32  ( ADR -- ADR' )
  269.         .# 16-BIT-DATA
  270.         IF   W@+
  271.         ELSE @+
  272.         THEN H.>S ;
  273.  
  274. : SIB   ( ADR MOD -- ADR )
  275.         >R COUNT TUCK 7 AND 5 = R@ 0= AND
  276.         IF    DISP32 SWAP [INDEX] R> DROP       \ EBP BASE AND MOD = 00
  277.         ELSE  R> CASE ( MOD )
  278.                    1 OF DISP8  ENDOF
  279.                    2 OF DISP32 ENDOF
  280.                  ENDCASE
  281.               SWAP DUP [REG32] [INDEX]
  282.         THEN ;
  283.  
  284.  
  285. : MOD-R/M32     ( ADR R/M MOD -- ADR' )
  286.                DUP 3 =
  287.                IF    DROP  REG                         \ MOD = 3, REGISTER CASE
  288.                ELSE  OVER 4 =
  289.                      IF NIP SIB                        \ R/M = 4, SIB CASE
  290.                      ELSE  2DUP 0= SWAP 5 = AND        \ MOD = 0, R/M = 5,
  291.                            IF 2DROP DISP32             \ DISP32 CASE
  292.                            ELSE ROT SWAP
  293.                                 CASE ( MOD )
  294.                                   1 OF DISP8  ENDOF
  295.                                   2 OF DISP32 ENDOF
  296.                                 ENDCASE
  297.                                 SWAP [REG32]
  298.                            THEN
  299.                      THEN
  300.                THEN ;
  301.  
  302. : MOD-R/M16     ( ADR R/M MOD -- ADR' )
  303.                 2DUP 0= SWAP 6 = AND
  304.                 IF   2DROP DISP16                       \ DISP16 CASE
  305.                 ELSE CASE ( MOD )
  306.                        0 OF [REG16]                     ENDOF
  307.                        1 OF SWAP DISP8  SWAP [REG16]    ENDOF
  308.                        2 OF SWAP DISP16 SWAP [REG16]    ENDOF
  309.                        3 OF REG                         ENDOF
  310.                      ENDCASE
  311.                 THEN ;
  312.  
  313. : MOD-R/M ( ADR MODR/M -- ADR' )
  314.          MOD/SIB NIP 16-BIT-ADDR
  315.          IF    MOD-R/M16
  316.          ELSE  MOD-R/M32
  317.          THEN ;
  318.  
  319.  
  320. : R/M8      0 TO SIZE MOD-R/M ;
  321. : R/M16/32  1 TO SIZE MOD-R/M ;
  322. : R/M16     TRUE TO 16-BIT-DATA R/M16/32 ;
  323.  
  324. : R,R/M  ( ADR -- ADR' )
  325.         COUNT DUP 3 RSHIFT REG .,  MOD-R/M ;
  326.  
  327. : R/M,R  ( ADR -- ADR' )
  328.        COUNT DUP>R MOD-R/M ., R> 3 RSHIFT REG ;
  329.  
  330. : R/M  ( ADR OP -- ADR' )
  331.         2 AND
  332.         IF     R,R/M
  333.         ELSE   R/M,R
  334.         THEN  ;
  335.  
  336. \ -------------------- SIMPLE OPCODES --------------------
  337.  
  338. : INH   ( -<NAME>- )
  339.         CREATE
  340.         BL WORD COUNT HERE PLACE
  341.         HERE C@ 1+ ALLOT
  342.         DOES> COUNT >S SSPACE DROP ;
  343.  
  344. INH CLC  CLC
  345. INH STC  STC
  346. INH CLD  CLD
  347. INH STD  STD
  348. \ INH RPNZ REPNZ
  349. \ INH REPZ REPZ
  350. INH CBW  CBW
  351. INH CDQ  CDQ
  352. INH DAA  DAA
  353. INH DAS  DAS
  354. INH AAA  AAA
  355. INH AAS  AAS
  356. \ INH LOCK LOCK
  357. INH INB  INSB
  358. INH OSB  OUTSB
  359. INH SAH  SAHF
  360. INH LAH  LAHF
  361. \ INH AAM  AAM
  362. \ INH AAD  AAD
  363. INH HLT  HLT
  364. INH CMC  CMC
  365. INH XLT  XLAT
  366. INH CLI  CLI
  367. INH STI  STI
  368.  
  369. INH CLT CLTS
  370. INH INV INVD
  371. INH WIV WBINVD
  372. INH UD2 UD2
  373. INH WMR WRMSR
  374. INH RTC RDTSC
  375. INH RMR RDMSR
  376. INH RPC RDPMC
  377. INH EMS EMMS
  378. INH RSM RSM
  379. INH CPU CPUID
  380. INH UD1 UD1
  381. \ INH LSS LSS
  382. \ INH LFS LFS
  383. \ INH LGS LGS
  384.  
  385. \ INH D16: D16:
  386. \ INH A16: A16:
  387. \ INH ES:  ES:
  388. \ INH CS:  CS:
  389. \ INH DS:  DS:
  390. \ INH FS:  FS:
  391. \ INH GS:  GS:
  392.  
  393. : AAM   ( ADR CODE -- ADR' )
  394.        .S" AAM" DROP COUNT DROP ;
  395.  
  396. : AAD   ( ADR CODE -- ADR' )
  397.         .S" AAD" DROP COUNT DROP ;
  398.  
  399. : D16   ( ADR CODE -- ADR' )
  400.        DROP .S" D16:"
  401.        TRUE TO 16-BIT-DATA
  402.        TRUE TO PREFIX-OP
  403.        ;
  404.  
  405. : A16   ( ADR CODE -- ADR' )
  406.         DROP .S" A16:"
  407.         TRUE TO 16-BIT-ADDR
  408.         TRUE TO PREFIX-OP
  409.         ;
  410.  
  411. : RPZ   ( ADR CODE -- ADR' )
  412.        DROP .S" REPNZ"
  413.        TRUE TO PREFIX-OP
  414.        ;
  415.  
  416. : REP   ( ADR CODE -- ADR' )
  417.         DROP .S" REPZ"
  418.         TRUE TO PREFIX-OP
  419.         ;
  420.  
  421. : LOK   ( ADR CODE -- ADR' )  \ THIS SHOULD HAVE ERROR CHECKING ADDED
  422.        DROP .S" LOCK"
  423.        TRUE TO PREFIX-OP
  424.        ;
  425.  
  426. : CS:   ( ADR CODE -- ADR' )
  427.         DROP .S" CS:"
  428.         TRUE TO PREFIX-OP
  429.         ;
  430.  
  431. : DS:   ( ADR CODE -- ADR' )
  432.        DROP .S" DS:"
  433.        TRUE TO PREFIX-OP
  434.        ;
  435.  
  436. : SS:   ( ADR CODE -- ADR' )
  437.         DROP .S" SS:"
  438.         TRUE TO PREFIX-OP
  439.         ;
  440.  
  441. : ES:   ( ADR CODE -- ADR' )
  442.        DROP .S" ES:"
  443.        TRUE TO PREFIX-OP
  444.        ;
  445.  
  446. : GS:   ( ADR CODE -- ADR' )
  447.         DROP .S" GS:"
  448.         TRUE TO PREFIX-OP
  449.         ;
  450.  
  451. : FS:   ( ADR CODE -- ADR' )
  452.        DROP .S" FS:"
  453.        TRUE TO PREFIX-OP
  454.        ;
  455.  
  456. : ISD   ( ADR CODE -- ADR' )
  457.         DROP 16-BIT-DATA
  458.         IF      .S" INSW    "
  459.         ELSE    .S" INSD    "
  460.         THEN ;
  461.  
  462. : OSD   ( ADR CODE -- ADR' )
  463.        DROP 16-BIT-DATA
  464.        IF      .S" OUTSW    "
  465.        ELSE    .S" OUTSD    "
  466.        THEN ;
  467.  
  468. : INP   ( ADDR CODE -- ADDR' )
  469.         .S" IN      " 1 AND
  470.         IF      16-BIT-DATA
  471.                 IF      .S" AX , "
  472.                 ELSE    .S" EAX , "
  473.                 THEN
  474.         ELSE    .S" AL , "
  475.         THEN
  476.         COUNT H.>S ;
  477.  
  478. : OTP   ( ADDR CODE -- ADDR' )
  479.        .S" OUT     " 1 AND
  480.        IF      COUNT H.>S 16-BIT-DATA
  481.                IF      .S" , AX"
  482.                ELSE    .S" , EAX"
  483.                THEN
  484.        ELSE    COUNT H.>S .S" , AL"
  485.        THEN
  486.        ;
  487.  
  488. : IND   ( ADDR CODE -- ADDR' )
  489.         .S" IN      " 1 AND
  490.         IF      16-BIT-DATA
  491.                 IF      .S" AX , DX"
  492.                 ELSE    .S" EAX , DX"
  493.                 THEN
  494.         ELSE    .S" AL , DX"
  495.         THEN
  496.         ;
  497.  
  498. : OTD   ( ADDR CODE -- ADDR' )
  499.        .S" OUT     " 1 AND
  500.        IF      16-BIT-DATA
  501.                IF      .S" DX , AX"
  502.                ELSE    .S" DX , EAX"
  503.                THEN
  504.        ELSE    .S" DX , AL"
  505.        THEN
  506.        ;
  507.  
  508. \ -------------------- ALU OPCODES --------------------
  509.  
  510. : .ALU  ( N -- )
  511.        7 AND S" ADDOR ADCSBBANDSUBXORCMP"  3 SS. 4 SSPACES
  512.    ;
  513.  
  514. : ALU  ( ADR OP -- ADR' )
  515.         DUP 3 RSHIFT .ALU R/M ;
  516.  
  517. : ALI ( ADR OP -- ADR' )
  518.        >R COUNT
  519.        DUP 3 RSHIFT .ALU
  520.        MOD-R/M
  521.        R> 3 AND ?DUP
  522.        IF      1 =
  523.                IF      IMM16/32
  524.                ELSE    .# COUNT SEXT 0 .R>S SSPACE
  525.                THEN
  526.        ELSE    IMM8
  527.        THEN ;
  528.  
  529. : ALA  ( ADR OP -- ADR' )
  530.         DUP 3 RSHIFT .ALU
  531.         1 AND IF 0 REG IMM16/32 ELSE 0 REG8 IMM8 THEN ;
  532.  
  533.  
  534. \ -------------------- TEST/XCHG --------------------
  535.  
  536. : TXB   ( ADDR OP -- ADDR' )
  537.        DUP 3 AND S" TESTTESTXCHGXCHG" 4 SS. 3 SSPACES
  538.        1 AND
  539.        IF      1 TO SIZE R,R/M     \ SMUB REMOVED COUNT
  540.        ELSE    0 TO SIZE R,R/M     \ SMUB REMOVED COUNT
  541.        THEN
  542.        ;
  543.  
  544. : TST   ( ADDR OP -- ADDR' )
  545.         .S" TEST    " 1 AND
  546.         IF      16-BIT-DATA
  547.                 IF   .S" AX , "
  548.                 ELSE .S" EAX , "
  549.                 THEN
  550.                 IMM16/32
  551.         ELSE    .S" AL , " IMM8
  552.         THEN
  553.         ;
  554.  
  555. \ -------------------- INC/DEC ----------------------
  556.  
  557. : INC  ( ADDR OP -- ADDR' )
  558.        .S" INC     " REG16/32 ;
  559.  
  560. : DEC  ( ADDR OP -- ADDR' )
  561.         .S" DEC     " REG16/32 ;
  562.  
  563.  
  564. \ -------------------- PUSH/POP --------------------
  565.  
  566. : PSH   ( ADDR OP -- ADDR' )
  567.        .S" PUSH    " REG16/32 ;
  568.  
  569. : POP   ( ADDR OP -- ADDR' )
  570.         .S" POP     " REG16/32 ;
  571.  
  572. : PSS   ( ADDR OP -- ADDR' )
  573.        .S" PUSH    " SREG ;
  574.  
  575. : PPS   ( ADDR OP -- ADDR' )
  576.         .S" POP     " SREG ;
  577.  
  578. : PSA   ( ADDR OP -- ADDR' )
  579.        DROP 16-BIT-DATA
  580.        IF      .S" PUSHA   "
  581.        ELSE    .S" PUSHAD  "
  582.        THEN ;
  583.  
  584. : PPA   ( ADDR OP -- ADDR' )
  585.         DROP 16-BIT-DATA
  586.         IF      .S" POPA    "
  587.         ELSE    .S" POPAD   "
  588.         THEN ;
  589.  
  590. : PSI   ( ADDR OP -- ADDR' )
  591.        .S" PUSH    " 2 AND
  592.        IF      IMM8
  593.        ELSE    IMM16/32
  594.        THEN ;
  595.  
  596. : PSF   ( ADDR OP -- ADDR' )
  597.         DROP 16-BIT-DATA
  598.         IF      .S" PUSHF   "
  599.         ELSE    .S" PUSHFD  "
  600.         THEN ;
  601.  
  602. : PPF   ( ADDR OP -- ADDR' )
  603.        DROP 16-BIT-DATA
  604.        IF      .S" POPF    "
  605.        ELSE    .S" POPFD   "
  606.        THEN ;
  607.  
  608. : 8F.   ( ADDR OP -- ADDR' )
  609.         DROP COUNT .S" POP     " R/M16/32 ;
  610.  
  611. \ -------------------- MOVE --------------------
  612.  
  613. : MOV  ( ADDR OP -- ADDR' )
  614.        .S" MOV     " R/M ;
  615.  
  616. : MRI  ( ADDR OP -- ADDR' ) ( MOV REGISTER, IMM )
  617.         .S" MOV     " DUP 8 AND
  618.         IF      REG16/32 IMM16/32
  619.         ELSE    REG8 IMM8
  620.         THEN ;
  621.  
  622. : MVI  ( ADR OP -- ADR' )   ( MOV MEM, IMM )
  623.        .S" MOV     " DROP COUNT MOD-R/M
  624.        SIZE
  625.        IF      IMM16/32
  626.        ELSE    IMM8
  627.        THEN
  628.        ;
  629.  
  630. : MRS   ( ADDR OP -- ADDR' )
  631. \ ? REMOVE REDUNDANT >R , R>
  632.         16-BIT-DATA
  633.         IF      .S" MOV     " DROP
  634.                 1 TO SIZE
  635.                 COUNT DUP MOD-R/M .,
  636.                 SREG
  637.         ELSE    ???
  638.         THEN ;
  639.  
  640. : MSR   ( ADDR OP -- ADDR' )
  641.        16-BIT-DATA
  642.        IF      .S" MOV     " DROP
  643.                1 TO SIZE
  644.                COUNT DUP SREG .,
  645.                MOD-R/M
  646.        ELSE    ???
  647.        THEN ;
  648.  
  649. : MRC   ( ADDR OP -- ADDR' )
  650.         .S" MOV     "
  651.         DROP COUNT DUP REG32 .S" , "
  652.         CREG ;
  653.  
  654. : MCR   ( ADDR OP -- ADDR' )
  655.        .S" MOV     "
  656.        DROP COUNT DUP CREG .S" , "
  657.        REG32 ;
  658.  
  659. : MRD   ( ADDR OP -- ADDR' )
  660.         .S" MOV     "
  661.         DROP COUNT DUP REG32 .S" , "
  662.         DREG ;
  663.  
  664. : MDR   ( ADDR OP -- ADDR' )
  665.        .S" MOV     "
  666.        DROP COUNT DUP DREG .S" , "
  667.        REG32 ;
  668.  
  669. : MRT   ( ADDR OP -- ADDR' )
  670. \ OBSOLETE
  671.         .S" MOV     "
  672.         DROP COUNT DUP REG32 .S" , "
  673.         TREG ;
  674.  
  675. : MTR   ( ADDR OP -- ADDR' )
  676. \ OBSOLETE
  677.        .S" MOV     "
  678.        DROP COUNT DUP TREG .S" , "
  679.        REG32 ;
  680.  
  681. : MV1   ( ADDR OP -- ADDR' )
  682.         .S" MOV     " 1 AND
  683.         IF      16-BIT-DATA
  684.                 IF      .S" AX , "
  685.                 ELSE    .S" EAX , "
  686.                 THEN
  687.         ELSE    .S" AL , "
  688.         THEN
  689.         DISP16/32 ;
  690.  
  691. : MV2   ( ADDR OP -- ADDR' )
  692.        .S" MOV     " SWAP DISP16/32 .,
  693.        SWAP 1 AND
  694.        IF      16-BIT-DATA
  695.                IF      .S"  AX"
  696.                ELSE    .S"  EAX"
  697.                THEN
  698.        ELSE    .S"  AL"
  699.        THEN
  700.        ;
  701.  
  702. : LEA  ( ADDR OP -- ADDR' )
  703.         .S" LEA     " DROP  1 TO SIZE R,R/M ;
  704.  
  705. : LXS   ( ADDR OP -- ADDR' )
  706.        1 AND
  707.        IF      .S" LDS     "
  708.        ELSE    .S" LES     "
  709.        THEN
  710.        R,R/M   \ SMUB REMOVED COUNT
  711.        ;
  712.  
  713. : BND  ( ADDR OP -- ADDR' )
  714.         .S" BOUND   " DROP  1 TO SIZE R,R/M ;
  715.  
  716. : ARP   ( ADDR OP -- ADDR' )
  717.        .S" ARPL    " DROP
  718.        1 TO SIZE
  719.        TRUE TO 16-BIT-DATA
  720.        R,R/M
  721.        ;
  722.  
  723. : MLI   ( ADDR OP -- ADDR' )
  724.         1 TO SIZE
  725.         .S" IMUL    " 0x69 =
  726.         IF      R,R/M IMM16/32
  727.         ELSE    R,R/M IMM8
  728.         THEN ;
  729.  
  730. \ -------------------- JUMPS AND CALLS --------------------
  731.  
  732. 0 VALUE MAX_REFERENCE
  733.  
  734. : >MAX_R  DUP MAX_REFERENCE UMAX TO MAX_REFERENCE ;
  735.  
  736. : REL8  ( ADDR OP -- ADDR' )
  737.        COUNT SEXT OVER + BASE-ADDR - >MAX_R H.>S ;
  738.  
  739.  
  740.  
  741. : REL16/32 ( ADDR OP -- ADDR' )
  742.         16-BIT-ADDR
  743.         IF      W@+
  744.         ELSE    @+
  745.         THEN    OVER + BASE-ADDR - >MAX_R SHOW-NAME ;
  746.  
  747. : JSR  ( ADDR OP -- ADDR' )
  748.        .S" CALL    " DROP REL16/32 ;
  749.  
  750. : JMP  ( ADDR OP -- ADDR' )
  751.         .S" JMP     " 2 AND IF REL8 ELSE REL16/32 THEN ;
  752.  
  753. : .JXX  ( ADDR OP -- ADDR' )
  754.        .S" J" TTTN 4 SSPACES ;
  755.  
  756. : BRA  ( ADDR OP -- ADDR' )
  757.         .JXX REL8 ;
  758.  
  759. : LUP  ( ADDR OP -- ADDR' )
  760.        3 AND S" LOOPNZLOOPZ LOOP  JECXZ " 6 SS. 1 SSPACES REL8 ;
  761.  
  762. : LBR  ( ADDR OP -- ADDR' )
  763.         .JXX REL16/32 ;
  764.  
  765. : RTN  ( ADDR OP -- ADDR' )
  766.        .S" RET     NEAR " 1 AND 0=
  767.        IF      W@+ H.>S
  768.        THEN ;
  769.  
  770. : RTF  ( ADDR OP -- ADDR' )
  771.         .S" RET     FAR " 1 AND 0=
  772.         IF      W@+ H.>S
  773.         THEN ;
  774.  
  775. : ENT  ( ADDR OP -- ADDR' )
  776.       DROP
  777.        .S" ENTER   " W@+ H.>S ., COUNT H.>S ;
  778.  
  779. : CIS   ( ADDR OP -- ADDR' )
  780.         0x9A =
  781.         IF      .S" CALL    "
  782.         ELSE    .S" JMP     "
  783.         THEN
  784.         16-BIT-DATA
  785.         IF      .S" PTR16:16 "
  786.         ELSE    .S" PTR16:32 "
  787.         THEN
  788.         COUNT MOD-R/M ;
  789.  
  790. : NT3   ( ADDR OP -- ADDR' )
  791.        DROP .S" INT     3 "
  792.        ;
  793.  
  794. : INT   ( ADDR OP -- ADDR' )
  795.         DROP .S" INT     "
  796.         COUNT H.>S ;
  797.  
  798. INH LEV LEAVE
  799. INH IRT  IRET
  800. INH NTO  INTO
  801.  
  802. \ -------------------- STRING OPS --------------------
  803.  
  804. : STR   INH DOES> COUNT >S  1 AND IF .S" D" ELSE .S" B" THEN ;
  805.  
  806. STR MVS MOVS
  807. STR CPS CMPS
  808. STR STS STOS
  809. STR LDS LODS
  810. STR SCS SCAS
  811.  
  812. \ -------------------- EXCHANGE --------------------
  813.  
  814. : XGA  ( ADDR OP -- ADDR' )
  815.        .S" XCHG     EAX, " REG16/32 ;
  816.  
  817. \ : XCH  ( ADDR OP -- ADDR' )
  818. \       .S" XCHG    " DROP R,R/M ;
  819.  
  820.  
  821. \ -------------------- SHIFTS & ROTATES --------------------
  822.  
  823. : .SHIFT ( N -- )
  824.         7 AND S" ROLRORRCLRCRSHLSHRXXXSAR" 3 SS.  4 SSPACES ;
  825.  
  826. : SHF  ( ADDR OP -- ADDR' )
  827.        >R COUNT
  828.        DUP 3 RSHIFT .SHIFT
  829.        MOD-R/M .,
  830.        R> 0xD2 AND
  831.        CASE
  832.           0xC0 OF COUNT H.>S      ENDOF
  833.           0xD0 OF 1 H.>S          ENDOF
  834.           0xD2 OF 1 REG8          ENDOF
  835.        ENDCASE ;
  836.  
  837. \ -------------------- EXTENDED OPCODES --------------------
  838.  
  839. : WF1  ( ADDR -- ADDR' )
  840.         1+ COUNT DUP
  841.         0x0C0 <
  842.         IF      DUP
  843.                 3 RSHIFT 7 AND
  844.                 CASE 6 OF     .S" FSTENV  "      MOD-R/M   ENDOF
  845.                      7 OF     .S" FSTCW   WORD " MOD-R/M   ENDOF
  846.                      2DROP 2 - DUP .S" FWAIT   "
  847.                 ENDCASE
  848.         ELSE    DROP 2 - .S" FWAIT   "
  849.         THEN ;
  850.  
  851. : WF2  ( ADDR -- ADDR' )
  852.        1+ COUNT
  853.        CASE 0xE2 OF   .S" FCLEX   "  ENDOF
  854.             0xE3 OF   .S" FINIT   "  ENDOF
  855.             SWAP 2 - SWAP .S" FWAIT   "
  856.        ENDCASE ;
  857.  
  858. : WF3  ( ADDR -- ADDR' )
  859.         1+ COUNT DUP 3 RSHIFT 7 AND
  860.         CASE 6 OF     .S" FSAVE   "      MOD-R/M   ENDOF
  861.              7 OF     .S" FSTSW   WORD " MOD-R/M   ENDOF
  862.              2DROP 2 - DUP .S" FWAIT   "
  863.         ENDCASE ;
  864.  
  865. : WF4  ( ADDR -- ADDR' )
  866.        1+ COUNT 0xE0 =
  867.        IF      .S" FSTSW   AX "
  868.        ELSE    2 - .S" FWAIT   "
  869.        THEN ;
  870.  
  871. : FWAITOPS   ( ADDR OP -- ADDR' )
  872.         CASE 0xD9 OF    WF1     ENDOF
  873.              0xDB OF    WF2     ENDOF
  874.              0xDD OF    WF3     ENDOF
  875.              0xDF OF    WF4     ENDOF
  876.              .S" FWAIT   "
  877.         ENDCASE ;
  878.  
  879. : W8F   ( ADDR OP -- ADDR' )
  880.        DROP DUP C@ DUP 0xF8 AND 0xD8 =
  881.        IF      FWAITOPS
  882.        ELSE    DROP .S" WAIT    "
  883.        THEN ;
  884.  
  885. : FALU1   ( XOPCODE -- )
  886.        3 RSHIFT 7 AND
  887.        S" FADD FMUL FCOM FCOMPFSUB FSUBRFDIV FDIVR"
  888.        5 SS. 2 SSPACES ;
  889.  
  890. : FALU5   ( XOPCODE -- )
  891.        3 RSHIFT 7 AND
  892.        S" FADD FMUL ???? ???? FSUBRFSUB FDIVRFDIV "
  893.        5 SS. 2 SSPACES ;
  894.  
  895. : STI.   ( OP -- )
  896.        7 AND .S" ST(" 1 .R>S .S" )";
  897.  
  898. \ : STI.ST   ( OP -- )
  899. \       7 AND
  900. \       .S" ST(" 1 .R>S .S" )" .S"  ST " ;
  901.  
  902. : FD8   ( ADDR OPCODE -- ADDR' )
  903.         DROP COUNT DUP FALU1
  904.         DUP 0xC0 <
  905.         IF      .S" FLOAT " MOD-R/M
  906.         ELSE    DUP 0xF0 AND 0xD0 =
  907.                 IF      STI.
  908.                 ELSE    .S" ST , " STI.
  909.                 THEN
  910.         THEN ;
  911.  
  912. : FDC   ( ADDR OPCODE -- ADDR' )
  913.        DROP COUNT
  914.        DUP DUP 0xC0 <
  915.        IF      FALU1 .S" DOUBLE " MOD-R/M
  916.        ELSE    FALU5 STI. .S"  , ST"
  917.        THEN ;
  918.  
  919. : FNULLARY-F   ( OP -- )
  920.        0x0F AND DUP 8 <
  921.        IF
  922.           S" F2XM1  FYL2X  FPTAN  FPATAN FXTRACTFPREM1 FDECSTPFINCSTP"
  923.        ELSE  8 -
  924.           S" FPREM  FYL2XP1FSQRT  FSINCOSFRNDINTFSCALE FSIN   FCOS   "
  925.        THEN
  926.        7 SS. ;
  927.  
  928. : FNULLARY-E   ( OP -- )
  929.        0x0F AND DUP 8 <
  930.        IF
  931.           S" FCHS   FABS   ???    ???    FTST   FXAM   ???    ???    "
  932.        ELSE  8 -
  933.           S" FLD1   FLDL2T FLDL2E FLDPI  FLDLG2 FLDLN2 FLDZ   ???    "
  934.        THEN
  935.        7 SS. ;
  936.  
  937. : FNULLARY   ( OP -- )
  938.        DUP 0xEF >
  939.        IF      FNULLARY-F EXIT
  940.        THEN
  941.        DUP 0xE0 <
  942.        IF      0xD0 =
  943.                IF      .S" FNOP"
  944.                ELSE    DUP ???
  945.                THEN
  946.                EXIT
  947.        THEN
  948.        FNULLARY-E ;
  949.  
  950.  
  951. \ : FALU2   ( OP -- )
  952. \       3 RSHIFT 7 AND
  953. \       S" FLD    ???    FST    FSTP   FLDENV FLDCW  FNSTENVFNSTCW "
  954. \       7 SS. ;
  955.  
  956. : FD9   ( ADDR OP -- ADDR' )
  957.         DROP COUNT DUP 0xC0 <
  958.         IF      DUP 0x38 AND
  959.                 CASE
  960.                         0x00 OF .S" FLD     FLOAT "  ENDOF
  961.                         0x10 OF .S" FST     FLOAT "  ENDOF
  962.                         0x18 OF .S" FSTP    FLOAT "  ENDOF
  963.                         0x20 OF .S" FLDENV  "        ENDOF
  964.                         0x28 OF .S" FLDCW   WORD "   ENDOF
  965.                         0x30 OF .S" FNSTENV "        ENDOF
  966.                         0x38 OF .S" FNSTCW  WORD "   ENDOF
  967.                             DUP ???
  968.                 ENDCASE
  969.                 MOD-R/M
  970.         ELSE
  971.                 DUP 0xD0 <
  972.                 IF      DUP 0xC8 <
  973.                         IF      .S" FLD     "
  974.                         ELSE    .S" FXCH    "
  975.                         THEN
  976.                         STI.
  977.                 ELSE    FNULLARY
  978.                 THEN
  979.         THEN ;
  980.  
  981. : FALU3   ( OP -- )
  982.         3 RSHIFT 7 AND
  983.         S" FIADD FIMUL FICOM FICOMPFISUB FISUBRFIDIV FIDIVR"
  984.         6 SS. 1 SSPACES ;
  985.  
  986. : FCMOVA  ( OP -- )
  987.         3 RSHIFT 7 AND
  988.         S" FCMOVB FCMOVE FCMOVBEFCMOVU ???    ???    ???    ???    "
  989.         7 SS. ;
  990.  
  991. : FDA   ( ADDR OP -- )
  992.         DROP COUNT DUP 0xC0 <
  993.         IF      DUP FALU3 .S" DWORD " MOD-R/M
  994.         ELSE    DUP 0xE9 =
  995.                 IF      .S" FUCOMPP" DROP
  996.                 ELSE    DUP FCMOVA STI.
  997.                 THEN
  998.         THEN ;
  999.  
  1000. : FALU7  ( OP -- )
  1001.         3 RSHIFT 7 AND
  1002.         S" FADDP FMULP ???   ???   FSUBRPFSUBP FDIVRPFDIVP "
  1003.         6 SS. SSPACE ;
  1004.  
  1005. : FDE   ( ADDR OP -- ADDR' )
  1006.        DROP COUNT DUP 0xC0 <
  1007.        IF      DUP FALU3 .S" WORD " MOD-R/M
  1008.        ELSE    DUP 0xD9 =
  1009.                IF    .S" FCOMPP" DROP
  1010.                ELSE  DUP FALU7 STI.
  1011.                THEN
  1012.        THEN ;
  1013.  
  1014.  
  1015. : FCMOVB  ( OP -- )
  1016.        3 RSHIFT 7 AND
  1017.        S" FCMOVNB FCMOVNE FCMOVNBEFCMOVNU ???     FUCOMI  FCOMI   ???     "
  1018.        8 SS. ;
  1019.  
  1020. : FDB   ( ADDR OP -- ADDR' )
  1021.         DROP COUNT DUP 0xC0 <
  1022.         IF      DUP 0x38 AND
  1023.                 CASE    0x00 OF .S" FILD    DWORD "    ENDOF
  1024.                         0x10 OF .S" FIST    DWORD "    ENDOF
  1025.                         0x18 OF .S" FISTP   DWORD "    ENDOF
  1026.                         0x28 OF .S" FLD     EXTENDED " ENDOF
  1027.                         0x38 OF .S" FSTP    EXTENDED " ENDOF
  1028.                             DUP ???
  1029.                 ENDCASE
  1030.                 MOD-R/M
  1031.         ELSE
  1032.                 CASE    0xE2 OF .S" FNCLEX" ENDOF
  1033.                         0xE3 OF .S" FNINIT" ENDOF
  1034.                             DUP DUP FCMOVB STI.
  1035.                 ENDCASE
  1036.         THEN ;
  1037.  
  1038. : FALU6  ( OP -- )
  1039.         3 RSHIFT 7 AND
  1040.         S" FFREE ???   FST   FSTP  FUCOM FUCOMP???   ???   "
  1041.         6 SS. SSPACE ;
  1042.  
  1043. : FDD   ( ADDR OP -- ADDR' )
  1044.        DROP COUNT DUP 0xC0 <
  1045.        IF      DUP 0x38 AND
  1046.                CASE    0x00 OF .S" FLD     DOUBLE "  ENDOF
  1047.                        0x10 OF .S" FST     DOUBLE "  ENDOF
  1048.                        0x18 OF .S" FSTP    DOUBLE "  ENDOF
  1049.                        0x20 OF .S" FRSTOR  "         ENDOF
  1050.                        0x30 OF .S" FNSAVE  "         ENDOF
  1051.                        0x38 OF .S" FNSTSW  WORD   "  ENDOF
  1052.                            DUP ???
  1053.                ENDCASE
  1054.                MOD-R/M
  1055.        ELSE    DUP FALU6 STI.
  1056.        THEN ;
  1057.  
  1058. : FDF   ( ADDR OP -- ADDR' )
  1059.         DROP COUNT DUP 0xC0 <
  1060.         IF      DUP 0x38 AND
  1061.                 CASE    0x00 OF .S" FILD    WORD "   ENDOF
  1062.                         0x10 OF .S" FIST    WORD "   ENDOF
  1063.                         0x18 OF .S" FISTP   WORD "   ENDOF
  1064.                         0x20 OF .S" FBLD    TBYTE "  ENDOF
  1065.                         0x28 OF .S" FILD    QWORD "  ENDOF
  1066.                         0x30 OF .S" FBSTP   TBYTE "  ENDOF
  1067.                         0x38 OF .S" FISTP   QWORD "  ENDOF
  1068.                             DUP ???
  1069.                 ENDCASE
  1070.                 MOD-R/M
  1071.         ELSE    DUP 0xE0 =
  1072.                 IF      .S" FNSTSW  AX " DROP
  1073.                 ELSE    DUP 0x38 AND
  1074.                         CASE    0x28 OF .S" FUCOMIP " STI. ENDOF
  1075.                                 0x30 OF .S" FCOMIP  " STI. ENDOF
  1076.                                         ???
  1077.                         ENDCASE
  1078.                 THEN
  1079.         THEN ;
  1080.  
  1081. : GP6 ( ADDR OP -- ADDR' )
  1082.        DROP COUNT DUP 3 RSHIFT
  1083.        7 AND S" SLDTSTR LLDTLTR VERRVERW??? ???" 4 SS. 3 SSPACES
  1084.        R/M16 ;
  1085.  
  1086. : GP7 ( ADDR OP -- ADDR' )
  1087.         DROP COUNT DUP 3 RSHIFT
  1088.         7 AND DUP S" SGDT  SIDT  LGDT  LIDT  SMSW  ???   LMSW  INVLPG" 6 SS. 1 SSPACES
  1089.         4 AND 4 =
  1090.         IF   R/M16
  1091.         ELSE R/M16/32
  1092.         THEN ;
  1093.  
  1094. : BTX.  ( N -- )
  1095.         3 RSHIFT
  1096.         3 AND S" BT BTSBTRBTC" 3 SS. 4 SSPACES ;
  1097.  
  1098. : GP8 ( ADDR OP -- ADDR' )
  1099.        DROP COUNT DUP BTX.
  1100.        R/M16/32 IMM8 ;
  1101.  
  1102. : LAR ( ADDR OP -- ADDR' )
  1103.         .S" LAR     " DROP R,R/M ;
  1104.  
  1105. : LSL ( ADDR OP -- ADDR' )
  1106.        .S" LSL     " DROP R,R/M ;
  1107.  
  1108. : LSS ( ADDR OP -- ADDR' )
  1109.         .S" LSS     " DROP R,R/M ;
  1110.  
  1111. : LFS ( ADDR OP -- ADDR' )
  1112.        .S" LFS     " DROP R,R/M ;
  1113.  
  1114. : LGS ( ADDR OP -- ADDR' )
  1115.         .S" LGS     " DROP R,R/M ;
  1116.  
  1117. : BTX ( ADDR OP -- ADDR' )
  1118.        BTX. R/M,R ;
  1119.  
  1120. : SLI ( ADDR OP -- ADDR' )
  1121.         .S" SHLD    " DROP R/M,R IMM8 ;
  1122.  
  1123. : SRI ( ADDR OP -- ADDR' )
  1124.        .S" SHRD    " DROP R/M,R IMM8 ;
  1125.  
  1126. : SLC ( ADDR OP -- ADDR' )
  1127.         .S" SHLD    " DROP R/M,R .S" , CL" ;
  1128.  
  1129. : SRC ( ADDR OP -- ADDR' )
  1130.        .S" SHRD    " DROP R/M,R .S" , CL" ;
  1131.  
  1132. : IML ( ADDR OP -- ADDR' )
  1133.         .S" IMUL    " DROP R,R/M ;
  1134.  
  1135. : CXC ( ADDR OP -- ADDR' )
  1136.        .S" CMPXCHG " 1 AND TO SIZE R/M,R ;
  1137.  
  1138. : MVX ( ADDR OP -- ADDR' )
  1139.         DUP 8 AND
  1140.         IF      .S" MOVSX   "
  1141.         ELSE    .S" MOVZX   "
  1142.         THEN
  1143.         1 AND >R
  1144.         COUNT MOD/SIB R>                        \ SIZE BIT
  1145.         IF    SWAP REG32 .,                     \ WORD TO DWORD CASE
  1146.               3 =
  1147.               IF   REG16
  1148.               ELSE .S" WORD PTR "  DROP DUP 1- C@ MOD-R/M
  1149.               THEN
  1150.         ELSE  SWAP REG16/32 .,                  \ BYTE CASE
  1151.               3 =
  1152.               IF   REG8
  1153.               ELSE .S" BYTE PTR "  DROP DUP 1- C@ MOD-R/M
  1154.               THEN
  1155.         THEN ;
  1156.  
  1157. : XAD ( ADDR OP -- ADDR' )
  1158.        .S" XADD    " 1 AND TO SIZE R/M,R ;
  1159.  
  1160. : BSF ( ADDR OP -- ADDR' )
  1161.         .S" BSF     " DROP R,R/M ;
  1162.  
  1163. : BSR ( ADDR OP -- ADDR' )
  1164.        .S" BSR     " DROP R,R/M ;
  1165.  
  1166. : CX8 ( ADDR OP -- ADDR' )
  1167.         .S" CMPXCHG8B " DROP COUNT R/M16/32 ;
  1168.  
  1169. : BSP ( ADDR OP -- ADDR' )
  1170.        .S" BSWAP   " REG32 ;
  1171.  
  1172.  
  1173. : F6.  ( ADDR OP -- ADDR' )
  1174. \ ??
  1175.         >R COUNT
  1176.         DUP 3 RSHIFT 7 AND DUP>R S" TESTXXXXNOT NEG MUL IMULDIV IDIV" 4 SS. 3 SSPACES
  1177.         MOD-R/M
  1178.         R> 0= IF
  1179.                 R@ 1 AND IF IMM16/32
  1180.                          ELSE IMM8
  1181.                          THEN
  1182.               THEN
  1183.         R> DROP ;
  1184.  
  1185. : FE.  ( ADDR OP -- ADDR' )
  1186.        DROP COUNT
  1187.        DUP 3 RSHIFT 7 AND
  1188.        CASE
  1189.                0 OF .S" INC     "  ENDOF
  1190.                1 OF .S" DEC     "  ENDOF
  1191.                     .S" ???     "
  1192.        ENDCASE R/M8 ;
  1193.  
  1194. : FF.  ( ADDR OP -- ADDR' )
  1195.         DROP COUNT
  1196.         DUP 3 RSHIFT 7 AND
  1197.         CASE
  1198.                 0 OF .S" INC     "      ENDOF
  1199.                 1 OF .S" DEC     "      ENDOF
  1200.                 2 OF .S" CALL    "      ENDOF
  1201.                 3 OF .S" CALL    FAR "  ENDOF
  1202.                 4 OF .S" JMP     "      ENDOF
  1203.                 5 OF .S" JMP     FAR "  ENDOF
  1204.                 6 OF .S" PUSH    "      ENDOF
  1205.                      .S" ???     "
  1206.         ENDCASE R/M16/32 ;
  1207.  
  1208.  
  1209. \ --------------------- CONDITIONAL MOVE ---------------
  1210.  
  1211. : SET   ( ADR OP -- )
  1212.         .S" SET"
  1213.         TTTN 2 SSPACES
  1214.         COUNT R/M8 ;
  1215.  
  1216. : CMV   ( ADR OP -- )
  1217.         .S" CMOV"
  1218.         TTTN 1 SSPACES
  1219.         R,R/M ;
  1220.  
  1221. \ --------------------- MMX OPERATIONS -----------------
  1222.  
  1223. : MMX-SIZE ( OP -- )
  1224.         3 AND S" BWDQ" 1 SS. ;
  1225.  
  1226. : UPL   ( ADR OP -- ADR' )
  1227.        3 AND S" PUNPCKLBWPUNPCKLWDPUNPCKLDQ" 9 SS. R,R/M ;
  1228.  
  1229. : UPH   ( ADR OP -- ADR' )
  1230.         3 AND S" PUNPCKHBWPUNPCKHWDPUNPCKHDQ" 9 SS. R,R/M ;
  1231.  
  1232. : CGT   ( ADR OP -- ADR' )
  1233.        .S" PCMPGT" MMX-SIZE R,R/M ;
  1234.  
  1235. : CEQ   ( ADR OP -- ADR' )
  1236.         .S" PCMPEQ" MMX-SIZE R,R/M ;
  1237.  
  1238. : PSH.  ( OP -- )
  1239.         0x30 AND
  1240.         CASE
  1241.              0x10 OF .S" PSRL" ENDOF
  1242.              0x20 OF .S" PSRA" ENDOF
  1243.              0x30 OF .S" PSLL" ENDOF
  1244.         ENDCASE ;
  1245.  
  1246. : GPA   ( ADR OP -- ADR' )
  1247.        >R COUNT DUP PSH. R> MMX-SIZE 2 SSPACES MREG IMM8 ;
  1248.  
  1249. : PUW   ( ADR OP -- ADR' )
  1250.         .S" PACKUSDW " DROP R,R/M ;
  1251.  
  1252. : PSB   ( ADR OP -- ADR' )
  1253.        .S" PACKSSWB " DROP R,R/M ;
  1254.  
  1255. : PSW   ( ADR OP -- ADR' )
  1256.         .S" PACKSSDW " DROP R,R/M ;
  1257.  
  1258. : MPD   ( ADR OP -- ADR' )
  1259.        .S" MOVD    " DROP COUNT MOD/SIB
  1260.        SWAP MREG ., 3 =
  1261.        IF   REG32
  1262.        ELSE MOD-R/M
  1263.        THEN ;
  1264.  
  1265. : MDP   ( ADR OP -- ADR' )
  1266.         .S" MOVD    " DROP COUNT MOD/SIB
  1267.         3 =
  1268.         IF   SWAP REG32
  1269.         ELSE SWAP MOD-R/M
  1270.         THEN ., MREG ;
  1271.  
  1272. : MPQ   ( ADR OP -- ADR' )
  1273.        .S" MOVQ    " DROP R,R/M ;
  1274.  
  1275. : MQP   ( ADR OP -- ADR' )
  1276.         .S" MOVQ    " DROP R/M,R ;
  1277.  
  1278. : SHX   ( ADR OP -- ADR' )
  1279.        DUP PSH. MMX-SIZE 2 SSPACES R,R/M ;
  1280.  
  1281. : MLL   ( ADR OP -- ADR' )
  1282.         .S" PMULLW  " DROP R,R/M ;
  1283.  
  1284. : MLH   ( ADR OP -- ADR' )
  1285.        .S" PMULHW  " DROP R,R/M ;
  1286.  
  1287. : MAD   ( ADR OP -- ADR' )
  1288.         .S" PMADDWD " DROP R,R/M ;
  1289.  
  1290. : SUS   ( ADR OP -- ADR' )
  1291.        .S" PSUBUS" MMX-SIZE R,R/M ;
  1292.  
  1293. : SBS   ( ADR OP -- ADR' )
  1294.         .S" PSUBS" MMX-SIZE SSPACE R,R/M ;
  1295.  
  1296. : SUB   ( ADR OP -- ADR' )
  1297.        .S" PSUB" MMX-SIZE 2 SSPACES R,R/M ;
  1298.  
  1299. : AUS   ( ADR OP -- ADR' )
  1300.         .S" PADDUS" MMX-SIZE R,R/M ;
  1301.  
  1302. : ADS   ( ADR OP -- ADR' )
  1303.        .S" PADDS" MMX-SIZE SSPACE R,R/M ;
  1304.  
  1305. : ADD   ( ADR OP -- ADR' )
  1306.         .S" PADD" MMX-SIZE 2 SSPACES R,R/M ;
  1307.  
  1308. : PAD   ( ADR OP -- ADR' )
  1309.        .S" PAND    " DROP R,R/M ;
  1310.  
  1311. : POR   ( ADR OP -- ADR' )
  1312.         .S" POR     " DROP R,R/M ;
  1313.  
  1314. : PAN   ( ADR OP -- ADR' )
  1315.        .S" PANDN   " DROP R,R/M ;
  1316.  
  1317. : PXR   ( ADR OP -- ADR' )
  1318.         .S" PXOR    " DROP R,R/M ;
  1319.  
  1320.  
  1321. \ -------------------- OPCODE TABLE --------------------
  1322.  
  1323. : OPS 0x10 0 DO ' , LOOP ;
  1324.  
  1325.  
  1326. CREATE OP-TABLE2
  1327.  
  1328. \    0   1   2   3    4   5   6   7    8   9   A   B    C   D   E   F
  1329.  
  1330. OPS  GP6 GP7 LAR LSL  ??? ??? CLT ???  INV WIV ??? UD2  ??? ??? ??? ???  \ 0
  1331. OPS  ??? ??? ??? ???  ??? ??? ??? ???  ??? ??? ??? ???  ??? ??? ??? ???  \ 1
  1332. OPS  MRC MRD MCR MDR  MRT ??? MTR ???  ??? ??? ??? ???  ??? ??? ??? ???  \ 2
  1333. OPS  WMR RTC RMR RPC  ??? ??? ??? ???  ??? ??? ??? ???  ??? ??? ??? ???  \ 3
  1334.  
  1335. OPS  CMV CMV CMV CMV  CMV CMV CMV CMV  CMV CMV CMV CMV  CMV CMV CMV CMV  \ 4
  1336. OPS  ??? ??? ??? ???  ??? ??? ??? ???  ??? ??? ??? ???  ??? ??? ??? ???  \ 5
  1337. OPS  UPL UPL UPL PUW  CGT CGT CGT PSB  UPH UPH UPH PSW  ??? ??? MPD MPQ  \ 6
  1338. OPS  ??? GPA GPA GPA  CEQ CEQ CEQ EMS  ??? ??? ??? ???  ??? ??? MDP MQP  \ 7
  1339.  
  1340. OPS  LBR LBR LBR LBR  LBR LBR LBR LBR  LBR LBR LBR LBR  LBR LBR LBR LBR  \ 8
  1341. OPS  SET SET SET SET  SET SET SET SET  SET SET SET SET  SET SET SET SET  \ 9
  1342. OPS  PSS PPS CPU BTX  SLI SLC ??? ???  PSS PPS RSM BTX  SRI SRC ??? IML  \ A
  1343. OPS  CXC CXC LSS BTX  LFS LGS MVX MVX  ??? UD1 GP8 BTX  BSF BSR MVX MVX  \ B
  1344.  
  1345. OPS  XAD XAD ??? ???  ??? ??? ??? CX8  BSP BSP BSP BSP  BSP BSP BSP BSP  \ C
  1346. OPS  ??? SHX SHX SHX  ??? MLL ??? ???  SUS SUS ??? PAD  AUS AUS ??? PAN  \ D
  1347. OPS  ??? SHX SHX ???  ??? MLH ??? ???  SBS SBS ??? POR  ADS ADS ??? PXR  \ E
  1348. OPS  ??? ??? SHX SHX  ??? MAD ??? ???  SUB SUB SUB ???  ADD ADD ADD ???  \ F
  1349.  
  1350. \    0   1   2   3    4   5   6   7    8   9   A   B    C   D   E   F
  1351.  
  1352. : 0F.  ( ADR CODE -- )
  1353.        DROP COUNT DUP
  1354.        DUP 0x70 AND 0x50 0x80 WITHIN TO MMX-REG
  1355.        CELLS OP-TABLE2 + @ EXECUTE
  1356.        0 TO MMX-REG ;
  1357.  
  1358.  
  1359. CREATE OP-TABLE
  1360.  
  1361. \    0   1   2   3    4   5   6   7    8   9   A   B    C   D   E   F
  1362.  
  1363. OPS  ALU ALU ALU ALU  ALA ALA PSS PPS  ALU ALU ALU ALU  ALA ALA PSS 0F.  \ 0
  1364. OPS  ALU ALU ALU ALU  ALA ALA PSS PPS  ALU ALU ALU ALU  ALA ALA PSS PPS  \ 1
  1365. OPS  ALU ALU ALU ALU  ALA ALA ES: DAA  ALU ALU ALU ALU  ALA ALA CS: DAS  \ 2
  1366. OPS  ALU ALU ALU ALU  ALA ALA SS: AAA  ALU ALU ALU ALU  ALA ALA DS: AAS  \ 3
  1367.  
  1368. OPS  INC INC INC INC  INC INC INC INC  DEC DEC DEC DEC  DEC DEC DEC DEC  \ 4
  1369. OPS  PSH PSH PSH PSH  PSH PSH PSH PSH  POP POP POP POP  POP POP POP POP  \ 5
  1370. OPS  PSA PPA BND ARP  FS: GS: D16 A16  PSI MLI PSI MLI  INB ISD OSB OSD  \ 6
  1371. OPS  BRA BRA BRA BRA  BRA BRA BRA BRA  BRA BRA BRA BRA  BRA BRA BRA BRA  \ 7
  1372.  
  1373. OPS  ALI ALI ??? ALI  TXB TXB TXB TXB  MOV MOV MOV MOV  MRS LEA MSR 8F.  \ 8
  1374. OPS  XGA XGA XGA XGA  XGA XGA XGA XGA  CBW CDQ CIS W8F  PSF PPF SAH LAH  \ 9
  1375. OPS  MV1 MV1 MV2 MV2  MVS MVS CPS CPS  TST TST STS STS  LDS LDS SCS SCS  \ A
  1376. OPS  MRI MRI MRI MRI  MRI MRI MRI MRI  MRI MRI MRI MRI  MRI MRI MRI MRI  \ B
  1377.  
  1378. OPS  SHF SHF RTN RTN  LXS LXS MVI MVI  ENT LEV RTF RTF  NT3 INT NTO IRT  \ C
  1379. OPS  SHF SHF SHF SHF  AAM AAD ??? XLT  FD8 FD9 FDA FDB  FDC FDD FDE FDF  \ D
  1380. OPS  LUP LUP LUP LUP  INP INP OTP OTP  JSR JMP CIS JMP  IND IND OTD OTD  \ E
  1381. OPS  LOK ??? RPZ REP  HLT CMC F6. F6.  CLC STC CLI STI  CLD STD FE. FF.  \ F
  1382.  
  1383. \    0   1   2   3    4   5   6   7    8   9   A   B    C   D   E   F
  1384.  
  1385. : DIS-OP  ( ADR -- ADR' )
  1386.         0>S
  1387.         FALSE TO PREFIX-OP           \ SMUB
  1388.         COUNT
  1389.         DUP 1 AND TO SIZE
  1390.         DUP CELLS OP-TABLE + @ EXECUTE
  1391.         PREFIX-OP 0=
  1392.         IF DEFAULT-16BIT? 0=
  1393.            IF   FALSE TO 16-BIT-DATA
  1394.                 FALSE TO 16-BIT-ADDR
  1395.            ELSE TRUE  TO 16-BIT-DATA
  1396.                 TRUE  TO 16-BIT-ADDR
  1397.            THEN
  1398.         THEN ;
  1399.  
  1400.  
  1401. 0 VALUE NEXT-INST
  1402.  
  1403. : X".  ( ADDR -- ADDR' )
  1404. \      CR DUP  BASE-ADDR - 6 H.R SPACE
  1405.        DUP C@ 2DUP DUMP
  1406.        + 2+
  1407. \      ."  C, " 1+ OVER + SWAP
  1408. \      DO I C@ 2 H.R  ."  C, " LOOP
  1409. \      COUNT  + 1+
  1410. ;
  1411.  
  1412. [DEFINED] G. [IF]
  1413.  
  1414. : FLIT8.  ( ADDR -- ADDR' )
  1415.       ." FLITERAL: "
  1416.       DUP DF@ G.  8 +
  1417. ;
  1418.  
  1419. : FLIT10.  ( ADDR -- ADDR' )
  1420.       ." FLITERAL: "
  1421.       DUP F@ G.  10 +
  1422. ;
  1423.  
  1424. [ELSE]
  1425.  
  1426. : FLIT8.
  1427.       CR DUP  BASE-ADDR - 6 H.R SPACE
  1428.       ."  A; " DUP 8 OVER + SWAP
  1429.       DO I C@ 3 H.R ."  C," LOOP
  1430.       8 +
  1431. ;
  1432.  
  1433. : FLIT10. ( ADDR -- ADDR' )
  1434.       CR DUP  BASE-ADDR - 6 H.R SPACE
  1435.       ."  A; "  DUP 10 OVER + SWAP
  1436.       DO I C@ 3 H.R ."  C," LOOP
  1437.       10 +
  1438. ;
  1439.  
  1440. [THEN]
  1441.  
  1442. : VECT. ( ADDR -- ADDR' )
  1443.       CR DUP  BASE-ADDR - 6 H.R SPACE
  1444.       ."  A; " DUP @ 8 H.R DUP CELL+ SWAP @ ."  ,  \ " WordByAddr TYPE
  1445. ;
  1446.  
  1447. : CONS. ( ADDR -- )
  1448.       CR DUP BASE-ADDR - 6 H.R SPACE
  1449.       ."  A; " @ 8 H.R ."  ,"
  1450. ;
  1451.  
  1452. : USER. ( ADDR -- )
  1453.       CR DUP  BASE-ADDR - 6 H.R SPACE
  1454.       ."  A; " @ 8 H.R ."  , \ Relative in heap [hex]" \ CELL+
  1455. ;
  1456.  
  1457. : UVAL. ( ADDR -- ADDR' )
  1458.       CR DUP  BASE-ADDR - 6 H.R SPACE
  1459.       ."  A; " DUP @ 8 H.R ."  , \ Relative in heap [hex]" CELL+
  1460. ;
  1461.  
  1462. : CODE. ( ADDR -- )
  1463.        DUP NextNFA
  1464.        ?DUP
  1465.        IF OVER - 5 -
  1466.        ELSE
  1467.           DUP DP @ SWAP - ABS DUP 512 > IF DROP 40 THEN \ no applicable end found
  1468.        THEN
  1469.        ." Size of data: ~" DUP .
  1470.        DUMP
  1471. ;
  1472.  
  1473.  
  1474. : DIS-DB   CR .S" DB " COUNT H.>S ;
  1475. : DIS-DW   CR .S" DW " W@+ H.>S ;
  1476. : DIS-DD   CR .S" DD " @+ H.>S ;
  1477. : DIS-DS   CR .S" STRING " 0x22 EMIT>S COUNT 2DUP >S + 0x22 EMIT>S ;
  1478.  
  1479. : FIND-REST-END ( xt -- addr | 0)
  1480.    DUP NextNFA DUP
  1481.    IF
  1482.      NIP
  1483.      NAME>C 1- \ Skip CFA field
  1484.    ELSE
  1485.      DROP
  1486.      DP @ - ABS 100 > IF 0 EXIT THEN \ no applicable end found
  1487.      DP @ 1-
  1488.    THEN
  1489.  
  1490.    BEGIN \ Skip alignment
  1491.      DUP C@ 0= WHILE 1-
  1492.    REPEAT ;
  1493.  
  1494. ( wid ) SET-CURRENT
  1495.  
  1496. : INST  ( ADR -- ADR' )
  1497.        DUP TO NEXT-INST
  1498.        COLS 0x29 <
  1499.        IF      DIS-OP
  1500.                S-BUF COUNT TYPE
  1501.        ELSE    DUP DIS-OP
  1502.                OVER BASE-ADDR - 6  H.R SPACE
  1503.                DUP ROT
  1504.                2DUP - DUP>R 0x10 U> ABORT" DECOMPILER ERROR"
  1505.                DO I C@ 2 H.N LOOP
  1506.                R> 5 < IF 9 EMIT THEN
  1507.                9 EMIT S-BUF COUNT TYPE
  1508.        THEN    NEXT-INST C@ 0xE8 =
  1509.                IF  NEXT-INST 1+ @+ SWAP +
  1510.                    CASE
  1511.                   ['] _CLITERAL-CODE OF  X".   ENDOF
  1512.                    ['] _SLITERAL-CODE OF  X".   ENDOF
  1513.                   ['] _VECT-CODE     OF  VECT. 2DROP RDROP ENDOF
  1514.                    ['] _CONSTANT-CODE OF  CONS. DROP RDROP ENDOF
  1515.                   ['] _USER-CODE     OF  USER. DROP RDROP ENDOF
  1516.                    ['] _CREATE-CODE   OF  CODE. DROP RDROP ENDOF
  1517.                   ['] _USER-VALUE-CODE OF UVAL. ENDOF
  1518.                    ['] _FLIT-CODE10   OF  FLIT10. ENDOF
  1519.                   ['] _FLIT-CODE8    OF  FLIT8. ENDOF
  1520.                     ENDCASE
  1521.                 THEN  ;
  1522.  
  1523.  
  1524. : (REST-AREA) ( addr1 addr2 -- )
  1525. \ if addr2 = 0 continue till RET instruction
  1526.                 SWAP DUP TO NEXT-INST
  1527.                 BEGIN
  1528.                         \ We do not look for JMP's because there may be
  1529.                         \ a jump in a forth word
  1530.                        CR
  1531.                        OVER 0= IF  NEXT-INST C@ 0xC3 <>
  1532.                                ELSE 2DUP < INVERT
  1533.                                THEN
  1534.                WHILE   INST
  1535.                REPEAT  2DROP ." END-CODE  "
  1536.                ;
  1537.  
  1538. VECT REST-AREA                
  1539. ' (REST-AREA) TO REST-AREA
  1540.  
  1541. : REST ( addr -- )
  1542.     DUP HERE U> 0=  HERE 1- AND REST-AREA
  1543. ;
  1544.  
  1545. : SEE       ( "name" -- )
  1546.     ' DUP FIND-REST-END ['] REST-AREA CATCH DROP
  1547. ;
  1548.  
  1549. PREVIOUS
  1550.  
  1551. ( warn base )
  1552. BASE !
  1553. WARNING !
  1554.  
  1555. .(  Ok) CR
  1556.