Subversion Repositories Kolibri OS

Rev

Rev 748 | Rev 752 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2008. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;;
  21. ;; Data in this file was originally part of MenuetOS project which is
  22. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  23. ;; part of KolibriOS project under the terms of GNU GPL.
  24. ;;
  25. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  26. ;; PROGRAMMING:
  27. ;;
  28. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  29. ;; - main os coding/design
  30. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  31. ;; Felix Kaiser, info@felix-kaiser.de
  32. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  33. ;; quickcode@mail.ru
  34. ;; Alexey, kgaz@crosswinds.net
  35. ;; Juan M. Caravaca, bitrider@wanadoo.es
  36. ;; kristol@nic.fi
  37. ;; Mike Hibbett, mikeh@oceanfree.net
  38. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  39. ;; Jarek Pelczar, jarekp3@wp.pl
  40. ;;
  41. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  42. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  43. ;; consequences of using it or for whether it serves any particular purpose or
  44. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  45. ;; License (the "GPL") for full details.
  46. ;
  47. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  48. ;; but only under the conditions described in the GPL. A copy of this license
  49. ;; is supposed to have been given to you along with KolibriOS so you can know
  50. ;; your rights and responsibilities. It should be in a file named COPYING.
  51. ;; Among other things, the copyright notice and this notice must be preserved
  52. ;; on all copies.
  53. ;;
  54. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  55.  
  56. include 'macros.inc'
  57.  
  58. $Revision: 750 $
  59.  
  60.  
  61. USE_COM_IRQ equ 0      ;make irq 3 and irq 4 available for PCI devices
  62.  
  63. include "proc32.inc"
  64. include "kglobals.inc"
  65. include "lang.inc"
  66.  
  67. include "const.inc"
  68. max_processes   equ   255
  69. tss_step        equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  70.  
  71.  
  72. os_stack       equ  (os_data_l-gdts)    ; GDTs
  73. os_code       equ  (os_code_l-gdts)
  74. graph_data     equ  (3+graph_data_l-gdts)
  75. tss0          equ  (tss0_l-gdts)
  76. app_code       equ  (3+app_code_l-gdts)
  77. app_data       equ  (3+app_data_l-gdts)
  78. pci_code_sel   equ  (pci_code_32-gdts)
  79. pci_data_sel   equ  (pci_data_32-gdts)
  80.  
  81.  
  82. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  83. ;;
  84. ;;   Included files:
  85. ;;
  86. ;;   Kernel16.inc
  87. ;;    - Booteng.inc   English text for bootup
  88. ;;    - Bootcode.inc  Hardware setup
  89. ;;    - Pci16.inc     PCI functions
  90. ;;
  91. ;;   Kernel32.inc
  92. ;;    - Sys32.inc     Process management
  93. ;;    - Shutdown.inc  Shutdown and restart
  94. ;;    - Fat32.inc     Read / write hd
  95. ;;    - Vesa12.inc    Vesa 1.2 driver
  96. ;;    - Vesa20.inc    Vesa 2.0 driver
  97. ;;    - Vga.inc       VGA driver
  98. ;;    - Stack.inc     Network interface
  99. ;;    - Mouse.inc     Mouse pointer
  100. ;;    - Scincode.inc  Window skinning
  101. ;;    - Pci32.inc     PCI functions
  102. ;;
  103. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  104.  
  105.  
  106. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  107. ;;                                                                      ;;
  108. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  109. ;;                                                                      ;;
  110. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  111.  
  112. use16
  113.                   org   0x0
  114.                   jmp   start_of_code
  115.  
  116. version db    'Kolibri OS  version 0.7.1.0      ',13,10,13,10,0
  117.  
  118. include "boot/bootstr.inc"     ; language-independent boot messages
  119. include "boot/preboot.inc"
  120.  
  121. if lang eq en
  122. include "boot/booteng.inc"     ; english system boot messages
  123. else if lang eq ru
  124. include "boot/bootru.inc"      ; russian system boot messages
  125. include "boot/ru.inc"          ; Russian font
  126. else if lang eq et
  127. include "boot/bootet.inc"      ; estonian system boot messages
  128. include "boot/et.inc"          ; Estonian font
  129. else
  130. include "boot/bootge.inc"      ; german system boot messages
  131. end if
  132.  
  133. include "boot/bootcode.inc"    ; 16 bit system boot code
  134. include "bus/pci/pci16.inc"
  135. include "detect/biosdisk.inc"
  136.  
  137. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  138. ;;                                                                      ;;
  139. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  140. ;;                                                                      ;;
  141. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  142.  
  143.  
  144. ; CR0 Flags - Protected mode and Paging
  145.  
  146.         mov ecx, CR0_PE
  147.  
  148. ; Enabling 32 bit protected mode
  149.  
  150.         sidt    [cs:old_ints_h]
  151.  
  152.         cli                             ; disable all irqs
  153.         cld
  154.         mov     al,255                  ; mask all irqs
  155.         out     0xa1,al
  156.         out     0x21,al
  157.    l.5: in      al, 0x64                ; Enable A20
  158.         test    al, 2
  159.         jnz     l.5
  160.         mov     al, 0xD1
  161.         out     0x64, al
  162.    l.6: in      al, 0x64
  163.         test    al, 2
  164.         jnz     l.6
  165.         mov     al, 0xDF
  166.         out     0x60, al
  167.    l.7: in      al, 0x64
  168.         test    al, 2
  169.         jnz     l.7
  170.         mov     al, 0xFF
  171.         out     0x64, al
  172.  
  173.         lgdt    [cs:tmp_gdt]            ; Load GDT
  174.         mov     eax, cr0                ; protected mode
  175.         or      eax, ecx
  176.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  177.         mov     cr0, eax
  178.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  179.  
  180. align 8
  181. tmp_gdt:
  182.  
  183.         dw     23
  184.         dd     tmp_gdt+0x10000
  185.         dw     0
  186.  
  187.         dw     0xffff
  188.         dw     0x0000
  189.         db     0x00
  190.         dw     11011111b *256 +10011010b
  191.         db     0x00
  192.  
  193.         dw     0xffff
  194.         dw     0x0000
  195.         db     0x00
  196.         dw     11011111b *256 +10010010b
  197.         db     0x00
  198.  
  199. include "data16.inc"
  200.  
  201. use32
  202. org $+0x10000
  203.  
  204. align 4
  205. B32:
  206.            mov   ax,os_stack       ; Selector for os
  207.            mov   ds,ax
  208.            mov   es,ax
  209.            mov   fs,ax
  210.            mov   gs,ax
  211.            mov   ss,ax
  212.            mov   esp,0x3ec00       ; Set stack
  213.  
  214. ; CLEAR 0x280000 - HEAP_BASE
  215.  
  216.            xor   eax,eax
  217.            mov   edi,0x280000
  218.            mov   ecx,(HEAP_BASE-OS_BASE-0x280000) / 4
  219.            cld
  220.            rep   stosd
  221.  
  222.            mov   edi,0x40000
  223.            mov   ecx,(0x90000-0x40000)/4
  224.            rep   stosd
  225.  
  226. ; CLEAR KERNEL UNDEFINED GLOBALS
  227.            mov   edi, endofcode-OS_BASE
  228.            mov   ecx, (uglobals_size/4)+4
  229.            rep   stosd
  230.  
  231. ; SAVE & CLEAR 0-0xffff
  232.  
  233.            xor esi, esi
  234.            mov   edi,0x2F0000
  235.            mov   ecx,0x10000 / 4
  236.            rep   movsd
  237.            xor edi, edi
  238.            mov   ecx,0x10000 / 4
  239.            rep   stosd
  240.  
  241.            call test_cpu
  242.            bts [cpu_caps-OS_BASE], CAPS_TSC     ;force use rdtsc
  243.  
  244.            call init_BIOS32
  245. ; MEMORY MODEL
  246.            call mem_test
  247.            call init_mem
  248.            call init_page_map
  249.  
  250. ; ENABLE PAGING
  251.  
  252.            mov eax, sys_pgdir-OS_BASE
  253.            mov cr3, eax
  254.  
  255.            mov eax,cr0
  256.            or eax,CR0_PG+CR0_WP
  257.            mov cr0,eax
  258.  
  259.            lgdt [gdts]
  260.            jmp pword os_code:high_code
  261.  
  262. align 4
  263. bios32_entry    dd ?
  264. tmp_page_tabs   dd ?
  265.  
  266. use16
  267. org $-0x10000
  268. include "boot/shutdown.inc" ; shutdown or restart
  269. org $+0x10000
  270. use32
  271.  
  272. __DEBUG__ fix 1
  273. __DEBUG_LEVEL__ fix 1
  274. include 'init.inc'
  275.  
  276. org OS_BASE+$
  277.  
  278. align 4
  279. high_code:
  280.            mov ax,os_stack
  281.            mov bx,app_data
  282.            mov ss,ax
  283.            add  esp, OS_BASE
  284.  
  285.            mov ds,bx
  286.            mov es,bx
  287.            mov fs,bx
  288.            mov gs,bx
  289.  
  290.            bt [cpu_caps], CAPS_PGE
  291.            jnc @F
  292.  
  293.            or dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  294.  
  295.            mov ebx, cr4
  296.            or ebx, CR4_PGE
  297.            mov cr4, ebx
  298. @@:
  299.            xor eax, eax
  300.            mov dword [sys_pgdir], eax
  301.            mov dword [sys_pgdir+4], eax
  302.  
  303.            mov eax, cr3
  304.            mov cr3, eax           ; flush TLB
  305.  
  306. ; SAVE REAL MODE VARIABLES
  307.         mov     ax, [BOOT_VAR + 0x9031]
  308.         mov     [IDEContrRegsBaseAddr], ax
  309. ; --------------- APM ---------------------
  310.  
  311. ; init selectors
  312.     mov ebx,    [BOOT_VAR+0x9040]              ; offset of APM entry point
  313.     movzx eax, word [BOOT_VAR+0x9050] ; real-mode segment base address of
  314.                                       ; protected-mode 32-bit code segment
  315.     movzx ecx, word [BOOT_VAR+0x9052] ; real-mode segment base address of
  316.                                       ; protected-mode 16-bit code segment
  317.     movzx edx, word [BOOT_VAR+0x9054] ; real-mode segment base address of
  318.                                       ; protected-mode 16-bit data segment
  319.  
  320.     shl    eax, 4
  321.     mov    [dword apm_code_32 + 2], ax
  322.     shr    eax, 16
  323.     mov    [dword apm_code_32 + 4], al
  324.  
  325.     shl    ecx, 4
  326.     mov    [dword apm_code_16 + 2], cx
  327.     shr    ecx, 16
  328.     mov    [dword apm_code_16 + 4], cl
  329.  
  330.     shl    edx, 4
  331.     mov    [dword apm_data_16 + 2], dx
  332.     shr    edx, 16
  333.     mov    [dword apm_data_16 + 4], dl
  334.  
  335.     mov    dword[apm_entry], ebx
  336.     mov    word [apm_entry + 4], apm_code_32 - gdts
  337.  
  338.     mov    eax, [BOOT_VAR + 0x9044]    ; version & flags
  339.     mov    [apm_vf], eax
  340. ; -----------------------------------------
  341. ;        movzx eax,byte [BOOT_VAR+0x9010]  ; mouse port
  342. ;        mov   [0xF604],byte 1  ;al
  343.         mov     al, [BOOT_VAR+0x901F]   ; DMA access
  344.         mov     [allow_dma_access], al
  345.         mov   al,[BOOT_VAR+0x9000]        ; bpp
  346.         mov   [ScreenBPP],al
  347.         movzx eax,word [BOOT_VAR+0x900A]  ; X max
  348.         dec   eax
  349.         mov   [ScreenWidth],eax
  350.         mov   [screen_workarea.right],eax
  351.         movzx eax,word [BOOT_VAR+0x900C]  ; Y max
  352.         dec   eax
  353.         mov   [ScreenHeight],eax
  354.         mov   [screen_workarea.bottom],eax
  355.         movzx eax,word [BOOT_VAR+0x9008]  ; screen mode
  356.         mov   [SCR_MODE],eax
  357.         mov   eax,[BOOT_VAR+0x9014]       ; Vesa 1.2 bnk sw add
  358.         mov   [BANK_SWITCH],eax
  359.         mov   [BytesPerScanLine],word 640*4         ; Bytes PerScanLine
  360.         cmp   [SCR_MODE],word 0x13          ; 320x200
  361.         je    @f
  362.         cmp   [SCR_MODE],word 0x12          ; VGA 640x480
  363.         je    @f
  364.         mov   ax,[BOOT_VAR+0x9001]        ; for other modes
  365.         mov   [BytesPerScanLine],ax
  366. @@:
  367.         mov     esi, BOOT_VAR+0x9080
  368.         movzx   ecx, byte [esi-1]
  369.         mov     [NumBiosDisks], ecx
  370.         mov     edi, BiosDisksData
  371.         rep     movsd
  372.  
  373. ; GRAPHICS ADDRESSES
  374.  
  375.         mov     byte [BOOT_VAR+0x901e],0x0
  376.         mov     eax,[BOOT_VAR+0x9018]
  377.         mov     [LFBAddress],eax
  378.  
  379.         cmp     [SCR_MODE],word 0100000000000000b
  380.         jge     setvesa20
  381.         cmp     [SCR_MODE],word 0x13
  382.         je      v20ga32
  383.         mov     [PUTPIXEL],dword Vesa12_putpixel24  ; Vesa 1.2
  384.         mov     [GETPIXEL],dword Vesa12_getpixel24
  385.         cmp     [ScreenBPP],byte 24
  386.         jz      ga24
  387.         mov     [PUTPIXEL],dword Vesa12_putpixel32
  388.         mov     [GETPIXEL],dword Vesa12_getpixel32
  389.       ga24:
  390.         jmp     v20ga24
  391.       setvesa20:
  392.         mov     [PUTPIXEL],dword Vesa20_putpixel24  ; Vesa 2.0
  393.         mov     [GETPIXEL],dword Vesa20_getpixel24
  394.         cmp     [ScreenBPP],byte 24
  395.         jz      v20ga24
  396.       v20ga32:
  397.         mov     [PUTPIXEL],dword Vesa20_putpixel32
  398.         mov     [GETPIXEL],dword Vesa20_getpixel32
  399.       v20ga24:
  400.         cmp     [SCR_MODE],word 0x12                ; 16 C VGA 640x480
  401.         jne     no_mode_0x12
  402.         mov     [PUTPIXEL],dword VGA_putpixel
  403.         mov     [GETPIXEL],dword Vesa20_getpixel32
  404.       no_mode_0x12:
  405.  
  406. ; -------- Fast System Call init ----------
  407. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  408.            bt [cpu_caps], CAPS_SEP
  409.            jnc .SEnP   ; SysEnter not Present
  410.            xor edx, edx
  411.            mov ecx, MSR_SYSENTER_CS
  412.            mov eax, os_code
  413.            wrmsr
  414.            mov ecx, MSR_SYSENTER_ESP
  415. ;           mov eax, sysenter_stack ; Check it
  416.            xor     eax, eax
  417.            wrmsr
  418.            mov ecx, MSR_SYSENTER_EIP
  419.            mov eax, sysenter_entry
  420.            wrmsr
  421. .SEnP:
  422. ; AMD SYSCALL/SYSRET
  423.            cmp byte[cpu_vendor], 'A'
  424.            jne .noSYSCALL
  425.            mov eax, 0x80000001
  426.            cpuid
  427.            test edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  428.            jz .noSYSCALL
  429.            mov ecx, MSR_AMD_EFER
  430.            rdmsr
  431.            or eax, 1   ; bit_0 - System Call Extension (SCE)
  432.            wrmsr
  433.  
  434.         ; !!!! It`s dirty hack, fix it !!!
  435.         ; Bits of EDX :
  436.         ; Bit 31Ц16 During the SYSRET instruction, this field is copied into the CS register
  437.         ;  and the contents of this field, plus 8, are copied into the SS register.
  438.         ; Bit 15Ц0 During the SYSCALL instruction, this field is copied into the CS register
  439.         ;  and the contents of this field, plus 8, are copied into the SS register.
  440.  
  441.         ; mov   edx, (os_code + 16) * 65536 + os_code
  442.            mov edx, 0x1B0008
  443.  
  444.            mov eax, syscall_entry
  445.            mov ecx, MSR_AMD_STAR
  446.            wrmsr
  447. .noSYSCALL:
  448. ; -----------------------------------------
  449.  
  450. ; LOAD IDT
  451.  
  452.            call build_interrupt_table
  453.            lidt [idtreg]
  454.  
  455.            call init_kernel_heap
  456.            stdcall kernel_alloc, RING0_STACK_SIZE+512
  457.            mov [os_stack_seg], eax
  458.  
  459.            lea esp, [eax+RING0_STACK_SIZE]
  460.  
  461.            mov [tss._ss0], os_stack
  462.            mov [tss._esp0], esp
  463.            mov [tss._esp], esp
  464.            mov [tss._cs],os_code
  465.            mov [tss._ss],os_stack
  466.            mov [tss._ds],app_data
  467.            mov [tss._es],app_data
  468.            mov [tss._fs],app_data
  469.            mov [tss._gs],app_data
  470.            mov [tss._io],128
  471. ;Add IO access table - bit array of permitted ports
  472.            mov edi, tss._io_map_0
  473.            xor eax, eax
  474.            not eax
  475.            mov ecx, 8192/4
  476.            rep stosd                 ; access to 4096*8=65536 ports
  477.  
  478.            mov  ax,tss0
  479.            ltr  ax
  480.  
  481.            mov [LFBSize], 0x800000
  482.            call init_LFB
  483.            call init_fpu
  484.            call init_malloc
  485.  
  486.            stdcall alloc_kernel_space, 0x51000
  487.            mov [default_io_map], eax
  488.  
  489.            add eax, 0x2000
  490.            mov [ipc_tmp], eax
  491.            mov ebx, 0x1000
  492.  
  493.            add eax, 0x40000
  494.            mov [proc_mem_map], eax
  495.  
  496.            add eax, 0x8000
  497.            mov [proc_mem_pdir], eax
  498.  
  499.            add eax, ebx
  500.            mov [proc_mem_tab], eax
  501.  
  502.            add eax, ebx
  503.            mov [tmp_task_pdir], eax
  504.  
  505.            add eax, ebx
  506.            mov [tmp_task_ptab], eax
  507.  
  508.            add eax, ebx
  509.            mov [ipc_pdir], eax
  510.  
  511.            add eax, ebx
  512.            mov [ipc_ptab], eax
  513.  
  514.            stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  515.                                  (unpack.lc+unpack.lp)))*4
  516.  
  517.            mov [unpack.p], eax
  518.  
  519.            call init_events
  520.            mov eax, srv.fd-SRV_FD_OFFSET
  521.            mov [srv.fd], eax
  522.            mov [srv.bk], eax
  523.  
  524.            mov edi, irq_tab
  525.            xor eax, eax
  526.            mov ecx, 16
  527.            rep stosd
  528.  
  529. ;Set base of graphic segment to linear address of LFB
  530.         mov     eax,[LFBAddress]          ; set for gs
  531.         mov     [graph_data_l+2],ax
  532.         shr     eax,16
  533.         mov     [graph_data_l+4],al
  534.         mov     [graph_data_l+7],ah
  535.  
  536.         mov [CURRENT_TASK],dword 1
  537.         mov [TASK_COUNT],dword 1
  538.         mov [TASK_BASE],dword TASK_DATA
  539.         mov [current_slot], SLOT_BASE+256
  540.  
  541. ; set background
  542.         xor  eax,eax
  543.         inc  eax
  544.         mov   [BgrDrawMode],eax
  545.         mov   [BgrDataWidth],eax
  546.         mov   [BgrDataHeight],eax
  547.         mov    [mem_BACKGROUND],4095
  548.         stdcall kernel_alloc, [mem_BACKGROUND]
  549.         mov [img_background], eax
  550.  
  551.         mov     [SLOT_BASE + 256 + APPDATA.dir_table], sys_pgdir - OS_BASE
  552.  
  553. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  554.  
  555.         call  rerouteirqs
  556.  
  557. ; Initialize system V86 machine
  558.         call    init_sys_v86
  559.  
  560. ; TIMER SET TO 1/100 S
  561.  
  562.         mov   al,0x34              ; set to 100Hz
  563.         out   0x43,al
  564.         mov   al,0x9b              ; lsb    1193180 / 1193
  565.         out   0x40,al
  566.         mov   al,0x2e              ; msb
  567.         out   0x40,al
  568.  
  569. ; Enable timer IRQ (IRQ0) and hard drives IRQs (IRQ14, IRQ15)
  570. ; they are used: when partitions are scanned, hd_read relies on timer
  571.         mov     al, 0xFE
  572.         out     0x21, al
  573.         mov     al, 0x3F
  574.         out     0xA1, al
  575.  
  576. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  577. include 'detect/disks.inc'
  578. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  579.  
  580.   call Parser_params
  581.  
  582. ; READ RAMDISK IMAGE FROM HD
  583.  
  584. ;!!!!!!!!!!!!!!!!!!!!!!!
  585. include 'boot/rdload.inc'
  586. ;!!!!!!!!!!!!!!!!!!!!!!!
  587. ;    mov    [dma_hdd],1
  588. ; CALCULATE FAT CHAIN FOR RAMDISK
  589.  
  590.         call  calculatefatchain
  591.  
  592. ; LOAD VMODE DRIVER
  593.  
  594. ;!!!!!!!!!!!!!!!!!!!!!!!
  595. include 'vmodeld.inc'
  596. ;!!!!!!!!!!!!!!!!!!!!!!!
  597.  
  598.   mov ax,[OS_BASE+0x10000+bx_from_load]
  599.   cmp ax,'r1'           ; if using not ram disk, then load librares and parameters {SPraid.simba}
  600.   je  no_lib_load
  601. ; LOADING LIBRARES
  602.    stdcall dll.Load,@IMPORT                 ; loading librares for kernel (.obj files)
  603.    call load_file_parse_table               ; prepare file parse table
  604.    call set_kernel_conf                     ; configure devices and gui
  605. no_lib_load:
  606.  
  607. ; LOAD FONTS I and II
  608.  
  609.         stdcall read_file, char, FONT_I, 0, 2304
  610.         stdcall read_file, char2, FONT_II, 0, 2560
  611.  
  612.         mov   esi,boot_fonts
  613.         call  boot_log
  614.  
  615. ; PRINT AMOUNT OF MEMORY
  616.         mov     esi, boot_memdetect
  617.         call    boot_log
  618.  
  619.         movzx   ecx, word [boot_y]
  620.         or      ecx, (10+29*6) shl 16 ; "Determining amount of memory"
  621.         sub     ecx, 10
  622.         mov     edx, 0xFFFFFF
  623.         mov     ebx, [MEM_AMOUNT]
  624.         shr     ebx, 20
  625.         mov     edi, 1
  626.         mov     eax, 0x00040000
  627.         call    display_number_force
  628.  
  629. ; BUILD SCHEDULER
  630.  
  631.         call   build_scheduler ; sys32.inc
  632.  
  633.         mov    esi,boot_devices
  634.         call   boot_log
  635.  
  636.         mov  [pci_access_enabled],1
  637.  
  638.         call   detect_devices
  639.         stdcall load_driver, szPS2MDriver
  640.  
  641. ; SET MOUSE
  642.  
  643.         mov   esi,boot_setmouse
  644.         call  boot_log
  645.         call  setmouse
  646.  
  647.  
  648. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  649.  
  650.         mov   esi,boot_windefs
  651.         call  boot_log
  652.         call  setwindowdefaults
  653.  
  654. ; SET BACKGROUND DEFAULTS
  655.  
  656.         mov   esi,boot_bgr
  657.         call  boot_log
  658.         call  init_background
  659.         call  calculatebackground
  660.  
  661. ; RESERVE SYSTEM IRQ'S JA PORT'S
  662.  
  663.         mov   esi,boot_resirqports
  664.         call  boot_log
  665.         call  reserve_irqs_ports
  666.  
  667. ; SET PORTS FOR IRQ HANDLERS
  668.  
  669.         mov  esi,boot_setrports
  670.         call boot_log
  671.         call setirqreadports
  672.  
  673. ; SET UP OS TASK
  674.  
  675.         mov  esi,boot_setostask
  676.         call boot_log
  677.  
  678.         xor  eax, eax
  679.         mov  dword [SLOT_BASE+APPDATA.fpu_state], fpu_data
  680.         mov  dword [SLOT_BASE+APPDATA.fpu_handler], eax
  681.         mov  dword [SLOT_BASE+APPDATA.sse_handler], eax
  682.  
  683.         ; name for OS/IDLE process
  684.  
  685.         mov dword [SLOT_BASE+256+APPDATA.app_name],   dword 'OS/I'
  686.         mov dword [SLOT_BASE+256+APPDATA.app_name+4], dword 'DLE '
  687.         mov edi, [os_stack_seg]
  688.         mov dword [SLOT_BASE+256+APPDATA.pl0_stack], edi
  689.         add edi, 0x2000-512
  690.         mov dword [SLOT_BASE+256+APPDATA.fpu_state], edi
  691.         mov dword [SLOT_BASE+256+APPDATA.saved_esp0], edi ; just for case
  692.         mov dword [SLOT_BASE+256+APPDATA.io_map],\
  693.                   (tss._io_map_0-OS_BASE+PG_MAP)
  694.         mov dword [SLOT_BASE+256+APPDATA.io_map+4],\
  695.                   (tss._io_map_1-OS_BASE+PG_MAP)
  696.  
  697.         mov esi, fpu_data
  698.         mov ecx, 512/4
  699.         cld
  700.         rep movsd
  701.  
  702.         mov dword [SLOT_BASE+256+APPDATA.fpu_handler], eax
  703.         mov dword [SLOT_BASE+256+APPDATA.sse_handler], eax
  704.  
  705.         mov ebx, SLOT_BASE+256+APP_OBJ_OFFSET
  706.         mov  dword [SLOT_BASE+256+APPDATA.fd_obj], ebx
  707.         mov  dword [SLOT_BASE+256+APPDATA.bk_obj], ebx
  708.  
  709.         mov  dword [SLOT_BASE+256+APPDATA.cur_dir], sysdir_path
  710.  
  711.         ; task list
  712.         mov  [CURRENT_TASK],dword 1
  713.         mov  [TASK_COUNT],dword 1
  714.         mov  [current_slot], SLOT_BASE+256
  715.         mov  [TASK_BASE],dword TASK_DATA
  716.         mov  [TASK_DATA+TASKDATA.wnd_number], 1 ; on screen number
  717.         mov  [TASK_DATA+TASKDATA.pid], 1        ; process id number
  718.         mov  [TASK_DATA+TASKDATA.mem_start], 0  ; process base address
  719.  
  720.         call init_cursors
  721.         mov eax, [def_cursor]
  722.         mov [SLOT_BASE+APPDATA.cursor],eax
  723.         mov [SLOT_BASE+APPDATA.cursor+256],eax
  724.  
  725.   ; READ TSC / SECOND
  726.  
  727.         mov   esi,boot_tsc
  728.         call  boot_log
  729.         cli
  730.         call  _rdtsc
  731.         mov   ecx,eax
  732.         mov   esi,250               ; wait 1/4 a second
  733.         call  delay_ms
  734.         call  _rdtsc
  735.         sti
  736.         sub   eax,ecx
  737.         shl   eax,2
  738.         mov   [CPU_FREQ],eax          ; save tsc / sec
  739.         mov ebx, 1000000
  740.         div ebx
  741.         mov [stall_mcs], eax
  742.  
  743. ; SET VARIABLES
  744.  
  745.         call  set_variables
  746.  
  747. ; STACK AND FDC
  748.  
  749.         call  stack_init
  750.         call  fdc_init
  751.  
  752. ; PALETTE FOR 320x200 and 640x480 16 col
  753.  
  754.         cmp   [SCR_MODE],word 0x12
  755.         jne   no_pal_vga
  756.         mov   esi,boot_pal_vga
  757.         call  boot_log
  758.         call  paletteVGA
  759.       no_pal_vga:
  760.  
  761.         cmp   [SCR_MODE],word 0x13
  762.         jne   no_pal_ega
  763.         mov   esi,boot_pal_ega
  764.         call  boot_log
  765.         call  palette320x200
  766.       no_pal_ega:
  767.  
  768. ; LOAD DEFAULT SKIN
  769.  
  770.         call    load_default_skin
  771.  
  772. ;protect io permission map
  773.  
  774.            mov esi, [default_io_map]
  775.            stdcall map_page,esi,(tss._io_map_0-OS_BASE), PG_MAP
  776.            add esi, 0x1000
  777.            stdcall map_page,esi,(tss._io_map_1-OS_BASE), PG_MAP
  778.  
  779.            stdcall map_page,tss._io_map_0,\
  780.                    (tss._io_map_0-OS_BASE), PG_MAP
  781.            stdcall map_page,tss._io_map_1,\
  782.                    (tss._io_map_1-OS_BASE), PG_MAP
  783.  
  784.   mov ax,[OS_BASE+0x10000+bx_from_load]
  785.   cmp ax,'r1'           ; if not rused ram disk - load network configuration from files {SPraid.simba}
  786.   je  no_st_network
  787.         call set_network_conf
  788.   no_st_network:
  789.  
  790. ; LOAD FIRST APPLICATION
  791.         cli
  792.  
  793.         cmp   byte [BOOT_VAR+0x9030],1
  794.         jne   no_load_vrr_m
  795.  
  796.         mov     ebp, vrr_m
  797.         call    fs_execute_from_sysdir
  798.  
  799.         cmp   eax,2                  ; if vrr_m app found (PID=2)
  800.         je    first_app_found
  801.  
  802. no_load_vrr_m:
  803.  
  804.         mov     ebp, firstapp
  805.         call    fs_execute_from_sysdir
  806.  
  807.         cmp   eax,2                  ; continue if a process has been loaded
  808.         je    first_app_found
  809.  
  810.         mov     esi, boot_failed
  811.         call    boot_log
  812.  
  813.         mov   eax, 0xDEADBEEF        ; otherwise halt
  814.         hlt
  815.  
  816. first_app_found:
  817.  
  818.         cli
  819.  
  820.         ;mov   [TASK_COUNT],dword 2
  821.         mov   [CURRENT_TASK],dword 1       ; set OS task fisrt
  822.  
  823. ; SET KEYBOARD PARAMETERS
  824.         mov   al, 0xf6         ; reset keyboard, scan enabled
  825.         call  kb_write
  826.  
  827.         ; wait until 8042 is ready
  828.         xor ecx,ecx
  829.       @@:
  830.         in     al,64h
  831.         and    al,00000010b
  832.         loopnz @b
  833.  
  834.        ; mov   al, 0xED       ; svetodiody - only for testing!
  835.        ; call  kb_write
  836.        ; call  kb_read
  837.        ; mov   al, 111b
  838.        ; call  kb_write
  839.        ; call  kb_read
  840.  
  841.         mov   al, 0xF3       ; set repeat rate & delay
  842.         call  kb_write
  843. ;        call  kb_read
  844.         mov   al, 0 ; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  845.         call  kb_write
  846. ;        call  kb_read
  847.      ;// mike.dld [
  848.         call  set_lights
  849.      ;// mike.dld ]
  850.  
  851. ; START MULTITASKING
  852.  
  853.         mov   esi,boot_tasking
  854.         call  boot_log
  855.  
  856. ;       mov   [ENABLE_TASKSWITCH],byte 1        ; multitasking enabled
  857.  
  858. ; UNMASK ALL IRQ'S
  859.  
  860.         mov   esi,boot_allirqs
  861.         call  boot_log
  862.  
  863.         cli                          ;guarantee forbidance of interrupts.
  864.         mov   al,0                   ; unmask all irq's
  865.         out   0xA1,al
  866.         out   0x21,al
  867.  
  868.         mov   ecx,32
  869.  
  870.      ready_for_irqs:
  871.  
  872.         mov   al,0x20                ; ready for irqs
  873.         out   0x20,al
  874.         out   0xa0,al
  875.  
  876.         loop  ready_for_irqs         ; flush the queue
  877.  
  878.         stdcall attach_int_handler, dword 1, irq1
  879.  
  880. ;        mov    [dma_hdd],1
  881.         cmp     [IDEContrRegsBaseAddr], 0
  882.         setnz   [dma_hdd]
  883.         mov [timer_ticks_enable],1              ; for cd driver
  884.  
  885. ;        stdcall init_uart_service, DRV_ENTRY
  886.  
  887.         sti
  888.         call change_task
  889.  
  890.         jmp osloop
  891.  
  892. ;        jmp   $                      ; wait here for timer to take control
  893.  
  894.         ; Fly :)
  895.  
  896. include 'unpacker.inc'
  897. include 'fdo.inc'
  898.  
  899. align 4
  900. boot_log:
  901.          pushad
  902.  
  903.          mov   ebx,10*65536
  904.          mov   bx,word [boot_y]
  905.          add   [boot_y],dword 10
  906.          mov   ecx,0x80ffffff   ; ASCIIZ string with white color
  907.          mov   edx,esi
  908.          mov   edi,1
  909.          call  dtext
  910.  
  911.          mov   [novesachecksum],1000
  912.          call  checkVga_N13
  913.  
  914.          cmp   [preboot_blogesc+OS_BASE+0x10000],byte 1
  915.          je    .bll2
  916.  
  917.          cmp   esi,boot_tasking
  918.          jne   .bll2
  919.          ; begin ealex 04.08.05
  920. ;         in    al,0x61
  921. ;         and   al,01111111b
  922. ;         out   0x61,al
  923.          ; end ealex 04.08.05
  924. .bll1:   in    al,0x60    ; wait for ESC key press
  925.          cmp   al,129
  926.          jne   .bll1
  927.  
  928. .bll2:   popad
  929.  
  930.          ret
  931.  
  932.  
  933. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  934. ;                                                                    ;
  935. ;                    MAIN OS LOOP START                              ;
  936. ;                                                                    ;
  937. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  938. align 32
  939. osloop:
  940.         call   [draw_pointer]
  941.         call   checkbuttons
  942.         call   checkwindows
  943. ;       call   check_window_move_request
  944.         call   checkmisc
  945.         call   checkVga_N13
  946.         call   stack_handler
  947.         call   checkidle
  948.         call   check_fdd_motor_status
  949.         call   check_ATAPI_device_event
  950.         jmp    osloop
  951. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  952. ;                                                                    ;
  953. ;                      MAIN OS LOOP END                              ;
  954. ;                                                                    ;
  955. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  956.  
  957. checkidle:
  958.         pushad
  959.  
  960.         cmp  [check_idle_semaphore],0
  961.         jne  no_idle_state
  962.  
  963.         call change_task
  964.         mov  eax,[idlemem]
  965.         mov  ebx,[timer_ticks] ;[0xfdf0]
  966.         cmp  eax,ebx
  967.         jnz  idle_exit
  968.         call _rdtsc
  969.         mov  ecx,eax
  970.       idle_loop:
  971.         hlt
  972.         cmp  [check_idle_semaphore],0
  973.         jne  idle_loop_exit
  974.         mov  eax,[timer_ticks] ;[0xfdf0]
  975.         cmp  ebx,eax
  976.         jz   idle_loop
  977.       idle_loop_exit:
  978.         mov  [idlemem],eax
  979.         call _rdtsc
  980.         sub  eax,ecx
  981.         mov  ebx,[idleuse]
  982.         add  ebx,eax
  983.         mov  [idleuse],ebx
  984.  
  985.         popad
  986.         ret
  987.  
  988.       idle_exit:
  989.  
  990.         mov  ebx,[timer_ticks] ;[0xfdf0]
  991.         mov  [idlemem],ebx
  992.         call change_task
  993.  
  994.         popad
  995.         ret
  996.  
  997.       no_idle_state:
  998.  
  999.         dec  [check_idle_semaphore]
  1000.  
  1001.         mov  ebx,[timer_ticks] ;[0xfdf0]
  1002.         mov  [idlemem],ebx
  1003.         call change_task
  1004.  
  1005.         popad
  1006.         ret
  1007.  
  1008. uglobal
  1009.   idlemem               dd   0x0
  1010.   idleuse               dd   0x0
  1011.   idleusesec            dd   0x0
  1012.   check_idle_semaphore  dd   0x0
  1013. endg
  1014.  
  1015.  
  1016.  
  1017. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1018. ;                                                                      ;
  1019. ;                   INCLUDED SYSTEM FILES                              ;
  1020. ;                                                                      ;
  1021. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1022.  
  1023.  
  1024. include "kernel32.inc"
  1025.  
  1026.  
  1027. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1028. ;                                                                      ;
  1029. ;                       KERNEL FUNCTIONS                               ;
  1030. ;                                                                      ;
  1031. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1032.  
  1033. reserve_irqs_ports:
  1034.  
  1035.         pushad
  1036.  
  1037.         mov  [irq_owner+4*0], 1    ; timer
  1038.         mov  [irq_owner+4*1], 1    ; keyboard
  1039.         mov  [irq_owner+4*5], 1    ; sound blaster
  1040.         mov  [irq_owner+4*6], 1    ; floppy diskette
  1041.         mov  [irq_owner+4*13], 1   ; math co-pros
  1042.         mov  [irq_owner+4*14], 1   ; ide I
  1043.         mov  [irq_owner+4*15], 1   ; ide II
  1044.  
  1045.         ; RESERVE PORTS
  1046.         mov   edi,1                    ; 0x00-0x2d
  1047.         mov   [RESERVED_PORTS],edi
  1048.         shl   edi,4
  1049.         mov   [RESERVED_PORTS+edi+0],dword 1
  1050.         mov   [RESERVED_PORTS+edi+4],dword 0x0
  1051.         mov   [RESERVED_PORTS+edi+8],dword 0x2d
  1052.  
  1053.         inc   dword [RESERVED_PORTS]          ; 0x30-0x4d
  1054.         mov   edi,[RESERVED_PORTS]
  1055.         shl   edi,4
  1056.         mov   [RESERVED_PORTS+edi+0],dword 1
  1057.         mov   [RESERVED_PORTS+edi+4],dword 0x30
  1058.         mov   [RESERVED_PORTS+edi+8],dword 0x4d
  1059.  
  1060.         inc   dword [RESERVED_PORTS]          ; 0x50-0xdf
  1061.         mov   edi,[RESERVED_PORTS]
  1062.         shl   edi,4
  1063.         mov   [RESERVED_PORTS+edi+0],dword 1
  1064.         mov   [RESERVED_PORTS+edi+4],dword 0x50
  1065.         mov   [RESERVED_PORTS+edi+8],dword 0xdf
  1066.  
  1067.         inc   dword [RESERVED_PORTS]          ; 0xe5-0xff
  1068.         mov   edi,[RESERVED_PORTS]
  1069.         shl   edi,4
  1070.         mov   [RESERVED_PORTS+edi+0],dword 1
  1071.         mov   [RESERVED_PORTS+edi+4],dword 0xe5
  1072.         mov   [RESERVED_PORTS+edi+8],dword 0xff
  1073.  
  1074.         popad
  1075.         ret
  1076.  
  1077. iglobal
  1078. mouseirqtable   db  12    ; ps2
  1079.                 db  4     ; com1
  1080.                 db  3     ; com2
  1081. endg
  1082.  
  1083. setirqreadports:
  1084.  
  1085.         mov   [irq12read+0],dword 0x60 + 0x01000000  ; read port 0x60 , byte
  1086.         mov   [irq12read+4],dword 0                  ; end of port list
  1087.         mov   [irq04read+0],dword 0x3f8 + 0x01000000 ; read port 0x3f8 , byte
  1088.         mov   [irq04read+4],dword 0                  ; end of port list
  1089.         mov   [irq03read+0],dword 0x2f8 + 0x01000000 ; read port 0x2f8 , byte
  1090.         mov   [irq03read+4],dword 0                  ; end of port list
  1091.  
  1092.         ret
  1093.  
  1094. iglobal
  1095.   process_number dd 0x1
  1096. endg
  1097.  
  1098. set_variables:
  1099.  
  1100.         mov   ecx,0x100                       ; flush port 0x60
  1101. .fl60:  in    al,0x60
  1102.         loop  .fl60
  1103.         mov   [MOUSE_BUFF_COUNT],byte 0                 ; mouse buffer
  1104.         mov   [KEY_COUNT],byte 0                 ; keyboard buffer
  1105.         mov   [BTN_COUNT],byte 0                 ; button buffer
  1106. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1107.  
  1108.         push  eax
  1109.         mov   ax,[BOOT_VAR+0x900c]
  1110.         shr   ax,1
  1111.         shl   eax,16
  1112.         mov   ax,[BOOT_VAR+0x900A]
  1113.         shr   ax,1
  1114.         mov   [MOUSE_X],eax
  1115.         pop   eax
  1116.  
  1117.         mov   byte [SB16_Status],0            ; Minazzi Paolo
  1118.         mov   [BTN_ADDR],dword BUTTON_INFO    ; address of button list
  1119.  
  1120.      ;!! IP 04.02.2005:
  1121.         mov   [next_usage_update], 100
  1122.         mov   byte [DONT_SWITCH], 0 ; change task if possible
  1123.  
  1124.         ret
  1125.  
  1126. ;* mouse centered - start code- Mario79
  1127. mouse_centered:
  1128.         push  eax
  1129.         mov   eax,[ScreenWidth]
  1130.         shr   eax,1
  1131.         mov   [MOUSE_X],ax
  1132.         mov   eax,[ScreenHeight]
  1133.         shr   eax,1
  1134.         mov   [MOUSE_Y],ax
  1135.         pop   eax
  1136.         ret
  1137. ;* mouse centered - end code- Mario79
  1138.  
  1139. align 4
  1140.  
  1141. sys_outport:
  1142.  
  1143.     mov   edi,ebx          ; separate flag for read / write
  1144.     and   ebx,65535
  1145.  
  1146.     mov   ecx,[RESERVED_PORTS]
  1147.     test  ecx,ecx
  1148.     jne   sopl8
  1149.     mov   [esp+36],dword 1
  1150.     ret
  1151.  
  1152.   sopl8:
  1153.     mov   edx,[TASK_BASE]
  1154.     mov   edx,[edx+0x4]
  1155.     and   ebx,65535
  1156.     cld
  1157.   sopl1:
  1158.  
  1159.     mov   esi,ecx
  1160.     shl   esi,4
  1161.     add   esi,RESERVED_PORTS
  1162.     cmp   edx,[esi+0]
  1163.     jne   sopl2
  1164.     cmp   ebx,[esi+4]
  1165.     jb    sopl2
  1166.     cmp   ebx,[esi+8]
  1167.     jg    sopl2
  1168.     jmp   sopl3
  1169.  
  1170.   sopl2:
  1171.  
  1172.     dec   ecx
  1173.     jnz   sopl1
  1174.     mov   [esp+36],dword 1
  1175.     ret
  1176.  
  1177.   sopl3:
  1178.  
  1179.     test  edi,0x80000000 ; read ?
  1180.     jnz   sopl4
  1181.  
  1182.     mov   dx,bx          ; write
  1183.     out   dx,al
  1184.     mov   [esp+36],dword 0
  1185.     ret
  1186.  
  1187.   sopl4:
  1188.  
  1189.     mov   dx,bx          ; read
  1190.     in    al,dx
  1191.     and   eax,0xff
  1192.     mov   [esp+36],dword 0
  1193.     mov   [esp+24],eax
  1194.     ret
  1195.  
  1196.  
  1197.  
  1198. align 4
  1199. sys_sb16:
  1200.  
  1201.      cmp  word [sb16],word 0
  1202.      jnz  sb16l1
  1203.      mov  [esp+36],dword 1
  1204.      ret
  1205.    sb16l1:
  1206.      mov  [esp+36],dword 0
  1207.      cmp  eax,1    ; set volume - main
  1208.      jnz  sb16l2
  1209.      mov  dx,word [sb16]
  1210.      add  dx,4
  1211.      mov  al,0x22
  1212.      out  dx,al
  1213.      mov  esi,1
  1214.      call delay_ms
  1215.      mov  eax,ebx
  1216.      inc  edx
  1217.      out  dx,al
  1218.      ret
  1219.    sb16l2:
  1220.  
  1221.      cmp  eax,2    ; set volume - cd
  1222.      jnz  sb16l3
  1223.      mov  dx,word [sb16]
  1224.      add  dx,4
  1225.      mov  al,0x28
  1226.      out  dx,al
  1227.      mov  esi,1
  1228.      call delay_ms
  1229.      mov  eax,ebx
  1230.      add  edx,1
  1231.      out  dx,al
  1232.      ret
  1233.    sb16l3:
  1234.       mov  [esp+36],dword 2
  1235.       ret
  1236.  
  1237.  
  1238. align 4
  1239.  
  1240. sys_sb16II:
  1241.  
  1242.      cmp  word [sb16],word 0
  1243.      jnz  IIsb16l1
  1244.      mov  [esp+36],dword 1
  1245.      ret
  1246.    IIsb16l1:
  1247.  
  1248.      cmp  eax,1    ; set volume - main
  1249.      jnz  IIsb16l2
  1250.      ; L
  1251.      mov  dx,word [sb16]
  1252.      add  dx,4
  1253.      mov  al,0x30
  1254.      out  dx,al
  1255.      mov  eax,ebx
  1256.      inc  edx
  1257.      out  dx,al
  1258.      ; R
  1259.      mov  dx,word [sb16]
  1260.      add  dx,4
  1261.      mov  al,0x31
  1262.      out  dx,al
  1263.      mov  eax,ebx
  1264.      inc  edx
  1265.      out  dx,al
  1266.      mov  [esp+36],dword 0
  1267.      ret
  1268.    IIsb16l2:
  1269.  
  1270.      cmp  eax,2    ; set volume - cd
  1271.      jnz  IIsb16l3
  1272.      ; L
  1273.      mov  dx,word [sb16]
  1274.      add  dx,4
  1275.      mov  al,0x36
  1276.      out  dx,al
  1277.      mov  eax,ebx
  1278.      inc  edx
  1279.      out  dx,al
  1280.      ; R
  1281.      mov  dx,word [sb16]
  1282.      add  dx,4
  1283.      mov  al,0x37
  1284.      out  dx,al
  1285.      mov  eax,ebx
  1286.      inc  edx
  1287.      out  dx,al
  1288.      mov  [esp+36],dword 0
  1289.      ret
  1290.    IIsb16l3:
  1291.  
  1292.      mov  [esp+36],dword 2
  1293.      ret
  1294.  
  1295.  
  1296. display_number:
  1297.  
  1298. ; eax = print type, al=0 -> ebx is number
  1299. ;                   al=1 -> ebx is pointer
  1300. ;                   ah=0 -> display decimal
  1301. ;                   ah=1 -> display hexadecimal
  1302. ;                   ah=2 -> display binary
  1303. ;                   eax bits 16-21 = number of digits to display (0-32)
  1304. ;                   eax bits 22-31 = reserved
  1305. ;
  1306. ; ebx = number or pointer
  1307. ; ecx = x shl 16 + y
  1308. ; edx = color
  1309.         xor     edi, edi
  1310. display_number_force:
  1311.      push  eax
  1312.      and   eax,0x3fffffff
  1313.      cmp   eax,0xffff            ; length > 0 ?
  1314.      pop   eax
  1315.      jge   cont_displ
  1316.      ret
  1317.    cont_displ:
  1318.      push  eax
  1319.      and   eax,0x3fffffff
  1320.      cmp   eax,61*0x10000        ; length <= 60 ?
  1321.      pop   eax
  1322.      jb    cont_displ2
  1323.      ret
  1324.    cont_displ2:
  1325.  
  1326.      pushad
  1327.  
  1328.      cmp   al,1                  ; ecx is a pointer ?
  1329.      jne   displnl1
  1330.      mov   ebp,ebx
  1331.      add   ebp,4
  1332.      mov   ebp,[ebp+std_application_base_address]
  1333.      mov   ebx,[ebx+std_application_base_address]
  1334.    displnl1:
  1335.      sub   esp,64
  1336.  
  1337.      cmp   ah,0                  ; DECIMAL
  1338.      jne   no_display_desnum
  1339.      shr   eax,16
  1340.      and   eax,0xC03f
  1341. ;     and   eax,0x3f
  1342.      push  eax
  1343.      and   eax,0x3f
  1344.      mov   edi,esp
  1345.      add   edi,4+64-1
  1346.      mov   ecx,eax
  1347.      mov   eax,ebx
  1348.      mov   ebx,10
  1349.    d_desnum:
  1350.      xor   edx,edx
  1351.      call  division_64_bits
  1352.      div   ebx
  1353.      add   dl,48
  1354.      mov   [edi],dl
  1355.      dec   edi
  1356.      loop  d_desnum
  1357.      pop   eax
  1358.      call  normalize_number
  1359.      call  draw_num_text
  1360.      add   esp,64
  1361.      popad
  1362.      ret
  1363.    no_display_desnum:
  1364.  
  1365.      cmp   ah,0x01               ; HEXADECIMAL
  1366.      jne   no_display_hexnum
  1367.      shr   eax,16
  1368.      and   eax,0xC03f
  1369. ;     and   eax,0x3f
  1370.      push  eax
  1371.      and   eax,0x3f
  1372.      mov   edi,esp
  1373.      add   edi,4+64-1
  1374.      mov   ecx,eax
  1375.      mov   eax,ebx
  1376.      mov   ebx,16
  1377.    d_hexnum:
  1378.      xor   edx,edx
  1379.      call  division_64_bits
  1380.      div   ebx
  1381.      add   edx,hexletters
  1382.      mov   dl,[edx]
  1383.      mov   [edi],dl
  1384.      dec   edi
  1385.      loop  d_hexnum
  1386.      pop   eax
  1387.      call  normalize_number
  1388.      call  draw_num_text
  1389.      add   esp,64
  1390.      popad
  1391.      ret
  1392.    no_display_hexnum:
  1393.  
  1394.      cmp   ah,0x02               ; BINARY
  1395.      jne   no_display_binnum
  1396.      shr   eax,16
  1397.      and   eax,0xC03f
  1398. ;     and   eax,0x3f
  1399.      push  eax
  1400.      and   eax,0x3f
  1401.      mov   edi,esp
  1402.      add   edi,4+64-1
  1403.      mov   ecx,eax
  1404.      mov   eax,ebx
  1405.      mov   ebx,2
  1406.    d_binnum:
  1407.      xor   edx,edx
  1408.      call  division_64_bits
  1409.      div   ebx
  1410.      add   dl,48
  1411.      mov   [edi],dl
  1412.      dec   edi
  1413.      loop  d_binnum
  1414.      pop   eax
  1415.      call  normalize_number
  1416.      call  draw_num_text
  1417.      add   esp,64
  1418.      popad
  1419.      ret
  1420.    no_display_binnum:
  1421.  
  1422.      add   esp,64
  1423.      popad
  1424.      ret
  1425.  
  1426. normalize_number:
  1427.      test  ah,0x80
  1428.      jz   .continue
  1429.      mov  ecx,48
  1430.      and   eax,0x3f
  1431. @@:
  1432.      inc   edi
  1433.      cmp   [edi],cl
  1434.      jne   .continue
  1435.      dec   eax
  1436.      cmp   eax,1
  1437.      ja    @r
  1438.      mov   al,1
  1439. .continue:
  1440.      and   eax,0x3f
  1441.      ret
  1442.  
  1443. division_64_bits:
  1444.      test  [esp+1+4],byte 0x40
  1445.      jz   .continue
  1446.      push  eax
  1447.      mov   eax,ebp
  1448.      div   ebx
  1449.      mov   ebp,eax
  1450.      pop   eax
  1451. .continue:
  1452.      ret
  1453.  
  1454. draw_num_text:
  1455.      mov   esi,eax
  1456.      mov   edx,64+4
  1457.      sub   edx,eax
  1458.      add   edx,esp
  1459.      mov   ebx,[esp+64+32-8+4]
  1460. ; add window start x & y
  1461.      mov   ecx,[TASK_BASE]
  1462.  
  1463.      mov   edi,[CURRENT_TASK]
  1464.      shl   edi,8
  1465.  
  1466.      mov   eax,[ecx-twdw+WDATA.box.left]
  1467.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1468.      shl   eax,16
  1469.      add   eax,[ecx-twdw+WDATA.box.top]
  1470.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1471.      add   ebx,eax
  1472.      mov   ecx,[esp+64+32-12+4]
  1473.         and     ecx, not 0x80000000     ; force counted string
  1474.         mov     eax, [esp+64+8]         ; background color (if given)
  1475.         mov     edi, [esp+64+4]
  1476.      jmp   dtext
  1477.  
  1478. align 4
  1479.  
  1480. sys_setup:
  1481.  
  1482. ; 1=roland mpu midi base , base io address
  1483. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1484. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1485. ; 4=sb16 base , base io address
  1486. ; 5=system language, 1eng 2fi 3ger 4rus
  1487. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1488. ; 8=fat32 partition in hd
  1489. ; 9
  1490. ; 10 = sound dma channel
  1491. ; 11 = enable lba read
  1492. ; 12 = enable pci access
  1493.  
  1494.  
  1495.      mov  [esp+36],dword 0
  1496.      cmp  eax,1                      ; MIDI
  1497.      jnz  nsyse1
  1498.      cmp  ebx,0x100
  1499.      jb   nsyse1
  1500.      mov  edx,65535
  1501.      cmp  edx,ebx
  1502.      jb   nsyse1
  1503.      mov  [midi_base],bx
  1504.      mov  word [mididp],bx
  1505.      inc  bx
  1506.      mov  word [midisp],bx
  1507.      ret
  1508.  
  1509. iglobal
  1510. midi_base dw 0
  1511. endg
  1512.  
  1513.    nsyse1:
  1514.  
  1515.      cmp  eax,2                      ; KEYBOARD
  1516.      jnz  nsyse2
  1517.      cmp  ebx,1
  1518.      jnz  kbnobase
  1519.      mov  edi,[TASK_BASE]
  1520.      add  ecx,[edi+TASKDATA.mem_start]
  1521.      mov  eax,ecx
  1522.      mov  ebx,keymap
  1523.      mov  ecx,128
  1524.      call memmove
  1525.      ret
  1526.    kbnobase:
  1527.      cmp  ebx,2
  1528.      jnz  kbnoshift
  1529.      mov  edi,[TASK_BASE]
  1530.      add  ecx,[edi+TASKDATA.mem_start]
  1531.      mov  eax,ecx
  1532.      mov  ebx,keymap_shift
  1533.      mov  ecx,128
  1534.      call memmove
  1535.      ret
  1536.    kbnoshift:
  1537.      cmp  ebx,3
  1538.      jne  kbnoalt
  1539.      mov  edi,[TASK_BASE]
  1540.      add  ecx,[edi+TASKDATA.mem_start]
  1541.      mov  eax,ecx
  1542.      mov  ebx,keymap_alt
  1543.      mov  ecx,128
  1544.      call memmove
  1545.      ret
  1546.    kbnoalt:
  1547.      cmp  ebx,9
  1548.      jnz  kbnocountry
  1549.      mov  word [keyboard],cx
  1550.      ret
  1551.    kbnocountry:
  1552.      mov  [esp+36],dword 1
  1553.      ret
  1554.    nsyse2:
  1555.      cmp  eax,3                      ; CD
  1556.      jnz  nsyse3
  1557.      test ebx,ebx
  1558.      jz   nosesl
  1559.      cmp  ebx, 4
  1560.      ja   nosesl
  1561.      mov  [cd_base],bl
  1562.      cmp  ebx,1
  1563.      jnz  noprma
  1564.      mov  [cdbase],0x1f0
  1565.      mov  [cdid],0xa0
  1566.    noprma:
  1567.      cmp  ebx,2
  1568.      jnz  noprsl
  1569.      mov  [cdbase],0x1f0
  1570.      mov  [cdid],0xb0
  1571.    noprsl:
  1572.      cmp  ebx,3
  1573.      jnz  nosema
  1574.      mov  [cdbase],0x170
  1575.      mov  [cdid],0xa0
  1576.    nosema:
  1577.      cmp  ebx,4
  1578.      jnz  nosesl
  1579.      mov  [cdbase],0x170
  1580.      mov  [cdid],0xb0
  1581.    nosesl:
  1582.      ret
  1583.  
  1584. cd_base db 0
  1585.  
  1586.    nsyse3:
  1587.  
  1588.      cmp  eax,4                      ; SB
  1589.      jnz  nsyse4
  1590.      cmp  ebx,0x100
  1591.      jb   nsyse4
  1592.      mov  edx,65535
  1593.      cmp  edx,ebx
  1594.      jb   nsyse4
  1595.      mov  word [sb16],bx
  1596.      ret
  1597.    nsyse4:
  1598.  
  1599.      cmp  eax,5                      ; SYSTEM LANGUAGE
  1600.      jnz  nsyse5
  1601.      mov  [syslang],ebx
  1602.      ret
  1603.    nsyse5:
  1604.  
  1605.      cmp  eax,7                      ; HD BASE
  1606.      jne  nsyse7
  1607.      test ebx,ebx
  1608.      jz   nosethd
  1609.      cmp  ebx,4
  1610.      ja   nosethd
  1611.      mov  [hd_base],bl
  1612.      cmp  ebx,1
  1613.      jnz  noprmahd
  1614.      mov  [hdbase],0x1f0
  1615.      mov  [hdid],0x0
  1616.      mov  [hdpos],1
  1617. ;     call set_FAT32_variables
  1618.    noprmahd:
  1619.      cmp  ebx,2
  1620.      jnz  noprslhd
  1621.      mov  [hdbase],0x1f0
  1622.      mov  [hdid],0x10
  1623.      mov  [hdpos],2
  1624. ;     call set_FAT32_variables
  1625.    noprslhd:
  1626.      cmp  ebx,3
  1627.      jnz  nosemahd
  1628.      mov  [hdbase],0x170
  1629.      mov  [hdid],0x0
  1630.      mov  [hdpos],3
  1631. ;     call set_FAT32_variables
  1632.    nosemahd:
  1633.      cmp  ebx,4
  1634.      jnz  noseslhd
  1635.      mov  [hdbase],0x170
  1636.      mov  [hdid],0x10
  1637.      mov  [hdpos],4
  1638. ;     call set_FAT32_variables
  1639.    noseslhd:
  1640.     call  reserve_hd1
  1641.     call  reserve_hd_channel
  1642.     call  free_hd_channel
  1643.     mov   [hd1_status],0        ; free
  1644.    nosethd:
  1645.      ret
  1646.  
  1647. iglobal
  1648. hd_base db 0
  1649. endg
  1650.  
  1651.    nsyse7:
  1652.  
  1653.      cmp  eax,8                      ; HD PARTITION
  1654.      jne  nsyse8
  1655.      mov  [fat32part],ebx
  1656. ;     call set_FAT32_variables
  1657.     call  reserve_hd1
  1658.     call  reserve_hd_channel
  1659.     call  free_hd_channel
  1660.      pusha
  1661.      call  choice_necessity_partition_1
  1662.      popa
  1663.     mov   [hd1_status],0        ; free
  1664.      ret
  1665.    nsyse8:
  1666.  
  1667.      cmp  eax,10                     ; SOUND DMA CHANNEL
  1668.      jne  no_set_sound_dma
  1669.      cmp  ebx,3
  1670.      ja   sys_setup_err
  1671.      mov  [sound_dma],ebx
  1672.      ret
  1673.    no_set_sound_dma:
  1674.  
  1675.      cmp  eax,11                     ; ENABLE LBA READ
  1676.      jne  no_set_lba_read
  1677.      and  ebx,1
  1678.      mov  [lba_read_enabled],ebx
  1679.      ret
  1680.    no_set_lba_read:
  1681.  
  1682.      cmp  eax,12                     ; ENABLE PCI ACCESS
  1683.      jne  no_set_pci_access
  1684.      and  ebx,1
  1685.      mov  [pci_access_enabled],ebx
  1686.      ret
  1687.    no_set_pci_access:
  1688.  
  1689. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1690. include 'vmodeint.inc'
  1691. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1692.  
  1693. sys_setup_err:
  1694.      mov  [esp+36],dword -1
  1695.      ret
  1696.  
  1697. align 4
  1698.  
  1699. sys_getsetup:
  1700.  
  1701. ; 1=roland mpu midi base , base io address
  1702. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1703. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1704. ; 4=sb16 base , base io address
  1705. ; 5=system language, 1eng 2fi 3ger 4rus
  1706. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1707. ; 8=fat32 partition in hd
  1708. ; 9=get hs timer tic
  1709.  
  1710.      cmp  eax,1
  1711.      jne  ngsyse1
  1712.      movzx eax,[midi_base]
  1713.      mov  [esp+36],eax
  1714.      ret
  1715.    ngsyse1:
  1716.  
  1717.      cmp  eax,2
  1718.      jne  ngsyse2
  1719.      cmp  ebx,1
  1720.      jnz  kbnobaseret
  1721.      mov  edi,[TASK_BASE]
  1722.      add  ecx,[edi+TASKDATA.mem_start]
  1723.      mov  ebx,ecx
  1724.      mov  eax,keymap
  1725.      mov  ecx,128
  1726.      call memmove
  1727.      ret
  1728.    kbnobaseret:
  1729.      cmp  ebx,2
  1730.      jnz  kbnoshiftret
  1731.      mov  edi,[TASK_BASE]
  1732.      add  ecx,[edi+TASKDATA.mem_start]
  1733.      mov  ebx,ecx
  1734.      mov  eax,keymap_shift
  1735.      mov  ecx,128
  1736.      call memmove
  1737.      ret
  1738.    kbnoshiftret:
  1739.      cmp  ebx,3
  1740.      jne  kbnoaltret
  1741.      mov  edi,[TASK_BASE]
  1742.      add  ecx,[edi+TASKDATA.mem_start]
  1743.      mov  ebx,ecx
  1744.      mov  eax,keymap_alt
  1745.      mov  ecx,128
  1746.      call memmove
  1747.      ret
  1748.    kbnoaltret:
  1749.      cmp  ebx,9
  1750.      jnz  ngsyse2
  1751.      movzx eax,word [keyboard]
  1752.      mov  [esp+36],eax
  1753.      ret
  1754.    ngsyse2:
  1755.  
  1756.      cmp  eax,3
  1757.      jnz  ngsyse3
  1758.      movzx eax,[cd_base]
  1759.      mov  [esp+36],eax
  1760.      ret
  1761.    ngsyse3:
  1762.  
  1763.      cmp  eax,4
  1764.      jne  ngsyse4
  1765.      mov  eax,[sb16]
  1766.      mov  [esp+36],eax
  1767.      ret
  1768.    ngsyse4:
  1769.  
  1770.      cmp  eax,5
  1771.      jnz  ngsyse5
  1772.      mov  eax,[syslang]
  1773.      mov  [esp+36],eax
  1774.      ret
  1775.    ngsyse5:
  1776.      cmp  eax,7
  1777.      jnz  ngsyse7
  1778.      movzx eax,[hd_base]
  1779.      mov  [esp+36],eax
  1780.      ret
  1781.    ngsyse7:
  1782.      cmp  eax,8
  1783.      jnz  ngsyse8
  1784.      mov eax,[fat32part]
  1785.      mov  [esp+36],eax
  1786.      ret
  1787.    ngsyse8:
  1788.      cmp  eax,9
  1789.      jne  ngsyse9
  1790.      mov  eax,[timer_ticks] ;[0xfdf0]
  1791.      mov  [esp+36],eax
  1792.      ret
  1793.    ngsyse9:
  1794.      cmp  eax,10
  1795.      jnz  ngsyse10
  1796.      mov eax,[sound_dma]
  1797.      mov  [esp+36],eax
  1798.      ret
  1799.    ngsyse10:
  1800.      cmp  eax,11
  1801.      jnz  ngsyse11
  1802.      mov eax,[lba_read_enabled]
  1803.      mov  [esp+36],eax
  1804.      ret
  1805.    ngsyse11:
  1806.      cmp  eax,12
  1807.      jnz  ngsyse12
  1808.      mov eax,[pci_access_enabled]
  1809.      mov  [esp+36],eax
  1810.      ret
  1811.    ngsyse12:
  1812.      mov  [esp+36],dword 1
  1813.      ret
  1814.  
  1815. get_timer_ticks:
  1816.     mov eax,[timer_ticks]
  1817.     ret
  1818.  
  1819. iglobal
  1820. align 4
  1821. mousefn dd msscreen, mswin, msbutton, msset
  1822.         dd app_load_cursor
  1823.         dd app_set_cursor
  1824.         dd app_delete_cursor
  1825.         dd msz
  1826. endg
  1827.  
  1828. readmousepos:
  1829.  
  1830. ; eax=0 screen relative
  1831. ; eax=1 window relative
  1832. ; eax=2 buttons pressed
  1833. ; eax=3 set mouse pos   ; reserved
  1834. ; eax=4 load cursor
  1835. ; eax=5 set cursor
  1836. ; eax=6 delete cursor   ; reserved
  1837. ; eax=7 get mouse_z
  1838.  
  1839.            cmp eax, 7
  1840.            ja msset
  1841.            jmp [mousefn+eax*4]
  1842. msscreen:
  1843.            mov  eax,[MOUSE_X]
  1844.            shl  eax,16
  1845.            mov  ax,[MOUSE_Y]
  1846.            mov  [esp+36],eax
  1847.            ret
  1848. mswin:
  1849.            mov  eax,[MOUSE_X]
  1850.            shl  eax,16
  1851.            mov  ax,[MOUSE_Y]
  1852.            mov  esi,[TASK_BASE]
  1853.            mov  bx, word [esi-twdw+WDATA.box.left]
  1854.            shl  ebx,16
  1855.            mov  bx, word [esi-twdw+WDATA.box.top]
  1856.            sub  eax,ebx
  1857.  
  1858.            mov  edi,[CURRENT_TASK]
  1859.            shl  edi,8
  1860.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1861.            rol  eax,16
  1862.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1863.            rol  eax,16
  1864.            mov  [esp+36],eax
  1865.            ret
  1866. msbutton:
  1867.            movzx eax,byte [BTN_DOWN]
  1868.            mov  [esp+36],eax
  1869.            ret
  1870. msz:
  1871.            mov   edi, [TASK_COUNT]
  1872.            movzx edi, word [WIN_POS + edi*2]
  1873.            cmp   edi, [CURRENT_TASK]
  1874.            jne   @f
  1875.            mov   ax,[MOUSE_SCROLL_H]
  1876.            shl   eax,16
  1877.            mov   ax,[MOUSE_SCROLL_V]
  1878.            mov   [esp+36],eax
  1879.            mov   [MOUSE_SCROLL_H],word 0
  1880.            mov   [MOUSE_SCROLL_V],word 0
  1881.            ret
  1882.        @@:
  1883.            mov  [esp+36],dword 0
  1884.            ret
  1885. msset:
  1886.            ret
  1887.  
  1888. app_load_cursor:
  1889.       ;     add ebx, new_app_base
  1890.            cmp ebx, OS_BASE
  1891.            jae msset
  1892.            stdcall load_cursor, ebx, ecx
  1893.            mov [esp+36], eax
  1894.            ret
  1895.  
  1896. app_set_cursor:
  1897.            stdcall set_cursor, ebx
  1898.            mov [esp+36], eax
  1899.            ret
  1900.  
  1901. app_delete_cursor:
  1902.            stdcall delete_cursor, ebx
  1903.            mov [esp+36], eax
  1904.            ret
  1905.  
  1906. is_input:
  1907.  
  1908.    push edx
  1909.    mov  dx,word [midisp]
  1910.    in   al,dx
  1911.    and  al,0x80
  1912.    pop  edx
  1913.    ret
  1914.  
  1915. is_output:
  1916.  
  1917.    push edx
  1918.    mov  dx,word [midisp]
  1919.    in   al,dx
  1920.    and  al,0x40
  1921.    pop  edx
  1922.    ret
  1923.  
  1924.  
  1925. get_mpu_in:
  1926.  
  1927.    push edx
  1928.    mov  dx,word [mididp]
  1929.    in   al,dx
  1930.    pop  edx
  1931.    ret
  1932.  
  1933.  
  1934. put_mpu_out:
  1935.  
  1936.    push edx
  1937.    mov  dx,word [mididp]
  1938.    out  dx,al
  1939.    pop  edx
  1940.    ret
  1941.  
  1942.  
  1943. setuart:
  1944.  
  1945.  su1:
  1946.    call is_output
  1947.    cmp  al,0
  1948.    jnz  su1
  1949.    mov  dx,word [midisp]
  1950.    mov  al,0xff
  1951.    out  dx,al
  1952.  su2:
  1953.    mov  dx,word [midisp]
  1954.    mov  al,0xff
  1955.    out  dx,al
  1956.    call is_input
  1957.    cmp  al,0
  1958.    jnz  su2
  1959.    call get_mpu_in
  1960.    cmp  al,0xfe
  1961.    jnz  su2
  1962.  su3:
  1963.    call is_output
  1964.    cmp  al,0
  1965.    jnz  su3
  1966.    mov  dx,word [midisp]
  1967.    mov  al,0x3f
  1968.    out  dx,al
  1969.  
  1970.    ret
  1971.  
  1972.  
  1973. align 4
  1974.  
  1975. sys_midi:
  1976.  
  1977.      cmp  [mididp],0
  1978.      jnz  sm0
  1979.      mov  [esp+36],dword 1
  1980.      ret
  1981.    sm0:
  1982.  
  1983.      cmp  eax,1
  1984.      mov  [esp+36],dword 0
  1985.      jnz  smn1
  1986.      call setuart
  1987.      ret
  1988.    smn1:
  1989.  
  1990.      cmp  eax,2
  1991.      jnz  smn2
  1992.    sm10:
  1993.      call get_mpu_in
  1994.      call is_output
  1995.      test al,al
  1996.      jnz  sm10
  1997.      mov  al,bl
  1998.      call put_mpu_out
  1999.      ret
  2000.    smn2:
  2001.  
  2002.      ret
  2003.  
  2004.  
  2005. detect_devices:
  2006. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2007. include 'detect/commouse.inc'
  2008. ;include 'detect/ps2mouse.inc'
  2009. ;include 'detect/dev_fd.inc'
  2010. ;include 'detect/dev_hdcd.inc'
  2011. ;include 'detect/sear_par.inc'
  2012. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2013.     ret
  2014.  
  2015.  
  2016. sys_end:
  2017.  
  2018.      mov   eax,[TASK_BASE]
  2019.      mov   [eax+TASKDATA.state], 3  ; terminate this program
  2020.  
  2021.     waitterm:            ; wait here for termination
  2022.      mov   ebx,100
  2023.      call  delay_hs
  2024.      jmp   waitterm
  2025.  
  2026. iglobal
  2027. align 4
  2028. sys_system_table:
  2029.         dd      0                       ; 1 = system shutdown
  2030.         dd      sysfn_terminate         ; 2 = terminate thread
  2031.         dd      sysfn_activate          ; 3 = activate window
  2032.         dd      sysfn_getidletime       ; 4 = get idle time
  2033.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2034.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2035.         dd      sysfn_getactive         ; 7 = get active window
  2036.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2037.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2038.         dd      sysfn_minimize          ; 10 = minimize window
  2039.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2040.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2041.         dd      sysfn_getversion        ; 13 = get kernel version
  2042.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2043.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2044.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2045.         dd      sysfn_getallmem         ; 17 = get total memory size
  2046.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2047.                                         ;                 instead of slot
  2048.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2049.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2050.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2051.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2052. sysfn_num = ($ - sys_system_table)/4
  2053. endg
  2054.  
  2055. sys_system:
  2056.         dec     ebx
  2057.         cmp     ebx, sysfn_num
  2058.         jae     @f
  2059.         jmp     dword [sys_system_table + ebx*4]
  2060. @@:
  2061.         ret
  2062.  
  2063.  
  2064. sysfn_shutdown:          ; 18.9 = system shutdown
  2065.      cmp  ecx,1
  2066.      jl   exit_for_anyone
  2067.      cmp  ecx,4
  2068.      jg   exit_for_anyone
  2069.      mov  [BOOT_VAR+0x9030],cl
  2070.  
  2071.      mov  eax,[TASK_COUNT]
  2072.      mov  [SYS_SHUTDOWN],al
  2073.      mov  [shutdown_processes],eax
  2074.      and  dword [esp+32], 0
  2075.  exit_for_anyone:
  2076.      ret
  2077.   uglobal
  2078.    shutdown_processes: dd 0x0
  2079.   endg
  2080.  
  2081. sysfn_terminate:        ; 18.2 = TERMINATE
  2082.      cmp  ecx,2
  2083.      jb   noprocessterminate
  2084.      mov  edx,[TASK_COUNT]
  2085.      cmp  ecx,edx
  2086.      ja   noprocessterminate
  2087.      mov  eax,[TASK_COUNT]
  2088.      shl  ecx,5
  2089.      mov  edx,[ecx+CURRENT_TASK+TASKDATA.pid]
  2090.      add  ecx,CURRENT_TASK+TASKDATA.state
  2091.      cmp  byte [ecx], 9
  2092.      jz   noprocessterminate
  2093.  
  2094.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2095.      mov  [ecx],byte 3       ; clear possible i40's
  2096.      ;call MEM_Heap_UnLock
  2097.  
  2098.      cmp  edx,[application_table_status]    ; clear app table stat
  2099.      jne  noatsc
  2100.      mov  [application_table_status],0
  2101.    noatsc:
  2102.    noprocessterminate:
  2103.      ret
  2104.  
  2105. sysfn_terminate2:
  2106. ;lock application_table_status mutex
  2107. .table_status:
  2108.     cli
  2109.     cmp    [application_table_status],0
  2110.     je     .stf
  2111.     sti
  2112.     call   change_task
  2113.     jmp    .table_status
  2114. .stf:
  2115.     call   set_application_table_status
  2116.     mov    eax,ecx
  2117.     call   pid_to_slot
  2118.     test   eax,eax
  2119.     jz     .not_found
  2120.     mov    ecx,eax
  2121.     cli
  2122.     call   sysfn_terminate
  2123.     mov    [application_table_status],0
  2124.     sti
  2125.     and    dword [esp+32],0
  2126.     ret
  2127. .not_found:
  2128.     mov    [application_table_status],0
  2129.     or     dword [esp+32],-1
  2130.     ret
  2131.  
  2132. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2133.      cmp  ecx,2
  2134.      jb   .nowindowactivate
  2135.      cmp  ecx,[TASK_COUNT]
  2136.      ja   .nowindowactivate
  2137.  
  2138.      mov   [window_minimize], 2   ; restore window if minimized
  2139.  
  2140.      movzx esi, word [WIN_STACK + ecx*2]
  2141.      cmp   esi, [TASK_COUNT]
  2142.      je    .nowindowactivate ; already active
  2143.  
  2144.      mov   edi, ecx
  2145.      shl   edi, 5
  2146.      add   edi, window_data
  2147.      movzx esi, word [WIN_STACK + ecx * 2]
  2148.      lea   esi, [WIN_POS + esi * 2]
  2149.      call  waredraw
  2150. .nowindowactivate:
  2151.      ret
  2152.  
  2153. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2154.      mov  eax,[idleusesec]
  2155.      mov  [esp+32], eax
  2156.      ret
  2157.  
  2158. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2159.      mov  eax,[CPU_FREQ]
  2160.      mov  [esp+32], eax
  2161.      ret
  2162.  
  2163. ;  SAVE ramdisk to /hd/1/menuet.img
  2164. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2165.    include 'blkdev/rdsave.inc'
  2166. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2167.  
  2168. sysfn_getactive:        ; 18.7 = get active window
  2169.      mov  eax, [TASK_COUNT]
  2170.    movzx  eax, word [WIN_POS + eax*2]
  2171.      mov  [esp+32],eax
  2172.      ret
  2173.  
  2174. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2175.      cmp  ecx,1
  2176.      jne  nogetsoundflag
  2177.      movzx  eax,byte [sound_flag] ; get sound_flag
  2178.      mov  [esp+32],eax
  2179.      ret
  2180.  nogetsoundflag:
  2181.      cmp  ecx,2
  2182.      jnz  nosoundflag
  2183.      xor  byte [sound_flag], 1
  2184.  nosoundflag:
  2185.      ret
  2186.  
  2187. sysfn_minimize:         ; 18.10 = minimize window
  2188.      mov   [window_minimize],1
  2189.      ret
  2190.  
  2191. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2192.      cmp  ecx,1
  2193.      jnz  full_table
  2194.   small_table:
  2195.      call for_all_tables
  2196.      mov ecx,10
  2197.      cld
  2198.      rep movsb
  2199.      ret
  2200.    for_all_tables:
  2201.      mov edi,edx
  2202.      mov esi,DRIVE_DATA
  2203.      ret
  2204.   full_table:
  2205.      cmp  ecx,2
  2206.      jnz  exit_for_anyone
  2207.      call for_all_tables
  2208.      mov ecx,16384
  2209.      cld
  2210.      rep movsd
  2211.      ret
  2212.  
  2213. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2214.         and     dword [esp+32], 0
  2215.         ret
  2216.  
  2217. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2218.      mov edi,ebx
  2219.      mov esi,version_inf
  2220.      mov ecx,version_end-version_inf
  2221.      rep movsb
  2222.      ret
  2223.  
  2224. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2225.      ;wait retrace functions
  2226.  sys_wait_retrace:
  2227.      mov edx,0x3da
  2228.  WaitRetrace_loop:
  2229.      in al,dx
  2230.      test al,1000b
  2231.      jz WaitRetrace_loop
  2232.      and [esp+32],dword 0
  2233.      ret
  2234.  
  2235. sysfn_centermouse:      ; 18.15 = mouse centered
  2236.      call  mouse_centered
  2237.      and [esp+32],dword 0
  2238.      ret
  2239.  
  2240. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2241.      cmp  ecx,0  ; get mouse speed factor
  2242.      jnz  .set_mouse_acceleration
  2243.      xor  eax,eax
  2244.      mov  ax,[mouse_speed_factor]
  2245.      mov  [esp+32],eax
  2246.      ret
  2247.  .set_mouse_acceleration:
  2248.      cmp  ecx,1  ; set mouse speed factor
  2249.      jnz  .get_mouse_delay
  2250.      mov  [mouse_speed_factor],dx
  2251.      ret
  2252.  .get_mouse_delay:
  2253.      cmp  ecx,2  ; get mouse delay
  2254.      jnz  .set_mouse_delay
  2255.      mov  eax,[mouse_delay]
  2256.      mov  [esp+32],eax
  2257.      ret
  2258.  .set_mouse_delay:
  2259.      cmp  ecx,3  ; set mouse delay
  2260.      jnz  .set_pointer_position
  2261.      mov  [mouse_delay],edx
  2262.      ret
  2263.  .set_pointer_position:
  2264.      cmp  ecx,4  ; set mouse pointer position
  2265.      jnz  .set_mouse_button
  2266.      mov   [MOUSE_Y],dx    ;y
  2267.      ror   edx,16
  2268.      mov   [MOUSE_X],dx    ;x
  2269.      rol   edx,16
  2270.      ret
  2271.  .set_mouse_button:
  2272.      cmp   ecx,5  ; set mouse button features
  2273.      jnz  .end
  2274.      mov   [BTN_DOWN],dl
  2275.      mov   [mouse_active],1
  2276.  .end:
  2277.      ret
  2278.  
  2279. sysfn_getfreemem:
  2280.      mov eax, [pg_data.pages_free]
  2281.      shl eax, 2
  2282.      mov [esp+32],eax
  2283.      ret
  2284.  
  2285. sysfn_getallmem:
  2286.      mov  eax,[MEM_AMOUNT]
  2287.      shr eax, 10
  2288.      mov  [esp+32],eax
  2289.      ret
  2290.  
  2291. ; // Alver, 2007-22-08 // {
  2292. sysfn_pid_to_slot:
  2293.      mov   eax, ecx
  2294.      call  pid_to_slot
  2295.      mov   [esp+32], eax
  2296.      ret
  2297.  
  2298. sysfn_min_rest_window:
  2299.      pushad
  2300.      mov   eax, edx      ; ebx - operating
  2301.      shr   ecx, 1
  2302.      jnc    @f
  2303.      call  pid_to_slot
  2304. @@:
  2305.      or    eax, eax      ; eax - number of slot
  2306.      jz    .error
  2307.      cmp   eax, 255         ; varify maximal slot number
  2308.      ja    .error
  2309.      movzx eax, word [WIN_STACK + eax*2]
  2310.      shr   ecx, 1
  2311.      jc    .restore
  2312.  ; .minimize:
  2313.      call  minimize_window
  2314.      jmp   .exit
  2315. .restore:
  2316.      call  restore_minimized_window
  2317. .exit:
  2318.      popad
  2319.      xor   eax, eax
  2320.      mov   [esp+32], eax
  2321.      ret
  2322. .error:
  2323.      popad
  2324.      xor   eax, eax
  2325.      dec   eax
  2326.      mov   [esp+32], eax
  2327.      ret
  2328. ; } \\ Alver, 2007-22-08 \\
  2329.  
  2330. uglobal
  2331. ;// mike.dld, 2006-29-01 [
  2332. screen_workarea RECT
  2333. ;// mike.dld, 2006-29-01 ]
  2334. window_minimize db 0
  2335. sound_flag      db 0
  2336. endg
  2337.  
  2338. iglobal
  2339. version_inf:
  2340.   db 0,7,1,0  ; version 0.7.1.0
  2341.   db UID_KOLIBRI
  2342.   dd __REV__
  2343. version_end:
  2344. endg
  2345.  
  2346. UID_NONE=0
  2347. UID_MENUETOS=1   ;official
  2348. UID_KOLIBRI=2    ;russian
  2349.  
  2350. sys_cachetodiskette:
  2351.         cmp     ebx, 1
  2352.         jne     .no_floppy_a_save
  2353.         mov     [flp_number], 1
  2354.         jmp     .save_image_on_floppy
  2355. .no_floppy_a_save:
  2356.         cmp     ebx, 2
  2357.         jne     .no_floppy_b_save
  2358.         mov     [flp_number], 2
  2359. .save_image_on_floppy:
  2360.         call    save_image
  2361.         mov     [esp + 32], dword 0
  2362.         cmp     [FDC_Status], 0
  2363.         je      .yes_floppy_save
  2364. .no_floppy_b_save:
  2365.         mov     [esp + 32], dword 1
  2366. .yes_floppy_save:
  2367.         ret
  2368.  
  2369. uglobal
  2370. ;  bgrchanged  dd  0x0
  2371. bgrlock db 0
  2372. bgrlockpid dd 0
  2373. endg
  2374.  
  2375. sys_background:
  2376.  
  2377.     cmp   ebx,1                            ; BACKGROUND SIZE
  2378.     jnz   nosb1
  2379.     cmp   ecx,0
  2380.     je    sbgrr
  2381.     cmp   edx,0
  2382.     je    sbgrr
  2383. @@:
  2384.         mov     al, 1
  2385.         xchg    [bgrlock], al
  2386.         test    al, al
  2387.         jz      @f
  2388.         call    change_task
  2389.         jmp     @b
  2390. @@:
  2391.     mov   [BgrDataWidth],ecx
  2392.     mov   [BgrDataHeight],edx
  2393. ;    mov   [bgrchanged],1
  2394.  
  2395.     pushad
  2396. ; return memory for old background
  2397.     stdcall kernel_free, [img_background]
  2398. ; calculate RAW size
  2399.     xor  eax,eax
  2400.     inc  eax
  2401.     cmp  [BgrDataWidth],eax
  2402.     jae   @f
  2403.     mov [BgrDataWidth],eax
  2404. @@:
  2405.     cmp  [BgrDataHeight],eax
  2406.     jae   @f
  2407.     mov [BgrDataHeight],eax
  2408. @@:
  2409.     mov  eax,[BgrDataWidth]
  2410.     imul eax,[BgrDataHeight]
  2411.     lea  eax,[eax*3]
  2412.     mov  [mem_BACKGROUND],eax
  2413. ; get memory for new background
  2414.     stdcall kernel_alloc, eax
  2415.     test eax, eax
  2416.     jz .exit_mem
  2417.     mov [img_background], eax
  2418. .exit_mem:
  2419.     popad
  2420.         mov     [bgrlock], 0
  2421.  
  2422.   sbgrr:
  2423.     ret
  2424.  
  2425.   nosb1:
  2426.  
  2427.     cmp   ebx,2                            ; SET PIXEL
  2428.     jnz   nosb2
  2429.     cmp   ecx,[mem_BACKGROUND]
  2430.     jae   nosb2
  2431.     mov   eax,[img_background]
  2432.     mov   ebx,[eax+ecx]
  2433.     and   ebx,0xFF000000 ;255*256*256*256
  2434.     and   edx,0x00FFFFFF ;255*256*256+255*256+255
  2435.     add   edx,ebx
  2436.     mov   [eax+ecx],edx
  2437. ;    mov   [bgrchanged],1
  2438.     ret
  2439.   nosb2:
  2440.  
  2441.     cmp   ebx,3                            ; DRAW BACKGROUND
  2442.     jnz   nosb3
  2443. draw_background_temp:
  2444. ;    cmp   [bgrchanged],1 ;0
  2445. ;    je    nosb31
  2446. ;draw_background_temp:
  2447. ;    mov   [bgrchanged],1 ;0
  2448.     mov    [background_defined], 1
  2449.     call  force_redraw_background
  2450.     mov    [REDRAW_BACKGROUND], byte 2
  2451.    nosb31:
  2452.     ret
  2453.   nosb3:
  2454.  
  2455.     cmp   ebx,4                            ; TILED / STRETCHED
  2456.     jnz   nosb4
  2457.     cmp   ecx,[BgrDrawMode]
  2458.     je    nosb41
  2459.     mov   [BgrDrawMode],ecx
  2460. ;    mov   [bgrchanged],1
  2461.    nosb41:
  2462.     ret
  2463.   nosb4:
  2464.  
  2465.     cmp   ebx,5                            ; BLOCK MOVE TO BGR
  2466.     jnz   nosb5
  2467.   ; bughere
  2468.     mov   eax, ecx
  2469.     mov   ebx, edx
  2470.     add   ebx, [img_background]   ;IMG_BACKGROUND
  2471.     mov   ecx, esi
  2472.     call  memmove
  2473.   .fin:
  2474.     ret
  2475.   nosb5:
  2476.  
  2477.         cmp     ebx, 6
  2478.         jnz     nosb6
  2479. @@:
  2480.         mov     al, 1
  2481.         xchg    [bgrlock], al
  2482.         test    al, al
  2483.         jz      @f
  2484.         call    change_task
  2485.         jmp     @b
  2486. @@:
  2487.         mov     eax, [CURRENT_TASK]
  2488.         mov     [bgrlockpid], eax
  2489.         stdcall user_alloc, [mem_BACKGROUND]
  2490.         mov     [esp+32], eax
  2491.         test    eax, eax
  2492.         jz      .nomem
  2493.         mov     ebx, eax
  2494.         shr     ebx, 12
  2495.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2496.         mov     esi, [img_background]
  2497.         shr     esi, 12
  2498.         mov     ecx, [mem_BACKGROUND]
  2499.         add     ecx, 0xFFF
  2500.         shr     ecx, 12
  2501. .z:
  2502.         mov     eax, [page_tabs+ebx*4]
  2503.         test    al, 1
  2504.         jz      @f
  2505.         call    free_page
  2506. @@:
  2507.         mov     eax, [page_tabs+esi*4]
  2508.         or      al, PG_UW
  2509.         mov     [page_tabs+ebx*4], eax
  2510.         mov     eax, ebx
  2511.         shl     eax, 12
  2512.         invlpg  [eax]
  2513.         inc     ebx
  2514.         inc     esi
  2515.         loop    .z
  2516.         ret
  2517. .nomem:
  2518.         and     [bgrlockpid], 0
  2519.         mov     [bgrlock], 0
  2520. nosb6:
  2521.         cmp     ebx, 7
  2522.         jnz     nosb7
  2523.         cmp     [bgrlock], 0
  2524.         jz      .err
  2525.         mov     eax, [CURRENT_TASK]
  2526.         cmp     [bgrlockpid], eax
  2527.         jnz     .err
  2528.         mov     eax, ecx
  2529.         mov     ebx, ecx
  2530.         shr     eax, 12
  2531.         mov     ecx, [page_tabs+(eax-1)*4]
  2532.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2533.         jz      .err
  2534.         jnp     .err
  2535.         push    eax
  2536.         shr     ecx, 12
  2537. @@:
  2538.         and     dword [page_tabs+eax*4], 0
  2539.         mov     edx, eax
  2540.         shl     edx, 12
  2541.         invlpg  [edx]
  2542.         inc     eax
  2543.         loop    @b
  2544.         pop     eax
  2545.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2546.         stdcall user_free, ebx
  2547.         mov     [esp+32], eax
  2548.         and     [bgrlockpid], 0
  2549.         mov     [bgrlock], 0
  2550.         ret
  2551. .err:
  2552.         and     dword [esp+32], 0
  2553.         ret
  2554.  
  2555. nosb7:
  2556.     ret
  2557.  
  2558. force_redraw_background:
  2559.     mov   [draw_data+32 + RECT.left],dword 0
  2560.     mov   [draw_data+32 + RECT.top],dword 0
  2561.     push  eax ebx
  2562.     mov   eax,[ScreenWidth]
  2563.     mov   ebx,[ScreenHeight]
  2564.     mov   [draw_data+32 + RECT.right],eax
  2565.     mov   [draw_data+32 + RECT.bottom],ebx
  2566.     pop   ebx eax
  2567.     mov   byte [REDRAW_BACKGROUND], 1
  2568.     ret
  2569.  
  2570. align 4
  2571.  
  2572. sys_getbackground:
  2573.  
  2574.     cmp   eax,1                                  ; SIZE
  2575.     jnz   nogb1
  2576.     mov   eax,[BgrDataWidth]
  2577.     shl   eax,16
  2578.     mov   ax,[BgrDataHeight]
  2579.     mov   [esp+36],eax
  2580.     ret
  2581.   nogb1:
  2582.  
  2583.     cmp   eax,2                                  ; PIXEL
  2584.     jnz   nogb2
  2585. ;    mov   edx,0x160000-16
  2586. ;    cmp   edx,ebx
  2587. ;    jbe   nogb2
  2588. ;    mov   eax, [ebx+IMG_BACKGROUND]
  2589.     mov   eax,[img_background]
  2590.     mov   eax,[ebx+eax]
  2591.  
  2592.     and   eax, 0xFFFFFF
  2593.     mov   [esp+36],eax
  2594.     ret
  2595.   nogb2:
  2596.  
  2597.     cmp   eax,4                                  ; TILED / STRETCHED
  2598.     jnz   nogb4
  2599.     mov   eax,[BgrDrawMode]
  2600.   nogb4:
  2601.     mov   [esp+36],eax
  2602.     ret
  2603.  
  2604.  
  2605. align 4
  2606.  
  2607. sys_getkey:
  2608.         mov     [esp + 32],dword 1
  2609.         ; test main buffer
  2610.         mov     ebx, [CURRENT_TASK]                          ; TOP OF WINDOW STACK
  2611.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2612.         mov     edx, [TASK_COUNT]
  2613.         cmp     ecx, edx
  2614.         jne     .finish
  2615.         cmp     [KEY_COUNT], byte 0
  2616.         je      .finish
  2617.         movzx   eax, byte [KEY_BUFF]
  2618.         shl     eax, 8
  2619.         push    eax
  2620.         dec     byte [KEY_COUNT]
  2621.         and     byte [KEY_COUNT], 127
  2622.         movzx   ecx, byte [KEY_COUNT]
  2623.         add     ecx, 2
  2624.         mov     eax, KEY_BUFF + 1
  2625.         mov     ebx, KEY_BUFF
  2626.         call    memmove
  2627.         pop     eax
  2628. .ret_eax:
  2629.         mov     [esp + 32], eax
  2630.         ret
  2631. .finish:
  2632. ; test hotkeys buffer
  2633.         mov     ecx, hotkey_buffer
  2634. @@:
  2635.         cmp     [ecx], ebx
  2636.         jz      .found
  2637.         add     ecx, 8
  2638.         cmp     ecx, hotkey_buffer + 120 * 8
  2639.         jb      @b
  2640.         ret
  2641. .found:
  2642.         mov     ax, [ecx + 6]
  2643.         shl     eax, 16
  2644.         mov     ah, [ecx + 4]
  2645.         mov     al, 2
  2646.         and     dword [ecx + 4], 0
  2647.         and     dword [ecx], 0
  2648.         jmp     .ret_eax
  2649.  
  2650. align 4
  2651.  
  2652. sys_getbutton:
  2653.  
  2654.         mov     ebx, [CURRENT_TASK]                         ; TOP OF WINDOW STACK
  2655.         mov     [esp + 32], dword 1
  2656.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2657.         mov     edx, [TASK_COUNT] ; less than 256 processes
  2658.         cmp     ecx, edx
  2659.         jne     .exit
  2660.         movzx   eax, byte [BTN_COUNT]
  2661.         test    eax, eax
  2662.         jz      .exit
  2663.         mov     eax, [BTN_BUFF]
  2664.         shl     eax, 8
  2665.         mov     [BTN_COUNT], byte 0
  2666.         mov     [esp + 32], eax
  2667. .exit:
  2668.         ret
  2669.  
  2670.  
  2671. align 4
  2672.  
  2673. sys_cpuusage:
  2674.  
  2675. ;  RETURN:
  2676. ;
  2677. ;  +00 dword     process cpu usage
  2678. ;  +04  word     position in windowing stack
  2679. ;  +06  word     windowing stack value at current position (cpu nro)
  2680. ;  +10 12 bytes  name
  2681. ;  +22 dword     start in mem
  2682. ;  +26 dword     used mem
  2683. ;  +30 dword     PID , process idenfification number
  2684. ;
  2685.  
  2686.     cmp  ecx,-1         ; who am I ?
  2687.     jne  .no_who_am_i
  2688.     mov  ecx,[CURRENT_TASK]
  2689.   .no_who_am_i:
  2690.         cmp     ecx, max_processes
  2691.         ja      .nofillbuf
  2692.  
  2693. ; +4: word: position of the window of thread in the window stack
  2694.         mov     ax, [WIN_STACK + ecx * 2]
  2695.         mov     [ebx+4], ax
  2696. ; +6: word: number of the thread slot, which window has in the window stack
  2697. ;           position ecx (has no relation to the specific thread)
  2698.         mov     ax, [WIN_POS + ecx * 2]
  2699.         mov     [ebx+6], ax
  2700.  
  2701.         shl     ecx, 5
  2702.  
  2703. ; +0: dword: memory usage
  2704.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.cpu_usage]
  2705.         mov     [ebx], eax
  2706. ; +10: 11 bytes: name of the process
  2707.         push    ecx
  2708.         lea     eax, [ecx*8+SLOT_BASE+APPDATA.app_name]
  2709.         add     ebx, 10
  2710.         mov     ecx, 11
  2711.         call    memmove
  2712.         pop     ecx
  2713.  
  2714. ; +22: address of the process in memory
  2715. ; +26: size of used memory - 1
  2716.         push    edi
  2717.         lea     edi, [ebx+12]
  2718.         xor     eax, eax
  2719.         mov     edx, 0x100000*16
  2720.         cmp     ecx, 1 shl 5
  2721.         je      .os_mem
  2722.         mov     edx, [SLOT_BASE+ecx*8+APPDATA.mem_size]
  2723.         mov     eax, std_application_base_address
  2724. .os_mem:
  2725.         stosd
  2726.         lea     eax, [edx-1]
  2727.         stosd
  2728.  
  2729. ; +30: PID/TID
  2730.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.pid]
  2731.         stosd
  2732.  
  2733.     ; window position and size
  2734.         push    esi
  2735.         lea     esi, [ecx + window_data + WDATA.box]
  2736.         movsd
  2737.         movsd
  2738.         movsd
  2739.         movsd
  2740.  
  2741.     ; Process state (+50)
  2742.         mov     eax, dword [ecx+CURRENT_TASK+TASKDATA.state]
  2743.         stosd
  2744.  
  2745.     ; Window client area box
  2746.         lea     esi, [ecx*8 + SLOT_BASE + APPDATA.wnd_clientbox]
  2747.         movsd
  2748.         movsd
  2749.         movsd
  2750.         movsd
  2751.  
  2752.     ; Window state
  2753.         mov     al, [ecx+window_data+WDATA.fl_wstate]
  2754.         stosb
  2755.  
  2756.         pop     esi
  2757.         pop     edi
  2758.  
  2759. .nofillbuf:
  2760.     ; return number of processes
  2761.  
  2762.     mov    eax,[TASK_COUNT]
  2763.     mov    [esp+32],eax
  2764.     ret
  2765.  
  2766. align 4
  2767. sys_clock:
  2768.         cli
  2769.   ; Mikhail Lisovin  xx Jan 2005
  2770.   @@:   mov   al, 10
  2771.         out   0x70, al
  2772.         in    al, 0x71
  2773.         test  al, al
  2774.         jns   @f
  2775.         mov   esi, 1
  2776.         call  delay_ms
  2777.         jmp   @b
  2778.   @@:
  2779.   ; end Lisovin's fix
  2780.  
  2781.         xor   al,al           ; seconds
  2782.         out   0x70,al
  2783.         in    al,0x71
  2784.         movzx ecx,al
  2785.         mov   al,02           ; minutes
  2786.         shl   ecx,16
  2787.         out   0x70,al
  2788.         in    al,0x71
  2789.         movzx edx,al
  2790.         mov   al,04           ; hours
  2791.         shl   edx,8
  2792.         out   0x70,al
  2793.         in    al,0x71
  2794.         add   ecx,edx
  2795.         movzx edx,al
  2796.         add   ecx,edx
  2797.         sti
  2798.         mov     [esp + 32], ecx
  2799.         ret
  2800.  
  2801.  
  2802. align 4
  2803.  
  2804. sys_date:
  2805.  
  2806.         cli
  2807.   @@:   mov   al, 10
  2808.         out   0x70, al
  2809.         in    al, 0x71
  2810.         test  al, al
  2811.         jns   @f
  2812.         mov   esi, 1
  2813.         call  delay_ms
  2814.         jmp   @b
  2815.   @@:
  2816.  
  2817.         mov     ch,0
  2818.         mov     al,7            ; date
  2819.         out     0x70,al
  2820.         in      al,0x71
  2821.         mov     cl,al
  2822.         mov     al,8            ; month
  2823.         shl     ecx,16
  2824.         out     0x70,al
  2825.         in      al,0x71
  2826.         mov     ch,al
  2827.         mov     al,9            ; year
  2828.         out     0x70,al
  2829.         in      al,0x71
  2830.         mov     cl,al
  2831.         sti
  2832.         mov     [esp+32], ecx
  2833.         ret
  2834.  
  2835.  
  2836. ; redraw status
  2837.  
  2838. sys_redrawstat:
  2839.         cmp     ebx, 1
  2840.         jne     no_widgets_away
  2841.         ; buttons away
  2842.         mov     ecx,[CURRENT_TASK]
  2843.   sys_newba2:
  2844.         mov     edi,[BTN_ADDR]
  2845.         cmp     [edi], dword 0  ; empty button list ?
  2846.         je      end_of_buttons_away
  2847.         movzx   ebx, word [edi]
  2848.         inc     ebx
  2849.         mov     eax,edi
  2850.   sys_newba:
  2851.         dec     ebx
  2852.         jz      end_of_buttons_away
  2853.  
  2854.         add     eax, 0x10
  2855.         cmp     cx, [eax]
  2856.         jnz     sys_newba
  2857.  
  2858.         push    eax ebx ecx
  2859.         mov     ecx,ebx
  2860.         inc     ecx
  2861.         shl     ecx, 4
  2862.         mov     ebx, eax
  2863.         add     eax, 0x10
  2864.         call    memmove
  2865.         dec     dword [edi]
  2866.         pop     ecx ebx eax
  2867.  
  2868.         jmp     sys_newba2
  2869.  
  2870.   end_of_buttons_away:
  2871.  
  2872.         ret
  2873.  
  2874.   no_widgets_away:
  2875.  
  2876.         cmp     ebx, 2
  2877.         jnz     srl1
  2878.  
  2879.         mov     edx, [TASK_BASE]      ; return whole screen draw area for this app
  2880.         add     edx, draw_data - CURRENT_TASK
  2881.         mov     [edx + RECT.left], 0
  2882.         mov     [edx + RECT.top