Subversion Repositories Kolibri OS

Rev

Rev 866 | Go to most recent revision | Blame | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;                                                                 ;;
  3. ;; Copyright (C) KolibriOS team 2004-2007. All rights reserved.    ;;
  4. ;; Distributed under terms of the GNU General Public License       ;;
  5. ;;                                                                 ;;
  6. ;;  ETHERNET.INC                                                   ;;
  7. ;;                                                                 ;;
  8. ;;  Ethernet network layer for Menuet OS                           ;;
  9. ;;                                                                 ;;
  10. ;;  Version 0.4  22 September 2003                                 ;;
  11. ;;                                                                 ;;
  12. ;;  This file contains the following:                              ;;
  13. ;;      PCI bus scanning for valid devices                         ;;
  14. ;;      Table of supported ethernet drivers                        ;;
  15. ;;      Code to identify and activate a supported driver           ;;
  16. ;;      ARP handler                                                ;;
  17. ;;      Driver interface to the IP layer                           ;;
  18. ;;      Gateway support                                            ;;
  19. ;;                                                                 ;;
  20. ;;  Individual driver files are included here                      ;;
  21. ;;                                                                 ;;
  22. ;;  The PCI bus scanning code was ported from the etherboot        ;;
  23. ;;  5.0.6 project. The copyright statement for that code is        ;;
  24. ;;                                                                 ;;
  25. ;;          GNU GENERAL PUBLIC LICENSE                             ;;
  26. ;;             Version 2, June 1991                                ;;
  27. ;;                                                                 ;;
  28. ;;  remaining parts Copyright 2002 Mike Hibbett                    ;;
  29. ;;   mikeh@oceanfree.net                                           ;;
  30. ;;                                                                 ;;
  31. ;;  See file COPYING for details                                   ;;
  32. ;;                                                                 ;;
  33. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  34.  
  35. $Revision: 867 $
  36.  
  37.  
  38. ;********************************************************************
  39. ;   Interface
  40. ;      ethernet_driver   called by stack_handler in stack.inc
  41. ;      eth_probe         called by app_stack_handler in stack.inc
  42. ;
  43. ;********************************************************************
  44.  
  45. ETHER_IP                    equ     0x0008      ; Reversed from 0800 for intel
  46. ETHER_ARP                   equ     0x0608      ; Reversed from 0806 for intel
  47. ETHER_RARP                  equ     0x3580
  48.  
  49. struc ETH_FRAME
  50. {  .DstMAC       dp   ?  ;destination MAC-address [6 bytes]
  51.    .SrcMAC       dp   ?  ;source MAC-address [6 bytes]
  52.    .Type         dw   ?  ;type of the upper-layer protocol [2 bytes]
  53.    .Data         db   ?  ;data [46-1500 bytes]
  54. }
  55.  
  56. virtual at Ether_buffer
  57.   ETH_FRAME ETH_FRAME
  58. end virtual
  59.  
  60.  
  61. ; Some useful information on data structures
  62.  
  63. ;     Ethernet Packet - ARP Request example
  64. ;
  65. ;   0                   1                   2                   3
  66. ;   0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0 1
  67. ;
  68. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  69. ;   |       Dest   H/W Address                                      |
  70. ;   |                    ( 14 byte header )                         |
  71. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  72. ;   |                               |     Source     H/W Address    |
  73. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  74. ;   |                                                               |
  75. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  76. ;   |    Protocol - ARP 08  06      |
  77. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  78.  
  79. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  80. ;   |  H/W Type  00           01    |  Protocol Type   08 00        |
  81. ;   |                   ( ARP Request packet )                      |
  82. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  83. ;   | HLen    0x06  | PLen    0x04  |    OpCode        00   01      |
  84. ;   |               ( 0001 for request, 0002 for reply )            |
  85. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  86. ;   | Source Hardware Address ( MAC Address )                       |
  87. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  88. ;   |                               |  Source IP Address            |
  89. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  90. ;   |                               | Destination Hardware Address  |
  91. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  92. ;   |                                                               |
  93. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  94. ;   | Destination IP Address                                        |
  95. ;   +-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+
  96.  
  97. ; Include individual drivers source files at this point.
  98. ; If you create a new driver, include it below.
  99.  
  100. include "drivers/rtl8029.inc"
  101. include "drivers/i8255x.inc"
  102. include "drivers/rtl8139.inc"
  103. include "drivers/3c59x.inc"
  104. include "drivers/sis900.inc"
  105. include "drivers/pcnet32.inc"
  106. include "drivers/rtl8169.inc"
  107. include "drivers/forcedeth.inc"
  108.  
  109. ; PCICards
  110. ; ========
  111. ; PCI vendor and hardware types for hardware supported by the above drivers
  112. ; If you add a driver, ensure you update this datastructure, otherwise the
  113. ; card will not be probed.
  114. ; Each driver is defined by 4 double words. These are
  115. ;   PCIVendorDevice  probeFunction ResetFunction PollFunction transmitFunction
  116. ; The last entry must be kept at all zeros, to indicate the end of the list
  117. ; As a PCI driver may support more than one hardware implementation, there may
  118. ; be several lines which refer to the same functions.
  119. ; The first driver found on the PCI bus will be the one used.
  120.  
  121. PCICARDS_ENTRY_SIZE         equ     24    ; Size of each PCICARDS entry
  122.  
  123. iglobal
  124. PCICards:
  125. dd  0x12098086, I8255x_probe, I8255x_reset, I8255x_poll, I8255x_transmit, 0
  126. dd  0x10298086, I8255x_probe, I8255x_reset, I8255x_poll, I8255x_transmit, 0
  127. dd  0x12298086, I8255x_probe, I8255x_reset, I8255x_poll, I8255x_transmit, 0
  128. dd  0x10308086, I8255x_probe, I8255x_reset, I8255x_poll, I8255x_transmit, 0
  129. dd  0x24498086, I8255x_probe, I8255x_reset, I8255x_poll, I8255x_transmit, 0
  130.  
  131. dd  0x802910ec, rtl8029_probe, rtl8029_reset, rtl8029_poll, rtl8029_transmit, 0
  132.  
  133. dd  0x813910ec, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable  ; tested by hidnplayr: works ok
  134. dd  0x813810ec, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  135. dd  0x12111113, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable  ; tested by hidnplayr: works ok
  136. dd  0x13601500, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  137. dd  0x13604033, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  138. dd  0x13001186, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  139. dd  0x13401186, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  140. dd  0xab0613d1, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  141. dd  0xa1171259, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  142. dd  0xa11e1259, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  143. dd  0xab0614ea, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  144. dd  0xab0714ea, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  145. dd  0x123411db, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  146. dd  0x91301432, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  147. dd  0x101202ac, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  148. dd  0x0106018a, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  149. dd  0x1211126c, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  150. dd  0x81391743, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  151. dd  0x8139021b, rtl8139_probe, rtl8139_reset, rtl8139_poll, rtl8139_transmit, rtl8139_cable
  152.  
  153. dd  0x816810ec, rtl8169_probe, rtl8169_reset, rtl8169_poll, rtl8169_transmit, 0
  154. dd  0x816910ec, rtl8169_probe, rtl8169_reset, rtl8169_poll, rtl8169_transmit, 0
  155. dd  0x011616ec, rtl8169_probe, rtl8169_reset, rtl8169_poll, rtl8169_transmit, 0
  156. dd  0x43001186, rtl8169_probe, rtl8169_reset, rtl8169_poll, rtl8169_transmit, 0
  157.  
  158. dd  0x590010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  159. dd  0x592010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  160. dd  0x597010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  161. dd  0x595010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  162. dd  0x595110b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  163. dd  0x595210b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  164. dd  0x900010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  165. dd  0x900110b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  166. dd  0x900410b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  167. dd  0x900510b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  168. dd  0x900610b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  169. dd  0x900A10b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  170. dd  0x905010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  171. dd  0x905110b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  172. dd  0x905510b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  173. dd  0x905810b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  174. dd  0x905A10b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  175. dd  0x920010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  176. dd  0x980010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  177. dd  0x980510b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  178. dd  0x764610b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  179. dd  0x505510b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  180. dd  0x605510b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  181. dd  0x605610b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  182. dd  0x5b5710b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  183. dd  0x505710b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  184. dd  0x515710b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  185. dd  0x525710b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  186. dd  0x656010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  187. dd  0x656210b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  188. dd  0x656410b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  189. dd  0x450010b7, e3c59x_probe, e3c59x_reset, e3c59x_poll, e3c59x_transmit, 0
  190.  
  191. dd  0x09001039, SIS900_probe, SIS900_reset, SIS900_poll, SIS900_transmit, 0
  192.  
  193. dd  0x20001022, pcnet32_probe, pcnet32_reset, pcnet32_poll, pcnet32_xmit, 0
  194. dd  0x26251022, pcnet32_probe, pcnet32_reset, pcnet32_poll, pcnet32_xmit, 0
  195. dd  0x20011022, pcnet32_probe, pcnet32_reset, pcnet32_poll, pcnet32_xmit, 0
  196.  
  197. ;dd  0x08031516, mtd80x_probe, mtd80x_reset, mtd80x_poll, mtd80x_transmit, mtd80x_cable
  198.  
  199. ; following cards are untested
  200. dd  0x70161039, SIS900_probe, SIS900_reset, SIS900_poll, SIS900_transmit, 0
  201. ;dd  0x08001516, mtd80x_probe, mtd80x_reset, mtd80x_poll, mtd80x_transmit, mtd80x_cable
  202. ;dd  0x08911516, mtd80x_probe, mtd80x_reset, mtd80x_poll, mtd80x_transmit, mtd80x_cable
  203.  
  204. dd 0x006610de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; nVidia Corporation nForce2 Ethernet Controller
  205. dd 0x01c310de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  206. dd 0x00D610de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  207. dd 0x008610de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  208. dd 0x008c10de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  209. dd 0x00e610de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  210. dd 0x00df10de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  211. dd 0x005610de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  212. dd 0x005710de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  213. dd 0x003710de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  214. dd 0x003810de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  215. dd 0x026810de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  216. dd 0x026910de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  217. dd 0x037210de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  218. dd 0x037310de, forcedeth_probe, forcedeth_reset, forcedeth_poll, forcedeth_transmit, forcedeth_cable ; not tested
  219.  
  220.  
  221. rb PCICARDS_ENTRY_SIZE  ; end of list marker, do not remove
  222. endg
  223.  
  224. uglobal
  225. ;Net-stack's interface's settings
  226.   node_addr:          db  0,0,0,0,0,0
  227.   gateway_ip:         dd  0
  228.   dns_ip:             dd  0
  229.  
  230.   eth_rx_data_len:    dw  0
  231.   eth_status:         dd  0
  232.   io_addr:            dd  0
  233.   hdrtype:            db  0
  234.   vendor_device:      dd  0
  235.   pci_data:           dd  0
  236.   pci_dev:            dd  0
  237.   pci_bus:            dd  0
  238.  
  239.   ; These will hold pointers to the selected driver functions
  240.   drvr_probe:         dd  0
  241.   drvr_reset:         dd  0
  242.   drvr_poll:          dd  0
  243.   drvr_transmit:      dd  0
  244.   drvr_cable:         dd  0
  245.  
  246. endg
  247.  
  248. iglobal
  249.   broadcast_add:      db  0xff,0xff,0xff,0xff,0xff,0xff
  250.   subnet_mask:        dd  0x00ffffff   ; 255.255.255.0
  251. endg
  252.  
  253. include "arp.inc"    ;arp-protocol functions
  254. include "pci.inc"    ;PCI bus access functions
  255.  
  256.  
  257. ;***************************************************************************
  258. ;   Function
  259. ;      eth_tx
  260. ;
  261. ;   Description
  262. ;      Looks at the NET1OUT_QUEUE for data to send.
  263. ;      Stores that destination IP in a location used by the tx routine
  264. ;      Looks up the MAC address in the ARP table; stores that where
  265. ;      the tx routine can get it
  266. ;      Get the length of the data. Store that where the tx routine wants it
  267. ;      Call tx
  268. ;      Places buffer on empty queue when the tx routine finished
  269. ;
  270. ;***************************************************************************
  271. proc eth_tx stdcall uses ebx esi edi
  272. local MACAddress  dp  ?  ;allocate 6 bytes in the stack
  273.  
  274.     ; Look for a buffer to tx
  275.     mov     eax, NET1OUT_QUEUE
  276.     call    dequeue
  277.     cmp     ax, NO_BUFFER
  278.     je      .exit            ; Exit if no buffer available
  279.  
  280.     push    eax  ;save buffer number
  281.  
  282.     ; convert buffer pointer eax to the absolute address
  283.     imul    eax, IPBUFFSIZE
  284.     add     eax, IPbuffs
  285.  
  286.     ; Extract the destination IP
  287.     ; find the destination IP in the ARP table, get MAC
  288.     ; store this MAC in 'MACAddress'
  289.     mov     ebx, eax               ; Save buffer address
  290.     mov     edx, [ebx + 16]        ; get destination address
  291.  
  292.     ; If the destination address is 255.255.255.255,
  293.     ; set the MACAddress to all ones ( broadcast )
  294.     cld
  295.     mov     esi, broadcast_add
  296.     lea     edi, [MACAddress]
  297.     movsd
  298.     movsw
  299.     cmp     edx, 0xffffffff
  300.     je      .send                ; If it is broadcast, just send
  301.  
  302.     lea     eax, [MACAddress]    ;cause this is local variable
  303.     stdcall arp_table_manager, ARP_TABLE_IP_TO_MAC, edx, eax ;opcode,IP,MAC_ptr - Get the MAC address.
  304.  
  305.     cmp     eax, ARP_VALID_MAPPING
  306.     je      .send
  307.  
  308.     ; No valid entry. Has the request been sent, but timed out?
  309.     cmp     eax, ARP_RESPONSE_TIMEOUT
  310.     je      .freebuf
  311.  
  312.   .wait_response:                   ;we wait arp-response
  313.                                     ; Re-queue the packet, and exit
  314.     pop     ebx
  315.     mov     eax, NET1OUT_QUEUE
  316.     call    queue                        ; Get the buffer back
  317.     jmp     .exit
  318.  
  319.   .send:    ;if ARP_VALID_MAPPING then send the packet
  320.     lea     edi, [MACAddress]     ; Pointer to 48 bit destination address
  321.     movzx   ecx, word[ebx+2]      ; Size of IP packet to send
  322.     xchg    ch, cl                ; because mirror byte-order
  323.     mov     esi, ebx              ; Pointer to packet data
  324.     mov     bx, ETHER_IP          ; Type of packet
  325.     push    ebp
  326.     call    dword [drvr_transmit] ; Call the drivers transmit function
  327.     pop     ebp
  328.  
  329.     ; OK, we have sent a packet, so increment the count
  330.     inc     dword [ip_tx_count]
  331.  
  332.     ; And finally, return the buffer to the free queue
  333.   .freebuf:
  334.     pop     eax
  335.     call    freeBuff
  336.  
  337.   .exit:
  338.     ret
  339. endp
  340.  
  341. ;***************************************************************************
  342. ;   Function
  343. ;      ether_IP_handler
  344. ;
  345. ;   Description
  346. ;      Called when an IP ethernet packet is received on the ethernet
  347. ;      Header + Data is in Ether_buffer[]
  348. ;      We just need to get a buffer from the 'free' queue, and
  349. ;      store the packet in it, then insert the packet number into the
  350. ;      IPRX queue.
  351. ;      If no queue entry is available, the packet is silently discarded
  352. ;      All registers may be destroyed
  353. ;
  354. ;***************************************************************************
  355. ether_IP_handler:
  356.     mov     eax, EMPTY_QUEUE
  357.     call    dequeue
  358.     cmp     ax, NO_BUFFER
  359.     je      eiph00x
  360.  
  361.     ; convert buffer pointer eax to the absolute address
  362.     push    eax
  363.     mov     ecx, IPBUFFSIZE
  364.     mul     ecx
  365.     add     eax, IPbuffs
  366.  
  367.     mov     edi, eax
  368.  
  369.     ; get a pointer to the start of the DATA
  370.     mov     esi, ETH_FRAME.Data
  371.  
  372.     ; Now store it all away
  373.     mov     ecx, IPBUFFSIZE / 4     ; Copy all of the available
  374.                               ; data across - worse case
  375.     cld
  376.     rep     movsd
  377.  
  378.     ; And finally, place the buffer in the IPRX queue
  379.     pop     ebx
  380.     mov     eax, IPIN_QUEUE
  381.     call    queue
  382.  
  383. eiph00x:
  384.     ret
  385.  
  386. ;***************************************************************************
  387. ;   Function
  388. ;      eth_probe
  389. ;   Description
  390. ;      Searches for an ethernet card. If found, the card is enabled and
  391. ;      the ethernet -> IP link established
  392. ;
  393. ;      This function scans the PCI bus looking for a supported device.
  394. ;      ISA bus is currently not supported.
  395. ;
  396. ;        eax is 0 if no hardware found
  397. ;***************************************************************************
  398. eth_probe:
  399.     ; Find a card on the PCI bus, and get it's address
  400.     call    scan_bus                    ; Find the ethernet cards PIC address
  401.     xor     eax, eax
  402.     cmp     [io_addr], eax
  403.     je      ep_00x                      ; Return 0 in eax if no cards found
  404.  
  405.     call    dword [drvr_probe]          ; Call the drivers probe function
  406.  
  407.     mov     eax, [io_addr]              ; return a non zero value
  408.  
  409. ep_00x:
  410.     ret
  411.  
  412. ;***************************************************************************
  413. ;   Function
  414. ;      ethernet_driver
  415. ;
  416. ;   Description
  417. ;       The ethernet RX and TX handler
  418. ;       This is a kernel function, called by stack_handler
  419. ;
  420. ;***************************************************************************
  421. ethernet_driver:
  422.     ; Do nothing if the driver is inactive
  423.     cmp     [ethernet_active], byte 0
  424.     je      eth_exit
  425.  
  426.     call    eth_rx
  427.     call    eth_tx
  428.  
  429. eth_exit:
  430.     ret
  431.  
  432. ;***************************************************************************
  433. ;   Function
  434. ;      eth_rx
  435. ;
  436. ;   Description
  437. ;      Polls the ethernet card for received data. Extracts if present
  438. ;       Depending on the Protocol within the packet:
  439. ;         ARP : Pass to ARP_handler. This may result in an ARP reply
  440. ;               being tx'ed
  441. ;         IP  : Store in an IP buffer
  442. ;
  443. ;***************************************************************************
  444. eth_rx:
  445.     xor     ax, ax
  446.     mov     [eth_rx_data_len], ax
  447.     call    dword [drvr_poll]       ; Call the drivers poll function
  448.  
  449.     mov     ax, [eth_rx_data_len]
  450.     cmp     ax, 0
  451.     je      .exit
  452.  
  453.  
  454.     ; Check the protocol. Call appropriate handler
  455.  
  456.     mov     ax, [ETH_FRAME.Type]    ; The address of the protocol word
  457.  
  458.     cmp     ax, ETHER_IP
  459.     je      .is_ip                   ; It's IP
  460.  
  461.     cmp     ax, ETHER_ARP
  462.     je      .is_arp                  ; It is ARP
  463.  
  464.     jmp     .exit               ; If not IP or ARP, ignore
  465.  
  466.   .is_ip:
  467.     DEBUGF  1,"K : eth_rx - IP packet\n"
  468.     inc     dword [ip_rx_count]
  469.     call    ether_IP_handler
  470.     jmp     .exit
  471.  
  472.   .is_arp:
  473.     DEBUGF  1,"K : eth_rx - ARP packet\n"
  474.     ; At this point, the packet is still in the Ether_buffer
  475.     call    arp_handler
  476.  
  477.   .exit:
  478.     ret
  479.