Subversion Repositories Kolibri OS

Rev

Rev 2167 | Rev 2231 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | Download | RSS feed

  1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  2. ;;
  3. ;; Copyright (C) KolibriOS team 2004-2011. All rights reserved.
  4. ;; PROGRAMMING:
  5. ;; Ivan Poddubny
  6. ;; Marat Zakiyanov (Mario79)
  7. ;; VaStaNi
  8. ;; Trans
  9. ;; Mihail Semenyako (mike.dld)
  10. ;; Sergey Kuzmin (Wildwest)
  11. ;; Andrey Halyavin (halyavin)
  12. ;; Mihail Lisovin (Mihasik)
  13. ;; Andrey Ignatiev (andrew_programmer)
  14. ;; NoName
  15. ;; Evgeny Grechnikov (Diamond)
  16. ;; Iliya Mihailov (Ghost)
  17. ;; Sergey Semyonov (Serge)
  18. ;; Johnny_B
  19. ;; SPraid (simba)
  20. ;; Hidnplayr
  21. ;; Alexey Teplov (<Lrz>)
  22. ;; Rus
  23. ;; Nable
  24. ;; shurf
  25. ;; Alver
  26. ;; Maxis
  27. ;; Galkov
  28. ;; CleverMouse
  29. ;; tsdima
  30. ;; turbanoff
  31. ;; Asper
  32. ;; art_zh
  33. ;;
  34. ;; Data in this file was originally part of MenuetOS project which is
  35. ;; distributed under the terms of GNU GPL. It is modified and redistributed as
  36. ;; part of KolibriOS project under the terms of GNU GPL.
  37. ;;
  38. ;; Copyright (C) MenuetOS 2000-2004 Ville Mikael Turjanmaa
  39. ;; PROGRAMMING:
  40. ;;
  41. ;; Ville Mikael Turjanmaa, villemt@itu.jyu.fi
  42. ;; - main os coding/design
  43. ;; Jan-Michael Brummer, BUZZ2@gmx.de
  44. ;; Felix Kaiser, info@felix-kaiser.de
  45. ;; Paolo Minazzi, paolo.minazzi@inwind.it
  46. ;; quickcode@mail.ru
  47. ;; Alexey, kgaz@crosswinds.net
  48. ;; Juan M. Caravaca, bitrider@wanadoo.es
  49. ;; kristol@nic.fi
  50. ;; Mike Hibbett, mikeh@oceanfree.net
  51. ;; Lasse Kuusijarvi, kuusijar@lut.fi
  52. ;; Jarek Pelczar, jarekp3@wp.pl
  53. ;;
  54. ;; KolibriOS is distributed in the hope that it will be useful, but WITHOUT ANY
  55. ;; WARRANTY. No author or distributor accepts responsibility to anyone for the
  56. ;; consequences of using it or for whether it serves any particular purpose or
  57. ;; works at all, unless he says so in writing. Refer to the GNU General Public
  58. ;; License (the "GPL") for full details.
  59. ;
  60. ;; Everyone is granted permission to copy, modify and redistribute KolibriOS,
  61. ;; but only under the conditions described in the GPL. A copy of this license
  62. ;; is supposed to have been given to you along with KolibriOS so you can know
  63. ;; your rights and responsibilities. It should be in a file named COPYING.
  64. ;; Among other things, the copyright notice and this notice must be preserved
  65. ;; on all copies.
  66. ;;
  67. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  68.  
  69. include 'macros.inc'
  70.  
  71. $Revision: 2218 $
  72.  
  73.  
  74. USE_COM_IRQ     equ 1      ; make irq 3 and irq 4 available for PCI devices
  75.  
  76. ; Enabling the next line will enable serial output console
  77. ;debug_com_base  equ 0x3f8  ; 0x3f8 is com1, 0x2f8 is com2, 0x3e8 is com3, 0x2e8 is com4, no irq's are used
  78.  
  79. include "proc32.inc"
  80. include "kglobals.inc"
  81. include "lang.inc"
  82.  
  83. include "const.inc"
  84. max_processes   equ   255
  85. tss_step         equ   (128+8192) ; tss & i/o - 65535 ports, * 256=557056*4
  86.  
  87.  
  88. os_stack       equ  (os_data_l-gdts)    ; GDTs
  89. os_code       equ  (os_code_l-gdts)
  90. graph_data     equ  (3+graph_data_l-gdts)
  91. tss0           equ  (tss0_l-gdts)
  92. app_code       equ  (3+app_code_l-gdts)
  93. app_data       equ  (3+app_data_l-gdts)
  94. app_tls       equ  (3+tls_data_l-gdts)
  95. pci_code_sel   equ  (pci_code_32-gdts)
  96. pci_data_sel   equ  (pci_data_32-gdts)
  97.  
  98.  
  99. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  100. ;;
  101. ;;   Included files:
  102. ;;
  103. ;;   Kernel16.inc
  104. ;;    - Booteng.inc   English text for bootup
  105. ;;    - Bootcode.inc  Hardware setup
  106. ;;    - Pci16.inc     PCI functions
  107. ;;
  108. ;;   Kernel32.inc
  109. ;;    - Sys32.inc     Process management
  110. ;;    - Shutdown.inc  Shutdown and restart
  111. ;;    - Fat32.inc     Read / write hd
  112. ;;    - Vesa12.inc    Vesa 1.2 driver
  113. ;;    - Vesa20.inc    Vesa 2.0 driver
  114. ;;    - Vga.inc       VGA driver
  115. ;;    - Stack.inc     Network interface
  116. ;;    - Mouse.inc     Mouse pointer
  117. ;;    - Scincode.inc  Window skinning
  118. ;;    - Pci32.inc     PCI functions
  119. ;;
  120. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  121.  
  122.  
  123. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  124. ;;                                                                      ;;
  125. ;;                  16 BIT ENTRY FROM BOOTSECTOR                        ;;
  126. ;;                                                                      ;;
  127. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  128.  
  129. use16
  130.                   org   0x0
  131.                   jmp   start_of_code
  132.  
  133. version db    'Kolibri OS  version 0.7.7.0+     ',13,10,13,10,0
  134.  
  135. include "boot/bootstr.inc"     ; language-independent boot messages
  136. include "boot/preboot.inc"
  137.  
  138. if lang eq en
  139. include "boot/booteng.inc"     ; english system boot messages
  140. else if lang eq ru
  141. include "boot/bootru.inc"      ; russian system boot messages
  142. include "boot/ru.inc"          ; Russian font
  143. else if lang eq et
  144. include "boot/bootet.inc"      ; estonian system boot messages
  145. include "boot/et.inc"          ; Estonian font
  146. else
  147. include "boot/bootge.inc"      ; german system boot messages
  148. end if
  149.  
  150. include "boot/bootcode.inc"    ; 16 bit system boot code
  151. include "bus/pci/pci16.inc"
  152. include "detect/biosdisk.inc"
  153.  
  154. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  155. ;;                                                                      ;;
  156. ;;                  SWITCH TO 32 BIT PROTECTED MODE                     ;;
  157. ;;                                                                      ;;
  158. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  159.  
  160.  
  161. ; CR0 Flags - Protected mode and Paging
  162.  
  163.         mov ecx, CR0_PE
  164.  
  165. ; Enabling 32 bit protected mode
  166.  
  167.         sidt    [cs:old_ints_h]
  168.  
  169.         cli                             ; disable all irqs
  170.         cld
  171.         mov     al,255                  ; mask all irqs
  172.         out     0xa1,al
  173.         out     0x21,al
  174.    l.5: in      al, 0x64                ; Enable A20
  175.         test    al, 2
  176.         jnz     l.5
  177.         mov     al, 0xD1
  178.         out     0x64, al
  179.    l.6: in      al, 0x64
  180.         test    al, 2
  181.         jnz     l.6
  182.         mov     al, 0xDF
  183.         out     0x60, al
  184.    l.7: in      al, 0x64
  185.         test    al, 2
  186.         jnz     l.7
  187.         mov     al, 0xFF
  188.         out     0x64, al
  189.  
  190.         lgdt    [cs:tmp_gdt]            ; Load GDT
  191.         mov     eax, cr0                ; protected mode
  192.         or      eax, ecx
  193.         and     eax, 10011111b *65536*256 + 0xffffff ; caching enabled
  194.         mov     cr0, eax
  195.         jmp     pword os_code:B32       ; jmp to enable 32 bit mode
  196.  
  197. align 8
  198. tmp_gdt:
  199.  
  200.         dw     23
  201.         dd     tmp_gdt+0x10000
  202.         dw     0
  203.  
  204.         dw     0xffff
  205.         dw     0x0000
  206.         db     0x00
  207.         dw     11011111b *256 +10011010b
  208.         db     0x00
  209.  
  210.         dw     0xffff
  211.         dw     0x0000
  212.         db     0x00
  213.         dw     11011111b *256 +10010010b
  214.         db     0x00
  215.  
  216. include "data16.inc"
  217.  
  218. use32
  219. org $+0x10000
  220.  
  221. align 4
  222. B32:
  223.            mov   ax,os_stack       ; Selector for os
  224.            mov   ds,ax
  225.            mov   es,ax
  226.            mov   fs,ax
  227.            mov   gs,ax
  228.            mov   ss,ax
  229.            mov   esp,0x5ec00       ; Set stack
  230.  
  231. ; CLEAR 0x280000 - HEAP_BASE
  232.  
  233.            xor   eax,eax
  234.            mov   edi,CLEAN_ZONE
  235.            mov   ecx,(HEAP_BASE-OS_BASE-CLEAN_ZONE) / 4
  236.            cld
  237.            rep   stosd
  238.  
  239.            mov   edi,0x40000
  240.            mov   ecx,(0x90000-0x40000)/4
  241.            rep   stosd
  242.  
  243. ; CLEAR KERNEL UNDEFINED GLOBALS
  244.            mov   edi, endofcode-OS_BASE
  245.            mov   ecx, (uglobals_size/4)+4
  246.            rep   stosd
  247.  
  248. ; SAVE & CLEAR 0-0xffff
  249.  
  250.            xor   esi, esi
  251.            mov   edi,(BOOT_VAR-OS_BASE)
  252.            mov   ecx,0x10000 / 4
  253.            rep   movsd
  254.            mov   edi,0x1000
  255.            mov   ecx,0xf000 / 4
  256.            rep   stosd
  257.  
  258.            call test_cpu
  259.            bts [cpu_caps-OS_BASE], CAPS_TSC     ;force use rdtsc
  260.  
  261.            call check_acpi
  262.            call init_BIOS32
  263. ; MEMORY MODEL
  264.            call mem_test
  265.            call init_mem
  266.            call init_page_map
  267.  
  268. ; ENABLE PAGING
  269.  
  270.            mov eax, sys_pgdir-OS_BASE
  271.            mov cr3, eax
  272.  
  273.            mov eax,cr0
  274.            or eax,CR0_PG+CR0_WP
  275.            mov cr0,eax
  276.  
  277.            lgdt [gdts]
  278.            jmp pword os_code:high_code
  279.  
  280. align 4
  281. bios32_entry    dd ?
  282. tmp_page_tabs   dd ?
  283.  
  284. use16
  285. org $-0x10000
  286. include "boot/shutdown.inc" ; shutdown or restart
  287. org $+0x10000
  288. use32
  289.  
  290. __DEBUG__ fix 1
  291. __DEBUG_LEVEL__ fix 1
  292. include 'init.inc'
  293.  
  294. org OS_BASE+$
  295.  
  296. align 4
  297. high_code:
  298.            mov ax, os_stack
  299.            mov bx, app_data
  300.            mov cx, app_tls
  301.            mov ss, ax
  302.            add esp, OS_BASE
  303.  
  304.            mov ds, bx
  305.            mov es, bx
  306.            mov fs, cx
  307.            mov gs, bx
  308.  
  309.            bt [cpu_caps], CAPS_PGE
  310.            jnc @F
  311.  
  312.            or dword [sys_pgdir+(OS_BASE shr 20)], PG_GLOBAL
  313.  
  314.            mov ebx, cr4
  315.            or ebx, CR4_PGE
  316.            mov cr4, ebx
  317. @@:
  318.            xor eax, eax
  319.            mov dword [sys_pgdir], eax
  320.            mov dword [sys_pgdir+4], eax
  321.  
  322.            mov eax, cr3
  323.            mov cr3, eax           ; flush TLB
  324.  
  325.            mov ecx, pg_data.mutex
  326.            call mutex_init
  327.  
  328.            mov ecx, disk_list_mutex
  329.            call mutex_init
  330.  
  331. ; SAVE REAL MODE VARIABLES
  332.         mov     ax, [BOOT_VAR + 0x9031]
  333.         mov     [IDEContrRegsBaseAddr], ax
  334. ; --------------- APM ---------------------
  335.  
  336. ; init selectors
  337.     mov ebx,[BOOT_VAR+0x9040]                   ; offset of APM entry point
  338.     movzx eax,word [BOOT_VAR+0x9050]    ; real-mode segment base address of
  339.                                                                                 ; protected-mode 32-bit code segment
  340.     movzx ecx,word [BOOT_VAR+0x9052]    ; real-mode segment base address of
  341.                                                                                 ; protected-mode 16-bit code segment
  342.     movzx edx,word [BOOT_VAR+0x9054]    ; real-mode segment base address of
  343.                                                                                 ; protected-mode 16-bit data segment
  344.  
  345.     shl    eax, 4
  346.     mov    [dword apm_code_32 + 2], ax
  347.     shr    eax, 16
  348.     mov    [dword apm_code_32 + 4], al
  349.  
  350.     shl    ecx, 4
  351.     mov    [dword apm_code_16 + 2], cx
  352.     shr    ecx, 16
  353.     mov    [dword apm_code_16 + 4], cl
  354.  
  355.     shl    edx, 4
  356.     mov    [dword apm_data_16 + 2], dx
  357.     shr    edx, 16
  358.     mov    [dword apm_data_16 + 4], dl
  359.  
  360.     mov    dword[apm_entry], ebx
  361.     mov    word [apm_entry + 4], apm_code_32 - gdts
  362.  
  363.     mov    eax, [BOOT_VAR + 0x9044]    ; version & flags
  364.     mov    [apm_vf], eax
  365. ; -----------------------------------------
  366. ;        movzx eax,byte [BOOT_VAR+0x9010]       ; mouse port
  367. ;        mov   [0xF604],byte 1  ;al
  368.                 mov     al, [BOOT_VAR+0x901F]           ; DMA access
  369.         mov     [allow_dma_access], al
  370.         movzx eax, byte [BOOT_VAR+0x9000]        ; bpp
  371.         mov [ScreenBPP],al
  372.  
  373.         mov [_display.bpp], eax
  374.         mov [_display.vrefresh], 60
  375.         mov [_display.disable_mouse],  __sys_disable_mouse
  376.  
  377.         movzx eax,word [BOOT_VAR+0x900A]  ; X max
  378.         mov [_display.width], eax
  379.         dec   eax
  380.         mov   [Screen_Max_X],eax
  381.         mov   [screen_workarea.right],eax
  382.         movzx eax,word [BOOT_VAR+0x900C]  ; Y max
  383.         mov [_display.height], eax
  384.         dec   eax
  385.         mov   [Screen_Max_Y],eax
  386.         mov   [screen_workarea.bottom],eax
  387.         movzx eax,word [BOOT_VAR+0x9008]  ; screen mode
  388.         mov   [SCR_MODE],eax
  389.         mov   eax,[BOOT_VAR+0x9014]       ; Vesa 1.2 bnk sw add
  390.         mov   [BANK_SWITCH],eax
  391.         mov   [BytesPerScanLine],word 640*4         ; Bytes PerScanLine
  392.         cmp   [SCR_MODE],word 0x13          ; 320x200
  393.         je    @f
  394.         cmp   [SCR_MODE],word 0x12          ; VGA 640x480
  395.         je    @f
  396.         movzx eax, word[BOOT_VAR+0x9001]        ; for other modes
  397.         mov   [BytesPerScanLine],ax
  398.         mov [_display.pitch], eax
  399. @@:
  400.         mov eax, [_display.width]
  401.         mul [_display.height]
  402.         mov [_WinMapSize], eax
  403.  
  404.         mov     esi, BOOT_VAR+0x9080
  405.         movzx   ecx, byte [esi-1]
  406.         mov     [NumBiosDisks], ecx
  407.         mov     edi, BiosDisksData
  408.         rep     movsd
  409.  
  410. ; GRAPHICS ADDRESSES
  411.  
  412.         and     byte [BOOT_VAR+0x901e],0x0
  413.         mov     eax,[BOOT_VAR+0x9018]
  414.         mov     [LFBAddress],eax
  415.  
  416.         cmp     [SCR_MODE],word 0100000000000000b
  417.         jge     setvesa20
  418.         cmp     [SCR_MODE],word 0x13
  419.         je      v20ga32
  420.         mov     [PUTPIXEL],dword Vesa12_putpixel24  ; Vesa 1.2
  421.         mov     [GETPIXEL],dword Vesa12_getpixel24
  422.         cmp     [ScreenBPP],byte 24
  423.         jz      ga24
  424.         mov     [PUTPIXEL],dword Vesa12_putpixel32
  425.         mov     [GETPIXEL],dword Vesa12_getpixel32
  426.       ga24:
  427.         jmp     v20ga24
  428.       setvesa20:
  429.         mov     [PUTPIXEL],dword Vesa20_putpixel24  ; Vesa 2.0
  430.         mov     [GETPIXEL],dword Vesa20_getpixel24
  431.         cmp     [ScreenBPP],byte 24
  432.         jz      v20ga24
  433.       v20ga32:
  434.         mov     [PUTPIXEL],dword Vesa20_putpixel32
  435.         mov     [GETPIXEL],dword Vesa20_getpixel32
  436.       v20ga24:
  437.         cmp     [SCR_MODE],word 0x12                ; 16 C VGA 640x480
  438.         jne     no_mode_0x12
  439.         mov     [PUTPIXEL],dword VGA_putpixel
  440.         mov     [GETPIXEL],dword Vesa20_getpixel32
  441.       no_mode_0x12:
  442.  
  443. ; -------- Fast System Call init ----------
  444. ; Intel SYSENTER/SYSEXIT (AMD CPU support it too)
  445.            bt [cpu_caps], CAPS_SEP
  446.            jnc .SEnP   ; SysEnter not Present
  447.            xor edx, edx
  448.            mov ecx, MSR_SYSENTER_CS
  449.            mov eax, os_code
  450.            wrmsr
  451.            mov ecx, MSR_SYSENTER_ESP
  452. ;           mov eax, sysenter_stack ; Check it
  453.            xor     eax, eax
  454.            wrmsr
  455.            mov ecx, MSR_SYSENTER_EIP
  456.            mov eax, sysenter_entry
  457.            wrmsr
  458. .SEnP:
  459. ; AMD SYSCALL/SYSRET
  460.            cmp byte[cpu_vendor], 'A'
  461.            jne .noSYSCALL
  462.            mov eax, 0x80000001
  463.            cpuid
  464.            test edx, 0x800  ; bit_11 - SYSCALL/SYSRET support
  465.            jz .noSYSCALL
  466.            mov ecx, MSR_AMD_EFER
  467.            rdmsr
  468.            or eax, 1   ; bit_0 - System Call Extension (SCE)
  469.            wrmsr
  470.  
  471.         ; !!!! It`s dirty hack, fix it !!!
  472.         ; Bits of EDX :
  473.         ; Bit 31Ц16 During the SYSRET instruction, this field is copied into the CS register
  474.         ;  and the contents of this field, plus 8, are copied into the SS register.
  475.         ; Bit 15Ц0 During the SYSCALL instruction, this field is copied into the CS register
  476.         ;  and the contents of this field, plus 8, are copied into the SS register.
  477.  
  478.         ; mov   edx, (os_code + 16) * 65536 + os_code
  479.            mov edx, 0x1B0008
  480.  
  481.            mov eax, syscall_entry
  482.            mov ecx, MSR_AMD_STAR
  483.            wrmsr
  484. .noSYSCALL:
  485. ; -----------------------------------------
  486.         stdcall alloc_page
  487.         stdcall map_page, tss-0xF80, eax, PG_SW
  488.         stdcall alloc_page
  489.         inc     eax
  490.         mov     [SLOT_BASE+256+APPDATA.io_map], eax
  491.         stdcall map_page, tss+0x80, eax, PG_SW
  492.         stdcall alloc_page
  493.         inc     eax
  494.         mov     dword [SLOT_BASE+256+APPDATA.io_map+4], eax
  495.         stdcall map_page, tss+0x1080, eax, PG_SW
  496.  
  497. ; LOAD IDT
  498.  
  499.            call build_interrupt_table ;lidt is executed
  500.           ;lidt [idtreg]
  501.  
  502.            call init_kernel_heap
  503.            stdcall kernel_alloc, RING0_STACK_SIZE+512
  504.            mov [os_stack_seg], eax
  505.  
  506.            lea esp, [eax+RING0_STACK_SIZE]
  507.  
  508.            mov [tss._ss0], os_stack
  509.            mov [tss._esp0], esp
  510.            mov [tss._esp], esp
  511.            mov [tss._cs],os_code
  512.            mov [tss._ss],os_stack
  513.            mov [tss._ds],app_data
  514.            mov [tss._es],app_data
  515.            mov [tss._fs],app_data
  516.            mov [tss._gs],app_data
  517.            mov [tss._io],128
  518. ;Add IO access table - bit array of permitted ports
  519.            mov edi, tss._io_map_0
  520.            xor eax, eax
  521.            not eax
  522.            mov ecx, 8192/4
  523.            rep stosd                 ; access to 4096*8=65536 ports
  524.  
  525.            mov  ax,tss0
  526.            ltr  ax
  527.  
  528.            mov [LFBSize], 0x800000
  529.            call init_LFB
  530.            call init_fpu
  531.            call init_malloc
  532.  
  533.            stdcall alloc_kernel_space, 0x51000
  534.            mov [default_io_map], eax
  535.  
  536.            add eax, 0x2000
  537.            mov [ipc_tmp], eax
  538.            mov ebx, 0x1000
  539.  
  540.            add eax, 0x40000
  541.            mov [proc_mem_map], eax
  542.  
  543.            add eax, 0x8000
  544.            mov [proc_mem_pdir], eax
  545.  
  546.            add eax, ebx
  547.            mov [proc_mem_tab], eax
  548.  
  549.            add eax, ebx
  550.            mov [tmp_task_pdir], eax
  551.  
  552.            add eax, ebx
  553.            mov [tmp_task_ptab], eax
  554.  
  555.            add eax, ebx
  556.            mov [ipc_pdir], eax
  557.  
  558.            add eax, ebx
  559.            mov [ipc_ptab], eax
  560.  
  561.            stdcall kernel_alloc, (unpack.LZMA_BASE_SIZE+(unpack.LZMA_LIT_SIZE shl \
  562.                                  (unpack.lc+unpack.lp)))*4
  563.  
  564.            mov [unpack.p], eax
  565.  
  566.            call init_events
  567.            mov eax, srv.fd-SRV_FD_OFFSET
  568.            mov [srv.fd], eax
  569.            mov [srv.bk], eax
  570.  
  571. ;Set base of graphic segment to linear address of LFB
  572.         mov     eax,[LFBAddress]          ; set for gs
  573.         mov     [graph_data_l+2],ax
  574.         shr     eax,16
  575.         mov     [graph_data_l+4],al
  576.         mov     [graph_data_l+7],ah
  577.  
  578.         stdcall kernel_alloc, [_WinMapSize]
  579.         mov [_WinMapAddress], eax
  580.  
  581.         xor  eax,eax
  582.         inc  eax
  583.         mov [CURRENT_TASK],eax          ;dword 1
  584.         mov [TASK_COUNT],eax            ;dword 1
  585.         mov [TASK_BASE],dword TASK_DATA
  586.         mov [current_slot], SLOT_BASE+256
  587.  
  588. ; set background
  589.  
  590.         mov   [BgrDrawMode],eax
  591.         mov   [BgrDataWidth],eax
  592.         mov   [BgrDataHeight],eax
  593.         mov    [mem_BACKGROUND], 4
  594.         mov [img_background], static_background_data
  595.  
  596.         mov     [SLOT_BASE + 256 + APPDATA.dir_table], sys_pgdir - OS_BASE
  597.  
  598.         stdcall kernel_alloc, 0x10000/8
  599.         mov     edi, eax
  600.         mov     [network_free_ports], eax
  601.         or      eax, -1
  602.         mov     ecx, 0x10000/32
  603.         rep     stosd
  604.  
  605. ; REDIRECT ALL IRQ'S TO INT'S 0x20-0x2f
  606.  
  607.         call  init_irqs
  608.         call  rerouteirqs
  609.  
  610. ; Initialize system V86 machine
  611.         call    init_sys_v86
  612.  
  613. ; TIMER SET TO 1/100 S
  614.  
  615.         mov   al,0x34              ; set to 100Hz
  616.         out   0x43,al
  617.         mov   al,0x9b              ; lsb    1193180 / 1193
  618.         out   0x40,al
  619.         mov   al,0x2e              ; msb
  620.         out   0x40,al
  621.  
  622. ; Enable timer IRQ (IRQ0) and hard drives IRQs (IRQ14, IRQ15)
  623. ; they are used: when partitions are scanned, hd_read relies on timer
  624. ; Also enable IRQ2, because in some configurations
  625. ; IRQs from slave controller are not delivered until IRQ2 on master is enabled
  626.         mov     al, 0xFA
  627.         out     0x21, al
  628.         mov     al, 0x3F
  629.         out     0xA1, al
  630.  
  631. ; Enable interrupts in IDE controller
  632.         mov     al, 0
  633.         mov     dx, 0x3F6
  634.         out     dx, al
  635.         mov     dl, 0x76
  636.         out     dx, al
  637.  
  638. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  639. include 'detect/disks.inc'
  640. ;!!!!!!!!!!!!!!!!!!!!!!!!!!
  641.  
  642.   call Parser_params
  643.  
  644. if ~ defined extended_primary_loader
  645. ; ramdisk image should be loaded by extended primary loader if it exists
  646. ; READ RAMDISK IMAGE FROM HD
  647.  
  648. ;!!!!!!!!!!!!!!!!!!!!!!!
  649. include 'boot/rdload.inc'
  650. ;!!!!!!!!!!!!!!!!!!!!!!!
  651. end if
  652. ;    mov    [dma_hdd],1
  653. ; CALCULATE FAT CHAIN FOR RAMDISK
  654.  
  655.         call  calculatefatchain
  656.  
  657. ; LOAD VMODE DRIVER
  658.  
  659. ;!!!!!!!!!!!!!!!!!!!!!!!
  660. include 'vmodeld.inc'
  661. ;!!!!!!!!!!!!!!!!!!!!!!!
  662.  
  663. if 0
  664.   mov ax,[OS_BASE+0x10000+bx_from_load]
  665.   cmp ax,'r1'           ; if using not ram disk, then load librares and parameters {SPraid.simba}
  666.   je  no_lib_load
  667. ; LOADING LIBRARES
  668.    stdcall dll.Load,@IMPORT                 ; loading librares for kernel (.obj files)
  669.    call load_file_parse_table               ; prepare file parse table
  670.    call set_kernel_conf                     ; configure devices and gui
  671. no_lib_load:
  672. end if
  673.  
  674. ; LOAD FONTS I and II
  675.  
  676.         stdcall read_file, char, FONT_I, 0, 2304
  677.         stdcall read_file, char2, FONT_II, 0, 2560
  678.  
  679.         mov   esi,boot_fonts
  680.         call  boot_log
  681.  
  682. ; PRINT AMOUNT OF MEMORY
  683.         mov     esi, boot_memdetect
  684.         call    boot_log
  685.  
  686.         movzx   ecx, word [boot_y]
  687.         if lang eq ru
  688.                 or      ecx, (10+30*6) shl 16
  689.                 else
  690.                 or      ecx, (10+29*6) shl 16
  691.                 end if
  692.         sub     ecx, 10
  693.         mov     edx, 0xFFFFFF
  694.         mov     ebx, [MEM_AMOUNT]
  695.         shr     ebx, 20
  696.         xor     edi,edi
  697.         mov     eax, 0x00040000
  698.                 inc             edi
  699.         call    display_number_force
  700.  
  701. ; BUILD SCHEDULER
  702.  
  703.         call   build_scheduler ; sys32.inc
  704.  
  705.         mov    esi,boot_devices
  706.         call   boot_log
  707.  
  708.         mov  [pci_access_enabled],1
  709.  
  710.  
  711. ; SET PRELIMINARY WINDOW STACK AND POSITIONS
  712.  
  713.         mov   esi,boot_windefs
  714.         call  boot_log
  715.         call  set_window_defaults
  716.  
  717. ; SET BACKGROUND DEFAULTS
  718.  
  719.         mov   esi,boot_bgr
  720.         call  boot_log
  721.         call  init_background
  722.         call  calculatebackground
  723.  
  724. ; RESERVE SYSTEM IRQ'S JA PORT'S
  725.  
  726.         mov   esi,boot_resirqports
  727.         call  boot_log
  728.         call  reserve_irqs_ports
  729.  
  730. ; SET UP OS TASK
  731.  
  732.         mov  esi,boot_setostask
  733.         call boot_log
  734.  
  735.         xor  eax, eax
  736.         mov  dword [SLOT_BASE+APPDATA.fpu_state], fpu_data
  737.         mov  dword [SLOT_BASE+APPDATA.exc_handler], eax
  738.         mov  dword [SLOT_BASE+APPDATA.except_mask], eax
  739.  
  740.         ; name for OS/IDLE process
  741.  
  742.         mov dword [SLOT_BASE+256+APPDATA.app_name],   dword 'OS/I'
  743.         mov dword [SLOT_BASE+256+APPDATA.app_name+4], dword 'DLE '
  744.         mov edi, [os_stack_seg]
  745.         mov dword [SLOT_BASE+256+APPDATA.pl0_stack], edi
  746.         add edi, 0x2000-512
  747.         mov dword [SLOT_BASE+256+APPDATA.fpu_state], edi
  748.         mov dword [SLOT_BASE+256+APPDATA.saved_esp0], edi ; just for case
  749.         ; [SLOT_BASE+256+APPDATA.io_map] was set earlier
  750.  
  751.         mov esi, fpu_data
  752.         mov ecx, 512/4
  753.         cld
  754.         rep movsd
  755.  
  756.         mov dword [SLOT_BASE+256+APPDATA.exc_handler], eax
  757.         mov dword [SLOT_BASE+256+APPDATA.except_mask], eax
  758.  
  759.         mov ebx, SLOT_BASE+256+APP_OBJ_OFFSET
  760.         mov  dword [SLOT_BASE+256+APPDATA.fd_obj], ebx
  761.         mov  dword [SLOT_BASE+256+APPDATA.bk_obj], ebx
  762.  
  763.         mov  dword [SLOT_BASE+256+APPDATA.cur_dir], sysdir_path
  764.         mov dword [SLOT_BASE+256+APPDATA.tls_base], eax
  765.  
  766.         ; task list
  767.         mov  dword [TASK_DATA+TASKDATA.mem_start],eax   ; process base address
  768.         inc  eax
  769.         mov  dword [CURRENT_TASK],eax
  770.         mov  dword [TASK_COUNT],eax
  771.         mov  [current_slot], SLOT_BASE+256
  772.         mov  [TASK_BASE],dword TASK_DATA
  773.         mov  byte[TASK_DATA+TASKDATA.wnd_number],al     ; on screen number
  774.         mov  dword [TASK_DATA+TASKDATA.pid], eax        ; process id number
  775.  
  776.         call init_display
  777.         mov eax, [def_cursor]
  778.         mov [SLOT_BASE+APPDATA.cursor],eax
  779.         mov [SLOT_BASE+APPDATA.cursor+256],eax
  780.  
  781.   ; READ TSC / SECOND
  782.  
  783.         mov   esi,boot_tsc
  784.         call  boot_log
  785.         cli
  786.         rdtsc ;call  _rdtsc
  787.         mov   ecx,eax
  788.         mov   esi,250               ; wait 1/4 a second
  789.         call  delay_ms
  790.         rdtsc ;call  _rdtsc
  791.         sti
  792.         sub   eax,ecx
  793.         shl   eax,2
  794.         mov   [CPU_FREQ],eax          ; save tsc / sec
  795. ;       mov ebx, 1000000
  796. ;       div ebx
  797. ; вообще-то производительность в данном конкретном месте
  798. ; совершенно некритична, но чтобы заткнуть любителей
  799. ; оптимизирующих компиляторов ЯВУ...
  800.         mov     edx, 2251799814
  801.         mul     edx
  802.         shr     edx, 19
  803.         mov [stall_mcs], edx
  804. ; PRINT CPU FREQUENCY
  805.         mov     esi, boot_cpufreq
  806.         call    boot_log
  807.  
  808.         mov     ebx, edx
  809.         movzx   ecx, word [boot_y]
  810.         if lang eq ru
  811.                 add      ecx, (10+19*6) shl 16 - 10; 'Determining amount of memory'
  812.                 else
  813.                 add      ecx, (10+17*6) shl 16 - 10; 'Determining amount of memory'
  814.                 end if
  815.         mov     edx, 0xFFFFFF
  816.         xor     edi,edi
  817.         mov     eax, 0x00040000
  818.                 inc             edi
  819.         call    display_number_force
  820.  
  821. ; SET VARIABLES
  822.  
  823.         call  set_variables
  824.  
  825. ; SET MOUSE
  826.  
  827.         ;call   detect_devices
  828.         stdcall load_driver, szPS2MDriver
  829. ;        stdcall load_driver, szCOM_MDriver
  830.  
  831.         mov   esi,boot_setmouse
  832.         call  boot_log
  833.         call  setmouse
  834.  
  835.  
  836. ; STACK AND FDC
  837.  
  838.         call  stack_init
  839.         call  fdc_init
  840.  
  841. ; PALETTE FOR 320x200 and 640x480 16 col
  842.  
  843.         cmp   [SCR_MODE],word 0x12
  844.         jne   no_pal_vga
  845.         mov   esi,boot_pal_vga
  846.         call  boot_log
  847.         call  paletteVGA
  848.       no_pal_vga:
  849.  
  850.         cmp   [SCR_MODE],word 0x13
  851.         jne   no_pal_ega
  852.         mov   esi,boot_pal_ega
  853.         call  boot_log
  854.         call  palette320x200
  855.       no_pal_ega:
  856.  
  857. ; LOAD DEFAULT SKIN
  858.  
  859.         call    load_default_skin
  860.  
  861. ;protect io permission map
  862.  
  863.            mov esi, [default_io_map]
  864.            stdcall map_page,esi,[SLOT_BASE+256+APPDATA.io_map], PG_MAP
  865.            add esi, 0x1000
  866.            stdcall map_page,esi,[SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  867.  
  868.            stdcall map_page,tss._io_map_0,\
  869.                    [SLOT_BASE+256+APPDATA.io_map], PG_MAP
  870.            stdcall map_page,tss._io_map_1,\
  871.                    [SLOT_BASE+256+APPDATA.io_map+4], PG_MAP
  872.  
  873.   mov ax,[OS_BASE+0x10000+bx_from_load]
  874.   cmp ax,'r1'           ; if not rused ram disk - load network configuration from files {SPraid.simba}
  875.   je  no_st_network
  876.         call set_network_conf
  877.   no_st_network:
  878.  
  879. ; LOAD FIRST APPLICATION
  880.         cli
  881.  
  882.         cmp   byte [BOOT_VAR+0x9030],1
  883.         jne   no_load_vrr_m
  884.  
  885.         mov     ebp, vrr_m
  886.         call    fs_execute_from_sysdir
  887.  
  888. ;        cmp   eax,2                  ; if vrr_m app found (PID=2)
  889.         sub   eax,2
  890.         jz    first_app_found
  891.  
  892. no_load_vrr_m:
  893.  
  894.         mov     ebp, firstapp
  895.         call    fs_execute_from_sysdir
  896.  
  897. ;        cmp   eax,2                  ; continue if a process has been loaded
  898.         sub   eax,2
  899.         jz    first_app_found
  900.  
  901.         mov     esi, boot_failed
  902.         call    boot_log
  903.  
  904.         mov   eax, 0xDEADBEEF        ; otherwise halt
  905.         hlt
  906.  
  907. first_app_found:
  908.  
  909.         cli
  910.  
  911.         ;mov   [TASK_COUNT],dword 2
  912.         push  1
  913.         pop   dword [CURRENT_TASK]      ; set OS task fisrt
  914.  
  915. ; SET KEYBOARD PARAMETERS
  916.         mov   al, 0xf6         ; reset keyboard, scan enabled
  917.         call  kb_write
  918.  
  919.         ; wait until 8042 is ready
  920.         xor ecx,ecx
  921.       @@:
  922.         in     al,64h
  923.         and    al,00000010b
  924.         loopnz @b
  925.  
  926.        ; mov   al, 0xED       ; Keyboard LEDs - only for testing!
  927.        ; call  kb_write
  928.        ; call  kb_read
  929.        ; mov   al, 111b
  930.        ; call  kb_write
  931.        ; call  kb_read
  932.  
  933.         mov   al, 0xF3       ; set repeat rate & delay
  934.         call  kb_write
  935. ;        call  kb_read
  936.         mov   al, 0 ; 30 250 ;00100010b ; 24 500  ;00100100b  ; 20 500
  937.         call  kb_write
  938. ;        call  kb_read
  939.      ;// mike.dld [
  940.         call  set_lights
  941.      ;// mike.dld ]
  942.  
  943.  
  944. ; Setup serial output console (if enabled)
  945.  
  946. if defined debug_com_base
  947.  
  948.         ; enable Divisor latch
  949.  
  950.         mov     dx, debug_com_base+3
  951.         mov     al, 1 shl 7
  952.         out     dx, al
  953.  
  954.         ; Set speed to 115200 baud (max speed)
  955.  
  956.         mov     dx, debug_com_base
  957.         mov     al, 0x01
  958.         out     dx, al
  959.  
  960.         mov     dx, debug_com_base+1
  961.         mov     al, 0x00
  962.         out     dx, al
  963.  
  964.         ; No parity, 8bits words, one stop bit, dlab bit back to 0
  965.  
  966.         mov     dx, debug_com_base+3
  967.         mov     al, 3
  968.         out     dx, al
  969.  
  970.         ; disable interrupts
  971.  
  972.         mov     dx, debug_com_base+1
  973.         mov     al, 0
  974.         out     dx, al
  975.  
  976.         ; clear +  enable fifo (64 bits)
  977.  
  978.         mov     dx, debug_com_base+2
  979.         mov     al, 0x7 + 1 shl 5
  980.         out     dx, al
  981.  
  982.  
  983. end if
  984.  
  985. ; START MULTITASKING
  986.  
  987. ; A 'All set - press ESC to start' messages if need
  988. if preboot_blogesc
  989.         mov     esi, boot_tasking
  990.         call    boot_log
  991. .bll1:  in      al, 0x60        ; wait for ESC key press
  992.         cmp     al, 129
  993.         jne     .bll1
  994. end if
  995.  
  996.  
  997.         stdcall attach_int_handler, 1, irq1, 0
  998.  
  999. ;        mov    [dma_hdd],1
  1000.         cmp     [IDEContrRegsBaseAddr], 0
  1001.         setnz   [dma_hdd]
  1002.         mov [timer_ticks_enable],1              ; for cd driver
  1003.  
  1004.         sti
  1005.         call change_task
  1006.  
  1007.         jmp osloop
  1008.  
  1009.  
  1010.         ; Fly :)
  1011.  
  1012. include 'unpacker.inc'
  1013. include 'fdo.inc'
  1014.  
  1015. align 4
  1016. boot_log:
  1017.          pushad
  1018.  
  1019.         mov   ebx,10*65536
  1020.         mov   bx,word [boot_y]
  1021.         add   [boot_y],dword 10
  1022.         mov   ecx,0x80ffffff   ; ASCIIZ string with white color
  1023.                 xor       edi,edi
  1024.         mov   edx,esi
  1025.                 inc       edi
  1026.         call  dtext
  1027.  
  1028.         mov   [novesachecksum],1000
  1029.         call  checkVga_N13
  1030.  
  1031.         popad
  1032.  
  1033.         ret
  1034.  
  1035. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1036. ;                                                                    ;
  1037. ;                    MAIN OS LOOP START                              ;
  1038. ;                                                                    ;
  1039. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1040. align 32
  1041. osloop:
  1042.         call   [draw_pointer]
  1043.         call    window_check_events
  1044.         call    mouse_check_events
  1045.         call   checkmisc
  1046.         call   checkVga_N13
  1047.         call   stack_handler
  1048.         call   checkidle
  1049.         call   check_fdd_motor_status
  1050.         call   check_ATAPI_device_event
  1051.         call   check_timers
  1052.         jmp    osloop
  1053. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1054. ;                                                                    ;
  1055. ;                      MAIN OS LOOP END                              ;
  1056. ;                                                                    ;
  1057. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1058. align 4
  1059. checkidle:
  1060.         pushad
  1061.         call    change_task
  1062.         jmp     idle_loop_entry
  1063.   idle_loop:
  1064.         cmp     eax,[idlemem]     ; eax == [timer_ticks]
  1065.         jne     idle_exit
  1066.         rdtsc   ;call _rdtsc
  1067.         mov     ecx,eax
  1068.         hlt
  1069.         rdtsc   ;call _rdtsc
  1070.         sub     eax,ecx
  1071.         add     [idleuse],eax
  1072.   idle_loop_entry:
  1073.         mov     eax,[timer_ticks] ; eax =  [timer_ticks]
  1074.         cmp     [check_idle_semaphore],0
  1075.         je      idle_loop
  1076.         dec     [check_idle_semaphore]
  1077.   idle_exit:
  1078.         mov     [idlemem],eax     ; eax == [timer_ticks]
  1079.         popad
  1080.         ret
  1081.  
  1082. uglobal
  1083.   idlemem               dd   0x0
  1084.   idleuse               dd   0x0
  1085.   idleusesec            dd   0x0
  1086.   check_idle_semaphore  dd   0x0
  1087. endg
  1088.  
  1089.  
  1090.  
  1091. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1092. ;                                                                      ;
  1093. ;                   INCLUDED SYSTEM FILES                              ;
  1094. ;                                                                      ;
  1095. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1096.  
  1097.  
  1098. include "kernel32.inc"
  1099.  
  1100.  
  1101. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1102. ;                                                                      ;
  1103. ;                       KERNEL FUNCTIONS                               ;
  1104. ;                                                                      ;
  1105. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  1106.  
  1107. reserve_irqs_ports:
  1108.  
  1109.  
  1110. ; RESERVE PORTS
  1111.         mov eax, RESERVED_PORTS
  1112.         mov ecx, 1
  1113.  
  1114.         mov [eax], dword 4
  1115.  
  1116.         mov [eax+16], ecx
  1117.         mov [eax+16+4], dword 0
  1118.         mov [eax+16+4], dword 0x2D
  1119.  
  1120.         mov [eax+32], ecx
  1121.         mov [eax+32+4], dword 0x30
  1122.         mov [eax+32+8], dword 0x4D
  1123.  
  1124.         mov [eax+48], ecx
  1125.         mov [eax+48+4], dword 0x50
  1126.         mov [eax+28+8], dword 0xDF
  1127.  
  1128.         mov [eax+64], ecx
  1129.         mov [eax+64+4], dword 0xE5
  1130.         mov [eax+64+8], dword 0xFF
  1131.  
  1132.         ret
  1133.  
  1134.  
  1135. iglobal
  1136.   process_number dd 0x1
  1137. endg
  1138.  
  1139. set_variables:
  1140.  
  1141.         mov   ecx,0x16                       ; flush port 0x60
  1142. .fl60:
  1143.         in    al,0x60
  1144.         loop  .fl60
  1145.         push  eax
  1146.  
  1147.         mov   ax,[BOOT_VAR+0x900c]
  1148.         shr   ax,1
  1149.         shl   eax,16
  1150.         mov   ax,[BOOT_VAR+0x900A]
  1151.         shr   ax,1
  1152.         mov   [MOUSE_X],eax
  1153.  
  1154.         xor   eax,eax
  1155.         mov   [BTN_ADDR],dword BUTTON_INFO    ; address of button list
  1156.  
  1157.         mov   byte [MOUSE_BUFF_COUNT],al                 ; mouse buffer
  1158.         mov   byte [KEY_COUNT],al                 ; keyboard buffer
  1159.         mov   byte [BTN_COUNT],al                 ; button buffer
  1160. ;        mov   [MOUSE_X],dword 100*65536+100    ; mouse x/y
  1161.  
  1162.      ;!! IP 04.02.2005:
  1163.         mov   byte [DONT_SWITCH],al ; change task if possible
  1164.         pop   eax
  1165.         ret
  1166.  
  1167. align 4
  1168. ;input  eax=43,bl-byte of output, ecx - number of port
  1169. sys_outport:
  1170.  
  1171.     mov   edi,ecx          ; separate flag for read / write
  1172.     and   ecx,65535
  1173.  
  1174.     mov   eax,[RESERVED_PORTS]
  1175.     test  eax,eax
  1176.     jnz   .sopl8
  1177.     inc   eax
  1178.         mov   [esp+32],eax
  1179.     ret
  1180.  
  1181.   .sopl8:
  1182.     mov   edx,[TASK_BASE]
  1183.     mov   edx,[edx+0x4]
  1184.     ;and   ecx,65535
  1185.     ;cld - set on interrupt 0x40
  1186.   .sopl1:
  1187.  
  1188.     mov   esi,eax
  1189.     shl   esi,4
  1190.     add   esi,RESERVED_PORTS
  1191.     cmp   edx,[esi+0]
  1192.     jne   .sopl2
  1193.     cmp   ecx,[esi+4]
  1194.     jb    .sopl2
  1195.     cmp   ecx,[esi+8]
  1196.     jg    .sopl2
  1197. .sopl3:
  1198.  
  1199.     test  edi,0x80000000 ; read ?
  1200.     jnz   .sopl4
  1201.  
  1202.         mov       eax,ebx
  1203.     mov   dx,cx          ; write
  1204.     out   dx,al
  1205.     and   [esp+32],dword 0
  1206.     ret
  1207.  
  1208.         .sopl2:
  1209.  
  1210.     dec   eax
  1211.     jnz   .sopl1
  1212.         inc       eax
  1213.     mov   [esp+32],eax
  1214.     ret
  1215.  
  1216.  
  1217.   .sopl4:
  1218.  
  1219.     mov   dx,cx          ; read
  1220.     in    al,dx
  1221.     and   eax,0xff
  1222.     and   [esp+32],dword 0
  1223.     mov   [esp+20],eax
  1224.     ret
  1225.  
  1226. display_number:
  1227. ;It is not optimization
  1228.         mov     eax, ebx
  1229.         mov     ebx, ecx
  1230.         mov     ecx, edx
  1231.         mov     edx, esi
  1232.         mov     esi, edi
  1233. ; eax = print type, al=0 -> ebx is number
  1234. ;                   al=1 -> ebx is pointer
  1235. ;                   ah=0 -> display decimal
  1236. ;                   ah=1 -> display hexadecimal
  1237. ;                   ah=2 -> display binary
  1238. ;                   eax bits 16-21 = number of digits to display (0-32)
  1239. ;                   eax bits 22-31 = reserved
  1240. ;
  1241. ; ebx = number or pointer
  1242. ; ecx = x shl 16 + y
  1243. ; edx = color
  1244.     xor     edi, edi
  1245. display_number_force:
  1246.     push  eax
  1247.     and   eax,0x3fffffff
  1248.     cmp   eax,0xffff            ; length > 0 ?
  1249.     pop   eax
  1250.     jge   cont_displ
  1251.     ret
  1252.    cont_displ:
  1253.      push  eax
  1254.      and   eax,0x3fffffff
  1255.      cmp   eax,61*0x10000        ; length <= 60 ?
  1256.      pop   eax
  1257.      jb    cont_displ2
  1258.      ret
  1259.    cont_displ2:
  1260.  
  1261.      pushad
  1262.  
  1263.      cmp   al,1                  ; ecx is a pointer ?
  1264.      jne   displnl1
  1265.      mov   ebp,ebx
  1266.      add   ebp,4
  1267.      mov   ebp,[ebp+std_application_base_address]
  1268.      mov   ebx,[ebx+std_application_base_address]
  1269.  displnl1:
  1270.      sub   esp,64
  1271.  
  1272.     test   ah,ah                  ; DECIMAL
  1273.     jnz   no_display_desnum
  1274.     shr   eax,16
  1275.     and   eax,0xC03f
  1276. ;     and   eax,0x3f
  1277.     push  eax
  1278.     and   eax,0x3f
  1279.     mov   edi,esp
  1280.     add   edi,4+64-1
  1281.     mov   ecx,eax
  1282.     mov   eax,ebx
  1283.     mov   ebx,10
  1284.  d_desnum:
  1285.      xor   edx,edx
  1286.      call  division_64_bits
  1287.      div   ebx
  1288.      add   dl,48
  1289.      mov   [edi],dl
  1290.      dec   edi
  1291.      loop  d_desnum
  1292.      pop   eax
  1293.      call  normalize_number
  1294.      call  draw_num_text
  1295.      add   esp,64
  1296.      popad
  1297.      ret
  1298.    no_display_desnum:
  1299.  
  1300.      cmp   ah,0x01               ; HEXADECIMAL
  1301.      jne   no_display_hexnum
  1302.      shr   eax,16
  1303.      and   eax,0xC03f
  1304. ;     and   eax,0x3f
  1305.      push  eax
  1306.      and   eax,0x3f
  1307.      mov   edi,esp
  1308.      add   edi,4+64-1
  1309.      mov   ecx,eax
  1310.      mov   eax,ebx
  1311.      mov   ebx,16
  1312.    d_hexnum:
  1313.      xor   edx,edx
  1314.      call  division_64_bits
  1315.      div   ebx
  1316.    hexletters = __fdo_hexdigits
  1317.      add   edx,hexletters
  1318.      mov   dl,[edx]
  1319.      mov   [edi],dl
  1320.      dec   edi
  1321.      loop  d_hexnum
  1322.      pop   eax
  1323.      call  normalize_number
  1324.      call  draw_num_text
  1325.      add   esp,64
  1326.      popad
  1327.      ret
  1328.    no_display_hexnum:
  1329.  
  1330.      cmp   ah,0x02               ; BINARY
  1331.      jne   no_display_binnum
  1332.      shr   eax,16
  1333.      and   eax,0xC03f
  1334. ;     and   eax,0x3f
  1335.      push  eax
  1336.      and   eax,0x3f
  1337.      mov   edi,esp
  1338.      add   edi,4+64-1
  1339.      mov   ecx,eax
  1340.      mov   eax,ebx
  1341.      mov   ebx,2
  1342.    d_binnum:
  1343.      xor   edx,edx
  1344.      call  division_64_bits
  1345.      div   ebx
  1346.      add   dl,48
  1347.      mov   [edi],dl
  1348.      dec   edi
  1349.      loop  d_binnum
  1350.      pop   eax
  1351.      call  normalize_number
  1352.      call  draw_num_text
  1353.      add   esp,64
  1354.      popad
  1355.      ret
  1356.    no_display_binnum:
  1357.  
  1358.      add   esp,64
  1359.      popad
  1360.      ret
  1361.  
  1362. normalize_number:
  1363.      test  ah,0x80
  1364.      jz   .continue
  1365.      mov  ecx,48
  1366.      and   eax,0x3f
  1367. @@:
  1368.      inc   edi
  1369.      cmp   [edi],cl
  1370.      jne   .continue
  1371.      dec   eax
  1372.      cmp   eax,1
  1373.      ja    @r
  1374.      mov   al,1
  1375. .continue:
  1376.      and   eax,0x3f
  1377.      ret
  1378.  
  1379. division_64_bits:
  1380.      test  [esp+1+4],byte 0x40
  1381.      jz   .continue
  1382.      push  eax
  1383.      mov   eax,ebp
  1384.      div   ebx
  1385.      mov   ebp,eax
  1386.      pop   eax
  1387. .continue:
  1388.      ret
  1389.  
  1390. draw_num_text:
  1391.      mov   esi,eax
  1392.      mov   edx,64+4
  1393.      sub   edx,eax
  1394.      add   edx,esp
  1395.      mov   ebx,[esp+64+32-8+4]
  1396. ; add window start x & y
  1397.      mov   ecx,[TASK_BASE]
  1398.  
  1399.      mov   edi,[CURRENT_TASK]
  1400.      shl   edi,8
  1401.  
  1402.      mov   eax,[ecx-twdw+WDATA.box.left]
  1403.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1404.      shl   eax,16
  1405.      add   eax,[ecx-twdw+WDATA.box.top]
  1406.      add   eax,[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1407.      add   ebx,eax
  1408.      mov   ecx,[esp+64+32-12+4]
  1409.         and     ecx, not 0x80000000     ; force counted string
  1410.         mov     eax, [esp+64+8]         ; background color (if given)
  1411.         mov     edi, [esp+64+4]
  1412.      jmp   dtext
  1413.  
  1414. align 4
  1415.  
  1416. sys_setup:
  1417.  
  1418. ; 1=roland mpu midi base , base io address
  1419. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1420. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1421. ; 5=system language, 1eng 2fi 3ger 4rus
  1422. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1423. ; 8=fat32 partition in hd
  1424. ; 9
  1425. ; 10 = sound dma channel
  1426. ; 11 = enable lba read
  1427. ; 12 = enable pci access
  1428.  
  1429.  
  1430.         and  [esp+32],dword 0
  1431.         dec     ebx                             ; MIDI
  1432.         jnz  nsyse1
  1433.         cmp  ecx,0x100
  1434.  
  1435.         jb   nsyse1
  1436.         mov     esi,65535
  1437.         cmp     esi,ecx
  1438.  
  1439.         jb   nsyse1
  1440.         mov  [midi_base],cx     ;bx
  1441.         mov  word [mididp],cx   ;bx
  1442.         inc  cx                 ;bx
  1443.         mov  word [midisp],cx   ;bx
  1444.         ret
  1445.  
  1446. iglobal
  1447. midi_base dw 0
  1448. endg
  1449.  
  1450.    nsyse1:
  1451.         dec     ebx                              ; KEYBOARD
  1452.         jnz  nsyse2
  1453.         mov  edi,[TASK_BASE]
  1454.         mov  eax,[edi+TASKDATA.mem_start]
  1455.         add  eax,edx
  1456.  
  1457.         dec     ecx
  1458.         jnz  kbnobase
  1459.         mov  ebx,keymap
  1460.         mov  ecx,128
  1461.         call memmove
  1462.         ret
  1463.    kbnobase:
  1464.         dec  ecx
  1465.         jnz  kbnoshift
  1466.  
  1467.         mov  ebx,keymap_shift
  1468.         mov  ecx,128
  1469.         call memmove
  1470.         ret
  1471.    kbnoshift:
  1472.         dec  ecx
  1473.         jnz  kbnoalt
  1474.         mov  ebx,keymap_alt
  1475.         mov  ecx,128
  1476.         call memmove
  1477.         ret
  1478.    kbnoalt:
  1479.         sub  ecx,6
  1480.         jnz  kbnocountry
  1481.         mov  word [keyboard],dx
  1482.         ret
  1483.    kbnocountry:
  1484.         mov  [esp+32],dword 1
  1485.         ret
  1486.    nsyse2:
  1487.         dec  ebx                            ; CD
  1488.         jnz  nsyse4
  1489.  
  1490.         test ecx,ecx
  1491.         jz   nosesl
  1492.  
  1493.         cmp  ecx, 4
  1494.         ja   nosesl
  1495.         mov  [cd_base],cl
  1496.  
  1497.         dec     ecx
  1498.         jnz  noprma
  1499.         mov  [cdbase],0x1f0
  1500.         mov  [cdid],0xa0
  1501.    noprma:
  1502.  
  1503.         dec     ecx
  1504.         jnz  noprsl
  1505.         mov  [cdbase],0x1f0
  1506.         mov  [cdid],0xb0
  1507.    noprsl:
  1508.         dec     ecx
  1509.         jnz  nosema
  1510.         mov  [cdbase],0x170
  1511.         mov  [cdid],0xa0
  1512.    nosema:
  1513.         dec     ecx
  1514.         jnz  nosesl
  1515.         mov  [cdbase],0x170
  1516.         mov  [cdid],0xb0
  1517.    nosesl:
  1518.         ret
  1519.  
  1520. iglobal
  1521. cd_base db 0
  1522.  
  1523. endg
  1524.    nsyse4:
  1525.  
  1526.         sub  ebx,2               ; SYSTEM LANGUAGE
  1527.         jnz  nsyse5
  1528.         mov  [syslang],ecx
  1529.         ret
  1530.    nsyse5:
  1531.  
  1532.         sub  ebx,2              ; HD BASE
  1533.         jnz  nsyse7
  1534.  
  1535.         test ecx,ecx
  1536.         jz   nosethd
  1537.  
  1538.         cmp  ecx,4
  1539.         ja   nosethd
  1540.         mov  [hd_base],cl
  1541.  
  1542.         cmp  ecx,1
  1543.         jnz  noprmahd
  1544.         mov  [hdbase],0x1f0
  1545.         and  dword [hdid],0x0
  1546.         mov  dword [hdpos],ecx
  1547. ;     call set_FAT32_variables
  1548.    noprmahd:
  1549.  
  1550.         cmp  ecx,2
  1551.         jnz  noprslhd
  1552.         mov  [hdbase],0x1f0
  1553.         mov  [hdid],0x10
  1554.         mov  dword [hdpos],ecx
  1555. ;     call set_FAT32_variables
  1556.    noprslhd:
  1557.  
  1558.         cmp  ecx,3
  1559.         jnz  nosemahd
  1560.         mov  [hdbase],0x170
  1561.         and  dword [hdid],0x0
  1562.         mov  dword [hdpos],ecx
  1563. ;     call set_FAT32_variables
  1564.    nosemahd:
  1565.  
  1566.         cmp  ecx,4
  1567.         jnz  noseslhd
  1568.         mov  [hdbase],0x170
  1569.         mov  [hdid],0x10
  1570.         mov  dword [hdpos],ecx
  1571. ;     call set_FAT32_variables
  1572.    noseslhd:
  1573.         call  reserve_hd1
  1574.         call  reserve_hd_channel
  1575.         call  free_hd_channel
  1576.         and   dword [hd1_status],0        ; free
  1577.    nosethd:
  1578.         ret
  1579.  
  1580. iglobal
  1581. hd_base db 0
  1582. endg
  1583.  
  1584. nsyse7:
  1585.  
  1586. ;     cmp  eax,8                      ; HD PARTITION
  1587.         dec  ebx
  1588.         jnz  nsyse8
  1589.         mov  [fat32part],ecx
  1590. ;     call set_FAT32_variables
  1591.         call  reserve_hd1
  1592.         call  reserve_hd_channel
  1593.         call  free_hd_channel
  1594. ;       pusha
  1595.         call  choice_necessity_partition_1
  1596. ;       popa
  1597.         and dword [hd1_status],0        ; free
  1598.         ret
  1599.  
  1600. nsyse8:
  1601. ;     cmp  eax,11                     ; ENABLE LBA READ
  1602.         and  ecx,1
  1603.         sub  ebx,3
  1604.         jnz  no_set_lba_read
  1605.         mov  [lba_read_enabled],ecx
  1606.         ret
  1607.  
  1608. no_set_lba_read:
  1609. ;     cmp  eax,12                     ; ENABLE PCI ACCESS
  1610.         dec  ebx
  1611.         jnz  no_set_pci_access
  1612.         mov  [pci_access_enabled],ecx
  1613.         ret
  1614. no_set_pci_access:
  1615.  
  1616. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1617. include 'vmodeint.inc'
  1618. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1619.  
  1620. sys_setup_err:
  1621.         or  [esp+32],dword -1
  1622.         ret
  1623.  
  1624. align 4
  1625.  
  1626. sys_getsetup:
  1627.  
  1628. ; 1=roland mpu midi base , base io address
  1629. ; 2=keyboard   1, base kaybap 2, shift keymap, 9 country 1eng 2fi 3ger 4rus
  1630. ; 3=cd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1631. ; 5=system language, 1eng 2fi 3ger 4rus
  1632. ; 7=hd base    1, pri.master 2, pri slave 3 sec master, 4 sec slave
  1633. ; 8=fat32 partition in hd
  1634. ; 9=get hs timer tic
  1635.  
  1636. ;     cmp  eax,1
  1637.         dec     ebx
  1638.         jnz  ngsyse1
  1639.         movzx eax,[midi_base]
  1640.         mov  [esp+32],eax
  1641.         ret
  1642. ngsyse1:
  1643. ;     cmp  eax,2
  1644.         dec     ebx
  1645.         jnz  ngsyse2
  1646.  
  1647.         mov  edi,[TASK_BASE]
  1648.         mov  ebx,[edi+TASKDATA.mem_start]
  1649.         add  ebx,edx
  1650.  
  1651. ;     cmp  ebx,1
  1652.         dec     ecx
  1653.         jnz  kbnobaseret
  1654.         mov  eax,keymap
  1655.         mov  ecx,128
  1656.         call memmove
  1657.         ret
  1658. kbnobaseret:
  1659. ;     cmp  ebx,2
  1660.         dec     ecx
  1661.         jnz  kbnoshiftret
  1662.  
  1663.         mov  eax,keymap_shift
  1664.         mov  ecx,128
  1665.         call memmove
  1666.         ret
  1667. kbnoshiftret:
  1668. ;     cmp  ebx,3
  1669.         dec     ecx
  1670.         jne  kbnoaltret
  1671.  
  1672.         mov  eax,keymap_alt
  1673.         mov  ecx,128
  1674.         call memmove
  1675.         ret
  1676. kbnoaltret:
  1677. ;     cmp  ebx,9
  1678.         sub     ecx,6
  1679.         jnz  ngsyse2
  1680.         movzx eax,word [keyboard]
  1681.         mov  [esp+32],eax
  1682.         ret
  1683.  
  1684.  
  1685. ngsyse2:
  1686. ;         cmp  eax,3
  1687.         dec     ebx
  1688.         jnz  ngsyse3
  1689.         movzx eax,[cd_base]
  1690.         mov  [esp+32],eax
  1691.         ret
  1692. ngsyse3:
  1693. ;         cmp  eax,5
  1694.         sub     ebx,2
  1695.         jnz  ngsyse5
  1696.         mov  eax,[syslang]
  1697.         mov  [esp+32],eax
  1698.         ret
  1699. ngsyse5:
  1700. ;     cmp  eax,7
  1701.         sub     ebx,2
  1702.         jnz  ngsyse7
  1703.         movzx eax,[hd_base]
  1704.         mov  [esp+32],eax
  1705.         ret
  1706. ngsyse7:
  1707. ;     cmp  eax,8
  1708.         dec     ebx
  1709.         jnz  ngsyse8
  1710.         mov eax,[fat32part]
  1711.         mov  [esp+32],eax
  1712.         ret
  1713. ngsyse8:
  1714. ;     cmp  eax,9
  1715.         dec     ebx
  1716.         jnz  ngsyse9
  1717.         mov  eax,[timer_ticks] ;[0xfdf0]
  1718.         mov  [esp+32],eax
  1719.         ret
  1720. ngsyse9:
  1721. ;     cmp  eax,11
  1722.         sub     ebx,2
  1723.         jnz  ngsyse11
  1724.         mov eax,[lba_read_enabled]
  1725.         mov  [esp+32],eax
  1726.         ret
  1727. ngsyse11:
  1728. ;     cmp  eax,12
  1729.         dec     ebx
  1730.         jnz  ngsyse12
  1731.         mov eax,[pci_access_enabled]
  1732.         mov  [esp+32],eax
  1733.         ret
  1734. ngsyse12:
  1735.         mov  [esp+32],dword 1
  1736.         ret
  1737.  
  1738.  
  1739. get_timer_ticks:
  1740.         mov eax,[timer_ticks]
  1741.         ret
  1742.  
  1743. iglobal
  1744. align 4
  1745. mousefn dd msscreen, mswin, msbutton, msset
  1746.         dd app_load_cursor
  1747.         dd app_set_cursor
  1748.         dd app_delete_cursor
  1749.         dd msz
  1750. endg
  1751.  
  1752. readmousepos:
  1753.  
  1754. ; eax=0 screen relative
  1755. ; eax=1 window relative
  1756. ; eax=2 buttons pressed
  1757. ; eax=3 set mouse pos   ; reserved
  1758. ; eax=4 load cursor
  1759. ; eax=5 set cursor
  1760. ; eax=6 delete cursor   ; reserved
  1761. ; eax=7 get mouse_z
  1762.  
  1763.            cmp ebx, 7
  1764.            ja msset
  1765.            jmp [mousefn+ebx*4]
  1766. msscreen:
  1767.            mov  eax,[MOUSE_X]
  1768.            shl  eax,16
  1769.            mov  ax,[MOUSE_Y]
  1770.            mov  [esp+36-4],eax
  1771.            ret
  1772. mswin:
  1773.            mov  eax,[MOUSE_X]
  1774.            shl  eax,16
  1775.            mov  ax,[MOUSE_Y]
  1776.            mov  esi,[TASK_BASE]
  1777.            mov  bx, word [esi-twdw+WDATA.box.left]
  1778.            shl  ebx,16
  1779.            mov  bx, word [esi-twdw+WDATA.box.top]
  1780.            sub  eax,ebx
  1781.  
  1782.            mov  edi,[CURRENT_TASK]
  1783.            shl  edi,8
  1784.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.top]
  1785.            rol  eax,16
  1786.            sub  ax,word[edi+SLOT_BASE+APPDATA.wnd_clientbox.left]
  1787.            rol  eax,16
  1788.            mov  [esp+36-4],eax
  1789.            ret
  1790. msbutton:
  1791.            movzx eax,byte [BTN_DOWN]
  1792.            mov  [esp+36-4],eax
  1793.            ret
  1794. msz:
  1795.            mov   edi, [TASK_COUNT]
  1796.            movzx edi, word [WIN_POS + edi*2]
  1797.            cmp   edi, [CURRENT_TASK]
  1798.            jne   @f
  1799.            mov   ax,[MOUSE_SCROLL_H]
  1800.            shl   eax,16
  1801.            mov   ax,[MOUSE_SCROLL_V]
  1802.            mov   [esp+36-4],eax
  1803.            and   [MOUSE_SCROLL_H],word 0
  1804.            and   [MOUSE_SCROLL_V],word 0
  1805.            ret
  1806.        @@:
  1807.            and  [esp+36-4],dword 0
  1808. ;           ret
  1809. msset:
  1810.            ret
  1811.  
  1812. app_load_cursor:
  1813.            cmp ecx, OS_BASE
  1814.            jae msset
  1815.            stdcall load_cursor, ecx, edx
  1816.            mov [esp+36-4], eax
  1817.            ret
  1818.  
  1819. app_set_cursor:
  1820.            stdcall set_cursor, ecx
  1821.            mov [esp+36-4], eax
  1822.            ret
  1823.  
  1824. app_delete_cursor:
  1825.            stdcall delete_cursor, ecx
  1826.            mov [esp+36-4], eax
  1827.            ret
  1828.  
  1829. is_input:
  1830.  
  1831.    push edx
  1832.    mov  dx,word [midisp]
  1833.    in   al,dx
  1834.    and  al,0x80
  1835.    pop  edx
  1836.    ret
  1837.  
  1838. is_output:
  1839.  
  1840.    push edx
  1841.    mov  dx,word [midisp]
  1842.    in   al,dx
  1843.    and  al,0x40
  1844.    pop  edx
  1845.    ret
  1846.  
  1847.  
  1848. get_mpu_in:
  1849.  
  1850.    push edx
  1851.    mov  dx,word [mididp]
  1852.    in   al,dx
  1853.    pop  edx
  1854.    ret
  1855.  
  1856.  
  1857. put_mpu_out:
  1858.  
  1859.    push edx
  1860.    mov  dx,word [mididp]
  1861.    out  dx,al
  1862.    pop  edx
  1863.    ret
  1864.  
  1865.  
  1866.  
  1867. align 4
  1868.  
  1869. sys_midi:
  1870.         cmp  [mididp],0
  1871.         jnz  sm0
  1872.         mov  [esp+36],dword 1
  1873.         ret
  1874. sm0:
  1875.         and  [esp+36],dword 0
  1876.         dec  ebx
  1877.         jnz  smn1
  1878.  ;    call setuart
  1879. su1:
  1880.         call is_output
  1881.         test al,al
  1882.         jnz  su1
  1883.         mov  dx,word [midisp]
  1884.         mov  al,0xff
  1885.         out  dx,al
  1886. su2:
  1887.         mov  dx,word [midisp]
  1888.         mov  al,0xff
  1889.         out  dx,al
  1890.         call is_input
  1891.         test al,al
  1892.         jnz  su2
  1893.         call get_mpu_in
  1894.         cmp  al,0xfe
  1895.         jnz  su2
  1896. su3:
  1897.         call is_output
  1898.         test  al,al
  1899.         jnz  su3
  1900.         mov  dx,word [midisp]
  1901.         mov  al,0x3f
  1902.         out  dx,al
  1903.         ret
  1904. smn1:
  1905.         dec  ebx
  1906.         jnz  smn2
  1907. sm10:
  1908.         call get_mpu_in
  1909.         call is_output
  1910.         test al,al
  1911.         jnz  sm10
  1912.         mov  al,bl
  1913.         call put_mpu_out
  1914.         smn2:
  1915.         ret
  1916.  
  1917. detect_devices:
  1918. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1919. ;include 'detect/commouse.inc'
  1920. ;include 'detect/ps2mouse.inc'
  1921. ;include 'detect/dev_fd.inc'
  1922. ;include 'detect/dev_hdcd.inc'
  1923. ;include 'detect/sear_par.inc'
  1924. ;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  1925.     ret
  1926.  
  1927. sys_end:
  1928.  
  1929.      mov ecx, [current_slot]
  1930.      mov eax, [ecx+APPDATA.tls_base]
  1931.      test eax, eax
  1932.      jz @F
  1933.  
  1934.      stdcall user_free, eax
  1935. @@:
  1936.  
  1937.      mov   eax,[TASK_BASE]
  1938.      mov   [eax+TASKDATA.state], 3  ; terminate this program
  1939.  
  1940.     waitterm:            ; wait here for termination
  1941.      mov   ebx,100
  1942.      call  delay_hs
  1943.      jmp   waitterm
  1944.  
  1945. iglobal
  1946. align 4
  1947. sys_system_table:
  1948.         dd      exit_for_anyone         ; 1 = obsolete
  1949.         dd      sysfn_terminate         ; 2 = terminate thread
  1950.         dd      sysfn_activate          ; 3 = activate window
  1951.         dd      sysfn_getidletime       ; 4 = get idle time
  1952.         dd      sysfn_getcpuclock       ; 5 = get cpu clock
  1953.         dd      sysfn_saveramdisk       ; 6 = save ramdisk
  1954.         dd      sysfn_getactive         ; 7 = get active window
  1955.         dd      sysfn_sound_flag        ; 8 = get/set sound_flag
  1956.         dd      sysfn_shutdown          ; 9 = shutdown with parameter
  1957.         dd      sysfn_minimize          ; 10 = minimize window
  1958.         dd      sysfn_getdiskinfo       ; 11 = get disk subsystem info
  1959.         dd      sysfn_lastkey           ; 12 = get last pressed key
  1960.         dd      sysfn_getversion        ; 13 = get kernel version
  1961.         dd      sysfn_waitretrace       ; 14 = wait retrace
  1962.         dd      sysfn_centermouse       ; 15 = center mouse cursor
  1963.         dd      sysfn_getfreemem        ; 16 = get free memory size
  1964.         dd      sysfn_getallmem         ; 17 = get total memory size
  1965.         dd      sysfn_terminate2        ; 18 = terminate thread using PID
  1966.                                         ;                 instead of slot
  1967.         dd      sysfn_mouse_acceleration; 19 = set/get mouse acceleration
  1968.         dd      sysfn_meminfo           ; 20 = get extended memory info
  1969.         dd      sysfn_pid_to_slot       ; 21 = get slot number for pid
  1970.         dd      sysfn_min_rest_window   ; 22 = minimize and restore any window
  1971. sysfn_num = ($ - sys_system_table)/4
  1972. endg
  1973.  
  1974. sys_system:
  1975.         dec     ebx
  1976.         cmp     ebx, sysfn_num
  1977.         jae     @f
  1978.         jmp     dword [sys_system_table + ebx*4]
  1979. @@:
  1980.         ret
  1981.  
  1982.  
  1983. sysfn_shutdown:          ; 18.9 = system shutdown
  1984.      cmp  ecx,1
  1985.      jl   exit_for_anyone
  1986.      cmp  ecx,4
  1987.      jg   exit_for_anyone
  1988.      mov  [BOOT_VAR+0x9030],cl
  1989.  
  1990.      mov  eax,[TASK_COUNT]
  1991.      mov  [SYS_SHUTDOWN],al
  1992.      mov  [shutdown_processes],eax
  1993.      and  dword [esp+32], 0
  1994.  exit_for_anyone:
  1995.      ret
  1996.   uglobal
  1997.    shutdown_processes: dd 0x0
  1998.   endg
  1999.  
  2000. sysfn_terminate:        ; 18.2 = TERMINATE
  2001.      cmp  ecx,2
  2002.      jb   noprocessterminate
  2003.      mov  edx,[TASK_COUNT]
  2004.      cmp  ecx,edx
  2005.      ja   noprocessterminate
  2006.      mov  eax,[TASK_COUNT]
  2007.      shl  ecx,5
  2008.      mov  edx,[ecx+CURRENT_TASK+TASKDATA.pid]
  2009.      add  ecx,CURRENT_TASK+TASKDATA.state
  2010.      cmp  byte [ecx], 9
  2011.      jz   noprocessterminate
  2012.  
  2013.      ;call MEM_Heap_Lock      ;guarantee that process isn't working with heap
  2014.      mov  [ecx],byte 3       ; clear possible i40's
  2015.      ;call MEM_Heap_UnLock
  2016.  
  2017.      cmp  edx,[application_table_status]    ; clear app table stat
  2018.      jne  noatsc
  2019.      and  [application_table_status],0
  2020.    noatsc:
  2021.    noprocessterminate:
  2022.      ret
  2023.  
  2024. sysfn_terminate2:
  2025. ;lock application_table_status mutex
  2026. .table_status:
  2027.     cli
  2028.     cmp    [application_table_status],0
  2029.     je     .stf
  2030.     sti
  2031.     call   change_task
  2032.     jmp    .table_status
  2033. .stf:
  2034.     call   set_application_table_status
  2035.     mov    eax,ecx
  2036.     call   pid_to_slot
  2037.     test   eax,eax
  2038.     jz     .not_found
  2039.     mov    ecx,eax
  2040.     cli
  2041.     call   sysfn_terminate
  2042.     and    [application_table_status],0
  2043.     sti
  2044.     and    dword [esp+32],0
  2045.     ret
  2046. .not_found:
  2047.     mov    [application_table_status],0
  2048.     or     dword [esp+32],-1
  2049.     ret
  2050.  
  2051. sysfn_activate:         ; 18.3 = ACTIVATE WINDOW
  2052.      cmp  ecx,2
  2053.      jb   .nowindowactivate
  2054.      cmp  ecx,[TASK_COUNT]
  2055.      ja   .nowindowactivate
  2056.  
  2057.      mov   [window_minimize], 2   ; restore window if minimized
  2058.  
  2059.      movzx esi, word [WIN_STACK + ecx*2]
  2060.      cmp   esi, [TASK_COUNT]
  2061.      je    .nowindowactivate ; already active
  2062.  
  2063.      mov   edi, ecx
  2064.      shl   edi, 5
  2065.      add   edi, window_data
  2066.      movzx esi, word [WIN_STACK + ecx * 2]
  2067.      lea   esi, [WIN_POS + esi * 2]
  2068.      call  waredraw
  2069. .nowindowactivate:
  2070.      ret
  2071.  
  2072. sysfn_getidletime:              ; 18.4 = GET IDLETIME
  2073.      mov  eax,[idleusesec]
  2074.      mov  [esp+32], eax
  2075.      ret
  2076.  
  2077. sysfn_getcpuclock:              ; 18.5 = GET TSC/SEC
  2078.      mov  eax,[CPU_FREQ]
  2079.      mov  [esp+32], eax
  2080.      ret
  2081.  
  2082. ;  SAVE ramdisk to /hd/1/menuet.img
  2083. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2084.    include 'blkdev/rdsave.inc'
  2085. ;!!!!!!!!!!!!!!!!!!!!!!!!
  2086. align 4
  2087. sysfn_getactive:        ; 18.7 = get active window
  2088.      mov  eax, [TASK_COUNT]
  2089.    movzx  eax, word [WIN_POS + eax*2]
  2090.      mov  [esp+32],eax
  2091.      ret
  2092.  
  2093. sysfn_sound_flag:       ; 18.8 = get/set sound_flag
  2094. ;     cmp  ecx,1
  2095.      dec  ecx
  2096.      jnz  nogetsoundflag
  2097.      movzx  eax,byte [sound_flag] ; get sound_flag
  2098.      mov  [esp+32],eax
  2099.      ret
  2100.  nogetsoundflag:
  2101. ;     cmp  ecx,2
  2102.      dec  ecx
  2103.      jnz  nosoundflag
  2104.      xor  byte [sound_flag], 1
  2105.  nosoundflag:
  2106.      ret
  2107.  
  2108. sysfn_minimize:         ; 18.10 = minimize window
  2109.      mov   [window_minimize],1
  2110.      ret
  2111. align 4
  2112. sysfn_getdiskinfo:      ; 18.11 = get disk info table
  2113. ;     cmp  ecx,1
  2114.      dec  ecx
  2115.      jnz  full_table
  2116.   small_table:
  2117.      call for_all_tables
  2118.      mov ecx,10
  2119.      cld
  2120.      rep movsb
  2121.      ret
  2122.    for_all_tables:
  2123.      mov edi,edx
  2124.      mov esi,DRIVE_DATA
  2125.      ret
  2126.   full_table:
  2127. ;     cmp  ecx,2
  2128.      dec  ecx
  2129.      jnz  exit_for_anyone
  2130.      call for_all_tables
  2131.      mov ecx,16384
  2132.      cld
  2133.      rep movsd
  2134.      ret
  2135.  
  2136. sysfn_lastkey:          ; 18.12 = return 0 (backward compatibility)
  2137.         and     dword [esp+32], 0
  2138.         ret
  2139.  
  2140. sysfn_getversion:       ; 18.13 = get kernel ID and version
  2141.      mov edi,ecx
  2142.      mov esi,version_inf
  2143.      mov ecx,version_end-version_inf
  2144.      rep movsb
  2145.      ret
  2146.  
  2147. sysfn_waitretrace:     ; 18.14 = sys wait retrace
  2148.      ;wait retrace functions
  2149.  sys_wait_retrace:
  2150.      mov edx,0x3da
  2151.  WaitRetrace_loop:
  2152.      in al,dx
  2153.      test al,1000b
  2154.      jz WaitRetrace_loop
  2155.      and [esp+32],dword 0
  2156.      ret
  2157.  
  2158. align 4
  2159. sysfn_centermouse:      ; 18.15 = mouse centered
  2160. ; removed here by <Lrz>
  2161. ;     call  mouse_centered
  2162. ;* mouse centered - start code- Mario79
  2163. ;mouse_centered:
  2164. ;        push  eax
  2165.         mov   eax,[Screen_Max_X]
  2166.         shr   eax,1
  2167.         mov   [MOUSE_X],ax
  2168.         mov   eax,[Screen_Max_Y]
  2169.         shr   eax,1
  2170.         mov   [MOUSE_Y],ax
  2171. ;        ret
  2172. ;* mouse centered - end code- Mario79
  2173.         xor   eax,eax
  2174.         and   [esp+32],eax
  2175. ;        pop   eax
  2176.  
  2177.      ret
  2178. align 4
  2179. sysfn_mouse_acceleration: ; 18.19 = set/get mouse features
  2180.      test ecx,ecx  ; get mouse speed factor
  2181.      jnz  .set_mouse_acceleration
  2182.      xor  eax,eax
  2183.      mov  ax,[mouse_speed_factor]
  2184.      mov  [esp+32],eax
  2185.      ret
  2186.  .set_mouse_acceleration:
  2187. ;     cmp  ecx,1  ; set mouse speed factor
  2188.      dec  ecx
  2189.      jnz  .get_mouse_delay
  2190.      mov  [mouse_speed_factor],dx
  2191.      ret
  2192.  .get_mouse_delay:
  2193. ;     cmp  ecx,2  ; get mouse delay
  2194.      dec  ecx
  2195.      jnz  .set_mouse_delay
  2196.      mov  eax,[mouse_delay]
  2197.      mov  [esp+32],eax
  2198.      ret
  2199.  .set_mouse_delay:
  2200. ;     cmp  ecx,3  ; set mouse delay
  2201.      dec  ecx
  2202.      jnz  .set_pointer_position
  2203.      mov  [mouse_delay],edx
  2204.      ret
  2205.  .set_pointer_position:
  2206. ;     cmp  ecx,4  ; set mouse pointer position
  2207.      dec   ecx
  2208.      jnz  .set_mouse_button
  2209.      cmp   dx, word[Screen_Max_Y]
  2210.      ja    .end
  2211.      rol   edx,16
  2212.      cmp   dx, word[Screen_Max_X]
  2213.      ja    .end
  2214.      mov   [MOUSE_X], edx
  2215.      ret
  2216.  .set_mouse_button:
  2217. ;     cmp   ecx,5  ; set mouse button features
  2218.      dec   ecx
  2219.      jnz  .end
  2220.      mov   [BTN_DOWN],dl
  2221.      mov   [mouse_active],1
  2222.  .end:
  2223.      ret
  2224.  
  2225. sysfn_getfreemem:
  2226.      mov eax, [pg_data.pages_free]
  2227.      shl eax, 2
  2228.      mov [esp+32],eax
  2229.      ret
  2230.  
  2231. sysfn_getallmem:
  2232.      mov  eax,[MEM_AMOUNT]
  2233.      shr eax, 10
  2234.      mov  [esp+32],eax
  2235.      ret
  2236.  
  2237. ; // Alver, 2007-22-08 // {
  2238. sysfn_pid_to_slot:
  2239.      mov   eax, ecx
  2240.      call  pid_to_slot
  2241.      mov   [esp+32], eax
  2242.      ret
  2243.  
  2244. sysfn_min_rest_window:
  2245.      pushad
  2246.      mov   eax, edx      ; ebx - operating
  2247.      shr   ecx, 1
  2248.      jnc    @f
  2249.      call  pid_to_slot
  2250. @@:
  2251.      or    eax, eax      ; eax - number of slot
  2252.      jz    .error
  2253.      cmp   eax, 255         ; varify maximal slot number
  2254.      ja    .error
  2255.      movzx eax, word [WIN_STACK + eax*2]
  2256.      shr   ecx, 1
  2257.      jc    .restore
  2258.  ; .minimize:
  2259.      call  minimize_window
  2260.      jmp   .exit
  2261. .restore:
  2262.      call  restore_minimized_window
  2263. .exit:
  2264.      popad
  2265.      xor   eax, eax
  2266.      mov   [esp+32], eax
  2267.      ret
  2268. .error:
  2269.      popad
  2270.      xor   eax, eax
  2271.      dec   eax
  2272.      mov   [esp+32], eax
  2273.      ret
  2274. ; } \\ Alver, 2007-22-08 \\
  2275.  
  2276. uglobal
  2277. ;// mike.dld, 2006-29-01 [
  2278. screen_workarea RECT
  2279. ;// mike.dld, 2006-29-01 ]
  2280. window_minimize db 0
  2281. sound_flag      db 0
  2282. endg
  2283.  
  2284. UID_NONE=0
  2285. UID_MENUETOS=1   ;official
  2286. UID_KOLIBRI=2    ;russian
  2287.  
  2288. iglobal
  2289. version_inf:
  2290.   db 0,7,7,0  ; version 0.7.7.0
  2291.   db 0
  2292.   dd __REV__
  2293. version_end:
  2294. endg
  2295.  
  2296. sys_cachetodiskette:
  2297.         cmp     ebx, 1
  2298.         jne     .no_floppy_a_save
  2299.         mov     [flp_number], 1
  2300.         jmp     .save_image_on_floppy
  2301. .no_floppy_a_save:
  2302.         cmp     ebx, 2
  2303.         jne     .no_floppy_b_save
  2304.         mov     [flp_number], 2
  2305. .save_image_on_floppy:
  2306.         call    save_image
  2307.         mov     [esp + 32], dword 0
  2308.         cmp     [FDC_Status], 0
  2309.         je      .yes_floppy_save
  2310. .no_floppy_b_save:
  2311.         mov     [esp + 32], dword 1
  2312. .yes_floppy_save:
  2313.         ret
  2314.  
  2315. uglobal
  2316. ;  bgrchanged  dd  0x0
  2317. align 4
  2318. bgrlockpid dd 0
  2319. bgrlock db 0
  2320. endg
  2321.  
  2322. sys_background:
  2323.  
  2324.     cmp   ebx,1                            ; BACKGROUND SIZE
  2325.     jnz   nosb1
  2326.     test  ecx,ecx
  2327. ;    cmp   ecx,0
  2328.     jz    sbgrr
  2329.     test  edx,edx
  2330. ;    cmp   edx,0
  2331.     jz    sbgrr
  2332. @@:
  2333. ;;Maxis use atomic bts for mutexes  4.4.2009
  2334.         bts     dword [bgrlock], 0
  2335.         jnc     @f
  2336.         call    change_task
  2337.         jmp     @b
  2338. @@:
  2339.     mov   [BgrDataWidth],ecx
  2340.     mov   [BgrDataHeight],edx
  2341. ;    mov   [bgrchanged],1
  2342.  
  2343.     pushad
  2344. ; return memory for old background
  2345.         mov     eax, [img_background]
  2346.         cmp     eax, static_background_data
  2347.         jz      @f
  2348.         stdcall kernel_free, eax
  2349. @@:
  2350. ; calculate RAW size
  2351.     xor  eax,eax
  2352.     inc  eax
  2353.     cmp  [BgrDataWidth],eax
  2354.     jae   @f
  2355.     mov [BgrDataWidth],eax
  2356. @@:
  2357.     cmp  [BgrDataHeight],eax
  2358.     jae   @f
  2359.     mov [BgrDataHeight],eax
  2360. @@:
  2361.     mov  eax,[BgrDataWidth]
  2362.     imul eax,[BgrDataHeight]
  2363.     lea  eax,[eax*3]
  2364.     mov  [mem_BACKGROUND],eax
  2365. ; get memory for new background
  2366.     stdcall kernel_alloc, eax
  2367.     test eax, eax
  2368.     jz .memfailed
  2369.     mov [img_background], eax
  2370.     jmp .exit
  2371. .memfailed:
  2372. ; revert to static monotone data
  2373.         mov     [img_background], static_background_data
  2374.         xor     eax, eax
  2375.         inc     eax
  2376.         mov     [BgrDataWidth], eax
  2377.         mov     [BgrDataHeight], eax
  2378.         mov     [mem_BACKGROUND], 4
  2379. .exit:
  2380.     popad
  2381.         mov     [bgrlock], 0
  2382.  
  2383.   sbgrr:
  2384.     ret
  2385.  
  2386. nosb1:
  2387.  
  2388.     cmp   ebx,2                            ; SET PIXEL
  2389.     jnz   nosb2
  2390.  
  2391.     mov   eax, [img_background]
  2392.     test  ecx, ecx
  2393.     jz    @f
  2394.     cmp   eax, static_background_data
  2395.     jz    .ret
  2396. @@:
  2397.     mov ebx, [mem_BACKGROUND]
  2398.     add ebx, 4095
  2399.     and ebx, -4096
  2400.     sub ebx, 4
  2401.     cmp   ecx, ebx
  2402.     ja   .ret
  2403.  
  2404.     mov   ebx,[eax+ecx]
  2405.     and   ebx,0xFF000000 ;255*256*256*256
  2406.     and   edx,0x00FFFFFF ;255*256*256+255*256+255
  2407.     add   edx,ebx
  2408.     mov   [eax+ecx],edx
  2409. .ret:
  2410.     ret
  2411. nosb2:
  2412.  
  2413.     cmp   ebx,3                            ; DRAW BACKGROUND
  2414.     jnz   nosb3
  2415. draw_background_temp:
  2416. ;    cmp   [bgrchanged],1 ;0
  2417. ;    je    nosb31
  2418. ;draw_background_temp:
  2419. ;    mov   [bgrchanged],1 ;0
  2420.     mov    [background_defined], 1
  2421.     mov    byte[BACKGROUND_CHANGED], 1
  2422.     call  force_redraw_background
  2423.    nosb31:
  2424.     ret
  2425.   nosb3:
  2426.  
  2427.     cmp   ebx,4                            ; TILED / STRETCHED
  2428.     jnz   nosb4
  2429.     cmp   ecx,[BgrDrawMode]
  2430.     je    nosb41
  2431.     mov   [BgrDrawMode],ecx
  2432. ;    mov   [bgrchanged],1
  2433.    nosb41:
  2434.     ret
  2435.   nosb4:
  2436.  
  2437.     cmp   ebx,5                            ; BLOCK MOVE TO BGR
  2438.     jnz   nosb5
  2439.     cmp   [img_background], static_background_data
  2440.     jnz   @f
  2441.     test  edx, edx
  2442.     jnz   .fin
  2443.     cmp   esi, 4
  2444.     ja    .fin
  2445.   @@:
  2446.   ; bughere
  2447.     mov   eax, ecx
  2448.     mov   ebx, edx
  2449.     add   ebx, [img_background]   ;IMG_BACKGROUND
  2450.     mov   ecx, esi
  2451.     call  memmove
  2452.   .fin:
  2453.     ret
  2454.   nosb5:
  2455.  
  2456.         cmp     ebx, 6
  2457.         jnz     nosb6
  2458. ;;Maxis use atomic bts for mutex 4.4.2009
  2459. @@:
  2460.         bts     dword [bgrlock], 0
  2461.         jnc     @f
  2462.         call    change_task
  2463.         jmp     @b
  2464. @@:
  2465.         mov     eax, [CURRENT_TASK]
  2466.         mov     [bgrlockpid], eax
  2467.         cmp     [img_background], static_background_data
  2468.         jz      .nomem
  2469.         stdcall user_alloc, [mem_BACKGROUND]
  2470.         mov     [esp+32], eax
  2471.         test    eax, eax
  2472.         jz      .nomem
  2473.         mov     ebx, eax
  2474.         shr     ebx, 12
  2475.         or      dword [page_tabs+(ebx-1)*4], DONT_FREE_BLOCK
  2476.         mov     esi, [img_background]
  2477.         shr     esi, 12
  2478.         mov     ecx, [mem_BACKGROUND]
  2479.         add     ecx, 0xFFF
  2480.         shr     ecx, 12
  2481. .z:
  2482.         mov     eax, [page_tabs+ebx*4]
  2483.         test    al, 1
  2484.         jz      @f
  2485.         call    free_page
  2486. @@:
  2487.         mov     eax, [page_tabs+esi*4]
  2488.         or      al, PG_UW
  2489.         mov     [page_tabs+ebx*4], eax
  2490.         mov     eax, ebx
  2491.         shl     eax, 12
  2492.         invlpg  [eax]
  2493.         inc     ebx
  2494.         inc     esi
  2495.         loop    .z
  2496.         ret
  2497. .nomem:
  2498.         and     [bgrlockpid], 0
  2499.         mov     [bgrlock], 0
  2500. nosb6:
  2501.         cmp     ebx, 7
  2502.         jnz     nosb7
  2503.         cmp     [bgrlock], 0
  2504.         jz      .err
  2505.         mov     eax, [CURRENT_TASK]
  2506.         cmp     [bgrlockpid], eax
  2507.         jnz     .err
  2508.         mov     eax, ecx
  2509.         mov     ebx, ecx
  2510.         shr     eax, 12
  2511.         mov     ecx, [page_tabs+(eax-1)*4]
  2512.         test    cl, USED_BLOCK+DONT_FREE_BLOCK
  2513.         jz      .err
  2514.         jnp     .err
  2515.         push    eax
  2516.         shr     ecx, 12
  2517.         dec     ecx
  2518. @@:
  2519.         and     dword [page_tabs+eax*4], 0
  2520.         mov     edx, eax
  2521.         shl     edx, 12
  2522.         push eax
  2523.         invlpg  [edx]
  2524.         pop eax
  2525.         inc     eax
  2526.         loop    @b
  2527.         pop     eax
  2528.         and     dword [page_tabs+(eax-1)*4], not DONT_FREE_BLOCK
  2529.         stdcall user_free, ebx
  2530.         mov     [esp+32], eax
  2531.         and     [bgrlockpid], 0
  2532.         mov     [bgrlock], 0
  2533.         ret
  2534. .err:
  2535.         and     dword [esp+32], 0
  2536.         ret
  2537.  
  2538. nosb7:
  2539.     ret
  2540.  
  2541. force_redraw_background:
  2542.     and   [draw_data+32 + RECT.left], 0
  2543.     and   [draw_data+32 + RECT.top], 0
  2544.     push  eax ebx
  2545.     mov   eax,[Screen_Max_X]
  2546.     mov   ebx,[Screen_Max_Y]
  2547.     mov   [draw_data+32 + RECT.right],eax
  2548.     mov   [draw_data+32 + RECT.bottom],ebx
  2549.     pop   ebx eax
  2550.     inc   byte[REDRAW_BACKGROUND]
  2551.     ret
  2552.  
  2553. align 4
  2554.  
  2555. sys_getbackground:
  2556. ;    cmp   eax,1                                  ; SIZE
  2557.     dec   ebx
  2558.     jnz   nogb1
  2559.     mov   eax,[BgrDataWidth]
  2560.     shl   eax,16
  2561.     mov   ax,[BgrDataHeight]
  2562.     mov   [esp+32],eax
  2563.     ret
  2564.  
  2565. nogb1:
  2566. ;    cmp   eax,2                                  ; PIXEL
  2567.     dec   ebx
  2568.     jnz   nogb2
  2569.  
  2570.         mov     eax, [img_background]
  2571.         test    ecx, ecx
  2572.         jz      @f
  2573.         cmp     eax, static_background_data
  2574.         jz      .ret
  2575. @@:
  2576.     mov ebx, [mem_BACKGROUND]
  2577.     add ebx, 4095
  2578.     and ebx, -4096
  2579.     sub ebx, 4
  2580.     cmp ecx, ebx
  2581.     ja  .ret
  2582.  
  2583.     mov   eax,[ecx+eax]
  2584.  
  2585.     and   eax, 0xFFFFFF
  2586.     mov   [esp+32],eax
  2587. .ret:
  2588.     ret
  2589.   nogb2:
  2590.  
  2591. ;    cmp   eax,4                                  ; TILED / STRETCHED
  2592.     dec   ebx
  2593.     dec   ebx
  2594.     jnz   nogb4
  2595.     mov   eax,[BgrDrawMode]
  2596.   nogb4:
  2597.     mov   [esp+32],eax
  2598.     ret
  2599.  
  2600. align 4
  2601.  
  2602. sys_getkey:
  2603.         mov     [esp + 32],dword 1
  2604.         ; test main buffer
  2605.         mov     ebx, [CURRENT_TASK]                          ; TOP OF WINDOW STACK
  2606.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2607.         mov     edx, [TASK_COUNT]
  2608.         cmp     ecx, edx
  2609.         jne     .finish
  2610.         cmp     [KEY_COUNT], byte 0
  2611.         je      .finish
  2612.         movzx   eax, byte [KEY_BUFF]
  2613.         shl     eax, 8
  2614.         push    eax
  2615.         dec     byte [KEY_COUNT]
  2616.         and     byte [KEY_COUNT], 127
  2617.         movzx   ecx, byte [KEY_COUNT]
  2618.         add     ecx, 2
  2619.         mov     eax, KEY_BUFF + 1
  2620.         mov     ebx, KEY_BUFF
  2621.         call    memmove
  2622.         pop     eax
  2623. .ret_eax:
  2624.         mov     [esp + 32], eax
  2625.         ret
  2626. .finish:
  2627. ; test hotkeys buffer
  2628.         mov     ecx, hotkey_buffer
  2629. @@:
  2630.         cmp     [ecx], ebx
  2631.         jz      .found
  2632.         add     ecx, 8
  2633.         cmp     ecx, hotkey_buffer + 120 * 8
  2634.         jb      @b
  2635.         ret
  2636. .found:
  2637.         mov     ax, [ecx + 6]
  2638.         shl     eax, 16
  2639.         mov     ah, [ecx + 4]
  2640.         mov     al, 2
  2641.         and     dword [ecx + 4], 0
  2642.         and     dword [ecx], 0
  2643.         jmp     .ret_eax
  2644.  
  2645. align 4
  2646.  
  2647. sys_getbutton:
  2648.  
  2649.         mov     ebx, [CURRENT_TASK]                         ; TOP OF WINDOW STACK
  2650.         mov     [esp + 32], dword 1
  2651.         movzx   ecx, word [WIN_STACK + ebx * 2]
  2652.         mov     edx, [TASK_COUNT] ; less than 256 processes
  2653.         cmp     ecx, edx
  2654.         jne     .exit
  2655.         movzx   eax, byte [BTN_COUNT]
  2656.         test    eax, eax
  2657.         jz      .exit
  2658.         mov     eax, [BTN_BUFF]
  2659.         and     al, 0xFE                                    ; delete left button bit
  2660.         mov     [BTN_COUNT], byte 0
  2661.         mov     [esp + 32], eax
  2662. .exit:
  2663.         ret
  2664.  
  2665.  
  2666. align 4
  2667.  
  2668. sys_cpuusage:
  2669.  
  2670. ;  RETURN:
  2671. ;
  2672. ;  +00 dword     process cpu usage
  2673. ;  +04  word     position in windowing stack
  2674. ;  +06  word     windowing stack value at current position (cpu nro)
  2675. ;  +10 12 bytes  name
  2676. ;  +22 dword     start in mem
  2677. ;  +26 dword     used mem
  2678. ;  +30 dword     PID , process idenfification number
  2679. ;
  2680.  
  2681.     cmp  ecx,-1         ; who am I ?
  2682.     jne  .no_who_am_i
  2683.     mov  ecx,[CURRENT_TASK]
  2684.   .no_who_am_i:
  2685.         cmp     ecx, max_processes
  2686.         ja      .nofillbuf
  2687.  
  2688. ; +4: word: position of the window of thread in the window stack
  2689.         mov     ax, [WIN_STACK + ecx * 2]
  2690.         mov     [ebx+4], ax
  2691. ; +6: word: number of the thread slot, which window has in the window stack
  2692. ;           position ecx (has no relation to the specific thread)
  2693.         mov     ax, [WIN_POS + ecx * 2]
  2694.         mov     [ebx+6], ax
  2695.  
  2696.         shl     ecx, 5
  2697.  
  2698. ; +0: dword: memory usage
  2699.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.cpu_usage]
  2700.         mov     [ebx], eax
  2701. ; +10: 11 bytes: name of the process
  2702.         push    ecx
  2703.         lea     eax, [ecx*8+SLOT_BASE+APPDATA.app_name]
  2704.         add     ebx, 10
  2705.         mov     ecx, 11
  2706.         call    memmove
  2707.         pop     ecx
  2708.  
  2709. ; +22: address of the process in memory
  2710. ; +26: size of used memory - 1
  2711.         push    edi
  2712.         lea     edi, [ebx+12]
  2713.         xor     eax, eax
  2714.         mov     edx, 0x100000*16
  2715.         cmp     ecx, 1 shl 5
  2716.         je      .os_mem
  2717.         mov     edx, [SLOT_BASE+ecx*8+APPDATA.mem_size]
  2718.         mov     eax, std_application_base_address
  2719. .os_mem:
  2720.         stosd
  2721.         lea     eax, [edx-1]
  2722.         stosd
  2723.  
  2724. ; +30: PID/TID
  2725.         mov     eax, [ecx+CURRENT_TASK+TASKDATA.pid]
  2726.         stosd
  2727.  
  2728.     ; window position and size
  2729.         push    esi
  2730.         lea     esi, [ecx + window_data + WDATA.box]
  2731.         movsd
  2732.         movsd
  2733.         movsd
  2734.         movsd
  2735.  
  2736.     ; Process state (+50)
  2737.         mov     eax, dword [ecx+CURRENT_TASK+TASKDATA.state]
  2738.         stosd
  2739.  
  2740.     ; Window client area box
  2741.         lea     esi, [ecx*8 + SLOT_BASE + APPDATA.wnd_clientbox]
  2742.         movsd
  2743.         movsd
  2744.         movsd
  2745.         movsd
  2746.  
  2747.     ; Window state
  2748.         mov     al, [ecx+window_data+WDATA.fl_wstate]
  2749.         stosb
  2750.  
  2751.     ; Event mask (+71)
  2752.         mov     EAX, dword [ECX+CURRENT_TASK+TASKDATA.event_mask]
  2753.         stosd
  2754.  
  2755.         pop     esi
  2756.         pop     edi
  2757.  
  2758. .nofillbuf:
  2759.     ; return number of processes
  2760.  
  2761.     mov    eax,[TASK_COUNT]
  2762.     mov    [esp+32],eax
  2763.     ret
  2764.  
  2765. align 4
  2766. sys_clock:
  2767.         cli
  2768.   ; Mikhail Lisovin  xx Jan 2005
  2769.   @@:   mov   al, 10
  2770.         out   0x70, al
  2771.         in    al, 0x71
  2772.         test  al, al
  2773.         jns   @f
  2774.         mov   esi, 1
  2775.         call  delay_ms
  2776.         jmp   @b
  2777.   @@:
  2778.   ; end Lisovin's fix
  2779.  
  2780.         xor   al,al           ; seconds
  2781.         out   0x70,al
  2782.         in    al,0x71
  2783.         movzx ecx,al
  2784.         mov   al,02           ; minutes
  2785.         shl   ecx,16
  2786.         out   0x70,al
  2787.         in    al,0x71
  2788.         movzx edx,al
  2789.         mov   al,04           ; hours
  2790.         shl   edx,8
  2791.         out   0x70,al
  2792.         in    al,0x71
  2793.         add   ecx,edx
  2794.         movzx edx,al
  2795.         add   ecx,edx
  2796.         sti
  2797.         mov     [esp + 32], ecx
  2798.         ret
  2799.  
  2800.  
  2801. align 4
  2802.  
  2803. sys_date:
  2804.  
  2805.         cli
  2806.   @@:   mov   al, 10
  2807.         out   0x70, al
  2808.         in    al, 0x71
  2809.         test  al, al
  2810.         jns   @f
  2811.         mov   esi, 1
  2812.         call  delay_ms
  2813.         jmp   @b
  2814.   @@:
  2815.  
  2816.         mov     ch,0
  2817.         mov     al,7            ; date
  2818.         out     0x70,al
  2819.         in      al,0x71
  2820.         mov     cl,al
  2821.         mov     al,8            ; month
  2822.         shl     ecx,16
  2823.         out     0x70,al
  2824.         in      al,0x71
  2825.         mov     ch,al
  2826.         mov     al,9            ; year
  2827.         out     0x70,al
  2828.         in      al,0x71
  2829.         mov     cl,al
  2830.         sti
  2831.         mov     [esp+32], ecx
  2832.         ret
  2833.  
  2834.  
  2835. ; redraw status
  2836.  
  2837. sys_redrawstat:
  2838.         cmp     ebx, 1
  2839.         jne     no_widgets_away
  2840.         ; buttons away
  2841.         mov     ecx,[CURRENT_TASK]
  2842.   sys_newba2:
  2843.         mov     edi,[BTN_ADDR]
  2844.         cmp     [edi], dword 0  ; empty button list ?
  2845.         je      end_of_buttons_away
  2846.         movzx   ebx, word [edi]
  2847.         inc     ebx
  2848.         mov     eax,edi
  2849.   sys_newba:
  2850.         dec     ebx
  2851.         jz      end_of_buttons_away
  2852.  
  2853.         add     eax, 0x10
  2854.         cmp     cx, [eax]
  2855.         jnz     sys_newba
  2856.  
  2857.         push    eax ebx ecx
  2858.         mov     ecx,ebx
  2859.         inc     ecx
  2860.         shl     ecx, 4
  2861.         mov     ebx, eax
  2862.         add     eax, 0x10
  2863.         call    memmove
  2864.         dec     dword [edi]
  2865.         pop     ecx ebx eax
  2866.  
  2867.         jmp     sys_newba2
  2868.  
  2869.   end_of_buttons_away:
  2870.  
  2871.         ret
  2872.  
  2873.   no_widgets_away:
  2874.  
  2875.         cmp     ebx, 2
  2876.         jnz     srl1
  2877.  
  2878.         mov     edx, [TASK_BASE]      ; return whole screen draw area for this app
  2879.         add     edx, draw_data - CURRENT_TASK
  2880.         mov     [edx + RECT.left], 0
  2881.         mov     [edx + RECT.top], 0
  2882.         mov     eax, [Screen_Max_X]
  2883.         mov     [edx + RECT.right], eax
  2884.         mov     eax, [Screen_Max_Y]
  2885.         mov     [edx + RECT.bottom], eax
  2886.  
  2887.   srl1:
  2888.         ret
  2889.  
  2890. ;ok - 100% work
  2891. ;nt - not tested
  2892. ;---------------------------------------------------------------------------------------------
  2893. ;eax
  2894. ;0 - task switch counter. Ret switch counter in eax. Block. ok.
  2895. ;1 - change task. Ret nothing. Block. ok.
  2896. ;2 - performance control
  2897. ; ebx
  2898. ; 0 - enable or disable (inversion) PCE flag on CR4 for rdmpc in user mode.
  2899. ; returned new cr4 in eax. Ret cr4 in eax. Block. ok.
  2900. ; 1 - is cache enabled. Ret cr0 in eax if enabled else zero in eax. Block. ok.
  2901. ; 2 - enable cache. Ret 1 in eax. Ret nothing. Block. ok.
  2902. ; 3 - disable cache. Ret 0 in eax. Ret nothing. Block. ok.
  2903. ;eax
  2904. ;3 - rdmsr. Counter in edx. (edx:eax) [esi:edi, edx] => [edx:esi, ecx]. Ret in ebx:eax. Block. ok.