Subversion Repositories Kolibri OS

Rev

Rev 4741 | Rev 5012 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 4772 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_BIOS32
  287. ; MEMORY MODEL
  288.         call    mem_test
  289.         call    init_mem
  290.         call    init_page_map
  291.  
  292. ; ENABLE PAGING
  293.  
  294.         mov     eax, sys_pgdir-OS_BASE
  295.         mov     cr3, eax
  296.  
  297.         mov     eax, cr0
  298.         or      eax, CR0_PG+CR0_WP
  299.         mov     cr0, eax
  300.  
  301.         lgdt    [gdts]
  302.         jmp     pword os_code:high_code
  303.  
  304. align 4
  305. bios32_entry    dd ?
  306. tmp_page_tabs   dd ?
  307.  
  308. use16
  309. org $-0x10000
  310. include "boot/shutdown.inc" ; shutdown or restart
  311. org $+0x10000
  312. use32
  313.  
  314. __DEBUG__ fix 1
  315. __DEBUG_LEVEL__ fix 1
  316. include 'init.inc'
  317.  
  318. org OS_BASE+$
  319.  
  320. include 'fdo.inc'
  321.  
  322. align 4
  323. high_code:
  324.         mov     ax, os_stack
  325.         mov     bx, app_data
  326.         mov     cx, app_tls
  327.         mov     ss, ax
  328.         add     esp, OS_BASE
  329.  
  330.         mov     ds, bx
  331.         mov     es, bx
  332.         mov     fs, cx
  333.         mov     gs, bx
  334.  
  335.         bt      [cpu_caps], CAPS_PGE
  336.         jnc     @F
  337.  
  338.         or      dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  339.  
  340.         mov     ebx, cr4
  341.         or      ebx, CR4_PGE
  342.         mov     cr4, ebx
  343. @@:
  344.         xor     eax, eax
  345.         mov     dword [sys_pgdir], eax
  346.         mov     dword [sys_pgdir+4], eax
  347.  
  348.         mov     eax, cr3
  349.         mov     cr3, eax          ; flush TLB
  350.  
  351.         mov     ecx, pg_data.mutex
  352.         call    mutex_init
  353.  
  354.         mov     ecx, disk_list_mutex
  355.         call    mutex_init
  356.  
  357.         mov     ecx, keyboard_list_mutex
  358.         call    mutex_init
  359.  
  360.         mov     ecx, unpack_mutex
  361.         call    mutex_init
  362.  
  363.         mov     ecx, application_table_mutex
  364.         call    mutex_init
  365.  
  366.         mov     ecx, ide_mutex
  367.         call    mutex_init
  368.         mov     ecx, ide_channel1_mutex
  369.         call    mutex_init
  370.         mov     ecx, ide_channel2_mutex
  371.         call    mutex_init
  372.         mov     ecx, ide_channel3_mutex
  373.         call    mutex_init
  374.         mov     ecx, ide_channel4_mutex
  375.         call    mutex_init
  376.         mov     ecx, ide_channel5_mutex
  377.         call    mutex_init
  378.         mov     ecx, ide_channel6_mutex
  379.         call    mutex_init
  380. ;-----------------------------------------------------------------------------
  381. ; SAVE REAL MODE VARIABLES
  382. ;-----------------------------------------------------------------------------
  383. ; --------------- APM ---------------------
  384.  
  385. ; init selectors
  386.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  387.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  388.                                                                                 ; protected-mode 32-bit code segment
  389.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  390.                                                                                 ; protected-mode 16-bit code segment
  391.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  392.                                                                                 ; protected-mode 16-bit data segment
  393.  
  394.         shl     eax, 4
  395.         mov     [dword apm_code_32 + 2], ax
  396.         shr     eax, 16
  397.         mov     [dword apm_code_32 + 4], al
  398.  
  399.         shl     ecx, 4
  400.         mov     [dword apm_code_16 + 2], cx
  401.         shr     ecx, 16
  402.         mov     [dword apm_code_16 + 4], cl
  403.  
  404.         shl     edx, 4
  405.         mov     [dword apm_data_16 + 2], dx
  406.         shr     edx, 16
  407.         mov     [dword apm_data_16 + 4], dl
  408.  
  409.         mov     dword[apm_entry], ebx
  410.         mov     word [apm_entry + 4], apm_code_32 - gdts
  411.  
  412.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  413.         mov     [apm_vf], eax
  414. ; -----------------------------------------
  415.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  416.         mov     [allow_dma_access], al
  417.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  418.         mov     [_display.bpp], eax
  419.         mov     [_display.vrefresh], 60
  420.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  421.         mov     [debug_direct_print], al
  422.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  423.         mov     [launcher_start], al
  424.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  425.         mov     [_display.width], eax
  426.         mov     [display_width_standard], eax
  427.         dec     eax
  428.         mov     [Screen_Max_X], eax
  429.         mov     [screen_workarea.right], eax
  430.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  431.         mov     [_display.height], eax
  432.         mov     [display_height_standard], eax
  433.         dec     eax
  434.         mov     [Screen_Max_Y], eax
  435.         mov     [screen_workarea.bottom], eax
  436.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  437.         mov     dword [SCR_MODE], eax
  438. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  439. ;        mov     [BANK_SWITCH], eax
  440.         mov     eax, 640 *4                         ; Bytes PerScanLine
  441.         cmp     [SCR_MODE], word 0x13               ; 320x200
  442.         je      @f
  443.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  444.         je      @f
  445.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  446. @@:
  447.         mov     [_display.pitch], eax
  448.         mov     eax, [_display.width]
  449.         mul     [_display.height]
  450.         mov     [_WinMapSize], eax
  451.  
  452.         call    calculate_fast_getting_offset_for_WinMapAddress
  453. ; for Qemu or non standart video cards
  454. ; Unfortunately [BytesPerScanLine] does not always
  455. ;                             equal to [_display.width] * [ScreenBPP] / 8
  456.         call    calculate_fast_getting_offset_for_LFB
  457.  
  458.         mov     esi, BOOT_VARS+0x9080
  459.         movzx   ecx, byte [esi-1]
  460.         mov     [NumBiosDisks], ecx
  461.         mov     edi, BiosDisksData
  462.         rep movsd
  463.  
  464. ; GRAPHICS ADDRESSES
  465.  
  466.         mov     eax, [BOOT_VARS+BOOT_LFB]
  467.         mov     [LFBAddress], eax
  468.  
  469.         cmp     [SCR_MODE], word 0100000000000000b
  470.         jge     setvesa20
  471.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  472.         je      v20ga32
  473.         jmp     v20ga24
  474.  
  475. setvesa20:
  476.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  477.         mov     [GETPIXEL], dword Vesa20_getpixel24
  478.         cmp     byte [_display.bpp], 24
  479.         jz      v20ga24
  480. v20ga32:
  481.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  482.         mov     [GETPIXEL], dword Vesa20_getpixel32
  483.         jmp     no_mode_0x12
  484. v20ga24:
  485.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  486.         jne     no_mode_0x12
  487.         mov     [PUTPIXEL], dword VGA_putpixel
  488.         mov     [GETPIXEL], dword Vesa20_getpixel32
  489. no_mode_0x12:
  490.  
  491.         mov     [MOUSE_PICTURE], dword mousepointer
  492.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  493.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  494.  
  495. ; -------- Fast System Call init ----------
  496. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  497.         bt      [cpu_caps], CAPS_SEP
  498.         jnc     .SEnP  ; SysEnter not Present
  499.         xor     edx, edx
  500.         mov     ecx, MSR_SYSENTER_CS
  501.         mov     eax, os_code
  502.         wrmsr
  503.         mov     ecx, MSR_SYSENTER_ESP
  504. ;           mov eax, sysenter_stack ; Check it
  505.         xor     eax, eax
  506.         wrmsr
  507.         mov     ecx, MSR_SYSENTER_EIP
  508.         mov     eax, sysenter_entry
  509.         wrmsr
  510. .SEnP:
  511. ; AMD SYSCALL/SYSRET
  512.         cmp     byte[cpu_vendor], 'A'
  513.         jne     .noSYSCALL
  514.         mov     eax, 0x80000001
  515.         cpuid
  516.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  517.         jz      .noSYSCALL
  518.         mov     ecx, MSR_AMD_EFER
  519.         rdmsr
  520.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  521.         wrmsr
  522.  
  523.         ; !!!! It`s dirty hack, fix it !!!
  524.         ; Bits of EDX :
  525.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  526.         ;  and the contents of this field, plus 8, are copied into the SS register.
  527.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  528.         ;  and the contents of this field, plus 8, are copied into the SS register.
  529.  
  530.         ; mov   edx, (os_code + 16) * 65536 + os_code
  531.         mov     edx, 0x1B0008
  532.  
  533.         mov     eax, syscall_entry
  534.         mov     ecx, MSR_AMD_STAR
  535.         wrmsr
  536. .noSYSCALL:
  537. ; -----------------------------------------
  538.         stdcall alloc_page
  539.         stdcall map_page, tss-0xF80, eax, PG_SW
  540.         stdcall alloc_page
  541.         stdcall map_page, tss+0x80, eax, PG_SW
  542.         stdcall alloc_page
  543.         stdcall map_page, tss+0x1080, eax, PG_SW
  544.  
  545. ; LOAD IDT
  546.  
  547.         call    build_interrupt_table ;lidt is executed
  548.           ;lidt [idtreg]
  549.  
  550.         call    init_kernel_heap
  551.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  552.         mov     [os_stack_seg], eax
  553.  
  554.         lea     esp, [eax+RING0_STACK_SIZE]
  555.  
  556.         mov     [tss._ss0], os_stack
  557.         mov     [tss._esp0], esp
  558.         mov     [tss._esp], esp
  559.         mov     [tss._cs], os_code
  560.         mov     [tss._ss], os_stack
  561.         mov     [tss._ds], app_data
  562.         mov     [tss._es], app_data
  563.         mov     [tss._fs], app_data
  564.         mov     [tss._gs], app_data
  565.         mov     [tss._io], 128
  566. ;Add IO access table - bit array of permitted ports
  567.         mov     edi, tss._io_map_0
  568.         xor     eax, eax
  569.         not     eax
  570.         mov     ecx, 8192/4
  571.         rep stosd                    ; access to 4096*8=65536 ports
  572.  
  573.         mov     ax, tss0
  574.         ltr     ax
  575.  
  576.         mov     [LFBSize], 0xC00000
  577.         call    init_LFB
  578.         call    init_fpu
  579.         call    init_malloc
  580.  
  581.         stdcall alloc_kernel_space, 0x51000
  582.         mov     [default_io_map], eax
  583.  
  584.         add     eax, 0x2000
  585.         mov     [ipc_tmp], eax
  586.         mov     ebx, 0x1000
  587.  
  588.         add     eax, 0x40000
  589.         mov     [proc_mem_map], eax
  590.  
  591.         add     eax, 0x8000
  592.         mov     [proc_mem_pdir], eax
  593.  
  594.         add     eax, ebx
  595.         mov     [proc_mem_tab], eax
  596.  
  597.         add     eax, ebx
  598.         mov     [tmp_task_pdir], eax
  599.  
  600.         add     eax, ebx
  601.         mov     [tmp_task_ptab], eax
  602.  
  603.         add     eax, ebx
  604.         mov     [ipc_pdir], eax
  605.  
  606.         add     eax, ebx
  607.         mov     [ipc_ptab], eax
  608.  
  609.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  610.                 (unpack.lc+unpack.lp)))*4
  611.  
  612.         mov     [unpack.p], eax
  613.  
  614.         call    init_events
  615.         mov     eax, srv.fd-SRV.fd
  616.         mov     [srv.fd], eax
  617.         mov     [srv.bk], eax
  618.  
  619. ;Set base of graphic segment to linear address of LFB
  620.         mov     eax, [LFBAddress]         ; set for gs
  621.         mov     [graph_data_l+2], ax
  622.         shr     eax, 16
  623.         mov     [graph_data_l+4], al
  624.         mov     [graph_data_l+7], ah
  625.  
  626.         stdcall kernel_alloc, [_WinMapSize]
  627.         mov     [_WinMapAddress], eax
  628.  
  629.         xor     eax, eax
  630.         inc     eax
  631.  
  632. ; set background
  633.  
  634.         mov     [BgrDrawMode], eax
  635.         mov     [BgrDataWidth], eax
  636.         mov     [BgrDataHeight], eax
  637.         mov     [mem_BACKGROUND], 4
  638.         mov     [img_background], static_background_data
  639.  
  640. ; set clipboard
  641.  
  642.         xor     eax, eax
  643.         mov     [clipboard_slots], eax
  644.         mov     [clipboard_write_lock], eax
  645.         stdcall kernel_alloc, 4096
  646.         test    eax, eax
  647.         jnz     @f
  648.  
  649.         dec     eax
  650. @@:
  651.         mov     [clipboard_main_list], eax
  652.  
  653. ; SET UP OS TASK
  654.  
  655.         mov     esi, boot_setostask
  656.         call    boot_log
  657.  
  658.         mov     edx, SLOT_BASE+256
  659.         mov     ebx, [os_stack_seg]
  660.         add     ebx, 0x2000
  661.         call    setup_os_slot
  662.         mov     dword [edx], 'IDLE'
  663.         sub     [edx+APPDATA.saved_esp], 4
  664.         mov     eax, [edx+APPDATA.saved_esp]
  665.         mov     dword [eax], idle_thread
  666.         mov     ecx, IDLE_PRIORITY
  667.         call    scheduler_add_thread
  668.  
  669.         mov     edx, SLOT_BASE+256*2
  670.         mov     ebx, [os_stack_seg]
  671.         call    setup_os_slot
  672.         mov     dword [edx], 'OS'
  673.         xor     ecx, ecx
  674.         call    scheduler_add_thread
  675.  
  676.         mov     dword [CURRENT_TASK], 2
  677.         mov     dword [TASK_COUNT], 2
  678.         mov     dword [current_slot], SLOT_BASE + 256*2
  679.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  680.  
  681.  
  682. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  683.         mov     esi, boot_initirq
  684.         call    boot_log
  685.         call    init_irqs
  686.  
  687.         mov     esi, boot_picinit
  688.         call    boot_log
  689.         call    PIC_init
  690.  
  691.         mov     esi, boot_v86machine
  692.         call    boot_log
  693. ; Initialize system V86 machine
  694.         call    init_sys_v86
  695.  
  696.         mov     esi, boot_inittimer
  697.         call    boot_log
  698. ; Initialize system timer (IRQ0)
  699.         call    PIT_init
  700.  
  701. ; Register ramdisk file system
  702.         cmp     [boot_dev+OS_BASE+0x10000], 1
  703.         je      @f
  704.  
  705.         call    register_ramdisk
  706. ;--------------------------------------
  707. @@:
  708.         mov     esi, boot_initapic
  709.         call    boot_log
  710. ; Try to Initialize APIC
  711.         call    APIC_init
  712.  
  713.         mov     esi, boot_enableirq
  714.         call    boot_log
  715. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  716. ; they are used: when partitions are scanned, hd_read relies on timer
  717.         call    unmask_timer
  718.         stdcall enable_irq, 2               ; @#$%! PIC
  719.         stdcall enable_irq, 13              ; co-processor
  720.  
  721. ; Setup serial output console (if enabled)
  722. if defined debug_com_base
  723.  
  724.         ; reserve port so nobody else will use it
  725.         xor     ebx, ebx
  726.         mov     ecx, debug_com_base
  727.         mov     edx, debug_com_base+7
  728.         call    r_f_port_area
  729.  
  730.         ; enable Divisor latch
  731.         mov     dx, debug_com_base+3
  732.         mov     al, 1 shl 7
  733.         out     dx, al
  734.  
  735.         ; Set speed to 115200 baud (max speed)
  736.         mov     dx, debug_com_base
  737.         mov     al, 0x01
  738.         out     dx, al
  739.  
  740.         mov     dx, debug_com_base+1
  741.         mov     al, 0x00
  742.         out     dx, al
  743.  
  744.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  745.         mov     dx, debug_com_base+3
  746.         mov     al, 3
  747.         out     dx, al
  748.  
  749.         ; disable interrupts
  750.         mov     dx, debug_com_base+1
  751.         mov     al, 0
  752.         out     dx, al
  753.  
  754.         ; clear +  enable fifo (64 bits)
  755.         mov     dx, debug_com_base+2
  756.         mov     al, 0x7 + 1 shl 5
  757.         out     dx, al
  758.  
  759. end if
  760.  
  761.  
  762. ;-----------------------------------------------------------------------------
  763. ; show SVN version of kernel on the message board
  764. ;-----------------------------------------------------------------------------
  765.         mov     eax, [version_inf.rev]
  766.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  767. ;-----------------------------------------------------------------------------
  768. ; show CPU count on the message board
  769. ;-----------------------------------------------------------------------------
  770.         mov     eax, [cpu_count]
  771.         test    eax, eax
  772.         jnz     @F
  773.         mov     al, 1                             ; at least one CPU
  774. @@:
  775.         DEBUGF  1, "K : %d CPU detected\n", eax
  776. ;-----------------------------------------------------------------------------
  777. ; detect Floppy drives
  778. ;-----------------------------------------------------------------------------
  779.         mov     esi, boot_detectfloppy
  780.         call    boot_log
  781. include 'detect/dev_fd.inc'
  782. ;-----------------------------------------------------------------------------
  783. ; create pci-devices list
  784. ;-----------------------------------------------------------------------------
  785.         mov     [pci_access_enabled], 1
  786.         call    pci_enum
  787. ;-----------------------------------------------------------------------------
  788. ; initialisation IDE ATA code
  789. ;-----------------------------------------------------------------------------
  790. include 'detect/init_ata.inc'
  791. ;-----------------------------------------------------------------------------
  792. if 0
  793.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  794.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  795.         je      no_lib_load
  796.  
  797.         mov     esi, boot_loadlibs
  798.         call    boot_log
  799. ; LOADING LIBRARES
  800.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  801.         call    load_file_parse_table       ; prepare file parse table
  802.         call    set_kernel_conf             ; configure devices and gui
  803. no_lib_load:
  804. end if
  805.  
  806. ; Display APIC status
  807.         mov     esi, boot_APIC_found
  808.         cmp     [irq_mode], IRQ_APIC
  809.         je      @f
  810.         mov     esi, boot_APIC_nfound
  811. @@:
  812.         call    boot_log
  813.  
  814. ; PRINT AMOUNT OF MEMORY
  815.         mov     esi, boot_memdetect
  816.         call    boot_log
  817.  
  818.         movzx   ecx, word [boot_y]
  819.         if lang eq ru
  820.         or      ecx, (10+30*6) shl 16
  821.         else if lang eq sp
  822.         or      ecx, (10+33*6) shl 16
  823.         else
  824.         or      ecx, (10+29*6) shl 16
  825.         end if
  826.         sub     ecx, 10
  827.         mov     edx, 0xFFFFFF
  828.         mov     ebx, [MEM_AMOUNT]
  829.         shr     ebx, 20
  830.         xor     edi, edi
  831.         mov     eax, 0x00040000
  832.         inc     edi
  833.         call    display_number_force
  834.  
  835. ; BUILD SCHEDULER
  836.  
  837. ;        call    build_scheduler; sys32.inc
  838.  
  839. ;        mov     esi, boot_devices
  840. ;        call    boot_log
  841.  
  842.         call    clear_pci_ide_interrupts
  843.  
  844. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  845.  
  846.         stdcall load_driver, szVidintel
  847.  
  848.         call    usb_init
  849.  
  850. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  851.  
  852.         mov     esi, boot_windefs
  853.         call    boot_log
  854.         call    set_window_defaults
  855.  
  856. ; SET BACKGROUND DEFAULTS
  857.  
  858.         mov     esi, boot_bgr
  859.         call    boot_log
  860.         call    init_background
  861.         call    calculatebackground
  862.  
  863. ; RESERVE SYSTEM IRQ'S JA PORT'S
  864.  
  865.         mov     esi, boot_resirqports
  866.         call    boot_log
  867.         call    reserve_irqs_ports
  868.  
  869.         call    init_display
  870.         mov     eax, [def_cursor]
  871.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  872.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  873.  
  874. ; PRINT CPU FREQUENCY
  875.  
  876.         mov     esi, boot_cpufreq
  877.         call    boot_log
  878.  
  879.         cli                         ;FIXME check IF
  880.         rdtsc
  881.         mov     ecx, eax
  882.         mov     esi, 250            ; wait 1/4 a second
  883.         call    delay_ms
  884.         rdtsc
  885.  
  886.         sub     eax, ecx
  887.         xor     edx, edx
  888.         shld    edx, eax, 2
  889.         shl     eax, 2
  890.         mov     dword [cpu_freq], eax
  891.         mov     dword [cpu_freq+4], edx
  892.         mov     ebx, 1000000
  893.         div     ebx
  894.         mov     ebx, eax
  895.  
  896.         movzx   ecx, word [boot_y]
  897.         if lang eq ru
  898.         add     ecx, (10+19*6) shl 16 - 10
  899.         else if lang eq sp
  900.         add     ecx, (10+25*6) shl 16 - 10
  901.         else
  902.         add     ecx, (10+17*6) shl 16 - 10
  903.         end if
  904.  
  905.         mov     edx, 0xFFFFFF
  906.         xor     edi, edi
  907.         mov     eax, 0x00040000
  908.         inc     edi
  909.         call    display_number_force
  910.  
  911. ; SET VARIABLES
  912.  
  913.         call    set_variables
  914.  
  915. ; STACK AND FDC
  916.  
  917.         call    stack_init
  918.         call    fdc_init
  919.  
  920. ; PALETTE FOR 320x200 and 640x480 16 col
  921.  
  922.         cmp     [SCR_MODE], word 0x12
  923.         jne     no_pal_vga
  924.         mov     esi, boot_pal_vga
  925.         call    boot_log
  926.         call    paletteVGA
  927.       no_pal_vga:
  928.  
  929.         cmp     [SCR_MODE], word 0x13
  930.         jne     no_pal_ega
  931.         mov     esi, boot_pal_ega
  932.         call    boot_log
  933.         call    palette320x200
  934.       no_pal_ega:
  935.  
  936. ; LOAD DEFAULT SKIN
  937.  
  938.         call    load_default_skin
  939.  
  940. ;protect io permission map
  941.  
  942.         mov     esi, [default_io_map]
  943.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  944.         add     esi, 0x1000
  945.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  946.  
  947.         stdcall map_page, tss._io_map_0, \
  948.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  949.         stdcall map_page, tss._io_map_1, \
  950.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  951.  
  952. ; LOAD FIRST APPLICATION
  953.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  954.         jnz     first_app_found
  955.  
  956.         cli
  957.         mov     ebp, firstapp
  958.         call    fs_execute_from_sysdir
  959.         test    eax, eax
  960.         jns     first_app_found
  961.  
  962.         mov     esi, boot_failed
  963.         call    boot_log
  964.  
  965.         mov     eax, 0xDEADBEEF      ; otherwise halt
  966.         hlt
  967.  
  968. first_app_found:
  969.  
  970.         cli
  971.  
  972. ; SET KEYBOARD PARAMETERS
  973.         mov     al, 0xf6       ; reset keyboard, scan enabled
  974.         call    kb_write
  975.         test    ah, ah
  976.         jnz     .no_keyboard
  977.  
  978.         ; wait until 8042 is ready
  979.         xor     ecx, ecx
  980.       @@:
  981.         in      al, 64h
  982.         and     al, 00000010b
  983.         loopnz  @b
  984.  
  985. iglobal
  986. align 4
  987. ps2_keyboard_functions:
  988.         dd      .end - $
  989.         dd      0       ; no close
  990.         dd      ps2_set_lights
  991. .end:
  992. endg
  993.         stdcall register_keyboard, ps2_keyboard_functions, 0
  994.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  995.        ; call  kb_write
  996.        ; call  kb_read
  997.        ; mov   al, 111b
  998.        ; call  kb_write
  999.        ; call  kb_read
  1000.  
  1001.         mov     al, 0xF3     ; set repeat rate & delay
  1002.         call    kb_write
  1003. ;        call  kb_read
  1004.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1005.         call    kb_write
  1006. ;        call  kb_read
  1007.      ;// mike.dld [
  1008.         call    set_lights
  1009.      ;// mike.dld ]
  1010.         stdcall attach_int_handler, 1, irq1, 0
  1011.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1012. .no_keyboard:
  1013.  
  1014. ; Load PS/2 mouse driver
  1015.  
  1016.         stdcall load_driver, szPS2MDriver
  1017.  
  1018.         mov     esi, boot_setmouse
  1019.         call    boot_log
  1020.         call    setmouse
  1021.  
  1022. ; START MULTITASKING
  1023.  
  1024. ; A 'All set - press ESC to start' messages if need
  1025. if preboot_blogesc
  1026.         mov     esi, boot_tasking
  1027.         call    boot_log
  1028. .bll1:
  1029.         in      al, 0x60        ; wait for ESC key press
  1030.         cmp     al, 129
  1031.         jne     .bll1
  1032. end if
  1033.  
  1034.         mov     [timer_ticks_enable], 1         ; for cd driver
  1035.  
  1036.         sti
  1037.  
  1038.         call    mtrr_validate
  1039.  
  1040.         jmp     osloop
  1041.  
  1042.  
  1043.         ; Fly :)
  1044.  
  1045. include 'unpacker.inc'
  1046.  
  1047. align 4
  1048. boot_log:
  1049.         pushad
  1050.  
  1051.         mov     ebx, 10*65536
  1052.         mov     bx, word [boot_y]
  1053.         add     [boot_y], dword 10
  1054.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1055.         xor     edi, edi
  1056.         mov     edx, esi
  1057.         inc     edi
  1058.         call    dtext
  1059.  
  1060.         mov     [novesachecksum], 1000
  1061.         call    checkVga_N13
  1062.  
  1063.         popad
  1064.  
  1065.         ret
  1066.  
  1067. ; in: edx -> APPDATA for OS/IDLE slot
  1068. ; in: ebx = stack base
  1069. proc setup_os_slot
  1070.         xor     eax, eax
  1071.         mov     ecx, 256/4
  1072.         mov     edi, edx
  1073.         rep stosd
  1074.  
  1075.         mov     eax, tss+0x80
  1076.         call    get_pg_addr
  1077.         inc     eax
  1078.         mov     [edx+APPDATA.io_map], eax
  1079.         mov     eax, tss+0x1080
  1080.         call    get_pg_addr
  1081.         inc     eax
  1082.         mov     [edx+APPDATA.io_map+4], eax
  1083.  
  1084.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1085.         lea     edi, [ebx+0x2000-512]
  1086.         mov     dword [edx+APPDATA.fpu_state], edi
  1087.         mov     dword [edx+APPDATA.saved_esp0], edi
  1088.         mov     dword [edx+APPDATA.saved_esp], edi
  1089.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1090.  
  1091.         mov     esi, fpu_data
  1092.         mov     ecx, 512/4
  1093.         cld
  1094.         rep movsd
  1095.  
  1096.         lea     eax, [edx+APP_OBJ_OFFSET]
  1097.         mov     dword [edx+APPDATA.fd_obj], eax
  1098.         mov     dword [edx+APPDATA.bk_obj], eax
  1099.  
  1100.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1101.  
  1102.         mov     [edx + APPDATA.dir_table], sys_pgdir - OS_BASE
  1103.  
  1104.         mov     eax, edx
  1105.         shr     eax, 3
  1106.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1107.         mov     [eax+TASKDATA.wnd_number], dh
  1108.         mov     byte [eax+TASKDATA.pid], dh
  1109.  
  1110.         ret
  1111. endp
  1112.  
  1113. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1114. ;                                                                    ;
  1115. ;                    MAIN OS LOOP START                              ;
  1116. ;                                                                    ;
  1117. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1118. align 32
  1119. osloop:
  1120.         mov     edx, osloop_has_work?
  1121.         xor     ecx, ecx
  1122.         call    Wait_events
  1123.         xor     eax, eax
  1124.         xchg    eax, [osloop_nonperiodic_work]
  1125.         test    eax, eax
  1126.         jz      .no_periodic
  1127.  
  1128.         call    __sys_draw_pointer
  1129.         call    window_check_events
  1130.         call    mouse_check_events
  1131.         call    checkmisc
  1132.         call    checkVga_N13
  1133. ;--------------------------------------
  1134. .no_periodic:
  1135.         call    stack_handler
  1136.         call    check_fdd_motor_status
  1137.         call    check_ATAPI_device_event
  1138.         call    check_lights_state
  1139.         call    check_timers
  1140.  
  1141.         jmp     osloop
  1142. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1143. ;                                                                    ;
  1144. ;                      MAIN OS LOOP END                              ;
  1145. ;                                                                    ;
  1146. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1147. proc osloop_has_work?
  1148.         cmp     [osloop_nonperiodic_work], 0
  1149.         jnz     .yes
  1150.         call    stack_handler_has_work?
  1151.         jnz     .yes
  1152.         call    check_fdd_motor_status_has_work?
  1153.         jnz     .yes
  1154.         call    check_ATAPI_device_event_has_work?
  1155.         jnz     .yes
  1156.         call    check_lights_state_has_work?
  1157.         jnz     .yes
  1158.         call    check_timers_has_work?
  1159.         jnz     .yes
  1160. .no:
  1161.         xor     eax, eax
  1162.         ret
  1163. .yes:
  1164.         xor     eax, eax
  1165.         inc     eax
  1166.         ret
  1167. endp
  1168.  
  1169. proc wakeup_osloop
  1170.         mov     [osloop_nonperiodic_work], 1
  1171.         ret
  1172. endp
  1173.  
  1174. uglobal
  1175. align 4
  1176. osloop_nonperiodic_work dd      ?
  1177. endg
  1178.  
  1179. align 4
  1180. idle_thread:
  1181.         sti
  1182. idle_loop:
  1183.         hlt
  1184.         jmp     idle_loop
  1185.  
  1186.  
  1187.  
  1188. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1189. ;                                                                      ;
  1190. ;                   INCLUDED SYSTEM FILES                              ;
  1191. ;                                                                      ;
  1192. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1193.  
  1194.  
  1195. include "kernel32.inc"
  1196.  
  1197.  
  1198. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1199. ;                                                                      ;
  1200. ;                       KERNEL FUNCTIONS                               ;
  1201. ;                                                                      ;
  1202. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1203.  
  1204. reserve_irqs_ports:
  1205.  
  1206.  
  1207. ; RESERVE PORTS
  1208.         mov     eax, RESERVED_PORTS
  1209.         mov     ecx, 1
  1210.  
  1211.         mov     [eax], dword 4
  1212.  
  1213.         mov     [eax+16], ecx
  1214.         mov     [eax+16+4], dword 0
  1215.         mov     [eax+16+8], dword 0x2D
  1216.  
  1217.         mov     [eax+32], ecx
  1218.         mov     [eax+32+4], dword 0x30
  1219.         mov     [eax+32+8], dword 0x4D
  1220.  
  1221.         mov     [eax+48], ecx
  1222.         mov     [eax+48+4], dword 0x50
  1223.         mov     [eax+48+8], dword 0xDF
  1224.  
  1225.         mov     [eax+64], ecx
  1226.         mov     [eax+64+4], dword 0xE5
  1227.         mov     [eax+64+8], dword 0xFF
  1228.  
  1229.         ret
  1230.  
  1231.  
  1232. iglobal
  1233.   process_number dd 0x2
  1234. endg
  1235.  
  1236. set_variables:
  1237.  
  1238.         mov     ecx, 0x16                    ; flush port 0x60
  1239. .fl60:
  1240.         in      al, 0x60
  1241.         loop    .fl60
  1242.         push    eax
  1243.  
  1244.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1245.         shr     ax, 1
  1246.         shl     eax, 16
  1247.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1248.         shr     ax, 1
  1249.         mov     [MOUSE_X], eax
  1250.         call    wakeup_osloop
  1251.  
  1252.         xor     eax, eax
  1253.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1254.  
  1255.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1256.         mov     byte [BTN_COUNT], al              ; button buffer
  1257. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1258.  
  1259.         pop     eax
  1260.         ret
  1261.  
  1262. align 4
  1263. ;input  eax=43,bl-byte of output, ecx - number of port
  1264. sys_outport:
  1265.  
  1266.         mov     edi, ecx   ; separate flag for read / write
  1267.         and     ecx, 65535
  1268.  
  1269.         mov     eax, [RESERVED_PORTS]
  1270.         test    eax, eax
  1271.         jnz     .sopl8
  1272.         inc     eax
  1273.         mov     [esp+32], eax
  1274.         ret
  1275.  
  1276.   .sopl8:
  1277.         mov     edx, [TASK_BASE]
  1278.         mov     edx, [edx+0x4]
  1279.     ;and   ecx,65535
  1280.     ;cld - set on interrupt 0x40
  1281.   .sopl1:
  1282.  
  1283.         mov     esi, eax
  1284.         shl     esi, 4
  1285.         add     esi, RESERVED_PORTS
  1286.         cmp     edx, [esi+0]
  1287.         jne     .sopl2
  1288.         cmp     ecx, [esi+4]
  1289.         jb      .sopl2
  1290.         cmp     ecx, [esi+8]
  1291.         jg      .sopl2
  1292. .sopl3:
  1293.  
  1294.         test    edi, 0x80000000; read ?
  1295.         jnz     .sopl4
  1296.  
  1297.         mov     eax, ebx
  1298.         mov     dx, cx   ; write
  1299.         out     dx, al
  1300.         and     [esp+32], dword 0
  1301.         ret
  1302.  
  1303.         .sopl2:
  1304.  
  1305.         dec     eax
  1306.         jnz     .sopl1
  1307.         inc     eax
  1308.         mov     [esp+32], eax
  1309.         ret
  1310.  
  1311.  
  1312.   .sopl4:
  1313.  
  1314.         mov     dx, cx   ; read
  1315.         in      al, dx
  1316.         and     eax, 0xff
  1317.         and     [esp+32], dword 0
  1318.         mov     [esp+20], eax
  1319.         ret
  1320.  
  1321. display_number:
  1322. ;It is not optimization
  1323.         mov     eax, ebx
  1324.         mov     ebx, ecx
  1325.         mov     ecx, edx
  1326.         mov     edx, esi
  1327.         mov     esi, edi
  1328. ; eax = print type, al=0 -> ebx is number
  1329. ;                   al=1 -> ebx is pointer
  1330. ;                   ah=0 -> display decimal
  1331. ;                   ah=1 -> display hexadecimal
  1332. ;                   ah=2 -> display binary
  1333. ;                   eax bits 16-21 = number of digits to display (0-32)
  1334. ;                   eax bits 22-31 = reserved
  1335. ;
  1336. ; ebx = number or pointer
  1337. ; ecx = x shl 16 + y
  1338. ; edx = color
  1339.         xor     edi, edi
  1340. display_number_force:
  1341.         push    eax
  1342.         and     eax, 0x3fffffff
  1343.         cmp     eax, 0xffff     ; length > 0 ?
  1344.         pop     eax
  1345.         jge     cont_displ
  1346.         ret
  1347.    cont_displ:
  1348.         push    eax
  1349.         and     eax, 0x3fffffff
  1350.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1351.         pop     eax
  1352.         jb      cont_displ2
  1353.         ret
  1354.    cont_displ2:
  1355.  
  1356.         pushad
  1357.  
  1358.         cmp     al, 1            ; ecx is a pointer ?
  1359.         jne     displnl1
  1360.         mov     ebp, ebx
  1361.         add     ebp, 4
  1362.         mov     ebp, [ebp+std_application_base_address]
  1363.         mov     ebx, [ebx+std_application_base_address]
  1364.  displnl1:
  1365.         sub     esp, 64
  1366.  
  1367.         test    ah, ah            ; DECIMAL
  1368.         jnz     no_display_desnum
  1369.         shr     eax, 16
  1370.         and     eax, 0xC03f
  1371. ;     and   eax,0x3f
  1372.         push    eax
  1373.         and     eax, 0x3f
  1374.         mov     edi, esp
  1375.         add     edi, 4+64-1
  1376.         mov     ecx, eax
  1377.         mov     eax, ebx
  1378.         mov     ebx, 10
  1379.  d_desnum:
  1380.         xor     edx, edx
  1381.         call    division_64_bits
  1382.         div     ebx
  1383.         add     dl, 48
  1384.         mov     [edi], dl
  1385.         dec     edi
  1386.         loop    d_desnum
  1387.         pop     eax
  1388.         call    normalize_number
  1389.         call    draw_num_text
  1390.         add     esp, 64
  1391.         popad
  1392.         ret
  1393.    no_display_desnum:
  1394.  
  1395.         cmp     ah, 0x01         ; HEXADECIMAL
  1396.         jne     no_display_hexnum
  1397.         shr     eax, 16
  1398.         and     eax, 0xC03f
  1399. ;     and   eax,0x3f
  1400.         push    eax
  1401.         and     eax, 0x3f
  1402.         mov     edi, esp
  1403.         add     edi, 4+64-1
  1404.         mov     ecx, eax
  1405.         mov     eax, ebx
  1406.         mov     ebx, 16
  1407.    d_hexnum:
  1408.         xor     edx, edx
  1409.         call    division_64_bits
  1410.         div     ebx
  1411.    hexletters = __fdo_hexdigits
  1412.         add     edx, hexletters
  1413.         mov     dl, [edx]
  1414.         mov     [edi], dl
  1415.         dec     edi
  1416.         loop    d_hexnum
  1417.         pop     eax
  1418.         call    normalize_number
  1419.         call    draw_num_text
  1420.         add     esp, 64
  1421.         popad
  1422.         ret
  1423.    no_display_hexnum:
  1424.  
  1425.         cmp     ah, 0x02         ; BINARY
  1426.         jne     no_display_binnum
  1427.         shr     eax, 16
  1428.         and     eax, 0xC03f
  1429. ;     and   eax,0x3f
  1430.         push    eax
  1431.         and     eax, 0x3f
  1432.         mov     edi, esp
  1433.         add     edi, 4+64-1
  1434.         mov     ecx, eax
  1435.         mov     eax, ebx
  1436.         mov     ebx, 2
  1437.    d_binnum:
  1438.         xor     edx, edx
  1439.         call    division_64_bits
  1440.         div     ebx
  1441.         add     dl, 48
  1442.         mov     [edi], dl
  1443.         dec     edi
  1444.         loop    d_binnum
  1445.         pop     eax
  1446.         call    normalize_number
  1447.         call    draw_num_text
  1448.         add     esp, 64
  1449.         popad
  1450.         ret
  1451.    no_display_binnum:
  1452.  
  1453.         add     esp, 64
  1454.         popad
  1455.         ret
  1456.  
  1457. normalize_number:
  1458.         test    ah, 0x80
  1459.         jz      .continue
  1460.         mov     ecx, 48
  1461.         and     eax, 0x3f
  1462. @@:
  1463.         inc     edi
  1464.         cmp     [edi], cl
  1465.         jne     .continue
  1466.         dec     eax
  1467.         cmp     eax, 1
  1468.         ja      @r
  1469.         mov     al, 1
  1470. .continue:
  1471.         and     eax, 0x3f
  1472.         ret
  1473.  
  1474. division_64_bits:
  1475.         test    [esp+1+4], byte 0x40
  1476.         jz      .continue
  1477.         push    eax
  1478.         mov     eax, ebp
  1479.         div     ebx
  1480.         mov     ebp, eax
  1481.         pop     eax
  1482. .continue:
  1483.         ret
  1484.  
  1485. draw_num_text:
  1486.         mov     esi, eax
  1487.         mov     edx, 64+4
  1488.         sub     edx, eax
  1489.         add     edx, esp
  1490.         mov     ebx, [esp+64+32-8+4]
  1491. ; add window start x & y
  1492.         mov     ecx, [TASK_BASE]
  1493.  
  1494.         mov     edi, [CURRENT_TASK]
  1495.         shl     edi, 8
  1496.  
  1497.         mov     eax, [ecx-twdw+WDATA.box.left]
  1498.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1499.         shl     eax, 16
  1500.         add     eax, [ecx-twdw+WDATA.box.top]
  1501.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1502.         add     ebx, eax
  1503.         mov     ecx, [esp+64+32-12+4]
  1504.         and     ecx, not 0x80000000     ; force counted string
  1505.         mov     eax, [esp+64+8]         ; background color (if given)
  1506.         mov     edi, [esp+64+4]
  1507.         jmp     dtext
  1508. ;-----------------------------------------------------------------------------
  1509. iglobal
  1510. midi_base dw 0
  1511. endg
  1512. ;-----------------------------------------------------------------------------
  1513. align 4
  1514. sys_setup:
  1515. ;  1 = roland mpu midi base , base io address
  1516. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1517. ;  3 = not used
  1518. ;  4 = not used
  1519. ;  5 = system language, 1eng 2fi 3ger 4rus
  1520. ;  6 = not used
  1521. ;  7 = not used
  1522. ;  8 = not used
  1523. ;  9 = not used
  1524. ; 10 = not used
  1525. ; 11 = enable lba read
  1526. ; 12 = enable pci access
  1527. ;-----------------------------------------------------------------------------
  1528.         and     [esp+32], dword 0
  1529. ; F.21.1 - set MPU MIDI base port
  1530.         dec     ebx
  1531.         jnz     @f
  1532.  
  1533.         cmp     ecx, 0x100
  1534.         jb      @f
  1535.  
  1536.         mov     esi, 65535
  1537.         cmp     esi, ecx
  1538.         jb      @f
  1539.  
  1540.         mov     [midi_base], cx
  1541.         mov     word [mididp], cx
  1542.         inc     cx
  1543.         mov     word [midisp], cx
  1544.         ret
  1545. ;--------------------------------------
  1546. @@:
  1547. ; F.21.2 - set keyboard layout
  1548.         dec     ebx
  1549.         jnz     @f
  1550.  
  1551.         mov     edi, [TASK_BASE]
  1552.         mov     eax, [edi+TASKDATA.mem_start]
  1553.         add     eax, edx
  1554. ; 1 = normal layout
  1555.         dec     ecx
  1556.         jnz     .shift
  1557.  
  1558.         mov     ebx, keymap
  1559.         mov     ecx, 128
  1560.         call    memmove
  1561.         ret
  1562. ;--------------------------------------
  1563. .shift:
  1564. ; 2 = layout at pressed Shift
  1565.         dec     ecx
  1566.         jnz     .alt
  1567.  
  1568.         mov     ebx, keymap_shift
  1569.         mov     ecx, 128
  1570.         call    memmove
  1571.         ret
  1572. ;--------------------------------------
  1573. .alt:
  1574. ; 3 = layout at pressed Alt
  1575.         dec     ecx
  1576.         jnz     .country
  1577.  
  1578.         mov     ebx, keymap_alt
  1579.         mov     ecx, 128
  1580.         call    memmove
  1581.         ret
  1582. ;--------------------------------------
  1583. .country:
  1584. ; country identifier
  1585.         sub     ecx, 6
  1586.         jnz     .error
  1587.  
  1588.         mov     word [keyboard], dx
  1589.         ret
  1590. ;--------------------------------------
  1591. @@:
  1592. ; F.21.5 - set system language
  1593.         sub     ebx, 3
  1594.         jnz     @f
  1595.  
  1596.         mov     [syslang], ecx
  1597.         ret
  1598. ;--------------------------------------
  1599. @@:
  1600. ; F.21.11 - enable/disable low-level access to HD
  1601.         and     ecx, 1
  1602.         sub     ebx, 6
  1603.         jnz     @f
  1604.  
  1605.         mov     [lba_read_enabled], ecx
  1606.         ret
  1607. ;--------------------------------------
  1608. @@:
  1609. ; F.21.12 - enable/disable low-level access to PCI
  1610.         dec     ebx
  1611.         jnz     .error
  1612.  
  1613.         mov     [pci_access_enabled], ecx
  1614.         ret
  1615. ;--------------------------------------
  1616. .error:
  1617.         or      [esp+32], dword -1
  1618.         ret
  1619. ;-----------------------------------------------------------------------------
  1620. align 4
  1621. sys_getsetup:
  1622. ;  1 = roland mpu midi base , base io address
  1623. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1624. ;  3 = not used
  1625. ;  4 = not used
  1626. ;  5 = system language, 1eng 2fi 3ger 4rus
  1627. ;  6 = not used
  1628. ;  7 = not used
  1629. ;  8 = not used
  1630. ;  9 = get hs timer tic
  1631. ; 10 = not used
  1632. ; 11 = get the state "lba read"
  1633. ; 12 = get the state "pci access"
  1634. ;-----------------------------------------------------------------------------
  1635. ; F.26.1 - get MPU MIDI base port
  1636.         dec     ebx
  1637.         jnz     @f
  1638.  
  1639.         movzx   eax, [midi_base]
  1640.         mov     [esp+32], eax
  1641.         ret
  1642. ;--------------------------------------
  1643. @@:
  1644. ; F.26.2 - get keyboard layout
  1645.         dec     ebx
  1646.         jnz     @f
  1647.  
  1648.         mov     edi, [TASK_BASE]
  1649.         mov     ebx, [edi+TASKDATA.mem_start]
  1650.         add     ebx, edx
  1651. ; 1 = normal layout
  1652.         dec     ecx
  1653.         jnz     .shift
  1654.  
  1655.         mov     eax, keymap
  1656.         mov     ecx, 128
  1657.         call    memmove
  1658.         ret
  1659. ;--------------------------------------
  1660. .shift:
  1661. ; 2 = layout with pressed Shift
  1662.         dec     ecx
  1663.         jnz     .alt
  1664.  
  1665.         mov     eax, keymap_shift
  1666.         mov     ecx, 128
  1667.         call    memmove
  1668.         ret
  1669. ;--------------------------------------
  1670. .alt:
  1671. ; 3 = layout with pressed Alt
  1672.         dec     ecx
  1673.         jne     .country
  1674.  
  1675.         mov     eax, keymap_alt
  1676.         mov     ecx, 128
  1677.         call    memmove
  1678.         ret
  1679. ;--------------------------------------
  1680. .country:
  1681. ; 9 = country identifier
  1682.         sub     ecx, 6
  1683.         jnz     .error
  1684.  
  1685.         movzx   eax, word [keyboard]
  1686.         mov     [esp+32], eax
  1687.         ret
  1688. ;--------------------------------------
  1689. @@:
  1690. ; F.26.5 - get system language
  1691.         sub     ebx, 3
  1692.         jnz     @f
  1693.  
  1694.         mov     eax, [syslang]
  1695.         mov     [esp+32], eax
  1696.         ret
  1697. ;--------------------------------------
  1698. @@:
  1699. ; F.26.9 - get the value of the time counter
  1700.         sub     ebx, 4
  1701.         jnz     @f
  1702.  
  1703.         mov     eax, [timer_ticks]
  1704.         mov     [esp+32], eax
  1705.         ret
  1706. ;--------------------------------------
  1707. @@:
  1708. ; F.26.11 - Find out whether low-level HD access is enabled
  1709.         sub     ebx, 2
  1710.         jnz     @f
  1711.  
  1712.         mov     eax, [lba_read_enabled]
  1713.         mov     [esp+32], eax
  1714.         ret
  1715. ;--------------------------------------
  1716. @@:
  1717. ; F.26.12 - Find out whether low-level PCI access is enabled
  1718.         dec     ebx
  1719.         jnz     .error
  1720.  
  1721.         mov     eax, [pci_access_enabled]
  1722.         mov     [esp+32], eax
  1723.         ret
  1724. ;--------------------------------------
  1725. .error:
  1726.         or      [esp+32], dword -1
  1727.         ret
  1728. ;-----------------------------------------------------------------------------
  1729. get_timer_ticks:
  1730.         mov     eax, [timer_ticks]
  1731.         ret
  1732. ;-----------------------------------------------------------------------------
  1733. iglobal
  1734. align 4
  1735. mousefn dd msscreen, mswin, msbutton, msset
  1736.         dd app_load_cursor
  1737.         dd app_set_cursor
  1738.         dd app_delete_cursor
  1739.         dd msz
  1740. endg
  1741. ;-----------------------------------------------------------------------------
  1742. readmousepos:
  1743.  
  1744. ; eax=0 screen relative
  1745. ; eax=1 window relative
  1746. ; eax=2 buttons pressed
  1747. ; eax=3 set mouse pos   ; reserved
  1748. ; eax=4 load cursor
  1749. ; eax=5 set cursor
  1750. ; eax=6 delete cursor   ; reserved
  1751. ; eax=7 get mouse_z
  1752.  
  1753.         cmp     ebx, 7
  1754.         ja      msset
  1755.         jmp     [mousefn+ebx*4]
  1756. msscreen:
  1757.         mov     eax, [MOUSE_X]
  1758.         shl     eax, 16
  1759.         mov     ax, [MOUSE_Y]
  1760.         mov     [esp+36-4], eax
  1761.         ret
  1762. mswin:
  1763.         mov     eax, [MOUSE_X]
  1764.         shl     eax, 16
  1765.         mov     ax, [MOUSE_Y]
  1766.         mov     esi, [TASK_BASE]
  1767.         mov     bx, word [esi-twdw+WDATA.box.left]
  1768.         shl     ebx, 16
  1769.         mov     bx, word [esi-twdw+WDATA.box.top]
  1770.         sub     eax, ebx
  1771.  
  1772.         mov     edi, [CURRENT_TASK]
  1773.         shl     edi, 8
  1774.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1775.         rol     eax, 16
  1776.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1777.         rol     eax, 16
  1778.         mov     [esp+36-4], eax
  1779.         ret
  1780. msbutton:
  1781.         movzx   eax, byte [BTN_DOWN]
  1782.         mov     [esp+36-4], eax
  1783.         ret
  1784. msz:
  1785.         mov     edi, [TASK_COUNT]
  1786.         movzx   edi, word [WIN_POS + edi*2]
  1787.         cmp     edi, [CURRENT_TASK]
  1788.         jne     @f
  1789.         mov     ax, [MOUSE_SCROLL_H]
  1790.         shl     eax, 16
  1791.         mov     ax, [MOUSE_SCROLL_V]
  1792.         mov     [esp+36-4], eax
  1793.         and     [MOUSE_SCROLL_H], word 0
  1794.         and     [MOUSE_SCROLL_V], word 0
  1795.         ret
  1796.        @@:
  1797.         and     [esp+36-4], dword 0
  1798. ;           ret
  1799. msset:
  1800.         ret
  1801.  
  1802. app_load_cursor:
  1803.         cmp     ecx, OS_BASE
  1804.         jae     msset
  1805.         stdcall load_cursor, ecx, edx
  1806.         mov     [esp+36-4], eax
  1807.         ret
  1808.  
  1809. app_set_cursor:
  1810.         stdcall set_cursor, ecx
  1811.         mov     [esp+36-4], eax
  1812.         ret
  1813.  
  1814. app_delete_cursor:
  1815.         stdcall delete_cursor, ecx
  1816.         mov     [esp+36-4], eax
  1817.         ret
  1818.  
  1819. is_input:
  1820.  
  1821.         push    edx
  1822.         mov     dx, word [midisp]
  1823.         in      al, dx
  1824.         and     al, 0x80
  1825.         pop     edx
  1826.         ret
  1827.  
  1828. is_output:
  1829.  
  1830.         push    edx
  1831.         mov     dx, word [midisp]
  1832.         in      al, dx
  1833.         and     al, 0x40
  1834.         pop     edx
  1835.         ret
  1836.  
  1837.  
  1838. get_mpu_in:
  1839.  
  1840.         push    edx
  1841.         mov     dx, word [mididp]
  1842.         in      al, dx
  1843.         pop     edx
  1844.         ret
  1845.  
  1846.  
  1847. put_mpu_out:
  1848.  
  1849.         push    edx
  1850.         mov     dx, word [mididp]
  1851.         out     dx, al
  1852.         pop     edx
  1853.         ret
  1854.  
  1855.  
  1856.  
  1857. align 4
  1858.  
  1859. sys_midi:
  1860.         cmp     [mididp], 0
  1861.         jnz     sm0
  1862.         mov     [esp+36], dword 1
  1863.         ret
  1864. sm0:
  1865.         and     [esp+36], dword 0
  1866.         dec     ebx
  1867.         jnz     smn1
  1868.  ;    call setuart
  1869. su1:
  1870.         call    is_output
  1871.         test    al, al
  1872.         jnz     su1
  1873.         mov     dx, word [midisp]
  1874.         mov     al, 0xff
  1875.         out     dx, al
  1876. su2:
  1877.         mov     dx, word [midisp]
  1878.         mov     al, 0xff
  1879.         out     dx, al
  1880.         call    is_input
  1881.         test    al, al
  1882.         jnz     su2
  1883.         call    get_mpu_in
  1884.         cmp     al, 0xfe
  1885.         jnz     su2
  1886. su3:
  1887.         call    is_output
  1888.         test    al, al
  1889.         jnz     su3
  1890.         mov     dx, word [midisp]
  1891.         mov     al, 0x3f
  1892.         out     dx, al
  1893.         ret
  1894. smn1:
  1895.         dec     ebx
  1896.         jnz     smn2
  1897. sm10:
  1898.         call    get_mpu_in
  1899.         call    is_output
  1900.         test    al, al
  1901.         jnz     sm10
  1902.         mov     al, bl
  1903.         call    put_mpu_out
  1904.         smn2:
  1905.         ret
  1906.  
  1907. detect_devices:
  1908. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1909. ;include 'detect/commouse.inc'
  1910. ;include 'detect/ps2mouse.inc'
  1911. ;include 'detect/dev_fd.inc'
  1912. ;include 'detect/dev_hdcd.inc'
  1913. ;include 'detect/sear_par.inc'
  1914. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1915.         ret
  1916.  
  1917. sys_end:
  1918. ;--------------------------------------
  1919.         cmp     [_display.select_cursor], 0
  1920.         je      @f
  1921. ; restore default cursor before killing
  1922.         pusha
  1923.         mov     ecx, [current_slot]
  1924.         call    restore_default_cursor_before_killing
  1925.         popa
  1926. @@:
  1927. ;--------------------------------------
  1928. ; kill all sockets this process owns
  1929.         pusha
  1930.         mov     edx, [TASK_BASE]
  1931.         mov     edx, [edx+TASKDATA.pid]
  1932.         call    SOCKET_process_end
  1933.         popa
  1934. ;--------------------------------------
  1935.         mov     ecx, [current_slot]
  1936.         mov     eax, [ecx+APPDATA.tls_base]
  1937.         test    eax, eax
  1938.         jz      @F
  1939.  
  1940.         stdcall user_free, eax
  1941. @@:
  1942.  
  1943.         mov     eax, [TASK_BASE]
  1944.         mov     [eax+TASKDATA.state], 3; terminate this program
  1945.         call    wakeup_osloop
  1946.  
  1947. .waitterm:            ; wait here for termination
  1948.         call    change_task
  1949.         jmp     .waitterm
  1950. ;------------------------------------------------------------------------------
  1951. align 4
  1952. restore_default_cursor_before_killing:
  1953.         pushfd
  1954.         cli
  1955.         mov     eax, [def_cursor]
  1956.         mov     [ecx+APPDATA.cursor], eax
  1957.  
  1958.         movzx   eax, word [MOUSE_Y]
  1959.         movzx   ebx, word [MOUSE_X]
  1960. ;        mov     ecx, [Screen_Max_X]
  1961. ;        inc     ecx
  1962. ;        mul     ecx
  1963.         mov     eax, [d_width_calc_area + eax*4]
  1964.  
  1965.         add     eax, [_WinMapAddress]
  1966.         movzx   edx, byte [ebx+eax]
  1967.         shl     edx, 8
  1968.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  1969.  
  1970.         cmp     esi, [current_cursor]
  1971.         je      @f
  1972.  
  1973.         push    esi
  1974.         call    [_display.select_cursor]
  1975.         mov     [current_cursor], esi
  1976. @@:
  1977.         mov     [redrawmouse_unconditional], 1
  1978.         call    wakeup_osloop
  1979.         popfd
  1980.         ret
  1981. ;------------------------------------------------------------------------------
  1982. iglobal
  1983. align 4
  1984. sys_system_table:
  1985.         dd      sysfn_deactivate        ; 1 = deactivate window
  1986.         dd      sysfn_terminate         ; 2 = terminate thread
  1987.         dd      sysfn_activate          ; 3 = activate window
  1988.         dd      sysfn_getidletime       ; 4 = get idle time
  1989.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  1990.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  1991.         dd      sysfn_getactive         ; 7 = get active window
  1992.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  1993.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  1994.         dd      sysfn_minimize          ; 10 = minimize window
  1995.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  1996.         dd      sysfn_lastkey           ; 12 = get last pressed key
  1997.         dd      sysfn_getversion        ; 13 = get kernel version
  1998.         dd      sysfn_waitretrace       ; 14 = wait retrace
  1999.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2000.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2001.         dd      sysfn_getallmem         ; 17 = get total memory size
  2002.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2003.                                         ;                 instead of slot
  2004.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2005.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2006.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2007.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2008.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2009.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2010. sysfn_num = ($ - sys_system_table)/4
  2011. endg
  2012. ;------------------------------------------------------------------------------
  2013. sys_system:
  2014.         dec     ebx
  2015.         cmp     ebx, sysfn_num
  2016.         jae     @f
  2017.         jmp     dword [sys_system_table + ebx*4]
  2018. @@:
  2019.         ret
  2020. ;------------------------------------------------------------------------------
  2021. sysfn_shutdown:          ; 18.9 = system shutdown
  2022.         cmp     ecx, 1
  2023.         jl      exit_for_anyone
  2024.         cmp     ecx, 4
  2025.         jg      exit_for_anyone
  2026.         mov     [BOOT_VARS+0x9030], cl
  2027.  
  2028.         mov     eax, [TASK_COUNT]
  2029.         mov     [SYS_SHUTDOWN], al
  2030.         mov     [shutdown_processes], eax
  2031.         call    wakeup_osloop
  2032.         and     dword [esp+32], 0
  2033.  exit_for_anyone:
  2034.         ret
  2035.   uglobal
  2036.    shutdown_processes:
  2037.                        dd 0x0
  2038.   endg
  2039. ;------------------------------------------------------------------------------
  2040. sysfn_terminate:        ; 18.2 = TERMINATE
  2041.         push    ecx
  2042.         cmp     ecx, 2
  2043.         jb      noprocessterminate
  2044.         mov     edx, [TASK_COUNT]
  2045.         cmp     ecx, edx
  2046.         ja      noprocessterminate
  2047.         mov     eax, [TASK_COUNT]
  2048.         shl     ecx, 5
  2049.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2050.         add     ecx, CURRENT_TASK+TASKDATA.state
  2051.         cmp     byte [ecx], 9
  2052.         jz      noprocessterminate
  2053.         push    ecx edx
  2054.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2055.         call    request_terminate
  2056.         pop     edx ecx
  2057.         test    eax, eax
  2058.         jz      noprocessterminate
  2059. ;--------------------------------------
  2060. ; terminate all network sockets it used
  2061.         pusha
  2062.         mov     eax, edx
  2063.         call    SOCKET_process_end
  2064.         popa
  2065. ;--------------------------------------
  2066.         cmp     [_display.select_cursor], 0
  2067.         je      .restore_end
  2068. ; restore default cursor before killing
  2069.         pusha
  2070.         mov     ecx, [esp+32]
  2071.         shl     ecx, 8
  2072.         add     ecx, SLOT_BASE
  2073.         mov     eax, [def_cursor]
  2074.         cmp     [ecx+APPDATA.cursor], eax
  2075.         je      @f
  2076.         call    restore_default_cursor_before_killing
  2077. @@:
  2078.         popa
  2079. .restore_end:
  2080. ;--------------------------------------
  2081.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2082.         mov     [ecx], byte 3; clear possible i40's
  2083.         call    wakeup_osloop
  2084.      ;call MEM_Heap_UnLock
  2085.  
  2086.         cmp     edx, [application_table_owner]; clear app table stat
  2087.         jne     noatsc
  2088.         call    unlock_application_table
  2089. noatsc:
  2090. noprocessterminate:
  2091.         add     esp, 4
  2092.         ret
  2093. ;------------------------------------------------------------------------------
  2094. sysfn_terminate2:
  2095. ;lock application_table_status mutex
  2096. .table_status:
  2097.         call    lock_application_table
  2098.         mov     eax, ecx
  2099.         call    pid_to_slot
  2100.         test    eax, eax
  2101.         jz      .not_found
  2102.         mov     ecx, eax
  2103.         cli
  2104.         call    sysfn_terminate
  2105.         call    unlock_application_table
  2106.         sti
  2107.         and     dword [esp+32], 0
  2108.         ret
  2109. .not_found:
  2110.         call    unlock_application_table
  2111.         or      dword [esp+32], -1
  2112.         ret
  2113. ;------------------------------------------------------------------------------
  2114. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2115.         cmp     ecx, 2
  2116.         jb      .nowindowdeactivate
  2117.         cmp     ecx, [TASK_COUNT]
  2118.         ja      .nowindowdeactivate
  2119.  
  2120.         movzx   esi, word [WIN_STACK + ecx*2]
  2121.         cmp     esi, 1
  2122.         je      .nowindowdeactivate ; already deactive
  2123.  
  2124.         mov     edi, ecx
  2125.         shl     edi, 5
  2126.         add     edi, window_data
  2127.         movzx   esi, word [WIN_STACK + ecx * 2]
  2128.         lea     esi, [WIN_POS + esi * 2]
  2129.         call    window._.window_deactivate
  2130.  
  2131.         call    syscall_display_settings._.calculate_whole_screen
  2132.         call    syscall_display_settings._.redraw_whole_screen
  2133. .nowindowdeactivate:
  2134.         ret
  2135. ;------------------------------------------------------------------------------
  2136. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2137.         cmp     ecx, 2
  2138.         jb      .nowindowactivate
  2139.         cmp     ecx, [TASK_COUNT]
  2140.         ja      .nowindowactivate
  2141. ;-------------------------------------
  2142. @@:
  2143. ; If the window is captured and moved by the user,
  2144. ; then you can't change the position in window stack!!!
  2145.         mov     al, [mouse.active_sys_window.action]
  2146.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2147.         test    al, al
  2148.         jz      @f
  2149.         call    change_task
  2150.         jmp     @b
  2151. @@:
  2152. ;-------------------------------------
  2153.         mov     [window_minimize], 2; restore window if minimized
  2154.         call    wakeup_osloop
  2155.  
  2156.         movzx   esi, word [WIN_STACK + ecx*2]
  2157.         cmp     esi, [TASK_COUNT]
  2158.         je      .nowindowactivate; already active
  2159.  
  2160.         mov     edi, ecx
  2161.         shl     edi, 5
  2162.         add     edi, window_data
  2163.         movzx   esi, word [WIN_STACK + ecx * 2]
  2164.         lea     esi, [WIN_POS + esi * 2]
  2165.         call    waredraw
  2166. .nowindowactivate:
  2167.         ret
  2168. ;------------------------------------------------------------------------------
  2169. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2170.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2171.         mov     [esp+32], eax
  2172.         ret
  2173. ;------------------------------------------------------------------------------
  2174. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2175.         mov     eax, dword [cpu_freq]
  2176.         mov     [esp+32], eax
  2177.         ret
  2178. ;------------------------------------------------------------------------------
  2179. get_cpu_freq:
  2180.         mov     eax, dword [cpu_freq]
  2181.         mov     edx, dword [cpu_freq+4]
  2182.         ret
  2183. ;  SAVE ramdisk to /hd/1/menuet.img
  2184. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2185.    include 'blkdev/rdsave.inc'
  2186. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2187. ;------------------------------------------------------------------------------
  2188. align 4
  2189. sysfn_getactive:        ; 18.7 = get active window
  2190.         mov     eax, [TASK_COUNT]
  2191.         movzx   eax, word [WIN_POS + eax*2]
  2192.         mov     [esp+32], eax
  2193.         ret
  2194. ;------------------------------------------------------------------------------
  2195. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2196. ;     cmp  ecx,1
  2197.         dec     ecx
  2198.         jnz     nogetsoundflag
  2199.         movzx   eax, byte [sound_flag]; get sound_flag
  2200.         mov     [esp+32], eax
  2201.         ret
  2202.  nogetsoundflag:
  2203. ;     cmp  ecx,2
  2204.         dec     ecx
  2205.         jnz     nosoundflag
  2206.         xor     byte [sound_flag], 1
  2207.  nosoundflag:
  2208.         ret
  2209. ;------------------------------------------------------------------------------
  2210. sysfn_minimize:         ; 18.10 = minimize window
  2211.         mov     [window_minimize], 1
  2212.         call    wakeup_osloop
  2213.         ret
  2214. ;------------------------------------------------------------------------------
  2215. align 4
  2216. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2217.         dec     ecx
  2218.         jnz     .exit
  2219. .small_table:
  2220.         mov     edi, edx
  2221.         mov     esi, DRIVE_DATA
  2222.         mov     ecx, DRIVE_DATA_SIZE ;10
  2223.         cld
  2224.         rep movsb
  2225. .exit:
  2226.         ret
  2227. ;------------------------------------------------------------------------------
  2228. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2229.         and     dword [esp+32], 0
  2230.         ret
  2231. ;------------------------------------------------------------------------------
  2232. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2233.         mov     edi, ecx
  2234.         mov     esi, version_inf
  2235.         mov     ecx, version_end-version_inf
  2236.         rep movsb
  2237.         ret
  2238. ;------------------------------------------------------------------------------
  2239. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2240.      ;wait retrace functions
  2241.  sys_wait_retrace:
  2242.         mov     edx, 0x3da
  2243.  WaitRetrace_loop:
  2244.         in      al, dx
  2245.         test    al, 1000b
  2246.         jz      WaitRetrace_loop
  2247.         and     [esp+32], dword 0
  2248.         ret
  2249. ;------------------------------------------------------------------------------
  2250. align 4
  2251. sysfn_centermouse:      ; 18.15 = mouse centered
  2252. ; removed here by <Lrz>
  2253. ;     call  mouse_centered
  2254. ;* mouse centered - start code- Mario79
  2255. ;mouse_centered:
  2256. ;        push  eax
  2257.         mov     eax, [Screen_Max_X]
  2258.         shr     eax, 1
  2259.         mov     [MOUSE_X], ax
  2260.         mov     eax, [Screen_Max_Y]
  2261.         shr     eax, 1
  2262.         mov     [MOUSE_Y], ax
  2263.         call    wakeup_osloop
  2264. ;        ret
  2265. ;* mouse centered - end code- Mario79
  2266.         xor     eax, eax
  2267.         and     [esp+32], eax
  2268. ;        pop   eax
  2269.         ret
  2270. ;------------------------------------------------------------------------------
  2271. align 4
  2272. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2273.         test    ecx, ecx; get mouse speed factor
  2274.         jnz     .set_mouse_acceleration
  2275.         xor     eax, eax
  2276.         mov     ax, [mouse_speed_factor]
  2277.         mov     [esp+32], eax
  2278.         ret
  2279.  .set_mouse_acceleration:
  2280. ;     cmp  ecx,1  ; set mouse speed factor
  2281.         dec     ecx
  2282.         jnz     .get_mouse_delay
  2283.         mov     [mouse_speed_factor], dx
  2284.         ret
  2285.  .get_mouse_delay:
  2286. ;     cmp  ecx,2  ; get mouse delay
  2287.         dec     ecx
  2288.         jnz     .set_mouse_delay
  2289.         mov     eax, [mouse_delay]
  2290.         mov     [esp+32], eax
  2291.         ret
  2292.  .set_mouse_delay:
  2293. ;     cmp  ecx,3  ; set mouse delay
  2294.         dec     ecx
  2295.         jnz     .set_pointer_position
  2296.         mov     [mouse_delay], edx
  2297.         ret
  2298.  .set_pointer_position:
  2299. ;     cmp  ecx,4  ; set mouse pointer position
  2300.         dec     ecx
  2301.         jnz     .set_mouse_button
  2302.         cmp     dx, word[Screen_Max_Y]
  2303.         ja      .end
  2304.         rol     edx, 16
  2305.         cmp     dx, word[Screen_Max_X]
  2306.         ja      .end
  2307.         mov     [MOUSE_X], edx
  2308.         mov     [mouse_active], 1
  2309.         call    wakeup_osloop
  2310.         ret
  2311.  .set_mouse_button:
  2312. ;     cmp   ecx,5  ; set mouse button features
  2313.         dec     ecx
  2314.         jnz     .end
  2315.         mov     [BTN_DOWN], dl
  2316.         mov     [mouse_active], 1
  2317.         call    wakeup_osloop
  2318.  .end:
  2319.         ret
  2320. ;------------------------------------------------------------------------------
  2321. sysfn_getfreemem:
  2322.         mov     eax, [pg_data.pages_free]
  2323.         shl     eax, 2
  2324.         mov     [esp+32], eax
  2325.         ret
  2326. ;------------------------------------------------------------------------------
  2327. sysfn_getallmem:
  2328.         mov     eax, [MEM_AMOUNT]
  2329.         shr     eax, 10
  2330.         mov     [esp+32], eax
  2331.         ret
  2332. ;------------------------------------------------------------------------------
  2333. sysfn_pid_to_slot:
  2334.         mov     eax, ecx
  2335.         call    pid_to_slot
  2336.         mov     [esp+32], eax
  2337.         ret
  2338. ;------------------------------------------------------------------------------
  2339. sysfn_min_rest_window:
  2340.         pushad
  2341.         mov     eax, edx ; ebx - operating
  2342.         shr     ecx, 1
  2343.         jnc     @f
  2344.         call    pid_to_slot
  2345. @@:
  2346.         or      eax, eax ; eax - number of slot
  2347.         jz      .error
  2348.         cmp     eax, 255    ; varify maximal slot number
  2349.         ja      .error
  2350.         movzx   eax, word [WIN_STACK + eax*2]
  2351.         shr     ecx, 1
  2352.         jc      .restore
  2353.  ; .minimize:
  2354.         call    minimize_window
  2355.         jmp     .exit
  2356. .restore:
  2357.         call    restore_minimized_window
  2358. .exit:
  2359.         popad
  2360.         xor     eax, eax
  2361.         mov     [esp+32], eax
  2362.         ret
  2363. .error:
  2364.         popad
  2365.         xor     eax, eax
  2366.         dec     eax
  2367.         mov     [esp+32], eax
  2368.         ret
  2369. ;------------------------------------------------------------------------------
  2370. sysfn_min_windows:
  2371.         call    minimize_all_window
  2372.         mov     [esp+32], eax
  2373.         call    change_task
  2374.         ret
  2375. ;------------------------------------------------------------------------------
  2376. sysfn_set_screen_sizes:
  2377.         cmp     [SCR_MODE], word 0x13
  2378.         jbe     .exit
  2379.  
  2380.         cmp     [_display.select_cursor], select_cursor
  2381.         jne     .exit
  2382.  
  2383.         cmp     ecx, [display_width_standard]
  2384.         ja      .exit
  2385.  
  2386.         cmp     edx, [display_height_standard]
  2387.         ja      .exit
  2388.  
  2389.         pushfd
  2390.         cli
  2391.         mov     eax, ecx
  2392.         mov     ecx, [_display.pitch]
  2393.         mov     [_display.width], eax
  2394.         dec     eax
  2395.         mov     [_display.height], edx
  2396.         dec     edx
  2397. ; eax - new Screen_Max_X
  2398. ; edx - new Screen_Max_Y
  2399.         mov     [do_not_touch_winmap], 1
  2400.         call    set_screen
  2401.         mov     [do_not_touch_winmap], 0
  2402.         popfd
  2403.         call    change_task
  2404. .exit:
  2405.         ret
  2406. ;------------------------------------------------------------------------------
  2407. uglobal
  2408. screen_workarea RECT
  2409. display_width_standard dd 0
  2410. display_height_standard dd 0
  2411. do_not_touch_winmap db 0
  2412. window_minimize db 0
  2413. sound_flag      db 0
  2414.  
  2415. endg
  2416.  
  2417. UID_NONE=0
  2418. UID_MENUETOS=1   ;official
  2419. UID_KOLIBRI=2    ;russian
  2420.  
  2421. iglobal
  2422. version_inf:
  2423.         db 0,7,7,0  ; version 0.7.7.0
  2424.         db 0
  2425. .rev    dd __REV__
  2426. version_end:
  2427. endg
  2428. ;------------------------------------------------------------------------------
  2429. align 4
  2430. sys_cachetodiskette:
  2431.         cmp     ebx, 1
  2432.         jb      .no_floppy_save
  2433.         cmp     ebx, 2
  2434.         ja      .no_floppy_save
  2435.         call    save_image
  2436.         mov     [esp + 32], eax
  2437.         ret
  2438. .no_floppy_save:
  2439.         mov     [esp + 32], dword 1
  2440.         ret
  2441. ;------------------------------------------------------------------------------
  2442. uglobal
  2443. ;  bgrchanged  dd  0x0
  2444. align 4
  2445. bgrlockpid dd 0
  2446. bgrlock db 0
  2447. endg
  2448. ;------------------------------------------------------------------------------
  2449. align 4
  2450. sys_background:
  2451.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2452.         jnz     nosb1
  2453.         test    ecx, ecx
  2454.         jz      sbgrr
  2455.  
  2456.         test    edx, edx
  2457.         jz      sbgrr
  2458. ;--------------------------------------
  2459. align 4
  2460. @@:
  2461. ;;Maxis use atomic bts for mutexes  4.4.2009
  2462.         bts     dword [bgrlock], 0
  2463.         jnc     @f
  2464.         call    change_task
  2465.         jmp     @b
  2466. ;--------------------------------------
  2467. align 4
  2468. @@:
  2469.         mov     [BgrDataWidth], ecx
  2470.         mov     [BgrDataHeight], edx
  2471. ;    mov   [bgrchanged],1
  2472.  
  2473.         pushad
  2474. ; return memory for old background
  2475.         mov     eax, [img_background]
  2476.         cmp     eax, static_background_data
  2477.         jz      @f
  2478.         stdcall kernel_free, eax
  2479. ;--------------------------------------
  2480. align 4
  2481. @@:
  2482. ; calculate RAW size
  2483.         xor     eax, eax
  2484.         inc     eax
  2485.         cmp     [BgrDataWidth], eax
  2486.         jae     @f
  2487.         mov     [BgrDataWidth], eax
  2488. ;--------------------------------------
  2489. align 4
  2490. @@:
  2491.         cmp     [BgrDataHeight], eax
  2492.         jae     @f
  2493.         mov     [BgrDataHeight], eax
  2494. ;--------------------------------------
  2495. align 4
  2496. @@:
  2497.         mov     eax, [BgrDataWidth]
  2498.         imul    eax, [BgrDataHeight]
  2499.         lea     eax, [eax*3]
  2500. ; it is reserved with aligned to the boundary of 4 KB pages,
  2501. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2502. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2503.         shr     eax, 12
  2504.         inc     eax
  2505.         shl     eax, 12
  2506.         mov     [mem_BACKGROUND], eax
  2507. ; get memory for new background
  2508.         stdcall kernel_alloc, eax
  2509.         test    eax, eax
  2510.         jz      .memfailed
  2511.         mov     [img_background], eax
  2512.         jmp     .exit
  2513. ;--------------------------------------
  2514. align 4
  2515. .memfailed:
  2516. ; revert to static monotone data
  2517.         mov     [img_background], static_background_data
  2518.         xor     eax, eax
  2519.         inc     eax
  2520.         mov     [BgrDataWidth], eax
  2521.         mov     [BgrDataHeight], eax
  2522.         mov     [mem_BACKGROUND], 4
  2523. ;--------------------------------------
  2524. align 4
  2525. .exit:
  2526.         popad
  2527.         mov     [bgrlock], 0
  2528. ;--------------------------------------
  2529. align 4
  2530. sbgrr:
  2531.         ret
  2532. ;------------------------------------------------------------------------------
  2533. align 4
  2534. nosb1:
  2535.         cmp     ebx, 2                     ; SET PIXEL
  2536.         jnz     nosb2
  2537.  
  2538.         mov     eax, [img_background]
  2539.         test    ecx, ecx
  2540.         jz      @f
  2541.         cmp     eax, static_background_data
  2542.         jz      .ret
  2543. ;--------------------------------------
  2544. align 4
  2545. @@:
  2546.         mov     ebx, [mem_BACKGROUND]
  2547.         add     ebx, 4095
  2548.         and     ebx, -4096
  2549.         sub     ebx, 4
  2550.         cmp     ecx, ebx
  2551.         ja      .ret
  2552.  
  2553.         mov     ebx, [eax+ecx]
  2554.         and     ebx, 0xFF000000;255*256*256*256
  2555.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2556.         add     edx, ebx
  2557.         mov     [eax+ecx], edx
  2558. ;--------------------------------------
  2559. align 4
  2560. .ret:
  2561.         ret
  2562. ;------------------------------------------------------------------------------
  2563. align 4
  2564. nosb2:
  2565.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2566.         jnz     nosb3
  2567. ;--------------------------------------
  2568. align 4
  2569. draw_background_temp:
  2570.         mov     [background_defined], 1
  2571.         call    force_redraw_background
  2572. ;--------------------------------------
  2573. align 4
  2574. nosb31:
  2575.         ret
  2576. ;------------------------------------------------------------------------------
  2577. align 4
  2578. nosb3:
  2579.         cmp     ebx, 4                     ; TILED / STRETCHED
  2580.         jnz     nosb4
  2581.         cmp     ecx, [BgrDrawMode]
  2582.         je      nosb41
  2583.         mov     [BgrDrawMode], ecx
  2584. ;--------------------------------------
  2585. align 4
  2586. nosb41:
  2587.         ret
  2588. ;------------------------------------------------------------------------------
  2589. align 4
  2590. nosb4:
  2591.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2592.         jnz     nosb5
  2593.         cmp     [img_background], static_background_data
  2594.         jnz     @f
  2595.         test    edx, edx
  2596.         jnz     .fin
  2597.         cmp     esi, 4
  2598.         ja      .fin
  2599. ;--------------------------------------
  2600. align 4
  2601. @@:
  2602.   ; bughere
  2603.         mov     eax, ecx
  2604.         mov     ebx, edx
  2605.         add     ebx, [img_background];IMG_BACKGROUND
  2606.         mov     ecx, esi
  2607.         call    memmove
  2608. ;--------------------------------------
  2609. align 4
  2610. .fin:
  2611.         ret
  2612. ;------------------------------------------------------------------------------
  2613. align 4
  2614. nosb5:
  2615.         cmp     ebx, 6
  2616.         jnz     nosb6
  2617. ;--------------------------------------
  2618. align 4
  2619. ;;Maxis use atomic bts for mutex 4.4.2009
  2620. @@:
  2621.         bts     dword [bgrlock], 0
  2622.         jnc     @f
  2623.         call    change_task
  2624.         jmp     @b
  2625. ;--------------------------------------
  2626. align 4
  2627. @@:
  2628.         mov     eax, [CURRENT_TASK]
  2629.         mov     [bgrlockpid], eax
  2630.         cmp     [img_background], static_background_data
  2631.         jz      .nomem
  2632.         stdcall user_alloc, [mem_BACKGROUND]
  2633.         mov     [esp+32], eax
  2634.         test    eax, eax
  2635.         jz      .nomem
  2636.         mov     ebx, eax
  2637.         shr     ebx, 12
  2638.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2639.         mov     esi, [img_background]
  2640.         shr     esi, 12
  2641.         mov     ecx, [mem_BACKGROUND]
  2642.         add     ecx, 0xFFF
  2643.         shr     ecx, 12
  2644. ;--------------------------------------
  2645. align 4
  2646. .z:
  2647.         mov     eax, [page_tabs+ebx*4]
  2648.         test    al, 1
  2649.         jz      @f
  2650.         call    free_page
  2651. ;--------------------------------------
  2652. align 4
  2653. @@:
  2654.         mov     eax, [page_tabs+esi*4]
  2655.         or      al, PG_UW
  2656.         mov     [page_tabs+ebx*4], eax
  2657.         mov     eax, ebx
  2658.         shl     eax, 12
  2659.         invlpg  [eax]
  2660.         inc     ebx
  2661.         inc     esi
  2662.         loop    .z
  2663.         ret
  2664. ;--------------------------------------
  2665. align 4
  2666. .nomem:
  2667.         and     [bgrlockpid], 0
  2668.         mov     [bgrlock], 0
  2669. ;------------------------------------------------------------------------------
  2670. align 4
  2671. nosb6:
  2672.         cmp     ebx, 7
  2673.         jnz     nosb7
  2674.         cmp     [bgrlock], 0
  2675.         jz      .err
  2676.         mov     eax, [CURRENT_TASK]
  2677.         cmp     [bgrlockpid], eax
  2678.         jnz     .err
  2679.         mov     eax, ecx
  2680.         mov     ebx, ecx
  2681.         shr     eax, 12
  2682.         mov     ecx, [page_tabs+(eax-1)*4]
  2683.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2684.         jz      .err
  2685.         jnp     .err
  2686.         push    eax
  2687.         shr     ecx, 12
  2688.         dec     ecx
  2689. ;--------------------------------------
  2690. align 4
  2691. @@:
  2692.         and     dword [page_tabs+eax*4], 0
  2693.         mov     edx, eax
  2694.         shl     edx, 12
  2695.         push    eax
  2696.         invlpg  [edx]
  2697.         pop     eax
  2698.         inc     eax
  2699.         loop    @b
  2700.         pop     eax
  2701.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2702.         stdcall user_free, ebx
  2703.         mov     [esp+32], eax
  2704.         and     [bgrlockpid], 0
  2705.         mov     [bgrlock], 0
  2706.         ret
  2707. ;--------------------------------------
  2708. align 4
  2709. .err:
  2710.         and     dword [esp+32], 0
  2711.         ret
  2712. ;------------------------------------------------------------------------------
  2713. align 4
  2714. nosb7:
  2715.         cmp     ebx, 8
  2716.         jnz     nosb8
  2717.  
  2718.         mov     ecx, [current_slot]
  2719.         xor     eax, eax
  2720.         xchg    eax, [ecx+APPDATA.draw_bgr_x]
  2721.         mov     [esp + 32], eax ; eax = [left]*65536 + [right]
  2722.         xor     eax, eax
  2723.         xchg    eax, [ecx+APPDATA.draw_bgr_y]
  2724.         mov     [esp + 20], eax ; ebx = [top]*65536 + [bottom]
  2725.         ret
  2726. ;------------------------------------------------------------------------------
  2727. align 4
  2728. nosb8:
  2729.         cmp     ebx, 9
  2730.         jnz     nosb9
  2731. ; ecx = [left]*65536 + [right]
  2732. ; edx = [top]*65536 + [bottom]
  2733.         mov     eax, [Screen_Max_X]
  2734.         mov     ebx, [Screen_Max_Y]
  2735. ; check [right]
  2736.         cmp     cx, ax
  2737.         ja      .exit
  2738. ; check [left]
  2739.         ror     ecx, 16
  2740.         cmp     cx, ax
  2741.         ja      .exit
  2742. ; check [bottom]
  2743.         cmp     dx, bx
  2744.         ja      .exit
  2745. ; check [top]
  2746.         ror     edx, 16
  2747.         cmp     dx, bx
  2748.         ja      .exit
  2749.  
  2750.         movzx   eax, cx  ; [left]
  2751.         movzx   ebx, dx  ; [top]
  2752.  
  2753.         shr     ecx, 16 ; [right]
  2754.         shr     edx, 16 ; [bottom]
  2755.  
  2756.         mov     [background_defined], 1
  2757.  
  2758.         mov     [draw_data+32 + RECT.left], eax
  2759.         mov     [draw_data+32 + RECT.top], ebx
  2760.  
  2761.         mov     [draw_data+32 + RECT.right], ecx
  2762.         mov     [draw_data+32 + RECT.bottom], edx
  2763.  
  2764.         inc     byte[REDRAW_BACKGROUND]
  2765.         call    wakeup_osloop
  2766. ;--------------------------------------
  2767. align 4
  2768. .exit:
  2769.         ret
  2770. ;------------------------------------------------------------------------------
  2771. align 4
  2772. nosb9:
  2773.         ret
  2774. ;------------------------------------------------------------------------------
  2775. align 4
  2776. uglobal
  2777.   BG_Rect_X_left_right  dd   0x0
  2778.   BG_Rect_Y_top_bottom  dd   0x0
  2779. endg
  2780. ;------------------------------------------------------------------------------
  2781. align 4
  2782. force_redraw_background:
  2783.         and     [draw_data+32 + RECT.left], 0
  2784.         and     [draw_data+32 + RECT.top], 0
  2785.         push    eax ebx
  2786.         mov     eax, [Screen_Max_X]
  2787.         mov     ebx, [Screen_Max_Y]
  2788.         mov     [draw_data+32 + RECT.right], eax
  2789.         mov     [draw_data+32 + RECT.bottom], ebx
  2790.         pop     ebx eax
  2791.         inc     byte[REDRAW_BACKGROUND]
  2792.         call    wakeup_osloop
  2793.         ret
  2794. ;------------------------------------------------------------------------------
  2795. align 4
  2796. sys_getbackground:
  2797. ;    cmp   eax,1                                  ; SIZE
  2798.         dec     ebx
  2799.         jnz     nogb1
  2800.         mov     eax, [BgrDataWidth]
  2801.         shl     eax, 16
  2802.         mov     ax, word [BgrDataHeight]
  2803.         mov     [esp+32], eax
  2804.         ret
  2805. ;------------------------------------------------------------------------------
  2806. align 4
  2807. nogb1:
  2808. ;    cmp   eax,2                                  ; PIXEL
  2809.         dec     ebx
  2810.         jnz     nogb2
  2811.  
  2812.         mov     eax, [img_background]
  2813.         test    ecx, ecx
  2814.         jz      @f
  2815.         cmp     eax, static_background_data
  2816.         jz      .ret
  2817. ;--------------------------------------
  2818. align 4
  2819. @@:
  2820.         mov     ebx, [mem_BACKGROUND]
  2821.         add     ebx, 4095
  2822.         and     ebx, -4096
  2823.         sub     ebx, 4
  2824.         cmp     ecx, ebx
  2825.         ja      .ret
  2826.  
  2827.         mov     eax, [ecx+eax]
  2828.  
  2829.         and     eax, 0xFFFFFF
  2830.         mov     [esp+32], eax
  2831. ;--------------------------------------
  2832. align 4
  2833. .ret:
  2834.         ret
  2835. ;------------------------------------------------------------------------------
  2836. align 4
  2837. nogb2:
  2838.  
  2839. ;    cmp   eax,4                                  ; TILED / STRETCHED
  2840.         dec     ebx
  2841.         dec     ebx
  2842.         jnz     nogb4
  2843.         mov     eax, [BgrDrawMode]
  2844. ;--------------------------------------
  2845. align 4
  2846. nogb4:
  2847.         mov     [esp+32], eax
  2848.         ret
  2849. ;------------------------------------------------------------------------------
  2850. align 4
  2851. sys_getkey:
  2852.         mov     [esp + 32], dword 1
  2853.         ; test main buffer
  2854.         mov     ebx, [CURRENT_TASK]                          ; TOP OF WINDOW STACK
  2855.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2856.         mov     edx, [TASK_COUNT]
  2857.         cmp     ecx, edx
  2858.         jne     .finish
  2859.         cmp     [KEY_COUNT], byte 0
  2860.         je      .finish
  2861.         movzx   ax, byte [KEY_BUFF + 120 + 2]
  2862.         shl     eax, 8
  2863.         mov     al, byte [KEY_BUFF]
  2864.         shl     eax, 8
  2865.         push    eax
  2866.         dec     byte [KEY_COUNT]
  2867.         and     byte [KEY_COUNT], 127
  2868.         movzx   ecx, byte [KEY_COUNT]
  2869.         add     ecx, 2
  2870.         mov     eax, KEY_BUFF + 1
  2871.         mov     ebx, KEY_BUFF
  2872.         call    memmove
  2873.         add     eax, 120 + 2
  2874.         add     ebx, 120 + 2