Subversion Repositories Kolibri OS

Rev

Rev 5363 | Rev 5635 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2015. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 5595 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_BIOS32
  287. ; MEMORY MODEL
  288.         call    mem_test
  289.         call    init_mem
  290.         call    init_page_map
  291.  
  292. ; ENABLE PAGING
  293.  
  294.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  295.         mov     cr3, eax
  296.  
  297.         mov     eax, cr0
  298.         or      eax, CR0_PG+CR0_WP
  299.         mov     cr0, eax
  300.  
  301.         lgdt    [gdts]
  302.         jmp     pword os_code:high_code
  303.  
  304. align 4
  305. bios32_entry    dd ?
  306. tmp_page_tabs   dd ?
  307.  
  308. use16
  309. org $-0x10000
  310. include "boot/shutdown.inc" ; shutdown or restart
  311. org $+0x10000
  312.  
  313. ap_init16:
  314.         cli
  315.         lgdt    [cs:gdts_ap-ap_init16]
  316.         mov     eax, [cs:cr3_ap-ap_init16]
  317.         mov     cr3, eax
  318.         mov     eax, [cs:cr4_ap-ap_init16]
  319.         mov     cr4, eax
  320.         mov     eax, CR0_PE+CR0_PG+CR0_WP
  321.         mov     cr0, eax
  322.         jmp     pword os_code:ap_init_high
  323. align 16
  324. gdts_ap:
  325.         dw     gdte-gdts-1
  326.         dd     gdts
  327.         dw     0
  328. cr3_ap  dd     ?
  329. cr4_ap  dd     ?
  330. ap_init16_size = $ - ap_init16
  331. use32
  332.  
  333. __DEBUG__ fix 1
  334. __DEBUG_LEVEL__ fix 1
  335. include 'init.inc'
  336.  
  337. org OS_BASE+$
  338.  
  339. include 'fdo.inc'
  340.  
  341. align 4
  342. high_code:
  343.         mov     ax, os_stack
  344.         mov     bx, app_data
  345.         mov     cx, app_tls
  346.         mov     ss, ax
  347.         add     esp, OS_BASE
  348.  
  349.         mov     ds, bx
  350.         mov     es, bx
  351.         mov     fs, cx
  352.         mov     gs, bx
  353.  
  354.         xor     eax, eax
  355.         mov     ebx, 0xFFFFF000+PG_SHARED+PG_NOCACHE+PG_UWR
  356.         bt      [cpu_caps], CAPS_PAT
  357.         setc    al
  358.         shl     eax, 7
  359.         or      ebx, eax
  360.  
  361.         mov     eax, PG_GLOBAL
  362.         bt      [cpu_caps], CAPS_PGE
  363.         jnc     @F
  364.  
  365.         or      [sys_proc+PROC.pdt_0+(OS_BASE shr 20)], eax
  366.         or      ebx, eax
  367.  
  368.         mov     eax, cr4
  369.         or      eax, CR4_PGE
  370.         mov     cr4, eax
  371. @@:
  372.         mov     [pte_valid_mask], ebx
  373.  
  374.         xor     eax, eax
  375.         mov     dword [sys_proc+PROC.pdt_0], eax
  376.         mov     dword [sys_proc+PROC.pdt_0+4], eax
  377.  
  378.         mov     eax, cr3
  379.         mov     cr3, eax          ; flush TLB
  380.  
  381.         mov     ecx, pg_data.mutex
  382.         call    mutex_init
  383.  
  384.         mov     ecx, disk_list_mutex
  385.         call    mutex_init
  386.  
  387.         mov     ecx, keyboard_list_mutex
  388.         call    mutex_init
  389.  
  390.         mov     ecx, unpack_mutex
  391.         call    mutex_init
  392.  
  393.         mov     ecx, application_table_mutex
  394.         call    mutex_init
  395.  
  396.         mov     ecx, ide_mutex
  397.         call    mutex_init
  398.         mov     ecx, ide_channel1_mutex
  399.         call    mutex_init
  400.         mov     ecx, ide_channel2_mutex
  401.         call    mutex_init
  402.         mov     ecx, ide_channel3_mutex
  403.         call    mutex_init
  404.         mov     ecx, ide_channel4_mutex
  405.         call    mutex_init
  406.         mov     ecx, ide_channel5_mutex
  407.         call    mutex_init
  408.         mov     ecx, ide_channel6_mutex
  409.         call    mutex_init
  410. ;-----------------------------------------------------------------------------
  411. ; SAVE REAL MODE VARIABLES
  412. ;-----------------------------------------------------------------------------
  413. ; --------------- APM ---------------------
  414.  
  415. ; init selectors
  416.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  417.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  418.                                                                                 ; protected-mode 32-bit code segment
  419.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  420.                                                                                 ; protected-mode 16-bit code segment
  421.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  422.                                                                                 ; protected-mode 16-bit data segment
  423.  
  424.         shl     eax, 4
  425.         mov     [dword apm_code_32 + 2], ax
  426.         shr     eax, 16
  427.         mov     [dword apm_code_32 + 4], al
  428.  
  429.         shl     ecx, 4
  430.         mov     [dword apm_code_16 + 2], cx
  431.         shr     ecx, 16
  432.         mov     [dword apm_code_16 + 4], cl
  433.  
  434.         shl     edx, 4
  435.         mov     [dword apm_data_16 + 2], dx
  436.         shr     edx, 16
  437.         mov     [dword apm_data_16 + 4], dl
  438.  
  439.         mov     dword[apm_entry], ebx
  440.         mov     word [apm_entry + 4], apm_code_32 - gdts
  441.  
  442.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  443.         mov     [apm_vf], eax
  444. ; -----------------------------------------
  445.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  446.         mov     [allow_dma_access], al
  447.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  448.         mov     [_display.bits_per_pixel], eax
  449.         mov     [_display.vrefresh], 60
  450.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  451.         mov     [debug_direct_print], al
  452.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  453.         mov     [launcher_start], al
  454.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  455.         mov     [_display.width], eax
  456.         mov     [display_width_standard], eax
  457.         dec     eax
  458.         mov     [screen_workarea.right], eax
  459.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  460.         mov     [_display.height], eax
  461.         mov     [display_height_standard], eax
  462.         dec     eax
  463.         mov     [screen_workarea.bottom], eax
  464.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  465.         mov     dword [SCR_MODE], eax
  466. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  467. ;        mov     [BANK_SWITCH], eax
  468.         mov     eax, 640 *4                         ; Bytes PerScanLine
  469.         cmp     [SCR_MODE], word 0x13               ; 320x200
  470.         je      @f
  471.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  472.         je      @f
  473.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  474. @@:
  475.         mov     [_display.lfb_pitch], eax
  476.         mov     eax, [_display.width]
  477.         mul     [_display.height]
  478.         mov     [_display.win_map_size], eax
  479.  
  480.         call    calculate_fast_getting_offset_for_WinMapAddress
  481. ; for Qemu or non standart video cards
  482. ; Unfortunately [BytesPerScanLine] does not always
  483. ;                             equal to [_display.width] * [ScreenBPP] / 8
  484.         call    calculate_fast_getting_offset_for_LFB
  485.  
  486.         mov     esi, BOOT_VARS+0x9080
  487.         movzx   ecx, byte [esi-1]
  488.         mov     [NumBiosDisks], ecx
  489.         mov     edi, BiosDisksData
  490.         rep movsd
  491.  
  492. setvideomode:
  493.  
  494.         mov     eax, [BOOT_VARS+BOOT_LFB]
  495.         mov     [LFBAddress], eax
  496.  
  497.         cmp     word [SCR_MODE], 0x0012                 ; VGA (640x480 16 colors)
  498.         je      .vga
  499.         cmp     word [SCR_MODE], 0x0013                 ; MCGA (320*200 256 colors)
  500.         je      .32bpp
  501.         cmp     byte [_display.bits_per_pixel], 32
  502.         je      .32bpp
  503.         cmp     byte [_display.bits_per_pixel], 24
  504.         je      .24bpp
  505.         cmp     byte [_display.bits_per_pixel], 16
  506.         je      .16bpp
  507. ;        cmp     byte [_display.bits_per_pixel], 15
  508. ;        je      .15bpp
  509.  
  510.   .vga:
  511.         mov     [PUTPIXEL], VGA_putpixel
  512.         mov     [GETPIXEL], Vesa20_getpixel32           ; Conversion buffer is 32 bpp
  513.         mov     [_display.bytes_per_pixel], 4           ; Conversion buffer is 32 bpp
  514.         jmp     .finish
  515.  
  516. ;  .15bpp:
  517. ;        mov     [PUTPIXEL], Vesa20_putpixel15
  518. ;        mov     [GETPIXEL], Vesa20_getpixel15
  519. ;        mov     [_display.bytes_per_pixel], 2
  520. ;        jmp     .finish
  521.  
  522.   .16bpp:
  523.         mov     [PUTPIXEL], Vesa20_putpixel16
  524.         mov     [GETPIXEL], Vesa20_getpixel16
  525.         mov     [_display.bytes_per_pixel], 2
  526.         jmp     .finish
  527.  
  528.   .24bpp:
  529.         mov     [PUTPIXEL], Vesa20_putpixel24
  530.         mov     [GETPIXEL], Vesa20_getpixel24
  531.         mov     [_display.bytes_per_pixel], 3
  532.         jmp     .finish
  533.  
  534.   .32bpp:
  535.         mov     [PUTPIXEL], Vesa20_putpixel32
  536.         mov     [GETPIXEL], Vesa20_getpixel32
  537.         mov     [_display.bytes_per_pixel], 4
  538. ;        jmp     .finish
  539.  
  540.   .finish:
  541.         mov     [MOUSE_PICTURE], mousepointer
  542.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  543.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  544.  
  545. ; -------- Fast System Call init ----------
  546. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  547.         bt      [cpu_caps], CAPS_SEP
  548.         jnc     .SEnP  ; SysEnter not Present
  549.         xor     edx, edx
  550.         mov     ecx, MSR_SYSENTER_CS
  551.         mov     eax, os_code
  552.         wrmsr
  553.         mov     ecx, MSR_SYSENTER_ESP
  554. ;           mov eax, sysenter_stack ; Check it
  555.         xor     eax, eax
  556.         wrmsr
  557.         mov     ecx, MSR_SYSENTER_EIP
  558.         mov     eax, sysenter_entry
  559.         wrmsr
  560. .SEnP:
  561. ; AMD SYSCALL/SYSRET
  562.         cmp     byte[cpu_vendor], 'A'
  563.         jne     .noSYSCALL
  564.         mov     eax, 0x80000001
  565.         cpuid
  566.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  567.         jz      .noSYSCALL
  568.         mov     ecx, MSR_AMD_EFER
  569.         rdmsr
  570.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  571.         wrmsr
  572.  
  573.         ; !!!! It`s dirty hack, fix it !!!
  574.         ; Bits of EDX :
  575.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  576.         ;  and the contents of this field, plus 8, are copied into the SS register.
  577.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  578.         ;  and the contents of this field, plus 8, are copied into the SS register.
  579.  
  580.         ; mov   edx, (os_code + 16) * 65536 + os_code
  581.         mov     edx, 0x1B0008
  582.  
  583.         mov     eax, syscall_entry
  584.         mov     ecx, MSR_AMD_STAR
  585.         wrmsr
  586. .noSYSCALL:
  587. ; -----------------------------------------
  588.         stdcall alloc_page
  589.         stdcall map_page, tss-0xF80, eax, PG_SWR
  590.         stdcall alloc_page
  591.         stdcall map_page, tss+0x80, eax, PG_SWR
  592.         stdcall alloc_page
  593.         stdcall map_page, tss+0x1080, eax, PG_SWR
  594.  
  595. ; LOAD IDT
  596.  
  597.         call    build_interrupt_table ;lidt is executed
  598.           ;lidt [idtreg]
  599.  
  600.         call    init_kernel_heap
  601.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  602.         mov     [os_stack_seg], eax
  603.  
  604.         lea     esp, [eax+RING0_STACK_SIZE]
  605.  
  606.         mov     [tss._ss0], os_stack
  607.         mov     [tss._esp0], esp
  608.         mov     [tss._esp], esp
  609.         mov     [tss._cs], os_code
  610.         mov     [tss._ss], os_stack
  611.         mov     [tss._ds], app_data
  612.         mov     [tss._es], app_data
  613.         mov     [tss._fs], app_data
  614.         mov     [tss._gs], app_data
  615.         mov     [tss._io], 128
  616. ;Add IO access table - bit array of permitted ports
  617.         mov     edi, tss._io_map_0
  618.         xor     eax, eax
  619.         not     eax
  620.         mov     ecx, 8192/4
  621.         rep stosd                    ; access to 4096*8=65536 ports
  622.  
  623.         mov     ax, tss0
  624.         ltr     ax
  625.  
  626.         mov     [LFBSize], 0xC00000
  627.         call    init_LFB
  628.         call    init_fpu
  629.         call    init_malloc
  630.  
  631.         stdcall alloc_kernel_space, 0x50000         ; FIXME check size
  632.         mov     [default_io_map], eax
  633.  
  634.         add     eax, 0x2000
  635.         mov     [ipc_tmp], eax
  636.         mov     ebx, 0x1000
  637.  
  638.         add     eax, 0x40000
  639.         mov     [proc_mem_map], eax
  640.  
  641.         add     eax, 0x8000
  642.         mov     [proc_mem_pdir], eax
  643.  
  644.         add     eax, ebx
  645.         mov     [proc_mem_tab], eax
  646.  
  647.         add     eax, ebx
  648.         mov     [tmp_task_ptab], eax
  649.  
  650.         add     eax, ebx
  651.         mov     [ipc_pdir], eax
  652.  
  653.         add     eax, ebx
  654.         mov     [ipc_ptab], eax
  655.  
  656.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  657.                 (unpack.lc+unpack.lp)))*4
  658.  
  659.         mov     [unpack.p], eax
  660.  
  661.         call    init_events
  662.         mov     eax, srv.fd-SRV.fd
  663.         mov     [srv.fd], eax
  664.         mov     [srv.bk], eax
  665.  
  666. ;Set base of graphic segment to linear address of LFB
  667.         mov     eax, [LFBAddress]         ; set for gs
  668.         mov     [graph_data_l+2], ax
  669.         shr     eax, 16
  670.         mov     [graph_data_l+4], al
  671.         mov     [graph_data_l+7], ah
  672.  
  673.         stdcall kernel_alloc, [_display.win_map_size]
  674.         mov     [_display.win_map], eax
  675.  
  676.         xor     eax, eax
  677.         inc     eax
  678.  
  679. ; set background
  680.  
  681.         mov     [BgrDrawMode], eax
  682.         mov     [BgrDataWidth], eax
  683.         mov     [BgrDataHeight], eax
  684.         mov     [mem_BACKGROUND], 4
  685.         mov     [img_background], static_background_data
  686.  
  687. ; set clipboard
  688.  
  689.         xor     eax, eax
  690.         mov     [clipboard_slots], eax
  691.         mov     [clipboard_write_lock], eax
  692.         stdcall kernel_alloc, 4096
  693.         test    eax, eax
  694.         jnz     @f
  695.  
  696.         dec     eax
  697. @@:
  698.         mov     [clipboard_main_list], eax
  699.  
  700. ; SET UP OS TASK
  701.  
  702.         mov     esi, boot_setostask
  703.         call    boot_log
  704.  
  705.         mov     eax, sys_proc
  706.         lea     edi, [eax+PROC.heap_lock]
  707.         mov     ecx, (PROC.ht_free-PROC.heap_lock)/4
  708.  
  709.         list_init eax
  710.         add     eax, PROC.thr_list
  711.         list_init eax
  712.  
  713.         xor     eax, eax
  714.         cld
  715.         rep stosd
  716.  
  717.         mov     [edi], dword (PROC.pdt_0 - PROC.htab)/4 - 3
  718.         mov     [edi+4], dword 3           ;reserve handles for stdin stdout and stderr
  719.         mov     ecx, (PROC.pdt_0 - PROC.htab)/4
  720.         add     edi, 8
  721.         inc     eax
  722. @@:
  723.         stosd
  724.         inc     eax
  725.         cmp     eax, ecx
  726.         jbe     @B
  727.  
  728.         mov     [sys_proc+PROC.pdt_0_phys], sys_proc-OS_BASE+PROC.pdt_0
  729.  
  730.         mov     eax, -1
  731.         mov     edi, thr_slot_map+4
  732.         mov     [edi-4], dword 0xFFFFFFF8
  733.         stosd
  734.         stosd
  735.         stosd
  736.         stosd
  737.         stosd
  738.         stosd
  739.         stosd
  740.  
  741.         mov     [current_process], sys_proc
  742.  
  743.         mov     edx, SLOT_BASE+256*1
  744.         mov     ebx, [os_stack_seg]
  745.         add     ebx, 0x2000
  746.         call    setup_os_slot
  747.         mov     dword [edx], 'IDLE'
  748.         sub     [edx+APPDATA.saved_esp], 4
  749.         mov     eax, [edx+APPDATA.saved_esp]
  750.         mov     dword [eax], idle_thread
  751.         mov     ecx, IDLE_PRIORITY
  752.         call    scheduler_add_thread
  753.  
  754.         mov     edx, SLOT_BASE+256*2
  755.         mov     ebx, [os_stack_seg]
  756.         call    setup_os_slot
  757.         mov     dword [edx], 'OS'
  758.         xor     ecx, ecx
  759.         call    scheduler_add_thread
  760.  
  761.         mov     dword [CURRENT_TASK], 2
  762.         mov     dword [TASK_COUNT], 2
  763.         mov     dword [current_slot], SLOT_BASE + 256*2
  764.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  765.  
  766. ; Move other CPUs to deep sleep, if it is useful
  767. uglobal
  768. use_mwait_for_idle db 0
  769. endg
  770.         cmp     [cpu_vendor+8], 'ntel'
  771.         jnz     .no_wake_cpus
  772.         bt      [cpu_caps+4], CAPS_MONITOR-32
  773.         jnc     .no_wake_cpus
  774.         dbgstr 'using mwait for idle loop'
  775.         inc     [use_mwait_for_idle]
  776.         mov     ebx, [cpu_count]
  777.         cmp     ebx, 1
  778.         jbe     .no_wake_cpus
  779.         call    create_trampoline_pgmap
  780.         mov     [cr3_ap+OS_BASE], eax
  781.         mov     eax, cr4
  782.         mov     [cr4_ap+OS_BASE], eax
  783.         mov     esi, OS_BASE + ap_init16
  784.         mov     edi, OS_BASE + 8000h
  785.         mov     ecx, (ap_init16_size + 3) / 4
  786.         rep movsd
  787.         stdcall map_io_mem, [acpi_lapic_base], 0x1000, PG_GLOBAL+PG_NOCACHE+PG_SWR
  788.         mov     [LAPIC_BASE], eax
  789.         lea     edi, [eax+300h]
  790.         mov     esi, smpt+4
  791.         dec     ebx
  792. .wake_cpus_loop:
  793.         lodsd
  794.         push    esi
  795.         xor     esi, esi
  796.         inc     esi
  797.         shl     eax, 24
  798.         mov     [edi+10h], eax
  799. ; assert INIT IPI
  800.         mov     dword [edi], 0C500h
  801.         call    delay_ms
  802. @@:
  803.         test    dword [edi], 1000h
  804.         jnz     @b
  805. ; deassert INIT IPI
  806.         mov     dword [edi], 8500h
  807.         call    delay_ms
  808. @@:
  809.         test    dword [edi], 1000h
  810.         jnz     @b
  811. ; send STARTUP IPI
  812.         mov     dword [edi], 600h + (8000h shr 12)
  813.         call    delay_ms
  814. @@:
  815.         test    dword [edi], 1000h
  816.         jnz     @b
  817.         pop     esi
  818.         dec     ebx
  819.         jnz     .wake_cpus_loop
  820.         mov     eax, [cpu_count]
  821.         dec     eax
  822. @@:
  823.         cmp     [ap_initialized], eax
  824.         jnz     @b
  825.         mov     eax, [cr3_ap+OS_BASE]
  826.         call    free_page
  827. .no_wake_cpus:
  828.  
  829. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  830.         mov     esi, boot_initirq
  831.         call    boot_log
  832.         call    init_irqs
  833.  
  834.         mov     esi, boot_picinit
  835.         call    boot_log
  836.         call    PIC_init
  837.  
  838.         mov     esi, boot_v86machine
  839.         call    boot_log
  840. ; Initialize system V86 machine
  841.         call    init_sys_v86
  842.  
  843.         mov     esi, boot_inittimer
  844.         call    boot_log
  845. ; Initialize system timer (IRQ0)
  846.         call    PIT_init
  847.  
  848. ; Register ramdisk file system
  849.         cmp     [boot_dev+OS_BASE+0x10000], 1
  850.         je      @f
  851.  
  852.         call    register_ramdisk
  853. ;--------------------------------------
  854. @@:
  855.         mov     esi, boot_initapic
  856.         call    boot_log
  857. ; Try to Initialize APIC
  858.         call    APIC_init
  859.  
  860.         mov     esi, boot_enableirq
  861.         call    boot_log
  862. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  863. ; they are used: when partitions are scanned, hd_read relies on timer
  864.         call    unmask_timer
  865.         stdcall enable_irq, 2               ; @#$%! PIC
  866.         stdcall enable_irq, 13              ; co-processor
  867.  
  868. ; Setup serial output console (if enabled)
  869. if defined debug_com_base
  870.  
  871.         ; reserve port so nobody else will use it
  872.         xor     ebx, ebx
  873.         mov     ecx, debug_com_base
  874.         mov     edx, debug_com_base+7
  875.         call    r_f_port_area
  876.  
  877.         ; enable Divisor latch
  878.         mov     dx, debug_com_base+3
  879.         mov     al, 1 shl 7
  880.         out     dx, al
  881.  
  882.         ; Set speed to 115200 baud (max speed)
  883.         mov     dx, debug_com_base
  884.         mov     al, 0x01
  885.         out     dx, al
  886.  
  887.         mov     dx, debug_com_base+1
  888.         mov     al, 0x00
  889.         out     dx, al
  890.  
  891.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  892.         mov     dx, debug_com_base+3
  893.         mov     al, 3
  894.         out     dx, al
  895.  
  896.         ; disable interrupts
  897.         mov     dx, debug_com_base+1
  898.         mov     al, 0
  899.         out     dx, al
  900.  
  901.         ; clear +  enable fifo (64 bits)
  902.         mov     dx, debug_com_base+2
  903.         mov     al, 0x7 + 1 shl 5
  904.         out     dx, al
  905.  
  906. end if
  907.  
  908.  
  909. ;-----------------------------------------------------------------------------
  910. ; show SVN version of kernel on the message board
  911. ;-----------------------------------------------------------------------------
  912.         mov     eax, [version_inf.rev]
  913.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  914. ;-----------------------------------------------------------------------------
  915. ; show CPU count on the message board
  916. ;-----------------------------------------------------------------------------
  917.         mov     eax, [cpu_count]
  918.         test    eax, eax
  919.         jnz     @F
  920.         mov     al, 1                             ; at least one CPU
  921. @@:
  922.         DEBUGF  1, "K : %d CPU detected\n", eax
  923. ;-----------------------------------------------------------------------------
  924. ; detect Floppy drives
  925. ;-----------------------------------------------------------------------------
  926.         mov     esi, boot_detectfloppy
  927.         call    boot_log
  928. include 'detect/dev_fd.inc'
  929. ;-----------------------------------------------------------------------------
  930. ; create pci-devices list
  931. ;-----------------------------------------------------------------------------
  932.         mov     [pci_access_enabled], 1
  933.         call    pci_enum
  934. ;-----------------------------------------------------------------------------
  935. ; initialisation IDE ATA code
  936. ;-----------------------------------------------------------------------------
  937. include 'detect/init_ata.inc'
  938. ;-----------------------------------------------------------------------------
  939. if 0
  940.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  941.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  942.         je      no_lib_load
  943.  
  944.         mov     esi, boot_loadlibs
  945.         call    boot_log
  946. ; LOADING LIBRARES
  947.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  948.         call    load_file_parse_table       ; prepare file parse table
  949.         call    set_kernel_conf             ; configure devices and gui
  950. no_lib_load:
  951. end if
  952.  
  953. ; Display APIC status
  954.         mov     esi, boot_APIC_found
  955.         cmp     [irq_mode], IRQ_APIC
  956.         je      @f
  957.         mov     esi, boot_APIC_nfound
  958. @@:
  959.         call    boot_log
  960.  
  961. ; PRINT AMOUNT OF MEMORY
  962.         mov     esi, boot_memdetect
  963.         call    boot_log
  964.  
  965.         movzx   ecx, word [boot_y]
  966.         if lang eq ru
  967.         or      ecx, (10+30*6) shl 16
  968.         else if lang eq sp
  969.         or      ecx, (10+33*6) shl 16
  970.         else
  971.         or      ecx, (10+29*6) shl 16
  972.         end if
  973.         sub     ecx, 10
  974.         mov     edx, 0xFFFFFF
  975.         mov     ebx, [MEM_AMOUNT]
  976.         shr     ebx, 20
  977.         xor     edi, edi
  978.         mov     eax, 0x00040000
  979.         inc     edi
  980.         call    display_number_force
  981.  
  982. ; BUILD SCHEDULER
  983.  
  984. ;        call    build_scheduler; sys32.inc
  985.  
  986. ;        mov     esi, boot_devices
  987. ;        call    boot_log
  988.  
  989.         call    clear_pci_ide_interrupts
  990.  
  991. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  992.  
  993.         stdcall load_pe_driver, szVidintel, 0
  994.  
  995.         call    usb_init
  996.  
  997. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  998.  
  999.         mov     esi, boot_windefs
  1000.         call    boot_log
  1001.         call    set_window_defaults
  1002.  
  1003. ; SET BACKGROUND DEFAULTS
  1004.  
  1005.         mov     esi, boot_bgr
  1006.         call    boot_log
  1007.         call    init_background
  1008.         call    calculatebackground
  1009.  
  1010. ; RESERVE SYSTEM IRQ'S JA PORT'S
  1011.  
  1012.         mov     esi, boot_resirqports
  1013.         call    boot_log
  1014.         call    reserve_irqs_ports
  1015.  
  1016.         call    init_display
  1017.         mov     eax, [def_cursor]
  1018.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  1019.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  1020.  
  1021. ; PRINT CPU FREQUENCY
  1022.  
  1023.         mov     esi, boot_cpufreq
  1024.         call    boot_log
  1025.  
  1026.         cli                         ;FIXME check IF
  1027.         rdtsc
  1028.         mov     ecx, eax
  1029.         mov     esi, 250            ; wait 1/4 a second
  1030.         call    delay_ms
  1031.         rdtsc
  1032.         sti
  1033.  
  1034.         sub     eax, ecx
  1035.         xor     edx, edx
  1036.         shld    edx, eax, 2
  1037.         shl     eax, 2
  1038.         mov     dword [cpu_freq], eax
  1039.         mov     dword [cpu_freq+4], edx
  1040.         mov     ebx, 1000000
  1041.         div     ebx
  1042.         mov     ebx, eax
  1043.  
  1044.         movzx   ecx, word [boot_y]
  1045.         if lang eq ru
  1046.         add     ecx, (10+19*6) shl 16 - 10
  1047.         else if lang eq sp
  1048.         add     ecx, (10+25*6) shl 16 - 10
  1049.         else
  1050.         add     ecx, (10+17*6) shl 16 - 10
  1051.         end if
  1052.  
  1053.         mov     edx, 0xFFFFFF
  1054.         xor     edi, edi
  1055.         mov     eax, 0x00040000
  1056.         inc     edi
  1057.         call    display_number_force
  1058.  
  1059. ; SET VARIABLES
  1060.  
  1061.         call    set_variables
  1062.  
  1063. ; STACK AND FDC
  1064.  
  1065.         call    stack_init
  1066.         call    fdc_init
  1067.  
  1068. ; PALETTE FOR 320x200 and 640x480 16 col
  1069.  
  1070.         cmp     [SCR_MODE], word 0x12
  1071.         jne     no_pal_vga
  1072.         mov     esi, boot_pal_vga
  1073.         call    boot_log
  1074.         call    paletteVGA
  1075.       no_pal_vga:
  1076.  
  1077.         cmp     [SCR_MODE], word 0x13
  1078.         jne     no_pal_ega
  1079.         mov     esi, boot_pal_ega
  1080.         call    boot_log
  1081.         call    palette320x200
  1082.       no_pal_ega:
  1083.  
  1084. ; LOAD DEFAULT SKIN
  1085.  
  1086.         call    load_default_skin
  1087.  
  1088. ;protect io permission map
  1089.  
  1090.         mov     esi, [default_io_map]
  1091.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1092.         add     esi, 0x1000
  1093.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1094.  
  1095.         stdcall map_page, tss._io_map_0, \
  1096.                 [SLOT_BASE+256+APPDATA.io_map], PG_READ
  1097.         stdcall map_page, tss._io_map_1, \
  1098.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_READ
  1099.  
  1100. ; SET KEYBOARD PARAMETERS
  1101.         mov     al, 0xf6       ; reset keyboard, scan enabled
  1102.         call    kb_write_wait_ack
  1103.         test    ah, ah
  1104.         jnz     .no_keyboard
  1105.  
  1106. iglobal
  1107. align 4
  1108. ps2_keyboard_functions:
  1109.         dd      .end - $
  1110.         dd      0       ; no close
  1111.         dd      ps2_set_lights
  1112. .end:
  1113. endg
  1114.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1115.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1116.        ; call  kb_write_wait_ack
  1117.        ; mov   al, 111b
  1118.        ; call  kb_write_wait_ack
  1119.  
  1120.         mov     al, 0xF3     ; set repeat rate & delay
  1121.         call    kb_write_wait_ack
  1122.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1123.         call    kb_write_wait_ack
  1124.      ;// mike.dld [
  1125.         call    set_lights
  1126.      ;// mike.dld ]
  1127.         stdcall attach_int_handler, 1, irq1, 0
  1128.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1129. .no_keyboard:
  1130.  
  1131. ; Load PS/2 mouse driver
  1132.  
  1133.         stdcall load_pe_driver, szPS2MDriver, 0
  1134.  
  1135.         mov     esi, boot_setmouse
  1136.         call    boot_log
  1137.         call    setmouse
  1138.  
  1139. ; LOAD FIRST APPLICATION
  1140.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  1141.         jnz     first_app_found
  1142.  
  1143.         cli
  1144.         mov     ebp, firstapp
  1145.         call    fs_execute_from_sysdir
  1146.         test    eax, eax
  1147.         jns     first_app_found
  1148.  
  1149.         mov     esi, boot_failed
  1150.         call    boot_log
  1151.  
  1152.         mov     eax, 0xDEADBEEF      ; otherwise halt
  1153.         hlt
  1154.  
  1155. first_app_found:
  1156.  
  1157. ; START MULTITASKING
  1158.  
  1159. ; A 'All set - press ESC to start' messages if need
  1160. if preboot_blogesc
  1161.         mov     esi, boot_tasking
  1162.         call    boot_log
  1163. .bll1:
  1164.         in      al, 0x60        ; wait for ESC key press
  1165.         cmp     al, 129
  1166.         jne     .bll1
  1167. end if
  1168.  
  1169.         mov     [timer_ticks_enable], 1         ; for cd driver
  1170.  
  1171.         sti
  1172.  
  1173.         call    mtrr_validate
  1174.  
  1175.         jmp     osloop
  1176.  
  1177.  
  1178.         ; Fly :)
  1179.  
  1180. uglobal
  1181. align 4
  1182. ap_initialized  dd      0
  1183. endg
  1184.  
  1185. ap_init_high:
  1186.         mov     ax, os_stack
  1187.         mov     bx, app_data
  1188.         mov     cx, app_tls
  1189.         mov     ss, ax
  1190.         mov     ds, bx
  1191.         mov     es, bx
  1192.         mov     fs, cx
  1193.         mov     gs, bx
  1194.         xor     esp, esp
  1195.         mov     eax, sys_proc-OS_BASE+PROC.pdt_0
  1196.         mov     cr3, eax
  1197.         lock inc [ap_initialized]
  1198.         jmp     idle_loop
  1199.  
  1200.  
  1201. include 'unpacker.inc'
  1202.  
  1203. align 4
  1204. boot_log:
  1205.         pushad
  1206.  
  1207.         mov     ebx, 10*65536
  1208.         mov     bx, word [boot_y]
  1209.         add     [boot_y], dword 10
  1210.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1211.         xor     edi, edi
  1212.         mov     edx, esi
  1213.         inc     edi
  1214.         call    dtext
  1215.  
  1216.         mov     [novesachecksum], 1000
  1217.         call    checkVga_N13
  1218.  
  1219.         popad
  1220.  
  1221.         ret
  1222.  
  1223. ; in: edx -> APPDATA for OS/IDLE slot
  1224. ; in: ebx = stack base
  1225. proc setup_os_slot
  1226.         xor     eax, eax
  1227.         mov     ecx, 256/4
  1228.         mov     edi, edx
  1229.         rep stosd
  1230.  
  1231.         mov     eax, tss+0x80
  1232.         call    get_pg_addr
  1233.         inc     eax
  1234.         mov     [edx+APPDATA.io_map], eax
  1235.         mov     eax, tss+0x1080
  1236.         call    get_pg_addr
  1237.         inc     eax
  1238.         mov     [edx+APPDATA.io_map+4], eax
  1239.  
  1240.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1241.         lea     edi, [ebx+0x2000-512]
  1242.         mov     dword [edx+APPDATA.fpu_state], edi
  1243.         mov     dword [edx+APPDATA.saved_esp0], edi
  1244.         mov     dword [edx+APPDATA.saved_esp], edi
  1245.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1246.  
  1247.         mov     esi, fpu_data
  1248.         mov     ecx, 512/4
  1249.         cld
  1250.         rep movsd
  1251.  
  1252.         lea     eax, [edx+APP_OBJ_OFFSET]
  1253.         mov     dword [edx+APPDATA.fd_obj], eax
  1254.         mov     dword [edx+APPDATA.bk_obj], eax
  1255.  
  1256.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1257.  
  1258.         mov     [edx + APPDATA.process], sys_proc
  1259.  
  1260.         lea     ebx, [edx+APPDATA.list]
  1261.         lea     ecx, [sys_proc+PROC.thr_list]
  1262.         list_add_tail ebx, ecx
  1263.  
  1264.         mov     eax, edx
  1265.         shr     eax, 3
  1266.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1267.         mov     [eax+TASKDATA.wnd_number], dh
  1268.         mov     byte [eax+TASKDATA.pid], dh
  1269.  
  1270.         ret
  1271. endp
  1272.  
  1273. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1274. ;                                                                    ;
  1275. ;                    MAIN OS LOOP START                              ;
  1276. ;                                                                    ;
  1277. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1278. align 32
  1279. osloop:
  1280.         mov     edx, osloop_has_work?
  1281.         xor     ecx, ecx
  1282.         call    Wait_events
  1283.         xor     eax, eax
  1284.         xchg    eax, [osloop_nonperiodic_work]
  1285.         test    eax, eax
  1286.         jz      .no_periodic
  1287.  
  1288.         call    __sys_draw_pointer
  1289.         call    window_check_events
  1290.         call    mouse_check_events
  1291.         call    checkmisc
  1292.         call    checkVga_N13
  1293. ;--------------------------------------
  1294. .no_periodic:
  1295.         call    stack_handler
  1296.         call    check_fdd_motor_status
  1297.         call    check_ATAPI_device_event
  1298.         call    check_lights_state
  1299.         call    check_timers
  1300.  
  1301.         jmp     osloop
  1302. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1303. ;                                                                    ;
  1304. ;                      MAIN OS LOOP END                              ;
  1305. ;                                                                    ;
  1306. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1307. proc osloop_has_work?
  1308.         cmp     [osloop_nonperiodic_work], 0
  1309.         jnz     .yes
  1310.         call    stack_handler_has_work?
  1311.         jnz     .yes
  1312.         call    check_fdd_motor_status_has_work?
  1313.         jnz     .yes
  1314.         call    check_ATAPI_device_event_has_work?
  1315.         jnz     .yes
  1316.         call    check_lights_state_has_work?
  1317.         jnz     .yes
  1318.         call    check_timers_has_work?
  1319.         jnz     .yes
  1320. .no:
  1321.         xor     eax, eax
  1322.         ret
  1323. .yes:
  1324.         xor     eax, eax
  1325.         inc     eax
  1326.         ret
  1327. endp
  1328.  
  1329. proc wakeup_osloop
  1330.         mov     [osloop_nonperiodic_work], 1
  1331.         ret
  1332. endp
  1333.  
  1334. uglobal
  1335. align 4
  1336. osloop_nonperiodic_work dd      ?
  1337. endg
  1338.  
  1339. uglobal
  1340. align 64
  1341. idle_addr       rb      64
  1342. endg
  1343.  
  1344. idle_thread:
  1345.         sti
  1346.  
  1347. ; The following code can be executed by all CPUs in the system.
  1348. ; All other parts of the kernel do not expect multi-CPU.
  1349. ; Also, APs don't even have a stack here.
  1350. ; Beware. Don't do anything here. Anything at all.
  1351. idle_loop:
  1352.         cmp     [use_mwait_for_idle], 0
  1353.         jnz     idle_loop_mwait
  1354.  
  1355. idle_loop_hlt:
  1356.         hlt
  1357.         jmp     idle_loop_hlt
  1358.  
  1359. idle_loop_mwait:
  1360.         mov     eax, idle_addr
  1361.         xor     ecx, ecx
  1362.         xor     edx, edx
  1363.         monitor
  1364.         xor     ecx, ecx
  1365.         mov     eax, 20h        ; or 10h
  1366.         mwait
  1367.         jmp     idle_loop_mwait
  1368.  
  1369.  
  1370. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1371. ;                                                                      ;
  1372. ;                   INCLUDED SYSTEM FILES                              ;
  1373. ;                                                                      ;
  1374. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1375.  
  1376.  
  1377. include "kernel32.inc"
  1378.  
  1379.  
  1380. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1381. ;                                                                      ;
  1382. ;                       KERNEL FUNCTIONS                               ;
  1383. ;                                                                      ;
  1384. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1385.  
  1386. reserve_irqs_ports:
  1387.  
  1388.  
  1389. ; RESERVE PORTS
  1390.         mov     eax, RESERVED_PORTS
  1391.         mov     ecx, 1
  1392.  
  1393.         mov     [eax], dword 4
  1394.  
  1395.         mov     [eax+16], ecx
  1396.         mov     [eax+16+4], dword 0
  1397.         mov     [eax+16+8], dword 0x2D
  1398.  
  1399.         mov     [eax+32], ecx
  1400.         mov     [eax+32+4], dword 0x30
  1401.         mov     [eax+32+8], dword 0x4D
  1402.  
  1403.         mov     [eax+48], ecx
  1404.         mov     [eax+48+4], dword 0x50
  1405.         mov     [eax+48+8], dword 0xDF
  1406.  
  1407.         mov     [eax+64], ecx
  1408.         mov     [eax+64+4], dword 0xE5
  1409.         mov     [eax+64+8], dword 0xFF
  1410.  
  1411.         ret
  1412.  
  1413.  
  1414. iglobal
  1415.   process_number dd 0x2
  1416. endg
  1417.  
  1418. set_variables:
  1419.  
  1420.         mov     ecx, 0x16                    ; flush port 0x60
  1421. .fl60:
  1422.         in      al, 0x60
  1423.         loop    .fl60
  1424.         push    eax
  1425.  
  1426.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1427.         shr     ax, 1
  1428.         shl     eax, 16
  1429.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1430.         shr     ax, 1
  1431.         mov     [MOUSE_X], eax
  1432.         call    wakeup_osloop
  1433.  
  1434.         xor     eax, eax
  1435.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1436.  
  1437.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1438.         mov     byte [BTN_COUNT], al              ; button buffer
  1439. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1440.  
  1441.         pop     eax
  1442.         ret
  1443.  
  1444. align 4
  1445. ;input  eax=43,bl-byte of output, ecx - number of port
  1446. sys_outport:
  1447.  
  1448.         mov     edi, ecx   ; separate flag for read / write
  1449.         and     ecx, 65535
  1450.  
  1451.         mov     eax, [RESERVED_PORTS]
  1452.         test    eax, eax
  1453.         jnz     .sopl8
  1454.         inc     eax
  1455.         mov     [esp+32], eax
  1456.         ret
  1457.  
  1458.   .sopl8:
  1459.         mov     edx, [TASK_BASE]
  1460.         mov     edx, [edx+0x4]
  1461.     ;and   ecx,65535
  1462.     ;cld - set on interrupt 0x40
  1463.   .sopl1:
  1464.  
  1465.         mov     esi, eax
  1466.         shl     esi, 4
  1467.         add     esi, RESERVED_PORTS
  1468.         cmp     edx, [esi+0]
  1469.         jne     .sopl2
  1470.         cmp     ecx, [esi+4]
  1471.         jb      .sopl2
  1472.         cmp     ecx, [esi+8]
  1473.         jg      .sopl2
  1474. .sopl3:
  1475.  
  1476.         test    edi, 0x80000000; read ?
  1477.         jnz     .sopl4
  1478.  
  1479.         mov     eax, ebx
  1480.         mov     dx, cx   ; write
  1481.         out     dx, al
  1482.         and     [esp+32], dword 0
  1483.         ret
  1484.  
  1485.         .sopl2:
  1486.  
  1487.         dec     eax
  1488.         jnz     .sopl1
  1489.         inc     eax
  1490.         mov     [esp+32], eax
  1491.         ret
  1492.  
  1493.  
  1494.   .sopl4:
  1495.  
  1496.         mov     dx, cx   ; read
  1497.         in      al, dx
  1498.         and     eax, 0xff
  1499.         and     [esp+32], dword 0
  1500.         mov     [esp+20], eax
  1501.         ret
  1502.  
  1503. display_number:
  1504. ;It is not optimization
  1505.         mov     eax, ebx
  1506.         mov     ebx, ecx
  1507.         mov     ecx, edx
  1508.         mov     edx, esi
  1509.         mov     esi, edi
  1510. ; eax = print type, al=0 -> ebx is number
  1511. ;                   al=1 -> ebx is pointer
  1512. ;                   ah=0 -> display decimal
  1513. ;                   ah=1 -> display hexadecimal
  1514. ;                   ah=2 -> display binary
  1515. ;                   eax bits 16-21 = number of digits to display (0-32)
  1516. ;                   eax bits 22-31 = reserved
  1517. ;
  1518. ; ebx = number or pointer
  1519. ; ecx = x shl 16 + y
  1520. ; edx = color
  1521.         xor     edi, edi
  1522. display_number_force:
  1523.         push    eax
  1524.         and     eax, 0x3fffffff
  1525.         cmp     eax, 0xffff     ; length > 0 ?
  1526.         pop     eax
  1527.         jge     cont_displ
  1528.         ret
  1529.    cont_displ:
  1530.         push    eax
  1531.         and     eax, 0x3fffffff
  1532.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1533.         pop     eax
  1534.         jb      cont_displ2
  1535.         ret
  1536.    cont_displ2:
  1537.  
  1538.         pushad
  1539.  
  1540.         cmp     al, 1            ; ecx is a pointer ?
  1541.         jne     displnl1
  1542.         mov     ebp, ebx
  1543.         add     ebp, 4
  1544.         mov     ebp, [ebp+std_application_base_address]
  1545.         mov     ebx, [ebx+std_application_base_address]
  1546.  displnl1:
  1547.         sub     esp, 64
  1548.  
  1549.         test    ah, ah            ; DECIMAL
  1550.         jnz     no_display_desnum
  1551.         shr     eax, 16
  1552.         and     eax, 0xC03f
  1553. ;     and   eax,0x3f
  1554.         push    eax
  1555.         and     eax, 0x3f
  1556.         mov     edi, esp
  1557.         add     edi, 4+64-1
  1558.         mov     ecx, eax
  1559.         mov     eax, ebx
  1560.         mov     ebx, 10
  1561.  d_desnum:
  1562.         xor     edx, edx
  1563.         call    division_64_bits
  1564.         div     ebx
  1565.         add     dl, 48
  1566.         mov     [edi], dl
  1567.         dec     edi
  1568.         loop    d_desnum
  1569.         pop     eax
  1570.         call    normalize_number
  1571.         call    draw_num_text
  1572.         add     esp, 64
  1573.         popad
  1574.         ret
  1575.    no_display_desnum:
  1576.  
  1577.         cmp     ah, 0x01         ; HEXADECIMAL
  1578.         jne     no_display_hexnum
  1579.         shr     eax, 16
  1580.         and     eax, 0xC03f
  1581. ;     and   eax,0x3f
  1582.         push    eax
  1583.         and     eax, 0x3f
  1584.         mov     edi, esp
  1585.         add     edi, 4+64-1
  1586.         mov     ecx, eax
  1587.         mov     eax, ebx
  1588.         mov     ebx, 16
  1589.    d_hexnum:
  1590.         xor     edx, edx
  1591.         call    division_64_bits
  1592.         div     ebx
  1593.    hexletters = __fdo_hexdigits
  1594.         add     edx, hexletters
  1595.         mov     dl, [edx]
  1596.         mov     [edi], dl
  1597.         dec     edi
  1598.         loop    d_hexnum
  1599.         pop     eax
  1600.         call    normalize_number
  1601.         call    draw_num_text
  1602.         add     esp, 64
  1603.         popad
  1604.         ret
  1605.    no_display_hexnum:
  1606.  
  1607.         cmp     ah, 0x02         ; BINARY
  1608.         jne     no_display_binnum
  1609.         shr     eax, 16
  1610.         and     eax, 0xC03f
  1611. ;     and   eax,0x3f
  1612.         push    eax
  1613.         and     eax, 0x3f
  1614.         mov     edi, esp
  1615.         add     edi, 4+64-1
  1616.         mov     ecx, eax
  1617.         mov     eax, ebx
  1618.         mov     ebx, 2
  1619.    d_binnum:
  1620.         xor     edx, edx
  1621.         call    division_64_bits
  1622.         div     ebx
  1623.         add     dl, 48
  1624.         mov     [edi], dl
  1625.         dec     edi
  1626.         loop    d_binnum
  1627.         pop     eax
  1628.         call    normalize_number
  1629.         call    draw_num_text
  1630.         add     esp, 64
  1631.         popad
  1632.         ret
  1633.    no_display_binnum:
  1634.  
  1635.         add     esp, 64
  1636.         popad
  1637.         ret
  1638.  
  1639. normalize_number:
  1640.         test    ah, 0x80
  1641.         jz      .continue
  1642.         mov     ecx, 48
  1643.         and     eax, 0x3f
  1644. @@:
  1645.         inc     edi
  1646.         cmp     [edi], cl
  1647.         jne     .continue
  1648.         dec     eax
  1649.         cmp     eax, 1
  1650.         ja      @r
  1651.         mov     al, 1
  1652. .continue:
  1653.         and     eax, 0x3f
  1654.         ret
  1655.  
  1656. division_64_bits:
  1657.         test    [esp+1+4], byte 0x40
  1658.         jz      .continue
  1659.         push    eax
  1660.         mov     eax, ebp
  1661.         div     ebx
  1662.         mov     ebp, eax
  1663.         pop     eax
  1664. .continue:
  1665.         ret
  1666.  
  1667. draw_num_text:
  1668.         mov     esi, eax
  1669.         mov     edx, 64+4
  1670.         sub     edx, eax
  1671.         add     edx, esp
  1672.         mov     ebx, [esp+64+32-8+4]
  1673. ; add window start x & y
  1674.         mov     ecx, [TASK_BASE]
  1675.  
  1676.         mov     edi, [CURRENT_TASK]
  1677.         shl     edi, 8
  1678.  
  1679.         mov     eax, [ecx-twdw+WDATA.box.left]
  1680.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1681.         shl     eax, 16
  1682.         add     eax, [ecx-twdw+WDATA.box.top]
  1683.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1684.         add     ebx, eax
  1685.         mov     ecx, [esp+64+32-12+4]
  1686.         and     ecx, not 0x80000000     ; force counted string
  1687.         mov     eax, [esp+64+8]         ; background color (if given)
  1688.         mov     edi, [esp+64+4]
  1689.         jmp     dtext
  1690. ;-----------------------------------------------------------------------------
  1691. iglobal
  1692. midi_base dw 0
  1693. endg
  1694. ;-----------------------------------------------------------------------------
  1695. align 4
  1696. sys_setup:
  1697. ;  1 = roland mpu midi base , base io address
  1698. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1699. ;  3 = not used
  1700. ;  4 = not used
  1701. ;  5 = system language, 1eng 2fi 3ger 4rus
  1702. ;  6 = not used
  1703. ;  7 = not used
  1704. ;  8 = not used
  1705. ;  9 = not used
  1706. ; 10 = not used
  1707. ; 11 = enable lba read
  1708. ; 12 = enable pci access
  1709. ;-----------------------------------------------------------------------------
  1710.         and     [esp+32], dword 0
  1711. ; F.21.1 - set MPU MIDI base port
  1712.         dec     ebx
  1713.         jnz     @f
  1714.  
  1715.         cmp     ecx, 0x100
  1716.         jb      @f
  1717.  
  1718.         mov     esi, 65535
  1719.         cmp     esi, ecx
  1720.         jb      @f
  1721.  
  1722.         mov     [midi_base], cx
  1723.         mov     word [mididp], cx
  1724.         inc     cx
  1725.         mov     word [midisp], cx
  1726.         ret
  1727. ;--------------------------------------
  1728. @@:
  1729. ; F.21.2 - set keyboard layout
  1730.         dec     ebx
  1731.         jnz     @f
  1732.  
  1733.         mov     edi, [TASK_BASE]
  1734.         mov     eax, [edi+TASKDATA.mem_start]
  1735.         add     eax, edx
  1736. ; 1 = normal layout
  1737.         dec     ecx
  1738.         jnz     .shift
  1739.  
  1740.         mov     ebx, keymap
  1741.         mov     ecx, 128
  1742.         call    memmove
  1743.         ret
  1744. ;--------------------------------------
  1745. .shift:
  1746. ; 2 = layout at pressed Shift
  1747.         dec     ecx
  1748.         jnz     .alt
  1749.  
  1750.         mov     ebx, keymap_shift
  1751.         mov     ecx, 128
  1752.         call    memmove
  1753.         ret
  1754. ;--------------------------------------
  1755. .alt:
  1756. ; 3 = layout at pressed Alt
  1757.         dec     ecx
  1758.         jnz     .country
  1759.  
  1760.         mov     ebx, keymap_alt
  1761.         mov     ecx, 128
  1762.         call    memmove
  1763.         ret
  1764. ;--------------------------------------
  1765. .country:
  1766. ; country identifier
  1767.         sub     ecx, 6
  1768.         jnz     .error
  1769.  
  1770.         mov     word [keyboard], dx
  1771.         ret
  1772. ;--------------------------------------
  1773. @@:
  1774. ; F.21.5 - set system language
  1775.         sub     ebx, 3
  1776.         jnz     @f
  1777.  
  1778.         mov     [syslang], ecx
  1779.         ret
  1780. ;--------------------------------------
  1781. @@:
  1782. ; F.21.11 - enable/disable low-level access to HD
  1783.         and     ecx, 1
  1784.         sub     ebx, 6
  1785.         jnz     @f
  1786.  
  1787.         mov     [lba_read_enabled], ecx
  1788.         ret
  1789. ;--------------------------------------
  1790. @@:
  1791. ; F.21.12 - enable/disable low-level access to PCI
  1792.         dec     ebx
  1793.         jnz     .error
  1794.  
  1795.         mov     [pci_access_enabled], ecx
  1796.         ret
  1797. ;--------------------------------------
  1798. .error:
  1799.         or      [esp+32], dword -1
  1800.         ret
  1801. ;-----------------------------------------------------------------------------
  1802. align 4
  1803. sys_getsetup:
  1804. ;  1 = roland mpu midi base , base io address
  1805. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1806. ;  3 = not used
  1807. ;  4 = not used
  1808. ;  5 = system language, 1eng 2fi 3ger 4rus
  1809. ;  6 = not used
  1810. ;  7 = not used
  1811. ;  8 = not used
  1812. ;  9 = get hs timer tic
  1813. ; 10 = not used
  1814. ; 11 = get the state "lba read"
  1815. ; 12 = get the state "pci access"
  1816. ;-----------------------------------------------------------------------------
  1817. ; F.26.1 - get MPU MIDI base port
  1818.         dec     ebx
  1819.         jnz     @f
  1820.  
  1821.         movzx   eax, [midi_base]
  1822.         mov     [esp+32], eax
  1823.         ret
  1824. ;--------------------------------------
  1825. @@:
  1826. ; F.26.2 - get keyboard layout
  1827.         dec     ebx
  1828.         jnz     @f
  1829.  
  1830.         mov     edi, [TASK_BASE]
  1831.         mov     ebx, [edi+TASKDATA.mem_start]
  1832.         add     ebx, edx
  1833. ; 1 = normal layout
  1834.         dec     ecx
  1835.         jnz     .shift
  1836.  
  1837.         mov     eax, keymap
  1838.         mov     ecx, 128
  1839.         call    memmove
  1840.         ret
  1841. ;--------------------------------------
  1842. .shift:
  1843. ; 2 = layout with pressed Shift
  1844.         dec     ecx
  1845.         jnz     .alt
  1846.  
  1847.         mov     eax, keymap_shift
  1848.         mov     ecx, 128
  1849.         call    memmove
  1850.         ret
  1851. ;--------------------------------------
  1852. .alt:
  1853. ; 3 = layout with pressed Alt
  1854.         dec     ecx
  1855.         jne     .country
  1856.  
  1857.         mov     eax, keymap_alt
  1858.         mov     ecx, 128
  1859.         call    memmove
  1860.         ret
  1861. ;--------------------------------------
  1862. .country:
  1863. ; 9 = country identifier
  1864.         sub     ecx, 6
  1865.         jnz     .error
  1866.  
  1867.         movzx   eax, word [keyboard]
  1868.         mov     [esp+32], eax
  1869.         ret
  1870. ;--------------------------------------
  1871. @@:
  1872. ; F.26.5 - get system language
  1873.         sub     ebx, 3
  1874.         jnz     @f
  1875.  
  1876.         mov     eax, [syslang]
  1877.         mov     [esp+32], eax
  1878.         ret
  1879. ;--------------------------------------
  1880. @@:
  1881. ; F.26.9 - get the value of the time counter
  1882.         sub     ebx, 4
  1883.         jnz     @f
  1884.  
  1885.         mov     eax, [timer_ticks]
  1886.         mov     [esp+32], eax
  1887.         ret
  1888. ;--------------------------------------
  1889. @@:
  1890. ; F.26.11 - Find out whether low-level HD access is enabled
  1891.         sub     ebx, 2
  1892.         jnz     @f
  1893.  
  1894.         mov     eax, [lba_read_enabled]
  1895.         mov     [esp+32], eax
  1896.         ret
  1897. ;--------------------------------------
  1898. @@:
  1899. ; F.26.12 - Find out whether low-level PCI access is enabled
  1900.         dec     ebx
  1901.         jnz     .error
  1902.  
  1903.         mov     eax, [pci_access_enabled]
  1904.         mov     [esp+32], eax
  1905.         ret
  1906. ;--------------------------------------
  1907. .error:
  1908.         or      [esp+32], dword -1
  1909.         ret
  1910. ;-----------------------------------------------------------------------------
  1911. get_timer_ticks:
  1912.         mov     eax, [timer_ticks]
  1913.         ret
  1914. ;-----------------------------------------------------------------------------
  1915. iglobal
  1916. align 4
  1917. mousefn dd msscreen, mswin, msbutton, msset
  1918.         dd app_load_cursor
  1919.         dd app_set_cursor
  1920.         dd app_delete_cursor
  1921.         dd msz
  1922. endg
  1923. ;-----------------------------------------------------------------------------
  1924. readmousepos:
  1925.  
  1926. ; eax=0 screen relative
  1927. ; eax=1 window relative
  1928. ; eax=2 buttons pressed
  1929. ; eax=3 set mouse pos   ; reserved
  1930. ; eax=4 load cursor
  1931. ; eax=5 set cursor
  1932. ; eax=6 delete cursor   ; reserved
  1933. ; eax=7 get mouse_z
  1934.  
  1935.         cmp     ebx, 7
  1936.         ja      msset
  1937.         jmp     [mousefn+ebx*4]
  1938. msscreen:
  1939.         mov     eax, [MOUSE_X]
  1940.         shl     eax, 16
  1941.         mov     ax, [MOUSE_Y]
  1942.         mov     [esp+36-4], eax
  1943.         ret
  1944. mswin:
  1945.         mov     eax, [MOUSE_X]
  1946.         shl     eax, 16
  1947.         mov     ax, [MOUSE_Y]
  1948.         mov     esi, [TASK_BASE]
  1949.         mov     bx, word [esi-twdw+WDATA.box.left]
  1950.         shl     ebx, 16
  1951.         mov     bx, word [esi-twdw+WDATA.box.top]
  1952.         sub     eax, ebx
  1953.  
  1954.         mov     edi, [CURRENT_TASK]
  1955.         shl     edi, 8
  1956.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1957.         rol     eax, 16
  1958.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1959.         rol     eax, 16
  1960.         mov     [esp+36-4], eax
  1961.         ret
  1962. msbutton:
  1963.         movzx   eax, byte [BTN_DOWN]
  1964.         mov     [esp+36-4], eax
  1965.         ret
  1966. msz:
  1967.         mov     edi, [TASK_COUNT]
  1968.         movzx   edi, word [WIN_POS + edi*2]
  1969.         cmp     edi, [CURRENT_TASK]
  1970.         jne     @f
  1971.         mov     ax, [MOUSE_SCROLL_H]
  1972.         shl     eax, 16
  1973.         mov     ax, [MOUSE_SCROLL_V]
  1974.         mov     [esp+36-4], eax
  1975.         and     [MOUSE_SCROLL_H], word 0
  1976.         and     [MOUSE_SCROLL_V], word 0
  1977.         ret
  1978.        @@:
  1979.         and     [esp+36-4], dword 0
  1980. ;           ret
  1981. msset:
  1982.         ret
  1983.  
  1984. app_load_cursor:
  1985.         cmp     ecx, OS_BASE
  1986.         jae     msset
  1987.         stdcall load_cursor, ecx, edx
  1988.         mov     [esp+36-4], eax
  1989.         ret
  1990.  
  1991. app_set_cursor:
  1992.         stdcall set_cursor, ecx
  1993.         mov     [esp+36-4], eax
  1994.         ret
  1995.  
  1996. app_delete_cursor:
  1997.         stdcall delete_cursor, ecx
  1998.         mov     [esp+36-4], eax
  1999.         ret
  2000.  
  2001. is_input:
  2002.  
  2003.         push    edx
  2004.         mov     dx, word [midisp]
  2005.         in      al, dx
  2006.         and     al, 0x80
  2007.         pop     edx
  2008.         ret
  2009.  
  2010. is_output:
  2011.  
  2012.         push    edx
  2013.         mov     dx, word [midisp]
  2014.         in      al, dx
  2015.         and     al, 0x40
  2016.         pop     edx
  2017.         ret
  2018.  
  2019.  
  2020. get_mpu_in:
  2021.  
  2022.         push    edx
  2023.         mov     dx, word [mididp]
  2024.         in      al, dx
  2025.         pop     edx
  2026.         ret
  2027.  
  2028.  
  2029. put_mpu_out:
  2030.  
  2031.         push    edx
  2032.         mov     dx, word [mididp]
  2033.         out     dx, al
  2034.         pop     edx
  2035.         ret
  2036.  
  2037.  
  2038.  
  2039. align 4
  2040.  
  2041. sys_midi:
  2042.         cmp     [mididp], 0
  2043.         jnz     sm0
  2044.         mov     [esp+36], dword 1
  2045.         ret
  2046. sm0:
  2047.         and     [esp+36], dword 0
  2048.         dec     ebx
  2049.         jnz     smn1
  2050.  ;    call setuart
  2051. su1:
  2052.         call    is_output
  2053.         test    al, al
  2054.         jnz     su1
  2055.         mov     dx, word [midisp]
  2056.         mov     al, 0xff
  2057.         out     dx, al
  2058. su2:
  2059.         mov     dx, word [midisp]
  2060.         mov     al, 0xff
  2061.         out     dx, al
  2062.         call    is_input
  2063.         test    al, al
  2064.         jnz     su2
  2065.         call    get_mpu_in
  2066.         cmp     al, 0xfe
  2067.         jnz     su2
  2068. su3:
  2069.         call    is_output
  2070.         test    al, al
  2071.         jnz     su3
  2072.         mov     dx, word [midisp]
  2073.         mov     al, 0x3f
  2074.         out     dx, al
  2075.         ret
  2076. smn1:
  2077.         dec     ebx
  2078.         jnz     smn2
  2079. sm10:
  2080.         call    get_mpu_in
  2081.         call    is_output
  2082.         test    al, al
  2083.         jnz     sm10
  2084.         mov     al, bl
  2085.         call    put_mpu_out
  2086.         smn2:
  2087.         ret
  2088.  
  2089. detect_devices:
  2090. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2091. ;include 'detect/commouse.inc'
  2092. ;include 'detect/ps2mouse.inc'
  2093. ;include 'detect/dev_fd.inc'
  2094. ;include 'detect/dev_hdcd.inc'
  2095. ;include 'detect/sear_par.inc'
  2096. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  2097.         ret
  2098.  
  2099. sys_end:
  2100. ;--------------------------------------
  2101.         cmp     [_display.select_cursor], 0
  2102.         je      @f
  2103. ; restore default cursor before killing
  2104.         pusha
  2105.         mov     ecx, [current_slot]
  2106.         call    restore_default_cursor_before_killing
  2107.         popa
  2108. @@:
  2109. ;--------------------------------------
  2110. ; kill all sockets this process owns
  2111.         pusha
  2112.         mov     edx, [TASK_BASE]
  2113.         mov     edx, [edx+TASKDATA.pid]
  2114.         call    SOCKET_process_end
  2115.         popa
  2116. ;--------------------------------------
  2117.         mov     ecx, [current_slot]
  2118.         mov     eax, [ecx+APPDATA.tls_base]
  2119.         test    eax, eax
  2120.         jz      @F
  2121.  
  2122.         stdcall user_free, eax
  2123. @@:
  2124.  
  2125.         mov     eax, [TASK_BASE]
  2126.         mov     [eax+TASKDATA.state], 3; terminate this program
  2127.         call    wakeup_osloop
  2128.  
  2129. .waitterm:            ; wait here for termination
  2130.         call    change_task
  2131.         jmp     .waitterm
  2132. ;------------------------------------------------------------------------------
  2133. align 4
  2134. restore_default_cursor_before_killing:
  2135.         pushfd
  2136.         cli
  2137.         mov     eax, [def_cursor]
  2138.         mov     [ecx+APPDATA.cursor], eax
  2139.  
  2140.         movzx   eax, word [MOUSE_Y]
  2141.         movzx   ebx, word [MOUSE_X]
  2142.         mov     eax, [d_width_calc_area + eax*4]
  2143.  
  2144.         add     eax, [_display.win_map]
  2145.         movzx   edx, byte [ebx+eax]
  2146.         shl     edx, 8
  2147.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  2148.  
  2149.         cmp     esi, [current_cursor]
  2150.         je      @f
  2151.  
  2152.         push    esi
  2153.         call    [_display.select_cursor]
  2154.         mov     [current_cursor], esi
  2155. @@:
  2156.         mov     [redrawmouse_unconditional], 1
  2157.         call    wakeup_osloop
  2158.         popfd
  2159.         ret
  2160. ;------------------------------------------------------------------------------
  2161. iglobal
  2162. align 4
  2163. sys_system_table:
  2164.         dd      sysfn_deactivate        ; 1 = deactivate window
  2165.         dd      sysfn_terminate         ; 2 = terminate thread
  2166.         dd      sysfn_activate          ; 3 = activate window
  2167.         dd      sysfn_getidletime       ; 4 = get idle time
  2168.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2169.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2170.         dd      sysfn_getactive         ; 7 = get active window
  2171.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2172.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2173.         dd      sysfn_minimize          ; 10 = minimize window
  2174.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2175.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2176.         dd      sysfn_getversion        ; 13 = get kernel version
  2177.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2178.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2179.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2180.         dd      sysfn_getallmem         ; 17 = get total memory size
  2181.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2182.                                         ;                 instead of slot
  2183.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2184.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2185.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2186.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2187.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2188.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2189. sysfn_num = ($ - sys_system_table)/4
  2190. endg
  2191. ;------------------------------------------------------------------------------
  2192. sys_system:
  2193.         dec     ebx
  2194.         cmp     ebx, sysfn_num
  2195.         jae     @f
  2196.         jmp     dword [sys_system_table + ebx*4]
  2197. @@:
  2198.         ret
  2199. ;------------------------------------------------------------------------------
  2200. sysfn_shutdown:          ; 18.9 = system shutdown
  2201.         cmp     ecx, 1
  2202.         jl      exit_for_anyone
  2203.         cmp     ecx, 4
  2204.         jg      exit_for_anyone
  2205.         mov     [BOOT_VARS+0x9030], cl
  2206.  
  2207.         mov     eax, [TASK_COUNT]
  2208.         mov     [SYS_SHUTDOWN], al
  2209.         mov     [shutdown_processes], eax
  2210.         call    wakeup_osloop
  2211.         and     dword [esp+32], 0
  2212.  exit_for_anyone:
  2213.         ret
  2214.   uglobal
  2215.    shutdown_processes:
  2216.                        dd 0x0
  2217.   endg
  2218. ;------------------------------------------------------------------------------
  2219. sysfn_terminate:        ; 18.2 = TERMINATE
  2220.         push    ecx
  2221.         cmp     ecx, 2
  2222.         jb      noprocessterminate
  2223.         mov     edx, [TASK_COUNT]
  2224.         cmp     ecx, edx
  2225.         ja      noprocessterminate
  2226.         mov     eax, [TASK_COUNT]
  2227.         shl     ecx, 5
  2228.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2229.         add     ecx, CURRENT_TASK+TASKDATA.state
  2230.         cmp     byte [ecx], 9
  2231.         jz      noprocessterminate
  2232.         push    ecx edx
  2233.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2234.         call    request_terminate
  2235.         pop     edx ecx
  2236.         test    eax, eax
  2237.         jz      noprocessterminate
  2238. ;--------------------------------------
  2239. ; terminate all network sockets it used
  2240.         pusha
  2241.         mov     eax, edx
  2242.         call    SOCKET_process_end
  2243.         popa
  2244. ;--------------------------------------
  2245.         cmp     [_display.select_cursor], 0
  2246.         je      .restore_end
  2247. ; restore default cursor before killing
  2248.         pusha
  2249.         mov     ecx, [esp+32]
  2250.         shl     ecx, 8
  2251.         add     ecx, SLOT_BASE
  2252.         mov     eax, [def_cursor]
  2253.         cmp     [ecx+APPDATA.cursor], eax
  2254.         je      @f
  2255.         call    restore_default_cursor_before_killing
  2256. @@:
  2257.         popa
  2258. .restore_end:
  2259. ;--------------------------------------
  2260.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2261.         mov     [ecx], byte 3; clear possible i40's
  2262.         call    wakeup_osloop
  2263.      ;call MEM_Heap_UnLock
  2264.  
  2265.         cmp     edx, [application_table_owner]; clear app table stat
  2266.         jne     noatsc
  2267.         call    unlock_application_table
  2268. noatsc:
  2269. noprocessterminate:
  2270.         add     esp, 4
  2271.         ret
  2272. ;------------------------------------------------------------------------------
  2273. sysfn_terminate2:
  2274. ;lock application_table_status mutex
  2275. .table_status:
  2276.         call    lock_application_table
  2277.         mov     eax, ecx
  2278.         call    pid_to_slot
  2279.         test    eax, eax
  2280.         jz      .not_found
  2281.         mov     ecx, eax
  2282.         cli
  2283.         call    sysfn_terminate
  2284.         call    unlock_application_table
  2285.         sti
  2286.         and     dword [esp+32], 0
  2287.         ret
  2288. .not_found:
  2289.         call    unlock_application_table
  2290.         or      dword [esp+32], -1
  2291.         ret
  2292. ;------------------------------------------------------------------------------
  2293. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2294.         cmp     ecx, 2
  2295.         jb      .nowindowdeactivate
  2296.         cmp     ecx, [TASK_COUNT]
  2297.         ja      .nowindowdeactivate
  2298.  
  2299.         movzx   esi, word [WIN_STACK + ecx*2]
  2300.         cmp     esi, 1
  2301.         je      .nowindowdeactivate ; already deactive
  2302.  
  2303.         mov     edi, ecx
  2304.         shl     edi, 5
  2305.         add     edi, window_data
  2306.         movzx   esi, word [WIN_STACK + ecx * 2]
  2307.         lea     esi, [WIN_POS + esi * 2]
  2308.         call    window._.window_deactivate
  2309.  
  2310.         call    syscall_display_settings._.calculate_whole_screen
  2311.         call    syscall_display_settings._.redraw_whole_screen
  2312. .nowindowdeactivate:
  2313.         ret
  2314. ;------------------------------------------------------------------------------
  2315. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2316.         cmp     ecx, 2
  2317.         jb      .nowindowactivate
  2318.         cmp     ecx, [TASK_COUNT]
  2319.         ja      .nowindowactivate
  2320. ;-------------------------------------
  2321. @@:
  2322. ; If the window is captured and moved by the user,
  2323. ; then you can't change the position in window stack!!!
  2324.         mov     al, [mouse.active_sys_window.action]
  2325.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2326.         test    al, al
  2327.         jz      @f
  2328.         call    change_task
  2329.         jmp     @b
  2330. @@:
  2331. ;-------------------------------------
  2332.         mov     [window_minimize], 2; restore window if minimized
  2333.         call    wakeup_osloop
  2334.  
  2335.         movzx   esi, word [WIN_STACK + ecx*2]
  2336.         cmp     esi, [TASK_COUNT]
  2337.         je      .nowindowactivate; already active
  2338.  
  2339.         mov     edi, ecx
  2340.         shl     edi, 5
  2341.         add     edi, window_data
  2342.         movzx   esi, word [WIN_STACK + ecx * 2]
  2343.         lea     esi, [WIN_POS + esi * 2]
  2344.         call    waredraw
  2345. .nowindowactivate:
  2346.         ret
  2347. ;------------------------------------------------------------------------------
  2348. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2349.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2350.         mov     [esp+32], eax
  2351.         ret
  2352. ;------------------------------------------------------------------------------
  2353. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2354.         mov     eax, dword [cpu_freq]
  2355.         mov     [esp+32], eax
  2356.         ret
  2357. ;------------------------------------------------------------------------------
  2358. get_cpu_freq:
  2359.         mov     eax, dword [cpu_freq]
  2360.         mov     edx, dword [cpu_freq+4]
  2361.         ret
  2362. ;  SAVE ramdisk to /hd/1/menuet.img
  2363. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2364.    include 'blkdev/rdsave.inc'
  2365. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2366. ;------------------------------------------------------------------------------
  2367. align 4
  2368. sysfn_getactive:        ; 18.7 = get active window
  2369.         mov     eax, [TASK_COUNT]
  2370.         movzx   eax, word [WIN_POS + eax*2]
  2371.         mov     [esp+32], eax
  2372.         ret
  2373. ;------------------------------------------------------------------------------
  2374. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2375. ;     cmp  ecx,1
  2376.         dec     ecx
  2377.         jnz     nogetsoundflag
  2378.         movzx   eax, byte [sound_flag]; get sound_flag
  2379.         mov     [esp+32], eax
  2380.         ret
  2381.  nogetsoundflag:
  2382. ;     cmp  ecx,2
  2383.         dec     ecx
  2384.         jnz     nosoundflag
  2385.         xor     byte [sound_flag], 1
  2386.  nosoundflag:
  2387.         ret
  2388. ;------------------------------------------------------------------------------
  2389. sysfn_minimize:         ; 18.10 = minimize window
  2390.         mov     [window_minimize], 1
  2391.         call    wakeup_osloop
  2392.         ret
  2393. ;------------------------------------------------------------------------------
  2394. align 4
  2395. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2396.         dec     ecx
  2397.         jnz     .exit
  2398. .small_table:
  2399.         mov     edi, edx
  2400.         mov     esi, DRIVE_DATA
  2401.         mov     ecx, DRIVE_DATA_SIZE ;10
  2402.         cld
  2403.         rep movsb
  2404. .exit:
  2405.         ret
  2406. ;------------------------------------------------------------------------------
  2407. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2408.         and     dword [esp+32], 0
  2409.         ret
  2410. ;------------------------------------------------------------------------------
  2411. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2412.         mov     edi, ecx
  2413.         mov     esi, version_inf
  2414.         mov     ecx, version_end-version_inf
  2415.         rep movsb
  2416.         ret
  2417. ;------------------------------------------------------------------------------
  2418. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2419.      ;wait retrace functions
  2420.  sys_wait_retrace:
  2421.         mov     edx, 0x3da
  2422.  WaitRetrace_loop:
  2423.         in      al, dx
  2424.         test    al, 1000b
  2425.         jz      WaitRetrace_loop
  2426.         and     [esp+32], dword 0
  2427.         ret
  2428. ;------------------------------------------------------------------------------
  2429. align 4
  2430. sysfn_centermouse:      ; 18.15 = mouse centered
  2431. ; removed here by <Lrz>
  2432. ;     call  mouse_centered
  2433. ;* mouse centered - start code- Mario79
  2434. ;mouse_centered:
  2435. ;        push  eax
  2436.         mov     eax, [_display.width]
  2437.         shr     eax, 1
  2438.         mov     [MOUSE_X], ax
  2439.         mov     eax, [_display.height]
  2440.         shr     eax, 1
  2441.         mov     [MOUSE_Y], ax
  2442.         call    wakeup_osloop
  2443. ;        ret
  2444. ;* mouse centered - end code- Mario79
  2445.         xor     eax, eax
  2446.         and     [esp+32], eax
  2447. ;        pop   eax
  2448.         ret
  2449. ;------------------------------------------------------------------------------
  2450. align 4
  2451. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2452.         test    ecx, ecx; get mouse speed factor
  2453.         jnz     .set_mouse_acceleration
  2454.         xor     eax, eax
  2455.         mov     ax, [mouse_speed_factor]
  2456.         mov     [esp+32], eax
  2457.         ret
  2458.  .set_mouse_acceleration:
  2459. ;     cmp  ecx,1  ; set mouse speed factor
  2460.         dec     ecx
  2461.         jnz     .get_mouse_delay
  2462.         mov     [mouse_speed_factor], dx
  2463.         ret
  2464.  .get_mouse_delay:
  2465. ;     cmp  ecx,2  ; get mouse delay
  2466.         dec     ecx
  2467.         jnz     .set_mouse_delay
  2468.         mov     eax, [mouse_delay]
  2469.         mov     [esp+32], eax
  2470.         ret
  2471.  .set_mouse_delay:
  2472. ;     cmp  ecx,3  ; set mouse delay
  2473.         dec     ecx
  2474.         jnz     .set_pointer_position
  2475.         mov     [mouse_delay], edx
  2476.         ret
  2477.  .set_pointer_position:
  2478. ;     cmp  ecx,4  ; set mouse pointer position
  2479.         dec     ecx
  2480.         jnz     .set_mouse_button
  2481.         cmp     dx, word[_display.height]
  2482.         jae     .end
  2483.         rol     edx, 16
  2484.         cmp     dx, word[_display.width]
  2485.         jae     .end
  2486.         mov     [MOUSE_X], edx
  2487.         mov     [mouse_active], 1
  2488.         call    wakeup_osloop
  2489.         ret
  2490.  .set_mouse_button:
  2491. ;     cmp   ecx,5  ; set mouse button features
  2492.         dec     ecx
  2493.         jnz     .end
  2494.         mov     [BTN_DOWN], dl
  2495.         mov     [mouse_active], 1
  2496.         call    wakeup_osloop
  2497.  .end:
  2498.         ret
  2499. ;------------------------------------------------------------------------------
  2500. sysfn_getfreemem:
  2501.         mov     eax, [pg_data.pages_free]
  2502.         shl     eax, 2
  2503.         mov     [esp+32], eax
  2504.         ret
  2505. ;------------------------------------------------------------------------------
  2506. sysfn_getallmem:
  2507.         mov     eax, [MEM_AMOUNT]
  2508.         shr     eax, 10
  2509.         mov     [esp+32], eax
  2510.         ret
  2511. ;------------------------------------------------------------------------------
  2512. sysfn_pid_to_slot:
  2513.         mov     eax, ecx
  2514.         call    pid_to_slot
  2515.         mov     [esp+32], eax
  2516.         ret
  2517. ;------------------------------------------------------------------------------
  2518. sysfn_min_rest_window:
  2519.         pushad
  2520.         mov     eax, edx ; ebx - operating
  2521.         shr     ecx, 1
  2522.         jnc     @f
  2523.         call    pid_to_slot
  2524. @@:
  2525.         or      eax, eax ; eax - number of slot
  2526.         jz      .error
  2527.         cmp     eax, 255    ; varify maximal slot number
  2528.         ja      .error
  2529.         movzx   eax, word [WIN_STACK + eax*2]
  2530.         shr     ecx, 1
  2531.         jc      .restore
  2532.  ; .minimize:
  2533.         call    minimize_window
  2534.         jmp     .exit
  2535. .restore:
  2536.         call    restore_minimized_window
  2537. .exit:
  2538.         popad
  2539.         xor     eax, eax
  2540.         mov     [esp+32], eax
  2541.         ret
  2542. .error:
  2543.         popad
  2544.         xor     eax, eax
  2545.         dec     eax
  2546.         mov     [esp+32], eax
  2547.         ret
  2548. ;------------------------------------------------------------------------------
  2549. sysfn_min_windows:
  2550.         call    minimize_all_window
  2551.         mov     [esp+32], eax
  2552.         call    change_task
  2553.         ret
  2554. ;------------------------------------------------------------------------------
  2555. sysfn_set_screen_sizes:
  2556.         cmp     [SCR_MODE], word 0x13
  2557.         jbe     .exit
  2558.  
  2559.         cmp     [_display.select_cursor], select_cursor
  2560.         jne     .exit
  2561.  
  2562.         cmp     ecx, [display_width_standard]
  2563.         ja      .exit
  2564.  
  2565.         cmp     edx, [display_height_standard]
  2566.         ja      .exit
  2567.  
  2568.         pushfd
  2569.         cli
  2570.         mov     eax, ecx
  2571.         mov     ecx, [_display.lfb_pitch]
  2572.         mov     [_display.width], eax
  2573.         dec     eax
  2574.         mov     [_display.height], edx
  2575.         dec     edx
  2576. ; eax - new Screen_Max_X
  2577. ; edx - new Screen_Max_Y
  2578.         mov     [do_not_touch_winmap], 1
  2579.         call    set_screen
  2580.         mov     [do_not_touch_winmap], 0
  2581.         popfd
  2582.         call    change_task
  2583. .exit:
  2584.         ret
  2585. ;------------------------------------------------------------------------------
  2586. uglobal
  2587. screen_workarea RECT
  2588. display_width_standard dd 0
  2589. display_height_standard dd 0
  2590. do_not_touch_winmap db 0
  2591. window_minimize db 0
  2592. sound_flag      db 0
  2593.  
  2594. endg
  2595.  
  2596. UID_NONE=0
  2597. UID_MENUETOS=1   ;official
  2598. UID_KOLIBRI=2    ;russian
  2599.  
  2600. iglobal
  2601. version_inf:
  2602.         db 0,7,7,0  ; version 0.7.7.0
  2603.         db 0
  2604. .rev    dd __REV__
  2605. version_end:
  2606. endg
  2607. ;------------------------------------------------------------------------------
  2608. align 4
  2609. sys_cachetodiskette:
  2610.         cmp     ebx, 1
  2611.         jb      .no_floppy_save
  2612.         cmp     ebx, 2
  2613.         ja      .no_floppy_save
  2614.         call    save_image
  2615.         mov     [esp + 32], eax
  2616.         ret
  2617. .no_floppy_save:
  2618.         mov     [esp + 32], dword 1
  2619.         ret
  2620. ;------------------------------------------------------------------------------
  2621. uglobal
  2622. ;  bgrchanged  dd  0x0
  2623. align 4
  2624. bgrlockpid dd 0
  2625. bgrlock db 0
  2626. endg
  2627. ;------------------------------------------------------------------------------
  2628. align 4
  2629. sys_background:
  2630.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2631.         jnz     nosb1
  2632.         test    ecx, ecx
  2633.         jz      sbgrr
  2634.  
  2635.         test    edx, edx
  2636.         jz      sbgrr
  2637. ;--------------------------------------
  2638. align 4
  2639. @@:
  2640. ;;Maxis use atomic bts for mutexes  4.4.2009
  2641.         bts     dword [bgrlock], 0
  2642.         jnc     @f
  2643.         call    change_task
  2644.         jmp     @b
  2645. ;--------------------------------------
  2646. align 4
  2647. @@:
  2648.         mov     [BgrDataWidth], ecx
  2649.         mov     [BgrDataHeight], edx
  2650. ;    mov   [bgrchanged],1
  2651.  
  2652.         pushad
  2653. ; return memory for old background
  2654.         mov     eax, [img_background]
  2655.         cmp     eax, static_background_data
  2656.         jz      @f
  2657.         stdcall kernel_free, eax
  2658. ;--------------------------------------
  2659. align 4
  2660. @@:
  2661. ; calculate RAW size
  2662.         xor     eax, eax
  2663.         inc     eax
  2664.         cmp     [BgrDataWidth], eax
  2665.         jae     @f
  2666.         mov     [BgrDataWidth], eax
  2667. ;--------------------------------------
  2668. align 4
  2669. @@:
  2670.         cmp     [BgrDataHeight], eax
  2671.         jae     @f
  2672.         mov     [BgrDataHeight], eax
  2673. ;--------------------------------------
  2674. align 4
  2675. @@:
  2676.         mov     eax, [BgrDataWidth]
  2677.         imul    eax, [BgrDataHeight]
  2678.         lea     eax, [eax*3]
  2679. ; it is reserved with aligned to the boundary of 4 KB pages,
  2680. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2681. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2682.         shr     eax, 12
  2683.         inc     eax
  2684.         shl     eax, 12
  2685.         mov     [mem_BACKGROUND], eax
  2686. ; get memory for new background
  2687.         stdcall kernel_alloc, eax
  2688.         test    eax, eax
  2689.         jz      .memfailed
  2690.         mov     [img_background], eax
  2691.         jmp     .exit
  2692. ;--------------------------------------
  2693. align 4
  2694. .memfailed:
  2695. ; revert to static monotone data
  2696.         mov     [img_background], static_background_data
  2697.         xor     eax, eax
  2698.         inc     eax
  2699.         mov     [BgrDataWidth], eax
  2700.         mov     [BgrDataHeight], eax
  2701.         mov     [mem_BACKGROUND], 4
  2702. ;--------------------------------------
  2703. align 4
  2704. .exit:
  2705.         popad
  2706.         mov     [bgrlock], 0
  2707. ;--------------------------------------
  2708. align 4
  2709. sbgrr:
  2710.         ret
  2711. ;------------------------------------------------------------------------------
  2712. align 4
  2713. nosb1:
  2714.         cmp     ebx, 2                     ; SET PIXEL
  2715.         jnz     nosb2
  2716.  
  2717.         mov     eax, [img_background]
  2718.         test    ecx, ecx
  2719.         jz      @f
  2720.         cmp     eax, static_background_data
  2721.         jz      .ret
  2722. ;--------------------------------------
  2723. align 4
  2724. @@:
  2725.         mov     ebx, [mem_BACKGROUND]
  2726.         add     ebx, 4095
  2727.         and     ebx, -4096
  2728.         sub     ebx, 4
  2729.         cmp     ecx, ebx
  2730.         ja      .ret
  2731.  
  2732.         mov     ebx, [eax+ecx]
  2733.         and     ebx, 0xFF000000;255*256*256*256
  2734.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2735.         add     edx, ebx
  2736.         mov     [eax+ecx], edx
  2737. ;--------------------------------------
  2738. align 4
  2739. .ret:
  2740.         ret
  2741. ;------------------------------------------------------------------------------
  2742. align 4
  2743. nosb2:
  2744.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2745.         jnz     nosb3
  2746. ;--------------------------------------
  2747. align 4
  2748. draw_background_temp:
  2749.         mov     [background_defined], 1
  2750.         call    force_redraw_background
  2751. ;--------------------------------------
  2752. align 4
  2753. nosb31:
  2754.         ret
  2755. ;------------------------------------------------------------------------------
  2756. align 4
  2757. nosb3:
  2758.         cmp     ebx, 4                     ; TILED / STRETCHED
  2759.         jnz     nosb4
  2760.         cmp     ecx, [BgrDrawMode]
  2761.         je      nosb41
  2762.         mov     [BgrDrawMode], ecx
  2763. ;--------------------------------------
  2764. align 4
  2765. nosb41:
  2766.         ret
  2767. ;------------------------------------------------------------------------------
  2768. align 4
  2769. nosb4:
  2770.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2771.         jnz     nosb5
  2772.         cmp     [img_background], static_background_data
  2773.         jnz     @f
  2774.         test    edx, edx
  2775.         jnz     .fin
  2776.         cmp     esi, 4
  2777.         ja      .fin
  2778. ;--------------------------------------
  2779. align 4
  2780. @@:
  2781.   ; bughere
  2782.         mov     eax, ecx
  2783.         mov     ebx, edx
  2784.         add     ebx, [img_background];IMG_BACKGROUND
  2785.         mov     ecx, esi
  2786.         call    memmove
  2787. ;--------------------------------------
  2788. align 4
  2789. .fin:
  2790.         ret
  2791. ;------------------------------------------------------------------------------
  2792. align 4
  2793. nosb5:
  2794.         cmp     ebx, 6
  2795.         jnz     nosb6
  2796. ;--------------------------------------
  2797. align 4
  2798. ;;Maxis use atomic bts for mutex 4.4.2009
  2799. @@:
  2800.         bts     dword [bgrlock], 0
  2801.         jnc     @f
  2802.         call    change_task
  2803.         jmp     @b
  2804. ;--------------------------------------
  2805. align 4
  2806. @@:
  2807.         mov     eax, [CURRENT_TASK]
  2808.         mov     [bgrlockpid], eax
  2809.         cmp     [img_background], static_background_data
  2810.         jz      .nomem
  2811.         stdcall user_alloc, [mem_BACKGROUND]
  2812.         mov     [esp+32], eax
  2813.         test    eax, eax
  2814.         jz      .nomem
  2815.         mov     ebx, eax
  2816.         shr     ebx, 12
  2817.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2818.         mov     esi, [img_background]
  2819.         shr     esi, 12
  2820.         mov     ecx, [mem_BACKGROUND]
  2821.         add     ecx, 0xFFF
  2822.         shr     ecx, 12
  2823. ;--------------------------------------
  2824. align 4
  2825. .z:
  2826.         mov     eax, [page_tabs+ebx*4]
  2827.         test    al, 1
  2828.         jz      @f
  2829.         call    free_page
  2830. ;--------------------------------------
  2831. align 4
  2832. @@:
  2833.         mov     eax, [page_tabs+esi*4]
  2834.         or      al, PG_UWR
  2835.         mov     [page_tabs+ebx*4], eax
  2836.         mov     eax, ebx
  2837.         shl     eax, 12
  2838.         invlpg  [eax]
  2839.         inc     ebx
  2840.         inc     esi
  2841.         loop    .z
  2842.         ret
  2843. ;--------------------------------------
  2844. align 4
  2845. .nomem:
  2846.         and     [bgrlockpid], 0
  2847.         mov     [bgrlock], 0
  2848. ;------------------------------------------------------------------------------
  2849. align 4
  2850. nosb6:
  2851.         cmp     ebx, 7
  2852.         jnz     nosb7
  2853.         cmp     [bgrlock], 0
  2854.         jz      .err
  2855.         mov     eax, [CURRENT_TASK]
  2856.         cmp     [bgrlockpid], eax
  2857.         jnz     .err
  2858.         mov     eax, ecx
  2859.         mov     ebx, ecx
  2860.         shr     eax, 12
  2861.         mov     ecx, [page_tabs+(eax-1)*4]
  2862.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2863.         jz      .err
  2864.         jnp     .err
  2865.         push    eax
  2866.         shr     ecx, 12
  2867.         dec     ecx
  2868. ;--------------------------------------
  2869. align 4
  2870. @@:
  2871.         and     dword [page_tabs+eax*4], 0
  2872.         mov     edx, eax
  2873.         shl     edx, 12
  2874.         push    eax