Subversion Repositories Kolibri OS

Rev

Rev 5794 | Rev 5851 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2015. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 5836 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_hpet
  287.         call    init_BIOS32
  288. ; MEMORY MODEL
  289.         call    mem_test
  290.         call    init_mem
  291.         call    init_page_map
  292.  
  293. ; ENABLE PAGING
  294.  
  295.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  296.         mov     cr3, eax
  297.  
  298.         mov     eax, cr0
  299.         or      eax, CR0_PG+CR0_WP
  300.         mov     cr0, eax
  301.  
  302.         lgdt    [gdts]
  303.         jmp     pword os_code:high_code
  304.  
  305. align 4
  306. bios32_entry    dd ?
  307. tmp_page_tabs   dd ?
  308.  
  309. use16
  310. org $-0x10000
  311. include "boot/shutdown.inc" ; shutdown or restart
  312. org $+0x10000
  313.  
  314. ap_init16:
  315.         cli
  316.         lgdt    [cs:gdts_ap-ap_init16]
  317.         mov     eax, [cs:cr3_ap-ap_init16]
  318.         mov     cr3, eax
  319.         mov     eax, [cs:cr4_ap-ap_init16]
  320.         mov     cr4, eax
  321.         mov     eax, CR0_PE+CR0_PG+CR0_WP
  322.         mov     cr0, eax
  323.         jmp     pword os_code:ap_init_high
  324. align 16
  325. gdts_ap:
  326.         dw     gdte-gdts-1
  327.         dd     gdts
  328.         dw     0
  329. cr3_ap  dd     ?
  330. cr4_ap  dd     ?
  331. ap_init16_size = $ - ap_init16
  332. use32
  333.  
  334. __DEBUG__ fix 1
  335. __DEBUG_LEVEL__ fix 1
  336. include 'init.inc'
  337.  
  338. org OS_BASE+$
  339.  
  340. include 'fdo.inc'
  341.  
  342. align 4
  343. high_code:
  344.         mov     ax, os_stack
  345.         mov     bx, app_data
  346.         mov     cx, app_tls
  347.         mov     ss, ax
  348.         add     esp, OS_BASE
  349.  
  350.         mov     ds, bx
  351.         mov     es, bx
  352.         mov     fs, cx
  353.         mov     gs, bx
  354.  
  355.         xor     eax, eax
  356.         mov     ebx, 0xFFFFF000+PG_SHARED+PG_NOCACHE+PG_UWR
  357.         bt      [cpu_caps], CAPS_PAT
  358.         setc    al
  359.         shl     eax, 7
  360.         or      ebx, eax
  361.  
  362.         mov     eax, PG_GLOBAL
  363.         bt      [cpu_caps], CAPS_PGE
  364.         jnc     @F
  365.  
  366.         or      [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], eax
  367.         or      ebx, eax
  368.  
  369.         mov     eax, cr4
  370.         or      eax, CR4_PGE
  371.         mov     cr4, eax
  372. @@:
  373.         mov     [pte_valid_mask], ebx
  374.  
  375.         xor     eax, eax
  376.         mov     dword [sys_proc+PROC.pdt_0], eax
  377.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  378.  
  379.         mov     eax, cr3
  380.         mov     cr3, eax          ; flush TLB
  381.  
  382.         mov     ecx, pg_data.mutex
  383.         call    mutex_init
  384.  
  385.         mov     ecx, disk_list_mutex
  386.         call    mutex_init
  387.  
  388.         mov     ecx, keyboard_list_mutex
  389.         call    mutex_init
  390.  
  391.         mov     ecx, unpack_mutex
  392.         call    mutex_init
  393.  
  394.         mov     ecx, application_table_mutex
  395.         call    mutex_init
  396.  
  397.         mov     ecx, ide_mutex
  398.         call    mutex_init
  399.         mov     ecx, ide_channel1_mutex
  400.         call    mutex_init
  401.         mov     ecx, ide_channel2_mutex
  402.         call    mutex_init
  403.         mov     ecx, ide_channel3_mutex
  404.         call    mutex_init
  405.         mov     ecx, ide_channel4_mutex
  406.         call    mutex_init
  407.         mov     ecx, ide_channel5_mutex
  408.         call    mutex_init
  409.         mov     ecx, ide_channel6_mutex
  410.         call    mutex_init
  411. ;-----------------------------------------------------------------------------
  412. ; SAVE REAL MODE VARIABLES
  413. ;-----------------------------------------------------------------------------
  414. ; --------------- APM ---------------------
  415.  
  416. ; init selectors
  417.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  418.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  419.                                                                                 ; protected-mode 32-bit code segment
  420.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  421.                                                                                 ; protected-mode 16-bit code segment
  422.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  423.                                                                                 ; protected-mode 16-bit data segment
  424.  
  425.         shl     eax, 4
  426.         mov     [dword apm_code_32 + 2], ax
  427.         shr     eax, 16
  428.         mov     [dword apm_code_32 + 4], al
  429.  
  430.         shl     ecx, 4
  431.         mov     [dword apm_code_16 + 2], cx
  432.         shr     ecx, 16
  433.         mov     [dword apm_code_16 + 4], cl
  434.  
  435.         shl     edx, 4
  436.         mov     [dword apm_data_16 + 2], dx
  437.         shr     edx, 16
  438.         mov     [dword apm_data_16 + 4], dl
  439.  
  440.         mov     dword[apm_entry], ebx
  441.         mov     word [apm_entry + 4], apm_code_32 - gdts
  442.  
  443.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  444.         mov     [apm_vf], eax
  445. ; -----------------------------------------
  446.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  447.         mov     [allow_dma_access], al
  448.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  449.         mov     [_display.bits_per_pixel], eax
  450.         mov     [_display.vrefresh], 60
  451.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  452.         mov     [debug_direct_print], al
  453.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  454.         mov     [launcher_start], al
  455.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  456.         mov     [_display.width], eax
  457.         mov     [display_width_standard], eax
  458.         dec     eax
  459.         mov     [screen_workarea.right], eax
  460.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  461.         mov     [_display.height], eax
  462.         mov     [display_height_standard], eax
  463.         dec     eax
  464.         mov     [screen_workarea.bottom], eax
  465.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  466.         mov     dword [SCR_MODE], eax
  467. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  468. ;        mov     [BANK_SWITCH], eax
  469.         mov     eax, 640 *4                         ; Bytes PerScanLine
  470.         cmp     [SCR_MODE], word 0x13               ; 320x200
  471.         je      @f
  472.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  473.         je      @f
  474.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  475. @@:
  476.         mov     [_display.lfb_pitch], eax
  477.         mov     eax, [_display.width]
  478.         mul     [_display.height]
  479.         mov     [_display.win_map_size], eax
  480.  
  481.         call    calculate_fast_getting_offset_for_WinMapAddress
  482. ; for Qemu or non standart video cards
  483. ; Unfortunately [BytesPerScanLine] does not always
  484. ;                             equal to [_display.width] * [ScreenBPP] / 8
  485.         call    calculate_fast_getting_offset_for_LFB
  486.  
  487.         mov     esi, BOOT_VARS+0x9080
  488.         movzx   ecx, byte [esi-1]
  489.         mov     [NumBiosDisks], ecx
  490.         mov     edi, BiosDisksData
  491.         rep movsd
  492.  
  493. setvideomode:
  494.  
  495.         mov     eax, [BOOT_VARS+BOOT_LFB]
  496.         mov     [LFBAddress], eax
  497.  
  498.         cmp     word [SCR_MODE], 0x0012                 ; VGA (640x480 16 colors)
  499.         je      .vga
  500.         cmp     word [SCR_MODE], 0x0013                 ; MCGA (320*200 256 colors)
  501.         je      .32bpp
  502.         cmp     byte [_display.bits_per_pixel], 32
  503.         je      .32bpp
  504.         cmp     byte [_display.bits_per_pixel], 24
  505.         je      .24bpp
  506.         cmp     byte [_display.bits_per_pixel], 16
  507.         je      .16bpp
  508. ;        cmp     byte [_display.bits_per_pixel], 15
  509. ;        je      .15bpp
  510.  
  511.   .vga:
  512.         mov     [PUTPIXEL], VGA_putpixel
  513.         mov     [GETPIXEL], Vesa20_getpixel32           ; Conversion buffer is 32 bpp
  514.         mov     [_display.bytes_per_pixel], 4           ; Conversion buffer is 32 bpp
  515.         jmp     .finish
  516.  
  517. ;  .15bpp:
  518. ;        mov     [PUTPIXEL], Vesa20_putpixel15
  519. ;        mov     [GETPIXEL], Vesa20_getpixel15
  520. ;        mov     [_display.bytes_per_pixel], 2
  521. ;        jmp     .finish
  522.  
  523.   .16bpp:
  524.         mov     [PUTPIXEL], Vesa20_putpixel16
  525.         mov     [GETPIXEL], Vesa20_getpixel16
  526.         mov     [_display.bytes_per_pixel], 2
  527.         jmp     .finish
  528.  
  529.   .24bpp:
  530.         mov     [PUTPIXEL], Vesa20_putpixel24
  531.         mov     [GETPIXEL], Vesa20_getpixel24
  532.         mov     [_display.bytes_per_pixel], 3
  533.         jmp     .finish
  534.  
  535.   .32bpp:
  536.         mov     [PUTPIXEL], Vesa20_putpixel32
  537.         mov     [GETPIXEL], Vesa20_getpixel32
  538.         mov     [_display.bytes_per_pixel], 4
  539. ;        jmp     .finish
  540.  
  541.   .finish:
  542.         mov     [MOUSE_PICTURE], mousepointer
  543.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  544.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  545.  
  546. ; -------- Fast System Call init ----------
  547. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  548.         bt      [cpu_caps], CAPS_SEP
  549.         jnc     .SEnP  ; SysEnter not Present
  550.         xor     edx, edx
  551.         mov     ecx, MSR_SYSENTER_CS
  552.         mov     eax, os_code
  553.         wrmsr
  554.         mov     ecx, MSR_SYSENTER_ESP
  555. ;           mov eax, sysenter_stack ; Check it
  556.         xor     eax, eax
  557.         wrmsr
  558.         mov     ecx, MSR_SYSENTER_EIP
  559.         mov     eax, sysenter_entry
  560.         wrmsr
  561. .SEnP:
  562. ; AMD SYSCALL/SYSRET
  563.         cmp     byte[cpu_vendor], 'A'
  564.         jne     .noSYSCALL
  565.         mov     eax, 0x80000001
  566.         cpuid
  567.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  568.         jz      .noSYSCALL
  569.         mov     ecx, MSR_AMD_EFER
  570.         rdmsr
  571.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  572.         wrmsr
  573.  
  574.         ; !!!! It`s dirty hack, fix it !!!
  575.         ; Bits of EDX :
  576.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  577.         ;  and the contents of this field, plus 8, are copied into the SS register.
  578.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  579.         ;  and the contents of this field, plus 8, are copied into the SS register.
  580.  
  581.         ; mov   edx, (os_code + 16) * 65536 + os_code
  582.         mov     edx, 0x1B0008
  583.  
  584.         mov     eax, syscall_entry
  585.         mov     ecx, MSR_AMD_STAR
  586.         wrmsr
  587. .noSYSCALL:
  588. ; -----------------------------------------
  589.         stdcall alloc_page
  590.         stdcall map_page, tss-0xF80, eax, PG_SWR
  591.         stdcall alloc_page
  592.         stdcall map_page, tss+0x80, eax, PG_SWR
  593.         stdcall alloc_page
  594.         stdcall map_page, tss+0x1080, eax, PG_SWR
  595.  
  596. ; LOAD IDT
  597.  
  598.         call    build_interrupt_table ;lidt is executed
  599.           ;lidt [idtreg]
  600.  
  601.         call    init_kernel_heap
  602.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  603.         mov     [os_stack_seg], eax
  604.  
  605.         lea     esp, [eax+RING0_STACK_SIZE]
  606.  
  607.         mov     [tss._ss0], os_stack
  608.         mov     [tss._esp0], esp
  609.         mov     [tss._esp], esp
  610.         mov     [tss._cs], os_code
  611.         mov     [tss._ss], os_stack
  612.         mov     [tss._ds], app_data
  613.         mov     [tss._es], app_data
  614.         mov     [tss._fs], app_data
  615.         mov     [tss._gs], app_data
  616.         mov     [tss._io], 128
  617. ;Add IO access table - bit array of permitted ports
  618.         mov     edi, tss._io_map_0
  619.         xor     eax, eax
  620.         not     eax
  621.         mov     ecx, 8192/4
  622.         rep stosd                    ; access to 4096*8=65536 ports
  623.  
  624.         mov     ax, tss0
  625.         ltr     ax
  626.  
  627.         mov     [LFBSize], 0xC00000
  628.         call    init_LFB
  629.         call    init_fpu
  630.         call    init_malloc
  631.  
  632.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  633.         mov     [default_io_map], eax
  634.  
  635.         add     eax, 0x2000
  636.         mov     [ipc_tmp], eax
  637.         mov     ebx, 0x1000
  638.  
  639.         add     eax, 0x40000
  640.         mov     [proc_mem_map], eax
  641.  
  642.         add     eax, 0x8000
  643.         mov     [proc_mem_pdir], eax
  644.  
  645.         add     eax, ebx
  646.         mov     [proc_mem_tab], eax
  647.  
  648.         add     eax, ebx
  649.         mov     [tmp_task_ptab], eax
  650.  
  651.         add     eax, ebx
  652.         mov     [ipc_pdir], eax
  653.  
  654.         add     eax, ebx
  655.         mov     [ipc_ptab], eax
  656.  
  657.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  658.                 (unpack.lc+unpack.lp)))*4
  659.  
  660.         mov     [unpack.p], eax
  661.  
  662.         call    init_events
  663.         mov     eax, srv.fd-SRV.fd
  664.         mov     [srv.fd], eax
  665.         mov     [srv.bk], eax
  666.  
  667. ;Set base of graphic segment to linear address of LFB
  668.         mov     eax, [LFBAddress]         ; set for gs
  669.         mov     [graph_data_l+2], ax
  670.         shr     eax, 16
  671.         mov     [graph_data_l+4], al
  672.         mov     [graph_data_l+7], ah
  673.  
  674.         stdcall kernel_alloc, [_display.win_map_size]
  675.         mov     [_display.win_map], eax
  676.  
  677.         xor     eax, eax
  678.         inc     eax
  679.  
  680. ; set background
  681.  
  682.         mov     [BgrDrawMode], eax
  683.         mov     [BgrDataWidth], eax
  684.         mov     [BgrDataHeight], eax
  685.         mov     [mem_BACKGROUND], 4
  686.         mov     [img_background], static_background_data
  687.  
  688. ; set clipboard
  689.  
  690.         xor     eax, eax
  691.         mov     [clipboard_slots], eax
  692.         mov     [clipboard_write_lock], eax
  693.         stdcall kernel_alloc, 4096
  694.         test    eax, eax
  695.         jnz     @f
  696.  
  697.         dec     eax
  698. @@:
  699.         mov     [clipboard_main_list], eax
  700.  
  701.         mov     eax, [hpet_base]
  702.         test    eax, eax
  703.         jz      @F
  704.         mov     eax, [hpet_base]
  705.         stdcall map_io_mem, [hpet_base], 1024, PG_GLOBAL+PAT_UC+PG_SWR
  706.         mov     [hpet_base], eax
  707.         mov     eax, [eax]
  708.         DEBUGF  1, "K : HPET caps %x\n", eax
  709. @@:
  710. ; SET UP OS TASK
  711.  
  712.         mov     esi, boot_setostask
  713.         call    boot_log
  714.  
  715.         mov     eax, sys_proc
  716.         lea     edi, [eax+PROC.heap_lock]
  717.         mov     ecx, (PROC.ht_free-PROC.heap_lock)/4
  718.  
  719.         list_init eax
  720.         add     eax, PROC.thr_list
  721.         list_init eax
  722.  
  723.         xor     eax, eax
  724.         cld
  725.         rep stosd
  726.  
  727.         mov     [edi], dword (PROC.pdt_0 - PROC.htab)/4 - 3
  728.         mov     [edi+4], dword 3           ;reserve handles for stdin stdout and stderr
  729.         mov     ecx, (PROC.pdt_0 - PROC.htab)/4
  730.         add     edi, 8
  731.         inc     eax
  732. @@:
  733.         stosd
  734.         inc     eax
  735.         cmp     eax, ecx
  736.         jbe     @B
  737.  
  738.         mov     [sys_proc+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  739.  
  740.         mov     eax, -1
  741.         mov     edi, thr_slot_map+4
  742.         mov     [edi-4], dword 0xFFFFFFF8
  743.         stosd
  744.         stosd
  745.         stosd
  746.         stosd
  747.         stosd
  748.         stosd
  749.         stosd
  750.  
  751.         mov     [current_process], sys_proc
  752.  
  753.         mov     edx, SLOT_BASE+256*1
  754.         mov     ebx, [os_stack_seg]
  755.         add     ebx, 0x2000
  756.         call    setup_os_slot
  757.         mov     dword [edx], 'IDLE'
  758.         sub     [edx+APPDATA.saved_esp], 4
  759.         mov     eax, [edx+APPDATA.saved_esp]
  760.         mov     dword [eax], idle_thread
  761.         mov     ecx, IDLE_PRIORITY
  762.         call    scheduler_add_thread
  763.  
  764.         mov     edx, SLOT_BASE+256*2
  765.         mov     ebx, [os_stack_seg]
  766.         call    setup_os_slot
  767.         mov     dword [edx], 'OS'
  768.         xor     ecx, ecx
  769.         call    scheduler_add_thread
  770.  
  771.         mov     dword [CURRENT_TASK], 2
  772.         mov     dword [TASK_COUNT], 2
  773.         mov     dword [current_slot], SLOT_BASE + 256*2
  774.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  775.  
  776. ; Move other CPUs to deep sleep, if it is useful
  777. uglobal
  778. use_mwait_for_idle db 0
  779. endg
  780.         cmp     [cpu_vendor+8], 'ntel'
  781.         jnz     .no_wake_cpus
  782.         bt      [cpu_caps+4], CAPS_MONITOR-32
  783.         jnc     .no_wake_cpus
  784.         dbgstr 'using mwait for idle loop'
  785.         inc     [use_mwait_for_idle]
  786.         mov     ebx, [cpu_count]
  787.         cmp     ebx, 1
  788.         jbe     .no_wake_cpus
  789.         call    create_trampoline_pgmap
  790.         mov     [cr3_ap+OS_BASE], eax
  791.         mov     eax, cr4
  792.         mov     [cr4_ap+OS_BASE], eax
  793.         mov     esi, OS_BASE + ap_init16
  794.         mov     edi, OS_BASE + 8000h
  795.         mov     ecx, (ap_init16_size + 3) / 4
  796.         rep movsd
  797.         stdcall map_io_mem, [acpi_lapic_base], 0x1000, PG_GLOBAL+PG_NOCACHE+PG_SWR
  798.         mov     [LAPIC_BASE], eax
  799.         lea     edi, [eax+300h]
  800.         mov     esi, smpt+4
  801.         dec     ebx
  802. .wake_cpus_loop:
  803.         lodsd
  804.         push    esi
  805.         xor     esi, esi
  806.         inc     esi
  807.         shl     eax, 24
  808.         mov     [edi+10h], eax
  809. ; assert INIT IPI
  810.         mov     dword [edi], 0C500h
  811.         call    delay_ms
  812. @@:
  813.         test    dword [edi], 1000h
  814.         jnz     @b
  815. ; deassert INIT IPI
  816.         mov     dword [edi], 8500h
  817.         call    delay_ms
  818. @@:
  819.         test    dword [edi], 1000h
  820.         jnz     @b
  821. ; send STARTUP IPI
  822.         mov     dword [edi], 600h + (8000h shr 12)
  823.         call    delay_ms
  824. @@:
  825.         test    dword [edi], 1000h
  826.         jnz     @b
  827.         pop     esi
  828.         dec     ebx
  829.         jnz     .wake_cpus_loop
  830.         mov     eax, [cpu_count]
  831.         dec     eax
  832. @@:
  833.         cmp     [ap_initialized], eax
  834.         jnz     @b
  835.         mov     eax, [cr3_ap+OS_BASE]
  836.         call    free_page
  837. .no_wake_cpus:
  838.  
  839. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  840.         mov     esi, boot_initirq
  841.         call    boot_log
  842.         call    init_irqs
  843.  
  844.         mov     esi, boot_picinit
  845.         call    boot_log
  846.         call    PIC_init
  847.  
  848.         mov     esi, boot_v86machine
  849.         call    boot_log
  850. ; Initialize system V86 machine
  851.         call    init_sys_v86
  852.  
  853.         mov     esi, boot_inittimer
  854.         call    boot_log
  855. ; Initialize system timer (IRQ0)
  856.         call    PIT_init
  857.  
  858. ; Register ramdisk file system
  859.         cmp     [boot_dev+OS_BASE+0x10000], 1
  860.         je      @f
  861.  
  862.         call    register_ramdisk
  863. ;--------------------------------------
  864. @@:
  865.         mov     esi, boot_initapic
  866.         call    boot_log
  867. ; Try to Initialize APIC
  868.         call    APIC_init
  869.  
  870.         mov     esi, boot_enableirq
  871.         call    boot_log
  872. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  873. ; they are used: when partitions are scanned, hd_read relies on timer
  874.         call    unmask_timer
  875.         stdcall enable_irq, 2               ; @#$%! PIC
  876.         stdcall enable_irq, 13              ; co-processor
  877.  
  878. ; Setup serial output console (if enabled)
  879. if defined debug_com_base
  880.  
  881.         ; reserve port so nobody else will use it
  882.         xor     ebx, ebx
  883.         mov     ecx, debug_com_base
  884.         mov     edx, debug_com_base+7
  885.         call    r_f_port_area
  886.  
  887.         ; enable Divisor latch
  888.         mov     dx, debug_com_base+3
  889.         mov     al, 1 shl 7
  890.         out     dx, al
  891.  
  892.         ; Set speed to 115200 baud (max speed)
  893.         mov     dx, debug_com_base
  894.         mov     al, 0x01
  895.         out     dx, al
  896.  
  897.         mov     dx, debug_com_base+1
  898.         mov     al, 0x00
  899.         out     dx, al
  900.  
  901.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  902.         mov     dx, debug_com_base+3
  903.         mov     al, 3
  904.         out     dx, al
  905.  
  906.         ; disable interrupts
  907.         mov     dx, debug_com_base+1
  908.         mov     al, 0
  909.         out     dx, al
  910.  
  911.         ; clear +  enable fifo (64 bits)
  912.         mov     dx, debug_com_base+2
  913.         mov     al, 0x7 + 1 shl 5
  914.         out     dx, al
  915.  
  916. end if
  917.  
  918.  
  919. ;-----------------------------------------------------------------------------
  920. ; show SVN version of kernel on the message board
  921. ;-----------------------------------------------------------------------------
  922.         mov     eax, [version_inf.rev]
  923.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  924. ;-----------------------------------------------------------------------------
  925. ; show CPU count on the message board
  926. ;-----------------------------------------------------------------------------
  927.         mov     eax, [cpu_count]
  928.         test    eax, eax
  929.         jnz     @F
  930.         mov     al, 1                             ; at least one CPU
  931. @@:
  932.         DEBUGF  1, "K : %d CPU detected\n", eax
  933. ;-----------------------------------------------------------------------------
  934. ; detect Floppy drives
  935. ;-----------------------------------------------------------------------------
  936.         mov     esi, boot_detectfloppy
  937.         call    boot_log
  938. include 'detect/dev_fd.inc'
  939. ;-----------------------------------------------------------------------------
  940. ; create pci-devices list
  941. ;-----------------------------------------------------------------------------
  942.         mov     [pci_access_enabled], 1
  943.         call    pci_enum
  944. ;-----------------------------------------------------------------------------
  945. ; initialisation IDE ATA code
  946. ;-----------------------------------------------------------------------------
  947. include 'detect/init_ata.inc'
  948. ;-----------------------------------------------------------------------------
  949. if 0
  950.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  951.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  952.         je      no_lib_load
  953.  
  954.         mov     esi, boot_loadlibs
  955.         call    boot_log
  956. ; LOADING LIBRARES
  957.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  958.         call    load_file_parse_table       ; prepare file parse table
  959.         call    set_kernel_conf             ; configure devices and gui
  960. no_lib_load:
  961. end if
  962.  
  963. ; Display APIC status
  964.         mov     esi, boot_APIC_found
  965.         cmp     [irq_mode], IRQ_APIC
  966.         je      @f
  967.         mov     esi, boot_APIC_nfound
  968. @@:
  969.         call    boot_log
  970.  
  971. ; PRINT AMOUNT OF MEMORY
  972.         mov     esi, boot_memdetect
  973.         call    boot_log
  974.  
  975.         movzx   ecx, word [boot_y]
  976.         if lang eq ru
  977.         or      ecx, (10+30*6) shl 16
  978.         else if lang eq sp
  979.         or      ecx, (10+33*6) shl 16
  980.         else
  981.         or      ecx, (10+29*6) shl 16
  982.         end if
  983.         sub     ecx, 10
  984.         mov     edx, 0xFFFFFF
  985.         mov     ebx, [MEM_AMOUNT]
  986.         shr     ebx, 20
  987.         xor     edi, edi
  988.         mov     eax, 0x00040000
  989.         inc     edi
  990.         call    display_number_force
  991.  
  992. ; BUILD SCHEDULER
  993.  
  994. ;        call    build_scheduler; sys32.inc
  995.  
  996. ;        mov     esi, boot_devices
  997. ;        call    boot_log
  998.  
  999.         call    clear_pci_ide_interrupts
  1000.  
  1001. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  1002.  
  1003.         stdcall load_pe_driver, szVidintel, 0
  1004.  
  1005.         call    usb_init
  1006.  
  1007. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  1008.  
  1009.         mov     esi, boot_windefs
  1010.         call    boot_log
  1011.         call    set_window_defaults
  1012.  
  1013. ; SET BACKGROUND DEFAULTS
  1014.  
  1015.         mov     esi, boot_bgr
  1016.         call    boot_log
  1017.         call    init_background
  1018.         call    calculatebackground
  1019.  
  1020. ; RESERVE SYSTEM IRQ'S JA PORT'S
  1021.  
  1022.         mov     esi, boot_resirqports
  1023.         call    boot_log
  1024.         call    reserve_irqs_ports
  1025.  
  1026.         call    init_display
  1027.         mov     eax, [def_cursor]
  1028.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  1029.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  1030.  
  1031. ; PRINT CPU FREQUENCY
  1032.  
  1033.         mov     esi, boot_cpufreq
  1034.         call    boot_log
  1035.  
  1036.         cli
  1037.         mov     ebx, [hpet_base]
  1038.         test    ebx, ebx
  1039.         jz      @F
  1040.         mov     ebx, [ebx+0xF0]
  1041.  
  1042.         rdtsc
  1043.         mov     ecx, 1000
  1044.         sub     eax, [hpet_tsc_start]
  1045.         sbb     edx, [hpet_tsc_start+4]
  1046.         shld    edx, eax, 10
  1047.         shl     eax, 10
  1048.         mov     esi, eax
  1049.         mov     eax, edx
  1050.         mul     ecx
  1051.         xchg    eax, esi
  1052.         mul     ecx
  1053.         adc     edx, esi
  1054.         div     ebx
  1055.         mul     ecx
  1056.         div     [hpet_period]
  1057.         mul     ecx
  1058.         DEBUGF  1, "K : cpu frequency %u Hz\n", eax
  1059.         jmp     .next
  1060. @@:
  1061.         rdtsc
  1062.         mov     ecx, eax
  1063.         mov     esi, 250            ; wait 1/4 a second
  1064.         call    delay_ms
  1065.         rdtsc
  1066.         sti
  1067.  
  1068.         sub     eax, ecx
  1069.         xor     edx, edx
  1070.         shld    edx, eax, 2
  1071.         shl     eax, 2
  1072. .next:
  1073.         mov     dword [cpu_freq], eax
  1074.         mov     dword [cpu_freq+4], edx
  1075.         mov     ebx, 1000000
  1076.         div     ebx
  1077.         mov     ebx, eax
  1078.  
  1079.         movzx   ecx, word [boot_y]
  1080.         if lang eq ru
  1081.         add     ecx, (10+19*6) shl 16 - 10
  1082.         else if lang eq sp
  1083.         add     ecx, (10+25*6) shl 16 - 10
  1084.         else
  1085.         add     ecx, (10+17*6) shl 16 - 10
  1086.         end if
  1087.  
  1088.         mov     edx, 0xFFFFFF
  1089.         xor     edi, edi
  1090.         mov     eax, 0x00040000
  1091.         inc     edi
  1092.         call    display_number_force
  1093.  
  1094. ; SET VARIABLES
  1095.  
  1096.         call    set_variables
  1097.  
  1098. ; STACK AND FDC
  1099.  
  1100.         call    stack_init
  1101.         call    fdc_init
  1102.  
  1103. ; PALETTE FOR 320x200 and 640x480 16 col
  1104.  
  1105.         cmp     [SCR_MODE], word 0x12
  1106.         jne     no_pal_vga
  1107.         mov     esi, boot_pal_vga
  1108.         call    boot_log
  1109.         call    paletteVGA
  1110.       no_pal_vga:
  1111.  
  1112.         cmp     [SCR_MODE], word 0x13
  1113.         jne     no_pal_ega
  1114.         mov     esi, boot_pal_ega
  1115.         call    boot_log
  1116.         call    palette320x200
  1117.       no_pal_ega:
  1118.  
  1119. ; LOAD DEFAULT SKIN
  1120.  
  1121.         call    load_default_skin
  1122.  
  1123. ; Protect I/O permission map
  1124.  
  1125.         mov     esi, [default_io_map]
  1126.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1127.         add     esi, 0x1000
  1128.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1129.  
  1130.         stdcall map_page, tss._io_map_0, \
  1131.                 [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1132.         stdcall map_page, tss._io_map_1, \
  1133.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1134.  
  1135. ; SET KEYBOARD PARAMETERS
  1136.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1137.         call    kb_write_wait_ack
  1138.         test    ah, ah
  1139.         jnz     .no_keyboard
  1140.  
  1141. iglobal
  1142. align 4
  1143. ps2_keyboard_functions:
  1144.         dd      .end - $
  1145.         dd      0       ; no close
  1146.         dd      ps2_set_lights
  1147. .end:
  1148. endg
  1149.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1150.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1151.        ; call  kb_write_wait_ack
  1152.        ; mov   al, 111b
  1153.        ; call  kb_write_wait_ack
  1154.  
  1155.         mov     al, 0xF3     ; set repeat rate & delay
  1156.         call    kb_write_wait_ack
  1157.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1158.         call    kb_write_wait_ack
  1159.      ;// mike.dld [
  1160.         call    set_lights
  1161.      ;// mike.dld ]
  1162.         stdcall attach_int_handler, 1, irq1, 0
  1163.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1164. .no_keyboard:
  1165.  
  1166. ; Load PS/2 mouse driver
  1167.  
  1168.         stdcall load_pe_driver, szPS2MDriver, 0
  1169.  
  1170.         mov     esi, boot_setmouse
  1171.         call    boot_log
  1172.         call    setmouse
  1173.  
  1174. ; LOAD FIRST APPLICATION
  1175.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1176.         jnz     first_app_found
  1177.  
  1178.         cli
  1179.         mov     ebp, firstapp
  1180.         call    fs_execute_from_sysdir
  1181.         test    eax, eax
  1182.         jns     first_app_found
  1183.  
  1184.         mov     esi, boot_failed
  1185.         call    boot_log
  1186.  
  1187.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1188.         hlt
  1189.  
  1190. first_app_found:
  1191.  
  1192. ; START MULTITASKING
  1193.  
  1194. ; A 'All set - press ESC to start' messages if need
  1195. if preboot_blogesc
  1196.         mov     esi, boot_tasking
  1197.         call    boot_log
  1198. .bll1:
  1199.         in      al, 0x60        ; wait for ESC key press
  1200.         cmp     al, 129
  1201.         jne     .bll1
  1202. end if
  1203.  
  1204.         mov     [timer_ticks_enable], 1         ; for cd driver
  1205.  
  1206.         sti
  1207.  
  1208.         call    mtrr_validate
  1209.  
  1210.         jmp     osloop
  1211.  
  1212.  
  1213.         ; Fly :)
  1214.  
  1215. uglobal
  1216. align 4
  1217. ap_initialized  dd      0
  1218. endg
  1219.  
  1220. ap_init_high:
  1221.         mov     ax, os_stack
  1222.         mov     bx, app_data
  1223.         mov     cx, app_tls
  1224.         mov     ss, ax
  1225.         mov     ds, bx
  1226.         mov     es, bx
  1227.         mov     fs, cx
  1228.         mov     gs, bx
  1229.         xor     esp, esp
  1230.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  1231.         mov     cr3, eax
  1232.         lock inc [ap_initialized]
  1233.         jmp     idle_loop
  1234.  
  1235.  
  1236. include 'unpacker.inc'
  1237.  
  1238. align 4
  1239. boot_log:
  1240.         pushad
  1241.  
  1242.         mov     ebx, 10*65536
  1243.         mov     bx, word [boot_y]
  1244.         add     [boot_y], dword 10
  1245.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1246.         xor     edi, edi
  1247.         mov     edx, esi
  1248.         inc     edi
  1249.         call    dtext
  1250.  
  1251.         mov     [novesachecksum], 1000
  1252.         call    checkVga_N13
  1253.  
  1254.         popad
  1255.  
  1256.         ret
  1257.  
  1258. ; in: edx -> APPDATA for OS/IDLE slot
  1259. ; in: ebx = stack base
  1260. proc setup_os_slot
  1261.         xor     eax, eax
  1262.         mov     ecx, 256/4
  1263.         mov     edi, edx
  1264.         rep stosd
  1265.  
  1266.         mov     eax, tss+0x80
  1267.         call    get_pg_addr
  1268.         inc     eax
  1269.         mov     [edx+APPDATA.io_map], eax
  1270.         mov     eax, tss+0x1080
  1271.         call    get_pg_addr
  1272.         inc     eax
  1273.         mov     [edx+APPDATA.io_map+4], eax
  1274.  
  1275.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1276.         lea     edi, [ebx+0x2000-512]
  1277.         mov     dword [edx+APPDATA.fpu_state], edi
  1278.         mov     dword [edx+APPDATA.saved_esp0], edi
  1279.         mov     dword [edx+APPDATA.saved_esp], edi
  1280.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1281.  
  1282.         mov     esi, fpu_data
  1283.         mov     ecx, 512/4
  1284.         cld
  1285.         rep movsd
  1286.  
  1287.         lea     eax, [edx+APP_OBJ_OFFSET]
  1288.         mov     dword [edx+APPDATA.fd_obj], eax
  1289.         mov     dword [edx+APPDATA.bk_obj], eax
  1290.  
  1291.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1292.  
  1293.         mov     [edx + APPDATA.process], sys_proc
  1294.  
  1295.         lea     ebx, [edx+APPDATA.list]
  1296.         lea     ecx, [sys_proc+PROC.thr_list]
  1297.         list_add_tail ebx, ecx
  1298.  
  1299.         mov     eax, edx
  1300.         shr     eax, 3
  1301.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1302.         mov     [eax+TASKDATA.wnd_number], dh
  1303.         mov     byte [eax+TASKDATA.pid], dh
  1304.  
  1305.         ret
  1306. endp
  1307.  
  1308. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1309. ;                                                                    ;
  1310. ;                    MAIN OS LOOP START                              ;
  1311. ;                                                                    ;
  1312. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1313. align 32
  1314. osloop:
  1315.         mov     edx, osloop_has_work?
  1316.         xor     ecx, ecx
  1317.         call    Wait_events
  1318.         xor     eax, eax
  1319.         xchg    eax, [osloop_nonperiodic_work]
  1320.         test    eax, eax
  1321.         jz      .no_periodic
  1322.  
  1323.         call    __sys_draw_pointer
  1324.         call    window_check_events
  1325.         call    mouse_check_events
  1326.         call    checkmisc
  1327.         call    checkVga_N13
  1328. ;--------------------------------------
  1329. .no_periodic:
  1330.         call    stack_handler
  1331.         call    check_fdd_motor_status
  1332.         call    check_ATAPI_device_event
  1333.         call    check_lights_state
  1334.         call    check_timers
  1335.  
  1336.         jmp     osloop
  1337. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1338. ;                                                                    ;
  1339. ;                      MAIN OS LOOP END                              ;
  1340. ;                                                                    ;
  1341. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1342. proc osloop_has_work?
  1343.         cmp     [osloop_nonperiodic_work], 0
  1344.         jnz     .yes
  1345.         call    stack_handler_has_work?
  1346.         jnz     .yes
  1347.         call    check_fdd_motor_status_has_work?
  1348.         jnz     .yes
  1349.         call    check_ATAPI_device_event_has_work?
  1350.         jnz     .yes
  1351.         call    check_lights_state_has_work?
  1352.         jnz     .yes
  1353.         call    check_timers_has_work?
  1354.         jnz     .yes
  1355. .no:
  1356.         xor     eax, eax
  1357.         ret
  1358. .yes:
  1359.         xor     eax, eax
  1360.         inc     eax
  1361.         ret
  1362. endp
  1363.  
  1364. proc wakeup_osloop
  1365.         mov     [osloop_nonperiodic_work], 1
  1366.         ret
  1367. endp
  1368.  
  1369. uglobal
  1370. align 4
  1371. osloop_nonperiodic_work dd      ?
  1372. endg
  1373.  
  1374. uglobal
  1375. align 64
  1376. idle_addr       rb      64
  1377. endg
  1378.  
  1379. idle_thread:
  1380.         sti
  1381.  
  1382. ; The following code can be executed by all CPUs in the system.
  1383. ; All other parts of the kernel do not expect multi-CPU.
  1384. ; Also, APs don't even have a stack here.
  1385. ; Beware. Don't do anything here. Anything at all.
  1386. idle_loop:
  1387.         cmp     [use_mwait_for_idle], 0
  1388.         jnz     idle_loop_mwait
  1389.  
  1390. idle_loop_hlt:
  1391.         hlt
  1392.         jmp     idle_loop_hlt
  1393.  
  1394. idle_loop_mwait:
  1395.         mov     eax, idle_addr
  1396.         xor     ecx, ecx
  1397.         xor     edx, edx
  1398.         monitor
  1399.         xor     ecx, ecx
  1400.         mov     eax, 20h        ; or 10h
  1401.         mwait
  1402.         jmp     idle_loop_mwait
  1403.  
  1404.  
  1405. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1406. ;                                                                      ;
  1407. ;                   INCLUDED SYSTEM FILES                              ;
  1408. ;                                                                      ;
  1409. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1410.  
  1411.  
  1412. include "kernel32.inc"
  1413.  
  1414.  
  1415. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1416. ;                                                                      ;
  1417. ;                       KERNEL FUNCTIONS                               ;
  1418. ;                                                                      ;
  1419. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1420.  
  1421. reserve_irqs_ports:
  1422.  
  1423.  
  1424. ; RESERVE PORTS
  1425.         mov     eax, RESERVED_PORTS
  1426.         mov     ecx, 1
  1427.  
  1428.         mov     [eax], dword 4
  1429.  
  1430.         mov     [eax+16], ecx
  1431.         mov     [eax+16+4], dword 0
  1432.         mov     [eax+16+8], dword 0x2D
  1433.  
  1434.         mov     [eax+32], ecx
  1435.         mov     [eax+32+4], dword 0x30
  1436.         mov     [eax+32+8], dword 0x4D
  1437.  
  1438.         mov     [eax+48], ecx
  1439.         mov     [eax+48+4], dword 0x50
  1440.         mov     [eax+48+8], dword 0xDF
  1441.  
  1442.         mov     [eax+64], ecx
  1443.         mov     [eax+64+4], dword 0xE5
  1444.         mov     [eax+64+8], dword 0xFF
  1445.  
  1446.         ret
  1447.  
  1448.  
  1449. iglobal
  1450.   process_number dd 0x2
  1451. endg
  1452.  
  1453. set_variables:
  1454.  
  1455.         mov     ecx, 0x16                    ; flush port 0x60
  1456. .fl60:
  1457.         in      al, 0x60
  1458.         loop    .fl60
  1459.         push    eax
  1460.  
  1461.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1462.         shr     ax, 1
  1463.         shl     eax, 16
  1464.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1465.         shr     ax, 1
  1466.         mov     [MOUSE_X], eax
  1467.         call    wakeup_osloop
  1468.  
  1469.         xor     eax, eax
  1470.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1471.  
  1472.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1473.         mov     byte [BTN_COUNT], al              ; button buffer
  1474. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1475.  
  1476.         pop     eax
  1477.         ret
  1478.  
  1479. align 4
  1480. ;input  eax=43,bl-byte of output, ecx - number of port
  1481. sys_outport:
  1482.  
  1483.         mov     edi, ecx   ; separate flag for read / write
  1484.         and     ecx, 65535
  1485.  
  1486.         mov     eax, [RESERVED_PORTS]
  1487.         test    eax, eax
  1488.         jnz     .sopl8
  1489.         inc     eax
  1490.         mov     [esp+32], eax
  1491.         ret
  1492.  
  1493.   .sopl8:
  1494.         mov     edx, [TASK_BASE]
  1495.         mov     edx, [edx+0x4]
  1496.     ;and   ecx,65535
  1497.     ;cld - set on interrupt 0x40
  1498.   .sopl1:
  1499.  
  1500.         mov     esi, eax
  1501.         shl     esi, 4
  1502.         add     esi, RESERVED_PORTS
  1503.         cmp     edx, [esi+0]
  1504.         jne     .sopl2
  1505.         cmp     ecx, [esi+4]
  1506.         jb      .sopl2
  1507.         cmp     ecx, [esi+8]
  1508.         jg      .sopl2
  1509. .sopl3:
  1510.  
  1511.         test    edi, 0x80000000; read ?
  1512.         jnz     .sopl4
  1513.  
  1514.         mov     eax, ebx
  1515.         mov     dx, cx   ; write
  1516.         out     dx, al
  1517.         and     [esp+32], dword 0
  1518.         ret
  1519.  
  1520.         .sopl2:
  1521.  
  1522.         dec     eax
  1523.         jnz     .sopl1
  1524.         inc     eax
  1525.         mov     [esp+32], eax
  1526.         ret
  1527.  
  1528.  
  1529.   .sopl4:
  1530.  
  1531.         mov     dx, cx   ; read
  1532.         in      al, dx
  1533.         and     eax, 0xff
  1534.         and     [esp+32], dword 0
  1535.         mov     [esp+20], eax
  1536.         ret
  1537.  
  1538. display_number:
  1539. ;It is not optimization
  1540.         mov     eax, ebx
  1541.         mov     ebx, ecx
  1542.         mov     ecx, edx
  1543.         mov     edx, esi
  1544.         mov     esi, edi
  1545. ; eax = print type, al=0 -> ebx is number
  1546. ;                   al=1 -> ebx is pointer
  1547. ;                   ah=0 -> display decimal
  1548. ;                   ah=1 -> display hexadecimal
  1549. ;                   ah=2 -> display binary
  1550. ;                   eax bits 16-21 = number of digits to display (0-32)
  1551. ;                   eax bits 22-31 = reserved
  1552. ;
  1553. ; ebx = number or pointer
  1554. ; ecx = x shl 16 + y
  1555. ; edx = color
  1556.         xor     edi, edi
  1557. display_number_force:
  1558.         push    eax
  1559.         and     eax, 0x3fffffff
  1560.         cmp     eax, 0xffff     ; length > 0 ?
  1561.         pop     eax
  1562.         jge     cont_displ
  1563.         ret
  1564.    cont_displ:
  1565.         push    eax
  1566.         and     eax, 0x3fffffff
  1567.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1568.         pop     eax
  1569.         jb      cont_displ2
  1570.         ret
  1571.    cont_displ2:
  1572.  
  1573.         pushad
  1574.  
  1575.         cmp     al, 1            ; ecx is a pointer ?
  1576.         jne     displnl1
  1577.         mov     ebp, ebx
  1578.         add     ebp, 4
  1579.         mov     ebp, [ebp+std_application_base_address]
  1580.         mov     ebx, [ebx+std_application_base_address]
  1581.  displnl1:
  1582.         sub     esp, 64
  1583.  
  1584.         test    ah, ah            ; DECIMAL
  1585.         jnz     no_display_desnum
  1586.         shr     eax, 16
  1587.         and     eax, 0xC03f
  1588. ;     and   eax,0x3f
  1589.         push    eax
  1590.         and     eax, 0x3f
  1591.         mov     edi, esp
  1592.         add     edi, 4+64-1
  1593.         mov     ecx, eax
  1594.         mov     eax, ebx
  1595.         mov     ebx, 10
  1596.  d_desnum:
  1597.         xor     edx, edx
  1598.         call    division_64_bits
  1599.         div     ebx
  1600.         add     dl, 48
  1601.         mov     [edi], dl
  1602.         dec     edi
  1603.         loop    d_desnum
  1604.         pop     eax
  1605.         call    normalize_number
  1606.         call    draw_num_text
  1607.         add     esp, 64
  1608.         popad
  1609.         ret
  1610.    no_display_desnum:
  1611.  
  1612.         cmp     ah, 0x01         ; HEXADECIMAL
  1613.         jne     no_display_hexnum
  1614.         shr     eax, 16
  1615.         and     eax, 0xC03f
  1616. ;     and   eax,0x3f
  1617.         push    eax
  1618.         and     eax, 0x3f
  1619.         mov     edi, esp
  1620.         add     edi, 4+64-1
  1621.         mov     ecx, eax
  1622.         mov     eax, ebx
  1623.         mov     ebx, 16
  1624.    d_hexnum:
  1625.         xor     edx, edx
  1626.         call    division_64_bits
  1627.         div     ebx
  1628.    hexletters = __fdo_hexdigits
  1629.         add     edx, hexletters
  1630.         mov     dl, [edx]
  1631.         mov     [edi], dl
  1632.         dec     edi
  1633.         loop    d_hexnum
  1634.         pop     eax
  1635.         call    normalize_number
  1636.         call    draw_num_text
  1637.         add     esp, 64
  1638.         popad
  1639.         ret
  1640.    no_display_hexnum:
  1641.  
  1642.         cmp     ah, 0x02         ; BINARY
  1643.         jne     no_display_binnum
  1644.         shr     eax, 16
  1645.         and     eax, 0xC03f
  1646. ;     and   eax,0x3f
  1647.         push    eax
  1648.         and     eax, 0x3f
  1649.         mov     edi, esp
  1650.         add     edi, 4+64-1
  1651.         mov     ecx, eax
  1652.         mov     eax, ebx
  1653.         mov     ebx, 2
  1654.    d_binnum:
  1655.         xor     edx, edx
  1656.         call    division_64_bits
  1657.         div     ebx
  1658.         add     dl, 48
  1659.         mov     [edi], dl
  1660.         dec     edi
  1661.         loop    d_binnum
  1662.         pop     eax
  1663.         call    normalize_number
  1664.         call    draw_num_text
  1665.         add     esp, 64
  1666.         popad
  1667.         ret
  1668.    no_display_binnum:
  1669.  
  1670.         add     esp, 64
  1671.         popad
  1672.         ret
  1673.  
  1674. normalize_number:
  1675.         test    ah, 0x80
  1676.         jz      .continue
  1677.         mov     ecx, 48
  1678.         and     eax, 0x3f
  1679. @@:
  1680.         inc     edi
  1681.         cmp     [edi], cl
  1682.         jne     .continue
  1683.         dec     eax
  1684.         cmp     eax, 1
  1685.         ja      @r
  1686.         mov     al, 1
  1687. .continue:
  1688.         and     eax, 0x3f
  1689.         ret
  1690.  
  1691. division_64_bits:
  1692.         test    [esp+1+4], byte 0x40
  1693.         jz      .continue
  1694.         push    eax
  1695.         mov     eax, ebp
  1696.         div     ebx
  1697.         mov     ebp, eax
  1698.         pop     eax
  1699. .continue:
  1700.         ret
  1701.  
  1702. draw_num_text:
  1703.         mov     esi, eax
  1704.         mov     edx, 64+4
  1705.         sub     edx, eax
  1706.         add     edx, esp
  1707.         mov     ebx, [esp+64+32-8+4]
  1708. ; add window start x & y
  1709.         mov     ecx, [TASK_BASE]
  1710.  
  1711.         mov     edi, [CURRENT_TASK]
  1712.         shl     edi, 8
  1713.  
  1714.         mov     eax, [ecx-twdw+WDATA.box.left]
  1715.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1716.         shl     eax, 16
  1717.         add     eax, [ecx-twdw+WDATA.box.top]
  1718.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1719.         add     ebx, eax
  1720.         mov     ecx, [esp+64+32-12+4]
  1721.         and     ecx, not 0x80000000     ; force counted string
  1722.         mov     eax, [esp+64+8]         ; background color (if given)
  1723.         mov     edi, [esp+64+4]
  1724.         jmp     dtext
  1725. ;-----------------------------------------------------------------------------
  1726. iglobal
  1727. midi_base dw 0
  1728. endg
  1729. ;-----------------------------------------------------------------------------
  1730. align 4
  1731. sys_setup:
  1732. ;  1 = roland mpu midi base , base io address
  1733. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1734. ;  3 = not used
  1735. ;  4 = not used
  1736. ;  5 = system language, 1eng 2fi 3ger 4rus
  1737. ;  6 = not used
  1738. ;  7 = not used
  1739. ;  8 = not used
  1740. ;  9 = not used
  1741. ; 10 = not used
  1742. ; 11 = enable lba read
  1743. ; 12 = enable pci access
  1744. ;-----------------------------------------------------------------------------
  1745.         and     [esp+32], dword 0
  1746. ; F.21.1 - set MPU MIDI base port
  1747.         dec     ebx
  1748.         jnz     @f
  1749.  
  1750.         cmp     ecx, 0x100
  1751.         jb      @f
  1752.  
  1753.         mov     esi, 65535
  1754.         cmp     esi, ecx
  1755.         jb      @f
  1756.  
  1757.         mov     [midi_base], cx
  1758.         mov     word [mididp], cx
  1759.         inc     cx
  1760.         mov     word [midisp], cx
  1761.         ret
  1762. ;--------------------------------------
  1763. @@:
  1764. ; F.21.2 - set keyboard layout
  1765.         dec     ebx
  1766.         jnz     @f
  1767.  
  1768.         mov     edi, [TASK_BASE]
  1769.         mov     eax, [edi+TASKDATA.mem_start]
  1770.         add     eax, edx
  1771. ; 1 = normal layout
  1772.         dec     ecx
  1773.         jnz     .shift
  1774.  
  1775.         mov     ebx, keymap
  1776.         mov     ecx, 128
  1777.         call    memmove
  1778.         ret
  1779. ;--------------------------------------
  1780. .shift:
  1781. ; 2 = layout at pressed Shift
  1782.         dec     ecx
  1783.         jnz     .alt
  1784.  
  1785.         mov     ebx, keymap_shift
  1786.         mov     ecx, 128
  1787.         call    memmove
  1788.         ret
  1789. ;--------------------------------------
  1790. .alt:
  1791. ; 3 = layout at pressed Alt
  1792.         dec     ecx
  1793.         jnz     .country
  1794.  
  1795.         mov     ebx, keymap_alt
  1796.         mov     ecx, 128
  1797.         call    memmove
  1798.         ret
  1799. ;--------------------------------------
  1800. .country:
  1801. ; country identifier
  1802.         sub     ecx, 6
  1803.         jnz     .error
  1804.  
  1805.         mov     word [keyboard], dx
  1806.         ret
  1807. ;--------------------------------------
  1808. @@:
  1809. ; F.21.5 - set system language
  1810.         sub     ebx, 3
  1811.         jnz     @f
  1812.  
  1813.         mov     [syslang], ecx
  1814.         ret
  1815. ;--------------------------------------
  1816. @@:
  1817. ; F.21.11 - enable/disable low-level access to HD
  1818.         and     ecx, 1
  1819.         sub     ebx, 6
  1820.         jnz     @f
  1821.  
  1822.         mov     [lba_read_enabled], ecx
  1823.         ret
  1824. ;--------------------------------------
  1825. @@:
  1826. ; F.21.12 - enable/disable low-level access to PCI
  1827.         dec     ebx
  1828.         jnz     .error
  1829.  
  1830.         mov     [pci_access_enabled], ecx
  1831.         ret
  1832. ;--------------------------------------
  1833. .error:
  1834.         or      [esp+32], dword -1
  1835.         ret
  1836. ;-----------------------------------------------------------------------------
  1837. align 4
  1838. sys_getsetup:
  1839. ;  1 = roland mpu midi base , base io address
  1840. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1841. ;  3 = not used
  1842. ;  4 = not used
  1843. ;  5 = system language, 1eng 2fi 3ger 4rus
  1844. ;  6 = not used
  1845. ;  7 = not used
  1846. ;  8 = not used
  1847. ;  9 = get hs timer tic
  1848. ; 10 = not used
  1849. ; 11 = get the state "lba read"
  1850. ; 12 = get the state "pci access"
  1851. ;-----------------------------------------------------------------------------
  1852. ; F.26.1 - get MPU MIDI base port
  1853.         dec     ebx
  1854.         jnz     @f
  1855.  
  1856.         movzx   eax, [midi_base]
  1857.         mov     [esp+32], eax
  1858.         ret
  1859. ;--------------------------------------
  1860. @@:
  1861. ; F.26.2 - get keyboard layout
  1862.         dec     ebx
  1863.         jnz     @f
  1864.  
  1865.         mov     edi, [TASK_BASE]
  1866.         mov     ebx, [edi+TASKDATA.mem_start]
  1867.         add     ebx, edx
  1868. ; 1 = normal layout
  1869.         dec     ecx
  1870.         jnz     .shift
  1871.  
  1872.         mov     eax, keymap
  1873.         mov     ecx, 128
  1874.         call    memmove
  1875.         ret
  1876. ;--------------------------------------
  1877. .shift:
  1878. ; 2 = layout with pressed Shift
  1879.         dec     ecx
  1880.         jnz     .alt
  1881.  
  1882.         mov     eax, keymap_shift
  1883.         mov     ecx, 128
  1884.         call    memmove
  1885.         ret
  1886. ;--------------------------------------
  1887. .alt:
  1888. ; 3 = layout with pressed Alt
  1889.         dec     ecx
  1890.         jne     .country
  1891.  
  1892.         mov     eax, keymap_alt
  1893.         mov     ecx, 128
  1894.         call    memmove
  1895.         ret
  1896. ;--------------------------------------
  1897. .country:
  1898. ; 9 = country identifier
  1899.         sub     ecx, 6
  1900.         jnz     .error
  1901.  
  1902.         movzx   eax, word [keyboard]
  1903.         mov     [esp+32], eax
  1904.         ret
  1905. ;--------------------------------------
  1906. @@:
  1907. ; F.26.5 - get system language
  1908.         sub     ebx, 3
  1909.         jnz     @f
  1910.  
  1911.         mov     eax, [syslang]
  1912.         mov     [esp+32], eax
  1913.         ret
  1914. ;--------------------------------------
  1915. @@:
  1916. ; F.26.9 - get the value of the time counter
  1917.         sub     ebx, 4
  1918.         jnz     @f
  1919.  
  1920.         mov     eax, [timer_ticks]
  1921.         mov     [esp+32], eax
  1922.         ret
  1923. ;--------------------------------------
  1924. @@:
  1925. ; F.26.10 - get the time from kernel launch in nanoseconds
  1926.         sub     ebx, 1
  1927.         jnz     @f
  1928.  
  1929.         call    get_clock_ns
  1930.         mov     [esp+24], edx
  1931.         mov     [esp+32], eax
  1932.         ret
  1933. ;--------------------------------------
  1934. @@:
  1935. ; F.26.11 - Find out whether low-level HD access is enabled
  1936.         sub     ebx, 1
  1937.         jnz     @f
  1938.  
  1939.         mov     eax, [lba_read_enabled]
  1940.         mov     [esp+32], eax
  1941.         ret
  1942. ;--------------------------------------
  1943. @@:
  1944. ; F.26.12 - Find out whether low-level PCI access is enabled
  1945.         dec     ebx
  1946.         jnz     .error
  1947.  
  1948.         mov     eax, [pci_access_enabled]
  1949.         mov     [esp+32], eax
  1950.         ret
  1951. ;--------------------------------------
  1952. .error:
  1953.         or      [esp+32], dword -1
  1954.         ret
  1955. ;-----------------------------------------------------------------------------
  1956. get_timer_ticks:
  1957.         mov     eax, [timer_ticks]
  1958.         ret
  1959. ;-----------------------------------------------------------------------------
  1960. iglobal
  1961. align 4
  1962. mousefn dd msscreen, mswin, msbutton, msset
  1963.         dd app_load_cursor
  1964.         dd app_set_cursor
  1965.         dd app_delete_cursor
  1966.         dd msz
  1967. endg
  1968. ;-----------------------------------------------------------------------------
  1969. readmousepos:
  1970.  
  1971. ; eax=0 screen relative
  1972. ; eax=1 window relative
  1973. ; eax=2 buttons pressed
  1974. ; eax=3 set mouse pos   ; reserved
  1975. ; eax=4 load cursor
  1976. ; eax=5 set cursor
  1977. ; eax=6 delete cursor   ; reserved
  1978. ; eax=7 get mouse_z
  1979.  
  1980.         cmp     ebx, 7
  1981.         ja      msset
  1982.         jmp     [mousefn+ebx*4]
  1983. msscreen:
  1984.         mov     eax, [MOUSE_X]
  1985.         shl     eax, 16
  1986.         mov     ax, [MOUSE_Y]
  1987.         mov     [esp+36-4], eax
  1988.         ret
  1989. mswin:
  1990.         mov     eax, [MOUSE_X]
  1991.         shl     eax, 16
  1992.         mov     ax, [MOUSE_Y]
  1993.         mov     esi, [TASK_BASE]
  1994.         mov     bx, word [esi-twdw+WDATA.box.left]
  1995.         shl     ebx, 16
  1996.         mov     bx, word [esi-twdw+WDATA.box.top]
  1997.         sub     eax, ebx
  1998.  
  1999.         mov     edi, [CURRENT_TASK]
  2000.         shl     edi, 8
  2001.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  2002.         rol     eax, 16
  2003.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  2004.         rol     eax, 16
  2005.         mov     [esp+36-4], eax
  2006.         ret
  2007. msbutton:
  2008.         movzx   eax, byte [BTN_DOWN]
  2009.         mov     [esp+36-4], eax
  2010.         ret
  2011. msz:
  2012.         mov     edi, [TASK_COUNT]
  2013.         movzx   edi, word [WIN_POS + edi*2]
  2014.         cmp     edi, [CURRENT_TASK]
  2015.         jne     @f
  2016.         mov     ax, [MOUSE_SCROLL_H]
  2017.         shl     eax, 16
  2018.         mov     ax, [MOUSE_SCROLL_V]
  2019.         mov     [esp+36-4], eax
  2020.         and     [MOUSE_SCROLL_H], word 0
  2021.         and     [MOUSE_SCROLL_V], word 0
  2022.         ret
  2023.        @@:
  2024.         and     [esp+36-4], dword 0
  2025. ;           ret
  2026. msset:
  2027.         ret
  2028.  
  2029. app_load_cursor:
  2030.         cmp     ecx, OS_BASE
  2031.         jae     msset
  2032.         stdcall load_cursor, ecx, edx
  2033.         mov     [esp+36-4], eax
  2034.         ret
  2035.  
  2036. app_set_cursor:
  2037.         stdcall set_cursor, ecx
  2038.         mov     [esp+36-4], eax
  2039.         ret
  2040.  
  2041. app_delete_cursor:
  2042.         stdcall delete_cursor, ecx
  2043.         mov     [esp+36-4], eax
  2044.         ret
  2045.  
  2046. is_input:
  2047.  
  2048.         push    edx
  2049.         mov     dx, word [midisp]
  2050.         in      al, dx
  2051.         and     al, 0x80
  2052.         pop     edx
  2053.         ret
  2054.  
  2055. is_output:
  2056.  
  2057.         push    edx
  2058.         mov     dx, word [midisp]
  2059.         in      al, dx
  2060.         and     al, 0x40
  2061.         pop     edx
  2062.         ret
  2063.  
  2064.  
  2065. get_mpu_in:
  2066.  
  2067.         push    edx
  2068.         mov     dx, word [mididp]
  2069.         in      al, dx
  2070.         pop     edx
  2071.         ret
  2072.  
  2073.  
  2074. put_mpu_out:
  2075.  
  2076.         push    edx
  2077.         mov     dx, word [mididp]
  2078.         out     dx, al
  2079.         pop     edx
  2080.         ret
  2081.  
  2082.  
  2083.  
  2084. align 4
  2085.  
  2086. sys_midi:
  2087.         cmp     [mididp], 0
  2088.         jnz     sm0
  2089.         mov     [esp+36], dword 1
  2090.         ret
  2091. sm0:
  2092.         and     [esp+36], dword 0
  2093.         dec     ebx
  2094.         jnz     smn1
  2095.  ;    call setuart
  2096. su1:
  2097.         call    is_output
  2098.         test    al, al
  2099.         jnz     su1
  2100.         mov     dx, word [midisp]
  2101.         mov     al, 0xff
  2102.         out     dx, al
  2103. su2:
  2104.         mov     dx, word [midisp]
  2105.         mov     al, 0xff
  2106.         out     dx, al
  2107.         call    is_input
  2108.         test    al, al
  2109.         jnz     su2
  2110.         call    get_mpu_in
  2111.         cmp     al, 0xfe
  2112.         jnz     su2
  2113. su3:
  2114.         call    is_output
  2115.         test    al, al
  2116.         jnz     su3
  2117.         mov     dx, word [midisp]
  2118.         mov     al, 0x3f
  2119.         out     dx, al
  2120.         ret
  2121. smn1:
  2122.         dec     ebx
  2123.         jnz     smn2
  2124. sm10:
  2125.         call    get_mpu_in
  2126.         call    is_output
  2127.         test    al, al
  2128.         jnz     sm10
  2129.         mov     al, bl
  2130.         call    put_mpu_out
  2131.         smn2:
  2132.         ret
  2133.  
  2134. detect_devices:
  2135. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2136. ;include 'detect/commouse.inc'
  2137. ;include 'detect/ps2mouse.inc'
  2138. ;include 'detect/dev_fd.inc'
  2139. ;include 'detect/dev_hdcd.inc'
  2140. ;include 'detect/sear_par.inc'
  2141. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2142.         ret
  2143.  
  2144. sys_end:
  2145. ;--------------------------------------
  2146.         cmp     [_display.select_cursor], 0
  2147.         je      @f
  2148. ; restore default cursor before killing
  2149.         pusha
  2150.         mov     ecx, [current_slot]
  2151.         call    restore_default_cursor_before_killing
  2152.         popa
  2153. @@:
  2154. ;--------------------------------------
  2155. ; kill all sockets this process owns
  2156.         pusha
  2157.         mov     edx, [TASK_BASE]
  2158.         mov     edx, [edx+TASKDATA.pid]
  2159.         call    SOCKET_process_end
  2160.         popa
  2161. ;--------------------------------------
  2162.         mov     ecx, [current_slot]
  2163.         mov     eax, [ecx+APPDATA.tls_base]
  2164.         test    eax, eax
  2165.         jz      @F
  2166.  
  2167.         stdcall user_free, eax
  2168. @@:
  2169.  
  2170.         mov     eax, [TASK_BASE]
  2171.         mov     [eax+TASKDATA.state], 3; terminate this program
  2172.         call    wakeup_osloop
  2173.  
  2174. .waitterm:            ; wait here for termination
  2175.         call    change_task
  2176.         jmp     .waitterm
  2177. ;------------------------------------------------------------------------------
  2178. align 4
  2179. restore_default_cursor_before_killing:
  2180.         pushfd
  2181.         cli
  2182.         mov     eax, [def_cursor]
  2183.         mov     [ecx+APPDATA.cursor], eax
  2184.  
  2185.         movzx   eax, word [MOUSE_Y]
  2186.         movzx   ebx, word [MOUSE_X]
  2187.         mov     eax, [d_width_calc_area + eax*4]
  2188.  
  2189.         add     eax, [_display.win_map]
  2190.         movzx   edx, byte [ebx+eax]
  2191.         shl     edx, 8
  2192.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2193.  
  2194.         cmp     esi, [current_cursor]
  2195.         je      @f
  2196.  
  2197.         push    esi
  2198.         call    [_display.select_cursor]
  2199.         mov     [current_cursor], esi
  2200. @@:
  2201.         mov     [redrawmouse_unconditional], 1
  2202.         call    wakeup_osloop
  2203.         popfd
  2204.         ret
  2205. ;------------------------------------------------------------------------------
  2206. iglobal
  2207. align 4
  2208. sys_system_table:
  2209.         dd      sysfn_deactivate        ; 1 = deactivate window
  2210.         dd      sysfn_terminate         ; 2 = terminate thread
  2211.         dd      sysfn_activate          ; 3 = activate window
  2212.         dd      sysfn_getidletime       ; 4 = get idle time
  2213.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2214.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2215.         dd      sysfn_getactive         ; 7 = get active window
  2216.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2217.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2218.         dd      sysfn_minimize          ; 10 = minimize window
  2219.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2220.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2221.         dd      sysfn_getversion        ; 13 = get kernel version
  2222.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2223.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2224.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2225.         dd      sysfn_getallmem         ; 17 = get total memory size
  2226.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2227.                                         ;                 instead of slot
  2228.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2229.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2230.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2231.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2232.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2233.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2234.  
  2235.         dd      sysfn_zmodif            ; 25 = get/set window z modifier  ;Fantomer
  2236. sysfn_num = ($ - sys_system_table)/4
  2237. endg
  2238. ;------------------------------------------------------------------------------
  2239. sys_system:
  2240.         dec     ebx
  2241.         cmp     ebx, sysfn_num
  2242.         jae     @f
  2243.         jmp     dword [sys_system_table + ebx*4]
  2244. @@:
  2245.         ret
  2246. ;------------------------------------------------------------------------------
  2247. sysfn_shutdown:          ; 18.9 = system shutdown
  2248.         cmp     ecx, 1
  2249.         jl      exit_for_anyone
  2250.         cmp     ecx, 4
  2251.         jg      exit_for_anyone
  2252.         mov     [BOOT_VARS+0x9030], cl
  2253.  
  2254.         mov     eax, [TASK_COUNT]
  2255.         mov     [SYS_SHUTDOWN], al
  2256.         mov     [shutdown_processes], eax
  2257.         call    wakeup_osloop
  2258.         and     dword [esp+32], 0
  2259.  exit_for_anyone:
  2260.         ret
  2261.   uglobal
  2262.    shutdown_processes:
  2263.                        dd 0x0
  2264.   endg
  2265. ;------------------------------------------------------------------------------
  2266. sysfn_terminate:        ; 18.2 = TERMINATE
  2267.         push    ecx
  2268.         cmp     ecx, 2
  2269.         jb      noprocessterminate
  2270.         mov     edx, [TASK_COUNT]
  2271.         cmp     ecx, edx
  2272.         ja      noprocessterminate
  2273.         mov     eax, [TASK_COUNT]
  2274.         shl     ecx, 5
  2275.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2276.         add     ecx, CURRENT_TASK+TASKDATA.state
  2277.         cmp     byte [ecx], 9
  2278.         jz      noprocessterminate
  2279.         push    ecx edx
  2280.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2281.         call    request_terminate
  2282.         pop     edx ecx
  2283.         test    eax, eax
  2284.         jz      noprocessterminate
  2285. ;--------------------------------------
  2286. ; terminate all network sockets it used
  2287.         pusha
  2288.         mov     eax, edx
  2289.         call    SOCKET_process_end
  2290.         popa
  2291. ;--------------------------------------
  2292.         cmp     [_display.select_cursor], 0
  2293.         je      .restore_end
  2294. ; restore default cursor before killing
  2295.         pusha
  2296.         mov     ecx, [esp+32]
  2297.         shl     ecx, 8
  2298.         add     ecx, SLOT_BASE
  2299.         mov     eax, [def_cursor]
  2300.         cmp     [ecx+APPDATA.cursor], eax
  2301.         je      @f
  2302.         call    restore_default_cursor_before_killing
  2303. @@:
  2304.         popa
  2305. .restore_end:
  2306. ;--------------------------------------
  2307.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2308.         mov     [ecx], byte 3; clear possible i40's
  2309.         call    wakeup_osloop
  2310.      ;call MEM_Heap_UnLock
  2311.  
  2312.         cmp     edx, [application_table_owner]; clear app table stat
  2313.         jne     noatsc
  2314.         call    unlock_application_table
  2315. noatsc:
  2316. noprocessterminate:
  2317.         add     esp, 4
  2318.         ret
  2319. ;------------------------------------------------------------------------------
  2320. sysfn_terminate2:
  2321. ;lock application_table_status mutex
  2322. .table_status:
  2323.         call    lock_application_table
  2324.         mov     eax, ecx
  2325.         call    pid_to_slot
  2326.         test    eax, eax
  2327.         jz      .not_found
  2328.         mov     ecx, eax
  2329.         cli
  2330.         call    sysfn_terminate
  2331.         call    unlock_application_table
  2332.         sti
  2333.         and     dword [esp+32], 0
  2334.         ret
  2335. .not_found:
  2336.         call    unlock_application_table
  2337.         or      dword [esp+32], -1
  2338.         ret
  2339. ;------------------------------------------------------------------------------
  2340. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2341.         cmp     ecx, 2
  2342.         jb      .nowindowdeactivate
  2343.         cmp     ecx, [TASK_COUNT]
  2344.         ja      .nowindowdeactivate
  2345.  
  2346.         movzx   esi, word [WIN_STACK + ecx*2]
  2347.         cmp     esi, 1
  2348.         je      .nowindowdeactivate ; already deactive
  2349.  
  2350.         mov     edi, ecx
  2351.         shl     edi, 5
  2352.         add     edi, window_data
  2353.         movzx   esi, word [WIN_STACK + ecx * 2]
  2354.         lea     esi, [WIN_POS + esi * 2]
  2355.         call    window._.window_deactivate
  2356.  
  2357.         call    syscall_display_settings._.calculate_whole_screen
  2358.         call    syscall_display_settings._.redraw_whole_screen
  2359. .nowindowdeactivate:
  2360.         ret
  2361. ;------------------------------------------------------------------------------
  2362. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2363.         cmp     ecx, 2
  2364.         jb      .nowindowactivate
  2365.         cmp     ecx, [TASK_COUNT]
  2366.         ja      .nowindowactivate
  2367. ;-------------------------------------
  2368. @@:
  2369. ; If the window is captured and moved by the user,
  2370. ; then you can't change the position in window stack!!!
  2371.         mov     al, [mouse.active_sys_window.action]
  2372.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2373.         test    al, al
  2374.         jz      @f
  2375.         call    change_task
  2376.         jmp     @b
  2377. @@:
  2378. ;-------------------------------------
  2379.         mov     [window_minimize], 2; restore window if minimized
  2380.         call    wakeup_osloop
  2381.  
  2382.         movzx   esi, word [WIN_STACK + ecx*2]
  2383.         cmp     esi, [TASK_COUNT]
  2384.         je      .nowindowactivate; already active
  2385.  
  2386.         mov     edi, ecx
  2387.         shl     edi, 5
  2388.         add     edi, window_data
  2389.         movzx   esi, word [WIN_STACK + ecx * 2]
  2390.         lea     esi, [WIN_POS + esi * 2]
  2391.         call    waredraw
  2392. .nowindowactivate:
  2393.         ret
  2394. ;------------------------------------------------------------------------------
  2395. align 4                         ;Fantomer
  2396. sysfn_zmodif:
  2397. ;18,25,1 - get z_modif
  2398. ;18,25,2 - set z_modif
  2399. ;edx = -1(for current task) or TID
  2400. ;esi(for 2) = new value z_modif
  2401. ;return:
  2402. ;1:   eax = z_modif
  2403. ;2: eax=0(fail),1(success) for set z_modif
  2404.  
  2405.         xor     eax, eax
  2406.  
  2407.         cmp     edx, -1
  2408.         jne     @f
  2409.         mov     edx, [CURRENT_TASK]
  2410.      @@:
  2411.         cmp     edx, [TASK_COUNT]
  2412.         ja      .exit
  2413.         cmp     edx, 1
  2414.         je      .exit
  2415.  
  2416.  
  2417.         shl     edx, 5
  2418.  
  2419.         cmp     [edx + CURRENT_TASK + TASKDATA.state], 9
  2420.         je      .exit
  2421.  
  2422.         cmp     ecx, 1
  2423.         jnz     .set_zmod
  2424.  
  2425.         mov     al, [edx + window_data + WDATA.z_modif]
  2426.  
  2427.         jmp     .exit
  2428. align 4
  2429. .set_zmod:
  2430.         cmp     ecx, 2
  2431.         jnz     .exit
  2432.  
  2433.         mov     eax, esi
  2434.         mov     esi, edx
  2435.  
  2436.         cmp     al, ZPOS_ALWAYS_TOP
  2437.         ja      .exit
  2438.  
  2439.         mov     [edx + window_data + WDATA.z_modif], al
  2440.  
  2441.         mov     eax, [edx + window_data + WDATA.box.left]
  2442.         mov     ebx, [edx + window_data + WDATA.box.top]
  2443.         mov     ecx, [edx + window_data + WDATA.box.width]
  2444.         mov     edx, [edx + window_data + WDATA.box.height]
  2445.         add     ecx, eax
  2446.         add     edx, ebx
  2447.         call    window._.set_top_wnd
  2448.  
  2449.         mov     eax, 1
  2450. align 4
  2451. .exit:
  2452.         mov     [esp+32], eax
  2453.         ret
  2454.  
  2455. ;------------------------------------------------------------------------------
  2456. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2457.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2458.         mov     [esp+32], eax
  2459.         ret
  2460. ;------------------------------------------------------------------------------
  2461. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2462.         mov     eax, dword [cpu_freq]
  2463.         mov     [esp+32], eax
  2464.         ret
  2465. ;------------------------------------------------------------------------------
  2466. get_cpu_freq:
  2467.         mov     eax, dword [cpu_freq]
  2468.         mov     edx, dword [cpu_freq+4]
  2469.         ret
  2470. ;  SAVE ramdisk to /hd/1/menuet.img
  2471. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2472.    include 'blkdev/rdsave.inc'
  2473. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2474. ;------------------------------------------------------------------------------
  2475. align 4
  2476. sysfn_getactive:        ; 18.7 = get active window
  2477.         mov     eax, [TASK_COUNT]
  2478.         movzx   eax, word [WIN_POS + eax*2]
  2479.         mov     [esp+32], eax
  2480.         ret
  2481. ;------------------------------------------------------------------------------
  2482. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2483. ;     cmp  ecx,1
  2484.         dec     ecx
  2485.         jnz     nogetsoundflag
  2486.         movzx   eax, byte [sound_flag]; get sound_flag
  2487.         mov     [esp+32], eax
  2488.         ret
  2489.  nogetsoundflag:
  2490. ;     cmp  ecx,2
  2491.         dec     ecx
  2492.         jnz     nosoundflag
  2493.         xor     byte [sound_flag], 1
  2494.  nosoundflag:
  2495.         ret
  2496. ;------------------------------------------------------------------------------
  2497. sysfn_minimize:         ; 18.10 = minimize window
  2498.         mov     [window_minimize], 1
  2499.         call    wakeup_osloop
  2500.         ret
  2501. ;------------------------------------------------------------------------------
  2502. align 4
  2503. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2504.         dec     ecx
  2505.         jnz     .exit
  2506. .small_table:
  2507.         mov     edi, edx
  2508.         mov     esi, DRIVE_DATA
  2509.         mov     ecx, DRIVE_DATA_SIZE ;10
  2510.         cld
  2511.         rep movsb
  2512. .exit:
  2513.         ret
  2514. ;------------------------------------------------------------------------------
  2515. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2516.         and     dword [esp+32], 0
  2517.         ret
  2518. ;------------------------------------------------------------------------------
  2519. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2520.         mov     edi, ecx
  2521.         mov     esi, version_inf
  2522.         mov     ecx, version_end-version_inf
  2523.         rep movsb
  2524.         ret
  2525. ;------------------------------------------------------------------------------
  2526. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2527.      ;wait retrace functions
  2528.  sys_wait_retrace:
  2529.         mov     edx, 0x3da
  2530.  WaitRetrace_loop:
  2531.         in      al, dx
  2532.         test    al, 1000b
  2533.         jz      WaitRetrace_loop
  2534.         and     [esp+32], dword 0
  2535.         ret
  2536. ;------------------------------------------------------------------------------
  2537. align 4
  2538. sysfn_centermouse:      ; 18.15 = mouse centered
  2539. ; removed here by <Lrz>
  2540. ;     call  mouse_centered
  2541. ;* mouse centered - start code- Mario79
  2542. ;mouse_centered:
  2543. ;        push  eax
  2544.         mov     eax, [_display.width]
  2545.         shr     eax, 1
  2546.         mov     [MOUSE_X], ax
  2547.         mov     eax, [_display.height]
  2548.         shr     eax, 1
  2549.         mov     [MOUSE_Y], ax
  2550.         call    wakeup_osloop
  2551. ;        ret
  2552. ;* mouse centered - end code- Mario79
  2553.         xor     eax, eax
  2554.         and     [esp+32], eax
  2555. ;        pop   eax
  2556.         ret
  2557. ;------------------------------------------------------------------------------
  2558. align 4
  2559. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2560.         test    ecx, ecx; get mouse speed factor
  2561.         jnz     .set_mouse_acceleration
  2562.         xor     eax, eax
  2563.         mov     ax, [mouse_speed_factor]
  2564.         mov     [esp+32], eax
  2565.         ret
  2566.  .set_mouse_acceleration:
  2567. ;     cmp  ecx,1  ; set mouse speed factor
  2568.         dec     ecx
  2569.         jnz     .get_mouse_delay
  2570.         mov     [mouse_speed_factor], dx
  2571.         ret
  2572.  .get_mouse_delay:
  2573. ;     cmp  ecx,2  ; get mouse delay
  2574.         dec     ecx
  2575.         jnz     .set_mouse_delay
  2576.         mov     eax, [mouse_delay]
  2577.         mov     [esp+32], eax
  2578.         ret
  2579.  .set_mouse_delay:
  2580. ;     cmp  ecx,3  ; set mouse delay
  2581.         dec     ecx
  2582.         jnz     .set_pointer_position
  2583.         mov     [mouse_delay], edx
  2584.         ret
  2585.  .set_pointer_position:
  2586. ;     cmp  ecx,4  ; set mouse pointer position
  2587.         dec     ecx
  2588.         jnz     .set_mouse_button
  2589.         cmp     dx, word[_display.height]
  2590.         jae     .end
  2591.         rol     edx, 16
  2592.         cmp     dx, word[_display.width]
  2593.         jae     .end
  2594.         mov     [MOUSE_X], edx
  2595.         mov     [mouse_active], 1
  2596.         call    wakeup_osloop
  2597.         ret
  2598.  .set_mouse_button:
  2599. ;     cmp   ecx,5  ; set mouse button features
  2600.         dec     ecx
  2601.         jnz     .end
  2602.         mov     [BTN_DOWN], dl
  2603.         mov     [mouse_active], 1
  2604.         call    wakeup_osloop
  2605.  .end:
  2606.         ret
  2607. ;------------------------------------------------------------------------------
  2608. sysfn_getfreemem:
  2609.         mov     eax, [pg_data.pages_free]
  2610.         shl     eax, 2
  2611.         mov     [esp+32], eax
  2612.         ret
  2613. ;------------------------------------------------------------------------------
  2614. sysfn_getallmem:
  2615.         mov     eax, [MEM_AMOUNT]
  2616.         shr     eax, 10
  2617.         mov     [esp+32], eax
  2618.         ret
  2619. ;------------------------------------------------------------------------------
  2620. sysfn_pid_to_slot:
  2621.         mov     eax, ecx
  2622.         call    pid_to_slot
  2623.         mov     [esp+32], eax
  2624.         ret
  2625. ;------------------------------------------------------------------------------
  2626. sysfn_min_rest_window:
  2627.         pushad
  2628.         mov     eax, edx ; ebx - operating
  2629.         shr     ecx, 1
  2630.         jnc     @f
  2631.         call    pid_to_slot
  2632. @@:
  2633.         or      eax, eax ; eax - number of slot
  2634.         jz      .error
  2635.         cmp     eax, 255    ; varify maximal slot number
  2636.         ja      .error
  2637.         movzx   eax, word [WIN_STACK + eax*2]
  2638.         shr     ecx, 1
  2639.         jc      .restore
  2640.  ; .minimize:
  2641.         call    minimize_window
  2642.         jmp     .exit
  2643. .restore:
  2644.         call    restore_minimized_window
  2645. .exit:
  2646.         popad
  2647.         xor     eax, eax
  2648.         mov     [esp+32], eax
  2649.         ret
  2650. .error:
  2651.         popad
  2652.         xor     eax, eax
  2653.         dec     eax
  2654.         mov     [esp+32], eax
  2655.         ret
  2656. ;------------------------------------------------------------------------------
  2657. sysfn_min_windows:
  2658.         call    minimize_all_window
  2659.         mov     [esp+32], eax
  2660.         call    change_task
  2661.         ret
  2662. ;------------------------------------------------------------------------------
  2663. sysfn_set_screen_sizes:
  2664.         cmp     [SCR_MODE], word 0x13
  2665.         jbe     .exit
  2666.  
  2667.         cmp     [_display.select_cursor], select_cursor
  2668.         jne     .exit
  2669.  
  2670.         cmp     ecx, [display_width_standard]
  2671.         ja      .exit
  2672.  
  2673.         cmp     edx, [display_height_standard]
  2674.         ja      .exit
  2675.  
  2676.         pushfd
  2677.         cli
  2678.         mov     eax, ecx
  2679.         mov     ecx, [_display.lfb_pitch]
  2680.         mov     [_display.width], eax
  2681.         dec     eax
  2682.         mov     [_display.height], edx
  2683.         dec     edx
  2684. ; eax - new Screen_Max_X
  2685. ; edx - new Screen_Max_Y
  2686.         mov     [do_not_touch_winmap], 1
  2687.         call    set_screen
  2688.         mov     [do_not_touch_winmap], 0
  2689.         popfd
  2690.         call    change_task
  2691. .exit:
  2692.         ret
  2693. ;------------------------------------------------------------------------------
  2694. uglobal
  2695. screen_workarea RECT
  2696. display_width_standard dd 0
  2697. display_height_standard dd 0
  2698. do_not_touch_winmap db 0
  2699. window_minimize db 0
  2700. sound_flag      db 0
  2701.  
  2702. endg
  2703.  
  2704. UID_NONE=0
  2705. UID_MENUETOS=1   ;official
  2706. UID_KOLIBRI=2    ;russian
  2707.  
  2708. iglobal
  2709. version_inf:
  2710.         db 0,7,7,0  ; version 0.7.7.0
  2711.         db 0
  2712. .rev    dd __REV__
  2713. version_end:
  2714. endg
  2715. ;------------------------------------------------------------------------------
  2716. align 4
  2717. sys_cachetodiskette:
  2718.         cmp     ebx, 1
  2719.         jb      .no_floppy_save
  2720.         cmp     ebx, 2
  2721.         ja      .no_floppy_save
  2722.         call    save_image
  2723.         mov     [esp + 32], eax
  2724.         ret
  2725. .no_floppy_save:
  2726.         mov     [esp + 32], dword 1
  2727.         ret
  2728. ;------------------------------------------------------------------------------
  2729. uglobal
  2730. ;  bgrchanged  dd  0x0
  2731. align 4
  2732. bgrlockpid dd 0
  2733. bgrlock db 0
  2734. endg
  2735. ;------------------------------------------------------------------------------
  2736. align 4
  2737. sys_background:
  2738.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2739.         jnz     nosb1
  2740.         test    ecx, ecx
  2741.         jz      sbgrr
  2742.  
  2743.         test    edx, edx
  2744.         jz      sbgrr
  2745. ;--------------------------------------
  2746. align 4
  2747. @@:
  2748. ;;Maxis use atomic bts for mutexes  4.4.2009
  2749.         bts     dword [bgrlock], 0
  2750.         jnc     @f
  2751.         call    change_task
  2752.         jmp     @b
  2753. ;--------------------------------------
  2754. align 4
  2755. @@:
  2756.         mov     [BgrDataWidth], ecx
  2757.         mov     [BgrDataHeight], edx
  2758. ;    mov   [bgrchanged],1
  2759.  
  2760.         pushad
  2761. ; return memory for old background
  2762.         mov     eax, [img_background]
  2763.         cmp     eax, static_background_data
  2764.         jz      @f
  2765.         stdcall kernel_free, eax
  2766. ;--------------------------------------
  2767. align 4
  2768. @@:
  2769. ; calculate RAW size
  2770.         xor     eax, eax
  2771.         inc     eax
  2772.         cmp     [BgrDataWidth], eax
  2773.         jae     @f
  2774.         mov     [BgrDataWidth], eax
  2775. ;--------------------------------------
  2776. align 4
  2777. @@:
  2778.         cmp     [BgrDataHeight], eax
  2779.         jae     @f
  2780.         mov     [BgrDataHeight], eax
  2781. ;--------------------------------------
  2782. align 4
  2783. @@:
  2784.         mov     eax, [BgrDataWidth]
  2785.         imul    eax, [BgrDataHeight]
  2786.         lea     eax, [eax*3]
  2787. ; it is reserved with aligned to the boundary of 4 KB pages,
  2788. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2789. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2790.         shr     eax, 12
  2791.         inc     eax
  2792.         shl     eax, 12
  2793.         mov     [mem_BACKGROUND], eax
  2794. ; get memory for new background
  2795.         stdcall kernel_alloc, eax
  2796.         test    eax, eax
  2797.         jz      .memfailed
  2798.         mov     [img_background], eax
  2799.         jmp     .exit
  2800. ;--------------------------------------
  2801. align 4
  2802. .memfailed:
  2803. ; revert to static monotone data
  2804.         mov     [img_background], static_background_data
  2805.         xor     eax, eax
  2806.         inc     eax
  2807.         mov     [BgrDataWidth], eax
  2808.         mov     [BgrDataHeight], eax
  2809.         mov     [mem_BACKGROUND], 4
  2810. ;--------------------------------------
  2811. align 4
  2812. .exit:
  2813.         popad
  2814.         mov     [bgrlock], 0
  2815. ;--------------------------------------
  2816. align 4
  2817. sbgrr:
  2818.         ret
  2819. ;------------------------------------------------------------------------------
  2820. align 4
  2821. nosb1:
  2822.         cmp     ebx, 2                     ; SET PIXEL
  2823.         jnz     nosb2
  2824.  
  2825.         mov     eax, [img_background]
  2826.         test    ecx, ecx
  2827.         jz      @f
  2828.         cmp     eax, static_background_data
  2829.         jz      .ret
  2830. ;--------------------------------------
  2831. align 4
  2832. @@:
  2833.         mov     ebx, [mem_BACKGROUND]
  2834.         add     ebx, 4095
  2835.         and     ebx, -4096
  2836.         sub     ebx, 4
  2837.         cmp     ecx, ebx
  2838.         ja      .ret
  2839.  
  2840.         mov     ebx, [eax+ecx]
  2841.         and     ebx, 0xFF000000;255*256*256*256
  2842.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2843.         add     edx, ebx
  2844.         mov     [eax+ecx], edx
  2845. ;--------------------------------------
  2846. align 4
  2847. .ret:
  2848.         ret
  2849. ;------------------------------------------------------------------------------
  2850. align 4
  2851. nosb2:
  2852.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2853.         jnz     nosb3
  2854. ;--------------------------------------
  2855. align 4
  2856. draw_background_temp:
  2857.         mov     [background_defined], 1
  2858.         call    force_redraw_background
  2859. ;--------------------------------------
  2860. align 4
  2861. nosb31:
  2862.         ret
  2863. ;------------------------------------------------------------------------------
  2864. align 4
  2865. nosb3:
  2866.         cmp     ebx, 4                     ; TILED / STRETCHED
  2867.         jnz     nosb4
  2868.         cmp     ecx, [BgrDrawMode]
  2869.         je      nosb41
  2870.         mov     [BgrDrawMode], ecx
  2871. ;--------------------------------------
  2872. align 4
  2873. nosb41:
  2874.         ret
  2875. ;------------------------------------------------------------------------------
  2876. align 4
  2877. nosb4: