Subversion Repositories Kolibri OS

Rev

Rev 7136 | Rev 7276 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2016. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 7165 $
  75.  
  76.  
  77. USE_COM_IRQ     = 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO  = 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  = 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes  =  255
  98. tss_step       =  128 + 8192 ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       =  os_data_l - gdts    ; GDTs
  101. os_code        =  os_code_l - gdts
  102. graph_data     =  3 + graph_data_l - gdts
  103. tss0           =  tss0_l - gdts
  104. app_code       =  3 + app_code_l - gdts
  105. app_data       =  3 + app_data_l - gdts
  106. app_tls        =  3 + tls_data_l - gdts
  107. pci_code_sel   =  pci_code_32-gdts
  108. pci_data_sel   =  pci_data_32-gdts
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134. ; In bios boot mode the kernel code below is appended to bootbios.bin file.
  135. ; That is a loading and initialization code that also draws the blue screen
  136. ; menu with svn revision number near top right corner of the screen. This fasm
  137. ; preprocessor code searches for '****' signature inside bootbios.bin and
  138. ; places revision number there.
  139. if ~ defined UEFI
  140.   bootbios:
  141.   file 'bootbios.bin'
  142.   if __REV__ > 0
  143.     cur_pos = 0
  144.     cnt = 0
  145.     repeat $ - bootbios
  146.       load a byte from %
  147.       if a = '*'
  148.         cnt = cnt + 1
  149.       else
  150.         cnt = 0
  151.       end if
  152.       if cnt = 4
  153.         cur_pos = % - 1
  154.         break
  155.       end if
  156.     end repeat
  157.     store byte ' ' at cur_pos + 1
  158.     rev_var = __REV__
  159.     while rev_var > 0
  160.       store byte rev_var mod 10 + '0' at cur_pos
  161.       cur_pos = cur_pos - 1
  162.       rev_var = rev_var / 10
  163.     end while
  164.       store byte ' ' at cur_pos
  165.       store dword ' SVN' at cur_pos - 4
  166.   end if
  167. end if
  168.  
  169. use32
  170. org $+0x10000
  171.  
  172. align 4
  173. B32:
  174.         mov     ax, os_stack       ; Selector for os
  175.         mov     ds, ax
  176.         mov     es, ax
  177.         mov     fs, ax
  178.         mov     gs, ax
  179.         mov     ss, ax
  180.         mov     esp, TMP_STACK_TOP       ; Set stack
  181.  
  182. ; CLEAR 0x280000 - HEAP_BASE
  183.  
  184.         xor     eax, eax
  185.         mov     edi, CLEAN_ZONE
  186.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  187.         cld
  188.         rep stosd
  189.  
  190. ; CLEAR KERNEL UNDEFINED GLOBALS
  191.         mov     edi, endofcode-OS_BASE
  192.         mov     ecx, 0x90000
  193.         sub     ecx, edi
  194.         shr     ecx, 2
  195.         rep stosd
  196.  
  197. ; SAVE & CLEAR 0-0xffff
  198.  
  199.         mov     edi, 0x1000
  200.         mov     ecx, 0x8000 / 4
  201.         rep stosd
  202.         mov     edi, 0xa000
  203.         mov     ecx, 0x6000 / 4
  204.         rep stosd
  205.  
  206.         call    test_cpu
  207.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  208.  
  209.         call    check_acpi
  210.         call    init_hpet
  211.         call    init_BIOS32
  212. ; MEMORY MODEL
  213.         call    mem_test
  214.         call    init_mem
  215.         call    init_page_map
  216.  
  217. ; ENABLE PAGING
  218.  
  219.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  220.         mov     cr3, eax
  221.  
  222.         mov     eax, cr0
  223.         or      eax, CR0_PG+CR0_WP
  224.         mov     cr0, eax
  225.  
  226.         lgdt    [gdts]
  227.         jmp     pword os_code:high_code
  228.  
  229. align 4
  230. bios32_entry    dd ?
  231. tmp_page_tabs   dd ?
  232. use16
  233. ap_init16:
  234.         cli
  235.         lgdt    [cs:gdts_ap-ap_init16]
  236.         mov     eax, [cs:cr3_ap-ap_init16]
  237.         mov     cr3, eax
  238.         mov     eax, [cs:cr4_ap-ap_init16]
  239.         mov     cr4, eax
  240.         mov     eax, CR0_PE+CR0_PG+CR0_WP
  241.         mov     cr0, eax
  242.         jmp     pword os_code:ap_init_high
  243. align 16
  244. gdts_ap:
  245.         dw     gdte-gdts-1
  246.         dd     gdts
  247.         dw     0
  248. cr3_ap  dd     ?
  249. cr4_ap  dd     ?
  250. ap_init16_size = $ - ap_init16
  251. use32
  252.  
  253. __DEBUG__ fix 1
  254. __DEBUG_LEVEL__ fix 1
  255. include 'init.inc'
  256.  
  257. org OS_BASE+$
  258.  
  259. include 'fdo.inc'
  260.  
  261. align 4
  262. high_code:
  263.         mov     ax, os_stack
  264.         mov     bx, app_data
  265.         mov     cx, app_tls
  266.         mov     ss, ax
  267.         add     esp, OS_BASE
  268.  
  269.         mov     ds, bx
  270.         mov     es, bx
  271.         mov     fs, cx
  272.         mov     gs, bx
  273.  
  274.         xor     eax, eax
  275.         mov     ebx, 0xFFFFF000+PG_SHARED+PG_NOCACHE+PG_UWR
  276.         bt      [cpu_caps], CAPS_PAT
  277.         setc    al
  278.         shl     eax, 7
  279.         or      ebx, eax
  280.  
  281.         mov     eax, PG_GLOBAL
  282.         bt      [cpu_caps], CAPS_PGE
  283.         jnc     @F
  284.  
  285.         or      [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], eax
  286.         or      ebx, eax
  287.  
  288.         mov     eax, cr4
  289.         or      eax, CR4_PGE
  290.         mov     cr4, eax
  291. @@:
  292.         mov     [pte_valid_mask], ebx
  293.  
  294.         xor     eax, eax
  295.         mov     dword [sys_proc+PROC.pdt_0], eax
  296.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  297.  
  298.         mov     eax, cr3
  299.         mov     cr3, eax          ; flush TLB
  300.  
  301.         mov     ecx, pg_data.mutex
  302.         call    mutex_init
  303.  
  304.         mov     ecx, disk_list_mutex
  305.         call    mutex_init
  306.  
  307.         mov     ecx, keyboard_list_mutex
  308.         call    mutex_init
  309.  
  310.         mov     ecx, unpack_mutex
  311.         call    mutex_init
  312.  
  313.         mov     ecx, application_table_mutex
  314.         call    mutex_init
  315.  
  316.         mov     ecx, ide_mutex
  317.         call    mutex_init
  318.         mov     ecx, ide_channel1_mutex
  319.         call    mutex_init
  320.         mov     ecx, ide_channel2_mutex
  321.         call    mutex_init
  322.         mov     ecx, ide_channel3_mutex
  323.         call    mutex_init
  324.         mov     ecx, ide_channel4_mutex
  325.         call    mutex_init
  326.         mov     ecx, ide_channel5_mutex
  327.         call    mutex_init
  328.         mov     ecx, ide_channel6_mutex
  329.         call    mutex_init
  330. ;-----------------------------------------------------------------------------
  331. ; SAVE REAL MODE VARIABLES
  332. ;-----------------------------------------------------------------------------
  333. ; --------------- APM ---------------------
  334.  
  335. ; init selectors
  336.         mov     ebx, [BOOT.apm_entry]        ; offset of APM entry point
  337.         movzx   eax, word [BOOT.apm_code_32] ; real-mode segment base address of
  338.                                              ; protected-mode 32-bit code segment
  339.         movzx   ecx, word [BOOT.apm_code_16] ; real-mode segment base address of
  340.                                              ; protected-mode 16-bit code segment
  341.         movzx   edx, word [BOOT.apm_data_16] ; real-mode segment base address of
  342.                                              ; protected-mode 16-bit data segment
  343.  
  344.         shl     eax, 4
  345.         mov     [dword apm_code_32 + 2], ax
  346.         shr     eax, 16
  347.         mov     [dword apm_code_32 + 4], al
  348.  
  349.         shl     ecx, 4
  350.         mov     [dword apm_code_16 + 2], cx
  351.         shr     ecx, 16
  352.         mov     [dword apm_code_16 + 4], cl
  353.  
  354.         shl     edx, 4
  355.         mov     [dword apm_data_16 + 2], dx
  356.         shr     edx, 16
  357.         mov     [dword apm_data_16 + 4], dl
  358.  
  359.         mov     dword[apm_entry], ebx
  360.         mov     word [apm_entry + 4], apm_code_32 - gdts
  361.  
  362.         mov     eax, dword[BOOT.apm_version]   ; version & flags
  363.         mov     [apm_vf], eax
  364. ; -----------------------------------------
  365.         mov     al, [BOOT.dma]            ; DMA access
  366.         mov     [allow_dma_access], al
  367.  
  368.         mov     al, [BOOT.debug_print]    ; If nonzero, duplicates debug output to the screen
  369.         mov     [debug_direct_print], al
  370.  
  371.         mov     al, [BOOT.launcher_start] ; Start the first app (LAUNCHER) after kernel is loaded?
  372.         mov     [launcher_start], al
  373.  
  374.         mov     esi, BOOT.bios_hd
  375.         movzx   ecx, byte [esi-1]
  376.         mov     [NumBiosDisks], ecx
  377.         mov     edi, BiosDisksData
  378.         shl     ecx, 2
  379.         rep movsd
  380.  
  381. ; -------- Fast System Call init ----------
  382. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  383.         bt      [cpu_caps], CAPS_SEP
  384.         jnc     .SEnP  ; SysEnter not Present
  385.         xor     edx, edx
  386.         mov     ecx, MSR_SYSENTER_CS
  387.         mov     eax, os_code
  388.         wrmsr
  389.         mov     ecx, MSR_SYSENTER_ESP
  390. ;           mov eax, sysenter_stack ; Check it
  391.         xor     eax, eax
  392.         wrmsr
  393.         mov     ecx, MSR_SYSENTER_EIP
  394.         mov     eax, sysenter_entry
  395.         wrmsr
  396. .SEnP:
  397. ; AMD SYSCALL/SYSRET
  398.         cmp     byte[cpu_vendor], 'A'
  399.         jne     .noSYSCALL
  400.         mov     eax, 0x80000001
  401.         cpuid
  402.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  403.         jz      .noSYSCALL
  404.         mov     ecx, MSR_AMD_EFER
  405.         rdmsr
  406.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  407.         wrmsr
  408.  
  409.         ; !!!! It`s dirty hack, fix it !!!
  410.         ; Bits of EDX :
  411.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  412.         ;  and the contents of this field, plus 8, are copied into the SS register.
  413.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  414.         ;  and the contents of this field, plus 8, are copied into the SS register.
  415.  
  416.         ; mov   edx, (os_code + 16) * 65536 + os_code
  417.         mov     edx, 0x1B0008
  418.  
  419.         mov     eax, syscall_entry
  420.         mov     ecx, MSR_AMD_STAR
  421.         wrmsr
  422. .noSYSCALL:
  423. ; -----------------------------------------
  424.         stdcall alloc_page
  425.         stdcall map_page, tss-0xF80, eax, PG_SWR
  426.         stdcall alloc_page
  427.         stdcall map_page, tss+0x80, eax, PG_SWR
  428.         stdcall alloc_page
  429.         stdcall map_page, tss+0x1080, eax, PG_SWR
  430.  
  431. ; LOAD IDT
  432.  
  433.         call    build_interrupt_table ;lidt is executed
  434.           ;lidt [idtreg]
  435.  
  436.         call    init_kernel_heap
  437.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  438.         mov     [os_stack_seg], eax
  439.  
  440.         lea     esp, [eax+RING0_STACK_SIZE]
  441.  
  442.         mov     [tss._ss0], os_stack
  443.         mov     [tss._esp0], esp
  444.         mov     [tss._esp], esp
  445.         mov     [tss._cs], os_code
  446.         mov     [tss._ss], os_stack
  447.         mov     [tss._ds], app_data
  448.         mov     [tss._es], app_data
  449.         mov     [tss._fs], app_data
  450.         mov     [tss._gs], app_data
  451.         mov     [tss._io], 128
  452. ;Add IO access table - bit array of permitted ports
  453.         mov     edi, tss._io_map_0
  454.         xor     eax, eax
  455.         not     eax
  456.         mov     ecx, 8192/4
  457.         rep stosd                    ; access to 4096*8=65536 ports
  458.  
  459.         mov     ax, tss0
  460.         ltr     ax
  461.  
  462.         mov     eax, sys_proc
  463.         list_init eax
  464.         add     eax, PROC.thr_list
  465.         list_init eax
  466.  
  467.         call    init_video
  468.         call    init_mtrr
  469.         mov     [LFBAddress], LFB_BASE
  470.         mov     ecx, bios_fb
  471.         call    set_framebuffer
  472.         call    init_fpu
  473.         call    init_malloc
  474.  
  475.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  476.         mov     [default_io_map], eax
  477.  
  478.         add     eax, 0x2000
  479.         mov     [ipc_tmp], eax
  480.         mov     ebx, 0x1000
  481.  
  482.         add     eax, 0x40000
  483.         mov     [proc_mem_map], eax
  484.  
  485.         add     eax, 0x8000
  486.         mov     [proc_mem_pdir], eax
  487.  
  488.         add     eax, ebx
  489.         mov     [proc_mem_tab], eax
  490.  
  491.         add     eax, ebx
  492.         mov     [tmp_task_ptab], eax
  493.  
  494.         add     eax, ebx
  495.         mov     [ipc_pdir], eax
  496.  
  497.         add     eax, ebx
  498.         mov     [ipc_ptab], eax
  499.  
  500.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  501.                 (unpack.lc+unpack.lp)))*4
  502.  
  503.         mov     [unpack.p], eax
  504.  
  505.         call    init_events
  506.         mov     eax, srv.fd-SRV.fd
  507.         mov     [srv.fd], eax
  508.         mov     [srv.bk], eax
  509.  
  510. ;Set base of graphic segment to linear address of LFB
  511.         mov     eax, [LFBAddress]         ; set for gs
  512.         mov     [graph_data_l+2], ax
  513.         shr     eax, 16
  514.         mov     [graph_data_l+4], al
  515.         mov     [graph_data_l+7], ah
  516.  
  517.         stdcall kernel_alloc, [_display.win_map_size]
  518.         mov     [_display.win_map], eax
  519.  
  520.         xor     eax, eax
  521.         inc     eax
  522.  
  523. ; set background
  524.  
  525.         mov     [BgrDrawMode], eax
  526.         mov     [BgrDataWidth], eax
  527.         mov     [BgrDataHeight], eax
  528.         mov     [mem_BACKGROUND], 4
  529.         mov     [img_background], static_background_data
  530.  
  531. ; set clipboard
  532.  
  533.         xor     eax, eax
  534.         mov     [clipboard_slots], eax
  535.         mov     [clipboard_write_lock], eax
  536.         stdcall kernel_alloc, 4096
  537.         test    eax, eax
  538.         jnz     @f
  539.  
  540.         dec     eax
  541. @@:
  542.         mov     [clipboard_main_list], eax
  543.  
  544.         mov     eax, [hpet_base]
  545.         test    eax, eax
  546.         jz      @F
  547.         mov     eax, [hpet_base]
  548.         stdcall map_io_mem, [hpet_base], 1024, PG_GLOBAL+PAT_UC+PG_SWR
  549.         mov     [hpet_base], eax
  550.         mov     eax, [eax]
  551.         DEBUGF  1, "K : HPET caps %x\n", eax
  552. @@:
  553. ; SET UP OS TASK
  554.  
  555.         mov     esi, boot_setostask
  556.         call    boot_log
  557.  
  558.         mov     edi, sys_proc+PROC.heap_lock
  559.         mov     ecx, (PROC.ht_free-PROC.heap_lock)/4
  560.  
  561.         xor     eax, eax
  562.         cld
  563.         rep stosd
  564.  
  565.         mov     [edi], dword (PROC.pdt_0 - PROC.htab)/4 - 3
  566.         mov     [edi+4], dword 3           ;reserve handles for stdin stdout and stderr
  567.         mov     ecx, (PROC.pdt_0 - PROC.htab)/4
  568.         add     edi, 8
  569.         inc     eax
  570. @@:
  571.         stosd
  572.         inc     eax
  573.         cmp     eax, ecx
  574.         jbe     @B
  575.  
  576.         mov     [sys_proc+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  577.  
  578.         mov     eax, -1
  579.         mov     edi, thr_slot_map+4
  580.         mov     [edi-4], dword 0xFFFFFFF8
  581.         stosd
  582.         stosd
  583.         stosd
  584.         stosd
  585.         stosd
  586.         stosd
  587.         stosd
  588.  
  589.         mov     [current_process], sys_proc
  590.  
  591.         mov     edx, SLOT_BASE+256*1
  592.         mov     ebx, [os_stack_seg]
  593.         add     ebx, 0x2000
  594.         call    setup_os_slot
  595.         mov     dword [edx], 'IDLE'
  596.         sub     [edx+APPDATA.saved_esp], 4
  597.         mov     eax, [edx+APPDATA.saved_esp]
  598.         mov     dword [eax], idle_thread
  599.         mov     ecx, IDLE_PRIORITY
  600.         call    scheduler_add_thread
  601.  
  602.         mov     edx, SLOT_BASE+256*2
  603.         mov     ebx, [os_stack_seg]
  604.         call    setup_os_slot
  605.         mov     dword [edx], 'OS'
  606.         xor     ecx, ecx
  607.         call    scheduler_add_thread
  608.  
  609.         mov     dword [CURRENT_TASK], 2
  610.         mov     dword [TASK_COUNT], 2
  611.         mov     dword [current_slot], SLOT_BASE + 256*2
  612.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  613.  
  614. ; Move other CPUs to deep sleep, if it is useful
  615. uglobal
  616. use_mwait_for_idle db 0
  617. endg
  618.         cmp     [cpu_vendor+8], 'ntel'
  619.         jnz     .no_wake_cpus
  620.         bt      [cpu_caps+4], CAPS_MONITOR-32
  621.         jnc     .no_wake_cpus
  622.         dbgstr 'using mwait for idle loop'
  623.         inc     [use_mwait_for_idle]
  624.         mov     ebx, [cpu_count]
  625.         cmp     ebx, 1
  626.         jbe     .no_wake_cpus
  627.         call    create_trampoline_pgmap
  628.         mov     [cr3_ap+OS_BASE], eax
  629.         mov     eax, cr4
  630.         mov     [cr4_ap+OS_BASE], eax
  631.         mov     esi, OS_BASE + ap_init16
  632.         mov     edi, OS_BASE + 8000h
  633.         mov     ecx, (ap_init16_size + 3) / 4
  634.         rep movsd
  635.         stdcall map_io_mem, [acpi_lapic_base], 0x1000, PG_GLOBAL+PG_NOCACHE+PG_SWR
  636.         mov     [LAPIC_BASE], eax
  637.         lea     edi, [eax+300h]
  638.         mov     esi, smpt+4
  639.         dec     ebx
  640. .wake_cpus_loop:
  641.         lodsd
  642.         push    esi
  643.         xor     esi, esi
  644.         inc     esi
  645.         shl     eax, 24
  646.         mov     [edi+10h], eax
  647. ; assert INIT IPI
  648.         mov     dword [edi], 0C500h
  649.         call    delay_ms
  650. @@:
  651.         test    dword [edi], 1000h
  652.         jnz     @b
  653. ; deassert INIT IPI
  654.         mov     dword [edi], 8500h
  655.         call    delay_ms
  656. @@:
  657.         test    dword [edi], 1000h
  658.         jnz     @b
  659. ; send STARTUP IPI
  660.         mov     dword [edi], 600h + (8000h shr 12)
  661.         call    delay_ms
  662. @@:
  663.         test    dword [edi], 1000h
  664.         jnz     @b
  665.         pop     esi
  666.         dec     ebx
  667.         jnz     .wake_cpus_loop
  668.         mov     eax, [cpu_count]
  669.         dec     eax
  670. @@:
  671.         cmp     [ap_initialized], eax
  672.         jnz     @b
  673.         mov     eax, [cr3_ap+OS_BASE]
  674.         call    free_page
  675. .no_wake_cpus:
  676.  
  677. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  678.         mov     esi, boot_initirq
  679.         call    boot_log
  680.         call    init_irqs
  681.  
  682.         mov     esi, boot_picinit
  683.         call    boot_log
  684.         call    PIC_init
  685.  
  686.         mov     esi, boot_v86machine
  687.         call    boot_log
  688. ; Initialize system V86 machine
  689.         call    init_sys_v86
  690.  
  691.         mov     esi, boot_inittimer
  692.         call    boot_log
  693. ; Initialize system timer (IRQ0)
  694.         call    PIT_init
  695.  
  696. ; Register ramdisk file system
  697.         cmp     byte [BOOT.dev+0x10000], 1
  698.         je      @f
  699.  
  700.         call    register_ramdisk
  701. ;--------------------------------------
  702. @@:
  703.         mov     esi, boot_initapic
  704.         call    boot_log
  705. ; Try to Initialize APIC
  706.         call    APIC_init
  707.  
  708.         mov     esi, boot_enableirq
  709.         call    boot_log
  710. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  711. ; they are used: when partitions are scanned, hd_read relies on timer
  712.         call    unmask_timer
  713.         stdcall enable_irq, 2               ; @#$%! PIC
  714.         stdcall enable_irq, 13              ; co-processor
  715.  
  716. ; Setup serial output console (if enabled)
  717. if defined debug_com_base
  718.  
  719.         ; reserve port so nobody else will use it
  720.         xor     ebx, ebx
  721.         mov     ecx, debug_com_base
  722.         mov     edx, debug_com_base+7
  723.         call    r_f_port_area
  724.  
  725.         ; enable Divisor latch
  726.         mov     dx, debug_com_base+3
  727.         mov     al, 1 shl 7
  728.         out     dx, al
  729.  
  730.         ; Set speed to 115200 baud (max speed)
  731.         mov     dx, debug_com_base
  732.         mov     al, 0x01
  733.         out     dx, al
  734.  
  735.         mov     dx, debug_com_base+1
  736.         mov     al, 0x00
  737.         out     dx, al
  738.  
  739.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  740.         mov     dx, debug_com_base+3
  741.         mov     al, 3
  742.         out     dx, al
  743.  
  744.         ; disable interrupts
  745.         mov     dx, debug_com_base+1
  746.         mov     al, 0
  747.         out     dx, al
  748.  
  749.         ; clear +  enable fifo (64 bits)
  750.         mov     dx, debug_com_base+2
  751.         mov     al, 0x7 + 1 shl 5
  752.         out     dx, al
  753.  
  754. end if
  755.  
  756.  
  757. ;-----------------------------------------------------------------------------
  758. ; show SVN version of kernel on the message board
  759. ;-----------------------------------------------------------------------------
  760.         mov     eax, [version_inf.rev]
  761.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  762. ;-----------------------------------------------------------------------------
  763. ; show CPU count on the message board
  764. ;-----------------------------------------------------------------------------
  765.         mov     eax, [cpu_count]
  766.         test    eax, eax
  767.         jnz     @F
  768.         mov     al, 1                             ; at least one CPU
  769. @@:
  770.         DEBUGF  1, "K : %d CPU detected\n", eax
  771. ;-----------------------------------------------------------------------------
  772. ; detect Floppy drives
  773. ;-----------------------------------------------------------------------------
  774.         mov     esi, boot_detectfloppy
  775.         call    boot_log
  776. include 'detect/dev_fd.inc'
  777. ;-----------------------------------------------------------------------------
  778. ; create pci-devices list
  779. ;-----------------------------------------------------------------------------
  780.         mov     [pci_access_enabled], 1
  781.         call    pci_enum
  782. ;-----------------------------------------------------------------------------
  783. ; initialisation IDE ATA code
  784. ;-----------------------------------------------------------------------------
  785. include 'detect/init_ata.inc'
  786. ;-----------------------------------------------------------------------------
  787. if 0
  788.         mov     ax, [BOOT.bx_from_load]
  789.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  790.         je      no_lib_load
  791.  
  792.         mov     esi, boot_loadlibs
  793.         call    boot_log
  794. ; LOADING LIBRARES
  795.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  796.         call    load_file_parse_table       ; prepare file parse table
  797.         call    set_kernel_conf             ; configure devices and gui
  798. no_lib_load:
  799. end if
  800.  
  801. ; Display APIC status
  802.         mov     esi, boot_APIC_found
  803.         cmp     [irq_mode], IRQ_APIC
  804.         je      @f
  805.         mov     esi, boot_APIC_nfound
  806. @@:
  807.         call    boot_log
  808.  
  809. ; PRINT AMOUNT OF MEMORY
  810.         mov     esi, boot_memdetect
  811.         call    boot_log
  812.  
  813.         movzx   ecx, word [boot_y]
  814.         if lang eq ru
  815.         or      ecx, (10+30*6) shl 16
  816.         else if lang eq sp
  817.         or      ecx, (10+33*6) shl 16
  818.         else
  819.         or      ecx, (10+29*6) shl 16
  820.         end if
  821.         sub     ecx, 10
  822.         mov     edx, 0xFFFFFF
  823.         mov     ebx, [MEM_AMOUNT]
  824.         shr     ebx, 20
  825.         xor     edi, edi
  826.         mov     eax, 0x00040000
  827.         inc     edi
  828.         call    display_number_force
  829.  
  830. ; BUILD SCHEDULER
  831.  
  832. ;        call    build_scheduler; sys32.inc
  833.  
  834. ;        mov     esi, boot_devices
  835. ;        call    boot_log
  836.  
  837. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  838.  
  839.         stdcall load_pe_driver, szVidintel, 0
  840.  
  841.         call    usb_init
  842.  
  843. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  844.  
  845.         mov     esi, boot_windefs
  846.         call    boot_log
  847.         call    set_window_defaults
  848.  
  849. ; SET BACKGROUND DEFAULTS
  850.  
  851.         mov     esi, boot_bgr
  852.         call    boot_log
  853.         call    init_background
  854.         call    calculatebackground
  855.  
  856. ; RESERVE SYSTEM IRQ'S JA PORT'S
  857.  
  858.         mov     esi, boot_resirqports
  859.         call    boot_log
  860.         call    reserve_irqs_ports
  861.  
  862.         call    init_display
  863.         mov     eax, [def_cursor]
  864.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  865.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  866.  
  867. ; PRINT CPU FREQUENCY
  868.  
  869.         mov     esi, boot_cpufreq
  870.         call    boot_log
  871.  
  872.         cli
  873.         mov     ebx, [hpet_base]
  874.         test    ebx, ebx
  875.         jz      @F
  876.         mov     ebx, [ebx+0xF0]
  877.  
  878.         rdtsc
  879.         mov     ecx, 1000
  880.         sub     eax, [hpet_tsc_start]
  881.         sbb     edx, [hpet_tsc_start+4]
  882.         shld    edx, eax, 10
  883.         shl     eax, 10
  884.         mov     esi, eax
  885.         mov     eax, edx
  886.         mul     ecx
  887.         xchg    eax, esi
  888.         mul     ecx
  889.         adc     edx, esi
  890.         div     ebx
  891.         mul     ecx
  892.         div     [hpet_period]
  893.         mul     ecx
  894.         DEBUGF  1, "K : cpu frequency %u Hz\n", eax
  895.         jmp     .next
  896. @@:
  897.         rdtsc
  898.         mov     ecx, eax
  899.         mov     esi, 250            ; wait 1/4 a second
  900.         call    delay_ms
  901.         rdtsc
  902.  
  903.         sub     eax, ecx
  904.         xor     edx, edx
  905.         shld    edx, eax, 2
  906.         shl     eax, 2
  907. .next:
  908.         mov     dword [cpu_freq], eax
  909.         mov     dword [cpu_freq+4], edx
  910.         mov     ebx, 1000000
  911.         div     ebx
  912.         mov     ebx, eax
  913.  
  914.         movzx   ecx, word [boot_y]
  915.         if lang eq ru
  916.         add     ecx, (10+19*6) shl 16 - 10
  917.         else if lang eq sp
  918.         add     ecx, (10+25*6) shl 16 - 10
  919.         else
  920.         add     ecx, (10+17*6) shl 16 - 10
  921.         end if
  922.  
  923.         mov     edx, 0xFFFFFF
  924.         xor     edi, edi
  925.         mov     eax, 0x00040000
  926.         inc     edi
  927.         call    display_number_force
  928.  
  929. ; SET VARIABLES
  930.  
  931.         call    set_variables
  932.  
  933. ; STACK AND FDC
  934.  
  935.         call    stack_init
  936.         call    fdc_init
  937.  
  938. ; PALETTE FOR 320x200 and 640x480 16 col
  939.  
  940.         cmp     [SCR_MODE], word 0x12
  941.         jne     no_pal_vga
  942.         mov     esi, boot_pal_vga
  943.         call    boot_log
  944.         call    paletteVGA
  945.       no_pal_vga:
  946.  
  947.         cmp     [SCR_MODE], word 0x13
  948.         jne     no_pal_ega
  949.         mov     esi, boot_pal_ega
  950.         call    boot_log
  951.         call    palette320x200
  952.       no_pal_ega:
  953.  
  954. ; LOAD DEFAULT SKIN
  955.  
  956.         call    load_default_skin
  957.  
  958. ; Protect I/O permission map
  959.  
  960.         mov     esi, [default_io_map]
  961.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_READ
  962.         add     esi, 0x1000
  963.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  964.  
  965.         stdcall map_page, tss._io_map_0, \
  966.                 [SLOT_BASE+256+APPDATA.io_map], PG_READ
  967.         stdcall map_page, tss._io_map_1, \
  968.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  969.  
  970. ; SET KEYBOARD PARAMETERS
  971.         mov     al, 0xf6       ; reset keyboard, scan enabled
  972.         call    kb_write_wait_ack
  973.         test    ah, ah
  974.         jnz     .no_keyboard
  975.  
  976. iglobal
  977. align 4
  978. ps2_keyboard_functions:
  979.         dd      .end - $
  980.         dd      0       ; no close
  981.         dd      ps2_set_lights
  982. .end:
  983. endg
  984.         stdcall register_keyboard, ps2_keyboard_functions, 0
  985.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  986.        ; call  kb_write_wait_ack
  987.        ; mov   al, 111b
  988.        ; call  kb_write_wait_ack
  989.  
  990.         mov     al, 0xF3     ; set repeat rate & delay
  991.         call    kb_write_wait_ack
  992.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  993.         call    kb_write_wait_ack
  994.      ;// mike.dld [
  995.         call    set_lights
  996.      ;// mike.dld ]
  997.         stdcall attach_int_handler, 1, irq1, 0
  998.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  999. .no_keyboard:
  1000.  
  1001. ; Load PS/2 mouse driver
  1002.  
  1003.         stdcall load_pe_driver, szPS2MDriver, 0
  1004.  
  1005.         mov     esi, boot_setmouse
  1006.         call    boot_log
  1007.         call    setmouse
  1008.  
  1009. ; LOAD FIRST APPLICATION
  1010.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1011.         jnz     first_app_found
  1012.  
  1013.         cli
  1014.         mov     ebp, firstapp
  1015.         call    fs_execute_from_sysdir
  1016.         test    eax, eax
  1017.         jns     first_app_found
  1018.  
  1019.         mov     esi, boot_failed
  1020.         call    boot_log
  1021.  
  1022.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1023.         hlt
  1024.  
  1025. first_app_found:
  1026.  
  1027. ; START MULTITASKING
  1028. preboot_blogesc = 0       ; start immediately after bootlog
  1029.  
  1030. ; A 'All set - press ESC to start' messages if need
  1031. if preboot_blogesc
  1032.         mov     esi, boot_tasking
  1033.         call    boot_log
  1034. .bll1:
  1035.         in      al, 0x60        ; wait for ESC key press
  1036.         cmp     al, 129
  1037.         jne     .bll1
  1038. end if
  1039.  
  1040.         mov     [timer_ticks_enable], 1         ; for cd driver
  1041.  
  1042.         sti
  1043.  
  1044.         call    mtrr_validate
  1045.  
  1046.         jmp     osloop
  1047.  
  1048.  
  1049.         ; Fly :)
  1050.  
  1051. uglobal
  1052. align 4
  1053. ap_initialized  dd      0
  1054. endg
  1055.  
  1056. ap_init_high:
  1057.         mov     ax, os_stack
  1058.         mov     bx, app_data
  1059.         mov     cx, app_tls
  1060.         mov     ss, ax
  1061.         mov     ds, bx
  1062.         mov     es, bx
  1063.         mov     fs, cx
  1064.         mov     gs, bx
  1065.         xor     esp, esp
  1066.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  1067.         mov     cr3, eax
  1068.         lock inc [ap_initialized]
  1069.         jmp     idle_loop
  1070.  
  1071.  
  1072. include 'unpacker.inc'
  1073.  
  1074. align 4
  1075. boot_log:
  1076.         pushad
  1077.  
  1078.         mov     ebx, 10*65536
  1079.         mov     bx, word [boot_y]
  1080.         add     [boot_y], dword 10
  1081.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1082.         xor     edi, edi
  1083.         mov     edx, esi
  1084.         inc     edi
  1085.         call    dtext
  1086.  
  1087.         mov     [novesachecksum], 1000
  1088.         call    checkVga_N13
  1089.  
  1090.         popad
  1091.  
  1092.         ret
  1093.  
  1094. ; in: edx -> APPDATA for OS/IDLE slot
  1095. ; in: ebx = stack base
  1096. proc setup_os_slot
  1097.         xor     eax, eax
  1098.         mov     ecx, 256/4
  1099.         mov     edi, edx
  1100.         rep stosd
  1101.  
  1102.         mov     eax, tss+0x80
  1103.         call    get_pg_addr
  1104.         inc     eax
  1105.         mov     [edx+APPDATA.io_map], eax
  1106.         mov     eax, tss+0x1080
  1107.         call    get_pg_addr
  1108.         inc     eax
  1109.         mov     [edx+APPDATA.io_map+4], eax
  1110.  
  1111.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1112.         lea     edi, [ebx+RING0_STACK_SIZE]
  1113.         mov     dword [edx+APPDATA.fpu_state], edi
  1114.         mov     dword [edx+APPDATA.saved_esp0], edi
  1115.         mov     dword [edx+APPDATA.saved_esp], edi
  1116.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1117.  
  1118.         mov     esi, fpu_data
  1119.         mov     ecx, [xsave_area_size]
  1120.         add     ecx, 3
  1121.         shr     ecx, 2
  1122.         rep movsd
  1123.  
  1124.         lea     eax, [edx+APP_OBJ_OFFSET]
  1125.         mov     dword [edx+APPDATA.fd_obj], eax
  1126.         mov     dword [edx+APPDATA.bk_obj], eax
  1127.  
  1128.         mov     dword [edx+APPDATA.cur_dir], sysdir_path-2
  1129.  
  1130.         mov     [edx + APPDATA.process], sys_proc
  1131.  
  1132.         lea     ebx, [edx+APPDATA.list]
  1133.         lea     ecx, [sys_proc+PROC.thr_list]
  1134.         list_add_tail ebx, ecx
  1135.  
  1136.         mov     eax, edx
  1137.         shr     eax, 3
  1138.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1139.         mov     [eax+TASKDATA.wnd_number], dh
  1140.         mov     byte [eax+TASKDATA.pid], dh
  1141.  
  1142.         ret
  1143. endp
  1144.  
  1145. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1146. ;                                                                    ;
  1147. ;                    MAIN OS LOOP START                              ;
  1148. ;                                                                    ;
  1149. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1150. align 32
  1151. osloop:
  1152.         mov     edx, osloop_has_work?
  1153.         xor     ecx, ecx
  1154.         call    Wait_events
  1155.         xor     eax, eax
  1156.         xchg    eax, [osloop_nonperiodic_work]
  1157.         test    eax, eax
  1158.         jz      .no_periodic
  1159.  
  1160.         call    __sys_draw_pointer
  1161.         call    window_check_events
  1162.         call    mouse_check_events
  1163.         call    checkmisc
  1164.         call    checkVga_N13
  1165. ;--------------------------------------
  1166. .no_periodic:
  1167.         call    stack_handler
  1168.         call    check_fdd_motor_status
  1169.         call    check_ATAPI_device_event
  1170.         call    check_lights_state
  1171.         call    check_timers
  1172.  
  1173.         jmp     osloop
  1174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1175. ;                                                                    ;
  1176. ;                      MAIN OS LOOP END                              ;
  1177. ;                                                                    ;
  1178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1179. proc osloop_has_work?
  1180.         cmp     [osloop_nonperiodic_work], 0
  1181.         jnz     .yes
  1182.         call    stack_handler_has_work?
  1183.         jnz     .yes
  1184.         call    check_fdd_motor_status_has_work?
  1185.         jnz     .yes
  1186.         call    check_ATAPI_device_event_has_work?
  1187.         jnz     .yes
  1188.         call    check_lights_state_has_work?
  1189.         jnz     .yes
  1190.         call    check_timers_has_work?
  1191.         jnz     .yes
  1192. .no:
  1193.         xor     eax, eax
  1194.         ret
  1195. .yes:
  1196.         xor     eax, eax
  1197.         inc     eax
  1198.         ret
  1199. endp
  1200.  
  1201. proc wakeup_osloop
  1202.         mov     [osloop_nonperiodic_work], 1
  1203.         ret
  1204. endp
  1205.  
  1206. uglobal
  1207. align 4
  1208. osloop_nonperiodic_work dd      ?
  1209. endg
  1210.  
  1211. uglobal
  1212. align 64
  1213. idle_addr       rb      64
  1214. endg
  1215.  
  1216. idle_thread:
  1217.         sti
  1218.  
  1219. ; The following code can be executed by all CPUs in the system.
  1220. ; All other parts of the kernel do not expect multi-CPU.
  1221. ; Also, APs don't even have a stack here.
  1222. ; Beware. Don't do anything here. Anything at all.
  1223. idle_loop:
  1224.         cmp     [use_mwait_for_idle], 0
  1225.         jnz     idle_loop_mwait
  1226.  
  1227. idle_loop_hlt:
  1228.         hlt
  1229.         jmp     idle_loop_hlt
  1230.  
  1231. idle_loop_mwait:
  1232.         mov     eax, idle_addr
  1233.         xor     ecx, ecx
  1234.         xor     edx, edx
  1235.         monitor
  1236.         xor     ecx, ecx
  1237.         mov     eax, 20h        ; or 10h
  1238.         mwait
  1239.         jmp     idle_loop_mwait
  1240.  
  1241.  
  1242. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1243. ;                                                                      ;
  1244. ;                   INCLUDED SYSTEM FILES                              ;
  1245. ;                                                                      ;
  1246. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1247.  
  1248.  
  1249. include "kernel32.inc"
  1250.  
  1251.  
  1252. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1253. ;                                                                      ;
  1254. ;                       KERNEL FUNCTIONS                               ;
  1255. ;                                                                      ;
  1256. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1257.  
  1258. reserve_irqs_ports:
  1259.  
  1260.  
  1261. ; RESERVE PORTS
  1262.         mov     eax, RESERVED_PORTS
  1263.         mov     ecx, 1
  1264.  
  1265.         mov     [eax], dword 4
  1266.  
  1267.         mov     [eax+16], ecx
  1268.         mov     [eax+16+4], dword 0
  1269.         mov     [eax+16+8], dword 0x2D
  1270.  
  1271.         mov     [eax+32], ecx
  1272.         mov     [eax+32+4], dword 0x30
  1273.         mov     [eax+32+8], dword 0x4D
  1274.  
  1275.         mov     [eax+48], ecx
  1276.         mov     [eax+48+4], dword 0x50
  1277.         mov     [eax+48+8], dword 0xDF
  1278.  
  1279.         mov     [eax+64], ecx
  1280.         mov     [eax+64+4], dword 0xE5
  1281.         mov     [eax+64+8], dword 0xFF
  1282.  
  1283.         ret
  1284.  
  1285.  
  1286. iglobal
  1287.   process_number dd 0x2
  1288. endg
  1289.  
  1290. set_variables:
  1291.  
  1292.         mov     ecx, 0x16                    ; flush port 0x60
  1293. .fl60:
  1294.         in      al, 0x60
  1295.         loop    .fl60
  1296.         push    eax
  1297.  
  1298.         mov     ax, [BOOT.y_res]
  1299.         shr     ax, 1
  1300.         shl     eax, 16
  1301.         mov     ax, [BOOT.x_res]
  1302.         shr     ax, 1
  1303.         mov     [MOUSE_X], eax
  1304.         call    wakeup_osloop
  1305.  
  1306.         xor     eax, eax
  1307.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1308.  
  1309.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1310.         mov     byte [BTN_COUNT], al              ; button buffer
  1311. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1312.  
  1313.         pop     eax
  1314.         ret
  1315.  
  1316. align 4
  1317. ;input  eax=43,bl-byte of output, ecx - number of port
  1318. sys_outport:
  1319.  
  1320.         mov     edi, ecx   ; separate flag for read / write
  1321.         and     ecx, 65535
  1322.  
  1323.         mov     eax, [RESERVED_PORTS]
  1324.         test    eax, eax
  1325.         jnz     .sopl8
  1326.         inc     eax
  1327.         mov     [esp+32], eax
  1328.         ret
  1329.  
  1330.   .sopl8:
  1331.         mov     edx, [TASK_BASE]
  1332.         mov     edx, [edx+0x4]
  1333.     ;and   ecx,65535
  1334.     ;cld - set on interrupt 0x40
  1335.   .sopl1:
  1336.  
  1337.         mov     esi, eax
  1338.         shl     esi, 4
  1339.         add     esi, RESERVED_PORTS
  1340.         cmp     edx, [esi+0]
  1341.         jne     .sopl2
  1342.         cmp     ecx, [esi+4]
  1343.         jb      .sopl2
  1344.         cmp     ecx, [esi+8]
  1345.         jg      .sopl2
  1346. .sopl3:
  1347.  
  1348.         test    edi, 0x80000000; read ?
  1349.         jnz     .sopl4
  1350.  
  1351.         mov     eax, ebx
  1352.         mov     dx, cx   ; write
  1353.         out     dx, al
  1354.         and     [esp+32], dword 0
  1355.         ret
  1356.  
  1357.         .sopl2:
  1358.  
  1359.         dec     eax
  1360.         jnz     .sopl1
  1361.         inc     eax
  1362.         mov     [esp+32], eax
  1363.         ret
  1364.  
  1365.  
  1366.   .sopl4:
  1367.  
  1368.         mov     dx, cx   ; read
  1369.         in      al, dx
  1370.         and     eax, 0xff
  1371.         and     [esp+32], dword 0
  1372.         mov     [esp+20], eax
  1373.         ret
  1374.  
  1375. display_number:
  1376. ;It is not optimization
  1377.         mov     eax, ebx
  1378.         mov     ebx, ecx
  1379.         mov     ecx, edx
  1380.         mov     edx, esi
  1381.         mov     esi, edi
  1382. ; eax = print type, al=0 -> ebx is number
  1383. ;                   al=1 -> ebx is pointer
  1384. ;                   ah=0 -> display decimal
  1385. ;                   ah=1 -> display hexadecimal
  1386. ;                   ah=2 -> display binary
  1387. ;                   eax bits 16-21 = number of digits to display (0-32)
  1388. ;                   eax bits 22-31 = reserved
  1389. ;
  1390. ; ebx = number or pointer
  1391. ; ecx = x shl 16 + y
  1392. ; edx = color
  1393.         xor     edi, edi
  1394. display_number_force:
  1395.         push    eax
  1396.         and     eax, 0x3fffffff
  1397.         cmp     eax, 0xffff     ; length > 0 ?
  1398.         pop     eax
  1399.         jge     cont_displ
  1400.         ret
  1401.    cont_displ:
  1402.         push    eax
  1403.         and     eax, 0x3fffffff
  1404.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1405.         pop     eax
  1406.         jb      cont_displ2
  1407.         ret
  1408.    cont_displ2:
  1409.  
  1410.         pushad
  1411.  
  1412.         cmp     al, 1            ; ecx is a pointer ?
  1413.         jne     displnl1
  1414.         mov     ebp, ebx
  1415.         add     ebp, 4
  1416.         mov     ebp, [ebp+std_application_base_address]
  1417.         mov     ebx, [ebx+std_application_base_address]
  1418.  displnl1:
  1419.         sub     esp, 64
  1420.  
  1421.         test    ah, ah            ; DECIMAL
  1422.         jnz     no_display_desnum
  1423.         shr     eax, 16
  1424.         and     eax, 0xC03f
  1425. ;     and   eax,0x3f
  1426.         push    eax
  1427.         and     eax, 0x3f
  1428.         mov     edi, esp
  1429.         add     edi, 4+64-1
  1430.         mov     ecx, eax
  1431.         mov     eax, ebx
  1432.         mov     ebx, 10
  1433.  d_desnum:
  1434.         xor     edx, edx
  1435.         call    division_64_bits
  1436.         div     ebx
  1437.         add     dl, 48
  1438.         mov     [edi], dl
  1439.         dec     edi
  1440.         loop    d_desnum
  1441.         pop     eax
  1442.         call    normalize_number
  1443.         call    draw_num_text
  1444.         add     esp, 64
  1445.         popad
  1446.         ret
  1447.    no_display_desnum:
  1448.  
  1449.         cmp     ah, 0x01         ; HEXADECIMAL
  1450.         jne     no_display_hexnum
  1451.         shr     eax, 16
  1452.         and     eax, 0xC03f
  1453. ;     and   eax,0x3f
  1454.         push    eax
  1455.         and     eax, 0x3f
  1456.         mov     edi, esp
  1457.         add     edi, 4+64-1
  1458.         mov     ecx, eax
  1459.         mov     eax, ebx
  1460.         mov     ebx, 16
  1461.    d_hexnum:
  1462.         xor     edx, edx
  1463.         call    division_64_bits
  1464.         div     ebx
  1465.    hexletters = __fdo_hexdigits
  1466.         add     edx, hexletters
  1467.         mov     dl, [edx]
  1468.         mov     [edi], dl
  1469.         dec     edi
  1470.         loop    d_hexnum
  1471.         pop     eax
  1472.         call    normalize_number
  1473.         call    draw_num_text
  1474.         add     esp, 64
  1475.         popad
  1476.         ret
  1477.    no_display_hexnum:
  1478.  
  1479.         cmp     ah, 0x02         ; BINARY
  1480.         jne     no_display_binnum
  1481.         shr     eax, 16
  1482.         and     eax, 0xC03f
  1483. ;     and   eax,0x3f
  1484.         push    eax
  1485.         and     eax, 0x3f
  1486.         mov     edi, esp
  1487.         add     edi, 4+64-1
  1488.         mov     ecx, eax
  1489.         mov     eax, ebx
  1490.         mov     ebx, 2
  1491.    d_binnum:
  1492.         xor     edx, edx
  1493.         call    division_64_bits
  1494.         div     ebx
  1495.         add     dl, 48
  1496.         mov     [edi], dl
  1497.         dec     edi
  1498.         loop    d_binnum
  1499.         pop     eax
  1500.         call    normalize_number
  1501.         call    draw_num_text
  1502.         add     esp, 64
  1503.         popad
  1504.         ret
  1505.    no_display_binnum:
  1506.  
  1507.         add     esp, 64
  1508.         popad
  1509.         ret
  1510.  
  1511. normalize_number:
  1512.         test    ah, 0x80
  1513.         jz      .continue
  1514.         mov     ecx, 48
  1515.         and     eax, 0x3f
  1516. @@:
  1517.         inc     edi
  1518.         cmp     [edi], cl
  1519.         jne     .continue
  1520.         dec     eax
  1521.         cmp     eax, 1
  1522.         ja      @r
  1523.         mov     al, 1
  1524. .continue:
  1525.         and     eax, 0x3f
  1526.         ret
  1527.  
  1528. division_64_bits:
  1529.         test    [esp+1+4], byte 0x40
  1530.         jz      .continue
  1531.         push    eax
  1532.         mov     eax, ebp
  1533.         div     ebx
  1534.         mov     ebp, eax
  1535.         pop     eax
  1536. .continue:
  1537.         ret
  1538.  
  1539. draw_num_text:
  1540.         mov     esi, eax
  1541.         mov     edx, 64+4
  1542.         sub     edx, eax
  1543.         add     edx, esp
  1544.         mov     ebx, [esp+64+32-8+4]
  1545. ; add window start x & y
  1546.         mov     ecx, [TASK_BASE]
  1547.  
  1548.         mov     edi, [CURRENT_TASK]
  1549.         shl     edi, 8
  1550.  
  1551.         mov     eax, [ecx-twdw+WDATA.box.left]
  1552.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1553.         shl     eax, 16
  1554.         add     eax, [ecx-twdw+WDATA.box.top]
  1555.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1556.         add     ebx, eax
  1557.         mov     ecx, [esp+64+32-12+4]
  1558.         mov     eax, [esp+64+8]         ; background color (if given)
  1559.         mov     edi, [esp+64+4]
  1560.         and     ecx, 5FFFFFFFh
  1561.         bt      ecx, 27
  1562.         jnc     @f
  1563.         mov     edi, eax
  1564. @@:
  1565.         jmp     dtext
  1566. ;-----------------------------------------------------------------------------
  1567. iglobal
  1568. midi_base dw 0
  1569. endg
  1570. ;-----------------------------------------------------------------------------
  1571. align 4
  1572. sys_setup:
  1573. ;  1 = roland mpu midi base , base io address
  1574. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1575. ;  3 = not used
  1576. ;  4 = not used
  1577. ;  5 = system language, 1eng 2fi 3ger 4rus
  1578. ;  6 = not used
  1579. ;  7 = not used
  1580. ;  8 = not used
  1581. ;  9 = not used
  1582. ; 10 = not used
  1583. ; 11 = enable lba read
  1584. ; 12 = enable pci access
  1585. ;-----------------------------------------------------------------------------
  1586.         and     [esp+32], dword 0
  1587. ; F.21.1 - set MPU MIDI base port
  1588.         dec     ebx
  1589.         jnz     @f
  1590.  
  1591.         cmp     ecx, 0x100
  1592.         jb      @f
  1593.  
  1594.         mov     esi, 65535
  1595.         cmp     esi, ecx
  1596.         jb      @f
  1597.  
  1598.         mov     [midi_base], cx
  1599.         mov     word [mididp], cx
  1600.         inc     cx
  1601.         mov     word [midisp], cx
  1602.         ret
  1603. ;--------------------------------------
  1604. @@:
  1605. ; F.21.2 - set keyboard layout
  1606.         dec     ebx
  1607.         jnz     @f
  1608.  
  1609.         mov     edi, [TASK_BASE]
  1610.         mov     eax, [edi+TASKDATA.mem_start]
  1611.         add     eax, edx
  1612. ; 1 = normal layout
  1613.         dec     ecx
  1614.         jnz     .shift
  1615.  
  1616.         mov     ebx, keymap
  1617.         mov     ecx, 128
  1618.         call    memmove
  1619.         ret
  1620. ;--------------------------------------
  1621. .shift:
  1622. ; 2 = layout at pressed Shift
  1623.         dec     ecx
  1624.         jnz     .alt
  1625.  
  1626.         mov     ebx, keymap_shift
  1627.         mov     ecx, 128
  1628.         call    memmove
  1629.         ret
  1630. ;--------------------------------------
  1631. .alt:
  1632. ; 3 = layout at pressed Alt
  1633.         dec     ecx
  1634.         jnz     .country
  1635.  
  1636.         mov     ebx, keymap_alt
  1637.         mov     ecx, 128
  1638.         call    memmove
  1639.         ret
  1640. ;--------------------------------------
  1641. .country:
  1642. ; country identifier
  1643.         sub     ecx, 6
  1644.         jnz     .error
  1645.  
  1646.         mov     word [keyboard], dx
  1647.         ret
  1648. ;--------------------------------------
  1649. @@:
  1650. ; F.21.5 - set system language
  1651.         sub     ebx, 3
  1652.         jnz     @f
  1653.  
  1654.         mov     [syslang], ecx
  1655.         ret
  1656. ;--------------------------------------
  1657. @@:
  1658. ; F.21.11 - enable/disable low-level access to HD
  1659.         and     ecx, 1
  1660.         sub     ebx, 6
  1661.         jnz     @f
  1662.  
  1663.         mov     [lba_read_enabled], ecx
  1664.         ret
  1665. ;--------------------------------------
  1666. @@:
  1667. ; F.21.12 - enable/disable low-level access to PCI
  1668.         dec     ebx
  1669.         jnz     .error
  1670.  
  1671.         mov     [pci_access_enabled], ecx
  1672.         ret
  1673. ;--------------------------------------
  1674. .error:
  1675.         or      [esp+32], dword -1
  1676.         ret
  1677. ;-----------------------------------------------------------------------------
  1678. align 4
  1679. sys_getsetup:
  1680. ;  1 = roland mpu midi base , base io address
  1681. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1682. ;  3 = not used
  1683. ;  4 = not used
  1684. ;  5 = system language, 1eng 2fi 3ger 4rus
  1685. ;  6 = not used
  1686. ;  7 = not used
  1687. ;  8 = not used
  1688. ;  9 = get hs timer tic
  1689. ; 10 = not used
  1690. ; 11 = get the state "lba read"
  1691. ; 12 = get the state "pci access"
  1692. ;-----------------------------------------------------------------------------
  1693. ; F.26.1 - get MPU MIDI base port
  1694.         dec     ebx
  1695.         jnz     @f
  1696.  
  1697.         movzx   eax, [midi_base]
  1698.         mov     [esp+32], eax
  1699.         ret
  1700. ;--------------------------------------
  1701. @@:
  1702. ; F.26.2 - get keyboard layout
  1703.         dec     ebx
  1704.         jnz     @f
  1705.  
  1706.         mov     edi, [TASK_BASE]
  1707.         mov     ebx, [edi+TASKDATA.mem_start]
  1708.         add     ebx, edx
  1709. ; 1 = normal layout
  1710.         dec     ecx
  1711.         jnz     .shift
  1712.  
  1713.         mov     eax, keymap
  1714.         mov     ecx, 128
  1715.         call    memmove
  1716.         ret
  1717. ;--------------------------------------
  1718. .shift:
  1719. ; 2 = layout with pressed Shift
  1720.         dec     ecx
  1721.         jnz     .alt
  1722.  
  1723.         mov     eax, keymap_shift
  1724.         mov     ecx, 128
  1725.         call    memmove
  1726.         ret
  1727. ;--------------------------------------
  1728. .alt:
  1729. ; 3 = layout with pressed Alt
  1730.         dec     ecx
  1731.         jne     .country
  1732.  
  1733.         mov     eax, keymap_alt
  1734.         mov     ecx, 128
  1735.         call    memmove
  1736.         ret
  1737. ;--------------------------------------
  1738. .country:
  1739. ; 9 = country identifier
  1740.         sub     ecx, 6
  1741.         jnz     .error
  1742.  
  1743.         movzx   eax, word [keyboard]
  1744.         mov     [esp+32], eax
  1745.         ret
  1746. ;--------------------------------------
  1747. @@:
  1748. ; F.26.5 - get system language
  1749.         sub     ebx, 3
  1750.         jnz     @f
  1751.  
  1752.         mov     eax, [syslang]
  1753.         mov     [esp+32], eax
  1754.         ret
  1755. ;--------------------------------------
  1756. @@:
  1757. ; F.26.9 - get the value of the time counter
  1758.         sub     ebx, 4
  1759.         jnz     @f
  1760.  
  1761.         mov     eax, [timer_ticks]
  1762.         mov     [esp+32], eax
  1763.         ret
  1764. ;--------------------------------------
  1765. @@:
  1766. ; F.26.10 - get the time from kernel launch in nanoseconds
  1767.         sub     ebx, 1
  1768.         jnz     @f
  1769.  
  1770.         call    get_clock_ns
  1771.         mov     [esp+24], edx
  1772.         mov     [esp+32], eax
  1773.         ret
  1774. ;--------------------------------------
  1775. @@:
  1776. ; F.26.11 - Find out whether low-level HD access is enabled
  1777.         sub     ebx, 1
  1778.         jnz     @f
  1779.  
  1780.         mov     eax, [lba_read_enabled]
  1781.         mov     [esp+32], eax
  1782.         ret
  1783. ;--------------------------------------
  1784. @@:
  1785. ; F.26.12 - Find out whether low-level PCI access is enabled
  1786.         dec     ebx
  1787.         jnz     .error
  1788.  
  1789.         mov     eax, [pci_access_enabled]
  1790.         mov     [esp+32], eax
  1791.         ret
  1792. ;--------------------------------------
  1793. .error:
  1794.         or      [esp+32], dword -1
  1795.         ret
  1796. ;-----------------------------------------------------------------------------
  1797. get_timer_ticks:
  1798.         mov     eax, [timer_ticks]
  1799.         ret
  1800. ;-----------------------------------------------------------------------------
  1801. readmousepos:
  1802. ; eax=0 screen relative
  1803. ; eax=1 window relative
  1804. ; eax=2 buttons pressed
  1805. ; eax=3 buttons pressed ext
  1806. ; eax=4 load cursor
  1807. ; eax=5 set cursor
  1808. ; eax=6 delete cursor
  1809. ; eax=7 get mouse_z
  1810. ; eax=8 load cursor unicode
  1811.         cmp     ebx, 8
  1812.         ja      @f
  1813.         jmp     dword[.mousefn+ebx*4]
  1814.  
  1815. align 4
  1816. .mousefn:
  1817. dd  .msscreen
  1818. dd  .mswin
  1819. dd  .msbutton
  1820. dd  .msbuttonExt
  1821. dd  .app_load_cursor
  1822. dd  .app_set_cursor
  1823. dd  .app_delete_cursor
  1824. dd  .msz
  1825. dd  .loadCursorUni
  1826.  
  1827. .msscreen:
  1828.         mov     eax, [MOUSE_X]
  1829.         shl     eax, 16
  1830.         mov     ax, [MOUSE_Y]
  1831.         mov     [esp+36-4], eax
  1832. @@:
  1833.         ret
  1834.  
  1835. .mswin:
  1836.         mov     eax, [MOUSE_X]
  1837.         shl     eax, 16
  1838.         mov     ax, [MOUSE_Y]
  1839.         mov     esi, [TASK_BASE]
  1840.         mov     bx, word [esi-twdw+WDATA.box.left]
  1841.         shl     ebx, 16
  1842.         mov     bx, word [esi-twdw+WDATA.box.top]
  1843.         sub     eax, ebx
  1844.         mov     edi, [CURRENT_TASK]
  1845.         shl     edi, 8
  1846.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1847.         rol     eax, 16
  1848.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1849.         rol     eax, 16
  1850.         mov     [esp+36-4], eax
  1851.         ret
  1852.  
  1853. .msbutton:
  1854.         movzx   eax, byte [BTN_DOWN]
  1855.         mov     [esp+36-4], eax
  1856.         ret
  1857.  
  1858. .msbuttonExt:
  1859.         mov     eax, [BTN_DOWN]
  1860.         mov     [esp+36-4], eax
  1861.         ret
  1862.  
  1863. .app_load_cursor:
  1864.         cmp     ecx, OS_BASE
  1865.         jae     @f
  1866.         stdcall load_cursor, ecx, edx
  1867.         mov     [esp+36-4], eax
  1868. @@:
  1869.         ret
  1870.  
  1871. .loadCursorUni:
  1872.         cmp     ecx, OS_BASE
  1873.         jae     @b
  1874.         push    ecx edx
  1875.         stdcall kernel_alloc, maxPathLength
  1876.         mov     edi, eax
  1877.         pop     eax esi
  1878.         push    edi
  1879.         call    getFullPath
  1880.         pop     ebp
  1881.         test    eax, eax
  1882.         jz      @f
  1883.         stdcall load_cursor, ebp, LOAD_FROM_FILE
  1884.         mov     [esp+32], eax
  1885. @@:
  1886.         stdcall kernel_free, ebp
  1887.         ret
  1888.  
  1889. .app_set_cursor:
  1890.         stdcall set_cursor, ecx
  1891.         mov     [esp+36-4], eax
  1892.         ret
  1893.  
  1894. .app_delete_cursor:
  1895.         stdcall delete_cursor, ecx
  1896.         mov     [esp+36-4], eax
  1897.         ret
  1898.  
  1899. .msz:
  1900.         mov     edi, [TASK_COUNT]
  1901.         movzx   edi, word [WIN_POS + edi*2]
  1902.         cmp     edi, [CURRENT_TASK]
  1903.         jne     @f
  1904.         mov     ax, [MOUSE_SCROLL_H]
  1905.         shl     eax, 16
  1906.         mov     ax, [MOUSE_SCROLL_V]
  1907.         mov     [esp+36-4], eax
  1908.         and     [MOUSE_SCROLL_H], word 0
  1909.         and     [MOUSE_SCROLL_V], word 0
  1910.         ret
  1911. @@:
  1912.         and     [esp+36-4], dword 0
  1913.         ret
  1914.  
  1915. is_input:
  1916.  
  1917.         push    edx
  1918.         mov     dx, word [midisp]
  1919.         in      al, dx
  1920.         and     al, 0x80
  1921.         pop     edx
  1922.         ret
  1923.  
  1924. is_output:
  1925.  
  1926.         push    edx
  1927.         mov     dx, word [midisp]
  1928.         in      al, dx
  1929.         and     al, 0x40
  1930.         pop     edx
  1931.         ret
  1932.  
  1933.  
  1934. get_mpu_in:
  1935.  
  1936.         push    edx
  1937.         mov     dx, word [mididp]
  1938.         in      al, dx
  1939.         pop     edx
  1940.         ret
  1941.  
  1942.  
  1943. put_mpu_out:
  1944.  
  1945.         push    edx
  1946.         mov     dx, word [mididp]
  1947.         out     dx, al
  1948.         pop     edx
  1949.         ret
  1950.  
  1951.  
  1952.  
  1953. align 4
  1954.  
  1955. sys_midi:
  1956.         cmp     [mididp], 0
  1957.         jnz     sm0
  1958.         mov     [esp+36], dword 1
  1959.         ret
  1960. sm0:
  1961.         and     [esp+36], dword 0
  1962.         dec     ebx
  1963.         jnz     smn1
  1964.  ;    call setuart
  1965. su1:
  1966.         call    is_output
  1967.         test    al, al
  1968.         jnz     su1
  1969.         mov     dx, word [midisp]
  1970.         mov     al, 0xff
  1971.         out     dx, al
  1972. su2:
  1973.         mov     dx, word [midisp]
  1974.         mov     al, 0xff
  1975.         out     dx, al
  1976.         call    is_input
  1977.         test    al, al
  1978.         jnz     su2
  1979.         call    get_mpu_in
  1980.         cmp     al, 0xfe
  1981.         jnz     su2
  1982. su3:
  1983.         call    is_output
  1984.         test    al, al
  1985.         jnz     su3
  1986.         mov     dx, word [midisp]
  1987.         mov     al, 0x3f
  1988.         out     dx, al
  1989.         ret
  1990. smn1:
  1991.         dec     ebx
  1992.         jnz     smn2
  1993. sm10:
  1994.         call    get_mpu_in
  1995.         call    is_output
  1996.         test    al, al
  1997.         jnz     sm10
  1998.         mov     al, bl
  1999.         call    put_mpu_out
  2000.         smn2:
  2001.         ret
  2002.  
  2003. detect_devices:
  2004. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2005. ;include 'detect/commouse.inc'
  2006. ;include 'detect/ps2mouse.inc'
  2007. ;include 'detect/dev_fd.inc'
  2008. ;include 'detect/dev_hdcd.inc'
  2009. ;include 'detect/sear_par.inc'
  2010. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2011.         ret
  2012.  
  2013. sys_end:
  2014. ;--------------------------------------
  2015.         cmp     [_display.select_cursor], 0
  2016.         je      @f
  2017. ; restore default cursor before killing
  2018.         pusha
  2019.         mov     ecx, [current_slot]
  2020.         call    restore_default_cursor_before_killing
  2021.         popa
  2022. @@:
  2023. ;--------------------------------------
  2024. ; kill all sockets this process owns
  2025.         pusha
  2026.         mov     edx, [TASK_BASE]
  2027.         mov     edx, [edx+TASKDATA.pid]
  2028.         call    socket_process_end
  2029.         popa
  2030. ;--------------------------------------
  2031.         mov     ecx, [current_slot]
  2032.         mov     eax, [ecx+APPDATA.tls_base]
  2033.         test    eax, eax
  2034.         jz      @F
  2035.  
  2036.         stdcall user_free, eax
  2037. @@:
  2038.  
  2039.         mov     eax, [TASK_BASE]
  2040.         mov     [eax+TASKDATA.state], TSTATE_ZOMBIE
  2041.         call    wakeup_osloop
  2042.  
  2043. .waitterm:            ; wait here for termination
  2044.         call    change_task
  2045.         jmp     .waitterm
  2046. ;------------------------------------------------------------------------------
  2047. align 4
  2048. restore_default_cursor_before_killing:
  2049.         pushfd
  2050.         cli
  2051.         mov     eax, [def_cursor]
  2052.         mov     [ecx+APPDATA.cursor], eax
  2053.  
  2054.         movzx   eax, word [MOUSE_Y]
  2055.         movzx   ebx, word [MOUSE_X]
  2056.         mov     eax, [d_width_calc_area + eax*4]
  2057.  
  2058.         add     eax, [_display.win_map]
  2059.         movzx   edx, byte [ebx+eax]
  2060.         shl     edx, 8
  2061.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2062.  
  2063.         cmp     esi, [current_cursor]
  2064.         je      @f
  2065.  
  2066.         push    esi
  2067.         call    [_display.select_cursor]
  2068.         mov     [current_cursor], esi
  2069. @@:
  2070.         mov     [redrawmouse_unconditional], 1
  2071.         call    wakeup_osloop
  2072.         popfd
  2073.         ret
  2074. ;------------------------------------------------------------------------------
  2075. iglobal
  2076. align 4
  2077. sys_system_table:
  2078.         dd      sysfn_deactivate        ; 1 = deactivate window
  2079.         dd      sysfn_terminate         ; 2 = terminate thread
  2080.         dd      sysfn_activate          ; 3 = activate window
  2081.         dd      sysfn_getidletime       ; 4 = get idle time
  2082.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2083.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2084.         dd      sysfn_getactive         ; 7 = get active window
  2085.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2086.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2087.         dd      sysfn_minimize          ; 10 = minimize window
  2088.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2089.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2090.         dd      sysfn_getversion        ; 13 = get kernel version
  2091.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2092.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2093.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2094.         dd      sysfn_getallmem         ; 17 = get total memory size
  2095.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2096.                                         ;                 instead of slot
  2097.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2098.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2099.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2100.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2101.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2102.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2103.  
  2104.         dd      sysfn_zmodif            ; 25 = get/set window z modifier  ;Fantomer
  2105. sysfn_num = ($ - sys_system_table)/4
  2106. endg
  2107. ;------------------------------------------------------------------------------
  2108. sys_system:
  2109.         dec     ebx
  2110.         cmp     ebx, sysfn_num
  2111.         jae     @f
  2112.         jmp     dword [sys_system_table + ebx*4]
  2113. @@:
  2114.         ret
  2115. ;------------------------------------------------------------------------------
  2116. sysfn_shutdown:          ; 18.9 = system shutdown
  2117.         cmp     ecx, SYSTEM_SHUTDOWN
  2118.         jl      exit_for_anyone
  2119.         cmp     ecx, SYSTEM_RESTART
  2120.         jg      exit_for_anyone
  2121.         mov     [BOOT.shutdown_type], cl
  2122.  
  2123.         mov     eax, [TASK_COUNT]
  2124.         mov     [SYS_SHUTDOWN], al
  2125.         mov     [shutdown_processes], eax
  2126.         call    wakeup_osloop
  2127.         and     dword [esp+32], 0
  2128.  exit_for_anyone:
  2129.         ret
  2130.   uglobal
  2131.    shutdown_processes:
  2132.                        dd 0x0
  2133.   endg
  2134. ;------------------------------------------------------------------------------
  2135. sysfn_terminate:        ; 18.2 = TERMINATE
  2136.         push    ecx
  2137.         cmp     ecx, 2
  2138.         jb      noprocessterminate
  2139.         mov     edx, [TASK_COUNT]
  2140.         cmp     ecx, edx
  2141.         ja      noprocessterminate
  2142.         mov     eax, [TASK_COUNT]
  2143.         shl     ecx, 5
  2144.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2145.         add     ecx, CURRENT_TASK+TASKDATA.state
  2146.         cmp     byte [ecx], 9
  2147.         jz      noprocessterminate
  2148.         push    ecx edx
  2149.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2150.         call    request_terminate
  2151.         pop     edx ecx
  2152.         test    eax, eax
  2153.         jz      noprocessterminate
  2154. ;--------------------------------------
  2155. ; terminate all network sockets it used
  2156.         pusha
  2157.         mov     eax, edx
  2158.         call    socket_process_end
  2159.         popa
  2160. ;--------------------------------------
  2161.         cmp     [_display.select_cursor], 0
  2162.         je      .restore_end
  2163. ; restore default cursor before killing
  2164.         pusha
  2165.         mov     ecx, [esp+32]
  2166.         shl     ecx, 8
  2167.         add     ecx, SLOT_BASE
  2168.         mov     eax, [def_cursor]
  2169.         cmp     [ecx+APPDATA.cursor], eax
  2170.         je      @f
  2171.         call    restore_default_cursor_before_killing
  2172. @@:
  2173.         popa
  2174. .restore_end:
  2175. ;--------------------------------------
  2176.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2177.         mov     [ecx], byte 3; clear possible i40's
  2178.         call    wakeup_osloop
  2179.      ;call MEM_Heap_UnLock
  2180.  
  2181.         cmp     edx, [application_table_owner]; clear app table stat
  2182.         jne     noatsc
  2183.         call    unlock_application_table
  2184. noatsc:
  2185. noprocessterminate:
  2186.         add     esp, 4
  2187.         ret
  2188. ;------------------------------------------------------------------------------
  2189. sysfn_terminate2:
  2190. ;lock application_table_status mutex
  2191. .table_status:
  2192.         call    lock_application_table
  2193.         mov     eax, ecx
  2194.         call    pid_to_slot
  2195.         test    eax, eax
  2196.         jz      .not_found
  2197.         mov     ecx, eax
  2198.         cli
  2199.         call    sysfn_terminate
  2200.         call    unlock_application_table
  2201.         sti
  2202.         and     dword [esp+32], 0
  2203.         ret
  2204. .not_found:
  2205.         call    unlock_application_table
  2206.         or      dword [esp+32], -1
  2207.         ret
  2208. ;------------------------------------------------------------------------------
  2209. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2210.         cmp     ecx, 2
  2211.         jb      .nowindowdeactivate
  2212.         cmp     ecx, [TASK_COUNT]
  2213.         ja      .nowindowdeactivate
  2214.  
  2215.         movzx   esi, word [WIN_STACK + ecx*2]
  2216.         cmp     esi, 1
  2217.         je      .nowindowdeactivate ; already deactive
  2218.  
  2219.         mov     edi, ecx
  2220.         shl     edi, 5
  2221.         add     edi, window_data
  2222.         movzx   esi, word [WIN_STACK + ecx * 2]
  2223.         lea     esi, [WIN_POS + esi * 2]
  2224.         call    window._.window_deactivate
  2225.         call    syscall_display_settings.calculateScreen
  2226.         call    syscall_display_settings.redrawScreen
  2227. .nowindowdeactivate:
  2228.         ret
  2229. ;------------------------------------------------------------------------------
  2230. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2231.         cmp     ecx, 2
  2232.         jb      .nowindowactivate
  2233.         cmp     ecx, [TASK_COUNT]
  2234.         ja      .nowindowactivate
  2235. ;-------------------------------------
  2236. @@:
  2237. ; If the window is captured and moved by the user,
  2238. ; then you can't change the position in window stack!!!
  2239.         mov     al, [mouse.active_sys_window.action]
  2240.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2241.         test    al, al
  2242.         jz      @f
  2243.         call    change_task
  2244.         jmp     @b
  2245. @@:
  2246. ;-------------------------------------
  2247.         mov     [window_minimize], 2; restore window if minimized
  2248.         call    wakeup_osloop
  2249.  
  2250.         movzx   esi, word [WIN_STACK + ecx*2]
  2251.         cmp     esi, [TASK_COUNT]
  2252.         je      .nowindowactivate; already active
  2253.  
  2254.         mov     edi, ecx
  2255.         shl     edi, 5
  2256.         add     edi, window_data
  2257.         movzx   esi, word [WIN_STACK + ecx * 2]
  2258.         lea     esi, [WIN_POS + esi * 2]
  2259.         call    waredraw
  2260. .nowindowactivate:
  2261.         ret
  2262. ;------------------------------------------------------------------------------
  2263. align 4
  2264. sysfn_zmodif:
  2265. ;18,25,1 - get z_modif
  2266. ;18,25,2 - set z_modif
  2267. ;edx = -1(for current task) or TID
  2268. ;esi(for 2) = new value z_modif
  2269. ;return:
  2270. ;1:   eax = z_modif
  2271. ;2: eax=0(fail),1(success) for set z_modif
  2272.  
  2273.         cmp     edx, -1
  2274.         jne     @f
  2275.         mov     edx, [CURRENT_TASK]
  2276.      @@:
  2277.         cmp     edx, [TASK_COUNT]
  2278.         ja      .fail
  2279.         cmp     edx, 1
  2280.         je      .fail
  2281.  
  2282.         mov     eax, edx
  2283.         shl     edx, 5
  2284.  
  2285.         cmp     [edx + CURRENT_TASK + TASKDATA.state], 9
  2286.         je      .fail
  2287.  
  2288.         cmp     ecx, 1
  2289.         jnz     .set_zmod
  2290.  
  2291.         mov     al, [edx + window_data + WDATA.z_modif]
  2292.         jmp     .exit
  2293.  
  2294. .set_zmod:
  2295.         cmp     ecx, 2
  2296.         jnz     .fail
  2297.  
  2298.         mov     ebx, esi
  2299.         mov     esi, eax
  2300.  
  2301.         cmp     bl, ZPOS_ALWAYS_TOP
  2302.         jg      .fail
  2303.  
  2304.         mov     [edx + window_data + WDATA.z_modif], bl
  2305.  
  2306.         mov     eax, [edx + window_data + WDATA.box.left]
  2307.         mov     ebx, [edx + window_data + WDATA.box.top]
  2308.         mov     ecx, [edx + window_data + WDATA.box.width]
  2309.         mov     edx, [edx + window_data + WDATA.box.height]
  2310.         add     ecx, eax
  2311.         add     edx, ebx
  2312.         call    window._.set_screen
  2313.         call    window._.set_top_wnd
  2314.         call    window._.redraw_top_wnd
  2315.  
  2316.         shl     esi, 5
  2317.         mov     [esi + window_data + WDATA.fl_redraw], 1
  2318.  
  2319.  
  2320.         mov     eax, 1
  2321.         jmp     .exit
  2322. .fail:
  2323.         xor     eax, eax
  2324. .exit:
  2325.         mov     [esp+32], eax
  2326.         ret
  2327.  
  2328. ;------------------------------------------------------------------------------
  2329. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2330.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2331.         mov     [esp+32], eax
  2332.         ret
  2333. ;------------------------------------------------------------------------------
  2334. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2335.         mov     eax, dword [cpu_freq]
  2336.         mov     [esp+32], eax
  2337.         ret
  2338. ;------------------------------------------------------------------------------
  2339. get_cpu_freq:
  2340.         mov     eax, dword [cpu_freq]
  2341.         mov     edx, dword [cpu_freq+4]
  2342.         ret
  2343. ;  SAVE ramdisk to /hd/1/menuet.img
  2344. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2345.    include 'blkdev/rdsave.inc'
  2346. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2347. ;------------------------------------------------------------------------------
  2348. align 4
  2349. sysfn_getactive:        ; 18.7 = get active window
  2350.         mov     eax, [TASK_COUNT]
  2351.         movzx   eax, word [WIN_POS + eax*2]
  2352.         mov     [esp+32], eax
  2353.         ret
  2354. ;------------------------------------------------------------------------------
  2355. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2356. ;     cmp  ecx,1
  2357.         dec     ecx
  2358.         jnz     nogetsoundflag
  2359.         movzx   eax, byte [sound_flag]; get sound_flag
  2360.         mov     [esp+32], eax
  2361.         ret
  2362.  nogetsoundflag:
  2363. ;     cmp  ecx,2
  2364.         dec     ecx
  2365.         jnz     nosoundflag
  2366.         xor     byte [sound_flag], 1
  2367.  nosoundflag:
  2368.         ret
  2369. ;------------------------------------------------------------------------------
  2370. sysfn_minimize:         ; 18.10 = minimize window
  2371.         mov     [window_minimize], 1
  2372.         call    wakeup_osloop
  2373.         ret
  2374. ;------------------------------------------------------------------------------
  2375. align 4
  2376. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2377.         dec     ecx
  2378.         jnz     .exit
  2379. .small_table:
  2380.         mov     edi, edx
  2381.         mov     esi, DRIVE_DATA
  2382.         mov     ecx, DRIVE_DATA_SIZE ;10
  2383.         cld
  2384.         rep movsb
  2385. .exit:
  2386.         ret
  2387. ;------------------------------------------------------------------------------
  2388. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2389.         and     dword [esp+32], 0
  2390.         ret
  2391. ;------------------------------------------------------------------------------
  2392. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2393.         mov     edi, ecx
  2394.         mov     esi, version_inf
  2395.         mov     ecx, version_end-version_inf
  2396.         rep movsb
  2397.         ret
  2398. ;------------------------------------------------------------------------------
  2399. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2400.      ;wait retrace functions
  2401.  sys_wait_retrace:
  2402.         mov     edx, 0x3da
  2403.  WaitRetrace_loop:
  2404.         in      al, dx
  2405.         test    al, 1000b
  2406.         jz      WaitRetrace_loop
  2407.         and     [esp+32], dword 0
  2408.         ret
  2409. ;------------------------------------------------------------------------------
  2410. align 4
  2411. sysfn_centermouse:      ; 18.15 = mouse centered
  2412.         mov     eax, [_display.width]
  2413.         shr     eax, 1
  2414.         mov     [MOUSE_X], ax
  2415.         mov     eax, [_display.height]
  2416.         shr     eax, 1
  2417.         mov     [MOUSE_Y], ax
  2418.         call    wakeup_osloop
  2419.         xor     eax, eax
  2420.         and     [esp+32], eax
  2421.         ret
  2422. ;------------------------------------------------------------------------------
  2423. sysfn_mouse_acceleration:       ; 18.19 = set/get mouse features
  2424.         cmp     ecx, 8
  2425.         jnc     @f
  2426.         jmp     dword [.table+ecx*4]
  2427. .get_mouse_acceleration:
  2428.         xor     eax, eax
  2429.         mov     ax, [mouse_speed_factor]
  2430.         mov     [esp+32], eax
  2431.         ret
  2432. .set_mouse_acceleration:
  2433.         mov     [mouse_speed_factor], dx
  2434.         ret
  2435. .get_mouse_delay:
  2436.         xor     eax, eax
  2437.         mov     al, [mouse_delay]
  2438.         mov     [esp+32], eax
  2439.         ret
  2440. .set_mouse_delay:
  2441.         mov     [mouse_delay], dl
  2442. @@:
  2443.         ret
  2444. .set_pointer_position:
  2445.         cmp     dx, word[_display.height]
  2446.         jae     @b
  2447.         rol     edx, 16
  2448.         cmp     dx, word[_display.width]
  2449.         jae     @b
  2450.         mov     [MOUSE_X], edx
  2451.         mov     [mouse_active], 1
  2452.         jmp     wakeup_osloop
  2453. .set_mouse_button:
  2454.         mov     [BTN_DOWN], edx
  2455.         mov     [mouse_active], 1
  2456.         jmp     wakeup_osloop
  2457. .get_doubleclick_delay:
  2458.         xor     eax, eax
  2459.         mov     al, [mouse_doubleclick_delay]
  2460.         mov     [esp+32], eax
  2461.         ret
  2462. .set_doubleclick_delay:
  2463.         mov     [mouse_doubleclick_delay], dl
  2464.         ret
  2465. align 4
  2466. .table:
  2467. dd      .get_mouse_acceleration
  2468. dd      .set_mouse_acceleration
  2469. dd      .get_mouse_delay
  2470. dd      .set_mouse_delay
  2471. dd      .set_pointer_position
  2472. dd      .set_mouse_button
  2473. dd      .get_doubleclick_delay
  2474. dd      .set_doubleclick_delay
  2475. ;------------------------------------------------------------------------------
  2476. sysfn_getfreemem:
  2477.         mov     eax, [pg_data.pages_free]
  2478.         shl     eax, 2
  2479.         mov     [esp+32], eax
  2480.         ret
  2481. ;------------------------------------------------------------------------------
  2482. sysfn_getallmem:
  2483.         mov     eax, [MEM_AMOUNT]
  2484.         shr     eax, 10
  2485.         mov     [esp+32], eax
  2486.         ret
  2487. ;------------------------------------------------------------------------------
  2488. sysfn_pid_to_slot:
  2489.         mov     eax, ecx
  2490.         call    pid_to_slot
  2491.         mov     [esp+32], eax
  2492.         ret
  2493. ;------------------------------------------------------------------------------
  2494. sysfn_min_rest_window:
  2495.         pushad
  2496.         mov     eax, edx ; ebx - operating
  2497.         shr     ecx, 1
  2498.         jnc     @f
  2499.         call    pid_to_slot
  2500. @@:
  2501.         or      eax, eax ; eax - number of slot
  2502.         jz      .error
  2503.         cmp     eax, 255    ; varify maximal slot number
  2504.         ja      .error
  2505.         movzx   eax, word [WIN_STACK + eax*2]
  2506.         shr     ecx, 1
  2507.         jc      .restore
  2508.  ; .minimize:
  2509.         call    minimize_window
  2510.         jmp     .exit
  2511. .restore:
  2512.         call    restore_minimized_window
  2513. .exit:
  2514.         popad
  2515.         xor     eax, eax
  2516.         mov     [esp+32], eax
  2517.         ret
  2518. .error:
  2519.         popad
  2520.         xor     eax, eax
  2521.         dec     eax
  2522.         mov     [esp+32], eax
  2523.         ret
  2524. ;------------------------------------------------------------------------------
  2525. sysfn_min_windows:
  2526.         call    minimize_all_window
  2527.         mov     [esp+32], eax
  2528.         call    change_task
  2529.         ret
  2530. ;------------------------------------------------------------------------------
  2531. sysfn_set_screen_sizes:
  2532.         cmp     [SCR_MODE], word 0x13
  2533.         jbe     .exit
  2534.  
  2535.         cmp     [_display.select_cursor], select_cursor
  2536.         jne     .exit
  2537.  
  2538.         cmp     ecx, [display_width_standard]
  2539.         ja      .exit
  2540.  
  2541.         cmp     edx, [display_height_standard]
  2542.         ja      .exit
  2543.  
  2544.         pushfd
  2545.         cli
  2546.         mov     eax, ecx
  2547.         mov     ecx, [_display.lfb_pitch]
  2548.         mov     [_display.width], eax
  2549.         dec     eax
  2550.         mov     [_display.height], edx
  2551.         dec     edx
  2552. ; eax - new Screen_Max_X
  2553. ; edx - new Screen_Max_Y
  2554.         mov     [do_not_touch_winmap], 1
  2555.         call    set_screen
  2556.         mov     [do_not_touch_winmap], 0
  2557.         popfd
  2558.         call    change_task
  2559. .exit:
  2560.         ret
  2561. ;------------------------------------------------------------------------------
  2562. uglobal
  2563. screen_workarea RECT
  2564. display_width_standard dd 0
  2565. display_height_standard dd 0
  2566. do_not_touch_winmap db 0
  2567. window_minimize db 0
  2568. sound_flag      db 0
  2569.  
  2570. endg
  2571.  
  2572. UID_NONE=0
  2573. UID_MENUETOS=1   ;official
  2574. UID_KOLIBRI=2    ;russian
  2575.  
  2576. iglobal
  2577. version_inf:
  2578.         db 0,7,7,0  ; version 0.7.7.0
  2579.         db 0
  2580. .rev    dd __REV__
  2581. version_end:
  2582. endg
  2583. ;------------------------------------------------------------------------------
  2584. align 4
  2585. sys_cachetodiskette:
  2586.         cmp     ebx, 1
  2587.         jb      .no_floppy_save
  2588.         cmp     ebx, 2
  2589.         ja      .no_floppy_save
  2590.         call    save_image
  2591.         mov     [esp + 32], eax
  2592.         ret
  2593. .no_floppy_save:
  2594.         mov     [esp + 32], dword 1
  2595.         ret
  2596. ;------------------------------------------------------------------------------
  2597. uglobal
  2598. ;  bgrchanged  dd  0x0
  2599. align 4
  2600. bgrlockpid dd 0
  2601. bgrlock db 0
  2602. endg
  2603. ;------------------------------------------------------------------------------
  2604. align 4
  2605. sys_background:
  2606.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2607.         jnz     nosb1
  2608.         test    ecx, ecx
  2609.         jz      sbgrr
  2610.  
  2611.         test    edx, edx
  2612.         jz      sbgrr
  2613. ;--------------------------------------
  2614. align 4
  2615. @@:
  2616. ;;Maxis use atomic bts for mutexes  4.4.2009
  2617.         bts     dword [bgrlock], 0
  2618.         jnc     @f
  2619.         call    change_task
  2620.         jmp     @b
  2621. ;--------------------------------------
  2622. align 4
  2623. @@:
  2624.         mov     [BgrDataWidth], ecx
  2625.         mov     [BgrDataHeight], edx
  2626. ;    mov   [bgrchanged],1
  2627.  
  2628.         pushad
  2629. ; return memory for old background
  2630.         mov     eax, [img_background]
  2631.         cmp     eax, static_background_data
  2632.         jz      @f
  2633.         stdcall kernel_free, eax
  2634. ;--------------------------------------
  2635. align 4
  2636. @@:
  2637. ; calculate RAW size
  2638.         xor     eax, eax
  2639.         inc     eax
  2640.         cmp     [BgrDataWidth], eax
  2641.         jae     @f
  2642.         mov     [BgrDataWidth], eax
  2643. ;--------------------------------------
  2644. align 4
  2645. @@:
  2646.         cmp     [BgrDataHeight], eax
  2647.         jae     @f
  2648.         mov     [BgrDataHeight], eax
  2649. ;--------------------------------------
  2650. align 4
  2651. @@:
  2652.         mov     eax, [BgrDataWidth]
  2653.         imul    eax, [BgrDataHeight]
  2654.         lea     eax, [eax*3]
  2655. ; it is reserved with aligned to the boundary of 4 KB pages,
  2656. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2657. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2658.         shr     eax, 12
  2659.         inc     eax
  2660.         shl     eax, 12
  2661.         mov     [mem_BACKGROUND], eax
  2662. ; get memory for new background
  2663.         stdcall kernel_alloc, eax
  2664.         test    eax, eax
  2665.         jz      .memfailed
  2666.         mov     [img_background], eax
  2667.         jmp     .exit
  2668. ;--------------------------------------
  2669. align 4
  2670. .memfailed:
  2671. ; revert to static monotone data
  2672.         mov     [img_background], static_background_data
  2673.         xor     eax, eax
  2674.         inc     eax
  2675.         mov     [BgrDataWidth], eax
  2676.         mov     [BgrDataHeight], eax
  2677.         mov     [mem_BACKGROUND], 4
  2678. ;--------------------------------------
  2679. align 4
  2680. .exit:
  2681.         popad
  2682.         mov     [bgrlock], 0
  2683. ;--------------------------------------
  2684. align 4
  2685. sbgrr:
  2686.         ret
  2687. ;------------------------------------------------------------------------------
  2688. align 4
  2689. nosb1:
  2690.         cmp     ebx, 2                     ; SET PIXEL
  2691.         jnz     nosb2
  2692.  
  2693.         mov     eax, [img_background]
  2694.         test    ecx, ecx
  2695.         jz      @f
  2696.         cmp     eax, static_background_data
  2697.         jz      .ret
  2698. ;--------------------------------------
  2699. align 4
  2700. @@:
  2701.         mov     ebx, [mem_BACKGROUND]
  2702.         add     ebx, 4095
  2703.         and     ebx, -4096
  2704.         sub     ebx, 4
  2705.         cmp     ecx, ebx
  2706.         ja      .ret
  2707.  
  2708.         mov     ebx, [eax+ecx]
  2709.         and     ebx, 0xFF000000;255*256*256*256
  2710.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2711.         add     edx, ebx
  2712.         mov     [eax+ecx], edx
  2713. ;--------------------------------------
  2714. align 4
  2715. .ret:
  2716.         ret
  2717. ;------------------------------------------------------------------------------
  2718. align 4
  2719. nosb2:
  2720.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2721.         jnz     nosb3
  2722. ;--------------------------------------
  2723. align 4
  2724. draw_background_temp:
  2725.         mov     [background_defined], 1
  2726.         call    force_redraw_background
  2727. ;--------------------------------------
  2728. align 4
  2729. nosb31:
  2730.         ret
  2731. ;------------------------------------------------------------------------------
  2732. align 4
  2733. nosb3:
  2734.         cmp     ebx, 4                     ; TILED / STRETCHED
  2735.         jnz     nosb4
  2736.         cmp     ecx, [BgrDrawMode]
  2737.         je      nosb41
  2738.         mov     [BgrDrawMode], ecx
  2739. ;--------------------------------------
  2740. align 4
  2741. nosb41:
  2742.         ret
  2743. ;------------------------------------------------------------------------------
  2744. align 4
  2745. nosb4:
  2746.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2747.         jnz     nosb5
  2748.         cmp     [img_background], static_background_data
  2749.         jnz     @f
  2750.         test    edx, edx
  2751.         jnz     .fin
  2752.         cmp     esi, 4
  2753.         ja      .fin
  2754. ;--------------------------------------
  2755. align 4
  2756. @@:
  2757.   ; bughere
  2758.         mov     eax, ecx
  2759.         mov     ebx, edx
  2760.         add     ebx, [img_background];IMG_BACKGROUND
  2761.         mov     ecx, esi
  2762.         call    memmove
  2763. ;--------------------------------------
  2764. align 4
  2765. .fin:
  2766.         ret
  2767. ;------------------------------------------------------------------------------
  2768. align 4
  2769. nosb5:
  2770.         cmp     ebx, 6
  2771.         jnz     nosb6
  2772. ;--------------------------------------
  2773. align 4
  2774. ;;Maxis use atomic bts for mutex 4.4.2009
  2775. @@:
  2776.         bts     dword [bgrlock], 0
  2777.         jnc     @f
  2778.         call    change_task
  2779.         jmp     @b
  2780. ;--------------------------------------
  2781. align 4
  2782. @@:
  2783.         mov     eax, [CURRENT_TASK]
  2784.         mov     [bgrlockpid], eax
  2785.         cmp     [img_background], static_background_data
  2786.         jz      .nomem
  2787.         stdcall user_alloc, [mem_BACKGROUND]
  2788.         mov     [esp+32], eax
  2789.         test    eax, eax
  2790.         jz      .nomem
  2791.         mov     ebx, eax
  2792.         shr     ebx, 12
  2793.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2794.         mov     esi, [img_background]
  2795.         shr     esi, 12
  2796.         mov     ecx, [mem_BACKGROUND]
  2797.         add     ecx, 0xFFF
  2798.         shr     ecx, 12
  2799. ;--------------------------------------
  2800. align 4
  2801. .z:
  2802.         mov     eax, [page_tabs+ebx*4]
  2803.         test    al, 1
  2804.         jz      @f
  2805.         call    free_page
  2806. ;--------------------------------------
  2807. align 4
  2808. @@:
  2809.         mov     eax, [page_tabs+esi*4]
  2810.         or      al, PG_UWR
  2811.         mov     [page_tabs+ebx*4], eax
  2812.         mov     eax, ebx
  2813.         shl     eax, 12
  2814.         invlpg  [eax]
  2815.         inc     ebx
  2816.         inc     esi
  2817.         loop    .z
  2818.         ret
  2819. ;--------------------------------------
  2820. align 4
  2821. .nomem:
  2822.         and     [bgrlockpid], 0
  2823.         mov     [bgrlock], 0
  2824. ;------------------------------------------------------------------------------
  2825. align 4
  2826. nosb6:
  2827.         cmp     ebx, 7
  2828.         jnz     nosb7
  2829.         cmp     [bgrlock], 0
  2830.         jz      .err
  2831.         mov     eax, [CURRENT_TASK]
  2832.         cmp     [bgrlockpid], eax
  2833.         jnz     .err
  2834.         mov     eax, ecx
  2835.         mov     ebx, ecx
  2836.         shr     eax, 12
  2837.         mov     ecx, [page_tabs+(eax-1)*4]
  2838.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2839.         jz      .err
  2840.         jnp     .err
  2841.         push    eax
  2842.         shr     ecx, 12
  2843.         dec     ecx
  2844. ;--------------------------------------
  2845. align 4
  2846. @@:
  2847.         and     dword [page_tabs+eax*4], 0
  2848.         mov     edx, eax
  2849.         shl     edx, 12
  2850.         push    eax
  2851.         invlpg  [edx]
  2852.         pop     eax
  2853.         inc     eax
  2854.         loop    @b
  2855.         pop     eax
  2856.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2857.         stdcall user_free, ebx
  2858.         mov     [esp+32], eax
  2859.         and     [bgrlockpid], 0
  2860.         mov     [bgrlock], 0
  2861.         ret
  2862. ;--------------------------------------
  2863. align 4
  2864. .err:
  2865.         and     dword [esp+32], 0
  2866.         ret
  2867. ;------------------------------------------------------------------------------
  2868. align 4
  2869. nosb7:
  2870.         cmp     ebx, 8
  2871.         jnz     nosb8
  2872.  
  2873.         mov     ecx, [current_slot]
  2874.         xor     eax, eax
  2875.         xchg    eax, [ecx+APPDATA.draw_bgr_x]
  2876.         mov     [esp + 32], eax ; eax = [left]*65536 + [right]
  2877.         xor     eax, eax
  2878.         xchg    eax, [ecx+APPDATA.draw_bgr_y]
  2879.         mov     [esp + 20], eax ; ebx = [top]*65536 + [bottom]
  2880.         ret
  2881. ;------------------------------------------------------------------------------
  2882. align 4
  2883. nosb8:
  2884.         cmp     ebx, 9
  2885.         jnz     nosb9
  2886. ; ecx = [left]*65536 + [right]
  2887. ; edx = [top]*65536 + [bottom]
  2888.         mov     eax, [_display.width]
  2889.