Subversion Repositories Kolibri OS

Rev

Rev 4734 | Rev 4772 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2013. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. format binary as "mnt"
  70.  
  71. include 'macros.inc'
  72. include 'struct.inc'
  73.  
  74. $Revision: 4741 $
  75.  
  76.  
  77. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  78. VESA_1_2_VIDEO equ 0      ; enable vesa 1.2 bank switch functions
  79.  
  80. ; Enabling the next line will enable serial output console
  81. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  82.  
  83. include "proc32.inc"
  84. include "kglobals.inc"
  85. include "lang.inc"
  86. include "encoding.inc"
  87.  
  88. include "const.inc"
  89.  
  90. iglobal
  91. ; The following variable, if equal to 1, duplicates debug output to the screen.
  92. debug_direct_print db 0
  93. ; Start the first app (LAUNCHER) after kernel is loaded? (1=yes, 2 or 0=no)
  94. launcher_start db 1
  95. endg
  96.  
  97. max_processes   equ   255
  98. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  99.  
  100. os_stack       equ  (os_data_l-gdts)    ; GDTs
  101. os_code       equ  (os_code_l-gdts)
  102. graph_data     equ  (3+graph_data_l-gdts)
  103. tss0           equ  (tss0_l-gdts)
  104. app_code       equ  (3+app_code_l-gdts)
  105. app_data       equ  (3+app_data_l-gdts)
  106. app_tls       equ  (3+tls_data_l-gdts)
  107. pci_code_sel   equ  (pci_code_32-gdts)
  108. pci_data_sel   equ  (pci_data_32-gdts)
  109.  
  110.  
  111. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  112. ;;
  113. ;;   Included files:
  114. ;;
  115. ;;   Kernel16.inc
  116. ;;    - Booteng.inc   English text for bootup
  117. ;;    - Bootcode.inc  Hardware setup
  118. ;;    - Pci16.inc     PCI functions
  119. ;;
  120. ;;   Kernel32.inc
  121. ;;    - Sys32.inc     Process management
  122. ;;    - Shutdown.inc  Shutdown and restart
  123. ;;    - Fat32.inc     Read / write hd
  124. ;;    - Vesa12.inc    Vesa 1.2 driver
  125. ;;    - Vesa20.inc    Vesa 2.0 driver
  126. ;;    - Vga.inc       VGA driver
  127. ;;    - Stack.inc     Network interface
  128. ;;    - Mouse.inc     Mouse pointer
  129. ;;    - Scincode.inc  Window skinning
  130. ;;    - Pci32.inc     PCI functions
  131. ;;
  132. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  133.  
  134.  
  135. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  136. ;;                                                                      ;;
  137. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  138. ;;                                                                      ;;
  139. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  140.  
  141. use16
  142.                   org   0x0
  143.         jmp     start_of_code
  144.  
  145. if lang eq sp
  146. include "kernelsp.inc"  ; spanish kernel messages
  147. else if lang eq et
  148. version db    'Kolibri OS  versioon 0.7.7.0+    ',13,10,13,10,0
  149. else
  150. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  151. end if
  152.  
  153. include "boot/bootstr.inc"     ; language-independent boot messages
  154. include "boot/preboot.inc"
  155.  
  156. if lang eq ge
  157. include "boot/bootge.inc"     ; german system boot messages
  158. else if lang eq sp
  159. include "boot/bootsp.inc"     ; spanish system boot messages
  160. else if lang eq ru
  161. include "boot/bootru.inc"      ; russian system boot messages
  162. include "boot/ru.inc"          ; Russian font
  163. else if lang eq et
  164. include "boot/bootet.inc"      ; estonian system boot messages
  165. include "boot/et.inc"          ; Estonian font
  166. else
  167. include "boot/booten.inc"      ; english system boot messages
  168. end if
  169.  
  170. include "boot/bootcode.inc"    ; 16 bit system boot code
  171. include "bus/pci/pci16.inc"
  172. include "detect/biosdisk.inc"
  173.  
  174. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  175. ;;                                                                      ;;
  176. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  177. ;;                                                                      ;;
  178. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  179.  
  180.  
  181. ; CR0 Flags - Protected mode and Paging
  182.  
  183.         mov     ecx, CR0_PE
  184.  
  185. ; Enabling 32 bit protected mode
  186.  
  187.         sidt    [cs:old_ints_h]
  188.  
  189.         cli                             ; disable all irqs
  190.         cld
  191.         mov     al, 255                 ; mask all irqs
  192.         out     0xa1, al
  193.         out     0x21, al
  194.    l.5:
  195.         in      al, 0x64                ; Enable A20
  196.         test    al, 2
  197.         jnz     l.5
  198.         mov     al, 0xD1
  199.         out     0x64, al
  200.    l.6:
  201.         in      al, 0x64
  202.         test    al, 2
  203.         jnz     l.6
  204.         mov     al, 0xDF
  205.         out     0x60, al
  206.    l.7:
  207.         in      al, 0x64
  208.         test    al, 2
  209.         jnz     l.7
  210.         mov     al, 0xFF
  211.         out     0x64, al
  212.  
  213.         lgdt    [cs:tmp_gdt]            ; Load GDT
  214.         mov     eax, cr0                ; protected mode
  215.         or      eax, ecx
  216.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  217.         mov     cr0, eax
  218.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  219.  
  220. align 8
  221. tmp_gdt:
  222.  
  223.         dw     23
  224.         dd     tmp_gdt+0x10000
  225.         dw     0
  226.  
  227.         dw     0xffff
  228.         dw     0x0000
  229.         db     0x00
  230.         dw     11011111b *256 +10011010b
  231.         db     0x00
  232.  
  233.         dw     0xffff
  234.         dw     0x0000
  235.         db     0x00
  236.         dw     11011111b *256 +10010010b
  237.         db     0x00
  238.  
  239. include "data16.inc"
  240.  
  241. if ~ lang eq sp
  242. diff16 "end of bootcode",0,$+0x10000
  243. end if
  244.  
  245. use32
  246. org $+0x10000
  247.  
  248. align 4
  249. B32:
  250.         mov     ax, os_stack       ; Selector for os
  251.         mov     ds, ax
  252.         mov     es, ax
  253.         mov     fs, ax
  254.         mov     gs, ax
  255.         mov     ss, ax
  256.         mov     esp, 0x006CC00       ; Set stack
  257.  
  258. ; CLEAR 0x280000 - HEAP_BASE
  259.  
  260.         xor     eax, eax
  261.         mov     edi, CLEAN_ZONE
  262.         mov     ecx, (HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  263.         cld
  264.         rep stosd
  265.  
  266. ; CLEAR KERNEL UNDEFINED GLOBALS
  267.         mov     edi, endofcode-OS_BASE
  268.         mov     ecx, 0x90000
  269.         sub     ecx, edi
  270.         shr     ecx, 2
  271.         rep stosd
  272.  
  273. ; SAVE & CLEAR 0-0xffff
  274.  
  275.         mov     edi, 0x1000
  276.         mov     ecx, 0x8000 / 4
  277.         rep stosd
  278.         mov     edi, 0xa000
  279.         mov     ecx, 0x6000 / 4
  280.         rep stosd
  281.  
  282.         call    test_cpu
  283.         bts     [cpu_caps-OS_BASE], CAPS_TSC    ;force use rdtsc
  284.  
  285.         call    check_acpi
  286.         call    init_BIOS32
  287. ; MEMORY MODEL
  288.         call    mem_test
  289.         call    init_mem
  290.         call    init_page_map
  291.  
  292. ; ENABLE PAGING
  293.  
  294.         mov     eax, sys_pgdir-OS_BASE
  295.         mov     cr3, eax
  296.  
  297.         mov     eax, cr0
  298.         or      eax, CR0_PG+CR0_WP
  299.         mov     cr0, eax
  300.  
  301.         lgdt    [gdts]
  302.         jmp     pword os_code:high_code
  303.  
  304. align 4
  305. bios32_entry    dd ?
  306. tmp_page_tabs   dd ?
  307.  
  308. use16
  309. org $-0x10000
  310. include "boot/shutdown.inc" ; shutdown or restart
  311. org $+0x10000
  312. use32
  313.  
  314. __DEBUG__ fix 1
  315. __DEBUG_LEVEL__ fix 1
  316. include 'init.inc'
  317.  
  318. org OS_BASE+$
  319.  
  320. include 'fdo.inc'
  321.  
  322. align 4
  323. high_code:
  324.         mov     ax, os_stack
  325.         mov     bx, app_data
  326.         mov     cx, app_tls
  327.         mov     ss, ax
  328.         add     esp, OS_BASE
  329.  
  330.         mov     ds, bx
  331.         mov     es, bx
  332.         mov     fs, cx
  333.         mov     gs, bx
  334.  
  335.         bt      [cpu_caps], CAPS_PGE
  336.         jnc     @F
  337.  
  338.         or      dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  339.  
  340.         mov     ebx, cr4
  341.         or      ebx, CR4_PGE
  342.         mov     cr4, ebx
  343. @@:
  344.         xor     eax, eax
  345.         mov     dword [sys_pgdir], eax
  346.         mov     dword [sys_pgdir+4], eax
  347.  
  348.         mov     eax, cr3
  349.         mov     cr3, eax          ; flush TLB
  350.  
  351.         mov     ecx, pg_data.mutex
  352.         call    mutex_init
  353.  
  354.         mov     ecx, disk_list_mutex
  355.         call    mutex_init
  356.  
  357.         mov     ecx, keyboard_list_mutex
  358.         call    mutex_init
  359.  
  360.         mov     ecx, unpack_mutex
  361.         call    mutex_init
  362.  
  363.         mov     ecx, application_table_mutex
  364.         call    mutex_init
  365.  
  366.         mov     ecx, ide_mutex
  367.         call    mutex_init
  368.         mov     ecx, ide_channel1_mutex
  369.         call    mutex_init
  370.         mov     ecx, ide_channel2_mutex
  371.         call    mutex_init
  372.         mov     ecx, ide_channel3_mutex
  373.         call    mutex_init
  374.         mov     ecx, ide_channel4_mutex
  375.         call    mutex_init
  376.         mov     ecx, ide_channel5_mutex
  377.         call    mutex_init
  378.         mov     ecx, ide_channel6_mutex
  379.         call    mutex_init
  380. ;-----------------------------------------------------------------------------
  381. ; SAVE REAL MODE VARIABLES
  382. ;-----------------------------------------------------------------------------
  383. ; --------------- APM ---------------------
  384.  
  385. ; init selectors
  386.         mov     ebx, [BOOT_VARS+BOOT_APM_ENTRY]        ; offset of APM entry point
  387.         movzx   eax, word [BOOT_VARS+BOOT_APM_CODE_32] ; real-mode segment base address of
  388.                                                                                 ; protected-mode 32-bit code segment
  389.         movzx   ecx, word [BOOT_VARS+BOOT_APM_CODE_16]; real-mode segment base address of
  390.                                                                                 ; protected-mode 16-bit code segment
  391.         movzx   edx, word [BOOT_VARS+BOOT_APM_DATA_16]; real-mode segment base address of
  392.                                                                                 ; protected-mode 16-bit data segment
  393.  
  394.         shl     eax, 4
  395.         mov     [dword apm_code_32 + 2], ax
  396.         shr     eax, 16
  397.         mov     [dword apm_code_32 + 4], al
  398.  
  399.         shl     ecx, 4
  400.         mov     [dword apm_code_16 + 2], cx
  401.         shr     ecx, 16
  402.         mov     [dword apm_code_16 + 4], cl
  403.  
  404.         shl     edx, 4
  405.         mov     [dword apm_data_16 + 2], dx
  406.         shr     edx, 16
  407.         mov     [dword apm_data_16 + 4], dl
  408.  
  409.         mov     dword[apm_entry], ebx
  410.         mov     word [apm_entry + 4], apm_code_32 - gdts
  411.  
  412.         mov     eax, [BOOT_VARS + BOOT_APM_VERSION] ; version & flags
  413.         mov     [apm_vf], eax
  414. ; -----------------------------------------
  415.         mov     al, [BOOT_VARS+BOOT_DMA]            ; DMA access
  416.         mov     [allow_dma_access], al
  417.         movzx   eax, byte [BOOT_VARS+BOOT_BPP]      ; bpp
  418.         mov     [_display.bpp], eax
  419.         mov     [_display.vrefresh], 60
  420.         mov     al, [BOOT_VARS+BOOT_DEBUG_PRINT]    ; If nonzero, duplicates debug output to the screen
  421.         mov     [debug_direct_print], al
  422.         mov     al, [BOOT_VARS+BOOT_LAUNCHER_START] ; Start the first app (LAUNCHER) after kernel is loaded?
  423.         mov     [launcher_start], al
  424.         movzx   eax, word [BOOT_VARS+BOOT_X_RES]; X max
  425.         mov     [_display.width], eax
  426.         mov     [display_width_standard], eax
  427.         dec     eax
  428.         mov     [Screen_Max_X], eax
  429.         mov     [screen_workarea.right], eax
  430.         movzx   eax, word [BOOT_VARS+BOOT_Y_RES]; Y max
  431.         mov     [_display.height], eax
  432.         mov     [display_height_standard], eax
  433.         dec     eax
  434.         mov     [Screen_Max_Y], eax
  435.         mov     [screen_workarea.bottom], eax
  436.         movzx   eax, word [BOOT_VARS+BOOT_VESA_MODE] ; screen mode
  437.         mov     dword [SCR_MODE], eax
  438. ;        mov     eax, [BOOT_VAR+0x9014]             ; Vesa 1.2 bnk sw add
  439. ;        mov     [BANK_SWITCH], eax
  440.         mov     eax, 640 *4                         ; Bytes PerScanLine
  441.         cmp     [SCR_MODE], word 0x13               ; 320x200
  442.         je      @f
  443.         cmp     [SCR_MODE], word 0x12               ; VGA 640x480
  444.         je      @f
  445.         movzx   eax, word[BOOT_VARS+BOOT_PITCH]      ; for other modes
  446. @@:
  447.         mov     [_display.pitch], eax
  448.         mov     eax, [_display.width]
  449.         mul     [_display.height]
  450.         mov     [_WinMapSize], eax
  451.  
  452.         call    calculate_fast_getting_offset_for_WinMapAddress
  453. ; for Qemu or non standart video cards
  454. ; Unfortunately [BytesPerScanLine] does not always
  455. ;                             equal to [_display.width] * [ScreenBPP] / 8
  456.         call    calculate_fast_getting_offset_for_LFB
  457.  
  458.         mov     esi, BOOT_VARS+0x9080
  459.         movzx   ecx, byte [esi-1]
  460.         mov     [NumBiosDisks], ecx
  461.         mov     edi, BiosDisksData
  462.         rep movsd
  463.  
  464. ; GRAPHICS ADDRESSES
  465.  
  466.         mov     eax, [BOOT_VARS+BOOT_LFB]
  467.         mov     [LFBAddress], eax
  468.  
  469.         cmp     [SCR_MODE], word 0100000000000000b
  470.         jge     setvesa20
  471.         cmp     [SCR_MODE], word 0x13  ; EGA 320*200 256 colors
  472.         je      v20ga32
  473.         jmp     v20ga24
  474.  
  475. setvesa20:
  476.         mov     [PUTPIXEL], dword Vesa20_putpixel24 ; Vesa 2.0
  477.         mov     [GETPIXEL], dword Vesa20_getpixel24
  478.         cmp     byte [_display.bpp], 24
  479.         jz      v20ga24
  480. v20ga32:
  481.         mov     [PUTPIXEL], dword Vesa20_putpixel32
  482.         mov     [GETPIXEL], dword Vesa20_getpixel32
  483.         jmp     no_mode_0x12
  484. v20ga24:
  485.         cmp     [SCR_MODE], word 0x12               ; 16 C VGA 640x480
  486.         jne     no_mode_0x12
  487.         mov     [PUTPIXEL], dword VGA_putpixel
  488.         mov     [GETPIXEL], dword Vesa20_getpixel32
  489. no_mode_0x12:
  490.  
  491.         mov     [MOUSE_PICTURE], dword mousepointer
  492.         mov     [_display.check_mouse], check_mouse_area_for_putpixel
  493.         mov     [_display.check_m_pixel], check_mouse_area_for_getpixel
  494.  
  495. ; -------- Fast System Call init ----------
  496. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  497.         bt      [cpu_caps], CAPS_SEP
  498.         jnc     .SEnP  ; SysEnter not Present
  499.         xor     edx, edx
  500.         mov     ecx, MSR_SYSENTER_CS
  501.         mov     eax, os_code
  502.         wrmsr
  503.         mov     ecx, MSR_SYSENTER_ESP
  504. ;           mov eax, sysenter_stack ; Check it
  505.         xor     eax, eax
  506.         wrmsr
  507.         mov     ecx, MSR_SYSENTER_EIP
  508.         mov     eax, sysenter_entry
  509.         wrmsr
  510. .SEnP:
  511. ; AMD SYSCALL/SYSRET
  512.         cmp     byte[cpu_vendor], 'A'
  513.         jne     .noSYSCALL
  514.         mov     eax, 0x80000001
  515.         cpuid
  516.         test    edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  517.         jz      .noSYSCALL
  518.         mov     ecx, MSR_AMD_EFER
  519.         rdmsr
  520.         or      eax, 1 ; bit_0 - System Call Extension (SCE)
  521.         wrmsr
  522.  
  523.         ; !!!! It`s dirty hack, fix it !!!
  524.         ; Bits of EDX :
  525.         ; Bit 31–16 During the SYSRET instruction, this field is copied into the CS register
  526.         ;  and the contents of this field, plus 8, are copied into the SS register.
  527.         ; Bit 15–0 During the SYSCALL instruction, this field is copied into the CS register
  528.         ;  and the contents of this field, plus 8, are copied into the SS register.
  529.  
  530.         ; mov   edx, (os_code + 16) * 65536 + os_code
  531.         mov     edx, 0x1B0008
  532.  
  533.         mov     eax, syscall_entry
  534.         mov     ecx, MSR_AMD_STAR
  535.         wrmsr
  536. .noSYSCALL:
  537. ; -----------------------------------------
  538.         stdcall alloc_page
  539.         stdcall map_page, tss-0xF80, eax, PG_SW
  540.         stdcall alloc_page
  541.         stdcall map_page, tss+0x80, eax, PG_SW
  542.         stdcall alloc_page
  543.         stdcall map_page, tss+0x1080, eax, PG_SW
  544.  
  545. ; LOAD IDT
  546.  
  547.         call    build_interrupt_table ;lidt is executed
  548.           ;lidt [idtreg]
  549.  
  550.         call    init_kernel_heap
  551.         stdcall kernel_alloc, (RING0_STACK_SIZE+512) * 2
  552.         mov     [os_stack_seg], eax
  553.  
  554.         lea     esp, [eax+RING0_STACK_SIZE]
  555.  
  556.         mov     [tss._ss0], os_stack
  557.         mov     [tss._esp0], esp
  558.         mov     [tss._esp], esp
  559.         mov     [tss._cs], os_code
  560.         mov     [tss._ss], os_stack
  561.         mov     [tss._ds], app_data
  562.         mov     [tss._es], app_data
  563.         mov     [tss._fs], app_data
  564.         mov     [tss._gs], app_data
  565.         mov     [tss._io], 128
  566. ;Add IO access table - bit array of permitted ports
  567.         mov     edi, tss._io_map_0
  568.         xor     eax, eax
  569.         not     eax
  570.         mov     ecx, 8192/4
  571.         rep stosd                    ; access to 4096*8=65536 ports
  572.  
  573.         mov     ax, tss0
  574.         ltr     ax
  575.  
  576.         mov     [LFBSize], 0xC00000
  577.         call    init_LFB
  578.         call    init_fpu
  579.         call    init_malloc
  580.  
  581.         stdcall alloc_kernel_space, 0x51000
  582.         mov     [default_io_map], eax
  583.  
  584.         add     eax, 0x2000
  585.         mov     [ipc_tmp], eax
  586.         mov     ebx, 0x1000
  587.  
  588.         add     eax, 0x40000
  589.         mov     [proc_mem_map], eax
  590.  
  591.         add     eax, 0x8000
  592.         mov     [proc_mem_pdir], eax
  593.  
  594.         add     eax, ebx
  595.         mov     [proc_mem_tab], eax
  596.  
  597.         add     eax, ebx
  598.         mov     [tmp_task_pdir], eax
  599.  
  600.         add     eax, ebx
  601.         mov     [tmp_task_ptab], eax
  602.  
  603.         add     eax, ebx
  604.         mov     [ipc_pdir], eax
  605.  
  606.         add     eax, ebx
  607.         mov     [ipc_ptab], eax
  608.  
  609.         stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  610.                 (unpack.lc+unpack.lp)))*4
  611.  
  612.         mov     [unpack.p], eax
  613.  
  614.         call    init_events
  615.         mov     eax, srv.fd-SRV.fd
  616.         mov     [srv.fd], eax
  617.         mov     [srv.bk], eax
  618.  
  619. ;Set base of graphic segment to linear address of LFB
  620.         mov     eax, [LFBAddress]         ; set for gs
  621.         mov     [graph_data_l+2], ax
  622.         shr     eax, 16
  623.         mov     [graph_data_l+4], al
  624.         mov     [graph_data_l+7], ah
  625.  
  626.         stdcall kernel_alloc, [_WinMapSize]
  627.         mov     [_WinMapAddress], eax
  628.  
  629.         xor     eax, eax
  630.         inc     eax
  631.  
  632. ; set background
  633.  
  634.         mov     [BgrDrawMode], eax
  635.         mov     [BgrDataWidth], eax
  636.         mov     [BgrDataHeight], eax
  637.         mov     [mem_BACKGROUND], 4
  638.         mov     [img_background], static_background_data
  639.  
  640. ; set clipboard
  641.  
  642.         xor     eax, eax
  643.         mov     [clipboard_slots], eax
  644.         mov     [clipboard_write_lock], eax
  645.         stdcall kernel_alloc, 4096
  646.         test    eax, eax
  647.         jnz     @f
  648.  
  649.         dec     eax
  650. @@:
  651.         mov     [clipboard_main_list], eax
  652.  
  653. ; SET UP OS TASK
  654.  
  655.         mov     esi, boot_setostask
  656.         call    boot_log
  657.  
  658.         mov     edx, SLOT_BASE+256
  659.         mov     ebx, [os_stack_seg]
  660.         add     ebx, 0x2000
  661.         call    setup_os_slot
  662.         mov     dword [edx], 'IDLE'
  663.         sub     [edx+APPDATA.saved_esp], 4
  664.         mov     eax, [edx+APPDATA.saved_esp]
  665.         mov     dword [eax], idle_thread
  666.         mov     ecx, IDLE_PRIORITY
  667.         call    scheduler_add_thread
  668.  
  669.         mov     edx, SLOT_BASE+256*2
  670.         mov     ebx, [os_stack_seg]
  671.         call    setup_os_slot
  672.         mov     dword [edx], 'OS'
  673.         xor     ecx, ecx
  674.         call    scheduler_add_thread
  675.  
  676.         mov     dword [CURRENT_TASK], 2
  677.         mov     dword [TASK_COUNT], 2
  678.         mov     dword [current_slot], SLOT_BASE + 256*2
  679.         mov     dword [TASK_BASE], CURRENT_TASK + 32*2
  680.  
  681.  
  682. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  683.         mov     esi, boot_initirq
  684.         call    boot_log
  685.         call    init_irqs
  686.  
  687.         mov     esi, boot_picinit
  688.         call    boot_log
  689.         call    PIC_init
  690.  
  691.         mov     esi, boot_v86machine
  692.         call    boot_log
  693. ; Initialize system V86 machine
  694.         call    init_sys_v86
  695.  
  696.         mov     esi, boot_inittimer
  697.         call    boot_log
  698. ; Initialize system timer (IRQ0)
  699.         call    PIT_init
  700.  
  701. ; Register ramdisk file system
  702.         mov     esi, boot_initramdisk
  703.         call    boot_log
  704.         call    ramdisk_init
  705.  
  706.         mov     esi, boot_initapic
  707.         call    boot_log
  708. ; Try to Initialize APIC
  709.         call    APIC_init
  710.  
  711.         mov     esi, boot_enableirq
  712.         call    boot_log
  713. ; Enable timer IRQ (IRQ0) and co-processor IRQ (IRQ13)
  714. ; they are used: when partitions are scanned, hd_read relies on timer
  715.         call    unmask_timer
  716.         stdcall enable_irq, 2               ; @#$%! PIC
  717.         stdcall enable_irq, 13              ; co-processor
  718.  
  719. ; Setup serial output console (if enabled)
  720. if defined debug_com_base
  721.  
  722.         ; reserve port so nobody else will use it
  723.         xor     ebx, ebx
  724.         mov     ecx, debug_com_base
  725.         mov     edx, debug_com_base+7
  726.         call    r_f_port_area
  727.  
  728.         ; enable Divisor latch
  729.         mov     dx, debug_com_base+3
  730.         mov     al, 1 shl 7
  731.         out     dx, al
  732.  
  733.         ; Set speed to 115200 baud (max speed)
  734.         mov     dx, debug_com_base
  735.         mov     al, 0x01
  736.         out     dx, al
  737.  
  738.         mov     dx, debug_com_base+1
  739.         mov     al, 0x00
  740.         out     dx, al
  741.  
  742.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  743.         mov     dx, debug_com_base+3
  744.         mov     al, 3
  745.         out     dx, al
  746.  
  747.         ; disable interrupts
  748.         mov     dx, debug_com_base+1
  749.         mov     al, 0
  750.         out     dx, al
  751.  
  752.         ; clear +  enable fifo (64 bits)
  753.         mov     dx, debug_com_base+2
  754.         mov     al, 0x7 + 1 shl 5
  755.         out     dx, al
  756.  
  757. end if
  758.  
  759.  
  760. ;-----------------------------------------------------------------------------
  761. ; show SVN version of kernel on the message board
  762. ;-----------------------------------------------------------------------------
  763.         mov     eax, [version_inf.rev]
  764.         DEBUGF  1, "K : kernel SVN r%d\n", eax
  765. ;-----------------------------------------------------------------------------
  766. ; show CPU count on the message board
  767. ;-----------------------------------------------------------------------------
  768.         mov     eax, [cpu_count]
  769.         test    eax, eax
  770.         jnz     @F
  771.         mov     al, 1                             ; at least one CPU
  772. @@:
  773.         DEBUGF  1, "K : %d CPU detected\n", eax
  774. ;-----------------------------------------------------------------------------
  775. ; detect Floppy drives
  776. ;-----------------------------------------------------------------------------
  777.         mov     esi, boot_detectfloppy
  778.         call    boot_log
  779. include 'detect/dev_fd.inc'
  780. ;-----------------------------------------------------------------------------
  781. ; create pci-devices list
  782. ;-----------------------------------------------------------------------------
  783.         mov     [pci_access_enabled], 1
  784.         call    pci_enum
  785. ;-----------------------------------------------------------------------------
  786. ; initialisation IDE ATA code
  787. ;-----------------------------------------------------------------------------
  788. include 'detect/init_ata.inc'
  789. ;-----------------------------------------------------------------------------
  790.         mov     esi, boot_init_sys
  791.         call    boot_log
  792.         call    Parser_params
  793.  
  794. if ~ defined extended_primary_loader
  795. ; ramdisk image should be loaded by extended primary loader if it exists
  796. ; READ RAMDISK IMAGE FROM HD
  797.  
  798. ;!!!!!!!!!!!!!!!!!!!!!!!
  799. include 'boot/rdload.inc'
  800. ;!!!!!!!!!!!!!!!!!!!!!!!
  801. end if
  802.  
  803. if 0
  804.         mov     ax, [OS_BASE+0x10000+bx_from_load]
  805.         cmp     ax, 'r1'; if using not ram disk, then load librares and parameters {SPraid.simba}
  806.         je      no_lib_load
  807.  
  808.         mov     esi, boot_loadlibs
  809.         call    boot_log
  810. ; LOADING LIBRARES
  811.         stdcall dll.Load, @IMPORT           ; loading librares for kernel (.obj files)
  812.         call    load_file_parse_table       ; prepare file parse table
  813.         call    set_kernel_conf             ; configure devices and gui
  814. no_lib_load:
  815. end if
  816.  
  817. ; Display APIC status
  818.         mov     esi, boot_APIC_found
  819.         cmp     [irq_mode], IRQ_APIC
  820.         je      @f
  821.         mov     esi, boot_APIC_nfound
  822. @@:
  823.         call    boot_log
  824.  
  825. ; PRINT AMOUNT OF MEMORY
  826.         mov     esi, boot_memdetect
  827.         call    boot_log
  828.  
  829.         movzx   ecx, word [boot_y]
  830.         if lang eq ru
  831.         or      ecx, (10+30*6) shl 16
  832.         else if lang eq sp
  833.         or      ecx, (10+33*6) shl 16
  834.         else
  835.         or      ecx, (10+29*6) shl 16
  836.         end if
  837.         sub     ecx, 10
  838.         mov     edx, 0xFFFFFF
  839.         mov     ebx, [MEM_AMOUNT]
  840.         shr     ebx, 20
  841.         xor     edi, edi
  842.         mov     eax, 0x00040000
  843.         inc     edi
  844.         call    display_number_force
  845.  
  846. ; BUILD SCHEDULER
  847.  
  848. ;        call    build_scheduler; sys32.inc
  849.  
  850. ;        mov     esi, boot_devices
  851. ;        call    boot_log
  852.  
  853.         call    clear_pci_ide_interrupts
  854.  
  855. include "detect/vortex86.inc"                     ; Vortex86 SoC detection code
  856.  
  857.         stdcall load_driver, szVidintel
  858.  
  859.         call    usb_init
  860.  
  861. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  862.  
  863.         mov     esi, boot_windefs
  864.         call    boot_log
  865.         call    set_window_defaults
  866.  
  867. ; SET BACKGROUND DEFAULTS
  868.  
  869.         mov     esi, boot_bgr
  870.         call    boot_log
  871.         call    init_background
  872.         call    calculatebackground
  873.  
  874. ; RESERVE SYSTEM IRQ'S JA PORT'S
  875.  
  876.         mov     esi, boot_resirqports
  877.         call    boot_log
  878.         call    reserve_irqs_ports
  879.  
  880.         call    init_display
  881.         mov     eax, [def_cursor]
  882.         mov     [SLOT_BASE+APPDATA.cursor+256], eax
  883.         mov     [SLOT_BASE+APPDATA.cursor+256*2], eax
  884.  
  885. ; PRINT CPU FREQUENCY
  886.  
  887.         mov     esi, boot_cpufreq
  888.         call    boot_log
  889.  
  890.         cli                         ;FIXME check IF
  891.         rdtsc
  892.         mov     ecx, eax
  893.         mov     esi, 250            ; wait 1/4 a second
  894.         call    delay_ms
  895.         rdtsc
  896.  
  897.         sub     eax, ecx
  898.         xor     edx, edx
  899.         shld    edx, eax, 2
  900.         shl     eax, 2
  901.         mov     dword [cpu_freq], eax
  902.         mov     dword [cpu_freq+4], edx
  903.         mov     ebx, 1000000
  904.         div     ebx
  905.         mov     ebx, eax
  906.  
  907.         movzx   ecx, word [boot_y]
  908.         if lang eq ru
  909.         add     ecx, (10+19*6) shl 16 - 10
  910.         else if lang eq sp
  911.         add     ecx, (10+25*6) shl 16 - 10
  912.         else
  913.         add     ecx, (10+17*6) shl 16 - 10
  914.         end if
  915.  
  916.         mov     edx, 0xFFFFFF
  917.         xor     edi, edi
  918.         mov     eax, 0x00040000
  919.         inc     edi
  920.         call    display_number_force
  921.  
  922. ; SET VARIABLES
  923.  
  924.         call    set_variables
  925.  
  926. ; STACK AND FDC
  927.  
  928.         call    stack_init
  929.         call    fdc_init
  930.  
  931. ; PALETTE FOR 320x200 and 640x480 16 col
  932.  
  933.         cmp     [SCR_MODE], word 0x12
  934.         jne     no_pal_vga
  935.         mov     esi, boot_pal_vga
  936.         call    boot_log
  937.         call    paletteVGA
  938.       no_pal_vga:
  939.  
  940.         cmp     [SCR_MODE], word 0x13
  941.         jne     no_pal_ega
  942.         mov     esi, boot_pal_ega
  943.         call    boot_log
  944.         call    palette320x200
  945.       no_pal_ega:
  946.  
  947. ; LOAD DEFAULT SKIN
  948.  
  949.         call    load_default_skin
  950.  
  951. ;protect io permission map
  952.  
  953.         mov     esi, [default_io_map]
  954.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  955.         add     esi, 0x1000
  956.         stdcall map_page, esi, [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  957.  
  958.         stdcall map_page, tss._io_map_0, \
  959.                 [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  960.         stdcall map_page, tss._io_map_1, \
  961.                 [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  962.  
  963. ; LOAD FIRST APPLICATION
  964.         cmp     byte [launcher_start], 1        ; Check if starting LAUNCHER is selected on blue screen (1 = yes)
  965.         jnz     first_app_found
  966.  
  967.         cli
  968.         mov     ebp, firstapp
  969.         call    fs_execute_from_sysdir
  970.         test    eax, eax
  971.         jns     first_app_found
  972.  
  973.         mov     esi, boot_failed
  974.         call    boot_log
  975.  
  976.         mov     eax, 0xDEADBEEF      ; otherwise halt
  977.         hlt
  978.  
  979. first_app_found:
  980.  
  981.         cli
  982.  
  983. ; SET KEYBOARD PARAMETERS
  984.         mov     al, 0xf6       ; reset keyboard, scan enabled
  985.         call    kb_write
  986.         test    ah, ah
  987.         jnz     .no_keyboard
  988.  
  989.         ; wait until 8042 is ready
  990.         xor     ecx, ecx
  991.       @@:
  992.         in      al, 64h
  993.         and     al, 00000010b
  994.         loopnz  @b
  995.  
  996. iglobal
  997. align 4
  998. ps2_keyboard_functions:
  999.         dd      .end - $
  1000.         dd      0       ; no close
  1001.         dd      ps2_set_lights
  1002. .end:
  1003. endg
  1004.         stdcall register_keyboard, ps2_keyboard_functions, 0
  1005.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  1006.        ; call  kb_write
  1007.        ; call  kb_read
  1008.        ; mov   al, 111b
  1009.        ; call  kb_write
  1010.        ; call  kb_read
  1011.  
  1012.         mov     al, 0xF3     ; set repeat rate & delay
  1013.         call    kb_write
  1014. ;        call  kb_read
  1015.         mov     al, 0; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  1016.         call    kb_write
  1017. ;        call  kb_read
  1018.      ;// mike.dld [
  1019.         call    set_lights
  1020.      ;// mike.dld ]
  1021.         stdcall attach_int_handler, 1, irq1, 0
  1022.         DEBUGF  1, "K : IRQ1 return code %x\n", eax
  1023. .no_keyboard:
  1024.  
  1025. ; Load PS/2 mouse driver
  1026.  
  1027.         stdcall load_driver, szPS2MDriver
  1028.  
  1029.         mov     esi, boot_setmouse
  1030.         call    boot_log
  1031.         call    setmouse
  1032.  
  1033. ; START MULTITASKING
  1034.  
  1035. ; A 'All set - press ESC to start' messages if need
  1036. if preboot_blogesc
  1037.         mov     esi, boot_tasking
  1038.         call    boot_log
  1039. .bll1:
  1040.         in      al, 0x60        ; wait for ESC key press
  1041.         cmp     al, 129
  1042.         jne     .bll1
  1043. end if
  1044.  
  1045.         mov     [timer_ticks_enable], 1         ; for cd driver
  1046.  
  1047.         sti
  1048.  
  1049.         call    mtrr_validate
  1050.  
  1051.         jmp     osloop
  1052.  
  1053.  
  1054.         ; Fly :)
  1055.  
  1056. include 'unpacker.inc'
  1057.  
  1058. align 4
  1059. boot_log:
  1060.         pushad
  1061.  
  1062.         mov     ebx, 10*65536
  1063.         mov     bx, word [boot_y]
  1064.         add     [boot_y], dword 10
  1065.         mov     ecx, 0x80ffffff; ASCIIZ string with white color
  1066.         xor     edi, edi
  1067.         mov     edx, esi
  1068.         inc     edi
  1069.         call    dtext
  1070.  
  1071.         mov     [novesachecksum], 1000
  1072.         call    checkVga_N13
  1073.  
  1074.         popad
  1075.  
  1076.         ret
  1077.  
  1078. ; in: edx -> APPDATA for OS/IDLE slot
  1079. ; in: ebx = stack base
  1080. proc setup_os_slot
  1081.         xor     eax, eax
  1082.         mov     ecx, 256/4
  1083.         mov     edi, edx
  1084.         rep stosd
  1085.  
  1086.         mov     eax, tss+0x80
  1087.         call    get_pg_addr
  1088.         inc     eax
  1089.         mov     [edx+APPDATA.io_map], eax
  1090.         mov     eax, tss+0x1080
  1091.         call    get_pg_addr
  1092.         inc     eax
  1093.         mov     [edx+APPDATA.io_map+4], eax
  1094.  
  1095.         mov     dword [edx+APPDATA.pl0_stack], ebx
  1096.         lea     edi, [ebx+0x2000-512]
  1097.         mov     dword [edx+APPDATA.fpu_state], edi
  1098.         mov     dword [edx+APPDATA.saved_esp0], edi
  1099.         mov     dword [edx+APPDATA.saved_esp], edi
  1100.         mov     dword [edx+APPDATA.terminate_protection], 1 ; make unkillable
  1101.  
  1102.         mov     esi, fpu_data
  1103.         mov     ecx, 512/4
  1104.         cld
  1105.         rep movsd
  1106.  
  1107.         lea     eax, [edx+APP_OBJ_OFFSET]
  1108.         mov     dword [edx+APPDATA.fd_obj], eax
  1109.         mov     dword [edx+APPDATA.bk_obj], eax
  1110.  
  1111.         mov     dword [edx+APPDATA.cur_dir], sysdir_path
  1112.  
  1113.         mov     [edx + APPDATA.dir_table], sys_pgdir - OS_BASE
  1114.  
  1115.         mov     eax, edx
  1116.         shr     eax, 3
  1117.         add     eax, CURRENT_TASK - (SLOT_BASE shr 3)
  1118.         mov     [eax+TASKDATA.wnd_number], dh
  1119.         mov     byte [eax+TASKDATA.pid], dh
  1120.  
  1121.         ret
  1122. endp
  1123.  
  1124. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1125. ;                                                                    ;
  1126. ;                    MAIN OS LOOP START                              ;
  1127. ;                                                                    ;
  1128. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1129. align 32
  1130. osloop:
  1131.         mov     edx, osloop_has_work?
  1132.         xor     ecx, ecx
  1133.         call    Wait_events
  1134.         xor     eax, eax
  1135.         xchg    eax, [osloop_nonperiodic_work]
  1136.         test    eax, eax
  1137.         jz      .no_periodic
  1138.  
  1139.         call    __sys_draw_pointer
  1140.         call    window_check_events
  1141.         call    mouse_check_events
  1142.         call    checkmisc
  1143.         call    checkVga_N13
  1144. ;--------------------------------------
  1145. .no_periodic:
  1146.         call    stack_handler
  1147.         call    check_fdd_motor_status
  1148.         call    check_ATAPI_device_event
  1149.         call    check_lights_state
  1150.         call    check_timers
  1151.  
  1152.         jmp     osloop
  1153. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1154. ;                                                                    ;
  1155. ;                      MAIN OS LOOP END                              ;
  1156. ;                                                                    ;
  1157. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1158. proc osloop_has_work?
  1159.         cmp     [osloop_nonperiodic_work], 0
  1160.         jnz     .yes
  1161.         call    stack_handler_has_work?
  1162.         jnz     .yes
  1163.         call    check_fdd_motor_status_has_work?
  1164.         jnz     .yes
  1165.         call    check_ATAPI_device_event_has_work?
  1166.         jnz     .yes
  1167.         call    check_lights_state_has_work?
  1168.         jnz     .yes
  1169.         call    check_timers_has_work?
  1170.         jnz     .yes
  1171. .no:
  1172.         xor     eax, eax
  1173.         ret
  1174. .yes:
  1175.         xor     eax, eax
  1176.         inc     eax
  1177.         ret
  1178. endp
  1179.  
  1180. proc wakeup_osloop
  1181.         mov     [osloop_nonperiodic_work], 1
  1182.         ret
  1183. endp
  1184.  
  1185. uglobal
  1186. align 4
  1187. osloop_nonperiodic_work dd      ?
  1188. endg
  1189.  
  1190. align 4
  1191. idle_thread:
  1192.         sti
  1193. idle_loop:
  1194.         hlt
  1195.         jmp     idle_loop
  1196.  
  1197.  
  1198.  
  1199. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1200. ;                                                                      ;
  1201. ;                   INCLUDED SYSTEM FILES                              ;
  1202. ;                                                                      ;
  1203. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1204.  
  1205.  
  1206. include "kernel32.inc"
  1207.  
  1208.  
  1209. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1210. ;                                                                      ;
  1211. ;                       KERNEL FUNCTIONS                               ;
  1212. ;                                                                      ;
  1213. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1214.  
  1215. reserve_irqs_ports:
  1216.  
  1217.  
  1218. ; RESERVE PORTS
  1219.         mov     eax, RESERVED_PORTS
  1220.         mov     ecx, 1
  1221.  
  1222.         mov     [eax], dword 4
  1223.  
  1224.         mov     [eax+16], ecx
  1225.         mov     [eax+16+4], dword 0
  1226.         mov     [eax+16+8], dword 0x2D
  1227.  
  1228.         mov     [eax+32], ecx
  1229.         mov     [eax+32+4], dword 0x30
  1230.         mov     [eax+32+8], dword 0x4D
  1231.  
  1232.         mov     [eax+48], ecx
  1233.         mov     [eax+48+4], dword 0x50
  1234.         mov     [eax+48+8], dword 0xDF
  1235.  
  1236.         mov     [eax+64], ecx
  1237.         mov     [eax+64+4], dword 0xE5
  1238.         mov     [eax+64+8], dword 0xFF
  1239.  
  1240.         ret
  1241.  
  1242.  
  1243. iglobal
  1244.   process_number dd 0x2
  1245. endg
  1246.  
  1247. set_variables:
  1248.  
  1249.         mov     ecx, 0x16                    ; flush port 0x60
  1250. .fl60:
  1251.         in      al, 0x60
  1252.         loop    .fl60
  1253.         push    eax
  1254.  
  1255.         mov     ax, [BOOT_VARS+BOOT_Y_RES]
  1256.         shr     ax, 1
  1257.         shl     eax, 16
  1258.         mov     ax, [BOOT_VARS+BOOT_X_RES]
  1259.         shr     ax, 1
  1260.         mov     [MOUSE_X], eax
  1261.         call    wakeup_osloop
  1262.  
  1263.         xor     eax, eax
  1264.         mov     [BTN_ADDR], dword BUTTON_INFO ; address of button list
  1265.  
  1266.         mov     byte [KEY_COUNT], al              ; keyboard buffer
  1267.         mov     byte [BTN_COUNT], al              ; button buffer
  1268. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1269.  
  1270.         pop     eax
  1271.         ret
  1272.  
  1273. align 4
  1274. ;input  eax=43,bl-byte of output, ecx - number of port
  1275. sys_outport:
  1276.  
  1277.         mov     edi, ecx   ; separate flag for read / write
  1278.         and     ecx, 65535
  1279.  
  1280.         mov     eax, [RESERVED_PORTS]
  1281.         test    eax, eax
  1282.         jnz     .sopl8
  1283.         inc     eax
  1284.         mov     [esp+32], eax
  1285.         ret
  1286.  
  1287.   .sopl8:
  1288.         mov     edx, [TASK_BASE]
  1289.         mov     edx, [edx+0x4]
  1290.     ;and   ecx,65535
  1291.     ;cld - set on interrupt 0x40
  1292.   .sopl1:
  1293.  
  1294.         mov     esi, eax
  1295.         shl     esi, 4
  1296.         add     esi, RESERVED_PORTS
  1297.         cmp     edx, [esi+0]
  1298.         jne     .sopl2
  1299.         cmp     ecx, [esi+4]
  1300.         jb      .sopl2
  1301.         cmp     ecx, [esi+8]
  1302.         jg      .sopl2
  1303. .sopl3:
  1304.  
  1305.         test    edi, 0x80000000; read ?
  1306.         jnz     .sopl4
  1307.  
  1308.         mov     eax, ebx
  1309.         mov     dx, cx   ; write
  1310.         out     dx, al
  1311.         and     [esp+32], dword 0
  1312.         ret
  1313.  
  1314.         .sopl2:
  1315.  
  1316.         dec     eax
  1317.         jnz     .sopl1
  1318.         inc     eax
  1319.         mov     [esp+32], eax
  1320.         ret
  1321.  
  1322.  
  1323.   .sopl4:
  1324.  
  1325.         mov     dx, cx   ; read
  1326.         in      al, dx
  1327.         and     eax, 0xff
  1328.         and     [esp+32], dword 0
  1329.         mov     [esp+20], eax
  1330.         ret
  1331.  
  1332. display_number:
  1333. ;It is not optimization
  1334.         mov     eax, ebx
  1335.         mov     ebx, ecx
  1336.         mov     ecx, edx
  1337.         mov     edx, esi
  1338.         mov     esi, edi
  1339. ; eax = print type, al=0 -> ebx is number
  1340. ;                   al=1 -> ebx is pointer
  1341. ;                   ah=0 -> display decimal
  1342. ;                   ah=1 -> display hexadecimal
  1343. ;                   ah=2 -> display binary
  1344. ;                   eax bits 16-21 = number of digits to display (0-32)
  1345. ;                   eax bits 22-31 = reserved
  1346. ;
  1347. ; ebx = number or pointer
  1348. ; ecx = x shl 16 + y
  1349. ; edx = color
  1350.         xor     edi, edi
  1351. display_number_force:
  1352.         push    eax
  1353.         and     eax, 0x3fffffff
  1354.         cmp     eax, 0xffff     ; length > 0 ?
  1355.         pop     eax
  1356.         jge     cont_displ
  1357.         ret
  1358.    cont_displ:
  1359.         push    eax
  1360.         and     eax, 0x3fffffff
  1361.         cmp     eax, 61*0x10000  ; length <= 60 ?
  1362.         pop     eax
  1363.         jb      cont_displ2
  1364.         ret
  1365.    cont_displ2:
  1366.  
  1367.         pushad
  1368.  
  1369.         cmp     al, 1            ; ecx is a pointer ?
  1370.         jne     displnl1
  1371.         mov     ebp, ebx
  1372.         add     ebp, 4
  1373.         mov     ebp, [ebp+std_application_base_address]
  1374.         mov     ebx, [ebx+std_application_base_address]
  1375.  displnl1:
  1376.         sub     esp, 64
  1377.  
  1378.         test    ah, ah            ; DECIMAL
  1379.         jnz     no_display_desnum
  1380.         shr     eax, 16
  1381.         and     eax, 0xC03f
  1382. ;     and   eax,0x3f
  1383.         push    eax
  1384.         and     eax, 0x3f
  1385.         mov     edi, esp
  1386.         add     edi, 4+64-1
  1387.         mov     ecx, eax
  1388.         mov     eax, ebx
  1389.         mov     ebx, 10
  1390.  d_desnum:
  1391.         xor     edx, edx
  1392.         call    division_64_bits
  1393.         div     ebx
  1394.         add     dl, 48
  1395.         mov     [edi], dl
  1396.         dec     edi
  1397.         loop    d_desnum
  1398.         pop     eax
  1399.         call    normalize_number
  1400.         call    draw_num_text
  1401.         add     esp, 64
  1402.         popad
  1403.         ret
  1404.    no_display_desnum:
  1405.  
  1406.         cmp     ah, 0x01         ; HEXADECIMAL
  1407.         jne     no_display_hexnum
  1408.         shr     eax, 16
  1409.         and     eax, 0xC03f
  1410. ;     and   eax,0x3f
  1411.         push    eax
  1412.         and     eax, 0x3f
  1413.         mov     edi, esp
  1414.         add     edi, 4+64-1
  1415.         mov     ecx, eax
  1416.         mov     eax, ebx
  1417.         mov     ebx, 16
  1418.    d_hexnum:
  1419.         xor     edx, edx
  1420.         call    division_64_bits
  1421.         div     ebx
  1422.    hexletters = __fdo_hexdigits
  1423.         add     edx, hexletters
  1424.         mov     dl, [edx]
  1425.         mov     [edi], dl
  1426.         dec     edi
  1427.         loop    d_hexnum
  1428.         pop     eax
  1429.         call    normalize_number
  1430.         call    draw_num_text
  1431.         add     esp, 64
  1432.         popad
  1433.         ret
  1434.    no_display_hexnum:
  1435.  
  1436.         cmp     ah, 0x02         ; BINARY
  1437.         jne     no_display_binnum
  1438.         shr     eax, 16
  1439.         and     eax, 0xC03f
  1440. ;     and   eax,0x3f
  1441.         push    eax
  1442.         and     eax, 0x3f
  1443.         mov     edi, esp
  1444.         add     edi, 4+64-1
  1445.         mov     ecx, eax
  1446.         mov     eax, ebx
  1447.         mov     ebx, 2
  1448.    d_binnum:
  1449.         xor     edx, edx
  1450.         call    division_64_bits
  1451.         div     ebx
  1452.         add     dl, 48
  1453.         mov     [edi], dl
  1454.         dec     edi
  1455.         loop    d_binnum
  1456.         pop     eax
  1457.         call    normalize_number
  1458.         call    draw_num_text
  1459.         add     esp, 64
  1460.         popad
  1461.         ret
  1462.    no_display_binnum:
  1463.  
  1464.         add     esp, 64
  1465.         popad
  1466.         ret
  1467.  
  1468. normalize_number:
  1469.         test    ah, 0x80
  1470.         jz      .continue
  1471.         mov     ecx, 48
  1472.         and     eax, 0x3f
  1473. @@:
  1474.         inc     edi
  1475.         cmp     [edi], cl
  1476.         jne     .continue
  1477.         dec     eax
  1478.         cmp     eax, 1
  1479.         ja      @r
  1480.         mov     al, 1
  1481. .continue:
  1482.         and     eax, 0x3f
  1483.         ret
  1484.  
  1485. division_64_bits:
  1486.         test    [esp+1+4], byte 0x40
  1487.         jz      .continue
  1488.         push    eax
  1489.         mov     eax, ebp
  1490.         div     ebx
  1491.         mov     ebp, eax
  1492.         pop     eax
  1493. .continue:
  1494.         ret
  1495.  
  1496. draw_num_text:
  1497.         mov     esi, eax
  1498.         mov     edx, 64+4
  1499.         sub     edx, eax
  1500.         add     edx, esp
  1501.         mov     ebx, [esp+64+32-8+4]
  1502. ; add window start x & y
  1503.         mov     ecx, [TASK_BASE]
  1504.  
  1505.         mov     edi, [CURRENT_TASK]
  1506.         shl     edi, 8
  1507.  
  1508.         mov     eax, [ecx-twdw+WDATA.box.left]
  1509.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1510.         shl     eax, 16
  1511.         add     eax, [ecx-twdw+WDATA.box.top]
  1512.         add     eax, [edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1513.         add     ebx, eax
  1514.         mov     ecx, [esp+64+32-12+4]
  1515.         and     ecx, not 0x80000000     ; force counted string
  1516.         mov     eax, [esp+64+8]         ; background color (if given)
  1517.         mov     edi, [esp+64+4]
  1518.         jmp     dtext
  1519. ;-----------------------------------------------------------------------------
  1520. iglobal
  1521. midi_base dw 0
  1522. endg
  1523. ;-----------------------------------------------------------------------------
  1524. align 4
  1525. sys_setup:
  1526. ;  1 = roland mpu midi base , base io address
  1527. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1528. ;  3 = not used
  1529. ;  4 = not used
  1530. ;  5 = system language, 1eng 2fi 3ger 4rus
  1531. ;  6 = not used
  1532. ;  7 = not used
  1533. ;  8 = not used
  1534. ;  9 = not used
  1535. ; 10 = not used
  1536. ; 11 = enable lba read
  1537. ; 12 = enable pci access
  1538. ;-----------------------------------------------------------------------------
  1539.         and     [esp+32], dword 0
  1540. ; F.21.1 - set MPU MIDI base port
  1541.         dec     ebx
  1542.         jnz     @f
  1543.  
  1544.         cmp     ecx, 0x100
  1545.         jb      @f
  1546.  
  1547.         mov     esi, 65535
  1548.         cmp     esi, ecx
  1549.         jb      @f
  1550.  
  1551.         mov     [midi_base], cx
  1552.         mov     word [mididp], cx
  1553.         inc     cx
  1554.         mov     word [midisp], cx
  1555.         ret
  1556. ;--------------------------------------
  1557. @@:
  1558. ; F.21.2 - set keyboard layout
  1559.         dec     ebx
  1560.         jnz     @f
  1561.  
  1562.         mov     edi, [TASK_BASE]
  1563.         mov     eax, [edi+TASKDATA.mem_start]
  1564.         add     eax, edx
  1565. ; 1 = normal layout
  1566.         dec     ecx
  1567.         jnz     .shift
  1568.  
  1569.         mov     ebx, keymap
  1570.         mov     ecx, 128
  1571.         call    memmove
  1572.         ret
  1573. ;--------------------------------------
  1574. .shift:
  1575. ; 2 = layout at pressed Shift
  1576.         dec     ecx
  1577.         jnz     .alt
  1578.  
  1579.         mov     ebx, keymap_shift
  1580.         mov     ecx, 128
  1581.         call    memmove
  1582.         ret
  1583. ;--------------------------------------
  1584. .alt:
  1585. ; 3 = layout at pressed Alt
  1586.         dec     ecx
  1587.         jnz     .country
  1588.  
  1589.         mov     ebx, keymap_alt
  1590.         mov     ecx, 128
  1591.         call    memmove
  1592.         ret
  1593. ;--------------------------------------
  1594. .country:
  1595. ; country identifier
  1596.         sub     ecx, 6
  1597.         jnz     .error
  1598.  
  1599.         mov     word [keyboard], dx
  1600.         ret
  1601. ;--------------------------------------
  1602. @@:
  1603. ; F.21.5 - set system language
  1604.         sub     ebx, 3
  1605.         jnz     @f
  1606.  
  1607.         mov     [syslang], ecx
  1608.         ret
  1609. ;--------------------------------------
  1610. @@:
  1611. ; F.21.11 - enable/disable low-level access to HD
  1612.         and     ecx, 1
  1613.         sub     ebx, 6
  1614.         jnz     @f
  1615.  
  1616.         mov     [lba_read_enabled], ecx
  1617.         ret
  1618. ;--------------------------------------
  1619. @@:
  1620. ; F.21.12 - enable/disable low-level access to PCI
  1621.         dec     ebx
  1622.         jnz     .error
  1623.  
  1624.         mov     [pci_access_enabled], ecx
  1625.         ret
  1626. ;--------------------------------------
  1627. .error:
  1628.         or      [esp+32], dword -1
  1629.         ret
  1630. ;-----------------------------------------------------------------------------
  1631. align 4
  1632. sys_getsetup:
  1633. ;  1 = roland mpu midi base , base io address
  1634. ;  2 = keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1635. ;  3 = not used
  1636. ;  4 = not used
  1637. ;  5 = system language, 1eng 2fi 3ger 4rus
  1638. ;  6 = not used
  1639. ;  7 = not used
  1640. ;  8 = not used
  1641. ;  9 = get hs timer tic
  1642. ; 10 = not used
  1643. ; 11 = get the state "lba read"
  1644. ; 12 = get the state "pci access"
  1645. ;-----------------------------------------------------------------------------
  1646. ; F.26.1 - get MPU MIDI base port
  1647.         dec     ebx
  1648.         jnz     @f
  1649.  
  1650.         movzx   eax, [midi_base]
  1651.         mov     [esp+32], eax
  1652.         ret
  1653. ;--------------------------------------
  1654. @@:
  1655. ; F.26.2 - get keyboard layout
  1656.         dec     ebx
  1657.         jnz     @f
  1658.  
  1659.         mov     edi, [TASK_BASE]
  1660.         mov     ebx, [edi+TASKDATA.mem_start]
  1661.         add     ebx, edx
  1662. ; 1 = normal layout
  1663.         dec     ecx
  1664.         jnz     .shift
  1665.  
  1666.         mov     eax, keymap
  1667.         mov     ecx, 128
  1668.         call    memmove
  1669.         ret
  1670. ;--------------------------------------
  1671. .shift:
  1672. ; 2 = layout with pressed Shift
  1673.         dec     ecx
  1674.         jnz     .alt
  1675.  
  1676.         mov     eax, keymap_shift
  1677.         mov     ecx, 128
  1678.         call    memmove
  1679.         ret
  1680. ;--------------------------------------
  1681. .alt:
  1682. ; 3 = layout with pressed Alt
  1683.         dec     ecx
  1684.         jne     .country
  1685.  
  1686.         mov     eax, keymap_alt
  1687.         mov     ecx, 128
  1688.         call    memmove
  1689.         ret
  1690. ;--------------------------------------
  1691. .country:
  1692. ; 9 = country identifier
  1693.         sub     ecx, 6
  1694.         jnz     .error
  1695.  
  1696.         movzx   eax, word [keyboard]
  1697.         mov     [esp+32], eax
  1698.         ret
  1699. ;--------------------------------------
  1700. @@:
  1701. ; F.26.5 - get system language
  1702.         sub     ebx, 3
  1703.         jnz     @f
  1704.  
  1705.         mov     eax, [syslang]
  1706.         mov     [esp+32], eax
  1707.         ret
  1708. ;--------------------------------------
  1709. @@:
  1710. ; F.26.9 - get the value of the time counter
  1711.         sub     ebx, 4
  1712.         jnz     @f
  1713.  
  1714.         mov     eax, [timer_ticks]
  1715.         mov     [esp+32], eax
  1716.         ret
  1717. ;--------------------------------------
  1718. @@:
  1719. ; F.26.11 - Find out whether low-level HD access is enabled
  1720.         sub     ebx, 2
  1721.         jnz     @f
  1722.  
  1723.         mov     eax, [lba_read_enabled]
  1724.         mov     [esp+32], eax
  1725.         ret
  1726. ;--------------------------------------
  1727. @@:
  1728. ; F.26.12 - Find out whether low-level PCI access is enabled
  1729.         dec     ebx
  1730.         jnz     .error
  1731.  
  1732.         mov     eax, [pci_access_enabled]
  1733.         mov     [esp+32], eax
  1734.         ret
  1735. ;--------------------------------------
  1736. .error:
  1737.         or      [esp+32], dword -1
  1738.         ret
  1739. ;-----------------------------------------------------------------------------
  1740. get_timer_ticks:
  1741.         mov     eax, [timer_ticks]
  1742.         ret
  1743. ;-----------------------------------------------------------------------------
  1744. iglobal
  1745. align 4
  1746. mousefn dd msscreen, mswin, msbutton, msset
  1747.         dd app_load_cursor
  1748.         dd app_set_cursor
  1749.         dd app_delete_cursor
  1750.         dd msz
  1751. endg
  1752. ;-----------------------------------------------------------------------------
  1753. readmousepos:
  1754.  
  1755. ; eax=0 screen relative
  1756. ; eax=1 window relative
  1757. ; eax=2 buttons pressed
  1758. ; eax=3 set mouse pos   ; reserved
  1759. ; eax=4 load cursor
  1760. ; eax=5 set cursor
  1761. ; eax=6 delete cursor   ; reserved
  1762. ; eax=7 get mouse_z
  1763.  
  1764.         cmp     ebx, 7
  1765.         ja      msset
  1766.         jmp     [mousefn+ebx*4]
  1767. msscreen:
  1768.         mov     eax, [MOUSE_X]
  1769.         shl     eax, 16
  1770.         mov     ax, [MOUSE_Y]
  1771.         mov     [esp+36-4], eax
  1772.         ret
  1773. mswin:
  1774.         mov     eax, [MOUSE_X]
  1775.         shl     eax, 16
  1776.         mov     ax, [MOUSE_Y]
  1777.         mov     esi, [TASK_BASE]
  1778.         mov     bx, word [esi-twdw+WDATA.box.left]
  1779.         shl     ebx, 16
  1780.         mov     bx, word [esi-twdw+WDATA.box.top]
  1781.         sub     eax, ebx
  1782.  
  1783.         mov     edi, [CURRENT_TASK]
  1784.         shl     edi, 8
  1785.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1786.         rol     eax, 16
  1787.         sub     ax, word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1788.         rol     eax, 16
  1789.         mov     [esp+36-4], eax
  1790.         ret
  1791. msbutton:
  1792.         movzx   eax, byte [BTN_DOWN]
  1793.         mov     [esp+36-4], eax
  1794.         ret
  1795. msz:
  1796.         mov     edi, [TASK_COUNT]
  1797.         movzx   edi, word [WIN_POS + edi*2]
  1798.         cmp     edi, [CURRENT_TASK]
  1799.         jne     @f
  1800.         mov     ax, [MOUSE_SCROLL_H]
  1801.         shl     eax, 16
  1802.         mov     ax, [MOUSE_SCROLL_V]
  1803.         mov     [esp+36-4], eax
  1804.         and     [MOUSE_SCROLL_H], word 0
  1805.         and     [MOUSE_SCROLL_V], word 0
  1806.         ret
  1807.        @@:
  1808.         and     [esp+36-4], dword 0
  1809. ;           ret
  1810. msset:
  1811.         ret
  1812.  
  1813. app_load_cursor:
  1814.         cmp     ecx, OS_BASE
  1815.         jae     msset
  1816.         stdcall load_cursor, ecx, edx
  1817.         mov     [esp+36-4], eax
  1818.         ret
  1819.  
  1820. app_set_cursor:
  1821.         stdcall set_cursor, ecx
  1822.         mov     [esp+36-4], eax
  1823.         ret
  1824.  
  1825. app_delete_cursor:
  1826.         stdcall delete_cursor, ecx
  1827.         mov     [esp+36-4], eax
  1828.         ret
  1829.  
  1830. is_input:
  1831.  
  1832.         push    edx
  1833.         mov     dx, word [midisp]
  1834.         in      al, dx
  1835.         and     al, 0x80
  1836.         pop     edx
  1837.         ret
  1838.  
  1839. is_output:
  1840.  
  1841.         push    edx
  1842.         mov     dx, word [midisp]
  1843.         in      al, dx
  1844.         and     al, 0x40
  1845.         pop     edx
  1846.         ret
  1847.  
  1848.  
  1849. get_mpu_in:
  1850.  
  1851.         push    edx
  1852.         mov     dx, word [mididp]
  1853.         in      al, dx
  1854.         pop     edx
  1855.         ret
  1856.  
  1857.  
  1858. put_mpu_out:
  1859.  
  1860.         push    edx
  1861.         mov     dx, word [mididp]
  1862.         out     dx, al
  1863.         pop     edx
  1864.         ret
  1865.  
  1866.  
  1867.  
  1868. align 4
  1869.  
  1870. sys_midi:
  1871.         cmp     [mididp], 0
  1872.         jnz     sm0
  1873.         mov     [esp+36], dword 1
  1874.         ret
  1875. sm0:
  1876.         and     [esp+36], dword 0
  1877.         dec     ebx
  1878.         jnz     smn1
  1879.  ;    call setuart
  1880. su1:
  1881.         call    is_output
  1882.         test    al, al
  1883.         jnz     su1
  1884.         mov     dx, word [midisp]
  1885.         mov     al, 0xff
  1886.         out     dx, al
  1887. su2:
  1888.         mov     dx, word [midisp]
  1889.         mov     al, 0xff
  1890.         out     dx, al
  1891.         call    is_input
  1892.         test    al, al
  1893.         jnz     su2
  1894.         call    get_mpu_in
  1895.         cmp     al, 0xfe
  1896.         jnz     su2
  1897. su3:
  1898.         call    is_output
  1899.         test    al, al
  1900.         jnz     su3
  1901.         mov     dx, word [midisp]
  1902.         mov     al, 0x3f
  1903.         out     dx, al
  1904.         ret
  1905. smn1:
  1906.         dec     ebx
  1907.         jnz     smn2
  1908. sm10:
  1909.         call    get_mpu_in
  1910.         call    is_output
  1911.         test    al, al
  1912.         jnz     sm10
  1913.         mov     al, bl
  1914.         call    put_mpu_out
  1915.         smn2:
  1916.         ret
  1917.  
  1918. detect_devices:
  1919. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1920. ;include 'detect/commouse.inc'
  1921. ;include 'detect/ps2mouse.inc'
  1922. ;include 'detect/dev_fd.inc'
  1923. ;include 'detect/dev_hdcd.inc'
  1924. ;include 'detect/sear_par.inc'
  1925. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1926.         ret
  1927.  
  1928. sys_end:
  1929. ;--------------------------------------
  1930.         cmp     [_display.select_cursor], 0
  1931.         je      @f
  1932. ; restore default cursor before killing
  1933.         pusha
  1934.         mov     ecx, [current_slot]
  1935.         call    restore_default_cursor_before_killing
  1936.         popa
  1937. @@:
  1938. ;--------------------------------------
  1939. ; kill all sockets this process owns
  1940.         pusha
  1941.         mov     edx, [TASK_BASE]
  1942.         mov     edx, [edx+TASKDATA.pid]
  1943.         call    SOCKET_process_end
  1944.         popa
  1945. ;--------------------------------------
  1946.         mov     ecx, [current_slot]
  1947.         mov     eax, [ecx+APPDATA.tls_base]
  1948.         test    eax, eax
  1949.         jz      @F
  1950.  
  1951.         stdcall user_free, eax
  1952. @@:
  1953.  
  1954.         mov     eax, [TASK_BASE]
  1955.         mov     [eax+TASKDATA.state], 3; terminate this program
  1956.         call    wakeup_osloop
  1957.  
  1958. .waitterm:            ; wait here for termination
  1959.         call    change_task
  1960.         jmp     .waitterm
  1961. ;------------------------------------------------------------------------------
  1962. align 4
  1963. restore_default_cursor_before_killing:
  1964.         pushfd
  1965.         cli
  1966.         mov     eax, [def_cursor]
  1967.         mov     [ecx+APPDATA.cursor], eax
  1968.  
  1969.         movzx   eax, word [MOUSE_Y]
  1970.         movzx   ebx, word [MOUSE_X]
  1971. ;        mov     ecx, [Screen_Max_X]
  1972. ;        inc     ecx
  1973. ;        mul     ecx
  1974.         mov     eax, [d_width_calc_area + eax*4]
  1975.  
  1976.         add     eax, [_WinMapAddress]
  1977.         movzx   edx, byte [ebx+eax]
  1978.         shl     edx, 8
  1979.         mov     esi, [edx+SLOT_BASE+APPDATA.cursor]
  1980.  
  1981.         cmp     esi, [current_cursor]
  1982.         je      @f
  1983.  
  1984.         push    esi
  1985.         call    [_display.select_cursor]
  1986.         mov     [current_cursor], esi
  1987. @@:
  1988.         mov     [redrawmouse_unconditional], 1
  1989.         call    wakeup_osloop
  1990.         popfd
  1991.         ret
  1992. ;------------------------------------------------------------------------------
  1993. iglobal
  1994. align 4
  1995. sys_system_table:
  1996.         dd      sysfn_deactivate        ; 1 = deactivate window
  1997.         dd      sysfn_terminate         ; 2 = terminate thread
  1998.         dd      sysfn_activate          ; 3 = activate window
  1999.         dd      sysfn_getidletime       ; 4 = get idle time
  2000.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  2001.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  2002.         dd      sysfn_getactive         ; 7 = get active window
  2003.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  2004.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  2005.         dd      sysfn_minimize          ; 10 = minimize window
  2006.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  2007.         dd      sysfn_lastkey           ; 12 = get last pressed key
  2008.         dd      sysfn_getversion        ; 13 = get kernel version
  2009.         dd      sysfn_waitretrace       ; 14 = wait retrace
  2010.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  2011.         dd      sysfn_getfreemem        ; 16 = get free memory size
  2012.         dd      sysfn_getallmem         ; 17 = get total memory size
  2013.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  2014.                                         ;                 instead of slot
  2015.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  2016.         dd      sysfn_meminfo           ; 20 = get extended memory info
  2017.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  2018.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  2019.         dd      sysfn_min_windows       ; 23 = minimize all windows
  2020.         dd      sysfn_set_screen_sizes  ; 24 = set screen sizes for Vesa
  2021. sysfn_num = ($ - sys_system_table)/4
  2022. endg
  2023. ;------------------------------------------------------------------------------
  2024. sys_system:
  2025.         dec     ebx
  2026.         cmp     ebx, sysfn_num
  2027.         jae     @f
  2028.         jmp     dword [sys_system_table + ebx*4]
  2029. @@:
  2030.         ret
  2031. ;------------------------------------------------------------------------------
  2032. sysfn_shutdown:          ; 18.9 = system shutdown
  2033.         cmp     ecx, 1
  2034.         jl      exit_for_anyone
  2035.         cmp     ecx, 4
  2036.         jg      exit_for_anyone
  2037.         mov     [BOOT_VARS+0x9030], cl
  2038.  
  2039.         mov     eax, [TASK_COUNT]
  2040.         mov     [SYS_SHUTDOWN], al
  2041.         mov     [shutdown_processes], eax
  2042.         call    wakeup_osloop
  2043.         and     dword [esp+32], 0
  2044.  exit_for_anyone:
  2045.         ret
  2046.   uglobal
  2047.    shutdown_processes:
  2048.                        dd 0x0
  2049.   endg
  2050. ;------------------------------------------------------------------------------
  2051. sysfn_terminate:        ; 18.2 = TERMINATE
  2052.         push    ecx
  2053.         cmp     ecx, 2
  2054.         jb      noprocessterminate
  2055.         mov     edx, [TASK_COUNT]
  2056.         cmp     ecx, edx
  2057.         ja      noprocessterminate
  2058.         mov     eax, [TASK_COUNT]
  2059.         shl     ecx, 5
  2060.         mov     edx, [ecx+CURRENT_TASK+TASKDATA.pid]
  2061.         add     ecx, CURRENT_TASK+TASKDATA.state
  2062.         cmp     byte [ecx], 9
  2063.         jz      noprocessterminate
  2064.         push    ecx edx
  2065.         lea     edx, [(ecx-(CURRENT_TASK and 1FFFFFFFh)-TASKDATA.state)*8+SLOT_BASE]
  2066.         call    request_terminate
  2067.         pop     edx ecx
  2068.         test    eax, eax
  2069.         jz      noprocessterminate
  2070. ;--------------------------------------
  2071. ; terminate all network sockets it used
  2072.         pusha
  2073.         mov     eax, edx
  2074.         call    SOCKET_process_end
  2075.         popa
  2076. ;--------------------------------------
  2077.         cmp     [_display.select_cursor], 0
  2078.         je      .restore_end
  2079. ; restore default cursor before killing
  2080.         pusha
  2081.         mov     ecx, [esp+32]
  2082.         shl     ecx, 8
  2083.         add     ecx, SLOT_BASE
  2084.         mov     eax, [def_cursor]
  2085.         cmp     [ecx+APPDATA.cursor], eax
  2086.         je      @f
  2087.         call    restore_default_cursor_before_killing
  2088. @@:
  2089.         popa
  2090. .restore_end:
  2091. ;--------------------------------------
  2092.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2093.         mov     [ecx], byte 3; clear possible i40's
  2094.         call    wakeup_osloop
  2095.      ;call MEM_Heap_UnLock
  2096.  
  2097.         cmp     edx, [application_table_owner]; clear app table stat
  2098.         jne     noatsc
  2099.         call    unlock_application_table
  2100. noatsc:
  2101. noprocessterminate:
  2102.         add     esp, 4
  2103.         ret
  2104. ;------------------------------------------------------------------------------
  2105. sysfn_terminate2:
  2106. ;lock application_table_status mutex
  2107. .table_status:
  2108.         call    lock_application_table
  2109.         mov     eax, ecx
  2110.         call    pid_to_slot
  2111.         test    eax, eax
  2112.         jz      .not_found
  2113.         mov     ecx, eax
  2114.         cli
  2115.         call    sysfn_terminate
  2116.         call    unlock_application_table
  2117.         sti
  2118.         and     dword [esp+32], 0
  2119.         ret
  2120. .not_found:
  2121.         call    unlock_application_table
  2122.         or      dword [esp+32], -1
  2123.         ret
  2124. ;------------------------------------------------------------------------------
  2125. sysfn_deactivate:         ; 18.1 = DEACTIVATE WINDOW
  2126.         cmp     ecx, 2
  2127.         jb      .nowindowdeactivate
  2128.         cmp     ecx, [TASK_COUNT]
  2129.         ja      .nowindowdeactivate
  2130.  
  2131.         movzx   esi, word [WIN_STACK + ecx*2]
  2132.         cmp     esi, 1
  2133.         je      .nowindowdeactivate ; already deactive
  2134.  
  2135.         mov     edi, ecx
  2136.         shl     edi, 5
  2137.         add     edi, window_data
  2138.         movzx   esi, word [WIN_STACK + ecx * 2]
  2139.         lea     esi, [WIN_POS + esi * 2]
  2140.         call    window._.window_deactivate
  2141.  
  2142.         call    syscall_display_settings._.calculate_whole_screen
  2143.         call    syscall_display_settings._.redraw_whole_screen
  2144. .nowindowdeactivate:
  2145.         ret
  2146. ;------------------------------------------------------------------------------
  2147. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2148.         cmp     ecx, 2
  2149.         jb      .nowindowactivate
  2150.         cmp     ecx, [TASK_COUNT]
  2151.         ja      .nowindowactivate
  2152. ;-------------------------------------
  2153. @@:
  2154. ; If the window is captured and moved by the user,
  2155. ; then you can't change the position in window stack!!!
  2156.         mov     al, [mouse.active_sys_window.action]
  2157.         and     al, WINDOW_MOVE_AND_RESIZE_FLAGS
  2158.         test    al, al
  2159.         jz      @f
  2160.         call    change_task
  2161.         jmp     @b
  2162. @@:
  2163. ;-------------------------------------
  2164.         mov     [window_minimize], 2; restore window if minimized
  2165.         call    wakeup_osloop
  2166.  
  2167.         movzx   esi, word [WIN_STACK + ecx*2]
  2168.         cmp     esi, [TASK_COUNT]
  2169.         je      .nowindowactivate; already active
  2170.  
  2171.         mov     edi, ecx
  2172.         shl     edi, 5
  2173.         add     edi, window_data
  2174.         movzx   esi, word [WIN_STACK + ecx * 2]
  2175.         lea     esi, [WIN_POS + esi * 2]
  2176.         call    waredraw
  2177. .nowindowactivate:
  2178.         ret
  2179. ;------------------------------------------------------------------------------
  2180. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2181.         mov     eax, [CURRENT_TASK+32+TASKDATA.cpu_usage]
  2182.         mov     [esp+32], eax
  2183.         ret
  2184. ;------------------------------------------------------------------------------
  2185. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2186.         mov     eax, dword [cpu_freq]
  2187.         mov     [esp+32], eax
  2188.         ret
  2189. ;------------------------------------------------------------------------------
  2190. get_cpu_freq:
  2191.         mov     eax, dword [cpu_freq]
  2192.         mov     edx, dword [cpu_freq+4]
  2193.         ret
  2194. ;  SAVE ramdisk to /hd/1/menuet.img
  2195. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2196.    include 'blkdev/rdsave.inc'
  2197. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2198. ;------------------------------------------------------------------------------
  2199. align 4
  2200. sysfn_getactive:        ; 18.7 = get active window
  2201.         mov     eax, [TASK_COUNT]
  2202.         movzx   eax, word [WIN_POS + eax*2]
  2203.         mov     [esp+32], eax
  2204.         ret
  2205. ;------------------------------------------------------------------------------
  2206. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2207. ;     cmp  ecx,1
  2208.         dec     ecx
  2209.         jnz     nogetsoundflag
  2210.         movzx   eax, byte [sound_flag]; get sound_flag
  2211.         mov     [esp+32], eax
  2212.         ret
  2213.  nogetsoundflag:
  2214. ;     cmp  ecx,2
  2215.         dec     ecx
  2216.         jnz     nosoundflag
  2217.         xor     byte [sound_flag], 1
  2218.  nosoundflag:
  2219.         ret
  2220. ;------------------------------------------------------------------------------
  2221. sysfn_minimize:         ; 18.10 = minimize window
  2222.         mov     [window_minimize], 1
  2223.         call    wakeup_osloop
  2224.         ret
  2225. ;------------------------------------------------------------------------------
  2226. align 4
  2227. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2228.         dec     ecx
  2229.         jnz     .exit
  2230. .small_table:
  2231.         mov     edi, edx
  2232.         mov     esi, DRIVE_DATA
  2233.         mov     ecx, DRIVE_DATA_SIZE ;10
  2234.         cld
  2235.         rep movsb
  2236. .exit:
  2237.         ret
  2238. ;------------------------------------------------------------------------------
  2239. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2240.         and     dword [esp+32], 0
  2241.         ret
  2242. ;------------------------------------------------------------------------------
  2243. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2244.         mov     edi, ecx
  2245.         mov     esi, version_inf
  2246.         mov     ecx, version_end-version_inf
  2247.         rep movsb
  2248.         ret
  2249. ;------------------------------------------------------------------------------
  2250. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2251.      ;wait retrace functions
  2252.  sys_wait_retrace:
  2253.         mov     edx, 0x3da
  2254.  WaitRetrace_loop:
  2255.         in      al, dx
  2256.         test    al, 1000b
  2257.         jz      WaitRetrace_loop
  2258.         and     [esp+32], dword 0
  2259.         ret
  2260. ;------------------------------------------------------------------------------
  2261. align 4
  2262. sysfn_centermouse:      ; 18.15 = mouse centered
  2263. ; removed here by <Lrz>
  2264. ;     call  mouse_centered
  2265. ;* mouse centered - start code- Mario79
  2266. ;mouse_centered:
  2267. ;        push  eax
  2268.         mov     eax, [Screen_Max_X]
  2269.         shr     eax, 1
  2270.         mov     [MOUSE_X], ax
  2271.         mov     eax, [Screen_Max_Y]
  2272.         shr     eax, 1
  2273.         mov     [MOUSE_Y], ax
  2274.         call    wakeup_osloop
  2275. ;        ret
  2276. ;* mouse centered - end code- Mario79
  2277.         xor     eax, eax
  2278.         and     [esp+32], eax
  2279. ;        pop   eax
  2280.         ret
  2281. ;------------------------------------------------------------------------------
  2282. align 4
  2283. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2284.         test    ecx, ecx; get mouse speed factor
  2285.         jnz     .set_mouse_acceleration
  2286.         xor     eax, eax
  2287.         mov     ax, [mouse_speed_factor]
  2288.         mov     [esp+32], eax
  2289.         ret
  2290.  .set_mouse_acceleration:
  2291. ;     cmp  ecx,1  ; set mouse speed factor
  2292.         dec     ecx
  2293.         jnz     .get_mouse_delay
  2294.         mov     [mouse_speed_factor], dx
  2295.         ret
  2296.  .get_mouse_delay:
  2297. ;     cmp  ecx,2  ; get mouse delay
  2298.         dec     ecx
  2299.         jnz     .set_mouse_delay
  2300.         mov     eax, [mouse_delay]
  2301.         mov     [esp+32], eax
  2302.         ret
  2303.  .set_mouse_delay:
  2304. ;     cmp  ecx,3  ; set mouse delay
  2305.         dec     ecx
  2306.         jnz     .set_pointer_position
  2307.         mov     [mouse_delay], edx
  2308.         ret
  2309.  .set_pointer_position:
  2310. ;     cmp  ecx,4  ; set mouse pointer position
  2311.         dec     ecx
  2312.         jnz     .set_mouse_button
  2313.         cmp     dx, word[Screen_Max_Y]
  2314.         ja      .end
  2315.         rol     edx, 16
  2316.         cmp     dx, word[Screen_Max_X]
  2317.         ja      .end
  2318.         mov     [MOUSE_X], edx
  2319.         mov     [mouse_active], 1
  2320.         call    wakeup_osloop
  2321.         ret
  2322.  .set_mouse_button:
  2323. ;     cmp   ecx,5  ; set mouse button features
  2324.         dec     ecx
  2325.         jnz     .end
  2326.         mov     [BTN_DOWN], dl
  2327.         mov     [mouse_active], 1
  2328.         call    wakeup_osloop
  2329.  .end:
  2330.         ret
  2331. ;------------------------------------------------------------------------------
  2332. sysfn_getfreemem:
  2333.         mov     eax, [pg_data.pages_free]
  2334.         shl     eax, 2
  2335.         mov     [esp+32], eax
  2336.         ret
  2337. ;------------------------------------------------------------------------------
  2338. sysfn_getallmem:
  2339.         mov     eax, [MEM_AMOUNT]
  2340.         shr     eax, 10
  2341.         mov     [esp+32], eax
  2342.         ret
  2343. ;------------------------------------------------------------------------------
  2344. sysfn_pid_to_slot:
  2345.         mov     eax, ecx
  2346.         call    pid_to_slot
  2347.         mov     [esp+32], eax
  2348.         ret
  2349. ;------------------------------------------------------------------------------
  2350. sysfn_min_rest_window:
  2351.         pushad
  2352.         mov     eax, edx ; ebx - operating
  2353.         shr     ecx, 1
  2354.         jnc     @f
  2355.         call    pid_to_slot
  2356. @@:
  2357.         or      eax, eax ; eax - number of slot
  2358.         jz      .error
  2359.         cmp     eax, 255    ; varify maximal slot number
  2360.         ja      .error
  2361.         movzx   eax, word [WIN_STACK + eax*2]
  2362.         shr     ecx, 1
  2363.         jc      .restore
  2364.  ; .minimize:
  2365.         call    minimize_window
  2366.         jmp     .exit
  2367. .restore:
  2368.         call    restore_minimized_window
  2369. .exit:
  2370.         popad
  2371.         xor     eax, eax
  2372.         mov     [esp+32], eax
  2373.         ret
  2374. .error:
  2375.         popad
  2376.         xor     eax, eax
  2377.         dec     eax
  2378.         mov     [esp+32], eax
  2379.         ret
  2380. ;------------------------------------------------------------------------------
  2381. sysfn_min_windows:
  2382.         call    minimize_all_window
  2383.         mov     [esp+32], eax
  2384.         call    change_task
  2385.         ret
  2386. ;------------------------------------------------------------------------------
  2387. sysfn_set_screen_sizes:
  2388.         cmp     [SCR_MODE], word 0x13
  2389.         jbe     .exit
  2390.  
  2391.         cmp     [_display.select_cursor], select_cursor
  2392.         jne     .exit
  2393.  
  2394.         cmp     ecx, [display_width_standard]
  2395.         ja      .exit
  2396.  
  2397.         cmp     edx, [display_height_standard]
  2398.         ja      .exit
  2399.  
  2400.         pushfd
  2401.         cli
  2402.         mov     eax, ecx
  2403.         mov     ecx, [_display.pitch]
  2404.         mov     [_display.width], eax
  2405.         dec     eax
  2406.         mov     [_display.height], edx
  2407.         dec     edx
  2408. ; eax - new Screen_Max_X
  2409. ; edx - new Screen_Max_Y
  2410.         mov     [do_not_touch_winmap], 1
  2411.         call    set_screen
  2412.         mov     [do_not_touch_winmap], 0
  2413.         popfd
  2414.         call    change_task
  2415. .exit:
  2416.         ret
  2417. ;------------------------------------------------------------------------------
  2418. uglobal
  2419. screen_workarea RECT
  2420. display_width_standard dd 0
  2421. display_height_standard dd 0
  2422. do_not_touch_winmap db 0
  2423. window_minimize db 0
  2424. sound_flag      db 0
  2425.  
  2426. endg
  2427.  
  2428. UID_NONE=0
  2429. UID_MENUETOS=1   ;official
  2430. UID_KOLIBRI=2    ;russian
  2431.  
  2432. iglobal
  2433. version_inf:
  2434.         db 0,7,7,0  ; version 0.7.7.0
  2435.         db 0
  2436. .rev    dd __REV__
  2437. version_end:
  2438. endg
  2439. ;------------------------------------------------------------------------------
  2440. align 4
  2441. sys_cachetodiskette:
  2442.         cmp     ebx, 1
  2443.         jb      .no_floppy_save
  2444.         cmp     ebx, 2
  2445.         ja      .no_floppy_save
  2446.         call    save_image
  2447.         mov     [esp + 32], eax
  2448.         ret
  2449. .no_floppy_save:
  2450.         mov     [esp + 32], dword 1
  2451.         ret
  2452. ;------------------------------------------------------------------------------
  2453. uglobal
  2454. ;  bgrchanged  dd  0x0
  2455. align 4
  2456. bgrlockpid dd 0
  2457. bgrlock db 0
  2458. endg
  2459. ;------------------------------------------------------------------------------
  2460. align 4
  2461. sys_background:
  2462.         cmp     ebx, 1                     ; BACKGROUND SIZE
  2463.         jnz     nosb1
  2464.         test    ecx, ecx
  2465.         jz      sbgrr
  2466.  
  2467.         test    edx, edx
  2468.         jz      sbgrr
  2469. ;--------------------------------------
  2470. align 4
  2471. @@:
  2472. ;;Maxis use atomic bts for mutexes  4.4.2009
  2473.         bts     dword [bgrlock], 0
  2474.         jnc     @f
  2475.         call    change_task
  2476.         jmp     @b
  2477. ;--------------------------------------
  2478. align 4
  2479. @@:
  2480.         mov     [BgrDataWidth], ecx
  2481.         mov     [BgrDataHeight], edx
  2482. ;    mov   [bgrchanged],1
  2483.  
  2484.         pushad
  2485. ; return memory for old background
  2486.         mov     eax, [img_background]
  2487.         cmp     eax, static_background_data
  2488.         jz      @f
  2489.         stdcall kernel_free, eax
  2490. ;--------------------------------------
  2491. align 4
  2492. @@:
  2493. ; calculate RAW size
  2494.         xor     eax, eax
  2495.         inc     eax
  2496.         cmp     [BgrDataWidth], eax
  2497.         jae     @f
  2498.         mov     [BgrDataWidth], eax
  2499. ;--------------------------------------
  2500. align 4
  2501. @@:
  2502.         cmp     [BgrDataHeight], eax
  2503.         jae     @f
  2504.         mov     [BgrDataHeight], eax
  2505. ;--------------------------------------
  2506. align 4
  2507. @@:
  2508.         mov     eax, [BgrDataWidth]
  2509.         imul    eax, [BgrDataHeight]
  2510.         lea     eax, [eax*3]
  2511. ; it is reserved with aligned to the boundary of 4 KB pages,
  2512. ; otherwise there may be exceptions a page fault for vesa20_drawbackground_tiled
  2513. ; because the 32 bit read is used for  high performance: "mov eax,[esi]"
  2514.         shr     eax, 12
  2515.         inc     eax
  2516.         shl     eax, 12
  2517.         mov     [mem_BACKGROUND], eax
  2518. ; get memory for new background
  2519.         stdcall kernel_alloc, eax
  2520.         test    eax, eax
  2521.         jz      .memfailed
  2522.         mov     [img_background], eax
  2523.         jmp     .exit
  2524. ;--------------------------------------
  2525. align 4
  2526. .memfailed:
  2527. ; revert to static monotone data
  2528.         mov     [img_background], static_background_data
  2529.         xor     eax, eax
  2530.         inc     eax
  2531.         mov     [BgrDataWidth], eax
  2532.         mov     [BgrDataHeight], eax
  2533.         mov     [mem_BACKGROUND], 4
  2534. ;--------------------------------------
  2535. align 4
  2536. .exit:
  2537.         popad
  2538.         mov     [bgrlock], 0
  2539. ;--------------------------------------
  2540. align 4
  2541. sbgrr:
  2542.         ret
  2543. ;------------------------------------------------------------------------------
  2544. align 4
  2545. nosb1:
  2546.         cmp     ebx, 2                     ; SET PIXEL
  2547.         jnz     nosb2
  2548.  
  2549.         mov     eax, [img_background]
  2550.         test    ecx, ecx
  2551.         jz      @f
  2552.         cmp     eax, static_background_data
  2553.         jz      .ret
  2554. ;--------------------------------------
  2555. align 4
  2556. @@:
  2557.         mov     ebx, [mem_BACKGROUND]
  2558.         add     ebx, 4095
  2559.         and     ebx, -4096
  2560.         sub     ebx, 4
  2561.         cmp     ecx, ebx
  2562.         ja      .ret
  2563.  
  2564.         mov     ebx, [eax+ecx]
  2565.         and     ebx, 0xFF000000;255*256*256*256
  2566.         and     edx, 0x00FFFFFF;255*256*256+255*256+255
  2567.         add     edx, ebx
  2568.         mov     [eax+ecx], edx
  2569. ;--------------------------------------
  2570. align 4
  2571. .ret:
  2572.         ret
  2573. ;------------------------------------------------------------------------------
  2574. align 4
  2575. nosb2:
  2576.         cmp     ebx, 3                     ; DRAW BACKGROUND
  2577.         jnz     nosb3
  2578. ;--------------------------------------
  2579. align 4
  2580. draw_background_temp:
  2581.         mov     [background_defined], 1
  2582.         call    force_redraw_background
  2583. ;--------------------------------------
  2584. align 4
  2585. nosb31:
  2586.         ret
  2587. ;------------------------------------------------------------------------------
  2588. align 4
  2589. nosb3:
  2590.         cmp     ebx, 4                     ; TILED / STRETCHED
  2591.         jnz     nosb4
  2592.         cmp     ecx, [BgrDrawMode]
  2593.         je      nosb41
  2594.         mov     [BgrDrawMode], ecx
  2595. ;--------------------------------------
  2596. align 4
  2597. nosb41:
  2598.         ret
  2599. ;------------------------------------------------------------------------------
  2600. align 4
  2601. nosb4:
  2602.         cmp     ebx, 5                     ; BLOCK MOVE TO BGR
  2603.         jnz     nosb5
  2604.         cmp     [img_background], static_background_data
  2605.         jnz     @f
  2606.         test    edx, edx
  2607.         jnz     .fin
  2608.         cmp     esi, 4
  2609.         ja      .fin
  2610. ;--------------------------------------
  2611. align 4
  2612. @@:
  2613.   ; bughere
  2614.         mov     eax, ecx
  2615.         mov     ebx, edx
  2616.         add     ebx, [img_background];IMG_BACKGROUND
  2617.         mov     ecx, esi
  2618.         call    memmove
  2619. ;--------------------------------------
  2620. align 4
  2621. .fin:
  2622.         ret
  2623. ;------------------------------------------------------------------------------
  2624. align 4
  2625. nosb5:
  2626.         cmp     ebx, 6
  2627.         jnz     nosb6
  2628. ;--------------------------------------
  2629. align 4
  2630. ;;Maxis use atomic bts for mutex 4.4.2009
  2631. @@:
  2632.         bts     dword [bgrlock], 0
  2633.         jnc     @f
  2634.         call    change_task
  2635.         jmp     @b
  2636. ;--------------------------------------
  2637. align 4
  2638. @@:
  2639.         mov     eax, [CURRENT_TASK]
  2640.         mov     [bgrlockpid], eax
  2641.         cmp     [img_background], static_background_data
  2642.         jz      .nomem
  2643.         stdcall user_alloc, [mem_BACKGROUND]
  2644.         mov     [esp+32], eax
  2645.         test    eax, eax
  2646.         jz      .nomem
  2647.         mov     ebx, eax
  2648.         shr     ebx, 12
  2649.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2650.         mov     esi, [img_background]
  2651.         shr     esi, 12
  2652.         mov     ecx, [mem_BACKGROUND]
  2653.         add     ecx, 0xFFF
  2654.         shr     ecx, 12
  2655. ;--------------------------------------
  2656. align 4
  2657. .z:
  2658.         mov     eax, [page_tabs+ebx*4]
  2659.         test    al, 1
  2660.         jz      @f
  2661.         call    free_page
  2662. ;--------------------------------------
  2663. align 4
  2664. @@:
  2665.         mov     eax, [page_tabs+esi*4]
  2666.         or      al, PG_UW
  2667.         mov     [page_tabs+ebx*4], eax
  2668.         mov     eax, ebx
  2669.         shl     eax, 12
  2670.         invlpg  [eax]
  2671.         inc     ebx
  2672.         inc     esi
  2673.         loop    .z
  2674.         ret
  2675. ;--------------------------------------
  2676. align 4
  2677. .nomem:
  2678.         and     [bgrlockpid], 0
  2679.         mov     [bgrlock], 0
  2680. ;------------------------------------------------------------------------------
  2681. align 4
  2682. nosb6:
  2683.         cmp     ebx, 7
  2684.         jnz     nosb7
  2685.         cmp     [bgrlock], 0
  2686.         jz      .err
  2687.         mov     eax, [CURRENT_TASK]
  2688.         cmp     [bgrlockpid], eax
  2689.         jnz     .err
  2690.         mov     eax, ecx
  2691.         mov     ebx, ecx
  2692.         shr     eax, 12
  2693.         mov     ecx, [page_tabs+(eax-1)*4]
  2694.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2695.         jz      .err
  2696.         jnp     .err
  2697.         push    eax
  2698.         shr     ecx, 12
  2699.         dec     ecx
  2700. ;--------------------------------------
  2701. align 4
  2702. @@:
  2703.         and     dword [page_tabs+eax*4], 0
  2704.         mov     edx, eax
  2705.         shl     edx, 12
  2706.         push    eax
  2707.         invlpg  [edx]
  2708.         pop     eax
  2709.         inc     eax
  2710.         loop    @b
  2711.         pop     eax
  2712.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2713.         stdcall user_free, ebx
  2714.         mov     [esp+32], eax
  2715.         and     [bgrlockpid], 0
  2716.         mov     [bgrlock], 0
  2717.         ret
  2718. ;--------------------------------------
  2719. align 4
  2720. .err:
  2721.         and     dword [esp+32], 0
  2722.         ret
  2723. ;------------------------------------------------------------------------------
  2724. align 4
  2725. nosb7:
  2726.         cmp     ebx, 8
  2727.         jnz     nosb8
  2728.  
  2729.         mov     ecx, [current_slot]
  2730.         xor     eax, eax
  2731.         xchg    eax, [ecx+APPDATA.draw_bgr_x]
  2732.         mov     [esp + 32], eax ; eax = [left]*65536 + [right]
  2733.         xor     eax, eax
  2734.         xchg    eax, [ecx+APPDATA.draw_bgr_y]
  2735.         mov     [esp + 20], eax ; ebx = [top]*65536 + [bottom]
  2736.         ret
  2737. ;------------------------------------------------------------------------------
  2738. align 4
  2739. nosb8:
  2740.         cmp     ebx, 9
  2741.         jnz     nosb9
  2742. ; ecx = [left]*65536 + [right]
  2743. ; edx = [top]*65536 + [bottom]
  2744.         mov     eax, [Screen_Max_X]
  2745.         mov     ebx, [Screen_Max_Y]
  2746. ; check [right]
  2747.         cmp     cx, ax
  2748.         ja      .exit
  2749. ; check [left]
  2750.         ror     ecx, 16
  2751.         cmp     cx, ax
  2752.         ja      .exit
  2753. ; check [bottom]
  2754.         cmp     dx, bx
  2755.         ja      .exit
  2756. ; check [top]
  2757.         ror     edx, 16
  2758.         cmp     dx, bx
  2759.         ja      .exit
  2760.  
  2761.         movzx   eax, cx  ; [left]
  2762.         movzx   ebx, dx  ; [top]
  2763.  
  2764.         shr     ecx, 16 ; [right]
  2765.         shr     edx, 16 ; [bottom]
  2766.  
  2767.         mov     [background_defined], 1
  2768.  
  2769.         mov     [draw_data+32 + RECT.left], eax
  2770.         mov     [draw_data+32 + RECT.top], ebx
  2771.  
  2772.         mov     [draw_data+32 + RECT.right], ecx
  2773.         mov     [draw_data+32 + RECT.bottom], edx
  2774.  
  2775.         inc     byte[REDRAW_BACKGROUND]
  2776.         call    wakeup_osloop
  2777. ;--------------------------------------
  2778. align 4
  2779. .exit:
  2780.         ret
  2781. ;------------------------------------------------------------------------------
  2782. align 4
  2783. nosb9:
  2784.         ret
  2785. ;------------------------------------------------------------------------------
  2786. align 4
  2787. uglobal
  2788.   BG_Rect_X_left_right  dd   0x0
  2789.   BG_Rect_Y_top_bottom  dd   0x0
  2790. endg
  2791. ;------------------------------------------------------------------------------
  2792. align 4
  2793. force_redraw_background:
  2794.         and     [draw_data+32 + RECT.left], 0
  2795.         and     [draw_data+32 + RECT.top], 0
  2796.         push    eax ebx
  2797.         mov     eax, [Screen_Max_X]
  2798.         mov     ebx, [Screen_Max_Y]
  2799.         mov     [draw_data+32 + RECT.right], eax
  2800.         mov     [draw_data+32 + RECT.bottom], ebx
  2801.         pop     ebx eax
  2802.         inc     byte[REDRAW_BACKGROUND]
  2803.         call    wakeup_osloop
  2804.         ret
  2805. ;------------------------------------------------------------------------------
  2806. align 4
  2807. sys_getbackground:
  2808. ;    cmp   eax,1                                  ; SIZE
  2809.         dec     ebx
  2810.         jnz     nogb1
  2811.         mov     eax, [BgrDataWidth]
  2812.         shl     eax, 16
  2813.         mov     ax, word [BgrDataHeight]
  2814.         mov     [esp+32], eax
  2815.         ret
  2816. ;------------------------------------------------------------------------------
  2817. align 4
  2818. nogb1:
  2819. ;    cmp   eax,2                                  ; PIXEL
  2820.         dec     ebx
  2821.         jnz     nogb2
  2822.  
  2823.         mov     eax, [img_background]
  2824.         test    ecx, ecx
  2825.         jz      @f
  2826.         cmp     eax, static_background_data
  2827.         jz      .ret
  2828. ;--------------------------------------
  2829. align 4
  2830. @@:
  2831.         mov     ebx, [mem_BACKGROUND]
  2832.         add     ebx, 4095
  2833.         and     ebx, -4096
  2834.         sub     ebx, 4
  2835.         cmp     ecx, ebx
  2836.         ja      .ret
  2837.  
  2838.         mov     eax, [ecx+eax]
  2839.  
  2840.         and     eax, 0xFFFFFF
  2841.         mov     [esp+32], eax
  2842. ;--------------------------------------
  2843. align 4
  2844. .ret:
  2845.         ret
  2846. ;------------------------------------------------------------------------------
  2847. align 4
  2848. nogb2:
  2849.  
  2850. ;    cmp   eax,4                                  ; TILED / STRETCHED
  2851.         dec     ebx
  2852.         dec     ebx
  2853.         jnz     nogb4
  2854.         mov     eax, [BgrDrawMode]
  2855. ;--------------------------------------
  2856. align 4
  2857. nogb4:
  2858.         mov     [esp+32], eax
  2859.         ret
  2860. ;------------------------------------------------------------------------------
  2861. align 4
  2862. sys_getkey:
  2863.         mov     [esp + 32], dword 1
  2864.         ; test main buffer
  2865.         mov     ebx, [CURRENT_TASK]                          ; TOP OF WINDOW STACK
  2866.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2867.         mov     edx, [TASK_COUNT]
  2868.         cmp     ecx, edx
  2869.         jne     .finish
  2870.         cmp     [KEY_COUNT], byte 0
  2871.         je      .finish
  2872.         movzx   ax, byte [KEY_BUFF + 120 + 2]
  2873.         shl     eax, 8
  2874.         mov     al, byte [KEY_BUFF]
  2875.         shl     eax, 8
  2876.         push    eax
  2877.         dec     byte [KEY_COUNT]
  2878.         and     byte [KEY_COUNT], 127
  2879.         movzx   ecx, byte [KEY_C